configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation; either version 3, or (at your option)
  14 dnl  any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  23 dnl  Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 dnl  Boston, MA 02110-1301, USA.
  25
  26 AC_PREREQ(2.61)dnl
  27 AC_INIT(emacs, 23.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 lispdir='${datadir}/emacs/${version}/lisp'
  36 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  37 '${datadir}/emacs/site-lisp'
  38 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  39 etcdir='${datadir}/emacs/${version}/etc'
  40 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  41 docdir='${datadir}/emacs/${version}/etc'
  42 gamedir='${localstatedir}/games/emacs'
  43
  44 gameuser=games
  45
  46 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  47 dnl Create a new --with option that defaults to being disabled.
  48 dnl NAME is the base name of the option.  The shell variable with_NAME
  49 dnl   will be set to either the user's value (if the option is
  50 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  51 dnl   option is not specified).  Note that the shell variable name is
  52 dnl   constructed as autoconf does, by replacing non-alphanumeric
  53 dnl   characters with "_".
  54 dnl HELP-STRING is the help text for the option.
  55 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  56   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  57     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  58 ])dnl
  59
  60 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  61 dnl Create a new --with option that defaults to being enabled.  NAME
  62 dnl   is the base name of the option.  The shell variable with_NAME
  63 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  64 dnl   'yes' (if the option is not specified).  Note that the shell
  65 dnl   variable name is constructed as autoconf does, by replacing
  66 dnl   non-alphanumeric characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  70    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  71 ])dnl
  72
  73 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  74 if test "$with_pop" = yes; then
  75    AC_DEFINE(MAIL_USE_POP)
  76 fi
  77 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  78
  79 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  80 if test "$with_kerberos" = yes; then
  81    AC_DEFINE(KERBEROS)
  82 fi
  83 AH_TEMPLATE(KERBEROS,
  84             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  85
  86 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  87 if test "${with_kerberos5}" = yes; then
  88   if test "${with_kerberos}" != yes; then
  89     with_kerberos=yes
  90     AC_DEFINE(KERBEROS)
  91   fi
  92   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  93 fi
  94
  95 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  96 if test "$with_hesiod" = yes; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 101
 102 dnl FIXME currently it is not the last.
 103 dnl This should be the last --with option, because --with-x is
 104 dnl added later on when we find the path of X, and it's best to
 105 dnl keep them together visually.
 106 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 107  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 108 [         case "${withval}" in
 109             y | ye | yes )      val=gtk ;;
 110             n | no )            val=no  ;;
 111             l | lu | luc | luci | lucid )       val=lucid ;;
 112             a | at | ath | athe | athen | athena )      val=athena ;;
 113             m | mo | mot | moti | motif )       val=motif ;;
 114             g | gt | gtk  )     val=gtk ;;
 115             * )
 116 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 117 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 118 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 119             ;;
 120           esac
 121           with_x_toolkit=$val
 122 ])
 123
 124 dnl _ON results in a '--without' option in the --help output, so
 125 dnl the help text should refer to "don't compile", etc.
 126 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 127 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 128 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 129 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 130 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 131 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 132
 133 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 134 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 135 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 136 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 137
 138 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 139 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 140 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 141 OPTION_DEFAULT_OFF([carbon],[use Carbon GUI on Mac OS X.  This is unsupported!])
 142
 143 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 144 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 145
 146 dnl Can remove these in Emacs 24.
 147 AC_ARG_WITH([gtk],,
 148   AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 149 specify a toolkit.]),,)
 150
 151 AC_ARG_WITH([gcc],,
 152   AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 153   variable to specify a compiler.]),,)
 154
 155 AC_ARG_WITH([pkg-config-prog],dnl
 156 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 157                   [Path to pkg-config for finding GTK and librsvg])])
 158 if test "X${with_pkg_config_prog}" != X; then
 159    if test "${with_pkg_config_prog}" != yes; then
 160       PKG_CONFIG="${with_pkg_config_prog}"
 161    fi
 162 fi
 163
 164 AC_ARG_ENABLE(carbon-app,
 165 [AS_HELP_STRING([--enable-carbon-app@<:@=DIR@:>@],
 166                 [specify install directory for Emacs.app on Mac OS X
 167                  [DIR=/Application]])],
 168 [ carbon_appdir_x=${enableval}])
 169
 170 ## Enabled by default.
 171 AC_ARG_ENABLE(font-backend,
 172 [AS_HELP_STRING([--disable-font-backend],[don't compile font-backend support])],
 173       USE_FONT_BACKEND=$enableval,
 174       USE_FONT_BACKEND=yes)
 175
 176 AC_ARG_ENABLE(asserts,
 177 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 178       USE_XASSERTS=$enableval,
 179       USE_XASSERTS=no)
 180
 181 AC_ARG_ENABLE(maintainer-mode,
 182 [AS_HELP_STRING([--enable-maintainer-mode],
 183                 [enable make rules and dependencies not useful (and sometimes
 184                  confusing) to the casual installer])],
 185       USE_MAINTAINER_MODE=$enableval,
 186       USE_MAINTAINER_MODE=no)
 187 if test $USE_MAINTAINER_MODE = yes; then
 188   MAINT=
 189 else
 190   MAINT=#
 191 fi
 192 AC_SUBST(MAINT)
 193
 194 AC_ARG_ENABLE(locallisppath,
 195 [AS_HELP_STRING([--enable-locallisppath=PATH],
 196                 [directories Emacs should search for lisp files specific
 197                  to this site])],
 198 if test "${enableval}" = "no"; then
 199   locallisppath=
 200 elif test "${enableval}" != "yes"; then
 201   locallisppath=${enableval}
 202 fi)
 203
 204 #### Make srcdir absolute, if it isn't already.  It's important to
 205 #### avoid running the path through pwd unnecessarily, since pwd can
 206 #### give you automounter prefixes, which can go away.  We do all this
 207 #### so Emacs can find its files when run uninstalled.
 208 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 209 unset CDPATH
 210 case "${srcdir}" in
 211   /* ) ;;
 212   . )
 213     ## We may be able to use the $PWD environment variable to make this
 214     ## absolute.  But sometimes PWD is inaccurate.
 215     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 216     ## but that tested only for a well-formed and valid PWD,
 217     ## it did not object when PWD was well-formed and valid but just wrong.
 218     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 219     then
 220       srcdir="$PWD"
 221     else
 222       srcdir="`(cd ${srcdir}; pwd)`"
 223     fi
 224   ;;
 225   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 226 esac
 227
 228 #### Check if the source directory already has a configured system in it.
 229 if test `pwd` != `(cd ${srcdir} && pwd)` \
 230    && test -f "${srcdir}/src/config.h" ; then
 231   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 232    as a build directory right now; it has been configured in its own
 233    right.  To configure in another directory as well, you MUST
 234    use GNU make.  If you do not have GNU make, then you must
 235    now do `make distclean' in ${srcdir},
 236    and then run $0 again.]])
 237 fi
 238
 239 #### Given the configuration name, set machfile and opsysfile to the
 240 #### names of the m/*.h and s/*.h files we should use.
 241
 242 ### Canonicalize the configuration name.
 243
 244 AC_CANONICAL_HOST
 245 canonical=$host
 246 configuration=${host_alias-${build_alias-$host}}
 247
 248 dnl This used to use changequote, but, apart from `changequote is evil'
 249 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 250 dnl the great gob of text.  Thus it's not processed for possible expansion.
 251 dnl Just make sure the brackets remain balanced.
 252 dnl
 253 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 254 dnl indicated by comments.
 255 dnl quotation begins
 256 [
 257
 258 ### If you add support for a new configuration, add code to this
 259 ### switch statement to recognize your configuration name and select
 260 ### the appropriate operating system and machine description files.
 261
 262 ### You would hope that you could choose an m/*.h file pretty much
 263 ### based on the machine portion of the configuration name, and an s-
 264 ### file based on the operating system portion.  However, it turns out
 265 ### that each m/*.h file is pretty manufacturer-specific - for
 266 ### example hp9000s300.h is a 68000 machine;
 267 ### mips.h, pmax.h are all MIPS
 268 ### machines.  So we basically have to have a special case for each
 269 ### configuration name.
 270 ###
 271 ### As far as handling version numbers on operating systems is
 272 ### concerned, make sure things will fail in a fixable way.  If
 273 ### /etc/MACHINES doesn't say anything about version numbers, be
 274 ### prepared to handle anything reasonably.  If version numbers
 275 ### matter, be sure /etc/MACHINES says something about it.
 276 ###
 277 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 278 ### "System V Release 4"; he writes, "The old convention encouraged
 279 ### confusion between `system' and `release' levels'."
 280
 281 machine='' opsys='' unported=no
 282 case "${canonical}" in
 283
 284   ## FreeBSD ports
 285   *-*-freebsd* )
 286     opsys=freebsd
 287     case "${canonical}" in
 288       alpha*-*-freebsd*)        machine=alpha ;;
 289       arm*-*-freebsd*)          machine=arm ;;
 290       ia64-*-freebsd*)          machine=ia64 ;;
 291       sparc64-*-freebsd*)       machine=sparc ;;
 292       powerpc-*-freebsd*)       machine=macppc ;;
 293       i[3456]86-*-freebsd*)     machine=intel386 ;;
 294       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 295     esac
 296   ;;
 297
 298   ## FreeBSD kernel + glibc based userland
 299   *-*-kfreebsd*gnu* )
 300     opsys=gnu-kfreebsd
 301     case "${canonical}" in
 302       alpha*-*-kfreebsd*)       machine=alpha ;;
 303       ia64-*-kfreebsd*)         machine=ia64 ;;
 304       sparc64-*-kfreebsd*)      machine=sparc ;;
 305       powerpc-*-kfreebsd*)      machine=macppc ;;
 306       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 307       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 308     esac
 309   ;;
 310
 311   ## NetBSD ports
 312   *-*-netbsd* )
 313     opsys=netbsd
 314     if test -f /usr/lib/crti.o; then]
 315 dnl The close and open brackets here are because this section is quoted --
 316 dnl see the `changequote' comment above.
 317       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 318 [   fi
 319
 320     case "${canonical}" in
 321       alpha*-*-netbsd*) machine=alpha ;;
 322       i[3456]86-*-netbsd*) machine=intel386 ;;
 323       m68k-*-netbsd*)
 324                         # This is somewhat bogus.
 325                         machine=hp9000s300 ;;
 326       mips-*-netbsd*)   machine=pmax ;;
 327       mipsel-*-netbsd*) machine=pmax ;;
 328       mipseb-*-netbsd*) machine=pmax ;;
 329       powerpc-*-netbsd*) machine=macppc ;;
 330       sparc*-*-netbsd*) machine=sparc ;;
 331       vax-*-netbsd*)    machine=vax ;;
 332       arm-*-netbsd*)    machine=arm ;;
 333       x86_64-*-netbsd*) machine=amdx86-64 ;;
 334       hppa-*-netbsd*)   machine=hp800 ;;
 335     esac
 336   ;;
 337
 338   ## OpenBSD ports
 339   *-*-openbsd* )
 340     opsys=openbsd
 341     case "${canonical}" in
 342       alpha*-*-openbsd*)        machine=alpha ;;
 343       arm-*-openbsd*)          machine=arm ;;
 344       hppa-*-openbsd*)         machine=hp9000s300 ;;
 345       i386-*-openbsd*)         machine=intel386 ;;
 346       m68k-*-openbsd*)         machine=hp9000s300 ;;
 347       powerpc-*-openbsd*)      machine=macppc ;;
 348       sparc*-*-openbsd*)       machine=sparc ;;
 349       vax-*-openbsd*)          machine=vax ;;
 350       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 351     esac
 352   ;;
 353
 354   ## LynxOS ports
 355   *-*-lynxos* )
 356     opsys=lynxos
 357     case "${canonical}" in
 358       i[3456]86-*-lynxos*) machine=intel386 ;;
 359       powerpc-*-lynxos*) machine=powerpc ;;
 360     esac
 361   ;;
 362
 363   ## BSDI ports
 364   *-*-bsdi* )
 365     opsys=bsdi
 366     case "${canonical}" in
 367       i[345]86-*-bsdi*) machine=intel386 ;;
 368       sparc-*-bsdi*)  machine=sparc ;;
 369       powerpc-*-bsdi*)  machine=macppc ;;
 370     esac
 371     case "${canonical}" in
 372       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 373       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 374       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 375       *-*-bsdi3* )              opsys=bsdos3 ;;
 376       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 377     esac
 378   ;;
 379
 380   alpha*-*-linux-gnu* )
 381     machine=alpha opsys=gnu-linux
 382   ;;
 383
 384   arm*-*-linux-gnu* )
 385     machine=arm opsys=gnu-linux
 386   ;;
 387
 388   ## Apple Darwin / Mac OS X
 389   *-apple-darwin* )
 390     case "${canonical}" in
 391       i[3456]86-* )  machine=intel386 ;;
 392       powerpc-* )    machine=powermac ;;
 393       * )            unported=yes ;;
 394     esac
 395     opsys=darwin
 396     # Define CPP as follows to make autoconf work correctly.
 397     CPP="${CC-cc} -E -no-cpp-precomp"
 398     # Use fink packages if available.
 399     if test -d /sw/include && test -d /sw/lib; then
 400       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 401       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 402       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 403     fi
 404   ;;
 405
 406   ## Cubix QBx/386
 407   i[3456]86-cubix-sysv* )
 408     machine=intel386 opsys=usg5-3
 409   ;;
 410
 411   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 412     machine=pmax opsys=bsd4-2
 413   ;;
 414   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 415     machine=pmax opsys=bsd4-3
 416   ;;
 417   mips-dec-ultrix* )
 418     machine=pmax opsys=ultrix4-3
 419   ;;
 420   ## HP 9000 series 200 or 300
 421   m68*-hp-bsd* )
 422     machine=hp9000s300 opsys=bsd4-3
 423   ;;
 424   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 425   m68*-hp-hpux* )
 426     case "`uname -r`" in
 427       ## Someone's system reports A.B8.05 for this.
 428       ## I wonder what other possibilities there are.
 429       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 430       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 431       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 432       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 433       *) machine=hp9000s300 opsys=hpux ;;
 434     esac
 435   ;;
 436
 437   ## HP 9000 series 700 and 800, running HP/UX
 438   hppa*-hp-hpux7* )
 439     machine=hp800 opsys=hpux
 440   ;;
 441   hppa*-hp-hpux8* )
 442     machine=hp800 opsys=hpux8
 443   ;;
 444   hppa*-hp-hpux9shr* )
 445     machine=hp800 opsys=hpux9shr
 446   ;;
 447   hppa*-hp-hpux9* )
 448     machine=hp800 opsys=hpux9
 449   ;;
 450   hppa*-hp-hpux10.2* )
 451     machine=hp800 opsys=hpux10-20
 452   ;;
 453   hppa*-hp-hpux10* )
 454     machine=hp800 opsys=hpux10
 455   ;;
 456   hppa*-hp-hpux1[1-9]* )
 457     machine=hp800 opsys=hpux11
 458     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 459   ;;
 460
 461   hppa*-*-linux-gnu* )
 462     machine=hp800 opsys=gnu-linux
 463   ;;
 464
 465   ## HP 9000 series 700 and 800, running HP/UX
 466   hppa*-hp-hpux* )
 467     ## Cross-compilation?  Nah!
 468     case "`uname -r`" in
 469       ## Someone's system reports A.B8.05 for this.
 470       ## I wonder what other possibilities there are.
 471       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 472       *.08.* ) machine=hp800 opsys=hpux8 ;;
 473       *.09.* ) machine=hp800 opsys=hpux9 ;;
 474       *) machine=hp800 opsys=hpux10 ;;
 475     esac
 476   ;;
 477   hppa*-*-nextstep* )
 478     machine=hp800 opsys=nextstep
 479   ;;
 480
 481   ## IBM machines
 482   i370-ibm-aix*)
 483     machine=ibm370aix opsys=usg5-3
 484   ;;
 485   s390-*-linux-gnu* )
 486     machine=ibms390 opsys=gnu-linux
 487   ;;
 488   s390x-*-linux-gnu* )
 489     machine=ibms390x opsys=gnu-linux
 490   ;;
 491   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 492     machine=ibmrs6000 opsys=aix3-1
 493   ;;
 494   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 495     machine=ibmrs6000 opsys=aix3-2-5
 496   ;;
 497   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 498     machine=ibmrs6000 opsys=aix4-1
 499   ;;
 500   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 501     machine=ibmrs6000 opsys=aix4-2
 502   ;;
 503   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 504     machine=ibmrs6000 opsys=aix4-2
 505   ;;
 506   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 507     machine=ibmrs6000 opsys=aix4-2
 508   ;;
 509   rs6000-ibm-aix5* | powerpc-ibm-aix6*  )
 510     machine=ibmrs6000 opsys=aix4-2
 511   ;;
 512   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 513     machine=ibmrs6000 opsys=aix4
 514   ;;
 515   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 516     machine=ibmrs6000 opsys=aix4-1
 517   ;;
 518   rs6000-ibm-aix* | powerpc-ibm-aix* )
 519     machine=ibmrs6000 opsys=aix3-2
 520   ;;
 521
 522   ## Prime EXL
 523   i[3456]86-prime-sysv* )
 524     machine=i386 opsys=usg5-3
 525   ;;
 526
 527   ## ncr machine running svr4.3.
 528   i[3456]86-ncr-sysv4.3 )
 529     machine=ncr386 opsys=usg5-4-3
 530   ;;
 531
 532   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 533   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 534   i[3456]86-ncr-sysv* )
 535     machine=ncr386 opsys=usg5-4-2
 536   ;;
 537
 538   ## Macintosh PowerPC
 539   powerpc*-*-linux-gnu* )
 540     machine=macppc opsys=gnu-linux
 541   ;;
 542
 543   ## Workstations sold by MIPS
 544   ## This is not necessarily all workstations using the MIPS processor -
 545   ## Irises are produced by SGI, and DECstations by DEC.
 546
 547   mips-mips-bsd* )
 548     machine=mips opsys=bsd4-3
 549   ;;
 550   mips-mips-* )
 551     machine=mips opsys=usg5-2-2
 552   ;;
 553
 554   ## NeXT
 555   m68*-next-* | m68k-*-nextstep* )
 556     machine=m68k opsys=nextstep
 557   ;;
 558
 559   ## NEC EWS4800
 560   mips-nec-sysv4*)
 561   machine=ews4800 opsys=ux4800
 562   ;;
 563
 564   ## Siemens Nixdorf
 565   mips-siemens-sysv* | mips-sni-sysv*)
 566     machine=mips-siemens opsys=usg5-4
 567     NON_GNU_CC=/usr/ccs/bin/cc
 568     NON_GNU_CPP=/usr/ccs/lib/cpp
 569   ;;
 570
 571   ## Silicon Graphics machines
 572   ## Iris 4D
 573   mips-sgi-irix6.5 )
 574     machine=iris4d opsys=irix6-5
 575     # Without defining _LANGUAGE_C, things get masked out in the headers
 576     # so that, for instance, grepping for `free' in stdlib.h fails and
 577     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 578     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 579     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 580   ;;
 581
 582   ## Suns
 583   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 584     machine=sparc opsys=gnu-linux
 585   ;;
 586
 587   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 588     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 589     | rs6000-*-solaris2*)
 590     case "${canonical}" in
 591       i[3456]86-*-* )     machine=intel386 ;;
 592       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 593       powerpcle* )      machine=powerpcle ;;
 594       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 595       sparc* )          machine=sparc ;;
 596       * )               unported=yes ;;
 597     esac
 598     case "${canonical}" in
 599       *-sunos5.3* | *-solaris2.3* )
 600                 opsys=sol2-3
 601                 NON_GNU_CPP=/usr/ccs/lib/cpp
 602                 ;;
 603       *-sunos5.4* | *-solaris2.4* )
 604                 opsys=sol2-4
 605                 NON_GNU_CPP=/usr/ccs/lib/cpp
 606                 RANLIB="ar -ts"
 607                 ;;
 608       *-sunos5.5* | *-solaris2.5* )
 609                 opsys=sol2-5
 610                 NON_GNU_CPP=/usr/ccs/lib/cpp
 611                 RANLIB="ar -ts"
 612                 ;;
 613       *-sunos5.6* | *-solaris2.6* )
 614                 opsys=sol2-6
 615                 NON_GNU_CPP=/usr/ccs/lib/cpp
 616                 RANLIB="ar -ts"
 617                 ;;
 618       *-sunos5* | *-solaris* )
 619                 opsys=sol2-6
 620                 emacs_check_sunpro_c=yes
 621                 NON_GNU_CPP=/usr/ccs/lib/cpp
 622                 ;;
 623       *                   ) opsys=bsd4-2   ;;
 624     esac
 625     ## Watch out for a compiler that we know will not work.
 626     case "${canonical}" in
 627      *-solaris* | *-sunos5* )
 628                 if [ "x$CC" = x/usr/ucb/cc ]; then
 629                   ## /usr/ucb/cc doesn't work;
 630                   ## we should find some other compiler that does work.
 631                   unset CC
 632                 fi
 633                 ;;
 634       *) ;;
 635     esac
 636   ;;
 637   sparc-*-nextstep* )
 638     machine=sparc opsys=nextstep
 639   ;;
 640
 641   ## Tandem Integrity S2
 642   mips-tandem-sysv* )
 643     machine=tandem-s2 opsys=usg5-3
 644   ;;
 645
 646   ## Vaxen.
 647   vax-dec-* )
 648     machine=vax
 649     case "${canonical}" in
 650       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 651       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 652       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 653       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 654       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 655       *-vms* )                                          opsys=vms ;;
 656       * )                                               unported=yes
 657     esac
 658   ;;
 659
 660   ## IA-64
 661   ia64*-*-linux* )
 662     machine=ia64 opsys=gnu-linux
 663   ;;
 664
 665   ## Intel 386 machines where we don't care about the manufacturer
 666   i[3456]86-*-* )
 667     machine=intel386
 668     case "${canonical}" in
 669       *-cygwin )                opsys=cygwin ;;
 670       *-darwin* )               opsys=darwin
 671                                 CPP="${CC-cc} -E -no-cpp-precomp"
 672                                 ;;
 673       *-linux-gnu* )            opsys=gnu-linux ;;
 674       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 675       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 676       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 677       *-386bsd* )               opsys=386bsd ;;
 678       *-nextstep* )             opsys=nextstep ;;
 679       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 680     esac
 681   ;;
 682
 683   ## m68k Linux-based GNU system
 684   m68k-*-linux-gnu* )
 685     machine=m68k opsys=gnu-linux
 686   ;;
 687
 688   ## Mips Linux-based GNU system
 689   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 690     machine=mips opsys=gnu-linux
 691   ;;
 692
 693   ## UXP/DS
 694   sparc-fujitsu-sysv4* )
 695     machine=sparc opsys=uxpds
 696     NON_GNU_CPP=/usr/ccs/lib/cpp
 697     RANLIB="ar -ts"
 698   ;;
 699
 700   ## AMD x86-64 Linux-based GNU system
 701   x86_64-*-linux-gnu* )
 702     machine=amdx86-64 opsys=gnu-linux
 703   ;;
 704
 705   ## Tensilica Xtensa Linux-based GNU system
 706   xtensa*-*-linux-gnu* )
 707     machine=xtensa opsys=gnu-linux
 708     ;;
 709
 710   * )
 711     unported=yes
 712   ;;
 713 esac
 714
 715 ### If the code above didn't choose an operating system, just choose
 716 ### an operating system based on the configuration name.  You really
 717 ### only want to use this when you have no idea what the right
 718 ### operating system is; if you know what operating systems a machine
 719 ### runs, it's cleaner to make it explicit in the case statement
 720 ### above.
 721 if test x"${opsys}" = x; then
 722   case "${canonical}" in
 723     *-gnu* )                            opsys=gnu ;;
 724     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 725     *-bsd4.2 )                          opsys=bsd4-2 ;;
 726     *-bsd4.3 )                          opsys=bsd4-3 ;;
 727     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 728     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 729     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 730     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 731     *-sysv4.2uw* )                      opsys=unixware ;;
 732     *-sysv5uw* )                        opsys=unixware ;;
 733     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 734     *-sysv4.1* | *-sysvr4.1* )
 735         NON_GNU_CPP=/usr/lib/cpp
 736         opsys=usg5-4 ;;
 737     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 738         if [ x$NON_GNU_CPP = x ]; then
 739           if [ -f /usr/ccs/lib/cpp ]; then
 740             NON_GNU_CPP=/usr/ccs/lib/cpp
 741           else
 742             NON_GNU_CPP=/lib/cpp
 743           fi
 744         fi
 745         opsys=usg5-4-2 ;;
 746     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 747     * )
 748       unported=yes
 749     ;;
 750   esac
 751 fi
 752
 753 ### Tests for sytems that we beleive are obsolete and should be desupported.
 754
 755 case "${machine}" in
 756      pmax | hp9000s300 | ibm370aix | ncr386 | ews4800 | mips-siemens | powerpcle | tandem-s2 )
 757           echo "The system that you are configuring on: ${canonical} is considered to be obsolete"
 758           echo "and it is planned to be desupported in the next version of Emacs"
 759           echo "Please email emacs-devel@gnu.org as soon as possible if this system is still in use."
 760           echo "The code is still functional, but you need to edit the 'configure' script and remove the"
 761           echo "exit 33 line.  After that you can run configure again and 'complete' the build."
 762           exit 33
 763           ;;
 764 esac
 765
 766 case "${opsys}" in
 767      bsd386 | bsdos2-1 |  bsdos2 | bsdos3 | bsdos4 | bsd4-1 | bsd4-2 | bsd4-3 | usg5-0 | usg5-2-2 | usg5-2 | usg5-3 | ultrix4-3 | 386bsd | hpux | hpux8 | hpux9 | hpux9shr | hpux10 | hpux10-20 | aix3-1 | aix3-2-5 | aix3-2 | aix4-1 | nextstep | ux4800 | uxpds | uxpv )
 768           echo "The system that you are configuring on: ${canonical} is considered to be obsolete"
 769           echo "and it is planned to be desupported in the next version of Emacs"
 770           echo "Please email emacs-devel@gnu.org as soon as possible if this system is still in use."
 771           echo "The code is still functional, but you need to edit the 'configure' script and remove the"
 772           echo "'exit 44' line.  After that you can run 'configure' again and complete the build."
 773           exit 44
 774           ;;
 775 esac
 776
 777 ]
 778 dnl quotation ends
 779
 780 if test $unported = yes; then
 781   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 782 Check `etc/MACHINES' for recognized configuration names.])
 783 fi
 784
 785 machfile="m/${machine}.h"
 786 opsysfile="s/${opsys}.h"
 787
 788
 789 #### Choose a compiler.
 790 test -n "$CC" && cc_specified=yes
 791
 792 # Save the value of CFLAGS that the user specified.
 793 SPECIFIED_CFLAGS="$CFLAGS"
 794
 795 dnl Sets GCC=yes if using gcc.
 796 AC_PROG_CC
 797
 798 # On Suns, sometimes $CPP names a directory.
 799 if test -n "$CPP" && test -d "$CPP"; then
 800   CPP=
 801 fi
 802
 803 ## If not using gcc, and on Solaris, and no CPP specified, see if
 804 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 805 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 806  test x"$CPP" = x; then
 807   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 808   AC_CACHE_VAL(emacs_cv_sunpro_c,
 809   [AC_TRY_LINK([],
 810 [#ifndef __SUNPRO_C
 811 fail;
 812 #endif
 813 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 814   AC_MSG_RESULT($emacs_cv_sunpro_c)
 815
 816   if test x"$emacs_cv_sunpro_c" = xyes; then
 817     NON_GNU_CPP="$CC -E -Xs"
 818   fi
 819 fi
 820
 821 #### Some systems specify a CPP to use unless we are using GCC.
 822 #### Now that we know whether we are using GCC, we can decide whether
 823 #### to use that one.
 824 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 825 then
 826   CPP="$NON_GNU_CPP"
 827 fi
 828
 829 #### Some systems specify a CC to use unless we are using GCC.
 830 #### Now that we know whether we are using GCC, we can decide whether
 831 #### to use that one.
 832 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 833   test x$cc_specified != xyes
 834 then
 835   CC="$NON_GNU_CC"
 836 fi
 837
 838 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 839 then
 840   CC="$CC $GCC_TEST_OPTIONS"
 841 fi
 842
 843 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 844 then
 845   CC="$CC $NON_GCC_TEST_OPTIONS"
 846 fi
 847
 848 dnl checks for Unix variants
 849 AC_AIX
 850 AC_GNU_SOURCE
 851
 852 ### Use -Wno-pointer-sign if the compiler supports it
 853 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 854 SAVE_CFLAGS="$CFLAGS"
 855 CFLAGS="$CFLAGS -Wno-pointer-sign"
 856 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 857 if test $has_option = yes; then
 858    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 859 fi
 860 AC_MSG_RESULT($has_option)
 861 CFLAGS="$SAVE_CFLAGS"
 862 unset has_option
 863 unset SAVE_CFLAGS
 864
 865 #### Some other nice autoconf tests.
 866
 867 dnl checks for programs
 868 AC_PROG_LN_S
 869 AC_PROG_CPP
 870 AC_PROG_INSTALL
 871 if test "x$RANLIB" = x; then
 872   AC_PROG_RANLIB
 873 fi
 874 AC_PATH_PROG(INSTALL_INFO, install-info)
 875 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 876 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 877 dnl Don't use GZIP, which is used by gzip for additional parameters.
 878 AC_PATH_PROG(GZIP_PROG, gzip)
 879
 880
 881 ## Need makeinfo >= 4.6 (?) to build the manuals.
 882 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 883 dnl By this stage, configure has already checked for egrep and set EGREP,
 884 dnl or exited with an error if no egrep was found.
 885 if test "$MAKEINFO" != "no" && \
 886   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 887    MAKEINFO=no
 888 fi
 889
 890 if test "$MAKEINFO" = "no"; then
 891   AC_MSG_ERROR( [makeinfo >= 4.6 is required] )
 892 fi
 893
 894
 895 dnl Add our options to ac_link now, after it is set up.
 896
 897 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 898 then
 899   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 900 fi
 901
 902 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 903 then
 904   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 905 fi
 906
 907 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 908 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 909 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 910 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 911 dnl if not built to support GNU ld.
 912
 913 late_LDFLAGS=$LDFLAGS
 914 if test "$GCC" = yes; then
 915   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 916 else
 917   LDFLAGS="$LDFLAGS -znocombreloc"
 918 fi
 919
 920 AC_MSG_CHECKING([for -znocombreloc])
 921 AC_LINK_IFELSE([main(){return 0;}],
 922   [AC_MSG_RESULT(yes)],
 923   LDFLAGS=$late_LDFLAGS
 924   [AC_MSG_RESULT(no)])
 925
 926 #### Extract some information from the operating system and machine files.
 927
 928 AC_CHECKING([the machine- and system-dependent files to find out
 929  - which libraries the lib-src programs will want, and
 930  - whether the GNU malloc routines are usable])
 931
 932 ### First figure out CFLAGS (which we use for running the compiler here)
 933 ### and REAL_CFLAGS (which we use for real compilation).
 934 ### The two are the same except on a few systems, where they are made
 935 ### different to work around various lossages.  For example,
 936 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 937 ### as implying static linking.
 938
 939 ### If the CFLAGS env var is specified, we use that value
 940 ### instead of the default.
 941
 942 ### It's not important that this name contain the PID; you can't run
 943 ### two configures in the same directory and have anything work
 944 ### anyway.
 945 tempcname="conftest.c"
 946
 947 echo '
 948 #include "'${srcdir}'/src/'${opsysfile}'"
 949 #include "'${srcdir}'/src/'${machfile}'"
 950 #ifndef LIBS_MACHINE
 951 #define LIBS_MACHINE
 952 #endif
 953 #ifndef LIBS_SYSTEM
 954 #define LIBS_SYSTEM
 955 #endif
 956 #ifndef C_SWITCH_SYSTEM
 957 #define C_SWITCH_SYSTEM
 958 #endif
 959 #ifndef C_SWITCH_MACHINE
 960 #define C_SWITCH_MACHINE
 961 #endif
 962 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 963 configure___ c_switch_system=C_SWITCH_SYSTEM
 964 configure___ c_switch_machine=C_SWITCH_MACHINE
 965
 966 #ifndef LIB_X11_LIB
 967 #define LIB_X11_LIB -lX11
 968 #endif
 969
 970 #ifndef LIBX11_SYSTEM
 971 #define LIBX11_SYSTEM
 972 #endif
 973 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 974
 975 #ifdef UNEXEC
 976 configure___ unexec=UNEXEC
 977 #else
 978 configure___ unexec=unexec.o
 979 #endif
 980
 981 #ifdef SYSTEM_MALLOC
 982 configure___ system_malloc=yes
 983 #else
 984 configure___ system_malloc=no
 985 #endif
 986
 987 #ifdef USE_MMAP_FOR_BUFFERS
 988 configure___ use_mmap_for_buffers=yes
 989 #else
 990 configure___ use_mmap_for_buffers=no
 991 #endif
 992
 993 #ifndef C_DEBUG_SWITCH
 994 #define C_DEBUG_SWITCH -g
 995 #endif
 996
 997 #ifndef C_OPTIMIZE_SWITCH
 998 #ifdef __GNUC__
 999 #define C_OPTIMIZE_SWITCH -O2
1000 #else
1001 #define C_OPTIMIZE_SWITCH -O
1002 #endif
1003 #endif
1004
1005 #ifndef C_WARNINGS_SWITCH
1006 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
1007 #endif
1008
1009 #ifndef LD_SWITCH_MACHINE
1010 #define LD_SWITCH_MACHINE
1011 #endif
1012
1013 #ifndef LD_SWITCH_SYSTEM
1014 #define LD_SWITCH_SYSTEM
1015 #endif
1016
1017 #ifndef LD_SWITCH_X_SITE_AUX
1018 #define LD_SWITCH_X_SITE_AUX
1019 #endif
1020
1021 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1022 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1023
1024 #ifdef THIS_IS_CONFIGURE
1025
1026 /* Get the CFLAGS for tests in configure.  */
1027 #ifdef __GNUC__
1028 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1029 #else
1030 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1031 #endif
1032
1033 #else /* not THIS_IS_CONFIGURE */
1034
1035 /* Get the CFLAGS for real compilation.  */
1036 #ifdef __GNUC__
1037 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
1038 #else
1039 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1040 #endif
1041
1042 #endif /* not THIS_IS_CONFIGURE */
1043 ' > ${tempcname}
1044
1045 # The value of CPP is a quoted variable reference, so we need to do this
1046 # to get its actual value...
1047 CPP=`eval "echo $CPP"`
1048 [eval `${CPP} -Isrc ${tempcname} \
1049        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1050 if test "x$SPECIFIED_CFLAGS" = x; then
1051   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1052          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1053 else
1054   REAL_CFLAGS="$CFLAGS"
1055 fi]
1056 rm ${tempcname}
1057
1058 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1059
1060 ### Make sure subsequent tests use flags consistent with the build flags.
1061
1062 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1063   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1064 else
1065   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1066 fi
1067
1068 dnl For AC_FUNC_GETLOADAVG, at least:
1069 AC_CONFIG_LIBOBJ_DIR(src)
1070
1071 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1072 AC_SYS_LARGEFILE
1073
1074
1075 ### The standard library on x86-64 and s390x GNU/Linux distributions can
1076 ### be located in either /usr/lib64 or /usr/lib.
1077 case "${canonical}" in
1078   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1079     if test -d /usr/lib64; then
1080       AC_DEFINE(HAVE_LIB64_DIR, 1,
1081         [Define to 1 if the directory /usr/lib64 exists.])
1082 fi
1083 esac
1084
1085 dnl This function defintion taken from Gnome 2.0
1086 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1087 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1088 dnl also defines GSTUFF_PKG_ERRORS on error
1089 AC_DEFUN([PKG_CHECK_MODULES], [
1090   succeeded=no
1091
1092   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1093
1094   if test "$PKG_CONFIG" = "no" ; then
1095      ifelse([$4], , [AC_MSG_ERROR([
1096       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1097   else
1098      PKG_CONFIG_MIN_VERSION=0.9.0
1099      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1100         AC_MSG_CHECKING(for $2)
1101
1102         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1103             AC_MSG_RESULT(yes)
1104             succeeded=yes
1105
1106             AC_MSG_CHECKING($1_CFLAGS)
1107             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1108             AC_MSG_RESULT($$1_CFLAGS)
1109
1110             AC_MSG_CHECKING($1_LIBS)
1111             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1112             AC_MSG_RESULT($$1_LIBS)
1113         else
1114             AC_MSG_RESULT(no)
1115             $1_CFLAGS=""
1116             $1_LIBS=""
1117             ## If we have a custom action on failure, don't print errors, but
1118             ## do set a variable so people can do so.
1119             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1120             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1121         fi
1122
1123         AC_SUBST($1_CFLAGS)
1124         AC_SUBST($1_LIBS)
1125      else
1126         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1127         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1128      fi
1129   fi
1130
1131   if test $succeeded = yes; then
1132      ifelse([$3], , :, [$3])
1133   else
1134      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1135   fi
1136 ])
1137
1138
1139 if test "${with_sound}" != "no"; then
1140   # Sound support for GNU/Linux and the free BSDs.
1141   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1142   # Emulation library used on NetBSD.
1143   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1144   AC_SUBST(LIBSOUND)
1145
1146   ALSA_REQUIRED=1.0.0
1147   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1148   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1149   if test $HAVE_ALSA = yes; then
1150     SAVE_CFLAGS="$CFLAGS"
1151     SAVE_LDFLAGS="$LDFLAGS"
1152     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1153     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1154     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1155                     emacs_alsa_normal=yes,
1156                     emacs_alsa_normal=no)
1157     if test "$emacs_alsa_normal" != yes; then
1158       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1159                      [snd_lib_error_set_handler (0);],
1160                      emacs_alsa_subdir=yes,
1161                      emacs_alsa_subdir=no)
1162       if test "$emacs_alsa_subdir" != yes; then
1163         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1164       fi
1165       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1166     fi
1167
1168     CFLAGS="$SAVE_CFLAGS"
1169     LDFLAGS="$SAVE_LDFLAGS"
1170     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1171     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1172     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1173   fi
1174   AC_SUBST(CFLAGS_SOUND)
1175 fi
1176
1177 dnl checks for header files
1178 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1179   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1180   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1181   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1182   sys/utsname.h pwd.h)
1183
1184 AC_MSG_CHECKING(if personality LINUX32 can be set)
1185 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1186                emacs_cv_personality_linux32=yes,
1187                emacs_cv_personality_linux32=no)
1188 AC_MSG_RESULT($emacs_cv_personality_linux32)
1189
1190 if test $emacs_cv_personality_linux32 = yes; then
1191   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1192             [Define to 1 if personality LINUX32 can be set.])
1193 fi
1194
1195 dnl On Solaris 8 there's a compilation warning for term.h because
1196 dnl it doesn't define `bool'.
1197 AC_CHECK_HEADERS(term.h, , , -)
1198 AC_HEADER_STDC
1199 AC_HEADER_TIME
1200 AC_CHECK_DECLS([sys_siglist])
1201 if test $ac_cv_have_decl_sys_siglist != yes; then
1202   # For Tru64, at least:
1203   AC_CHECK_DECLS([__sys_siglist])
1204   if test $ac_cv_have_decl___sys_siglist = yes; then
1205     AC_DEFINE(sys_siglist, __sys_siglist,
1206               [Define to any substitute for sys_siglist.])
1207   fi
1208 fi
1209 AC_HEADER_SYS_WAIT
1210
1211 dnl Some systems have utime.h but don't declare the struct anyplace.
1212 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1213 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1214 #include <sys/time.h>
1215 #include <time.h>
1216 #else
1217 #ifdef HAVE_SYS_TIME_H
1218 #include <sys/time.h>
1219 #else
1220 #include <time.h>
1221 #endif
1222 #endif
1223 #ifdef HAVE_UTIME_H
1224 #include <utime.h>
1225 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1226   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1227 if test $emacs_cv_struct_utimbuf = yes; then
1228   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1229 fi
1230
1231 dnl checks for typedefs
1232 AC_TYPE_SIGNAL
1233
1234 dnl Check for speed_t typedef.
1235 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1236   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1237     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1238 if test $emacs_cv_speed_t = yes; then
1239   AC_DEFINE(HAVE_SPEED_T, 1,
1240            [Define to 1 if `speed_t' is declared by <termios.h>.])
1241 fi
1242
1243 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1244 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1245 #include <sys/time.h>
1246 #include <time.h>
1247 #else
1248 #ifdef HAVE_SYS_TIME_H
1249 #include <sys/time.h>
1250 #else
1251 #include <time.h>
1252 #endif
1253 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1254   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1255 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1256 if test $emacs_cv_struct_timeval = yes; then
1257   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1258 fi
1259
1260 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1261 AC_TRY_COMPILE([#include <math.h>],
1262 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1263   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1264 HAVE_EXCEPTION=$emacs_cv_struct_exception
1265 if test $emacs_cv_struct_exception != yes; then
1266   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1267 fi
1268
1269 AC_CHECK_HEADERS(sys/socket.h)
1270 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1271 #if HAVE_SYS_SOCKET_H
1272 #include <sys/socket.h>
1273 #endif])
1274
1275 dnl checks for structure members
1276 AC_STRUCT_TM
1277 AC_STRUCT_TIMEZONE
1278 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1279                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1280                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1281                 [#include <time.h>])
1282 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1283                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1284                   struct ifreq.ifr_addr], , ,
1285                  [AC_INCLUDES_DEFAULT
1286 #if HAVE_SYS_SOCKET_H
1287 #include <sys/socket.h>
1288 #endif
1289 #if HAVE_NET_IF_H
1290 #include <net/if.h>
1291 #endif])
1292
1293 dnl checks for compiler characteristics
1294
1295 dnl Testing __STDC__ to determine prototype support isn't good enough.
1296 dnl DEC C, for instance, doesn't define it with default options, and
1297 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1298 dnl and void *.
1299 AC_C_PROTOTYPES
1300 AC_C_VOLATILE
1301 AC_C_CONST
1302 dnl This isn't useful because we can't turn on use of `inline' unless
1303 dnl the compiler groks `extern inline'.
1304 dnl AC_C_INLINE
1305 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1306   [AC_TRY_COMPILE(, [void * foo;],
1307                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1308 if test $emacs_cv_void_star = yes; then
1309   AC_DEFINE(POINTER_TYPE, void)
1310 else
1311   AC_DEFINE(POINTER_TYPE, char)
1312 fi
1313 AH_TEMPLATE(POINTER_TYPE,
1314             [Define as `void' if your compiler accepts `void *'; otherwise
1315              define as `char'.])dnl
1316
1317
1318
1319 dnl This could be used for targets which can have both byte sexes.
1320 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1321 dnl AC_C_BIGENDIAN
1322
1323 dnl check for Make feature
1324 AC_PROG_MAKE_SET
1325
1326 dnl checks for operating system services
1327 AC_SYS_LONG_FILE_NAMES
1328
1329 #### Choose a window system.
1330
1331 AC_PATH_X
1332 if test "$no_x" = yes; then
1333   window_system=none
1334 else
1335   window_system=x11
1336 fi
1337
1338 if test "${x_libraries}" != NONE; then
1339   if test -n "${x_libraries}"; then
1340     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1341     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1342   fi
1343   x_default_search_path=""
1344   x_search_path=${x_libraries}
1345   if test -z "${x_search_path}"; then
1346     x_search_path=/usr/lib
1347   fi
1348   for x_library in `echo ${x_search_path}: | \
1349                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1350     x_search_path="\
1351 ${x_library}/X11/%L/%T/%N%C%S:\
1352 ${x_library}/X11/%l/%T/%N%C%S:\
1353 ${x_library}/X11/%T/%N%C%S:\
1354 ${x_library}/X11/%L/%T/%N%S:\
1355 ${x_library}/X11/%l/%T/%N%S:\
1356 ${x_library}/X11/%T/%N%S"
1357     if test x"${x_default_search_path}" = x; then
1358       x_default_search_path=${x_search_path}
1359     else
1360       x_default_search_path="${x_search_path}:${x_default_search_path}"
1361     fi
1362   done
1363 fi
1364 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1365   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1366 fi
1367
1368 if test x"${x_includes}" = x; then
1369   bitmapdir=/usr/include/X11/bitmaps
1370 else
1371   # accumulate include directories that have X11 bitmap subdirectories
1372   bmd_acc="dummyval"
1373   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1374     if test -d "${bmd}/X11/bitmaps"; then
1375       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1376     fi
1377     if test -d "${bmd}/bitmaps"; then
1378       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1379     fi
1380   done
1381   if test ${bmd_acc} != "dummyval"; then
1382     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1383   fi
1384 fi
1385
1386 HAVE_CARBON=no
1387 if test "${with_carbon}" != no; then
1388   AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1389 fi
1390 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1391   if test "${with_carbon+set}" != set \
1392      && test "${carbon_appdir_x+set}" != set; then
1393     for var in with_x with_x_toolkit with_xim \
1394                with_xpm with_jpeg with_tiff with_gif with_png; do
1395       if eval test \"\${$var+set}\" = set; then
1396         HAVE_CARBON=no
1397         break
1398       fi
1399     done
1400   fi
1401 fi
1402 if test "${HAVE_CARBON}" = yes; then
1403   window_system=mac
1404 fi
1405
1406 case "${window_system}" in
1407   x11 )
1408     HAVE_X_WINDOWS=yes
1409     HAVE_X11=yes
1410     case "${with_x_toolkit}" in
1411       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1412       motif ) USE_X_TOOLKIT=MOTIF ;;
1413       gtk ) with_gtk=yes
1414 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1415 dnl USE_X_TOOLKIT is set.
1416             USE_X_TOOLKIT=none ;;
1417       no ) USE_X_TOOLKIT=none ;;
1418 dnl If user did not say whether to use a toolkit, make this decision later:
1419 dnl use the toolkit if we have gtk, or X11R5 or newer.
1420       * ) USE_X_TOOLKIT=maybe ;;
1421     esac
1422   ;;
1423   mac | none )
1424     HAVE_X_WINDOWS=no
1425     HAVE_X11=no
1426     USE_X_TOOLKIT=none
1427   ;;
1428 esac
1429
1430 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1431    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1432    if test "$HAVE_XSERVER" = true ||
1433       test -n "$DISPLAY" ||
1434       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1435         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1436 were found.  You should install the relevant development files for X
1437 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1438 sure you have development files for image handling, i.e.
1439 tiff, gif, jpeg, png and xpm.
1440 If you are sure you want Emacs compiled without X window support, pass
1441   --without-x
1442 to configure.])
1443    fi
1444 fi
1445
1446 ### If we're using X11, we should use the X menu package.
1447 HAVE_MENUS=no
1448 case ${HAVE_X11} in
1449   yes ) HAVE_MENUS=yes ;;
1450 esac
1451
1452 ### Compute the unexec source name from the object name.
1453 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1454
1455 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1456 # Assume not, until told otherwise.
1457 GNU_MALLOC=yes
1458 doug_lea_malloc=yes
1459 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1460 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1461 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1462                emacs_cv_var___after_morecore_hook,
1463 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1464   emacs_cv_var___after_morecore_hook=yes,
1465   emacs_cv_var___after_morecore_hook=no)])
1466 if test $emacs_cv_var___after_morecore_hook = no; then
1467   doug_lea_malloc=no
1468 fi
1469 if test "${system_malloc}" = "yes"; then
1470   GNU_MALLOC=no
1471   GNU_MALLOC_reason="
1472     (The GNU allocators don't work with this system configuration.)"
1473 fi
1474 if test "$doug_lea_malloc" = "yes" ; then
1475   if test "$GNU_MALLOC" = yes ; then
1476     GNU_MALLOC_reason="
1477       (Using Doug Lea's new malloc from the GNU C Library.)"
1478   fi
1479   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1480             [Define to 1 if you are using the GNU C Library.])
1481 fi
1482
1483 if test x"${REL_ALLOC}" = x; then
1484   REL_ALLOC=${GNU_MALLOC}
1485 fi
1486
1487 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1488 dnl the system configuration file (s/*.h) to turn the use of mmap
1489 dnl in the relocating allocator on.
1490
1491 AC_FUNC_MMAP
1492 if test $use_mmap_for_buffers = yes; then
1493   REL_ALLOC=no
1494 fi
1495
1496 LIBS="$libsrc_libs $LIBS"
1497
1498 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1499 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1500 AC_CHECK_LIB(dnet, dnet_ntoa)
1501 dnl This causes -lresolv to get used in subsequent tests,
1502 dnl which causes failures on some systems such as HPUX 9.
1503 dnl AC_CHECK_LIB(resolv, gethostbyname)
1504
1505 dnl FIXME replace main with a function we actually want from this library.
1506 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1507
1508 AC_CHECK_LIB(pthreads, cma_open)
1509
1510 dnl Check for need for bigtoc support on IBM AIX
1511
1512 case ${host_os} in
1513 aix*)
1514   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1515     case $GCC in
1516     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1517     *) gdb_cv_bigtoc=-bbigtoc ;;
1518     esac
1519
1520     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1521     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1522   ])
1523   ;;
1524 esac
1525
1526 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1527 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1528 # REAL_CPPFLAGS later on.
1529
1530 REAL_CPPFLAGS="$CPPFLAGS"
1531
1532 if test "${HAVE_X11}" = "yes"; then
1533   DEFS="$C_SWITCH_X_SITE $DEFS"
1534   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1535   LIBS="$LIBX $LIBS"
1536   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1537   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1538
1539   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1540   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1541   # but it's more convenient here to set LD_RUN_PATH
1542   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1543   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1544     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1545     export LD_RUN_PATH
1546   fi
1547
1548   if test "${opsys}" = "gnu-linux"; then
1549     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1550     AC_TRY_LINK([],
1551      [XOpenDisplay ("foo");],
1552      [xlinux_first_failure=no],
1553      [xlinux_first_failure=yes])
1554     if test "${xlinux_first_failure}" = "yes"; then
1555       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1556       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1557       OLD_CPPFLAGS="$CPPFLAGS"
1558       OLD_LIBS="$LIBS"
1559       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1560       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1561       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1562       LIBS="$LIBS -b i486-linuxaout"
1563       AC_TRY_LINK([],
1564        [XOpenDisplay ("foo");],
1565        [xlinux_second_failure=no],
1566        [xlinux_second_failure=yes])
1567       if test "${xlinux_second_failure}" = "yes"; then
1568         # If we get the same failure with -b, there is no use adding -b.
1569         # So take it out.  This plays safe.
1570         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1571         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1572         CPPFLAGS="$OLD_CPPFLAGS"
1573         LIBS="$OLD_LIBS"
1574         AC_MSG_RESULT(no)
1575       else
1576         AC_MSG_RESULT(yes)
1577       fi
1578     else
1579       AC_MSG_RESULT(no)
1580     fi
1581   fi
1582
1583   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1584   # header files included from there.
1585   AC_MSG_CHECKING(for Xkb)
1586   AC_TRY_LINK([#include <X11/Xlib.h>
1587 #include <X11/XKBlib.h>],
1588         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1589         emacs_xkb=yes, emacs_xkb=no)
1590   AC_MSG_RESULT($emacs_xkb)
1591   if test $emacs_xkb = yes; then
1592     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1593   fi
1594
1595   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1596 XScreenNumberOfScreen XSetWMProtocols)
1597 fi
1598
1599 if test "${window_system}" = "x11"; then
1600   AC_MSG_CHECKING(X11 version 6)
1601   AC_CACHE_VAL(emacs_cv_x11_version_6,
1602   [AC_TRY_LINK([#include <X11/Xlib.h>],
1603 [#if XlibSpecificationRelease < 6
1604 fail;
1605 #endif
1606 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1607   if test $emacs_cv_x11_version_6 = yes; then
1608     AC_MSG_RESULT(6 or newer)
1609     AC_DEFINE(HAVE_X11R6, 1,
1610               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1611   else
1612     AC_MSG_RESULT(before 6)
1613   fi
1614 fi
1615
1616
1617 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1618 HAVE_RSVG=no
1619 if test "${HAVE_X11}" = "yes" || test "${HAVE_CARBON}" = "yes"; then
1620   if test "${with_rsvg}" != "no"; then
1621     RSVG_REQUIRED=2.0.0
1622     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1623
1624     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1625     AC_SUBST(RSVG_CFLAGS)
1626     AC_SUBST(RSVG_LIBS)
1627
1628     if test ".${RSVG_CFLAGS}" != "."; then
1629       HAVE_RSVG=yes
1630       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1631       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1632       LIBS="$RSVG_LIBS $LIBS"
1633     fi
1634   fi
1635 fi
1636
1637
1638 HAVE_GTK=no
1639 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1640   GLIB_REQUIRED=2.6
1641   GTK_REQUIRED=2.6
1642   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1643
1644   dnl Checks for libraries.
1645   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1646   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1647      AC_MSG_ERROR($GTK_PKG_ERRORS)
1648   fi
1649 fi
1650
1651
1652 if test x"$pkg_check_gtk" = xyes; then
1653
1654   AC_SUBST(GTK_CFLAGS)
1655   AC_SUBST(GTK_LIBS)
1656   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1657   CFLAGS="$CFLAGS $GTK_CFLAGS"
1658   LIBS="$GTK_LIBS $LIBS"
1659   dnl Try to compile a simple GTK program.
1660   GTK_COMPILES=no
1661   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1662   if test "${GTK_COMPILES}" != "yes"; then
1663     if test "$USE_X_TOOLKIT" != "maybe"; then
1664       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1665     fi
1666   else
1667     HAVE_GTK=yes
1668     AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
1669     USE_X_TOOLKIT=none
1670     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1671       :
1672     else
1673       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1674        closing open displays.  This is no problem if you just use
1675        one display, but if you use more than one and close one of them
1676        Emacs may crash.]])
1677       sleep 3
1678     fi
1679   fi
1680
1681 fi
1682
1683
1684 if test "${HAVE_GTK}" = "yes"; then
1685
1686   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1687   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1688   if test "$with_toolkit_scroll_bars" != no; then
1689     with_toolkit_scroll_bars=yes
1690   fi
1691
1692   dnl  Check if we can use multiple displays with this GTK version.
1693   dnl  If gdk_display_open exists, assume all others are there also.
1694   HAVE_GTK_MULTIDISPLAY=no
1695   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1696   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1697     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1698               [Define to 1 if GTK can handle more than one display.])
1699   fi
1700
1701   dnl  Check if we have the old file selection dialog.
1702   dnl  If gdk_display_open exists, assume all others are there also.
1703   HAVE_GTK_FILE_SELECTION=no
1704   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1705
1706   dnl  Check if we have the new file chooser dialog
1707   dnl  If gdk_display_open exists, assume all others are there also.
1708   HAVE_GTK_FILE_CHOOSER=no
1709   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1710
1711   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1712      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1713     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1714               [Define to 1 if GTK has both file selection and chooser dialog.])
1715   fi
1716
1717   dnl Check if pthreads are available.  Emacs only needs this when using
1718   dnl gtk_file_chooser under Gnome.
1719   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1720     HAVE_GTK_AND_PTHREAD=no
1721     AC_CHECK_HEADERS(pthread.h)
1722     if test "$ac_cv_header_pthread_h"; then
1723       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1724     fi
1725     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1726       case "${canonical}" in
1727         *-hpux*) ;;
1728         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1729       esac
1730       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1731                [Define to 1 if you have GTK and pthread (-lpthread).])
1732     fi
1733   fi
1734 fi
1735
1736 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1737 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1738 dnl also not configured.
1739 HAVE_DBUS=no
1740 if test "${with_dbus}" = "yes"; then
1741    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1742    if test "$HAVE_DBUS" = yes; then
1743       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1744    fi
1745 fi
1746
1747 dnl Do not put whitespace before the #include statements below.
1748 dnl Older compilers (eg sunos4 cc) choke on it.
1749 HAVE_XAW3D=no
1750 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1751   if test "$with_xaw3d" != no; then
1752     AC_MSG_CHECKING(for xaw3d)
1753     AC_CACHE_VAL(emacs_cv_xaw3d,
1754     [AC_TRY_LINK([
1755 #include <X11/Intrinsic.h>
1756 #include <X11/Xaw3d/Simple.h>],
1757       [],
1758       emacs_cv_xaw3d=yes,
1759       emacs_cv_xaw3d=no)])
1760   else
1761     emacs_cv_xaw3d=no
1762   fi
1763   if test $emacs_cv_xaw3d = yes; then
1764     AC_MSG_RESULT([yes; using Lucid toolkit])
1765     USE_X_TOOLKIT=LUCID
1766     HAVE_XAW3D=yes
1767     AC_DEFINE(HAVE_XAW3D, 1,
1768               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1769   else
1770     AC_MSG_RESULT(no)
1771     AC_MSG_CHECKING(for libXaw)
1772     AC_CACHE_VAL(emacs_cv_xaw,
1773     [AC_TRY_LINK([
1774 #include <X11/Intrinsic.h>
1775 #include <X11/Xaw/Simple.h>],
1776       [],
1777       emacs_cv_xaw=yes,
1778       emacs_cv_xaw=no)])
1779     if test $emacs_cv_xaw = yes; then
1780       AC_MSG_RESULT([yes; using Lucid toolkit])
1781       USE_X_TOOLKIT=LUCID
1782     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1783       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1784     else
1785       AC_MSG_RESULT([no; do not use toolkit by default])
1786       USE_X_TOOLKIT=none
1787     fi
1788   fi
1789 fi
1790
1791 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1792
1793 if test "${USE_X_TOOLKIT}" != "none"; then
1794   AC_MSG_CHECKING(X11 toolkit version)
1795   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1796   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1797 [#if XtSpecificationRelease < 6
1798 fail;
1799 #endif
1800 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1801   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1802   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1803     AC_MSG_RESULT(6 or newer)
1804     AC_DEFINE(HAVE_X11XTR6, 1,
1805               [Define to 1 if you have the X11R6 or newer version of Xt.])
1806   else
1807     AC_MSG_RESULT(before 6)
1808   fi
1809
1810 dnl If using toolkit, check whether libXmu.a exists.
1811 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1812   OLDLIBS="$LIBS"
1813   if test x$HAVE_X11XTR6 = xyes; then
1814     LIBS="-lXt -lSM -lICE $LIBS"
1815   else
1816     LIBS="-lXt $LIBS"
1817   fi
1818   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1819   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1820 fi
1821
1822 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1823 if test "${HAVE_X11}" = "yes"; then
1824   if test "${USE_X_TOOLKIT}" != "none"; then
1825     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1826   fi
1827 fi
1828
1829 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1830   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1831   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1832     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1833 int x = 5;
1834 #else
1835 Motif version prior to 2.1.
1836 #endif],
1837     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1838   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1839   if test $emacs_cv_motif_version_2_1 = yes; then
1840     HAVE_LIBXP=no
1841     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1842               [Define to 1 if you have Motif 2.1 or newer.])
1843     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1844     if test ${HAVE_LIBXP} = yes; then
1845       AC_DEFINE(HAVE_LIBXP, 1,
1846                 [Define to 1 if you have the Xp library (-lXp).])
1847     fi
1848   else
1849     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1850     # We put this in CFLAGS temporarily to precede other -I options
1851     # that might be in CFLAGS temporarily.
1852     # We put this in CPPFLAGS where it precedes the other -I options.
1853     OLD_CPPFLAGS=$CPPFLAGS
1854     OLD_CFLAGS=$CFLAGS
1855     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1856     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1857     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1858       [int x = 5;],
1859       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1860     if test $emacs_cv_lesstif = yes; then
1861       # Make sure this -I option remains in CPPFLAGS after it is set
1862       # back to REAL_CPPFLAGS.
1863       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1864       # have those other -I options anyway.  Ultimately, having this
1865       # directory ultimately in CPPFLAGS will be enough.
1866       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1867       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1868     else
1869       CFLAGS=$OLD_CFLAGS
1870       CPPFLAGS=$OLD_CPPFLAGS
1871     fi
1872   fi
1873 fi
1874
1875 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1876 dnl using Motif or Xaw3d is available, and unless
1877 dnl --with-toolkit-scroll-bars=no was specified.
1878
1879 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1880             [Define to 1 if we should use toolkit scroll bars.])dnl
1881 USE_TOOLKIT_SCROLL_BARS=no
1882 if test "${with_toolkit_scroll_bars}" != "no"; then
1883   if test "${USE_X_TOOLKIT}" != "none"; then
1884     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1885       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1886       HAVE_XAW3D=no
1887       USE_TOOLKIT_SCROLL_BARS=yes
1888     elif test "${HAVE_XAW3D}" = "yes"; then
1889       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1890       USE_TOOLKIT_SCROLL_BARS=yes
1891     fi
1892   elif test "${HAVE_GTK}" = "yes"; then
1893     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1894     USE_TOOLKIT_SCROLL_BARS=yes
1895   elif test "${HAVE_CARBON}" = "yes"; then
1896     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1897     USE_TOOLKIT_SCROLL_BARS=yes
1898   fi
1899 fi
1900
1901 dnl See if XIM is available.
1902 AC_TRY_COMPILE([
1903           #include <X11/Xlib.h>
1904           #include <X11/Xresource.h>],
1905          [XIMProc  callback;],
1906          [HAVE_XIM=yes
1907          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1908          HAVE_XIM=no)
1909
1910 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1911
1912 if test "${with_xim}" != "no"; then
1913   AC_DEFINE(USE_XIM, 1,
1914             [Define to 1 if we should use XIM, if it is available.])
1915 fi
1916
1917
1918 if test "${HAVE_XIM}" != "no"; then
1919   late_CFLAGS=$CFLAGS
1920   if test "$GCC" = yes; then
1921     CFLAGS="$CFLAGS --pedantic-errors"
1922   fi
1923   AC_TRY_COMPILE([
1924 #include <X11/Xlib.h>
1925 #include <X11/Xresource.h>],
1926 [Display *display;
1927 XrmDatabase db;
1928 char *res_name;
1929 char *res_class;
1930 XIMProc  callback;
1931 XPointer *client_data;
1932 #ifndef __GNUC__
1933 /* If we're not using GCC, it's probably not XFree86, and this is
1934    probably right, but we can't use something like --pedantic-errors.  */
1935 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1936                                            char*, XIMProc, XPointer*);
1937 #endif
1938 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1939    client_data);],
1940     [emacs_cv_arg6_star=yes])
1941   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1942          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1943 either XPointer or XPointer*.])dnl
1944   if test "$emacs_cv_arg6_star" = yes; then
1945     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1946   else
1947     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1948   fi
1949   CFLAGS=$late_CFLAGS
1950 fi
1951
1952 ### Start of font-backend section.
1953 if test "${HAVE_X11}" != "yes"; then
1954   USE_FONT_BACKEND=no
1955 fi
1956
1957 if test "${USE_FONT_BACKEND}" = "yes"; then
1958   AC_DEFINE(USE_FONT_BACKEND, 1, [Define to 1 if we should use font-backend.])
1959
1960   ## Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1961   HAVE_XFT=maybe
1962   if test "x${with_freetype}" = "xno"; then
1963     with_xft="no";
1964   fi
1965   if test "x${with_xft}" != "xno"; then
1966
1967     PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1968     if test "$HAVE_XFT" != no; then
1969       OLD_CPPFLAGS="$CPPFLAGS"
1970       OLD_CFLAGS="$CFLAGS"
1971       OLD_LIBS="$LIBS"
1972       CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1973       CFLAGS="$CFLAGS $XFT_CFLAGS"
1974       LIBS="$XFT_LIBS $LIBS"
1975       AC_CHECK_HEADER(X11/Xft/Xft.h,
1976         AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1977
1978       if test "${HAVE_XFT}" = "yes"; then
1979         AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1980         AC_SUBST(XFT_LIBS)
1981         C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1982       else
1983         CPPFLAGS="$OLD_CPPFLAGS"
1984         CFLAGS="$OLD_CFLAGS"
1985         LIBS="$OLD_LIBS"
1986       fi                        # "${HAVE_XFT}" = "yes"
1987     fi                          # "$HAVE_XFT" != no
1988   fi                            # "x${with_xft}" != "xno"
1989
1990   dnl For the "Does Emacs use" message at the end.
1991   if test "$HAVE_XFT" != "yes"; then
1992      HAVE_XFT=no
1993   fi
1994
1995
1996   HAVE_FREETYPE=no
1997   ### Use -lfreetype if available, unless `--with-freetype=no'.
1998   if test "${HAVE_XFT}" = "yes"; then
1999     dnl As we use Xft, we anyway use freetype.
2000     dnl In this case, there's no need of additional CFLAGS and LIBS.
2001     HAVE_FREETYPE=yes
2002   elif test "x${with_freetype}" != "xno"; then
2003
2004     PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
2005     if test "${HAVE_FREETYPE}" = "yes"; then
2006       PKG_CHECK_MODULES(FONTCONFIG, fontconfig, HAVE_FC=yes, HAVE_FC=no)
2007       if test "${HAVE_FC}" = "no"; then
2008         dnl Without fontconfig, we can't use freetype at the moment.
2009         HAVE_FREETYPE=no
2010       fi
2011     fi
2012   fi
2013
2014   HAVE_LIBOTF=no
2015   if test "${HAVE_FREETYPE}" = "yes"; then
2016     AC_DEFINE(HAVE_FREETYPE, 1,
2017               [Define to 1 if using the freetype and fontconfig libraries.])
2018     if test "${with_libotf}" != "no"; then
2019       PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2020                         HAVE_LIBOTF=no)
2021       if test "$HAVE_LIBOTF" = "yes"; then
2022         AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2023       fi
2024     fi
2025 dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2026 dnl Does the new font backend require it, or can it work without it?
2027   fi
2028
2029   HAVE_M17N_FLT=no
2030   if test "${with_m17n_flt}" != "no"; then
2031     PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2032     if test "$HAVE_M17N_FLT" = "yes"; then
2033       AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2034     fi
2035   fi
2036
2037   AC_SUBST(FREETYPE_CFLAGS)
2038   AC_SUBST(FREETYPE_LIBS)
2039   AC_SUBST(FONTCONFIG_CFLAGS)
2040   AC_SUBST(FONTCONFIG_LIBS)
2041   AC_SUBST(LIBOTF_CFLAGS)
2042   AC_SUBST(LIBOTF_LIBS)
2043   AC_SUBST(M17N_FLT_CFLAGS)
2044   AC_SUBST(M17N_FLT_LIBS)
2045
2046 fi                              # "${USE_FONT_BACKEND}" = "yes"
2047 ### End of font-backend section.
2048
2049 ### Use -lXpm if available, unless `--with-xpm=no'.
2050 HAVE_XPM=no
2051 if test "${HAVE_X11}" = "yes"; then
2052   if test "${with_xpm}" != "no"; then
2053     AC_CHECK_HEADER(X11/xpm.h,
2054       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2055     if test "${HAVE_XPM}" = "yes"; then
2056       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2057       AC_EGREP_CPP(no_return_alloc_pixels,
2058       [#include "X11/xpm.h"
2059 #ifndef XpmReturnAllocPixels
2060 no_return_alloc_pixels
2061 #endif
2062       ], HAVE_XPM=no, HAVE_XPM=yes)
2063
2064       if test "${HAVE_XPM}" = "yes"; then
2065         AC_MSG_RESULT(yes)
2066       else
2067         AC_MSG_RESULT(no)
2068       fi
2069     fi
2070   fi
2071
2072   if test "${HAVE_XPM}" = "yes"; then
2073     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2074   fi
2075 fi
2076
2077 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2078 HAVE_JPEG=no
2079 if test "${HAVE_X11}" = "yes"; then
2080   if test "${with_jpeg}" != "no"; then
2081     dnl Checking for jpeglib.h can lose because of a redefinition of
2082     dnl  HAVE_STDLIB_H.
2083     AC_CHECK_HEADER(jerror.h,
2084       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2085   fi
2086
2087   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2088   if test "${HAVE_JPEG}" = "yes"; then
2089     AC_DEFINE(HAVE_JPEG)
2090     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2091         [#include <jpeglib.h>
2092          version=JPEG_LIB_VERSION
2093 ],
2094         [AC_DEFINE(HAVE_JPEG)],
2095         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2096         HAVE_JPEG=no])
2097   fi
2098 fi
2099
2100 ### Use -lpng if available, unless `--with-png=no'.
2101 HAVE_PNG=no
2102 if test "${HAVE_X11}" = "yes"; then
2103   if test "${with_png}" != "no"; then
2104     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2105     # in /usr/include/libpng.
2106     AC_CHECK_HEADERS(png.h libpng/png.h)
2107     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2108       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2109     fi
2110   fi
2111
2112   if test "${HAVE_PNG}" = "yes"; then
2113     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2114   fi
2115 fi
2116
2117 ### Use -ltiff if available, unless `--with-tiff=no'.
2118 HAVE_TIFF=no
2119 if test "${HAVE_X11}" = "yes"; then
2120   if test "${with_tiff}" != "no"; then
2121     AC_CHECK_HEADER(tiffio.h,
2122       [tifflibs="-lz -lm"
2123       # At least one tiff package requires the jpeg library.
2124       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2125       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2126   fi
2127
2128   if test "${HAVE_TIFF}" = "yes"; then
2129     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2130   fi
2131 fi
2132
2133 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2134 HAVE_GIF=no
2135 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2136   AC_CHECK_HEADER(gif_lib.h,
2137 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2138 # Earlier versions can crash Emacs.
2139     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2140
2141   if test "$HAVE_GIF" = yes; then
2142       ac_gif_lib_name="-lgif"
2143   fi
2144
2145 # If gif_lib.h but no libgif, try libungif.
2146   if test x"$try_libungif" = xyes; then
2147     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2148
2149     if test "$HAVE_GIF" = yes; then
2150       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2151       ac_gif_lib_name="-lungif"
2152     fi
2153   fi
2154
2155   if test "${HAVE_GIF}" = "yes"; then
2156     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2157   fi
2158 fi
2159
2160 dnl Check for required libraries.
2161 if test "${HAVE_X11}" = "yes"; then
2162   MISSING=""
2163   WITH_NO=""
2164   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2165     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2166   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2167     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2168   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2169     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2170   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2171     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2172   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2173     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2174
2175   if test "X${MISSING}" != X; then
2176     AC_MSG_ERROR([The following required libraries were not found:
2177     $MISSING
2178 Maybe some development libraries/packages are missing?
2179 If you don't want to link with them give
2180     $WITH_NO
2181 as options to configure])
2182   fi
2183 fi
2184
2185 ### Use -lgpm if available, unless `--with-gpm=no'.
2186 HAVE_GPM=no
2187 if test "${with_gpm}" != "no"; then
2188   AC_CHECK_HEADER(gpm.h,
2189     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2190 fi
2191
2192 if test "${HAVE_GPM}" = "yes"; then
2193   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2194 fi
2195
2196 dnl Check for malloc/malloc.h on darwin
2197 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2198
2199 ### Use Mac OS X Carbon API to implement GUI.
2200 if test "${HAVE_CARBON}" = "yes"; then
2201   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2202   ## Specify the install directory
2203   carbon_appdir=
2204   if test "${carbon_appdir_x}" != ""; then
2205     case ${carbon_appdir_x} in
2206       y | ye | yes)  carbon_appdir=/Applications ;;
2207       * ) carbon_appdir=${carbon_appdir_x} ;;
2208     esac
2209   fi
2210   # We also have mouse menus.
2211   HAVE_MENUS=yes
2212 fi
2213
2214 ### Use session management (-lSM -lICE) if available
2215 HAVE_X_SM=no
2216 if test "${HAVE_X11}" = "yes"; then
2217   AC_CHECK_HEADER(X11/SM/SMlib.h,
2218     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2219
2220   if test "${HAVE_X_SM}" = "yes"; then
2221     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2222     case "$LIBS" in
2223       *-lSM*) ;;
2224       *)      LIBS="-lSM -lICE $LIBS" ;;
2225     esac
2226   fi
2227 fi
2228
2229 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2230 AC_CACHE_CHECK(whether netdb declares h_errno,
2231                emacs_cv_netdb_declares_h_errno,
2232 [AC_TRY_LINK([#include <netdb.h>],
2233   [return h_errno;],
2234   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2235 if test $emacs_cv_netdb_declares_h_errno = yes; then
2236   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2237 fi
2238
2239 AC_FUNC_ALLOCA
2240
2241 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2242 dnl FIXME is there an autoconf test that does the right thing, without
2243 dnl needing to call A_M_E afterwards?
2244 if test x"$ac_cv_func_alloca_works" != xyes; then
2245    AC_MSG_ERROR( [a system implementation of alloca is required] )
2246 fi
2247
2248 # fmod, logb, and frexp are found in -lm on most systems.
2249 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2250 AC_CHECK_LIB(m, sqrt)
2251
2252 # Check for mail-locking functions in a "mail" library.  Probably this should
2253 # have the same check as for liblockfile below.
2254 AC_CHECK_LIB(mail, maillock)
2255 dnl Debian, at least:
2256 AC_CHECK_LIB(lockfile, maillock)
2257 # If we have the shared liblockfile, assume we must use it for mail
2258 # locking (e.g. Debian).  If we couldn't link against liblockfile
2259 # (no liblockfile.a installed), ensure that we don't need to.
2260 if test "$ac_cv_lib_lockfile_maillock" = no; then
2261   dnl This works for files generally, not just executables.
2262   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2263   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2264                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2265   if test $ac_cv_prog_liblockfile = yes; then
2266     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2267 This probably means that movemail could lose mail.
2268 There may be a `development' package to install containing liblockfile.])
2269   else :
2270   fi
2271 fi
2272 AC_CHECK_FUNCS(touchlock)
2273 AC_CHECK_HEADERS(maillock.h)
2274
2275 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2276 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2277 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2278 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2279 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2280 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2281 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2282 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2283 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2284
2285 AC_CHECK_HEADERS(sys/un.h)
2286
2287 AC_FUNC_MKTIME
2288 if test "$ac_cv_func_working_mktime" = no; then
2289   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2290 fi
2291
2292 AC_FUNC_GETLOADAVG
2293
2294 AC_FUNC_FSEEKO
2295
2296 # Configure getopt.
2297 m4_include([m4/getopt.m4])
2298 gl_GETOPT_IFELSE([
2299   gl_GETOPT_SUBSTITUTE_HEADER
2300   gl_PREREQ_GETOPT
2301   GETOPTOBJS='getopt.o getopt1.o'
2302 ])
2303 AC_SUBST(GETOPTOBJS)
2304
2305 AC_FUNC_GETPGRP
2306
2307 AC_FUNC_STRFTIME
2308
2309 # UNIX98 PTYs.
2310 AC_CHECK_FUNCS(grantpt)
2311
2312 # PTY-related GNU extensions.
2313 AC_CHECK_FUNCS(getpt)
2314
2315 # Check this now, so that we will NOT find the above functions in ncurses.
2316 # That is because we have not set up to link ncurses in lib-src.
2317 # It's better to believe a function is not available
2318 # than to expect to find it in ncurses.
2319 AC_CHECK_LIB(ncurses, tparm)
2320
2321 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2322
2323 resolv=no
2324 AC_TRY_LINK([#include <netinet/in.h>
2325 #include <arpa/nameser.h>
2326 #include <resolv.h>],
2327     [return res_init();],
2328     have_res_init=yes, have_res_init=no)
2329 if test "$have_res_init" = no; then
2330   OLIBS="$LIBS"
2331   LIBS="$LIBS -lresolv"
2332   AC_MSG_CHECKING(for res_init with -lresolv)
2333   AC_TRY_LINK([#include <netinet/in.h>
2334 #include <arpa/nameser.h>
2335 #include <resolv.h>],
2336     [return res_init();],
2337     have_res_init=yes, have_res_init=no)
2338   AC_MSG_RESULT($have_res_init)
2339   if test "$have_res_init" = yes ; then
2340     resolv=yes
2341   fi
2342   LIBS="$OLIBS"
2343 fi
2344
2345 if test "$have_res_init" = yes; then
2346   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2347 fi
2348
2349 # Do we need the Hesiod library to provide the support routines?
2350 if test "$with_hesiod" = yes ; then
2351   # Don't set $LIBS here -- see comments above.
2352   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2353      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2354                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2355   if test "$resolv" = yes ; then
2356     RESOLVLIB=-lresolv
2357   else
2358     RESOLVLIB=
2359   fi
2360   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2361         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2362                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2363         :, $RESOLVLIB)])
2364 fi
2365
2366 # Do we need libresolv (due to res_init or Hesiod)?
2367 if test "$resolv" = yes ; then
2368   AC_DEFINE(HAVE_LIBRESOLV, 1,
2369             [Define to 1 if you have the resolv library (-lresolv).])
2370 fi
2371
2372 # These tell us which Kerberos-related libraries to use.
2373 if test "${with_kerberos+set}" = set; then
2374   AC_CHECK_LIB(com_err, com_err)
2375   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2376   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2377   AC_CHECK_LIB(krb5, krb5_init_context)
2378   if test "${with_kerberos5+set}" != set; then
2379     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2380                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2381     AC_CHECK_LIB(krb4, krb_get_cred,,
2382                  [AC_CHECK_LIB(krb, krb_get_cred)])
2383   fi
2384
2385   if test "${with_kerberos5+set}" = set; then
2386     AC_CHECK_HEADERS(krb5.h)
2387   else
2388     AC_CHECK_HEADERS(des.h,,
2389                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2390                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2391     AC_CHECK_HEADERS(krb.h,,
2392                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2393                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2394   fi
2395   AC_CHECK_HEADERS(com_err.h)
2396 fi
2397
2398 # Solaris requires -lintl if you want strerror (which calls dgettext)
2399 # to return localized messages.
2400 AC_CHECK_LIB(intl, dgettext)
2401
2402 AC_MSG_CHECKING(whether localtime caches TZ)
2403 AC_CACHE_VAL(emacs_cv_localtime_cache,
2404 [if test x$ac_cv_func_tzset = xyes; then
2405 AC_TRY_RUN([#include <time.h>
2406 extern char **environ;
2407 unset_TZ ()
2408 {
2409   char **from, **to;
2410   for (to = from = environ; (*to = *from); from++)
2411     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2412       to++;
2413 }
2414 char TZ_GMT0[] = "TZ=GMT0";
2415 char TZ_PST8[] = "TZ=PST8";
2416 main()
2417 {
2418   time_t now = time ((time_t *) 0);
2419   int hour_GMT0, hour_unset;
2420   if (putenv (TZ_GMT0) != 0)
2421     exit (1);
2422   hour_GMT0 = localtime (&now)->tm_hour;
2423   unset_TZ ();
2424   hour_unset = localtime (&now)->tm_hour;
2425   if (putenv (TZ_PST8) != 0)
2426     exit (1);
2427   if (localtime (&now)->tm_hour == hour_GMT0)
2428     exit (1);
2429   unset_TZ ();
2430   if (localtime (&now)->tm_hour != hour_unset)
2431     exit (1);
2432   exit (0);
2433 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2434 [# If we have tzset, assume the worst when cross-compiling.
2435 emacs_cv_localtime_cache=yes])
2436 else
2437         # If we lack tzset, report that localtime does not cache TZ,
2438         # since we can't invalidate the cache if we don't have tzset.
2439         emacs_cv_localtime_cache=no
2440 fi])dnl
2441 AC_MSG_RESULT($emacs_cv_localtime_cache)
2442 if test $emacs_cv_localtime_cache = yes; then
2443   AC_DEFINE(LOCALTIME_CACHE, 1,
2444             [Define to 1 if localtime caches TZ.])
2445 fi
2446
2447 if test "x$HAVE_TIMEVAL" = xyes; then
2448   AC_CHECK_FUNCS(gettimeofday)
2449   if test $ac_cv_func_gettimeofday = yes; then
2450     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2451                    emacs_cv_gettimeofday_two_arguments,
2452     [AC_TRY_COMPILE([
2453 #ifdef TIME_WITH_SYS_TIME
2454 #include <sys/time.h>
2455 #include <time.h>
2456 #else
2457 #ifdef HAVE_SYS_TIME_H
2458 #include <sys/time.h>
2459 #else
2460 #include <time.h>
2461 #endif
2462 #endif],
2463       [struct timeval time;
2464        gettimeofday (&time, 0);],
2465       emacs_cv_gettimeofday_two_arguments=yes,
2466       emacs_cv_gettimeofday_two_arguments=no)])
2467     if test $emacs_cv_gettimeofday_two_arguments = no; then
2468       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2469                 [Define to 1 if gettimeofday accepts only one argument.])
2470     fi
2471   fi
2472 fi
2473
2474 ok_so_far=yes
2475 AC_CHECK_FUNC(socket, , ok_so_far=no)
2476 if test $ok_so_far = yes; then
2477   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2478 fi
2479 if test $ok_so_far = yes; then
2480   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2481 fi
2482 if test $ok_so_far = yes; then
2483 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2484   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2485             [Define to 1 if you have inet sockets.])
2486 fi
2487
2488 AC_CHECK_HEADERS(sys/ioctl.h)
2489
2490 if test -f /usr/lpp/X11/bin/smt.exp; then
2491   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2492             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2493 fi
2494
2495 AC_MSG_CHECKING(whether system supports dynamic ptys)
2496 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2497   AC_MSG_RESULT(yes)
2498   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2499 else
2500   AC_MSG_RESULT(no)
2501 fi
2502
2503 AC_FUNC_FORK
2504
2505 dnl Adapted from Haible's version.
2506 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2507   [AC_TRY_LINK([#include <langinfo.h>],
2508     [char* cs = nl_langinfo(CODESET);],
2509     emacs_cv_langinfo_codeset=yes,
2510     emacs_cv_langinfo_codeset=no)
2511   ])
2512 if test $emacs_cv_langinfo_codeset = yes; then
2513   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2514     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2515 fi
2516
2517 AC_CHECK_TYPES(size_t)
2518
2519 AC_TYPE_MBSTATE_T
2520
2521 dnl Restrict could probably be used effectively other than in regex.c.
2522 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2523   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2524                   emacs_cv_c_restrict=yes,
2525                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2526                                   emacs_cv_c_restrict=__restrict,
2527                                   emacs_cv_c_restrict=no)])])
2528 case "$emacs_cv_c_restrict" in
2529   yes) emacs_restrict=restrict;;
2530   no) emacs_restrict="";;
2531   *) emacs_restrict="$emacs_cv_c_restrict";;
2532 esac
2533 if test "$emacs_restrict" != __restrict; then
2534   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2535     [Define to compiler's equivalent of C99 restrict keyword.
2536      Don't define if equivalent is `__restrict'.])
2537 fi
2538
2539 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2540   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2541                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2542 if test "$emacs_cv_c_restrict_arr" = yes; then
2543   AC_DEFINE(__restrict_arr, __restrict,
2544     [Define to compiler's equivalent of C99 restrict keyword in array
2545      declarations.  Define as empty for no equivalent.])
2546 fi
2547
2548 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2549 dnl how the tty code is related to POSIX and/or other versions of termios.
2550 dnl The following looks like a useful start.
2551 dnl
2552 dnl AC_SYS_POSIX_TERMIOS
2553 dnl if test $ac_cv_sys_posix_termios = yes; then
2554 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2555 dnl                                and macros for terminal control.])
2556 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2557 dnl fi
2558
2559 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2560
2561 # Set up the CFLAGS for real compilation, so we can substitute it.
2562 CFLAGS="$REAL_CFLAGS"
2563 CPPFLAGS="$REAL_CPPFLAGS"
2564
2565 #### Find out which version of Emacs this is.
2566 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2567          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2568 if test x"${version}" = x; then
2569   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2570 fi
2571
2572 ### Specify what sort of things we'll be editing into Makefile and config.h.
2573 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2574 AC_SUBST(version)
2575 AC_SUBST(configuration)
2576 AC_SUBST(canonical)
2577 AC_SUBST(srcdir)
2578 AC_SUBST(prefix)
2579 AC_SUBST(exec_prefix)
2580 AC_SUBST(bindir)
2581 AC_SUBST(datadir)
2582 AC_SUBST(sharedstatedir)
2583 AC_SUBST(libexecdir)
2584 AC_SUBST(mandir)
2585 AC_SUBST(infodir)
2586 AC_SUBST(lispdir)
2587 AC_SUBST(locallisppath)
2588 AC_SUBST(lisppath)
2589 AC_SUBST(x_default_search_path)
2590 AC_SUBST(etcdir)
2591 AC_SUBST(archlibdir)
2592 AC_SUBST(docdir)
2593 AC_SUBST(bitmapdir)
2594 AC_SUBST(gamedir)
2595 AC_SUBST(gameuser)
2596 AC_SUBST(c_switch_system)
2597 AC_SUBST(c_switch_machine)
2598 AC_SUBST(LD_SWITCH_X_SITE)
2599 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2600 AC_SUBST(C_SWITCH_X_SITE)
2601 AC_SUBST(CFLAGS)
2602 AC_SUBST(X_TOOLKIT_TYPE)
2603 AC_SUBST(machfile)
2604 AC_SUBST(opsysfile)
2605 AC_SUBST(GETLOADAVG_LIBS)
2606 AC_SUBST(carbon_appdir)
2607
2608 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2609                    [Define to the canonical Emacs configuration name.])
2610 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2611                    [Define to the options passed to configure.])
2612 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2613                    [Define to the used machine dependent file.])
2614 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2615                    [Define to the used os dependent file.])
2616 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2617 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2618  may need to deal with X Windows.  For instance, if you've defined
2619  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2620  your loader can find on its own, you might want to add "-L/..." or
2621  something similar.])
2622 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2623                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2624                     in case it's needed (for Solaris, for example).])
2625 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2626 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2627  may need to deal with X Windows.  For instance, if you've defined
2628  HAVE_X_WINDOWS above and your X include files aren't in a place
2629  that your compiler can find on its own, you might want to add
2630  "-I/..." or something similar.])
2631 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2632                    [Define to the unexec source file name.])
2633
2634 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2635   AC_DEFINE(HAVE_X_WINDOWS, 1,
2636             [Define to 1 if you want to use the X window system.])
2637 fi
2638 if test "${USE_X_TOOLKIT}" != "none" ; then
2639   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2640 fi
2641 if test "${HAVE_X11}" = "yes" ; then
2642   AC_DEFINE(HAVE_X11, 1,
2643             [Define to 1 if you want to use version 11 of X windows.
2644              Otherwise, Emacs expects to use version 10.])
2645 fi
2646 if test "${HAVE_MENUS}" = "yes" ; then
2647   AC_DEFINE(HAVE_MENUS, 1,
2648             [Define to 1 if you have mouse menus.
2649              (This is automatic if you use X, but the option to specify it remains.)
2650              It is also defined with other window systems that support xmenu.c.])
2651 fi
2652 if test "${GNU_MALLOC}" = "yes" ; then
2653   AC_DEFINE(GNU_MALLOC, 1,
2654             [Define to 1 if you want to use the GNU memory allocator.])
2655 fi
2656 if test "${REL_ALLOC}" = "yes" ; then
2657   AC_DEFINE(REL_ALLOC, 1,
2658             [Define REL_ALLOC if you want to use the relocating allocator for
2659              buffer space.])
2660 fi
2661
2662
2663 AH_TOP([/* GNU Emacs site configuration template file.
2664    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2665      2006, 2007, 2008  Free Software Foundation, Inc.
2666
2667 This file is part of GNU Emacs.
2668
2669 GNU Emacs is free software; you can redistribute it and/or modify
2670 it under the terms of the GNU General Public License as published by
2671 the Free Software Foundation; either version 3, or (at your option)
2672 any later version.
2673
2674 GNU Emacs is distributed in the hope that it will be useful,
2675 but WITHOUT ANY WARRANTY; without even the implied warranty of
2676 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2677 GNU General Public License for more details.
2678
2679 You should have received a copy of the GNU General Public License
2680 along with GNU Emacs; see the file COPYING.  If not, write to the
2681 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
2682 Boston, MA 02110-1301, USA.  */
2683
2684
2685 /* No code in Emacs #includes config.h twice, but some bits of code
2686    intended to work with other packages as well (like gmalloc.c)
2687    think they can include it as many times as they like.  */
2688 #ifndef EMACS_CONFIG_H
2689 #define EMACS_CONFIG_H
2690 ])dnl
2691
2692 AH_BOTTOM([
2693 /* If we're using any sort of window system, define some consequences.  */
2694 #ifdef HAVE_X_WINDOWS
2695 #define HAVE_WINDOW_SYSTEM
2696 #define MULTI_KBOARD
2697 #define HAVE_MOUSE
2698 #endif
2699
2700 /* Multi-tty support relies on MULTI_KBOARD.  It seems safe to turn it
2701    on unconditionally. */
2702 #ifndef MULTI_KBOARD
2703 #define MULTI_KBOARD
2704 #endif
2705
2706 /* If we're using the Carbon API on Mac OS X, define a few more
2707    variables as well.  */
2708 #ifdef HAVE_CARBON
2709 #define HAVE_WINDOW_SYSTEM
2710 #define HAVE_MOUSE
2711 #endif
2712
2713 /* Define USER_FULL_NAME to return a string
2714    that is the user's full name.
2715    It can assume that the variable `pw'
2716    points to the password file entry for this user.
2717
2718    At some sites, the pw_gecos field contains
2719    the user's full name.  If neither this nor any other
2720    field contains the right thing, use pw_name,
2721    giving the user's login name, since that is better than nothing.  */
2722 #define USER_FULL_NAME pw->pw_gecos
2723
2724 /* Define AMPERSAND_FULL_NAME if you use the convention
2725    that & in the full name stands for the login id.  */
2726 /* Turned on June 1996 supposing nobody will mind it.  */
2727 #define AMPERSAND_FULL_NAME
2728
2729 /* We have blockinput.h.  */
2730 #define DO_BLOCK_INPUT
2731
2732 /* Define HAVE_SOUND if we have sound support.  We know it works
2733    and compiles only on the specified platforms.   For others,
2734    it probably doesn't make sense to try.  */
2735
2736 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2737 #ifdef HAVE_MACHINE_SOUNDCARD_H
2738 #define HAVE_SOUND 1
2739 #endif
2740 #ifdef HAVE_SYS_SOUNDCARD_H
2741 #define HAVE_SOUND 1
2742 #endif
2743 #ifdef HAVE_SOUNDCARD_H
2744 #define HAVE_SOUND 1
2745 #endif
2746 #ifdef HAVE_ALSA
2747 #define HAVE_SOUND 1
2748 #endif
2749 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2750
2751 /* If using GNU, then support inline function declarations. */
2752 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2753    generally, because even if non-gcc compilers accept `inline', they
2754    may reject `extern inline'.  */
2755 #if defined (__GNUC__) && defined (OPTIMIZE)
2756 #define INLINE __inline__
2757 #else
2758 #define INLINE
2759 #endif
2760
2761 /* Include the os and machine dependent files.  */
2762 #include config_opsysfile
2763 #include config_machfile
2764
2765 /* If no remapping takes place, static variables cannot be dumped as
2766    pure, so don't worry about the `static' keyword. */
2767 #ifdef NO_REMAP
2768 #undef static
2769 #endif
2770
2771 /* Define `subprocesses' should be defined if you want to
2772    have code for asynchronous subprocesses
2773    (as used in M-x compile and M-x shell).
2774    These do not work for some USG systems yet;
2775    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
2776
2777 #ifndef VMS
2778 #ifndef USG
2779 /* #define subprocesses */
2780 #endif
2781 #endif
2782
2783 /* SIGTYPE is the macro we actually use.  */
2784 #ifndef SIGTYPE
2785 #define SIGTYPE RETSIGTYPE
2786 #endif
2787
2788 #ifdef emacs /* Don't do this for lib-src.  */
2789 /* Tell regex.c to use a type compatible with Emacs.  */
2790 #define RE_TRANSLATE_TYPE Lisp_Object
2791 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2792 #ifdef make_number
2793 /* If make_number is a macro, use it.  */
2794 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2795 #else
2796 /* If make_number is a function, avoid it.  */
2797 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2798 #endif
2799 #endif
2800
2801 /* Avoid link-time collision with system mktime if we will use our own.  */
2802 #if ! HAVE_MKTIME || BROKEN_MKTIME
2803 #define mktime emacs_mktime
2804 #endif
2805
2806 #define my_strftime nstrftime   /* for strftime.c */
2807
2808 /* The rest of the code currently tests the CPP symbol BSTRING.
2809    Override any claims made by the system-description files.
2810    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2811 #undef BSTRING
2812 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2813 #define BSTRING
2814 #endif
2815
2816 /* Some of the files of Emacs which are intended for use with other
2817    programs assume that if you have a config.h file, you must declare
2818    the type of getenv.
2819
2820    This declaration shouldn't appear when alloca.s or Makefile.in
2821    includes config.h.  */
2822 #ifndef NOT_C_CODE
2823 extern char *getenv ();
2824 #endif
2825
2826 /* These default definitions are good for almost all machines.
2827    The exceptions override them in m/MACHINE.h.  */
2828
2829 #ifndef BITS_PER_CHAR
2830 #define BITS_PER_CHAR 8
2831 #endif
2832
2833 #ifndef BITS_PER_SHORT
2834 #define BITS_PER_SHORT 16
2835 #endif
2836
2837 /* Note that lisp.h uses this in a preprocessor conditional, so it
2838    would not work to use sizeof.  That being so, we do all of them
2839    without sizeof, for uniformity's sake.  */
2840 #ifndef BITS_PER_INT
2841 #define BITS_PER_INT 32
2842 #endif
2843
2844 #ifndef BITS_PER_LONG
2845 #ifdef _LP64
2846 #define BITS_PER_LONG 64
2847 #else
2848 #define BITS_PER_LONG 32
2849 #endif
2850 #endif
2851
2852 /* Define if the compiler supports function prototypes.  It may do so
2853    but not define __STDC__ (e.g. DEC C by default) or may define it as
2854    zero.  */
2855 #undef PROTOTYPES
2856 /* For mktime.c:  */
2857 #ifndef __P
2858 # if defined PROTOTYPES
2859 #  define __P(args) args
2860 # else
2861 #  define __P(args) ()
2862 # endif  /* GCC.  */
2863 #endif /* __P */
2864
2865 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2866 #ifndef NOT_C_CODE
2867 #ifdef HAVE_STRING_H
2868 #include "string.h"
2869 #endif
2870 #ifdef HAVE_STRINGS_H
2871 #include "strings.h"  /* May be needed for bcopy & al. */
2872 #endif
2873 #ifdef HAVE_STDLIB_H
2874 #include <stdlib.h>
2875 #endif
2876 #ifndef __GNUC__
2877 # ifdef HAVE_ALLOCA_H
2878 #  include <alloca.h>
2879 # else /* AIX files deal with #pragma.  */
2880 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2881 char *alloca ();
2882 #  endif
2883 # endif /* HAVE_ALLOCA_H */
2884 #endif /* __GNUC__ */
2885 #ifndef HAVE_SIZE_T
2886 typedef unsigned size_t;
2887 #endif
2888 #endif /* NOT_C_CODE */
2889
2890 /* Define HAVE_X_I18N if we have usable i18n support.  */
2891
2892 #ifdef HAVE_X11R6
2893 #define HAVE_X_I18N
2894 #elif !defined X11R5_INHIBIT_I18N
2895 #define HAVE_X_I18N
2896 #endif
2897
2898 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2899
2900 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2901 #define HAVE_X11R6_XIM
2902 #endif
2903
2904 /* Should we enable expensive run-time checking of data types?  */
2905 #undef ENABLE_CHECKING
2906
2907 #if defined __GNUC__ && (__GNUC__ > 2 \
2908                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2909 #define NO_RETURN       __attribute__ ((__noreturn__))
2910 #else
2911 #define NO_RETURN       /* nothing */
2912 #endif
2913
2914 /* These won't be used automatically yet.  We also need to know, at least,
2915    that the stack is continuous.  */
2916 #ifdef __GNUC__
2917 #  ifndef GC_SETJMP_WORKS
2918   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2919      see NON_SAVING_SETJMP in the target descriptions.  */
2920   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2921      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2922      Fixme: Deal with SVR3.  */
2923 #    define GC_SETJMP_WORKS 1
2924 #  endif
2925 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2926 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2927 #  endif
2928 #endif
2929
2930 #ifndef HAVE_BCOPY
2931 #define bcopy(a,b,s) memcpy (b,a,s)
2932 #endif
2933 #ifndef HAVE_BZERO
2934 #define bzero(a,s) memset (a,0,s)
2935 #endif
2936 #ifndef HAVE_BCMP
2937 #define BCMP memcmp
2938 #endif
2939
2940 #endif /* EMACS_CONFIG_H */
2941
2942 /*
2943 Local Variables:
2944 mode: c
2945 End:
2946 */
2947 ])dnl
2948
2949 #### Report on what we decided to do.
2950 #### Report GTK as a toolkit, even if it doesn't use Xt.
2951 #### It makes printing result more understandable as using GTK sets
2952 #### toolkit_scroll_bars to yes by default.
2953 if test "${HAVE_GTK}" = "yes"; then
2954   USE_X_TOOLKIT=GTK
2955 fi
2956
2957 echo "
2958 Configured for \`${canonical}'.
2959
2960   Where should the build process find the source code?    ${srcdir}
2961   What operating system and machine description files should Emacs use?
2962         \`${opsysfile}' and \`${machfile}'
2963   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2964   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2965   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2966   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2967   What window system should Emacs use?                    ${window_system}
2968   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2969
2970 if test -n "${x_includes}"; then
2971 echo "  Where do we find X Windows header files?                ${x_includes}"
2972 else
2973 echo "  Where do we find X Windows header files?                Standard dirs"
2974 fi
2975 if test -n "${x_libraries}"; then
2976 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2977 else
2978 echo "  Where do we find X Windows libraries?                   Standard dirs"
2979 fi
2980
2981 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2982 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2983 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2984 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2985 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2986 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2987 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2988 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2989 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2990 echo "  Does Emacs use a font backend?                          ${USE_FONT_BACKEND}"
2991
2992 if test "${USE_FONT_BACKEND}" = "yes"; then
2993   echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2994   echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2995   echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2996   echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2997 fi
2998 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
2999 echo
3000
3001 if test $USE_XASSERTS = yes; then
3002    echo "  Compiling with asserts turned on."
3003    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3004    echo
3005 fi
3006
3007 if test "$USE_X_TOOLKIT" = GTK; then
3008   case "$canonical" in
3009   *cygwin*)
3010     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
3011   will probably get a crash on startup.  If this happens, please use another
3012   toolkit for Emacs.  See etc/PROBLEMS for more information."
3013   ;;
3014   esac
3015 fi
3016
3017
3018 if test "$HAVE_CARBON" = "yes"; then
3019    echo
3020    echo "Warning: The Mac Carbon port is currently unsupported and has
3021 known problems.  It is not recommended for use by non-developers.
3022 Read the emacs-devel archives for more information."
3023    echo
3024 fi
3025
3026 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3027   echo "D-Bus integration has been tested for GNU/Linux only."
3028   echo
3029 fi
3030
3031
3032 # Remove any trailing slashes in these variables.
3033 [test "${prefix}" != NONE &&
3034   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3035 test "${exec_prefix}" != NONE &&
3036   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3037
3038 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3039 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3040 ## from Makefile.c can correctly provide the arg `-traditional' to the
3041 ## C preprocessor.
3042
3043 AC_EGREP_CPP(yes..yes,
3044         [yes..yes],
3045         CPP_NEED_TRADITIONAL=no,
3046         CPP_NEED_TRADITIONAL=yes)
3047
3048 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3049         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3050         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3051         lwlib/Makefile lisp/Makefile leim/Makefile, [
3052
3053 ### Make the necessary directories, if they don't exist.
3054 for dir in etc lisp ; do
3055   test -d ${dir} || mkdir ${dir}
3056 done
3057
3058 # Build src/Makefile from ${srcdir}/src/Makefile.c
3059 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3060 # This must be done after src/config.h is built, since we rely on that file.
3061
3062 # Now get this: Some word that is part of the ${srcdir} directory name
3063 # or the ${configuration} value might, just might, happen to be an
3064 # identifier like `sun4' or `i386' or something, and be predefined by
3065 # the C preprocessor to some helpful value like 1, or maybe the empty
3066 # string.  Needless to say consequent macro substitutions are less
3067 # than conducive to the makefile finding the correct directory.
3068 [undefs="`echo $top_srcdir $configuration $canonical |
3069 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3070     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3071 `"]
3072
3073 echo creating src/epaths.h
3074 ${MAKE-make} epaths-force
3075
3076 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3077 # `..' to `. .'  unless invoked with -traditional
3078
3079 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3080   CPPFLAGS="$CPPFLAGS -traditional"
3081 fi
3082
3083 echo creating lib-src/Makefile
3084 ( cd lib-src
3085   rm -f junk.c junk1.c junk2.c
3086   sed -e '/start of cpp stuff/q' \
3087       < Makefile.c > junk1.c
3088   sed -e '1,/start of cpp stuff/d'\
3089       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3090       < Makefile.c > junk.c
3091   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3092       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3093   cat junk1.c junk2.c > Makefile.new
3094   rm -f junk.c junk1.c junk2.c
3095   chmod 444 Makefile.new
3096   mv -f Makefile.new Makefile
3097 )
3098
3099 echo creating src/Makefile
3100 ( cd src
3101   rm -f junk.c junk1.c junk2.c
3102   sed -e '/start of cpp stuff/q' \
3103       < Makefile.c > junk1.c
3104   sed -e '1,/start of cpp stuff/d'\
3105       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3106       < Makefile.c > junk.c
3107   if test -f ${srcdir}/admin/unidata/UnicodeData.txt; then
3108     echo creating ${srcdir}/admin/unidata/Makefile
3109     cp ${srcdir}/admin/unidata/Makefile.in ${srcdir}/admin/unidata/Makefile
3110     CPPFLAGS="$CPPFLAGS -DHAVE_UNIDATA"
3111   fi
3112   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3113       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3114   cat junk1.c junk2.c > Makefile.new
3115   rm -f junk.c junk1.c junk2.c
3116   chmod 444 Makefile.new
3117   mv -f Makefile.new Makefile
3118 )
3119
3120 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3121   echo creating src/.gdbinit
3122   echo source $srcdir/src/.gdbinit > src/.gdbinit
3123 fi
3124
3125 # This is how we know whether to re-run configure in certain cases.
3126 touch src/config.stamp
3127
3128 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3129
3130 m4_if(dnl       Do not change this comment
3131    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3132 )dnl