configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 23.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 137 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 138 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 139
 140 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 141 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 142 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 143 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 144
 145 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 146 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 147
 148 ## For the times when you want to build Emacs but don't have
 149 ## a suitable makeinfo, and can live without the manuals.
 150 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 151 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 152
 153 dnl Can remove these in Emacs 24.
 154 AC_ARG_WITH([gtk],,
 155   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 156 specify a toolkit.])],,)
 157
 158 AC_ARG_WITH([gcc],,
 159   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 160 variable to specify a compiler.])],,)
 161
 162 AC_ARG_WITH([pkg-config-prog],dnl
 163 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 164                   [path to pkg-config for finding GTK and librsvg])])
 165 if test "X${with_pkg_config_prog}" != X; then
 166    if test "${with_pkg_config_prog}" != yes; then
 167       PKG_CONFIG="${with_pkg_config_prog}"
 168    fi
 169 fi
 170
 171 AC_ARG_WITH([gnustep-conf],dnl
 172 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 173 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 174   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 175 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 176      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 177
 178 AC_ARG_ENABLE(ns-self-contained,
 179 [AS_HELP_STRING([--disable-ns-self-contained],
 180                 [disable self contained build under NeXTstep])],
 181    EN_NS_SELF_CONTAINED=$enableval,
 182    EN_NS_SELF_CONTAINED=yes)
 183
 184 AC_ARG_ENABLE(asserts,
 185 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 186       USE_XASSERTS=$enableval,
 187       USE_XASSERTS=no)
 188
 189 AC_ARG_ENABLE(maintainer-mode,
 190 [AS_HELP_STRING([--enable-maintainer-mode],
 191                 [enable make rules and dependencies not useful (and sometimes
 192                  confusing) to the casual installer])],
 193       USE_MAINTAINER_MODE=$enableval,
 194       USE_MAINTAINER_MODE=no)
 195 if test $USE_MAINTAINER_MODE = yes; then
 196   MAINT=
 197 else
 198   MAINT=#
 199 fi
 200 AC_SUBST(MAINT)
 201
 202 AC_ARG_ENABLE(locallisppath,
 203 [AS_HELP_STRING([--enable-locallisppath=PATH],
 204                 [directories Emacs should search for lisp files specific
 205                  to this site])],
 206 if test "${enableval}" = "no"; then
 207   locallisppath=
 208 elif test "${enableval}" != "yes"; then
 209   locallisppath=${enableval}
 210 fi)
 211
 212 AC_ARG_ENABLE(checking,
 213 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 214                 [enable expensive run-time checks.  With LIST,
 215                  enable only specific categories of checks.
 216                  Categories are: all,yes,no.
 217                  Flags are: stringbytes, stringoverrun, stringfreelist,
 218                  xmallocoverrun, conslist])],
 219 [ac_checking_flags="${enableval}"],[])
 220 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 221 for check in $ac_checking_flags
 222 do
 223         case $check in
 224         # these set all the flags to specific states
 225         yes)            ac_enable_checking=1 ;;
 226         no)             ac_enable_checking= ;
 227                         ac_gc_check_stringbytes= ;
 228                         ac_gc_check_string_overrun= ;
 229                         ac_gc_check_string_free_list= ;
 230                         ac_xmalloc_overrun= ;
 231                         ac_gc_check_cons_list= ;;
 232         all)            ac_enable_checking=1 ;
 233                         ac_gc_check_stringbytes=1 ;
 234                         ac_gc_check_string_overrun=1 ;
 235                         ac_gc_check_string_free_list=1 ;
 236                         ac_xmalloc_overrun=1 ;
 237                         ac_gc_check_cons_list=1 ;;
 238         # these enable particular checks
 239         stringbytes)    ac_gc_check_stringbytes=1 ;;
 240         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 241         stringfreelist) ac_gc_check_string_free_list=1 ;;
 242         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 243         conslist)       ac_gc_check_cons_list=1 ;;
 244         *)      AC_MSG_ERROR(unknown check category $check) ;;
 245         esac
 246 done
 247 IFS="$ac_save_IFS"
 248
 249 if test x$ac_enable_checking != x ; then
 250   AC_DEFINE(ENABLE_CHECKING, 1,
 251 [Enable expensive run-time checking of data types?])
 252 fi
 253 if test x$ac_gc_check_stringbytes != x ; then
 254   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 255 [Define this temporarily to hunt a bug.  If defined, the size of
 256    strings is redundantly recorded in sdata structures so that it can
 257    be compared to the sizes recorded in Lisp strings.])
 258 fi
 259 if test x$ac_gc_check_stringoverrun != x ; then
 260   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 261 [Define this to check for short string overrun.])
 262 fi
 263 if test x$ac_gc_check_string_free_list != x ; then
 264   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 265 [Define this to check the string free list.])
 266 fi
 267 if test x$ac_xmalloc_overrun != x ; then
 268   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 269 [Define this to check for malloc buffer overrun.])
 270 fi
 271 if test x$ac_gc_check_cons_list != x ; then
 272   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 273 [Define this to check for errors in cons list.])
 274 fi
 275
 276 AC_ARG_ENABLE(profiling,
 277 [AS_HELP_STRING([--enable-profiling],
 278                 [build emacs with profiling support.
 279                  This might not work on all platforms])],
 280 [ac_enable_profiling="${enableval}"],[])
 281 if test x$ac_enable_profiling != x ; then
 282    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 283    PROFILING_LDFLAGS="-pg"
 284 else
 285    PROFILING_CFLAGS=
 286    PROFILING_LDFLAGS=
 287 fi
 288
 289 AC_ARG_ENABLE(autodepend,
 290 [AS_HELP_STRING([--enable-autodepend],
 291                 [automatically generate dependencies to .h-files.
 292                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 293                  found])],
 294 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 295
 296 #### Make srcdir absolute, if it isn't already.  It's important to
 297 #### avoid running the path through pwd unnecessarily, since pwd can
 298 #### give you automounter prefixes, which can go away.  We do all this
 299 #### so Emacs can find its files when run uninstalled.
 300 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 301 unset CDPATH
 302 case "${srcdir}" in
 303   /* ) ;;
 304   . )
 305     ## We may be able to use the $PWD environment variable to make this
 306     ## absolute.  But sometimes PWD is inaccurate.
 307     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 308     ## but that tested only for a well-formed and valid PWD,
 309     ## it did not object when PWD was well-formed and valid but just wrong.
 310     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 311     then
 312       srcdir="$PWD"
 313     else
 314       srcdir="`(cd ${srcdir}; pwd)`"
 315     fi
 316   ;;
 317   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 318 esac
 319
 320 #### Check if the source directory already has a configured system in it.
 321 if test `pwd` != `(cd ${srcdir} && pwd)` \
 322    && test -f "${srcdir}/src/config.h" ; then
 323   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 324    as a build directory right now; it has been configured in its own
 325    right.  To configure in another directory as well, you MUST
 326    use GNU make.  If you do not have GNU make, then you must
 327    now do `make distclean' in ${srcdir},
 328    and then run $0 again.]])
 329 fi
 330
 331 #### Given the configuration name, set machfile and opsysfile to the
 332 #### names of the m/*.h and s/*.h files we should use.
 333
 334 ### Canonicalize the configuration name.
 335
 336 AC_CANONICAL_HOST
 337 canonical=$host
 338 configuration=${host_alias-${build_alias-$host}}
 339
 340 dnl This used to use changequote, but, apart from `changequote is evil'
 341 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 342 dnl the great gob of text.  Thus it's not processed for possible expansion.
 343 dnl Just make sure the brackets remain balanced.
 344 dnl
 345 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 346 dnl indicated by comments.
 347 dnl quotation begins
 348 [
 349
 350 ### If you add support for a new configuration, add code to this
 351 ### switch statement to recognize your configuration name and select
 352 ### the appropriate operating system and machine description files.
 353
 354 ### You would hope that you could choose an m/*.h file pretty much
 355 ### based on the machine portion of the configuration name, and an s-
 356 ### file based on the operating system portion.  However, it turns out
 357 ### that each m/*.h file is pretty manufacturer-specific - for
 358 ### example mips.h is MIPS
 359 ### So we basically have to have a special case for each
 360 ### configuration name.
 361 ###
 362 ### As far as handling version numbers on operating systems is
 363 ### concerned, make sure things will fail in a fixable way.  If
 364 ### /etc/MACHINES doesn't say anything about version numbers, be
 365 ### prepared to handle anything reasonably.  If version numbers
 366 ### matter, be sure /etc/MACHINES says something about it.
 367 ###
 368 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 369 ### "System V Release 4"; he writes, "The old convention encouraged
 370 ### confusion between `system' and `release' levels'."
 371
 372 machine='' opsys='' unported=no
 373 case "${canonical}" in
 374
 375   ## FreeBSD ports
 376   *-*-freebsd* )
 377     opsys=freebsd
 378     case "${canonical}" in
 379       alpha*-*-freebsd*)        machine=alpha ;;
 380       arm*-*-freebsd*)          machine=arm ;;
 381       ia64-*-freebsd*)          machine=ia64 ;;
 382       sparc-*-freebsd*)         machine=sparc ;;
 383       sparc64-*-freebsd*)       machine=sparc ;;
 384       powerpc-*-freebsd*)       machine=macppc ;;
 385       i[3456]86-*-freebsd*)     machine=intel386 ;;
 386       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 387     esac
 388   ;;
 389
 390   ## FreeBSD kernel + glibc based userland
 391   *-*-kfreebsd*gnu* )
 392     opsys=gnu-kfreebsd
 393     case "${canonical}" in
 394       alpha*-*-kfreebsd*)       machine=alpha ;;
 395       ia64-*-kfreebsd*)         machine=ia64 ;;
 396       sparc-*-kfreebsd*)        machine=sparc ;;
 397       sparc64-*-kfreebsd*)      machine=sparc ;;
 398       powerpc-*-kfreebsd*)      machine=macppc ;;
 399       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 400       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 401     esac
 402   ;;
 403
 404   ## NetBSD ports
 405   *-*-netbsd* )
 406     opsys=netbsd
 407     if test -f /usr/lib/crti.o; then]
 408 dnl The close and open brackets here are because this section is quoted --
 409 dnl see the `changequote' comment above.
 410       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 411 [   fi
 412
 413     case "${canonical}" in
 414       alpha*-*-netbsd*) machine=alpha ;;
 415       i[3456]86-*-netbsd*) machine=intel386 ;;
 416       mips-*-netbsd*)   machine=mips ;;
 417       mipsel-*-netbsd*) machine=mips ;;
 418       mipseb-*-netbsd*) machine=mips ;;
 419       powerpc-*-netbsd*) machine=macppc ;;
 420       sparc*-*-netbsd*) machine=sparc ;;
 421       vax-*-netbsd*)    machine=vax ;;
 422       arm-*-netbsd*)    machine=arm ;;
 423       x86_64-*-netbsd*) machine=amdx86-64 ;;
 424       hppa-*-netbsd*)   machine=hp800 ;;
 425       m68k-*-netbsd*)   machine=m68k ;;
 426     esac
 427   ;;
 428
 429   ## OpenBSD ports
 430   *-*-openbsd* )
 431     opsys=openbsd
 432     case "${canonical}" in
 433       alpha*-*-openbsd*)        machine=alpha ;;
 434       arm-*-openbsd*)          machine=arm ;;
 435       i386-*-openbsd*)         machine=intel386 ;;
 436       powerpc-*-openbsd*)      machine=macppc ;;
 437       sparc*-*-openbsd*)       machine=sparc ;;
 438       vax-*-openbsd*)          machine=vax ;;
 439       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 440       hppa-*-openbsd*)         machine=hp800 ;;
 441     esac
 442   ;;
 443
 444   ## LynxOS ports
 445   *-*-lynxos* )
 446     opsys=lynxos
 447     case "${canonical}" in
 448       i[3456]86-*-lynxos*) machine=intel386 ;;
 449       powerpc-*-lynxos*) machine=powerpc ;;
 450     esac
 451   ;;
 452
 453   alpha*-*-linux-gnu* )
 454     machine=alpha opsys=gnu-linux
 455   ;;
 456
 457   arm*-*-linux-gnu* )
 458     machine=arm opsys=gnu-linux
 459   ;;
 460
 461   ## Apple Darwin / Mac OS X
 462   *-apple-darwin* )
 463     case "${canonical}" in
 464       i[3456]86-* )  machine=intel386 ;;
 465       powerpc-* )    machine=macppc ;;
 466       x86_64-* )     machine=amdx86-64 ;;
 467       * )            unported=yes ;;
 468     esac
 469     opsys=darwin
 470     # Define CPP as follows to make autoconf work correctly.
 471     CPP="${CC-cc} -E -no-cpp-precomp"
 472     # Use fink packages if available.
 473     if test -d /sw/include && test -d /sw/lib; then
 474       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 475       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 476       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 477     fi
 478   ;;
 479
 480   ## HP 9000 series 700 and 800, running HP/UX
 481   hppa*-hp-hpux10.2* )
 482     machine=hp800 opsys=hpux10-20
 483   ;;
 484   hppa*-hp-hpux1[1-9]* )
 485     machine=hp800 opsys=hpux11
 486     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 487   ;;
 488
 489   hppa*-*-linux-gnu* )
 490     machine=hp800 opsys=gnu-linux
 491   ;;
 492
 493   ## IBM machines
 494   s390-*-linux-gnu* )
 495     machine=ibms390 opsys=gnu-linux
 496   ;;
 497   s390x-*-linux-gnu* )
 498     machine=ibms390x opsys=gnu-linux
 499   ;;
 500   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 501     machine=ibmrs6000 opsys=aix4-2
 502   ;;
 503   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 504     machine=ibmrs6000 opsys=aix4-2
 505   ;;
 506   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 507     machine=ibmrs6000 opsys=aix4-2
 508   ;;
 509   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 510     machine=ibmrs6000 opsys=aix4-2
 511   ;;
 512
 513   ## Macintosh PowerPC
 514   powerpc*-*-linux-gnu* )
 515     machine=macppc opsys=gnu-linux
 516   ;;
 517
 518   ## Silicon Graphics machines
 519   ## Iris 4D
 520   mips-sgi-irix6.5 )
 521     machine=iris4d opsys=irix6-5
 522     # Without defining _LANGUAGE_C, things get masked out in the headers
 523     # so that, for instance, grepping for `free' in stdlib.h fails and
 524     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 525     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 526     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 527   ;;
 528
 529   ## Suns
 530   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 531     machine=sparc opsys=gnu-linux
 532   ;;
 533
 534   *-sun-solaris* \
 535     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 536     | x86_64-*-solaris2*    | x86_64-*-sunos5*    \
 537     | powerpc*-*-solaris2*  | rs6000-*-solaris2*)
 538     case "${canonical}" in
 539       i[3456]86-*-* )     machine=intel386 ;;
 540       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 541       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 542       sparc* )          machine=sparc ;;
 543       * )               unported=yes ;;
 544     esac
 545     case "${canonical}" in
 546       *-sunos5.3* | *-solaris2.3* )
 547                 opsys=sol2-3
 548                 NON_GNU_CPP=/usr/ccs/lib/cpp
 549                 ;;
 550       *-sunos5.4* | *-solaris2.4* )
 551                 opsys=sol2-4
 552                 NON_GNU_CPP=/usr/ccs/lib/cpp
 553                 RANLIB="ar -ts"
 554                 ;;
 555       *-sunos5.5* | *-solaris2.5* )
 556                 opsys=sol2-5
 557                 NON_GNU_CPP=/usr/ccs/lib/cpp
 558                 RANLIB="ar -ts"
 559                 ;;
 560       *-sunos5.6* | *-solaris2.6* )
 561                 opsys=sol2-6
 562                 NON_GNU_CPP=/usr/ccs/lib/cpp
 563                 RANLIB="ar -ts"
 564                 ;;
 565       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 566                 opsys=sol2-6
 567                 emacs_check_sunpro_c=yes
 568                 NON_GNU_CPP=/usr/ccs/lib/cpp
 569                 ;;
 570       *-sunos5* | *-solaris* )
 571                 opsys=sol2-10
 572                 emacs_check_sunpro_c=yes
 573                 NON_GNU_CPP=/usr/ccs/lib/cpp
 574                 ;;
 575     esac
 576     ## Watch out for a compiler that we know will not work.
 577     case "${canonical}" in
 578      *-solaris* | *-sunos5* )
 579                 if [ "x$CC" = x/usr/ucb/cc ]; then
 580                   ## /usr/ucb/cc doesn't work;
 581                   ## we should find some other compiler that does work.
 582                   unset CC
 583                 fi
 584                 ;;
 585       *) ;;
 586     esac
 587   ;;
 588
 589   ## IA-64
 590   ia64*-*-linux* )
 591     machine=ia64 opsys=gnu-linux
 592   ;;
 593
 594   ## Intel 386 machines where we don't care about the manufacturer
 595   i[3456]86-*-* )
 596     machine=intel386
 597     case "${canonical}" in
 598       *-cygwin )                opsys=cygwin ;;
 599       *-darwin* )               opsys=darwin
 600                                 CPP="${CC-cc} -E -no-cpp-precomp"
 601                                 ;;
 602       *-linux-gnu* )            opsys=gnu-linux ;;
 603       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 604       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 605       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 606       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 607     esac
 608   ;;
 609
 610   ## m68k Linux-based GNU system
 611   m68k-*-linux-gnu* )
 612     machine=m68k opsys=gnu-linux
 613   ;;
 614
 615   ## Mips Linux-based GNU system
 616   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 617     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 618     machine=mips opsys=gnu-linux
 619   ;;
 620
 621   ## AMD x86-64 Linux-based GNU system
 622   x86_64-*-linux-gnu* )
 623     machine=amdx86-64 opsys=gnu-linux
 624   ;;
 625
 626   ## Tensilica Xtensa Linux-based GNU system
 627   xtensa*-*-linux-gnu* )
 628     machine=xtensa opsys=gnu-linux
 629     ;;
 630
 631   ## SuperH Linux-based GNU system
 632   sh[34]*-*-linux-gnu* )
 633     machine=sh3 opsys=gnu-linux
 634   ;;
 635
 636   * )
 637     unported=yes
 638   ;;
 639 esac
 640
 641 ### If the code above didn't choose an operating system, just choose
 642 ### an operating system based on the configuration name.  You really
 643 ### only want to use this when you have no idea what the right
 644 ### operating system is; if you know what operating systems a machine
 645 ### runs, it's cleaner to make it explicit in the case statement
 646 ### above.
 647 if test x"${opsys}" = x; then
 648   case "${canonical}" in
 649     *-gnu* )                            opsys=gnu ;;
 650     *-sysv4.2uw* )                      opsys=unixware ;;
 651     *-sysv5uw* )                        opsys=unixware ;;
 652     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 653     *-sysv4.1* | *-sysvr4.1* )
 654         NON_GNU_CPP=/usr/lib/cpp
 655         opsys=usg5-4 ;;
 656     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 657         if [ x$NON_GNU_CPP = x ]; then
 658           if [ -f /usr/ccs/lib/cpp ]; then
 659             NON_GNU_CPP=/usr/ccs/lib/cpp
 660           else
 661             NON_GNU_CPP=/lib/cpp
 662           fi
 663         fi
 664         opsys=usg5-4-2 ;;
 665     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 666     * )
 667       unported=yes
 668     ;;
 669   esac
 670 fi
 671
 672 ]
 673 dnl quotation ends
 674
 675 if test $unported = yes; then
 676   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 677 Check `etc/MACHINES' for recognized configuration names.])
 678 fi
 679
 680 machfile="m/${machine}.h"
 681 opsysfile="s/${opsys}.h"
 682
 683
 684 #### Choose a compiler.
 685 test -n "$CC" && cc_specified=yes
 686
 687 # Save the value of CFLAGS that the user specified.
 688 SPECIFIED_CFLAGS="$CFLAGS"
 689
 690 dnl Sets GCC=yes if using gcc.
 691 AC_PROG_CC
 692
 693 # On Suns, sometimes $CPP names a directory.
 694 if test -n "$CPP" && test -d "$CPP"; then
 695   CPP=
 696 fi
 697
 698 ## If not using gcc, and on Solaris, and no CPP specified, see if
 699 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 700 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 701  test x"$CPP" = x; then
 702   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 703   AC_CACHE_VAL(emacs_cv_sunpro_c,
 704   [AC_TRY_LINK([],
 705 [#ifndef __SUNPRO_C
 706 fail;
 707 #endif
 708 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 709   AC_MSG_RESULT($emacs_cv_sunpro_c)
 710
 711   if test x"$emacs_cv_sunpro_c" = xyes; then
 712     NON_GNU_CPP="$CC -E -Xs"
 713   fi
 714 fi
 715
 716 #### Some systems specify a CPP to use unless we are using GCC.
 717 #### Now that we know whether we are using GCC, we can decide whether
 718 #### to use that one.
 719 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 720 then
 721   CPP="$NON_GNU_CPP"
 722 fi
 723
 724 #### Some systems specify a CC to use unless we are using GCC.
 725 #### Now that we know whether we are using GCC, we can decide whether
 726 #### to use that one.
 727 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 728   test x$cc_specified != xyes
 729 then
 730   CC="$NON_GNU_CC"
 731 fi
 732
 733 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 734 then
 735   CC="$CC $GCC_TEST_OPTIONS"
 736 fi
 737
 738 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 739 then
 740   CC="$CC $NON_GCC_TEST_OPTIONS"
 741 fi
 742
 743 dnl checks for Unix variants
 744 AC_USE_SYSTEM_EXTENSIONS
 745
 746 ### Use -Wno-pointer-sign if the compiler supports it
 747 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 748 SAVE_CFLAGS="$CFLAGS"
 749 CFLAGS="$CFLAGS -Wno-pointer-sign"
 750 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 751 if test $has_option = yes; then
 752    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 753 fi
 754 AC_MSG_RESULT($has_option)
 755 CFLAGS="$SAVE_CFLAGS"
 756 unset has_option
 757 unset SAVE_CFLAGS
 758
 759 #### Some other nice autoconf tests.
 760
 761 dnl checks for programs
 762 AC_PROG_LN_S
 763 AC_PROG_CPP
 764 AC_PROG_INSTALL
 765 if test "x$RANLIB" = x; then
 766   AC_PROG_RANLIB
 767 fi
 768 AC_PATH_PROG(INSTALL_INFO, install-info)
 769 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 770 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 771 dnl Don't use GZIP, which is used by gzip for additional parameters.
 772 AC_PATH_PROG(GZIP_PROG, gzip)
 773
 774
 775 ## Need makeinfo >= 4.6 (?) to build the manuals.
 776 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 777 dnl By this stage, configure has already checked for egrep and set EGREP,
 778 dnl or exited with an error if no egrep was found.
 779 if test "$MAKEINFO" != "no" && \
 780   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 781    MAKEINFO=no
 782 fi
 783
 784 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 785 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 786 ## therefore in the category of "special tools" not normally required, which
 787 ## configure does not have to check for (eg autoconf itself).
 788 ## In a CVS checkout on the other hand, the manuals are not included.
 789 ## So makeinfo is a requirement to build from CVS, and configure
 790 ## should test for it as it does for any other build requirement.
 791 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 792 ## with pre-built manuals, from a CVS checkout.
 793 if test "$MAKEINFO" = "no"; then
 794   if test "x${with_makeinfo}" = "xno"; then
 795     MAKEINFO=off
 796   elif ! test -e $srcdir/info/emacs; then
 797     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 798 source tree does not seem to have pre-built manuals in the `info' directory.
 799 Either install a suitable version of makeinfo, or re-run configure
 800 with the `--without-makeinfo' option to build without the manuals.] )
 801   fi
 802 fi
 803
 804 dnl Add our options to ac_link now, after it is set up.
 805
 806 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 807 then
 808   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 809 fi
 810
 811 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 812 then
 813   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 814 fi
 815
 816 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 817 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 818 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 819 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 820 dnl if not built to support GNU ld.
 821
 822 late_LDFLAGS=$LDFLAGS
 823 if test "$GCC" = yes; then
 824   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 825 else
 826   LDFLAGS="$LDFLAGS -znocombreloc"
 827 fi
 828
 829 AC_MSG_CHECKING([for -znocombreloc])
 830 AC_LINK_IFELSE([main(){return 0;}],
 831   [AC_MSG_RESULT(yes)],
 832   LDFLAGS=$late_LDFLAGS
 833   [AC_MSG_RESULT(no)])
 834
 835 #### Extract some information from the operating system and machine files.
 836
 837 AC_CHECKING([the machine- and system-dependent files to find out
 838  - which libraries the lib-src programs will want, and
 839  - whether the GNU malloc routines are usable])
 840
 841 ### First figure out CFLAGS (which we use for running the compiler here)
 842 ### and REAL_CFLAGS (which we use for real compilation).
 843 ### The two are the same except on a few systems, where they are made
 844 ### different to work around various lossages.  For example,
 845 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 846 ### as implying static linking.
 847
 848 ### If the CFLAGS env var is specified, we use that value
 849 ### instead of the default.
 850
 851 ### It's not important that this name contain the PID; you can't run
 852 ### two configures in the same directory and have anything work
 853 ### anyway.
 854 tempcname="conftest.c"
 855
 856 echo '
 857 #include "'${srcdir}'/src/'${opsysfile}'"
 858 #include "'${srcdir}'/src/'${machfile}'"
 859 #ifndef LIBS_MACHINE
 860 #define LIBS_MACHINE
 861 #endif
 862 #ifndef LIBS_SYSTEM
 863 #define LIBS_SYSTEM
 864 #endif
 865 #ifndef C_SWITCH_SYSTEM
 866 #define C_SWITCH_SYSTEM
 867 #endif
 868 #ifndef C_SWITCH_MACHINE
 869 #define C_SWITCH_MACHINE
 870 #endif
 871 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 872 configure___ c_switch_system=C_SWITCH_SYSTEM
 873 configure___ c_switch_machine=C_SWITCH_MACHINE
 874
 875 #ifndef LIB_X11_LIB
 876 #define LIB_X11_LIB -lX11
 877 #endif
 878
 879 #ifndef LIBX11_SYSTEM
 880 #define LIBX11_SYSTEM
 881 #endif
 882 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 883
 884 #ifdef UNEXEC
 885 configure___ unexec=UNEXEC
 886 #else
 887 configure___ unexec=unexec.o
 888 #endif
 889
 890 #ifdef SYSTEM_MALLOC
 891 configure___ system_malloc=yes
 892 #else
 893 configure___ system_malloc=no
 894 #endif
 895
 896 #ifdef USE_MMAP_FOR_BUFFERS
 897 configure___ use_mmap_for_buffers=yes
 898 #else
 899 configure___ use_mmap_for_buffers=no
 900 #endif
 901
 902 #ifndef C_DEBUG_SWITCH
 903 #define C_DEBUG_SWITCH -g
 904 #endif
 905
 906 #ifndef C_OPTIMIZE_SWITCH
 907 #ifdef __GNUC__
 908 #define C_OPTIMIZE_SWITCH -O2
 909 #else
 910 #define C_OPTIMIZE_SWITCH -O
 911 #endif
 912 #endif
 913
 914 #ifndef C_WARNINGS_SWITCH
 915 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 916 #endif
 917
 918 #ifndef LD_SWITCH_MACHINE
 919 #define LD_SWITCH_MACHINE
 920 #endif
 921
 922 #ifndef LD_SWITCH_SYSTEM
 923 #define LD_SWITCH_SYSTEM
 924 #endif
 925
 926 #ifndef LD_SWITCH_X_SITE_AUX
 927 #define LD_SWITCH_X_SITE_AUX
 928 #endif
 929
 930 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 931 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 932
 933 #ifdef THIS_IS_CONFIGURE
 934
 935 /* Get the CFLAGS for tests in configure.  */
 936 #ifdef __GNUC__
 937 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 938 #else
 939 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 940 #endif
 941
 942 #else /* not THIS_IS_CONFIGURE */
 943
 944 /* Get the CFLAGS for real compilation.  */
 945 #ifdef __GNUC__
 946 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 947 #else
 948 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 949 #endif
 950
 951 #endif /* not THIS_IS_CONFIGURE */
 952 ' > ${tempcname}
 953
 954 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 955
 956 # The value of CPP is a quoted variable reference, so we need to do this
 957 # to get its actual value...
 958 CPP=`eval "echo $CPP"`
 959 [eval `${CPP} -Isrc ${tempcname} \
 960        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 961 if test "x$SPECIFIED_CFLAGS" = x; then
 962   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 963          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 964 else
 965   REAL_CFLAGS="$CFLAGS"
 966 fi]
 967 rm ${tempcname}
 968
 969 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 970
 971 ### Make sure subsequent tests use flags consistent with the build flags.
 972
 973 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 974   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 975 else
 976   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 977 fi
 978
 979 dnl For AC_FUNC_GETLOADAVG, at least:
 980 AC_CONFIG_LIBOBJ_DIR(src)
 981
 982 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 983 AC_SYS_LARGEFILE
 984
 985
 986 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 987 ### be located in either /usr/lib64 or /usr/lib.
 988 ### In some rare cases, /usr/lib64 exists but does not contain the
 989 ### relevant files (bug#1287).  Hence test for crtn.o.
 990 case "${canonical}" in
 991   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 992     if test -e /usr/lib64/crtn.o; then
 993       AC_DEFINE(HAVE_LIB64_DIR, 1,
 994         [Define to 1 if the directory /usr/lib64 exists.])
 995 fi
 996 esac
 997
 998 dnl This function defintion taken from Gnome 2.0
 999 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1000 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1001 dnl also defines GSTUFF_PKG_ERRORS on error
1002 AC_DEFUN([PKG_CHECK_MODULES], [
1003   succeeded=no
1004
1005   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1006
1007   if test "$PKG_CONFIG" = "no" ; then
1008      ifelse([$4], , [AC_MSG_ERROR([
1009       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1010   else
1011      PKG_CONFIG_MIN_VERSION=0.9.0
1012      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1013         AC_MSG_CHECKING(for $2)
1014
1015         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1016             AC_MSG_RESULT(yes)
1017             succeeded=yes
1018
1019             AC_MSG_CHECKING($1_CFLAGS)
1020             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1021             AC_MSG_RESULT($$1_CFLAGS)
1022
1023             AC_MSG_CHECKING($1_LIBS)
1024             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1025             AC_MSG_RESULT($$1_LIBS)
1026         else
1027             AC_MSG_RESULT(no)
1028             $1_CFLAGS=""
1029             $1_LIBS=""
1030             ## If we have a custom action on failure, don't print errors, but
1031             ## do set a variable so people can do so.
1032             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1033             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1034         fi
1035
1036         AC_SUBST($1_CFLAGS)
1037         AC_SUBST($1_LIBS)
1038      else
1039         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1040         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1041      fi
1042   fi
1043
1044   if test $succeeded = yes; then
1045      ifelse([$3], , :, [$3])
1046   else
1047      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1048   fi
1049 ])
1050
1051
1052 if test "${with_sound}" != "no"; then
1053   # Sound support for GNU/Linux and the free BSDs.
1054   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1055   # Emulation library used on NetBSD.
1056   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1057   AC_SUBST(LIBSOUND)
1058
1059   ALSA_REQUIRED=1.0.0
1060   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1061   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1062   if test $HAVE_ALSA = yes; then
1063     SAVE_CFLAGS="$CFLAGS"
1064     SAVE_LDFLAGS="$LDFLAGS"
1065     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1066     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1067     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1068                     emacs_alsa_normal=yes,
1069                     emacs_alsa_normal=no)
1070     if test "$emacs_alsa_normal" != yes; then
1071       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1072                      [snd_lib_error_set_handler (0);],
1073                      emacs_alsa_subdir=yes,
1074                      emacs_alsa_subdir=no)
1075       if test "$emacs_alsa_subdir" != yes; then
1076         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1077       fi
1078       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1079     fi
1080
1081     CFLAGS="$SAVE_CFLAGS"
1082     LDFLAGS="$SAVE_LDFLAGS"
1083     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1084     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1085     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1086   fi
1087   AC_SUBST(CFLAGS_SOUND)
1088 fi
1089
1090 dnl checks for header files
1091 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1092   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1093   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1094   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1095   sys/utsname.h pwd.h)
1096
1097 AC_MSG_CHECKING(if personality LINUX32 can be set)
1098 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1099                emacs_cv_personality_linux32=yes,
1100                emacs_cv_personality_linux32=no)
1101 AC_MSG_RESULT($emacs_cv_personality_linux32)
1102
1103 if test $emacs_cv_personality_linux32 = yes; then
1104   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1105             [Define to 1 if personality LINUX32 can be set.])
1106 fi
1107
1108 dnl On Solaris 8 there's a compilation warning for term.h because
1109 dnl it doesn't define `bool'.
1110 AC_CHECK_HEADERS(term.h, , , -)
1111 AC_HEADER_STDC
1112 AC_HEADER_TIME
1113 AC_CHECK_DECLS([sys_siglist])
1114 if test $ac_cv_have_decl_sys_siglist != yes; then
1115   # For Tru64, at least:
1116   AC_CHECK_DECLS([__sys_siglist])
1117   if test $ac_cv_have_decl___sys_siglist = yes; then
1118     AC_DEFINE(sys_siglist, __sys_siglist,
1119               [Define to any substitute for sys_siglist.])
1120   fi
1121 fi
1122 AC_HEADER_SYS_WAIT
1123
1124 dnl Some systems have utime.h but don't declare the struct anyplace.
1125 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1126 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1127 #include <sys/time.h>
1128 #include <time.h>
1129 #else
1130 #ifdef HAVE_SYS_TIME_H
1131 #include <sys/time.h>
1132 #else
1133 #include <time.h>
1134 #endif
1135 #endif
1136 #ifdef HAVE_UTIME_H
1137 #include <utime.h>
1138 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1139   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1140 if test $emacs_cv_struct_utimbuf = yes; then
1141   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1142 fi
1143
1144 dnl checks for typedefs
1145 AC_TYPE_SIGNAL
1146
1147 dnl Check for speed_t typedef.
1148 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1149   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1150     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1151 if test $emacs_cv_speed_t = yes; then
1152   AC_DEFINE(HAVE_SPEED_T, 1,
1153            [Define to 1 if `speed_t' is declared by <termios.h>.])
1154 fi
1155
1156 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1157 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1158 #include <sys/time.h>
1159 #include <time.h>
1160 #else
1161 #ifdef HAVE_SYS_TIME_H
1162 #include <sys/time.h>
1163 #else
1164 #include <time.h>
1165 #endif
1166 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1167   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1168 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1169 if test $emacs_cv_struct_timeval = yes; then
1170   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1171 fi
1172
1173 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1174 AC_TRY_COMPILE([#include <math.h>],
1175 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1176   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1177 HAVE_EXCEPTION=$emacs_cv_struct_exception
1178 if test $emacs_cv_struct_exception != yes; then
1179   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1180 fi
1181
1182 AC_CHECK_HEADERS(sys/socket.h)
1183 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1184 #if HAVE_SYS_SOCKET_H
1185 #include <sys/socket.h>
1186 #endif])
1187
1188 dnl checks for structure members
1189 AC_STRUCT_TM
1190 AC_STRUCT_TIMEZONE
1191 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1192                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1193                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1194                 [#include <time.h>])
1195 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1196                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1197                   struct ifreq.ifr_addr], , ,
1198                  [AC_INCLUDES_DEFAULT
1199 #if HAVE_SYS_SOCKET_H
1200 #include <sys/socket.h>
1201 #endif
1202 #if HAVE_NET_IF_H
1203 #include <net/if.h>
1204 #endif])
1205
1206 dnl checks for compiler characteristics
1207
1208 dnl Testing __STDC__ to determine prototype support isn't good enough.
1209 dnl DEC C, for instance, doesn't define it with default options, and
1210 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1211 dnl and void *.
1212 AC_C_PROTOTYPES
1213 AC_C_VOLATILE
1214 AC_C_CONST
1215 dnl This isn't useful because we can't turn on use of `inline' unless
1216 dnl the compiler groks `extern inline'.
1217 dnl AC_C_INLINE
1218 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1219   [AC_TRY_COMPILE(, [void * foo;],
1220                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1221 if test $emacs_cv_void_star = yes; then
1222   AC_DEFINE(POINTER_TYPE, void)
1223 else
1224   AC_DEFINE(POINTER_TYPE, char)
1225 fi
1226 AH_TEMPLATE(POINTER_TYPE,
1227             [Define as `void' if your compiler accepts `void *'; otherwise
1228              define as `char'.])dnl
1229
1230
1231
1232 dnl This could be used for targets which can have both byte sexes.
1233 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1234 dnl AC_C_BIGENDIAN
1235
1236 dnl check for Make feature
1237 AC_PROG_MAKE_SET
1238
1239 dnl check for GNU Make if we have GCC and autodepend is on.
1240 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1241    AC_MSG_CHECKING([whether we are using GNU Make])
1242    HAVE_GNU_MAKE=no
1243    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1244    if test "x$testval" != x; then
1245       HAVE_GNU_MAKE=yes
1246    else
1247       ac_enable_autodepend=no
1248    fi
1249    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1250    if test $HAVE_GNU_MAKE = yes; then
1251       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1252       SAVE_CFLAGS="$CFLAGS"
1253       CFLAGS="$CFLAGS -MMD -MF deps.d"
1254       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1255       CFLAGS="$SAVE_CFLAGS"
1256       test -f deps.d || ac_enable_autodepend=no
1257       rm -rf deps.d
1258       AC_MSG_RESULT([$ac_enable_autodepend])
1259    fi
1260    if test $ac_enable_autodepend = yes; then
1261       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1262    fi
1263 fi
1264
1265 dnl checks for operating system services
1266 AC_SYS_LONG_FILE_NAMES
1267
1268 #### Choose a window system.
1269
1270 AC_PATH_X
1271 if test "$no_x" = yes; then
1272   window_system=none
1273 else
1274   window_system=x11
1275 fi
1276
1277 ## Workaround for bug in autoconf <= 2.62.
1278 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1279 ## No need to do anything special for these standard directories.
1280 ## This is an experiment, take it out if it causes problems.
1281 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1282
1283    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1284
1285 fi
1286
1287 if test "${x_libraries}" != NONE; then
1288   if test -n "${x_libraries}"; then
1289     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1290     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1291   fi
1292   x_default_search_path=""
1293   x_search_path=${x_libraries}
1294   if test -z "${x_search_path}"; then
1295     x_search_path=/usr/lib
1296   fi
1297   for x_library in `echo ${x_search_path}: | \
1298                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1299     x_search_path="\
1300 ${x_library}/X11/%L/%T/%N%C%S:\
1301 ${x_library}/X11/%l/%T/%N%C%S:\
1302 ${x_library}/X11/%T/%N%C%S:\
1303 ${x_library}/X11/%L/%T/%N%S:\
1304 ${x_library}/X11/%l/%T/%N%S:\
1305 ${x_library}/X11/%T/%N%S"
1306     if test x"${x_default_search_path}" = x; then
1307       x_default_search_path=${x_search_path}
1308     else
1309       x_default_search_path="${x_search_path}:${x_default_search_path}"
1310     fi
1311   done
1312 fi
1313 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1314   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1315 fi
1316
1317 if test x"${x_includes}" = x; then
1318   bitmapdir=/usr/include/X11/bitmaps
1319 else
1320   # accumulate include directories that have X11 bitmap subdirectories
1321   bmd_acc="dummyval"
1322   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1323     if test -d "${bmd}/X11/bitmaps"; then
1324       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1325     fi
1326     if test -d "${bmd}/bitmaps"; then
1327       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1328     fi
1329   done
1330   if test ${bmd_acc} != "dummyval"; then
1331     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1332   fi
1333 fi
1334
1335 HAVE_NS=no
1336 NS_IMPL_COCOA=no
1337 NS_IMPL_GNUSTEP=no
1338 tmp_CPPFLAGS="$CPPFLAGS"
1339 tmp_CFLAGS="$CFLAGS"
1340 CPPFLAGS="$CPPFLAGS -x objective-c"
1341 CFLAGS="$CFLAGS -x objective-c"
1342 if test "${with_ns}" != no; then
1343   if test "${opsys}" = darwin; then
1344      NS_IMPL_COCOA=yes
1345      ns_appdir=`pwd`/nextstep/Emacs.app
1346      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1347      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1348      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1349   elif test -f $GNUSTEP_CONFIG_FILE; then
1350      NS_IMPL_GNUSTEP=yes
1351      ns_appdir=`pwd`/nextstep/Emacs.app
1352      ns_appbindir=`pwd`/nextstep/Emacs.app
1353      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1354      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1355      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1356      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1357      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1358      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1359      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1360      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1361      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1362      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1363   fi
1364   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1365                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1366   files are missing or cannot be compiled.])])
1367   NS_HAVE_NSINTEGER=yes
1368   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1369                                      [NSInteger i;])],
1370                     ns_have_nsinteger=yes,
1371                     ns_have_nsinteger=no)
1372   if test $ns_have_nsinteger = no; then
1373     NS_HAVE_NSINTEGER=no
1374   fi
1375 fi
1376 if test "${HAVE_NS}" = yes; then
1377   window_system=nextstep
1378   with_xft=no
1379   # set up packaging dirs
1380   exec_prefix=${ns_appbindir}
1381   libexecdir=${ns_appbindir}/libexec
1382   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1383      prefix=${ns_appresdir}
1384   fi
1385 fi
1386 CFLAGS="$tmp_CFLAGS"
1387 CPPFLAGS="$tmp_CPPFLAGS"
1388
1389 case "${window_system}" in
1390   x11 )
1391     HAVE_X_WINDOWS=yes
1392     HAVE_X11=yes
1393     case "${with_x_toolkit}" in
1394       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1395       motif ) USE_X_TOOLKIT=MOTIF ;;
1396       gtk ) with_gtk=yes
1397 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1398 dnl USE_X_TOOLKIT is set.
1399             USE_X_TOOLKIT=none ;;
1400       no ) USE_X_TOOLKIT=none ;;
1401 dnl If user did not say whether to use a toolkit, make this decision later:
1402 dnl use the toolkit if we have gtk, or X11R5 or newer.
1403       * ) USE_X_TOOLKIT=maybe ;;
1404     esac
1405   ;;
1406   nextstep | none )
1407     HAVE_X_WINDOWS=no
1408     HAVE_X11=no
1409     USE_X_TOOLKIT=none
1410   ;;
1411 esac
1412
1413 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1414    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1415    if test "$HAVE_XSERVER" = true ||
1416       test -n "$DISPLAY" ||
1417       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1418         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1419 were found.  You should install the relevant development files for X
1420 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1421 sure you have development files for image handling, i.e.
1422 tiff, gif, jpeg, png and xpm.
1423 If you are sure you want Emacs compiled without X window support, pass
1424   --without-x
1425 to configure.])
1426    fi
1427 fi
1428
1429 ### If we're using X11, we should use the X menu package.
1430 HAVE_MENUS=no
1431 case ${HAVE_X11} in
1432   yes ) HAVE_MENUS=yes ;;
1433 esac
1434
1435 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1436 # Assume not, until told otherwise.
1437 GNU_MALLOC=yes
1438 doug_lea_malloc=yes
1439 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1440 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1441 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1442                emacs_cv_var___after_morecore_hook,
1443 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1444   emacs_cv_var___after_morecore_hook=yes,
1445   emacs_cv_var___after_morecore_hook=no)])
1446 if test $emacs_cv_var___after_morecore_hook = no; then
1447   doug_lea_malloc=no
1448 fi
1449 if test "${system_malloc}" = "yes"; then
1450   GNU_MALLOC=no
1451   GNU_MALLOC_reason="
1452     (The GNU allocators don't work with this system configuration.)"
1453 fi
1454 if test "$doug_lea_malloc" = "yes" ; then
1455   if test "$GNU_MALLOC" = yes ; then
1456     GNU_MALLOC_reason="
1457       (Using Doug Lea's new malloc from the GNU C Library.)"
1458   fi
1459   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1460             [Define to 1 if you are using the GNU C Library.])
1461 fi
1462
1463 if test x"${REL_ALLOC}" = x; then
1464   REL_ALLOC=${GNU_MALLOC}
1465 fi
1466
1467 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1468 dnl the system configuration file (s/*.h) to turn the use of mmap
1469 dnl in the relocating allocator on.
1470
1471 AC_FUNC_MMAP
1472 if test $use_mmap_for_buffers = yes; then
1473   REL_ALLOC=no
1474 fi
1475
1476 LIBS="$libsrc_libs $LIBS"
1477
1478 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1479 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1480 AC_CHECK_LIB(dnet, dnet_ntoa)
1481 dnl This causes -lresolv to get used in subsequent tests,
1482 dnl which causes failures on some systems such as HPUX 9.
1483 dnl AC_CHECK_LIB(resolv, gethostbyname)
1484
1485 dnl FIXME replace main with a function we actually want from this library.
1486 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1487
1488 AC_CHECK_LIB(pthreads, cma_open)
1489
1490 dnl Check for need for bigtoc support on IBM AIX
1491
1492 case ${host_os} in
1493 aix*)
1494   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1495     case $GCC in
1496     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1497     *) gdb_cv_bigtoc=-bbigtoc ;;
1498     esac
1499
1500     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1501     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1502   ])
1503   ;;
1504 esac
1505
1506 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1507 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1508 # REAL_CPPFLAGS later on.
1509
1510 REAL_CPPFLAGS="$CPPFLAGS"
1511
1512 if test "${HAVE_X11}" = "yes"; then
1513   DEFS="$C_SWITCH_X_SITE $DEFS"
1514   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1515   LIBS="$LIBX $LIBS"
1516   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1517   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1518
1519   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1520   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1521   # but it's more convenient here to set LD_RUN_PATH
1522   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1523   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1524     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1525     export LD_RUN_PATH
1526   fi
1527
1528   if test "${opsys}" = "gnu-linux"; then
1529     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1530     AC_TRY_LINK([],
1531      [XOpenDisplay ("foo");],
1532      [xlinux_first_failure=no],
1533      [xlinux_first_failure=yes])
1534     if test "${xlinux_first_failure}" = "yes"; then
1535       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1536       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1537       OLD_CPPFLAGS="$CPPFLAGS"
1538       OLD_LIBS="$LIBS"
1539       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1540       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1541       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1542       LIBS="$LIBS -b i486-linuxaout"
1543       AC_TRY_LINK([],
1544        [XOpenDisplay ("foo");],
1545        [xlinux_second_failure=no],
1546        [xlinux_second_failure=yes])
1547       if test "${xlinux_second_failure}" = "yes"; then
1548         # If we get the same failure with -b, there is no use adding -b.
1549         # So take it out.  This plays safe.
1550         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1551         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1552         CPPFLAGS="$OLD_CPPFLAGS"
1553         LIBS="$OLD_LIBS"
1554         AC_MSG_RESULT(no)
1555       else
1556         AC_MSG_RESULT(yes)
1557       fi
1558     else
1559       AC_MSG_RESULT(no)
1560     fi
1561   fi
1562
1563   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1564   # header files included from there.
1565   AC_MSG_CHECKING(for Xkb)
1566   AC_TRY_LINK([#include <X11/Xlib.h>
1567 #include <X11/XKBlib.h>],
1568         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1569         emacs_xkb=yes, emacs_xkb=no)
1570   AC_MSG_RESULT($emacs_xkb)
1571   if test $emacs_xkb = yes; then
1572     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1573   fi
1574
1575   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1576 XScreenNumberOfScreen XSetWMProtocols)
1577 fi
1578
1579 if test "${window_system}" = "x11"; then
1580   AC_MSG_CHECKING(X11 version 6)
1581   AC_CACHE_VAL(emacs_cv_x11_version_6,
1582   [AC_TRY_LINK([#include <X11/Xlib.h>],
1583 [#if XlibSpecificationRelease < 6
1584 fail;
1585 #endif
1586 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1587   if test $emacs_cv_x11_version_6 = yes; then
1588     AC_MSG_RESULT(6 or newer)
1589     AC_DEFINE(HAVE_X11R6, 1,
1590               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1591   else
1592     AC_MSG_RESULT(before 6)
1593   fi
1594 fi
1595
1596
1597 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1598 HAVE_RSVG=no
1599 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1600   if test "${with_rsvg}" != "no"; then
1601     RSVG_REQUIRED=2.11.0
1602     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1603
1604     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1605     AC_SUBST(RSVG_CFLAGS)
1606     AC_SUBST(RSVG_LIBS)
1607
1608     if test ".${RSVG_CFLAGS}" != "."; then
1609       HAVE_RSVG=yes
1610       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1611       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1612       LIBS="$RSVG_LIBS $LIBS"
1613     fi
1614   fi
1615 fi
1616
1617
1618 HAVE_GTK=no
1619 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1620   GLIB_REQUIRED=2.6
1621   GTK_REQUIRED=2.6
1622   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1623
1624   dnl Checks for libraries.
1625   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1626   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1627      AC_MSG_ERROR($GTK_PKG_ERRORS)
1628   fi
1629 fi
1630
1631
1632 if test x"$pkg_check_gtk" = xyes; then
1633
1634   AC_SUBST(GTK_CFLAGS)
1635   AC_SUBST(GTK_LIBS)
1636   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1637   CFLAGS="$CFLAGS $GTK_CFLAGS"
1638   LIBS="$GTK_LIBS $LIBS"
1639   dnl Try to compile a simple GTK program.
1640   GTK_COMPILES=no
1641   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1642   if test "${GTK_COMPILES}" != "yes"; then
1643     if test "$USE_X_TOOLKIT" != "maybe"; then
1644       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1645     fi
1646   else
1647     HAVE_GTK=yes
1648     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1649     USE_X_TOOLKIT=none
1650     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1651       :
1652     else
1653       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1654        closing open displays.  This is no problem if you just use
1655        one display, but if you use more than one and close one of them
1656        Emacs may crash.]])
1657       sleep 3
1658     fi
1659   fi
1660
1661 fi
1662
1663
1664 if test "${HAVE_GTK}" = "yes"; then
1665
1666   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1667   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1668   if test "$with_toolkit_scroll_bars" != no; then
1669     with_toolkit_scroll_bars=yes
1670   fi
1671
1672   dnl  Check if we can use multiple displays with this GTK version.
1673   dnl  If gdk_display_open exists, assume all others are there also.
1674   HAVE_GTK_MULTIDISPLAY=no
1675   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1676   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1677     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1678               [Define to 1 if GTK can handle more than one display.])
1679   fi
1680
1681   dnl  Check if we have the old file selection dialog declared and
1682   dnl  in the link library.  In 2.x it may be in the library,
1683   dnl  but not declared if deprecated featured has been selected out.
1684   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1685   HAVE_GTK_FILE_SELECTION=no
1686   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1687                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1688 #include <gtk/gtk.h>])
1689   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1690     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1691                    HAVE_GTK_FILE_SELECTION=no)
1692   fi
1693
1694   dnl  Check if we have the new file chooser dialog
1695   HAVE_GTK_FILE_CHOOSER=no
1696   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1697                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1698 #include <gtk/gtk.h>])
1699   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1700     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1701                    HAVE_GTK_FILE_CHOOSER=no)
1702   fi
1703
1704   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1705      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1706     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1707               [Define to 1 if GTK has both file selection and chooser dialog.])
1708   fi
1709
1710   dnl Check if pthreads are available.  Emacs only needs this when using
1711   dnl gtk_file_chooser under Gnome.
1712   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1713     HAVE_GTK_AND_PTHREAD=no
1714     AC_CHECK_HEADERS(pthread.h)
1715     if test "$ac_cv_header_pthread_h"; then
1716       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1717     fi
1718     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1719       case "${canonical}" in
1720         *-hpux*) ;;
1721         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1722       esac
1723       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1724                [Define to 1 if you have GTK and pthread (-lpthread).])
1725     fi
1726   fi
1727 fi
1728
1729 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1730 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1731 dnl also not configured.
1732 HAVE_DBUS=no
1733 if test "${with_dbus}" = "yes"; then
1734    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1735    if test "$HAVE_DBUS" = yes; then
1736      LIBS="$LIBS $DBUS_LIBS"
1737      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1738      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1739    fi
1740 fi
1741
1742 dnl Do not put whitespace before the #include statements below.
1743 dnl Older compilers (eg sunos4 cc) choke on it.
1744 HAVE_XAW3D=no
1745 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1746   if test "$with_xaw3d" != no; then
1747     AC_MSG_CHECKING(for xaw3d)
1748     AC_CACHE_VAL(emacs_cv_xaw3d,
1749     [AC_TRY_LINK([
1750 #include <X11/Intrinsic.h>
1751 #include <X11/Xaw3d/Simple.h>],
1752       [],
1753       emacs_cv_xaw3d=yes,
1754       emacs_cv_xaw3d=no)])
1755   else
1756     emacs_cv_xaw3d=no
1757   fi
1758   if test $emacs_cv_xaw3d = yes; then
1759     AC_MSG_RESULT([yes; using Lucid toolkit])
1760     USE_X_TOOLKIT=LUCID
1761     HAVE_XAW3D=yes
1762     AC_DEFINE(HAVE_XAW3D, 1,
1763               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1764   else
1765     AC_MSG_RESULT(no)
1766     AC_MSG_CHECKING(for libXaw)
1767     AC_CACHE_VAL(emacs_cv_xaw,
1768     [AC_TRY_LINK([
1769 #include <X11/Intrinsic.h>
1770 #include <X11/Xaw/Simple.h>],
1771       [],
1772       emacs_cv_xaw=yes,
1773       emacs_cv_xaw=no)])
1774     if test $emacs_cv_xaw = yes; then
1775       AC_MSG_RESULT([yes; using Lucid toolkit])
1776       USE_X_TOOLKIT=LUCID
1777     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1778       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1779     else
1780       AC_MSG_RESULT([no; do not use toolkit by default])
1781       USE_X_TOOLKIT=none
1782     fi
1783   fi
1784 fi
1785
1786 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1787
1788 if test "${USE_X_TOOLKIT}" != "none"; then
1789   AC_MSG_CHECKING(X11 toolkit version)
1790   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1791   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1792 [#if XtSpecificationRelease < 6
1793 fail;
1794 #endif
1795 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1796   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1797   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1798     AC_MSG_RESULT(6 or newer)
1799     AC_DEFINE(HAVE_X11XTR6, 1,
1800               [Define to 1 if you have the X11R6 or newer version of Xt.])
1801   else
1802     AC_MSG_RESULT(before 6)
1803   fi
1804
1805 dnl If using toolkit, check whether libXmu.a exists.
1806 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1807   OLDLIBS="$LIBS"
1808   if test x$HAVE_X11XTR6 = xyes; then
1809     LIBS="-lXt -lSM -lICE $LIBS"
1810   else
1811     LIBS="-lXt $LIBS"
1812   fi
1813   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1814   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1815 fi
1816
1817 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1818 if test "${HAVE_X11}" = "yes"; then
1819   if test "${USE_X_TOOLKIT}" != "none"; then
1820     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1821   fi
1822 fi
1823
1824 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1825   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1826   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1827     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1828 int x = 5;
1829 #else
1830 Motif version prior to 2.1.
1831 #endif],
1832     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1833   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1834   if test $emacs_cv_motif_version_2_1 = yes; then
1835     HAVE_LIBXP=no
1836     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1837               [Define to 1 if you have Motif 2.1 or newer.])
1838     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1839     if test ${HAVE_LIBXP} = yes; then
1840       AC_DEFINE(HAVE_LIBXP, 1,
1841                 [Define to 1 if you have the Xp library (-lXp).])
1842     fi
1843   else
1844     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1845     # We put this in CFLAGS temporarily to precede other -I options
1846     # that might be in CFLAGS temporarily.
1847     # We put this in CPPFLAGS where it precedes the other -I options.
1848     OLD_CPPFLAGS=$CPPFLAGS
1849     OLD_CFLAGS=$CFLAGS
1850     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1851     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1852     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1853       [int x = 5;],
1854       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1855     if test $emacs_cv_lesstif = yes; then
1856       # Make sure this -I option remains in CPPFLAGS after it is set
1857       # back to REAL_CPPFLAGS.
1858       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1859       # have those other -I options anyway.  Ultimately, having this
1860       # directory ultimately in CPPFLAGS will be enough.
1861       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1862       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1863     else
1864       CFLAGS=$OLD_CFLAGS
1865       CPPFLAGS=$OLD_CPPFLAGS
1866     fi
1867   fi
1868 fi
1869
1870 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1871 dnl using Motif or Xaw3d is available, and unless
1872 dnl --with-toolkit-scroll-bars=no was specified.
1873
1874 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1875             [Define to 1 if we should use toolkit scroll bars.])dnl
1876 USE_TOOLKIT_SCROLL_BARS=no
1877 if test "${with_toolkit_scroll_bars}" != "no"; then
1878   if test "${USE_X_TOOLKIT}" != "none"; then
1879     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1880       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1881       HAVE_XAW3D=no
1882       USE_TOOLKIT_SCROLL_BARS=yes
1883     elif test "${HAVE_XAW3D}" = "yes"; then
1884       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1885       USE_TOOLKIT_SCROLL_BARS=yes
1886     fi
1887   elif test "${HAVE_GTK}" = "yes"; then
1888     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1889     USE_TOOLKIT_SCROLL_BARS=yes
1890   elif test "${HAVE_NS}" = "yes"; then
1891     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1892     USE_TOOLKIT_SCROLL_BARS=yes
1893   fi
1894 fi
1895
1896 dnl See if XIM is available.
1897 AC_TRY_COMPILE([
1898           #include <X11/Xlib.h>
1899           #include <X11/Xresource.h>],
1900          [XIMProc  callback;],
1901          [HAVE_XIM=yes
1902          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1903          HAVE_XIM=no)
1904
1905 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1906
1907 if test "${with_xim}" != "no"; then
1908   AC_DEFINE(USE_XIM, 1,
1909             [Define to 1 if we should use XIM, if it is available.])
1910 fi
1911
1912
1913 if test "${HAVE_XIM}" != "no"; then
1914   late_CFLAGS=$CFLAGS
1915   if test "$GCC" = yes; then
1916     CFLAGS="$CFLAGS --pedantic-errors"
1917   fi
1918   AC_TRY_COMPILE([
1919 #include <X11/Xlib.h>
1920 #include <X11/Xresource.h>],
1921 [Display *display;
1922 XrmDatabase db;
1923 char *res_name;
1924 char *res_class;
1925 XIMProc  callback;
1926 XPointer *client_data;
1927 #ifndef __GNUC__
1928 /* If we're not using GCC, it's probably not XFree86, and this is
1929    probably right, but we can't use something like --pedantic-errors.  */
1930 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1931                                            char*, XIMProc, XPointer*);
1932 #endif
1933 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1934    client_data);],
1935     [emacs_cv_arg6_star=yes])
1936   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1937          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1938 either XPointer or XPointer*.])dnl
1939   if test "$emacs_cv_arg6_star" = yes; then
1940     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1941   else
1942     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1943   fi
1944   CFLAGS=$late_CFLAGS
1945 fi
1946
1947 ### Start of font-backend (under any platform) section.
1948 # (nothing here yet -- this is a placeholder)
1949 ### End of font-backend (under any platform) section.
1950
1951 ### Start of font-backend (under X11) section.
1952 if test "${HAVE_X11}" = "yes"; then
1953    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1954
1955    ## Use -lXft if available, unless `--with-xft=no'.
1956    HAVE_XFT=maybe
1957     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
1958       with_xft="no";
1959     fi
1960     if test "x${with_xft}" != "xno"; then
1961
1962       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1963       if test "$HAVE_XFT" != no; then
1964         OLD_CPPFLAGS="$CPPFLAGS"
1965         OLD_CFLAGS="$CFLAGS"
1966         OLD_LIBS="$LIBS"
1967         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1968         CFLAGS="$CFLAGS $XFT_CFLAGS"
1969         LIBS="$XFT_LIBS $LIBS"
1970         AC_CHECK_HEADER(X11/Xft/Xft.h,
1971           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1972
1973         if test "${HAVE_XFT}" = "yes"; then
1974           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1975             AC_SUBST(XFT_LIBS)
1976           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1977         else
1978           CPPFLAGS="$OLD_CPPFLAGS"
1979           CFLAGS="$OLD_CFLAGS"
1980           LIBS="$OLD_LIBS"
1981         fi                        # "${HAVE_XFT}" = "yes"
1982       fi                          # "$HAVE_XFT" != no
1983     fi                            # "x${with_xft}" != "xno"
1984
1985     dnl For the "Does Emacs use" message at the end.
1986     if test "$HAVE_XFT" != "yes"; then
1987        HAVE_XFT=no
1988     fi
1989
1990
1991     HAVE_FREETYPE=no
1992     ## We used to allow building with FreeType and without Xft.
1993     ## However, the ftx font backend driver is not in good shape.
1994     if test "${HAVE_XFT}" = "yes"; then
1995       dnl As we use Xft, we anyway use freetype.
1996       dnl There's no need for additional CFLAGS and LIBS.
1997       HAVE_FREETYPE=yes
1998       FONTCONFIG_CFLAGS=
1999       FONTCONFIG_LIBS=
2000     fi
2001
2002     HAVE_LIBOTF=no
2003     if test "${HAVE_FREETYPE}" = "yes"; then
2004       AC_DEFINE(HAVE_FREETYPE, 1,
2005                 [Define to 1 if using the freetype and fontconfig libraries.])
2006       if test "${with_libotf}" != "no"; then
2007         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2008                           HAVE_LIBOTF=no)
2009         if test "$HAVE_LIBOTF" = "yes"; then
2010           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2011           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2012                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2013                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2014           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2015             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2016                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2017           fi
2018         fi
2019       fi
2020     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2021     dnl Does the new font backend require it, or can it work without it?
2022     fi
2023
2024     HAVE_M17N_FLT=no
2025     if test "${HAVE_LIBOTF}" = yes; then
2026       if test "${with_m17n_flt}" != "no"; then
2027         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2028         if test "$HAVE_M17N_FLT" = "yes"; then
2029           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2030         fi
2031       fi
2032     fi
2033 else
2034     HAVE_XFT=no
2035     HAVE_FREETYPE=no
2036     HAVE_LIBOTF=no
2037     HAVE_M17N_FLT=no
2038 fi
2039 ### End of font-backend (under X11) section.
2040
2041 AC_SUBST(FREETYPE_CFLAGS)
2042 AC_SUBST(FREETYPE_LIBS)
2043 AC_SUBST(FONTCONFIG_CFLAGS)
2044 AC_SUBST(FONTCONFIG_LIBS)
2045 AC_SUBST(LIBOTF_CFLAGS)
2046 AC_SUBST(LIBOTF_LIBS)
2047 AC_SUBST(M17N_FLT_CFLAGS)
2048 AC_SUBST(M17N_FLT_LIBS)
2049
2050 ### Use -lXpm if available, unless `--with-xpm=no'.
2051 HAVE_XPM=no
2052 if test "${HAVE_X11}" = "yes"; then
2053   if test "${with_xpm}" != "no"; then
2054     AC_CHECK_HEADER(X11/xpm.h,
2055       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2056     if test "${HAVE_XPM}" = "yes"; then
2057       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2058       AC_EGREP_CPP(no_return_alloc_pixels,
2059       [#include "X11/xpm.h"
2060 #ifndef XpmReturnAllocPixels
2061 no_return_alloc_pixels
2062 #endif
2063       ], HAVE_XPM=no, HAVE_XPM=yes)
2064
2065       if test "${HAVE_XPM}" = "yes"; then
2066         AC_MSG_RESULT(yes)
2067       else
2068         AC_MSG_RESULT(no)
2069       fi
2070     fi
2071   fi
2072
2073   if test "${HAVE_XPM}" = "yes"; then
2074     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2075   fi
2076 fi
2077
2078 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2079 HAVE_JPEG=no
2080 if test "${HAVE_X11}" = "yes"; then
2081   if test "${with_jpeg}" != "no"; then
2082     dnl Checking for jpeglib.h can lose because of a redefinition of
2083     dnl  HAVE_STDLIB_H.
2084     AC_CHECK_HEADER(jerror.h,
2085       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2086   fi
2087
2088   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2089   if test "${HAVE_JPEG}" = "yes"; then
2090     AC_DEFINE(HAVE_JPEG)
2091     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2092         [#include <jpeglib.h>
2093          version=JPEG_LIB_VERSION
2094 ],
2095         [AC_DEFINE(HAVE_JPEG)],
2096         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2097         HAVE_JPEG=no])
2098   fi
2099 fi
2100
2101 ### Use -lpng if available, unless `--with-png=no'.
2102 HAVE_PNG=no
2103 if test "${HAVE_X11}" = "yes"; then
2104   if test "${with_png}" != "no"; then
2105     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2106     # in /usr/include/libpng.
2107     AC_CHECK_HEADERS(png.h libpng/png.h)
2108     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2109       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2110     fi
2111   fi
2112
2113   if test "${HAVE_PNG}" = "yes"; then
2114     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2115   fi
2116 fi
2117
2118 ### Use -ltiff if available, unless `--with-tiff=no'.
2119 HAVE_TIFF=no
2120 if test "${HAVE_X11}" = "yes"; then
2121   if test "${with_tiff}" != "no"; then
2122     AC_CHECK_HEADER(tiffio.h,
2123       [tifflibs="-lz -lm"
2124       # At least one tiff package requires the jpeg library.
2125       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2126       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2127   fi
2128
2129   if test "${HAVE_TIFF}" = "yes"; then
2130     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2131   fi
2132 fi
2133
2134 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2135 HAVE_GIF=no
2136 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2137   AC_CHECK_HEADER(gif_lib.h,
2138 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2139 # Earlier versions can crash Emacs.
2140     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2141
2142   if test "$HAVE_GIF" = yes; then
2143       ac_gif_lib_name="-lgif"
2144   fi
2145
2146 # If gif_lib.h but no libgif, try libungif.
2147   if test x"$try_libungif" = xyes; then
2148     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2149
2150     if test "$HAVE_GIF" = yes; then
2151       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2152       ac_gif_lib_name="-lungif"
2153     fi
2154   fi
2155
2156   if test "${HAVE_GIF}" = "yes"; then
2157     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2158   fi
2159 fi
2160
2161 dnl Check for required libraries.
2162 if test "${HAVE_X11}" = "yes"; then
2163   MISSING=""
2164   WITH_NO=""
2165   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2166     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2167   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2168     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2169   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2170     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2171   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2172     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2173   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2174     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2175
2176   if test "X${MISSING}" != X; then
2177     AC_MSG_ERROR([The following required libraries were not found:
2178     $MISSING
2179 Maybe some development libraries/packages are missing?
2180 If you don't want to link with them give
2181     $WITH_NO
2182 as options to configure])
2183   fi
2184 fi
2185
2186 ### Use -lgpm if available, unless `--with-gpm=no'.
2187 HAVE_GPM=no
2188 if test "${with_gpm}" != "no"; then
2189   AC_CHECK_HEADER(gpm.h,
2190     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2191 fi
2192
2193 if test "${HAVE_GPM}" = "yes"; then
2194   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2195 fi
2196
2197 dnl Check for malloc/malloc.h on darwin
2198 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2199
2200 ### Use NeXTstep API to implement GUI.
2201 if test "${HAVE_NS}" = "yes"; then
2202   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2203   if test "${NS_IMPL_COCOA}" = "yes"; then
2204     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2205     GNU_OBJC_CFLAGS=
2206   fi
2207   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2208     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2209     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2210   fi
2211   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2212     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2213   fi
2214   # We also have mouse menus.
2215   HAVE_MENUS=yes
2216   OTHER_FILES=ns-app
2217 fi
2218
2219
2220 ### Use session management (-lSM -lICE) if available
2221 HAVE_X_SM=no
2222 if test "${HAVE_X11}" = "yes"; then
2223   AC_CHECK_HEADER(X11/SM/SMlib.h,
2224     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2225
2226   if test "${HAVE_X_SM}" = "yes"; then
2227     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2228     case "$LIBS" in
2229       *-lSM*) ;;
2230       *)      LIBS="-lSM -lICE $LIBS" ;;
2231     esac
2232   fi
2233 fi
2234
2235 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2236 AC_CACHE_CHECK(whether netdb declares h_errno,
2237                emacs_cv_netdb_declares_h_errno,
2238 [AC_TRY_LINK([#include <netdb.h>],
2239   [return h_errno;],
2240   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2241 if test $emacs_cv_netdb_declares_h_errno = yes; then
2242   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2243 fi
2244
2245 AC_FUNC_ALLOCA
2246
2247 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2248 dnl FIXME is there an autoconf test that does the right thing, without
2249 dnl needing to call A_M_E afterwards?
2250 if test x"$ac_cv_func_alloca_works" != xyes; then
2251    AC_MSG_ERROR( [a system implementation of alloca is required] )
2252 fi
2253
2254 # fmod, logb, and frexp are found in -lm on most systems.
2255 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2256 AC_CHECK_LIB(m, sqrt)
2257
2258 # Check for mail-locking functions in a "mail" library.  Probably this should
2259 # have the same check as for liblockfile below.
2260 AC_CHECK_LIB(mail, maillock)
2261 dnl Debian, at least:
2262 AC_CHECK_LIB(lockfile, maillock)
2263 # If we have the shared liblockfile, assume we must use it for mail
2264 # locking (e.g. Debian).  If we couldn't link against liblockfile
2265 # (no liblockfile.a installed), ensure that we don't need to.
2266 if test "$ac_cv_lib_lockfile_maillock" = no; then
2267   dnl This works for files generally, not just executables.
2268   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2269   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2270                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2271   if test $ac_cv_prog_liblockfile = yes; then
2272     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2273 This probably means that movemail could lose mail.
2274 There may be a `development' package to install containing liblockfile.])
2275   else :
2276   fi
2277 fi
2278 AC_CHECK_FUNCS(touchlock)
2279 AC_CHECK_HEADERS(maillock.h)
2280
2281 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2282 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2283 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2284 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2285 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2286 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2287 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2288 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2289 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2290 cfmakeraw cfsetspeed)
2291
2292 AC_CHECK_HEADERS(sys/un.h)
2293
2294 AC_FUNC_MKTIME
2295 if test "$ac_cv_func_working_mktime" = no; then
2296   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2297 fi
2298
2299 AC_FUNC_GETLOADAVG
2300
2301 AC_FUNC_FSEEKO
2302
2303 # Configure getopt.
2304 m4_include([m4/getopt.m4])
2305 gl_GETOPT_IFELSE([
2306   gl_GETOPT_SUBSTITUTE_HEADER
2307   gl_PREREQ_GETOPT
2308   GETOPTOBJS='getopt.o getopt1.o'
2309 ])
2310 AC_SUBST(GETOPTOBJS)
2311
2312 AC_FUNC_GETPGRP
2313
2314 AC_FUNC_STRFTIME
2315
2316 # UNIX98 PTYs.
2317 AC_CHECK_FUNCS(grantpt)
2318
2319 # PTY-related GNU extensions.
2320 AC_CHECK_FUNCS(getpt)
2321
2322 # Check this now, so that we will NOT find the above functions in ncurses.
2323 # That is because we have not set up to link ncurses in lib-src.
2324 # It's better to believe a function is not available
2325 # than to expect to find it in ncurses.
2326 AC_CHECK_LIB(ncurses, tparm)
2327
2328 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2329
2330 resolv=no
2331 AC_TRY_LINK([#include <netinet/in.h>
2332 #include <arpa/nameser.h>
2333 #include <resolv.h>],
2334     [return res_init();],
2335     have_res_init=yes, have_res_init=no)
2336 if test "$have_res_init" = no; then
2337   OLIBS="$LIBS"
2338   LIBS="$LIBS -lresolv"
2339   AC_MSG_CHECKING(for res_init with -lresolv)
2340   AC_TRY_LINK([#include <netinet/in.h>
2341 #include <arpa/nameser.h>
2342 #include <resolv.h>],
2343     [return res_init();],
2344     have_res_init=yes, have_res_init=no)
2345   AC_MSG_RESULT($have_res_init)
2346   if test "$have_res_init" = yes ; then
2347     resolv=yes
2348   fi
2349   LIBS="$OLIBS"
2350 fi
2351
2352 if test "$have_res_init" = yes; then
2353   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2354 fi
2355
2356 # Do we need the Hesiod library to provide the support routines?
2357 if test "$with_hesiod" != no ; then
2358   # Don't set $LIBS here -- see comments above.
2359   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2360      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2361                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2362   if test "$resolv" = yes ; then
2363     RESOLVLIB=-lresolv
2364   else
2365     RESOLVLIB=
2366   fi
2367   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2368         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2369                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2370         :, $RESOLVLIB)])
2371 fi
2372
2373 # Do we need libresolv (due to res_init or Hesiod)?
2374 if test "$resolv" = yes ; then
2375   AC_DEFINE(HAVE_LIBRESOLV, 1,
2376             [Define to 1 if you have the resolv library (-lresolv).])
2377 fi
2378
2379 # These tell us which Kerberos-related libraries to use.
2380 if test "${with_kerberos}" != no; then
2381   AC_CHECK_LIB(com_err, com_err)
2382   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2383   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2384   AC_CHECK_LIB(krb5, krb5_init_context)
2385   if test "${with_kerberos5}" = no; then
2386     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2387                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2388     AC_CHECK_LIB(krb4, krb_get_cred,,
2389                  [AC_CHECK_LIB(krb, krb_get_cred)])
2390   fi
2391
2392   if test "${with_kerberos5}" != no; then
2393     AC_CHECK_HEADERS(krb5.h,
2394       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2395                         [#include <krb5.h>])])
2396   else
2397     AC_CHECK_HEADERS(des.h,,
2398                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2399                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2400     AC_CHECK_HEADERS(krb.h,,
2401                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2402                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2403   fi
2404   AC_CHECK_HEADERS(com_err.h)
2405 fi
2406
2407 # Solaris requires -lintl if you want strerror (which calls dgettext)
2408 # to return localized messages.
2409 AC_CHECK_LIB(intl, dgettext)
2410
2411 AC_MSG_CHECKING(whether localtime caches TZ)
2412 AC_CACHE_VAL(emacs_cv_localtime_cache,
2413 [if test x$ac_cv_func_tzset = xyes; then
2414 AC_TRY_RUN([#include <time.h>
2415 extern char **environ;
2416 unset_TZ ()
2417 {
2418   char **from, **to;
2419   for (to = from = environ; (*to = *from); from++)
2420     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2421       to++;
2422 }
2423 char TZ_GMT0[] = "TZ=GMT0";
2424 char TZ_PST8[] = "TZ=PST8";
2425 main()
2426 {
2427   time_t now = time ((time_t *) 0);
2428   int hour_GMT0, hour_unset;
2429   if (putenv (TZ_GMT0) != 0)
2430     exit (1);
2431   hour_GMT0 = localtime (&now)->tm_hour;
2432   unset_TZ ();
2433   hour_unset = localtime (&now)->tm_hour;
2434   if (putenv (TZ_PST8) != 0)
2435     exit (1);
2436   if (localtime (&now)->tm_hour == hour_GMT0)
2437     exit (1);
2438   unset_TZ ();
2439   if (localtime (&now)->tm_hour != hour_unset)
2440     exit (1);
2441   exit (0);
2442 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2443 [# If we have tzset, assume the worst when cross-compiling.
2444 emacs_cv_localtime_cache=yes])
2445 else
2446         # If we lack tzset, report that localtime does not cache TZ,
2447         # since we can't invalidate the cache if we don't have tzset.
2448         emacs_cv_localtime_cache=no
2449 fi])dnl
2450 AC_MSG_RESULT($emacs_cv_localtime_cache)
2451 if test $emacs_cv_localtime_cache = yes; then
2452   AC_DEFINE(LOCALTIME_CACHE, 1,
2453             [Define to 1 if localtime caches TZ.])
2454 fi
2455
2456 if test "x$HAVE_TIMEVAL" = xyes; then
2457   AC_CHECK_FUNCS(gettimeofday)
2458   if test $ac_cv_func_gettimeofday = yes; then
2459     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2460                    emacs_cv_gettimeofday_two_arguments,
2461     [AC_TRY_COMPILE([
2462 #ifdef TIME_WITH_SYS_TIME
2463 #include <sys/time.h>
2464 #include <time.h>
2465 #else
2466 #ifdef HAVE_SYS_TIME_H
2467 #include <sys/time.h>
2468 #else
2469 #include <time.h>
2470 #endif
2471 #endif],
2472       [struct timeval time;
2473        gettimeofday (&time, 0);],
2474       emacs_cv_gettimeofday_two_arguments=yes,
2475       emacs_cv_gettimeofday_two_arguments=no)])
2476     if test $emacs_cv_gettimeofday_two_arguments = no; then
2477       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2478                 [Define to 1 if gettimeofday accepts only one argument.])
2479     fi
2480   fi
2481 fi
2482
2483 ok_so_far=yes
2484 AC_CHECK_FUNC(socket, , ok_so_far=no)
2485 if test $ok_so_far = yes; then
2486   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2487 fi
2488 if test $ok_so_far = yes; then
2489   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2490 fi
2491 if test $ok_so_far = yes; then
2492 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2493   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2494             [Define to 1 if you have inet sockets.])
2495 fi
2496
2497 AC_CHECK_HEADERS(sys/ioctl.h)
2498
2499 if test -f /usr/lpp/X11/bin/smt.exp; then
2500   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2501             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2502 fi
2503
2504 AC_MSG_CHECKING(whether system supports dynamic ptys)
2505 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2506   AC_MSG_RESULT(yes)
2507   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2508 else
2509   AC_MSG_RESULT(no)
2510 fi
2511
2512 AC_FUNC_FORK
2513
2514 dnl Adapted from Haible's version.
2515 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2516   [AC_TRY_LINK([#include <langinfo.h>],
2517     [char* cs = nl_langinfo(CODESET);],
2518     emacs_cv_langinfo_codeset=yes,
2519     emacs_cv_langinfo_codeset=no)
2520   ])
2521 if test $emacs_cv_langinfo_codeset = yes; then
2522   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2523     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2524 fi
2525
2526 AC_CHECK_TYPES(size_t)
2527
2528 AC_TYPE_MBSTATE_T
2529
2530 dnl Restrict could probably be used effectively other than in regex.c.
2531 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2532   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2533                   emacs_cv_c_restrict=yes,
2534                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2535                                   emacs_cv_c_restrict=__restrict,
2536                                   emacs_cv_c_restrict=no)])])
2537 case "$emacs_cv_c_restrict" in
2538   yes) emacs_restrict=restrict;;
2539   no) emacs_restrict="";;
2540   *) emacs_restrict="$emacs_cv_c_restrict";;
2541 esac
2542 if test "$emacs_restrict" != __restrict; then
2543   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2544     [Define to compiler's equivalent of C99 restrict keyword.
2545      Don't define if equivalent is `__restrict'.])
2546 fi
2547
2548 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2549   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2550                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2551 if test "$emacs_cv_c_restrict_arr" = yes; then
2552   AC_DEFINE(__restrict_arr, __restrict,
2553     [Define to compiler's equivalent of C99 restrict keyword in array
2554      declarations.  Define as empty for no equivalent.])
2555 fi
2556
2557 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2558 dnl how the tty code is related to POSIX and/or other versions of termios.
2559 dnl The following looks like a useful start.
2560 dnl
2561 dnl AC_SYS_POSIX_TERMIOS
2562 dnl if test $ac_cv_sys_posix_termios = yes; then
2563 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2564 dnl                                and macros for terminal control.])
2565 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2566 dnl fi
2567
2568 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2569
2570 # Set up the CFLAGS for real compilation, so we can substitute it.
2571 CFLAGS="$REAL_CFLAGS"
2572 CPPFLAGS="$REAL_CPPFLAGS"
2573
2574 #### Find out which version of Emacs this is.
2575 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2576          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2577 if test x"${version}" = x; then
2578   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2579 fi
2580 if test x"${version}" != x"$PACKAGE_VERSION"; then
2581   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
2582 fi
2583
2584 ### Specify what sort of things we'll be editing into Makefile and config.h.
2585 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2586 AC_SUBST(version)
2587 AC_SUBST(configuration)
2588 AC_SUBST(canonical)
2589 AC_SUBST(srcdir)
2590 AC_SUBST(prefix)
2591 AC_SUBST(exec_prefix)
2592 AC_SUBST(bindir)
2593 AC_SUBST(datadir)
2594 AC_SUBST(sharedstatedir)
2595 AC_SUBST(libexecdir)
2596 AC_SUBST(mandir)
2597 AC_SUBST(infodir)
2598 AC_SUBST(lispdir)
2599 AC_SUBST(locallisppath)
2600 AC_SUBST(lisppath)
2601 AC_SUBST(x_default_search_path)
2602 AC_SUBST(etcdir)
2603 AC_SUBST(archlibdir)
2604 AC_SUBST(docdir)
2605 AC_SUBST(bitmapdir)
2606 AC_SUBST(gamedir)
2607 AC_SUBST(gameuser)
2608 AC_SUBST(c_switch_system)
2609 AC_SUBST(c_switch_machine)
2610 AC_SUBST(LD_SWITCH_X_SITE)
2611 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2612 AC_SUBST(C_SWITCH_X_SITE)
2613 AC_SUBST(CFLAGS)
2614 AC_SUBST(X_TOOLKIT_TYPE)
2615 AC_SUBST(machfile)
2616 AC_SUBST(opsysfile)
2617 AC_SUBST(GETLOADAVG_LIBS)
2618 AC_SUBST(ns_appdir)
2619 AC_SUBST(ns_appbindir)
2620 AC_SUBST(ns_appresdir)
2621 AC_SUBST(ns_appsrc)
2622 AC_SUBST(GNUSTEP_MAKEFILES)
2623 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2624 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2625 AC_SUBST(GNU_OBJC_CFLAGS)
2626 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2627 AC_SUBST(OTHER_FILES)
2628
2629 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2630                    [Define to the canonical Emacs configuration name.])
2631 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2632                    [Define to the options passed to configure.])
2633 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2634                    [Define to the used machine dependent file.])
2635 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2636                    [Define to the used os dependent file.])
2637 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2638 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2639  may need to deal with X Windows.  For instance, if you've defined
2640  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2641  your loader can find on its own, you might want to add "-L/..." or
2642  something similar.])
2643 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2644                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2645                     in case it's needed (for Solaris, for example).])
2646 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2647 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2648  may need to deal with X Windows.  For instance, if you've defined
2649  HAVE_X_WINDOWS above and your X include files aren't in a place
2650  that your compiler can find on its own, you might want to add
2651  "-I/..." or something similar.])
2652 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2653                    [Define to the unexec source file name.])
2654
2655 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2656   AC_DEFINE(HAVE_X_WINDOWS, 1,
2657             [Define to 1 if you want to use the X window system.])
2658 fi
2659 if test "${USE_X_TOOLKIT}" != "none" ; then
2660   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2661   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2662     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2663   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2664     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2665   fi
2666 fi
2667 if test "${HAVE_X11}" = "yes" ; then
2668   AC_DEFINE(HAVE_X11, 1,
2669             [Define to 1 if you want to use version 11 of X windows.
2670              Otherwise, Emacs expects to use version 10.])
2671 fi
2672 if test "${HAVE_MENUS}" = "yes" ; then
2673   AC_DEFINE(HAVE_MENUS, 1,
2674             [Define to 1 if you have mouse menus.
2675              (This is automatic if you use X, but the option to specify it remains.)
2676              It is also defined with other window systems that support xmenu.c.])
2677 fi
2678 if test "${GNU_MALLOC}" = "yes" ; then
2679   AC_DEFINE(GNU_MALLOC, 1,
2680             [Define to 1 if you want to use the GNU memory allocator.])
2681 fi
2682 if test "${REL_ALLOC}" = "yes" ; then
2683   AC_DEFINE(REL_ALLOC, 1,
2684             [Define REL_ALLOC if you want to use the relocating allocator for
2685              buffer space.])
2686 fi
2687
2688
2689 AH_TOP([/* GNU Emacs site configuration template file.
2690    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2691      2006, 2007, 2008, 2009  Free Software Foundation, Inc.
2692
2693 This file is part of GNU Emacs.
2694
2695 GNU Emacs is free software: you can redistribute it and/or modify
2696 it under the terms of the GNU General Public License as published by
2697 the Free Software Foundation, either version 3 of the License, or
2698 (at your option) any later version.
2699
2700 GNU Emacs is distributed in the hope that it will be useful,
2701 but WITHOUT ANY WARRANTY; without even the implied warranty of
2702 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2703 GNU General Public License for more details.
2704
2705 You should have received a copy of the GNU General Public License
2706 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2707
2708
2709 /* No code in Emacs #includes config.h twice, but some bits of code
2710    intended to work with other packages as well (like gmalloc.c)
2711    think they can include it as many times as they like.  */
2712 #ifndef EMACS_CONFIG_H
2713 #define EMACS_CONFIG_H
2714 ])dnl
2715
2716 AH_BOTTOM([
2717 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2718 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2719 #define HAVE_WINDOW_SYSTEM
2720 #define HAVE_MOUSE
2721 #endif
2722
2723 /* Define AMPERSAND_FULL_NAME if you use the convention
2724    that & in the full name stands for the login id.  */
2725 /* Turned on June 1996 supposing nobody will mind it.  */
2726 #define AMPERSAND_FULL_NAME
2727
2728 /* Define HAVE_SOUND if we have sound support.  We know it works
2729    and compiles only on the specified platforms.   For others,
2730    it probably doesn't make sense to try.  */
2731
2732 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2733 #ifdef HAVE_MACHINE_SOUNDCARD_H
2734 #define HAVE_SOUND 1
2735 #endif
2736 #ifdef HAVE_SYS_SOUNDCARD_H
2737 #define HAVE_SOUND 1
2738 #endif
2739 #ifdef HAVE_SOUNDCARD_H
2740 #define HAVE_SOUND 1
2741 #endif
2742 #ifdef HAVE_ALSA
2743 #define HAVE_SOUND 1
2744 #endif
2745 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2746
2747 /* If using GNU, then support inline function declarations. */
2748 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2749    generally, because even if non-gcc compilers accept `inline', they
2750    may reject `extern inline'.  */
2751 #if defined (__GNUC__) && defined (OPTIMIZE)
2752 #define INLINE __inline__
2753 #else
2754 #define INLINE
2755 #endif
2756
2757 /* `subprocesses' should be defined if you want to
2758    have code for asynchronous subprocesses
2759    (as used in M-x compile and M-x shell).
2760    Only MSDOS does not support this (it overrides
2761    this in its config_opsysfile below).  */
2762
2763 #define subprocesses
2764
2765 /* Include the os and machine dependent files.  */
2766 #include config_opsysfile
2767 #include config_machfile
2768
2769 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2770   (There is probably a better place to do this, but right now the Cocoa
2771    side does this in s/darwin.h and we cannot
2772    parallel this exactly since GNUstep is multi-OS. */
2773 #ifdef HAVE_NS
2774 # ifdef NS_IMPL_GNUSTEP
2775 /* See also .m.o rule in Makefile.in */
2776 /* FIXME: are all these flags really needed?  Document here why.  */
2777 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2778 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2779 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2780 #  define SYSTEM_PURESIZE_EXTRA 30000
2781 # endif /* NS_IMPL_GNUSTEP */
2782 #endif /* HAVE_NS */
2783
2784 /* SIGTYPE is the macro we actually use.  */
2785 #ifndef SIGTYPE
2786 #define SIGTYPE RETSIGTYPE
2787 #endif
2788
2789 #ifdef emacs /* Don't do this for lib-src.  */
2790 /* Tell regex.c to use a type compatible with Emacs.  */
2791 #define RE_TRANSLATE_TYPE Lisp_Object
2792 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2793 #ifdef make_number
2794 /* If make_number is a macro, use it.  */
2795 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2796 #else
2797 /* If make_number is a function, avoid it.  */
2798 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2799 #endif
2800 #endif
2801
2802 /* Avoid link-time collision with system mktime if we will use our own.  */
2803 #if ! HAVE_MKTIME || BROKEN_MKTIME
2804 #define mktime emacs_mktime
2805 #endif
2806
2807 #define my_strftime nstrftime   /* for strftime.c */
2808
2809 /* The rest of the code currently tests the CPP symbol BSTRING.
2810    Override any claims made by the system-description files.
2811    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2812 #undef BSTRING
2813 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2814 #define BSTRING
2815 #endif
2816
2817 /* Some of the files of Emacs which are intended for use with other
2818    programs assume that if you have a config.h file, you must declare
2819    the type of getenv.
2820
2821    This declaration shouldn't appear when alloca.s or Makefile.in
2822    includes config.h.  */
2823 #ifndef NOT_C_CODE
2824 extern char *getenv ();
2825 #endif
2826
2827 /* These default definitions are good for almost all machines.
2828    The exceptions override them in m/MACHINE.h.  */
2829
2830 #ifndef BITS_PER_CHAR
2831 #define BITS_PER_CHAR 8
2832 #endif
2833
2834 #ifndef BITS_PER_SHORT
2835 #define BITS_PER_SHORT 16
2836 #endif
2837
2838 /* Note that lisp.h uses this in a preprocessor conditional, so it
2839    would not work to use sizeof.  That being so, we do all of them
2840    without sizeof, for uniformity's sake.  */
2841 #ifndef BITS_PER_INT
2842 #define BITS_PER_INT 32
2843 #endif
2844
2845 #ifndef BITS_PER_LONG
2846 #ifdef _LP64
2847 #define BITS_PER_LONG 64
2848 #else
2849 #define BITS_PER_LONG 32
2850 #endif
2851 #endif
2852
2853 /* Define if the compiler supports function prototypes.  It may do so
2854    but not define __STDC__ (e.g. DEC C by default) or may define it as
2855    zero.  */
2856 #undef PROTOTYPES
2857 /* For mktime.c:  */
2858 #ifndef __P
2859 # if defined PROTOTYPES
2860 #  define __P(args) args
2861 # else
2862 #  define __P(args) ()
2863 # endif  /* GCC.  */
2864 #endif /* __P */
2865
2866 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2867 #ifndef NOT_C_CODE
2868 #ifdef HAVE_STRING_H
2869 #include "string.h"
2870 #endif
2871 #ifdef HAVE_STRINGS_H
2872 #include "strings.h"  /* May be needed for bcopy & al. */
2873 #endif
2874 #ifdef HAVE_STDLIB_H
2875 #include <stdlib.h>
2876 #endif
2877 #ifndef __GNUC__
2878 # ifdef HAVE_ALLOCA_H
2879 #  include <alloca.h>
2880 # else /* AIX files deal with #pragma.  */
2881 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2882 char *alloca ();
2883 #  endif
2884 # endif /* HAVE_ALLOCA_H */
2885 #endif /* __GNUC__ */
2886 #ifndef HAVE_SIZE_T
2887 typedef unsigned size_t;
2888 #endif
2889 #endif /* NOT_C_CODE */
2890
2891 /* Define HAVE_X_I18N if we have usable i18n support.  */
2892
2893 #ifdef HAVE_X11R6
2894 #define HAVE_X_I18N
2895 #elif !defined X11R5_INHIBIT_I18N
2896 #define HAVE_X_I18N
2897 #endif
2898
2899 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2900
2901 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2902 #define HAVE_X11R6_XIM
2903 #endif
2904
2905 #if defined __GNUC__ && (__GNUC__ > 2 \
2906                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2907 #define NO_RETURN       __attribute__ ((__noreturn__))
2908 #else
2909 #define NO_RETURN       /* nothing */
2910 #endif
2911
2912 /* These won't be used automatically yet.  We also need to know, at least,
2913    that the stack is continuous.  */
2914 #ifdef __GNUC__
2915 #  ifndef GC_SETJMP_WORKS
2916   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2917      see NON_SAVING_SETJMP in the target descriptions.  */
2918   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2919      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2920      Fixme: Deal with SVR3.  */
2921 #    define GC_SETJMP_WORKS 1
2922 #  endif
2923 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2924 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2925 #  endif
2926 #endif
2927
2928 #ifndef HAVE_BCOPY
2929 #define bcopy(a,b,s) memcpy (b,a,s)
2930 #endif
2931 #ifndef HAVE_BZERO
2932 #define bzero(a,s) memset (a,0,s)
2933 #endif
2934 #ifndef HAVE_BCMP
2935 #define BCMP memcmp
2936 #endif
2937
2938 #endif /* EMACS_CONFIG_H */
2939
2940 /*
2941 Local Variables:
2942 mode: c
2943 End:
2944 */
2945 ])dnl
2946
2947 #### Report on what we decided to do.
2948 #### Report GTK as a toolkit, even if it doesn't use Xt.
2949 #### It makes printing result more understandable as using GTK sets
2950 #### toolkit_scroll_bars to yes by default.
2951 if test "${HAVE_GTK}" = "yes"; then
2952   USE_X_TOOLKIT=GTK
2953 fi
2954
2955 echo "
2956 Configured for \`${canonical}'.
2957
2958   Where should the build process find the source code?    ${srcdir}
2959   What operating system and machine description files should Emacs use?
2960         \`${opsysfile}' and \`${machfile}'
2961   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2962   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2963   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2964   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2965   What window system should Emacs use?                    ${window_system}
2966   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2967
2968 if test -n "${x_includes}"; then
2969 echo "  Where do we find X Windows header files?                ${x_includes}"
2970 else
2971 echo "  Where do we find X Windows header files?                Standard dirs"
2972 fi
2973 if test -n "${x_libraries}"; then
2974 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2975 else
2976 echo "  Where do we find X Windows libraries?                   Standard dirs"
2977 fi
2978
2979 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2980 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2981 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2982 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2983 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2984 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2985 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2986 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2987 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2988
2989 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2990 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2991 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2992 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2993
2994 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
2995 echo
2996
2997 if test $USE_XASSERTS = yes; then
2998    echo "  Compiling with asserts turned on."
2999    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3000 fi
3001
3002 echo
3003
3004 if test "$USE_X_TOOLKIT" = GTK; then
3005   case "$canonical" in
3006   *cygwin*)
3007     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
3008   will probably get a crash on startup.  If this happens, please use another
3009   toolkit for Emacs.  See etc/PROBLEMS for more information."
3010   ;;
3011   esac
3012 fi
3013
3014 if test "$HAVE_NS" = "yes"; then
3015    echo
3016    echo "You must run \"make install\" in order to test the built application.
3017 The installed application will go to nextstep/Emacs.app and can be
3018 run or moved from there."
3019    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3020       echo "The application will be fully self-contained."
3021     else
3022       echo "The lisp resources for the application will be installed under ${prefix}.
3023 You may need to run \"make install\" with sudo.  The application will fail
3024 to run if these resources are not installed."
3025    fi
3026    echo
3027 fi
3028
3029 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3030   echo "D-Bus integration has been tested for GNU/Linux only."
3031   echo
3032 fi
3033
3034
3035 # Remove any trailing slashes in these variables.
3036 [test "${prefix}" != NONE &&
3037   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3038 test "${exec_prefix}" != NONE &&
3039   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3040
3041 # Now get this: Some word that is part of the ${srcdir} directory name
3042 # or the ${configuration} value might, just might, happen to be an
3043 # identifier like `sun4' or `i386' or something, and be predefined by
3044 # the C preprocessor to some helpful value like 1, or maybe the empty
3045 # string.  Needless to say consequent macro substitutions are less
3046 # than conducive to the makefile finding the correct directory.
3047 [cpp_undefs="`echo $srcdir $configuration $canonical |
3048   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3049   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3050
3051 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3052 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3053 ## from Makefile.c can correctly provide the arg `-traditional' to the
3054 ## C preprocessor.
3055
3056 AC_EGREP_CPP(yes..yes,
3057         [yes..yes],
3058         CPP_NEED_TRADITIONAL=no,
3059         CPP_NEED_TRADITIONAL=yes)
3060
3061 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3062         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3063         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3064         lwlib/Makefile lisp/Makefile leim/Makefile, [
3065
3066 ### Make the necessary directories, if they don't exist.
3067 for dir in etc lisp ; do
3068   test -d ${dir} || mkdir ${dir}
3069 done
3070
3071 # Build src/Makefile from ${srcdir}/src/Makefile.c
3072 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3073 # This must be done after src/config.h is built, since we rely on that file.
3074
3075 echo creating src/epaths.h
3076 ${MAKE-make} epaths-force
3077
3078 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3079 # `..' to `. .'  unless invoked with -traditional
3080
3081 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3082   CPPFLAGS="$CPPFLAGS -traditional"
3083 fi
3084
3085 echo creating lib-src/Makefile
3086 ( cd lib-src
3087   rm -f junk.c junk1.c junk2.c
3088   sed -e '/start of cpp stuff/q' \
3089       < Makefile.c > junk1.c
3090   sed -e '1,/start of cpp stuff/d'\
3091       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3092       < Makefile.c > junk.c
3093   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3094       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3095   cat junk1.c junk2.c > Makefile.new
3096   rm -f junk.c junk1.c junk2.c
3097   chmod 444 Makefile.new
3098   mv -f Makefile.new Makefile
3099 )
3100
3101 echo creating src/Makefile
3102 ( cd src
3103   rm -f junk.c junk1.c junk2.c
3104   sed -e '/start of cpp stuff/q' \
3105       < Makefile.c > junk1.c
3106   sed -e '1,/start of cpp stuff/d'\
3107       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3108       < Makefile.c > junk.c
3109   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3110       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3111   cat junk1.c junk2.c > Makefile.new
3112   rm -f junk.c junk1.c junk2.c
3113   chmod 444 Makefile.new
3114   mv -f Makefile.new Makefile
3115 )
3116
3117 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3118   echo creating src/.gdbinit
3119   echo source $srcdir/src/.gdbinit > src/.gdbinit
3120 fi
3121
3122 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3123
3124 m4_if(dnl       Do not change this comment
3125    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3126 )dnl