lisp/url/url-http.el

   1 ;;; url-http.el --- HTTP retrieval routines
   2
   3 ;; Copyright (C) 1999, 2001, 2004, 2005, 2006, 2007  Free Software Foundation, Inc.
   4
   5 ;; Author: Bill Perry <wmperry@gnu.org>
   6 ;; Keywords: comm, data, processes
   7
   8 ;; This file is part of GNU Emacs.
   9 ;;
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30 (defvar url-http-extra-headers)
  31 (defvar url-http-target-url)
  32 (defvar url-http-proxy)
  33 (defvar url-http-connection-opened)
  34 (require 'url-gw)
  35 (require 'url-util)
  36 (require 'url-parse)
  37 (require 'url-cookie)
  38 (require 'mail-parse)
  39 (require 'url-auth)
  40 (require 'url)
  41 (autoload 'url-cache-create-filename "url-cache")
  42
  43 (defconst url-http-default-port 80 "Default HTTP port.")
  44 (defconst url-http-asynchronous-p t "HTTP retrievals are asynchronous.")
  45 (defalias 'url-http-expand-file-name 'url-default-expander)
  46
  47 (defvar url-http-real-basic-auth-storage nil)
  48 (defvar url-http-proxy-basic-auth-storage nil)
  49
  50 (defvar url-http-open-connections (make-hash-table :test 'equal
  51                                                    :size 17)
  52   "A hash table of all open network connections.")
  53
  54 (defvar url-http-version "1.1"
  55   "What version of HTTP we advertise, as a string.
  56 Valid values are 1.1 and 1.0.
  57 This is only useful when debugging the HTTP subsystem.
  58
  59 Setting this to 1.0 will tell servers not to send chunked encoding,
  60 and other HTTP/1.1 specific features.")
  61
  62 (defvar url-http-attempt-keepalives t
  63   "Whether to use a single TCP connection multiple times in HTTP.
  64 This is only useful when debugging the HTTP subsystem.  Setting to
  65 nil will explicitly close the connection to the server after every
  66 request.")
  67
  68 ;(eval-when-compile
  69 ;; These are all macros so that they are hidden from external sight
  70 ;; when the file is byte-compiled.
  71 ;;
  72 ;; This allows us to expose just the entry points we want.
  73
  74 ;; These routines will allow us to implement persistent HTTP
  75 ;; connections.
  76 (defsubst url-http-debug (&rest args)
  77   (if quit-flag
  78       (let ((proc (get-buffer-process (current-buffer))))
  79         ;; The user hit C-g, honor it!  Some things can get in an
  80         ;; incredibly tight loop (chunked encoding)
  81         (if proc
  82             (progn
  83               (set-process-sentinel proc nil)
  84               (set-process-filter proc nil)))
  85         (error "Transfer interrupted!")))
  86   (apply 'url-debug 'http args))
  87
  88 (defun url-http-mark-connection-as-busy (host port proc)
  89   (url-http-debug "Marking connection as busy: %s:%d %S" host port proc)
  90   (set-process-query-on-exit-flag proc t)
  91   (puthash (cons host port)
  92               (delq proc (gethash (cons host port) url-http-open-connections))
  93               url-http-open-connections)
  94   proc)
  95
  96 (defun url-http-mark-connection-as-free (host port proc)
  97   (url-http-debug "Marking connection as free: %s:%d %S" host port proc)
  98   (when (memq (process-status proc) '(open run connect))
  99     (set-process-buffer proc nil)
 100     (set-process-sentinel proc 'url-http-idle-sentinel)
 101     (set-process-query-on-exit-flag proc nil)
 102     (puthash (cons host port)
 103              (cons proc (gethash (cons host port) url-http-open-connections))
 104              url-http-open-connections))
 105   nil)
 106
 107 (defun url-http-find-free-connection (host port)
 108   (let ((conns (gethash (cons host port) url-http-open-connections))
 109         (found nil))
 110     (while (and conns (not found))
 111       (if (not (memq (process-status (car conns)) '(run open connect)))
 112           (progn
 113             (url-http-debug "Cleaning up dead process: %s:%d %S"
 114                             host port (car conns))
 115             (url-http-idle-sentinel (car conns) nil))
 116         (setq found (car conns))
 117         (url-http-debug "Found existing connection: %s:%d %S" host port found))
 118       (pop conns))
 119     (if found
 120         (url-http-debug "Reusing existing connection: %s:%d" host port)
 121       (url-http-debug "Contacting host: %s:%d" host port))
 122     (url-lazy-message "Contacting host: %s:%d" host port)
 123     (url-http-mark-connection-as-busy
 124      host port
 125      (or found
 126          (let ((buf (generate-new-buffer " *url-http-temp*")))
 127            ;; `url-open-stream' needs a buffer in which to do things
 128            ;; like authentication.  But we use another buffer afterwards.
 129            (unwind-protect
 130                (let ((proc (url-open-stream host buf host port)))
 131                  ;; url-open-stream might return nil.
 132                  (when (processp proc)
 133                    ;; Drop the temp buffer link before killing the buffer.
 134                    (set-process-buffer proc nil))
 135                  proc)
 136              (kill-buffer buf)))))))
 137
 138 ;; Building an HTTP request
 139 (defun url-http-user-agent-string ()
 140   (if (or (eq url-privacy-level 'paranoid)
 141           (and (listp url-privacy-level)
 142                (memq 'agent url-privacy-level)))
 143       ""
 144     (format "User-Agent: %sURL/%s%s\r\n"
 145             (if url-package-name
 146                 (concat url-package-name "/" url-package-version " ")
 147               "")
 148             url-version
 149             (cond
 150              ((and url-os-type url-system-type)
 151               (concat " (" url-os-type "; " url-system-type ")"))
 152              ((or url-os-type url-system-type)
 153               (concat " (" (or url-system-type url-os-type) ")"))
 154              (t "")))))
 155
 156 (defun url-http-create-request (&optional ref-url)
 157   "Create an HTTP request for `url-http-target-url', referred to by REF-URL."
 158   (declare (special proxy-info
 159                     url-http-method url-http-data
 160                     url-http-extra-headers))
 161   (let* ((extra-headers)
 162          (request nil)
 163          (no-cache (cdr-safe (assoc "Pragma" url-http-extra-headers)))
 164          (using-proxy url-http-proxy)
 165          (proxy-auth (if (or (cdr-safe (assoc "Proxy-Authorization"
 166                                               url-http-extra-headers))
 167                              (not using-proxy))
 168                          nil
 169                        (let ((url-basic-auth-storage
 170                               'url-http-proxy-basic-auth-storage))
 171                          (url-get-authentication url-http-target-url nil 'any nil))))
 172          (real-fname (concat (url-filename url-http-target-url)
 173                              (url-recreate-url-attributes url-http-target-url)))
 174          (host (url-host url-http-target-url))
 175          (auth (if (cdr-safe (assoc "Authorization" url-http-extra-headers))
 176                    nil
 177                  (url-get-authentication (or
 178                                           (and (boundp 'proxy-info)
 179                                                proxy-info)
 180                                           url-http-target-url) nil 'any nil))))
 181     (if (equal "" real-fname)
 182         (setq real-fname "/"))
 183     (setq no-cache (and no-cache (string-match "no-cache" no-cache)))
 184     (if auth
 185         (setq auth (concat "Authorization: " auth "\r\n")))
 186     (if proxy-auth
 187         (setq proxy-auth (concat "Proxy-Authorization: " proxy-auth "\r\n")))
 188
 189     ;; Protection against stupid values in the referer
 190     (if (and ref-url (stringp ref-url) (or (string= ref-url "file:nil")
 191                                            (string= ref-url "")))
 192         (setq ref-url nil))
 193
 194     ;; We do not want to expose the referer if the user is paranoid.
 195     (if (or (memq url-privacy-level '(low high paranoid))
 196             (and (listp url-privacy-level)
 197                  (memq 'lastloc url-privacy-level)))
 198         (setq ref-url nil))
 199
 200     ;; url-http-extra-headers contains an assoc-list of
 201     ;; header/value pairs that we need to put into the request.
 202     (setq extra-headers (mapconcat
 203                          (lambda (x)
 204                            (concat (car x) ": " (cdr x)))
 205                          url-http-extra-headers "\r\n"))
 206     (if (not (equal extra-headers ""))
 207         (setq extra-headers (concat extra-headers "\r\n")))
 208
 209     ;; This was done with a call to `format'.  Concatting parts has
 210     ;; the advantage of keeping the parts of each header together and
 211     ;; allows us to elide null lines directly, at the cost of making
 212     ;; the layout less clear.
 213     (setq request
 214           ;; We used to concat directly, but if one of the strings happens
 215           ;; to being multibyte (even if it only contains pure ASCII) then
 216           ;; every string gets converted with `string-MAKE-multibyte' which
 217           ;; turns the 127-255 codes into things like latin-1 accented chars
 218           ;; (it would work right if it used `string-TO-multibyte' instead).
 219           ;; So to avoid the problem we force every string to be unibyte.
 220           (mapconcat
 221            ;; FIXME: Instead of `string-AS-unibyte' we'd want
 222            ;; `string-to-unibyte', so as to properly signal an error if one
 223            ;; of the strings contains a multibyte char.
 224            'string-as-unibyte
 225            (delq nil
 226             (list
 227              ;; The request
 228              (or url-http-method "GET") " "
 229              (if using-proxy (url-recreate-url url-http-target-url) real-fname)
 230              " HTTP/" url-http-version "\r\n"
 231              ;; Version of MIME we speak
 232              "MIME-Version: 1.0\r\n"
 233              ;; (maybe) Try to keep the connection open
 234              "Connection: " (if (or using-proxy
 235                                     (not url-http-attempt-keepalives))
 236                                 "close" "keep-alive") "\r\n"
 237                                 ;; HTTP extensions we support
 238              (if url-extensions-header
 239                  (format
 240                   "Extension: %s\r\n" url-extensions-header))
 241              ;; Who we want to talk to
 242              (if (/= (url-port url-http-target-url)
 243                      (url-scheme-get-property
 244                       (url-type url-http-target-url) 'default-port))
 245                  (format
 246                   "Host: %s:%d\r\n" host (url-port url-http-target-url))
 247                (format "Host: %s\r\n" host))
 248              ;; Who its from
 249              (if url-personal-mail-address
 250                  (concat
 251                   "From: " url-personal-mail-address "\r\n"))
 252              ;; Encodings we understand
 253              (if url-mime-encoding-string
 254                  (concat
 255                   "Accept-encoding: " url-mime-encoding-string "\r\n"))
 256              (if url-mime-charset-string
 257                  (concat
 258                   "Accept-charset: " url-mime-charset-string "\r\n"))
 259              ;; Languages we understand
 260              (if url-mime-language-string
 261                  (concat
 262                   "Accept-language: " url-mime-language-string "\r\n"))
 263              ;; Types we understand
 264              "Accept: " (or url-mime-accept-string "*/*") "\r\n"
 265              ;; User agent
 266              (url-http-user-agent-string)
 267              ;; Proxy Authorization
 268              proxy-auth
 269              ;; Authorization
 270              auth
 271              ;; Cookies
 272              (url-cookie-generate-header-lines host real-fname
 273                                                (equal "https" (url-type url-http-target-url)))
 274              ;; If-modified-since
 275              (if (and (not no-cache)
 276                       (member url-http-method '("GET" nil)))
 277                  (let ((tm (url-is-cached url-http-target-url)))
 278                    (if tm
 279                        (concat "If-modified-since: "
 280                                (url-get-normalized-date tm) "\r\n"))))
 281              ;; Whence we came
 282              (if ref-url (concat
 283                           "Referer: " ref-url "\r\n"))
 284              extra-headers
 285              ;; Length of data
 286              (if url-http-data
 287                  (concat
 288                   "Content-length: " (number-to-string
 289                                       (length url-http-data))
 290                   "\r\n"))
 291              ;; End request
 292              "\r\n"
 293              ;; Any data
 294              url-http-data))
 295            ""))
 296     (url-http-debug "Request is: \n%s" request)
 297     request))
 298
 299 ;; Parsing routines
 300 (defun url-http-clean-headers ()
 301   "Remove trailing \r from header lines.
 302 This allows us to use `mail-fetch-field', etc."
 303   (declare (special url-http-end-of-headers))
 304   (goto-char (point-min))
 305   (while (re-search-forward "\r$" url-http-end-of-headers t)
 306     (replace-match "")))
 307
 308 (defun url-http-handle-authentication (proxy)
 309   (declare (special status success url-http-method url-http-data
 310                     url-callback-function url-callback-arguments))
 311   (url-http-debug "Handling %s authentication" (if proxy "proxy" "normal"))
 312   (let ((auths (or (nreverse
 313                     (mail-fetch-field
 314                      (if proxy "proxy-authenticate" "www-authenticate")
 315                      nil nil t))
 316                   '("basic")))
 317         (type nil)
 318         (url (url-recreate-url url-current-object))
 319         (url-basic-auth-storage 'url-http-real-basic-auth-storage)
 320         auth
 321         (strength 0))
 322     ;; Cheating, but who cares? :)
 323     (if proxy
 324         (setq url-basic-auth-storage 'url-http-proxy-basic-auth-storage))
 325
 326     ;; find strongest supported auth
 327     (dolist (this-auth auths)
 328       (setq this-auth (url-eat-trailing-space
 329                        (url-strip-leading-spaces
 330                         this-auth)))
 331       (let* ((this-type
 332               (if (string-match "[ \t]" this-auth)
 333                   (downcase (substring this-auth 0 (match-beginning 0)))
 334                 (downcase this-auth)))
 335              (registered (url-auth-registered this-type))
 336              (this-strength (cddr registered)))
 337         (when (and registered (> this-strength strength))
 338           (setq auth this-auth
 339                 type this-type
 340                 strength this-strength))))
 341
 342     (if (not (url-auth-registered type))
 343         (progn
 344           (widen)
 345           (goto-char (point-max))
 346           (insert "<hr>Sorry, but I do not know how to handle " type
 347                   " authentication.  If you'd like to write it,"
 348                   " send it to " url-bug-address ".<hr>")
 349           (setq status t))
 350       (let* ((args (url-parse-args (subst-char-in-string ?, ?\; auth)))
 351              (auth (url-get-authentication url (cdr-safe (assoc "realm" args))
 352                                            type t args)))
 353         (if (not auth)
 354             (setq success t)
 355           (push (cons (if proxy "Proxy-Authorization" "Authorization") auth)
 356                 url-http-extra-headers)
 357           (let ((url-request-method url-http-method)
 358                 (url-request-data url-http-data)
 359                 (url-request-extra-headers url-http-extra-headers))
 360             (url-retrieve-internal url url-callback-function
 361                                    url-callback-arguments)))))))
 362
 363 (defun url-http-parse-response ()
 364   "Parse just the response code."
 365   (declare (special url-http-end-of-headers url-http-response-status
 366                     url-http-response-version))
 367   (if (not url-http-end-of-headers)
 368       (error "Trying to parse HTTP response code in odd buffer: %s" (buffer-name)))
 369   (url-http-debug "url-http-parse-response called in (%s)" (buffer-name))
 370   (goto-char (point-min))
 371   (skip-chars-forward " \t\n")          ; Skip any blank crap
 372   (skip-chars-forward "HTTP/")          ; Skip HTTP Version
 373   (setq url-http-response-version
 374         (buffer-substring (point)
 375                           (progn
 376                             (skip-chars-forward "[0-9].")
 377                             (point))))
 378   (setq url-http-response-status (read (current-buffer))))
 379
 380 (defun url-http-handle-cookies ()
 381   "Handle all set-cookie / set-cookie2 headers in an HTTP response.
 382 The buffer must already be narrowed to the headers, so `mail-fetch-field' will
 383 work correctly."
 384   (let ((cookies (nreverse (mail-fetch-field "Set-Cookie" nil nil t)))
 385         (cookies2 (nreverse (mail-fetch-field "Set-Cookie2" nil nil t))))
 386     (and cookies (url-http-debug "Found %d Set-Cookie headers" (length cookies)))
 387     (and cookies2 (url-http-debug "Found %d Set-Cookie2 headers" (length cookies2)))
 388     (while cookies
 389       (url-cookie-handle-set-cookie (pop cookies)))
 390 ;;;     (while cookies2
 391 ;;;       (url-cookie-handle-set-cookie2 (pop cookies)))
 392     )
 393   )
 394
 395 (defun url-http-parse-headers ()
 396  "Parse and handle HTTP specific headers.
 397 Return t if and only if the current buffer is still active and
 398 should be shown to the user."
 399   ;; The comments after each status code handled are taken from RFC
 400   ;; 2616 (HTTP/1.1)
 401   (declare (special url-http-end-of-headers url-http-response-status
 402                     url-http-response-version
 403                     url-http-method url-http-data url-http-process
 404                     url-callback-function url-callback-arguments))
 405
 406   (url-http-mark-connection-as-free (url-host url-current-object)
 407                                     (url-port url-current-object)
 408                                     url-http-process)
 409
 410   (if (or (not (boundp 'url-http-end-of-headers))
 411           (not url-http-end-of-headers))
 412       (error "Trying to parse headers in odd buffer: %s" (buffer-name)))
 413   (goto-char (point-min))
 414   (url-http-debug "url-http-parse-headers called in (%s)" (buffer-name))
 415   (url-http-parse-response)
 416   (mail-narrow-to-head)
 417   ;;(narrow-to-region (point-min) url-http-end-of-headers)
 418   (let ((connection (mail-fetch-field "Connection")))
 419     ;; In HTTP 1.0, keep the connection only if there is a
 420     ;; "Connection: keep-alive" header.
 421     ;; In HTTP 1.1 (and greater), keep the connection unless there is a
 422     ;; "Connection: close" header
 423     (cond
 424      ((string= url-http-response-version "1.0")
 425       (unless (and connection
 426                    (string= (downcase connection) "keep-alive"))
 427         (delete-process url-http-process)))
 428      (t
 429       (when (and connection
 430                  (string= (downcase connection) "close"))
 431         (delete-process url-http-process)))))
 432   (let ((buffer (current-buffer))
 433         (class nil)
 434         (success nil))
 435     (setq class (/ url-http-response-status 100))
 436     (url-http-debug "Parsed HTTP headers: class=%d status=%d" class url-http-response-status)
 437     (url-http-handle-cookies)
 438
 439     (case class
 440       ;; Classes of response codes
 441       ;;
 442       ;; 5xx = Server Error
 443       ;; 4xx = Client Error
 444       ;; 3xx = Redirection
 445       ;; 2xx = Successful
 446       ;; 1xx = Informational
 447       (1                                ; Information messages
 448        ;; 100 = Continue with request
 449        ;; 101 = Switching protocols
 450        ;; 102 = Processing (Added by DAV)
 451        (url-mark-buffer-as-dead buffer)
 452        (error "HTTP responses in class 1xx not supported (%d)" url-http-response-status))
 453       (2                                ; Success
 454        ;; 200 Ok
 455        ;; 201 Created
 456        ;; 202 Accepted
 457        ;; 203 Non-authoritative information
 458        ;; 204 No content
 459        ;; 205 Reset content
 460        ;; 206 Partial content
 461        ;; 207 Multi-status (Added by DAV)
 462        (case url-http-response-status
 463          ((204 205)
 464           ;; No new data, just stay at the same document
 465           (url-mark-buffer-as-dead buffer)
 466           (setq success t))
 467          (otherwise
 468           ;; Generic success for all others.  Store in the cache, and
 469           ;; mark it as successful.
 470           (widen)
 471           (if (and url-automatic-caching (equal url-http-method "GET"))
 472               (url-store-in-cache buffer))
 473           (setq success t))))
 474       (3                                ; Redirection
 475        ;; 300 Multiple choices
 476        ;; 301 Moved permanently
 477        ;; 302 Found
 478        ;; 303 See other
 479        ;; 304 Not modified
 480        ;; 305 Use proxy
 481        ;; 307 Temporary redirect
 482        (let ((redirect-uri (or (mail-fetch-field "Location")
 483                                (mail-fetch-field "URI"))))
 484          (case url-http-response-status
 485            (300
 486             ;; Quoth the spec (section 10.3.1)
 487             ;; -------------------------------
 488             ;; The requested resource corresponds to any one of a set of
 489             ;; representations, each with its own specific location and
 490             ;; agent-driven negotiation information is being provided so
 491             ;; that the user can select a preferred representation and
 492             ;; redirect its request to that location.
 493             ;; [...]
 494             ;; If the server has a preferred choice of representation, it
 495             ;; SHOULD include the specific URI for that representation in
 496             ;; the Location field; user agents MAY use the Location field
 497             ;; value for automatic redirection.
 498             ;; -------------------------------
 499             ;; We do not support agent-driven negotiation, so we just
 500             ;; redirect to the preferred URI if one is provided.
 501             nil)
 502            ((301 302 307)
 503             ;; If the 301|302 status code is received in response to a
 504             ;; request other than GET or HEAD, the user agent MUST NOT
 505             ;; automatically redirect the request unless it can be
 506             ;; confirmed by the user, since this might change the
 507             ;; conditions under which the request was issued.
 508             (if (member url-http-method '("HEAD" "GET"))
 509                 ;; Automatic redirection is ok
 510                 nil
 511               ;; It is just too big of a pain in the ass to get this
 512               ;; prompt all the time.  We will just silently lose our
 513               ;; data and convert to a GET method.
 514               (url-http-debug "Converting `%s' request to `GET' because of REDIRECT(%d)"
 515                               url-http-method url-http-response-status)
 516               (setq url-http-method "GET"
 517                     url-http-data nil)))
 518            (303
 519             ;; The response to the request can be found under a different
 520             ;; URI and SHOULD be retrieved using a GET method on that
 521             ;; resource.
 522             (setq url-http-method "GET"
 523                   url-http-data nil))
 524            (304
 525             ;; The 304 response MUST NOT contain a message-body.
 526             (url-http-debug "Extracting document from cache... (%s)"
 527                             (url-cache-create-filename (url-view-url t)))
 528             (url-cache-extract (url-cache-create-filename (url-view-url t)))
 529             (setq redirect-uri nil
 530                   success t))
 531            (305
 532             ;; The requested resource MUST be accessed through the
 533             ;; proxy given by the Location field.  The Location field
 534             ;; gives the URI of the proxy.  The recipient is expected
 535             ;; to repeat this single request via the proxy.  305
 536             ;; responses MUST only be generated by origin servers.
 537             (error "Redirection thru a proxy server not supported: %s"
 538                    redirect-uri))
 539            (otherwise
 540             ;; Treat everything like '300'
 541             nil))
 542          (when redirect-uri
 543            ;; Clean off any whitespace and/or <...> cruft.
 544            (if (string-match "\\([^ \t]+\\)[ \t]" redirect-uri)
 545                (setq redirect-uri (match-string 1 redirect-uri)))
 546            (if (string-match "^<\\(.*\\)>$" redirect-uri)
 547                (setq redirect-uri (match-string 1 redirect-uri)))
 548
 549            ;; Some stupid sites (like sourceforge) send a
 550            ;; non-fully-qualified URL (ie: /), which royally confuses
 551            ;; the URL library.
 552            (if (not (string-match url-nonrelative-link redirect-uri))
 553                ;; Be careful to use the real target URL, otherwise we may
 554                ;; compute the redirection relative to the URL of the proxy.
 555                (setq redirect-uri
 556                      (url-expand-file-name redirect-uri url-http-target-url)))
 557            (let ((url-request-method url-http-method)
 558                  (url-request-data url-http-data)
 559                  (url-request-extra-headers url-http-extra-headers))
 560              ;; Check existing number of redirects
 561              (if (or (< url-max-redirections 0)
 562                      (and (> url-max-redirections 0)
 563                           (let ((events (car url-callback-arguments))
 564                                 (old-redirects 0))
 565                             (while events
 566                               (if (eq (car events) :redirect)
 567                                   (setq old-redirects (1+ old-redirects)))
 568                               (and (setq events (cdr events))
 569                                    (setq events (cdr events))))
 570                             (< old-redirects url-max-redirections))))
 571                  ;; url-max-redirections hasn't been reached, so go
 572                  ;; ahead and redirect.
 573                  (progn
 574                    ;; Remember that the request was redirected.
 575                    (setf (car url-callback-arguments)
 576                          (nconc (list :redirect redirect-uri)
 577                                 (car url-callback-arguments)))
 578                    ;; Put in the current buffer a forwarding pointer to the new
 579                    ;; destination buffer.
 580                    ;; FIXME: This is a hack to fix url-retrieve-synchronously
 581                    ;; without changing the API.  Instead url-retrieve should
 582                    ;; either simply not return the "destination" buffer, or it
 583                    ;; should take an optional `dest-buf' argument.
 584                    (set (make-local-variable 'url-redirect-buffer)
 585                         (url-retrieve-internal
 586                          redirect-uri url-callback-function
 587                          url-callback-arguments))
 588                    (url-mark-buffer-as-dead buffer))
 589                ;; We hit url-max-redirections, so issue an error and
 590                ;; stop redirecting.
 591                (url-http-debug "Maximum redirections reached")
 592                (setf (car url-callback-arguments)
 593                      (nconc (list :error (list 'error 'http-redirect-limit
 594                                                redirect-uri))
 595                             (car url-callback-arguments)))
 596                (setq success t))))))
 597       (4                                ; Client error
 598        ;; 400 Bad Request
 599        ;; 401 Unauthorized
 600        ;; 402 Payment required
 601        ;; 403 Forbidden
 602        ;; 404 Not found
 603        ;; 405 Method not allowed
 604        ;; 406 Not acceptable
 605        ;; 407 Proxy authentication required
 606        ;; 408 Request time-out
 607        ;; 409 Conflict
 608        ;; 410 Gone
 609        ;; 411 Length required
 610        ;; 412 Precondition failed
 611        ;; 413 Request entity too large
 612        ;; 414 Request-URI too large
 613        ;; 415 Unsupported media type
 614        ;; 416 Requested range not satisfiable
 615        ;; 417 Expectation failed
 616        ;; 422 Unprocessable Entity (Added by DAV)
 617        ;; 423 Locked
 618        ;; 424 Failed Dependency
 619        (case url-http-response-status
 620          (401
 621           ;; The request requires user authentication.  The response
 622           ;; MUST include a WWW-Authenticate header field containing a
 623           ;; challenge applicable to the requested resource.  The
 624           ;; client MAY repeat the request with a suitable
 625           ;; Authorization header field.
 626           (url-http-handle-authentication nil))
 627          (402
 628           ;; This code is reserved for future use
 629           (url-mark-buffer-as-dead buffer)
 630           (error "Somebody wants you to give them money"))
 631          (403
 632           ;; The server understood the request, but is refusing to
 633           ;; fulfill it.  Authorization will not help and the request
 634           ;; SHOULD NOT be repeated.
 635           (setq success t))
 636          (404
 637           ;; Not found
 638           (setq success t))
 639          (405
 640           ;; The method specified in the Request-Line is not allowed
 641           ;; for the resource identified by the Request-URI.  The
 642           ;; response MUST include an Allow header containing a list of
 643           ;; valid methods for the requested resource.
 644           (setq success t))
 645          (406
 646           ;; The resource identified by the request is only capable of
 647           ;; generating response entities which have content
 648           ;; characteristics nota cceptable according to the accept
 649           ;; headers sent in the request.
 650           (setq success t))
 651          (407
 652           ;; This code is similar to 401 (Unauthorized), but indicates
 653           ;; that the client must first authenticate itself with the
 654           ;; proxy.  The proxy MUST return a Proxy-Authenticate header
 655           ;; field containing a challenge applicable to the proxy for
 656           ;; the requested resource.
 657           (url-http-handle-authentication t))
 658          (408
 659           ;; The client did not produce a request within the time that
 660           ;; the server was prepared to wait.  The client MAY repeat
 661           ;; the request without modifications at any later time.
 662           (setq success t))
 663          (409
 664           ;; The request could not be completed due to a conflict with
 665           ;; the current state of the resource.  This code is only
 666           ;; allowed in situations where it is expected that the user
 667           ;; mioght be able to resolve the conflict and resubmit the
 668           ;; request.  The response body SHOULD include enough
 669           ;; information for the user to recognize the source of the
 670           ;; conflict.
 671           (setq success t))
 672          (410
 673           ;; The requested resource is no longer available at the
 674           ;; server and no forwarding address is known.
 675           (setq success t))
 676          (411
 677           ;; The server refuses to accept the request without a defined
 678           ;; Content-Length.  The client MAY repeat the request if it
 679           ;; adds a valid Content-Length header field containing the
 680           ;; length of the message-body in the request message.
 681           ;;
 682           ;; NOTE - this will never happen because
 683           ;; `url-http-create-request' automatically calculates the
 684           ;; content-length.
 685           (setq success t))
 686          (412
 687           ;; The precondition given in one or more of the
 688           ;; request-header fields evaluated to false when it was
 689           ;; tested on the server.
 690           (setq success t))
 691          ((413 414)
 692           ;; The server is refusing to process a request because the
 693           ;; request entity|URI is larger than the server is willing or
 694           ;; able to process.
 695           (setq success t))
 696          (415
 697           ;; The server is refusing to service the request because the
 698           ;; entity of the request is in a format not supported by the
 699           ;; requested resource for the requested method.
 700           (setq success t))
 701          (416
 702           ;; A server SHOULD return a response with this status code if
 703           ;; a request included a Range request-header field, and none
 704           ;; of the range-specifier values in this field overlap the
 705           ;; current extent of the selected resource, and the request
 706           ;; did not include an If-Range request-header field.
 707           (setq success t))
 708          (417
 709           ;; The expectation given in an Expect request-header field
 710           ;; could not be met by this server, or, if the server is a
 711           ;; proxy, the server has unambiguous evidence that the
 712           ;; request could not be met by the next-hop server.
 713           (setq success t))
 714          (otherwise
 715           ;; The request could not be understood by the server due to
 716           ;; malformed syntax.  The client SHOULD NOT repeat the
 717           ;; request without modifications.
 718           (setq success t)))
 719        ;; Tell the callback that an error occurred, and what the
 720        ;; status code was.
 721        (when success
 722          (setf (car url-callback-arguments)
 723                (nconc (list :error (list 'error 'http url-http-response-status))
 724                       (car url-callback-arguments)))))
 725       (5
 726        ;; 500 Internal server error
 727        ;; 501 Not implemented
 728        ;; 502 Bad gateway
 729        ;; 503 Service unavailable
 730        ;; 504 Gateway time-out
 731        ;; 505 HTTP version not supported
 732        ;; 507 Insufficient storage
 733        (setq success t)
 734        (case url-http-response-status
 735          (501
 736           ;; The server does not support the functionality required to
 737           ;; fulfill the request.
 738           nil)
 739          (502
 740           ;; The server, while acting as a gateway or proxy, received
 741           ;; an invalid response from the upstream server it accessed
 742           ;; in attempting to fulfill the request.
 743           nil)
 744          (503
 745           ;; The server is currently unable to handle the request due
 746           ;; to a temporary overloading or maintenance of the server.
 747           ;; The implication is that this is a temporary condition
 748           ;; which will be alleviated after some delay.  If known, the
 749           ;; length of the delay MAY be indicated in a Retry-After
 750           ;; header.  If no Retry-After is given, the client SHOULD
 751           ;; handle the response as it would for a 500 response.
 752           nil)
 753          (504
 754           ;; The server, while acting as a gateway or proxy, did not
 755           ;; receive a timely response from the upstream server
 756           ;; specified by the URI (e.g. HTTP, FTP, LDAP) or some other
 757           ;; auxiliary server (e.g. DNS) it needed to access in
 758           ;; attempting to complete the request.
 759           nil)
 760          (505
 761           ;; The server does not support, or refuses to support, the
 762           ;; HTTP protocol version that was used in the request
 763           ;; message.
 764           nil)
 765          (507                           ; DAV
 766           ;; The method could not be performed on the resource
 767           ;; because the server is unable to store the representation
 768           ;; needed to successfully complete the request.  This
 769           ;; condition is considered to be temporary.  If the request
 770           ;; which received this status code was the result of a user
 771           ;; action, the request MUST NOT be repeated until it is
 772           ;; requested by a separate user action.
 773           nil))
 774        ;; Tell the callback that an error occurred, and what the
 775        ;; status code was.
 776        (when success
 777          (setf (car url-callback-arguments)
 778                (nconc (list :error (list 'error 'http url-http-response-status))
 779                       (car url-callback-arguments)))))
 780       (otherwise
 781        (error "Unknown class of HTTP response code: %d (%d)"
 782               class url-http-response-status)))
 783     (if (not success)
 784         (url-mark-buffer-as-dead buffer))
 785     (url-http-debug "Finished parsing HTTP headers: %S" success)
 786     (widen)
 787     success))
 788
 789 ;; Miscellaneous
 790 (defun url-http-activate-callback ()
 791   "Activate callback specified when this buffer was created."
 792   (declare (special url-http-process
 793                     url-callback-function
 794                     url-callback-arguments))
 795   (url-http-mark-connection-as-free (url-host url-current-object)
 796                                     (url-port url-current-object)
 797                                     url-http-process)
 798   (url-http-debug "Activating callback in buffer (%s)" (buffer-name))
 799   (apply url-callback-function url-callback-arguments))
 800
 801 ;; )
 802
 803 ;; These unfortunately cannot be macros... please ignore them!
 804 (defun url-http-idle-sentinel (proc why)
 805   "Remove this (now defunct) process PROC from the list of open connections."
 806   (maphash (lambda (key val)
 807                 (if (memq proc val)
 808                     (puthash key (delq proc val) url-http-open-connections)))
 809               url-http-open-connections))
 810
 811 (defun url-http-end-of-document-sentinel (proc why)
 812   ;; Sentinel used for old HTTP/0.9 or connections we know are going
 813   ;; to die as the 'end of document' notifier.
 814   (url-http-debug "url-http-end-of-document-sentinel in buffer (%s)"
 815                   (process-buffer proc))
 816   (url-http-idle-sentinel proc why)
 817   (with-current-buffer (process-buffer proc)
 818     (goto-char (point-min))
 819     (if (not (looking-at "HTTP/"))
 820         ;; HTTP/0.9 just gets passed back no matter what
 821         (url-http-activate-callback)
 822       (if (url-http-parse-headers)
 823           (url-http-activate-callback)))))
 824
 825 (defun url-http-simple-after-change-function (st nd length)
 826   ;; Function used when we do NOT know how long the document is going to be
 827   ;; Just _very_ simple 'downloaded %d' type of info.
 828   (declare (special url-http-end-of-headers))
 829   (url-lazy-message "Reading %s..." (url-pretty-length nd)))
 830
 831 (defun url-http-content-length-after-change-function (st nd length)
 832   "Function used when we DO know how long the document is going to be.
 833 More sophisticated percentage downloaded, etc.
 834 Also does minimal parsing of HTTP headers and will actually cause
 835 the callback to be triggered."
 836   (declare (special url-current-object
 837                     url-http-end-of-headers
 838                     url-http-content-length
 839                     url-http-content-type
 840                     url-http-process))
 841   (if url-http-content-type
 842       (url-display-percentage
 843        "Reading [%s]... %s of %s (%d%%)"
 844        (url-percentage (- nd url-http-end-of-headers)
 845                        url-http-content-length)
 846        url-http-content-type
 847        (url-pretty-length (- nd url-http-end-of-headers))
 848        (url-pretty-length url-http-content-length)
 849        (url-percentage (- nd url-http-end-of-headers)
 850                        url-http-content-length))
 851     (url-display-percentage
 852      "Reading... %s of %s (%d%%)"
 853      (url-percentage (- nd url-http-end-of-headers)
 854                      url-http-content-length)
 855      (url-pretty-length (- nd url-http-end-of-headers))
 856      (url-pretty-length url-http-content-length)
 857      (url-percentage (- nd url-http-end-of-headers)
 858                      url-http-content-length)))
 859
 860   (if (> (- nd url-http-end-of-headers) url-http-content-length)
 861       (progn
 862         ;; Found the end of the document!  Wheee!
 863         (url-display-percentage nil nil)
 864         (url-lazy-message "Reading... done.")
 865         (if (url-http-parse-headers)
 866             (url-http-activate-callback)))))
 867
 868 (defun url-http-chunked-encoding-after-change-function (st nd length)
 869   "Function used when dealing with 'chunked' encoding.
 870 Cannot give a sophisticated percentage, but we need a different
 871 function to look for the special 0-length chunk that signifies
 872 the end of the document."
 873   (declare (special url-current-object
 874                     url-http-end-of-headers
 875                     url-http-content-type
 876                     url-http-chunked-length
 877                     url-http-chunked-counter
 878                     url-http-process url-http-chunked-start))
 879   (save-excursion
 880     (goto-char st)
 881     (let ((read-next-chunk t)
 882           (case-fold-search t)
 883           (regexp nil)
 884           (no-initial-crlf nil))
 885       ;; We need to loop thru looking for more chunks even within
 886       ;; one after-change-function call.
 887       (while read-next-chunk
 888         (setq no-initial-crlf (= 0 url-http-chunked-counter))
 889         (if url-http-content-type
 890             (url-display-percentage nil
 891              "Reading [%s]... chunk #%d"
 892              url-http-content-type url-http-chunked-counter)
 893           (url-display-percentage nil
 894            "Reading... chunk #%d"
 895            url-http-chunked-counter))
 896         (url-http-debug "Reading chunk %d (%d %d %d)"
 897                         url-http-chunked-counter st nd length)
 898         (setq regexp (if no-initial-crlf
 899                          "\\([0-9a-z]+\\).*\r?\n"
 900                        "\r?\n\\([0-9a-z]+\\).*\r?\n"))
 901
 902         (if url-http-chunked-start
 903             ;; We know how long the chunk is supposed to be, skip over
 904             ;; leading crap if possible.
 905             (if (> nd (+ url-http-chunked-start url-http-chunked-length))
 906                 (progn
 907                   (url-http-debug "Got to the end of chunk #%d!"
 908                                   url-http-chunked-counter)
 909                   (goto-char (+ url-http-chunked-start
 910                                 url-http-chunked-length)))
 911               (url-http-debug "Still need %d bytes to hit end of chunk"
 912                               (- (+ url-http-chunked-start
 913                                     url-http-chunked-length)
 914                                  nd))
 915               (setq read-next-chunk nil)))
 916         (if (not read-next-chunk)
 917             (url-http-debug "Still spinning for next chunk...")
 918           (if no-initial-crlf (skip-chars-forward "\r\n"))
 919           (if (not (looking-at regexp))
 920               (progn
 921            ;; Must not have received the entirety of the chunk header,
 922                 ;; need to spin some more.
 923                 (url-http-debug "Did not see start of chunk @ %d!" (point))
 924                 (setq read-next-chunk nil))
 925             (add-text-properties (match-beginning 0) (match-end 0)
 926                                  (list 'start-open t
 927                                        'end-open t
 928                                        'chunked-encoding t
 929                                        'face 'cursor
 930                                        'invisible t))
 931             (setq url-http-chunked-length (string-to-number (buffer-substring
 932                                                              (match-beginning 1)
 933                                                              (match-end 1))
 934                                                             16)
 935                   url-http-chunked-counter (1+ url-http-chunked-counter)
 936                   url-http-chunked-start (set-marker
 937                                           (or url-http-chunked-start
 938                                               (make-marker))
 939                                           (match-end 0)))
 940 ;           (if (not url-http-debug)
 941                 (delete-region (match-beginning 0) (match-end 0));)
 942             (url-http-debug "Saw start of chunk %d (length=%d, start=%d"
 943                             url-http-chunked-counter url-http-chunked-length
 944                             (marker-position url-http-chunked-start))
 945             (if (= 0 url-http-chunked-length)
 946                 (progn
 947                   ;; Found the end of the document!  Wheee!
 948                   (url-http-debug "Saw end of stream chunk!")
 949                   (setq read-next-chunk nil)
 950                   (url-display-percentage nil nil)
 951                   (goto-char (match-end 1))
 952                   (if (re-search-forward "^\r*$" nil t)
 953                       (url-http-debug "Saw end of trailers..."))
 954                   (if (url-http-parse-headers)
 955                       (url-http-activate-callback))))))))))
 956
 957 (defun url-http-wait-for-headers-change-function (st nd length)
 958   ;; This will wait for the headers to arrive and then splice in the
 959   ;; next appropriate after-change-function, etc.
 960   (declare (special url-current-object
 961                     url-http-end-of-headers
 962                     url-http-content-type
 963                     url-http-content-length
 964                     url-http-transfer-encoding
 965                     url-callback-function
 966                     url-callback-arguments
 967                     url-http-process
 968                     url-http-method
 969                     url-http-after-change-function
 970                     url-http-response-status))
 971   (url-http-debug "url-http-wait-for-headers-change-function (%s)"
 972                   (buffer-name))
 973   (when (not (bobp))
 974     (let ((end-of-headers nil)
 975           (old-http nil)
 976           (content-length nil))
 977       (goto-char (point-min))
 978       (if (and (looking-at ".*\n")      ; have one line at least
 979                (not (looking-at "^HTTP/[1-9]\\.[0-9]")))
 980           ;; Not HTTP/x.y data, must be 0.9
 981           ;; God, I wish this could die.
 982           (setq end-of-headers t
 983                 url-http-end-of-headers 0
 984                 old-http t)
 985         (when (re-search-forward "^\r*$" nil t)
 986           ;; Saw the end of the headers
 987           (url-http-debug "Saw end of headers... (%s)" (buffer-name))
 988           (setq url-http-end-of-headers (set-marker (make-marker)
 989                                                     (point))
 990                 end-of-headers t)
 991           (url-http-clean-headers)))
 992
 993       (if (not end-of-headers)
 994           ;; Haven't seen the end of the headers yet, need to wait
 995           ;; for more data to arrive.
 996           nil
 997         (if old-http
 998             (message "HTTP/0.9 How I hate thee!")
 999           (progn
1000             (url-http-parse-response)
1001             (mail-narrow-to-head)
1002             ;;(narrow-to-region (point-min) url-http-end-of-headers)
1003             (setq url-http-transfer-encoding (mail-fetch-field
1004                                               "transfer-encoding")
1005                   url-http-content-type (mail-fetch-field "content-type"))
1006             (if (mail-fetch-field "content-length")
1007                 (setq url-http-content-length
1008                       (string-to-number (mail-fetch-field "content-length"))))
1009             (widen)))
1010         (when url-http-transfer-encoding
1011           (setq url-http-transfer-encoding
1012                 (downcase url-http-transfer-encoding)))
1013
1014         (cond
1015          ((or (= url-http-response-status 204)
1016               (= url-http-response-status 205))
1017           (url-http-debug "%d response must have headers only (%s)."
1018                           url-http-response-status (buffer-name))
1019           (when (url-http-parse-headers)
1020             (url-http-activate-callback)))
1021          ((string= "HEAD" url-http-method)
1022           ;; A HEAD request is _ALWAYS_ terminated by the header
1023           ;; information, regardless of any entity headers,
1024           ;; according to section 4.4 of the HTTP/1.1 draft.
1025           (url-http-debug "HEAD request must have headers only (%s)."
1026                           (buffer-name))
1027           (when (url-http-parse-headers)
1028             (url-http-activate-callback)))
1029          ((string= "CONNECT" url-http-method)
1030           ;; A CONNECT request is finished, but we cannot stick this
1031           ;; back on the free connectin list
1032           (url-http-debug "CONNECT request must have headers only.")
1033           (when (url-http-parse-headers)
1034             (url-http-activate-callback)))
1035          ((equal url-http-response-status 304)
1036           ;; Only allowed to have a header section.  We have to handle
1037           ;; this here instead of in url-http-parse-headers because if
1038           ;; you have a cached copy of something without a known
1039           ;; content-length, and try to retrieve it from the cache, we'd
1040           ;; fall into the 'being dumb' section and wait for the
1041           ;; connection to terminate, which means we'd wait for 10
1042           ;; seconds for the keep-alives to time out on some servers.
1043           (when (url-http-parse-headers)
1044             (url-http-activate-callback)))
1045          (old-http
1046           ;; HTTP/0.9 always signaled end-of-connection by closing the
1047           ;; connection.
1048           (url-http-debug
1049            "Saw HTTP/0.9 response, connection closed means end of document.")
1050           (setq url-http-after-change-function
1051                 'url-http-simple-after-change-function))
1052          ((equal url-http-transfer-encoding "chunked")
1053           (url-http-debug "Saw chunked encoding.")
1054           (setq url-http-after-change-function
1055                 'url-http-chunked-encoding-after-change-function)
1056           (when (> nd url-http-end-of-headers)
1057             (url-http-debug
1058              "Calling initial chunked-encoding for extra data at end of headers")
1059             (url-http-chunked-encoding-after-change-function
1060              (marker-position url-http-end-of-headers) nd
1061              (- nd url-http-end-of-headers))))
1062          ((integerp url-http-content-length)
1063           (url-http-debug
1064            "Got a content-length, being smart about document end.")
1065           (setq url-http-after-change-function
1066                 'url-http-content-length-after-change-function)
1067           (cond
1068            ((= 0 url-http-content-length)
1069             ;; We got a NULL body!  Activate the callback
1070             ;; immediately!
1071             (url-http-debug
1072              "Got 0-length content-length, activating callback immediately.")
1073             (when (url-http-parse-headers)
1074               (url-http-activate-callback)))
1075            ((> nd url-http-end-of-headers)
1076             ;; Have some leftover data
1077             (url-http-debug "Calling initial content-length for extra data at end of headers")
1078             (url-http-content-length-after-change-function
1079              (marker-position url-http-end-of-headers)
1080              nd
1081              (- nd url-http-end-of-headers)))
1082            (t
1083             nil)))
1084          (t
1085           (url-http-debug "No content-length, being dumb.")
1086           (setq url-http-after-change-function
1087                 'url-http-simple-after-change-function)))))
1088     ;; We are still at the beginning of the buffer... must just be
1089     ;; waiting for a response.
1090     (url-http-debug "Spinning waiting for headers..."))
1091   (goto-char (point-max)))
1092
1093 ;;;###autoload
1094 (defun url-http (url callback cbargs)
1095   "Retrieve URL via HTTP asynchronously.
1096 URL must be a parsed URL.  See `url-generic-parse-url' for details.
1097 When retrieval is completed, the function CALLBACK is executed with
1098 CBARGS as the arguments."
1099   (check-type url vector "Need a pre-parsed URL.")
1100   (declare (special url-current-object
1101                     url-http-end-of-headers
1102                     url-http-content-type
1103                     url-http-content-length
1104                     url-http-transfer-encoding
1105                     url-http-after-change-function
1106                     url-callback-function
1107                     url-callback-arguments
1108                     url-http-method
1109                     url-http-extra-headers
1110                     url-http-data
1111                     url-http-chunked-length
1112                     url-http-chunked-start
1113                     url-http-chunked-counter
1114                     url-http-process))
1115   (let* ((host (url-host (or url-using-proxy url)))
1116          (port (url-port (or url-using-proxy url)))
1117          (connection (url-http-find-free-connection host port))
1118          (buffer (generate-new-buffer (format " *http %s:%d*" host port))))
1119     (if (not connection)
1120         ;; Failed to open the connection for some reason
1121         (progn
1122           (kill-buffer buffer)
1123           (setq buffer nil)
1124           (error "Could not create connection to %s:%d" host port))
1125       (with-current-buffer buffer
1126         (mm-disable-multibyte)
1127         (setq url-current-object url
1128               mode-line-format "%b [%s]")
1129
1130         (dolist (var '(url-http-end-of-headers
1131                        url-http-content-type
1132                        url-http-content-length
1133                        url-http-transfer-encoding
1134                        url-http-after-change-function
1135                        url-http-response-version
1136                        url-http-response-status
1137                        url-http-chunked-length
1138                        url-http-chunked-counter
1139                        url-http-chunked-start
1140                        url-callback-function
1141                        url-callback-arguments
1142                        url-http-process
1143                        url-http-method
1144                        url-http-extra-headers
1145                        url-http-data
1146                        url-http-target-url
1147                        url-http-connection-opened
1148                        url-http-proxy))
1149           (set (make-local-variable var) nil))
1150
1151         (setq url-http-method (or url-request-method "GET")
1152               url-http-extra-headers url-request-extra-headers
1153               url-http-data url-request-data
1154               url-http-process connection
1155               url-http-chunked-length nil
1156               url-http-chunked-start nil
1157               url-http-chunked-counter 0
1158               url-callback-function callback
1159               url-callback-arguments cbargs
1160               url-http-after-change-function 'url-http-wait-for-headers-change-function
1161               url-http-target-url url-current-object
1162               url-http-connection-opened nil
1163               url-http-proxy url-using-proxy)
1164
1165         (set-process-buffer connection buffer)
1166         (set-process-filter connection 'url-http-generic-filter)
1167         (let ((status (process-status connection)))
1168           (cond
1169            ((eq status 'connect)
1170             ;; Asynchronous connection
1171             (set-process-sentinel connection 'url-http-async-sentinel))
1172            ((eq status 'failed)
1173             ;; Asynchronous connection failed
1174             (error "Could not create connection to %s:%d" host port))
1175            (t
1176             (set-process-sentinel connection 'url-http-end-of-document-sentinel)
1177             (process-send-string connection (url-http-create-request)))))))
1178     buffer))
1179
1180 (defun url-http-async-sentinel (proc why)
1181   (declare (special url-callback-arguments))
1182   ;; We are performing an asynchronous connection, and a status change
1183   ;; has occurred.
1184   (with-current-buffer (process-buffer proc)
1185     (cond
1186      (url-http-connection-opened
1187       (url-http-end-of-document-sentinel proc why))
1188      ((string= (substring why 0 4) "open")
1189       (setq url-http-connection-opened t)
1190       (process-send-string proc (url-http-create-request)))
1191      (t
1192       (setf (car url-callback-arguments)
1193             (nconc (list :error (list 'error 'connection-failed why
1194                                       :host (url-host (or url-http-proxy url-current-object))
1195                                       :service (url-port (or url-http-proxy url-current-object))))
1196                    (car url-callback-arguments)))
1197       (url-http-activate-callback)))))
1198
1199 ;; Since Emacs 19/20 does not allow you to change the
1200 ;; `after-change-functions' hook in the midst of running them, we fake
1201 ;; an after change by hooking into the process filter and inserting
1202 ;; the data ourselves.  This is slightly less efficient, but there
1203 ;; were tons of weird ways the after-change code was biting us in the
1204 ;; shorts.
1205 (defun url-http-generic-filter (proc data)
1206   ;; Sometimes we get a zero-length data chunk after the process has
1207   ;; been changed to 'free', which means it has no buffer associated
1208   ;; with it.  Do nothing if there is no buffer, or 0 length data.
1209   (declare (special url-http-after-change-function))
1210   (and (process-buffer proc)
1211        (/= (length data) 0)
1212        (with-current-buffer (process-buffer proc)
1213          (url-http-debug "Calling after change function `%s' for `%S'" url-http-after-change-function proc)
1214          (funcall url-http-after-change-function
1215                   (point-max)
1216                   (progn
1217                     (goto-char (point-max))
1218                     (insert data)
1219                     (point-max))
1220                   (length data)))))
1221
1222 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1223 ;;; file-name-handler stuff from here on out
1224 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1225 (defalias 'url-http-symbol-value-in-buffer
1226   (if (fboundp 'symbol-value-in-buffer)
1227       'symbol-value-in-buffer
1228     (lambda (symbol buffer &optional unbound-value)
1229       "Return the value of SYMBOL in BUFFER, or UNBOUND-VALUE if it is unbound."
1230       (with-current-buffer buffer
1231         (if (not (boundp symbol))
1232             unbound-value
1233           (symbol-value symbol))))))
1234
1235 (defun url-http-head (url)
1236   (let ((url-request-method "HEAD")
1237         (url-request-data nil))
1238     (url-retrieve-synchronously url)))
1239
1240 ;;;###autoload
1241 (defun url-http-file-exists-p (url)
1242   (let ((status nil)
1243         (exists nil)
1244         (buffer (url-http-head url)))
1245     (if (not buffer)
1246         (setq exists nil)
1247       (setq status (url-http-symbol-value-in-buffer 'url-http-response-status
1248                                                     buffer 500)
1249             exists (and (integerp status)
1250                         (>= status 200) (< status 300)))
1251       (kill-buffer buffer))
1252     exists))
1253
1254 ;;;###autoload
1255 (defalias 'url-http-file-readable-p 'url-http-file-exists-p)
1256
1257 (defun url-http-head-file-attributes (url &optional id-format)
1258   (let ((buffer (url-http-head url)))
1259     (when buffer
1260       (prog1
1261           (list
1262            nil                          ;dir / link / normal file
1263            1                            ;number of links to file.
1264            0 0                          ;uid ; gid
1265            nil nil nil                  ;atime ; mtime ; ctime
1266            (url-http-symbol-value-in-buffer 'url-http-content-length
1267                                             buffer -1)
1268            (eval-when-compile (make-string 10 ?-))
1269            nil nil nil)          ;whether gid would change ; inode ; device.
1270         (kill-buffer buffer)))))
1271
1272 ;;;###autoload
1273 (defun url-http-file-attributes (url &optional id-format)
1274   (if (url-dav-supported-p url)
1275       (url-dav-file-attributes url id-format)
1276     (url-http-head-file-attributes url id-format)))
1277
1278 ;;;###autoload
1279 (defun url-http-options (url)
1280   "Return a property list describing options available for URL.
1281 This list is retrieved using the `OPTIONS' HTTP method.
1282
1283 Property list members:
1284
1285 methods
1286   A list of symbols specifying what HTTP methods the resource
1287   supports.
1288
1289 dav
1290   A list of numbers specifying what DAV protocol/schema versions are
1291   supported.
1292
1293 dasl
1294   A list of supported DASL search types supported (string form)
1295
1296 ranges
1297   A list of the units available for use in partial document fetches.
1298
1299 p3p
1300   The `Platform For Privacy Protection' description for the resource.
1301   Currently this is just the raw header contents.  This is likely to
1302   change once P3P is formally supported by the URL package or
1303   Emacs/W3."
1304   (let* ((url-request-method "OPTIONS")
1305          (url-request-data nil)
1306          (buffer (url-retrieve-synchronously url))
1307          (header nil)
1308          (options nil))
1309     (when (and buffer (= 2 (/ (url-http-symbol-value-in-buffer
1310                                'url-http-response-status buffer 0) 100)))
1311       ;; Only parse the options if we got a 2xx response code!
1312       (with-current-buffer buffer
1313         (save-restriction
1314           (save-match-data
1315             (mail-narrow-to-head)
1316
1317             ;; Figure out what methods are supported.
1318             (when (setq header (mail-fetch-field "allow"))
1319               (setq options (plist-put
1320                              options 'methods
1321                              (mapcar 'intern (split-string header "[ ,]+")))))
1322
1323             ;; Check for DAV
1324             (when (setq header (mail-fetch-field "dav"))
1325               (setq options (plist-put
1326                              options 'dav
1327                              (delq 0
1328                                    (mapcar 'string-to-number
1329                                            (split-string header "[, ]+"))))))
1330
1331             ;; Now for DASL
1332             (when (setq header (mail-fetch-field "dasl"))
1333               (setq options (plist-put
1334                              options 'dasl
1335                              (split-string header "[, ]+"))))
1336
1337             ;; P3P - should get more detailed here.  FIXME
1338             (when (setq header (mail-fetch-field "p3p"))
1339               (setq options (plist-put options 'p3p header)))
1340
1341             ;; Check for whether they accept byte-range requests.
1342             (when (setq header (mail-fetch-field "accept-ranges"))
1343               (setq options (plist-put
1344                              options 'ranges
1345                              (delq 'none
1346                                    (mapcar 'intern
1347                                            (split-string header "[, ]+"))))))
1348             ))))
1349     (if buffer (kill-buffer buffer))
1350     options))
1351
1352 ;; HTTPS.  This used to be in url-https.el, but that file collides
1353 ;; with url-http.el on systems with 8-character file names.
1354 (require 'tls)
1355
1356 ;;;###autoload
1357 (defconst url-https-default-port 443 "Default HTTPS port.")
1358 ;;;###autoload
1359 (defconst url-https-asynchronous-p t "HTTPS retrievals are asynchronous.")
1360 ;;;###autoload
1361 (defalias 'url-https-expand-file-name 'url-http-expand-file-name)
1362
1363 (defmacro url-https-create-secure-wrapper (method args)
1364   `(defun ,(intern (format (if method "url-https-%s" "url-https") method)) ,args
1365     ,(format "HTTPS wrapper around `%s' call." (or method "url-http"))
1366     (let ((url-gateway-method 'tls))
1367       (,(intern (format (if method "url-http-%s" "url-http") method))
1368        ,@(remove '&rest (remove '&optional args))))))
1369
1370 ;;;###autoload (autoload 'url-https "url-http")
1371 (url-https-create-secure-wrapper nil (url callback cbargs))
1372 ;;;###autoload (autoload 'url-https-file-exists-p "url-http")
1373 (url-https-create-secure-wrapper file-exists-p (url))
1374 ;;;###autoload (autoload 'url-https-file-readable-p "url-http")
1375 (url-https-create-secure-wrapper file-readable-p (url))
1376 ;;;###autoload (autoload 'url-https-file-attributes "url-http")
1377 (url-https-create-secure-wrapper file-attributes (url &optional id-format))
1378
1379 (provide 'url-http)
1380
1381 ;; arch-tag: ba7c59ae-c0f4-4a31-9617-d85f221732ee
1382 ;;; url-http.el ends here