lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality -*-byte-compile-dynamic: t;-*-
   2
   3 ;; Copyright (C) 1993, 1994, 1997, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   8 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   9 ;; Keywords: dired extensions files
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  29 ;; 1.191, hacked up for GNU Emacs.  Redundant or conflicting material has
  30 ;; been removed or renamed in order to work properly with dired of GNU
  31 ;; Emacs.  All suggestions or comments are most welcomed.
  32
  33 ;;
  34 ;; Please, PLEASE, *PLEASE* see the info pages.
  35 ;;
  36
  37 ;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  38
  39 ;; INSTALLATION: In your ~/.emacs,
  40 ;;
  41 ;; (add-hook 'dired-load-hook
  42 ;;           (function (lambda ()
  43 ;;                       (load "dired-x")
  44 ;;                       ;; Set global variables here.  For example:
  45 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  46 ;;                       )))
  47 ;; (add-hook 'dired-mode-hook
  48 ;;           (function (lambda ()
  49 ;;                       ;; Set buffer-local variables here.  For example:
  50 ;;                       ;; (dired-omit-mode 1)
  51 ;;                       )))
  52 ;;
  53 ;; At load time dired-x.el will install itself, redefine some functions, and
  54 ;; bind some dired keys.  *Please* see the info pages for more details.
  55
  56 ;; *Please* see the info pages for more details.
  57
  58 ;; User defined variables:
  59 ;;
  60 ;;      dired-bind-vm
  61 ;;      dired-vm-read-only-folders
  62 ;;      dired-bind-jump
  63 ;;      dired-bind-info
  64 ;;      dired-bind-man
  65 ;;      dired-x-hands-off-my-keys
  66 ;;      dired-find-subdir
  67 ;;      dired-enable-local-variables
  68 ;;      dired-local-variables-file
  69 ;;      dired-guess-shell-gnutar
  70 ;;      dired-guess-shell-gzip-quiet
  71 ;;      dired-guess-shell-znew-switches
  72 ;;      dired-guess-shell-alist-user
  73 ;;      dired-clean-up-buffers-too
  74 ;;      dired-omit-mode
  75 ;;      dired-omit-files
  76 ;;      dired-omit-extensions
  77 ;;      dired-omit-size-limit
  78 ;;
  79 ;; To find out more about these variables, load this file, put your cursor at
  80 ;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  81 ;; the info pages for more details.
  82
  83 ;; When loaded this code redefines the following functions of GNU Emacs
  84 ;;
  85 ;;   Function                         Found in this file of GNU Emacs
  86 ;;   --------                         -------------------------------
  87 ;;   dired-clean-up-after-deletion    ../lisp/dired.el
  88 ;;   dired-find-buffer-nocreate       ../lisp/dired.el
  89 ;;   dired-initial-position           ../lisp/dired.el
  90 ;;
  91 ;;   dired-add-entry                  ../lisp/dired-aux.el
  92 ;;   dired-read-shell-command         ../lisp/dired-aux.el
  93
  94 \f
  95 ;;; Code:
  96
  97 ;; LOAD.
  98
  99 ;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 100 ;; here in case the user has autoloaded dired-x via the dired-jump key binding
 101 ;; (instead of autoloading to dired as is suggested in the info-pages).
 102
 103 (require 'dired)
 104
 105 ;; We will redefine some functions and also need some macros so we need to
 106 ;; load dired stuff of GNU Emacs.
 107
 108 (require 'dired-aux)
 109
 110 (defvar vm-folder-directory)
 111 (eval-when-compile (require 'man))
 112
 113 ;;; User-defined variables.
 114
 115 (defgroup dired-x nil
 116   "Extended directory editing (dired-x)."
 117   :group 'dired)
 118
 119 (defgroup dired-keys nil
 120   "Dired keys customizations."
 121   :prefix "dired-"
 122   :group 'dired-x)
 123
 124 (defcustom dired-bind-vm nil
 125   "*Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
 126 Also, RMAIL files contain -*- rmail -*- at the top so \"f\",
 127 `dired-advertised-find-file', will run rmail."
 128   :type 'boolean
 129   :group 'dired-keys)
 130
 131 (defcustom dired-bind-jump t
 132   "*Non-nil means bind `dired-jump' to C-x C-j, otherwise do not."
 133   :type 'boolean
 134   :group 'dired-keys)
 135
 136 (defcustom dired-bind-man t
 137   "*Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not."
 138   :type 'boolean
 139   :group 'dired-keys)
 140
 141 (defcustom dired-bind-info t
 142   "*Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not."
 143   :type 'boolean
 144   :group 'dired-keys)
 145
 146 (defcustom dired-vm-read-only-folders nil
 147   "*If non-nil, \\[dired-vm] will visit all folders read-only.
 148 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 149 files not writable by you are visited read-only.
 150
 151 Read-only folders only work in VM 5, not in VM 4."
 152   :type '(choice (const :tag "off" nil)
 153                  (const :tag "on" t)
 154                  (other :tag "non-writable only" if-file-read-only))
 155   :group 'dired-x)
 156
 157 (define-minor-mode dired-omit-mode
 158   "Toggle Dired-Omit mode.
 159 With numeric ARG, enable Dired-Omit mode if ARG is positive, disable
 160 otherwise.  Enabling and disabling is buffer-local.
 161 If enabled, \"uninteresting\" files are not listed.
 162 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 163 plus those ending with extensions in `dired-omit-extensions'."
 164   :group 'dired-x
 165   (if dired-omit-mode
 166       ;; This will mention how many lines were omitted:
 167       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 168     (revert-buffer)))
 169
 170 ;; For backward compatibility
 171 (define-obsolete-variable-alias 'dired-omit-files-p 'dired-omit-mode "22.1")
 172
 173 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 174   "*Filenames matching this regexp will not be displayed.
 175 This only has effect when `dired-omit-mode' is t.  See interactive function
 176 `dired-omit-mode' \(\\[dired-omit-mode]\) and variable
 177 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 178 files and lock files."
 179   :type 'regexp
 180   :group 'dired-x)
 181
 182 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 183   "*If non-nil, Dired always finds a directory in a buffer of its own.
 184 If nil, Dired finds the directory as a subdirectory in some other buffer
 185 if it is present as one.
 186
 187 If there are several dired buffers for a directory, the most recently
 188 used is chosen.
 189
 190 Dired avoids switching to the current buffer, so that if you have
 191 a normal and a wildcard buffer for the same directory, \\[dired] will
 192 toggle between those two."
 193   :type 'boolean
 194   :group 'dired-x)
 195
 196 (defcustom dired-omit-size-limit 30000
 197   "*Maximum size for the \"omitting\" feature.
 198 If nil, there is no maximum size."
 199   :type '(choice (const :tag "no maximum" nil) integer)
 200   :group 'dired-x)
 201
 202 (defcustom dired-enable-local-variables t
 203   "*Control use of local-variables lists in Dired.
 204 The value can be t, nil or something else.
 205 A value of t means local-variables lists are obeyed;
 206 nil means they are ignored; anything else means query.
 207
 208 This temporarily overrides the value of `enable-local-variables' when listing
 209 a directory.  See also `dired-local-variables-file'."
 210   :type 'boolean
 211   :group 'dired-x)
 212
 213 (defcustom dired-guess-shell-gnutar (when (or (eq system-type 'gnu)
 214                                               (eq system-type 'gnu/linux))
 215                                       "tar")
 216   "*If non-nil, name of GNU tar executable.
 217 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 218 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 219 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 220   :type '(choice (const :tag "Not GNU tar" nil)
 221                  (string :tag "Command name"))
 222   :group 'dired-x)
 223
 224 (defcustom dired-guess-shell-gzip-quiet t
 225   "*Non-nil says pass -q to gzip overriding verbose GZIP environment."
 226   :type 'boolean
 227   :group 'dired-x)
 228
 229 (defcustom dired-guess-shell-znew-switches nil
 230   "*If non-nil, then string of switches passed to `znew', example: \"-K\"."
 231   :type '(choice (const :tag "None" nil)
 232                  (string :tag "Switches"))
 233   :group 'dired-x)
 234
 235 (defcustom dired-clean-up-buffers-too t
 236   "*Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 237   :type 'boolean
 238   :group 'dired-x)
 239
 240 ;;; KEY BINDINGS.
 241
 242 (define-key dired-mode-map "\M-o" 'dired-omit-mode)
 243 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 244 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 245 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 246 (define-key dired-mode-map "*." 'dired-mark-extension)
 247 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 248 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 249 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 250 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 251 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 252 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 253 (define-key dired-mode-map "V" 'dired-do-run-mail)
 254
 255 (if dired-bind-man
 256     (define-key dired-mode-map "N" 'dired-man))
 257
 258 (if dired-bind-info
 259     (define-key dired-mode-map "I" 'dired-info))
 260
 261 ;;; MENU BINDINGS
 262
 263 (let ((menu-bar (lookup-key dired-mode-map [menu-bar])))
 264   (let ((menu (lookup-key menu-bar [operate])))
 265     (define-key-after
 266       menu
 267       [find-files]
 268       '(menu-item
 269         "Find files"
 270         dired-do-find-marked-files
 271         :help "Find current or marked files")
 272       'delete)
 273     (define-key-after
 274       menu
 275       [relsymlink]
 276       '(menu-item
 277         "Relative symlink to..."
 278         dired-do-relsymlink
 279         :visible (fboundp 'make-symbolic-link)
 280         :help "Make relative symbolic links for current or marked files")
 281       'symlink))
 282   (let ((menu (lookup-key menu-bar [mark])))
 283     (define-key-after
 284       menu
 285       [flag-extension]
 286       '(menu-item
 287         "Flag extension..."
 288         dired-flag-extension
 289         :help "Flag files with a certain extension for deletion")
 290       'garbage-files)
 291     (define-key-after
 292       menu
 293       [mark-extension]
 294       '(menu-item
 295         "Mark extension..."
 296         dired-mark-extension
 297         :help "Mark files with a certain extension")
 298       'symlinks)
 299     (define-key-after
 300       menu
 301       [mark-omitted]
 302       '(menu-item
 303         "Mark omitted"
 304         dired-mark-omitted
 305         :help "Mark files matching `dired-omit-files' and `dired-omit-extensions'")
 306       'mark-extension))
 307   (let ((menu (lookup-key menu-bar [regexp])))
 308     (define-key-after
 309       menu
 310       [relsymlink-regexp]
 311       '(menu-item
 312         "Relative symlink..."
 313         dired-do-relsymlink-regexp
 314         :visible (fboundp 'make-symbolic-link)
 315         :help "Make relative symbolic links for files matching regexp")
 316       'symlink))
 317   (let ((menu (lookup-key menu-bar [immediate])))
 318     (define-key-after
 319       menu
 320       [omit-mode]
 321       '(menu-item
 322         "Omit mode" dired-omit-mode
 323         :button (:toggle . dired-omit-mode)
 324         :help "Enable or disable omitting \"uninteresting\" files")
 325       'dashes)))
 326
 327 ;;; GLOBAL BINDING.
 328 (if dired-bind-jump
 329     (progn
 330       (define-key global-map "\C-x\C-j" 'dired-jump)
 331       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 332
 333 \f
 334 ;; Install into appropriate hooks.
 335
 336 (add-hook 'dired-mode-hook 'dired-extra-startup)
 337 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 338
 339 (defun dired-extra-startup ()
 340   "Automatically put on `dired-mode-hook' to get extra Dired features:
 341 \\<dired-mode-map>
 342   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 343   \\[dired-info]\t-- run info on file
 344   \\[dired-man]\t-- run man on file
 345   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 346   \\[dired-omit-mode]\t-- toggle omitting of files
 347   \\[dired-mark-sexp]\t-- mark by Lisp expression
 348   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring;
 349   \t   you can feed it to other commands using \\[yank]
 350
 351 For more features, see variables
 352
 353   `dired-bind-vm'
 354   `dired-bind-jump'
 355   `dired-bind-info'
 356   `dired-bind-man'
 357   `dired-vm-read-only-folders'
 358   `dired-omit-mode'
 359   `dired-omit-files'
 360   `dired-omit-extensions'
 361   `dired-omit-size-limit'
 362   `dired-find-subdir'
 363   `dired-enable-local-variables'
 364   `dired-local-variables-file'
 365   `dired-guess-shell-gnutar'
 366   `dired-guess-shell-gzip-quiet'
 367   `dired-guess-shell-znew-switches'
 368   `dired-guess-shell-alist-user'
 369   `dired-clean-up-buffers-too'
 370
 371 See also functions
 372
 373   `dired-flag-extension'
 374   `dired-virtual'
 375   `dired-jump'
 376   `dired-man'
 377   `dired-vm'
 378   `dired-rmail'
 379   `dired-info'
 380   `dired-do-find-marked-files'"
 381   (interactive)
 382
 383   ;; These must be done in each new dired buffer.
 384   (dired-hack-local-variables)
 385   (dired-omit-startup))
 386
 387 \f
 388 ;;; BUFFER CLEANING.
 389
 390 ;; REDEFINE.
 391 (defun dired-clean-up-after-deletion (fn)
 392   "Clean up after a deleted file or directory FN.
 393 Remove expanded subdir of deleted dir, if any."
 394   (save-excursion (and (cdr dired-subdir-alist)
 395                        (dired-goto-subdir fn)
 396                        (dired-kill-subdir)))
 397
 398   ;; Offer to kill buffer of deleted file FN.
 399   (if dired-clean-up-buffers-too
 400       (progn
 401         (let ((buf (get-file-buffer fn)))
 402           (and buf
 403                (funcall (function y-or-n-p)
 404                         (format "Kill buffer of %s, too? "
 405                                 (file-name-nondirectory fn)))
 406                (save-excursion ; you never know where kill-buffer leaves you
 407                  (kill-buffer buf))))
 408         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 409               (buf nil))
 410           (and buf-list
 411                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 412                                  (dired-plural-s (length buf-list))
 413                                  (file-name-nondirectory fn)))
 414                (while buf-list
 415                  (save-excursion (kill-buffer (car buf-list)))
 416                  (setq buf-list (cdr buf-list)))))))
 417   ;; Anything else?
 418   )
 419
 420 \f
 421 ;;; EXTENSION MARKING FUNCTIONS.
 422
 423 ;; Mark files with some extension.
 424 (defun dired-mark-extension (extension &optional marker-char)
 425   "Mark all files with a certain EXTENSION for use in later commands.
 426 A `.' is *not* automatically prepended to the string entered."
 427   ;; EXTENSION may also be a list of extensions instead of a single one.
 428   ;; Optional MARKER-CHAR is marker to use.
 429   (interactive "sMarking extension: \nP")
 430   (or (listp extension)
 431       (setq extension (list extension)))
 432   (dired-mark-files-regexp
 433    (concat ".";; don't match names with nothing but an extension
 434            "\\("
 435            (mapconcat 'regexp-quote extension "\\|")
 436            "\\)$")
 437    marker-char))
 438
 439 (defun dired-flag-extension (extension)
 440   "In dired, flag all files with a certain EXTENSION for deletion.
 441 A `.' is *not* automatically prepended to the string entered."
 442   (interactive "sFlagging extension: ")
 443   (dired-mark-extension extension dired-del-marker))
 444
 445 ;; Define some unpopular file extensions.  Used for cleaning and omitting.
 446
 447 (defvar dired-patch-unclean-extensions
 448   '(".rej" ".orig")
 449   "List of extensions of dispensable files created by the `patch' program.")
 450
 451 (defvar dired-tex-unclean-extensions
 452   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 453   "List of extensions of dispensable files created by TeX.")
 454
 455 (defvar dired-latex-unclean-extensions
 456   '(".idx" ".lof" ".lot" ".glo")
 457   "List of extensions of dispensable files created by LaTeX.")
 458
 459 (defvar dired-bibtex-unclean-extensions
 460   '(".blg" ".bbl")
 461   "List of extensions of dispensable files created by BibTeX.")
 462
 463 (defvar dired-texinfo-unclean-extensions
 464   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 465     ".tp" ".tps" ".vr" ".vrs")
 466   "List of extensions of dispensable files created by texinfo.")
 467
 468 (defun dired-clean-patch ()
 469   "Flag dispensable files created by patch for deletion.
 470 See variable `dired-patch-unclean-extensions'."
 471   (interactive)
 472   (dired-flag-extension dired-patch-unclean-extensions))
 473
 474 (defun dired-clean-tex ()
 475   "Flag dispensable files created by [La]TeX etc. for deletion.
 476 See variables `dired-tex-unclean-extensions',
 477 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 478 `dired-texinfo-unclean-extensions'."
 479   (interactive)
 480   (dired-flag-extension (append dired-texinfo-unclean-extensions
 481                                 dired-latex-unclean-extensions
 482                                 dired-bibtex-unclean-extensions
 483                                 dired-tex-unclean-extensions)))
 484
 485 (defun dired-very-clean-tex ()
 486   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 487 See variables `dired-texinfo-unclean-extensions',
 488 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 489 `dired-texinfo-unclean-extensions'."
 490   (interactive)
 491   (dired-flag-extension (append dired-texinfo-unclean-extensions
 492                                 dired-latex-unclean-extensions
 493                                 dired-bibtex-unclean-extensions
 494                                 dired-tex-unclean-extensions
 495                                 (list ".dvi"))))
 496 \f
 497 ;;; JUMP.
 498
 499 ;;;###autoload
 500 (defun dired-jump (&optional other-window)
 501   "Jump to dired buffer corresponding to current buffer.
 502 If in a file, dired the current directory and move to file's line.
 503 If in Dired already, pop up a level and goto old directory's line.
 504 In case the proper dired file line cannot be found, refresh the dired
 505 buffer and try again."
 506   (interactive "P")
 507   (let* ((file buffer-file-name)
 508          (dir (if file (file-name-directory file) default-directory)))
 509     (if (eq major-mode 'dired-mode)
 510         (progn
 511           (setq dir (dired-current-directory))
 512           (dired-up-directory other-window)
 513           (or (dired-goto-file dir)
 514               ;; refresh and try again
 515               (progn
 516                 (dired-insert-subdir (file-name-directory dir))
 517                 (dired-goto-file dir))))
 518       (if other-window
 519           (dired-other-window dir)
 520         (dired dir))
 521       (if file
 522           (or (dired-goto-file file)
 523               ;; refresh and try again
 524               (progn
 525                 (dired-insert-subdir (file-name-directory file))
 526                 (dired-goto-file file))
 527               ;; Toggle omitting, if it is on, and try again.
 528               (if dired-omit-mode
 529                   (progn
 530                     (dired-omit-mode)
 531                     (dired-goto-file file))))))))
 532
 533 (defun dired-jump-other-window ()
 534   "Like \\[dired-jump] (`dired-jump') but in other window."
 535   (interactive)
 536   (dired-jump t))
 537 \f
 538 ;;; OMITTING.
 539
 540 ;; Enhanced omitting of lines from directory listings.
 541 ;; Marked files are never omitted.
 542
 543 ;; should probably get rid of this and always use 'no-dir.
 544 ;; sk 28-Aug-1991 09:37
 545 (defvar dired-omit-localp 'no-dir
 546   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 547 If it is `no-dir', omitting is much faster, but you can only match
 548 against the non-directory part of the file name.  Set it to nil if you
 549 need to match the entire file name.")
 550
 551 ;; \017=^O for Omit - other packages can chose other control characters.
 552 (defvar dired-omit-marker-char ?\017
 553   "Temporary marker used by dired-omit.
 554 Should never be used as marker by the user or other packages.")
 555
 556 (defun dired-omit-startup ()
 557   (or (assq 'dired-omit-mode minor-mode-alist)
 558       (setq minor-mode-alist
 559             (append '((dired-omit-mode
 560                        (:eval (if (eq major-mode 'dired-mode)
 561                                   " Omit" ""))))
 562                     minor-mode-alist))))
 563
 564 (defun dired-mark-omitted ()
 565   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 566   (interactive)
 567   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 568   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 569
 570 (defvar dired-omit-extensions
 571   (append completion-ignored-extensions
 572           dired-latex-unclean-extensions
 573           dired-bibtex-unclean-extensions
 574           dired-texinfo-unclean-extensions)
 575   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 576 Defaults to elements of `completion-ignored-extensions',
 577 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 578 `dired-texinfo-unclean-extensions'.
 579
 580 See interactive function `dired-omit-mode' \(\\[dired-omit-mode]\) and
 581 variables `dired-omit-mode' and `dired-omit-files'.")
 582
 583 (defun dired-omit-expunge (&optional regexp)
 584   "Erases all unmarked files matching REGEXP.
 585 Does nothing if global variable `dired-omit-mode' is nil, or if called
 586   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 587 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 588   filenames ending in `dired-omit-extensions'.
 589 If REGEXP is the empty string, this function is a no-op.
 590
 591 This functions works by temporarily binding `dired-marker-char' to
 592 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 593   (interactive "sOmit files (regexp): ")
 594   (if (and dired-omit-mode
 595            (or (interactive-p)
 596                (not dired-omit-size-limit)
 597                (< (buffer-size) dired-omit-size-limit)
 598                (progn
 599                  (message "Not omitting: directory larger than %d characters."
 600                           dired-omit-size-limit)
 601                  (setq dired-omit-mode nil)
 602                  nil)))
 603       (let ((omit-re (or regexp (dired-omit-regexp)))
 604             (old-modified-p (buffer-modified-p))
 605             count)
 606         (or (string= omit-re "")
 607             (let ((dired-marker-char dired-omit-marker-char))
 608               (message "Omitting...")
 609               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 610                   (progn
 611                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 612                     (force-mode-line-update))
 613                 (message "(Nothing to omit)"))))
 614         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 615         ;; in mode-line of omitted buffers.
 616         (set-buffer-modified-p (and old-modified-p
 617                                     (save-excursion
 618                                       (goto-char (point-min))
 619                                       (re-search-forward dired-re-mark nil t))))
 620         count)))
 621
 622 (defun dired-omit-regexp ()
 623   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 624           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 625           (if dired-omit-extensions
 626               (concat ".";; a non-extension part should exist
 627                       "\\("
 628                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 629                       "\\)$")
 630             "")))
 631
 632 ;; Returns t if any work was done, nil otherwise.
 633 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 634   "Mark unmarked files matching REGEXP, displaying MSG.
 635 REGEXP is matched against the entire file name.
 636 Does not re-mark files which already have a mark.
 637 With prefix argument, unflag all those files.
 638 Optional fourth argument LOCALP is as in `dired-get-filename'."
 639   (interactive "P")
 640   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 641     (dired-mark-if
 642      (and
 643       ;; not already marked
 644       (looking-at " ")
 645       ;; uninteresting
 646       (let ((fn (dired-get-filename localp t)))
 647         (and fn (string-match regexp fn))))
 648      msg)))
 649
 650 ;; Compiler does not get fset.
 651 (declare-function dired-omit-old-add-entry "dired-x")
 652
 653 ;; REDEFINE.
 654 ;; Redefine dired-aux.el's version of `dired-add-entry'
 655 ;; Save old defun if not already done:
 656 (or (fboundp 'dired-omit-old-add-entry)
 657     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 658
 659 ;; REDEFINE.
 660 (defun dired-omit-new-add-entry (filename &optional marker-char relative)
 661   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 662   ;; files that are going to be omitted anyway.
 663   (if dired-omit-mode
 664       ;; perhaps return t without calling ls
 665       (let ((omit-re (dired-omit-regexp)))
 666         (if (or (string= omit-re "")
 667                 (not
 668                  (string-match omit-re
 669                                (cond
 670                                 ((eq 'no-dir dired-omit-localp)
 671                                  filename)
 672                                 ((eq t dired-omit-localp)
 673                                  (dired-make-relative filename))
 674                                 (t
 675                                  (dired-make-absolute
 676                                   filename
 677                                   (file-name-directory filename)))))))
 678             ;; if it didn't match, go ahead and add the entry
 679             (dired-omit-old-add-entry filename marker-char relative)
 680           ;; dired-add-entry returns t for success, perhaps we should
 681           ;; return file-exists-p
 682           t))
 683     ;; omitting is not turned on at all
 684     (dired-omit-old-add-entry filename marker-char relative)))
 685
 686 ;; Redefine it.
 687 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 688
 689 \f
 690 ;;; VIRTUAL DIRED MODE.
 691
 692 ;; For browsing `ls -lR' listings in a dired-like fashion.
 693
 694 (defalias 'virtual-dired 'dired-virtual)
 695 (defun dired-virtual (dirname &optional switches)
 696   "Put this buffer into Virtual Dired mode.
 697
 698 In Virtual Dired mode, all commands that do not actually consult the
 699 filesystem will work.
 700
 701 This is useful if you want to peruse and move around in an ls -lR
 702 output file, for example one you got from an ftp server.  With
 703 ange-ftp, you can even dired a directory containing an ls-lR file,
 704 visit that file and turn on virtual dired mode.  But don't try to save
 705 this file, as dired-virtual indents the listing and thus changes the
 706 buffer.
 707
 708 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 709 resume it in a later session.
 710
 711 Type \\<dired-mode-map>\\[revert-buffer] \
 712 in the Virtual Dired buffer and answer `y' to convert
 713 the virtual to a real dired buffer again.  You don't have to do this, though:
 714 you can relist single subdirs using \\[dired-do-redisplay]."
 715
 716   ;; DIRNAME is the top level directory of the buffer.  It will become
 717   ;; its `default-directory'.  If nil, the old value of
 718   ;; default-directory is used.
 719
 720   ;; Optional SWITCHES are the ls switches to use.
 721
 722   ;; Shell wildcards will be used if there already is a `wildcard'
 723   ;; line in the buffer (thus it is a saved Dired buffer), but there
 724   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 725   ;; hand if you want them.
 726
 727   (interactive
 728    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 729   (goto-char (point-min))
 730   (or (looking-at "  ")
 731       ;; if not already indented, do it now:
 732       (indent-region (point-min) (point-max) 2))
 733   (or dirname (setq dirname default-directory))
 734   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 735   (setq default-directory dirname)      ; contains no wildcards
 736   (let ((wildcard (save-excursion
 737                     (goto-char (point-min))
 738                     (forward-line 1)
 739                     (and (looking-at "^  wildcard ")
 740                          (buffer-substring (match-end 0)
 741                                            (progn (end-of-line) (point)))))))
 742   (if wildcard
 743         (setq dirname (expand-file-name wildcard default-directory))))
 744   ;; If raw ls listing (not a saved old dired buffer), give it a
 745   ;; decent subdir headerline:
 746   (goto-char (point-min))
 747   (or (looking-at dired-subdir-regexp)
 748       (insert "  "
 749               (directory-file-name (file-name-directory default-directory))
 750               ":\n"))
 751   (dired-mode dirname (or switches dired-listing-switches))
 752   (setq mode-name "Virtual Dired"
 753         revert-buffer-function 'dired-virtual-revert)
 754   (set (make-local-variable 'dired-subdir-alist) nil)
 755   (dired-build-subdir-alist)
 756   (goto-char (point-min))
 757   (dired-initial-position dirname))
 758
 759 (defun dired-virtual-guess-dir ()
 760   "Guess and return appropriate working directory of this buffer.
 761 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 762 based upon buffer contents.  If nothing could be guessed, returns
 763 nil."
 764
 765   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 766         (subexpr 2))
 767     (goto-char (point-min))
 768     (cond ((looking-at regexp)
 769            ;; If a saved dired buffer, look to which dir and
 770            ;; perhaps wildcard it belongs:
 771            (let ((dir (buffer-substring (match-beginning subexpr)
 772                                         (match-end subexpr))))
 773              (file-name-as-directory dir)))
 774           ;; Else no match for headerline found.  It's a raw ls listing.
 775           ;; In raw ls listings the directory does not have a headerline
 776           ;; try parent of first subdir, if any
 777           ((re-search-forward regexp nil t)
 778            (file-name-directory
 779             (directory-file-name
 780              (file-name-as-directory
 781               (buffer-substring (match-beginning subexpr)
 782                                 (match-end subexpr))))))
 783           (t                            ; if all else fails
 784            nil))))
 785
 786
 787 (defun dired-virtual-revert (&optional arg noconfirm)
 788   (if (not
 789        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 790       (error "Cannot revert a Virtual Dired buffer")
 791     (setq mode-name "Dired"
 792           revert-buffer-function 'dired-revert)
 793     (revert-buffer)))
 794
 795 ;; A zero-arg version of dired-virtual.
 796 (defun dired-virtual-mode ()
 797   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 798 Useful on `magic-mode-alist' with the regexp
 799
 800   \"^  \\\\(/[^ /]+\\\\)+/?:$\"
 801
 802 to put saved dired buffers automatically into Virtual Dired mode.
 803
 804 Also useful for `auto-mode-alist' like this:
 805
 806   (add-to-list 'auto-mode-alist
 807                '(\"[^/]\\\\.dired\\\\'\" . dired-virtual-mode))"
 808   (interactive)
 809   (dired-virtual (dired-virtual-guess-dir)))
 810
 811 \f
 812 ;;; SMART SHELL.
 813
 814 ;; An Emacs buffer can have but one working directory, stored in the
 815 ;; buffer-local variable `default-directory'.  A Dired buffer may have
 816 ;; several subdirectories inserted, but still has but one working directory:
 817 ;; that of the top level Dired directory in that buffer.  For some commands
 818 ;; it is appropriate that they use the current Dired directory instead of
 819 ;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 820 ;; mechanism is provided for special handling of the working directory in
 821 ;; special major modes.
 822
 823 ;; It's easier to add to this alist than redefine function
 824 ;; default-directory while keeping the old information.
 825 (defconst default-directory-alist
 826   '((dired-mode . (if (fboundp 'dired-current-directory)
 827                       (dired-current-directory)
 828                     default-directory)))
 829   "Alist of major modes and their opinion on `default-directory'.
 830 This is given as a Lisp expression to evaluate.  A resulting value of
 831 nil is ignored in favor of `default-directory'.")
 832
 833 (defun dired-default-directory ()
 834   "Usage like variable `default-directory'.
 835 Knows about the special cases in variable `default-directory-alist'."
 836   (or (eval (cdr (assq major-mode default-directory-alist)))
 837       default-directory))
 838
 839 (defun dired-smart-shell-command (command &optional output-buffer error-buffer)
 840   "Like function `shell-command', but in the current Virtual Dired directory."
 841   (interactive
 842    (list
 843     (minibuffer-with-setup-hook
 844         (lambda ()
 845           (set (make-local-variable 'minibuffer-default-add-function)
 846                'minibuffer-default-add-shell-commands))
 847       (read-shell-command "Shell command: " nil nil
 848                           (cond
 849                            (buffer-file-name (file-relative-name buffer-file-name))
 850                            ((eq major-mode 'dired-mode) (dired-get-filename t t)))))
 851     current-prefix-arg
 852     shell-command-default-error-buffer))
 853   (let ((default-directory (dired-default-directory)))
 854     (shell-command command output-buffer error-buffer)))
 855
 856 \f
 857 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 858
 859 ;; Brief Description:
 860 ;;;
 861 ;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 862 ;;;
 863 ;; * `dired-extra-startup' calls `dired-hack-local-variables'
 864 ;;;
 865 ;; * `dired-hack-local-variables' checks the value of
 866 ;;;   `dired-local-variables-file'
 867 ;;;
 868 ;; * Check if `dired-local-variables-file' is a non-nil string and is a
 869 ;;;   filename found in the directory of the Dired Buffer being created.
 870 ;;;
 871 ;; * If `dired-local-variables-file' satisfies the above, then temporarily
 872 ;;;   include it in the Dired Buffer at the bottom.
 873 ;;;
 874 ;; * Set `enable-local-variables' temporarily to the user variable
 875 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 876 ;;;   Dired Buffer.
 877
 878 (defvar dired-local-variables-file (convert-standard-filename ".dired")
 879   "Filename, as string, containing local dired buffer variables to be hacked.
 880 If this file found in current directory, then it will be inserted into dired
 881 buffer and `hack-local-variables' will be run.  See Info node
 882 `(emacs)File Variables' for more information on local variables.
 883 See also `dired-enable-local-variables'.")
 884
 885 (defun dired-hack-local-variables ()
 886   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 887   (if (and dired-local-variables-file
 888            (stringp dired-local-variables-file)
 889            (file-exists-p dired-local-variables-file))
 890       (let ((opoint (point-max))
 891             buffer-read-only
 892             ;; In case user has `enable-local-variables' set to nil we
 893             ;; override it locally with dired's variable.
 894             (enable-local-variables dired-enable-local-variables))
 895         ;; Insert 'em.
 896         (save-excursion
 897           (goto-char opoint)
 898           (insert "\^L\n")
 899           (insert-file-contents dired-local-variables-file))
 900         ;; Hack 'em.
 901         (let ((buffer-file-name dired-local-variables-file))
 902           (hack-local-variables))
 903         ;; Make sure that the modeline shows the proper information.
 904         (dired-sort-set-modeline)
 905         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 906         (delete-region opoint (point-max)))))
 907
 908 (defun dired-omit-here-always ()
 909   "Create `dired-local-variables-file' for omitting and reverts directory.
 910 Sets `dired-omit-mode' to t in a local variables file that is readable by
 911 dired."
 912   (interactive)
 913   (if (file-exists-p dired-local-variables-file)
 914       (message "File `./%s' already exists." dired-local-variables-file)
 915
 916     ;; Create `dired-local-variables-file'.
 917     (with-current-buffer (get-buffer-create " *dot-dired*")
 918       (erase-buffer)
 919       (insert "Local Variables:\ndired-omit-mode: t\nEnd:\n")
 920       (write-file dired-local-variables-file)
 921       (kill-buffer (current-buffer)))
 922
 923     ;; Run extra-hooks and revert directory.
 924     (dired-extra-startup)
 925     (dired-revert)))
 926
 927 \f
 928 ;;; GUESS SHELL COMMAND.
 929
 930 ;; Brief Description:
 931 ;;;
 932 ;; `dired-do-shell-command' is bound to `!' by dired.el.
 933 ;;;
 934 ;; * Redefine `dired-read-shell-command' so it calls
 935 ;;;   `dired-guess-shell-command'.
 936 ;;;
 937 ;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 938 ;;;    marked files.
 939 ;;;
 940 ;; * Parse `dired-guess-shell-alist-user' and
 941 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 942 ;;;   that matches the first file in the file list.
 943 ;;;
 944 ;; * If the REGEXP matches all the entries of the file list then evaluate
 945 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 946 ;;;   string.  COMMAND may be a list of commands.
 947 ;;;
 948 ;; * Return this command to `dired-guess-shell-command' which prompts user
 949 ;;;   with it.  The list of commands is put into the list of default values.
 950 ;;;   If a command is used successfully then it is stored permanently in
 951 ;;;   `dired-shell-command-history'.
 952
 953 ;; Guess what shell command to apply to a file.
 954 (defvar dired-shell-command-history nil
 955   "History list for commands that read dired-shell commands.")
 956
 957 ;; Default list of shell commands.
 958
 959 ;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 960 ;; install GNU zip's version of zcat.
 961
 962 (defvar dired-guess-shell-alist-default
 963   (list
 964    (list "\\.tar$"
 965          '(if dired-guess-shell-gnutar
 966               (concat dired-guess-shell-gnutar " xvf")
 967             "tar xvf")
 968          ;; Extract files into a separate subdirectory
 969          '(if dired-guess-shell-gnutar
 970               (concat "mkdir " (file-name-sans-extension file)
 971                       "; " dired-guess-shell-gnutar " -C "
 972                       (file-name-sans-extension file) " -xvf")
 973             (concat "mkdir " (file-name-sans-extension file)
 974                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 975          ;; List archive contents.
 976          '(if dired-guess-shell-gnutar
 977               (concat dired-guess-shell-gnutar " tvf")
 978             "tar tvf"))
 979
 980    ;; REGEXPS for compressed archives must come before the .Z rule to
 981    ;; be recognized:
 982    (list "\\.tar\\.Z$"
 983          ;; Untar it.
 984          '(if dired-guess-shell-gnutar
 985               (concat dired-guess-shell-gnutar " zxvf")
 986             (concat "zcat * | tar xvf -"))
 987          ;; Optional conversion to gzip format.
 988          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 989                   " " dired-guess-shell-znew-switches))
 990
 991    ;; gzip'ed archives
 992    (list "\\.t\\(ar\\.\\)?gz$"
 993          '(if dired-guess-shell-gnutar
 994               (concat dired-guess-shell-gnutar " zxvf")
 995             (concat "gunzip -qc * | tar xvf -"))
 996          ;; Extract files into a separate subdirectory
 997          '(if dired-guess-shell-gnutar
 998               (concat "mkdir " (file-name-sans-extension file)
 999                       "; " dired-guess-shell-gnutar " -C "
1000                       (file-name-sans-extension file) " -zxvf")
1001             (concat "mkdir " (file-name-sans-extension file)
1002                     "; gunzip -qc * | tar -C "
1003                     (file-name-sans-extension file) " -xvf -"))
1004          ;; Optional decompression.
1005          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
1006          ;; List archive contents.
1007          '(if dired-guess-shell-gnutar
1008               (concat dired-guess-shell-gnutar " ztvf")
1009             (concat "gunzip -qc * | tar tvf -")))
1010
1011    ;; bzip2'ed archives
1012    (list "\\.t\\(ar\\.bz2\\|bz\\)$"
1013          "bunzip2 -c * | tar xvf -"
1014          ;; Extract files into a separate subdirectory
1015          '(concat "mkdir " (file-name-sans-extension file)
1016                   "; bunzip2 -c * | tar -C "
1017                   (file-name-sans-extension file) " -xvf -")
1018          ;; Optional decompression.
1019          "bunzip2")
1020
1021    '("\\.shar\\.Z$" "zcat * | unshar")
1022    '("\\.shar\\.g?z$" "gunzip -qc * | unshar")
1023
1024    '("\\.e?ps$" "ghostview" "xloadimage" "lpr")
1025    (list "\\.e?ps\\.g?z$" "gunzip -qc * | ghostview -"
1026          ;; Optional decompression.
1027          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1028    (list "\\.e?ps\\.Z$" "zcat * | ghostview -"
1029          ;; Optional conversion to gzip format.
1030          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1031                   " " dired-guess-shell-znew-switches))
1032
1033    '("\\.patch$" "cat * | patch")
1034    (list "\\.patch\\.g?z$" "gunzip -qc * | patch"
1035          ;; Optional decompression.
1036          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1037    (list "\\.patch\\.Z$" "zcat * | patch"
1038          ;; Optional conversion to gzip format.
1039          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1040                   " " dired-guess-shell-znew-switches))
1041
1042    ;; The following four extensions are useful with dired-man ("N" key)
1043    (list "\\.\\(?:[0-9]\\|man\\)$" '(progn (require 'man)
1044                                            (if (Man-support-local-filenames)
1045                                                "man -l"
1046                                              "cat * | tbl | nroff -man -h")))
1047    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z$" '(progn (require 'man)
1048                                                  (if (Man-support-local-filenames)
1049                                                      "man -l"
1050                                                    "gunzip -qc * | tbl | nroff -man -h"))
1051          ;; Optional decompression.
1052          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1053    (list "\\.[0-9]\\.Z$" '(progn (require 'man)
1054                                  (if (Man-support-local-filenames)
1055                                      "man -l"
1056                                    "zcat * | tbl | nroff -man -h"))
1057          ;; Optional conversion to gzip format.
1058          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1059                   " " dired-guess-shell-znew-switches))
1060    '("\\.pod$" "perldoc" "pod2man * | nroff -man")
1061
1062    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
1063    '("\\.au$" "play")                   ; play Sun audiofiles
1064    '("\\.mpe?g$\\|\\.avi$" "xine -p")
1065    '("\\.wav$" "play")
1066    '("\\.uu$" "uudecode")               ; for uudecoded files
1067    '("\\.hqx$" "mcvert")
1068    '("\\.sh$" "sh")                     ; execute shell scripts
1069    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
1070    '("\\.gp$" "gnuplot")
1071    '("\\.p[bgpn]m$" "xloadimage")
1072    '("\\.gif$" "xloadimage")            ; view gif pictures
1073    '("\\.tif$" "xloadimage")
1074    '("\\.png$" "display")               ; xloadimage 4.1 doesn't grok PNG
1075    '("\\.jpe?g$" "xloadimage")
1076    '("\\.fig$" "xfig")                  ; edit fig pictures
1077    '("\\.out$" "xgraph")                ; for plotting purposes.
1078    '("\\.tex$" "latex" "tex")
1079    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
1080    '("\\.pdf$" "xpdf")
1081    '("\\.doc$" "antiword" "strings")
1082    '("\\.rpm$" "rpm -qilp" "rpm -ivh")
1083    '("\\.dia$" "dia")
1084    '("\\.mgp$" "mgp")
1085
1086    ;; Some other popular archivers.
1087    (list "\\.zip$" "unzip" "unzip -l"
1088          ;; Extract files into a separate subdirectory
1089          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1090                   " -d " (file-name-sans-extension file)))
1091    '("\\.zoo$" "zoo x//")
1092    '("\\.lzh$" "lharc x")
1093    '("\\.arc$" "arc x")
1094    '("\\.shar$" "unshar")
1095
1096    ;; Compression.
1097    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1098    (list "\\.dz$" "dictunzip")
1099    (list "\\.bz2$" "bunzip2")
1100    (list "\\.Z$" "uncompress"
1101          ;; Optional conversion to gzip format.
1102          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1103                   " " dired-guess-shell-znew-switches))
1104
1105    '("\\.sign?$" "gpg --verify"))
1106
1107   "Default alist used for shell command guessing.
1108 See `dired-guess-shell-alist-user'.")
1109
1110 (defcustom dired-guess-shell-alist-user nil
1111   "User-defined alist of rules for suggested commands.
1112 These rules take precedence over the predefined rules in the variable
1113 `dired-guess-shell-alist-default' (to which they are prepended).
1114
1115 Each element of this list looks like
1116
1117     \(REGEXP COMMAND...\)
1118
1119 where each COMMAND can either be a string or a Lisp expression that evaluates
1120 to a string.  If several COMMANDs are given, the first one will be the default
1121 and the rest will be added temporarily to the history and can be retrieved
1122 with \\[previous-history-element] (M-p) .
1123
1124 You can set this variable in your ~/.emacs.  For example, to add rules for
1125 `.foo' and `.bar' files, write
1126
1127  \(setq dired-guess-shell-alist-user
1128        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1129               ;; possibly more rules ...
1130               (list \"\\\\.bar\\\'\";; rule with condition test
1131                     '(if condition
1132                           \"BAR-COMMAND-1\"
1133                         \"BAR-COMMAND-2\")))\)"
1134   :group 'dired-x
1135   :type '(alist :key-type regexp :value-type (repeat sexp)))
1136
1137 (defcustom dired-guess-shell-case-fold-search t
1138   "If non-nil, `dired-guess-shell-alist-default' and
1139 `dired-guess-shell-alist-user' are matched case-insensitively."
1140   :group 'dired-x
1141   :type 'boolean)
1142
1143 (defun dired-guess-default (files)
1144   "Guess a shell commands for FILES.  Return command or list of commands.
1145 See `dired-guess-shell-alist-user'."
1146
1147   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1148          ;; Prepend the user's alist to the default alist.
1149          (alist (append dired-guess-shell-alist-user
1150                         dired-guess-shell-alist-default))
1151          (file (car files))
1152          (flist (cdr files))
1153          elt regexp cmds)
1154
1155     ;; Find the first match in the alist for first file in FILES.
1156     (while alist
1157       (setq elt (car alist)
1158             regexp (car elt)
1159             alist (cdr alist))
1160       (if (string-match regexp file)
1161           (setq cmds (cdr elt)
1162                 alist nil)))
1163
1164     ;; If more than one file, see if all of FILES match regular expression.
1165     (while (and flist
1166                 (string-match regexp (car flist)))
1167       (setq flist (cdr flist)))
1168
1169     ;; If flist is still non-nil, then do not guess since this means that not
1170     ;; all the files in FILES were matched by the regexp.
1171     (setq cmds (and (not flist) cmds))
1172
1173     ;; Return commands or nil if flist is still non-nil.
1174     ;; Evaluate the commands in order that any logical testing will be done.
1175     (cond ((not (cdr cmds))
1176            (eval (car cmds))) ; single command
1177           (t
1178            (mapcar (function eval) cmds)))))
1179
1180 (defun dired-guess-shell-command (prompt files)
1181   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1182   (let ((default (dired-guess-default files))
1183         default-list val)
1184     (if (null default)
1185         ;; Nothing to guess
1186         (read-from-minibuffer prompt nil nil nil 'dired-shell-command-history)
1187       (if (listp default)
1188           ;; More than one guess
1189           (setq default-list default
1190                 default (car default)
1191                 prompt (concat
1192                         prompt
1193                         (format "{%d guesses} " (length default-list))))
1194         ;; Just one guess
1195         (setq default-list (list default)))
1196       ;; Put the first guess in the prompt but not in the initial value.
1197       (setq prompt (concat prompt (format "[%s] " default)))
1198       ;; All guesses can be retrieved with M-n
1199       (setq val (read-from-minibuffer prompt nil nil nil
1200                                       'dired-shell-command-history
1201                                       default-list))
1202       ;; If we got a return, then return default.
1203       (if (equal val "") default val))))
1204
1205 ;; REDEFINE.
1206 ;; Redefine dired-aux.el's version:
1207 (defun dired-read-shell-command (prompt arg files)
1208   "Read a dired shell command prompting with PROMPT (using read-string).
1209 ARG is the prefix arg and may be used to indicate in the prompt which
1210   files are affected.
1211 This is an extra function so that you can redefine it."
1212   (dired-mark-pop-up
1213    nil 'shell files
1214    'dired-guess-shell-command
1215    (format prompt (dired-mark-prompt arg files)) ; PROMPT
1216    files))                                       ; FILES
1217
1218 \f
1219 ;;; RELATIVE SYMBOLIC LINKS.
1220
1221 (declare-function make-symbolic-link "fileio.c")
1222
1223 (defvar dired-keep-marker-relsymlink ?S
1224   "See variable `dired-keep-marker-move'.")
1225
1226 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1227   "Make a symbolic link (pointing to FILE1) in FILE2.
1228 The link is relative (if possible), for example
1229
1230     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1231
1232 results in
1233
1234     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1235   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1236   (let (name1 name2 len1 len2 (index 0) sub)
1237     (setq file1 (expand-file-name file1)
1238           file2 (expand-file-name file2)
1239           len1 (length file1)
1240           len2 (length file2))
1241     ;; Find common initial file name components:
1242     (let (next)
1243       (while (and (setq next (string-match "/" file1 index))
1244                   (setq next (1+ next))
1245                   (< next (min len1 len2))
1246                   ;; For the comparison, both substrings must end in
1247                   ;; `/', so NEXT is *one plus* the result of the
1248                   ;; string-match.
1249                   ;; E.g., consider the case of linking "/tmp/a/abc"
1250                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1251                   ;; of "/tmp/" as common initial component
1252                   (string-equal (substring file1 0 next)
1253                                 (substring file2 0 next)))
1254         (setq index next))
1255       (setq name2 file2
1256             sub (substring file1 0 index)
1257             name1 (substring file1 index)))
1258     (if (string-equal sub "/")
1259         ;; No common initial file name found
1260         (setq name1 file1)
1261       ;; Else they have a common parent directory
1262       (let ((tem (substring file2 index))
1263             (start 0)
1264             (count 0))
1265         ;; Count number of slashes we must compensate for ...
1266         (while (setq start (string-match "/" tem start))
1267           (setq count (1+ count)
1268                 start (1+ start)))
1269         ;; ... and prepend a "../" for each slash found:
1270         (while (> count 0)
1271           (setq count (1- count)
1272                 name1 (concat "../" name1)))))
1273     (make-symbolic-link
1274      (directory-file-name name1)        ; must not link to foo/
1275                                         ; (trailing slash!)
1276      name2 ok-if-already-exists)))
1277
1278 ;;;###autoload
1279 (defun dired-do-relsymlink (&optional arg)
1280    "Relative symlink all marked (or next ARG) files into a directory.
1281 Otherwise make a relative symbolic link to the current file.
1282 This creates relative symbolic links like
1283
1284     foo -> ../bar/foo
1285
1286 not absolute ones like
1287
1288     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1289
1290 For absolute symlinks, use \\[dired-do-symlink]."
1291   (interactive "P")
1292   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1293                            "RelSymLink" arg dired-keep-marker-relsymlink))
1294
1295 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1296   "RelSymlink all marked files containing REGEXP to NEWNAME.
1297 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1298 for more info."
1299   (interactive (dired-mark-read-regexp "RelSymLink"))
1300   (dired-do-create-files-regexp
1301    (function dired-make-relative-symlink)
1302    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1303
1304 \f
1305 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1306
1307 ;; Brief Description:
1308 ;;;
1309 ;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1310 ;;;
1311 ;; * Use `dired-get-marked-files' to collect the marked files in the current
1312 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1313 ;;;
1314 ;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1315 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1316 ;;;
1317 ;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1318 ;;;   list each time.
1319 ;;;
1320 ;; * If NOSELECT is non-nil then just run `find-file-noselect'  on each
1321 ;;;   element of FILE-LIST.
1322 ;;;
1323 ;; * If NOSELECT is nil then calculate the `size' of the window for each file
1324 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1325 ;;;   cognizant of the window-configuration.
1326 ;;;
1327 ;; * If `size' is too small abort, otherwise run `find-file' on each element
1328 ;;;   of FILE-LIST giving each a window of height `size'.
1329
1330 (defun dired-do-find-marked-files (&optional noselect)
1331   "Find all marked files displaying all of them simultaneously.
1332 With optional NOSELECT just find files but do not select them.
1333
1334 The current window is split across all files marked, as evenly as possible.
1335 Remaining lines go to bottom-most window.  The number of files that can be
1336 displayed this way is restricted by the height of the current window and
1337 `window-min-height'.
1338
1339 To keep dired buffer displayed, type \\[split-window-vertically] first.
1340 To display just marked files, type \\[delete-other-windows] first."
1341
1342   (interactive "P")
1343   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1344
1345 (defun dired-simultaneous-find-file (file-list noselect)
1346
1347   "Visit all files in FILE-LIST and display them simultaneously.
1348 The current window is split across all files in FILE-LIST, as evenly as
1349 possible.  Remaining lines go to the bottom-most window.  The number of
1350 files that can be displayed this way is restricted by the height of the
1351 current window and the variable `window-min-height'.  With non-nil
1352 NOSELECT the files are merely found but not selected."
1353
1354   ;; We don't make this function interactive because it is usually too clumsy
1355   ;; to specify FILE-LIST interactively unless via dired.
1356
1357   (let (size)
1358
1359     (if noselect
1360         ;; Do not select the buffer.
1361         (find-file-noselect (car file-list))
1362
1363       ;; We will have to select the buffer.  Calculate and check window size.
1364       (setq size (/ (window-height) (length file-list)))
1365       (or (<= window-min-height size)
1366           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1367       (find-file (car file-list)))
1368
1369     ;; Decrement.
1370     (setq file-list (cdr file-list))
1371
1372     (while file-list
1373
1374       (if noselect
1375           ;; Do not select the buffer.
1376           (find-file-noselect (car file-list))
1377
1378         ;; Vertically split off a window of desired size.  Upper window will
1379         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1380         (select-window (split-window nil size))
1381         (find-file (car file-list)))
1382
1383       ;; Decrement.
1384       (setq file-list (cdr file-list)))))
1385
1386 \f
1387 ;;; MISCELLANEOUS COMMANDS.
1388
1389 ;; Run man on files.
1390
1391 (defun dired-man ()
1392   "Run man on this file.  Display old buffer if buffer name matches filename.
1393 Uses `man.el' of \\[manual-entry] fame."
1394   (interactive)
1395   (require 'man)
1396   (let* ((file (dired-get-filename))
1397          (manual-program (replace-regexp-in-string "\\*" "%s"
1398                           (dired-guess-shell-command
1399                            "Man command: " (list file)))))
1400     (Man-getpage-in-background file)))
1401
1402 ;; Run Info on files.
1403
1404 (defun dired-info ()
1405   "Run info on this file."
1406   (interactive)
1407   (info (dired-get-filename)))
1408
1409 ;; Run mail on mail folders.
1410
1411 ;; Avoid compiler warning.
1412 (eval-when-compile
1413   (when (not (fboundp 'vm-visit-folder))
1414     (defun vm-visit-folder (file &optional arg)
1415       nil)))
1416
1417 (defun dired-vm (&optional read-only)
1418   "Run VM on this file.
1419 With prefix arg, visit folder read-only (this requires at least VM 5).
1420 See also variable `dired-vm-read-only-folders'."
1421   (interactive "P")
1422   (let ((dir (dired-current-directory))
1423         (fil (dired-get-filename)))
1424     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1425     (cond (read-only (vm-visit-folder fil t))
1426           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1427           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1428           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1429     ;; so that pressing `v' inside VM does prompt within current directory:
1430     (set (make-local-variable 'vm-folder-directory) dir)))
1431
1432 (defun dired-rmail ()
1433   "Run RMAIL on this file."
1434   (interactive)
1435   (rmail (dired-get-filename)))
1436
1437 (defun dired-do-run-mail ()
1438   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1439   (interactive)
1440   (if dired-bind-vm
1441       ;; Read mail folder using vm.
1442       (dired-vm)
1443     ;; Read mail folder using rmail.
1444     (dired-rmail)))
1445
1446 \f
1447 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1448
1449 (declare-function dired-old-find-buffer-nocreate "dired-x")
1450
1451 (or (fboundp 'dired-old-find-buffer-nocreate)
1452     (fset 'dired-old-find-buffer-nocreate
1453           (symbol-function 'dired-find-buffer-nocreate)))
1454
1455 ;; REDEFINE.
1456 ;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1457 (defun dired-find-buffer-nocreate (dirname &optional mode)
1458   (if (and dired-find-subdir
1459            ;; don't try to find a wildcard as a subdirectory
1460            (string-equal dirname (file-name-directory dirname)))
1461       (let* ((cur-buf (current-buffer))
1462              (buffers (nreverse
1463                        (dired-buffers-for-dir (expand-file-name dirname))))
1464              (cur-buf-matches (and (memq cur-buf buffers)
1465                                    ;; wildcards must match, too:
1466                                    (equal dired-directory dirname))))
1467         ;; We don't want to switch to the same buffer---
1468         (setq buffers (delq cur-buf buffers));;need setq with delq
1469         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1470             ;; ---unless it's the only possibility:
1471             (and cur-buf-matches cur-buf)))
1472     (dired-old-find-buffer-nocreate dirname mode)))
1473
1474 ;; This should be a builtin
1475 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1476   "Return t if BUFFER1 is more recently used than BUFFER2."
1477   (if (equal buffer1 buffer2)
1478       nil
1479     (let ((more-recent nil)
1480           (list (buffer-list)))
1481       (while (and list
1482                   (not (setq more-recent (equal buffer1 (car list))))
1483                   (not (equal buffer2 (car list))))
1484         (setq list (cdr list)))
1485       more-recent)))
1486
1487 ;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1488 ;; (defun dired-buffers-for-dir-exact (dir)
1489 ;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1490 ;; ;; at top level, or as subdirectory.
1491 ;; ;; Top level matches must match the wildcard part too, if any.
1492 ;; ;; The list is in reverse order of buffer creation, most recent last.
1493 ;; ;; As a side effect, killed dired buffers for DIR are removed from
1494 ;; ;; dired-buffers.
1495 ;;   (let ((alist dired-buffers) result elt)
1496 ;;     (while alist
1497 ;;       (setq elt (car alist)
1498 ;;             alist (cdr alist))
1499 ;;       (let ((buf (cdr elt)))
1500 ;;         (if (buffer-name buf)
1501 ;;             ;; Top level must match exactly against dired-directory in
1502 ;;             ;; case one of them is a wildcard.
1503 ;;             (if (or (equal dir (with-current-buffer buf dired-directory))
1504 ;;                     (assoc dir (with-current-buffer buf dired-subdir-alist)))
1505 ;;                 (setq result (cons buf result)))
1506 ;;           ;; else buffer is killed - clean up:
1507 ;;           (setq dired-buffers (delq elt dired-buffers)))))
1508 ;;     result))
1509
1510 ;; REDEFINE.
1511 ;; Redefines dired.el's version of `dired-initial-position'
1512 (defun dired-initial-position (dirname)
1513   "Where point should go in a new listing of DIRNAME.
1514 Point assumed at beginning of new subdir line.
1515 You may redefine this function as you wish, e.g. like in `dired-x.el'."
1516   (end-of-line)
1517   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1518   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1519
1520 \f
1521 ;; Does anyone use this? - lrd 6/29/93.
1522 ;; Apparently people do use it. - lrd 12/22/97.
1523 (defun dired-mark-sexp (predicate &optional unflag-p)
1524   "Mark files for which PREDICATE returns non-nil.
1525 With a prefix arg, unflag those files instead.
1526
1527 PREDICATE is a lisp expression that can refer to the following symbols:
1528
1529     inode  [integer] the inode of the file (only for ls -i output)
1530     s      [integer] the size of the file for ls -s output
1531                      (usually in blocks or, with -k, in KByte)
1532     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1533     nlink  [integer] number of links to file
1534     uid    [string]  owner
1535     gid    [string]  group  (If the gid is not displayed by ls,
1536                      this will still be set (to the same as uid))
1537     size   [integer] file size in bytes
1538     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1539     name   [string]  the name of the file
1540     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1541
1542 For example, use
1543
1544         (equal 0 size)
1545
1546 to mark all zero length files."
1547   ;; Using sym="" instead of nil avoids the trap of
1548   ;; (string-match "foo" sym) into which a user would soon fall.
1549   ;; Give `equal' instead of `=' in the example, as this works on
1550   ;; integers and strings.
1551   (interactive "xMark if (lisp expr): \nP")
1552   (message "%s" predicate)
1553   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1554         inode s mode nlink uid gid size time name sym)
1555     (dired-mark-if
1556      (save-excursion
1557        (and
1558         ;; Sets vars
1559         ;;                inode s mode nlink uid gid size time name sym
1560
1561         ;; according to current file line.  Returns t for success, nil if
1562         ;; there is no file line.  Upon success, all variables are set, either
1563         ;; to nil or the appropriate value, so they need not be initialized.
1564         ;; Moves point within the current line.
1565         (if (dired-move-to-filename)
1566             (let (pos
1567                   (mode-len 10) ; length of mode string
1568                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1569                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1570               (beginning-of-line)
1571               (forward-char 2)
1572               (if (looking-at dired-re-inode-size)
1573                   (progn
1574                     (goto-char (match-end 0))
1575                     (setq inode (string-to-number (buffer-substring (match-beginning 1)
1576                                                                     (match-end 1)))
1577                           s (string-to-number (buffer-substring (match-beginning 2)
1578                                                                 (match-end 2)))))
1579                 (setq inode nil
1580                       s nil))
1581               (setq mode (buffer-substring (point) (+ mode-len (point))))
1582               (forward-char mode-len)
1583               (setq nlink (read (current-buffer)))
1584               ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1585               (setq uid (buffer-substring (+ (point) 1)
1586                                           (progn (forward-word 1) (point))))
1587               (re-search-forward directory-listing-before-filename-regexp)
1588               (goto-char (match-beginning 1))
1589               (forward-char -1)
1590               (setq size (string-to-number (buffer-substring (save-excursion
1591                                                                (backward-word 1)
1592                                                                (setq pos (point)))
1593                                                              (point))))
1594               (goto-char pos)
1595               (backward-word 1)
1596               ;; if no gid is displayed, gid will be set to uid
1597               ;; but user will then not reference it anyway in PREDICATE.
1598               (setq gid (buffer-substring (save-excursion
1599                                             (forward-word 1) (point))
1600                                           (point))
1601                     time (buffer-substring (match-beginning 1)
1602                                            (1- (dired-move-to-filename)))
1603                     name (buffer-substring (point)
1604                                            (or
1605                                             (dired-move-to-end-of-filename t)
1606                                             (point)))
1607                     sym  (progn
1608                            (if (looking-at " -> ")
1609                                (buffer-substring
1610                                 (progn (forward-char 4) (point))
1611                                 (progn (end-of-line) (point)))
1612                              "")))
1613               t)
1614           nil)
1615                       (eval predicate)))
1616      (format "'%s file" predicate))))
1617
1618 \f
1619 ;;; FIND FILE AT POINT.
1620
1621 (defvar dired-x-hands-off-my-keys t
1622   "*Non-nil means don't bind `dired-x-find-file' over `find-file' on keyboard.
1623 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1624 If you change this variable after `dired-x.el' is loaded then do
1625 \\[dired-x-bind-find-file].")
1626
1627 ;; Bind `dired-x-find-file{-other-window}' over wherever
1628 ;; `find-file{-other-window}' is bound?
1629 (defun dired-x-bind-find-file ()
1630   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1631 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1632 Binding direction based on `dired-x-hands-off-my-keys'.
1633 This function is part of `after-init-hook'."
1634   (interactive)
1635   (if (interactive-p)
1636       (setq dired-x-hands-off-my-keys
1637             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1638   (cond ((not dired-x-hands-off-my-keys)
1639          (substitute-key-definition 'find-file
1640                                     'dired-x-find-file
1641                                     (current-global-map))
1642          (substitute-key-definition 'find-file-other-window
1643                                     'dired-x-find-file-other-window
1644                                     (current-global-map)))
1645         (t
1646          (substitute-key-definition 'dired-x-find-file
1647                                     'find-file
1648                                     (current-global-map))
1649          (substitute-key-definition 'dired-x-find-file-other-window
1650                                     'find-file-other-window
1651                                     (current-global-map))))
1652   ;; Clear mini-buffer.
1653   (message nil))
1654
1655 ;; Now call it so binding is correct and put on `after-init-hook' in case
1656 ;; user changes binding.
1657 (dired-x-bind-find-file)
1658 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1659
1660 (defun dired-x-find-file (filename)
1661   "Edit file FILENAME.
1662 May create a new window, or reuse an existing one.
1663 See the function `display-buffer'.
1664
1665 Identical to `find-file' except when called interactively, with a prefix arg
1666 \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1667 Useful for editing file mentioned in buffer you are viewing,
1668 or to test if that file exists.  Use minibuffer after snatching filename."
1669   (interactive (list (read-filename-at-point "Find file: ")))
1670   (find-file (expand-file-name filename)))
1671
1672 (defun dired-x-find-file-other-window (filename)
1673   "Edit file FILENAME, in another window.
1674 May create a new window, or reuse an existing one.
1675 See the function `display-buffer'.
1676
1677 Identical to `find-file-other-window' except when called interactively, with a
1678 prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1679 Useful for editing file mentioned in buffer you are viewing,
1680 or to test if that file exists.  Use minibuffer after snatching filename."
1681   (interactive (list (read-filename-at-point "Find file: ")))
1682   (find-file-other-window (expand-file-name filename)))
1683
1684 ;;; Internal functions.
1685
1686 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1687 (defun dired-filename-at-point ()
1688   "Get the filename closest to point, but do not change position.
1689 Has a preference for looking backward when not directly on a symbol.  Not
1690 perfect - point must be in middle of or end of filename."
1691
1692   (let ((filename-chars "-.[:alnum:]_/:$+@")
1693         start end filename prefix)
1694
1695     (save-excursion
1696       ;; First see if just past a filename.
1697       (if (not (eobp))
1698           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1699               (progn
1700                 (skip-chars-backward " \n\t\r({[]})")
1701                 (if (not (bobp))
1702                     (backward-char 1)))))
1703
1704       (if (string-match (concat "[" filename-chars "]")
1705                         (char-to-string (following-char)))
1706           (progn
1707             (if (re-search-backward (concat "[^" filename-chars "]") nil t)
1708                 (forward-char)
1709               (goto-char (point-min)))
1710             (setq start (point))
1711             (setq prefix
1712                   (and (string-match
1713                         "^\\w+@"
1714                         (buffer-substring start (line-beginning-position)))
1715                        "/"))
1716             (goto-char start)
1717             (if (string-match "[/~]" (char-to-string (preceding-char)))
1718                 (setq start (1- start)))
1719             (re-search-forward (concat "\\=[" filename-chars "]*") nil t))
1720
1721         (error "No file found around point!"))
1722
1723       ;; Return string.
1724       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1725
1726 (defun read-filename-at-point (prompt)
1727   "Return filename prompting with PROMPT with completion.
1728 If `current-prefix-arg' is non-nil, uses name at point as guess."
1729   (if current-prefix-arg
1730       (let ((guess (dired-filename-at-point)))
1731         (read-file-name prompt
1732                         (file-name-directory guess)
1733                         guess
1734                         nil (file-name-nondirectory guess)))
1735     (read-file-name prompt default-directory)))
1736 \f
1737 ;;; BUG REPORTS
1738
1739 ;; Fixme: get rid of this later.
1740
1741 ;; This section is provided for reports.  It uses Barry A. Warsaw's
1742 ;; reporter.el which is bundled with GNU Emacs v19.
1743
1744 (defconst dired-x-help-address "bug-gnu-emacs@gnu.org"
1745   "Address(es) accepting submission of reports on dired-x.el.")
1746
1747 (defconst dired-x-variable-list
1748   (list
1749    'dired-bind-vm
1750    'dired-vm-read-only-folders
1751    'dired-bind-jump
1752    'dired-bind-info
1753    'dired-bind-man
1754    'dired-find-subdir
1755    'dired-enable-local-variables
1756    'dired-local-variables-file
1757    'dired-guess-shell-gnutar
1758    'dired-guess-shell-gzip-quiet
1759    'dired-guess-shell-znew-switches
1760    'dired-guess-shell-alist-user
1761    'dired-clean-up-buffers-too
1762    'dired-omit-mode
1763    'dired-omit-files
1764    'dired-omit-extensions
1765    )
1766   "List of variables to be appended to reports sent by `dired-x-submit-report'.")
1767
1768 (defun dired-x-submit-report ()
1769   "Submit via `reporter.el' a bug report on program.
1770 Send report on `dired-x-file' version `dired-x-version,' to
1771 `dired-x-maintainer' at address `dired-x-help-address' listing
1772 variables `dired-x-variable-list' in the message."
1773   (interactive)
1774
1775   (reporter-submit-bug-report
1776    dired-x-help-address                 ; address
1777    "dired-x"                            ; pkgname
1778    dired-x-variable-list                ; varlist
1779    nil nil                              ; pre-/post-hooks
1780    ""))
1781
1782 \f
1783 ;; As Barry Warsaw would say: "This might be useful..."
1784 (provide 'dired-x)
1785
1786 ;; arch-tag: 71a43ba2-7a00-4793-a028-0613dd7765ae
1787 ;;; dired-x.el ends here