lisp/doc-view.el

   1 ;;; doc-view.el --- View PDF/PostScript/DVI files in Emacs -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2007-2013 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Tassilo Horn <tsdh@gnu.org>
   6 ;; Maintainer: Tassilo Horn <tsdh@gnu.org>
   7 ;; Keywords: files, pdf, ps, dvi
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Requirements:
  25
  26 ;; doc-view.el requires GNU Emacs 22.1 or newer.  You also need Ghostscript,
  27 ;; `dvipdf' (comes with Ghostscript) or `dvipdfm' (comes with teTeX or TeXLive)
  28 ;; and `pdftotext', which comes with xpdf (http://www.foolabs.com/xpdf/) or
  29 ;; poppler (http://poppler.freedesktop.org/).
  30
  31 ;;; Commentary:
  32
  33 ;; DocView is a document viewer for Emacs.  It converts PDF, PS and DVI files
  34 ;; to a set of PNG files, one PNG for each page, and displays the PNG images
  35 ;; inside an Emacs buffer.  This buffer uses `doc-view-mode' which provides
  36 ;; convenient key bindings for browsing the document.
  37 ;;
  38 ;; To use it simply open a document file with
  39 ;;
  40 ;;     C-x C-f ~/path/to/document RET
  41 ;;
  42 ;; and the document will be converted and displayed, if your emacs supports png
  43 ;; images.  With `C-c C-c' you can toggle between the rendered images
  44 ;; representation and the source text representation of the document.
  45 ;;
  46 ;; Since conversion may take some time all the PNG images are cached in a
  47 ;; subdirectory of `doc-view-cache-directory' and reused when you want to view
  48 ;; that file again.  To reconvert a document hit `g' (`doc-view-reconvert-doc')
  49 ;; when displaying the document.  To delete all cached files use
  50 ;; `doc-view-clear-cache'.  To open the cache with dired, so that you can tidy
  51 ;; it out use `doc-view-dired-cache'.
  52 ;;
  53 ;; When conversion in underway the first page will be displayed as soon as it
  54 ;; is available and the available pages are refreshed every
  55 ;; `doc-view-conversion-refresh-interval' seconds.  If that variable is nil the
  56 ;; pages won't be displayed before conversion of the document finished
  57 ;; completely.
  58 ;;
  59 ;; DocView lets you select a slice of the displayed pages.  This slice
  60 ;; will be remembered and applied to all pages of the current
  61 ;; document.  This enables you to cut away the margins of a document
  62 ;; to save some space.  To select a slice you can use
  63 ;; `doc-view-set-slice' (bound to `s s') which will query you for the
  64 ;; coordinates of the slice's top-left corner and its width and
  65 ;; height.  A much more convenient way to do the same is offered by
  66 ;; the command `doc-view-set-slice-using-mouse' (bound to `s m').
  67 ;; After invocation you only have to press mouse-1 at the top-left
  68 ;; corner and drag it to the bottom-right corner of the desired slice.
  69 ;; Even more accurate and convenient is to use
  70 ;; `doc-view-set-slice-from-bounding-box' (bound to `s b') which uses
  71 ;; the BoundingBox information of the current page to set an optimal
  72 ;; slice.  To reset the slice use `doc-view-reset-slice' (bound to `s
  73 ;; r').
  74 ;;
  75 ;; You can also search within the document.  The command `doc-view-search'
  76 ;; (bound to `C-s') queries for a search regexp and initializes a list of all
  77 ;; matching pages and messages how many match-pages were found.  After that you
  78 ;; can jump to the next page containing a match with an additional `C-s'.  With
  79 ;; `C-r' you can do the same, but backwards.  To search for a new regexp give a
  80 ;; prefix arg to one of the search functions, e.g. by typing `C-u C-s'.  The
  81 ;; searching works by using a plain text representation of the document.  If
  82 ;; that doesn't already exist the first invocation of `doc-view-search' (or
  83 ;; `doc-view-search-backward') starts the conversion.  When that finishes and
  84 ;; you're still viewing the document (i.e. you didn't switch to another buffer)
  85 ;; you're queried for the regexp then.
  86 ;;
  87 ;; Dired users can simply hit `v' on a document file.  If it's a PS, PDF or DVI
  88 ;; it will be opened using `doc-view-mode'.
  89 ;;
  90
  91 ;;; Configuration:
  92
  93 ;; If the images are too small or too big you should set the "-rXXX" option in
  94 ;; `doc-view-ghostscript-options' to another value.  (The bigger your screen,
  95 ;; the higher the value.)
  96 ;;
  97 ;; This and all other options can be set with the customization interface.
  98 ;; Simply do
  99 ;;
 100 ;;     M-x customize-group RET doc-view RET
 101 ;;
 102 ;; and modify them to your needs.
 103
 104 ;;; Todo:
 105
 106 ;; - add print command.
 107 ;; - share more code with image-mode.
 108 ;; - better menu.
 109 ;; - Bind slicing to a drag event.
 110 ;; - zoom the region around the cursor (like xdvi).
 111 ;; - get rid of the silly arrow in the fringe.
 112 ;; - improve anti-aliasing (pdf-utils gets it better).
 113
 114 ;;;; About isearch support
 115
 116 ;; I tried implementing isearch by setting
 117 ;; `isearch-search-fun-function' buffer-locally, but that didn't
 118 ;; work too good.  The function doing the real search was called
 119 ;; endlessly somehow.  But even if we'd get that working no real
 120 ;; isearch feeling comes up due to the missing match highlighting.
 121 ;; Currently I display all lines containing a match in a tooltip and
 122 ;; each C-s or C-r jumps directly to the next/previous page with a
 123 ;; match.  With isearch we could only display the current match.  So
 124 ;; we had to decide if another C-s jumps to the next page with a
 125 ;; match (thus only the first match in a page will be displayed in a
 126 ;; tooltip) or to the next match, which would do nothing visible
 127 ;; (except the tooltip) if the next match is on the same page.
 128
 129 ;; And it's much slower than the current search facility, because
 130 ;; isearch really searches for each step forward or backward whereas
 131 ;; the current approach searches once and then it knows to which
 132 ;; pages to jump.
 133
 134 ;; Anyway, if someone with better isearch knowledge wants to give it a try,
 135 ;; feel free to do it.  --Tassilo
 136
 137 ;;; Code:
 138
 139 (eval-when-compile (require 'cl-lib))
 140 (require 'dired)
 141 (require 'image-mode)
 142 (require 'jka-compr)
 143
 144 ;;;; Customization Options
 145
 146 (defgroup doc-view nil
 147   "In-buffer viewer for PDF, PostScript, DVI, and DJVU files."
 148   :link '(function-link doc-view)
 149   :version "22.2"
 150   :group 'applications
 151   :group 'data
 152   :group 'multimedia
 153   :prefix "doc-view-")
 154
 155 (defcustom doc-view-ghostscript-program "gs"
 156   "Program to convert PS and PDF files to PNG."
 157   :type 'file
 158   :group 'doc-view)
 159
 160 (defcustom doc-view-pdfdraw-program
 161   (cond
 162    ((executable-find "pdfdraw") "pdfdraw")
 163    (t "mudraw"))
 164   "Name of MuPDF's program to convert PDF files to PNG."
 165   :type 'file
 166   :version "24.4")
 167
 168 (defcustom doc-view-pdf->png-converter-function
 169   (if (executable-find doc-view-pdfdraw-program)
 170       #'doc-view-pdf->png-converter-mupdf
 171     #'doc-view-pdf->png-converter-ghostscript)
 172   "Function to call to convert a PDF file into a PNG file."
 173   :type '(radio
 174           (function-item doc-view-pdf->png-converter-ghostscript
 175                          :doc "Use ghostscript")
 176           (function-item doc-view-pdf->png-converter-mupdf
 177                          :doc "Use mupdf")
 178           function)
 179   :version "24.4")
 180
 181 (defcustom doc-view-ghostscript-options
 182   '("-dSAFER" ;; Avoid security problems when rendering files from untrusted
 183     ;; sources.
 184     "-dNOPAUSE" "-sDEVICE=png16m" "-dTextAlphaBits=4"
 185     "-dBATCH" "-dGraphicsAlphaBits=4" "-dQUIET")
 186   "A list of options to give to ghostscript."
 187   :type '(repeat string)
 188   :group 'doc-view)
 189
 190 (defcustom doc-view-resolution 100
 191   "Dots per inch resolution used to render the documents.
 192 Higher values result in larger images."
 193   :type 'number
 194   :group 'doc-view)
 195
 196 (defcustom doc-view-scale-internally t
 197   "Whether we should try to rescale images ourselves.
 198 If nil, the document is re-rendered every time the scaling factor is modified.
 199 This only has an effect if the image libraries linked with Emacs support
 200 scaling."
 201   :type 'boolean)
 202
 203 (defcustom doc-view-image-width 850
 204   "Default image width.
 205 Has only an effect if `doc-view-scale-internally' is non-nil and support for
 206 scaling is compiled into emacs."
 207   :version "24.1"
 208   :type 'number
 209   :group 'doc-view)
 210
 211 (defcustom doc-view-dvipdfm-program "dvipdfm"
 212   "Program to convert DVI files to PDF.
 213
 214 DVI file will be converted to PDF before the resulting PDF is
 215 converted to PNG.
 216
 217 If this and `doc-view-dvipdf-program' are set,
 218 `doc-view-dvipdf-program' will be preferred."
 219   :type 'file
 220   :group 'doc-view)
 221
 222 (defcustom doc-view-dvipdf-program "dvipdf"
 223   "Program to convert DVI files to PDF.
 224
 225 DVI file will be converted to PDF before the resulting PDF is
 226 converted to PNG.
 227
 228 If this and `doc-view-dvipdfm-program' are set,
 229 `doc-view-dvipdf-program' will be preferred."
 230   :type 'file
 231   :group 'doc-view)
 232
 233 (define-obsolete-variable-alias 'doc-view-unoconv-program
 234                                 'doc-view-odf->pdf-converter-program
 235                                 "24.4")
 236
 237 (defcustom doc-view-odf->pdf-converter-program
 238   (cond
 239    ((executable-find "soffice") "soffice")
 240    ((executable-find "unoconv") "unoconv")
 241    (t "soffice"))
 242   "Program to convert any file type readable by OpenOffice.org to PDF.
 243
 244 Needed for viewing OpenOffice.org (and MS Office) files."
 245   :version "24.4"
 246   :type 'file
 247   :group 'doc-view)
 248
 249 (defcustom doc-view-odf->pdf-converter-function
 250   (cond
 251    ((string-match "unoconv\\'" doc-view-odf->pdf-converter-program)
 252     #'doc-view-odf->pdf-converter-unoconv)
 253    ((string-match "soffice\\'" doc-view-odf->pdf-converter-program)
 254     #'doc-view-odf->pdf-converter-soffice))
 255   "Function to call to convert a ODF file into a PDF file."
 256   :type '(radio
 257           (function-item doc-view-odf->pdf-converter-unoconv
 258                          :doc "Use unoconv")
 259           (function-item doc-view-odf->pdf-converter-soffice
 260                          :doc "Use LibreOffice")
 261           function)
 262   :version "24.4")
 263
 264 (defcustom doc-view-ps2pdf-program "ps2pdf"
 265   "Program to convert PS files to PDF.
 266
 267 PS files will be converted to PDF before searching is possible."
 268   :type 'file
 269   :group 'doc-view)
 270
 271 (defcustom doc-view-pdftotext-program "pdftotext"
 272   "Program to convert PDF files to plain text.
 273
 274 Needed for searching."
 275   :type 'file
 276   :group 'doc-view)
 277
 278 (defcustom doc-view-cache-directory
 279   (expand-file-name (format "docview%d" (user-uid))
 280                     temporary-file-directory)
 281   "The base directory, where the PNG images will be saved."
 282   :type 'directory
 283   :group 'doc-view)
 284
 285 (defvar doc-view-conversion-buffer " *doc-view conversion output*"
 286   "The buffer where messages from the converter programs go to.")
 287
 288 (defcustom doc-view-conversion-refresh-interval 1
 289   "Interval in seconds between refreshes of the DocView buffer while converting.
 290 After such a refresh newly converted pages will be available for
 291 viewing.  If set to nil there won't be any refreshes and the
 292 pages won't be displayed before conversion of the whole document
 293 has finished."
 294   :type 'integer
 295   :group 'doc-view)
 296
 297 (defcustom doc-view-continuous nil
 298   "In Continuous mode reaching the page edge advances to next/previous page.
 299 When non-nil, scrolling a line upward at the bottom edge of the page
 300 moves to the next page, and scrolling a line downward at the top edge
 301 of the page moves to the previous page."
 302   :type 'boolean
 303   :group 'doc-view
 304   :version "23.2")
 305
 306 ;;;; Internal Variables
 307
 308 (defvar-local doc-view--current-converter-processes nil
 309   "Only used internally.")
 310
 311 (defun doc-view-new-window-function (winprops)
 312   ;; (message "New window %s for buf %s" (car winprops) (current-buffer))
 313   (cl-assert (or (eq t (car winprops))
 314                  (eq (window-buffer (car winprops)) (current-buffer))))
 315   (let ((ol (image-mode-window-get 'overlay winprops)))
 316     (if ol
 317         (progn
 318           (setq ol (copy-overlay ol))
 319           ;; `ol' might actually be dead.
 320           (move-overlay ol (point-min) (point-max)))
 321       (setq ol (make-overlay (point-min) (point-max) nil t))
 322       (overlay-put ol 'doc-view t))
 323     (overlay-put ol 'window (car winprops))
 324     (unless (windowp (car winprops))
 325       ;; It's a pseudo entry.  Let's make sure it's not displayed (the
 326       ;; `window' property is only effective if its value is a window).
 327       (cl-assert (eq t (car winprops)))
 328       (delete-overlay ol))
 329     (image-mode-window-put 'overlay ol winprops)
 330     (when (and (windowp (car winprops))
 331                (stringp (overlay-get ol 'display))
 332                (null doc-view--current-converter-processes))
 333       ;; We're not displaying an image yet, so let's do so.  This happens when
 334       ;; the buffer is displayed for the first time.
 335       ;; Don't do it if there's a conversion is running, since in that case, it
 336       ;; will be done later.
 337       (with-selected-window (car winprops)
 338         (doc-view-goto-page 1)))))
 339
 340 (defvar-local doc-view--current-files nil
 341   "Only used internally.")
 342
 343 (defvar-local doc-view--current-timer nil
 344   "Only used internally.")
 345
 346 (defvar-local doc-view--current-cache-dir nil
 347   "Only used internally.")
 348
 349 (defvar-local doc-view--current-search-matches nil
 350   "Only used internally.")
 351
 352 (defvar doc-view--pending-cache-flush nil
 353   "Only used internally.")
 354
 355 (defvar doc-view--previous-major-mode nil
 356   "Only used internally.")
 357
 358 (defvar doc-view--buffer-file-name nil
 359   "Only used internally.
 360 The file name used for conversion.  Normally it's the same as
 361 `buffer-file-name', but for remote files, compressed files and
 362 files inside an archive it is a temporary copy of
 363 the (uncompressed, extracted) file residing in
 364 `doc-view-cache-directory'.")
 365
 366 (defvar doc-view-doc-type nil
 367   "The type of document in the current buffer.
 368 Can be `dvi', `pdf', or `ps'.")
 369
 370 (defvar doc-view-single-page-converter-function nil
 371   "Function to call to convert a single page of the document to a bitmap file.
 372 May operate on the source document or on some intermediate (typically PDF)
 373 conversion of it.")
 374
 375 (defvar-local doc-view--image-type nil
 376   "The type of image in the current buffer.
 377 Can be `png' or `tiff'.")
 378
 379 (defvar-local doc-view--image-file-pattern nil
 380   "The `format' pattern of image file names.
 381 Typically \"page-%s.png\".")
 382
 383 ;;;; DocView Keymaps
 384
 385 (defvar doc-view-mode-map
 386   (let ((map (make-sparse-keymap)))
 387     (set-keymap-parent map image-mode-map)
 388     ;; Navigation in the document
 389     (define-key map (kbd "n")         'doc-view-next-page)
 390     (define-key map (kbd "p")         'doc-view-previous-page)
 391     (define-key map (kbd "<next>")    'forward-page)
 392     (define-key map (kbd "<prior>")   'backward-page)
 393     (define-key map [remap forward-page]  'doc-view-next-page)
 394     (define-key map [remap backward-page] 'doc-view-previous-page)
 395     (define-key map (kbd "SPC")       'doc-view-scroll-up-or-next-page)
 396     (define-key map (kbd "S-SPC")     'doc-view-scroll-down-or-previous-page)
 397     (define-key map (kbd "DEL")       'doc-view-scroll-down-or-previous-page)
 398     (define-key map (kbd "C-n")       'doc-view-next-line-or-next-page)
 399     (define-key map (kbd "<down>")    'doc-view-next-line-or-next-page)
 400     (define-key map (kbd "C-p")       'doc-view-previous-line-or-previous-page)
 401     (define-key map (kbd "<up>")      'doc-view-previous-line-or-previous-page)
 402     (define-key map (kbd "M-<")       'doc-view-first-page)
 403     (define-key map (kbd "M->")       'doc-view-last-page)
 404     (define-key map [remap goto-line] 'doc-view-goto-page)
 405     (define-key map (kbd "RET")       'image-next-line)
 406     ;; Zoom in/out.
 407     (define-key map "+"               'doc-view-enlarge)
 408     (define-key map "-"               'doc-view-shrink)
 409     ;; Fit the image to the window
 410     (define-key map "W"               'doc-view-fit-width-to-window)
 411     (define-key map "H"               'doc-view-fit-height-to-window)
 412     (define-key map "P"               'doc-view-fit-page-to-window)
 413     ;; Killing the buffer (and the process)
 414     (define-key map (kbd "k")         'doc-view-kill-proc-and-buffer)
 415     (define-key map (kbd "K")         'doc-view-kill-proc)
 416     ;; Slicing the image
 417     (define-key map (kbd "s s")       'doc-view-set-slice)
 418     (define-key map (kbd "s m")       'doc-view-set-slice-using-mouse)
 419     (define-key map (kbd "s b")       'doc-view-set-slice-from-bounding-box)
 420     (define-key map (kbd "s r")       'doc-view-reset-slice)
 421     ;; Searching
 422     (define-key map (kbd "C-s")       'doc-view-search)
 423     (define-key map (kbd "<find>")    'doc-view-search)
 424     (define-key map (kbd "C-r")       'doc-view-search-backward)
 425     ;; Show the tooltip
 426     (define-key map (kbd "C-t")       'doc-view-show-tooltip)
 427     ;; Toggle between text and image display or editing
 428     (define-key map (kbd "C-c C-c")   'doc-view-toggle-display)
 429     ;; Open a new buffer with doc's text contents
 430     (define-key map (kbd "C-c C-t")   'doc-view-open-text)
 431     ;; Reconvert the current document.  Don't just use revert-buffer
 432     ;; because that resets the scale factor, the page number, ...
 433     (define-key map (kbd "g")         'doc-view-revert-buffer)
 434     (define-key map (kbd "r")         'doc-view-revert-buffer)
 435     map)
 436   "Keymap used by `doc-view-mode' when displaying a doc as a set of images.")
 437
 438 (defun doc-view-revert-buffer (&optional ignore-auto noconfirm)
 439   "Like `revert-buffer', but preserves the buffer's current modes."
 440   ;; FIXME: this should probably be moved to files.el and used for
 441   ;; most/all "g" bindings to revert-buffer.
 442   (interactive (list (not current-prefix-arg)))
 443   (revert-buffer ignore-auto noconfirm 'preserve-modes))
 444
 445
 446 (easy-menu-define doc-view-menu doc-view-mode-map
 447   "Menu for Doc View mode."
 448   '("DocView"
 449     ["Toggle display"           doc-view-toggle-display]
 450     ("Continuous"
 451      ["Off"                     (setq doc-view-continuous nil)
 452       :style radio :selected    (eq doc-view-continuous nil)]
 453      ["On"                      (setq doc-view-continuous t)
 454       :style radio :selected    (eq doc-view-continuous t)]
 455      "---"
 456      ["Save as Default"
 457       (customize-save-variable 'doc-view-continuous doc-view-continuous) t]
 458      )
 459     "---"
 460     ["Set Slice"                doc-view-set-slice-using-mouse]
 461     ["Set Slice (BoundingBox)"  doc-view-set-slice-from-bounding-box]
 462     ["Set Slice (manual)"       doc-view-set-slice]
 463     ["Reset Slice"              doc-view-reset-slice]
 464     "---"
 465     ["Search"                   doc-view-search]
 466     ["Search Backwards"         doc-view-search-backward]
 467     ))
 468
 469 (defvar doc-view-minor-mode-map
 470   (let ((map (make-sparse-keymap)))
 471     ;; Toggle between text and image display or editing
 472     (define-key map (kbd "C-c C-c") 'doc-view-toggle-display)
 473     map)
 474   "Keymap used by `doc-minor-view-mode'.")
 475
 476 ;;;; Navigation Commands
 477
 478 (defmacro doc-view-current-page (&optional win)
 479   `(image-mode-window-get 'page ,win))
 480 (defmacro doc-view-current-info () `(image-mode-window-get 'info))
 481 (defmacro doc-view-current-overlay () `(image-mode-window-get 'overlay))
 482 (defmacro doc-view-current-image () `(image-mode-window-get 'image))
 483 (defmacro doc-view-current-slice () `(image-mode-window-get 'slice))
 484
 485 (defun doc-view-last-page-number ()
 486   (length doc-view--current-files))
 487
 488 (defun doc-view-goto-page (page)
 489   "View the page given by PAGE."
 490   (interactive "nPage: ")
 491   (let ((len (doc-view-last-page-number)))
 492     (if (< page 1)
 493         (setq page 1)
 494       (when (and (> page len)
 495                  ;; As long as the converter is running, we don't know
 496                  ;; how many pages will be available.
 497                  (null doc-view--current-converter-processes))
 498         (setq page len)))
 499     (setf (doc-view-current-page) page
 500           (doc-view-current-info)
 501           (concat
 502            (propertize
 503             (format "Page %d of %d." page len) 'face 'bold)
 504            ;; Tell user if converting isn't finished yet
 505            (if doc-view--current-converter-processes
 506                " (still converting...)\n"
 507              "\n")
 508            ;; Display context infos if this page matches the last search
 509            (when (and doc-view--current-search-matches
 510                       (assq page doc-view--current-search-matches))
 511              (concat (propertize "Search matches:\n" 'face 'bold)
 512                      (let ((contexts ""))
 513                        (dolist (m (cdr (assq page
 514                                              doc-view--current-search-matches)))
 515                          (setq contexts (concat contexts "  - \"" m "\"\n")))
 516                        contexts)))))
 517     ;; Update the buffer
 518     ;; We used to find the file name from doc-view--current-files but
 519     ;; that's not right if the pages are not generated sequentially
 520     ;; or if the page isn't in doc-view--current-files yet.
 521     (let ((file (expand-file-name
 522                  (format doc-view--image-file-pattern page)
 523                  (doc-view--current-cache-dir))))
 524       (doc-view-insert-image file :pointer 'arrow)
 525       (when (and (not (file-exists-p file))
 526                  doc-view--current-converter-processes)
 527         ;; The PNG file hasn't been generated yet.
 528         (funcall doc-view-single-page-converter-function
 529                  doc-view--buffer-file-name file page
 530                  (let ((win (selected-window)))
 531                    (lambda ()
 532                      (and (eq (current-buffer) (window-buffer win))
 533                           ;; If we changed page in the mean
 534                           ;; time, don't mess things up.
 535                           (eq (doc-view-current-page win) page)
 536                           ;; Make sure we don't infloop.
 537                           (file-readable-p file)
 538                           (with-selected-window win
 539                             (doc-view-goto-page page))))))))
 540     (overlay-put (doc-view-current-overlay)
 541                  'help-echo (doc-view-current-info))))
 542
 543 (defun doc-view-next-page (&optional arg)
 544   "Browse ARG pages forward."
 545   (interactive "p")
 546   (doc-view-goto-page (+ (doc-view-current-page) (or arg 1))))
 547
 548 (defun doc-view-previous-page (&optional arg)
 549   "Browse ARG pages backward."
 550   (interactive "p")
 551   (doc-view-goto-page (- (doc-view-current-page) (or arg 1))))
 552
 553 (defun doc-view-first-page ()
 554   "View the first page."
 555   (interactive)
 556   (doc-view-goto-page 1))
 557
 558 (defun doc-view-last-page ()
 559   "View the last page."
 560   (interactive)
 561   (doc-view-goto-page (doc-view-last-page-number)))
 562
 563 (defun doc-view-scroll-up-or-next-page (&optional arg)
 564   "Scroll page up ARG lines if possible, else goto next page.
 565 When `doc-view-continuous' is non-nil, scrolling upward
 566 at the bottom edge of the page moves to the next page.
 567 Otherwise, goto next page only on typing SPC (ARG is nil)."
 568   (interactive "P")
 569   (if (or doc-view-continuous (null arg))
 570       (let ((hscroll (window-hscroll))
 571             (cur-page (doc-view-current-page)))
 572         (when (= (window-vscroll) (image-scroll-up arg))
 573           (doc-view-next-page)
 574           (when (/= cur-page (doc-view-current-page))
 575             (image-bob)
 576             (image-bol 1))
 577           (set-window-hscroll (selected-window) hscroll)))
 578     (image-scroll-up arg)))
 579
 580 (defun doc-view-scroll-down-or-previous-page (&optional arg)
 581   "Scroll page down ARG lines if possible, else goto previous page.
 582 When `doc-view-continuous' is non-nil, scrolling downward
 583 at the top edge of the page moves to the previous page.
 584 Otherwise, goto previous page only on typing DEL (ARG is nil)."
 585   (interactive "P")
 586   (if (or doc-view-continuous (null arg))
 587       (let ((hscroll (window-hscroll))
 588             (cur-page (doc-view-current-page)))
 589         (when (= (window-vscroll) (image-scroll-down arg))
 590           (doc-view-previous-page)
 591           (when (/= cur-page (doc-view-current-page))
 592             (image-eob)
 593             (image-bol 1))
 594           (set-window-hscroll (selected-window) hscroll)))
 595     (image-scroll-down arg)))
 596
 597 (defun doc-view-next-line-or-next-page (&optional arg)
 598   "Scroll upward by ARG lines if possible, else goto next page.
 599 When `doc-view-continuous' is non-nil, scrolling a line upward
 600 at the bottom edge of the page moves to the next page."
 601   (interactive "p")
 602   (if doc-view-continuous
 603       (let ((hscroll (window-hscroll))
 604             (cur-page (doc-view-current-page)))
 605         (when (= (window-vscroll) (image-next-line arg))
 606           (doc-view-next-page)
 607           (when (/= cur-page (doc-view-current-page))
 608             (image-bob)
 609             (image-bol 1))
 610           (set-window-hscroll (selected-window) hscroll)))
 611     (image-next-line 1)))
 612
 613 (defun doc-view-previous-line-or-previous-page (&optional arg)
 614   "Scroll downward by ARG lines if possible, else goto previous page.
 615 When `doc-view-continuous' is non-nil, scrolling a line downward
 616 at the top edge of the page moves to the previous page."
 617   (interactive "p")
 618   (if doc-view-continuous
 619       (let ((hscroll (window-hscroll))
 620             (cur-page (doc-view-current-page)))
 621         (when (= (window-vscroll) (image-previous-line arg))
 622           (doc-view-previous-page)
 623           (when (/= cur-page (doc-view-current-page))
 624             (image-eob)
 625             (image-bol 1))
 626           (set-window-hscroll (selected-window) hscroll)))
 627     (image-previous-line arg)))
 628
 629 ;;;; Utility Functions
 630
 631 (defun doc-view-kill-proc ()
 632   "Kill the current converter process(es)."
 633   (interactive)
 634   (while (consp doc-view--current-converter-processes)
 635     (ignore-errors ;; Some entries might not be processes, and maybe
 636                    ;; some are dead already?
 637       (kill-process (pop doc-view--current-converter-processes))))
 638   (when doc-view--current-timer
 639     (cancel-timer doc-view--current-timer)
 640     (setq doc-view--current-timer nil))
 641   (setq mode-line-process nil))
 642
 643 (defun doc-view-kill-proc-and-buffer ()
 644   "Kill the current converter process and buffer."
 645   (interactive)
 646   (doc-view-kill-proc)
 647   (when (eq major-mode 'doc-view-mode)
 648     (kill-buffer (current-buffer))))
 649
 650 (defun doc-view-make-safe-dir (dir)
 651   (condition-case nil
 652       (let ((umask (default-file-modes)))
 653         (unwind-protect
 654             (progn
 655               ;; Create temp files with strict access rights.  It's easy to
 656               ;; loosen them later, whereas it's impossible to close the
 657               ;; time-window of loose permissions otherwise.
 658               (set-default-file-modes #o0700)
 659               (make-directory dir))
 660           ;; Reset the umask.
 661           (set-default-file-modes umask)))
 662     (file-already-exists
 663      (when (file-symlink-p dir)
 664        (error "Danger: %s points to a symbolic link" dir))
 665      ;; In case it was created earlier with looser rights.
 666      ;; We could check the mode info returned by file-attributes, but it's
 667      ;; a pain to parse and it may not tell you what we want under
 668      ;; non-standard file-systems.  So let's just say what we want and let
 669      ;; the underlying C code and file-system figure it out.
 670      ;; This also ends up checking a bunch of useful conditions: it makes
 671      ;; sure we have write-access to the directory and that we own it, thus
 672      ;; closing a bunch of security holes.
 673      (condition-case error
 674          (set-file-modes dir #o0700)
 675        (file-error
 676         (error
 677          (format "Unable to use temporary directory %s: %s"
 678                  dir (mapconcat 'identity (cdr error) " "))))))))
 679
 680 (defun doc-view--current-cache-dir ()
 681   "Return the directory where the png files of the current doc should be saved.
 682 It's a subdirectory of `doc-view-cache-directory'."
 683   (if doc-view--current-cache-dir
 684       doc-view--current-cache-dir
 685     ;; Try and make sure doc-view-cache-directory exists and is safe.
 686     (doc-view-make-safe-dir doc-view-cache-directory)
 687     ;; Now compute the subdirectory to use.
 688     (setq doc-view--current-cache-dir
 689           (file-name-as-directory
 690            (expand-file-name
 691             (concat (subst-char-in-string ?% ?_ ;; bug#13679
 692                      (file-name-nondirectory doc-view--buffer-file-name))
 693                     "-"
 694                     (let ((file doc-view--buffer-file-name))
 695                       (with-temp-buffer
 696                         (set-buffer-multibyte nil)
 697                         (insert-file-contents-literally file)
 698                         (md5 (current-buffer)))))
 699             doc-view-cache-directory)))))
 700
 701 (defun doc-view-remove-if (predicate list)
 702   "Return LIST with all items removed that satisfy PREDICATE."
 703   (let (new-list)
 704     (dolist (item list)
 705       (when (not (funcall predicate item))
 706         (setq new-list (cons item new-list))))
 707      (nreverse new-list)))
 708
 709 ;;;###autoload
 710 (defun doc-view-mode-p (type)
 711   "Return non-nil if document type TYPE is available for `doc-view'.
 712 Document types are symbols like `dvi', `ps', `pdf', or `odf' (any
 713 OpenDocument format)."
 714   (and (display-graphic-p)
 715        (or (image-type-available-p 'imagemagick)
 716            (image-type-available-p 'png))
 717        (cond
 718         ((eq type 'dvi)
 719          (and (doc-view-mode-p 'pdf)
 720               (or (and doc-view-dvipdf-program
 721                        (executable-find doc-view-dvipdf-program))
 722                   (and doc-view-dvipdfm-program
 723                        (executable-find doc-view-dvipdfm-program)))))
 724         ((memq type '(postscript ps eps pdf))
 725          ;; FIXME: allow mupdf here
 726          (and doc-view-ghostscript-program
 727               (executable-find doc-view-ghostscript-program)))
 728         ((eq type 'odf)
 729          (and doc-view-odf->pdf-converter-program
 730               (executable-find doc-view-odf->pdf-converter-program)
 731               (doc-view-mode-p 'pdf)))
 732         ((eq type 'djvu)
 733          (executable-find "ddjvu"))
 734         (t ;; unknown image type
 735          nil))))
 736
 737 ;;;; Conversion Functions
 738
 739 (defvar doc-view-shrink-factor 1.125)
 740
 741 (defun doc-view-enlarge (factor)
 742   "Enlarge the document by FACTOR."
 743   (interactive (list doc-view-shrink-factor))
 744   (if (and doc-view-scale-internally
 745            (eq (plist-get (cdr (doc-view-current-image)) :type)
 746                'imagemagick))
 747       ;; ImageMagick supports on-the-fly-rescaling.
 748       (let ((new (ceiling (* factor doc-view-image-width))))
 749         (unless (equal new doc-view-image-width)
 750           (setq-local doc-view-image-width new)
 751           (doc-view-insert-image
 752            (plist-get (cdr (doc-view-current-image)) :file)
 753            :width doc-view-image-width)))
 754     (let ((new (ceiling (* factor doc-view-resolution))))
 755       (unless (equal new doc-view-resolution)
 756         (setq-local doc-view-resolution new)
 757         (doc-view-reconvert-doc)))))
 758
 759 (defun doc-view-shrink (factor)
 760   "Shrink the document."
 761   (interactive (list doc-view-shrink-factor))
 762   (doc-view-enlarge (/ 1.0 factor)))
 763
 764 (defun doc-view-fit-width-to-window ()
 765   "Fit the image width to the window width."
 766   (interactive)
 767   (let ((win-width (- (nth 2 (window-inside-pixel-edges))
 768                       (nth 0 (window-inside-pixel-edges))))
 769         (slice (doc-view-current-slice)))
 770     (if (not slice)
 771         (let ((img-width (car (image-display-size
 772                                (image-get-display-property) t))))
 773           (doc-view-enlarge (/ (float win-width) (float img-width))))
 774
 775       ;; If slice is set
 776       (let* ((slice-width (nth 2 slice))
 777              (scale-factor (/ (float win-width) (float slice-width)))
 778              (new-slice (mapcar (lambda (x) (ceiling (* scale-factor x))) slice)))
 779
 780         (doc-view-enlarge scale-factor)
 781         (setf (doc-view-current-slice) new-slice)
 782         (doc-view-goto-page (doc-view-current-page))))))
 783
 784 (defun doc-view-fit-height-to-window ()
 785   "Fit the image height to the window height."
 786   (interactive)
 787   (let ((win-height (- (nth 3 (window-inside-pixel-edges))
 788                        (nth 1 (window-inside-pixel-edges))))
 789         (slice (doc-view-current-slice)))
 790     (if (not slice)
 791         (let ((img-height (cdr (image-display-size
 792                                 (image-get-display-property) t))))
 793           ;; When users call 'doc-view-fit-height-to-window',
 794           ;; they might want to go to next page by typing SPC
 795           ;; ONLY once. So I used '(- win-height 1)' instead of
 796           ;; 'win-height'
 797           (doc-view-enlarge (/ (float (- win-height 1)) (float img-height))))
 798
 799       ;; If slice is set
 800       (let* ((slice-height (nth 3 slice))
 801              (scale-factor (/ (float (- win-height 1)) (float slice-height)))
 802              (new-slice (mapcar (lambda (x) (ceiling (* scale-factor x))) slice)))
 803
 804         (doc-view-enlarge scale-factor)
 805         (setf (doc-view-current-slice) new-slice)
 806         (doc-view-goto-page (doc-view-current-page))))))
 807
 808 (defun doc-view-fit-page-to-window ()
 809   "Fit the image to the window.
 810 More specifically, this function enlarges image by:
 811
 812 min {(window-width / image-width), (window-height / image-height)} times."
 813   (interactive)
 814   (let ((win-width (- (nth 2 (window-inside-pixel-edges))
 815                       (nth 0 (window-inside-pixel-edges))))
 816         (win-height (- (nth 3 (window-inside-pixel-edges))
 817                        (nth 1 (window-inside-pixel-edges))))
 818         (slice (doc-view-current-slice)))
 819     (if (not slice)
 820         (let ((img-width (car (image-display-size
 821                                (image-get-display-property) t)))
 822               (img-height (cdr (image-display-size
 823                                 (image-get-display-property) t))))
 824           (doc-view-enlarge (min (/ (float win-width) (float img-width))
 825                                  (/ (float (- win-height 1))
 826                                     (float img-height)))))
 827       ;; If slice is set
 828       (let* ((slice-width (nth 2 slice))
 829              (slice-height (nth 3 slice))
 830              (scale-factor (min (/ (float win-width) (float slice-width))
 831                                 (/ (float (- win-height 1))
 832                                    (float slice-height))))
 833              (new-slice (mapcar (lambda (x) (ceiling (* scale-factor x))) slice)))
 834         (doc-view-enlarge scale-factor)
 835         (setf (doc-view-current-slice) new-slice)
 836         (doc-view-goto-page (doc-view-current-page))))))
 837
 838 (defun doc-view-reconvert-doc ()
 839   "Reconvert the current document.
 840 Should be invoked when the cached images aren't up-to-date."
 841   (interactive)
 842   (doc-view-kill-proc)
 843   ;; Clear the old cached files
 844   (when (file-exists-p (doc-view--current-cache-dir))
 845     (delete-directory (doc-view--current-cache-dir) 'recursive))
 846   (kill-local-variable 'doc-view-last-page-number)
 847   (doc-view-initiate-display))
 848
 849 (defun doc-view-sentinel (proc event)
 850   "Generic sentinel for doc-view conversion processes."
 851   (if (not (string-match "finished" event))
 852       (message "DocView: process %s changed status to %s."
 853                (process-name proc)
 854                (if (string-match "\\(.+\\)\n?\\'" event)
 855                    (match-string 1 event)
 856                  event))
 857     (when (buffer-live-p (process-get proc 'buffer))
 858       (with-current-buffer (process-get proc 'buffer)
 859         (setq doc-view--current-converter-processes
 860               (delq proc doc-view--current-converter-processes))
 861         (setq mode-line-process
 862               (if doc-view--current-converter-processes
 863                   (format ":%s" (car doc-view--current-converter-processes))))
 864         (funcall (process-get proc 'callback))))))
 865
 866 (defun doc-view-start-process (name program args callback)
 867   ;; Make sure the process is started in an existing directory, (rather than
 868   ;; some file-name-handler-managed dir, for example).
 869   (let* ((default-directory (or (unhandled-file-name-directory
 870                                  default-directory)
 871                               (expand-file-name "~/")))
 872          (proc (apply 'start-process name doc-view-conversion-buffer
 873                       program args)))
 874     (push proc doc-view--current-converter-processes)
 875     (setq mode-line-process (list (format ":%s" proc)))
 876     (set-process-sentinel proc 'doc-view-sentinel)
 877     (process-put proc 'buffer   (current-buffer))
 878     (process-put proc 'callback callback)))
 879
 880 (defun doc-view-dvi->pdf (dvi pdf callback)
 881   "Convert DVI to PDF asynchronously and call CALLBACK when finished."
 882   ;; Prefer dvipdf over dvipdfm, because the latter has problems if the DVI
 883   ;; references and includes other PS files.
 884   (if (and doc-view-dvipdf-program
 885            (executable-find doc-view-dvipdf-program))
 886       (doc-view-start-process "dvi->pdf" doc-view-dvipdf-program
 887                               (list dvi pdf)
 888                               callback)
 889     (doc-view-start-process "dvi->pdf" doc-view-dvipdfm-program
 890                             (list "-o" pdf dvi)
 891                             callback)))
 892
 893 (defun doc-view-pdf->png-converter-ghostscript (pdf png page callback)
 894   (doc-view-start-process
 895    "pdf/ps->png" doc-view-ghostscript-program
 896    `(,@doc-view-ghostscript-options
 897      ,(format "-r%d" (round doc-view-resolution))
 898      ,@(if page `(,(format "-dFirstPage=%d" page)))
 899      ,@(if page `(,(format "-dLastPage=%d" page)))
 900      ,(concat "-sOutputFile=" png)
 901      ,pdf)
 902    callback))
 903
 904 (defalias 'doc-view-ps->png-converter-ghostscript
 905   'doc-view-pdf->png-converter-ghostscript)
 906
 907 (defun doc-view-djvu->tiff-converter-ddjvu (djvu tiff page callback)
 908   "Convert PAGE of a DJVU file to bitmap(s) asynchronously.
 909 Call CALLBACK with no arguments when done.
 910 If PAGE is nil, convert the whole document."
 911   (doc-view-start-process
 912    "djvu->tiff" "ddjvu"
 913    `("-format=tiff"
 914      ;; ddjvu only accepts the range 1-999.
 915      ,(format "-scale=%d" (round doc-view-resolution))
 916      ;; -eachpage was only added after djvulibre-3.5.25.3!
 917      ,@(unless page '("-eachpage"))
 918      ,@(if page `(,(format "-page=%d" page)))
 919      ,djvu
 920      ,tiff)
 921    callback))
 922
 923 (defun doc-view-pdf->png-converter-mupdf (pdf png page callback)
 924   (doc-view-start-process
 925    "pdf->png" doc-view-pdfdraw-program
 926    `(,(concat "-o" png)
 927      ,(format "-r%d" (round doc-view-resolution))
 928      ,pdf
 929      ,@(if page `(,(format "%d" page))))
 930    callback))
 931
 932 (defun doc-view-odf->pdf-converter-unoconv (odf callback)
 933   "Convert ODF to PDF asynchronously and call CALLBACK when finished.
 934 The converted PDF is put into the current cache directory, and it
 935 is named like ODF with the extension turned to pdf."
 936   (doc-view-start-process "odf->pdf" doc-view-odf->pdf-converter-program
 937                           (list "-f" "pdf" "-o" (doc-view--current-cache-dir) odf)
 938                           callback))
 939
 940 (defun doc-view-odf->pdf-converter-soffice (odf callback)
 941   "Convert ODF to PDF asynchronously and call CALLBACK when finished.
 942 The converted PDF is put into the current cache directory, and it
 943 is named like ODF with the extension turned to pdf."
 944   ;; FIXME: soffice doesn't work when there's another running
 945   ;; LibreOffice instance, in which case it returns success without
 946   ;; actually doing anything.  See LibreOffice bug
 947   ;; https://bugs.freedesktop.org/show_bug.cgi?id=37531.  A workaround
 948   ;; is to start soffice with a separate UserInstallation directory.
 949   (let ((tmp-user-install-dir (make-temp-file "libreoffice-docview" t)))
 950     (doc-view-start-process "odf->pdf" doc-view-odf->pdf-converter-program
 951                             (list
 952                              (concat "-env:UserInstallation=file://"
 953                                      tmp-user-install-dir)
 954                              "--headless" "--convert-to" "pdf"
 955                              "--outdir" (doc-view--current-cache-dir) odf)
 956                             (lambda ()
 957                               (delete-directory tmp-user-install-dir t)
 958                               (funcall callback)))))
 959
 960 (defun doc-view-pdf/ps->png (pdf-ps png)
 961   ;; FIXME: Fix name and docstring to account for djvu&tiff.
 962   "Convert PDF-PS to PNG asynchronously."
 963   (funcall
 964    (pcase doc-view-doc-type
 965      (`pdf doc-view-pdf->png-converter-function)
 966      (`djvu #'doc-view-djvu->tiff-converter-ddjvu)
 967      (_ #'doc-view-ps->png-converter-ghostscript))
 968    pdf-ps png nil
 969    (let ((resolution doc-view-resolution))
 970      (lambda ()
 971        ;; Only create the resolution file when it's all done, so it also
 972        ;; serves as a witness that the conversion is complete.
 973        (write-region (prin1-to-string resolution) nil
 974                      (expand-file-name "resolution.el"
 975                                        (doc-view--current-cache-dir))
 976                      nil 'silently)
 977        (when doc-view--current-timer
 978          (cancel-timer doc-view--current-timer)
 979          (setq doc-view--current-timer nil))
 980        (doc-view-display (current-buffer) 'force))))
 981
 982   ;; Update the displayed pages as soon as they're done generating.
 983   (when doc-view-conversion-refresh-interval
 984     (setq doc-view--current-timer
 985           (run-at-time "1 secs" doc-view-conversion-refresh-interval
 986                        'doc-view-display
 987                        (current-buffer)))))
 988
 989 (declare-function clear-image-cache "image.c" (&optional filter))
 990
 991 (defun doc-view-document->bitmap (pdf png pages)
 992   "Convert a document file to bitmap images asynchronously.
 993 Start by converting PAGES, and then the rest."
 994   (if (null pages)
 995       (doc-view-pdf/ps->png pdf png)
 996     ;; We could render several `pages' with a single process if they're
 997     ;; (almost) consecutive, but since in 99% of the cases, there'll be only
 998     ;; a single page anyway, and of the remaining 1%, few cases will have
 999     ;; consecutive pages, it's not worth the trouble.
1000     (let ((rest (cdr pages)))
1001       (funcall doc-view-single-page-converter-function
1002                pdf (format png (car pages)) (car pages)
1003        (lambda ()
1004          (if rest
1005              (doc-view-document->bitmap pdf png rest)
1006            ;; Yippie, the important pages are done, update the display.
1007            (clear-image-cache)
1008            ;; For the windows that have a message (like "Welcome to
1009            ;; DocView") display property, clearing the image cache is
1010            ;; not sufficient.
1011            (dolist (win (get-buffer-window-list (current-buffer) nil 'visible))
1012              (with-selected-window win
1013                (when (stringp (overlay-get (doc-view-current-overlay) 'display))
1014                  (doc-view-goto-page (doc-view-current-page)))))
1015            ;; Convert the rest of the pages.
1016            (doc-view-pdf/ps->png pdf png)))))))
1017
1018 (defun doc-view-pdf->txt (pdf txt callback)
1019   "Convert PDF to TXT asynchronously and call CALLBACK when finished."
1020   (or (executable-find doc-view-pdftotext-program)
1021       (error "You need the `pdftotext' program to convert a PDF to text"))
1022   (doc-view-start-process "pdf->txt" doc-view-pdftotext-program
1023                           (list "-raw" pdf txt)
1024                           callback))
1025
1026 (defun doc-view-current-cache-doc-pdf ()
1027   "Return the name of the doc.pdf in the current cache dir.
1028   This file exists only if the current document isn't a PDF or PS file already."
1029   (expand-file-name "doc.pdf" (doc-view--current-cache-dir)))
1030
1031 (defun doc-view-doc->txt (txt callback)
1032   "Convert the current document to text and call CALLBACK when done."
1033   (make-directory (doc-view--current-cache-dir) t)
1034   (pcase doc-view-doc-type
1035     (`pdf
1036      ;; Doc is a PDF, so convert it to TXT
1037      (doc-view-pdf->txt doc-view--buffer-file-name txt callback))
1038     (`ps
1039      ;; Doc is a PS, so convert it to PDF (which will be converted to
1040      ;; TXT thereafter).
1041      (let ((pdf (doc-view-current-cache-doc-pdf)))
1042        (doc-view-ps->pdf doc-view--buffer-file-name pdf
1043                          (lambda () (doc-view-pdf->txt pdf txt callback)))))
1044     (`dvi
1045      ;; Doc is a DVI.  This means that a doc.pdf already exists in its
1046      ;; cache subdirectory.
1047      (doc-view-pdf->txt (doc-view-current-cache-doc-pdf) txt callback))
1048     (`odf
1049      ;; Doc is some ODF (or MS Office) doc.  This means that a doc.pdf
1050      ;; already exists in its cache subdirectory.
1051      (doc-view-pdf->txt (doc-view-current-cache-doc-pdf) txt callback))
1052     (_ (error "DocView doesn't know what to do"))))
1053
1054 (defun doc-view-ps->pdf (ps pdf callback)
1055   "Convert PS to PDF asynchronously and call CALLBACK when finished."
1056   (or (executable-find doc-view-ps2pdf-program)
1057       (error "You need the `ps2pdf' program to convert PS to PDF"))
1058   (doc-view-start-process "ps->pdf" doc-view-ps2pdf-program
1059                           (list
1060                            ;; Avoid security problems when rendering files from
1061                            ;; untrusted sources.
1062                            "-dSAFER"
1063                            ;; in-file and out-file
1064                            ps pdf)
1065                           callback))
1066
1067 (defun doc-view-active-pages ()
1068   (let ((pages ()))
1069     (dolist (win (get-buffer-window-list (current-buffer) nil 'visible))
1070       (let ((page (image-mode-window-get 'page win)))
1071         (unless (memq page pages) (push page pages))))
1072     pages))
1073
1074 (defun doc-view-convert-current-doc ()
1075   "Convert `doc-view--buffer-file-name' to a set of png files, one file per page.
1076 Those files are saved in the directory given by the function
1077 `doc-view--current-cache-dir'."
1078   ;; Let stale files still display while we recompute the new ones, so only
1079   ;; flush the cache when the conversion is over.  One of the reasons why it
1080   ;; is important to keep displaying the stale page is so that revert-buffer
1081   ;; preserves the horizontal/vertical scroll settings (which are otherwise
1082   ;; reset during the redisplay).
1083   (setq doc-view--pending-cache-flush t)
1084   (let ((png-file (expand-file-name
1085                    (format doc-view--image-file-pattern "%d")
1086                    (doc-view--current-cache-dir))))
1087     (make-directory (doc-view--current-cache-dir) t)
1088     (pcase doc-view-doc-type
1089       (`dvi
1090        ;; DVI files have to be converted to PDF before Ghostscript can process
1091        ;; it.
1092        (let ((pdf (doc-view-current-cache-doc-pdf)))
1093          (doc-view-dvi->pdf doc-view--buffer-file-name pdf
1094                             (lambda () (doc-view-pdf/ps->png pdf png-file)))))
1095       (`odf
1096        ;; ODF files have to be converted to PDF before Ghostscript can
1097        ;; process it.
1098        (let ((pdf (doc-view-current-cache-doc-pdf))
1099              (opdf (expand-file-name
1100                     (concat (file-name-base doc-view--buffer-file-name)
1101                             ".pdf")
1102                     doc-view--current-cache-dir))
1103              (png-file png-file))
1104          ;; The unoconv tool only supports an output directory, but no
1105          ;; file name.  It's named like the input file with the
1106          ;; extension replaced by pdf.
1107          (funcall doc-view-odf->pdf-converter-function doc-view--buffer-file-name
1108                             (lambda ()
1109                               ;; Rename to doc.pdf
1110                               (rename-file opdf pdf)
1111                               (doc-view-pdf/ps->png pdf png-file)))))
1112       ((or `pdf `djvu)
1113        (let ((pages (doc-view-active-pages)))
1114          ;; Convert doc to bitmap images starting with the active pages.
1115          (doc-view-document->bitmap doc-view--buffer-file-name png-file pages)))
1116       (_
1117        ;; Convert to PNG images.
1118        (doc-view-pdf/ps->png doc-view--buffer-file-name png-file)))))
1119
1120 ;;;; Slicing
1121
1122 (declare-function image-size "image.c" (spec &optional pixels frame))
1123
1124 (defun doc-view-set-slice (x y width height)
1125   "Set the slice of the images that should be displayed.
1126 You can use this function to tell doc-view not to display the
1127 margins of the document.  It prompts for the top-left corner (X
1128 and Y) of the slice to display and its WIDTH and HEIGHT.
1129
1130 See `doc-view-set-slice-using-mouse' and
1131 `doc-view-set-slice-from-bounding-box' for more convenient ways
1132 to do that.  To reset the slice use `doc-view-reset-slice'."
1133   (interactive
1134    (let* ((size (image-size (doc-view-current-image) t))
1135           (a (read-number (format "Top-left X (0..%d): " (car size))))
1136           (b (read-number (format "Top-left Y (0..%d): " (cdr size))))
1137           (c (read-number (format "Width (0..%d): " (- (car size) a))))
1138           (d (read-number (format "Height (0..%d): " (- (cdr size) b)))))
1139      (list a b c d)))
1140   (setf (doc-view-current-slice) (list x y width height))
1141   ;; Redisplay
1142   (doc-view-goto-page (doc-view-current-page)))
1143
1144 (defun doc-view-set-slice-using-mouse ()
1145   "Set the slice of the images that should be displayed.
1146 You set the slice by pressing mouse-1 at its top-left corner and
1147 dragging it to its bottom-right corner.  See also
1148 `doc-view-set-slice' and `doc-view-reset-slice'."
1149   (interactive)
1150   (let (x y w h done)
1151     (while (not done)
1152       (let ((e (read-event
1153                 (concat "Press mouse-1 at the top-left corner and "
1154                         "drag it to the bottom-right corner!"))))
1155         (when (eq (car e) 'drag-mouse-1)
1156           (setq x (car (posn-object-x-y (event-start e))))
1157           (setq y (cdr (posn-object-x-y (event-start e))))
1158           (setq w (- (car (posn-object-x-y (event-end e))) x))
1159           (setq h (- (cdr (posn-object-x-y (event-end e))) y))
1160           (setq done t))))
1161     (doc-view-set-slice x y w h)))
1162
1163 (defun doc-view-get-bounding-box ()
1164   "Get the BoundingBox information of the current page."
1165   (let* ((page (doc-view-current-page))
1166          (doc (let ((cache-doc (doc-view-current-cache-doc-pdf)))
1167                 (if (file-exists-p cache-doc)
1168                     cache-doc
1169                   doc-view--buffer-file-name)))
1170          (o (shell-command-to-string
1171              (concat doc-view-ghostscript-program
1172                      " -dSAFER -dBATCH -dNOPAUSE -q -sDEVICE=bbox "
1173                      (format "-dFirstPage=%s -dLastPage=%s %s"
1174                              page page doc)))))
1175     (save-match-data
1176       (when (string-match (concat "%%BoundingBox: "
1177                                   "\\([[:digit:]]+\\) \\([[:digit:]]+\\) "
1178                                   "\\([[:digit:]]+\\) \\([[:digit:]]+\\)") o)
1179         (mapcar #'string-to-number
1180                 (list (match-string 1 o)
1181                       (match-string 2 o)
1182                       (match-string 3 o)
1183                       (match-string 4 o)))))))
1184
1185 (defvar doc-view-paper-sizes
1186   '((a4 595 842)
1187     (a4-landscape 842 595)
1188     (letter 612 792)
1189     (letter-landscape 792 612)
1190     (legal 612 1008)
1191     (legal-landscape 1008 612)
1192     (a3 842 1191)
1193     (a3-landscape 1191 842)
1194     (tabloid 792 1224)
1195     (ledger 1224 792))
1196   "An alist from paper size names to dimensions.")
1197
1198 (defun doc-view-guess-paper-size (iw ih)
1199   "Guess the paper size according to the aspect ratio."
1200   (cl-labels ((div (x y)
1201                    (round (/ (* 100.0 x) y))))
1202     (let ((ar (div iw ih))
1203           (al (mapcar (lambda (l)
1204                         (list (div (nth 1 l) (nth 2 l)) (car l)))
1205                       doc-view-paper-sizes)))
1206       (cadr (assoc ar al)))))
1207
1208 (defun doc-view-scale-bounding-box (ps iw ih bb)
1209   (list (/ (* (nth 0 bb) iw) (nth 1 (assoc ps doc-view-paper-sizes)))
1210         (/ (* (nth 1 bb) ih) (nth 2 (assoc ps doc-view-paper-sizes)))
1211         (/ (* (nth 2 bb) iw) (nth 1 (assoc ps doc-view-paper-sizes)))
1212         (/ (* (nth 3 bb) ih) (nth 2 (assoc ps doc-view-paper-sizes)))))
1213
1214 (defun doc-view-set-slice-from-bounding-box (&optional force-paper-size)
1215   "Set the slice from the document's BoundingBox information.
1216 The result is that the margins are almost completely cropped,
1217 much more accurate than could be done manually using
1218 `doc-view-set-slice-using-mouse'."
1219   (interactive "P")
1220   (let ((bb (doc-view-get-bounding-box)))
1221     (if (not bb)
1222         (message "BoundingBox couldn't be determined")
1223       (let* ((is (image-size (doc-view-current-image) t))
1224              (iw (car is))
1225              (ih (cdr is))
1226              (ps (or (and (null force-paper-size)
1227                           (doc-view-guess-paper-size iw ih))
1228                      (intern (completing-read "Paper size: "
1229                                               doc-view-paper-sizes
1230                                               nil t))))
1231              (bb (doc-view-scale-bounding-box ps iw ih bb))
1232              (x1 (nth 0 bb))
1233              (y1 (nth 1 bb))
1234              (x2 (nth 2 bb))
1235              (y2 (nth 3 bb)))
1236         ;; We keep a 2 pixel margin.
1237         (doc-view-set-slice (- x1 2) (- ih y2 2)
1238                             (+ (- x2 x1) 4) (+ (- y2 y1) 4))))))
1239
1240 (defun doc-view-reset-slice ()
1241   "Reset the current slice.
1242 After calling this function whole pages will be visible again."
1243   (interactive)
1244   (setf (doc-view-current-slice) nil)
1245   ;; Redisplay
1246   (doc-view-goto-page (doc-view-current-page)))
1247
1248 ;;;; Display
1249
1250 (defun doc-view-insert-image (file &rest args)
1251   "Insert the given png FILE.
1252 ARGS is a list of image descriptors."
1253   (when doc-view--pending-cache-flush
1254     (clear-image-cache)
1255     (setq doc-view--pending-cache-flush nil))
1256   (let ((ol (doc-view-current-overlay)))
1257     ;; Only insert the image if the buffer is visible.
1258     (when (window-live-p (overlay-get ol 'window))
1259       (let* ((image (if (and file (file-readable-p file))
1260                         (if (not (and doc-view-scale-internally
1261                                       (fboundp 'imagemagick-types)))
1262                             (apply 'create-image file doc-view--image-type nil args)
1263                           (unless (member :width args)
1264                             (setq args `(,@args :width ,doc-view-image-width)))
1265                           (apply 'create-image file 'imagemagick nil args))))
1266              (slice (doc-view-current-slice))
1267              (img-width (and image (car (image-size image))))
1268              (displayed-img-width (if (and image slice)
1269                                       (* (/ (float (nth 2 slice))
1270                                             (car (image-size image 'pixels)))
1271                                          img-width)
1272                                     img-width))
1273              (window-width (window-width (selected-window))))
1274         (setf (doc-view-current-image) image)
1275         (move-overlay ol (point-min) (point-max))
1276         ;; In case the window is wider than the image, center the image
1277         ;; horizontally.
1278         (overlay-put ol 'before-string
1279                      (when (and image (> window-width displayed-img-width))
1280                        (propertize " " 'display
1281                                    `(space :align-to (+ center (-0.5 . ,displayed-img-width))))))
1282         (overlay-put ol 'display
1283                      (cond
1284                       (image
1285                        (if slice
1286                            (list (cons 'slice slice) image)
1287                          image))
1288                       ;; We're trying to display a page that doesn't exist.
1289                       (doc-view--current-converter-processes
1290                        ;; Maybe the page doesn't exist *yet*.
1291                        "Cannot display this page (yet)!")
1292                       (t
1293                        ;; Typically happens if the conversion process somehow
1294                        ;; failed.  Better not signal an error here because it
1295                        ;; could prevent a subsequent reconversion from fixing
1296                        ;; the problem.
1297                        (concat "Cannot display this page!\n"
1298                                "Maybe because of a conversion failure!"))))
1299         (let ((win (overlay-get ol 'window)))
1300           (if (stringp (overlay-get ol 'display))
1301               (progn            ;Make sure the text is not scrolled out of view.
1302                 (set-window-hscroll win 0)
1303                 (set-window-vscroll win 0))
1304             (let ((hscroll (image-mode-window-get 'hscroll win))
1305                   (vscroll (image-mode-window-get 'vscroll win)))
1306               ;; Reset scroll settings, in case they were changed.
1307               (if hscroll (set-window-hscroll win hscroll))
1308               (if vscroll (set-window-vscroll win vscroll)))))))))
1309
1310 (defun doc-view-sort (a b)
1311   "Return non-nil if A should be sorted before B.
1312 Predicate for sorting `doc-view--current-files'."
1313   (or (< (length a) (length b))
1314       (and (= (length a) (length b))
1315            (string< a b))))
1316
1317 (defun doc-view-display (buffer &optional force)
1318   "Start viewing the document in BUFFER.
1319 If FORCE is non-nil, start viewing even if the document does not
1320 have the page we want to view."
1321   (with-current-buffer buffer
1322     (let ((prev-pages doc-view--current-files))
1323       (setq doc-view--current-files
1324             (sort (directory-files (doc-view--current-cache-dir) t
1325                                    (format doc-view--image-file-pattern
1326                                            "[0-9]+")
1327                                    t)
1328                   'doc-view-sort))
1329       (unless (eq (length prev-pages) (length doc-view--current-files))
1330         (force-mode-line-update))
1331       (dolist (win (or (get-buffer-window-list buffer nil t)
1332                        (list t)))
1333         (let* ((page (doc-view-current-page win))
1334                (pagefile (expand-file-name
1335                           (format doc-view--image-file-pattern page)
1336                           (doc-view--current-cache-dir))))
1337           (when (or force
1338                     (and (not (member pagefile prev-pages))
1339                          (member pagefile doc-view--current-files)))
1340             (if (windowp win)
1341                 (with-selected-window win
1342                   (cl-assert (eq (current-buffer) buffer) t)
1343                   (doc-view-goto-page page))
1344               (doc-view-goto-page page))))))))
1345
1346 (defun doc-view-buffer-message ()
1347   ;; Only show this message initially, not when refreshing the buffer (in which
1348   ;; case it's better to keep displaying the "stale" page while computing
1349   ;; the fresh new ones).
1350   (unless (overlay-get (doc-view-current-overlay) 'display)
1351     (overlay-put (doc-view-current-overlay) 'display
1352                  (concat (propertize "Welcome to DocView!" 'face 'bold)
1353                          "\n"
1354                          "
1355 If you see this buffer it means that the document you want to view is being
1356 converted to PNG and the conversion of the first page hasn't finished yet or
1357 `doc-view-conversion-refresh-interval' is set to nil.
1358
1359 For now these keys are useful:
1360
1361 `q' : Bury this buffer.  Conversion will go on in background.
1362 `k' : Kill the conversion process and this buffer.
1363 `K' : Kill the conversion process.\n"))))
1364
1365 (declare-function tooltip-show "tooltip" (text &optional use-echo-area))
1366
1367 (defun doc-view-show-tooltip ()
1368   (interactive)
1369   (tooltip-show (doc-view-current-info)))
1370
1371 (defun doc-view-open-text ()
1372   "Open a buffer with the current doc's contents as text."
1373   (interactive)
1374   (if doc-view--current-converter-processes
1375       (message "DocView: please wait till conversion finished.")
1376     (let ((txt (expand-file-name "doc.txt" (doc-view--current-cache-dir))))
1377       (if (file-readable-p txt)
1378           (let ((name (concat "Text contents of "
1379                               (file-name-nondirectory buffer-file-name)))
1380                 (dir (file-name-directory buffer-file-name)))
1381             (with-current-buffer (find-file txt)
1382               (rename-buffer name)
1383               (setq default-directory dir)))
1384         (doc-view-doc->txt txt 'doc-view-open-text)))))
1385
1386 ;;;;; Toggle between editing and viewing
1387
1388 (defvar-local doc-view-saved-settings nil
1389   "Doc-view settings saved while in some other mode.")
1390 (put 'doc-view-saved-settings 'permanent-local t)
1391
1392 (defun doc-view-toggle-display ()
1393   "Toggle between editing a document as text or viewing it."
1394   (interactive)
1395   (if (eq major-mode 'doc-view-mode)
1396       ;; Switch to editing mode
1397       (progn
1398         (doc-view-kill-proc)
1399         (setq buffer-read-only nil)
1400         ;; Switch to the previously used major mode or fall back to
1401         ;; normal mode.
1402         (doc-view-fallback-mode)
1403         (doc-view-minor-mode 1))
1404     ;; Switch to doc-view-mode
1405     (when (and (buffer-modified-p)
1406                (y-or-n-p "The buffer has been modified.  Save the changes? "))
1407       (save-buffer))
1408     (doc-view-mode)))
1409
1410 ;;;; Searching
1411
1412
1413 (defun doc-view-search-internal (regexp file)
1414   "Return a list of FILE's pages that contain text matching REGEXP.
1415 The value is an alist of the form (PAGE CONTEXTS) where PAGE is
1416 the pagenumber and CONTEXTS are all lines of text containing a match."
1417   (with-temp-buffer
1418     (insert-file-contents file)
1419     (let ((page 1)
1420           (lastpage 1)
1421           matches)
1422       (while (re-search-forward (concat "\\(?:\\([\f]\\)\\|\\("
1423                                         regexp "\\)\\)") nil t)
1424         (when (match-string 1) (setq page (1+ page)))
1425         (when (match-string 2)
1426           (if (/= page lastpage)
1427               (push (cons page
1428                           (list (buffer-substring
1429                                  (line-beginning-position)
1430                                  (line-end-position))))
1431                     matches)
1432             (setq matches (cons
1433                            (append
1434                             (or
1435                              ;; This page already is a match.
1436                              (car matches)
1437                              ;; This is the first match on page.
1438                              (list page))
1439                             (list (buffer-substring
1440                                    (line-beginning-position)
1441                                    (line-end-position))))
1442                            (cdr matches))))
1443           (setq lastpage page)))
1444       (nreverse matches))))
1445
1446 (defun doc-view-search-no-of-matches (list)
1447   "Extract the number of matches from the search result LIST."
1448   (let ((no 0))
1449     (dolist (p list)
1450       (setq no (+ no (1- (length p)))))
1451     no))
1452
1453 (defun doc-view-search-backward (new-query)
1454   "Call `doc-view-search' for backward search.
1455 If prefix NEW-QUERY is given, ask for a new regexp."
1456   (interactive "P")
1457   (doc-view-search new-query t))
1458
1459 (defun doc-view-search (new-query &optional backward)
1460   "Jump to the next match or initiate a new search if NEW-QUERY is given.
1461 If the current document hasn't been transformed to plain text
1462 till now do that first.
1463 If BACKWARD is non-nil, jump to the previous match."
1464   (interactive "P")
1465   (if (and (not new-query)
1466            doc-view--current-search-matches)
1467       (if backward
1468           (doc-view-search-previous-match 1)
1469         (doc-view-search-next-match 1))
1470     ;; New search, so forget the old results.
1471     (setq doc-view--current-search-matches nil)
1472     (let ((txt (expand-file-name "doc.txt"
1473                                  (doc-view--current-cache-dir))))
1474       (if (file-readable-p txt)
1475           (progn
1476             (setq doc-view--current-search-matches
1477                   (doc-view-search-internal
1478                    (read-from-minibuffer "Regexp: ")
1479                    txt))
1480             (message "DocView: search yielded %d matches."
1481                      (doc-view-search-no-of-matches
1482                       doc-view--current-search-matches)))
1483         ;; We must convert to TXT first!
1484         (if doc-view--current-converter-processes
1485             (message "DocView: please wait till conversion finished.")
1486           (doc-view-doc->txt txt (lambda () (doc-view-search nil))))))))
1487
1488 (defun doc-view-search-next-match (arg)
1489   "Go to the ARGth next matching page."
1490   (interactive "p")
1491   (let* ((next-pages (doc-view-remove-if
1492                       (lambda (i) (<= (car i) (doc-view-current-page)))
1493                       doc-view--current-search-matches))
1494          (page (car (nth (1- arg) next-pages))))
1495     (if page
1496         (doc-view-goto-page page)
1497       (when (and
1498              doc-view--current-search-matches
1499              (y-or-n-p "No more matches after current page.  Wrap to first match? "))
1500         (doc-view-goto-page (caar doc-view--current-search-matches))))))
1501
1502 (defun doc-view-search-previous-match (arg)
1503   "Go to the ARGth previous matching page."
1504   (interactive "p")
1505   (let* ((prev-pages (doc-view-remove-if
1506                       (lambda (i) (>= (car i) (doc-view-current-page)))
1507                       doc-view--current-search-matches))
1508          (page (car (nth (1- arg) (nreverse prev-pages)))))
1509     (if page
1510         (doc-view-goto-page page)
1511       (when (and
1512              doc-view--current-search-matches
1513              (y-or-n-p "No more matches before current page.  Wrap to last match? "))
1514         (doc-view-goto-page (caar (last doc-view--current-search-matches)))))))
1515
1516 ;;;; User interface commands and the mode
1517
1518 (put 'doc-view-mode 'mode-class 'special)
1519
1520 (defun doc-view-already-converted-p ()
1521   "Return non-nil if the current doc was already converted."
1522   (and (file-exists-p (doc-view--current-cache-dir))
1523        ;; Check that the resolution info is there, otherwise it means
1524        ;; the conversion is incomplete.
1525        (file-readable-p (expand-file-name "resolution.el"
1526                                           (doc-view--current-cache-dir)))
1527        (> (length (directory-files
1528                    (doc-view--current-cache-dir)
1529                    nil (format doc-view--image-file-pattern "[0-9]+")))
1530           0)))
1531
1532 (defun doc-view-initiate-display ()
1533   ;; Switch to image display if possible.
1534   (if (doc-view-mode-p doc-view-doc-type)
1535       (progn
1536         (doc-view-buffer-message)
1537         (setf (doc-view-current-page) (or (doc-view-current-page) 1))
1538         (if (doc-view-already-converted-p)
1539             (progn
1540               (message "DocView: using cached files!")
1541               ;; Load the saved resolution.
1542               (let* ((res-file
1543                       (expand-file-name "resolution.el"
1544                                         (doc-view--current-cache-dir)))
1545                      (res
1546                       (with-temp-buffer
1547                         (when (file-readable-p res-file)
1548                           (insert-file-contents res-file)
1549                           (read (current-buffer))))))
1550                 (when (numberp res)
1551                   (setq-local doc-view-resolution res)))
1552               (doc-view-display (current-buffer) 'force))
1553           (doc-view-convert-current-doc))
1554         (message
1555          "%s"
1556          (substitute-command-keys
1557           (concat "Type \\[doc-view-toggle-display] to toggle between "
1558                   "editing or viewing the document."))))
1559     (message
1560      "%s"
1561      (concat "No PNG support is available, or some conversion utility for "
1562              (file-name-extension doc-view--buffer-file-name)
1563              " files is missing."))
1564     (when (and (executable-find doc-view-pdftotext-program)
1565                (y-or-n-p
1566                 "Unable to render file.  View extracted text instead? "))
1567       (doc-view-open-text))
1568     (doc-view-toggle-display)))
1569
1570 (defvar bookmark-make-record-function)
1571
1572 (defun doc-view-clone-buffer-hook ()
1573   ;; FIXME: There are several potential problems linked with reconversion
1574   ;; and auto-revert when we have indirect buffers because they share their
1575   ;; /tmp cache directory.  This sharing is good (you'd rather not reconvert
1576   ;; for each clone), but that means that clones need to collaborate a bit.
1577   ;; I guess it mostly means: detect when a reconversion process is already
1578   ;; running, and run the sentinel in all clones.
1579   ;;
1580   ;; Maybe the clones should really have a separate /tmp directory
1581   ;; so they could have a different resolution and you could use clones
1582   ;; for zooming.
1583   (remove-overlays (point-min) (point-max) 'doc-view t)
1584   (if (consp image-mode-winprops-alist) (setq image-mode-winprops-alist nil)))
1585
1586 (defun doc-view-intersection (l1 l2)
1587   (let ((l ()))
1588     (dolist (x l1) (if (memq x l2) (push x l)))
1589     l))
1590
1591 (defun doc-view-set-doc-type ()
1592   "Figure out the current document type (`doc-view-doc-type')."
1593   (let ((name-types
1594          (when buffer-file-name
1595            (cdr (assoc (file-name-extension buffer-file-name)
1596                        '(
1597                          ;; DVI
1598                          ("dvi" dvi)
1599                          ;; PDF
1600                          ("pdf" pdf) ("epdf" pdf)
1601                          ;; PostScript
1602                          ("ps" ps) ("eps" ps)
1603                          ;; DjVu
1604                          ("djvu" djvu)
1605                          ;; OpenDocument formats
1606                          ("odt" odf) ("ods" odf) ("odp" odf) ("odg" odf)
1607                          ("odc" odf) ("odi" odf) ("odm" odf) ("ott" odf)
1608                          ("ots" odf) ("otp" odf) ("otg" odf)
1609                          ;; Microsoft Office formats (also handled
1610                          ;; by the odf conversion chain)
1611                          ("doc" odf) ("docx" odf) ("xls" odf) ("xlsx" odf)
1612                          ("ppt" odf) ("pptx" odf))))))
1613         (content-types
1614          (save-excursion
1615            (goto-char (point-min))
1616            (cond
1617             ((looking-at "%!") '(ps))
1618             ((looking-at "%PDF") '(pdf))
1619             ((looking-at "\367\002") '(dvi))
1620             ((looking-at "AT&TFORM") '(djvu))))))
1621     (setq-local
1622      doc-view-doc-type
1623      (car (or (doc-view-intersection name-types content-types)
1624               (when (and name-types content-types)
1625                 (error "Conflicting types: name says %s but content says %s"
1626                        name-types content-types))
1627               name-types content-types
1628               (error "Cannot determine the document type"))))))
1629
1630 (defun doc-view-set-up-single-converter ()
1631   "Find the right single-page converter for the current document type"
1632   (pcase-let ((`(,conv-function ,type ,extension)
1633                (pcase doc-view-doc-type
1634                  (`djvu (list #'doc-view-djvu->tiff-converter-ddjvu 'tiff "tif"))
1635                  (_     (list doc-view-pdf->png-converter-function  'png  "png")))))
1636     (setq-local doc-view-single-page-converter-function conv-function)
1637     (setq-local doc-view--image-type type)
1638     (setq-local doc-view--image-file-pattern (concat "page-%s." extension))))
1639
1640 ;; desktop.el integration
1641
1642 (defun doc-view-desktop-save-buffer (_desktop-dirname)
1643   `((page . ,(doc-view-current-page))
1644     (slice . ,(doc-view-current-slice))))
1645
1646 (declare-function desktop-restore-file-buffer "desktop"
1647                   (buffer-filename buffer-name buffer-misc))
1648
1649 (defun doc-view-restore-desktop-buffer (file name misc)
1650   (let ((page  (cdr (assq 'page misc)))
1651         (slice (cdr (assq 'slice misc))))
1652     (desktop-restore-file-buffer file name misc)
1653     (with-selected-window (or (get-buffer-window (current-buffer) 0)
1654                               (selected-window))
1655       (doc-view-goto-page page)
1656       (when slice (apply 'doc-view-set-slice slice)))))
1657
1658 (add-to-list 'desktop-buffer-mode-handlers
1659              '(doc-view-mode . doc-view-restore-desktop-buffer))
1660
1661 ;;;###autoload
1662 (defun doc-view-mode ()
1663   "Major mode in DocView buffers.
1664
1665 DocView Mode is an Emacs document viewer.  It displays PDF, PS
1666 and DVI files (as PNG images) in Emacs buffers.
1667
1668 You can use \\<doc-view-mode-map>\\[doc-view-toggle-display] to
1669 toggle between displaying the document or editing it as text.
1670 \\{doc-view-mode-map}"
1671   (interactive)
1672
1673   (if (= (point-min) (point-max))
1674       ;; The doc is empty or doesn't exist at all, so fallback to
1675       ;; another mode.  We used to also check file-exists-p, but this
1676       ;; returns nil for tar members.
1677       (doc-view-fallback-mode)
1678
1679     (let* ((prev-major-mode (if (derived-mode-p 'doc-view-mode)
1680                                 doc-view--previous-major-mode
1681                               (unless (eq major-mode 'fundamental-mode)
1682                                 major-mode))))
1683       (kill-all-local-variables)
1684       (setq-local doc-view--previous-major-mode prev-major-mode))
1685
1686     (dolist (var doc-view-saved-settings)
1687       (set (make-local-variable (car var)) (cdr var)))
1688
1689     ;; Figure out the document type.
1690     (unless doc-view-doc-type
1691       (doc-view-set-doc-type))
1692     (doc-view-set-up-single-converter)
1693
1694     (doc-view-make-safe-dir doc-view-cache-directory)
1695     ;; Handle compressed files, remote files, files inside archives
1696     (setq-local doc-view--buffer-file-name
1697                 (cond
1698                  (jka-compr-really-do-compress
1699                   ;; FIXME: there's a risk of name conflicts here.
1700                   (expand-file-name
1701                    (file-name-nondirectory
1702                     (file-name-sans-extension buffer-file-name))
1703                    doc-view-cache-directory))
1704                  ;; Is the file readable by local processes?
1705                  ;; We used to use `file-remote-p' but it's unclear what it's
1706                  ;; supposed to return nil for things like local files accessed
1707                  ;; via `su' or via file://...
1708                  ((let ((file-name-handler-alist nil))
1709                     (not (and buffer-file-name
1710                               (file-readable-p buffer-file-name))))
1711                   ;; FIXME: there's a risk of name conflicts here.
1712                   (expand-file-name
1713                    (if buffer-file-name
1714                        (file-name-nondirectory buffer-file-name)
1715                      (buffer-name))
1716                    doc-view-cache-directory))
1717                  (t buffer-file-name)))
1718     (when (not (string= doc-view--buffer-file-name buffer-file-name))
1719       (write-region nil nil doc-view--buffer-file-name))
1720
1721     (add-hook 'change-major-mode-hook
1722               (lambda ()
1723                 (doc-view-kill-proc)
1724                 (remove-overlays (point-min) (point-max) 'doc-view t))
1725               nil t)
1726     (add-hook 'clone-indirect-buffer-hook 'doc-view-clone-buffer-hook nil t)
1727     (add-hook 'kill-buffer-hook 'doc-view-kill-proc nil t)
1728     (when (and (boundp 'desktop-save-mode)
1729                desktop-save-mode)
1730       (setq-local desktop-save-buffer 'doc-view-desktop-save-buffer))
1731
1732     (remove-overlays (point-min) (point-max) 'doc-view t) ;Just in case.
1733     ;; Keep track of display info ([vh]scroll, page number, overlay,
1734     ;; ...)  for each window in which this document is shown.
1735     (add-hook 'image-mode-new-window-functions
1736               'doc-view-new-window-function nil t)
1737     (image-mode-setup-winprops)
1738
1739     (setq-local mode-line-position
1740                 '(" P" (:eval (number-to-string (doc-view-current-page)))
1741                   "/" (:eval (number-to-string (doc-view-last-page-number)))))
1742     ;; Don't scroll unless the user specifically asked for it.
1743     (setq-local auto-hscroll-mode nil)
1744     (setq-local mwheel-scroll-up-function #'doc-view-scroll-up-or-next-page)
1745     (setq-local mwheel-scroll-down-function
1746                 #'doc-view-scroll-down-or-previous-page)
1747     (setq-local cursor-type nil)
1748     (use-local-map doc-view-mode-map)
1749     (add-hook 'after-revert-hook 'doc-view-reconvert-doc nil t)
1750     (setq-local bookmark-make-record-function
1751                 #'doc-view-bookmark-make-record)
1752     (setq mode-name "DocView"
1753           buffer-read-only t
1754           major-mode 'doc-view-mode)
1755     (doc-view-initiate-display)
1756     ;; Switch off view-mode explicitly, because doc-view-mode is the
1757     ;; canonical view mode for PDF/PS/DVI files.  This could be
1758     ;; switched on automatically depending on the value of
1759     ;; `view-read-only'.
1760     (setq-local view-read-only nil)
1761     (run-mode-hooks 'doc-view-mode-hook)))
1762
1763 (defun doc-view-fallback-mode ()
1764   "Fallback to the previous or next best major mode."
1765   (let ((vars (if (derived-mode-p 'doc-view-mode)
1766                   (mapcar (lambda (var) (cons var (symbol-value var)))
1767                           '(doc-view-resolution
1768                             image-mode-winprops-alist)))))
1769     (remove-overlays (point-min) (point-max) 'doc-view t)
1770     (if doc-view--previous-major-mode
1771         (funcall doc-view--previous-major-mode)
1772       (let ((auto-mode-alist
1773              (rassq-delete-all
1774               'doc-view-mode-maybe
1775               (rassq-delete-all 'doc-view-mode
1776                                 (copy-alist auto-mode-alist)))))
1777         (normal-mode)))
1778     (when vars
1779       (setq-local doc-view-saved-settings vars))))
1780
1781 ;;;###autoload
1782 (defun doc-view-mode-maybe ()
1783   "Switch to `doc-view-mode' if possible.
1784 If the required external tools are not available, then fallback
1785 to the next best mode."
1786   (condition-case nil
1787       (doc-view-set-doc-type)
1788     (error (doc-view-fallback-mode)))
1789   (if (doc-view-mode-p doc-view-doc-type)
1790       (doc-view-mode)
1791     (doc-view-fallback-mode)))
1792
1793 ;;;###autoload
1794 (define-minor-mode doc-view-minor-mode
1795   "Toggle displaying buffer via Doc View (Doc View minor mode).
1796 With a prefix argument ARG, enable Doc View minor mode if ARG is
1797 positive, and disable it otherwise.  If called from Lisp, enable
1798 the mode if ARG is omitted or nil.
1799
1800 See the command `doc-view-mode' for more information on this mode."
1801   nil " DocView" doc-view-minor-mode-map
1802   :group 'doc-view
1803   (when doc-view-minor-mode
1804     (add-hook 'change-major-mode-hook (lambda () (doc-view-minor-mode -1)) nil t)
1805     (message
1806      "%s"
1807      (substitute-command-keys
1808       "Type \\[doc-view-toggle-display] to toggle between editing or viewing the document."))))
1809
1810 (defun doc-view-clear-cache ()
1811   "Delete the whole cache (`doc-view-cache-directory')."
1812   (interactive)
1813   (dired-delete-file doc-view-cache-directory 'always))
1814
1815 (defun doc-view-dired-cache ()
1816   "Open `dired' in `doc-view-cache-directory'."
1817   (interactive)
1818   (dired doc-view-cache-directory))
1819
1820
1821 ;;;; Bookmark integration
1822
1823 (declare-function bookmark-make-record-default
1824                   "bookmark" (&optional no-file no-context posn))
1825 (declare-function bookmark-prop-get "bookmark" (bookmark prop))
1826 (declare-function bookmark-default-handler "bookmark" (bmk))
1827
1828 (defun doc-view-bookmark-make-record ()
1829   (nconc (bookmark-make-record-default)
1830          `((page     . ,(doc-view-current-page))
1831            (handler  . doc-view-bookmark-jump))))
1832
1833
1834 ;;;###autoload
1835 (defun doc-view-bookmark-jump (bmk)
1836   ;; This implements the `handler' function interface for record type
1837   ;; returned by `doc-view-bookmark-make-record', which see.
1838   (prog1 (bookmark-default-handler bmk)
1839     (let ((page (bookmark-prop-get bmk 'page)))
1840       (when (not (eq major-mode 'doc-view-mode))
1841         (doc-view-toggle-display))
1842       (with-selected-window
1843        (or (get-buffer-window (current-buffer) 0)
1844            (selected-window))
1845        (doc-view-goto-page page)))))
1846
1847
1848 (provide 'doc-view)
1849
1850 ;; Local Variables:
1851 ;; eval: (outline-minor-mode 1)
1852 ;; End:
1853
1854 ;;; doc-view.el ends here