configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 dnl FIXME hesiod support may not be present, so it seems like an error
  95 dnl to define, or at least use, this unconditionally.
  96 if test "$with_hesiod" != no; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 101 if test "$with_mmdf" != no; then
 102    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 106 if test "$with_mail_unlink" != no; then
 107    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 108 fi
 109
 110 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 111     [string giving default POP mail host])],
 112     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 113
 114 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 115
 116 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 117 if test "$with_sync_input" = yes; then
 118    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 119 fi
 120
 121 dnl FIXME currently it is not the last.
 122 dnl This should be the last --with option, because --with-x is
 123 dnl added later on when we find the path of X, and it's best to
 124 dnl keep them together visually.
 125 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 126  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 127 [         case "${withval}" in
 128             y | ye | yes )      val=gtk ;;
 129             n | no )            val=no  ;;
 130             l | lu | luc | luci | lucid )       val=lucid ;;
 131             a | at | ath | athe | athen | athena )      val=athena ;;
 132             m | mo | mot | moti | motif )       val=motif ;;
 133             g | gt | gtk  )     val=gtk ;;
 134             * )
 135 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 136 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 137 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 138             ;;
 139           esac
 140           with_x_toolkit=$val
 141 ])
 142
 143 dnl _ON results in a '--without' option in the --help output, so
 144 dnl the help text should refer to "don't compile", etc.
 145 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 146 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 147 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 148 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 149 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 150 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 151
 152 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 153 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 154 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 155
 156 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 157 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 158 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 159 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 160
 161 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 162 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 163 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 164
 165 ## For the times when you want to build Emacs but don't have
 166 ## a suitable makeinfo, and can live without the manuals.
 167 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 168 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 169
 170 dnl Can remove these in Emacs 24.
 171 AC_ARG_WITH([gtk],,
 172   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 173 specify a toolkit.])],,)
 174
 175 AC_ARG_WITH([gcc],,
 176   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 177 variable to specify a compiler.])],,)
 178
 179 AC_ARG_WITH([pkg-config-prog],dnl
 180 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 181                   [path to pkg-config for finding GTK and librsvg])])
 182 if test "X${with_pkg_config_prog}" != X; then
 183    if test "${with_pkg_config_prog}" != yes; then
 184       PKG_CONFIG="${with_pkg_config_prog}"
 185    fi
 186 fi
 187
 188 AC_ARG_WITH([gnustep-conf],dnl
 189 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 190 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 191   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 192 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 193      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 194
 195 AC_ARG_ENABLE(ns-self-contained,
 196 [AS_HELP_STRING([--disable-ns-self-contained],
 197                 [disable self contained build under NeXTstep])],
 198    EN_NS_SELF_CONTAINED=$enableval,
 199    EN_NS_SELF_CONTAINED=yes)
 200
 201 AC_ARG_ENABLE(asserts,
 202 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 203       USE_XASSERTS=$enableval,
 204       USE_XASSERTS=no)
 205
 206 AC_ARG_ENABLE(maintainer-mode,
 207 [AS_HELP_STRING([--enable-maintainer-mode],
 208                 [enable make rules and dependencies not useful (and sometimes
 209                  confusing) to the casual installer])],
 210       USE_MAINTAINER_MODE=$enableval,
 211       USE_MAINTAINER_MODE=no)
 212 if test $USE_MAINTAINER_MODE = yes; then
 213   MAINT=
 214 else
 215   MAINT=#
 216 fi
 217 AC_SUBST(MAINT)
 218
 219 AC_ARG_ENABLE(locallisppath,
 220 [AS_HELP_STRING([--enable-locallisppath=PATH],
 221                 [directories Emacs should search for lisp files specific
 222                  to this site])],
 223 if test "${enableval}" = "no"; then
 224   locallisppath=
 225 elif test "${enableval}" != "yes"; then
 226   locallisppath=${enableval}
 227 fi)
 228
 229 AC_ARG_ENABLE(checking,
 230 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 231                 [enable expensive run-time checks.  With LIST,
 232                  enable only specific categories of checks.
 233                  Categories are: all,yes,no.
 234                  Flags are: stringbytes, stringoverrun, stringfreelist,
 235                  xmallocoverrun, conslist])],
 236 [ac_checking_flags="${enableval}"],[])
 237 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 238 for check in $ac_checking_flags
 239 do
 240         case $check in
 241         # these set all the flags to specific states
 242         yes)            ac_enable_checking=1 ;;
 243         no)             ac_enable_checking= ;
 244                         ac_gc_check_stringbytes= ;
 245                         ac_gc_check_string_overrun= ;
 246                         ac_gc_check_string_free_list= ;
 247                         ac_xmalloc_overrun= ;
 248                         ac_gc_check_cons_list= ;;
 249         all)            ac_enable_checking=1 ;
 250                         ac_gc_check_stringbytes=1 ;
 251                         ac_gc_check_string_overrun=1 ;
 252                         ac_gc_check_string_free_list=1 ;
 253                         ac_xmalloc_overrun=1 ;
 254                         ac_gc_check_cons_list=1 ;;
 255         # these enable particular checks
 256         stringbytes)    ac_gc_check_stringbytes=1 ;;
 257         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 258         stringfreelist) ac_gc_check_string_free_list=1 ;;
 259         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 260         conslist)       ac_gc_check_cons_list=1 ;;
 261         *)      AC_MSG_ERROR(unknown check category $check) ;;
 262         esac
 263 done
 264 IFS="$ac_save_IFS"
 265
 266 if test x$ac_enable_checking != x ; then
 267   AC_DEFINE(ENABLE_CHECKING, 1,
 268 [Enable expensive run-time checking of data types?])
 269 fi
 270 if test x$ac_gc_check_stringbytes != x ; then
 271   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 272 [Define this temporarily to hunt a bug.  If defined, the size of
 273    strings is redundantly recorded in sdata structures so that it can
 274    be compared to the sizes recorded in Lisp strings.])
 275 fi
 276 if test x$ac_gc_check_stringoverrun != x ; then
 277   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 278 [Define this to check for short string overrun.])
 279 fi
 280 if test x$ac_gc_check_string_free_list != x ; then
 281   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 282 [Define this to check the string free list.])
 283 fi
 284 if test x$ac_xmalloc_overrun != x ; then
 285   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 286 [Define this to check for malloc buffer overrun.])
 287 fi
 288 if test x$ac_gc_check_cons_list != x ; then
 289   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 290 [Define this to check for errors in cons list.])
 291 fi
 292
 293 AC_ARG_ENABLE(profiling,
 294 [AS_HELP_STRING([--enable-profiling],
 295                 [build emacs with profiling support.
 296                  This might not work on all platforms])],
 297 [ac_enable_profiling="${enableval}"],[])
 298 if test x$ac_enable_profiling != x ; then
 299    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 300    PROFILING_LDFLAGS="-pg"
 301 else
 302    PROFILING_CFLAGS=
 303    PROFILING_LDFLAGS=
 304 fi
 305
 306 AC_ARG_ENABLE(autodepend,
 307 [AS_HELP_STRING([--enable-autodepend],
 308                 [automatically generate dependencies to .h-files.
 309                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 310                  found])],
 311 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 312
 313 #### Make srcdir absolute, if it isn't already.  It's important to
 314 #### avoid running the path through pwd unnecessarily, since pwd can
 315 #### give you automounter prefixes, which can go away.  We do all this
 316 #### so Emacs can find its files when run uninstalled.
 317 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 318 unset CDPATH
 319 case "${srcdir}" in
 320   /* ) ;;
 321   . )
 322     ## We may be able to use the $PWD environment variable to make this
 323     ## absolute.  But sometimes PWD is inaccurate.
 324     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 325     ## but that tested only for a well-formed and valid PWD,
 326     ## it did not object when PWD was well-formed and valid but just wrong.
 327     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 328     then
 329       srcdir="$PWD"
 330     else
 331       srcdir="`(cd ${srcdir}; pwd)`"
 332     fi
 333   ;;
 334   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 335 esac
 336
 337 #### Check if the source directory already has a configured system in it.
 338 if test `pwd` != `(cd ${srcdir} && pwd)` \
 339    && test -f "${srcdir}/src/config.h" ; then
 340   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 341    as a build directory right now; it has been configured in its own
 342    right.  To configure in another directory as well, you MUST
 343    use GNU make.  If you do not have GNU make, then you must
 344    now do `make distclean' in ${srcdir},
 345    and then run $0 again.]])
 346 fi
 347
 348 #### Given the configuration name, set machfile and opsysfile to the
 349 #### names of the m/*.h and s/*.h files we should use.
 350
 351 ### Canonicalize the configuration name.
 352
 353 AC_CANONICAL_HOST
 354 canonical=$host
 355 configuration=${host_alias-${build_alias-$host}}
 356
 357 dnl This used to use changequote, but, apart from `changequote is evil'
 358 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 359 dnl the great gob of text.  Thus it's not processed for possible expansion.
 360 dnl Just make sure the brackets remain balanced.
 361 dnl
 362 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 363 dnl indicated by comments.
 364 dnl quotation begins
 365 [
 366
 367 ### If you add support for a new configuration, add code to this
 368 ### switch statement to recognize your configuration name and select
 369 ### the appropriate operating system and machine description files.
 370
 371 ### You would hope that you could choose an m/*.h file pretty much
 372 ### based on the machine portion of the configuration name, and an s-
 373 ### file based on the operating system portion.  However, it turns out
 374 ### that each m/*.h file is pretty manufacturer-specific - for
 375 ### example mips.h is MIPS
 376 ### So we basically have to have a special case for each
 377 ### configuration name.
 378 ###
 379 ### As far as handling version numbers on operating systems is
 380 ### concerned, make sure things will fail in a fixable way.  If
 381 ### /etc/MACHINES doesn't say anything about version numbers, be
 382 ### prepared to handle anything reasonably.  If version numbers
 383 ### matter, be sure /etc/MACHINES says something about it.
 384 ###
 385 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 386 ### "System V Release 4"; he writes, "The old convention encouraged
 387 ### confusion between `system' and `release' levels'."
 388
 389 machine='' opsys='' unported=no
 390 case "${canonical}" in
 391
 392   ## FreeBSD ports
 393   *-*-freebsd* )
 394     opsys=freebsd
 395     case "${canonical}" in
 396       alpha*-*-freebsd*)        machine=alpha ;;
 397       arm*-*-freebsd*)          machine=arm ;;
 398       ia64-*-freebsd*)          machine=ia64 ;;
 399       sparc-*-freebsd*)         machine=sparc ;;
 400       sparc64-*-freebsd*)       machine=sparc ;;
 401       powerpc-*-freebsd*)       machine=macppc ;;
 402       i[3456]86-*-freebsd*)     machine=intel386 ;;
 403       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 404     esac
 405   ;;
 406
 407   ## FreeBSD kernel + glibc based userland
 408   *-*-kfreebsd*gnu* )
 409     opsys=gnu-kfreebsd
 410     case "${canonical}" in
 411       alpha*-*-kfreebsd*)       machine=alpha ;;
 412       ia64-*-kfreebsd*)         machine=ia64 ;;
 413       sparc-*-kfreebsd*)        machine=sparc ;;
 414       sparc64-*-kfreebsd*)      machine=sparc ;;
 415       powerpc-*-kfreebsd*)      machine=macppc ;;
 416       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 417       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 418     esac
 419   ;;
 420
 421   ## NetBSD ports
 422   *-*-netbsd* )
 423     opsys=netbsd
 424     if test -f /usr/lib/crti.o; then]
 425 dnl The close and open brackets here are because this section is quoted --
 426 dnl see the `changequote' comment above.
 427       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 428 [   fi
 429
 430     case "${canonical}" in
 431       alpha*-*-netbsd*) machine=alpha ;;
 432       i[3456]86-*-netbsd*) machine=intel386 ;;
 433       mips-*-netbsd*)   machine=mips ;;
 434       mipsel-*-netbsd*) machine=mips ;;
 435       mipseb-*-netbsd*) machine=mips ;;
 436       powerpc-*-netbsd*) machine=macppc ;;
 437       sparc*-*-netbsd*) machine=sparc ;;
 438       vax-*-netbsd*)    machine=vax ;;
 439       arm-*-netbsd*)    machine=arm ;;
 440       x86_64-*-netbsd*) machine=amdx86-64 ;;
 441       hppa-*-netbsd*)   machine=hp800 ;;
 442       m68k-*-netbsd*)   machine=m68k ;;
 443     esac
 444   ;;
 445
 446   ## OpenBSD ports
 447   *-*-openbsd* )
 448     opsys=openbsd
 449     case "${canonical}" in
 450       alpha*-*-openbsd*)        machine=alpha ;;
 451       arm-*-openbsd*)          machine=arm ;;
 452       i386-*-openbsd*)         machine=intel386 ;;
 453       powerpc-*-openbsd*)      machine=macppc ;;
 454       sparc*-*-openbsd*)       machine=sparc ;;
 455       vax-*-openbsd*)          machine=vax ;;
 456       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 457       hppa-*-openbsd*)         machine=hp800 ;;
 458     esac
 459   ;;
 460
 461   ## LynxOS ports
 462   *-*-lynxos* )
 463     opsys=lynxos
 464     case "${canonical}" in
 465       i[3456]86-*-lynxos*) machine=intel386 ;;
 466       powerpc-*-lynxos*) machine=powerpc ;;
 467     esac
 468   ;;
 469
 470   alpha*-*-linux-gnu* )
 471     machine=alpha opsys=gnu-linux
 472   ;;
 473
 474   arm*-*-linux-gnu* )
 475     machine=arm opsys=gnu-linux
 476   ;;
 477
 478   ## Apple Darwin / Mac OS X
 479   *-apple-darwin* )
 480     case "${canonical}" in
 481       i[3456]86-* )  machine=intel386 ;;
 482       powerpc-* )    machine=macppc ;;
 483       x86_64-* )     machine=amdx86-64 ;;
 484       * )            unported=yes ;;
 485     esac
 486     opsys=darwin
 487     # Define CPP as follows to make autoconf work correctly.
 488     CPP="${CC-cc} -E -no-cpp-precomp"
 489     # Use fink packages if available.
 490     if test -d /sw/include && test -d /sw/lib; then
 491       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 492       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 493       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 494     fi
 495   ;;
 496
 497   ## HP 9000 series 700 and 800, running HP/UX
 498   hppa*-hp-hpux10.2* )
 499     machine=hp800 opsys=hpux10-20
 500   ;;
 501   hppa*-hp-hpux1[1-9]* )
 502     machine=hp800 opsys=hpux11
 503     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 504   ;;
 505
 506   hppa*-*-linux-gnu* )
 507     machine=hp800 opsys=gnu-linux
 508   ;;
 509
 510   ## IBM machines
 511   s390-*-linux-gnu* )
 512     machine=ibms390 opsys=gnu-linux
 513   ;;
 514   s390x-*-linux-gnu* )
 515     machine=ibms390x opsys=gnu-linux
 516   ;;
 517   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 518     machine=ibmrs6000 opsys=aix4-2
 519   ;;
 520   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 521     machine=ibmrs6000 opsys=aix4-2
 522   ;;
 523   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 524     machine=ibmrs6000 opsys=aix4-2
 525   ;;
 526   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 527     machine=ibmrs6000 opsys=aix4-2
 528   ;;
 529
 530   ## Macintosh PowerPC
 531   powerpc*-*-linux-gnu* )
 532     machine=macppc opsys=gnu-linux
 533   ;;
 534
 535   ## Silicon Graphics machines
 536   ## Iris 4D
 537   mips-sgi-irix6.5 )
 538     machine=iris4d opsys=irix6-5
 539     # Without defining _LANGUAGE_C, things get masked out in the headers
 540     # so that, for instance, grepping for `free' in stdlib.h fails and
 541     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 542     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 543     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 544   ;;
 545
 546   ## Suns
 547   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 548     machine=sparc opsys=gnu-linux
 549   ;;
 550
 551   *-sun-solaris* \
 552     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 553     | x86_64-*-solaris2*    | x86_64-*-sunos5*    \
 554     | powerpc*-*-solaris2*  | rs6000-*-solaris2*)
 555     case "${canonical}" in
 556       i[3456]86-*-* )     machine=intel386 ;;
 557       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 558       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 559       sparc* )          machine=sparc ;;
 560       * )               unported=yes ;;
 561     esac
 562     case "${canonical}" in
 563       *-sunos5.3* | *-solaris2.3* )
 564                 opsys=sol2-3
 565                 NON_GNU_CPP=/usr/ccs/lib/cpp
 566                 ;;
 567       *-sunos5.4* | *-solaris2.4* )
 568                 opsys=sol2-4
 569                 NON_GNU_CPP=/usr/ccs/lib/cpp
 570                 RANLIB="ar -ts"
 571                 ;;
 572       *-sunos5.5* | *-solaris2.5* )
 573                 opsys=sol2-5
 574                 NON_GNU_CPP=/usr/ccs/lib/cpp
 575                 RANLIB="ar -ts"
 576                 ;;
 577       *-sunos5.6* | *-solaris2.6* )
 578                 opsys=sol2-6
 579                 NON_GNU_CPP=/usr/ccs/lib/cpp
 580                 RANLIB="ar -ts"
 581                 ;;
 582       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 583                 opsys=sol2-6
 584                 emacs_check_sunpro_c=yes
 585                 NON_GNU_CPP=/usr/ccs/lib/cpp
 586                 ;;
 587       *-sunos5* | *-solaris* )
 588                 opsys=sol2-10
 589                 emacs_check_sunpro_c=yes
 590                 NON_GNU_CPP=/usr/ccs/lib/cpp
 591                 ;;
 592     esac
 593     ## Watch out for a compiler that we know will not work.
 594     case "${canonical}" in
 595      *-solaris* | *-sunos5* )
 596                 if [ "x$CC" = x/usr/ucb/cc ]; then
 597                   ## /usr/ucb/cc doesn't work;
 598                   ## we should find some other compiler that does work.
 599                   unset CC
 600                 fi
 601                 ;;
 602       *) ;;
 603     esac
 604   ;;
 605
 606   ## IA-64
 607   ia64*-*-linux* )
 608     machine=ia64 opsys=gnu-linux
 609   ;;
 610
 611   ## Intel 386 machines where we don't care about the manufacturer
 612   i[3456]86-*-* )
 613     machine=intel386
 614     case "${canonical}" in
 615       *-cygwin )                opsys=cygwin ;;
 616       *-darwin* )               opsys=darwin
 617                                 CPP="${CC-cc} -E -no-cpp-precomp"
 618                                 ;;
 619       *-linux-gnu* )            opsys=gnu-linux ;;
 620       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 621       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 622       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 623       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 624     esac
 625   ;;
 626
 627   ## m68k Linux-based GNU system
 628   m68k-*-linux-gnu* )
 629     machine=m68k opsys=gnu-linux
 630   ;;
 631
 632   ## Mips Linux-based GNU system
 633   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 634     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 635     machine=mips opsys=gnu-linux
 636   ;;
 637
 638   ## AMD x86-64 Linux-based GNU system
 639   x86_64-*-linux-gnu* )
 640     machine=amdx86-64 opsys=gnu-linux
 641   ;;
 642
 643   ## Tensilica Xtensa Linux-based GNU system
 644   xtensa*-*-linux-gnu* )
 645     machine=xtensa opsys=gnu-linux
 646     ;;
 647
 648   ## SuperH Linux-based GNU system
 649   sh[34]*-*-linux-gnu* )
 650     machine=sh3 opsys=gnu-linux
 651   ;;
 652
 653   * )
 654     unported=yes
 655   ;;
 656 esac
 657
 658 ### If the code above didn't choose an operating system, just choose
 659 ### an operating system based on the configuration name.  You really
 660 ### only want to use this when you have no idea what the right
 661 ### operating system is; if you know what operating systems a machine
 662 ### runs, it's cleaner to make it explicit in the case statement
 663 ### above.
 664 if test x"${opsys}" = x; then
 665   case "${canonical}" in
 666     *-gnu* )                            opsys=gnu ;;
 667     *-sysv4.2uw* )                      opsys=unixware ;;
 668     *-sysv5uw* )                        opsys=unixware ;;
 669     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 670     *-sysv4.1* | *-sysvr4.1* )
 671         NON_GNU_CPP=/usr/lib/cpp
 672         opsys=usg5-4 ;;
 673     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 674         if [ x$NON_GNU_CPP = x ]; then
 675           if [ -f /usr/ccs/lib/cpp ]; then
 676             NON_GNU_CPP=/usr/ccs/lib/cpp
 677           else
 678             NON_GNU_CPP=/lib/cpp
 679           fi
 680         fi
 681         opsys=usg5-4-2 ;;
 682     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 683     * )
 684       unported=yes
 685     ;;
 686   esac
 687 fi
 688
 689 ]
 690 dnl quotation ends
 691
 692 if test $unported = yes; then
 693   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 694 Check `etc/MACHINES' for recognized configuration names.])
 695 fi
 696
 697 machfile="m/${machine}.h"
 698 opsysfile="s/${opsys}.h"
 699
 700
 701 #### Choose a compiler.
 702 test -n "$CC" && cc_specified=yes
 703
 704 # Save the value of CFLAGS that the user specified.
 705 SPECIFIED_CFLAGS="$CFLAGS"
 706
 707 dnl Sets GCC=yes if using gcc.
 708 AC_PROG_CC
 709
 710 # On Suns, sometimes $CPP names a directory.
 711 if test -n "$CPP" && test -d "$CPP"; then
 712   CPP=
 713 fi
 714
 715 ## If not using gcc, and on Solaris, and no CPP specified, see if
 716 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 717 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 718  test x"$CPP" = x; then
 719   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 720   AC_CACHE_VAL(emacs_cv_sunpro_c,
 721   [AC_TRY_LINK([],
 722 [#ifndef __SUNPRO_C
 723 fail;
 724 #endif
 725 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 726   AC_MSG_RESULT($emacs_cv_sunpro_c)
 727
 728   if test x"$emacs_cv_sunpro_c" = xyes; then
 729     NON_GNU_CPP="$CC -E -Xs"
 730   fi
 731 fi
 732
 733 #### Some systems specify a CPP to use unless we are using GCC.
 734 #### Now that we know whether we are using GCC, we can decide whether
 735 #### to use that one.
 736 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 737 then
 738   CPP="$NON_GNU_CPP"
 739 fi
 740
 741 #### Some systems specify a CC to use unless we are using GCC.
 742 #### Now that we know whether we are using GCC, we can decide whether
 743 #### to use that one.
 744 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 745   test x$cc_specified != xyes
 746 then
 747   CC="$NON_GNU_CC"
 748 fi
 749
 750 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 751 then
 752   CC="$CC $GCC_TEST_OPTIONS"
 753 fi
 754
 755 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 756 then
 757   CC="$CC $NON_GCC_TEST_OPTIONS"
 758 fi
 759
 760 dnl checks for Unix variants
 761 AC_USE_SYSTEM_EXTENSIONS
 762
 763 ### Use -Wno-pointer-sign if the compiler supports it
 764 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 765 SAVE_CFLAGS="$CFLAGS"
 766 CFLAGS="$CFLAGS -Wno-pointer-sign"
 767 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 768 if test $has_option = yes; then
 769    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 770 fi
 771 AC_MSG_RESULT($has_option)
 772 CFLAGS="$SAVE_CFLAGS"
 773 unset has_option
 774 unset SAVE_CFLAGS
 775
 776 ### Use -Wdeclaration-after-statement if the compiler supports it
 777 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 778 SAVE_CFLAGS="$CFLAGS"
 779 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 780 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 781 if test $has_option = yes; then
 782    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 783 fi
 784 AC_MSG_RESULT($has_option)
 785 CFLAGS="$SAVE_CFLAGS"
 786 unset has_option
 787 unset SAVE_CFLAGS
 788
 789 #### Some other nice autoconf tests.
 790
 791 dnl checks for programs
 792 AC_PROG_LN_S
 793 AC_PROG_CPP
 794 AC_PROG_INSTALL
 795 if test "x$RANLIB" = x; then
 796   AC_PROG_RANLIB
 797 fi
 798 AC_PATH_PROG(INSTALL_INFO, install-info)
 799 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 800 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 801 dnl Don't use GZIP, which is used by gzip for additional parameters.
 802 AC_PATH_PROG(GZIP_PROG, gzip)
 803
 804
 805 ## Need makeinfo >= 4.6 (?) to build the manuals.
 806 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 807 dnl By this stage, configure has already checked for egrep and set EGREP,
 808 dnl or exited with an error if no egrep was found.
 809 if test "$MAKEINFO" != "no" && \
 810   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 811    MAKEINFO=no
 812 fi
 813
 814 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 815 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 816 ## therefore in the category of "special tools" not normally required, which
 817 ## configure does not have to check for (eg autoconf itself).
 818 ## In a Bazaar checkout on the other hand, the manuals are not included.
 819 ## So makeinfo is a requirement to build from Bazaar, and configure
 820 ## should test for it as it does for any other build requirement.
 821 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 822 ## with pre-built manuals, from a Bazaar checkout.
 823 if test "$MAKEINFO" = "no"; then
 824   if test "x${with_makeinfo}" = "xno"; then
 825     MAKEINFO=off
 826   elif ! test -e $srcdir/info/emacs; then
 827     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 828 source tree does not seem to have pre-built manuals in the `info' directory.
 829 Either install a suitable version of makeinfo, or re-run configure
 830 with the `--without-makeinfo' option to build without the manuals.] )
 831   fi
 832 fi
 833
 834 dnl Add our options to ac_link now, after it is set up.
 835
 836 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 837 then
 838   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 839 fi
 840
 841 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 842 then
 843   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 844 fi
 845
 846 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 847 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 848 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 849 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 850 dnl if not built to support GNU ld.
 851
 852 late_LDFLAGS=$LDFLAGS
 853 if test "$GCC" = yes; then
 854   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 855 else
 856   LDFLAGS="$LDFLAGS -znocombreloc"
 857 fi
 858
 859 AC_MSG_CHECKING([for -znocombreloc])
 860 AC_LINK_IFELSE([main(){return 0;}],
 861   [AC_MSG_RESULT(yes)],
 862   LDFLAGS=$late_LDFLAGS
 863   [AC_MSG_RESULT(no)])
 864
 865 #### Extract some information from the operating system and machine files.
 866
 867 AC_CHECKING([the machine- and system-dependent files to find out
 868  - which libraries the lib-src programs will want, and
 869  - whether the GNU malloc routines are usable])
 870
 871 ### First figure out CFLAGS (which we use for running the compiler here)
 872 ### and REAL_CFLAGS (which we use for real compilation).
 873 ### The two are the same except on a few systems, where they are made
 874 ### different to work around various lossages.  For example,
 875 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 876 ### as implying static linking.
 877
 878 ### If the CFLAGS env var is specified, we use that value
 879 ### instead of the default.
 880
 881 ### It's not important that this name contain the PID; you can't run
 882 ### two configures in the same directory and have anything work
 883 ### anyway.
 884 tempcname="conftest.c"
 885
 886 echo '
 887 #include "'${srcdir}'/src/'${opsysfile}'"
 888 #include "'${srcdir}'/src/'${machfile}'"
 889 #ifndef LIBS_MACHINE
 890 #define LIBS_MACHINE
 891 #endif
 892 #ifndef LIBS_SYSTEM
 893 #define LIBS_SYSTEM
 894 #endif
 895 #ifndef C_SWITCH_SYSTEM
 896 #define C_SWITCH_SYSTEM
 897 #endif
 898 #ifndef C_SWITCH_MACHINE
 899 #define C_SWITCH_MACHINE
 900 #endif
 901 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 902 configure___ c_switch_system=C_SWITCH_SYSTEM
 903 configure___ c_switch_machine=C_SWITCH_MACHINE
 904
 905 #ifndef LIB_X11_LIB
 906 #define LIB_X11_LIB -lX11
 907 #endif
 908
 909 #ifndef LIBX11_SYSTEM
 910 #define LIBX11_SYSTEM
 911 #endif
 912 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 913
 914 #ifdef UNEXEC
 915 configure___ unexec=UNEXEC
 916 #else
 917 configure___ unexec=unexec.o
 918 #endif
 919
 920 #ifdef SYSTEM_MALLOC
 921 configure___ system_malloc=yes
 922 #else
 923 configure___ system_malloc=no
 924 #endif
 925
 926 #ifdef USE_MMAP_FOR_BUFFERS
 927 configure___ use_mmap_for_buffers=yes
 928 #else
 929 configure___ use_mmap_for_buffers=no
 930 #endif
 931
 932 #ifndef C_DEBUG_SWITCH
 933 #define C_DEBUG_SWITCH -g
 934 #endif
 935
 936 #ifndef C_OPTIMIZE_SWITCH
 937 #ifdef __GNUC__
 938 #define C_OPTIMIZE_SWITCH -O2
 939 #else
 940 #define C_OPTIMIZE_SWITCH -O
 941 #endif
 942 #endif
 943
 944 #ifndef C_WARNINGS_SWITCH
 945 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 946 #endif
 947
 948 #ifndef LD_SWITCH_MACHINE
 949 #define LD_SWITCH_MACHINE
 950 #endif
 951
 952 #ifndef LD_SWITCH_SYSTEM
 953 #define LD_SWITCH_SYSTEM
 954 #endif
 955
 956 #ifndef LD_SWITCH_X_SITE_AUX
 957 #define LD_SWITCH_X_SITE_AUX
 958 #endif
 959
 960 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 961 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 962
 963 #ifdef THIS_IS_CONFIGURE
 964
 965 /* Get the CFLAGS for tests in configure.  */
 966 #ifdef __GNUC__
 967 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 968 #else
 969 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 970 #endif
 971
 972 #else /* not THIS_IS_CONFIGURE */
 973
 974 /* Get the CFLAGS for real compilation.  */
 975 #ifdef __GNUC__
 976 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 977 #else
 978 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 979 #endif
 980
 981 #endif /* not THIS_IS_CONFIGURE */
 982 ' > ${tempcname}
 983
 984 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 985
 986 # The value of CPP is a quoted variable reference, so we need to do this
 987 # to get its actual value...
 988 CPP=`eval "echo $CPP"`
 989 [eval `${CPP} -Isrc ${tempcname} \
 990        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 991 if test "x$SPECIFIED_CFLAGS" = x; then
 992   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 993          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 994 else
 995   REAL_CFLAGS="$CFLAGS"
 996 fi]
 997 rm ${tempcname}
 998
 999 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1000
1001 ### Make sure subsequent tests use flags consistent with the build flags.
1002
1003 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1004   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1005 else
1006   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1007 fi
1008
1009 dnl For AC_FUNC_GETLOADAVG, at least:
1010 AC_CONFIG_LIBOBJ_DIR(src)
1011
1012 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1013 AC_SYS_LARGEFILE
1014
1015
1016 ### The standard library on x86-64 and s390x GNU/Linux distributions can
1017 ### be located in either /usr/lib64 or /usr/lib.
1018 ### In some rare cases, /usr/lib64 exists but does not contain the
1019 ### relevant files (bug#1287).  Hence test for crtn.o.
1020 case "${canonical}" in
1021   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1022     if test -e /usr/lib64/crtn.o; then
1023       AC_DEFINE(HAVE_LIB64_DIR, 1,
1024         [Define to 1 if the directory /usr/lib64 exists.])
1025 fi
1026 esac
1027
1028 dnl This function defintion taken from Gnome 2.0
1029 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1030 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1031 dnl also defines GSTUFF_PKG_ERRORS on error
1032 AC_DEFUN([PKG_CHECK_MODULES], [
1033   succeeded=no
1034
1035   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1036
1037   if test "$PKG_CONFIG" = "no" ; then
1038      ifelse([$4], , [AC_MSG_ERROR([
1039       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1040   else
1041      PKG_CONFIG_MIN_VERSION=0.9.0
1042      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1043         AC_MSG_CHECKING(for $2)
1044
1045         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1046             AC_MSG_RESULT(yes)
1047             succeeded=yes
1048
1049             AC_MSG_CHECKING($1_CFLAGS)
1050             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1051             AC_MSG_RESULT($$1_CFLAGS)
1052
1053             AC_MSG_CHECKING($1_LIBS)
1054             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1055             AC_MSG_RESULT($$1_LIBS)
1056         else
1057             AC_MSG_RESULT(no)
1058             $1_CFLAGS=""
1059             $1_LIBS=""
1060             ## If we have a custom action on failure, don't print errors, but
1061             ## do set a variable so people can do so.
1062             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1063             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1064         fi
1065
1066         AC_SUBST($1_CFLAGS)
1067         AC_SUBST($1_LIBS)
1068      else
1069         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1070         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1071      fi
1072   fi
1073
1074   if test $succeeded = yes; then
1075      ifelse([$3], , :, [$3])
1076   else
1077      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1078   fi
1079 ])
1080
1081
1082 if test "${with_sound}" != "no"; then
1083   # Sound support for GNU/Linux and the free BSDs.
1084   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1085   # Emulation library used on NetBSD.
1086   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1087   AC_SUBST(LIBSOUND)
1088
1089   ALSA_REQUIRED=1.0.0
1090   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1091   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1092   if test $HAVE_ALSA = yes; then
1093     SAVE_CFLAGS="$CFLAGS"
1094     SAVE_LDFLAGS="$LDFLAGS"
1095     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1096     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1097     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1098                     emacs_alsa_normal=yes,
1099                     emacs_alsa_normal=no)
1100     if test "$emacs_alsa_normal" != yes; then
1101       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1102                      [snd_lib_error_set_handler (0);],
1103                      emacs_alsa_subdir=yes,
1104                      emacs_alsa_subdir=no)
1105       if test "$emacs_alsa_subdir" != yes; then
1106         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1107       fi
1108       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1109     fi
1110
1111     CFLAGS="$SAVE_CFLAGS"
1112     LDFLAGS="$SAVE_LDFLAGS"
1113     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1114     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1115     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1116   fi
1117   AC_SUBST(CFLAGS_SOUND)
1118 fi
1119
1120 dnl checks for header files
1121 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1122   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1123   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1124   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1125   sys/utsname.h pwd.h utmp.h)
1126
1127 AC_MSG_CHECKING(if personality LINUX32 can be set)
1128 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1129                emacs_cv_personality_linux32=yes,
1130                emacs_cv_personality_linux32=no)
1131 AC_MSG_RESULT($emacs_cv_personality_linux32)
1132
1133 if test $emacs_cv_personality_linux32 = yes; then
1134   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1135             [Define to 1 if personality LINUX32 can be set.])
1136 fi
1137
1138 dnl On Solaris 8 there's a compilation warning for term.h because
1139 dnl it doesn't define `bool'.
1140 AC_CHECK_HEADERS(term.h, , , -)
1141 AC_HEADER_STDC
1142 AC_HEADER_TIME
1143 AC_CHECK_DECLS([sys_siglist])
1144 if test $ac_cv_have_decl_sys_siglist != yes; then
1145   # For Tru64, at least:
1146   AC_CHECK_DECLS([__sys_siglist])
1147   if test $ac_cv_have_decl___sys_siglist = yes; then
1148     AC_DEFINE(sys_siglist, __sys_siglist,
1149               [Define to any substitute for sys_siglist.])
1150   fi
1151 fi
1152 AC_HEADER_SYS_WAIT
1153
1154 dnl Some systems have utime.h but don't declare the struct anyplace.
1155 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1156 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1157 #include <sys/time.h>
1158 #include <time.h>
1159 #else
1160 #ifdef HAVE_SYS_TIME_H
1161 #include <sys/time.h>
1162 #else
1163 #include <time.h>
1164 #endif
1165 #endif
1166 #ifdef HAVE_UTIME_H
1167 #include <utime.h>
1168 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1169   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1170 if test $emacs_cv_struct_utimbuf = yes; then
1171   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1172 fi
1173
1174 dnl checks for typedefs
1175 AC_TYPE_SIGNAL
1176
1177 dnl Check for speed_t typedef.
1178 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1179   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1180     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1181 if test $emacs_cv_speed_t = yes; then
1182   AC_DEFINE(HAVE_SPEED_T, 1,
1183            [Define to 1 if `speed_t' is declared by <termios.h>.])
1184 fi
1185
1186 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1187 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1188 #include <sys/time.h>
1189 #include <time.h>
1190 #else
1191 #ifdef HAVE_SYS_TIME_H
1192 #include <sys/time.h>
1193 #else
1194 #include <time.h>
1195 #endif
1196 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1197   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1198 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1199 if test $emacs_cv_struct_timeval = yes; then
1200   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1201 fi
1202
1203 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1204 AC_TRY_COMPILE([#include <math.h>],
1205 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1206   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1207 HAVE_EXCEPTION=$emacs_cv_struct_exception
1208 if test $emacs_cv_struct_exception != yes; then
1209   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1210 fi
1211
1212 AC_CHECK_HEADERS(sys/socket.h)
1213 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1214 #if HAVE_SYS_SOCKET_H
1215 #include <sys/socket.h>
1216 #endif])
1217
1218 dnl checks for structure members
1219 AC_STRUCT_TM
1220 AC_STRUCT_TIMEZONE
1221 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1222                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1223                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1224                 [#include <time.h>])
1225 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1226                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1227                   struct ifreq.ifr_addr], , ,
1228                  [AC_INCLUDES_DEFAULT
1229 #if HAVE_SYS_SOCKET_H
1230 #include <sys/socket.h>
1231 #endif
1232 #if HAVE_NET_IF_H
1233 #include <net/if.h>
1234 #endif])
1235
1236 dnl checks for compiler characteristics
1237
1238 dnl Testing __STDC__ to determine prototype support isn't good enough.
1239 dnl DEC C, for instance, doesn't define it with default options, and
1240 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1241 dnl and void *.
1242 AC_C_PROTOTYPES
1243 AC_C_VOLATILE
1244 AC_C_CONST
1245 dnl This isn't useful because we can't turn on use of `inline' unless
1246 dnl the compiler groks `extern inline'.
1247 dnl AC_C_INLINE
1248 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1249   [AC_TRY_COMPILE(, [void * foo;],
1250                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1251 if test $emacs_cv_void_star = yes; then
1252   AC_DEFINE(POINTER_TYPE, void)
1253 else
1254   AC_DEFINE(POINTER_TYPE, char)
1255 fi
1256 AH_TEMPLATE(POINTER_TYPE,
1257             [Define as `void' if your compiler accepts `void *'; otherwise
1258              define as `char'.])dnl
1259
1260
1261
1262 dnl This could be used for targets which can have both byte sexes.
1263 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1264 dnl AC_C_BIGENDIAN
1265
1266 dnl check for Make feature
1267 AC_PROG_MAKE_SET
1268
1269 dnl check for GNU Make if we have GCC and autodepend is on.
1270 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1271    AC_MSG_CHECKING([whether we are using GNU Make])
1272    HAVE_GNU_MAKE=no
1273    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1274    if test "x$testval" != x; then
1275       HAVE_GNU_MAKE=yes
1276    else
1277       ac_enable_autodepend=no
1278    fi
1279    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1280    if test $HAVE_GNU_MAKE = yes; then
1281       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1282       SAVE_CFLAGS="$CFLAGS"
1283       CFLAGS="$CFLAGS -MMD -MF deps.d"
1284       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1285       CFLAGS="$SAVE_CFLAGS"
1286       test -f deps.d || ac_enable_autodepend=no
1287       rm -rf deps.d
1288       AC_MSG_RESULT([$ac_enable_autodepend])
1289    fi
1290    if test $ac_enable_autodepend = yes; then
1291       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1292    fi
1293 fi
1294
1295 dnl checks for operating system services
1296 AC_SYS_LONG_FILE_NAMES
1297
1298 #### Choose a window system.
1299
1300 AC_PATH_X
1301 if test "$no_x" = yes; then
1302   window_system=none
1303 else
1304   window_system=x11
1305 fi
1306
1307 ## Workaround for bug in autoconf <= 2.62.
1308 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1309 ## No need to do anything special for these standard directories.
1310 ## This is an experiment, take it out if it causes problems.
1311 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1312
1313    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1314
1315 fi
1316
1317 if test "${x_libraries}" != NONE; then
1318   if test -n "${x_libraries}"; then
1319     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1320     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1321   fi
1322   x_default_search_path=""
1323   x_search_path=${x_libraries}
1324   if test -z "${x_search_path}"; then
1325     x_search_path=/usr/lib
1326   fi
1327   for x_library in `echo ${x_search_path}: | \
1328                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1329     x_search_path="\
1330 ${x_library}/X11/%L/%T/%N%C%S:\
1331 ${x_library}/X11/%l/%T/%N%C%S:\
1332 ${x_library}/X11/%T/%N%C%S:\
1333 ${x_library}/X11/%L/%T/%N%S:\
1334 ${x_library}/X11/%l/%T/%N%S:\
1335 ${x_library}/X11/%T/%N%S"
1336     if test x"${x_default_search_path}" = x; then
1337       x_default_search_path=${x_search_path}
1338     else
1339       x_default_search_path="${x_search_path}:${x_default_search_path}"
1340     fi
1341   done
1342 fi
1343 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1344   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1345 fi
1346
1347 if test x"${x_includes}" = x; then
1348   bitmapdir=/usr/include/X11/bitmaps
1349 else
1350   # accumulate include directories that have X11 bitmap subdirectories
1351   bmd_acc="dummyval"
1352   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1353     if test -d "${bmd}/X11/bitmaps"; then
1354       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1355     fi
1356     if test -d "${bmd}/bitmaps"; then
1357       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1358     fi
1359   done
1360   if test ${bmd_acc} != "dummyval"; then
1361     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1362   fi
1363 fi
1364
1365 HAVE_NS=no
1366 NS_IMPL_COCOA=no
1367 NS_IMPL_GNUSTEP=no
1368 tmp_CPPFLAGS="$CPPFLAGS"
1369 tmp_CFLAGS="$CFLAGS"
1370 CPPFLAGS="$CPPFLAGS -x objective-c"
1371 CFLAGS="$CFLAGS -x objective-c"
1372 if test "${with_ns}" != no; then
1373   if test "${opsys}" = darwin; then
1374      NS_IMPL_COCOA=yes
1375      ns_appdir=`pwd`/nextstep/Emacs.app
1376      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1377      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1378      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1379   elif test -f $GNUSTEP_CONFIG_FILE; then
1380      NS_IMPL_GNUSTEP=yes
1381      ns_appdir=`pwd`/nextstep/Emacs.app
1382      ns_appbindir=`pwd`/nextstep/Emacs.app
1383      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1384      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1385      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1386      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1387      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1388      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1389      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1390      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1391      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1392      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1393   fi
1394   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1395                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1396   files are missing or cannot be compiled.])])
1397   NS_HAVE_NSINTEGER=yes
1398   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1399                                      [NSInteger i;])],
1400                     ns_have_nsinteger=yes,
1401                     ns_have_nsinteger=no)
1402   if test $ns_have_nsinteger = no; then
1403     NS_HAVE_NSINTEGER=no
1404   fi
1405 fi
1406 if test "${HAVE_NS}" = yes; then
1407   window_system=nextstep
1408   with_xft=no
1409   # set up packaging dirs
1410   exec_prefix=${ns_appbindir}
1411   libexecdir=${ns_appbindir}/libexec
1412   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1413      prefix=${ns_appresdir}
1414   fi
1415 fi
1416 CFLAGS="$tmp_CFLAGS"
1417 CPPFLAGS="$tmp_CPPFLAGS"
1418
1419 case "${window_system}" in
1420   x11 )
1421     HAVE_X_WINDOWS=yes
1422     HAVE_X11=yes
1423     case "${with_x_toolkit}" in
1424       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1425       motif ) USE_X_TOOLKIT=MOTIF ;;
1426       gtk ) with_gtk=yes
1427 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1428 dnl USE_X_TOOLKIT is set.
1429             USE_X_TOOLKIT=none ;;
1430       no ) USE_X_TOOLKIT=none ;;
1431 dnl If user did not say whether to use a toolkit, make this decision later:
1432 dnl use the toolkit if we have gtk, or X11R5 or newer.
1433       * ) USE_X_TOOLKIT=maybe ;;
1434     esac
1435   ;;
1436   nextstep | none )
1437     HAVE_X_WINDOWS=no
1438     HAVE_X11=no
1439     USE_X_TOOLKIT=none
1440   ;;
1441 esac
1442
1443 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1444    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1445    if test "$HAVE_XSERVER" = true ||
1446       test -n "$DISPLAY" ||
1447       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1448         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1449 were found.  You should install the relevant development files for X
1450 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1451 sure you have development files for image handling, i.e.
1452 tiff, gif, jpeg, png and xpm.
1453 If you are sure you want Emacs compiled without X window support, pass
1454   --without-x
1455 to configure.])
1456    fi
1457 fi
1458
1459 ### If we're using X11, we should use the X menu package.
1460 HAVE_MENUS=no
1461 case ${HAVE_X11} in
1462   yes ) HAVE_MENUS=yes ;;
1463 esac
1464
1465 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1466 # Assume not, until told otherwise.
1467 GNU_MALLOC=yes
1468 doug_lea_malloc=yes
1469 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1470 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1471 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1472                emacs_cv_var___after_morecore_hook,
1473 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1474   emacs_cv_var___after_morecore_hook=yes,
1475   emacs_cv_var___after_morecore_hook=no)])
1476 if test $emacs_cv_var___after_morecore_hook = no; then
1477   doug_lea_malloc=no
1478 fi
1479 if test "${system_malloc}" = "yes"; then
1480   GNU_MALLOC=no
1481   GNU_MALLOC_reason="
1482     (The GNU allocators don't work with this system configuration.)"
1483 fi
1484 if test "$doug_lea_malloc" = "yes" ; then
1485   if test "$GNU_MALLOC" = yes ; then
1486     GNU_MALLOC_reason="
1487       (Using Doug Lea's new malloc from the GNU C Library.)"
1488   fi
1489   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1490             [Define to 1 if you are using the GNU C Library.])
1491 fi
1492
1493 if test x"${REL_ALLOC}" = x; then
1494   REL_ALLOC=${GNU_MALLOC}
1495 fi
1496
1497 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1498 dnl the system configuration file (s/*.h) to turn the use of mmap
1499 dnl in the relocating allocator on.
1500
1501 AC_FUNC_MMAP
1502 if test $use_mmap_for_buffers = yes; then
1503   REL_ALLOC=no
1504 fi
1505
1506 LIBS="$libsrc_libs $LIBS"
1507
1508 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1509 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1510 AC_CHECK_LIB(dnet, dnet_ntoa)
1511 dnl This causes -lresolv to get used in subsequent tests,
1512 dnl which causes failures on some systems such as HPUX 9.
1513 dnl AC_CHECK_LIB(resolv, gethostbyname)
1514
1515 dnl FIXME replace main with a function we actually want from this library.
1516 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1517
1518 AC_CHECK_LIB(pthreads, cma_open)
1519
1520 dnl Check for need for bigtoc support on IBM AIX
1521
1522 case ${host_os} in
1523 aix*)
1524   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1525     case $GCC in
1526     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1527     *) gdb_cv_bigtoc=-bbigtoc ;;
1528     esac
1529
1530     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1531     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1532   ])
1533   ;;
1534 esac
1535
1536 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1537 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1538 # REAL_CPPFLAGS later on.
1539
1540 REAL_CPPFLAGS="$CPPFLAGS"
1541
1542 if test "${HAVE_X11}" = "yes"; then
1543   DEFS="$C_SWITCH_X_SITE $DEFS"
1544   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1545   LIBS="$LIBX $LIBS"
1546   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1547   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1548
1549   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1550   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1551   # but it's more convenient here to set LD_RUN_PATH
1552   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1553   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1554     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1555     export LD_RUN_PATH
1556   fi
1557
1558   if test "${opsys}" = "gnu-linux"; then
1559     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1560     AC_TRY_LINK([],
1561      [XOpenDisplay ("foo");],
1562      [xlinux_first_failure=no],
1563      [xlinux_first_failure=yes])
1564     if test "${xlinux_first_failure}" = "yes"; then
1565       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1566       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1567       OLD_CPPFLAGS="$CPPFLAGS"
1568       OLD_LIBS="$LIBS"
1569       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1570       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1571       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1572       LIBS="$LIBS -b i486-linuxaout"
1573       AC_TRY_LINK([],
1574        [XOpenDisplay ("foo");],
1575        [xlinux_second_failure=no],
1576        [xlinux_second_failure=yes])
1577       if test "${xlinux_second_failure}" = "yes"; then
1578         # If we get the same failure with -b, there is no use adding -b.
1579         # So take it out.  This plays safe.
1580         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1581         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1582         CPPFLAGS="$OLD_CPPFLAGS"
1583         LIBS="$OLD_LIBS"
1584         AC_MSG_RESULT(no)
1585       else
1586         AC_MSG_RESULT(yes)
1587       fi
1588     else
1589       AC_MSG_RESULT(no)
1590     fi
1591   fi
1592
1593   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1594   # header files included from there.
1595   AC_MSG_CHECKING(for Xkb)
1596   AC_TRY_LINK([#include <X11/Xlib.h>
1597 #include <X11/XKBlib.h>],
1598         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1599         emacs_xkb=yes, emacs_xkb=no)
1600   AC_MSG_RESULT($emacs_xkb)
1601   if test $emacs_xkb = yes; then
1602     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1603   fi
1604
1605   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1606 XScreenNumberOfScreen XSetWMProtocols)
1607 fi
1608
1609 if test "${window_system}" = "x11"; then
1610   AC_MSG_CHECKING(X11 version 6)
1611   AC_CACHE_VAL(emacs_cv_x11_version_6,
1612   [AC_TRY_LINK([#include <X11/Xlib.h>],
1613 [#if XlibSpecificationRelease < 6
1614 fail;
1615 #endif
1616 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1617   if test $emacs_cv_x11_version_6 = yes; then
1618     AC_MSG_RESULT(6 or newer)
1619     AC_DEFINE(HAVE_X11R6, 1,
1620               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1621   else
1622     AC_MSG_RESULT(before 6)
1623   fi
1624 fi
1625
1626
1627 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1628 HAVE_RSVG=no
1629 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1630   if test "${with_rsvg}" != "no"; then
1631     RSVG_REQUIRED=2.11.0
1632     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1633
1634     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1635     AC_SUBST(RSVG_CFLAGS)
1636     AC_SUBST(RSVG_LIBS)
1637
1638     if test ".${RSVG_CFLAGS}" != "."; then
1639       HAVE_RSVG=yes
1640       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1641       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1642       LIBS="$RSVG_LIBS $LIBS"
1643     fi
1644   fi
1645 fi
1646
1647
1648 HAVE_GTK=no
1649 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1650   GLIB_REQUIRED=2.6
1651   GTK_REQUIRED=2.6
1652   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1653
1654   dnl Checks for libraries.
1655   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1656   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1657      AC_MSG_ERROR($GTK_PKG_ERRORS)
1658   fi
1659 fi
1660
1661
1662 if test x"$pkg_check_gtk" = xyes; then
1663
1664   AC_SUBST(GTK_CFLAGS)
1665   AC_SUBST(GTK_LIBS)
1666   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1667   CFLAGS="$CFLAGS $GTK_CFLAGS"
1668   LIBS="$GTK_LIBS $LIBS"
1669   dnl Try to compile a simple GTK program.
1670   GTK_COMPILES=no
1671   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1672   if test "${GTK_COMPILES}" != "yes"; then
1673     if test "$USE_X_TOOLKIT" != "maybe"; then
1674       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1675     fi
1676   else
1677     HAVE_GTK=yes
1678     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1679     USE_X_TOOLKIT=none
1680     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1681       :
1682     else
1683       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1684        closing open displays.  This is no problem if you just use
1685        one display, but if you use more than one and close one of them
1686        Emacs may crash.]])
1687       sleep 3
1688     fi
1689   fi
1690
1691 fi
1692
1693
1694 if test "${HAVE_GTK}" = "yes"; then
1695
1696   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1697   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1698   if test "$with_toolkit_scroll_bars" != no; then
1699     with_toolkit_scroll_bars=yes
1700   fi
1701
1702   dnl  Check if we can use multiple displays with this GTK version.
1703   dnl  If gdk_display_open exists, assume all others are there also.
1704   HAVE_GTK_MULTIDISPLAY=no
1705   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1706   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1707     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1708               [Define to 1 if GTK can handle more than one display.])
1709   fi
1710
1711   dnl  Check if we have the old file selection dialog declared and
1712   dnl  in the link library.  In 2.x it may be in the library,
1713   dnl  but not declared if deprecated featured has been selected out.
1714   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1715   HAVE_GTK_FILE_SELECTION=no
1716   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1717                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1718 #include <gtk/gtk.h>])
1719   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1720     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1721                    HAVE_GTK_FILE_SELECTION=no)
1722   fi
1723
1724   dnl  Check if we have the new file chooser dialog
1725   HAVE_GTK_FILE_CHOOSER=no
1726   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1727                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1728 #include <gtk/gtk.h>])
1729   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1730     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1731                    HAVE_GTK_FILE_CHOOSER=no)
1732   fi
1733
1734   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1735      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1736     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1737               [Define to 1 if GTK has both file selection and chooser dialog.])
1738   fi
1739
1740   dnl Check if pthreads are available.  Emacs only needs this when using
1741   dnl gtk_file_chooser under Gnome.
1742   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1743     HAVE_GTK_AND_PTHREAD=no
1744     AC_CHECK_HEADERS(pthread.h)
1745     if test "$ac_cv_header_pthread_h"; then
1746       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1747     fi
1748     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1749       case "${canonical}" in
1750         *-hpux*) ;;
1751         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1752       esac
1753       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1754                [Define to 1 if you have GTK and pthread (-lpthread).])
1755     fi
1756   fi
1757 fi
1758
1759 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1760 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1761 dnl also not configured.
1762 HAVE_DBUS=no
1763 if test "${with_dbus}" = "yes"; then
1764    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1765    if test "$HAVE_DBUS" = yes; then
1766      LIBS="$LIBS $DBUS_LIBS"
1767      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1768      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1769    fi
1770 fi
1771
1772 dnl GConf has been tested under GNU/Linux only.
1773 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1774 HAVE_GCONF=no
1775 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1776    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1777    if test "$HAVE_GCONF" = yes; then
1778       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1779    fi
1780 fi
1781
1782 dnl Do not put whitespace before the #include statements below.
1783 dnl Older compilers (eg sunos4 cc) choke on it.
1784 HAVE_XAW3D=no
1785 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1786   if test "$with_xaw3d" != no; then
1787     AC_MSG_CHECKING(for xaw3d)
1788     AC_CACHE_VAL(emacs_cv_xaw3d,
1789     [AC_TRY_LINK([
1790 #include <X11/Intrinsic.h>
1791 #include <X11/Xaw3d/Simple.h>],
1792       [],
1793       emacs_cv_xaw3d=yes,
1794       emacs_cv_xaw3d=no)])
1795   else
1796     emacs_cv_xaw3d=no
1797   fi
1798   if test $emacs_cv_xaw3d = yes; then
1799     AC_MSG_RESULT([yes; using Lucid toolkit])
1800     USE_X_TOOLKIT=LUCID
1801     HAVE_XAW3D=yes
1802     AC_DEFINE(HAVE_XAW3D, 1,
1803               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1804   else
1805     AC_MSG_RESULT(no)
1806     AC_MSG_CHECKING(for libXaw)
1807     AC_CACHE_VAL(emacs_cv_xaw,
1808     [AC_TRY_LINK([
1809 #include <X11/Intrinsic.h>
1810 #include <X11/Xaw/Simple.h>],
1811       [],
1812       emacs_cv_xaw=yes,
1813       emacs_cv_xaw=no)])
1814     if test $emacs_cv_xaw = yes; then
1815       AC_MSG_RESULT([yes; using Lucid toolkit])
1816       USE_X_TOOLKIT=LUCID
1817     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1818       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1819     else
1820       AC_MSG_RESULT([no; do not use toolkit by default])
1821       USE_X_TOOLKIT=none
1822     fi
1823   fi
1824 fi
1825
1826 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1827
1828 if test "${USE_X_TOOLKIT}" != "none"; then
1829   AC_MSG_CHECKING(X11 toolkit version)
1830   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1831   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1832 [#if XtSpecificationRelease < 6
1833 fail;
1834 #endif
1835 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1836   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1837   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1838     AC_MSG_RESULT(6 or newer)
1839     AC_DEFINE(HAVE_X11XTR6, 1,
1840               [Define to 1 if you have the X11R6 or newer version of Xt.])
1841   else
1842     AC_MSG_RESULT(before 6)
1843   fi
1844
1845 dnl If using toolkit, check whether libXmu.a exists.
1846 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1847   OLDLIBS="$LIBS"
1848   if test x$HAVE_X11XTR6 = xyes; then
1849     LIBS="-lXt -lSM -lICE $LIBS"
1850   else
1851     LIBS="-lXt $LIBS"
1852   fi
1853   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1854   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1855 fi
1856
1857 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1858 if test "${HAVE_X11}" = "yes"; then
1859   if test "${USE_X_TOOLKIT}" != "none"; then
1860     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1861   fi
1862 fi
1863
1864 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1865   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1866   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1867     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1868 int x = 5;
1869 #else
1870 Motif version prior to 2.1.
1871 #endif],
1872     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1873   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1874   if test $emacs_cv_motif_version_2_1 = yes; then
1875     HAVE_LIBXP=no
1876     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1877               [Define to 1 if you have Motif 2.1 or newer.])
1878     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1879     if test ${HAVE_LIBXP} = yes; then
1880       AC_DEFINE(HAVE_LIBXP, 1,
1881                 [Define to 1 if you have the Xp library (-lXp).])
1882     fi
1883   else
1884     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1885     # We put this in CFLAGS temporarily to precede other -I options
1886     # that might be in CFLAGS temporarily.
1887     # We put this in CPPFLAGS where it precedes the other -I options.
1888     OLD_CPPFLAGS=$CPPFLAGS
1889     OLD_CFLAGS=$CFLAGS
1890     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1891     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1892     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1893       [int x = 5;],
1894       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1895     if test $emacs_cv_lesstif = yes; then
1896       # Make sure this -I option remains in CPPFLAGS after it is set
1897       # back to REAL_CPPFLAGS.
1898       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1899       # have those other -I options anyway.  Ultimately, having this
1900       # directory ultimately in CPPFLAGS will be enough.
1901       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1902       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1903     else
1904       CFLAGS=$OLD_CFLAGS
1905       CPPFLAGS=$OLD_CPPFLAGS
1906     fi
1907   fi
1908 fi
1909
1910 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1911 dnl using Motif or Xaw3d is available, and unless
1912 dnl --with-toolkit-scroll-bars=no was specified.
1913
1914 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1915             [Define to 1 if we should use toolkit scroll bars.])dnl
1916 USE_TOOLKIT_SCROLL_BARS=no
1917 if test "${with_toolkit_scroll_bars}" != "no"; then
1918   if test "${USE_X_TOOLKIT}" != "none"; then
1919     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1920       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1921       HAVE_XAW3D=no
1922       USE_TOOLKIT_SCROLL_BARS=yes
1923     elif test "${HAVE_XAW3D}" = "yes"; then
1924       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1925       USE_TOOLKIT_SCROLL_BARS=yes
1926     fi
1927   elif test "${HAVE_GTK}" = "yes"; then
1928     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1929     USE_TOOLKIT_SCROLL_BARS=yes
1930   elif test "${HAVE_NS}" = "yes"; then
1931     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1932     USE_TOOLKIT_SCROLL_BARS=yes
1933   fi
1934 fi
1935
1936 dnl See if XIM is available.
1937 AC_TRY_COMPILE([
1938           #include <X11/Xlib.h>
1939           #include <X11/Xresource.h>],
1940          [XIMProc  callback;],
1941          [HAVE_XIM=yes
1942          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1943          HAVE_XIM=no)
1944
1945 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1946
1947 if test "${with_xim}" != "no"; then
1948   AC_DEFINE(USE_XIM, 1,
1949             [Define to 1 if we should use XIM, if it is available.])
1950 fi
1951
1952
1953 if test "${HAVE_XIM}" != "no"; then
1954   late_CFLAGS=$CFLAGS
1955   if test "$GCC" = yes; then
1956     CFLAGS="$CFLAGS --pedantic-errors"
1957   fi
1958   AC_TRY_COMPILE([
1959 #include <X11/Xlib.h>
1960 #include <X11/Xresource.h>],
1961 [Display *display;
1962 XrmDatabase db;
1963 char *res_name;
1964 char *res_class;
1965 XIMProc  callback;
1966 XPointer *client_data;
1967 #ifndef __GNUC__
1968 /* If we're not using GCC, it's probably not XFree86, and this is
1969    probably right, but we can't use something like --pedantic-errors.  */
1970 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1971                                            char*, XIMProc, XPointer*);
1972 #endif
1973 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1974    client_data);],
1975     [emacs_cv_arg6_star=yes])
1976   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1977          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1978 either XPointer or XPointer*.])dnl
1979   if test "$emacs_cv_arg6_star" = yes; then
1980     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1981   else
1982     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1983   fi
1984   CFLAGS=$late_CFLAGS
1985 fi
1986
1987 ### Start of font-backend (under any platform) section.
1988 # (nothing here yet -- this is a placeholder)
1989 ### End of font-backend (under any platform) section.
1990
1991 ### Start of font-backend (under X11) section.
1992 if test "${HAVE_X11}" = "yes"; then
1993    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1994
1995    ## Use -lXft if available, unless `--with-xft=no'.
1996    HAVE_XFT=maybe
1997     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
1998       with_xft="no";
1999     fi
2000     if test "x${with_xft}" != "xno"; then
2001
2002       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2003       ## Because xftfont.c uses XRenderQueryExtension, we also
2004       ## need to link to -lXrender.
2005       HAVE_XRENDER=no
2006       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2007       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2008         OLD_CPPFLAGS="$CPPFLAGS"
2009         OLD_CFLAGS="$CFLAGS"
2010         OLD_LIBS="$LIBS"
2011         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2012         CFLAGS="$CFLAGS $XFT_CFLAGS"
2013         XFT_LIBS="-lXrender $XFT_LIBS"
2014         LIBS="$XFT_LIBS $LIBS"
2015         AC_CHECK_HEADER(X11/Xft/Xft.h,
2016           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2017
2018         if test "${HAVE_XFT}" = "yes"; then
2019           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2020             AC_SUBST(XFT_LIBS)
2021           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2022         else
2023           CPPFLAGS="$OLD_CPPFLAGS"
2024           CFLAGS="$OLD_CFLAGS"
2025           LIBS="$OLD_LIBS"
2026         fi                        # "${HAVE_XFT}" = "yes"
2027       fi                          # "$HAVE_XFT" != no
2028     fi                            # "x${with_xft}" != "xno"
2029
2030     dnl For the "Does Emacs use" message at the end.
2031     if test "$HAVE_XFT" != "yes"; then
2032        HAVE_XFT=no
2033     fi
2034
2035
2036     HAVE_FREETYPE=no
2037     ## We used to allow building with FreeType and without Xft.
2038     ## However, the ftx font backend driver is not in good shape.
2039     if test "${HAVE_XFT}" = "yes"; then
2040       dnl As we use Xft, we anyway use freetype.
2041       dnl There's no need for additional CFLAGS and LIBS.
2042       HAVE_FREETYPE=yes
2043       FONTCONFIG_CFLAGS=
2044       FONTCONFIG_LIBS=
2045     fi
2046
2047     HAVE_LIBOTF=no
2048     if test "${HAVE_FREETYPE}" = "yes"; then
2049       AC_DEFINE(HAVE_FREETYPE, 1,
2050                 [Define to 1 if using the freetype and fontconfig libraries.])
2051       if test "${with_libotf}" != "no"; then
2052         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2053                           HAVE_LIBOTF=no)
2054         if test "$HAVE_LIBOTF" = "yes"; then
2055           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2056           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2057                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2058                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2059           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2060             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2061                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2062           fi
2063         fi
2064       fi
2065     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2066     dnl Does the new font backend require it, or can it work without it?
2067     fi
2068
2069     HAVE_M17N_FLT=no
2070     if test "${HAVE_LIBOTF}" = yes; then
2071       if test "${with_m17n_flt}" != "no"; then
2072         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2073         if test "$HAVE_M17N_FLT" = "yes"; then
2074           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2075         fi
2076       fi
2077     fi
2078 else
2079     HAVE_XFT=no
2080     HAVE_FREETYPE=no
2081     HAVE_LIBOTF=no
2082     HAVE_M17N_FLT=no
2083 fi
2084 ### End of font-backend (under X11) section.
2085
2086 AC_SUBST(FREETYPE_CFLAGS)
2087 AC_SUBST(FREETYPE_LIBS)
2088 AC_SUBST(FONTCONFIG_CFLAGS)
2089 AC_SUBST(FONTCONFIG_LIBS)
2090 AC_SUBST(LIBOTF_CFLAGS)
2091 AC_SUBST(LIBOTF_LIBS)
2092 AC_SUBST(M17N_FLT_CFLAGS)
2093 AC_SUBST(M17N_FLT_LIBS)
2094
2095 ### Use -lXpm if available, unless `--with-xpm=no'.
2096 HAVE_XPM=no
2097 LIBXPM=
2098 if test "${HAVE_X11}" = "yes"; then
2099   if test "${with_xpm}" != "no"; then
2100     AC_CHECK_HEADER(X11/xpm.h,
2101       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2102     if test "${HAVE_XPM}" = "yes"; then
2103       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2104       AC_EGREP_CPP(no_return_alloc_pixels,
2105       [#include "X11/xpm.h"
2106 #ifndef XpmReturnAllocPixels
2107 no_return_alloc_pixels
2108 #endif
2109       ], HAVE_XPM=no, HAVE_XPM=yes)
2110
2111       if test "${HAVE_XPM}" = "yes"; then
2112         AC_MSG_RESULT(yes)
2113       else
2114         AC_MSG_RESULT(no)
2115       fi
2116     fi
2117   fi
2118
2119   if test "${HAVE_XPM}" = "yes"; then
2120     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2121     LIBXPM=-lXpm
2122   fi
2123 fi
2124 AC_SUBST(LIBXPM)
2125
2126 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2127 HAVE_JPEG=no
2128 LIBJPEG=
2129 if test "${HAVE_X11}" = "yes"; then
2130   if test "${with_jpeg}" != "no"; then
2131     dnl Checking for jpeglib.h can lose because of a redefinition of
2132     dnl  HAVE_STDLIB_H.
2133     AC_CHECK_HEADER(jerror.h,
2134       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2135   fi
2136
2137   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2138   if test "${HAVE_JPEG}" = "yes"; then
2139     AC_DEFINE(HAVE_JPEG)
2140     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2141         [#include <jpeglib.h>
2142          version=JPEG_LIB_VERSION
2143 ],
2144         [AC_DEFINE(HAVE_JPEG)],
2145         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2146         HAVE_JPEG=no])
2147   fi
2148   if test "${HAVE_JPEG}" = "yes"; then
2149     LIBJPEG=-ljpeg
2150   fi
2151 fi
2152 AC_SUBST(LIBJPEG)
2153
2154 ### Use -lpng if available, unless `--with-png=no'.
2155 HAVE_PNG=no
2156 LIBPNG=
2157 if test "${HAVE_X11}" = "yes"; then
2158   if test "${with_png}" != "no"; then
2159     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2160     # in /usr/include/libpng.
2161     AC_CHECK_HEADERS(png.h libpng/png.h)
2162     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2163       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2164     fi
2165   fi
2166
2167   if test "${HAVE_PNG}" = "yes"; then
2168     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2169     LIBPNG="-lpng -lz -lm"
2170   fi
2171 fi
2172 AC_SUBST(LIBPNG)
2173
2174 ### Use -ltiff if available, unless `--with-tiff=no'.
2175 HAVE_TIFF=no
2176 LIBTIFF=
2177 if test "${HAVE_X11}" = "yes"; then
2178   if test "${with_tiff}" != "no"; then
2179     AC_CHECK_HEADER(tiffio.h,
2180       [tifflibs="-lz -lm"
2181       # At least one tiff package requires the jpeg library.
2182       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2183       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2184   fi
2185
2186   if test "${HAVE_TIFF}" = "yes"; then
2187     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2188     dnl FIXME -lz -lm, as per libpng?
2189     LIBTIFF=-ltiff
2190   fi
2191 fi
2192 AC_SUBST(LIBTIFF)
2193
2194 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2195 HAVE_GIF=no
2196 LIBGIF=
2197 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2198   AC_CHECK_HEADER(gif_lib.h,
2199 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2200 # Earlier versions can crash Emacs.
2201     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2202
2203   if test "$HAVE_GIF" = yes; then
2204     LIBGIF=-lgif
2205   elif test "$HAVE_GIF" = maybe; then
2206 # If gif_lib.h but no libgif, try libungif.
2207     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2208     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2209   fi
2210
2211   if test "${HAVE_GIF}" = "yes"; then
2212     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2213   fi
2214 fi
2215 AC_SUBST(LIBGIF)
2216
2217 dnl Check for required libraries.
2218 if test "${HAVE_X11}" = "yes"; then
2219   MISSING=""
2220   WITH_NO=""
2221   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2222     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2223   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2224     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2225   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2226     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2227   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2228     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2229   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2230     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2231
2232   if test "X${MISSING}" != X; then
2233     AC_MSG_ERROR([The following required libraries were not found:
2234     $MISSING
2235 Maybe some development libraries/packages are missing?
2236 If you don't want to link with them give
2237     $WITH_NO
2238 as options to configure])
2239   fi
2240 fi
2241
2242 ### Use -lgpm if available, unless `--with-gpm=no'.
2243 HAVE_GPM=no
2244 LIBGPM=
2245 if test "${with_gpm}" != "no"; then
2246   AC_CHECK_HEADER(gpm.h,
2247     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2248
2249   if test "${HAVE_GPM}" = "yes"; then
2250     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2251     LIBGPM=-lgpm
2252   fi
2253 fi
2254 AC_SUBST(LIBGPM)
2255
2256 dnl Check for malloc/malloc.h on darwin
2257 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2258
2259 ### Use NeXTstep API to implement GUI.
2260 if test "${HAVE_NS}" = "yes"; then
2261   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2262   if test "${NS_IMPL_COCOA}" = "yes"; then
2263     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2264     GNU_OBJC_CFLAGS=
2265   fi
2266   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2267     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2268     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2269   fi
2270   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2271     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2272   fi
2273   # We also have mouse menus.
2274   HAVE_MENUS=yes
2275   OTHER_FILES=ns-app
2276 fi
2277
2278
2279 ### Use session management (-lSM -lICE) if available
2280 HAVE_X_SM=no
2281 if test "${HAVE_X11}" = "yes"; then
2282   AC_CHECK_HEADER(X11/SM/SMlib.h,
2283     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2284
2285   if test "${HAVE_X_SM}" = "yes"; then
2286     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2287     case "$LIBS" in
2288       *-lSM*) ;;
2289       *)      LIBS="-lSM -lICE $LIBS" ;;
2290     esac
2291   fi
2292 fi
2293
2294 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2295 AC_CACHE_CHECK(whether netdb declares h_errno,
2296                emacs_cv_netdb_declares_h_errno,
2297 [AC_TRY_LINK([#include <netdb.h>],
2298   [return h_errno;],
2299   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2300 if test $emacs_cv_netdb_declares_h_errno = yes; then
2301   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2302 fi
2303
2304 AC_FUNC_ALLOCA
2305
2306 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2307 dnl FIXME is there an autoconf test that does the right thing, without
2308 dnl needing to call A_M_E afterwards?
2309 if test x"$ac_cv_func_alloca_works" != xyes; then
2310    AC_MSG_ERROR( [a system implementation of alloca is required] )
2311 fi
2312
2313 # fmod, logb, and frexp are found in -lm on most systems.
2314 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2315 AC_CHECK_LIB(m, sqrt)
2316
2317 # Check for mail-locking functions in a "mail" library.  Probably this should
2318 # have the same check as for liblockfile below.
2319 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2320 if test $have_mail = yes; then
2321   LIBS_MAIL=-lmail
2322   LIBS="$LIBS_MAIL $LIBS"
2323   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2324 else
2325   LIBS_MAIL=
2326 fi
2327 dnl Debian, at least:
2328 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2329 if test $have_lockfile = yes; then
2330    LIBS_MAIL=-llockfile
2331    LIBS="$LIBS_MAIL $LIBS"
2332    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2333 else
2334 # If we have the shared liblockfile, assume we must use it for mail
2335 # locking (e.g. Debian).  If we couldn't link against liblockfile
2336 # (no liblockfile.a installed), ensure that we don't need to.
2337   dnl This works for files generally, not just executables.
2338   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2339   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2340                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2341   if test $ac_cv_prog_liblockfile = yes; then
2342     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2343 This probably means that movemail could lose mail.
2344 There may be a `development' package to install containing liblockfile.])
2345   fi
2346 fi
2347 AC_CHECK_FUNCS(touchlock)
2348 AC_CHECK_HEADERS(maillock.h)
2349 AC_SUBST(LIBS_MAIL)
2350
2351 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2352 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2353 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2354 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2355 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2356 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2357 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2358 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2359 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2360 cfmakeraw cfsetspeed)
2361
2362 AC_CHECK_HEADERS(sys/un.h)
2363
2364 AC_FUNC_MKTIME
2365 if test "$ac_cv_func_working_mktime" = no; then
2366   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2367 fi
2368
2369 AC_FUNC_GETLOADAVG
2370
2371 AC_FUNC_FSEEKO
2372
2373 # Configure getopt.
2374 m4_include([m4/getopt.m4])
2375 gl_GETOPT_IFELSE([
2376   gl_GETOPT_SUBSTITUTE_HEADER
2377   gl_PREREQ_GETOPT
2378   GETOPTOBJS='getopt.o getopt1.o'
2379 ])
2380 AC_SUBST(GETOPTOBJS)
2381
2382 AC_FUNC_GETPGRP
2383
2384 AC_FUNC_STRFTIME
2385
2386 # UNIX98 PTYs.
2387 AC_CHECK_FUNCS(grantpt)
2388
2389 # PTY-related GNU extensions.
2390 AC_CHECK_FUNCS(getpt)
2391
2392 # Check this now, so that we will NOT find the above functions in ncurses.
2393 # That is because we have not set up to link ncurses in lib-src.
2394 # It's better to believe a function is not available
2395 # than to expect to find it in ncurses.
2396 # Also we need tputs and frieds to be able to build at all.
2397 have_tputs_et_al=true
2398 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2399 if test "$have_tputs_et_al" != true; then
2400   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2401 Maybe some development libraries/packages are missing?  Try installing
2402 libncurses-dev(el), libterminfo-dev(el) or similar.])
2403 fi
2404 # Must define this when any termcap library is found.
2405 AC_DEFINE(HAVE_LIBNCURSES)
2406
2407 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2408
2409 resolv=no
2410 AC_TRY_LINK([#include <netinet/in.h>
2411 #include <arpa/nameser.h>
2412 #include <resolv.h>],
2413     [return res_init();],
2414     have_res_init=yes, have_res_init=no)
2415 if test "$have_res_init" = no; then
2416   OLIBS="$LIBS"
2417   LIBS="$LIBS -lresolv"
2418   AC_MSG_CHECKING(for res_init with -lresolv)
2419   AC_TRY_LINK([#include <netinet/in.h>
2420 #include <arpa/nameser.h>
2421 #include <resolv.h>],
2422     [return res_init();],
2423     have_res_init=yes, have_res_init=no)
2424   AC_MSG_RESULT($have_res_init)
2425   if test "$have_res_init" = yes ; then
2426     resolv=yes
2427   fi
2428   LIBS="$OLIBS"
2429 fi
2430
2431 if test "$have_res_init" = yes; then
2432   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2433 fi
2434
2435 # Do we need the Hesiod library to provide the support routines?
2436 LIBHESIOD=
2437 if test "$with_hesiod" != no ; then
2438   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2439   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2440      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2441                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2442   if test "$resolv" = yes ; then
2443     RESOLVLIB=-lresolv
2444   else
2445     RESOLVLIB=
2446   fi
2447   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2448         hesiod=yes, :, $RESOLVLIB)])
2449
2450   if test x"$hesiod" = xyes; then
2451     AC_DEFINE(HAVE_LIBHESIOD, 1,
2452               [Define to 1 if you have the hesiod library (-lhesiod).])
2453     LIBHESIOD=-lhesiod
2454   fi
2455 fi
2456 AC_SUBST(LIBHESIOD)
2457
2458 # Do we need libresolv (due to res_init or Hesiod)?
2459 if test "$resolv" = yes ; then
2460   AC_DEFINE(HAVE_LIBRESOLV, 1,
2461             [Define to 1 if you have the resolv library (-lresolv).])
2462   LIBRESOLV=-lresolv
2463 else
2464   LIBRESOLV=
2465 fi
2466 AC_SUBST(LIBRESOLV)
2467
2468 # These tell us which Kerberos-related libraries to use.
2469 COM_ERRLIB=
2470 CRYPTOLIB=
2471 KRB5LIB=
2472 DESLIB=
2473 KRB4LIB=
2474
2475 if test "${with_kerberos}" != no; then
2476   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2477   if test $have_com_err = yes; then
2478     COM_ERRLIB=-lcom_err
2479     LIBS="$COM_ERRLIB $LIBS"
2480     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2481   fi
2482   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2483   if test $have_crypto = yes; then
2484     CRYPTOLIB=-lcrypto
2485     LIBS="$CRYPTOLIB $LIBS"
2486     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2487   fi
2488   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2489   if test $have_k5crypto = yes; then
2490     CRYPTOLIB=-lk5crypto
2491     LIBS="$CRYPTOLIB $LIBS"
2492     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2493   fi
2494   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2495   if test $have_krb5=yes; then
2496     KRB5LIB=-lkrb5
2497     LIBS="$KRB5LIB $LIBS"
2498     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2499   fi
2500   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2501   if test "${with_kerberos5}" = no; then
2502     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2503     if test $have_des425 = yes; then
2504       DESLIB=-ldes425
2505       LIBS="$DESLIB $LIBS"
2506       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2507     else
2508       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2509       if test $have_des = yes; then
2510         DESLIB=-ldes
2511         LIBS="$DESLIB $LIBS"
2512         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2513       fi
2514     fi
2515     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2516     if test $have_krb4 = yes; then
2517       KRB4LIB=-lkrb4
2518       LIBS="$KRB4LIB $LIBS"
2519       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2520     else
2521       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2522       if test $have_krb = yes; then
2523         KRB4LIB=-lkrb
2524         LIBS="$KRB4LIB $LIBS"
2525         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2526       fi
2527     fi
2528   fi
2529
2530   if test "${with_kerberos5}" != no; then
2531     AC_CHECK_HEADERS(krb5.h,
2532       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2533                         [#include <krb5.h>])])
2534   else
2535     AC_CHECK_HEADERS(des.h,,
2536                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2537                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2538     AC_CHECK_HEADERS(krb.h,,
2539                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2540                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2541   fi
2542   AC_CHECK_HEADERS(com_err.h)
2543 fi
2544
2545 AC_SUBST(COM_ERRLIB)
2546 AC_SUBST(CRYPTOLIB)
2547 AC_SUBST(KRB5LIB)
2548 AC_SUBST(DESLIB)
2549 AC_SUBST(KRB4LIB)
2550
2551 # Solaris requires -lintl if you want strerror (which calls dgettext)
2552 # to return localized messages.
2553 AC_CHECK_LIB(intl, dgettext)
2554
2555 AC_MSG_CHECKING(whether localtime caches TZ)
2556 AC_CACHE_VAL(emacs_cv_localtime_cache,
2557 [if test x$ac_cv_func_tzset = xyes; then
2558 AC_TRY_RUN([#include <time.h>
2559 extern char **environ;
2560 unset_TZ ()
2561 {
2562   char **from, **to;
2563   for (to = from = environ; (*to = *from); from++)
2564     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2565       to++;
2566 }
2567 char TZ_GMT0[] = "TZ=GMT0";
2568 char TZ_PST8[] = "TZ=PST8";
2569 main()
2570 {
2571   time_t now = time ((time_t *) 0);
2572   int hour_GMT0, hour_unset;
2573   if (putenv (TZ_GMT0) != 0)
2574     exit (1);
2575   hour_GMT0 = localtime (&now)->tm_hour;
2576   unset_TZ ();
2577   hour_unset = localtime (&now)->tm_hour;
2578   if (putenv (TZ_PST8) != 0)
2579     exit (1);
2580   if (localtime (&now)->tm_hour == hour_GMT0)
2581     exit (1);
2582   unset_TZ ();
2583   if (localtime (&now)->tm_hour != hour_unset)
2584     exit (1);
2585   exit (0);
2586 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2587 [# If we have tzset, assume the worst when cross-compiling.
2588 emacs_cv_localtime_cache=yes])
2589 else
2590         # If we lack tzset, report that localtime does not cache TZ,
2591         # since we can't invalidate the cache if we don't have tzset.
2592         emacs_cv_localtime_cache=no
2593 fi])dnl
2594 AC_MSG_RESULT($emacs_cv_localtime_cache)
2595 if test $emacs_cv_localtime_cache = yes; then
2596   AC_DEFINE(LOCALTIME_CACHE, 1,
2597             [Define to 1 if localtime caches TZ.])
2598 fi
2599
2600 if test "x$HAVE_TIMEVAL" = xyes; then
2601   AC_CHECK_FUNCS(gettimeofday)
2602   if test $ac_cv_func_gettimeofday = yes; then
2603     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2604                    emacs_cv_gettimeofday_two_arguments,
2605     [AC_TRY_COMPILE([
2606 #ifdef TIME_WITH_SYS_TIME
2607 #include <sys/time.h>
2608 #include <time.h>
2609 #else
2610 #ifdef HAVE_SYS_TIME_H
2611 #include <sys/time.h>
2612 #else
2613 #include <time.h>
2614 #endif
2615 #endif],
2616       [struct timeval time;
2617        gettimeofday (&time, 0);],
2618       emacs_cv_gettimeofday_two_arguments=yes,
2619       emacs_cv_gettimeofday_two_arguments=no)])
2620     if test $emacs_cv_gettimeofday_two_arguments = no; then
2621       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2622                 [Define to 1 if gettimeofday accepts only one argument.])
2623     fi
2624   fi
2625 fi
2626
2627 ok_so_far=yes
2628 AC_CHECK_FUNC(socket, , ok_so_far=no)
2629 if test $ok_so_far = yes; then
2630   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2631 fi
2632 if test $ok_so_far = yes; then
2633   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2634 fi
2635 if test $ok_so_far = yes; then
2636 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2637   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2638             [Define to 1 if you have inet sockets.])
2639 fi
2640
2641 AC_CHECK_HEADERS(sys/ioctl.h)
2642
2643 if test -f /usr/lpp/X11/bin/smt.exp; then
2644   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2645             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2646 fi
2647
2648 AC_MSG_CHECKING(whether system supports dynamic ptys)
2649 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2650   AC_MSG_RESULT(yes)
2651   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2652 else
2653   AC_MSG_RESULT(no)
2654 fi
2655
2656 AC_FUNC_FORK
2657
2658 dnl Adapted from Haible's version.
2659 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2660   [AC_TRY_LINK([#include <langinfo.h>],
2661     [char* cs = nl_langinfo(CODESET);],
2662     emacs_cv_langinfo_codeset=yes,
2663     emacs_cv_langinfo_codeset=no)
2664   ])
2665 if test $emacs_cv_langinfo_codeset = yes; then
2666   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2667     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2668 fi
2669
2670 AC_CHECK_TYPES(size_t)
2671
2672 AC_TYPE_MBSTATE_T
2673
2674 dnl Restrict could probably be used effectively other than in regex.c.
2675 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2676   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2677                   emacs_cv_c_restrict=yes,
2678                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2679                                   emacs_cv_c_restrict=__restrict,
2680                                   emacs_cv_c_restrict=no)])])
2681 case "$emacs_cv_c_restrict" in
2682   yes) emacs_restrict=restrict;;
2683   no) emacs_restrict="";;
2684   *) emacs_restrict="$emacs_cv_c_restrict";;
2685 esac
2686 if test "$emacs_restrict" != __restrict; then
2687   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2688     [Define to compiler's equivalent of C99 restrict keyword.
2689      Don't define if equivalent is `__restrict'.])
2690 fi
2691
2692 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2693   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2694                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2695 if test "$emacs_cv_c_restrict_arr" = yes; then
2696   AC_DEFINE(__restrict_arr, __restrict,
2697     [Define to compiler's equivalent of C99 restrict keyword in array
2698      declarations.  Define as empty for no equivalent.])
2699 fi
2700
2701 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2702 dnl how the tty code is related to POSIX and/or other versions of termios.
2703 dnl The following looks like a useful start.
2704 dnl
2705 dnl AC_SYS_POSIX_TERMIOS
2706 dnl if test $ac_cv_sys_posix_termios = yes; then
2707 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2708 dnl                                and macros for terminal control.])
2709 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2710 dnl fi
2711
2712 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2713
2714 # Set up the CFLAGS for real compilation, so we can substitute it.
2715 CFLAGS="$REAL_CFLAGS"
2716 CPPFLAGS="$REAL_CPPFLAGS"
2717
2718 #### Find out which version of Emacs this is.
2719 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2720          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2721 if test x"${version}" = x; then
2722   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2723 fi
2724 if test x"${version}" != x"$PACKAGE_VERSION"; then
2725   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
2726 fi
2727
2728 ### Specify what sort of things we'll be editing into Makefile and config.h.
2729 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2730 AC_SUBST(version)
2731 AC_SUBST(configuration)
2732 AC_SUBST(canonical)
2733 AC_SUBST(srcdir)
2734 AC_SUBST(prefix)
2735 AC_SUBST(exec_prefix)
2736 AC_SUBST(bindir)
2737 AC_SUBST(datadir)
2738 AC_SUBST(sharedstatedir)
2739 AC_SUBST(libexecdir)
2740 AC_SUBST(mandir)
2741 AC_SUBST(infodir)
2742 AC_SUBST(lispdir)
2743 AC_SUBST(locallisppath)
2744 AC_SUBST(lisppath)
2745 AC_SUBST(x_default_search_path)
2746 AC_SUBST(etcdir)
2747 AC_SUBST(archlibdir)
2748 AC_SUBST(docdir)
2749 AC_SUBST(bitmapdir)
2750 AC_SUBST(gamedir)
2751 AC_SUBST(gameuser)
2752 AC_SUBST(c_switch_system)
2753 AC_SUBST(c_switch_machine)
2754 AC_SUBST(LD_SWITCH_X_SITE)
2755 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2756 AC_SUBST(C_SWITCH_X_SITE)
2757 AC_SUBST(CFLAGS)
2758 AC_SUBST(X_TOOLKIT_TYPE)
2759 AC_SUBST(machfile)
2760 AC_SUBST(opsysfile)
2761 AC_SUBST(GETLOADAVG_LIBS)
2762 AC_SUBST(ns_appdir)
2763 AC_SUBST(ns_appbindir)
2764 AC_SUBST(ns_appresdir)
2765 AC_SUBST(ns_appsrc)
2766 AC_SUBST(GNUSTEP_MAKEFILES)
2767 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2768 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2769 AC_SUBST(GNU_OBJC_CFLAGS)
2770 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2771 AC_SUBST(OTHER_FILES)
2772
2773 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2774                    [Define to the canonical Emacs configuration name.])
2775 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2776                    [Define to the options passed to configure.])
2777 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2778                    [Define to the used machine dependent file.])
2779 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2780                    [Define to the used os dependent file.])
2781 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2782 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2783  may need to deal with X Windows.  For instance, if you've defined
2784  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2785  your loader can find on its own, you might want to add "-L/..." or
2786  something similar.])
2787 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2788                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2789                     in case it's needed (for Solaris, for example).])
2790 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2791 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2792  may need to deal with X Windows.  For instance, if you've defined
2793  HAVE_X_WINDOWS above and your X include files aren't in a place
2794  that your compiler can find on its own, you might want to add
2795  "-I/..." or something similar.])
2796 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2797                    [Define to the unexec source file name.])
2798
2799 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2800   AC_DEFINE(HAVE_X_WINDOWS, 1,
2801             [Define to 1 if you want to use the X window system.])
2802 fi
2803 if test "${USE_X_TOOLKIT}" != "none" ; then
2804   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2805   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2806     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2807   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2808     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2809   fi
2810 fi
2811 if test "${HAVE_X11}" = "yes" ; then
2812   AC_DEFINE(HAVE_X11, 1,
2813             [Define to 1 if you want to use version 11 of X windows.
2814              Otherwise, Emacs expects to use version 10.])
2815 fi
2816 if test "${HAVE_MENUS}" = "yes" ; then
2817   AC_DEFINE(HAVE_MENUS, 1,
2818             [Define to 1 if you have mouse menus.
2819              (This is automatic if you use X, but the option to specify it remains.)
2820              It is also defined with other window systems that support xmenu.c.])
2821 fi
2822 if test "${GNU_MALLOC}" = "yes" ; then
2823   AC_DEFINE(GNU_MALLOC, 1,
2824             [Define to 1 if you want to use the GNU memory allocator.])
2825 fi
2826 if test "${REL_ALLOC}" = "yes" ; then
2827   AC_DEFINE(REL_ALLOC, 1,
2828             [Define REL_ALLOC if you want to use the relocating allocator for
2829              buffer space.])
2830 fi
2831
2832
2833 AH_TOP([/* GNU Emacs site configuration template file.
2834    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2835      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
2836
2837 This file is part of GNU Emacs.
2838
2839 GNU Emacs is free software: you can redistribute it and/or modify
2840 it under the terms of the GNU General Public License as published by
2841 the Free Software Foundation, either version 3 of the License, or
2842 (at your option) any later version.
2843
2844 GNU Emacs is distributed in the hope that it will be useful,
2845 but WITHOUT ANY WARRANTY; without even the implied warranty of
2846 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2847 GNU General Public License for more details.
2848
2849 You should have received a copy of the GNU General Public License
2850 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2851
2852
2853 /* No code in Emacs #includes config.h twice, but some bits of code
2854    intended to work with other packages as well (like gmalloc.c)
2855    think they can include it as many times as they like.  */
2856 #ifndef EMACS_CONFIG_H
2857 #define EMACS_CONFIG_H
2858 ])dnl
2859
2860 AH_BOTTOM([
2861 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2862 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2863 #define HAVE_WINDOW_SYSTEM
2864 #define HAVE_MOUSE
2865 #endif
2866
2867 /* Define AMPERSAND_FULL_NAME if you use the convention
2868    that & in the full name stands for the login id.  */
2869 /* Turned on June 1996 supposing nobody will mind it.  */
2870 #define AMPERSAND_FULL_NAME
2871
2872 /* Define HAVE_SOUND if we have sound support.  We know it works
2873    and compiles only on the specified platforms.   For others,
2874    it probably doesn't make sense to try.  */
2875
2876 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2877 #ifdef HAVE_MACHINE_SOUNDCARD_H
2878 #define HAVE_SOUND 1
2879 #endif
2880 #ifdef HAVE_SYS_SOUNDCARD_H
2881 #define HAVE_SOUND 1
2882 #endif
2883 #ifdef HAVE_SOUNDCARD_H
2884 #define HAVE_SOUND 1
2885 #endif
2886 #ifdef HAVE_ALSA
2887 #define HAVE_SOUND 1
2888 #endif
2889 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2890
2891 /* If using GNU, then support inline function declarations. */
2892 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2893    generally, because even if non-gcc compilers accept `inline', they
2894    may reject `extern inline'.  */
2895 #if defined (__GNUC__) && defined (OPTIMIZE)
2896 #define INLINE __inline__
2897 #else
2898 #define INLINE
2899 #endif
2900
2901 /* `subprocesses' should be defined if you want to
2902    have code for asynchronous subprocesses
2903    (as used in M-x compile and M-x shell).
2904    Only MSDOS does not support this (it overrides
2905    this in its config_opsysfile below).  */
2906
2907 #define subprocesses
2908
2909 /* Include the os and machine dependent files.  */
2910 #include config_opsysfile
2911 #include config_machfile
2912
2913 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2914   (There is probably a better place to do this, but right now the Cocoa
2915    side does this in s/darwin.h and we cannot
2916    parallel this exactly since GNUstep is multi-OS. */
2917 #ifdef HAVE_NS
2918 # ifdef NS_IMPL_GNUSTEP
2919 /* See also .m.o rule in Makefile.in */
2920 /* FIXME: are all these flags really needed?  Document here why.  */
2921 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2922 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2923 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2924 #  define SYSTEM_PURESIZE_EXTRA 30000
2925 # endif /* NS_IMPL_GNUSTEP */
2926 #endif /* HAVE_NS */
2927
2928 /* SIGTYPE is the macro we actually use.  */
2929 #ifndef SIGTYPE
2930 #define SIGTYPE RETSIGTYPE
2931 #endif
2932
2933 #ifdef emacs /* Don't do this for lib-src.  */
2934 /* Tell regex.c to use a type compatible with Emacs.  */
2935 #define RE_TRANSLATE_TYPE Lisp_Object
2936 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2937 #ifdef make_number
2938 /* If make_number is a macro, use it.  */
2939 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2940 #else
2941 /* If make_number is a function, avoid it.  */
2942 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2943 #endif
2944 #endif
2945
2946 /* Avoid link-time collision with system mktime if we will use our own.  */
2947 #if ! HAVE_MKTIME || BROKEN_MKTIME
2948 #define mktime emacs_mktime
2949 #endif
2950
2951 #define my_strftime nstrftime   /* for strftime.c */
2952
2953 /* The rest of the code currently tests the CPP symbol BSTRING.
2954    Override any claims made by the system-description files.
2955    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2956 #undef BSTRING
2957 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2958 #define BSTRING
2959 #endif
2960
2961 /* Some of the files of Emacs which are intended for use with other
2962    programs assume that if you have a config.h file, you must declare
2963    the type of getenv.
2964
2965    This declaration shouldn't appear when alloca.s or Makefile.in
2966    includes config.h.  */
2967 #ifndef NOT_C_CODE
2968 extern char *getenv ();
2969 #endif
2970
2971 /* These default definitions are good for almost all machines.
2972    The exceptions override them in m/MACHINE.h.  */
2973
2974 #ifndef BITS_PER_CHAR
2975 #define BITS_PER_CHAR 8
2976 #endif
2977
2978 #ifndef BITS_PER_SHORT
2979 #define BITS_PER_SHORT 16
2980 #endif
2981
2982 /* Note that lisp.h uses this in a preprocessor conditional, so it
2983    would not work to use sizeof.  That being so, we do all of them
2984    without sizeof, for uniformity's sake.  */
2985 #ifndef BITS_PER_INT
2986 #define BITS_PER_INT 32
2987 #endif
2988
2989 #ifndef BITS_PER_LONG
2990 #ifdef _LP64
2991 #define BITS_PER_LONG 64
2992 #else
2993 #define BITS_PER_LONG 32
2994 #endif
2995 #endif
2996
2997 /* Define if the compiler supports function prototypes.  It may do so
2998    but not define __STDC__ (e.g. DEC C by default) or may define it as
2999    zero.  */
3000 #undef PROTOTYPES
3001 /* For mktime.c:  */
3002 #ifndef __P
3003 # if defined PROTOTYPES
3004 #  define __P(args) args
3005 # else
3006 #  define __P(args) ()
3007 # endif  /* GCC.  */
3008 #endif /* __P */
3009
3010 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
3011 #ifndef NOT_C_CODE
3012 #ifdef HAVE_STRING_H
3013 #include "string.h"
3014 #endif
3015 #ifdef HAVE_STRINGS_H
3016 #include "strings.h"  /* May be needed for bcopy & al. */
3017 #endif
3018 #ifdef HAVE_STDLIB_H
3019 #include <stdlib.h>
3020 #endif
3021 #ifndef __GNUC__
3022 # ifdef HAVE_ALLOCA_H
3023 #  include <alloca.h>
3024 # else /* AIX files deal with #pragma.  */
3025 #  ifndef alloca /* predefined by HP cc +Olibcalls */
3026 char *alloca ();
3027 #  endif
3028 # endif /* HAVE_ALLOCA_H */
3029 #endif /* __GNUC__ */
3030 #ifndef HAVE_SIZE_T
3031 typedef unsigned size_t;
3032 #endif
3033 #endif /* NOT_C_CODE */
3034
3035 /* Define HAVE_X_I18N if we have usable i18n support.  */
3036
3037 #ifdef HAVE_X11R6
3038 #define HAVE_X_I18N
3039 #elif !defined X11R5_INHIBIT_I18N
3040 #define HAVE_X_I18N
3041 #endif
3042
3043 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3044
3045 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3046 #define HAVE_X11R6_XIM
3047 #endif
3048
3049 #if defined __GNUC__ && (__GNUC__ > 2 \
3050                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3051 #define NO_RETURN       __attribute__ ((__noreturn__))
3052 #else
3053 #define NO_RETURN       /* nothing */
3054 #endif
3055
3056 /* These won't be used automatically yet.  We also need to know, at least,
3057    that the stack is continuous.  */
3058 #ifdef __GNUC__
3059 #  ifndef GC_SETJMP_WORKS
3060   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3061      see NON_SAVING_SETJMP in the target descriptions.  */
3062   /* Exceptions (see NON_SAVING_SETJMP in target description) are
3063      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3064      Fixme: Deal with SVR3.  */
3065 #    define GC_SETJMP_WORKS 1
3066 #  endif
3067 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3068 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3069 #  endif
3070 #endif
3071
3072 #ifndef HAVE_BCOPY
3073 #define bcopy(a,b,s) memcpy (b,a,s)
3074 #endif
3075 #ifndef HAVE_BZERO
3076 #define bzero(a,s) memset (a,0,s)
3077 #endif
3078 #ifndef HAVE_BCMP
3079 #define BCMP memcmp
3080 #endif
3081
3082 #endif /* EMACS_CONFIG_H */
3083
3084 /*
3085 Local Variables:
3086 mode: c
3087 End:
3088 */
3089 ])dnl
3090
3091 #### Report on what we decided to do.
3092 #### Report GTK as a toolkit, even if it doesn't use Xt.
3093 #### It makes printing result more understandable as using GTK sets
3094 #### toolkit_scroll_bars to yes by default.
3095 if test "${HAVE_GTK}" = "yes"; then
3096   USE_X_TOOLKIT=GTK
3097 fi
3098
3099 echo "
3100 Configured for \`${canonical}'.
3101
3102   Where should the build process find the source code?    ${srcdir}
3103   What operating system and machine description files should Emacs use?
3104         \`${opsysfile}' and \`${machfile}'
3105   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3106   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3107   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3108   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3109   What window system should Emacs use?                    ${window_system}
3110   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3111
3112 if test -n "${x_includes}"; then
3113 echo "  Where do we find X Windows header files?                ${x_includes}"
3114 else
3115 echo "  Where do we find X Windows header files?                Standard dirs"
3116 fi
3117 if test -n "${x_libraries}"; then
3118 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3119 else
3120 echo "  Where do we find X Windows libraries?                   Standard dirs"
3121 fi
3122
3123 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3124 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3125 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3126 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3127 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3128 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3129 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3130 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3131 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3132 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3133
3134 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3135 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3136 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3137 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3138
3139 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3140 echo
3141
3142 if test $USE_XASSERTS = yes; then
3143    echo "  Compiling with asserts turned on."
3144    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3145 fi
3146
3147 echo
3148
3149 if test "$HAVE_NS" = "yes"; then
3150    echo
3151    echo "You must run \"make install\" in order to test the built application.
3152 The installed application will go to nextstep/Emacs.app and can be
3153 run or moved from there."
3154    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3155       echo "The application will be fully self-contained."
3156     else
3157       echo "The lisp resources for the application will be installed under ${prefix}.
3158 You may need to run \"make install\" with sudo.  The application will fail
3159 to run if these resources are not installed."
3160    fi
3161    echo
3162 fi
3163
3164 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3165   echo "D-Bus integration has been tested for GNU/Linux only."
3166   echo
3167 fi
3168
3169
3170 # Remove any trailing slashes in these variables.
3171 [test "${prefix}" != NONE &&
3172   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3173 test "${exec_prefix}" != NONE &&
3174   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3175
3176 # Now get this: Some word that is part of the ${srcdir} directory name
3177 # or the ${configuration} value might, just might, happen to be an
3178 # identifier like `sun4' or `i386' or something, and be predefined by
3179 # the C preprocessor to some helpful value like 1, or maybe the empty
3180 # string.  Needless to say consequent macro substitutions are less
3181 # than conducive to the makefile finding the correct directory.
3182 [cpp_undefs="`echo $srcdir $configuration $canonical |
3183   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3184   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3185
3186 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3187 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3188 ## from Makefile.c can correctly provide the arg `-traditional' to the
3189 ## C preprocessor.
3190
3191 AC_EGREP_CPP(yes..yes,
3192         [yes..yes],
3193         CPP_NEED_TRADITIONAL=no,
3194         CPP_NEED_TRADITIONAL=yes)
3195
3196 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3197         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3198         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3199         lwlib/Makefile lisp/Makefile leim/Makefile, [
3200
3201 ### Make the necessary directories, if they don't exist.
3202 for dir in etc lisp ; do
3203   test -d ${dir} || mkdir ${dir}
3204 done
3205
3206 # Build src/Makefile from ${srcdir}/src/Makefile.c
3207 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3208 # This must be done after src/config.h is built, since we rely on that file.
3209
3210 echo creating src/epaths.h
3211 ${MAKE-make} epaths-force
3212
3213 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3214 # `..' to `. .'  unless invoked with -traditional
3215
3216 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3217   CPPFLAGS="$CPPFLAGS -traditional"
3218 fi
3219
3220 echo creating lib-src/Makefile
3221 ( cd lib-src
3222   rm -f junk.c junk1.c junk2.c
3223   sed -e '/start of cpp stuff/q' \
3224       < Makefile.c > junk1.c
3225   sed -e '1,/start of cpp stuff/d'\
3226       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3227       < Makefile.c > junk.c
3228   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3229       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3230   cat junk1.c junk2.c > Makefile.new
3231   rm -f junk.c junk1.c junk2.c
3232   chmod 444 Makefile.new
3233   mv -f Makefile.new Makefile
3234 )
3235
3236 echo creating src/Makefile
3237 ( cd src
3238   rm -f junk.c junk1.c junk2.c
3239   sed -e '/start of cpp stuff/q' \
3240       < Makefile.c > junk1.c
3241   sed -e '1,/start of cpp stuff/d'\
3242       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3243       < Makefile.c > junk.c
3244   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3245       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3246   cat junk1.c junk2.c > Makefile.new
3247   rm -f junk.c junk1.c junk2.c
3248   chmod 444 Makefile.new
3249   mv -f Makefile.new Makefile
3250 )
3251
3252 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3253   echo creating src/.gdbinit
3254   echo source $srcdir/src/.gdbinit > src/.gdbinit
3255 fi
3256
3257 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3258
3259 m4_if(dnl       Do not change this comment
3260    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3261 )dnl