lisp/mail/mailalias.el

   1 ;;; mailalias.el --- expand and complete mailing address aliases
   2
   3 ;; Copyright (C) 1985, 1987, 1995, 1996, 1997, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Basic functions for defining and expanding mail aliases.
  27 ;; These seal off the interface to the alias-definition parts of a
  28 ;; .mailrc file formatted for BSD's Mail or USL's mailx.
  29
  30 ;;; Code:
  31
  32 (require 'sendmail)
  33
  34 (defgroup mailalias nil
  35   "Expanding mail aliases."
  36   :group 'mail)
  37
  38 (defcustom mail-passwd-files '("/etc/passwd")
  39   "*List of files from which to determine valid user names."
  40   :type '(repeat string)
  41   :group 'mailalias)
  42
  43 (defcustom mail-passwd-command nil
  44   "*Shell command to retrieve text to add to `/etc/passwd', or nil."
  45   :type '(choice string (const nil))
  46   :group 'mailalias)
  47
  48 (defvar mail-directory-names t
  49   "Alist of mail address directory entries.
  50 When t this still needs to be initialized.")
  51
  52 (defvar mail-address-field-regexp
  53   "^\\(Resent-\\)?\\(To\\|From\\|CC\\|BCC\\|Reply-to\\):")
  54
  55 (defcustom mail-complete-alist
  56   ;; Don't use backquote here; we don't want backquote to get loaded
  57   ;; just because of loading this file.
  58   ;; Don't refer to mail-address-field-regexp here;
  59   ;; that confuses some things such as cus-dep.el.
  60   (cons '("^\\(Resent-\\)?\\(To\\|From\\|CC\\|BCC\\|Reply-to\\):"
  61           . (mail-get-names pattern))
  62         '(("Newsgroups:" . (if (boundp 'gnus-active-hashtb)
  63                                gnus-active-hashtb
  64                              (if (boundp news-group-article-assoc)
  65                                  news-group-article-assoc)))
  66           ("Followup-To:" . (mail-sentto-newsgroups))
  67           ;;("Distribution:" ???)
  68           ))
  69   "*Alist of header field and expression to return alist for completion.
  70 The expression may reference the variable `pattern'
  71 which will hold the string being completed.
  72 If not on matching header, `mail-complete-function' gets called instead."
  73   :type 'alist
  74   :group 'mailalias)
  75 (put 'mail-complete-alist 'risky-local-variable t)
  76
  77 ;;;###autoload
  78 (defcustom mail-complete-style 'angles
  79   "*Specifies how \\[mail-complete] formats the full name when it completes.
  80 If `nil', they contain just the return address like:
  81         king@grassland.com
  82 If `parens', they look like:
  83         king@grassland.com (Elvis Parsley)
  84 If `angles', they look like:
  85         Elvis Parsley <king@grassland.com>"
  86   :type '(choice (const angles) (const parens) (const nil))
  87   :group 'mailalias)
  88
  89 (defcustom mail-complete-function 'ispell-complete-word
  90   "*Function to call when completing outside `mail-complete-alist'-header."
  91   :type '(choice function (const nil))
  92   :group 'mailalias)
  93
  94 (defcustom mail-directory-function nil
  95   "*Function to get completions from directory service or nil for none.
  96 See `mail-directory-requery'."
  97   :type '(choice function (const nil))
  98   :group 'mailalias)
  99
 100 ;; This is for when the directory is huge, or changes frequently.
 101 (defcustom mail-directory-requery nil
 102   "*When non-nil call `mail-directory-function' for each completion.
 103 In that case, one argument gets passed to the function, the partial string
 104 entered so far."
 105   :type 'boolean
 106   :group 'mailalias)
 107
 108 (defcustom mail-directory-process nil
 109   "*Shell command to get the list of names from a mail directory.
 110 This value is used when the value of `mail-directory-function'
 111 is `mail-directory-process'.  The value should be a list
 112 of the form (COMMAND ARG ...), where each of the list elements
 113 is evaluated.  COMMAND should evaluate to a string.  When
 114 `mail-directory-requery' is non-nil, during evaluation of these
 115 elements, the variable `pattern' contains the partial input being
 116 completed.  `pattern' is nil when `mail-directory-requery' is nil.
 117
 118 The value might look like this:
 119
 120   '(remote-shell-program \"HOST\" \"-nl\" \"USER\" \"COMMAND\")
 121
 122 or like this:
 123
 124   '(remote-shell-program \"HOST\" \"-n\" \"COMMAND '^\" pattern \"'\")"
 125   :type 'sexp
 126   :group 'mailalias)
 127 (put 'mail-directory-process 'risky-local-variable t)
 128
 129 (defcustom mail-directory-stream nil
 130   "*List of (HOST SERVICE) for stream connection to mail directory."
 131   :type 'sexp
 132   :group 'mailalias)
 133 (put 'mail-directory-stream 'risky-local-variable t)
 134
 135 (defcustom mail-directory-parser nil
 136   "*How to interpret the output of `mail-directory-function'.
 137 Three types of values are possible:
 138
 139   - nil means to gather each line as one name
 140   - regexp means first \\(grouping\\) in successive matches is name
 141   - function called at beginning of buffer that returns an alist of names"
 142   :type '(choice (const nil) regexp function)
 143   :group 'mailalias)
 144 (put 'mail-directory-parser 'risky-local-variable t)
 145
 146 ;; Internal variables.
 147
 148 (defvar mail-names t
 149   "Alist of local users, aliases and directory entries as available.
 150 Elements have the form (MAILNAME) or (MAILNAME . FULLNAME).
 151 If the value means t, it means the real value should be calculated
 152 for the next use.  This is used in `mail-complete'.")
 153
 154 (defvar mail-local-names t
 155   "Alist of local users.
 156 When t this still needs to be initialized.")
 157 \f
 158
 159 ;; Called from sendmail-send-it, or similar functions,
 160 ;; only if some mail aliases are defined.
 161 ;;;###autoload
 162 (defun expand-mail-aliases (beg end &optional exclude)
 163   "Expand all mail aliases in suitable header fields found between BEG and END.
 164 If interactive, expand in header fields.
 165 Suitable header fields are `To', `From', `CC' and `BCC', `Reply-to', and
 166 their `Resent-' variants.
 167
 168 Optional second arg EXCLUDE may be a regular expression defining text to be
 169 removed from alias expansions."
 170   (interactive
 171    (save-excursion
 172      (list (goto-char (point-min))
 173            (mail-header-end))))
 174   (sendmail-sync-aliases)
 175   (when (eq mail-aliases t)
 176     (setq mail-aliases nil)
 177     (build-mail-aliases))
 178   (save-excursion
 179     (goto-char beg)
 180     (setq end (set-marker (make-marker) end))
 181     (let ((case-fold-search nil))
 182       (while (let ((case-fold-search t))
 183                (re-search-forward mail-address-field-regexp end t))
 184         (skip-chars-forward " \t")
 185         (let ((beg1 (point))
 186               end1 pos epos seplen
 187               ;; DISABLED-ALIASES records aliases temporarily disabled
 188               ;; while we scan text that resulted from expanding those aliases.
 189               ;; Each element is (ALIAS . TILL-WHEN), where TILL-WHEN
 190               ;; is where to reenable the alias (expressed as number of chars
 191               ;; counting from END1).
 192               (disabled-aliases nil))
 193           (re-search-forward "^[^ \t]" end 'move)
 194           (beginning-of-line)
 195           (skip-chars-backward " \t\n")
 196           (setq end1 (point-marker))
 197           (goto-char beg1)
 198           (while (< (point) end1)
 199             (setq pos (point))
 200             ;; Reenable any aliases which were disabled for ranges
 201             ;; that we have passed out of.
 202             (while (and disabled-aliases
 203                         (> pos (- end1 (cdr (car disabled-aliases)))))
 204               (setq disabled-aliases (cdr disabled-aliases)))
 205             ;; EPOS gets position of end of next name;
 206             ;; SEPLEN gets length of whitespace&separator that follows it.
 207             (if (re-search-forward "[ \t]*[\n,][ \t]*" end1 t)
 208                 (setq epos (match-beginning 0)
 209                       seplen (- (point) epos))
 210               (setq epos (marker-position end1) seplen 0))
 211             (let ((string (buffer-substring-no-properties pos epos))
 212                   translation)
 213               (if (and (not (assoc string disabled-aliases))
 214                        (setq translation (cdr (assoc string mail-aliases))))
 215                   (progn
 216                     ;; This name is an alias.  Disable it.
 217                     (setq disabled-aliases (cons (cons string (- end1 epos))
 218                                                  disabled-aliases))
 219                     ;; Replace the alias with its expansion
 220                     ;; then rescan the expansion for more aliases.
 221                     (goto-char pos)
 222                     (insert translation)
 223                     (when exclude
 224                       (let ((regexp (concat "\\b\\(" exclude "\\)\\b"))
 225                             (end (point-marker)))
 226                         (goto-char pos)
 227                         (while (re-search-forward regexp end t)
 228                           (replace-match ""))
 229                         (goto-char end)))
 230                     (delete-region (point) (+ (point) (- epos pos)))
 231                     (goto-char pos))
 232                 ;; Name is not an alias.  Skip to start of next name.
 233                 (goto-char epos)
 234                 (forward-char seplen))))
 235           (set-marker end1 nil)))
 236       (set-marker end nil))))
 237
 238 ;; Called by mail-setup, or similar functions, only if the file specified
 239 ;; by mail-personal-alias-file (usually `~/.mailrc') exists.
 240 (defun build-mail-aliases (&optional file)
 241   "Read mail aliases from personal aliases file and set `mail-aliases'.
 242 By default, this is the file specified by `mail-personal-alias-file'."
 243   (setq file (expand-file-name (or file mail-personal-alias-file)))
 244   ;; In case mail-aliases is t, make sure define-mail-alias
 245   ;; does not recursively call build-mail-aliases.
 246   (setq mail-aliases nil)
 247   (let ((buffer nil)
 248         (obuf (current-buffer)))
 249     (unwind-protect
 250         (progn
 251           (setq buffer (generate-new-buffer " mailrc"))
 252           (set-buffer buffer)
 253           (while file
 254             (cond ((get-file-buffer file)
 255                    (insert (save-excursion
 256                              (set-buffer (get-file-buffer file))
 257                              (buffer-substring-no-properties
 258                               (point-min) (point-max)))))
 259                   ((file-exists-p file) (insert-file-contents file))
 260                   ((file-exists-p (setq file (concat "~/" file)))
 261                    (insert-file-contents file))
 262                   (t (setq file nil)))
 263             (goto-char (point-min))
 264             ;; Delete comments from the contents.
 265             (while (search-forward "# " nil t)
 266               (let ((p (- (point) 2)))
 267                 (end-of-line)
 268                 (delete-region p (point))))
 269             ;; Don't lose if no final newline.
 270             (goto-char (point-max))
 271             (or (eq (preceding-char) ?\n) (newline))
 272             (goto-char (point-min))
 273             ;; handle "\\\n" continuation lines
 274             (while (not (eobp))
 275               (end-of-line)
 276               (if (= (preceding-char) ?\\)
 277                   (progn (delete-char -1) (delete-char 1) (insert ?\ ))
 278                 (forward-char 1)))
 279             (goto-char (point-min))
 280             ;; handle `source' directives -- Eddy/1994/May/25
 281             (cond ((re-search-forward "^source[ \t]+" nil t)
 282                    (re-search-forward "\\S-+")
 283                    (setq file (buffer-substring-no-properties
 284                                (match-beginning 0) (match-end 0)))
 285                    (beginning-of-line)
 286                    (insert "# ") ; to ensure we don't re-process this file
 287                    (beginning-of-line))
 288                   (t (setq file nil))))
 289           (goto-char (point-min))
 290           (while (re-search-forward
 291                   "^\\(a\\|alias\\|g\\|group\\)[ \t]+\\([^ \t\n]+\\)" nil t)
 292             (let* ((name (match-string 2))
 293                    (start (progn (skip-chars-forward " \t") (point)))
 294                    value)
 295               (end-of-line)
 296               (setq value (buffer-substring-no-properties start (point)))
 297               (unless (equal value "")
 298                 (define-mail-alias name value t))))
 299           mail-aliases)
 300       (if buffer (kill-buffer buffer))
 301       (set-buffer obuf))))
 302
 303 ;; Always autoloadable in case the user wants to define aliases
 304 ;; interactively or in .emacs.
 305 ;;;###autoload
 306 (defun define-mail-alias (name definition &optional from-mailrc-file)
 307   "Define NAME as a mail alias that translates to DEFINITION.
 308 This means that sending a message to NAME will actually send to DEFINITION.
 309
 310 Normally, the addresses in DEFINITION must be separated by commas.
 311 If FROM-MAILRC-FILE is non-nil, then addresses in DEFINITION
 312 can be separated by spaces; an address can contain spaces
 313 if it is quoted with double-quotes."
 314
 315   (interactive "sDefine mail alias: \nsDefine %s as mail alias for: ")
 316   ;; Read the defaults first, if we have not done so.
 317   ;; But not if we are doing that already right now.
 318   (unless from-mailrc-file
 319     (sendmail-sync-aliases))
 320   (if (eq mail-aliases t)
 321       (progn
 322         (setq mail-aliases nil)
 323         (if (file-exists-p mail-personal-alias-file)
 324             (build-mail-aliases))))
 325   ;; strip garbage from front and end
 326   (if (string-match "\\`[ \t\n,]+" definition)
 327       (setq definition (substring definition (match-end 0))))
 328   (if (string-match "[ \t\n,]+\\'" definition)
 329       (setq definition (substring definition 0 (match-beginning 0))))
 330   (let ((result '())
 331         ;; If DEFINITION is null string, avoid looping even once.
 332         (start (and (not (equal definition "")) 0))
 333         (L (length definition))
 334         convert-backslash
 335         end tem)
 336     (while start
 337       (setq convert-backslash nil)
 338       ;; If we're reading from the mailrc file, then addresses are delimited
 339       ;; by spaces, and addresses with embedded spaces must be surrounded by
 340       ;; double-quotes.  Otherwise, addresses are separated by commas.
 341       (if from-mailrc-file
 342           (if (eq ?\" (aref definition start))
 343               ;; The following test on `found' compensates for a bug
 344               ;; in match-end, which does not return nil when match
 345               ;; failed.
 346               (let ((found (string-match "[^\\]\\(\\([\\][\\]\\)*\\)\"[ \t,]*"
 347                                          definition start)))
 348                 (setq start (1+ start)
 349                       end (and found (match-end 1))
 350                       convert-backslash t))
 351             (setq end (string-match "[ \t,]+" definition start)))
 352         (setq end (string-match "[ \t\n,]*,[ \t\n,]*" definition start)))
 353       (let ((temp (substring definition start end))
 354             (pos 0))
 355         (setq start (and end
 356                          (/= (match-end 0) L)
 357                          (match-end 0)))
 358         (if convert-backslash
 359             (while (string-match "[\\]" temp pos)
 360               (setq temp (replace-match "" t t temp))
 361               (if start
 362                   (setq start (1- start)))
 363               (setq pos (match-end 0))))
 364         (setq result (cons temp result))))
 365     (setq definition (mapconcat (function identity)
 366                                 (nreverse result)
 367                                 ", "))
 368     (setq tem (assoc name mail-aliases))
 369     (if tem
 370         (rplacd tem definition)
 371       (setq mail-aliases (cons (cons name definition) mail-aliases)
 372             mail-names t))))
 373
 374 ;;;###autoload
 375 (defun mail-complete (arg)
 376   "Perform completion on header field or word preceding point.
 377 Completable headers are according to `mail-complete-alist'.  If none matches
 378 current header, calls `mail-complete-function' and passes prefix arg if any."
 379   (interactive "P")
 380   ;; Read the defaults first, if we have not done so.
 381   (sendmail-sync-aliases)
 382   (if (eq mail-aliases t)
 383       (progn
 384         (setq mail-aliases nil)
 385         (if (file-exists-p mail-personal-alias-file)
 386             (build-mail-aliases))))
 387   (let ((list mail-complete-alist))
 388     (if (and (< 0 (mail-header-end))
 389              (save-excursion
 390                (if (re-search-backward "^[^\t]" nil t)
 391                    (while list
 392                      (if (looking-at (car (car list)))
 393                          (setq arg (cdr (car list))
 394                                list ())
 395                        (setq list (cdr list)))))
 396                arg))
 397         (let* ((end (point))
 398                (beg (save-excursion
 399                       (skip-chars-backward "^ \t<,:")
 400                       (point)))
 401                (pattern (buffer-substring beg end))
 402                completion)
 403           (setq list (eval arg)
 404                 completion (try-completion pattern list))
 405           (cond ((eq completion t))
 406                 ((null completion)
 407                  (message "Can't find completion for \"%s\"" pattern)
 408                  (ding))
 409                 ((not (string= pattern completion))
 410                  (delete-region beg end)
 411                  (let ((alist-elt (assoc completion mail-names)))
 412                    (if (cdr alist-elt)
 413                        (cond ((eq mail-complete-style 'parens)
 414                               (insert completion " (" (cdr alist-elt) ")"))
 415                              ((eq mail-complete-style 'angles)
 416                               (insert (cdr alist-elt) " <" completion ">"))
 417                              (t
 418                               (insert completion)))
 419                      (insert completion))))
 420                 (t
 421                  (message "Making completion list...")
 422                  (with-output-to-temp-buffer "*Completions*"
 423                    (display-completion-list
 424                     (all-completions pattern list)))
 425                  (message "Making completion list...%s" "done"))))
 426       (funcall mail-complete-function arg))))
 427
 428 (defun mail-get-names (pattern)
 429   "Fetch local users and global mail addresses for completion.
 430 Consults `/etc/passwd' and a directory service if one is set up via
 431 `mail-directory-function'.
 432 PATTERN is the string we want to complete."
 433   (if (eq mail-local-names t)
 434       (save-excursion
 435         (set-buffer (generate-new-buffer " passwd"))
 436         (let ((files mail-passwd-files))
 437           (while files
 438             (insert-file-contents (car files) nil nil nil t)
 439             (setq files (cdr files))))
 440         (if mail-passwd-command
 441             (call-process shell-file-name nil t nil
 442                           shell-command-switch mail-passwd-command))
 443         (goto-char (point-min))
 444         (setq mail-local-names nil)
 445         (while (not (eobp))
 446           ;;Recognize lines like
 447           ;;  nobody:*:65534:65534::/:
 448           ;;  +demo::::::/bin/csh
 449           ;;  +ethanb
 450           ;;while skipping
 451           ;;  +@SOFTWARE
 452           ;; The second \(...\) matches the user id.
 453           (if (looking-at "\\+?\\([^:@\n+]+\\):[^:\n]*:\\([^\n:]*\\):")
 454               (add-to-list 'mail-local-names
 455                            (cons (match-string 1)
 456                                  (user-full-name
 457                                   (string-to-number (match-string 2))))))
 458           (beginning-of-line 2))
 459         (kill-buffer (current-buffer))))
 460   (if (or (eq mail-names t)
 461           (eq mail-directory-names t))
 462       (let (directory)
 463         (and mail-directory-function
 464              (eq mail-directory-names t)
 465              (setq directory
 466                    (mail-directory (if mail-directory-requery pattern))))
 467         (or mail-directory-requery
 468             (setq mail-directory-names directory))
 469         (if (or directory
 470                 (eq mail-names t))
 471             (setq mail-names
 472                   (sort (append (if (consp mail-aliases)
 473                                     (mapcar
 474                                      (function (lambda (a) (list (car a))))
 475                                      mail-aliases))
 476                                 (if (consp mail-local-names)
 477                                     mail-local-names)
 478                                 (or directory
 479                                     (when (consp mail-directory-names)
 480                                       mail-directory-names)))
 481                         (lambda (a b)
 482                           ;; should cache downcased strings
 483                           (string< (downcase (car a))
 484                                    (downcase (car b)))))))))
 485   mail-names)
 486
 487
 488 (defun mail-directory (pattern)
 489   "Use mail-directory facility to get user names matching PATTERN.
 490 If PATTERN is nil, get all the defined user names.
 491 This function calls `mail-directory-function' to query the directory,
 492 then uses `mail-directory-parser' to parse the output it returns."
 493   (save-excursion
 494     (message "Querying directory...")
 495     (set-buffer (generate-new-buffer " *mail-directory*"))
 496     (funcall mail-directory-function pattern)
 497     (goto-char 1)
 498     (let (directory)
 499       (if (stringp mail-directory-parser)
 500           (while (re-search-forward mail-directory-parser nil t)
 501             (setq directory
 502                   (cons (match-string 1) directory)))
 503         (if mail-directory-parser
 504             (setq directory (funcall mail-directory-parser))
 505           (while (not (eobp))
 506             (setq directory
 507                   (cons (buffer-substring (point)
 508                                           (progn
 509                                             (forward-line)
 510                                             (if (bolp)
 511                                                 (1- (point))
 512                                               (point))))
 513                         directory)))))
 514       (kill-buffer (current-buffer))
 515       (message "Querying directory...done")
 516       directory)))
 517
 518
 519 (defun mail-directory-process (pattern)
 520   "Run a shell command to output names in directory.
 521 See `mail-directory-process'."
 522   (when (consp mail-directory-process)
 523     (apply 'call-process (eval (car mail-directory-process)) nil t nil
 524            (mapcar 'eval (cdr mail-directory-process)))))
 525
 526 ;; This should handle a dialog.  Currently expects port to spit out names.
 527 (defun mail-directory-stream (pattern)
 528   "Open a stream to retrieve names in directory.
 529 See `mail-directory-stream'."
 530   (let (mailalias-done)
 531     (set-process-sentinel
 532      (apply 'open-network-stream "mailalias" (current-buffer)
 533             mail-directory-stream)
 534      (lambda (x y)
 535        (setq mailalias-done t)))
 536     (while (not mailalias-done)
 537       (sit-for .1))))
 538
 539 (defun mail-sentto-newsgroups ()
 540   "Return all entries from Newsgroups: header as completion alist."
 541   (save-excursion
 542     (if (mail-position-on-field "newsgroups" t)
 543         (let ((point (point))
 544               list)
 545           (while (< (skip-chars-backward "^:, \t\n") 0)
 546             (setq list `((,(buffer-substring (point) point))
 547                          ,@list))
 548             (skip-chars-backward ", \t\n")
 549             (setq point (point)))
 550           list))))
 551
 552 (provide 'mailalias)
 553
 554 ;; arch-tag: 1d6a0f87-eb34-4d45-8816-60c1b952cf46
 555 ;;; mailalias.el ends here