lisp/textmodes/outline.el

   1 ;;; outline.el --- outline mode commands for Emacs
   2
   3 ;; Copyright (C) 1986, 1993, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: outlines
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package is a major mode for editing outline-format documents.
  28 ;; An outline can be `abstracted' to show headers at any given level,
  29 ;; with all stuff below hidden.  See the Emacs manual for details.
  30
  31 ;;; Code:
  32
  33 ;; Jan '86, Some new features added by Peter Desnoyers and rewritten by RMS.
  34
  35 (defvar outline-regexp nil
  36   "*Regular expression to match the beginning of a heading.
  37 Any line whose beginning matches this regexp is considered to start a heading.
  38 The recommended way to set this is with a Local Variables: list
  39 in the file it applies to.  See also outline-heading-end-regexp.")
  40
  41 ;; Can't initialize this in the defvar above -- some major modes have
  42 ;; already assigned a local value to it.
  43 (or (default-value 'outline-regexp)
  44     (setq-default outline-regexp "[*\^L]+"))
  45
  46 (defvar outline-heading-end-regexp "\n"
  47   "*Regular expression to match the end of a heading line.
  48 You can assume that point is at the beginning of a heading when this
  49 regexp is searched for.  The heading ends at the end of the match.
  50 The recommended way to set this is with a `Local Variables:' list
  51 in the file it applies to.")
  52
  53 (defvar outline-mode-prefix-map nil)
  54
  55 (if outline-mode-prefix-map
  56     nil
  57   (setq outline-mode-prefix-map (make-sparse-keymap))
  58   (define-key outline-mode-prefix-map "\C-n" 'outline-next-visible-heading)
  59   (define-key outline-mode-prefix-map "\C-p" 'outline-previous-visible-heading)
  60   (define-key outline-mode-prefix-map "\C-i" 'show-children)
  61   (define-key outline-mode-prefix-map "\C-s" 'show-subtree)
  62   (define-key outline-mode-prefix-map "\C-d" 'hide-subtree)
  63   (define-key outline-mode-prefix-map "\C-u" 'outline-up-heading)
  64   (define-key outline-mode-prefix-map "\C-f" 'outline-forward-same-level)
  65   (define-key outline-mode-prefix-map "\C-b" 'outline-backward-same-level)
  66   (define-key outline-mode-prefix-map "\C-t" 'hide-body)
  67   (define-key outline-mode-prefix-map "\C-a" 'show-all)
  68   (define-key outline-mode-prefix-map "\C-c" 'hide-entry)
  69   (define-key outline-mode-prefix-map "\C-e" 'show-entry)
  70   (define-key outline-mode-prefix-map "\C-l" 'hide-leaves)
  71   (define-key outline-mode-prefix-map "\C-k" 'show-branches)
  72   (define-key outline-mode-prefix-map "\C-q" 'hide-sublevels)
  73   (define-key outline-mode-prefix-map "\C-o" 'hide-other))
  74
  75 (defvar outline-mode-menu-bar-map nil)
  76 (if outline-mode-menu-bar-map
  77     nil
  78   (setq outline-mode-menu-bar-map (make-sparse-keymap))
  79
  80   (define-key outline-mode-menu-bar-map [hide]
  81     (cons "Hide" (make-sparse-keymap "Hide")))
  82
  83   (define-key outline-mode-menu-bar-map [hide hide-other]
  84     '("Hide Other" . hide-other))
  85   (define-key outline-mode-menu-bar-map [hide hide-sublevels]
  86     '("Hide Sublevels" . hide-sublevels))
  87   (define-key outline-mode-menu-bar-map [hide hide-subtree]
  88     '("Hide Subtree" . hide-subtree))
  89   (define-key outline-mode-menu-bar-map [hide hide-entry]
  90     '("Hide Entry" . hide-entry))
  91   (define-key outline-mode-menu-bar-map [hide hide-body]
  92     '("Hide Body" . hide-body))
  93   (define-key outline-mode-menu-bar-map [hide hide-leaves]
  94     '("Hide Leaves" . hide-leaves))
  95
  96   (define-key outline-mode-menu-bar-map [show]
  97     (cons "Show" (make-sparse-keymap "Show")))
  98
  99   (define-key outline-mode-menu-bar-map [show show-subtree]
 100     '("Show Subtree" . show-subtree))
 101   (define-key outline-mode-menu-bar-map [show show-children]
 102     '("Show Children" . show-children))
 103   (define-key outline-mode-menu-bar-map [show show-branches]
 104     '("Show Branches" . show-branches))
 105   (define-key outline-mode-menu-bar-map [show show-entry]
 106     '("Show Entry" . show-entry))
 107   (define-key outline-mode-menu-bar-map [show show-all]
 108     '("Show All" . show-all))
 109
 110   (define-key outline-mode-menu-bar-map [headings]
 111     (cons "Headings" (make-sparse-keymap "Headings")))
 112
 113   (define-key outline-mode-menu-bar-map [headings outline-backward-same-level]
 114     '("Previous Same Level" . outline-backward-same-level))
 115   (define-key outline-mode-menu-bar-map [headings outline-forward-same-level]
 116     '("Next Same Level" . outline-forward-same-level))
 117   (define-key outline-mode-menu-bar-map [headings outline-previous-visible-heading]
 118     '("Previous" . outline-previous-visible-heading))
 119   (define-key outline-mode-menu-bar-map [headings outline-next-visible-heading]
 120     '("Next" . outline-next-visible-heading))
 121   (define-key outline-mode-menu-bar-map [headings outline-up-heading]
 122     '("Up" . outline-up-heading)))
 123
 124 (defvar outline-mode-map nil "")
 125
 126 (if outline-mode-map
 127     nil
 128   (setq outline-mode-map (nconc (make-sparse-keymap) text-mode-map))
 129   (define-key outline-mode-map "\C-c" outline-mode-prefix-map)
 130   (define-key outline-mode-map [menu-bar] outline-mode-menu-bar-map))
 131
 132 (defvar outline-minor-mode nil
 133   "Non-nil if using Outline mode as a minor mode of some other mode.")
 134 (make-variable-buffer-local 'outline-minor-mode)
 135 (put 'outline-minor-mode 'permanent-local t)
 136 (or (assq 'outline-minor-mode minor-mode-alist)
 137     (setq minor-mode-alist (append minor-mode-alist
 138                                    (list '(outline-minor-mode " Outl")))))
 139
 140 (defvar outline-font-lock-keywords
 141   '(;; Highlight headings according to the level.
 142     ("^\\(\\*+\\)[ \t]*\\(.+\\)?[ \t]*$"
 143      (1 font-lock-string-face)
 144      (2 (let ((len (- (match-end 1) (match-beginning 1))))
 145           (or (cdr (assq len '((1 . font-lock-function-name-face)
 146                                (2 . font-lock-keyword-face)
 147                                (3 . font-lock-comment-face))))
 148               font-lock-variable-name-face))
 149         nil t))
 150     ;; Highlight citations of the form [1] and [Mar94].
 151     ("\\[\\([A-Z][A-Za-z]+\\)*[0-9]+\\]" . font-lock-type-face))
 152   "Additional expressions to highlight in Outline mode.")
 153
 154 (defvar outline-view-change-hook nil
 155   "Normal hook to be run after outline visibility changes.")
 156
 157 ;;;autoload
 158 (defun outline-mode ()
 159   "Set major mode for editing outlines with selective display.
 160 Headings are lines which start with asterisks: one for major headings,
 161 two for subheadings, etc.  Lines not starting with asterisks are body lines.
 162
 163 Body text or subheadings under a heading can be made temporarily
 164 invisible, or visible again.  Invisible lines are attached to the end
 165 of the heading, so they move with it, if the line is killed and yanked
 166 back.  A heading with text hidden under it is marked with an ellipsis (...).
 167
 168 Commands:\\<outline-mode-map>
 169 \\[outline-next-visible-heading]   outline-next-visible-heading      move by visible headings
 170 \\[outline-previous-visible-heading]   outline-previous-visible-heading
 171 \\[outline-forward-same-level]   outline-forward-same-level        similar but skip subheadings
 172 \\[outline-backward-same-level]   outline-backward-same-level
 173 \\[outline-up-heading]   outline-up-heading                 move from subheading to heading
 174
 175 \\[hide-body]   make all text invisible (not headings).
 176 \\[show-all]    make everything in buffer visible.
 177
 178 The remaining commands are used when point is on a heading line.
 179 They apply to some of the body or subheadings of that heading.
 180 \\[hide-subtree]   hide-subtree make body and subheadings invisible.
 181 \\[show-subtree]   show-subtree make body and subheadings visible.
 182 \\[show-children]   show-children       make direct subheadings visible.
 183                  No effect on body, or subheadings 2 or more levels down.
 184                  With arg N, affects subheadings N levels down.
 185 \\[hide-entry]     make immediately following body invisible.
 186 \\[show-entry]     make it visible.
 187 \\[hide-leaves]    make body under heading and under its subheadings invisible.
 188                      The subheadings remain visible.
 189 \\[show-branches]  make all subheadings at all levels visible.
 190
 191 The variable `outline-regexp' can be changed to control what is a heading.
 192 A line is a heading if `outline-regexp' matches something at the
 193 beginning of the line.  The longer the match, the deeper the level.
 194
 195 Turning on outline mode calls the value of `text-mode-hook' and then of
 196 `outline-mode-hook', if they are non-nil."
 197   (interactive)
 198   (kill-all-local-variables)
 199   (use-local-map outline-mode-map)
 200   (setq mode-name "Outline")
 201   (setq major-mode 'outline-mode)
 202   (define-abbrev-table 'text-mode-abbrev-table ())
 203   (setq local-abbrev-table text-mode-abbrev-table)
 204   (set-syntax-table text-mode-syntax-table)
 205   (make-local-variable 'line-move-ignore-invisible)
 206   (setq line-move-ignore-invisible t)
 207   ;; Cause use of ellipses for invisible text.
 208   (setq buffer-invisibility-spec '((t . t)))
 209   (make-local-variable 'paragraph-start)
 210   (setq paragraph-start (concat paragraph-start "\\|\\("
 211                                 outline-regexp "\\)"))
 212   ;; Inhibit auto-filling of header lines.
 213   (make-local-variable 'auto-fill-inhibit-regexp)
 214   (setq auto-fill-inhibit-regexp outline-regexp)
 215   (make-local-variable 'paragraph-separate)
 216   (setq paragraph-separate (concat paragraph-separate "\\|\\("
 217                                    outline-regexp "\\)"))
 218   (make-local-variable 'font-lock-defaults)
 219   (setq font-lock-defaults '(outline-font-lock-keywords t))
 220   (make-local-variable 'change-major-mode-hook)
 221   (add-hook 'change-major-mode-hook 'show-all)
 222   (run-hooks 'text-mode-hook 'outline-mode-hook))
 223
 224 (defvar outline-minor-mode-prefix "\C-c@"
 225   "*Prefix key to use for Outline commands in Outline minor mode.
 226 The value of this variable is checked as part of loading Outline mode.
 227 After that, changing the prefix key requires manipulating keymaps.")
 228
 229 (defvar outline-minor-mode-map nil)
 230 (if outline-minor-mode-map
 231     nil
 232   (setq outline-minor-mode-map (make-sparse-keymap))
 233   (define-key outline-minor-mode-map [menu-bar]
 234     outline-mode-menu-bar-map)
 235   (define-key outline-minor-mode-map outline-minor-mode-prefix
 236     outline-mode-prefix-map))
 237
 238 (or (assq 'outline-minor-mode minor-mode-map-alist)
 239     (setq minor-mode-map-alist
 240           (cons (cons 'outline-minor-mode outline-minor-mode-map)
 241                 minor-mode-map-alist)))
 242
 243 ;;;autoload
 244 (defun outline-minor-mode (&optional arg)
 245   "Toggle Outline minor mode.
 246 With arg, turn Outline minor mode on if arg is positive, off otherwise.
 247 See the command `outline-mode' for more information on this mode."
 248   (interactive "P")
 249   (setq outline-minor-mode
 250         (if (null arg) (not outline-minor-mode)
 251           (> (prefix-numeric-value arg) 0)))
 252   (if outline-minor-mode
 253       (progn
 254         (make-local-variable 'line-move-ignore-invisible)
 255         (setq line-move-ignore-invisible t)
 256         ;; Cause use of ellipses for invisible text.
 257         (setq buffer-invisibility-spec '((t . t)))
 258         (run-hooks 'outline-minor-mode-hook))
 259     (setq line-move-ignore-invisible nil)
 260     ;; Cause use of ellipses for invisible text.
 261     (setq buffer-invisibility-spec t))
 262   ;; When turning off outline mode, get rid of any outline hiding.
 263   (or outline-minor-mode
 264       (show-all))
 265   (force-mode-line-update))
 266 \f
 267 (defvar outline-level 'outline-level
 268   "Function of no args to compute a header's nesting level in an outline.
 269 It can assume point is at the beginning of a header line.")
 270
 271 ;; This used to count columns rather than characters, but that made ^L
 272 ;; appear to be at level 2 instead of 1.  Columns would be better for
 273 ;; tab handling, but the default regexp doesn't use tabs, and anyone
 274 ;; who changes the regexp can also redefine the outline-level variable
 275 ;; as appropriate.
 276 (defun outline-level ()
 277   "Return the depth to which a statement is nested in the outline.
 278 Point must be at the beginning of a header line.  This is actually
 279 the number of characters that `outline-regexp' matches."
 280   (save-excursion
 281     (looking-at outline-regexp)
 282     (- (match-end 0) (match-beginning 0))))
 283
 284 (defun outline-next-preface ()
 285   "Skip forward to just before the next heading line.
 286 If there's no following heading line, stop before the newline
 287 at the end of the buffer."
 288   (if (re-search-forward (concat "\n\\(" outline-regexp "\\)")
 289                          nil 'move)
 290       (goto-char (match-beginning 0)))
 291   (if (bolp)
 292       (forward-char -1)))
 293
 294 (defun outline-next-heading ()
 295   "Move to the next (possibly invisible) heading line."
 296   (interactive)
 297   (if (re-search-forward (concat "\n\\(" outline-regexp "\\)")
 298                          nil 'move)
 299       (goto-char (1+ (match-beginning 0)))))
 300
 301 (defsubst outline-visible ()
 302   "Non-nil if the character after point is visible."
 303   (not (get-char-property (point) 'invisible)))
 304
 305 (defun outline-back-to-heading ()
 306   "Move to previous heading line, or beg of this line if it's a heading.
 307 Only visible heading lines are considered."
 308   (beginning-of-line)
 309   (or (outline-on-heading-p)
 310       (let (found)
 311         (while (not found)
 312           (setq found
 313                 (and (re-search-backward (concat "^\\(" outline-regexp "\\)")
 314                                          nil t)
 315                      (outline-visible))))
 316         found)
 317       (error "before first heading")))
 318
 319 (defun outline-on-heading-p ()
 320   "Return t if point is on a (visible) heading line."
 321   (save-excursion
 322     (beginning-of-line)
 323     (and (bolp) (outline-visible)
 324          (looking-at outline-regexp))))
 325
 326 (defun outline-end-of-heading ()
 327   (if (re-search-forward outline-heading-end-regexp nil 'move)
 328       (forward-char -1)))
 329
 330 (defun outline-next-visible-heading (arg)
 331   "Move to the next visible heading line.
 332 With argument, repeats or can move backward if negative.
 333 A heading line is one that starts with a `*' (or that
 334 `outline-regexp' matches)."
 335   (interactive "p")
 336   (if (< arg 0)
 337       (beginning-of-line)
 338     (end-of-line))
 339   (while (and (not (bobp)) (< arg 0))
 340     (while (and (not (bobp))
 341                 (re-search-backward (concat "^\\(" outline-regexp "\\)")
 342                                     nil 'move)
 343                 (not (outline-visible))))
 344     (setq arg (1+ arg)))
 345   (while (and (not (eobp)) (> arg 0))
 346     (while (and (not (eobp))
 347                 (re-search-forward (concat "^\\(" outline-regexp "\\)")
 348                                    nil 'move)
 349                 (not (outline-visible))))
 350     (setq arg (1- arg)))
 351   (beginning-of-line))
 352
 353 (defun outline-previous-visible-heading (arg)
 354   "Move to the previous heading line.
 355 With argument, repeats or can move forward if negative.
 356 A heading line is one that starts with a `*' (or that
 357 `outline-regexp' matches)."
 358   (interactive "p")
 359   (outline-next-visible-heading (- arg)))
 360
 361 (defun outline-flag-region (from to flag)
 362   "Hides or shows lines from FROM to TO, according to FLAG.
 363 If FLAG is nil then text is shown, while if FLAG is t the text is hidden."
 364   (let ((inhibit-read-only t))
 365     (save-excursion
 366       (goto-char from)
 367       (end-of-line)
 368       (outline-discard-overlays (point) to 'outline)
 369       (if flag
 370           (let ((o (make-overlay (point) to)))
 371             (overlay-put o 'invisible flag)
 372             (overlay-put o 'outline t)))))
 373   (run-hooks 'outline-view-change-hook))
 374
 375 ;; Exclude from the region BEG ... END all overlays
 376 ;; with a non-nil PROP property.
 377 ;; Exclude them by shrinking them to exclude BEG ... END,
 378 ;; or even by splitting them if necessary.
 379 ;; Overlays without a non-nil PROP property are not touched.
 380 (defun outline-discard-overlays (beg end prop)
 381   (if (< end beg)
 382       (setq beg (prog1 end (setq end beg))))
 383   (save-excursion
 384     (goto-char beg)
 385     (while (< (point) end)
 386       (let ((overlays (overlays-at (point))))
 387         (while overlays
 388           (let ((o (car overlays)))
 389             (if (overlay-get o prop)
 390                 ;; Either push this overlay outside beg...end
 391                 ;; or split it to exclude beg...end
 392                 ;; or delete it entirely (if it is contained in beg...end).
 393                 (if (< (overlay-start o) beg)
 394                     (if (> (overlay-end o) end)
 395                         (let ((o1 (outline-copy-overlay o)))
 396                           (move-overlay o1 (overlay-start o1) beg)
 397                       (move-overlay o (overlay-start o) beg)))
 398                   (if (> (overlay-end o) end)
 399                       (move-overlay o end (overlay-end o))
 400                     (delete-overlay o)))))
 401           (setq overlays (cdr overlays))))
 402       (goto-char (next-overlay-change (point))))))
 403
 404 ;; Make a copy of overlay O, with the same beginning, end and properties.
 405 (defun outline-copy-overlay (o)
 406   (let ((o1 (make-overlay (overlay-start o) (overlay-end o)
 407                           (overlay-buffer o)))
 408         (props (overlay-properties o)))
 409     (while props
 410       (overlay-put o1 (car props) (nth 1 props))
 411       (setq props (cdr (cdr props))))
 412     o1))
 413 \f
 414 (defun hide-entry ()
 415   "Hide the body directly following this heading."
 416   (interactive)
 417   (outline-back-to-heading)
 418   (outline-end-of-heading)
 419   (save-excursion
 420    (outline-flag-region (point) (progn (outline-next-preface) (point)) t)))
 421
 422 (defun show-entry ()
 423   "Show the body directly following this heading."
 424   (interactive)
 425   (save-excursion
 426    (outline-flag-region (point) (progn (outline-next-preface) (point)) nil)))
 427
 428 (defun hide-body ()
 429   "Hide all of buffer except headings."
 430   (interactive)
 431   (hide-region-body (point-min) (point-max)))
 432
 433 (defun hide-region-body (start end)
 434   "Hide all body lines in the region, but not headings."
 435   (save-excursion
 436     (save-restriction
 437       (narrow-to-region start end)
 438       (goto-char (point-min))
 439       (if (outline-on-heading-p)
 440           (outline-end-of-heading))
 441       (while (not (eobp))
 442         (outline-flag-region (point)
 443                              (progn (outline-next-preface) (point)) t)
 444         (if (not (eobp))
 445             (progn
 446               (forward-char
 447                (if (looking-at "\n\n")
 448                    2 1))
 449               (outline-end-of-heading)))))))
 450
 451 (defun show-all ()
 452   "Show all of the text in the buffer."
 453   (interactive)
 454   (outline-flag-region (point-min) (point-max) nil))
 455
 456 (defun hide-subtree ()
 457   "Hide everything after this heading at deeper levels."
 458   (interactive)
 459   (outline-flag-subtree t))
 460
 461 (defun hide-leaves ()
 462   "Hide all body after this heading at deeper levels."
 463   (interactive)
 464   (outline-back-to-heading)
 465   (outline-end-of-heading)
 466   (hide-region-body (point) (progn (outline-end-of-subtree) (point))))
 467
 468 (defun show-subtree ()
 469   "Show everything after this heading at deeper levels."
 470   (interactive)
 471   (outline-flag-subtree nil))
 472
 473 (defun hide-sublevels (levels)
 474   "Hide everything but the top LEVELS levels of headers, in whole buffer."
 475   (interactive "p")
 476   (if (< levels 1)
 477       (error "Must keep at least one level of headers"))
 478   (setq levels (1- levels))
 479   (save-excursion
 480     (goto-char (point-min))
 481     ;; Keep advancing to the next top-level heading.
 482     (while (or (and (bobp) (outline-on-heading-p))
 483                (outline-next-heading))
 484       (let ((end (save-excursion (outline-end-of-subtree) (point))))
 485         ;; Hide everything under that.
 486         (outline-flag-region (point) end t)
 487         ;; Show the first LEVELS levels under that.
 488         (if (> levels 0)
 489             (show-children levels))
 490         ;; Move to the next, since we already found it.
 491         (goto-char end)))))
 492
 493 (defun hide-other ()
 494   "Hide everything except for the current body and the parent headings."
 495   (interactive)
 496   (hide-sublevels 1)
 497   (let ((last (point))
 498         (pos (point)))
 499     (while (save-excursion
 500              (and (end-of-line 0)
 501                   (not (outline-visible))))
 502       (save-excursion
 503         (beginning-of-line)
 504         (if (eq last (point))
 505             (progn
 506               (outline-next-heading)
 507               (outline-flag-region last (point) nil))
 508           (show-children)
 509           (setq last (point)))))))
 510
 511 (defun outline-flag-subtree (flag)
 512   (save-excursion
 513     (outline-back-to-heading)
 514     (outline-end-of-heading)
 515     (outline-flag-region (point)
 516                           (progn (outline-end-of-subtree) (point))
 517                           flag)))
 518
 519 (defun outline-end-of-subtree ()
 520   (outline-back-to-heading)
 521   (let ((opoint (point))
 522         (first t)
 523         (level (funcall outline-level)))
 524     (while (and (not (eobp))
 525                 (or first (> (funcall outline-level) level)))
 526       (setq first nil)
 527       (outline-next-heading))
 528     (if (bolp)
 529         (progn
 530           ;; Go to end of line before heading
 531           (forward-char -1)
 532           (if (bolp)
 533               ;; leave blank line before heading
 534               (forward-char -1))))))
 535 \f
 536 (defun show-branches ()
 537   "Show all subheadings of this heading, but not their bodies."
 538   (interactive)
 539   (show-children 1000))
 540
 541 (defun show-children (&optional level)
 542   "Show all direct subheadings of this heading.
 543 Prefix arg LEVEL is how many levels below the current level should be shown.
 544 Default is enough to cause the following heading to appear."
 545   (interactive "P")
 546   (setq level
 547         (if level (prefix-numeric-value level)
 548           (save-excursion
 549             (outline-back-to-heading)
 550             (let ((start-level (funcall outline-level)))
 551               (outline-next-heading)
 552               (if (eobp)
 553                   1
 554                 (max 1 (- (funcall outline-level) start-level)))))))
 555   (save-excursion
 556     (save-restriction
 557       (outline-back-to-heading)
 558       (setq level (+ level (funcall outline-level)))
 559       (narrow-to-region (point)
 560                         (progn (outline-end-of-subtree)
 561                                (if (eobp) (point-max) (1+ (point)))))
 562       (goto-char (point-min))
 563       (while (and (not (eobp))
 564                   (progn
 565                     (outline-next-heading)
 566                     (not (eobp))))
 567         (if (<= (funcall outline-level) level)
 568             (save-excursion
 569               (outline-flag-region (save-excursion
 570                                      (forward-char -1)
 571                                      (if (bolp)
 572                                          (forward-char -1))
 573                                      (point))
 574                                    (progn (outline-end-of-heading) (point))
 575                                    nil)))))))
 576 \f
 577 (defun outline-up-heading (arg)
 578   "Move to the heading line of which the present line is a subheading.
 579 With argument, move up ARG levels."
 580   (interactive "p")
 581   (outline-back-to-heading)
 582   (if (eq (funcall outline-level) 1)
 583       (error ""))
 584   (while (and (> (funcall outline-level) 1)
 585               (> arg 0)
 586               (not (bobp)))
 587     (let ((present-level (funcall outline-level)))
 588       (while (not (< (funcall outline-level) present-level))
 589         (outline-previous-visible-heading 1))
 590       (setq arg (- arg 1)))))
 591
 592 (defun outline-forward-same-level (arg)
 593   "Move forward to the ARG'th subheading at same level as this one.
 594 Stop at the first and last subheadings of a superior heading."
 595   (interactive "p")
 596   (outline-back-to-heading)
 597   (while (> arg 0)
 598     (let ((point-to-move-to (save-excursion
 599                               (outline-get-next-sibling))))
 600       (if point-to-move-to
 601           (progn
 602             (goto-char point-to-move-to)
 603             (setq arg (1- arg)))
 604         (progn
 605           (setq arg 0)
 606           (error ""))))))
 607
 608 (defun outline-get-next-sibling ()
 609   "Move to next heading of the same level, and return point or nil if none."
 610   (let ((level (funcall outline-level)))
 611     (outline-next-visible-heading 1)
 612     (while (and (> (funcall outline-level) level)
 613                 (not (eobp)))
 614       (outline-next-visible-heading 1))
 615     (if (< (funcall outline-level) level)
 616         nil
 617       (point))))
 618
 619 (defun outline-backward-same-level (arg)
 620   "Move backward to the ARG'th subheading at same level as this one.
 621 Stop at the first and last subheadings of a superior heading."
 622   (interactive "p")
 623   (outline-back-to-heading)
 624   (while (> arg 0)
 625     (let ((point-to-move-to (save-excursion
 626                               (outline-get-last-sibling))))
 627       (if point-to-move-to
 628           (progn
 629             (goto-char point-to-move-to)
 630             (setq arg (1- arg)))
 631         (progn
 632           (setq arg 0)
 633           (error ""))))))
 634
 635 (defun outline-get-last-sibling ()
 636   "Move to next heading of the same level, and return point or nil if none."
 637   (let ((level (funcall outline-level)))
 638     (outline-previous-visible-heading 1)
 639     (while (and (> (funcall outline-level) level)
 640                 (not (bobp)))
 641       (outline-previous-visible-heading 1))
 642     (if (< (funcall outline-level) level)
 643         nil
 644         (point))))
 645
 646 (provide 'outline)
 647 (provide 'noutline)
 648
 649 ;;; outline.el ends here