lisp/progmodes/f90.el

   1 ;;; f90.el --- Fortran-90 mode (free format)
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 2000 Free Software Foundation, Inc.
   4
   5 ;; Author: Torbj\"orn Einarsson <Torbjorn.Einarsson@era.ericsson.se>
   6 ;; Maintainer: Glenn Morris <gmorris@ast.cam.ac.uk>
   7 ;; Keywords: fortran, f90, languages
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Major mode for editing F90 programs in FREE FORMAT.
  29 ;; The minor language revision F95 is also supported (with font-locking).
  30
  31 ;; Knows about continuation lines, named structured statements, and other
  32 ;; features in F90 including HPF (High Performance Fortran) structures.
  33 ;; The basic feature provides accurate indentation of F90 programs.
  34 ;; In addition, there are many more features like automatic matching of all
  35 ;; end statements, an auto-fill function to break long lines, a join-lines
  36 ;; function which joins continued lines, etc.
  37
  38 ;; To facilitate typing, a fairly complete list of abbreviations is provided.
  39 ;; All abbreviations begin with the backquote character "`"
  40 ;; (this requires modification of the syntax-table).
  41 ;; For example, `i expands to integer (if abbrev-mode is on).
  42
  43 ;; There are two separate features for altering the appearance of code:
  44 ;;   1) Upcasing or capitalizing of all keywords.
  45 ;;   2) Colors/fonts using font-lock-mode.
  46 ;; Automatic upcase or downcase of keywords is controlled by the variable
  47 ;; f90-auto-keyword-case.
  48
  49 ;; The indentations of lines starting with ! is determined by the first of the
  50 ;; following matches (values in the left column are the defaults):
  51
  52 ;; start-string/regexp  indent         variable holding start-string/regexp
  53 ;;    !!!                  0
  54 ;;    !hpf\\$ (re)         0              f90-directive-comment-re
  55 ;;    !!$                  0              f90-comment-region
  56 ;;    !      (re)        as code          f90-indented-comment-re
  57 ;;    default            comment-column
  58
  59 ;; Ex: Here is the result of 3 different settings of f90-indented-comment-re
  60 ;;     f90-indented-comment-re  !-indentation      !!-indentation
  61 ;;          !                    as code             as code
  62 ;;          !!                   comment-column      as code
  63 ;;          ![^!]                as code             comment-column
  64 ;; Trailing comments are indented to comment-column with indent-for-comment.
  65 ;; The function f90-comment-region toggles insertion of
  66 ;; the variable f90-comment-region in every line of the region.
  67
  68 ;; One common convention for free vs. fixed format is that free-format files
  69 ;; have the ending .f90 or .f95 while fixed format files have the ending .f.
  70 ;; Emacs automatically loads Fortran files in the appropriate mode based
  71 ;; on extension. You can modify this by adjusting the variable auto-mode-alist.
  72 ;; For example:
  73 ;; (add-to-list 'auto-mode-alist '("\\.f\\'" . f90-mode))
  74
  75 ;; Once you have entered f90-mode, you may get more info by using
  76 ;; the command describe-mode (C-h m). For online help use
  77 ;; C-h f <Name of function you want described>, or
  78 ;; C-h v <Name of variable you want described>.
  79
  80 ;; To customize f90-mode for your taste, use, for example:
  81 ;; (you don't have to specify values for all the parameters below)
  82 ;;
  83 ;;(add-hook 'f90-mode-hook
  84 ;;      ;; These are the default values.
  85 ;;      '(lambda () (setq f90-do-indent 3
  86 ;;                        f90-if-indent 3
  87 ;;                        f90-type-indent 3
  88 ;;                        f90-program-indent 2
  89 ;;                        f90-continuation-indent 5
  90 ;;                        f90-comment-region "!!$"
  91 ;;                        f90-directive-comment-re "!hpf\\$"
  92 ;;                        f90-indented-comment-re "!"
  93 ;;                        f90-break-delimiters "[-+\\*/><=,% \t]"
  94 ;;                        f90-break-before-delimiters t
  95 ;;                        f90-beginning-ampersand t
  96 ;;                        f90-smart-end 'blink
  97 ;;                        f90-auto-keyword-case nil
  98 ;;                        f90-leave-line-no nil
  99 ;;                        indent-tabs-mode nil
 100 ;;                        f90-font-lock-keywords f90-font-lock-keywords-2
 101 ;;                  )
 102 ;;       ;; These are not default.
 103 ;;       (abbrev-mode 1)             ; turn on abbreviation mode
 104 ;;       (f90-add-imenu-menu)        ; extra menu with functions etc.
 105 ;;       (if f90-auto-keyword-case   ; change case of all keywords on startup
 106 ;;           (f90-change-keywords f90-auto-keyword-case))
 107 ;;       ))
 108 ;;
 109 ;; in your .emacs file. You can also customize the lists
 110 ;; f90-font-lock-keywords, etc.
 111 ;;
 112 ;; The auto-fill and abbreviation minor modes are accessible from the F90 menu,
 113 ;; or by using M-x auto-fill-mode and M-x abbrev-mode, respectively.
 114
 115 ;; Remarks
 116 ;; 1) Line numbers are by default left-justified. If f90-leave-line-no is
 117 ;;    non-nil, the line numbers are never touched.
 118 ;; 2) Multi-; statements like "do i=1,20 ; j=j+i ; end do" are not handled
 119 ;;    correctly, but I imagine them to be rare.
 120 ;; 3) Regexps for hilit19 are no longer supported.
 121 ;; 4) For FIXED FORMAT code, use fortran mode.
 122 ;; 5) This mode does not work under emacs-18.x.
 123 ;; 6) Preprocessor directives, i.e., lines starting with # are left-justified
 124 ;;    and are untouched by all case-changing commands. There is, at present, no
 125 ;;    mechanism for treating multi-line directives (continued by \ ).
 126 ;; 7) f77 do-loops do 10 i=.. ; ; 10 continue are not correctly indented.
 127 ;;    You are urged to use f90-do loops (with labels if you wish).
 128 ;; 8) The highlighting mode under XEmacs is not as complete as under Emacs.
 129
 130 ;; List of user commands
 131 ;;   f90-previous-statement         f90-next-statement
 132 ;;   f90-beginning-of-subprogram    f90-end-of-subprogram   f90-mark-subprogram
 133 ;;   f90-comment-region
 134 ;;   f90-indent-line                f90-indent-new-line
 135 ;;   f90-indent-region    (can be called by calling indent-region)
 136 ;;   f90-indent-subprogram
 137 ;;   f90-break-line                 f90-join-lines
 138 ;;   f90-fill-region
 139 ;;   f90-insert-end
 140 ;;   f90-upcase-keywords            f90-upcase-region-keywords
 141 ;;   f90-downcase-keywords          f90-downcase-region-keywords
 142 ;;   f90-capitalize-keywords        f90-capitalize-region-keywords
 143 ;;   f90-add-imenu-menu
 144 ;;   f90-font-lock-1, f90-font-lock-2, f90-font-lock-3, f90-font-lock-4
 145
 146 ;; Original author's thanks
 147 ;; Thanks to all the people who have tested the mode. Special thanks to Jens
 148 ;; Bloch Helmers for encouraging me to write this code, for creative
 149 ;; suggestions as well as for the lists of hpf-commands.
 150 ;; Also thanks to the authors of the fortran and pascal modes, on which some
 151 ;; of this code is built.
 152
 153 ;; TODO
 154 ;; Support for hideshow, align.
 155 ;; OpenMP, preprocessor highlighting.
 156
 157 ;;; Code:
 158
 159 ;; User options
 160
 161 (defgroup f90 nil
 162   "Major mode for editing Fortran 90,95 code."
 163   :group 'languages)
 164
 165 (defgroup f90-indent nil
 166   "Indentation in free-format Fortran."
 167   :prefix "f90-"
 168   :group 'f90)
 169
 170
 171 (defcustom f90-do-indent 3
 172   "*Extra indentation applied to DO blocks."
 173   :type 'integer
 174   :group 'f90-indent)
 175
 176 (defcustom f90-if-indent 3
 177   "*Extra indentation applied to IF, SELECT CASE, WHERE and FORALL blocks."
 178   :type 'integer
 179   :group 'f90-indent)
 180
 181 (defcustom f90-type-indent 3
 182   "*Extra indentation applied to TYPE, INTERFACE and BLOCK DATA blocks."
 183   :type 'integer
 184   :group 'f90-indent)
 185
 186 (defcustom f90-program-indent 2
 187   "*Extra indentation applied to PROGRAM/MODULE/SUBROUTINE/FUNCTION blocks."
 188   :type 'integer
 189   :group 'f90-indent)
 190
 191 (defcustom f90-continuation-indent 5
 192   "*Extra indentation applied to F90 continuation lines."
 193   :type 'integer
 194   :group 'f90-indent)
 195
 196 (defcustom f90-comment-region "!!$"
 197   "*String inserted by \\[f90-comment-region] at start of each line in region."
 198   :type 'string
 199   :group 'f90-indent)
 200
 201 (defcustom f90-indented-comment-re "!"
 202   "*Regexp saying which comments to indent like code."
 203   :type 'regexp
 204   :group 'f90-indent)
 205
 206 (defcustom f90-directive-comment-re "!hpf\\$"
 207   "*Regexp of comment-like directive like \"!HPF\\\\$\", not to be indented."
 208   :type 'regexp
 209   :group 'f90-indent)
 210
 211 (defcustom f90-beginning-ampersand t
 212   "*Non-nil gives automatic insertion of \& at start of continuation line."
 213   :type 'boolean
 214   :group 'f90)
 215
 216 (defcustom f90-smart-end 'blink
 217   "*From an END statement, check and fill the end using matching block start.
 218 Allowed values are 'blink, 'no-blink, and nil, which determine
 219 whether to blink the matching beginning."
 220   :type '(choice (const blink) (const no-blink) (const nil))
 221   :group 'f90)
 222
 223 (defcustom f90-break-delimiters "[-+\\*/><=,% \t]"
 224   "*Regexp holding list of delimiters at which lines may be broken."
 225   :type 'regexp
 226   :group 'f90)
 227
 228 (defcustom f90-break-before-delimiters t
 229   "*Non-nil causes `f90-do-auto-fill' to break lines before delimiters."
 230   :type 'boolean
 231   :group 'f90)
 232
 233 (defcustom f90-auto-keyword-case nil
 234   "*Automatic case conversion of keywords.
 235 The options are 'downcase-word, 'upcase-word, 'capitalize-word and nil."
 236   :type '(choice (const downcase-word) (const upcase-word)
 237                  (const capitalize-word) (const nil))
 238   :group 'f90)
 239
 240 (defcustom f90-leave-line-no nil
 241   "*If non-nil, line numbers are not left justified."
 242   :type 'boolean
 243   :group 'f90)
 244
 245 (defconst f90-xemacs-flag (string-match "XEmacs\\|Lucid" emacs-version)
 246   "Non-nil means F90 mode thinks it is running under XEmacs.")
 247
 248 (defconst f90-keywords-re
 249   (regexp-opt '("allocatable" "allocate" "assign" "assignment" "backspace"
 250                 "block" "call" "case" "character" "close" "common" "complex"
 251                 "contains" "continue" "cycle" "data" "deallocate"
 252                 "dimension" "do" "double" "else" "elseif" "elsewhere" "end"
 253                 "enddo" "endfile" "endif" "entry" "equivalence" "exit"
 254                 "external" "forall" "format" "function" "goto" "if"
 255                 "implicit" "include" "inquire" "integer" "intent"
 256                 "interface" "intrinsic" "logical" "module" "namelist" "none"
 257                 "nullify" "only" "open" "operator" "optional" "parameter"
 258                 "pause" "pointer" "precision" "print" "private" "procedure"
 259                 "program" "public" "read" "real" "recursive" "result" "return"
 260                 "rewind" "save" "select" "sequence" "stop" "subroutine"
 261                 "target" "then" "type" "use" "where" "while" "write"
 262                 ;; F95 keywords.
 263                 "elemental" "pure") 'words)
 264   "Regexp for F90 keywords.")
 265
 266 (defconst f90-keywords-level-3-re
 267   (regexp-opt
 268    '("allocatable" "allocate" "assign" "assignment" "backspace"
 269      "close" "deallocate" "dimension" "endfile" "entry" "equivalence"
 270      "external" "inquire" "intent" "intrinsic" "nullify" "only" "open"
 271      "operator" "optional" "parameter" "pause" "pointer" "print" "private"
 272      "public" "read" "recursive" "result" "rewind" "save" "select"
 273      "sequence" "target" "write"
 274      ;; F95 keywords.
 275      "elemental" "pure") 'words)
 276   "Keyword-regexp for font-lock level >= 3.")
 277
 278 (defconst f90-procedures-re
 279   (concat "\\<"
 280           (regexp-opt
 281            '("abs" "achar" "acos" "adjustl" "adjustr" "aimag" "aint"
 282              "all" "allocated" "anint" "any" "asin" "associated"
 283              "atan" "atan2" "bit_size" "btest" "ceiling" "char" "cmplx"
 284              "conjg" "cos" "cosh" "count" "cshift" "date_and_time" "dble"
 285              "digits" "dim" "dot_product" "dprod" "eoshift" "epsilon"
 286              "exp" "exponent" "floor" "fraction" "huge" "iachar" "iand"
 287              "ibclr" "ibits" "ibset" "ichar" "ieor" "index" "int" "ior"
 288              "ishft" "ishftc" "kind" "lbound" "len" "len_trim" "lge" "lgt"
 289              "lle" "llt" "log" "log10" "logical" "matmul" "max"
 290              "maxexponent" "maxloc" "maxval" "merge" "min" "minexponent"
 291              "minloc" "minval" "mod" "modulo" "mvbits" "nearest" "nint"
 292              "not" "pack" "precision" "present" "product" "radix"
 293              ;; Real is taken out here to avoid highlighting declarations.
 294              "random_number" "random_seed" "range" ;; "real"
 295              "repeat" "reshape" "rrspacing" "scale" "scan"
 296              "selected_int_kind" "selected_real_kind" "set_exponent"
 297              "shape" "sign" "sin" "sinh" "size" "spacing" "spread" "sqrt"
 298              "sum" "system_clock" "tan" "tanh" "tiny" "transfer"
 299              "transpose" "trim" "ubound" "unpack" "verify"
 300              ;; F95 intrinsic functions.
 301              "null" "cpu_time") t)
 302           ;; A left parenthesis to avoid highlighting non-procedures.
 303           "[ \t]*(")
 304   "Regexp whose first part matches F90 intrinsic procedures.")
 305
 306 (defconst f90-operators-re
 307   (concat "\\."
 308           (regexp-opt '("and" "eq" "eqv" "false" "ge" "gt" "le" "lt" "ne"
 309                         "neqv" "not" "or" "true") t)
 310           "\\.")
 311   "Regexp matching intrinsic operators.")
 312
 313 (defconst f90-hpf-keywords-re
 314   (regexp-opt
 315    ;; Intrinsic procedures.
 316    '("all_prefix" "all_scatter" "all_suffix" "any_prefix"
 317      "any_scatter" "any_suffix" "copy_prefix" "copy_scatter"
 318      "copy_suffix" "count_prefix" "count_scatter" "count_suffix"
 319      "grade_down" "grade_up"
 320      "hpf_alignment" "hpf_distribution" "hpf_template" "iall" "iall_prefix"
 321      "iall_scatter" "iall_suffix" "iany" "iany_prefix" "iany_scatter"
 322      "iany_suffix" "ilen" "iparity" "iparity_prefix"
 323      "iparity_scatter" "iparity_suffix" "leadz" "maxval_prefix"
 324      "maxval_scatter" "maxval_suffix" "minval_prefix" "minval_scatter"
 325      "minval_suffix" "number_of_processors" "parity"
 326      "parity_prefix" "parity_scatter" "parity_suffix" "popcnt" "poppar"
 327      "processors_shape" "product_prefix" "product_scatter"
 328      "product_suffix" "sum_prefix" "sum_scatter" "sum_suffix"
 329      ;; Directives.
 330      "align" "distribute" "dynamic" "independent" "inherit" "processors"
 331      "realign" "redistribute" "template"
 332      ;; Keywords.
 333      "block" "cyclic" "extrinsic" "new" "onto" "pure" "with") 'words)
 334   "Regexp for all HPF keywords, procedures and directives.")
 335
 336 ;; Highlighting patterns.
 337
 338 (defvar f90-font-lock-keywords-1
 339   (list
 340    ;; Special highlighting of "module procedure".
 341    '("\\<\\(module[ \t]*procedure\\)\\>" (1 font-lock-keyword-face))
 342    ;; Highlight declaration of derived type.
 343 ;;;   '("\\<\\(type\\)[ \t]*\\(.*::[ \t]*\\|[ \t]+\\)\\(\\sw+\\)"
 344 ;;;     (1 font-lock-keyword-face) (3 font-lock-function-name-face))
 345    ;; Other functions and declarations.
 346    '("\\<\\(\\(?:end[ \t]*\\)?\\(program\\|module\\|function\\|\
 347 subroutine\\|type\\)\\|use\\|call\\)\\>[ \t]*\\(\\sw+\\)?"
 348      (1 font-lock-keyword-face) (3 font-lock-function-name-face nil t))
 349    "\\<\\(\\(end[ \t]*\\)?\\(interface\\|block[ \t]*data\\)\\|contains\\)\\>")
 350   "This does fairly subdued highlighting of comments and function calls.")
 351
 352 (defvar f90-font-lock-keywords-2
 353   (append
 354    f90-font-lock-keywords-1
 355    (list
 356     ;; Variable declarations (avoid the real function call).
 357     '("^[ \t0-9]*\\(real\\|integer\\|c\\(haracter\\|omplex\\)\\|\
 358 logical\\|type[ \t]*(\\sw+)\\)\\(.*::\\|[ \t]*(.*)\\)?\\([^!\n]*\\)"
 359       (1 font-lock-type-face t) (4 font-lock-variable-name-face))
 360     ;; do, if, select, where, and forall constructs.
 361     '("\\<\\(end[ \t]*\\(do\\|if\\|select\\|forall\\|where\\)\\)\\>\
 362 \\([ \t]+\\(\\sw+\\)\\)?"
 363       (1 font-lock-keyword-face) (3 font-lock-constant-face nil t))
 364     '("^[ \t0-9]*\\(\\(\\sw+\\)[ \t]*:[ \t]*\\)?\\(\\(if\\|\
 365 do\\([ \t]*while\\)?\\|select[ \t]*case\\|where\\|forall\\)\\)\\>"
 366       (2 font-lock-constant-face nil t) (3 font-lock-keyword-face))
 367     ;; Implicit declaration.
 368     '("\\<\\(implicit\\)[ \t]*\\(real\\|integer\\|c\\(haracter\\|omplex\\)\
 369 \\|logical\\|type[ \t]*(\\sw+)\\|none\\)\\>"
 370       (1 font-lock-keyword-face) (2 font-lock-type-face))
 371     '("\\<\\(namelist\\|common\\)[ \t]*\/\\(\\sw+\\)?\/"
 372       (1 font-lock-keyword-face) (2 font-lock-constant-face nil t))
 373     "\\<else\\([ \t]*if\\|where\\)?\\>"
 374     "\\<\\(then\\|continue\\|format\\|include\\|stop\\|return\\)\\>"
 375     '("\\<\\(exit\\|cycle\\)[ \t]*\\(\\sw+\\)?\\>"
 376       (1 font-lock-keyword-face) (2 font-lock-constant-face nil t))
 377     '("\\<\\(case\\)[ \t]*\\(default\\|(\\)" . 1)
 378     '("\\<\\(do\\|go *to\\)\\>[ \t]*\\([0-9]+\\)"
 379       (1 font-lock-keyword-face) (2 font-lock-constant-face))
 380     ;; line numbers (lines whose first character after number is letter)
 381     '("^[ \t]*\\([0-9]+\\)[ \t]*[a-z]+" (1 font-lock-constant-face t))))
 382   "Highlights declarations, do-loops and other constructs.")
 383
 384 (defvar f90-font-lock-keywords-3
 385   (append f90-font-lock-keywords-2
 386           (list
 387            f90-keywords-level-3-re
 388            f90-operators-re
 389            (list f90-procedures-re '(1 font-lock-keyword-face keep))
 390            "\\<real\\>"                 ; avoid overwriting real defs
 391            ))
 392   "Highlights all F90 keywords and intrinsic procedures.")
 393
 394 (defvar f90-font-lock-keywords-4
 395   (append f90-font-lock-keywords-3
 396           (list f90-hpf-keywords-re))
 397   "Highlights all F90 and HPF keywords.")
 398
 399 (defvar f90-font-lock-keywords
 400   f90-font-lock-keywords-2
 401   "*Default expressions to highlight in F90 mode.")
 402
 403
 404 (defvar f90-mode-syntax-table
 405   (let ((table (make-syntax-table)))
 406     (modify-syntax-entry ?\! "<"  table) ; begin comment
 407     (modify-syntax-entry ?\n ">"  table) ; end comment
 408     (modify-syntax-entry ?_  "w"  table) ; underscore in names
 409     (modify-syntax-entry ?\' "\"" table) ; string quote
 410     (modify-syntax-entry ?\" "\"" table) ; string quote
 411     (modify-syntax-entry ?\` "w"  table) ; for abbrevs
 412     (modify-syntax-entry ?\r " "  table) ; return is whitespace
 413     (modify-syntax-entry ?+  "."  table) ; punctuation
 414     (modify-syntax-entry ?-  "."  table)
 415     (modify-syntax-entry ?=  "."  table)
 416     (modify-syntax-entry ?*  "."  table)
 417     (modify-syntax-entry ?/  "."  table)
 418     (modify-syntax-entry ?\\ "\\" table) ; escape chars
 419     table)
 420   "Syntax table used in F90 mode.")
 421
 422 (defvar f90-mode-map
 423   (let ((map (make-sparse-keymap)))
 424     (define-key map "`"        'f90-abbrev-start)
 425     (define-key map "\C-c;"    'f90-comment-region)
 426     (define-key map "\C-\M-a"  'f90-beginning-of-subprogram)
 427     (define-key map "\C-\M-e"  'f90-end-of-subprogram)
 428     (define-key map "\C-\M-h"  'f90-mark-subprogram)
 429     (define-key map "\C-\M-q"  'f90-indent-subprogram)
 430     (define-key map "\C-j"     'f90-indent-new-line) ; LFD equals C-j
 431     (define-key map "\r"       'newline)
 432     (define-key map "\C-c\r"   'f90-break-line)
 433 ;;;  (define-key map [M-return] 'f90-break-line)
 434     (define-key map "\C-c\C-d" 'f90-join-lines)
 435     (define-key map "\C-c\C-f" 'f90-fill-region)
 436     (define-key map "\C-c\C-p" 'f90-previous-statement)
 437     (define-key map "\C-c\C-n" 'f90-next-statement)
 438     (define-key map "\C-c\C-w" 'f90-insert-end)
 439     (define-key map "\t"       'f90-indent-line)
 440     (define-key map ","        'f90-electric-insert)
 441     (define-key map "+"        'f90-electric-insert)
 442     (define-key map "-"        'f90-electric-insert)
 443     (define-key map "*"        'f90-electric-insert)
 444     (define-key map "/"        'f90-electric-insert)
 445     map)
 446   "Keymap used in F90 mode.")
 447
 448 ;; Menu bar support.
 449 (if f90-xemacs-flag
 450     (defvar f90-xemacs-menu
 451       '("F90"
 452         ["Indent Subprogram"       f90-indent-subprogram t]
 453         ["Mark Subprogram"         f90-mark-subprogram t]
 454         ["Beginning of Subprogram" f90-beginning-of-subprogram t]
 455         ["End of Subprogram"       f90-end-of-subprogram t]
 456         "-----"
 457         ["(Un)Comment Region"      f90-comment-region t]
 458         ["Indent Region"           indent-region t]
 459         ["Fill Region"             f90-fill-region t]
 460         "-----"
 461         ["Break Line at Point"     f90-break-line t]
 462         ["Join with Next Line"     f90-join-lines t]
 463         ["Insert Newline"          newline t]
 464         ["Insert Block End"        f90-insert-end t]
 465         "-----"
 466         ["Upcase Keywords (buffer)"      f90-upcase-keywords t]
 467         ["Upcase Keywords (region)"      f90-upcase-region-keywords t]
 468         ["Capitalize Keywords (buffer)"  f90-capitalize-keywords t]
 469         ["Capitalize Keywords (region)"  f90-capitalize-region-keywords t]
 470         ["Downcase Keywords (buffer)"    f90-downcase-keywords t]
 471         ["Downcase Keywords (region)"    f90-downcase-region-keywords t]
 472         "-----"
 473         ["Toggle abbrev-mode"   abbrev-mode t]
 474         ["Toggle auto-fill"     auto-fill-mode t])
 475       "XEmacs menu for F90 mode.")
 476
 477   ;; Emacs.
 478   (defvar f90-menu-bar-menu
 479     (let ((map (make-sparse-keymap "F90")))
 480       (define-key map [f90-imenu-menu]
 481         '("Add imenu Menu" . f90-add-imenu-menu))
 482       (define-key map [abbrev-mode]
 483         '("Toggle abbrev-mode" . abbrev-mode))
 484       (define-key map [auto-fill-mode]
 485         '("Toggle auto-fill" . auto-fill-mode))
 486       (define-key map [line1] '("--"))
 487       (define-key map [f90-change-case-menu]
 488         '("Change Keyword Case" . f90-change-case-menu))
 489       (define-key map [f90-font-lock-menu]
 490         '("Highlighting" . f90-font-lock-menu))
 491       (define-key map [line2] '("--"))
 492       (define-key map [f90-insert-end]
 493         '("Insert Block End" . f90-insert-end))
 494       (define-key map [f90-join-lines]
 495         '("Join with Next Line" . f90-join-lines))
 496       (define-key map [f90-break-line]
 497         '("Break Line at Point" . f90-break-line))
 498       (define-key map [line3] '("--"))
 499       (define-key map [f90-fill-region]
 500         '("Fill Region" . f90-fill-region))
 501       (put 'f90-fill-region 'menu-enable 'mark-active)
 502       (define-key map [indent-region]
 503         '("Indent Region" . indent-region))
 504       (define-key map [f90-comment-region]
 505         '("(Un)Comment Region" . f90-comment-region))
 506       (put 'f90-comment-region 'menu-enable 'mark-active)
 507       (define-key map [line4] '("--"))
 508       (define-key map [f90-end-of-subprogram]
 509         '("End of Subprogram" . f90-end-of-subprogram))
 510       (define-key map [f90-beginning-of-subprogram]
 511         '("Beginning of Subprogram" . f90-beginning-of-subprogram))
 512       (define-key map [f90-mark-subprogram]
 513         '("Mark Subprogram" . f90-mark-subprogram))
 514       (define-key map [f90-indent-subprogram]
 515         '("Indent Subprogram" . f90-indent-subprogram))
 516       map)
 517     "F90 mode top-level menu bar menu.")
 518
 519   (define-key f90-mode-map [menu-bar f90-menu]
 520     (cons "F90" f90-menu-bar-menu))
 521
 522   (defvar f90-change-case-menu
 523     (let ((map (make-sparse-keymap "Change Keyword Case")))
 524       (define-key map [dkr]
 525         '("Downcase Keywords (region)" . f90-downcase-region-keywords))
 526       (put 'f90-downcase-region-keywords 'menu-enable 'mark-active)
 527       (define-key map [ckr]
 528         '("Capitalize Keywords (region)" . f90-capitalize-region-keywords))
 529       (put 'f90-capitalize-region-keywords 'menu-enable 'mark-active)
 530       (define-key map [ukr]
 531         '("Upcase Keywords (region)" . f90-upcase-region-keywords))
 532       (put 'f90-upcase-region-keywords 'menu-enable 'mark-active)
 533       (define-key map [line] '("--"))
 534       (define-key map [dkb]
 535         '("Downcase Keywords (buffer)" . f90-downcase-keywords))
 536       (define-key map [ckb]
 537         '("Capitalize Keywords (buffer)" . f90-capitalize-keywords))
 538       (define-key map [ukb]
 539         '("Upcase Keywords (buffer)" . f90-upcase-keywords))
 540       map)
 541     "Submenu for change of case.")
 542
 543   (defalias 'f90-change-case-menu f90-change-case-menu)
 544
 545   ;; Font-lock-menu and function calls.
 546   (defalias 'f90-font-lock-on 'font-lock-mode)
 547   (put 'f90-font-lock-on 'menu-enable 'font-lock-mode)
 548   (put 'f90-font-lock-on 'menu-alias t)
 549
 550   (defalias 'f90-font-lock-off 'font-lock-mode)
 551   (put 'f90-font-lock-off 'menu-enable '(not font-lock-mode))
 552   (put 'f90-font-lock-off 'menu-alias t)
 553
 554   (defun f90-font-lock-1 ()
 555     "Set `font-lock-keywords' to `f90-font-lock-keywords-1'."
 556     (interactive)
 557     (font-lock-mode 1)
 558     (setq font-lock-keywords f90-font-lock-keywords-1)
 559     (font-lock-fontify-buffer))
 560
 561   (defun f90-font-lock-2 ()
 562     "Set `font-lock-keywords' to `f90-font-lock-keywords-2'."
 563     (interactive)
 564     (font-lock-mode 1)
 565     (setq font-lock-keywords f90-font-lock-keywords-2)
 566     (font-lock-fontify-buffer))
 567
 568   (defun f90-font-lock-3 ()
 569     "Set `font-lock-keywords' to `f90-font-lock-keywords-3'."
 570     (interactive)
 571     (font-lock-mode 1)
 572     (setq font-lock-keywords f90-font-lock-keywords-3)
 573     (font-lock-fontify-buffer))
 574
 575   (defun f90-font-lock-4 ()
 576     "Set `font-lock-keywords' to `f90-font-lock-keywords-4'."
 577     (interactive)
 578     (font-lock-mode 1)
 579     (setq font-lock-keywords f90-font-lock-keywords-4)
 580     (font-lock-fontify-buffer))
 581
 582   (defvar f90-font-lock-menu
 583     (let ((map (make-sparse-keymap "f90-font-lock-menu")))
 584       (define-key map [h4]
 585         '("Maximum highlighting (level 4)" . f90-font-lock-4))
 586       (define-key map [h3]
 587         '("Heavy highlighting (level 3)" . f90-font-lock-3))
 588       (define-key map [h2]
 589         '("Default highlighting (level 2)" . f90-font-lock-2))
 590       (define-key map [h1]
 591         '("Light highlighting (level 1)" . f90-font-lock-1))
 592       (define-key map [line] '("--"))
 593       (define-key map [floff]
 594         '("Turn off font-lock-mode" . f90-font-lock-on))
 595       (define-key map [flon]
 596         '("Turn on font-lock-mode" . f90-font-lock-off))
 597       map)
 598     "Submenu for highlighting using font-lock-mode.")
 599
 600   (defalias 'f90-font-lock-menu f90-font-lock-menu)
 601
 602   )
 603
 604 ;; Regexps for finding program structures.
 605 (defconst f90-blocks-re
 606   (concat "\\(block[ \t]*data\\|"
 607           (regexp-opt '("do" "if" "interface" "function" "module" "program"
 608                         "select" "subroutine" "type" "where" "forall"))
 609           "\\)\\>")
 610   "Regexp potentially indicating a \"block\" of F90 code.")
 611
 612 (defconst f90-program-block-re
 613   (regexp-opt '("program" "module" "subroutine" "function") 'paren)
 614   "Regexp used to locate the start/end of a \"subprogram\".")
 615
 616 (defconst f90-else-like-re
 617   "\\(else\\([ \t]*if\\|where\\)?\\|case[ \t]*\\(default\\|(\\)\\)"
 618   "Regexp matching an ELSE IF, ELSEWHERE, CASE statement.")
 619
 620 (defconst f90-end-if-re
 621   (concat "end[ \t]*"
 622           (regexp-opt '("if" "select" "where" "forall") 'paren)
 623           "\\>")
 624   "Regexp matching the end of an IF, SELECT, WHERE, FORALL block.")
 625
 626 (defconst f90-end-type-re
 627   "end[ \t]*\\(type\\|interface\\|block[ \t]*data\\)\\>"
 628   "Regexp matching the end of a TYPE, INTERFACE, BLOCK DATA section.")
 629
 630 (defconst f90-type-def-re
 631   "\\<\\(type\\)\\([^(\n]*\\)\\(::\\)?[ \t]*\\b\\(\\sw+\\)"
 632   "Regexp matching the declaration of a variable of derived type.")
 633
 634 (defconst f90-no-break-re
 635   (regexp-opt '("**" "//" "=>") 'paren)
 636   "Regexp specifying where not to break lines when filling.")
 637
 638 (defvar f90-cache-position nil
 639   "Temporary position used to speed up region operations.")
 640 (make-variable-buffer-local 'f90-cache-position)
 641
 642 (defvar f90-imenu-flag nil
 643   "Non-nil means this buffer already has an imenu.")
 644 (make-variable-buffer-local 'f90-imenu-flag)
 645
 646 \f
 647 ;; Imenu support.
 648 (defvar f90-imenu-generic-expression
 649   (let ((good-char "[^!\"\&\n \t]") (not-e "[^e!\n\"\& \t]")
 650         (not-n "[^n!\n\"\& \t]") (not-d "[^d!\n\"\& \t]"))
 651     (list
 652      '(nil "^[ \t0-9]*program[ \t]+\\(\\sw+\\)" 1)
 653      '("Modules" "^[ \t0-9]*module[ \t]+\\(\\sw+\\)[ \t]*\\(!\\|$\\)" 1)
 654      '("Types" "^[ \t0-9]*type[ \t]+\\(\\sw+\\)" 1)
 655      (list
 656       "Procedures"
 657       (concat
 658        "^[ \t0-9]*"
 659        "\\("
 660        ;; At least three non-space characters before function/subroutine.
 661        ;; Check that the last three non-space characters do not spell E N D.
 662        "[^!\"\&\n]*\\("
 663        not-e good-char good-char "\\|"
 664        good-char not-n good-char "\\|"
 665        good-char good-char not-d "\\)"
 666        "\\|"
 667        ;; Less than three non-space characters before function/subroutine.
 668        good-char "?" good-char "?"
 669        "\\)"
 670        "[ \t]*\\(function\\|subroutine\\)[ \t]+\\(\\sw+\\)")
 671       4)))
 672   "Generic imenu expression for F90 mode.")
 673
 674 (defun f90-add-imenu-menu ()
 675   "Add an imenu menu to the menubar."
 676   (interactive)
 677   (if f90-imenu-flag
 678       (message "%s" "F90-imenu already exists.")
 679     (imenu-add-to-menubar "F90-imenu")
 680     (redraw-frame (selected-frame))
 681     (setq f90-imenu-flag t)))
 682
 683 (put 'f90-add-imenu-menu 'menu-enable '(not f90-imenu-flag))
 684
 685
 686 ;; When compiling under GNU Emacs, load imenu during compilation.
 687 ;; If you have 19.22 or earlier, comment this out, or get imenu.
 688 (or f90-xemacs-flag (eval-when-compile (require 'imenu)))
 689
 690 \f
 691 ;; Abbrevs have generally two letters, except standard types `c, `i, `r, `t.
 692 (defvar f90-mode-abbrev-table
 693   (let (abbrevs-changed)
 694     (define-abbrev-table 'f90-mode-abbrev-table
 695       '(("`al"  "allocate"      nil 0 t)
 696         ("`ab"  "allocatable"   nil 0 t)
 697         ("`as"  "assignment"    nil 0 t)
 698         ("`ba"  "backspace"     nil 0 t)
 699         ("`bd"  "block data"    nil 0 t)
 700         ("`c"   "character"     nil 0 t)
 701         ("`cl"  "close"         nil 0 t)
 702         ("`cm"  "common"        nil 0 t)
 703         ("`cx"  "complex"       nil 0 t)
 704         ("`cn"  "contains"      nil 0 t)
 705         ("`cy"  "cycle"         nil 0 t)
 706         ("`de"  "deallocate"    nil 0 t)
 707         ("`df"  "define"        nil 0 t)
 708         ("`di"  "dimension"     nil 0 t)
 709         ("`dw"  "do while"      nil 0 t)
 710         ("`el"  "else"          nil 0 t)
 711         ("`eli" "else if"       nil 0 t)
 712         ("`elw" "elsewhere"     nil 0 t)
 713         ("`eq"  "equivalence"   nil 0 t)
 714         ("`ex"  "external"      nil 0 t)
 715         ("`ey"  "entry"         nil 0 t)
 716         ("`fl"  "forall"        nil 0 t)
 717         ("`fo"  "format"        nil 0 t)
 718         ("`fu"  "function"      nil 0 t)
 719         ("`fa"  ".false."       nil 0 t)
 720         ("`im"  "implicit none" nil 0 t)
 721         ("`in " "include"       nil 0 t)
 722         ("`i"   "integer"       nil 0 t)
 723         ("`it"  "intent"        nil 0 t)
 724         ("`if"  "interface"     nil 0 t)
 725         ("`lo"  "logical"       nil 0 t)
 726         ("`mo"  "module"        nil 0 t)
 727         ("`na"  "namelist"      nil 0 t)
 728         ("`nu"  "nullify"       nil 0 t)
 729         ("`op"  "optional"      nil 0 t)
 730         ("`pa"  "parameter"     nil 0 t)
 731         ("`po"  "pointer"       nil 0 t)
 732         ("`pr"  "print"         nil 0 t)
 733         ("`pi"  "private"       nil 0 t)
 734         ("`pm"  "program"       nil 0 t)
 735         ("`pu"  "public"        nil 0 t)
 736         ("`r"   "real"          nil 0 t)
 737         ("`rc"  "recursive"     nil 0 t)
 738         ("`rt"  "return"        nil 0 t)
 739         ("`rw"  "rewind"        nil 0 t)
 740         ("`se"  "select"        nil 0 t)
 741         ("`sq"  "sequence"      nil 0 t)
 742         ("`su"  "subroutine"    nil 0 t)
 743         ("`ta"  "target"        nil 0 t)
 744         ("`tr"  ".true."        nil 0 t)
 745         ("`t"   "type"          nil 0 t)
 746         ("`wh"  "where"         nil 0 t)
 747         ("`wr"  "write"         nil 0 t)))
 748     f90-mode-abbrev-table)
 749   "Abbrev table for F90 mode.")
 750 \f
 751 (defcustom f90-mode-hook nil
 752   "Hook run when entering F90 mode."
 753   :type 'hook
 754   :options '(f90-add-imenu-menu)
 755   :group 'f90)
 756
 757 ;;;###autoload
 758 (defun f90-mode ()
 759   "Major mode for editing Fortran 90,95 code in free format.
 760
 761 \\[f90-indent-new-line] indents current line and creates a new\
 762  indented line.
 763 \\[f90-indent-line] indents the current line.
 764 \\[f90-indent-subprogram] indents the current subprogram.
 765
 766 Type `? or `\\[help-command] to display a list of built-in\
 767  abbrevs for F90 keywords.
 768
 769 Key definitions:
 770 \\{f90-mode-map}
 771
 772 Variables controlling indentation style and extra features:
 773
 774 `f90-do-indent'
 775   Extra indentation within do blocks (default 3).
 776 `f90-if-indent'
 777   Extra indentation within if/select case/where/forall blocks (default 3).
 778 `f90-type-indent'
 779   Extra indentation within type/interface/block-data blocks (default 3).
 780 `f90-program-indent'
 781   Extra indentation within program/module/subroutine/function blocks
 782   (default 2).
 783 `f90-continuation-indent'
 784   Extra indentation applied to continuation lines (default 5).
 785 `f90-comment-region'
 786   String inserted by function \\[f90-comment-region] at start of each
 787   line in region (default \"!!!$\").
 788 `f90-indented-comment-re'
 789   Regexp determining the type of comment to be intended like code
 790   (default \"!\").
 791 `f90-directive-comment-re'
 792   Regexp of comment-like directive like \"!HPF\\\\$\", not to be indented
 793   (default \"!hpf\\\\$\").
 794 `f90-break-delimiters'
 795   Regexp holding list of delimiters at which lines may be broken
 796   (default \"[-+*/><=,% \\t]\").
 797 `f90-break-before-delimiters'
 798   Non-nil causes `f90-do-auto-fill' to break lines before delimiters
 799   (default t).
 800 `f90-beginning-ampersand'
 801   Automatic insertion of \& at beginning of continuation lines (default t).
 802 `f90-smart-end'
 803   From an END statement, check and fill the end using matching block start.
 804   Allowed values are 'blink, 'no-blink, and nil, which determine
 805   whether to blink the matching beginning (default 'blink).
 806 `f90-auto-keyword-case'
 807   Automatic change of case of keywords (default nil).
 808   The possibilities are 'downcase-word, 'upcase-word, 'capitalize-word.
 809 `f90-leave-line-no'
 810   Do not left-justify line numbers (default nil).
 811 `f90-keywords-re'
 812   List of keywords used for highlighting/upcase-keywords etc.
 813
 814 Turning on F90 mode calls the value of the variable `f90-mode-hook'
 815 with no args, if that value is non-nil."
 816   (interactive)
 817   (kill-all-local-variables)
 818   (setq major-mode 'f90-mode
 819         mode-name "F90"
 820         local-abbrev-table f90-mode-abbrev-table)
 821   (set-syntax-table f90-mode-syntax-table)
 822   (use-local-map f90-mode-map)
 823   (set (make-local-variable 'indent-line-function) 'f90-indent-line)
 824   (set (make-local-variable 'indent-region-function) 'f90-indent-region)
 825   (set (make-local-variable 'require-final-newline) t)
 826   (set (make-local-variable 'comment-start) "!")
 827   (set (make-local-variable 'comment-start-skip) "!+ *")
 828   (set (make-local-variable 'comment-indent-function) 'f90-comment-indent)
 829   (set (make-local-variable 'abbrev-all-caps) t)
 830   (set (make-local-variable 'normal-auto-fill-function) 'f90-do-auto-fill)
 831   (setq indent-tabs-mode nil)           ; auto buffer local
 832   ;; Setting up things for font-lock.
 833   (when f90-xemacs-flag
 834     (put 'f90-mode 'font-lock-keywords-case-fold-search t)
 835     (when (and (featurep 'menubar)
 836                current-menubar
 837                (not (assoc "F90" current-menubar)))
 838       (set-buffer-menubar (copy-sequence current-menubar))
 839       (add-submenu nil f90-xemacs-menu)))
 840   ;; XEmacs: Does not need a special case, since both emacsen work alike -sb.
 841   (set (make-local-variable 'font-lock-defaults)
 842        '((f90-font-lock-keywords f90-font-lock-keywords-1
 843                                  f90-font-lock-keywords-2
 844                                  f90-font-lock-keywords-3
 845                                  f90-font-lock-keywords-4)
 846          nil t))
 847   ;; Tell imenu how to handle f90.
 848   (set (make-local-variable 'imenu-case-fold-search) t)
 849   (set (make-local-variable 'imenu-generic-expression)
 850         f90-imenu-generic-expression)
 851   (set (make-local-variable 'add-log-current-defun-function)
 852        #'f90-current-defun)
 853   (run-hooks 'f90-mode-hook))
 854
 855 \f
 856 ;; Inline-functions.
 857 (defsubst f90-in-string ()
 858   "Return non-nil if point is inside a string.
 859 Checks from `point-min', or `f90-cache-position', if that is non-nil
 860 and lies before point."
 861   (let ((beg-pnt
 862          (if (and f90-cache-position (> (point) f90-cache-position))
 863              f90-cache-position
 864            (point-min))))
 865     (nth 3 (parse-partial-sexp beg-pnt (point)))))
 866
 867 (defsubst f90-in-comment ()
 868   "Return non-nil if point is inside a comment.
 869 Checks from `point-min', or `f90-cache-position', if that is non-nil
 870 and lies before point."
 871   (let ((beg-pnt
 872          (if (and f90-cache-position (> (point) f90-cache-position))
 873              f90-cache-position
 874            (point-min))))
 875     (nth 4 (parse-partial-sexp beg-pnt (point)))))
 876
 877 (defsubst f90-line-continued ()
 878   "Return t if the current line is a continued one.
 879 This includes comment lines embedded in continued lines, but
 880 not the last line of a continued statement."
 881   (save-excursion
 882     (beginning-of-line)
 883     (while (and (looking-at "[ \t]*\\(!\\|$\\)") (zerop (forward-line -1))))
 884     (end-of-line)
 885     (while (f90-in-comment)
 886       (search-backward "!" (line-beginning-position))
 887       (skip-chars-backward "!"))
 888     (skip-chars-backward " \t")
 889     (= (preceding-char) ?&)))
 890
 891 (defsubst f90-current-indentation ()
 892   "Return indentation of current line.
 893 Line-numbers are considered whitespace characters."
 894   (save-excursion (beginning-of-line) (skip-chars-forward " \t0-9")))
 895
 896 (defsubst f90-indent-to (col &optional no-line-number)
 897   "Indent current line to column COL.
 898 If optional argument NO-LINE-NUMBER is nil, jump over a possible
 899 line-number before indenting."
 900   (beginning-of-line)
 901   (if (not no-line-number)
 902       (skip-chars-forward " \t0-9"))
 903   (delete-horizontal-space)
 904   (if (zerop (current-column))
 905       (indent-to col)
 906     (indent-to col 1)))                 ; leave >= 1 space after line number
 907
 908 (defsubst f90-get-present-comment-type ()
 909   "If point lies within a comment, return the string starting the comment.
 910 For example, \"!\" or \"!!\"."
 911   (save-excursion
 912     (when (f90-in-comment)
 913       (beginning-of-line)
 914       (re-search-forward "[!]+" (line-end-position))
 915       (while (f90-in-string)
 916         (re-search-forward "[!]+" (line-end-position))
 917         (match-string 0)))))
 918
 919 (defsubst f90-equal-symbols (a b)
 920   "Compare strings A and B neglecting case and allowing for nil value."
 921   (let ((a-local (if a (downcase a) nil))
 922         (b-local (if b (downcase b) nil)))
 923     (equal a-local b-local)))
 924
 925 ;; XEmacs 19.11 & 19.12 return a single char when matching an empty regexp.
 926 ;; The next 2 functions are therefore longer than necessary.
 927 (defsubst f90-looking-at-do ()
 928   "Return (\"do\" NAME) if a do statement starts after point.
 929 NAME is nil if the statement has no label."
 930   (if (looking-at "\\(\\(\\sw+\\)[ \t]*\:\\)?[ \t]*\\(do\\)\\>")
 931       (let (label
 932             (struct (match-string 3)))
 933         (if (looking-at "\\(\\sw+\\)[ \t]*\:")
 934             (setq label (match-string 1)))
 935         (list struct label))))
 936
 937 (defsubst f90-looking-at-select-case ()
 938   "Return (\"select\" NAME) if a select-case statement starts after point.
 939 NAME is nil if the statement has no label."
 940   (if (looking-at "\\(\\(\\sw+\\)[ \t]*\:\\)?[ \t]*\
 941 \\(select\\)[ \t]*case[ \t]*(")
 942       (let (label
 943             (struct (match-string 3)))
 944         (if (looking-at "\\(\\sw+\\)[ \t]*\:")
 945             (setq label (match-string 1)))
 946         (list struct label))))
 947
 948 (defsubst f90-looking-at-if-then ()
 949   "Return (\"if\" NAME) if an if () then statement starts after point.
 950 NAME is nil if the statement has no label."
 951   (save-excursion
 952     (when (looking-at "\\(\\(\\sw+\\)[ \t]*\:\\)?[ \t]*\\(if\\)\\>")
 953       (let (label
 954             (struct (match-string 3)))
 955         (if (looking-at "\\(\\sw+\\)[ \t]*\:")
 956             (setq label (match-string 1)))
 957         (let ((pos (scan-lists (point) 1 0)))
 958           (and pos (goto-char pos)))
 959         (skip-chars-forward " \t")
 960         (if (or (looking-at "then\\>")
 961                 (when (f90-line-continued)
 962                   (f90-next-statement)
 963                   (skip-chars-forward " \t0-9&")
 964                   (looking-at "then\\>")))
 965             (list struct label))))))
 966
 967 (defsubst f90-looking-at-where-or-forall ()
 968   "Return (KIND NAME) if a where or forall block starts after point.
 969 NAME is nil if the statement has no label."
 970   (if (looking-at "\\(\\(\\sw+\\)[ \t]*\:\\)?[ \t]*\
 971 \\(where\\|forall\\)[ \t]*(.*)[ \t]*\\(!\\|$\\)")
 972       (let (label
 973             (struct (match-string 3)))
 974         (if (looking-at "\\(\\sw+\\)[ \t]*\:")
 975             (setq label (match-string 1)))
 976         (list struct label))))
 977
 978 (defsubst f90-looking-at-type-like ()
 979   "Return (KIND NAME) if a type/interface/block-data block starts after point.
 980 NAME is non-nil only for type."
 981   (cond
 982    ((looking-at f90-type-def-re)
 983     (list (match-string 1) (match-string 4)))
 984    ((looking-at "\\(interface\\|block[\t]*data\\)\\>")
 985     (list (match-string 1) nil))))
 986
 987 (defsubst f90-looking-at-program-block-start ()
 988   "Return (KIND NAME) if a program block with name NAME starts after point."
 989   (cond
 990    ((looking-at "\\(program\\)[ \t]+\\(\\sw+\\)\\>")
 991     (list (match-string 1) (match-string 2)))
 992    ((and (not (looking-at "module[ \t]*procedure\\>"))
 993          (looking-at "\\(module\\)[ \t]+\\(\\sw+\\)\\>"))
 994     (list (match-string 1) (match-string 2)))
 995    ((and (not (looking-at "end[ \t]*\\(function\\|subroutine\\)"))
 996          (looking-at "[^!'\"\&\n]*\\(function\\|subroutine\\)\
 997 [ \t]+\\(\\sw+\\)"))
 998     (list (match-string 1) (match-string 2)))))
 999
1000 (defsubst f90-looking-at-program-block-end ()
1001   "Return (KIND NAME) if a block with name NAME ends after point."
1002   (if (looking-at (concat "end[ \t]*" f90-blocks-re
1003                           "?\\([ \t]+\\(\\sw+\\)\\)?\\>"))
1004       (list (match-string 1) (match-string 3))))
1005
1006 (defsubst f90-comment-indent ()
1007   "Return the indentation to be used for a comment starting at point.
1008 Used for `comment-indent-function' by F90 mode.
1009 \"!!!\", `f90-directive-comment-re', variable `f90-comment-region' return 0.
1010 `f90-indented-comment-re' (if not trailing code) calls `f90-calculate-indent'.
1011 Any other type return `comment-column', leaving at least one space after code."
1012   (cond ((looking-at "!!!") 0)
1013         ((and f90-directive-comment-re
1014               (looking-at f90-directive-comment-re)) 0)
1015         ((looking-at (regexp-quote f90-comment-region)) 0)
1016         ((and (looking-at f90-indented-comment-re)
1017               ;; Don't attempt to indent trailing comment as code.
1018               (save-excursion
1019                 (skip-chars-backward " \t")
1020                 (bolp)))
1021          (f90-calculate-indent))
1022         (t (skip-chars-backward " \t")
1023            (max (if (bolp) 0 (1+ (current-column))) comment-column))))
1024
1025 (defsubst f90-present-statement-cont ()
1026   "Return continuation properties of present statement.
1027 Possible return values are:
1028 single - statement is not continued.
1029 begin  - current line is the first in a continued statement.
1030 end    - current line is the last in a continued statement
1031 middle - current line is neither first nor last in a continued statement.
1032 Comment lines embedded amongst continued lines return 'middle."
1033   (let (pcont cont)
1034     (save-excursion
1035       (setq pcont (if (f90-previous-statement) (f90-line-continued))))
1036     (setq cont (f90-line-continued))
1037     (cond ((and (not pcont) (not cont)) 'single)
1038           ((and (not pcont) cont)       'begin)
1039           ((and pcont       (not cont)) 'end)
1040           ((and pcont       cont)       'middle)
1041           (t (error "The impossible occurred")))))
1042
1043 (defsubst f90-indent-line-no ()
1044   "If `f90-leave-line-no' is nil, left-justify a line number.
1045 Leaves point at the first non-blank character after the line number.
1046 Call from beginning of line."
1047   (if (and (null f90-leave-line-no) (looking-at "[ \t]+[0-9]"))
1048       (delete-horizontal-space))
1049   (skip-chars-forward " \t0-9"))
1050
1051 (defsubst f90-no-block-limit ()
1052   "Return nil if point is at the edge of a code block.
1053 Searches line forward for \"function\" or \"subroutine\",
1054 if all else fails."
1055   (let ((eol (line-end-position)))
1056     (save-excursion
1057       (not (or (looking-at "end")
1058                (looking-at "\\(do\\|if\\|else\\(if\\|where\\)?\
1059 \\|select[ \t]*case\\|case\\|where\\|forall\\)\\>")
1060                (looking-at "\\(program\\|module\\|interface\\|\
1061 block[ \t]*data\\)\\>")
1062                (looking-at "\\(contains\\|\\sw+[ \t]*:\\)")
1063                (looking-at f90-type-def-re)
1064                (re-search-forward "\\(function\\|subroutine\\)" eol t))))))
1065
1066 (defsubst f90-update-line ()
1067   "Change case of current line as per `f90-auto-keyword-case'."
1068   (if f90-auto-keyword-case
1069       (f90-change-keywords f90-auto-keyword-case
1070                            (line-beginning-position) (line-end-position))))
1071 \f
1072 (defun f90-electric-insert ()
1073   "Change keyword case and auto-fill line as operators are inserted."
1074   (interactive)
1075   (self-insert-command 1)
1076   (if auto-fill-function (f90-do-auto-fill) ; also updates line
1077     (f90-update-line)))
1078
1079
1080 (defun f90-get-correct-indent ()
1081   "Get correct indent for a line starting with line number.
1082 Does not check type and subprogram indentation."
1083   (let ((epnt (line-end-position)) icol cont)
1084     (save-excursion
1085       (while (and (f90-previous-statement)
1086                   (or (progn
1087                         (setq cont (f90-present-statement-cont))
1088                         (or (eq cont 'end) (eq cont 'middle)))
1089                       (looking-at "[ \t]*[0-9]"))))
1090       (setq icol (current-indentation))
1091       (beginning-of-line)
1092       (when (re-search-forward "\\(if\\|do\\|select\\|where\\|forall\\)"
1093                                (line-end-position) t)
1094         (beginning-of-line)
1095         (skip-chars-forward " \t")
1096         (cond ((f90-looking-at-do)
1097                (setq icol (+ icol f90-do-indent)))
1098               ((or (f90-looking-at-if-then)
1099                    (f90-looking-at-where-or-forall)
1100                    (f90-looking-at-select-case))
1101                (setq icol (+ icol f90-if-indent))))
1102         (end-of-line))
1103       (while (re-search-forward
1104               "\\(if\\|do\\|select\\|where\\|forall\\)" epnt t)
1105         (beginning-of-line)
1106         (skip-chars-forward " \t0-9")
1107         (cond ((f90-looking-at-do)
1108                (setq icol (+ icol f90-do-indent)))
1109               ((or (f90-looking-at-if-then)
1110                    (f90-looking-at-where-or-forall)
1111                    (f90-looking-at-select-case))
1112                (setq icol (+ icol f90-if-indent)))
1113               ((looking-at f90-end-if-re)
1114                (setq icol (- icol f90-if-indent)))
1115               ((looking-at "end[ \t]*do\\>")
1116                (setq icol (- icol f90-do-indent))))
1117         (end-of-line))
1118       icol)))
1119
1120 (defun f90-calculate-indent ()
1121   "Calculate the indent column based on previous statements."
1122   (interactive)
1123   (let (icol cont (case-fold-search t) (pnt (point)))
1124     (save-excursion
1125       (if (not (f90-previous-statement))
1126           (setq icol 0)
1127         (setq cont (f90-present-statement-cont))
1128         (if (eq cont 'end)
1129             (while (not (eq 'begin (f90-present-statement-cont)))
1130               (f90-previous-statement)))
1131         (cond ((eq cont 'begin)
1132                (setq icol (+ (f90-current-indentation)
1133                              f90-continuation-indent)))
1134               ((eq cont 'middle) (setq icol (current-indentation)))
1135               (t (setq icol (f90-current-indentation))
1136                  (skip-chars-forward " \t")
1137                  (if (looking-at "[0-9]")
1138                      (setq icol (f90-get-correct-indent))
1139                    (cond ((or (f90-looking-at-if-then)
1140                               (f90-looking-at-where-or-forall)
1141                               (f90-looking-at-select-case)
1142                               (looking-at f90-else-like-re))
1143                           (setq icol (+ icol f90-if-indent)))
1144                          ((f90-looking-at-do)
1145                           (setq icol (+ icol f90-do-indent)))
1146                          ((f90-looking-at-type-like)
1147                           (setq icol (+ icol f90-type-indent)))
1148                          ((or (f90-looking-at-program-block-start)
1149                               (looking-at "contains[ \t]*\\($\\|!\\)"))
1150                           (setq icol (+ icol f90-program-indent)))))
1151                  (goto-char pnt)
1152                  (beginning-of-line)
1153                  (cond ((looking-at "[ \t]*$"))
1154                        ((looking-at "[ \t]*#") ; check for cpp directive
1155                         (setq icol 0))
1156                        (t
1157                         (skip-chars-forward " \t0-9")
1158                         (cond ((or (looking-at f90-else-like-re)
1159                                    (looking-at f90-end-if-re))
1160                                (setq icol (- icol f90-if-indent)))
1161                               ((looking-at "end[ \t]*do\\>")
1162                                (setq icol (- icol f90-do-indent)))
1163                               ((looking-at f90-end-type-re)
1164                                (setq icol (- icol f90-type-indent)))
1165                               ((or (looking-at "contains[ \t]*\\(!\\|$\\)")
1166                                    (f90-looking-at-program-block-end))
1167                                (setq icol (- icol f90-program-indent))))))
1168                  ))))
1169     icol))
1170 \f
1171 (defun f90-previous-statement ()
1172   "Move point to beginning of the previous F90 statement.
1173 Return nil if no previous statement is found.
1174 A statement is a line which is neither blank nor a comment."
1175   (interactive)
1176   (let (not-first-statement)
1177     (beginning-of-line)
1178     (while (and (setq not-first-statement (zerop (forward-line -1)))
1179                 (looking-at "[ \t0-9]*\\(!\\|$\\|#\\)")))
1180     not-first-statement))
1181
1182 (defun f90-next-statement ()
1183   "Move point to beginning of the next F90 statement.
1184 Return nil if no later statement is found."
1185   (interactive)
1186   (let (not-last-statement)
1187     (beginning-of-line)
1188     (while (and (setq not-last-statement
1189                       (and (zerop (forward-line 1))
1190                            (not (eobp))))
1191                 (looking-at "[ \t0-9]*\\(!\\|$\\)")))
1192     not-last-statement))
1193
1194 (defun f90-beginning-of-subprogram ()
1195   "Move point to the beginning of subprogram.
1196 Return (TYPE NAME), or nil if not found."
1197   (interactive)
1198   (let ((count 1) (case-fold-search t) matching-beg)
1199     (beginning-of-line)
1200     (skip-chars-forward " \t0-9")
1201     (if (setq matching-beg (f90-looking-at-program-block-start))
1202         (setq count (1- count)))
1203     (while (and (not (zerop count))
1204                 (re-search-backward f90-program-block-re nil 'move))
1205       (beginning-of-line)
1206       (skip-chars-forward " \t0-9")
1207       (cond ((setq matching-beg (f90-looking-at-program-block-start))
1208              (setq count (1- count)))
1209             ((f90-looking-at-program-block-end)
1210              (setq count (1+ count)))))
1211     (beginning-of-line)
1212     (if (zerop count)
1213         matching-beg
1214       (message "No beginning found.")
1215       nil)))
1216
1217 (defun f90-end-of-subprogram ()
1218   "Move point to the end of subprogram.
1219 Return (TYPE NAME), or nil if not found."
1220   (interactive)
1221   (let ((count 1) (case-fold-search t) matching-end)
1222     (beginning-of-line)
1223     (skip-chars-forward " \t0-9")
1224     (if (setq matching-end (f90-looking-at-program-block-end))
1225         (setq count (1- count)))
1226     (end-of-line)
1227     (while (and (not (zerop count))
1228                 (re-search-forward f90-program-block-re nil 'move))
1229       (beginning-of-line)
1230       (skip-chars-forward " \t0-9")
1231       (cond ((f90-looking-at-program-block-start)
1232              (setq count (1+ count)))
1233             ((setq matching-end (f90-looking-at-program-block-end))
1234              (setq count (1- count))))
1235       (end-of-line))
1236     (forward-line 1)
1237     (if (zerop count)
1238         matching-end
1239       (message "No end found.")
1240       nil)))
1241
1242 (defvar f90-mark-subprogram-overlay nil
1243   "Used internally by `f90-mark-subprogram' to highlight the subprogram.")
1244 (make-variable-buffer-local 'f90-mark-subprogram-overlay)
1245
1246 (defun f90-mark-subprogram ()
1247   "Put mark at end of F90 subprogram, point at beginning, push marks.
1248 If called interactively, highlight the subprogram with the face `highlight'.
1249 Call again to remove the highlighting."
1250   (interactive)
1251   (let ((pos (point)) program)
1252     (f90-end-of-subprogram)
1253     (push-mark (point) t)
1254     (goto-char pos)
1255     (setq program (f90-beginning-of-subprogram))
1256     ;; The keywords in the preceding lists assume case-insensitivity.
1257     (if f90-xemacs-flag
1258         (zmacs-activate-region)
1259       (setq mark-active t
1260             deactivate-mark nil)
1261       (if (interactive-p)
1262           (if (overlayp f90-mark-subprogram-overlay)
1263               (if (overlay-buffer f90-mark-subprogram-overlay)
1264                   (delete-overlay f90-mark-subprogram-overlay)
1265                 (move-overlay f90-mark-subprogram-overlay (point) (mark)))
1266             (setq f90-mark-subprogram-overlay (make-overlay (point) (mark)))
1267             (overlay-put f90-mark-subprogram-overlay 'face 'highlight))))
1268     program))
1269
1270 (defun f90-comment-region (beg-region end-region)
1271   "Comment/uncomment every line in the region.
1272 Insert the variable `f90-comment-region' at the start of every line
1273 in the region, or, if already present, remove it."
1274   (interactive "*r")
1275   (let ((end (make-marker)))
1276     (set-marker end end-region)
1277     (goto-char beg-region)
1278     (beginning-of-line)
1279     (if (looking-at (regexp-quote f90-comment-region))
1280         (delete-region (point) (match-end 0))
1281       (insert f90-comment-region))
1282     (while (and (zerop (forward-line 1))
1283                 (< (point) (marker-position end)))
1284       (if (looking-at (regexp-quote f90-comment-region))
1285           (delete-region (point) (match-end 0))
1286         (insert f90-comment-region)))
1287     (set-marker end nil)))
1288
1289 (defun f90-indent-line (&optional no-update)
1290   "Indent current line as F90 code.
1291 Unless optional argument NO-UPDATE is non-nil, call `f90-update-line'
1292 after indenting."
1293   (interactive)
1294   (let (indent no-line-number (pos (make-marker)) (case-fold-search t))
1295     (set-marker pos (point))
1296     (beginning-of-line)                 ; digits after & \n are not line-nos
1297     (if (save-excursion (and (f90-previous-statement) (f90-line-continued)))
1298         (progn (setq no-line-number t) (skip-chars-forward " \t"))
1299       (f90-indent-line-no))
1300     (if (looking-at "!")
1301         (setq indent (f90-comment-indent))
1302       (if (and (looking-at "end") f90-smart-end)
1303           (f90-match-end))
1304       (setq indent (f90-calculate-indent)))
1305     (if (not (zerop (- indent (current-column))))
1306         (f90-indent-to indent no-line-number))
1307     ;; If initial point was within line's indentation,
1308     ;; position after the indentation.  Else stay at same point in text.
1309     (if (< (point) (marker-position pos))
1310         (goto-char (marker-position pos)))
1311     (if auto-fill-function
1312         (f90-do-auto-fill)              ; also updates line
1313       (if (not no-update) (f90-update-line)))
1314     (set-marker pos nil)))
1315
1316 (defun f90-indent-new-line ()
1317   "Reindent current line, insert a newline and indent the newline.
1318 An abbrev before point is expanded if the variable `abbrev-mode' is non-nil.
1319 If run in the middle of a line, the line is not broken."
1320   (interactive)
1321   (let (string cont (case-fold-search t))
1322     (if abbrev-mode (expand-abbrev))
1323     (beginning-of-line)                 ; reindent where likely to be needed
1324     (f90-indent-line-no)
1325     (f90-indent-line 'no-update)
1326     (end-of-line)
1327     (delete-horizontal-space)           ; destroy trailing whitespace
1328     (setq string (f90-in-string)
1329           cont (f90-line-continued))
1330     (if (and string (not cont)) (insert "&"))
1331     (f90-update-line)
1332     (newline)
1333     (if (or string (and cont f90-beginning-ampersand)) (insert "&"))
1334     (f90-indent-line 'no-update)))
1335
1336
1337 (defun f90-indent-region (beg-region end-region)
1338   "Indent every line in region by forward parsing."
1339   (interactive "*r")
1340   (let ((end-region-mark (make-marker))
1341         (save-point (point-marker))
1342         block-list ind-lev ind-curr ind-b cont
1343         struct beg-struct end-struct)
1344     (set-marker end-region-mark end-region)
1345     (goto-char beg-region)
1346     ;; First find a line which is not a continuation line or comment.
1347     (beginning-of-line)
1348     (while (and (looking-at "[ \t]*[0-9]*\\(!\\|#\\|[ \t]*$\\)")
1349                 (progn (f90-indent-line 'no-update)
1350                        (zerop (forward-line 1)))
1351                 (< (point) end-region-mark)))
1352     (setq cont (f90-present-statement-cont))
1353     (while (and (or (eq cont 'middle) (eq cont 'end))
1354                 (f90-previous-statement))
1355       (setq cont (f90-present-statement-cont)))
1356     ;; Process present line for beginning of block.
1357     (setq f90-cache-position (point))
1358     (f90-indent-line 'no-update)
1359     (setq ind-lev (f90-current-indentation)
1360           ind-curr ind-lev)
1361     (beginning-of-line)
1362     (skip-chars-forward " \t0-9")
1363     (setq struct nil
1364           ind-b (cond ((setq struct (f90-looking-at-do)) f90-do-indent)
1365                       ((or (setq struct (f90-looking-at-if-then))
1366                            (setq struct (f90-looking-at-select-case))
1367                            (setq struct (f90-looking-at-where-or-forall))
1368                            (looking-at f90-else-like-re))
1369                        f90-if-indent)
1370                       ((setq struct (f90-looking-at-type-like))
1371                        f90-type-indent)
1372                       ((or(setq struct (f90-looking-at-program-block-start))
1373                           (looking-at "contains[ \t]*\\($\\|!\\)"))
1374                        f90-program-indent)))
1375     (if ind-b (setq ind-lev (+ ind-lev ind-b)))
1376     (if struct (setq block-list (cons struct block-list)))
1377     (while (and (f90-line-continued) (zerop (forward-line 1))
1378                 (< (point) end-region-mark))
1379       (if (looking-at "[ \t]*!")
1380           (f90-indent-to (f90-comment-indent))
1381         (if (not (zerop (- (current-indentation)
1382                            (+ ind-curr f90-continuation-indent))))
1383             (f90-indent-to (+ ind-curr f90-continuation-indent) 'no-line-no))))
1384     ;; Process all following lines.
1385     (while (and (zerop (forward-line 1)) (< (point) end-region-mark))
1386       (beginning-of-line)
1387       (f90-indent-line-no)
1388       (setq f90-cache-position (point))
1389       (cond ((looking-at "[ \t]*$") (setq ind-curr 0))
1390             ((looking-at "[ \t]*#") (setq ind-curr 0))
1391             ((looking-at "!") (setq ind-curr (f90-comment-indent)))
1392             ((f90-no-block-limit) (setq ind-curr ind-lev))
1393             ((looking-at f90-else-like-re) (setq ind-curr
1394                                                  (- ind-lev f90-if-indent)))
1395             ((looking-at "contains[ \t]*\\($\\|!\\)")
1396              (setq ind-curr (- ind-lev f90-program-indent)))
1397             ((setq ind-b
1398                    (cond ((setq struct (f90-looking-at-do)) f90-do-indent)
1399                          ((or (setq struct (f90-looking-at-if-then))
1400                               (setq struct (f90-looking-at-select-case))
1401                               (setq struct (f90-looking-at-where-or-forall)))
1402                           f90-if-indent)
1403                          ((setq struct (f90-looking-at-type-like))
1404                           f90-type-indent)
1405                          ((setq struct (f90-looking-at-program-block-start))
1406                           f90-program-indent)))
1407              (setq ind-curr ind-lev)
1408              (if ind-b (setq ind-lev (+ ind-lev ind-b)))
1409              (setq block-list (cons struct block-list)))
1410             ((setq end-struct (f90-looking-at-program-block-end))
1411              (setq beg-struct (car block-list)
1412                    block-list (cdr block-list))
1413              (if f90-smart-end
1414                  (save-excursion
1415                    (f90-block-match (car beg-struct) (car (cdr beg-struct))
1416                                     (car end-struct) (car (cdr end-struct)))))
1417              (setq ind-b
1418                    (cond ((looking-at f90-end-if-re) f90-if-indent)
1419                          ((looking-at "end[ \t]*do\\>")  f90-do-indent)
1420                          ((looking-at f90-end-type-re) f90-type-indent)
1421                          ((f90-looking-at-program-block-end)
1422                           f90-program-indent)))
1423              (if ind-b (setq ind-lev (- ind-lev ind-b)))
1424              (setq ind-curr ind-lev))
1425             (t (setq ind-curr ind-lev)))
1426       ;; Do the indentation if necessary.
1427       (if (not (zerop (- ind-curr (current-column))))
1428           (f90-indent-to ind-curr))
1429       (while (and (f90-line-continued) (zerop (forward-line 1))
1430                   (< (point) end-region-mark))
1431         (if (looking-at "[ \t]*!")
1432             (f90-indent-to (f90-comment-indent))
1433           (if (not (zerop (- (current-indentation)
1434                              (+ ind-curr f90-continuation-indent))))
1435               (f90-indent-to
1436                (+ ind-curr f90-continuation-indent) 'no-line-no)))))
1437     ;; Restore point, etc.
1438     (setq f90-cache-position nil)
1439     (goto-char save-point)
1440     (set-marker end-region-mark nil)
1441     (set-marker save-point nil)
1442     (if f90-xemacs-flag
1443         (zmacs-deactivate-region)
1444       (deactivate-mark))))
1445
1446 (defun f90-indent-subprogram ()
1447   "Properly indent the subprogram containing point."
1448   (interactive)
1449   (save-excursion
1450     (let ((program (f90-mark-subprogram)))
1451       (if program
1452           (progn
1453             (message "Indenting %s %s..."
1454                      (car program) (car (cdr program)))
1455             (indent-region (point) (mark) nil)
1456             (message "Indenting %s %s...done"
1457                      (car program) (car (cdr program))))
1458         (message "Indenting the whole file...")
1459         (indent-region (point) (mark) nil)
1460         (message "Indenting the whole file...done")))))
1461
1462 (defun f90-break-line (&optional no-update)
1463   "Break line at point, insert continuation marker(s) and indent.
1464 Unless in a string or comment, or if the optional argument NO-UPDATE
1465 is non-nil, call `f90-update-line' after inserting the continuation marker."
1466   (interactive)
1467   (let (ctype)
1468     (cond ((f90-in-string)
1469            (insert "&") (newline 1) (insert "&"))
1470           ((f90-in-comment)
1471            (setq ctype (f90-get-present-comment-type))
1472            (newline 1)
1473            (insert ctype))
1474           (t (insert "&")
1475              (if (not no-update) (f90-update-line))
1476              (newline 1)
1477              (if f90-beginning-ampersand (insert "&")))))
1478   (indent-according-to-mode))
1479
1480 (defun f90-find-breakpoint ()
1481   "From `fill-column', search backward for break-delimiter."
1482   (let ((bol (line-beginning-position)))
1483     (re-search-backward f90-break-delimiters bol)
1484     (if (not f90-break-before-delimiters)
1485         (if (looking-at f90-no-break-re)
1486             (forward-char 2)
1487           (forward-char))
1488       (backward-char)
1489       (if (not (looking-at f90-no-break-re))
1490           (forward-char)))))
1491
1492 (defun f90-do-auto-fill ()
1493   "Break line if non-white characters beyond `fill-column'.
1494 Update keyword case first."
1495   (interactive)
1496   ;; Break line before or after last delimiter (non-word char) if
1497   ;; position is beyond fill-column.
1498   ;; Will not break **, //, or => (as specified by f90-no-break-re).
1499   (f90-update-line)
1500   (while (> (current-column) fill-column)
1501     (let ((pos-mark (point-marker)))
1502       (move-to-column fill-column)
1503       (or (f90-in-string) (f90-find-breakpoint))
1504       (f90-break-line)
1505       (goto-char pos-mark)
1506       (set-marker pos-mark nil))))
1507
1508
1509 (defun f90-join-lines ()
1510   "Join present line with next line, if this line ends with \&."
1511   (interactive)
1512   (let (pos (oldpos (point)))
1513     (end-of-line)
1514     (skip-chars-backward " \t")
1515     (when (= (preceding-char) ?&)
1516       (delete-char -1)
1517       (setq pos (point))
1518       (forward-line 1)
1519       (skip-chars-forward " \t")
1520       (if (looking-at "\&") (delete-char 1))
1521       (delete-region pos (point))
1522       (unless (f90-in-string)
1523         (delete-horizontal-space)
1524         (insert " "))
1525       (if (and auto-fill-function
1526                (> (line-end-position) fill-column))
1527           (f90-do-auto-fill))
1528       (goto-char oldpos)
1529       t)))                              ; return t if joined something
1530
1531 (defun f90-fill-region (beg-region end-region)
1532   "Fill every line in region by forward parsing.  Join lines if possible."
1533   (interactive "*r")
1534   (let ((end-region-mark (make-marker))
1535         (go-on t)
1536         f90-smart-end f90-auto-keyword-case auto-fill-function)
1537     (set-marker end-region-mark end-region)
1538     (goto-char beg-region)
1539     (while go-on
1540       ;; Join as much as possible.
1541       (while (f90-join-lines))
1542       ;; Chop the line if necessary.
1543       (while (> (save-excursion (end-of-line) (current-column))
1544                 fill-column)
1545         (move-to-column fill-column)
1546         (f90-find-breakpoint)
1547         (f90-break-line 'no-update))
1548       (setq go-on (and (< (point) (marker-position end-region-mark))
1549                        (zerop (forward-line 1)))
1550             f90-cache-position (point)))
1551     (setq f90-cache-position nil)
1552     (if f90-xemacs-flag
1553         (zmacs-deactivate-region)
1554       (deactivate-mark))))
1555 \f
1556 (defun f90-block-match (beg-block beg-name end-block end-name)
1557   "Match end-struct with beg-struct and complete end-block if possible.
1558 BEG-BLOCK is the type of block as indicated at the start (e.g., do).
1559 BEG-NAME is the block start name (may be nil).
1560 END-BLOCK is the type of block as indicated at the end (may be nil).
1561 END-NAME is the block end name (may be nil).
1562 Leave point at the end of line."
1563   (search-forward "end" (line-end-position))
1564   (catch 'no-match
1565     (if (not (f90-equal-symbols beg-block end-block))
1566         (if end-block
1567             (progn
1568               (message "END %s does not match %s." end-block beg-block)
1569               (end-of-line)
1570               (throw 'no-match nil))
1571           (message "Inserting %s." beg-block)
1572           (insert (concat " " beg-block)))
1573       (search-forward end-block))
1574     (if (not (f90-equal-symbols beg-name end-name))
1575         (cond ((and beg-name (not end-name))
1576                (message "Inserting %s." beg-name)
1577                (insert (concat " " beg-name)))
1578               ((and beg-name end-name)
1579                (message "Replacing %s with %s." end-name beg-name)
1580                (search-forward end-name)
1581                (replace-match beg-name))
1582               ((and (not beg-name) end-name)
1583                (message "Deleting %s." end-name)
1584                (search-forward end-name)
1585                (replace-match "")))
1586       (if end-name (search-forward end-name)))
1587     (if (not (looking-at "[ \t]*!")) (delete-horizontal-space))))
1588
1589 (defun f90-match-end ()
1590   "From an end block statement, find the corresponding block and name."
1591   (interactive)
1592   (let ((count 1) (top-of-window (window-start))
1593         (end-point (point)) (case-fold-search t)
1594         matching-beg beg-name end-name beg-block end-block end-struct)
1595     (when (save-excursion (beginning-of-line) (skip-chars-forward " \t0-9")
1596                           (setq end-struct (f90-looking-at-program-block-end)))
1597       (setq end-block (car end-struct)
1598             end-name  (car (cdr end-struct)))
1599       (save-excursion
1600         (beginning-of-line)
1601         (while
1602             (and (not (zerop count))
1603                  (let ((stop nil) notexist)
1604                    (while (not stop)
1605                      (setq notexist
1606                            (not (re-search-backward
1607                                  (concat "\\(" f90-blocks-re "\\)") nil t)))
1608                      (if notexist
1609                          (setq stop t)
1610                        (setq stop
1611                              (not (or (f90-in-string)
1612                                       (f90-in-comment))))))
1613                    (not notexist)))
1614           (beginning-of-line)
1615           (skip-chars-forward " \t0-9")
1616           (cond ((setq matching-beg
1617                        (or
1618                         (f90-looking-at-do)
1619                         (f90-looking-at-if-then)
1620                         (f90-looking-at-where-or-forall)
1621                         (f90-looking-at-select-case)
1622                         (f90-looking-at-type-like)
1623                         (f90-looking-at-program-block-start)))
1624                  (setq count (1- count)))
1625                 ((looking-at (concat "end[ \t]*" f90-blocks-re "\\b"))
1626                  (setq count (1+ count)))))
1627         (if (not (zerop count))
1628             (message "No matching beginning.")
1629           (f90-update-line)
1630           (if (eq f90-smart-end 'blink)
1631               (if (< (point) top-of-window)
1632                   (message "Matches %s: %s"
1633                            (what-line)
1634                            (buffer-substring
1635                             (line-beginning-position)
1636                             (line-end-position)))
1637                 (sit-for 1)))
1638           (setq beg-block (car matching-beg)
1639                 beg-name (car (cdr matching-beg)))
1640           (goto-char end-point)
1641           (beginning-of-line)
1642           (f90-block-match beg-block beg-name end-block end-name))))))
1643
1644 (defun f90-insert-end ()
1645   "Insert a complete end statement matching beginning of present block."
1646   (interactive)
1647   (let ((f90-smart-end (or f90-smart-end 'blink)))
1648     (insert "end")
1649     (f90-indent-new-line)))
1650 \f
1651 ;; Abbrevs and keywords.
1652
1653 (defun f90-abbrev-start ()
1654   "Typing `\\[help-command] or `? lists all the F90 abbrevs.
1655 Any other key combination is executed normally."
1656   (interactive)
1657   (let (e c)
1658     (insert last-command-char)
1659     (if (not f90-xemacs-flag)
1660         (setq c (read-event))
1661       (setq e (next-command-event)
1662             c (event-to-character e)))
1663     ;; Insert char if not equal to `?'.
1664     (if (or (eq c ??) (eq c help-char))
1665         (f90-abbrev-help)
1666       (if f90-xemacs-flag
1667           (setq unread-command-event e)
1668         (setq unread-command-events (list c))))))
1669
1670 (defun f90-abbrev-help ()
1671   "List the currently defined abbrevs in F90 mode."
1672   (interactive)
1673   (message "Listing abbrev table...")
1674   (display-buffer (f90-prepare-abbrev-list-buffer))
1675   (message "Listing abbrev table...done"))
1676
1677 (defun f90-prepare-abbrev-list-buffer ()
1678   "Create a buffer listing the F90 mode abbreviations."
1679   (save-excursion
1680     (set-buffer (get-buffer-create "*Abbrevs*"))
1681     (erase-buffer)
1682     (insert-abbrev-table-description 'f90-mode-abbrev-table t)
1683     (goto-char (point-min))
1684     (set-buffer-modified-p nil)
1685     (edit-abbrevs-mode))
1686   (get-buffer-create "*Abbrevs*"))
1687
1688 (defun f90-upcase-keywords ()
1689   "Upcase all F90 keywords in the buffer."
1690   (interactive)
1691   (f90-change-keywords 'upcase-word))
1692
1693 (defun f90-capitalize-keywords ()
1694   "Capitalize all F90 keywords in the buffer."
1695   (interactive)
1696   (f90-change-keywords 'capitalize-word))
1697
1698 (defun f90-downcase-keywords ()
1699   "Downcase all F90 keywords in the buffer."
1700   (interactive)
1701   (f90-change-keywords 'downcase-word))
1702
1703 (defun f90-upcase-region-keywords (beg end)
1704   "Upcase all F90 keywords in the region."
1705   (interactive "*r")
1706   (f90-change-keywords 'upcase-word beg end))
1707
1708 (defun f90-capitalize-region-keywords (beg end)
1709   "Capitalize all F90 keywords in the region."
1710   (interactive "*r")
1711   (f90-change-keywords 'capitalize-word beg end))
1712
1713 (defun f90-downcase-region-keywords (beg end)
1714   "Downcase all F90 keywords in the region."
1715   (interactive "*r")
1716   (f90-change-keywords 'downcase-word beg end))
1717
1718 ;; Change the keywords according to argument.
1719 (defun f90-change-keywords (change-word &optional beg end)
1720   "Change the case of F90 keywords in the region (if specified) or buffer.
1721 CHANGE-WORD should be one of 'upcase-word, 'downcase-word, capitalize-word."
1722   (save-excursion
1723     (setq beg (or beg (point-min))
1724           end (or end (point-max)))
1725     (let ((keyword-re
1726            (concat "\\("
1727                    f90-keywords-re "\\|" f90-procedures-re "\\|"
1728                    f90-hpf-keywords-re "\\|" f90-operators-re "\\)"))
1729           (ref-point (point-min))
1730           (modified (buffer-modified-p))
1731           state saveword back-point)
1732       (goto-char beg)
1733       (unwind-protect
1734           (while (re-search-forward keyword-re end t)
1735             (unless (progn
1736                       (setq state (parse-partial-sexp ref-point (point)))
1737                       (or (nth 3 state) (nth 4 state)
1738                           (save-excursion ; check for cpp directive
1739                             (beginning-of-line)
1740                             (skip-chars-forward " \t0-9")
1741                             (looking-at "#"))))
1742               (setq ref-point (point)
1743                     back-point (save-excursion (backward-word 1) (point))
1744                     saveword (buffer-substring back-point ref-point))
1745               (funcall change-word -1)
1746               (or (string= saveword (buffer-substring back-point ref-point))
1747                   (setq modified t))))
1748         (or modified (set-buffer-modified-p nil))))))
1749
1750
1751 (defun f90-current-defun ()
1752   "Function to use for `add-log-current-defun-function' in F90 mode."
1753   (save-excursion
1754     (nth 1 (f90-beginning-of-subprogram))))
1755
1756 (provide 'f90)
1757
1758 ;;; f90.el ends here