lisp/replace.el

   1 ;;; replace.el --- replace commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992, 1994, 1996, 1997, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005  Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package supplies the string and regular-expression replace functions
  28 ;; documented in the Emacs user's manual.
  29
  30 ;;; Code:
  31
  32 (defcustom case-replace t
  33   "*Non-nil means `query-replace' should preserve case in replacements."
  34   :type 'boolean
  35   :group 'matching)
  36
  37 (defvar query-replace-history nil)
  38
  39 (defvar query-replace-interactive nil
  40   "Non-nil means `query-replace' uses the last search string.
  41 That becomes the \"string to replace\".")
  42
  43 (defcustom query-replace-from-history-variable 'query-replace-history
  44   "History list to use for the FROM argument of `query-replace' commands.
  45 The value of this variable should be a symbol; that symbol
  46 is used as a variable to hold a history list for the strings
  47 or patterns to be replaced."
  48   :group 'matching
  49   :type 'symbol
  50   :version "20.3")
  51
  52 (defcustom query-replace-to-history-variable 'query-replace-history
  53   "History list to use for the TO argument of `query-replace' commands.
  54 The value of this variable should be a symbol; that symbol
  55 is used as a variable to hold a history list for replacement
  56 strings or patterns."
  57   :group 'matching
  58   :type 'symbol
  59   :version "20.3")
  60
  61 (defcustom query-replace-skip-read-only nil
  62   "*Non-nil means `query-replace' and friends ignore read-only matches."
  63   :type 'boolean
  64   :group 'matching
  65   :version "22.1")
  66
  67 (defcustom query-replace-highlight t
  68   "*Non-nil means to highlight matches during query replacement."
  69   :type 'boolean
  70   :group 'matching)
  71
  72 (defcustom query-replace-lazy-highlight t
  73   "*Controls the lazy-highlighting during query replacements.
  74 When non-nil, all text in the buffer matching the current match
  75 is highlighted lazily using isearch lazy highlighting (see
  76 `lazy-highlight-initial-delay' and `lazy-highlight-interval')."
  77   :type 'boolean
  78   :group 'lazy-highlight
  79   :group 'matching
  80   :version "22.1")
  81
  82 (defface query-replace
  83   '((t (:inherit isearch)))
  84   "Face for highlighting query replacement matches."
  85   :group 'matching
  86   :version "22.1")
  87
  88 (defun query-replace-descr (string)
  89   (mapconcat 'isearch-text-char-description string ""))
  90
  91 (defun query-replace-read-from (string regexp-flag)
  92   "Query and return the `from' argument of a query-replace operation.
  93 The return value can also be a pair (FROM . TO) indicating that the user
  94 wants to replace FROM with TO."
  95   (if query-replace-interactive
  96       (car (if regexp-flag regexp-search-ring search-ring))
  97     (let* ((lastfrom (car (symbol-value query-replace-from-history-variable)))
  98            (lastto (car (symbol-value query-replace-to-history-variable)))
  99            (from
 100             ;; The save-excursion here is in case the user marks and copies
 101             ;; a region in order to specify the minibuffer input.
 102             ;; That should not clobber the region for the query-replace itself.
 103             (save-excursion
 104               (when (equal lastfrom lastto)
 105                 ;; Typically, this is because the two histlists are shared.
 106                 (setq lastfrom (cadr (symbol-value
 107                                       query-replace-from-history-variable))))
 108               (read-from-minibuffer
 109                (if (and lastto lastfrom)
 110                    (format "%s (default %s -> %s): " string
 111                            (query-replace-descr lastfrom)
 112                            (query-replace-descr lastto))
 113                  (format "%s: " string))
 114                nil nil nil
 115                query-replace-from-history-variable
 116                nil t t))))
 117       (if (and (zerop (length from)) lastto lastfrom)
 118           (progn
 119             (set query-replace-from-history-variable
 120                  (cdr (symbol-value query-replace-from-history-variable)))
 121             (cons lastfrom
 122                   (query-replace-compile-replacement lastto regexp-flag)))
 123         ;; Warn if user types \n or \t, but don't reject the input.
 124         (and regexp-flag
 125              (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\(\\\\[nt]\\)" from)
 126              (let ((match (match-string 3 from)))
 127                (cond
 128                 ((string= match "\\n")
 129                  (message "Note: `\\n' here doesn't match a newline; to do that, type C-q C-j instead"))
 130                 ((string= match "\\t")
 131                  (message "Note: `\\t' here doesn't match a tab; to do that, just type TAB")))
 132                (sit-for 2)))
 133         from))))
 134
 135 (defun query-replace-compile-replacement (to regexp-flag)
 136   "Maybe convert a regexp replacement TO to Lisp.
 137 Returns a list suitable for `perform-replace' if necessary,
 138 the original string if not."
 139   (if (and regexp-flag
 140            (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\\\[,#]" to))
 141       (let (pos list char)
 142         (while
 143             (progn
 144               (setq pos (match-end 0))
 145               (push (substring to 0 (- pos 2)) list)
 146               (setq char (aref to (1- pos))
 147                     to (substring to pos))
 148               (cond ((eq char ?\#)
 149                      (push '(number-to-string replace-count) list))
 150                     ((eq char ?\,)
 151                      (setq pos (read-from-string to))
 152                      (push `(replace-quote ,(car pos)) list)
 153                      (let ((end
 154                             ;; Swallow a space after a symbol
 155                             ;; if there is a space.
 156                             (if (and (or (symbolp (car pos))
 157                                          ;; Swallow a space after 'foo
 158                                          ;; but not after (quote foo).
 159                                          (and (eq (car-safe (car pos)) 'quote)
 160                                               (not (= ?\( (aref to 0)))))
 161                                      (eq (string-match " " to (cdr pos))
 162                                          (cdr pos)))
 163                                 (1+ (cdr pos))
 164                               (cdr pos))))
 165                        (setq to (substring to end)))))
 166               (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\\\[,#]" to)))
 167         (setq to (nreverse (delete "" (cons to list))))
 168         (replace-match-string-symbols to)
 169         (cons 'replace-eval-replacement
 170               (if (cdr to)
 171                   (cons 'concat to)
 172                 (car to))))
 173     to))
 174
 175
 176 (defun query-replace-read-to (from string regexp-flag)
 177   "Query and return the `to' argument of a query-replace operation."
 178   (query-replace-compile-replacement
 179    (save-excursion
 180      (read-from-minibuffer
 181       (format "%s %s with: " string (query-replace-descr from))
 182       nil nil nil
 183       query-replace-to-history-variable from t t))
 184    regexp-flag))
 185
 186 (defun query-replace-read-args (string regexp-flag &optional noerror)
 187   (unless noerror
 188     (barf-if-buffer-read-only))
 189   (let* ((from (query-replace-read-from string regexp-flag))
 190          (to (if (consp from) (prog1 (cdr from) (setq from (car from)))
 191                (query-replace-read-to from string regexp-flag))))
 192     (list from to current-prefix-arg)))
 193
 194 (defun query-replace (from-string to-string &optional delimited start end)
 195   "Replace some occurrences of FROM-STRING with TO-STRING.
 196 As each match is found, the user must type a character saying
 197 what to do with it.  For directions, type \\[help-command] at that time.
 198
 199 In Transient Mark mode, if the mark is active, operate on the contents
 200 of the region.  Otherwise, operate from point to the end of the buffer.
 201
 202 If `query-replace-interactive' is non-nil, the last incremental search
 203 string is used as FROM-STRING--you don't have to specify it with the
 204 minibuffer.
 205
 206 Matching is independent of case if `case-fold-search' is non-nil and
 207 FROM-STRING has no uppercase letters.  Replacement transfers the case
 208 pattern of the old text to the new text, if `case-replace' and
 209 `case-fold-search' are non-nil and FROM-STRING has no uppercase
 210 letters.  \(Transferring the case pattern means that if the old text
 211 matched is all caps, or capitalized, then its replacement is upcased
 212 or capitalized.)
 213
 214 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 215 only matches surrounded by word boundaries.
 216 Fourth and fifth arg START and END specify the region to operate on.
 217
 218 To customize possible responses, change the \"bindings\" in `query-replace-map'."
 219   (interactive (let ((common
 220                       (query-replace-read-args
 221                        (if (and transient-mark-mode mark-active)
 222                          "Query replace in region"
 223                          "Query replace")
 224                          nil)))
 225                  (list (nth 0 common) (nth 1 common) (nth 2 common)
 226                        ;; These are done separately here
 227                        ;; so that command-history will record these expressions
 228                        ;; rather than the values they had this time.
 229                        (if (and transient-mark-mode mark-active)
 230                            (region-beginning))
 231                        (if (and transient-mark-mode mark-active)
 232                            (region-end)))))
 233   (perform-replace from-string to-string t nil delimited nil nil start end))
 234
 235 (define-key esc-map "%" 'query-replace)
 236
 237 (defun query-replace-regexp (regexp to-string &optional delimited start end)
 238   "Replace some things after point matching REGEXP with TO-STRING.
 239 As each match is found, the user must type a character saying
 240 what to do with it.  For directions, type \\[help-command] at that time.
 241
 242 In Transient Mark mode, if the mark is active, operate on the contents
 243 of the region.  Otherwise, operate from point to the end of the buffer.
 244
 245 If `query-replace-interactive' is non-nil, the last incremental search
 246 regexp is used as REGEXP--you don't have to specify it with the
 247 minibuffer.
 248
 249 Matching is independent of case if `case-fold-search' is non-nil and
 250 REGEXP has no uppercase letters.  Replacement transfers the case
 251 pattern of the old text to the new text, if `case-replace' and
 252 `case-fold-search' are non-nil and REGEXP has no uppercase letters.
 253 \(Transferring the case pattern means that if the old text matched is
 254 all caps, or capitalized, then its replacement is upcased or
 255 capitalized.)
 256
 257 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 258 only matches surrounded by word boundaries.
 259 Fourth and fifth arg START and END specify the region to operate on.
 260
 261 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 262 and `\\=\\N' (where N is a digit) stands for
 263 whatever what matched the Nth `\\(...\\)' in REGEXP.
 264 `\\?' lets you edit the replacement text in the minibuffer
 265 at the given position for each replacement.
 266
 267 In interactive calls, the replacement text can contain `\\,'
 268 followed by a Lisp expression.  Each
 269 replacement evaluates that expression to compute the replacement
 270 string.  Inside of that expression, `\\&' is a string denoting the
 271 whole match as a string, `\\N' for a partial match, `\\#&' and `\\#N'
 272 for the whole or a partial match converted to a number with
 273 `string-to-number', and `\\#' itself for the number of replacements
 274 done so far (starting with zero).
 275
 276 If the replacement expression is a symbol, write a space after it
 277 to terminate it.  One space there, if any, will be discarded.
 278
 279 When using those Lisp features interactively in the replacement
 280 text, TO-STRING is actually made a list instead of a string.
 281 Use \\[repeat-complex-command] after this command for details."
 282   (interactive
 283    (let ((common
 284           (query-replace-read-args
 285            (if (and transient-mark-mode mark-active)
 286                "Query replace regexp in region"
 287              "Query replace regexp")
 288            t)))
 289      (list (nth 0 common) (nth 1 common) (nth 2 common)
 290            ;; These are done separately here
 291            ;; so that command-history will record these expressions
 292            ;; rather than the values they had this time.
 293            (if (and transient-mark-mode mark-active)
 294                (region-beginning))
 295            (if (and transient-mark-mode mark-active)
 296                (region-end)))))
 297   (perform-replace regexp to-string t t delimited nil nil start end))
 298
 299 (define-key esc-map [?\C-%] 'query-replace-regexp)
 300
 301 (defun query-replace-regexp-eval (regexp to-expr &optional delimited start end)
 302   "Replace some things after point matching REGEXP with the result of TO-EXPR.
 303 As each match is found, the user must type a character saying
 304 what to do with it.  For directions, type \\[help-command] at that time.
 305
 306 TO-EXPR is a Lisp expression evaluated to compute each replacement.  It may
 307 reference `replace-count' to get the number of replacements already made.
 308 If the result of TO-EXPR is not a string, it is converted to one using
 309 `prin1-to-string' with the NOESCAPE argument (which see).
 310
 311 For convenience, when entering TO-EXPR interactively, you can use `\\&' or
 312 `\\0' to stand for whatever matched the whole of REGEXP, and `\\N' (where
 313 N is a digit) to stand for whatever matched the Nth `\\(...\\)' in REGEXP.
 314 Use `\\#&' or `\\#N' if you want a number instead of a string.
 315 In interactive use, `\\#' in itself stands for `replace-count'.
 316
 317 In Transient Mark mode, if the mark is active, operate on the contents
 318 of the region.  Otherwise, operate from point to the end of the buffer.
 319
 320 If `query-replace-interactive' is non-nil, the last incremental search
 321 regexp is used as REGEXP--you don't have to specify it with the
 322 minibuffer.
 323
 324 Preserves case in each replacement if `case-replace' and `case-fold-search'
 325 are non-nil and REGEXP has no uppercase letters.
 326
 327 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 328 only matches that are surrounded by word boundaries.
 329 Fourth and fifth arg START and END specify the region to operate on."
 330   (interactive
 331    (progn
 332    (barf-if-buffer-read-only)
 333    (let* ((from
 334            ;; Let-bind the history var to disable the "foo -> bar" default.
 335            ;; Maybe we shouldn't disable this default, but for now I'll
 336            ;; leave it off.  --Stef
 337            (let ((query-replace-to-history-variable nil))
 338              (query-replace-read-from "Query replace regexp" t)))
 339           (to (list (read-from-minibuffer
 340                      (format "Query replace regexp %s with eval: "
 341                              (query-replace-descr from))
 342                      nil nil t query-replace-to-history-variable from t))))
 343      ;; We make TO a list because replace-match-string-symbols requires one,
 344      ;; and the user might enter a single token.
 345      (replace-match-string-symbols to)
 346      (list from (car to) current-prefix-arg
 347            (if (and transient-mark-mode mark-active)
 348                (region-beginning))
 349            (if (and transient-mark-mode mark-active)
 350                (region-end))))))
 351   (perform-replace regexp (cons 'replace-eval-replacement to-expr)
 352                    t 'literal delimited nil nil start end))
 353
 354 (defun map-query-replace-regexp (regexp to-strings &optional n start end)
 355   "Replace some matches for REGEXP with various strings, in rotation.
 356 The second argument TO-STRINGS contains the replacement strings,
 357 separated by spaces.  Third arg DELIMITED (prefix arg if interactive),
 358 if non-nil, means replace only matches surrounded by word boundaries.
 359 This command works like `query-replace-regexp' except that each
 360 successive replacement uses the next successive replacement string,
 361 wrapping around from the last such string to the first.
 362
 363 In Transient Mark mode, if the mark is active, operate on the contents
 364 of the region.  Otherwise, operate from point to the end of the buffer.
 365
 366 Non-interactively, TO-STRINGS may be a list of replacement strings.
 367
 368 If `query-replace-interactive' is non-nil, the last incremental search
 369 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 370
 371 A prefix argument N says to use each replacement string N times
 372 before rotating to the next.
 373 Fourth and fifth arg START and END specify the region to operate on."
 374   (interactive
 375    (let* ((from (if query-replace-interactive
 376                     (car regexp-search-ring)
 377                   (read-from-minibuffer "Map query replace (regexp): "
 378                                         nil nil nil
 379                                         'query-replace-history nil t)))
 380           (to (read-from-minibuffer
 381                (format "Query replace %s with (space-separated strings): "
 382                        (query-replace-descr from))
 383                nil nil nil
 384                'query-replace-history from t)))
 385      (list from to
 386            (and current-prefix-arg
 387                 (prefix-numeric-value current-prefix-arg))
 388            (if (and transient-mark-mode mark-active)
 389                (region-beginning))
 390            (if (and transient-mark-mode mark-active)
 391                (region-end)))))
 392   (let (replacements)
 393     (if (listp to-strings)
 394         (setq replacements to-strings)
 395       (while (/= (length to-strings) 0)
 396         (if (string-match " " to-strings)
 397             (setq replacements
 398                   (append replacements
 399                           (list (substring to-strings 0
 400                                            (string-match " " to-strings))))
 401                   to-strings (substring to-strings
 402                                        (1+ (string-match " " to-strings))))
 403           (setq replacements (append replacements (list to-strings))
 404                 to-strings ""))))
 405     (perform-replace regexp replacements t t nil n nil start end)))
 406
 407 (defun replace-string (from-string to-string &optional delimited start end)
 408   "Replace occurrences of FROM-STRING with TO-STRING.
 409 Preserve case in each match if `case-replace' and `case-fold-search'
 410 are non-nil and FROM-STRING has no uppercase letters.
 411 \(Preserving case means that if the string matched is all caps, or capitalized,
 412 then its replacement is upcased or capitalized.)
 413
 414 In Transient Mark mode, if the mark is active, operate on the contents
 415 of the region.  Otherwise, operate from point to the end of the buffer.
 416
 417 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 418 only matches surrounded by word boundaries.
 419 Fourth and fifth arg START and END specify the region to operate on.
 420
 421 If `query-replace-interactive' is non-nil, the last incremental search
 422 string is used as FROM-STRING--you don't have to specify it with the
 423 minibuffer.
 424
 425 This function is usually the wrong thing to use in a Lisp program.
 426 What you probably want is a loop like this:
 427   (while (search-forward FROM-STRING nil t)
 428     (replace-match TO-STRING nil t))
 429 which will run faster and will not set the mark or print anything.
 430 \(You may need a more complex loop if FROM-STRING can match the null string
 431 and TO-STRING is also null.)"
 432   (interactive
 433    (let ((common
 434           (query-replace-read-args
 435            (if (and transient-mark-mode mark-active)
 436                "Replace string in region"
 437              "Replace string")
 438            nil)))
 439      (list (nth 0 common) (nth 1 common) (nth 2 common)
 440            (if (and transient-mark-mode mark-active)
 441                (region-beginning))
 442            (if (and transient-mark-mode mark-active)
 443                (region-end)))))
 444   (perform-replace from-string to-string nil nil delimited nil nil start end))
 445
 446 (defun replace-regexp (regexp to-string &optional delimited start end)
 447   "Replace things after point matching REGEXP with TO-STRING.
 448 Preserve case in each match if `case-replace' and `case-fold-search'
 449 are non-nil and REGEXP has no uppercase letters.
 450
 451 In Transient Mark mode, if the mark is active, operate on the contents
 452 of the region.  Otherwise, operate from point to the end of the buffer.
 453
 454 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 455 only matches surrounded by word boundaries.
 456 Fourth and fifth arg START and END specify the region to operate on.
 457
 458 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 459 and `\\=\\N' (where N is a digit) stands for
 460 whatever what matched the Nth `\\(...\\)' in REGEXP.
 461 `\\?' lets you edit the replacement text in the minibuffer
 462 at the given position for each replacement.
 463
 464 In interactive calls, the replacement text may contain `\\,'
 465 followed by a Lisp expression used as part of the replacement
 466 text.  Inside of that expression, `\\&' is a string denoting the
 467 whole match, `\\N' a partial matches, `\\#&' and `\\#N' the
 468 respective numeric values from `string-to-number', and `\\#'
 469 itself for `replace-count', the number of replacements occured so
 470 far.
 471
 472 If your Lisp expression is an identifier and the next letter in
 473 the replacement string would be interpreted as part of it, you
 474 can wrap it with an expression like `\\,(or \\#)'.  Incidentally,
 475 for this particular case you may also enter `\\#' in the
 476 replacement text directly.
 477
 478 When using those Lisp features interactively in the replacement
 479 text, TO-STRING is actually made a list instead of a string.
 480 Use \\[repeat-complex-command] after this command for details.
 481
 482 If `query-replace-interactive' is non-nil, the last incremental search
 483 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 484
 485 This function is usually the wrong thing to use in a Lisp program.
 486 What you probably want is a loop like this:
 487   (while (re-search-forward REGEXP nil t)
 488     (replace-match TO-STRING nil nil))
 489 which will run faster and will not set the mark or print anything."
 490   (interactive
 491    (let ((common
 492           (query-replace-read-args
 493            (if (and transient-mark-mode mark-active)
 494                "Replace regexp in region"
 495              "Replace regexp")
 496            t)))
 497      (list (nth 0 common) (nth 1 common) (nth 2 common)
 498            (if (and transient-mark-mode mark-active)
 499                (region-beginning))
 500            (if (and transient-mark-mode mark-active)
 501                (region-end)))))
 502   (perform-replace regexp to-string nil t delimited nil nil start end))
 503
 504 \f
 505 (defvar regexp-history nil
 506   "History list for some commands that read regular expressions.")
 507
 508
 509 (defalias 'delete-non-matching-lines 'keep-lines)
 510 (defalias 'delete-matching-lines 'flush-lines)
 511 (defalias 'count-matches 'how-many)
 512
 513
 514 (defun keep-lines-read-args (prompt)
 515   "Read arguments for `keep-lines' and friends.
 516 Prompt for a regexp with PROMPT.
 517 Value is a list, (REGEXP)."
 518   (list (read-from-minibuffer prompt nil nil nil
 519                               'regexp-history nil t)
 520         nil nil t))
 521
 522 (defun keep-lines (regexp &optional rstart rend interactive)
 523   "Delete all lines except those containing matches for REGEXP.
 524 A match split across lines preserves all the lines it lies in.
 525 When called from Lisp (and usually interactively as well, see below)
 526 applies to all lines starting after point.
 527
 528 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 529 the matching is case-sensitive.
 530
 531 Second and third arg RSTART and REND specify the region to operate on.
 532 This command operates on (the accessible part of) all lines whose
 533 accessible part is entirely contained in the region determined by RSTART
 534 and REND.  (A newline ending a line counts as part of that line.)
 535
 536 Interactively, in Transient Mark mode when the mark is active, operate
 537 on all lines whose accessible part is entirely contained in the region.
 538 Otherwise, the command applies to all lines starting after point.
 539 When calling this function from Lisp, you can pretend that it was
 540 called interactively by passing a non-nil INTERACTIVE argument.
 541
 542 This function starts looking for the next match from the end of
 543 the previous match.  Hence, it ignores matches that overlap
 544 a previously found match."
 545
 546   (interactive
 547    (progn
 548      (barf-if-buffer-read-only)
 549      (keep-lines-read-args "Keep lines (containing match for regexp): ")))
 550   (if rstart
 551       (progn
 552         (goto-char (min rstart rend))
 553         (setq rend
 554               (progn
 555                 (save-excursion
 556                   (goto-char (max rstart rend))
 557                   (unless (or (bolp) (eobp))
 558                     (forward-line 0))
 559                   (point-marker)))))
 560     (if (and interactive transient-mark-mode mark-active)
 561         (setq rstart (region-beginning)
 562               rend (progn
 563                      (goto-char (region-end))
 564                      (unless (or (bolp) (eobp))
 565                        (forward-line 0))
 566                      (point-marker)))
 567       (setq rstart (point)
 568             rend (point-max-marker)))
 569     (goto-char rstart))
 570   (save-excursion
 571     (or (bolp) (forward-line 1))
 572     (let ((start (point))
 573           (case-fold-search  (and case-fold-search
 574                                   (isearch-no-upper-case-p regexp t))))
 575       (while (< (point) rend)
 576         ;; Start is first char not preserved by previous match.
 577         (if (not (re-search-forward regexp rend 'move))
 578             (delete-region start rend)
 579           (let ((end (save-excursion (goto-char (match-beginning 0))
 580                                      (forward-line 0)
 581                                      (point))))
 582             ;; Now end is first char preserved by the new match.
 583             (if (< start end)
 584                 (delete-region start end))))
 585
 586         (setq start (save-excursion (forward-line 1) (point)))
 587         ;; If the match was empty, avoid matching again at same place.
 588         (and (< (point) rend)
 589              (= (match-beginning 0) (match-end 0))
 590              (forward-char 1)))))
 591   (set-marker rend nil)
 592   nil)
 593
 594
 595 (defun flush-lines (regexp &optional rstart rend interactive)
 596  "Delete lines containing matches for REGEXP.
 597 When called from Lisp (and usually when called interactively as
 598 well, see below), applies to the part of the buffer after point.
 599 The line point is in is deleted if and only if it contains a
 600 match for regexp starting after point.
 601
 602 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 603 the matching is case-sensitive.
 604
 605 Second and third arg RSTART and REND specify the region to operate on.
 606 Lines partially contained in this region are deleted if and only if
 607 they contain a match entirely contained in it.
 608
 609 Interactively, in Transient Mark mode when the mark is active, operate
 610 on the contents of the region.  Otherwise, operate from point to the
 611 end of (the accessible portion of) the buffer.  When calling this function
 612 from Lisp, you can pretend that it was called interactively by passing
 613 a non-nil INTERACTIVE argument.
 614
 615 If a match is split across lines, all the lines it lies in are deleted.
 616 They are deleted _before_ looking for the next match.  Hence, a match
 617 starting on the same line at which another match ended is ignored."
 618
 619   (interactive
 620    (progn
 621      (barf-if-buffer-read-only)
 622      (keep-lines-read-args "Flush lines (containing match for regexp): ")))
 623   (if rstart
 624       (progn
 625         (goto-char (min rstart rend))
 626         (setq rend (copy-marker (max rstart rend))))
 627     (if (and interactive transient-mark-mode mark-active)
 628         (setq rstart (region-beginning)
 629               rend (copy-marker (region-end)))
 630       (setq rstart (point)
 631             rend (point-max-marker)))
 632     (goto-char rstart))
 633   (let ((case-fold-search (and case-fold-search
 634                                (isearch-no-upper-case-p regexp t))))
 635     (save-excursion
 636       (while (and (< (point) rend)
 637                   (re-search-forward regexp rend t))
 638         (delete-region (save-excursion (goto-char (match-beginning 0))
 639                                        (forward-line 0)
 640                                        (point))
 641                        (progn (forward-line 1) (point))))))
 642   (set-marker rend nil)
 643   nil)
 644
 645
 646 (defun how-many (regexp &optional rstart rend interactive)
 647   "Print and return number of matches for REGEXP following point.
 648 When called from Lisp and INTERACTIVE is omitted or nil, just return
 649 the number, do not print it; if INTERACTIVE is t, the function behaves
 650 in all respects has if it had been called interactively.
 651
 652 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 653 the matching is case-sensitive.
 654
 655 Second and third arg RSTART and REND specify the region to operate on.
 656
 657 Interactively, in Transient Mark mode when the mark is active, operate
 658 on the contents of the region.  Otherwise, operate from point to the
 659 end of (the accessible portion of) the buffer.
 660
 661 This function starts looking for the next match from the end of
 662 the previous match.  Hence, it ignores matches that overlap
 663 a previously found match."
 664
 665   (interactive
 666    (keep-lines-read-args "How many matches for (regexp): "))
 667   (save-excursion
 668     (if rstart
 669         (progn
 670           (goto-char (min rstart rend))
 671           (setq rend (max rstart rend)))
 672       (if (and interactive transient-mark-mode mark-active)
 673           (setq rstart (region-beginning)
 674                 rend (region-end))
 675         (setq rstart (point)
 676               rend (point-max)))
 677       (goto-char rstart))
 678     (let ((count 0)
 679           opoint
 680           (case-fold-search (and case-fold-search
 681                                  (isearch-no-upper-case-p regexp t))))
 682       (while (and (< (point) rend)
 683                   (progn (setq opoint (point))
 684                          (re-search-forward regexp rend t)))
 685         (if (= opoint (point))
 686             (forward-char 1)
 687           (setq count (1+ count))))
 688       (when interactive (message "%d occurrence%s"
 689                                  count
 690                                  (if (= count 1) "" "s")))
 691       count)))
 692
 693 \f
 694 (defvar occur-mode-map
 695   (let ((map (make-sparse-keymap)))
 696     (define-key map [mouse-2] 'occur-mode-mouse-goto)
 697     (define-key map "\C-c\C-c" 'occur-mode-goto-occurrence)
 698     (define-key map "\C-m" 'occur-mode-goto-occurrence)
 699     (define-key map "o" 'occur-mode-goto-occurrence-other-window)
 700     (define-key map "\C-o" 'occur-mode-display-occurrence)
 701     (define-key map "\M-n" 'occur-next)
 702     (define-key map "\M-p" 'occur-prev)
 703     (define-key map "r" 'occur-rename-buffer)
 704     (define-key map "c" 'clone-buffer)
 705     (define-key map "g" 'revert-buffer)
 706     (define-key map "q" 'quit-window)
 707     (define-key map "z" 'kill-this-buffer)
 708     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
 709     map)
 710   "Keymap for `occur-mode'.")
 711
 712 (defvar occur-revert-arguments nil
 713   "Arguments to pass to `occur-1' to revert an Occur mode buffer.
 714 See `occur-revert-function'.")
 715
 716 (defcustom occur-mode-hook '(turn-on-font-lock)
 717   "Hook run when entering Occur mode."
 718   :type 'hook
 719   :group 'matching)
 720
 721 (defcustom occur-hook nil
 722   "Hook run by Occur when there are any matches."
 723   :type 'hook
 724   :group 'matching)
 725
 726 (put 'occur-mode 'mode-class 'special)
 727 (defun occur-mode ()
 728   "Major mode for output from \\[occur].
 729 \\<occur-mode-map>Move point to one of the items in this buffer, then use
 730 \\[occur-mode-goto-occurrence] to go to the occurrence that the item refers to.
 731 Alternatively, click \\[occur-mode-mouse-goto] on an item to go to it.
 732
 733 \\{occur-mode-map}"
 734   (interactive)
 735   (kill-all-local-variables)
 736   (use-local-map occur-mode-map)
 737   (setq major-mode 'occur-mode)
 738   (setq mode-name "Occur")
 739   (set (make-local-variable 'revert-buffer-function) 'occur-revert-function)
 740   (make-local-variable 'occur-revert-arguments)
 741   (add-hook 'change-major-mode-hook 'font-lock-defontify nil t)
 742   (setq next-error-function 'occur-next-error)
 743   (run-mode-hooks 'occur-mode-hook))
 744
 745 (defun occur-revert-function (ignore1 ignore2)
 746   "Handle `revert-buffer' for Occur mode buffers."
 747   (apply 'occur-1 (append occur-revert-arguments (list (buffer-name)))))
 748
 749 (defun occur-mode-mouse-goto (event)
 750   "In Occur mode, go to the occurrence whose line you click on."
 751   (interactive "e")
 752   (let (pos)
 753     (save-excursion
 754       (set-buffer (window-buffer (posn-window (event-end event))))
 755       (save-excursion
 756         (goto-char (posn-point (event-end event)))
 757         (setq pos (occur-mode-find-occurrence))))
 758     (pop-to-buffer (marker-buffer pos))
 759     (goto-char pos)))
 760
 761 (defun occur-mode-find-occurrence ()
 762   (let ((pos (get-text-property (point) 'occur-target)))
 763     (unless pos
 764       (error "No occurrence on this line"))
 765     (unless (buffer-live-p (marker-buffer pos))
 766       (error "Buffer for this occurrence was killed"))
 767     pos))
 768
 769 (defun occur-mode-goto-occurrence ()
 770   "Go to the occurrence the current line describes."
 771   (interactive)
 772   (let ((pos (occur-mode-find-occurrence)))
 773     (pop-to-buffer (marker-buffer pos))
 774     (goto-char pos)))
 775
 776 (defun occur-mode-goto-occurrence-other-window ()
 777   "Go to the occurrence the current line describes, in another window."
 778   (interactive)
 779   (let ((pos (occur-mode-find-occurrence)))
 780     (switch-to-buffer-other-window (marker-buffer pos))
 781     (goto-char pos)))
 782
 783 (defun occur-mode-display-occurrence ()
 784   "Display in another window the occurrence the current line describes."
 785   (interactive)
 786   (let ((pos (occur-mode-find-occurrence))
 787         window
 788         ;; Bind these to ensure `display-buffer' puts it in another window.
 789         same-window-buffer-names
 790         same-window-regexps)
 791     (setq window (display-buffer (marker-buffer pos)))
 792     ;; This is the way to set point in the proper window.
 793     (save-selected-window
 794       (select-window window)
 795       (goto-char pos))))
 796
 797 (defun occur-find-match (n search message)
 798   (if (not n) (setq n 1))
 799   (let ((r))
 800     (while (> n 0)
 801       (setq r (funcall search (point) 'occur-match))
 802       (and r
 803            (get-text-property r 'occur-match)
 804            (setq r (funcall search r 'occur-match)))
 805       (if r
 806           (goto-char r)
 807         (error message))
 808       (setq n (1- n)))))
 809
 810 (defun occur-next (&optional n)
 811   "Move to the Nth (default 1) next match in an Occur mode buffer."
 812   (interactive "p")
 813   (occur-find-match n #'next-single-property-change "No more matches"))
 814
 815 (defun occur-prev (&optional n)
 816   "Move to the Nth (default 1) previous match in an Occur mode buffer."
 817   (interactive "p")
 818   (occur-find-match n #'previous-single-property-change "No earlier matches"))
 819
 820 (defun occur-next-error (&optional argp reset)
 821   "Move to the Nth (default 1) next match in an Occur mode buffer.
 822 Compatibility function for \\[next-error] invocations."
 823   (interactive "p")
 824   ;; we need to run occur-find-match from within the Occur buffer
 825   (with-current-buffer
 826       ;; Choose the buffer and make it current.
 827       (if (next-error-buffer-p (current-buffer))
 828           (current-buffer)
 829         (next-error-find-buffer nil nil
 830                                 (lambda ()
 831                                   (eq major-mode 'occur-mode))))
 832
 833     (goto-char (cond (reset (point-min))
 834                      ((< argp 0) (line-beginning-position))
 835                      ((line-end-position))))
 836     (occur-find-match
 837      (abs argp)
 838      (if (> 0 argp)
 839          #'previous-single-property-change
 840        #'next-single-property-change)
 841      "No more matches")
 842     ;; In case the *Occur* buffer is visible in a nonselected window.
 843     (set-window-point (get-buffer-window (current-buffer)) (point))
 844     (occur-mode-goto-occurrence)))
 845 \f
 846 (defface match
 847   '((((class color) (min-colors 88) (background light))
 848      :background "Tan")
 849     (((class color) (min-colors 88) (background dark))
 850      :background "RoyalBlue3")
 851     (((class color) (min-colors 8))
 852      :background "blue" :foreground "white")
 853     (((type tty) (class mono))
 854      :inverse-video t)
 855     (t :background "gray"))
 856   "Face used to highlight matches permanently."
 857   :group 'matching
 858   :version "22.1")
 859
 860 (defcustom list-matching-lines-default-context-lines 0
 861   "*Default number of context lines included around `list-matching-lines' matches.
 862 A negative number means to include that many lines before the match.
 863 A positive number means to include that many lines both before and after."
 864   :type 'integer
 865   :group 'matching)
 866
 867 (defalias 'list-matching-lines 'occur)
 868
 869 (defcustom list-matching-lines-face 'match
 870   "*Face used by \\[list-matching-lines] to show the text that matches.
 871 If the value is nil, don't highlight the matching portions specially."
 872   :type 'face
 873   :group 'matching)
 874
 875 (defcustom list-matching-lines-buffer-name-face 'underline
 876   "*Face used by \\[list-matching-lines] to show the names of buffers.
 877 If the value is nil, don't highlight the buffer names specially."
 878   :type 'face
 879   :group 'matching)
 880
 881 (defun occur-accumulate-lines (count &optional keep-props)
 882   (save-excursion
 883     (let ((forwardp (> count 0))
 884           result beg end)
 885       (while (not (or (zerop count)
 886                       (if forwardp
 887                           (eobp)
 888                         (bobp))))
 889         (setq count (+ count (if forwardp -1 1)))
 890         (setq beg (line-beginning-position)
 891               end (line-end-position))
 892         (if (and keep-props (if (boundp 'jit-lock-mode) jit-lock-mode)
 893                  (text-property-not-all beg end 'fontified t))
 894             (if (fboundp 'jit-lock-fontify-now)
 895                 (jit-lock-fontify-now beg end)))
 896         (push
 897          (funcall (if keep-props
 898                       #'buffer-substring
 899                     #'buffer-substring-no-properties)
 900                   beg end)
 901          result)
 902         (forward-line (if forwardp 1 -1)))
 903       (nreverse result))))
 904
 905 (defun occur-read-primary-args ()
 906   (list (let* ((default (car regexp-history))
 907                (input
 908                 (read-from-minibuffer
 909                  (if default
 910                      (format "List lines matching regexp (default `%s'): "
 911                              (query-replace-descr default))
 912                    "List lines matching regexp: ")
 913                  nil
 914                  nil
 915                  nil
 916                  'regexp-history
 917                  default)))
 918           (if (equal input "")
 919               default
 920             input))
 921         (when current-prefix-arg
 922           (prefix-numeric-value current-prefix-arg))))
 923
 924 (defun occur-rename-buffer (&optional unique-p interactive-p)
 925   "Rename the current *Occur* buffer to *Occur: original-buffer-name*.
 926 Here `original-buffer-name' is the buffer name were Occur was originally run.
 927 When given the prefix argument, or called non-interactively, the renaming
 928 will not clobber the existing buffer(s) of that name, but use
 929 `generate-new-buffer-name' instead.  You can add this to `occur-hook'
 930 if you always want a separate *Occur* buffer for each buffer where you
 931 invoke `occur'."
 932   (interactive "P\np")
 933   (with-current-buffer
 934       (if (eq major-mode 'occur-mode) (current-buffer) (get-buffer "*Occur*"))
 935     (rename-buffer (concat "*Occur: "
 936                            (mapconcat #'buffer-name
 937                                       (car (cddr occur-revert-arguments)) "/")
 938                            "*")
 939                    (or unique-p (not interactive-p)))))
 940
 941 (defun occur (regexp &optional nlines)
 942   "Show all lines in the current buffer containing a match for REGEXP.
 943 This function can not handle matches that span more than one line.
 944
 945 Each line is displayed with NLINES lines before and after, or -NLINES
 946 before if NLINES is negative.
 947 NLINES defaults to `list-matching-lines-default-context-lines'.
 948 Interactively it is the prefix arg.
 949
 950 The lines are shown in a buffer named `*Occur*'.
 951 It serves as a menu to find any of the occurrences in this buffer.
 952 \\<occur-mode-map>\\[describe-mode] in that buffer will explain how.
 953
 954 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 955 the matching is case-sensitive."
 956   (interactive (occur-read-primary-args))
 957   (occur-1 regexp nlines (list (current-buffer))))
 958
 959 (defun multi-occur (bufs regexp &optional nlines)
 960   "Show all lines in buffers BUFS containing a match for REGEXP.
 961 This function acts on multiple buffers; otherwise, it is exactly like
 962 `occur'."
 963   (interactive
 964    (cons
 965     (let* ((bufs (list (read-buffer "First buffer to search: "
 966                                     (current-buffer) t)))
 967            (buf nil)
 968            (ido-ignore-item-temp-list bufs))
 969       (while (not (string-equal
 970                    (setq buf (read-buffer
 971                               (if (eq read-buffer-function 'ido-read-buffer)
 972                                   "Next buffer to search (C-j to end): "
 973                                 "Next buffer to search (RET to end): ")
 974                               nil t))
 975                    ""))
 976         (add-to-list 'bufs buf)
 977         (setq ido-ignore-item-temp-list bufs))
 978       (nreverse (mapcar #'get-buffer bufs)))
 979     (occur-read-primary-args)))
 980   (occur-1 regexp nlines bufs))
 981
 982 (defun multi-occur-by-filename-regexp (bufregexp regexp &optional nlines)
 983   "Show all lines matching REGEXP in buffers named by BUFREGEXP.
 984 See also `multi-occur'."
 985   (interactive
 986    (cons
 987     (let* ((default (car regexp-history))
 988            (input
 989             (read-from-minibuffer
 990              "List lines in buffers whose filename matches regexp: "
 991              nil
 992              nil
 993              nil
 994              'regexp-history)))
 995       (if (equal input "")
 996           default
 997         input))
 998     (occur-read-primary-args)))
 999   (when bufregexp
1000     (occur-1 regexp nlines
1001              (delq nil
1002                    (mapcar (lambda (buf)
1003                              (when (and (buffer-file-name buf)
1004                                         (string-match bufregexp
1005                                                       (buffer-file-name buf)))
1006                                buf))
1007                            (buffer-list))))))
1008
1009 (defun occur-1 (regexp nlines bufs &optional buf-name)
1010   (unless buf-name
1011     (setq buf-name "*Occur*"))
1012   (let (occur-buf
1013         (active-bufs (delq nil (mapcar #'(lambda (buf)
1014                                            (when (buffer-live-p buf) buf))
1015                                        bufs))))
1016     ;; Handle the case where one of the buffers we're searching is the
1017     ;; output buffer.  Just rename it.
1018     (when (member buf-name (mapcar 'buffer-name active-bufs))
1019       (with-current-buffer (get-buffer buf-name)
1020         (rename-uniquely)))
1021
1022     ;; Now find or create the output buffer.
1023     ;; If we just renamed that buffer, we will make a new one here.
1024     (setq occur-buf (get-buffer-create buf-name))
1025
1026     (with-current-buffer occur-buf
1027       (occur-mode)
1028       (let ((inhibit-read-only t))
1029         (erase-buffer)
1030         (let ((count (occur-engine
1031                       regexp active-bufs occur-buf
1032                       (or nlines list-matching-lines-default-context-lines)
1033                       (and case-fold-search
1034                            (isearch-no-upper-case-p regexp t))
1035                       list-matching-lines-buffer-name-face
1036                       nil list-matching-lines-face t)))
1037           (let* ((bufcount (length active-bufs))
1038                  (diff (- (length bufs) bufcount)))
1039             (message "Searched %d buffer%s%s; %s match%s for `%s'"
1040                      bufcount (if (= bufcount 1) "" "s")
1041                      (if (zerop diff) "" (format " (%d killed)" diff))
1042                      (if (zerop count) "no" (format "%d" count))
1043                      (if (= count 1) "" "es")
1044                      regexp))
1045           (setq occur-revert-arguments (list regexp nlines bufs))
1046           (if (= count 0)
1047               (kill-buffer occur-buf)
1048             (display-buffer occur-buf)
1049             (setq next-error-last-buffer occur-buf)
1050             (setq buffer-read-only t)
1051             (set-buffer-modified-p nil)
1052             (run-hooks 'occur-hook)))))))
1053
1054 (defun occur-engine-add-prefix (lines)
1055   (mapcar
1056    #'(lambda (line)
1057        (concat "       :" line "\n"))
1058    lines))
1059
1060 (defun occur-engine (regexp buffers out-buf nlines case-fold-search
1061                             title-face prefix-face match-face keep-props)
1062   (with-current-buffer out-buf
1063     (let ((globalcount 0)
1064           (coding nil))
1065       ;; Map over all the buffers
1066       (dolist (buf buffers)
1067         (when (buffer-live-p buf)
1068           (let ((matches 0)     ;; count of matched lines
1069                 (lines 1)       ;; line count
1070                 (matchbeg 0)
1071                 (origpt nil)
1072                 (begpt nil)
1073                 (endpt nil)
1074                 (marker nil)
1075                 (curstring "")
1076                 (headerpt (with-current-buffer out-buf (point))))
1077             (save-excursion
1078               (set-buffer buf)
1079               (or coding
1080                   ;; Set CODING only if the current buffer locally
1081                   ;; binds buffer-file-coding-system.
1082                   (not (local-variable-p 'buffer-file-coding-system))
1083                   (setq coding buffer-file-coding-system))
1084               (save-excursion
1085                 (goto-char (point-min)) ;; begin searching in the buffer
1086                 (while (not (eobp))
1087                   (setq origpt (point))
1088                   (when (setq endpt (re-search-forward regexp nil t))
1089                     (setq matches (1+ matches)) ;; increment match count
1090                     (setq matchbeg (match-beginning 0))
1091                     (setq lines (+ lines (1- (count-lines origpt endpt))))
1092                     (save-excursion
1093                       (goto-char matchbeg)
1094                       (setq begpt (line-beginning-position)
1095                             endpt (line-end-position)))
1096                     (setq marker (make-marker))
1097                     (set-marker marker matchbeg)
1098                     (if (and keep-props
1099                              (if (boundp 'jit-lock-mode) jit-lock-mode)
1100                              (text-property-not-all begpt endpt 'fontified t))
1101                         (if (fboundp 'jit-lock-fontify-now)
1102                             (jit-lock-fontify-now begpt endpt)))
1103                     (setq curstring (buffer-substring begpt endpt))
1104                     ;; Depropertize the string, and maybe
1105                     ;; highlight the matches
1106                     (let ((len (length curstring))
1107                           (start 0))
1108                       (unless keep-props
1109                         (set-text-properties 0 len nil curstring))
1110                       (while (and (< start len)
1111                                   (string-match regexp curstring start))
1112                         (add-text-properties
1113                          (match-beginning 0) (match-end 0)
1114                          (append
1115                           `(occur-match t)
1116                           (when match-face
1117                             ;; Use `face' rather than `font-lock-face' here
1118                             ;; so as to override faces copied from the buffer.
1119                             `(face ,match-face)))
1120                          curstring)
1121                         (setq start (match-end 0))))
1122                     ;; Generate the string to insert for this match
1123                     (let* ((out-line
1124                             (concat
1125                              ;; Using 7 digits aligns tabs properly.
1126                              (apply #'propertize (format "%7d:" lines)
1127                                     (append
1128                                      (when prefix-face
1129                                        `(font-lock-face prefix-face))
1130                                      '(occur-prefix t)))
1131                              ;; We don't put `mouse-face' on the newline,
1132                              ;; because that loses.  And don't put it
1133                              ;; on context lines to reduce flicker.
1134                              (propertize curstring 'mouse-face 'highlight)
1135                              "\n"))
1136                            (data
1137                             (if (= nlines 0)
1138                                 ;; The simple display style
1139                                 out-line
1140                               ;; The complex multi-line display
1141                               ;; style.  Generate a list of lines,
1142                               ;; concatenate them all together.
1143                               (apply #'concat
1144                                      (nconc
1145                                       (occur-engine-add-prefix (nreverse (cdr (occur-accumulate-lines (- (1+ (abs nlines))) keep-props))))
1146                                       (list out-line)
1147                                       (if (> nlines 0)
1148                                           (occur-engine-add-prefix
1149                                            (cdr (occur-accumulate-lines (1+ nlines) keep-props)))))))))
1150                       ;; Actually insert the match display data
1151                       (with-current-buffer out-buf
1152                         (let ((beg (point))
1153                               (end (progn (insert data) (point))))
1154                           (unless (= nlines 0)
1155                             (insert "-------\n"))
1156                           (add-text-properties
1157                            beg end
1158                            `(occur-target ,marker help-echo "mouse-2: go to this occurrence")))))
1159                     (goto-char endpt))
1160                   (if endpt
1161                       (progn
1162                         (setq lines (1+ lines))
1163                         ;; On to the next match...
1164                         (forward-line 1))
1165                     (goto-char (point-max))))))
1166             (when (not (zerop matches)) ;; is the count zero?
1167               (setq globalcount (+ globalcount matches))
1168               (with-current-buffer out-buf
1169                 (goto-char headerpt)
1170                 (let ((beg (point))
1171                       end)
1172                   (insert (format "%d match%s for \"%s\" in buffer: %s\n"
1173                                   matches (if (= matches 1) "" "es")
1174                                   regexp (buffer-name buf)))
1175                   (setq end (point))
1176                   (add-text-properties beg end
1177                                        (append
1178                                         (when title-face
1179                                           `(font-lock-face ,title-face))
1180                                         `(occur-title ,buf))))
1181                 (goto-char (point-min)))))))
1182       (if coding
1183           ;; CODING is buffer-file-coding-system of the first buffer
1184           ;; that locally binds it.  Let's use it also for the output
1185           ;; buffer.
1186           (set-buffer-file-coding-system coding))
1187       ;; Return the number of matches
1188       globalcount)))
1189
1190 \f
1191 ;; It would be nice to use \\[...], but there is no reasonable way
1192 ;; to make that display both SPC and Y.
1193 (defconst query-replace-help
1194   "Type Space or `y' to replace one match, Delete or `n' to skip to next,
1195 RET or `q' to exit, Period to replace one match and exit,
1196 Comma to replace but not move point immediately,
1197 C-r to enter recursive edit (\\[exit-recursive-edit] to get out again),
1198 C-w to delete match and recursive edit,
1199 C-l to clear the screen, redisplay, and offer same replacement again,
1200 ! to replace all remaining matches with no more questions,
1201 ^ to move point back to previous match,
1202 E to edit the replacement string"
1203   "Help message while in `query-replace'.")
1204
1205 (defvar query-replace-map (make-sparse-keymap)
1206   "Keymap that defines the responses to questions in `query-replace'.
1207 The \"bindings\" in this map are not commands; they are answers.
1208 The valid answers include `act', `skip', `act-and-show',
1209 `exit', `act-and-exit', `edit', `delete-and-edit', `recenter',
1210 `automatic', `backup', `exit-prefix', and `help'.")
1211
1212 (define-key query-replace-map " " 'act)
1213 (define-key query-replace-map "\d" 'skip)
1214 (define-key query-replace-map [delete] 'skip)
1215 (define-key query-replace-map [backspace] 'skip)
1216 (define-key query-replace-map "y" 'act)
1217 (define-key query-replace-map "n" 'skip)
1218 (define-key query-replace-map "Y" 'act)
1219 (define-key query-replace-map "N" 'skip)
1220 (define-key query-replace-map "e" 'edit-replacement)
1221 (define-key query-replace-map "E" 'edit-replacement)
1222 (define-key query-replace-map "," 'act-and-show)
1223 (define-key query-replace-map "q" 'exit)
1224 (define-key query-replace-map "\r" 'exit)
1225 (define-key query-replace-map [return] 'exit)
1226 (define-key query-replace-map "." 'act-and-exit)
1227 (define-key query-replace-map "\C-r" 'edit)
1228 (define-key query-replace-map "\C-w" 'delete-and-edit)
1229 (define-key query-replace-map "\C-l" 'recenter)
1230 (define-key query-replace-map "!" 'automatic)
1231 (define-key query-replace-map "^" 'backup)
1232 (define-key query-replace-map "\C-h" 'help)
1233 (define-key query-replace-map [f1] 'help)
1234 (define-key query-replace-map [help] 'help)
1235 (define-key query-replace-map "?" 'help)
1236 (define-key query-replace-map "\C-g" 'quit)
1237 (define-key query-replace-map "\C-]" 'quit)
1238 (define-key query-replace-map "\e" 'exit-prefix)
1239 (define-key query-replace-map [escape] 'exit-prefix)
1240
1241 (defun replace-match-string-symbols (n)
1242   "Process a list (and any sub-lists), expanding certain symbols.
1243 Symbol  Expands To
1244 N     (match-string N)           (where N is a string of digits)
1245 #N    (string-to-number (match-string N))
1246 &     (match-string 0)
1247 #&    (string-to-number (match-string 0))
1248 #     replace-count
1249
1250 Note that these symbols must be preceeded by a backslash in order to
1251 type them."
1252   (while n
1253     (cond
1254      ((consp (car n))
1255       (replace-match-string-symbols (car n))) ;Process sub-list
1256      ((symbolp (car n))
1257       (let ((name (symbol-name (car n))))
1258         (cond
1259          ((string-match "^[0-9]+$" name)
1260           (setcar n (list 'match-string (string-to-number name))))
1261          ((string-match "^#[0-9]+$" name)
1262           (setcar n (list 'string-to-number
1263                           (list 'match-string
1264                                 (string-to-number (substring name 1))))))
1265          ((string= "&" name)
1266           (setcar n '(match-string 0)))
1267          ((string= "#&" name)
1268           (setcar n '(string-to-number (match-string 0))))
1269          ((string= "#" name)
1270           (setcar n 'replace-count))))))
1271     (setq n (cdr n))))
1272
1273 (defun replace-eval-replacement (expression replace-count)
1274   (let ((replacement (eval expression)))
1275     (if (stringp replacement)
1276         replacement
1277       (prin1-to-string replacement t))))
1278
1279 (defun replace-quote (replacement)
1280   "Quote a replacement string.
1281 This just doubles all backslashes in REPLACEMENT and
1282 returns the resulting string.  If REPLACEMENT is not
1283 a string, it is first passed through `prin1-to-string'
1284 with the `noescape' argument set.
1285
1286 `match-data' is preserved across the call."
1287   (save-match-data
1288     (replace-regexp-in-string "\\\\" "\\\\"
1289                               (if (stringp replacement)
1290                                   replacement
1291                                 (prin1-to-string replacement t))
1292                               t t)))
1293
1294 (defun replace-loop-through-replacements (data replace-count)
1295   ;; DATA is a vector contaning the following values:
1296   ;;   0 next-rotate-count
1297   ;;   1 repeat-count
1298   ;;   2 next-replacement
1299   ;;   3 replacements
1300   (if (= (aref data 0) replace-count)
1301       (progn
1302         (aset data 0 (+ replace-count (aref data 1)))
1303         (let ((next (cdr (aref data 2))))
1304           (aset data 2 (if (consp next) next (aref data 3))))))
1305   (car (aref data 2)))
1306
1307 (defun replace-match-data (integers reuse &optional new)
1308   "Like `match-data', but markers in REUSE get invalidated.
1309 If NEW is non-NIL, it is set and returned instead of fresh data,
1310 but coerced to the correct value of INTEGERS."
1311   (or (and new
1312            (progn
1313              (set-match-data new)
1314              (and (eq new reuse)
1315                   (eq (null integers) (markerp (car reuse)))
1316                   new)))
1317       (match-data integers reuse t)))
1318
1319 (defun replace-match-maybe-edit (newtext fixedcase literal noedit match-data)
1320   "Make a replacement with `replace-match', editing `\\?'.
1321 NEWTEXT, FIXEDCASE, LITERAL are just passed on.  If NOEDIT is true, no
1322 check for `\\?' is made to save time.  MATCH-DATA is used for the
1323 replacement.  In case editing is done, it is changed to use markers.
1324
1325 The return value is non-NIL if there has been no `\\?' or NOEDIT was
1326 passed in.  If LITERAL is set, no checking is done, anyway."
1327   (unless (or literal noedit)
1328     (setq noedit t)
1329     (while (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\(\\\\\\?\\)"
1330                          newtext)
1331       (setq newtext
1332             (read-string "Edit replacement string: "
1333                          (prog1
1334                              (cons
1335                               (replace-match "" t t newtext 3)
1336                               (1+ (match-beginning 3)))
1337                            (setq match-data
1338                                  (replace-match-data
1339                                   nil match-data match-data))))
1340             noedit nil)))
1341   (set-match-data match-data)
1342   (replace-match newtext fixedcase literal)
1343   noedit)
1344
1345 (defun perform-replace (from-string replacements
1346                         query-flag regexp-flag delimited-flag
1347                         &optional repeat-count map start end)
1348   "Subroutine of `query-replace'.  Its complexity handles interactive queries.
1349 Don't use this in your own program unless you want to query and set the mark
1350 just as `query-replace' does.  Instead, write a simple loop like this:
1351
1352   (while (re-search-forward \"foo[ \\t]+bar\" nil t)
1353     (replace-match \"foobar\" nil nil))
1354
1355 which will run faster and probably do exactly what you want.  Please
1356 see the documentation of `replace-match' to find out how to simulate
1357 `case-replace'.
1358
1359 This function returns nil if and only if there were no matches to
1360 make, or the user didn't cancel the call."
1361   (or map (setq map query-replace-map))
1362   (and query-flag minibuffer-auto-raise
1363        (raise-frame (window-frame (minibuffer-window))))
1364   (let ((nocasify (not (and case-fold-search case-replace
1365                             (string-equal from-string
1366                                           (downcase from-string)))))
1367         (case-fold-search (and case-fold-search
1368                                (string-equal from-string
1369                                              (downcase from-string))))
1370         (literal (or (not regexp-flag) (eq regexp-flag 'literal)))
1371         (search-function (if regexp-flag 're-search-forward 'search-forward))
1372         (search-string from-string)
1373         (real-match-data nil)           ; the match data for the current match
1374         (next-replacement nil)
1375         (noedit nil)
1376         (keep-going t)
1377         (stack nil)
1378         (replace-count 0)
1379         (nonempty-match nil)
1380
1381         ;; If non-nil, it is marker saying where in the buffer to stop.
1382         (limit nil)
1383
1384         ;; Data for the next match.  If a cons, it has the same format as
1385         ;; (match-data); otherwise it is t if a match is possible at point.
1386         (match-again t)
1387
1388         (message
1389          (if query-flag
1390              (substitute-command-keys
1391               "Query replacing %s with %s: (\\<query-replace-map>\\[help] for help) "))))
1392
1393     ;; If region is active, in Transient Mark mode, operate on region.
1394     (when start
1395       (setq limit (copy-marker (max start end)))
1396       (goto-char (min start end))
1397       (deactivate-mark))
1398
1399     ;; REPLACEMENTS is either a string, a list of strings, or a cons cell
1400     ;; containing a function and its first argument.  The function is
1401     ;; called to generate each replacement like this:
1402     ;;   (funcall (car replacements) (cdr replacements) replace-count)
1403     ;; It must return a string.
1404     (cond
1405      ((stringp replacements)
1406       (setq next-replacement replacements
1407             replacements     nil))
1408      ((stringp (car replacements)) ; If it isn't a string, it must be a cons
1409       (or repeat-count (setq repeat-count 1))
1410       (setq replacements (cons 'replace-loop-through-replacements
1411                                (vector repeat-count repeat-count
1412                                        replacements replacements)))))
1413
1414     (if delimited-flag
1415         (setq search-function 're-search-forward
1416               search-string (concat "\\b"
1417                                     (if regexp-flag from-string
1418                                       (regexp-quote from-string))
1419                                     "\\b")))
1420     (when query-replace-lazy-highlight
1421       (setq isearch-lazy-highlight-last-string nil))
1422
1423     (push-mark)
1424     (undo-boundary)
1425     (unwind-protect
1426         ;; Loop finding occurrences that perhaps should be replaced.
1427         (while (and keep-going
1428                     (not (or (eobp) (and limit (>= (point) limit))))
1429                     ;; Use the next match if it is already known;
1430                     ;; otherwise, search for a match after moving forward
1431                     ;; one char if progress is required.
1432                     (setq real-match-data
1433                           (if (consp match-again)
1434                               (progn (goto-char (nth 1 match-again))
1435                                      (replace-match-data t
1436                                       real-match-data
1437                                       match-again))
1438                             (and (or match-again
1439                                      ;; MATCH-AGAIN non-nil means we
1440                                      ;; accept an adjacent match.  If
1441                                      ;; we don't, move one char to the
1442                                      ;; right.  This takes us a
1443                                      ;; character too far at the end,
1444                                      ;; but this is undone after the
1445                                      ;; while-loop.
1446                                      (progn
1447                                        (forward-char 1)
1448                                        (not (or (eobp)
1449                                                 (and limit (>= (point) limit))))))
1450                                  (funcall search-function search-string limit t)
1451                                  ;; For speed, use only integers and
1452                                  ;; reuse the list used last time.
1453                                  (replace-match-data t real-match-data)))))
1454           ;; Optionally ignore matches that have a read-only property.
1455           (unless (and query-replace-skip-read-only
1456                        (text-property-not-all
1457                         (match-beginning 0) (match-end 0)
1458                         'read-only nil))
1459
1460             ;; Record whether the match is nonempty, to avoid an infinite loop
1461             ;; repeatedly matching the same empty string.
1462             (setq nonempty-match
1463                   (/= (nth 0 real-match-data) (nth 1 real-match-data)))
1464
1465             ;; If the match is empty, record that the next one can't be
1466             ;; adjacent.
1467
1468             ;; Otherwise, if matching a regular expression, do the next
1469             ;; match now, since the replacement for this match may
1470             ;; affect whether the next match is adjacent to this one.
1471             ;; If that match is empty, don't use it.
1472             (setq match-again
1473                   (and nonempty-match
1474                        (or (not regexp-flag)
1475                            (and (looking-at search-string)
1476                                 (let ((match (match-data)))
1477                                   (and (/= (nth 0 match) (nth 1 match))
1478                                        match))))))
1479
1480             ;; Calculate the replacement string, if necessary.
1481             (when replacements
1482               (set-match-data real-match-data)
1483               (setq next-replacement
1484                     (funcall (car replacements) (cdr replacements)
1485                              replace-count)
1486                     noedit nil))
1487             (if (not query-flag)
1488                 (let ((inhibit-read-only
1489                        query-replace-skip-read-only))
1490                   (unless (or literal noedit)
1491                     (replace-highlight
1492                      (nth 0 real-match-data) (nth 1 real-match-data)
1493                      start end search-string
1494                      (or delimited-flag regexp-flag) case-fold-search))
1495                   (setq noedit
1496                         (replace-match-maybe-edit
1497                          next-replacement nocasify literal
1498                          noedit real-match-data)
1499                         replace-count (1+ replace-count)))
1500               (undo-boundary)
1501               (let (done replaced key def)
1502                 ;; Loop reading commands until one of them sets done,
1503                 ;; which means it has finished handling this
1504                 ;; occurrence.  Any command that sets `done' should
1505                 ;; leave behind proper match data for the stack.
1506                 ;; Commands not setting `done' need to adjust
1507                 ;; `real-match-data'.
1508                 (while (not done)
1509                   (set-match-data real-match-data)
1510                   (replace-highlight
1511                    (match-beginning 0) (match-end 0)
1512                    start end search-string
1513                    (or delimited-flag regexp-flag) case-fold-search)
1514                   ;; Bind message-log-max so we don't fill up the message log
1515                   ;; with a bunch of identical messages.
1516                   (let ((message-log-max nil))
1517                     (message message
1518                              (query-replace-descr from-string)
1519                              (query-replace-descr next-replacement)))
1520                   (setq key (read-event))
1521                   ;; Necessary in case something happens during read-event
1522                   ;; that clobbers the match data.
1523                   (set-match-data real-match-data)
1524                   (setq key (vector key))
1525                   (setq def (lookup-key map key))
1526                   ;; Restore the match data while we process the command.
1527                   (cond ((eq def 'help)
1528                          (with-output-to-temp-buffer "*Help*"
1529                            (princ
1530                             (concat "Query replacing "
1531                                     (if regexp-flag "regexp " "")
1532                                     from-string " with "
1533                                     next-replacement ".\n\n"
1534                                     (substitute-command-keys
1535                                      query-replace-help)))
1536                            (with-current-buffer standard-output
1537                              (help-mode))))
1538                         ((eq def 'exit)
1539                          (setq keep-going nil)
1540                          (setq done t))
1541                         ((eq def 'backup)
1542                          (if stack
1543                              (let ((elt (pop stack)))
1544                                (goto-char (nth 0 elt))
1545                                (setq replaced (nth 1 elt)
1546                                      real-match-data
1547                                      (replace-match-data
1548                                       t real-match-data
1549                                       (nth 2 elt))))
1550                            (message "No previous match")
1551                            (ding 'no-terminate)
1552                            (sit-for 1)))
1553                         ((eq def 'act)
1554                          (or replaced
1555                              (setq noedit
1556                                    (replace-match-maybe-edit
1557                                     next-replacement nocasify literal
1558                                     noedit real-match-data)
1559                                    replace-count (1+ replace-count)))
1560                          (setq done t replaced t))
1561                         ((eq def 'act-and-exit)
1562                          (or replaced
1563                              (setq noedit
1564                                    (replace-match-maybe-edit
1565                                     next-replacement nocasify literal
1566                                     noedit real-match-data)
1567                                    replace-count (1+ replace-count)))
1568                          (setq keep-going nil)
1569                          (setq done t replaced t))
1570                         ((eq def 'act-and-show)
1571                          (if (not replaced)
1572                              (setq noedit
1573                                    (replace-match-maybe-edit
1574                                     next-replacement nocasify literal
1575                                     noedit real-match-data)
1576                                    replace-count (1+ replace-count)
1577                                    real-match-data (replace-match-data
1578                                                     t real-match-data)
1579                                    replaced t)))
1580                         ((eq def 'automatic)
1581                          (or replaced
1582                              (setq noedit
1583                                    (replace-match-maybe-edit
1584                                     next-replacement nocasify literal
1585                                     noedit real-match-data)
1586                                    replace-count (1+ replace-count)))
1587                          (setq done t query-flag nil replaced t))
1588                         ((eq def 'skip)
1589                          (setq done t))
1590                         ((eq def 'recenter)
1591                          (recenter nil))
1592                         ((eq def 'edit)
1593                          (let ((opos (point-marker)))
1594                            (setq real-match-data (replace-match-data
1595                                                   nil real-match-data
1596                                                   real-match-data))
1597                            (goto-char (match-beginning 0))
1598                            (save-excursion
1599                              (save-window-excursion
1600                                (recursive-edit)))
1601                            (goto-char opos)
1602                            (set-marker opos nil))
1603                          ;; Before we make the replacement,
1604                          ;; decide whether the search string
1605                          ;; can match again just after this match.
1606                          (if (and regexp-flag nonempty-match)
1607                              (setq match-again (and (looking-at search-string)
1608                                                     (match-data)))))
1609                         ;; Edit replacement.
1610                         ((eq def 'edit-replacement)
1611                          (setq real-match-data (replace-match-data
1612                                                 nil real-match-data
1613                                                 real-match-data)
1614                                next-replacement
1615                                (read-string "Edit replacement string: "
1616                                             next-replacement)
1617                                noedit nil)
1618                          (if replaced
1619                              (set-match-data real-match-data)
1620                            (setq noedit
1621                                  (replace-match-maybe-edit
1622                                   next-replacement nocasify literal noedit
1623                                   real-match-data)
1624                                  replaced t))
1625                          (setq done t))
1626
1627                         ((eq def 'delete-and-edit)
1628                          (replace-match "" t t)
1629                          (setq real-match-data (replace-match-data
1630                                                 nil real-match-data))
1631                          (replace-dehighlight)
1632                          (save-excursion (recursive-edit))
1633                          (setq replaced t))
1634                         ;; Note: we do not need to treat `exit-prefix'
1635                         ;; specially here, since we reread
1636                         ;; any unrecognized character.
1637                         (t
1638                          (setq this-command 'mode-exited)
1639                          (setq keep-going nil)
1640                          (setq unread-command-events
1641                                (append (listify-key-sequence key)
1642                                        unread-command-events))
1643                          (setq done t)))
1644                   (when query-replace-lazy-highlight
1645                     ;; Force lazy rehighlighting only after replacements
1646                     (if (not (memq def '(skip backup)))
1647                         (setq isearch-lazy-highlight-last-string nil))))
1648                 ;; Record previous position for ^ when we move on.
1649                 ;; Change markers to numbers in the match data
1650                 ;; since lots of markers slow down editing.
1651                 (push (list (point) replaced
1652 ;;;  If the replacement has already happened, all we need is the
1653 ;;;  current match start and end.  We could get this with a trivial
1654 ;;;  match like
1655 ;;;  (save-excursion (goto-char (match-beginning 0))
1656 ;;;                  (search-forward (match-string 0))
1657 ;;;                  (match-data t))
1658 ;;;  if we really wanted to avoid manually constructing match data.
1659 ;;;  Adding current-buffer is necessary so that match-data calls can
1660 ;;;  return markers which are appropriate for editing.
1661                             (if replaced
1662                                 (list
1663                                  (match-beginning 0)
1664                                  (match-end 0)
1665                                  (current-buffer))
1666                               (match-data t)))
1667                       stack)))))
1668
1669       ;; The code preventing adjacent regexp matches in the condition
1670       ;; of the while-loop above will haven taken us one character
1671       ;; beyond the last replacement.  Undo that.
1672       (when (and regexp-flag (not match-again) (> replace-count 0))
1673         (backward-char 1))
1674
1675       (replace-dehighlight))
1676     (or unread-command-events
1677         (message "Replaced %d occurrence%s"
1678                  replace-count
1679                  (if (= replace-count 1) "" "s")))
1680     (and keep-going stack)))
1681
1682 (defvar replace-overlay nil)
1683
1684 (defun replace-highlight (match-beg match-end range-beg range-end
1685                           string regexp case-fold)
1686   (if query-replace-highlight
1687       (if replace-overlay
1688           (move-overlay replace-overlay match-beg match-end (current-buffer))
1689         (setq replace-overlay (make-overlay match-beg match-end))
1690         (overlay-put replace-overlay 'priority 1) ;higher than lazy overlays
1691         (overlay-put replace-overlay 'face 'query-replace)))
1692   (if query-replace-lazy-highlight
1693       (let ((isearch-string string)
1694             (isearch-regexp regexp)
1695             (isearch-case-fold-search case-fold))
1696         (isearch-lazy-highlight-new-loop range-beg range-end))))
1697
1698 (defun replace-dehighlight ()
1699   (when replace-overlay
1700     (delete-overlay replace-overlay))
1701   (when query-replace-lazy-highlight
1702     (lazy-highlight-cleanup lazy-highlight-cleanup)
1703     (setq isearch-lazy-highlight-last-string nil)))
1704
1705 ;; arch-tag: 16b4cd61-fd40-497b-b86f-b667c4cf88e4
1706 ;;; replace.el ends here