configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  42 '${datadir}/emacs/site-lisp'
  43 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  44 etcdir='${datadir}/emacs/${version}/etc'
  45 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  46 docdir='${datadir}/emacs/${version}/etc'
  47 gamedir='${localstatedir}/games/emacs'
  48
  49 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  50 dnl Create a new --with option that defaults to being disabled.
  51 dnl NAME is the base name of the option.  The shell variable with_NAME
  52 dnl   will be set to either the user's value (if the option is
  53 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  54 dnl   option is not specified).  Note that the shell variable name is
  55 dnl   constructed as autoconf does, by replacing non-alphanumeric
  56 dnl   characters with "_".
  57 dnl HELP-STRING is the help text for the option.
  58 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  59   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  60     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  61 ])dnl
  62
  63 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  64 dnl Create a new --with option that defaults to being enabled.  NAME
  65 dnl   is the base name of the option.  The shell variable with_NAME
  66 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  67 dnl   'yes' (if the option is not specified).  Note that the shell
  68 dnl   variable name is constructed as autoconf does, by replacing
  69 dnl   non-alphanumeric characters with "_".
  70 dnl HELP-STRING is the help text for the option.
  71 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  72   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  73    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  74 ])dnl
  75
  76 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  77 if test "$with_pop" = yes; then
  78    AC_DEFINE(MAIL_USE_POP)
  79 fi
  80 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  81
  82 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  83 if test "$with_kerberos" != no; then
  84    AC_DEFINE(KERBEROS)
  85 fi
  86 AH_TEMPLATE(KERBEROS,
  87             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  88
  89 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  90 if test "${with_kerberos5}" != no; then
  91   if test "${with_kerberos}" = no; then
  92     with_kerberos=yes
  93     AC_DEFINE(KERBEROS)
  94   fi
  95   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  96 fi
  97
  98 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  99 dnl FIXME hesiod support may not be present, so it seems like an error
 100 dnl to define, or at least use, this unconditionally.
 101 if test "$with_hesiod" != no; then
 102   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 106 if test "$with_mmdf" != no; then
 107    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 108 fi
 109
 110 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 111 if test "$with_mail_unlink" != no; then
 112    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 113 fi
 114
 115 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 116     [string giving default POP mail host])],
 117     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 118
 119 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 120
 121 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 122 if test "$with_sync_input" = yes; then
 123    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 124 fi
 125
 126 dnl FIXME currently it is not the last.
 127 dnl This should be the last --with option, because --with-x is
 128 dnl added later on when we find the path of X, and it's best to
 129 dnl keep them together visually.
 130 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 131  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 132 [         case "${withval}" in
 133             y | ye | yes )      val=gtk ;;
 134             n | no )            val=no  ;;
 135             l | lu | luc | luci | lucid )       val=lucid ;;
 136             a | at | ath | athe | athen | athena )      val=athena ;;
 137             m | mo | mot | moti | motif )       val=motif ;;
 138             g | gt | gtk  )     val=gtk ;;
 139             gtk3  )     val=gtk3 ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 143 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 150 if test "$with_wide_int" = yes; then
 151   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 152 fi
 153
 154 dnl _ON results in a '--without' option in the --help output, so
 155 dnl the help text should refer to "don't compile", etc.
 156 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 157 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 158 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 159 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 160 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 161 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 162 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 163 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 164
 165 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 166 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 167 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 168
 169 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 170 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 171 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 172 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 173
 174 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 175 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 176 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 177 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 178 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 179 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 180
 181 ## For the times when you want to build Emacs but don't have
 182 ## a suitable makeinfo, and can live without the manuals.
 183 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 184 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 185
 186 ## Makefile.in needs the cache file name.
 187 AC_SUBST(cache_file)
 188
 189 ## This is an option because I do not know if all info/man support
 190 ## compressed files, nor how to test if they do so.
 191 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 192 if test $with_compress_info = yes; then
 193    GZIP_INFO=yes
 194 else
 195    GZIP_INFO=
 196 fi
 197 AC_SUBST(GZIP_INFO)
 198
 199 AC_ARG_WITH([pkg-config-prog],dnl
 200 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 201                   [path to pkg-config for finding GTK and librsvg])])
 202 if test "X${with_pkg_config_prog}" != X; then
 203    if test "${with_pkg_config_prog}" != yes; then
 204       PKG_CONFIG="${with_pkg_config_prog}"
 205    fi
 206 fi
 207
 208 CRT_DIR=
 209 AC_ARG_WITH([crt-dir],dnl
 210 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 211 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 212 CRT_DIR="${with_crt_dir}"
 213
 214 AC_ARG_WITH(gameuser,dnl
 215 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 216 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 217   && gameuser="${with_gameuser}"
 218 test "X$gameuser" = X && gameuser=games
 219
 220 AC_ARG_WITH([gnustep-conf],dnl
 221 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 222 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 223   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 224 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 225      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 226
 227 AC_ARG_ENABLE(ns-self-contained,
 228 [AS_HELP_STRING([--disable-ns-self-contained],
 229                 [disable self contained build under NeXTstep])],
 230    EN_NS_SELF_CONTAINED=$enableval,
 231    EN_NS_SELF_CONTAINED=yes)
 232
 233 AC_ARG_ENABLE(asserts,
 234 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 235       USE_XASSERTS=$enableval,
 236       USE_XASSERTS=no)
 237
 238 AC_ARG_ENABLE(locallisppath,
 239 [AS_HELP_STRING([--enable-locallisppath=PATH],
 240                 [directories Emacs should search for lisp files specific
 241                  to this site])],
 242 if test "${enableval}" = "no"; then
 243   locallisppath=
 244 elif test "${enableval}" != "yes"; then
 245   locallisppath=${enableval}
 246 fi)
 247
 248 AC_ARG_ENABLE(checking,
 249 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 250                 [enable expensive run-time checks.  With LIST,
 251                  enable only specific categories of checks.
 252                  Categories are: all,yes,no.
 253                  Flags are: stringbytes, stringoverrun, stringfreelist,
 254                  xmallocoverrun, conslist])],
 255 [ac_checking_flags="${enableval}"],[])
 256 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 257 for check in $ac_checking_flags
 258 do
 259         case $check in
 260         # these set all the flags to specific states
 261         yes)            ac_enable_checking=1 ;;
 262         no)             ac_enable_checking= ;
 263                         ac_gc_check_stringbytes= ;
 264                         ac_gc_check_string_overrun= ;
 265                         ac_gc_check_string_free_list= ;
 266                         ac_xmalloc_overrun= ;
 267                         ac_gc_check_cons_list= ;;
 268         all)            ac_enable_checking=1 ;
 269                         ac_gc_check_stringbytes=1 ;
 270                         ac_gc_check_string_overrun=1 ;
 271                         ac_gc_check_string_free_list=1 ;
 272                         ac_xmalloc_overrun=1 ;
 273                         ac_gc_check_cons_list=1 ;;
 274         # these enable particular checks
 275         stringbytes)    ac_gc_check_stringbytes=1 ;;
 276         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 277         stringfreelist) ac_gc_check_string_free_list=1 ;;
 278         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 279         conslist)       ac_gc_check_cons_list=1 ;;
 280         *)      AC_MSG_ERROR(unknown check category $check) ;;
 281         esac
 282 done
 283 IFS="$ac_save_IFS"
 284
 285 if test x$ac_enable_checking != x ; then
 286   AC_DEFINE(ENABLE_CHECKING, 1,
 287 [Enable expensive run-time checking of data types?])
 288 fi
 289 if test x$ac_gc_check_stringbytes != x ; then
 290   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 291 [Define this temporarily to hunt a bug.  If defined, the size of
 292    strings is redundantly recorded in sdata structures so that it can
 293    be compared to the sizes recorded in Lisp strings.])
 294 fi
 295 if test x$ac_gc_check_string_overrun != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 297 [Define this to check for short string overrun.])
 298 fi
 299 if test x$ac_gc_check_string_free_list != x ; then
 300   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 301 [Define this to check the string free list.])
 302 fi
 303 if test x$ac_xmalloc_overrun != x ; then
 304   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 305 [Define this to check for malloc buffer overrun.])
 306 fi
 307 if test x$ac_gc_check_cons_list != x ; then
 308   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 309 [Define this to check for errors in cons list.])
 310 fi
 311
 312 AC_ARG_ENABLE(use-lisp-union-type,
 313 [AS_HELP_STRING([--enable-use-lisp-union-type],
 314                 [use a union for the Lisp_Object data type.
 315                 This is only useful for development for catching certain types of bugs.])],
 316 if test "${enableval}" != "no"; then
 317    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 318    [Define this to use a lisp union for the Lisp_Object data type.])
 319 fi)
 320
 321
 322 AC_ARG_ENABLE(profiling,
 323 [AS_HELP_STRING([--enable-profiling],
 324                 [build emacs with profiling support.
 325                  This might not work on all platforms])],
 326 [ac_enable_profiling="${enableval}"],[])
 327 if test x$ac_enable_profiling != x ; then
 328    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 329 else
 330    PROFILING_CFLAGS=
 331 fi
 332 AC_SUBST(PROFILING_CFLAGS)
 333
 334 AC_ARG_ENABLE(autodepend,
 335 [AS_HELP_STRING([--enable-autodepend],
 336                 [automatically generate dependencies to .h-files.
 337                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 338                  found])],
 339 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 340
 341 #### Make srcdir absolute, if it isn't already.  It's important to
 342 #### avoid running the path through pwd unnecessarily, since pwd can
 343 #### give you automounter prefixes, which can go away.  We do all this
 344 #### so Emacs can find its files when run uninstalled.
 345 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 346 unset CDPATH
 347 case "${srcdir}" in
 348   /* ) ;;
 349   . )
 350     ## We may be able to use the $PWD environment variable to make this
 351     ## absolute.  But sometimes PWD is inaccurate.
 352     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 353     ## but that tested only for a well-formed and valid PWD,
 354     ## it did not object when PWD was well-formed and valid but just wrong.
 355     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 356     then
 357       srcdir="$PWD"
 358     else
 359       srcdir="`(cd ${srcdir}; pwd)`"
 360     fi
 361   ;;
 362   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 363 esac
 364
 365 #### Given the configuration name, set opsysfile to the
 366 #### name of s/*.h file we should use.
 367
 368 ### Canonicalize the configuration name.
 369
 370 AC_CANONICAL_HOST
 371 canonical=$host
 372 configuration=${host_alias-${build_alias-$host}}
 373
 374 dnl This used to use changequote, but, apart from `changequote is evil'
 375 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 376 dnl the great gob of text.  Thus it's not processed for possible expansion.
 377 dnl Just make sure the brackets remain balanced.
 378 dnl
 379 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 380 dnl indicated by comments.
 381 dnl quotation begins
 382 [
 383
 384 ### If you add support for a new configuration, add code to this
 385 ### switch statement to recognize your configuration name and select
 386 ### the appropriate operating system file.
 387
 388 ### You would hope that you could choose an s/*.h
 389 ### file based on the operating system portion.  However, it turns out
 390 ### that each s/*.h file is pretty manufacturer-specific.
 391 ### So we basically have to have a special case for each
 392 ### configuration name.
 393 ###
 394 ### As far as handling version numbers on operating systems is
 395 ### concerned, make sure things will fail in a fixable way.  If
 396 ### /etc/MACHINES doesn't say anything about version numbers, be
 397 ### prepared to handle anything reasonably.  If version numbers
 398 ### matter, be sure /etc/MACHINES says something about it.
 399
 400 opsys='' unported=no
 401 case "${canonical}" in
 402
 403   ## GNU/Linux and similar ports
 404   *-*-linux* )
 405     opsys=gnu-linux
 406   ;;
 407
 408   ## FreeBSD ports
 409   *-*-freebsd* )
 410     opsys=freebsd
 411   ;;
 412
 413   ## FreeBSD kernel + glibc based userland
 414   *-*-kfreebsd*gnu* )
 415     opsys=gnu-kfreebsd
 416   ;;
 417
 418   ## NetBSD ports
 419   *-*-netbsd* )
 420     opsys=netbsd
 421   ;;
 422
 423   ## OpenBSD ports
 424   *-*-openbsd* )
 425     opsys=openbsd
 426   ;;
 427
 428   ## Apple Darwin / Mac OS X
 429   *-apple-darwin* )
 430     case "${canonical}" in
 431       i[3456]86-* )  ;;
 432       powerpc-* )    ;;
 433       x86_64-* )     ;;
 434       * )            unported=yes ;;
 435     esac
 436     opsys=darwin
 437     ## Use fink packages if available.
 438     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 439 ##    if test -d /sw/include && test -d /sw/lib; then
 440 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 441 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 442 ##    fi
 443   ;;
 444
 445   ## HP 9000 series 700 and 800, running HP/UX
 446   hppa*-hp-hpux10.2* )
 447     opsys=hpux10-20
 448   ;;
 449   hppa*-hp-hpux1[1-9]* )
 450     opsys=hpux11
 451     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 452   ;;
 453
 454   ## IBM machines
 455   rs6000-ibm-aix4.[23]* )
 456     opsys=aix4-2
 457   ;;
 458   powerpc-ibm-aix4.[23]*  )
 459     opsys=aix4-2
 460   ;;
 461   rs6000-ibm-aix[56]* )
 462     opsys=aix4-2
 463   ;;
 464   powerpc-ibm-aix[56]*  )
 465     opsys=aix4-2
 466   ;;
 467
 468   ## Silicon Graphics machines
 469   ## Iris 4D
 470   mips-sgi-irix6.5 )
 471     opsys=irix6-5
 472     # Without defining _LANGUAGE_C, things get masked out in the headers
 473     # so that, for instance, grepping for `free' in stdlib.h fails and
 474     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 475     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 476   ;;
 477
 478   ## Suns
 479   *-sun-solaris* \
 480     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 481     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 482     case "${canonical}" in
 483       i[3456]86-*-* )   ;;
 484       amd64-*-*|x86_64-*-*) ;;
 485       sparc* )          ;;
 486       * )               unported=yes ;;
 487     esac
 488     case "${canonical}" in
 489       *-sunos5.6* | *-solaris2.6* )
 490                 opsys=sol2-6
 491                 RANLIB="ar -ts"
 492                 ;;
 493       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 494                 opsys=sol2-6
 495                 emacs_check_sunpro_c=yes
 496                 ;;
 497       *-sunos5* | *-solaris* )
 498                 opsys=sol2-10
 499                 emacs_check_sunpro_c=yes
 500                 ;;
 501     esac
 502     ## Watch out for a compiler that we know will not work.
 503     case "${canonical}" in
 504      *-solaris* | *-sunos5* )
 505                 if [ "x$CC" = x/usr/ucb/cc ]; then
 506                   ## /usr/ucb/cc doesn't work;
 507                   ## we should find some other compiler that does work.
 508                   unset CC
 509                 fi
 510                 ;;
 511       *) ;;
 512     esac
 513   ;;
 514
 515   ## Intel 386 machines where we don't care about the manufacturer.
 516   i[3456]86-*-* )
 517     case "${canonical}" in
 518       *-cygwin )                opsys=cygwin ;;
 519       *-darwin* )               opsys=darwin ;;
 520       *-sysv4.2uw* )            opsys=unixware ;;
 521       *-sysv5uw* )              opsys=unixware ;;
 522       *-sysv5OpenUNIX* )        opsys=unixware ;;
 523       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 524     esac
 525   ;;
 526
 527   * )
 528     unported=yes
 529   ;;
 530 esac
 531
 532 ### If the code above didn't choose an operating system, just choose
 533 ### an operating system based on the configuration name.  You really
 534 ### only want to use this when you have no idea what the right
 535 ### operating system is; if you know what operating systems a machine
 536 ### runs, it's cleaner to make it explicit in the case statement
 537 ### above.
 538 if test x"${opsys}" = x; then
 539   case "${canonical}" in
 540     *-gnu* )                            opsys=gnu ;;
 541     * )
 542       unported=yes
 543     ;;
 544   esac
 545 fi
 546
 547 ]
 548 dnl quotation ends
 549
 550 if test $unported = yes; then
 551   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 552 Check `etc/MACHINES' for recognized configuration names.])
 553 fi
 554
 555 opsysfile="s/${opsys}.h"
 556
 557
 558 #### Choose a compiler.
 559
 560 dnl Sets GCC=yes if using gcc.
 561 AC_PROG_CC
 562 AM_PROG_CC_C_O
 563
 564 if test x$GCC = xyes; then
 565   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 566 else
 567   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 568 fi
 569
 570 # Initialize gnulib right after choosing the compiler.
 571 gl_EARLY
 572
 573 AC_ARG_ENABLE([gcc-warnings],
 574   [AS_HELP_STRING([--enable-gcc-warnings],
 575                   [turn on lots of GCC warnings (for developers)])],
 576   [case $enableval in
 577      yes|no) ;;
 578      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 579    esac
 580    gl_gcc_warnings=$enableval],
 581   [gl_gcc_warnings=no]
 582 )
 583
 584 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 585 # ------------------------------------------------
 586 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 587 # Otherwise, run RUN-IF-NOT-FOUND.
 588 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 589   [AC_PREPROC_IFELSE(
 590     [AC_LANG_PROGRAM(
 591       [[
 592 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 593 /* ok */
 594 #else
 595 # error "your version of gcc is older than $1.$2"
 596 #endif
 597       ]]),
 598     ], [$3], [$4])
 599   ]
 600 )
 601
 602 # When compiling with GCC, prefer -isystem to -I when including system
 603 # include files, to avoid generating useless diagnostics for the files.
 604 if test "$gl_gcc_warnings" != yes; then
 605   isystem='-I'
 606 else
 607   isystem='-isystem '
 608
 609   # This, $nw, is the list of warnings we disable.
 610   nw=
 611
 612   case $with_x_toolkit in
 613     lucid | athena | motif)
 614        # Old toolkits mishandle 'const'.
 615        nw="$nw -Wwrite-strings"
 616        ;;
 617     *)
 618        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 619        ;;
 620   esac
 621   AC_SUBST([WERROR_CFLAGS])
 622
 623   nw="$nw -Waggregate-return"       # anachronistic
 624   nw="$nw -Wlong-long"              # C90 is anachronistic
 625   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 626   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 627   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 628   nw="$nw -Wcast-qual"              # Too many warnings for now
 629   nw="$nw -Wconversion"             # Too many warnings for now
 630   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 631   nw="$nw -Wsign-conversion"        # Too many warnings for now
 632   nw="$nw -Woverlength-strings"     # Not a problem these days
 633   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 634   nw="$nw -Wpadded"                 # Our structs are not padded
 635   nw="$nw -Wredundant-decls"        # We regularly (re)declare getenv etc.
 636   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 637   nw="$nw -Wformat-nonliteral"      # Emacs does this a lot
 638   nw="$nw -Wvla"                    # warnings in gettext.h
 639   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 640   nw="$nw -Wswitch-enum"            # Too many warnings for now
 641   nw="$nw -Wswitch-default"         # Too many warnings for now
 642   nw="$nw -Wfloat-equal"            # e.g., ftoastr.c
 643   nw="$nw -Winline"                 # e.g., dispnew.c's inlining of row_equal_p
 644
 645   # Emacs doesn't care about shadowing; see
 646   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 647   nw="$nw -Wshadow"
 648
 649   # The following lines should be removable at some point.
 650   nw="$nw -Wstack-protector"
 651   nw="$nw -Wstrict-overflow"
 652   nw="$nw -Wsuggest-attribute=const"
 653   nw="$nw -Wsuggest-attribute=pure"
 654
 655   gl_MANYWARN_ALL_GCC([ws])
 656   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 657   for w in $ws; do
 658     gl_WARN_ADD([$w])
 659   done
 660   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 661   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 662   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 663   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 664   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 665   gl_WARN_ADD([-Wno-format-nonliteral])
 666
 667   # In spite of excluding -Wlogical-op above, it is enabled, as of
 668   # gcc 4.5.0 20090517.
 669   gl_WARN_ADD([-Wno-logical-op])
 670
 671   gl_WARN_ADD([-fdiagnostics-show-option])
 672   gl_WARN_ADD([-funit-at-a-time])
 673
 674   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 675   AC_DEFINE([_FORTIFY_SOURCE], [2],
 676     [enable compile-time and run-time bounds-checking, and some warnings])
 677   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 678
 679   # We use a slightly smaller set of warning options for lib/.
 680   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 681   nw=
 682   nw="$nw -Wunused-macros"
 683
 684   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 685   AC_SUBST([GNULIB_WARN_CFLAGS])
 686 fi
 687
 688
 689
 690 dnl Some other nice autoconf tests.
 691 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 692 dnl AC_PROG_INSTALL
 693 dnl AC_PROG_MKDIR_P
 694 dnl if test "x$RANLIB" = x; then
 695 dnl   AC_PROG_RANLIB
 696 dnl fi
 697
 698 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 699   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 700 dnl Don't use GZIP, which is used by gzip for additional parameters.
 701 AC_PATH_PROG(GZIP_PROG, gzip)
 702
 703
 704 ## Need makeinfo >= 4.7 (?) to build the manuals.
 705 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 706 dnl By this stage, configure has already checked for egrep and set EGREP,
 707 dnl or exited with an error if no egrep was found.
 708 if test "$MAKEINFO" != "no" && \
 709   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 710    MAKEINFO=no
 711 fi
 712
 713 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 714 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 715 ## therefore in the category of "special tools" not normally required, which
 716 ## configure does not have to check for (eg autoconf itself).
 717 ## In a Bazaar checkout on the other hand, the manuals are not included.
 718 ## So makeinfo is a requirement to build from Bazaar, and configure
 719 ## should test for it as it does for any other build requirement.
 720 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 721 ## with pre-built manuals, from a Bazaar checkout.
 722 HAVE_MAKEINFO=yes
 723
 724 if test "$MAKEINFO" = "no"; then
 725   MAKEINFO=makeinfo
 726   if test "x${with_makeinfo}" = "xno"; then
 727     HAVE_MAKEINFO=no
 728   elif test ! -e $srcdir/info/emacs; then
 729     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 730 source tree does not seem to have pre-built manuals in the `info' directory.
 731 Either install a suitable version of makeinfo, or re-run configure
 732 with the `--without-makeinfo' option to build without the manuals.] )
 733   fi
 734 fi
 735 AC_SUBST(HAVE_MAKEINFO)
 736
 737 dnl Just so that there is only a single place we need to edit.
 738 INFO_EXT=.info
 739 INFO_OPTS=--no-split
 740 AC_SUBST(INFO_EXT)
 741 AC_SUBST(INFO_OPTS)
 742
 743 dnl Add our options to ac_link now, after it is set up.
 744
 745 if test x$GCC = xyes; then
 746   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 747     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 748 else
 749   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 750     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 751 fi
 752
 753 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 754 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 755 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 756 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 757 dnl if not built to support GNU ld.
 758
 759 late_LDFLAGS=$LDFLAGS
 760 if test x$GCC = xyes; then
 761   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 762 else
 763   LDFLAGS="$LDFLAGS -znocombreloc"
 764 fi
 765
 766 AC_MSG_CHECKING([for -znocombreloc])
 767 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 768   [AC_MSG_RESULT(yes)],
 769   LDFLAGS=$late_LDFLAGS
 770   [AC_MSG_RESULT(no)])
 771
 772
 773 dnl The function dump-emacs will not be defined and temacs will do
 774 dnl (load "loadup") automatically unless told otherwise.
 775 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 776 case "$opsys" in
 777   your-opsys-here) CANNOT_DUMP=yes ;;
 778 esac
 779
 780 test "$CANNOT_DUMP" = "yes" && \
 781   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 782
 783 AC_SUBST(CANNOT_DUMP)
 784
 785
 786 UNEXEC_OBJ=unexelf.o
 787 case "$opsys" in
 788   # MSDOS uses unexcoff.o
 789   # MSWindows uses unexw32.o
 790   aix4-2)
 791    UNEXEC_OBJ=unexaix.o
 792    ;;
 793   cygwin)
 794    UNEXEC_OBJ=unexcw.o
 795    ;;
 796   darwin)
 797    UNEXEC_OBJ=unexmacosx.o
 798    ;;
 799   hpux10-20 | hpux11)
 800    UNEXEC_OBJ=unexhp9k800.o
 801    ;;
 802   sol2-10)
 803    # Use the Solaris dldump() function, called from unexsol.c, to dump
 804    # emacs, instead of the generic ELF dump code found in unexelf.c.
 805    # The resulting binary has a complete symbol table, and is better
 806    # for debugging and other observability tools (debuggers, pstack, etc).
 807    #
 808    # If you encounter a problem using dldump(), please consider sending
 809    # a message to the OpenSolaris tools-linking mailing list:
 810    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 811    #
 812    # It is likely that dldump() works with older Solaris too, but this has
 813    # not been tested, so for now this change is for Solaris 10 or newer.
 814    UNEXEC_OBJ=unexsol.o
 815    ;;
 816 esac
 817
 818 LD_SWITCH_SYSTEM=
 819 case "$opsys" in
 820   freebsd)
 821    ## Let `ld' find image libs and similar things in /usr/local/lib.
 822    ## The system compiler, GCC, has apparently been modified to not
 823    ## look there, contrary to what a stock GCC would do.
 824 ### It's not our place to do this.  See bug#10313#17.
 825 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 826       :
 827    ;;
 828
 829   gnu-linux)
 830    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 831    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 832    ;;
 833
 834   netbsd)
 835 ### It's not our place to do this.  See bug#10313#17.
 836 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 837       :
 838    ;;
 839
 840   openbsd)
 841    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 842    ## otherwise Emacs dumps core on elf systems.
 843    LD_SWITCH_SYSTEM="-Z"
 844    ;;
 845 esac
 846 AC_SUBST(LD_SWITCH_SYSTEM)
 847
 848 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 849
 850 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 851 ## which has not been defined yet.  When this was handled with cpp,
 852 ## it was expanded to null when configure sourced the s/*.h file.
 853 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 854 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 855 ## (or somesuch), but because it is supposed to go at the _front_
 856 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 857 ## Compare with the gnu-linux case below, which added to the end
 858 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 859 ## LD_SWITCH_SYSTEM_TEMACS.
 860 case "$opsys" in
 861   netbsd|openbsd)
 862    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 863 esac
 864
 865
 866 C_SWITCH_MACHINE=
 867 case $canonical in
 868  alpha*)
 869   AC_CHECK_DECL([__ELF__])
 870   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 871     ## With ELF, make sure that all common symbols get allocated to in the
 872     ## data section.  Otherwise, the dump of temacs may miss variables in
 873     ## the shared library that have been initialized.  For example, with
 874     ## GNU libc, __malloc_initialized would normally be resolved to the
 875     ## shared library's .bss section, which is fatal.
 876     if test "x$GCC" = "xyes"; then
 877       C_SWITCH_MACHINE="-fno-common"
 878     else
 879       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 880     fi
 881   else
 882     UNEXEC_OBJ=unexalpha.o
 883   fi
 884   ;;
 885 esac
 886 AC_SUBST(C_SWITCH_MACHINE)
 887
 888 AC_SUBST(UNEXEC_OBJ)
 889
 890 C_SWITCH_SYSTEM=
 891 ## Some programs in src produce warnings saying certain subprograms
 892 ## are too complex and need a MAXMEM value greater than 2000 for
 893 ## additional optimization.  --nils@exp-math.uni-essen.de
 894 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 895   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 896 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 897 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 898 AC_SUBST(C_SWITCH_SYSTEM)
 899
 900
 901 LIBS_SYSTEM=
 902 case "$opsys" in
 903   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 904   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 905
 906   freebsd) LIBS_SYSTEM="-lutil" ;;
 907
 908   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 909
 910   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 911
 912   ## Motif needs -lgen.
 913   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 914 esac
 915 AC_SUBST(LIBS_SYSTEM)
 916
 917
 918 ### Make sure subsequent tests use flags consistent with the build flags.
 919
 920 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 921   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 922 else
 923   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 924 fi
 925
 926 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 927 AC_DEFUN([AC_TYPE_SIZE_T])
 928 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 929 AC_DEFUN([AC_TYPE_UID_T])
 930
 931
 932 LIB_MATH=-lm
 933 LIB_STANDARD=
 934 START_FILES=
 935
 936 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 937 case $opsys in
 938   cygwin )
 939     LIB_MATH=
 940     START_FILES='pre-crt0.o'
 941     ;;
 942   darwin )
 943     ## Adding -lm confuses the dynamic linker, so omit it.
 944     LIB_MATH=
 945     START_FILES='pre-crt0.o'
 946     ;;
 947   freebsd )
 948     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
 949     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
 950     ;;
 951   gnu-linux | gnu-kfreebsd )
 952     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 953     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 954     ;;
 955   hpux10-20 | hpux11 )
 956     LIB_STANDARD=-lc
 957     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
 958     ;;
 959   dnl NB this may be adjusted below.
 960   netbsd | openbsd )
 961     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
 962     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
 963     ;;
 964 esac
 965
 966 AC_SUBST(LIB_MATH)
 967 AC_SUBST(START_FILES)
 968
 969 dnl Not all platforms use crtn.o files.  Check if the current one does.
 970 crt_files=
 971
 972 for file in x $LIB_STANDARD $START_FILES; do
 973   case "$file" in
 974     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
 975   esac
 976 done
 977
 978 if test "x$crt_files" != x; then
 979
 980   ## If user specified a crt-dir, use that unconditionally.
 981   crt_gcc=no
 982
 983   if test "X$CRT_DIR" = "X"; then
 984
 985     CRT_DIR=/usr/lib            # default
 986
 987     case "$canonical" in
 988       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
 989       ## On x86-64 and s390x GNU/Linux distributions, the standard library
 990       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
 991       ## For anything else (eg /usr/lib32), it is up the user to specify
 992       ## the location (bug#5655).
 993       ## Test for crtn.o, not just the directory, because sometimes the
 994       ## directory exists but does not have the relevant files (bug#1287).
 995       ## FIXME better to test for binary compatibility somehow.
 996       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
 997       ;;
 998
 999       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1000     esac
1001
1002     case "$opsys" in
1003       hpux10-20) CRT_DIR=/lib ;;
1004     esac
1005
1006     test "x${GCC}" = xyes && crt_gcc=yes
1007
1008   fi                            # CRT_DIR = ""
1009
1010   crt_missing=
1011
1012   for file in $crt_files; do
1013
1014     ## If we're using gcc, try to determine it automatically by asking
1015     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1016     ## system-dependent default from above.]
1017     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1018
1019        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1020        case "$crt_file" in
1021          */*)
1022            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1023            ;;
1024        esac
1025     fi
1026
1027     dnl We expect all the files to be in a single directory, so after the
1028     dnl first there is no point asking gcc.
1029     crt_gcc=no
1030
1031     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1032   done                          # $crt_files
1033
1034   test "x$crt_missing" = x || \
1035     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1036 Try using the --with-crt-dir option.])
1037
1038 fi                              # crt_files != ""
1039
1040 AC_SUBST(CRT_DIR)
1041
1042 case $opsys in
1043   netbsd | openbsd )
1044     if test -f $CRT_DIR/crti.o; then
1045
1046         test -f $CRT_DIR/crtn.o || \
1047           AC_MSG_ERROR([Required file not found: crtn.o])
1048
1049         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1050         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1051     fi
1052     ;;
1053 esac
1054
1055
1056 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1057
1058 dnl This function definition taken from Gnome 2.0
1059 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1060 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1061 dnl also defines GSTUFF_PKG_ERRORS on error
1062 AC_DEFUN([PKG_CHECK_MODULES], [
1063   succeeded=no
1064
1065   if test "$PKG_CONFIG" = "no" ; then
1066      ifelse([$4], , [AC_MSG_ERROR([
1067       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1068   else
1069      PKG_CONFIG_MIN_VERSION=0.9.0
1070      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1071         AC_MSG_CHECKING(for $2)
1072
1073         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1074            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1075            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1076             edit_cflags="
1077               s,///*,/,g
1078               s/^/ /
1079               s/ -I/ $isystem/g
1080               s/^ //
1081             "
1082             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1083             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1084             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1085             succeeded=yes
1086         else
1087             AC_MSG_RESULT(no)
1088             $1_CFLAGS=""
1089             $1_LIBS=""
1090             ## If we have a custom action on failure, don't print errors, but
1091             ## do set a variable so people can do so.
1092             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1093             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1094         fi
1095
1096         AC_SUBST($1_CFLAGS)
1097         AC_SUBST($1_LIBS)
1098      else
1099         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1100         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1101      fi
1102   fi
1103
1104   if test $succeeded = yes; then
1105      ifelse([$3], , :, [$3])
1106   else
1107      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1108   fi
1109 ])
1110
1111
1112 if test "${with_sound}" != "no"; then
1113   # Sound support for GNU/Linux and the free BSDs.
1114   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1115     have_sound_header=yes)
1116   # Emulation library used on NetBSD.
1117   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1118   AC_SUBST(LIBSOUND)
1119
1120   ALSA_REQUIRED=1.0.0
1121   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1122   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1123   if test $HAVE_ALSA = yes; then
1124     SAVE_CFLAGS="$CFLAGS"
1125     SAVE_LIBS="$LIBS"
1126     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1127     LIBS="$ALSA_LIBS $LIBS"
1128     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1129                     emacs_alsa_normal=yes,
1130                     emacs_alsa_normal=no)
1131     if test "$emacs_alsa_normal" != yes; then
1132       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1133                      [[snd_lib_error_set_handler (0);]])],
1134                      emacs_alsa_subdir=yes,
1135                      emacs_alsa_subdir=no)
1136       if test "$emacs_alsa_subdir" != yes; then
1137         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1138       fi
1139       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1140     fi
1141
1142     CFLAGS="$SAVE_CFLAGS"
1143     LIBS="$SAVE_LIBS"
1144     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1145     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1146     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1147   fi
1148
1149   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1150   dnl compiles only on the specified platforms.  For others, it
1151   dnl probably doesn't make sense to try.
1152   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1153      case "$opsys" in
1154        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1155        gnu-linux|freebsd|netbsd)
1156          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1157          ;;
1158      esac
1159   fi
1160
1161   AC_SUBST(CFLAGS_SOUND)
1162 fi
1163
1164 dnl checks for header files
1165 AC_CHECK_HEADERS_ONCE(
1166   sys/select.h sys/time.h utime.h
1167   linux/version.h sys/systeminfo.h
1168   stdio_ext.h fcntl.h coff.h pty.h
1169   sys/vlimit.h sys/resource.h
1170   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1171
1172 AC_MSG_CHECKING(if personality LINUX32 can be set)
1173 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1174                emacs_cv_personality_linux32=yes,
1175                emacs_cv_personality_linux32=no)
1176 AC_MSG_RESULT($emacs_cv_personality_linux32)
1177
1178 if test $emacs_cv_personality_linux32 = yes; then
1179   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1180             [Define to 1 if personality LINUX32 can be set.])
1181 fi
1182
1183 dnl On Solaris 8 there's a compilation warning for term.h because
1184 dnl it doesn't define `bool'.
1185 AC_CHECK_HEADERS(term.h, , , -)
1186 AC_HEADER_TIME
1187 AC_CHECK_DECLS([sys_siglist])
1188 if test $ac_cv_have_decl_sys_siglist != yes; then
1189   # For Tru64, at least:
1190   AC_CHECK_DECLS([__sys_siglist])
1191   if test $ac_cv_have_decl___sys_siglist = yes; then
1192     AC_DEFINE(sys_siglist, __sys_siglist,
1193               [Define to any substitute for sys_siglist.])
1194   fi
1195 fi
1196 AC_HEADER_SYS_WAIT
1197
1198 dnl Some systems have utime.h but don't declare the struct anyplace.
1199 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1200 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1201 #include <sys/time.h>
1202 #include <time.h>
1203 #else
1204 #ifdef HAVE_SYS_TIME_H
1205 #include <sys/time.h>
1206 #else
1207 #include <time.h>
1208 #endif
1209 #endif
1210 #ifdef HAVE_UTIME_H
1211 #include <utime.h>
1212 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1213   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1214 if test $emacs_cv_struct_utimbuf = yes; then
1215   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1216 fi
1217
1218 dnl Check for speed_t typedef.
1219 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1220   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1221     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1222 if test $emacs_cv_speed_t = yes; then
1223   AC_DEFINE(HAVE_SPEED_T, 1,
1224            [Define to 1 if `speed_t' is declared by <termios.h>.])
1225 fi
1226
1227 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1228 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1229 #include <sys/time.h>
1230 #include <time.h>
1231 #else
1232 #ifdef HAVE_SYS_TIME_H
1233 #include <sys/time.h>
1234 #else
1235 #include <time.h>
1236 #endif
1237 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1238   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1239 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1240 if test $emacs_cv_struct_timeval = yes; then
1241   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1242 fi
1243
1244 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1245 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1246 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1247   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1248 HAVE_EXCEPTION=$emacs_cv_struct_exception
1249 if test $emacs_cv_struct_exception != yes; then
1250   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1251 fi
1252
1253 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1254 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1255 #if HAVE_SYS_SOCKET_H
1256 #include <sys/socket.h>
1257 #endif])
1258 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1259 #if HAVE_SYS_SOCKET_H
1260 #include <sys/socket.h>
1261 #endif])
1262 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1263 #if HAVE_SYS_SOCKET_H
1264 #include <sys/socket.h>
1265 #endif])
1266 AC_CHECK_FUNCS(getifaddrs freeifaddrs)
1267
1268 dnl checks for structure members
1269 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1270                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1271                   struct ifreq.ifr_addr,
1272                   struct ifreq.ifr_addr.sa_len], , ,
1273                  [AC_INCLUDES_DEFAULT
1274 #if HAVE_SYS_SOCKET_H
1275 #include <sys/socket.h>
1276 #endif
1277 #if HAVE_NET_IF_H
1278 #include <net/if.h>
1279 #endif])
1280
1281 dnl Check for endianness.
1282 dnl AC_C_BIGENDIAN is done by gnulib.
1283
1284 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1285   [emacs_cv_attribute_aligned],
1286   [AC_COMPILE_IFELSE(
1287      [AC_LANG_PROGRAM(
1288         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1289         [[]])],
1290      [emacs_cv_attribute_aligned=yes],
1291      [emacs_cv_attribute_aligned=no])])
1292 if test $emacs_cv_attribute_aligned = yes; then
1293   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1294     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1295 fi
1296
1297 dnl check for Make feature
1298 dnl AC_PROG_MAKE_SET is done by Automake.
1299
1300 DEPFLAGS=
1301 MKDEPDIR=":"
1302 deps_frag=deps.mk
1303 dnl check for GNU Make if we have GCC and autodepend is on.
1304 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1305    AC_MSG_CHECKING([whether we are using GNU Make])
1306    HAVE_GNU_MAKE=no
1307    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1308    if test "x$testval" != x; then
1309       HAVE_GNU_MAKE=yes
1310    else
1311       ac_enable_autodepend=no
1312    fi
1313    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1314    if test $HAVE_GNU_MAKE = yes; then
1315       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1316       SAVE_CFLAGS="$CFLAGS"
1317       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1318       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1319       CFLAGS="$SAVE_CFLAGS"
1320       test -f deps.d || ac_enable_autodepend=no
1321       rm -rf deps.d
1322       AC_MSG_RESULT([$ac_enable_autodepend])
1323    fi
1324    if test $ac_enable_autodepend = yes; then
1325       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1326       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1327       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1328       deps_frag=autodeps.mk
1329    fi
1330 fi
1331 deps_frag=$srcdir/src/$deps_frag
1332 AC_SUBST(MKDEPDIR)
1333 AC_SUBST(DEPFLAGS)
1334 AC_SUBST_FILE(deps_frag)
1335
1336
1337 lisp_frag=$srcdir/src/lisp.mk
1338 AC_SUBST_FILE(lisp_frag)
1339
1340
1341 dnl checks for operating system services
1342 AC_SYS_LONG_FILE_NAMES
1343
1344 #### Choose a window system.
1345
1346 AC_PATH_X
1347 if test "$no_x" = yes; then
1348   window_system=none
1349 else
1350   window_system=x11
1351 fi
1352
1353 LD_SWITCH_X_SITE_RPATH=
1354 if test "${x_libraries}" != NONE; then
1355   if test -n "${x_libraries}"; then
1356     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1357     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1358   fi
1359   x_default_search_path=""
1360   x_search_path=${x_libraries}
1361   if test -z "${x_search_path}"; then
1362     x_search_path=/usr/lib
1363   fi
1364   for x_library in `echo ${x_search_path}: | \
1365                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1366     x_search_path="\
1367 ${x_library}/X11/%L/%T/%N%C%S:\
1368 ${x_library}/X11/%l/%T/%N%C%S:\
1369 ${x_library}/X11/%T/%N%C%S:\
1370 ${x_library}/X11/%L/%T/%N%S:\
1371 ${x_library}/X11/%l/%T/%N%S:\
1372 ${x_library}/X11/%T/%N%S"
1373     if test x"${x_default_search_path}" = x; then
1374       x_default_search_path=${x_search_path}
1375     else
1376       x_default_search_path="${x_search_path}:${x_default_search_path}"
1377     fi
1378   done
1379 fi
1380 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1381
1382 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1383   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1384 fi
1385
1386 if test x"${x_includes}" = x; then
1387   bitmapdir=/usr/include/X11/bitmaps
1388 else
1389   # accumulate include directories that have X11 bitmap subdirectories
1390   bmd_acc="dummyval"
1391   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1392     if test -d "${bmd}/X11/bitmaps"; then
1393       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1394     fi
1395     if test -d "${bmd}/bitmaps"; then
1396       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1397     fi
1398   done
1399   if test ${bmd_acc} != "dummyval"; then
1400     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1401   fi
1402 fi
1403
1404 HAVE_NS=no
1405 NS_IMPL_COCOA=no
1406 NS_IMPL_GNUSTEP=no
1407 tmp_CPPFLAGS="$CPPFLAGS"
1408 tmp_CFLAGS="$CFLAGS"
1409 CPPFLAGS="$CPPFLAGS -x objective-c"
1410 CFLAGS="$CFLAGS -x objective-c"
1411 TEMACS_LDFLAGS2="\${LDFLAGS}"
1412 GNU_OBJC_CFLAGS=
1413 if test "${with_ns}" != no; then
1414   if test "${opsys}" = darwin; then
1415      NS_IMPL_COCOA=yes
1416      ns_appdir=`pwd`/nextstep/Emacs.app
1417      ns_appbindir=${ns_appdir}/Contents/MacOS
1418      ns_appresdir=${ns_appdir}/Contents/Resources
1419      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1420   elif test -f $GNUSTEP_CONFIG_FILE; then
1421      NS_IMPL_GNUSTEP=yes
1422      ns_appdir=`pwd`/nextstep/Emacs.app
1423      ns_appbindir=${ns_appdir}
1424      ns_appresdir=${ns_appdir}/Resources
1425      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1426      dnl FIXME sourcing this several times in subshells seems inefficient.
1427      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1428      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1429      dnl I seemed to need these as well with GNUstep-startup 0.25.
1430      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1431      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1432      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1433        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1434      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1435        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1436      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1437      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1438      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1439      LIB_STANDARD=
1440      START_FILES=
1441      TEMACS_LDFLAGS2=
1442      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1443      dnl If they had chosen to either define it or not, we could have
1444      dnl just used AC_CHECK_DECL here.
1445      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1446        emacs_cv_objc_exceptions,
1447 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1448 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1449 1;
1450 #else
1451 fail;
1452 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1453      if test $emacs_cv_objc_exceptions = yes; then
1454        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1455        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1456          [Define if GNUstep uses ObjC exceptions.])
1457        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1458      fi
1459   fi
1460
1461   dnl This is only used while we test the NS headers, it gets reset below.
1462   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1463
1464   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1465                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1466   files are missing or cannot be compiled.])])
1467   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1468                                      [NSInteger i;])],
1469                     ns_have_nsinteger=yes,
1470                     ns_have_nsinteger=no)
1471   if test $ns_have_nsinteger = yes; then
1472     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1473   fi
1474 fi
1475 AC_SUBST(TEMACS_LDFLAGS2)
1476
1477 INSTALL_ARCH_INDEP_EXTRA=install-etc
1478 ns_self_contained=no
1479 ns_frag=/dev/null
1480 NS_OBJ=
1481 NS_OBJC_OBJ=
1482 if test "${HAVE_NS}" = yes; then
1483   if test "$with_toolkit_scroll_bars" = "no"; then
1484     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1485   fi
1486
1487   window_system=nextstep
1488   with_xft=no
1489   # set up packaging dirs
1490   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1491      ns_self_contained=yes
1492      prefix=${ns_appresdir}
1493      exec_prefix=${ns_appbindir}
1494      dnl This one isn't really used, only archlibdir is.
1495      libexecdir="\${ns_appbindir}/libexec"
1496      archlibdir="\${ns_appbindir}/libexec"
1497      docdir="\${ns_appresdir}/etc"
1498      etcdir="\${ns_appresdir}/etc"
1499      dnl FIXME maybe set datarootdir instead.
1500      dnl That would also get applications, icons, man.
1501      infodir="\${ns_appresdir}/info"
1502      mandir="\${ns_appresdir}/man"
1503      lispdir="\${ns_appresdir}/lisp"
1504      leimdir="\${ns_appresdir}/leim"
1505      INSTALL_ARCH_INDEP_EXTRA=
1506   fi
1507   ns_frag=$srcdir/src/ns.mk
1508   NS_OBJ="fontset.o fringe.o image.o"
1509   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1510 fi
1511 CFLAGS="$tmp_CFLAGS"
1512 CPPFLAGS="$tmp_CPPFLAGS"
1513 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1514 AC_SUBST(ns_self_contained)
1515 AC_SUBST(NS_OBJ)
1516 AC_SUBST(NS_OBJC_OBJ)
1517 AC_SUBST(LIB_STANDARD)
1518 AC_SUBST_FILE(ns_frag)
1519
1520 case "${window_system}" in
1521   x11 )
1522     HAVE_X_WINDOWS=yes
1523     HAVE_X11=yes
1524     case "${with_x_toolkit}" in
1525       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1526       motif ) USE_X_TOOLKIT=MOTIF ;;
1527       gtk ) with_gtk=yes
1528 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1529 dnl USE_X_TOOLKIT is set.
1530             USE_X_TOOLKIT=none ;;
1531       gtk3 ) with_gtk3=yes
1532              USE_X_TOOLKIT=none ;;
1533       no ) USE_X_TOOLKIT=none ;;
1534 dnl If user did not say whether to use a toolkit, make this decision later:
1535 dnl use the toolkit if we have gtk, or X11R5 or newer.
1536       * ) USE_X_TOOLKIT=maybe ;;
1537     esac
1538   ;;
1539   nextstep | none )
1540     HAVE_X_WINDOWS=no
1541     HAVE_X11=no
1542     USE_X_TOOLKIT=none
1543   ;;
1544 esac
1545
1546 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1547    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1548    if test "$HAVE_XSERVER" = true ||
1549       test -n "$DISPLAY" ||
1550       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1551         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1552 were found.  You should install the relevant development files for X
1553 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1554 sure you have development files for image handling, i.e.
1555 tiff, gif, jpeg, png and xpm.
1556 If you are sure you want Emacs compiled without X window support, pass
1557   --without-x
1558 to configure.])
1559    fi
1560 fi
1561
1562 ### If we're using X11, we should use the X menu package.
1563 HAVE_MENUS=no
1564 case ${HAVE_X11} in
1565   yes ) HAVE_MENUS=yes ;;
1566 esac
1567
1568 # Does the opsystem file prohibit the use of the GNU malloc?
1569 # Assume not, until told otherwise.
1570 GNU_MALLOC=yes
1571
1572 AC_CACHE_CHECK(
1573   [whether malloc is Doug Lea style],
1574   [emacs_cv_var_doug_lea_malloc],
1575   [AC_LINK_IFELSE(
1576      [AC_LANG_PROGRAM(
1577         [[#include <malloc.h>
1578           static void hook (void) {}]],
1579         [[malloc_set_state (malloc_get_state ());
1580           __after_morecore_hook = hook;
1581           __malloc_initialize_hook = hook;]])],
1582      [emacs_cv_var_doug_lea_malloc=yes],
1583      [emacs_cv_var_doug_lea_malloc=no])])
1584 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1585
1586
1587 dnl See comments in aix4-2.h about maybe using system malloc there.
1588 system_malloc=no
1589 case "$opsys" in
1590   ## darwin ld insists on the use of malloc routines in the System framework.
1591   darwin|sol2-10) system_malloc=yes ;;
1592 esac
1593
1594 if test "${system_malloc}" = "yes"; then
1595   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1596   GNU_MALLOC=no
1597   GNU_MALLOC_reason="
1598     (The GNU allocators don't work with this system configuration.)"
1599   GMALLOC_OBJ=
1600   VMLIMIT_OBJ=
1601 else
1602   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1603   VMLIMIT_OBJ=vm-limit.o
1604 fi
1605 AC_SUBST(GMALLOC_OBJ)
1606 AC_SUBST(VMLIMIT_OBJ)
1607
1608 if test "$doug_lea_malloc" = "yes" ; then
1609   if test "$GNU_MALLOC" = yes ; then
1610     GNU_MALLOC_reason="
1611       (Using Doug Lea's new malloc from the GNU C Library.)"
1612   fi
1613   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1614             [Define to 1 if you are using the GNU C Library.])
1615
1616   ## Use mmap directly for allocating larger buffers.
1617   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1618   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1619   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1620   case "$opsys" in
1621     gnu*) REL_ALLOC=no ;;
1622   esac
1623 fi
1624
1625 if test x"${REL_ALLOC}" = x; then
1626   REL_ALLOC=${GNU_MALLOC}
1627 fi
1628
1629 use_mmap_for_buffers=no
1630 case "$opsys" in
1631   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1632 esac
1633
1634 AC_FUNC_MMAP
1635 if test $use_mmap_for_buffers = yes; then
1636   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1637   REL_ALLOC=no
1638 fi
1639
1640 LIBS="$LIBS_SYSTEM $LIBS"
1641
1642 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1643 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1644 AC_CHECK_LIB(dnet, dnet_ntoa)
1645 dnl This causes -lresolv to get used in subsequent tests,
1646 dnl which causes failures on some systems such as HPUX 9.
1647 dnl AC_CHECK_LIB(resolv, gethostbyname)
1648
1649 dnl FIXME replace main with a function we actually want from this library.
1650 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1651
1652 dnl Check if pthreads is available.
1653 LIB_PTHREAD=
1654 AC_CHECK_HEADERS_ONCE(pthread.h)
1655 if test "$ac_cv_header_pthread_h"; then
1656   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1657   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1658   dnl testing for pthread_self if Emacs uses gmalloc.c.
1659   if test "$GMALLOC_OBJ" = gmalloc.o; then
1660     emacs_pthread_function=pthread_atfork
1661   else
1662     emacs_pthread_function=pthread_self
1663   fi
1664   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1665 fi
1666 if test "$HAVE_PTHREAD" = yes; then
1667   case "${canonical}" in
1668     *-hpux*) ;;
1669     *) LIB_PTHREAD="-lpthread"
1670        LIBS="$LIB_PTHREAD $LIBS" ;;
1671   esac
1672   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1673 fi
1674 AC_SUBST([LIB_PTHREAD])
1675
1676 AC_CHECK_LIB(pthreads, cma_open)
1677
1678 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1679 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1680 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1681 ## added to LIBS in configure would never contain the pthreads part,
1682 ## but the value used in Makefiles might.  FIXME?
1683 ##
1684 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1685 ## be harmless on older versions of X where it happens to exist.
1686 test "$opsys" = "aix4-2" && \
1687   test $ac_cv_lib_pthreads_cma_open = yes && \
1688   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1689
1690 dnl Check for need for bigtoc support on IBM AIX
1691
1692 case ${host_os} in
1693 aix*)
1694   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1695     case $GCC in
1696     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1697     *) gdb_cv_bigtoc=-bbigtoc ;;
1698     esac
1699
1700     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1701     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1702   ])
1703   ;;
1704 esac
1705
1706 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1707 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1708 # REAL_CPPFLAGS later on.
1709
1710 REAL_CFLAGS="$CFLAGS"
1711 REAL_CPPFLAGS="$CPPFLAGS"
1712
1713 if test "${HAVE_X11}" = "yes"; then
1714   DEFS="$C_SWITCH_X_SITE $DEFS"
1715   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1716   LIBS="-lX11 $LIBS"
1717   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1718   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1719
1720   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1721   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1722   # but it's more convenient here to set LD_RUN_PATH since this
1723   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1724   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1725     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1726     export LD_RUN_PATH
1727   fi
1728
1729   if test "${opsys}" = "gnu-linux"; then
1730     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1731     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1732      [[XOpenDisplay ("foo");]])],
1733      [xgnu_linux_first_failure=no],
1734      [xgnu_linux_first_failure=yes])
1735     if test "${xgnu_linux_first_failure}" = "yes"; then
1736       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1737       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1738       OLD_CPPFLAGS="$CPPFLAGS"
1739       OLD_LIBS="$LIBS"
1740       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1741       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1742       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1743       LIBS="$LIBS -b i486-linuxaout"
1744       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1745        [[XOpenDisplay ("foo");]])],
1746        [xgnu_linux_second_failure=no],
1747        [xgnu_linux_second_failure=yes])
1748       if test "${xgnu_linux_second_failure}" = "yes"; then
1749         # If we get the same failure with -b, there is no use adding -b.
1750         # So take it out.  This plays safe.
1751         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1752         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1753         CPPFLAGS="$OLD_CPPFLAGS"
1754         LIBS="$OLD_LIBS"
1755         AC_MSG_RESULT(no)
1756       else
1757         AC_MSG_RESULT(yes)
1758       fi
1759     else
1760       AC_MSG_RESULT(no)
1761     fi
1762   fi
1763
1764   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1765   # header files included from there.
1766   AC_MSG_CHECKING(for Xkb)
1767   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1768 #include <X11/XKBlib.h>]],
1769         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1770         emacs_xkb=yes, emacs_xkb=no)
1771   AC_MSG_RESULT($emacs_xkb)
1772   if test $emacs_xkb = yes; then
1773     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1774   fi
1775
1776   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1777 XScreenNumberOfScreen)
1778 fi
1779
1780 if test "${window_system}" = "x11"; then
1781   AC_MSG_CHECKING(X11 version 6)
1782   AC_CACHE_VAL(emacs_cv_x11_version_6,
1783   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1784 [[#if XlibSpecificationRelease < 6
1785 fail;
1786 #endif
1787 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1788   if test $emacs_cv_x11_version_6 = yes; then
1789     AC_MSG_RESULT(6 or newer)
1790     AC_DEFINE(HAVE_X11R6, 1,
1791               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1792     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1793     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1794     ## XIM support.
1795     case "$opsys" in
1796       sol2-*) : ;;
1797       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1798            [Define if you have usable X11R6-style XIM support.])
1799          ;;
1800     esac
1801   else
1802     AC_MSG_RESULT(before 6)
1803   fi
1804 fi
1805
1806
1807 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1808 HAVE_RSVG=no
1809 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1810   if test "${with_rsvg}" != "no"; then
1811     RSVG_REQUIRED=2.11.0
1812     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1813
1814     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1815     AC_SUBST(RSVG_CFLAGS)
1816     AC_SUBST(RSVG_LIBS)
1817
1818     if test $HAVE_RSVG = yes; then
1819       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1820       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1821       LIBS="$RSVG_LIBS $LIBS"
1822     fi
1823   fi
1824 fi
1825
1826 HAVE_IMAGEMAGICK=no
1827 if test "${HAVE_X11}" = "yes"; then
1828   if test "${with_imagemagick}" != "no"; then
1829     ## 6.2.8 is the earliest version known to work, but earlier versions
1830     ## might work - let us know if you find one.
1831     ## 6.0.7 does not work.  See bug#7955.
1832     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1833     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1834     AC_SUBST(IMAGEMAGICK_CFLAGS)
1835     AC_SUBST(IMAGEMAGICK_LIBS)
1836
1837     if test $HAVE_IMAGEMAGICK = yes; then
1838       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1839       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1840       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1841       AC_CHECK_FUNCS(MagickExportImagePixels)
1842     fi
1843   fi
1844 fi
1845
1846
1847 HAVE_GTK=no
1848 GTK_OBJ=
1849 if test "${with_gtk3}" = "yes"; then
1850   GLIB_REQUIRED=2.28
1851   GTK_REQUIRED=3.0
1852   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1853
1854   dnl Checks for libraries.
1855   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1856   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1857      AC_MSG_ERROR($GTK_PKG_ERRORS)
1858   fi
1859   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1860   GTK_OBJ=emacsgtkfixed.o
1861 fi
1862
1863 if test "$pkg_check_gtk" != "yes"; then
1864   HAVE_GTK=no
1865 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1866   GLIB_REQUIRED=2.10
1867   GTK_REQUIRED=2.10
1868   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1869
1870   dnl Checks for libraries.
1871   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1872   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1873      AC_MSG_ERROR($GTK_PKG_ERRORS)
1874   fi
1875 fi
1876 fi
1877
1878 if test x"$pkg_check_gtk" = xyes; then
1879
1880   AC_SUBST(GTK_CFLAGS)
1881   AC_SUBST(GTK_LIBS)
1882   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1883   CFLAGS="$CFLAGS $GTK_CFLAGS"
1884   LIBS="$GTK_LIBS $LIBS"
1885   dnl Try to compile a simple GTK program.
1886   GTK_COMPILES=no
1887   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1888   if test "${GTK_COMPILES}" != "yes"; then
1889     if test "$USE_X_TOOLKIT" != "maybe"; then
1890       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1891     fi
1892   else
1893     HAVE_GTK=yes
1894     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1895     GTK_OBJ="gtkutil.o $GTK_OBJ"
1896     USE_X_TOOLKIT=none
1897     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1898       :
1899     else
1900       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1901        closing open displays.  This is no problem if you just use
1902        one display, but if you use more than one and close one of them
1903        Emacs may crash.]])
1904       sleep 3
1905     fi
1906   fi
1907
1908 fi
1909 AC_SUBST(GTK_OBJ)
1910
1911
1912 if test "${HAVE_GTK}" = "yes"; then
1913
1914   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1915   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1916   if test "$with_toolkit_scroll_bars" != no; then
1917     with_toolkit_scroll_bars=yes
1918   fi
1919
1920   dnl  Check if we have the old file selection dialog declared and
1921   dnl  in the link library.  In 2.x it may be in the library,
1922   dnl  but not declared if deprecated featured has been selected out.
1923   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1924   HAVE_GTK_FILE_SELECTION=no
1925   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1926                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1927 #include <gtk/gtk.h>])
1928   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1929     AC_CHECK_FUNCS(gtk_file_selection_new)
1930   fi
1931
1932
1933   dnl Check for functions introduced in 2.14 and later.
1934   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1935                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1936                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1937                  gtk_orientable_set_orientation \
1938                  gtk_window_set_has_resize_grip)
1939 fi
1940
1941 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1942 dnl other platforms.
1943 HAVE_DBUS=no
1944 DBUS_OBJ=
1945 if test "${with_dbus}" = "yes"; then
1946    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1947    if test "$HAVE_DBUS" = yes; then
1948      LIBS="$LIBS $DBUS_LIBS"
1949      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1950      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1951      dnl dbus_validate_* have been introduced in D-Bus 1.5.12.
1952      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1953                     dbus_validate_bus_name \
1954                     dbus_validate_path \
1955                     dbus_validate_interface \
1956                     dbus_validate_member)
1957      DBUS_OBJ=dbusbind.o
1958    fi
1959 fi
1960 AC_SUBST(DBUS_OBJ)
1961
1962 dnl GSettings has been tested under GNU/Linux only.
1963 HAVE_GSETTINGS=no
1964 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1965    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1966    if test "$HAVE_GSETTINGS" = "yes"; then
1967       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1968       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1969       SETTINGS_LIBS="$GSETTINGS_LIBS"
1970    fi
1971 fi
1972
1973 dnl GConf has been tested under GNU/Linux only.
1974 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1975 HAVE_GCONF=no
1976 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1977    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1978    if test "$HAVE_GCONF" = yes; then
1979       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1980       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1981       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
1982       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
1983    fi
1984 fi
1985
1986 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
1987     SAVE_CFLAGS="$CFLAGS"
1988     SAVE_LIBS="$LIBS"
1989     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
1990     LIBS="$SETTINGS_LIBS $LIBS"
1991     AC_CHECK_FUNCS([g_type_init])
1992     CFLAGS="$SAVE_CFLAGS"
1993     LIBS="$SAVE_LIBS"
1994 fi
1995 AC_SUBST(SETTINGS_CFLAGS)
1996 AC_SUBST(SETTINGS_LIBS)
1997
1998
1999 dnl SELinux is available for GNU/Linux only.
2000 HAVE_LIBSELINUX=no
2001 LIBSELINUX_LIBS=
2002 if test "${with_selinux}" = "yes"; then
2003    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2004    if test "$HAVE_LIBSELINUX" = yes; then
2005       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2006       LIBSELINUX_LIBS=-lselinux
2007    fi
2008 fi
2009 AC_SUBST(LIBSELINUX_LIBS)
2010
2011 HAVE_GNUTLS=no
2012 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2013 if test "${with_gnutls}" = "yes" ; then
2014   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2015   if test "${HAVE_GNUTLS}" = "yes"; then
2016     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2017   fi
2018
2019   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2020   LIBS="$LIBGNUTLS_LIBS $LIBS"
2021   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2022
2023   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2024     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2025   fi
2026 fi
2027
2028 AC_SUBST(LIBGNUTLS_LIBS)
2029 AC_SUBST(LIBGNUTLS_CFLAGS)
2030
2031 dnl Do not put whitespace before the #include statements below.
2032 dnl Older compilers (eg sunos4 cc) choke on it.
2033 HAVE_XAW3D=no
2034 LUCID_LIBW=
2035 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2036   if test "$with_xaw3d" != no; then
2037     AC_MSG_CHECKING(for xaw3d)
2038     AC_CACHE_VAL(emacs_cv_xaw3d,
2039     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2040 #include <X11/Intrinsic.h>
2041 #include <X11/Xaw3d/Simple.h>]],
2042       [[]])],
2043       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2044                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2045       emacs_cv_xaw3d=no)])
2046   else
2047     emacs_cv_xaw3d=no
2048   fi
2049   if test $emacs_cv_xaw3d = yes; then
2050     AC_MSG_RESULT([yes; using Lucid toolkit])
2051     USE_X_TOOLKIT=LUCID
2052     HAVE_XAW3D=yes
2053     LUCID_LIBW=-lXaw3d
2054     AC_DEFINE(HAVE_XAW3D, 1,
2055               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2056   else
2057     AC_MSG_RESULT(no)
2058     AC_MSG_CHECKING(for libXaw)
2059     AC_CACHE_VAL(emacs_cv_xaw,
2060     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2061 #include <X11/Intrinsic.h>
2062 #include <X11/Xaw/Simple.h>]],
2063       [[]])],
2064       emacs_cv_xaw=yes,
2065       emacs_cv_xaw=no)])
2066     if test $emacs_cv_xaw = yes; then
2067       AC_MSG_RESULT([yes; using Lucid toolkit])
2068       USE_X_TOOLKIT=LUCID
2069       LUCID_LIBW=-lXaw
2070     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2071       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2072     else
2073       AC_MSG_ERROR([No X toolkit could be found.
2074 If you are sure you want Emacs compiled without an X toolkit, pass
2075   --with-x-toolkit=no
2076 to configure.  Otherwise, install the development libraries for the toolkit
2077 that you want to use (e.g. Gtk+) and re-run configure.])
2078     fi
2079   fi
2080 fi
2081
2082 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2083
2084 LIBXTR6=
2085 if test "${USE_X_TOOLKIT}" != "none"; then
2086   AC_MSG_CHECKING(X11 toolkit version)
2087   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2088   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2089 [[#if XtSpecificationRelease < 6
2090 fail;
2091 #endif
2092 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2093   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2094   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2095     AC_MSG_RESULT(6 or newer)
2096     AC_DEFINE(HAVE_X11XTR6, 1,
2097               [Define to 1 if you have the X11R6 or newer version of Xt.])
2098     LIBXTR6="-lSM -lICE"
2099     case "$opsys" in
2100       ## Use libw.a along with X11R6 Xt.
2101       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2102     esac
2103   else
2104     AC_MSG_RESULT(before 6)
2105   fi
2106
2107 dnl If using toolkit, check whether libXmu.a exists.
2108 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2109   OLDLIBS="$LIBS"
2110   if test x$HAVE_X11XTR6 = xyes; then
2111     LIBS="-lXt -lSM -lICE $LIBS"
2112   else
2113     LIBS="-lXt $LIBS"
2114   fi
2115   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2116   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2117 fi
2118 AC_SUBST(LIBXTR6)
2119
2120 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2121 dnl Why not just test for libxmu in the normal way?
2122 LIBXMU=-lXmu
2123 case $opsys in
2124   ## These systems don't supply Xmu.
2125   hpux* | aix4-2 )
2126     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2127     ;;
2128 esac
2129 AC_SUBST(LIBXMU)
2130
2131 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2132 if test "${HAVE_X11}" = "yes"; then
2133   if test "${USE_X_TOOLKIT}" != "none"; then
2134     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2135   fi
2136 fi
2137
2138 LIBXP=
2139 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2140   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2141   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2142     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2143 int x = 5;
2144 #else
2145 Motif version prior to 2.1.
2146 #endif]])],
2147     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2148   if test $emacs_cv_motif_version_2_1 = yes; then
2149     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2150   else
2151     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2152     # We put this in CFLAGS temporarily to precede other -I options
2153     # that might be in CFLAGS temporarily.
2154     # We put this in CPPFLAGS where it precedes the other -I options.
2155     OLD_CPPFLAGS=$CPPFLAGS
2156     OLD_CFLAGS=$CFLAGS
2157     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2158     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2159     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2160       [[int x = 5;]])],
2161       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2162     if test $emacs_cv_lesstif = yes; then
2163       # Make sure this -I option remains in CPPFLAGS after it is set
2164       # back to REAL_CPPFLAGS.
2165       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2166       # have those other -I options anyway.  Ultimately, having this
2167       # directory ultimately in CPPFLAGS will be enough.
2168       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2169       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2170     else
2171       CFLAGS=$OLD_CFLAGS
2172       CPPFLAGS=$OLD_CPPFLAGS
2173     fi
2174   fi
2175   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2176     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2177 fi
2178
2179 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2180 dnl using Motif or Xaw3d is available, and unless
2181 dnl --with-toolkit-scroll-bars=no was specified.
2182
2183 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2184             [Define to 1 if we should use toolkit scroll bars.])dnl
2185 USE_TOOLKIT_SCROLL_BARS=no
2186 if test "${with_toolkit_scroll_bars}" != "no"; then
2187   if test "${USE_X_TOOLKIT}" != "none"; then
2188     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2189       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2190       HAVE_XAW3D=no
2191       USE_TOOLKIT_SCROLL_BARS=yes
2192     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2193       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2194       USE_TOOLKIT_SCROLL_BARS=yes
2195     fi
2196   elif test "${HAVE_GTK}" = "yes"; then
2197     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2198     USE_TOOLKIT_SCROLL_BARS=yes
2199   elif test "${HAVE_NS}" = "yes"; then
2200     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2201     USE_TOOLKIT_SCROLL_BARS=yes
2202   fi
2203 fi
2204
2205 dnl See if XIM is available.
2206 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2207           #include <X11/Xlib.h>
2208           #include <X11/Xresource.h>]],
2209          [[XIMProc  callback;]])],
2210          [HAVE_XIM=yes
2211          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2212          HAVE_XIM=no)
2213
2214 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2215
2216 if test "${with_xim}" != "no"; then
2217   AC_DEFINE(USE_XIM, 1,
2218             [Define to 1 if we should use XIM, if it is available.])
2219 fi
2220
2221
2222 if test "${HAVE_XIM}" != "no"; then
2223   late_CFLAGS=$CFLAGS
2224   if test "$GCC" = yes; then
2225     CFLAGS="$CFLAGS --pedantic-errors"
2226   fi
2227   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2228 #include <X11/Xlib.h>
2229 #include <X11/Xresource.h>]],
2230 [[Display *display;
2231 XrmDatabase db;
2232 char *res_name;
2233 char *res_class;
2234 XIMProc  callback;
2235 XPointer *client_data;
2236 #ifndef __GNUC__
2237 /* If we're not using GCC, it's probably not XFree86, and this is
2238    probably right, but we can't use something like --pedantic-errors.  */
2239 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2240                                            char*, XIMProc, XPointer*);
2241 #endif
2242 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2243    client_data);]])],
2244     [emacs_cv_arg6_star=yes])
2245   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2246          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2247 either XPointer or XPointer*.])dnl
2248   if test "$emacs_cv_arg6_star" = yes; then
2249     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2250   else
2251     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2252   fi
2253   CFLAGS=$late_CFLAGS
2254 fi
2255
2256 ### Start of font-backend (under any platform) section.
2257 # (nothing here yet -- this is a placeholder)
2258 ### End of font-backend (under any platform) section.
2259
2260 ### Start of font-backend (under X11) section.
2261 if test "${HAVE_X11}" = "yes"; then
2262    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2263
2264    ## Use -lXft if available, unless `--with-xft=no'.
2265    HAVE_XFT=maybe
2266     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2267       with_xft="no";
2268     fi
2269     if test "x${with_xft}" != "xno"; then
2270
2271       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2272       ## Because xftfont.c uses XRenderQueryExtension, we also
2273       ## need to link to -lXrender.
2274       HAVE_XRENDER=no
2275       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2276       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2277         OLD_CPPFLAGS="$CPPFLAGS"
2278         OLD_CFLAGS="$CFLAGS"
2279         OLD_LIBS="$LIBS"
2280         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2281         CFLAGS="$CFLAGS $XFT_CFLAGS"
2282         XFT_LIBS="-lXrender $XFT_LIBS"
2283         LIBS="$XFT_LIBS $LIBS"
2284         AC_CHECK_HEADER(X11/Xft/Xft.h,
2285           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2286
2287         if test "${HAVE_XFT}" = "yes"; then
2288           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2289             AC_SUBST(XFT_LIBS)
2290           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2291         else
2292           CPPFLAGS="$OLD_CPPFLAGS"
2293           CFLAGS="$OLD_CFLAGS"
2294           LIBS="$OLD_LIBS"
2295         fi                        # "${HAVE_XFT}" = "yes"
2296       fi                          # "$HAVE_XFT" != no
2297     fi                            # "x${with_xft}" != "xno"
2298
2299     ## We used to allow building with FreeType and without Xft.
2300     ## However, the ftx font backend driver is not in good shape.
2301     if test "$HAVE_XFT" != "yes"; then
2302        dnl For the "Does Emacs use" message at the end.
2303        HAVE_XFT=no
2304        HAVE_FREETYPE=no
2305     else
2306        dnl Strict linkers fail with
2307        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2308        dnl if -lfreetype is not specified.
2309        dnl The following is needed to set FREETYPE_LIBS.
2310        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2311                          HAVE_FREETYPE=no)
2312
2313        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2314     fi
2315
2316     HAVE_LIBOTF=no
2317     if test "${HAVE_FREETYPE}" = "yes"; then
2318       AC_DEFINE(HAVE_FREETYPE, 1,
2319                 [Define to 1 if using the freetype and fontconfig libraries.])
2320       if test "${with_libotf}" != "no"; then
2321         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2322                           HAVE_LIBOTF=no)
2323         if test "$HAVE_LIBOTF" = "yes"; then
2324           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2325           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2326                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2327                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2328           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2329             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2330                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2331           fi
2332         fi
2333       fi
2334     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2335     dnl Does the new font backend require it, or can it work without it?
2336     fi
2337
2338     HAVE_M17N_FLT=no
2339     if test "${HAVE_LIBOTF}" = yes; then
2340       if test "${with_m17n_flt}" != "no"; then
2341         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2342         if test "$HAVE_M17N_FLT" = "yes"; then
2343           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2344         fi
2345       fi
2346     fi
2347 else
2348     HAVE_XFT=no
2349     HAVE_FREETYPE=no
2350     HAVE_LIBOTF=no
2351     HAVE_M17N_FLT=no
2352 fi
2353
2354 ### End of font-backend (under X11) section.
2355
2356 AC_SUBST(FREETYPE_CFLAGS)
2357 AC_SUBST(FREETYPE_LIBS)
2358 AC_SUBST(FONTCONFIG_CFLAGS)
2359 AC_SUBST(FONTCONFIG_LIBS)
2360 AC_SUBST(LIBOTF_CFLAGS)
2361 AC_SUBST(LIBOTF_LIBS)
2362 AC_SUBST(M17N_FLT_CFLAGS)
2363 AC_SUBST(M17N_FLT_LIBS)
2364
2365 ### Use -lXpm if available, unless `--with-xpm=no'.
2366 HAVE_XPM=no
2367 LIBXPM=
2368 if test "${HAVE_X11}" = "yes"; then
2369   if test "${with_xpm}" != "no"; then
2370     AC_CHECK_HEADER(X11/xpm.h,
2371       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2372     if test "${HAVE_XPM}" = "yes"; then
2373       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2374       AC_EGREP_CPP(no_return_alloc_pixels,
2375       [#include "X11/xpm.h"
2376 #ifndef XpmReturnAllocPixels
2377 no_return_alloc_pixels
2378 #endif
2379       ], HAVE_XPM=no, HAVE_XPM=yes)
2380
2381       if test "${HAVE_XPM}" = "yes"; then
2382         AC_MSG_RESULT(yes)
2383       else
2384         AC_MSG_RESULT(no)
2385       fi
2386     fi
2387   fi
2388
2389   if test "${HAVE_XPM}" = "yes"; then
2390     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2391     LIBXPM=-lXpm
2392   fi
2393 fi
2394 AC_SUBST(LIBXPM)
2395
2396 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2397 HAVE_JPEG=no
2398 LIBJPEG=
2399 if test "${HAVE_X11}" = "yes"; then
2400   if test "${with_jpeg}" != "no"; then
2401     dnl Checking for jpeglib.h can lose because of a redefinition of
2402     dnl  HAVE_STDLIB_H.
2403     AC_CHECK_HEADER(jerror.h,
2404       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2405   fi
2406
2407   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2408   if test "${HAVE_JPEG}" = "yes"; then
2409     AC_DEFINE(HAVE_JPEG)
2410     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2411         [#include <jpeglib.h>
2412          version=JPEG_LIB_VERSION
2413 ],
2414         [AC_DEFINE(HAVE_JPEG)],
2415         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2416         HAVE_JPEG=no])
2417   fi
2418   if test "${HAVE_JPEG}" = "yes"; then
2419     LIBJPEG=-ljpeg
2420   fi
2421 fi
2422 AC_SUBST(LIBJPEG)
2423
2424 ### Use -lpng if available, unless `--with-png=no'.
2425 HAVE_PNG=no
2426 LIBPNG=
2427 if test "${HAVE_X11}" = "yes"; then
2428   if test "${with_png}" != "no"; then
2429     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2430     # in /usr/include/libpng.
2431     AC_CHECK_HEADERS(png.h libpng/png.h)
2432     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2433       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2434     fi
2435   fi
2436
2437   if test "${HAVE_PNG}" = "yes"; then
2438     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2439     LIBPNG="-lpng -lz -lm"
2440   fi
2441 fi
2442 AC_SUBST(LIBPNG)
2443
2444 ### Use -ltiff if available, unless `--with-tiff=no'.
2445 HAVE_TIFF=no
2446 LIBTIFF=
2447 if test "${HAVE_X11}" = "yes"; then
2448   if test "${with_tiff}" != "no"; then
2449     AC_CHECK_HEADER(tiffio.h,
2450       [tifflibs="-lz -lm"
2451       # At least one tiff package requires the jpeg library.
2452       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2453       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2454   fi
2455
2456   if test "${HAVE_TIFF}" = "yes"; then
2457     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2458     dnl FIXME -lz -lm, as per libpng?
2459     LIBTIFF=-ltiff
2460   fi
2461 fi
2462 AC_SUBST(LIBTIFF)
2463
2464 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2465 HAVE_GIF=no
2466 LIBGIF=
2467 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2468   AC_CHECK_HEADER(gif_lib.h,
2469 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2470 # Earlier versions can crash Emacs.
2471     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2472
2473   if test "$HAVE_GIF" = yes; then
2474     LIBGIF=-lgif
2475   elif test "$HAVE_GIF" = maybe; then
2476 # If gif_lib.h but no libgif, try libungif.
2477     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2478     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2479   fi
2480
2481   if test "${HAVE_GIF}" = "yes"; then
2482     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2483   fi
2484 fi
2485 AC_SUBST(LIBGIF)
2486
2487 dnl Check for required libraries.
2488 if test "${HAVE_X11}" = "yes"; then
2489   MISSING=""
2490   WITH_NO=""
2491   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2492     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2493   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2494     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2495   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2496     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2497   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2498     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2499   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2500     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2501
2502   if test "X${MISSING}" != X; then
2503     AC_MSG_ERROR([The following required libraries were not found:
2504     $MISSING
2505 Maybe some development libraries/packages are missing?
2506 If you don't want to link with them give
2507     $WITH_NO
2508 as options to configure])
2509   fi
2510 fi
2511
2512 ### Use -lgpm if available, unless `--with-gpm=no'.
2513 HAVE_GPM=no
2514 LIBGPM=
2515 if test "${with_gpm}" != "no"; then
2516   AC_CHECK_HEADER(gpm.h,
2517     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2518
2519   if test "${HAVE_GPM}" = "yes"; then
2520     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2521     LIBGPM=-lgpm
2522   fi
2523 fi
2524 AC_SUBST(LIBGPM)
2525
2526 dnl Check for malloc/malloc.h on darwin
2527 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2528
2529 GNUSTEP_CFLAGS=
2530 ### Use NeXTstep API to implement GUI.
2531 if test "${HAVE_NS}" = "yes"; then
2532   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2533   if test "${NS_IMPL_COCOA}" = "yes"; then
2534     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2535   fi
2536   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2537     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2538     # See also .m.o rule in Makefile.in */
2539     # FIXME: are all these flags really needed?  Document here why.  */
2540     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2541     ## Extra CFLAGS applied to src/*.m files.
2542     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2543   fi
2544   # We also have mouse menus.
2545   HAVE_MENUS=yes
2546   OTHER_FILES=ns-app
2547 fi
2548
2549
2550 ### Use session management (-lSM -lICE) if available
2551 HAVE_X_SM=no
2552 LIBXSM=
2553 if test "${HAVE_X11}" = "yes"; then
2554   AC_CHECK_HEADER(X11/SM/SMlib.h,
2555     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2556
2557   if test "${HAVE_X_SM}" = "yes"; then
2558     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2559     LIBXSM="-lSM -lICE"
2560     case "$LIBS" in
2561       *-lSM*) ;;
2562       *)      LIBS="$LIBXSM $LIBS" ;;
2563     esac
2564   fi
2565 fi
2566 AC_SUBST(LIBXSM)
2567
2568 ### Use libxml (-lxml2) if available
2569 HAVE_LIBXML2=no
2570 if test "${with_xml2}" != "no"; then
2571   ### I'm not sure what the version number should be, so I just guessed.
2572   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2573   if test "${HAVE_LIBXML2}" = "yes"; then
2574     LIBS="$LIBXML2_LIBS $LIBS"
2575     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2576     if test "${HAVE_LIBXML2}" = "yes"; then
2577       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2578     else
2579       LIBXML2_LIBS=""
2580       LIBXML2_CFLAGS=""
2581     fi
2582   fi
2583 fi
2584 AC_SUBST(LIBXML2_LIBS)
2585 AC_SUBST(LIBXML2_CFLAGS)
2586
2587 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2588 AC_CACHE_CHECK(whether netdb declares h_errno,
2589                emacs_cv_netdb_declares_h_errno,
2590 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2591   [[return h_errno;]])],
2592   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2593 if test $emacs_cv_netdb_declares_h_errno = yes; then
2594   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2595 fi
2596
2597 # fmod, logb, and frexp are found in -lm on most systems.
2598 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2599 AC_CHECK_LIB(m, sqrt)
2600
2601 # Check for mail-locking functions in a "mail" library.  Probably this should
2602 # have the same check as for liblockfile below.
2603 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2604 if test $have_mail = yes; then
2605   LIBS_MAIL=-lmail
2606   LIBS="$LIBS_MAIL $LIBS"
2607   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2608 else
2609   LIBS_MAIL=
2610 fi
2611 dnl Debian, at least:
2612 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2613 if test $have_lockfile = yes; then
2614    LIBS_MAIL=-llockfile
2615    LIBS="$LIBS_MAIL $LIBS"
2616    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2617 else
2618 # If we have the shared liblockfile, assume we must use it for mail
2619 # locking (e.g. Debian).  If we couldn't link against liblockfile
2620 # (no liblockfile.a installed), ensure that we don't need to.
2621   dnl This works for files generally, not just executables.
2622   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2623   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2624                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2625   if test $ac_cv_prog_liblockfile = yes; then
2626     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2627 This probably means that movemail could lose mail.
2628 There may be a `development' package to install containing liblockfile.])
2629   fi
2630 fi
2631 AC_CHECK_FUNCS(touchlock)
2632 AC_CHECK_HEADERS_ONCE(maillock.h)
2633 AC_SUBST(LIBS_MAIL)
2634
2635 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2636 ## interlock access to the mail spool.  The alternative is a lock file named
2637 ## /usr/spool/mail/$USER.lock.
2638 mail_lock=no
2639 case "$opsys" in
2640   aix4-2) mail_lock="lockf" ;;
2641
2642   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2643
2644   ## On GNU/Linux systems, both methods are used by various mail programs.
2645   ## I assume most people are using newer mailers that have heard of flock.
2646   ## Change this if you need to.
2647   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2648   ## configure gets the right answers, and that means *NOT* using flock.
2649   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2650   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2651   ## Debian maintainer hasn't provided a clean fix for Emacs.
2652   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2653   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2654   ## correct logic.  -- fx
2655   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2656   ## liblockfile is a Free Software replacement for libmail, used on
2657   ## Debian systems and elsewhere. -rfr.
2658   gnu-*)
2659     mail_lock="flock"
2660     if test $have_mail = yes || test $have_lockfile = yes; then
2661       test $ac_cv_header_maillock_h = yes && mail_lock=no
2662     fi
2663     ;;
2664 esac
2665
2666 BLESSMAIL_TARGET=
2667 case "$mail_lock" in
2668   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2669
2670   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2671
2672   *) BLESSMAIL_TARGET="need-blessmail" ;;
2673 esac
2674 AC_SUBST(BLESSMAIL_TARGET)
2675
2676
2677 AC_CHECK_FUNCS(gethostname \
2678 rename closedir mkdir rmdir getrusage get_current_dir_name \
2679 random lrand48 logb frexp fmod rint cbrt setsid \
2680 strerror fpathconf select euidaccess getpagesize setlocale \
2681 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2682 __fpending strsignal setitimer \
2683 sendto recvfrom getsockname getpeername \
2684 gai_strerror mkstemp getline getdelim fsync sync \
2685 difftime posix_memalign \
2686 getpwent endpwent getgrent endgrent \
2687 cfmakeraw cfsetspeed copysign __executable_start)
2688
2689 dnl Cannot use AC_CHECK_FUNCS
2690 AC_CACHE_CHECK([for __builtin_unwind_init],
2691                emacs_cv_func___builtin_unwind_init,
2692 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2693                 emacs_cv_func___builtin_unwind_init=yes,
2694                 emacs_cv_func___builtin_unwind_init=no)])
2695 if test $emacs_cv_func___builtin_unwind_init = yes; then
2696   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2697             [Define to 1 if you have the `__builtin_unwind_init' function.])
2698 fi
2699
2700 AC_CHECK_HEADERS_ONCE(sys/un.h)
2701
2702 AC_FUNC_FSEEKO
2703
2704 AC_FUNC_GETPGRP
2705
2706 # UNIX98 PTYs.
2707 AC_CHECK_FUNCS(grantpt)
2708
2709 # PTY-related GNU extensions.
2710 AC_CHECK_FUNCS(getpt)
2711
2712 # Check this now, so that we will NOT find the above functions in ncurses.
2713 # That is because we have not set up to link ncurses in lib-src.
2714 # It's better to believe a function is not available
2715 # than to expect to find it in ncurses.
2716 # Also we need tputs and friends to be able to build at all.
2717 AC_MSG_CHECKING([for library containing tputs])
2718 # Run a test program that contains a call to tputs, a call that is
2719 # never executed.  This tests whether a pre-'main' dynamic linker
2720 # works with the library.  It's too much trouble to actually call
2721 # tputs in the test program, due to portability hassles.  When
2722 # cross-compiling, assume the test program will run if it links.
2723 AC_DEFUN([tputs_link_source], [
2724   AC_LANG_SOURCE(
2725      [[extern void tputs (const char *, int, int (*)(int));
2726        int main (int argc, char **argv)
2727        {
2728           if (argc == 10000)
2729             tputs (argv[0], 0, 0);
2730           return 0;
2731        }]])
2732 ])
2733 # Maybe curses should be tried earlier?
2734 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2735 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2736   OLIBS=$LIBS
2737   if test -z "$tputs_library"; then
2738     LIBS_TERMCAP=
2739     msg='none required'
2740   else
2741     LIBS_TERMCAP=-l$tputs_library
2742     msg=$LIBS_TERMCAP
2743     LIBS="$LIBS_TERMCAP $LIBS"
2744   fi
2745   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2746     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2747   LIBS=$OLIBS
2748   if test "X$msg" != Xno; then
2749     break
2750   fi
2751 done
2752 AC_MSG_RESULT([$msg])
2753 if test "X$msg" = Xno; then
2754   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2755 The following libraries were tried (in order):
2756   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2757 Please try installing whichever of these libraries is most appropriate
2758 for your system, together with its header files.
2759 For example, a libncurses-dev(el) or similar package.])
2760 fi
2761
2762 ## Use termcap instead of terminfo?
2763 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2764 TERMINFO=yes
2765 ## FIXME?  In the cases below where we unconditionally set
2766 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2767 ## if that was found above to have tputs.
2768 ## Should we use the gnu* logic everywhere?
2769 case "$opsys" in
2770   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2771   ##  The ncurses library has been moved out of the System framework in
2772   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2773   ##  option to use it.
2774   darwin) LIBS_TERMCAP="-lncurses" ;;
2775
2776   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2777
2778   freebsd)
2779     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2780     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2781     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2782 [[#if __FreeBSD_version < 400000
2783 fail;
2784 #endif
2785 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2786
2787     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2788
2789     if test $emacs_cv_freebsd_terminfo = yes; then
2790       LIBS_TERMCAP="-lncurses"
2791     else
2792       TERMINFO=no
2793       LIBS_TERMCAP="-ltermcap"
2794     fi
2795     ;;
2796
2797   netbsd)
2798     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2799       TERMINFO=no
2800       LIBS_TERMCAP="-ltermcap"
2801     fi
2802     ;;
2803
2804   openbsd) LIBS_TERMCAP="-lncurses" ;;
2805
2806   ## hpux: Make sure we get select from libc rather than from libcurses
2807   ##  because libcurses on HPUX 10.10 has a broken version of select.
2808   ##  We used to use -lc -lcurses, but this may be cleaner.
2809   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2810   # set that way, now it uses the default).  Isn't this a contradiction?
2811   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2812
2813 esac
2814
2815 TERMCAP_OBJ=tparam.o
2816 if test $TERMINFO = yes; then
2817   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2818   TERMCAP_OBJ=terminfo.o
2819 fi
2820 AC_SUBST(LIBS_TERMCAP)
2821 AC_SUBST(TERMCAP_OBJ)
2822
2823
2824 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2825 resolv=no
2826 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2827 #include <arpa/nameser.h>
2828 #include <resolv.h>]],
2829     [[return res_init();]])],
2830     have_res_init=yes, have_res_init=no)
2831 if test "$have_res_init" = no; then
2832   OLIBS="$LIBS"
2833   LIBS="$LIBS -lresolv"
2834   AC_MSG_CHECKING(for res_init with -lresolv)
2835   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2836 #include <arpa/nameser.h>
2837 #include <resolv.h>]],
2838     [[return res_init();]])],
2839     have_res_init=yes, have_res_init=no)
2840   AC_MSG_RESULT($have_res_init)
2841   if test "$have_res_init" = yes ; then
2842     resolv=yes
2843   fi
2844   LIBS="$OLIBS"
2845 fi
2846
2847 if test "$have_res_init" = yes; then
2848   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2849 fi
2850
2851 # Do we need the Hesiod library to provide the support routines?
2852 LIBHESIOD=
2853 if test "$with_hesiod" != no ; then
2854   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2855   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2856      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2857                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2858   if test "$resolv" = yes ; then
2859     RESOLVLIB=-lresolv
2860   else
2861     RESOLVLIB=
2862   fi
2863   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2864         hesiod=yes, :, $RESOLVLIB)])
2865
2866   if test x"$hesiod" = xyes; then
2867     AC_DEFINE(HAVE_LIBHESIOD, 1,
2868               [Define to 1 if you have the hesiod library (-lhesiod).])
2869     LIBHESIOD=-lhesiod
2870   fi
2871 fi
2872 AC_SUBST(LIBHESIOD)
2873
2874 # Do we need libresolv (due to res_init or Hesiod)?
2875 if test "$resolv" = yes ; then
2876   AC_DEFINE(HAVE_LIBRESOLV, 1,
2877             [Define to 1 if you have the resolv library (-lresolv).])
2878   LIBRESOLV=-lresolv
2879 else
2880   LIBRESOLV=
2881 fi
2882 AC_SUBST(LIBRESOLV)
2883
2884 # These tell us which Kerberos-related libraries to use.
2885 COM_ERRLIB=
2886 CRYPTOLIB=
2887 KRB5LIB=
2888 DESLIB=
2889 KRB4LIB=
2890
2891 if test "${with_kerberos}" != no; then
2892   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2893   if test $have_com_err = yes; then
2894     COM_ERRLIB=-lcom_err
2895     LIBS="$COM_ERRLIB $LIBS"
2896     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2897   fi
2898   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2899   if test $have_crypto = yes; then
2900     CRYPTOLIB=-lcrypto
2901     LIBS="$CRYPTOLIB $LIBS"
2902     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2903   fi
2904   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2905   if test $have_k5crypto = yes; then
2906     CRYPTOLIB=-lk5crypto
2907     LIBS="$CRYPTOLIB $LIBS"
2908     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2909   fi
2910   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2911   if test $have_krb5=yes; then
2912     KRB5LIB=-lkrb5
2913     LIBS="$KRB5LIB $LIBS"
2914     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2915   fi
2916   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2917   if test "${with_kerberos5}" = no; then
2918     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2919     if test $have_des425 = yes; then
2920       DESLIB=-ldes425
2921       LIBS="$DESLIB $LIBS"
2922       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2923     else
2924       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2925       if test $have_des = yes; then
2926         DESLIB=-ldes
2927         LIBS="$DESLIB $LIBS"
2928         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2929       fi
2930     fi
2931     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2932     if test $have_krb4 = yes; then
2933       KRB4LIB=-lkrb4
2934       LIBS="$KRB4LIB $LIBS"
2935       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2936     else
2937       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2938       if test $have_krb = yes; then
2939         KRB4LIB=-lkrb
2940         LIBS="$KRB4LIB $LIBS"
2941         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2942       fi
2943     fi
2944   fi
2945
2946   if test "${with_kerberos5}" != no; then
2947     AC_CHECK_HEADERS(krb5.h,
2948       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2949                         [#include <krb5.h>])])
2950   else
2951     AC_CHECK_HEADERS(des.h,,
2952                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2953                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2954     AC_CHECK_HEADERS(krb.h,,
2955                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2956                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2957   fi
2958   AC_CHECK_HEADERS(com_err.h)
2959 fi
2960
2961 AC_SUBST(COM_ERRLIB)
2962 AC_SUBST(CRYPTOLIB)
2963 AC_SUBST(KRB5LIB)
2964 AC_SUBST(DESLIB)
2965 AC_SUBST(KRB4LIB)
2966
2967 AC_CHECK_FUNCS_ONCE(tzset)
2968 AC_MSG_CHECKING(whether localtime caches TZ)
2969 AC_CACHE_VAL(emacs_cv_localtime_cache,
2970 [if test x$ac_cv_func_tzset = xyes; then
2971 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2972 char TZ_GMT0[] = "TZ=GMT0";
2973 char TZ_PST8[] = "TZ=PST8";
2974 main()
2975 {
2976   time_t now = time ((time_t *) 0);
2977   int hour_GMT0, hour_unset;
2978   if (putenv (TZ_GMT0) != 0)
2979     exit (1);
2980   hour_GMT0 = localtime (&now)->tm_hour;
2981   unsetenv("TZ");
2982   hour_unset = localtime (&now)->tm_hour;
2983   if (putenv (TZ_PST8) != 0)
2984     exit (1);
2985   if (localtime (&now)->tm_hour == hour_GMT0)
2986     exit (1);
2987   unsetenv("TZ");
2988   if (localtime (&now)->tm_hour != hour_unset)
2989     exit (1);
2990   exit (0);
2991 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2992 [# If we have tzset, assume the worst when cross-compiling.
2993 emacs_cv_localtime_cache=yes])
2994 else
2995         # If we lack tzset, report that localtime does not cache TZ,
2996         # since we can't invalidate the cache if we don't have tzset.
2997         emacs_cv_localtime_cache=no
2998 fi])dnl
2999 AC_MSG_RESULT($emacs_cv_localtime_cache)
3000 if test $emacs_cv_localtime_cache = yes; then
3001   AC_DEFINE(LOCALTIME_CACHE, 1,
3002             [Define to 1 if localtime caches TZ.])
3003 fi
3004
3005 if test "x$HAVE_TIMEVAL" = xyes; then
3006   AC_CHECK_FUNCS(gettimeofday)
3007   if test $ac_cv_func_gettimeofday = yes; then
3008     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3009                    emacs_cv_gettimeofday_two_arguments,
3010     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3011 #ifdef TIME_WITH_SYS_TIME
3012 #include <sys/time.h>
3013 #include <time.h>
3014 #else
3015 #ifdef HAVE_SYS_TIME_H
3016 #include <sys/time.h>
3017 #else
3018 #include <time.h>
3019 #endif
3020 #endif]],
3021       [[struct timeval time;
3022        gettimeofday (&time, 0);]])],
3023       emacs_cv_gettimeofday_two_arguments=yes,
3024       emacs_cv_gettimeofday_two_arguments=no)])
3025     if test $emacs_cv_gettimeofday_two_arguments = no; then
3026       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3027                 [Define to 1 if gettimeofday accepts only one argument.])
3028     fi
3029   fi
3030 fi
3031
3032 ok_so_far=yes
3033 AC_CHECK_FUNC(socket, , ok_so_far=no)
3034 if test $ok_so_far = yes; then
3035   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3036 fi
3037 if test $ok_so_far = yes; then
3038   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3039 fi
3040 if test $ok_so_far = yes; then
3041 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3042   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3043             [Define to 1 if you have inet sockets.])
3044 fi
3045
3046 if test -f /usr/lpp/X11/bin/smt.exp; then
3047   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3048             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3049 fi
3050
3051 AC_MSG_CHECKING(whether system supports dynamic ptys)
3052 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3053   AC_MSG_RESULT(yes)
3054   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3055 else
3056   AC_MSG_RESULT(no)
3057 fi
3058
3059 AC_FUNC_FORK
3060
3061 AC_CHECK_FUNCS(snprintf)
3062
3063 dnl Adapted from Haible's version.
3064 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3065   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3066     [[char* cs = nl_langinfo(CODESET);]])],
3067     emacs_cv_langinfo_codeset=yes,
3068     emacs_cv_langinfo_codeset=no)
3069   ])
3070 if test $emacs_cv_langinfo_codeset = yes; then
3071   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3072     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3073 fi
3074
3075 AC_TYPE_MBSTATE_T
3076
3077 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3078   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3079                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3080 if test "$emacs_cv_c_restrict_arr" = yes; then
3081   AC_DEFINE(__restrict_arr, __restrict,
3082     [Define to compiler's equivalent of C99 restrict keyword in array
3083      declarations.  Define as empty for no equivalent.])
3084 fi
3085
3086 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3087 dnl how the tty code is related to POSIX and/or other versions of termios.
3088 dnl The following looks like a useful start.
3089 dnl
3090 dnl AC_SYS_POSIX_TERMIOS
3091 dnl if test $ac_cv_sys_posix_termios = yes; then
3092 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3093 dnl                                and macros for terminal control.])
3094 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3095 dnl fi
3096
3097 # Set up the CFLAGS for real compilation, so we can substitute it.
3098 CFLAGS="$REAL_CFLAGS"
3099 CPPFLAGS="$REAL_CPPFLAGS"
3100
3101 ## Hack to detect a buggy GCC version.
3102 if test "x$GCC" = xyes \
3103    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3104    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3105    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3106    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3107 fi
3108
3109 version=$PACKAGE_VERSION
3110
3111 ### Specify what sort of things we'll be editing into Makefile and config.h.
3112 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3113 AC_SUBST(version)
3114 AC_SUBST(configuration)
3115 ## Unused?
3116 AC_SUBST(canonical)
3117 AC_SUBST(srcdir)
3118 AC_SUBST(prefix)
3119 AC_SUBST(exec_prefix)
3120 AC_SUBST(bindir)
3121 AC_SUBST(datadir)
3122 AC_SUBST(sharedstatedir)
3123 AC_SUBST(libexecdir)
3124 AC_SUBST(mandir)
3125 AC_SUBST(infodir)
3126 AC_SUBST(lispdir)
3127 AC_SUBST(leimdir)
3128 AC_SUBST(locallisppath)
3129 AC_SUBST(lisppath)
3130 AC_SUBST(x_default_search_path)
3131 AC_SUBST(etcdir)
3132 AC_SUBST(archlibdir)
3133 AC_SUBST(docdir)
3134 AC_SUBST(bitmapdir)
3135 AC_SUBST(gamedir)
3136 AC_SUBST(gameuser)
3137 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3138 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3139 ## end of LIBX_BASE, but nothing ever set it.
3140 AC_SUBST(LD_SWITCH_X_SITE)
3141 AC_SUBST(C_SWITCH_X_SITE)
3142 AC_SUBST(GNUSTEP_CFLAGS)
3143 AC_SUBST(CFLAGS)
3144 ## Used in lwlib/Makefile.in.
3145 AC_SUBST(X_TOOLKIT_TYPE)
3146 S_FILE="\$(srcdir)/${opsysfile}"
3147 AC_SUBST(S_FILE)
3148 AC_SUBST(ns_appdir)
3149 AC_SUBST(ns_appbindir)
3150 AC_SUBST(ns_appresdir)
3151 AC_SUBST(ns_appsrc)
3152 AC_SUBST(GNU_OBJC_CFLAGS)
3153 AC_SUBST(OTHER_FILES)
3154
3155 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3156                    [Define to the canonical Emacs configuration name.])
3157 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3158                    [Define to the options passed to configure.])
3159 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3160                    [Define to the used os dependent file.])
3161
3162 XMENU_OBJ=
3163 XOBJ=
3164 FONT_OBJ=
3165 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3166   AC_DEFINE(HAVE_X_WINDOWS, 1,
3167             [Define to 1 if you want to use the X window system.])
3168   XMENU_OBJ=xmenu.o
3169   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3170   FONT_OBJ=xfont.o
3171   if test "$HAVE_XFT" = "yes"; then
3172     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3173   elif test "$HAVE_FREETYPE" = "yes"; then
3174     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3175   fi
3176   AC_SUBST(FONT_OBJ)
3177 fi
3178 AC_SUBST(XMENU_OBJ)
3179 AC_SUBST(XOBJ)
3180 AC_SUBST(FONT_OBJ)
3181
3182 WIDGET_OBJ=
3183 MOTIF_LIBW=
3184 if test "${USE_X_TOOLKIT}" != "none" ; then
3185   WIDGET_OBJ=widget.o
3186   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3187   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3188     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3189   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3190     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3191     MOTIF_LIBW=-lXm
3192     case "$opsys" in
3193       gnu-linux)
3194         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3195         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3196         ;;
3197
3198       unixware)
3199         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3200         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3201         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3202         ;;
3203
3204       aix4-2)
3205         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3206         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3207         ;;
3208     esac
3209     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3210   fi
3211 fi
3212 AC_SUBST(WIDGET_OBJ)
3213
3214 TOOLKIT_LIBW=
3215 case "$USE_X_TOOLKIT" in
3216   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3217   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3218   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3219 esac
3220 AC_SUBST(TOOLKIT_LIBW)
3221
3222 if test "$USE_X_TOOLKIT" = "none"; then
3223   LIBXT_OTHER="\$(LIBXSM)"
3224   OLDXMENU_TARGET="really-oldXMenu"
3225 else
3226   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3227   OLDXMENU_TARGET="really-lwlib"
3228 fi
3229 AC_SUBST(LIBXT_OTHER)
3230
3231 ## The X Menu stuff is present in the X10 distribution, but missing
3232 ## from X11.  If we have X10, just use the installed library;
3233 ## otherwise, use our own copy.
3234 if test "${HAVE_X11}" = "yes" ; then
3235   AC_DEFINE(HAVE_X11, 1,
3236             [Define to 1 if you want to use version 11 of X windows.
3237              Otherwise, Emacs expects to use version 10.])
3238
3239   if test "$USE_X_TOOLKIT" = "none"; then
3240     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3241   else
3242     OLDXMENU="\${lwlibdir}/liblw.a"
3243   fi
3244   LIBXMENU="\$(OLDXMENU)"
3245   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3246   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3247 else
3248   ## For a syntactically valid Makefile; not actually used for anything.
3249   ## See comments in src/Makefile.in.
3250   OLDXMENU=nothing
3251   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3252   if test "${HAVE_X_WINDOWS}" = "yes"; then
3253     LIBXMENU="-lXMenu"
3254   else
3255     LIBXMENU=
3256   fi
3257   LIBX_OTHER=
3258   OLDXMENU_DEPS=
3259 fi
3260
3261 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3262   OLDXMENU_TARGET=
3263   OLDXMENU=nothing
3264   LIBXMENU=
3265   OLDXMENU_DEPS=
3266 fi
3267
3268 AC_SUBST(OLDXMENU_TARGET)
3269 AC_SUBST(OLDXMENU)
3270 AC_SUBST(LIBXMENU)
3271 AC_SUBST(LIBX_OTHER)
3272 AC_SUBST(OLDXMENU_DEPS)
3273
3274 if test "${HAVE_MENUS}" = "yes" ; then
3275   AC_DEFINE(HAVE_MENUS, 1,
3276             [Define to 1 if you have mouse menus.
3277              (This is automatic if you use X, but the option to specify it remains.)
3278              It is also defined with other window systems that support xmenu.c.])
3279 fi
3280
3281 if test "${GNU_MALLOC}" = "yes" ; then
3282   AC_DEFINE(GNU_MALLOC, 1,
3283             [Define to 1 if you want to use the GNU memory allocator.])
3284 fi
3285
3286 RALLOC_OBJ=
3287 if test "${REL_ALLOC}" = "yes" ; then
3288   AC_DEFINE(REL_ALLOC, 1,
3289             [Define REL_ALLOC if you want to use the relocating allocator for
3290              buffer space.])
3291
3292   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3293 fi
3294 AC_SUBST(RALLOC_OBJ)
3295
3296 if test "$opsys" = "cygwin"; then
3297   CYGWIN_OBJ="sheap.o"
3298   ## Cygwin differs because of its unexec().
3299   PRE_ALLOC_OBJ=
3300   POST_ALLOC_OBJ=lastfile.o
3301 else
3302   CYGWIN_OBJ=
3303   PRE_ALLOC_OBJ=lastfile.o
3304   POST_ALLOC_OBJ=
3305 fi
3306 AC_SUBST(CYGWIN_OBJ)
3307 AC_SUBST(PRE_ALLOC_OBJ)
3308 AC_SUBST(POST_ALLOC_OBJ)
3309
3310 # Configure gnulib here, now that we know LIBS.
3311 gl_ASSERT_NO_GNULIB_POSIXCHECK
3312 gl_ASSERT_NO_GNULIB_TESTS
3313 gl_INIT
3314
3315 case "$opsys" in
3316   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3317
3318   darwin)
3319    ## The -headerpad option tells ld (see man page) to leave room at the
3320    ## end of the header for adding load commands.  Needed for dumping.
3321    ## 0x690 is the total size of 30 segment load commands (at 56
3322    ## each); under Cocoa 31 commands are required.
3323    if test "$HAVE_NS" = "yes"; then
3324      libs_nsgui="-framework AppKit"
3325      headerpad_extra=6C8
3326    else
3327      libs_nsgui=
3328      headerpad_extra=690
3329    fi
3330    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3331
3332    ## This is here because src/Makefile.in did some extra fiddling around
3333    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3334    ##   #ifndef LD_SWITCH_SYSTEM
3335    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3336    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3337    ## not using gcc, darwin.
3338    ## Because this was done in src/Makefile.in, the resulting part of
3339    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3340    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3341    ## rather than LD_SWITCH_SYSTEM.
3342    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3343      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3344    ;;
3345
3346   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3347   ## find X at run-time.
3348   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3349   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3350   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3351   ## had different values in configure (in ac_link) and src/Makefile.in.
3352   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3353   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3354
3355   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3356 esac
3357
3358 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3359   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3360 fi
3361
3362 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3363
3364
3365 LD_FIRSTFLAG=
3366 ORDINARY_LINK=
3367 case "$opsys" in
3368   ## gnu: GNU needs its own crt0.
3369   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3370
3371   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3372   ## library search parth, i.e. it won't search /usr/lib for libc and
3373   ## friends.  Using -nostartfiles instead avoids this problem, and
3374   ## will also work on earlier NetBSD releases.
3375   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3376
3377   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3378   ##   MkLinux/LinuxPPC needs this.
3379   ## s390x-* only supports opsys = gnu-linux so it can be added here.
3380   gnu-*)
3381     case "$canonical" in
3382       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
3383     esac
3384     ;;
3385 esac
3386
3387
3388 if test "x$ORDINARY_LINK" = "xyes"; then
3389
3390   LD_FIRSTFLAG=""
3391   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3392
3393 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3394 ## freebsd, gnu-* not on powerpc*|s390x*.
3395 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3396
3397   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3398   ## places that are difficult to figure out at make time.  Fortunately,
3399   ## these same versions allow you to pass arbitrary flags on to the
3400   ## linker, so there is no reason not to use it as a linker.
3401   ##
3402   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3403   ## searching for libraries in its internal directories, so we have to
3404   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3405   LD_FIRSTFLAG="-nostdlib"
3406 fi
3407
3408 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3409 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3410
3411 AC_SUBST(LD_FIRSTFLAG)
3412
3413
3414 ## FIXME? The logic here is not precisely the same as that above.
3415 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3416 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3417 LIB_GCC=
3418 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3419
3420   case "$opsys" in
3421     freebsd|netbsd|openbsd) LIB_GCC= ;;
3422
3423     gnu-*)
3424       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3425       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3426       case $host_cpu in
3427       arm*)
3428         LIB_GCC="-lgcc_s"
3429         ;;
3430       *)
3431         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3432         ## immediately undefine it again and redefine it to empty.
3433         ## Was the C_SWITCH_X_SITE part really necessary?
3434 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3435         LIB_GCC=
3436         ;;
3437       esac
3438       ;;
3439
3440     ## Ask GCC where to find libgcc.a.
3441     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3442   esac
3443 fi                              dnl if $GCC
3444 AC_SUBST(LIB_GCC)
3445
3446
3447 ## If we're using X11/GNUstep, define some consequences.
3448 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3449   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3450   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3451 fi
3452
3453
3454 AH_TOP([/* GNU Emacs site configuration template file.
3455
3456 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3457   Free Software Foundation, Inc.
3458
3459 This file is part of GNU Emacs.
3460
3461 GNU Emacs is free software: you can redistribute it and/or modify
3462 it under the terms of the GNU General Public License as published by
3463 the Free Software Foundation, either version 3 of the License, or
3464 (at your option) any later version.
3465
3466 GNU Emacs is distributed in the hope that it will be useful,
3467 but WITHOUT ANY WARRANTY; without even the implied warranty of
3468 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3469 GNU General Public License for more details.
3470
3471 You should have received a copy of the GNU General Public License
3472 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3473
3474
3475 /* No code in Emacs #includes config.h twice, but some bits of code
3476    intended to work with other packages as well (like gmalloc.c)
3477    think they can include it as many times as they like.  */
3478 #ifndef EMACS_CONFIG_H
3479 #define EMACS_CONFIG_H
3480 ])dnl
3481
3482 AH_BOTTOM([
3483 /* On AIX 3 this must be included before any other include file.  */
3484 #include <alloca.h>
3485 #if ! HAVE_ALLOCA
3486 # error "alloca not available on this machine"
3487 #endif
3488
3489 /* Define AMPERSAND_FULL_NAME if you use the convention
3490    that & in the full name stands for the login id.  */
3491 /* Turned on June 1996 supposing nobody will mind it.  */
3492 #define AMPERSAND_FULL_NAME
3493
3494 /* `subprocesses' should be defined if you want to
3495    have code for asynchronous subprocesses
3496    (as used in M-x compile and M-x shell).
3497    Only MSDOS does not support this (it overrides
3498    this in its config_opsysfile below).  */
3499
3500 #define subprocesses
3501
3502 /* Include the os dependent file.  */
3503 #include config_opsysfile
3504
3505 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3506    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3507   (There is probably a better place to do this, but right now the
3508    Cocoa side does this in s/darwin.h and we cannot parallel this
3509    exactly since GNUstep is multi-OS.  */
3510 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3511 #  define SYSTEM_PURESIZE_EXTRA 30000
3512 #endif
3513
3514 #ifdef emacs /* Don't do this for lib-src.  */
3515 /* Tell regex.c to use a type compatible with Emacs.  */
3516 #define RE_TRANSLATE_TYPE Lisp_Object
3517 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3518 #ifdef make_number
3519 /* If make_number is a macro, use it.  */
3520 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3521 #else
3522 /* If make_number is a function, avoid it.  */
3523 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3524 #endif
3525 #endif
3526
3527 #include <string.h>
3528 #include <stdlib.h>
3529
3530 #if defined __GNUC__ && (__GNUC__ > 2 \
3531                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3532 #define NO_RETURN       __attribute__ ((__noreturn__))
3533 #else
3534 #define NO_RETURN       /* nothing */
3535 #endif
3536
3537 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3538 #define NO_INLINE __attribute__((noinline))
3539 #else
3540 #define NO_INLINE
3541 #endif
3542
3543 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3544 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3545 #else
3546 #define EXTERNALLY_VISIBLE
3547 #endif
3548
3549 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3550 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3551 #else
3552 # define ATTRIBUTE_FORMAT(spec) /* empty */
3553 #endif
3554
3555 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3556 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3557    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3558 #else
3559 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3560    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3561 #endif
3562
3563 /* Some versions of GNU/Linux define noinline in their headers.  */
3564 #ifdef noinline
3565 #undef noinline
3566 #endif
3567
3568 /* These won't be used automatically yet.  We also need to know, at least,
3569    that the stack is continuous.  */
3570 #ifdef __GNUC__
3571 #  ifndef GC_SETJMP_WORKS
3572   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3573 #    define GC_SETJMP_WORKS 1
3574 #  endif
3575 #endif
3576
3577 #endif /* EMACS_CONFIG_H */
3578
3579 /*
3580 Local Variables:
3581 mode: c
3582 End:
3583 */
3584 ])dnl
3585
3586 #### Report on what we decided to do.
3587 #### Report GTK as a toolkit, even if it doesn't use Xt.
3588 #### It makes printing result more understandable as using GTK sets
3589 #### toolkit_scroll_bars to yes by default.
3590 if test "${HAVE_GTK}" = "yes"; then
3591   USE_X_TOOLKIT=GTK
3592 fi
3593
3594 echo "
3595 Configured for \`${canonical}'.
3596
3597   Where should the build process find the source code?    ${srcdir}
3598   What operating system file should Emacs use?
3599         \`${opsysfile}'
3600   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3601   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3602   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3603   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3604   What window system should Emacs use?                    ${window_system}
3605   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3606
3607 if test -n "${x_includes}"; then
3608 echo "  Where do we find X Windows header files?                ${x_includes}"
3609 else
3610 echo "  Where do we find X Windows header files?                Standard dirs"
3611 fi
3612 if test -n "${x_libraries}"; then
3613 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3614 else
3615 echo "  Where do we find X Windows libraries?                   Standard dirs"
3616 fi
3617
3618 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3619 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3620 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3621 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3622 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3623 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3624 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3625 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3626
3627 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3628 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3629 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3630 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3631 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3632 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3633 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3634
3635 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3636 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3637 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3638 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3639
3640 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3641 echo
3642
3643 if test -n "${EMACSDATA}"; then
3644    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3645 fi
3646 if test -n "${EMACSDOC}"; then
3647    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3648 fi
3649
3650 if test $USE_XASSERTS = yes; then
3651    echo "  Compiling with asserts turned on."
3652    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3653 fi
3654
3655 echo
3656
3657 if test "$HAVE_NS" = "yes"; then
3658    echo
3659    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3660 The installed application will go to nextstep/Emacs.app and can be
3661 run or moved from there."
3662    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3663       echo "The application will be fully self-contained."
3664     else
3665       echo "The lisp resources for the application will be installed under ${prefix}.
3666 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3667 to run if these resources are not installed."
3668    fi
3669    echo
3670 fi
3671
3672 if test "${opsys}" = "cygwin"; then
3673   case `uname -r` in
3674     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3675            echo
3676            ;;
3677   esac
3678 fi
3679
3680 # Remove any trailing slashes in these variables.
3681 [test "${prefix}" != NONE &&
3682   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3683 test "${exec_prefix}" != NONE &&
3684   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3685
3686 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3687 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3688 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3689 dnl (else you get "no `Makefile.am' found for any configure output").
3690 dnl This will work, but you get a config.status that is not quite right
3691 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3692 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3693 dnl it seems better to just live with the duplication.
3694 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3695
3696 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3697        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3698        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3699        leim/Makefile])
3700
3701 dnl test/ is not present in release tarfiles.
3702 opt_makefile=test/automated/Makefile
3703
3704 if test -f $srcdir/${opt_makefile}.in; then
3705   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3706   dnl Again, it's best not to use a variable.  Though you can add
3707   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3708   AC_CONFIG_FILES([test/automated/Makefile])
3709 fi
3710
3711
3712 dnl admin/ may or may not be present.
3713 opt_makefile=admin/unidata/Makefile
3714
3715 if test -f $srcdir/${opt_makefile}.in; then
3716   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3717   AC_CONFIG_FILES([admin/unidata/Makefile])
3718 fi
3719
3720
3721 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3722
3723 AC_SUBST(SUBDIR_MAKEFILES_IN)
3724
3725 dnl Make the necessary directories, if they don't exist.
3726 AC_CONFIG_COMMANDS([mkdirs], [
3727 for dir in etc lisp ; do
3728   test -d ${dir} || mkdir ${dir}
3729 done
3730 ])
3731
3732 dnl You might wonder (I did) why epaths.h is generated by running make,
3733 dnl rather than just letting configure generate it from epaths.in.
3734 dnl One reason is that the various paths are not fully expanded (see above);
3735 dnl eg gamedir=${prefix}/var/games/emacs.
3736 dnl Secondly, the GNU Coding standards require that one should be able
3737 dnl to run `make prefix=/some/where/else' and override the values set
3738 dnl by configure.  This also explains the `move-if-change' test and
3739 dnl the use of force in the `epaths-force' rule in Makefile.in.
3740 AC_CONFIG_COMMANDS([epaths], [
3741 echo creating src/epaths.h
3742 ${MAKE-make} epaths-force
3743 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
3744
3745 AC_CONFIG_COMMANDS([gdbinit], [
3746 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3747   echo creating src/.gdbinit
3748   echo source $srcdir/src/.gdbinit > src/.gdbinit
3749 fi
3750 ])
3751
3752 AC_OUTPUT
3753
3754 dnl configure.in ends here