lisp/emacs-lisp/eldoc.el

   1 ;;; eldoc.el --- show function arglist or variable docstring in echo area
   2
   3 ;; Copyright (C) 1995 Noah S. Friedman
   4
   5 ;; Author: Noah Friedman <friedman@prep.ai.mit.edu>
   6 ;; Maintainer: friedman@prep.ai.mit.edu
   7 ;; Keywords: extensions
   8 ;; Status: Works in Emacs 19 and XEmacs.
   9 ;; Created: 1995-10-06
  10
  11 ;; LCD Archive Entry:
  12 ;; eldoc|Noah Friedman|friedman@prep.ai.mit.edu|
  13 ;; show function arglist or variable docstring in echo area|
  14 ;; $Date: 1995/11/21 15:21:34 $|$Revision: 1.4 $|~/misc/eldoc.el.gz|
  15
  16 ;; $Id: eldoc.el,v 1.4 1995/11/21 15:21:34 friedman Exp friedman $
  17
  18 ;; This program is free software; you can redistribute it and/or modify
  19 ;; it under the terms of the GNU General Public License as published by
  20 ;; the Free Software Foundation; either version 2, or (at your option)
  21 ;; any later version.
  22 ;;
  23 ;; This program is distributed in the hope that it will be useful,
  24 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  25 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  26 ;; GNU General Public License for more details.
  27 ;;
  28 ;; You should have received a copy of the GNU General Public License
  29 ;; along with this program; if not, you can either send email to this
  30 ;; program's maintainer or write to: The Free Software Foundation,
  31 ;; Inc.; 59 Temple Place, Suite 330; Boston, MA 02111-1307, USA.
  32
  33 ;;; Commentary:
  34
  35 ;; This program was inspired by the behavior of the Lisp Machine "mouse
  36 ;; documentation window"; as you type a function's symbol name as part of a
  37 ;; sexp, it will print the argument list for that function.  However, this
  38 ;; program's behavior is different in a couple of significant ways.  For
  39 ;; one, you need not actually type the function name; you need only move
  40 ;; point around in a sexp that calls it.  However, if point is over a
  41 ;; documented variable, it will print the one-line documentation for that
  42 ;; variable instead, to remind you of that variable's purpose.
  43
  44 ;; One useful way to enable this minor mode is to put the following in your
  45 ;; .emacs:
  46 ;;
  47 ;;      (autoload 'turn-on-eldoc-mode "eldoc" nil t)
  48 ;;      (add-hook 'emacs-lisp-mode-hook 'turn-on-eldoc-mode)
  49 ;;      (add-hook 'lisp-interaction-mode-hook 'turn-on-eldoc-mode)
  50
  51 ;;; Code:
  52
  53 ;;;###autoload
  54 (defvar eldoc-mode nil
  55   "*If non-nil, show the defined parameters for the elisp function near point.
  56
  57 For the emacs lisp function at the beginning of the sexp which point is
  58 within, show the defined parameters for the function in the echo area.
  59 This information is extracted directly from the function or macro if it is
  60 in pure lisp.
  61
  62 If the emacs function is a subr, the parameters are obtained from the
  63 documentation string if possible.
  64
  65 If point is over a documented variable, print that variable's docstring
  66 instead; see function `eldoc-print-var-docstring'.
  67
  68 This variable is buffer-local.")
  69 (make-variable-buffer-local 'eldoc-mode)
  70
  71 (defvar eldoc-idle-delay 0.50
  72   "*Number of seconds of idle time to wait before printing.
  73 If user input arrives before this interval of time has elapsed after the
  74 last input, no documentation will be printed.
  75
  76 If this variable is set to 0, no idle time is required.")
  77
  78 (defvar eldoc-argument-case 'upcase
  79   "Case to display argument names of functions, as a symbol.
  80 This has two preferred values: `upcase' or `downcase'.
  81 Actually, any name of a function which takes a string as an argument and
  82 returns another string is acceptable.")
  83
  84 (defvar eldoc-mode-message-commands nil
  85   "*Obarray of command names where it is appropriate to print in the echo area.
  86
  87 This is not done for all commands since some print their own
  88 messages in the echo area, and these functions would instantly overwrite
  89 them.  But self-insert-command as well as most motion commands are good
  90 candidates.
  91
  92 It is probably best to manipulate this data structure with the commands
  93 `eldoc-add-command' and `eldoc-remove-command'.")
  94
  95 (cond ((null eldoc-mode-message-commands)
  96        ;; If you increase the number of buckets, keep it a prime number.
  97        (setq eldoc-mode-message-commands (make-vector 31 0))
  98        (let ((list '("self-insert-command"
  99                      "next-"         "previous-"
 100                      "forward-"      "backward-"
 101                      "beginning-of-" "end-of-"
 102                      "goto-"
 103                      "recenter"
 104                      "scroll-"))
 105              (syms nil))
 106          (while list
 107            (setq syms (all-completions (car list) obarray 'fboundp))
 108            (setq list (cdr list))
 109            (while syms
 110              (set (intern (car syms) eldoc-mode-message-commands) t)
 111              (setq syms (cdr syms)))))))
 112
 113 ;; Bookkeeping; the car contains the last symbol read from the buffer.
 114 ;; The cdr contains the string last displayed in the echo area, so it can
 115 ;; be printed again if necessary without reconsing.
 116 (defvar eldoc-last-data '(nil . nil))
 117
 118 (defvar eldoc-minor-mode-string " ElDoc"
 119   "*String to display in mode line when Eldoc Mode is enabled.")
 120
 121 ;; Put this minor mode on the global minor-mode-alist.
 122 (or (assq 'eldoc-mode (default-value 'minor-mode-alist))
 123     (setq-default minor-mode-alist
 124                   (append (default-value 'minor-mode-alist)
 125                           '((eldoc-mode eldoc-minor-mode-string)))))
 126
 127 ;; In emacs 19.29 and later, and XEmacs 19.13 and later, all messages are
 128 ;; recorded in a log.  Do not put eldoc messages in that log since
 129 ;; they are Legion.
 130 (defmacro eldoc-message (&rest args)
 131   (if (fboundp 'display-message)
 132       ;; XEmacs 19.13 way of preventing log messages.
 133       (list 'display-message '(quote no-log) (apply 'list 'format args))
 134     (list 'let (list (list 'message-log-max 'nil))
 135           (apply 'list 'message args))))
 136
 137 \f
 138 ;;;###autoload
 139 (defun eldoc-mode (&optional prefix)
 140   "*If non-nil, then enable eldoc-mode (see variable docstring)."
 141   (interactive "P")
 142
 143   ;; Make sure it's on the post-command-idle-hook if defined, otherwise put
 144   ;; it on post-command-hook.  The former first appeared in Emacs 19.30.
 145   (add-hook (if (boundp 'post-command-idle-hook)
 146                 'post-command-idle-hook
 147               'post-command-hook)
 148             'eldoc-mode-print-current-symbol-info)
 149
 150   (setq eldoc-mode
 151         (>= (prefix-numeric-value prefix) 0))
 152   (and (interactive-p)
 153        (if eldoc-mode
 154            (message "eldoc-mode is enabled")
 155          (message "eldoc-mode is disabled")))
 156   eldoc-mode)
 157
 158 ;;;###autoload
 159 (defun turn-on-eldoc-mode ()
 160   "Unequivocally turn on eldoc-mode (see variable documentation)."
 161   (interactive)
 162   (eldoc-mode 1))
 163
 164 (defun eldoc-add-command (cmd)
 165   "Add COMMAND to the list of commands which causes function arg display.
 166 If called interactively, completion matches any bound function.
 167
 168 When point is in a sexp, the function args are not reprinted in the echo
 169 area after every possible interactive command because some of them print
 170 their own messages in the echo area; the eldoc functions would instantly
 171 overwrite them unless it is more restrained."
 172   (interactive "aAdd function to eldoc message commands list: ")
 173   (and (fboundp cmd)
 174        (set (intern (symbol-name cmd) eldoc-mode-message-commands) t)))
 175
 176 (defun eldoc-remove-command (cmd)
 177   "Remove COMMAND from the list of commands which causes function arg display.
 178 If called interactively, completion matches only those functions currently
 179 in the list.
 180
 181 When point is in a sexp, the function args are not reprinted in the echo
 182 area after every possible interactive command because some of them print
 183 their own messages in the echo area; the eldoc functions would instantly
 184 overwrite them unless it is more restrained."
 185   (interactive (list (completing-read
 186                       "Remove function from eldoc message commands list: "
 187                       eldoc-mode-message-commands 'boundp t)))
 188   (and (symbolp cmd)
 189        (setq cmd (symbol-name cmd)))
 190   (if (fboundp 'unintern)
 191       (unintern cmd eldoc-mode-message-commands)
 192     (let ((s (intern-soft cmd eldoc-mode-message-commands)))
 193       (and s
 194            (makunbound s)))))
 195
 196 (defun eldoc-mode-print-current-symbol-info ()
 197   (and eldoc-mode
 198        (not executing-macro)
 199        ;; Having this mode operate in the minibuffer makes it impossible to
 200        ;; see what you're doing.
 201        (not (eq (selected-window) (minibuffer-window)))
 202        (sit-for eldoc-idle-delay)
 203        (symbolp this-command)
 204        (intern-soft (symbol-name this-command) eldoc-mode-message-commands)
 205        (let ((current-symbol (eldoc-current-symbol))
 206              (current-fnsym  (eldoc-fnsym-in-current-sexp)))
 207          (cond ((eq current-symbol current-fnsym)
 208                 (eldoc-print-fnsym-args current-fnsym))
 209                (t
 210                 (or (eldoc-print-var-docstring current-symbol)
 211                     (eldoc-print-fnsym-args current-fnsym)))))))
 212
 213 \f
 214 (defun eldoc-print-var-docstring (&optional sym)
 215   "Print the brief (one-line) documentation string for the variable at point.
 216 If called with no argument, print the first line of the variable
 217 documentation string for the symbol at point in the echo area.
 218 If called with a symbol, print the line for that symbol.
 219
 220 If the entire line cannot fit in the echo area, the variable name may be
 221 truncated or eliminated entirely from the output to make room.
 222 Any leading `*' in the docstring (which indicates the variable is a user
 223 option) is not printed."
 224   (interactive)
 225   (let* ((s (or sym (eldoc-current-symbol)))
 226          (name (symbol-name s))
 227          (doc (and s (documentation-property s 'variable-documentation t))))
 228     (and doc
 229          (save-match-data
 230            (and (string-match "\n" doc)
 231                 (setq doc (substring doc 0 (match-beginning 0))))
 232            (and (string-match "^\\*" doc)
 233                 (setq doc (substring doc 1)))
 234            (let* ((doclen (+ (length name) (length ": ") (length doc)))
 235                   ;; Subtract 1 from window width since emacs seems not to
 236                   ;; write any chars to the last column, at least for some
 237                   ;; terminal types.
 238                   (strip (- doclen (1- (window-width (minibuffer-window))))))
 239              (cond ((> strip 0)
 240                     (let* ((len (length name)))
 241                       (cond ((>= strip len)
 242                              (eldoc-message "%s" doc))
 243                             (t
 244                              (setq name (substring name 0 (- len strip)))
 245                              (eldoc-message "%s: %s" name doc)))))
 246                    (t
 247                     (eldoc-message "%s: %s" s doc))))
 248            t))))
 249
 250 \f
 251 ;;;###autoload
 252 (defun eldoc-print-fnsym-args (&optional symbol)
 253   "*Show the defined parameters for the function near point.
 254 For the function at the beginning of the sexp which point is within, show
 255 the defined parameters for the function in the echo area.
 256 This information is extracted directly from the function or macro if it is
 257 in pure lisp.
 258 If the emacs function is a subr, the parameters are obtained from the
 259 documentation string if possible."
 260   (interactive)
 261   (let ((sym (or symbol (eldoc-fnsym-in-current-sexp)))
 262         (printit t)
 263         (args nil))
 264     (cond ((not (and (symbolp sym)
 265                      (fboundp sym))))
 266           ((eq sym (car eldoc-last-data))
 267            (setq printit nil)
 268            (setq args (cdr eldoc-last-data)))
 269           ((subrp (eldoc-symbol-function sym))
 270            (setq args (eldoc-function-argstring-from-docstring sym))
 271            (setcdr eldoc-last-data args))
 272           (t
 273            (setq args (eldoc-function-argstring sym))
 274            (setcdr eldoc-last-data args)))
 275     (and args
 276          printit
 277          (eldoc-message "%s: %s" sym args))))
 278
 279 (defun eldoc-fnsym-in-current-sexp ()
 280   (let* ((p (point))
 281          (sym (progn
 282                 (while (and (eldoc-forward-sexp-safe -1)
 283                             (> (point) (point-min))))
 284                 (cond ((or (= (point) (point-min))
 285                            (memq (or (char-after (point)) 0)
 286                                  '(?\( ?\"))
 287                            ;; If we hit a quotation mark before a paren, we
 288                            ;; are inside a specific string, not a list of
 289                            ;; symbols.
 290                            (eq (or (char-after (1- (point))) 0) ?\"))
 291                        nil)
 292                       (t (condition-case nil
 293                              (read (current-buffer))
 294                            (error nil)))))))
 295     (goto-char p)
 296     (and (symbolp sym)
 297          sym)))
 298
 299 (defun eldoc-function-argstring (fn)
 300   (let* ((prelim-def (eldoc-symbol-function fn))
 301          (def (if (eq (car-safe prelim-def) 'macro)
 302                   (cdr prelim-def)
 303                 prelim-def))
 304          (arglist (cond ((null def) nil)
 305                         ((byte-code-function-p def)
 306                          (if (fboundp 'compiled-function-arglist)
 307                              (funcall 'compiled-function-arglist def)
 308                            (aref def 0)))
 309                         ((eq (car-safe def) 'lambda)
 310                          (nth 1 def))
 311                         (t t))))
 312     (eldoc-function-argstring-format arglist)))
 313
 314 (defun eldoc-function-argstring-from-docstring (fn)
 315   (let ((docstring (documentation fn 'raw))
 316         (doc nil)
 317         (doclist nil)
 318         (end nil))
 319     (save-match-data
 320       (cond
 321        ;; Try first searching for args starting with symbol name.
 322        ;; This is to avoid matching parenthetical remarks in e.g. sit-for.
 323        ((string-match (format "^(%s[^\n)]*)$" fn) docstring)
 324         ;; end does not include trailing ")" sequence.
 325         (setq end (- (match-end 0) 1))
 326         (if (string-match " +" docstring (match-beginning 0))
 327             (setq doc (substring docstring (match-end 0) end))
 328           (setq doc "")))
 329
 330        ;; Try again not requiring this symbol name in the docstring.
 331        ;; This will be the case when looking up aliases.
 332        ((string-match (format "^([^\n)]+)$" fn) docstring)
 333         ;; end does not include trailing ")" sequence.
 334         (setq end (- (match-end 0) 1))
 335         (if (string-match " +" docstring (match-beginning 0))
 336             (setq doc (substring docstring (match-end 0) end))
 337           (setq doc "")))
 338
 339        ;; Emacs subr docstring style:
 340        ;;   (fn arg1 arg2 ...): description...
 341        ((string-match "^([^\n)]+):" docstring)
 342         ;; end does not include trailing "):" sequence.
 343         (setq end (- (match-end 0) 2))
 344         (if (string-match " +" docstring (match-beginning 0))
 345             (setq doc (substring docstring (match-end 0) end))
 346           (setq doc "")))
 347
 348        ;; XEmacs subr docstring style:
 349        ;;   "arguments: (arg1 arg2 ...)
 350        ((string-match "^arguments: (\\([^\n)]+\\))" docstring)
 351         ;; Also, skip leading paren, but the first word is actually an
 352         ;; argument, not the function name.
 353         (setq doc (substring docstring
 354                              (match-beginning 1)
 355                              (match-end 1))))
 356
 357        ;; This finds the argstring for `condition-case'.
 358        ;; I don't know if there are any others with the same pattern.
 359        ((string-match (format "^Usage looks like \\((%s[^\n)]*)\\)\\.$" fn)
 360                       docstring)
 361         ;; end does not include trailing ")" sequence.
 362         (setq end (- (match-end 1) 1))
 363         (if (string-match " +" docstring (match-beginning 1))
 364             (setq doc (substring docstring (match-end 0) end))
 365           (setq doc "")))
 366
 367        ;; This finds the argstring for `setq-default'.
 368        ;; I don't know if there are any others with the same pattern.
 369        ((string-match (format "^[ \t]+\\((%s[^\n)]*)\\)$" fn) docstring)
 370         ;; end does not include trailing ")" sequence.
 371         (setq end (- (match-end 1) 1))
 372         (if (string-match " +" docstring (match-beginning 1))
 373             (setq doc (substring docstring (match-end 0) end))
 374           (setq doc ""))))
 375
 376       (cond ((not (stringp doc))
 377              nil)
 378             ((string-match "&" doc)
 379              (let ((p 0)
 380                    (l (length doc)))
 381                (while (< p l)
 382                  (cond ((string-match "[ \t\n]+" doc p)
 383                         (setq doclist
 384                               (cons (substring doc p (match-beginning 0))
 385                                     doclist))
 386                         (setq p (match-end 0)))
 387                        (t
 388                         (setq doclist (cons (substring doc p) doclist))
 389                         (setq p l))))
 390                (eldoc-function-argstring-format (nreverse doclist))))
 391             (t
 392              (concat "(" (funcall eldoc-argument-case doc) ")"))))))
 393
 394 (defun eldoc-function-argstring-format (arglist)
 395   (cond ((not (listp arglist))
 396          (setq arglist nil))
 397         ((symbolp (car arglist))
 398          (setq arglist
 399                (mapcar (function (lambda (s)
 400                                    (if (memq s '(&optional &rest))
 401                                        (symbol-name s)
 402                                      (funcall eldoc-argument-case
 403                                               (symbol-name s)))))
 404                        arglist)))
 405         ((stringp (car arglist))
 406          (setq arglist
 407                (mapcar (function (lambda (s)
 408                                    (if (member s '("&optional" "&rest"))
 409                                        s
 410                                      (funcall eldoc-argument-case s))))
 411                        arglist))))
 412   (concat "(" (mapconcat 'identity arglist " ") ")"))
 413
 414 \f
 415 ;; forward-sexp calls scan-sexps, which returns an error if it hits the
 416 ;; beginning or end of the sexp.  This returns nil instead.
 417 (defun eldoc-forward-sexp-safe (&optional count)
 418   "Move forward across one balanced expression (sexp).
 419 With argument, do it that many times.  Negative arg -COUNT means
 420 move backward across COUNT balanced expressions.
 421 Return distance in buffer moved, or nil."
 422   (or count (setq count 1))
 423   (condition-case err
 424       (- (- (point) (progn
 425                       (let ((parse-sexp-ignore-comments t))
 426                         (forward-sexp count))
 427                       (point))))
 428     (error nil)))
 429
 430 ;; Do indirect function resolution if possible.
 431 (defun eldoc-symbol-function (fsym)
 432   (let ((defn (and (fboundp fsym)
 433                    (symbol-function fsym))))
 434     (and (symbolp defn)
 435          (condition-case err
 436              (setq defn (indirect-function fsym))
 437            (error (setq defn nil))))
 438     defn))
 439
 440 (defun eldoc-current-symbol ()
 441   (let ((c (char-after (point))))
 442     (and c
 443          (memq (char-syntax c) '(?w ?_))
 444          (intern-soft (current-word)))))
 445
 446 (provide 'eldoc)
 447
 448 ;;; eldoc.el ends here