lisp/mail/mail-utils.el

   1 ;;; mail-utils.el --- utility functions used both by rmail and rnews
   2
   3 ;; Copyright (C) 1985, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: mail, news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Utility functions for mail and netnews handling.  These handle fine
  27 ;; points of header parsing.
  28
  29 ;;; Code:
  30
  31 ;;; We require lisp-mode to make sure that lisp-mode-syntax-table has
  32 ;;; been initialized.
  33 (require 'lisp-mode)
  34
  35 ;;;###autoload
  36 (defcustom mail-use-rfc822 nil "\
  37 *If non-nil, use a full, hairy RFC822 parser on mail addresses.
  38 Otherwise, (the default) use a smaller, somewhat faster, and
  39 often correct parser."
  40   :type 'boolean
  41   :group 'mail)
  42
  43 ;; Returns t if file FILE is an Rmail file.
  44 ;;;###autoload
  45 (defun mail-file-babyl-p (file)
  46   (let ((buf (generate-new-buffer " *rmail-file-p*")))
  47     (unwind-protect
  48         (save-excursion
  49           (set-buffer buf)
  50           (insert-file-contents file nil 0 100)
  51           (looking-at "BABYL OPTIONS:"))
  52       (kill-buffer buf))))
  53
  54 (defun mail-string-delete (string start end)
  55   "Returns a string containing all of STRING except the part
  56 from START (inclusive) to END (exclusive)."
  57   (if (null end) (substring string 0 start)
  58     (concat (substring string 0 start)
  59             (substring string end nil))))
  60
  61 ;;;###autoload
  62 (defun mail-quote-printable (string &optional wrapper)
  63   "Convert a string to the \"quoted printable\" Q encoding.
  64 If the optional argument WRAPPER is non-nil,
  65 we add the wrapper characters =?ISO-8859-1?Q?....?=."
  66   (let ((i 0) (result ""))
  67     (save-match-data
  68       (while (string-match "[?=\"\200-\377]" string i)
  69         (setq result
  70               (concat result (substring string i (match-beginning 0))
  71                       (upcase (format "=%02x"
  72                                       (aref string (match-beginning 0))))))
  73         (setq i (match-end 0)))
  74       (if wrapper
  75           (concat "=?ISO-8859-1?Q?"
  76                   result (substring string i)
  77                   "?=")
  78         (concat result (substring string i))))))
  79
  80 (defun mail-unquote-printable-hexdigit (char)
  81   (setq char (upcase char))
  82   (if (>= char ?A)
  83       (+ (- char ?A) 10)
  84     (- char ?0)))
  85
  86 ;;;###autoload
  87 (defun mail-unquote-printable (string &optional wrapper)
  88   "Undo the \"quoted printable\" encoding.
  89 If the optional argument WRAPPER is non-nil,
  90 we expect to find and remove the wrapper characters =?ISO-8859-1?Q?....?=."
  91   (save-match-data
  92     (and wrapper
  93          (string-match "\\`=\\?ISO-8859-1\\?Q\\?\\([^?]*\\)\\?" string)
  94          (setq string (match-string 1 string)))
  95     (let ((i 0) strings)
  96       (while (string-match "=\\(..\\|\n\\)" string i)
  97         (setq strings (cons (substring string i (match-beginning 0)) strings))
  98         (unless (= (aref string (match-beginning 1)) ?\n)
  99           (setq strings
 100                 (cons (make-string 1
 101                                    (+ (* 16 (mail-unquote-printable-hexdigit
 102                                              (aref string (match-beginning 1))))
 103                                       (mail-unquote-printable-hexdigit
 104                                        (aref string (1+ (match-beginning 1))))))
 105                       strings)))
 106         (setq i (match-end 0)))
 107       (apply 'concat (nreverse (cons (substring string i) strings))))))
 108
 109 ;;;###autoload
 110 (defun mail-unquote-printable-region (beg end &optional wrapper noerror
 111                                           unibyte)
 112   "Undo the \"quoted printable\" encoding in buffer from BEG to END.
 113 If the optional argument WRAPPER is non-nil,
 114 we expect to find and remove the wrapper characters =?ISO-8859-1?Q?....?=.
 115 If NOERROR is non-nil, return t if successful.
 116 If UNIBYTE is non-nil, insert converted characters as unibyte.
 117 That is useful if you are going to character code decoding afterward,
 118 as Rmail does."
 119   (interactive "r\nP")
 120   (let (failed)
 121     (save-match-data
 122       (save-excursion
 123         (save-restriction
 124           (narrow-to-region beg end)
 125           (goto-char (point-min))
 126           (when (and wrapper
 127                      (looking-at "\\`=\\?ISO-8859-1\\?Q\\?\\([^?]*\\)\\?"))
 128             (delete-region (match-end 1) end)
 129             (delete-region (point) (match-beginning 1)))
 130           (while (re-search-forward "=\\(\\([0-9A-F][0-9A-F]\\)\\|[=\n]\\|..\\)" nil t)
 131             (goto-char (match-end 0))
 132             (cond ((= (char-after (match-beginning 1)) ?\n)
 133                    (replace-match ""))
 134                   ((= (char-after (match-beginning 1)) ?=)
 135                    (replace-match "="))
 136                   ((match-beginning 2)
 137                    (let ((char (+ (* 16 (mail-unquote-printable-hexdigit
 138                                          (char-after (match-beginning 2))))
 139                                   (mail-unquote-printable-hexdigit
 140                                    (char-after (1+ (match-beginning 2)))))))
 141                      (if unibyte
 142                          (progn
 143                            (replace-match "")
 144                            ;; insert-char will insert this as unibyte,
 145                            (insert-char char 1))
 146                        (replace-match (make-string 1 char) t t))))
 147                   (noerror
 148                    (setq failed t))
 149                   (t
 150                    (error "Malformed MIME quoted-printable message"))))
 151           (not failed))))))
 152
 153 (eval-when-compile (require 'rfc822))
 154
 155 (defun mail-strip-quoted-names (address)
 156   "Delete comments and quoted strings in an address list ADDRESS.
 157 Also delete leading/trailing whitespace and replace FOO <BAR> with just BAR.
 158 Return a modified address list."
 159   (if (null address)
 160       nil
 161     (if mail-use-rfc822
 162         (progn (require 'rfc822)
 163                (mapconcat 'identity (rfc822-addresses address) ", "))
 164       (let (pos)
 165
 166        ;; Detect nested comments.
 167        (if (string-match "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*(" address)
 168            ;; Strip nested comments.
 169            (with-current-buffer (get-buffer-create " *temp*")
 170              (erase-buffer)
 171              (insert address)
 172              (set-syntax-table lisp-mode-syntax-table)
 173              (goto-char 1)
 174              (while (search-forward "(" nil t)
 175                (forward-char -1)
 176                (skip-chars-backward " \t")
 177                (delete-region (point)
 178                               (save-excursion
 179                                 (condition-case ()
 180                                     (forward-sexp 1)
 181                                   (error (goto-char (point-max))))
 182                                   (point))))
 183              (setq address (buffer-string))
 184              (erase-buffer))
 185          ;; Strip non-nested comments an easier way.
 186          (while (setq pos (string-match
 187                             ;; This doesn't hack rfc822 nested comments
 188                             ;;  `(xyzzy (foo) whinge)' properly.  Big deal.
 189                             "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*)"
 190                             address))
 191            (setq address (replace-match "" nil nil address 0))))
 192
 193        ;; strip surrounding whitespace
 194        (string-match "\\`[ \t\n]*" address)
 195        (setq address (substring address
 196                                 (match-end 0)
 197                                 (string-match "[ \t\n]*\\'" address
 198                                               (match-end 0))))
 199
 200        ;; strip `quoted' names (This is supposed to hack `"Foo Bar" <bar@host>')
 201        (setq pos 0)
 202        (while (setq pos (string-match
 203                           "\\([ \t]?\\)\\([ \t]*\"\\([^\"\\]\\|\\\\.\\|\\\\\n\\)*\"[ \t\n]*\\)"
 204                           address pos))
 205          ;; If the next thing is "@", we have "foo bar"@host.  Leave it.
 206          (if (and (> (length address) (match-end 0))
 207                   (= (aref address (match-end 0)) ?@))
 208              (setq pos (match-end 0))
 209            ;; Otherwise discard the "..." part.
 210            (setq address (replace-match "" nil nil address 2))))
 211        ;; If this address contains <...>, replace it with just
 212        ;; the part between the <...>.
 213        (while (setq pos (string-match "\\(,\\s-*\\|\\`\\)\\([^,]*<\\([^>,:]*\\)>[^,]*\\)\\(\\s-*,\\|\\'\\)"
 214                                       address))
 215          (setq address (replace-match (match-string 3 address)
 216                                       nil 'literal address 2)))
 217        address))))
 218
 219 ;;; The following piece of ugliness is legacy code.  The name was an
 220 ;;; unfortunate choice --- a flagrant violation of the Emacs Lisp
 221 ;;; coding conventions.  `mail-dont-reply-to' would have been
 222 ;;; infinitely better.  Also, `rmail-dont-reply-to-names' might have
 223 ;;; been better named `mail-dont-reply-to-names' and sourced from this
 224 ;;; file instead of in rmail.el.  Yuck.  -pmr
 225 (defun rmail-dont-reply-to (destinations)
 226   "Prune addresses from DESTINATIONS, a list of recipient addresses.
 227 All addresses matching `rmail-dont-reply-to-names' are removed from
 228 the comma-separated list.  The pruned list is returned."
 229   (if (null rmail-dont-reply-to-names)
 230       (setq rmail-dont-reply-to-names
 231             (concat (if rmail-default-dont-reply-to-names
 232                         (concat rmail-default-dont-reply-to-names "\\|")
 233                       "")
 234                     (if (and user-mail-address
 235                              (not (equal user-mail-address user-login-name)))
 236                         ;; Anchor the login name and email address so
 237                         ;; that we don't match substrings: if the
 238                         ;; login name is "foo", we shouldn't match
 239                         ;; "barfoo@baz.com".
 240                         (concat "\\`"
 241                                 (regexp-quote user-mail-address)
 242                                 "\\'\\|")
 243                       "")
 244                     (concat "\\`" (regexp-quote user-login-name) "@"))))
 245   ;; Split up DESTINATIONS and match each element separately.
 246   (let ((start-pos 0) (cur-pos 0)
 247         (case-fold-search t))
 248     (while start-pos
 249       (setq cur-pos (string-match "[,\"]" destinations cur-pos))
 250       (if (and cur-pos (equal (match-string 0 destinations) "\""))
 251           ;; Search for matching quote.
 252           (let ((next-pos (string-match "\"" destinations (1+ cur-pos))))
 253             (if next-pos
 254                 (setq cur-pos (1+ next-pos))
 255               ;; If the open-quote has no close-quote,
 256               ;; delete the open-quote to get something well-defined.
 257               ;; This case is not valid, but it can happen if things
 258               ;; are weird elsewhere.
 259               (setq destinations (concat (substring destinations 0 cur-pos)
 260                                     (substring destinations (1+ cur-pos))))
 261               (setq cur-pos start-pos)))
 262         (let* ((address (substring destinations start-pos cur-pos))
 263                (naked-address (mail-strip-quoted-names address)))
 264           (if (string-match rmail-dont-reply-to-names naked-address)
 265               (setq destinations (concat (substring destinations 0 start-pos)
 266                                     (and cur-pos (substring destinations
 267                                                             (1+ cur-pos))))
 268                     cur-pos start-pos)
 269             (setq cur-pos (and cur-pos (1+ cur-pos))
 270                   start-pos cur-pos))))))
 271   ;; get rid of any trailing commas
 272   (let ((pos (string-match "[ ,\t\n]*\\'" destinations)))
 273     (if pos
 274         (setq destinations (substring destinations 0 pos))))
 275   ;; remove leading spaces. they bother me.
 276   (if (string-match "\\(\\s \\|,\\)*" destinations)
 277       (substring destinations (match-end 0))
 278     destinations))
 279
 280 \f
 281 ;;;###autoload
 282 (defun mail-fetch-field (field-name &optional last all list)
 283   "Return the value of the header field whose type is FIELD-NAME.
 284 The buffer is expected to be narrowed to just the header of the message.
 285 If second arg LAST is non-nil, use the last field of type FIELD-NAME.
 286 If third arg ALL is non-nil, concatenate all such fields with commas between.
 287 If 4th arg LIST is non-nil, return a list of all such fields."
 288   (save-excursion
 289     (goto-char (point-min))
 290     (let ((case-fold-search t)
 291           (name (concat "^" (regexp-quote field-name) "[ \t]*:[ \t]*")))
 292       (if (or all list)
 293           (let ((value (if all "")))
 294             (while (re-search-forward name nil t)
 295               (let ((opoint (point)))
 296                 (while (progn (forward-line 1)
 297                               (looking-at "[ \t]")))
 298                 ;; Back up over newline, then trailing spaces or tabs
 299                 (forward-char -1)
 300                 (skip-chars-backward " \t" opoint)
 301                 (if list
 302                     (setq value (cons (buffer-substring-no-properties
 303                                        opoint (point))
 304                                       value))
 305                   (setq value (concat value
 306                                       (if (string= value "") "" ", ")
 307                                       (buffer-substring-no-properties
 308                                        opoint (point)))))))
 309             (if list
 310                 value
 311               (and (not (string= value "")) value)))
 312         (if (re-search-forward name nil t)
 313             (progn
 314               (if last (while (re-search-forward name nil t)))
 315               (let ((opoint (point)))
 316                 (while (progn (forward-line 1)
 317                               (looking-at "[ \t]")))
 318                 ;; Back up over newline, then trailing spaces or tabs
 319                 (forward-char -1)
 320                 (skip-chars-backward " \t" opoint)
 321                 (buffer-substring-no-properties opoint (point)))))))))
 322 \f
 323 ;; Parse a list of tokens separated by commas.
 324 ;; It runs from point to the end of the visible part of the buffer.
 325 ;; Whitespace before or after tokens is ignored,
 326 ;; but whitespace within tokens is kept.
 327 (defun mail-parse-comma-list ()
 328   (let (accumulated
 329         beg)
 330     (skip-chars-forward " \t\n")
 331     (while (not (eobp))
 332       (setq beg (point))
 333       (skip-chars-forward "^,")
 334       (skip-chars-backward " \t\n")
 335       (setq accumulated
 336             (cons (buffer-substring-no-properties beg (point))
 337                   accumulated))
 338       (skip-chars-forward "^,")
 339       (skip-chars-forward ", \t\n"))
 340     accumulated))
 341
 342 (defun mail-comma-list-regexp (labels)
 343   (let (pos)
 344     (setq pos (or (string-match "[^ \t]" labels) 0))
 345     ;; Remove leading and trailing whitespace.
 346     (setq labels (substring labels pos (string-match "[ \t]*$" labels pos)))
 347     ;; Change each comma to \|, and flush surrounding whitespace.
 348     (while (setq pos (string-match "[ \t]*,[ \t]*" labels))
 349       (setq labels
 350             (concat (substring labels 0 pos)
 351                     "\\|"
 352                     (substring labels (match-end 0))))))
 353   labels)
 354 \f
 355 (defun mail-rfc822-time-zone (time)
 356   (let* ((sec (or (car (current-time-zone time)) 0))
 357          (absmin (/ (abs sec) 60)))
 358     (format "%c%02d%02d" (if (< sec 0) ?- ?+) (/ absmin 60) (% absmin 60))))
 359
 360 (defun mail-rfc822-date ()
 361   (let* ((time (current-time))
 362          (s (current-time-string time)))
 363     (string-match "[^ ]+ +\\([^ ]+\\) +\\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)" s)
 364     (concat (substring s (match-beginning 2) (match-end 2)) " "
 365             (substring s (match-beginning 1) (match-end 1)) " "
 366             (substring s (match-beginning 4) (match-end 4)) " "
 367             (substring s (match-beginning 3) (match-end 3)) " "
 368             (mail-rfc822-time-zone time))))
 369
 370 (provide 'mail-utils)
 371
 372 ;; arch-tag: b24aec2f-fd65-4ceb-9e39-3cc2827036fd
 373 ;;; mail-utils.el ends here