lisp/url/url-util.el

   1 ;;; url-util.el --- Miscellaneous helper routines for URL library
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2001, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Bill Perry <wmperry@gnu.org>
   7 ;; Keywords: comm, data, processes
   8
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'url-parse)
  31 (autoload 'timezone-parse-date "timezone")
  32 (autoload 'timezone-make-date-arpa-standard "timezone")
  33 (autoload 'mail-header-extract "mailheader")
  34
  35 (defvar url-parse-args-syntax-table
  36   (copy-syntax-table emacs-lisp-mode-syntax-table)
  37   "A syntax table for parsing sgml attributes.")
  38
  39 (modify-syntax-entry ?' "\"" url-parse-args-syntax-table)
  40 (modify-syntax-entry ?` "\"" url-parse-args-syntax-table)
  41 (modify-syntax-entry ?{ "(" url-parse-args-syntax-table)
  42 (modify-syntax-entry ?} ")" url-parse-args-syntax-table)
  43
  44 ;;;###autoload
  45 (defcustom url-debug nil
  46   "*What types of debug messages from the URL library to show.
  47 Debug messages are logged to the *URL-DEBUG* buffer.
  48
  49 If t, all messages will be logged.
  50 If a number, all messages will be logged, as well shown via `message'.
  51 If a list, it is a list of the types of messages to be logged."
  52   :type '(choice (const :tag "none" nil)
  53                  (const :tag "all" t)
  54                  (checklist :tag "custom"
  55                             (const :tag "HTTP" :value http)
  56                             (const :tag "DAV" :value dav)
  57                             (const :tag "General" :value retrieval)
  58                             (const :tag "Filename handlers" :value handlers)
  59                             (symbol :tag "Other")))
  60   :group 'url-hairy)
  61
  62 ;;;###autoload
  63 (defun url-debug (tag &rest args)
  64   (if quit-flag
  65       (error "Interrupted!"))
  66   (if (or (eq url-debug t)
  67           (numberp url-debug)
  68           (and (listp url-debug) (memq tag url-debug)))
  69       (with-current-buffer (get-buffer-create "*URL-DEBUG*")
  70         (goto-char (point-max))
  71         (insert (symbol-name tag) " -> " (apply 'format args) "\n")
  72         (if (numberp url-debug)
  73             (apply 'message args)))))
  74
  75 ;;;###autoload
  76 (defun url-parse-args (str &optional nodowncase)
  77   ;; Return an assoc list of attribute/value pairs from an RFC822-type string
  78   (let (
  79         name                            ; From name=
  80         value                           ; its value
  81         results                         ; Assoc list of results
  82         name-pos                        ; Start of XXXX= position
  83         val-pos                         ; Start of value position
  84         st
  85         nd
  86         )
  87     (save-excursion
  88       (save-restriction
  89         (set-buffer (get-buffer-create " *urlparse-temp*"))
  90         (set-syntax-table url-parse-args-syntax-table)
  91         (erase-buffer)
  92         (insert str)
  93         (setq st (point-min)
  94               nd (point-max))
  95         (set-syntax-table url-parse-args-syntax-table)
  96         (narrow-to-region st nd)
  97         (goto-char (point-min))
  98         (while (not (eobp))
  99           (skip-chars-forward "; \n\t")
 100           (setq name-pos (point))
 101           (skip-chars-forward "^ \n\t=;")
 102           (if (not nodowncase)
 103               (downcase-region name-pos (point)))
 104           (setq name (buffer-substring name-pos (point)))
 105           (skip-chars-forward " \t\n")
 106           (if (/= (or (char-after (point)) 0)  ?=) ; There is no value
 107               (setq value nil)
 108             (skip-chars-forward " \t\n=")
 109             (setq val-pos (point)
 110                   value
 111                   (cond
 112                    ((or (= (or (char-after val-pos) 0) ?\")
 113                         (= (or (char-after val-pos) 0) ?'))
 114                     (buffer-substring (1+ val-pos)
 115                                       (condition-case ()
 116                                           (prog2
 117                                               (forward-sexp 1)
 118                                               (1- (point))
 119                                             (skip-chars-forward "\""))
 120                                         (error
 121                                          (skip-chars-forward "^ \t\n")
 122                                          (point)))))
 123                    (t
 124                     (buffer-substring val-pos
 125                                       (progn
 126                                         (skip-chars-forward "^;")
 127                                         (skip-chars-backward " \t")
 128                                         (point)))))))
 129           (setq results (cons (cons name value) results))
 130           (skip-chars-forward "; \n\t"))
 131         results))))
 132
 133 ;;;###autoload
 134 (defun url-insert-entities-in-string (string)
 135   "Convert HTML markup-start characters to entity references in STRING.
 136 Also replaces the \" character, so that the result may be safely used as
 137   an attribute value in a tag.  Returns a new string with the result of the
 138   conversion.  Replaces these characters as follows:
 139     &  ==>  &amp;
 140     <  ==>  &lt;
 141     >  ==>  &gt;
 142     \"  ==>  &quot;"
 143   (if (string-match "[&<>\"]" string)
 144       (save-excursion
 145         (set-buffer (get-buffer-create " *entity*"))
 146         (erase-buffer)
 147         (buffer-disable-undo (current-buffer))
 148         (insert string)
 149         (goto-char (point-min))
 150         (while (progn
 151                  (skip-chars-forward "^&<>\"")
 152                  (not (eobp)))
 153           (insert (cdr (assq (char-after (point))
 154                              '((?\" . "&quot;")
 155                                (?& . "&amp;")
 156                                (?< . "&lt;")
 157                                (?> . "&gt;")))))
 158           (delete-char 1))
 159         (buffer-string))
 160     string))
 161
 162 ;;;###autoload
 163 (defun url-normalize-url (url)
 164   "Return a 'normalized' version of URL.
 165 Strips out default port numbers, etc."
 166   (let (type data retval)
 167     (setq data (url-generic-parse-url url)
 168           type (url-type data))
 169     (if (member type '("www" "about" "mailto" "info"))
 170         (setq retval url)
 171       (setf (url-target data) nil)
 172       (setq retval (url-recreate-url data)))
 173     retval))
 174
 175 ;;;###autoload
 176 (defun url-lazy-message (&rest args)
 177   "Just like `message', but is a no-op if called more than once a second.
 178 Will not do anything if `url-show-status' is nil."
 179   (if (or (null url-show-status)
 180           (active-minibuffer-window)
 181           (= url-lazy-message-time
 182              (setq url-lazy-message-time (nth 1 (current-time)))))
 183       nil
 184     (apply 'message args)))
 185
 186 ;;;###autoload
 187 (defun url-get-normalized-date (&optional specified-time)
 188   "Return a 'real' date string that most HTTP servers can understand."
 189   (require 'timezone)
 190   (let* ((raw (if specified-time (current-time-string specified-time)
 191                 (current-time-string)))
 192          (gmt (timezone-make-date-arpa-standard raw
 193                                                 (current-time-zone)
 194                                                 "GMT"))
 195          (parsed (timezone-parse-date gmt))
 196          (day (cdr-safe (assoc (substring raw 0 3) url-weekday-alist)))
 197          (year nil)
 198          (month (car
 199                  (rassoc
 200                   (string-to-number (aref parsed 1)) url-monthabbrev-alist)))
 201          )
 202     (setq day (or (car-safe (rassoc day url-weekday-alist))
 203                   (substring raw 0 3))
 204           year (aref parsed 0))
 205     ;; This is needed for plexus servers, or the server will hang trying to
 206     ;; parse the if-modified-since header.  Hopefully, I can take this out
 207     ;; soon.
 208     (if (and year (> (length year) 2))
 209         (setq year (substring year -2 nil)))
 210
 211     (concat day ", " (aref parsed 2) "-" month "-" year " "
 212             (aref parsed 3) " " (or (aref parsed 4)
 213                                     (concat "[" (nth 1 (current-time-zone))
 214                                             "]")))))
 215
 216 ;;;###autoload
 217 (defun url-eat-trailing-space (x)
 218   "Remove spaces/tabs at the end of a string."
 219   (let ((y (1- (length x)))
 220         (skip-chars (list ?  ?\t ?\n)))
 221     (while (and (>= y 0) (memq (aref x y) skip-chars))
 222       (setq y (1- y)))
 223     (substring x 0 (1+ y))))
 224
 225 ;;;###autoload
 226 (defun url-strip-leading-spaces (x)
 227   "Remove spaces at the front of a string."
 228   (let ((y (1- (length x)))
 229         (z 0)
 230         (skip-chars (list ?  ?\t ?\n)))
 231     (while (and (<= z y) (memq (aref x z) skip-chars))
 232       (setq z (1+ z)))
 233     (substring x z nil)))
 234
 235 ;;;###autoload
 236 (defun url-pretty-length (n)
 237   (cond
 238    ((< n 1024)
 239     (format "%d bytes" n))
 240    ((< n (* 1024 1024))
 241     (format "%dk" (/ n 1024.0)))
 242    (t
 243     (format "%2.2fM" (/ n (* 1024 1024.0))))))
 244
 245 ;;;###autoload
 246 (defun url-display-percentage (fmt perc &rest args)
 247   (when url-show-status
 248     (if (null fmt)
 249         (if (fboundp 'clear-progress-display)
 250             (clear-progress-display))
 251       (if (and (fboundp 'progress-display) perc)
 252           (apply 'progress-display fmt perc args)
 253         (apply 'message fmt args)))))
 254
 255 ;;;###autoload
 256 (defun url-percentage (x y)
 257   (if (fboundp 'float)
 258       (round (* 100 (/ x (float y))))
 259     (/ (* x 100) y)))
 260
 261 ;;;###autoload
 262 (defun url-file-directory (file)
 263   "Return the directory part of FILE, for a URL."
 264   (cond
 265    ((null file) "")
 266    ((string-match (eval-when-compile (regexp-quote "?")) file)
 267     (file-name-directory (substring file 0 (match-beginning 0))))
 268    (t (file-name-directory file))))
 269
 270 ;;;###autoload
 271 (defun url-file-nondirectory (file)
 272   "Return the nondirectory part of FILE, for a URL."
 273   (cond
 274    ((null file) "")
 275    ((string-match (eval-when-compile (regexp-quote "?")) file)
 276     (file-name-nondirectory (substring file 0 (match-beginning 0))))
 277    (t (file-name-nondirectory file))))
 278
 279 ;;;###autoload
 280 (defun url-parse-query-string (query &optional downcase allow-newlines)
 281   (let (retval pairs cur key val)
 282     (setq pairs (split-string query "&"))
 283     (while pairs
 284       (setq cur (car pairs)
 285             pairs (cdr pairs))
 286       (if (not (string-match "=" cur))
 287           nil                           ; Grace
 288         (setq key (url-unhex-string (substring cur 0 (match-beginning 0))
 289                                     allow-newlines))
 290         (setq val (url-unhex-string (substring cur (match-end 0) nil)
 291                                     allow-newlines))
 292         (if downcase
 293             (setq key (downcase key)))
 294         (setq cur (assoc key retval))
 295         (if cur
 296             (setcdr cur (cons val (cdr cur)))
 297           (setq retval (cons (list key val) retval)))))
 298     retval))
 299
 300 (defun url-unhex (x)
 301   (if (> x ?9)
 302       (if (>= x ?a)
 303           (+ 10 (- x ?a))
 304         (+ 10 (- x ?A)))
 305     (- x ?0)))
 306
 307 ;; Fixme: Is this definition better, and does it ever matter?
 308
 309 ;; (defun url-unhex-string (str &optional allow-newlines)
 310 ;;   "Remove %XX, embedded spaces, etc in a url.
 311 ;; If optional second argument ALLOW-NEWLINES is non-nil, then allow the
 312 ;; decoding of carriage returns and line feeds in the string, which is normally
 313 ;; forbidden in URL encoding."
 314 ;;   (setq str (or str ""))
 315 ;;   (setq str (replace-regexp-in-string "%[[:xdigit:]]\\{2\\}"
 316 ;;                                    (lambda (match)
 317 ;;                                      (string (string-to-number
 318 ;;                                               (substring match 1) 16)))
 319 ;;                                    str t t))
 320 ;;   (if allow-newlines
 321 ;;       (replace-regexp-in-string "[\n\r]" (lambda (match)
 322 ;;                                         (format "%%%.2X" (aref match 0)))
 323 ;;                              str t t)
 324 ;;     str))
 325
 326 ;;;###autoload
 327 (defun url-unhex-string (str &optional allow-newlines)
 328   "Remove %XX embedded spaces, etc in a url.
 329 If optional second argument ALLOW-NEWLINES is non-nil, then allow the
 330 decoding of carriage returns and line feeds in the string, which is normally
 331 forbidden in URL encoding."
 332   (setq str (or str ""))
 333   (let ((tmp "")
 334         (case-fold-search t))
 335     (while (string-match "%[0-9a-f][0-9a-f]" str)
 336       (let* ((start (match-beginning 0))
 337              (ch1 (url-unhex (elt str (+ start 1))))
 338              (code (+ (* 16 ch1)
 339                       (url-unhex (elt str (+ start 2))))))
 340         (setq tmp (concat
 341                    tmp (substring str 0 start)
 342                    (cond
 343                     (allow-newlines
 344                      (char-to-string code))
 345                     ((or (= code ?\n) (= code ?\r))
 346                      " ")
 347                     (t (char-to-string code))))
 348               str (substring str (match-end 0)))))
 349     (setq tmp (concat tmp str))
 350     tmp))
 351
 352 (defconst url-unreserved-chars
 353   '(
 354     ?a ?b ?c ?d ?e ?f ?g ?h ?i ?j ?k ?l ?m ?n ?o ?p ?q ?r ?s ?t ?u ?v ?w ?x ?y ?z
 355     ?A ?B ?C ?D ?E ?F ?G ?H ?I ?J ?K ?L ?M ?N ?O ?P ?Q ?R ?S ?T ?U ?V ?W ?X ?Y ?Z
 356     ?0 ?1 ?2 ?3 ?4 ?5 ?6 ?7 ?8 ?9
 357     ?- ?_ ?. ?! ?~ ?* ?' ?\( ?\))
 358   "A list of characters that are _NOT_ reserved in the URL spec.
 359 This is taken from RFC 2396.")
 360
 361 ;;;###autoload
 362 (defun url-hexify-string (string)
 363   "Return a new string that is STRING URI-encoded.
 364 First, STRING is converted to utf-8, if necessary.  Then, for each
 365 character in the utf-8 string, those found in `url-unreserved-chars'
 366 are left as-is, all others are represented as a three-character
 367 string: \"%\" followed by two lowercase hex digits."
 368   ;; To go faster and avoid a lot of consing, we could do:
 369   ;;
 370   ;; (defconst url-hexify-table
 371   ;;   (let ((map (make-vector 256 nil)))
 372   ;;     (dotimes (byte 256) (aset map byte
 373   ;;                               (if (memq byte url-unreserved-chars)
 374   ;;                                   (char-to-string byte)
 375   ;;                                 (format "%%%02x" byte))))
 376   ;;     map))
 377   ;;
 378   ;; (mapconcat (curry 'aref url-hexify-table) ...)
 379   (mapconcat (lambda (byte)
 380                (if (memq byte url-unreserved-chars)
 381                    (char-to-string byte)
 382                  (format "%%%02x" byte)))
 383              (if (multibyte-string-p string)
 384                  (encode-coding-string string 'utf-8)
 385                string)
 386              ""))
 387
 388 ;;;###autoload
 389 (defun url-file-extension (fname &optional x)
 390   "Return the filename extension of FNAME.
 391 If optional variable X is t,
 392 then return the basename of the file with the extension stripped off."
 393   (if (and fname
 394            (setq fname (url-file-nondirectory fname))
 395            (string-match "\\.[^./]+$" fname))
 396       (if x (substring fname 0 (match-beginning 0))
 397         (substring fname (match-beginning 0) nil))
 398     ;;
 399     ;; If fname has no extension, and x then return fname itself instead of
 400     ;; nothing. When caching it allows the correct .hdr file to be produced
 401     ;; for filenames without extension.
 402     ;;
 403     (if x
 404         fname
 405       "")))
 406
 407 ;;;###autoload
 408 (defun url-truncate-url-for-viewing (url &optional width)
 409   "Return a shortened version of URL that is WIDTH characters or less wide.
 410 WIDTH defaults to the current frame width."
 411   (let* ((fr-width (or width (frame-width)))
 412          (str-width (length url))
 413          (fname nil)
 414          (modified 0)
 415          (urlobj nil))
 416     ;; The first thing that can go are the search strings
 417     (if (and (>= str-width fr-width)
 418              (string-match "?" url))
 419         (setq url (concat (substring url 0 (match-beginning 0)) "?...")
 420               str-width (length url)))
 421     (if (< str-width fr-width)
 422         nil                             ; Hey, we are done!
 423       (setq urlobj (url-generic-parse-url url)
 424             fname (url-filename urlobj)
 425             fr-width (- fr-width 4))
 426       (while (and (>= str-width fr-width)
 427                   (string-match "/" fname))
 428         (setq fname (substring fname (match-end 0) nil)
 429               modified (1+ modified))
 430         (setf (url-filename urlobj) fname)
 431         (setq url (url-recreate-url urlobj)
 432               str-width (length url)))
 433       (if (> modified 1)
 434           (setq fname (concat "/.../" fname))
 435         (setq fname (concat "/" fname)))
 436       (setf (url-filename urlobj) fname)
 437       (setq url (url-recreate-url urlobj)))
 438     url))
 439
 440 ;;;###autoload
 441 (defun url-view-url (&optional no-show)
 442   "View the current document's URL.
 443 Optional argument NO-SHOW means just return the URL, don't show it in
 444 the minibuffer.
 445
 446 This uses `url-current-object', set locally to the buffer."
 447   (interactive)
 448   (if (not url-current-object)
 449       nil
 450     (if no-show
 451         (url-recreate-url url-current-object)
 452       (message "%s" (url-recreate-url url-current-object)))))
 453
 454 (eval-and-compile
 455   (defvar url-get-url-filename-chars "-%.?@a-zA-Z0-9()_/:~=&"
 456     "Valid characters in a URL")
 457   )
 458
 459 (defun url-get-url-at-point (&optional pt)
 460   "Get the URL closest to point, but don't change position.
 461 Has a preference for looking backward when not directly on a symbol."
 462   ;; Not at all perfect - point must be right in the name.
 463   (save-excursion
 464     (if pt (goto-char pt))
 465     (let (start url)
 466       (save-excursion
 467         ;; first see if you're just past a filename
 468         (if (not (eobp))
 469             (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
 470                 (progn
 471                   (skip-chars-backward " \n\t\r({[]})")
 472                   (if (not (bobp))
 473                       (backward-char 1)))))
 474         (if (and (char-after (point))
 475                  (string-match (eval-when-compile
 476                                  (concat "[" url-get-url-filename-chars "]"))
 477                                (char-to-string (char-after (point)))))
 478             (progn
 479               (skip-chars-backward url-get-url-filename-chars)
 480               (setq start (point))
 481               (skip-chars-forward url-get-url-filename-chars))
 482           (setq start (point)))
 483         (setq url (buffer-substring-no-properties start (point))))
 484       (if (and url (string-match "^(.*)\\.?$" url))
 485           (setq url (match-string 1 url)))
 486       (if (and url (string-match "^URL:" url))
 487           (setq url (substring url 4 nil)))
 488       (if (and url (string-match "\\.$" url))
 489           (setq url (substring url 0 -1)))
 490       (if (and url (string-match "^www\\." url))
 491           (setq url (concat "http://" url)))
 492       (if (and url (not (string-match url-nonrelative-link url)))
 493           (setq url nil))
 494       url)))
 495
 496 (defun url-generate-unique-filename (&optional fmt)
 497   "Generate a unique filename in `url-temporary-directory'."
 498   (if (not fmt)
 499       (let ((base (format "url-tmp.%d" (user-real-uid)))
 500             (fname "")
 501             (x 0))
 502         (setq fname (format "%s%d" base x))
 503         (while (file-exists-p
 504                 (expand-file-name fname url-temporary-directory))
 505           (setq x (1+ x)
 506                 fname (concat base (int-to-string x))))
 507         (expand-file-name fname url-temporary-directory))
 508     (let ((base (concat "url" (int-to-string (user-real-uid))))
 509           (fname "")
 510           (x 0))
 511       (setq fname (format fmt (concat base (int-to-string x))))
 512       (while (file-exists-p
 513               (expand-file-name fname url-temporary-directory))
 514         (setq x (1+ x)
 515               fname (format fmt (concat base (int-to-string x)))))
 516       (expand-file-name fname url-temporary-directory))))
 517
 518 (defun url-extract-mime-headers ()
 519   "Set `url-current-mime-headers' in current buffer."
 520   (save-excursion
 521     (goto-char (point-min))
 522     (unless url-current-mime-headers
 523       (set (make-local-variable 'url-current-mime-headers)
 524            (mail-header-extract)))))
 525
 526 (provide 'url-util)
 527
 528 ;; arch-tag: 24352abc-5a5a-412e-90cd-313b26bed5c9
 529 ;;; url-util.el ends here