lisp/url/url-handlers.el

   1 ;;; url-handlers.el --- file-name-handler stuff for URL loading
   2
   3 ;; Copyright (C) 1996-1999, 2004-2014 Free Software Foundation, Inc.
   4
   5 ;; Keywords: comm, data, processes, hypermedia
   6
   7 ;; This file is part of GNU Emacs.
   8 ;;
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 ;; (require 'url)
  27 (require 'url-parse)
  28 ;; (require 'url-util)
  29 (eval-when-compile (require 'mm-decode))
  30 ;; (require 'mailcap)
  31 ;; The following are autoloaded instead of `require'd to avoid eagerly
  32 ;; loading all of URL when turning on url-handler-mode in the .emacs.
  33 (autoload 'url-expand-file-name "url-expand" "Convert url to a fully specified url, and canonicalize it.")
  34 (autoload 'mm-dissect-buffer "mm-decode" "Dissect the current buffer and return a list of MIME handles.")
  35 (autoload 'url-scheme-get-property "url-methods" "Get property of a URL SCHEME.")
  36 (autoload 'url-http-parse-response "url-http" "Parse just the response code.")
  37
  38 ;; Always used after mm-dissect-buffer and defined in the same file.
  39 (declare-function mm-save-part-to-file "mm-decode" (handle file))
  40 (declare-function mm-destroy-parts "mm-decode" (handles))
  41 ;; mm-decode loads mm-bodies.
  42 (declare-function mm-decode-string "mm-bodies" (string charset))
  43 ;; mm-decode loads mail-parse.
  44 (declare-function mail-content-type-get "mail-parse" (ct attribute))
  45
  46 ;; Implementation status
  47 ;; ---------------------
  48 ;; Function                             Status
  49 ;; ------------------------------------------------------------
  50 ;; add-name-to-file                     Needs DAV Bindings
  51 ;; copy-file                            Broken (assumes 1st item is URL)
  52 ;; delete-directory                     Finished (DAV)
  53 ;; delete-file                          Finished (DAV)
  54 ;; diff-latest-backup-file
  55 ;; directory-file-name                  unnecessary (what about VMS)?
  56 ;; directory-files                      Finished (DAV)
  57 ;; dired-call-process
  58 ;; dired-compress-file
  59 ;; dired-uncache
  60 ;; expand-file-name                     Finished
  61 ;; file-accessible-directory-p
  62 ;; file-attributes                      Finished, better with DAV
  63 ;; file-directory-p                     Needs DAV, finished
  64 ;; file-executable-p                    Finished
  65 ;; file-exists-p                        Finished
  66 ;; file-local-copy
  67 ;; file-modes
  68 ;; file-name-all-completions            Finished (DAV)
  69 ;; file-name-as-directory
  70 ;; file-name-completion                 Finished (DAV)
  71 ;; file-name-directory
  72 ;; file-name-nondirectory
  73 ;; file-name-sans-versions              why?
  74 ;; file-newer-than-file-p
  75 ;; file-ownership-preserved-p           No way to know
  76 ;; file-readable-p                      Finished
  77 ;; file-regular-p                       !directory_p
  78 ;; file-remote-p                        Finished
  79 ;; file-symlink-p                       Needs DAV bindings
  80 ;; file-truename                        Needs DAV bindings
  81 ;; file-writable-p                      Check for LOCK?
  82 ;; find-backup-file-name                why?
  83 ;; get-file-buffer                      why?
  84 ;; insert-directory                     Use DAV
  85 ;; insert-file-contents                 Finished
  86 ;; load
  87 ;; make-directory                       Finished (DAV)
  88 ;; make-symbolic-link                   Needs DAV bindings
  89 ;; rename-file                          Finished (DAV)
  90 ;; set-file-modes                       Use mod_dav specific executable flag?
  91 ;; set-visited-file-modtime             Impossible?
  92 ;; shell-command                        Impossible?
  93 ;; unhandled-file-name-directory
  94 ;; vc-registered                        Finished (DAV)
  95 ;; verify-visited-file-modtime
  96 ;; write-region
  97
  98 (defvar url-handler-regexp) ; defined below to avoid recursive load (revno:108572)
  99
 100 ;;;###autoload
 101 (define-minor-mode url-handler-mode
 102   "Toggle using `url' library for URL filenames (URL Handler mode).
 103 With a prefix argument ARG, enable URL Handler mode if ARG is
 104 positive, and disable it otherwise.  If called from Lisp, enable
 105 the mode if ARG is omitted or nil."
 106   :global t :group 'url
 107   ;; Remove old entry, if any.
 108   (setq file-name-handler-alist
 109         (delq (rassq 'url-file-handler file-name-handler-alist)
 110               file-name-handler-alist))
 111   (if url-handler-mode
 112       (push (cons url-handler-regexp 'url-file-handler)
 113             file-name-handler-alist)))
 114
 115 (defcustom url-handler-regexp "\\`\\(https?\\|ftp\\|file\\|nfs\\|ssh\\|scp\\|rsync\\|telnet\\)://"
 116   "Regular expression for URLs handled by `url-handler-mode'.
 117 When URL Handler mode is enabled, this regular expression is
 118 added to `file-name-handler-alist'.
 119
 120 Some valid URL protocols just do not make sense to visit
 121 interactively \(about, data, info, irc, mailto, etc\).  This
 122 regular expression avoids conflicts with local files that look
 123 like URLs \(Gnus is particularly bad at this\)."
 124   :group 'url
 125   :type 'regexp
 126   :version "24.5"
 127   :set (lambda (symbol value)
 128          (let ((enable url-handler-mode))
 129            (url-handler-mode 0)
 130            (set-default symbol value)
 131            (if enable
 132                (url-handler-mode)))))
 133
 134 (defun url-run-real-handler (operation args)
 135   (let ((inhibit-file-name-handlers (cons 'url-file-handler
 136                                           (if (eq operation inhibit-file-name-operation)
 137                                               inhibit-file-name-handlers)))
 138         (inhibit-file-name-operation operation))
 139     (apply operation args)))
 140
 141 (defvar url-file-handler-load-in-progress nil
 142   "Check for recursive load.")
 143
 144 ;;;###autoload
 145 (defun url-file-handler (operation &rest args)
 146   "Function called from the `file-name-handler-alist' routines.
 147 OPERATION is what needs to be done (`file-exists-p', etc).  ARGS are
 148 the arguments that would have been passed to OPERATION."
 149   ;; Avoid recursive load.
 150   (if (and load-in-progress url-file-handler-load-in-progress)
 151       (url-run-real-handler operation args)
 152     (let ((url-file-handler-load-in-progress load-in-progress))
 153       ;; Check, whether there are arguments we want pass to Tramp.
 154       (if (catch :do
 155             (dolist (url (cons default-directory args))
 156               (and (member
 157                     (url-type (url-generic-parse-url (and (stringp url) url)))
 158                     url-tramp-protocols)
 159                    (throw :do t))))
 160           (apply 'url-tramp-file-handler operation args)
 161         ;; Otherwise, let's do the job.
 162         (let ((fn (get operation 'url-file-handlers))
 163               (val nil)
 164               (hooked nil))
 165           (if (and (not fn) (intern-soft (format "url-%s" operation))
 166                    (fboundp (intern-soft (format "url-%s" operation))))
 167               (error "Missing URL handler mapping for %s" operation))
 168           (if fn
 169               (setq hooked t
 170                     val (save-match-data (apply fn args)))
 171             (setq hooked nil
 172                   val (url-run-real-handler operation args)))
 173           (url-debug 'handlers "%s %S%S => %S" (if hooked "Hooked" "Real")
 174                      operation args val)
 175           val)))))
 176
 177 (defun url-file-handler-identity (&rest args)
 178   ;; Identity function
 179   (car args))
 180
 181 ;; These are operations that we can fully support
 182 (put 'file-readable-p 'url-file-handlers 'url-file-exists-p)
 183 (put 'substitute-in-file-name 'url-file-handlers 'url-file-handler-identity)
 184 (put 'file-name-absolute-p 'url-file-handlers (lambda (&rest ignored) t))
 185 (put 'expand-file-name 'url-file-handlers 'url-handler-expand-file-name)
 186 (put 'directory-file-name 'url-file-handlers 'url-handler-directory-file-name)
 187 (put 'unhandled-file-name-directory 'url-file-handlers 'url-handler-unhandled-file-name-directory)
 188 (put 'file-remote-p 'url-file-handlers 'url-handler-file-remote-p)
 189 ;; (put 'file-name-as-directory 'url-file-handlers 'url-handler-file-name-as-directory)
 190
 191 ;; These are operations that we do not support yet (DAV!!!)
 192 (put 'file-writable-p 'url-file-handlers 'ignore)
 193 (put 'file-symlink-p 'url-file-handlers 'ignore)
 194 ;; Just like for ange-ftp: let's not waste time trying to look for RCS/foo,v
 195 ;; files and such since we can't do anything clever with them anyway.
 196 (put 'vc-registered 'url-file-handlers 'ignore)
 197
 198 (defun url-handler-expand-file-name (file &optional base)
 199   ;; When we see "/foo/bar" in a file whose working dir is "http://bla/bla",
 200   ;; there are two interpretations possible: either it's a local "/foo/bar"
 201   ;; or it's "http:/bla/foo/bar".  When working with URLs, the second
 202   ;; interpretation is the right one, but when working with Emacs file
 203   ;; names, the first is preferred.
 204   (if (file-name-absolute-p file)
 205       (expand-file-name file "/")
 206     (url-expand-file-name file base)))
 207
 208 ;; directory-file-name and file-name-as-directory are kind of hard to
 209 ;; implement really right for URLs since URLs can have repeated / chars.
 210 ;; We'd want the following behavior:
 211 ;; idempotence: (d-f-n (d-f-n X) == (d-f-n X)
 212 ;; idempotence: (f-n-a-d (f-n-a-d X) == (f-n-a-d X)
 213 ;; reversible:  (d-f-n (f-n-a-d (d-f-n X))) == (d-f-n X)
 214 ;; reversible:  (f-n-a-d (d-f-n (f-n-a-d X))) == (f-n-a-d X)
 215 (defun url-handler-directory-file-name (dir)
 216   ;; When there's more than a single /, just don't touch the slashes at all.
 217   (if (string-match "//\\'" dir) dir
 218     (url-run-real-handler 'directory-file-name (list dir))))
 219
 220 (defun url-handler-unhandled-file-name-directory (filename)
 221   (let ((url (url-generic-parse-url filename)))
 222     (if (equal (url-type url) "file")
 223         ;; `file' URLs are actually local.  The filename part may be ""
 224         ;; which really stands for "/".
 225         ;; FIXME: maybe we should check that the host part is "" or "localhost"
 226         ;; or some name that represents the local host?
 227         (or (file-name-directory (url-filename url)) "/")
 228       ;; All other URLs are not expected to be directly accessible from
 229       ;; a local process.
 230       nil)))
 231
 232 (defun url-handler-file-remote-p (filename &optional identification connected)
 233   (let ((url (url-generic-parse-url filename)))
 234     (if (and (url-type url) (not (equal (url-type url) "file")))
 235         ;; Maybe we can find a suitable check for CONNECTED.  For now,
 236         ;; we ignore it.
 237         (cond
 238          ((eq identification 'method) (url-type url))
 239          ((eq identification 'user) (url-user url))
 240          ((eq identification 'host) (url-host url))
 241          ((eq identification 'localname) (url-filename url))
 242          (t (url-recreate-url
 243              (url-parse-make-urlobj (url-type url) (url-user url) nil
 244                                     (url-host url) (url-port url)))))
 245       ;; If there is no URL type, or it is a "file://" URL, the
 246       ;; filename is expected to be non remote.  A more subtle check
 247       ;; for "file://" URLs could be applied, as said in
 248       ;; `url-handler-unhandled-file-name-directory'.
 249       nil)))
 250
 251 ;; The actual implementation
 252 ;;;###autoload
 253 (defun url-copy-file (url newname &optional ok-if-already-exists
 254                           keep-time preserve-uid-gid)
 255   "Copy URL to NEWNAME.  Both args must be strings.
 256 Signals a `file-already-exists' error if file NEWNAME already exists,
 257 unless a third argument OK-IF-ALREADY-EXISTS is supplied and non-nil.
 258 A number as third arg means request confirmation if NEWNAME already exists.
 259 This is what happens in interactive use with M-x.
 260 Fourth arg KEEP-TIME non-nil means give the new file the same
 261 last-modified time as the old one.  (This works on only some systems.)
 262 Fifth arg PRESERVE-UID-GID is ignored.
 263 A prefix arg makes KEEP-TIME non-nil."
 264   (if (and (file-exists-p newname)
 265            (not ok-if-already-exists))
 266       (error "Opening output file: File already exists, %s" newname))
 267   (let ((buffer (url-retrieve-synchronously url))
 268         (handle nil))
 269     (if (not buffer)
 270         (error "Opening input file: No such file or directory, %s" url))
 271     (with-current-buffer buffer
 272       (setq handle (mm-dissect-buffer t)))
 273     (mm-save-part-to-file handle newname)
 274     (kill-buffer buffer)
 275     (mm-destroy-parts handle)))
 276 (put 'copy-file 'url-file-handlers 'url-copy-file)
 277
 278 ;;;###autoload
 279 (defun url-file-local-copy (url &rest ignored)
 280   "Copy URL into a temporary file on this machine.
 281 Returns the name of the local copy, or nil, if FILE is directly
 282 accessible."
 283   (let ((filename (make-temp-file "url")))
 284     (url-copy-file url filename 'ok-if-already-exists)
 285     filename))
 286 (put 'file-local-copy 'url-file-handlers 'url-file-local-copy)
 287
 288 (defun url-insert (buffer &optional beg end)
 289   "Insert the body of a URL object.
 290 BUFFER should be a complete URL buffer as returned by `url-retrieve'.
 291 If the headers specify a coding-system, it is applied to the body before it is inserted.
 292 Returns a list of the form (SIZE CHARSET), where SIZE is the size in bytes
 293 of the inserted text and CHARSET is the charset that was specified in the header,
 294 or nil if none was found.
 295 BEG and END can be used to only insert a subpart of the body.
 296 They count bytes from the beginning of the body."
 297   (let* ((handle (with-current-buffer buffer (mm-dissect-buffer t)))
 298          (data (with-current-buffer (mm-handle-buffer handle)
 299                  (if beg
 300                      (buffer-substring (+ (point-min) beg)
 301                                        (if end (+ (point-min) end) (point-max)))
 302                    (buffer-string))))
 303          (charset (mail-content-type-get (mm-handle-type handle)
 304                                           'charset)))
 305     (mm-destroy-parts handle)
 306     (if charset
 307         (insert (mm-decode-string data (mm-charset-to-coding-system charset)))
 308       (insert data))
 309     (list (length data) charset)))
 310
 311 ;;;###autoload
 312 (defun url-insert-file-contents (url &optional visit beg end replace)
 313   (let ((buffer (url-retrieve-synchronously url)))
 314     (unless buffer (signal 'file-error (list url "No Data")))
 315     (with-current-buffer buffer
 316       (let ((response (url-http-parse-response)))
 317         (if (and (>= response 200) (< response 300))
 318             (goto-char (point-min))
 319           (let ((desc (buffer-substring-no-properties (1+ (point))
 320                                                       (line-end-position))))
 321             (kill-buffer buffer)
 322             (signal 'file-error (list url desc))))))
 323     (if visit (setq buffer-file-name url))
 324     (save-excursion
 325       (let* ((start (point))
 326              (size-and-charset (url-insert buffer beg end)))
 327         (kill-buffer buffer)
 328         (when replace
 329           (delete-region (point-min) start)
 330           (delete-region (point) (point-max)))
 331         (unless (cadr size-and-charset)
 332           ;; If the headers don't specify any particular charset, use the
 333           ;; usual heuristic/rules that we apply to files.
 334           (decode-coding-inserted-region start (point) url visit beg end replace))
 335         (list url (car size-and-charset))))))
 336 (put 'insert-file-contents 'url-file-handlers 'url-insert-file-contents)
 337
 338 (defun url-file-name-completion (url directory &optional predicate)
 339   ;; Even if it's not implemented, it's not an error to ask for completion,
 340   ;; in case it's available (bug#14806).
 341   ;; (error "Unimplemented")
 342   url)
 343 (put 'file-name-completion 'url-file-handlers 'url-file-name-completion)
 344
 345 (defun url-file-name-all-completions (file directory)
 346   ;; Even if it's not implemented, it's not an error to ask for completion,
 347   ;; in case it's available (bug#14806).
 348   ;; (error "Unimplemented")
 349   nil)
 350 (put 'file-name-all-completions
 351      'url-file-handlers 'url-file-name-all-completions)
 352
 353 ;; All other handlers map onto their respective backends.
 354 (defmacro url-handlers-create-wrapper (method args)
 355   `(progn
 356      (defun ,(intern (format "url-%s" method)) ,args
 357        ,(format "URL file-name-handler wrapper for `%s' call.\n---\n%s" method
 358                 (or (documentation method t) "No original documentation."))
 359        (setq url (url-generic-parse-url url))
 360        (when (url-type url)
 361          (funcall (url-scheme-get-property (url-type url) (quote ,method))
 362                   ,@(remove '&rest (remove '&optional args)))))
 363      (unless (get ',method 'url-file-handlers)
 364        (put ',method 'url-file-handlers ',(intern (format "url-%s" method))))))
 365
 366 (url-handlers-create-wrapper file-exists-p (url))
 367 (url-handlers-create-wrapper file-attributes (url &optional id-format))
 368 (url-handlers-create-wrapper file-symlink-p (url))
 369 (url-handlers-create-wrapper file-writable-p (url))
 370 (url-handlers-create-wrapper file-directory-p (url))
 371 (url-handlers-create-wrapper file-executable-p (url))
 372 (url-handlers-create-wrapper directory-files (url &optional full match nosort))
 373 (url-handlers-create-wrapper file-truename (url &optional counter prev-dirs))
 374
 375 (add-hook 'find-file-hook 'url-handlers-set-buffer-mode)
 376
 377 (defun url-handlers-set-buffer-mode ()
 378   "Set correct modes for the current buffer if visiting a remote file."
 379   (and (stringp buffer-file-name)
 380        (string-match url-handler-regexp buffer-file-name)
 381        (auto-save-mode 0)))
 382
 383 (provide 'url-handlers)
 384
 385 ;;; url-handlers.el ends here