configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  49 dnl Create a new --with option that defaults to being disabled.
  50 dnl NAME is the base name of the option.  The shell variable with_NAME
  51 dnl   will be set to either the user's value (if the option is
  52 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  53 dnl   option is not specified).  Note that the shell variable name is
  54 dnl   constructed as autoconf does, by replacing non-alphanumeric
  55 dnl   characters with "_".
  56 dnl HELP-STRING is the help text for the option.
  57 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  58   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  59     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  60 ])dnl
  61
  62 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  63 dnl Create a new --with option that defaults to being enabled.  NAME
  64 dnl   is the base name of the option.  The shell variable with_NAME
  65 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  66 dnl   'yes' (if the option is not specified).  Note that the shell
  67 dnl   variable name is constructed as autoconf does, by replacing
  68 dnl   non-alphanumeric characters with "_".
  69 dnl HELP-STRING is the help text for the option.
  70 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  71   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  72    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  73 ])dnl
  74
  75 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  76 if test "$with_pop" = yes; then
  77    AC_DEFINE(MAIL_USE_POP)
  78 fi
  79 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  80
  81 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  82 if test "$with_kerberos" != no; then
  83    AC_DEFINE(KERBEROS)
  84 fi
  85 AH_TEMPLATE(KERBEROS,
  86             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  87
  88 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  89 if test "${with_kerberos5}" != no; then
  90   if test "${with_kerberos}" = no; then
  91     with_kerberos=yes
  92     AC_DEFINE(KERBEROS)
  93   fi
  94   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  95 fi
  96
  97 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  98 dnl FIXME hesiod support may not be present, so it seems like an error
  99 dnl to define, or at least use, this unconditionally.
 100 if test "$with_hesiod" != no; then
 101   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 102 fi
 103
 104 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 105 if test "$with_mmdf" != no; then
 106    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 107 fi
 108
 109 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 110 if test "$with_mail_unlink" != no; then
 111    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 112 fi
 113
 114 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 115     [string giving default POP mail host])],
 116     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 117
 118 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 119
 120 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 121 if test "$with_sync_input" = yes; then
 122    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 123 fi
 124
 125 dnl FIXME currently it is not the last.
 126 dnl This should be the last --with option, because --with-x is
 127 dnl added later on when we find the path of X, and it's best to
 128 dnl keep them together visually.
 129 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 130  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 131 [         case "${withval}" in
 132             y | ye | yes )      val=gtk ;;
 133             n | no )            val=no  ;;
 134             l | lu | luc | luci | lucid )       val=lucid ;;
 135             a | at | ath | athe | athen | athena )      val=athena ;;
 136             m | mo | mot | moti | motif )       val=motif ;;
 137             g | gt | gtk  )     val=gtk ;;
 138             gtk3  )     val=gtk3 ;;
 139             * )
 140 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 141 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 142 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 143             ;;
 144           esac
 145           with_x_toolkit=$val
 146 ])
 147
 148 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 149 if test "$with_wide_int" = yes; then
 150   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 151 fi
 152
 153 dnl _ON results in a '--without' option in the --help output, so
 154 dnl the help text should refer to "don't compile", etc.
 155 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 156 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 157 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 158 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 159 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 160 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 161 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 162 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 163
 164 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 165 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 166 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 167
 168 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 169 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 170 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 171 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 172
 173 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 174 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 175 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 176 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 177 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 178 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 179
 180 ## For the times when you want to build Emacs but don't have
 181 ## a suitable makeinfo, and can live without the manuals.
 182 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 183 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 184
 185 ## Makefile.in needs the cache file name.
 186 AC_SUBST(cache_file)
 187
 188 ## This is an option because I do not know if all info/man support
 189 ## compressed files, nor how to test if they do so.
 190 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 191 if test $with_compress_info = yes; then
 192    GZIP_INFO=yes
 193 else
 194    GZIP_INFO=
 195 fi
 196 AC_SUBST(GZIP_INFO)
 197
 198 AC_ARG_WITH([pkg-config-prog],dnl
 199 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 200                   [path to pkg-config for finding GTK and librsvg])])
 201 if test "X${with_pkg_config_prog}" != X; then
 202    if test "${with_pkg_config_prog}" != yes; then
 203       PKG_CONFIG="${with_pkg_config_prog}"
 204    fi
 205 fi
 206
 207 CRT_DIR=
 208 AC_ARG_WITH([crt-dir],dnl
 209 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 210 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 211 CRT_DIR="${with_crt_dir}"
 212
 213 AC_ARG_WITH(gameuser,dnl
 214 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 215 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 216   && gameuser="${with_gameuser}"
 217 test "X$gameuser" = X && gameuser=games
 218
 219 AC_ARG_WITH([gnustep-conf],dnl
 220 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 221 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 222   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 223 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 224      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 225
 226 AC_ARG_ENABLE(ns-self-contained,
 227 [AS_HELP_STRING([--disable-ns-self-contained],
 228                 [disable self contained build under NeXTstep])],
 229    EN_NS_SELF_CONTAINED=$enableval,
 230    EN_NS_SELF_CONTAINED=yes)
 231
 232 AC_ARG_ENABLE(asserts,
 233 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 234       USE_XASSERTS=$enableval,
 235       USE_XASSERTS=no)
 236
 237 AC_ARG_ENABLE(maintainer-mode,
 238 [AS_HELP_STRING([--disable-maintainer-mode],
 239                 [disable make rules and dependencies not useful (and sometimes
 240                  confusing) to the casual installer])],
 241       USE_MAINTAINER_MODE=$enableval,
 242       USE_MAINTAINER_MODE=yes)
 243 if test $USE_MAINTAINER_MODE = yes; then
 244   MAINT=
 245 else
 246   MAINT=#
 247 fi
 248 AC_SUBST(MAINT)
 249
 250 AC_ARG_ENABLE(locallisppath,
 251 [AS_HELP_STRING([--enable-locallisppath=PATH],
 252                 [directories Emacs should search for lisp files specific
 253                  to this site])],
 254 if test "${enableval}" = "no"; then
 255   locallisppath=
 256 elif test "${enableval}" != "yes"; then
 257   locallisppath=${enableval}
 258 fi)
 259
 260 AC_ARG_ENABLE(checking,
 261 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 262                 [enable expensive run-time checks.  With LIST,
 263                  enable only specific categories of checks.
 264                  Categories are: all,yes,no.
 265                  Flags are: stringbytes, stringoverrun, stringfreelist,
 266                  xmallocoverrun, conslist])],
 267 [ac_checking_flags="${enableval}"],[])
 268 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 269 for check in $ac_checking_flags
 270 do
 271         case $check in
 272         # these set all the flags to specific states
 273         yes)            ac_enable_checking=1 ;;
 274         no)             ac_enable_checking= ;
 275                         ac_gc_check_stringbytes= ;
 276                         ac_gc_check_string_overrun= ;
 277                         ac_gc_check_string_free_list= ;
 278                         ac_xmalloc_overrun= ;
 279                         ac_gc_check_cons_list= ;;
 280         all)            ac_enable_checking=1 ;
 281                         ac_gc_check_stringbytes=1 ;
 282                         ac_gc_check_string_overrun=1 ;
 283                         ac_gc_check_string_free_list=1 ;
 284                         ac_xmalloc_overrun=1 ;
 285                         ac_gc_check_cons_list=1 ;;
 286         # these enable particular checks
 287         stringbytes)    ac_gc_check_stringbytes=1 ;;
 288         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 289         stringfreelist) ac_gc_check_string_free_list=1 ;;
 290         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 291         conslist)       ac_gc_check_cons_list=1 ;;
 292         *)      AC_MSG_ERROR(unknown check category $check) ;;
 293         esac
 294 done
 295 IFS="$ac_save_IFS"
 296
 297 if test x$ac_enable_checking != x ; then
 298   AC_DEFINE(ENABLE_CHECKING, 1,
 299 [Enable expensive run-time checking of data types?])
 300 fi
 301 if test x$ac_gc_check_stringbytes != x ; then
 302   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 303 [Define this temporarily to hunt a bug.  If defined, the size of
 304    strings is redundantly recorded in sdata structures so that it can
 305    be compared to the sizes recorded in Lisp strings.])
 306 fi
 307 if test x$ac_gc_check_string_overrun != x ; then
 308   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 309 [Define this to check for short string overrun.])
 310 fi
 311 if test x$ac_gc_check_string_free_list != x ; then
 312   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 313 [Define this to check the string free list.])
 314 fi
 315 if test x$ac_xmalloc_overrun != x ; then
 316   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 317 [Define this to check for malloc buffer overrun.])
 318 fi
 319 if test x$ac_gc_check_cons_list != x ; then
 320   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 321 [Define this to check for errors in cons list.])
 322 fi
 323
 324 AC_ARG_ENABLE(use-lisp-union-type,
 325 [AS_HELP_STRING([--enable-use-lisp-union-type],
 326                 [use a union for the Lisp_Object data type.
 327                 This is only useful for development for catching certain types of bugs.])],
 328 if test "${enableval}" != "no"; then
 329    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 330    [Define this to use a lisp union for the Lisp_Object data type.])
 331 fi)
 332
 333
 334 AC_ARG_ENABLE(profiling,
 335 [AS_HELP_STRING([--enable-profiling],
 336                 [build emacs with profiling support.
 337                  This might not work on all platforms])],
 338 [ac_enable_profiling="${enableval}"],[])
 339 if test x$ac_enable_profiling != x ; then
 340    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 341 else
 342    PROFILING_CFLAGS=
 343 fi
 344 AC_SUBST(PROFILING_CFLAGS)
 345
 346 AC_ARG_ENABLE(autodepend,
 347 [AS_HELP_STRING([--enable-autodepend],
 348                 [automatically generate dependencies to .h-files.
 349                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 350                  found])],
 351 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 352
 353 #### Make srcdir absolute, if it isn't already.  It's important to
 354 #### avoid running the path through pwd unnecessarily, since pwd can
 355 #### give you automounter prefixes, which can go away.  We do all this
 356 #### so Emacs can find its files when run uninstalled.
 357 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 358 unset CDPATH
 359 case "${srcdir}" in
 360   /* ) ;;
 361   . )
 362     ## We may be able to use the $PWD environment variable to make this
 363     ## absolute.  But sometimes PWD is inaccurate.
 364     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 365     ## but that tested only for a well-formed and valid PWD,
 366     ## it did not object when PWD was well-formed and valid but just wrong.
 367     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 368     then
 369       srcdir="$PWD"
 370     else
 371       srcdir="`(cd ${srcdir}; pwd)`"
 372     fi
 373   ;;
 374   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 375 esac
 376
 377 #### Given the configuration name, set machfile and opsysfile to the
 378 #### names of the m/*.h and s/*.h files we should use.
 379
 380 ### Canonicalize the configuration name.
 381
 382 AC_CANONICAL_HOST
 383 canonical=$host
 384 configuration=${host_alias-${build_alias-$host}}
 385
 386 dnl This used to use changequote, but, apart from `changequote is evil'
 387 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 388 dnl the great gob of text.  Thus it's not processed for possible expansion.
 389 dnl Just make sure the brackets remain balanced.
 390 dnl
 391 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 392 dnl indicated by comments.
 393 dnl quotation begins
 394 [
 395
 396 ### If you add support for a new configuration, add code to this
 397 ### switch statement to recognize your configuration name and select
 398 ### the appropriate operating system and machine description files.
 399
 400 ### You would hope that you could choose an m/*.h file pretty much
 401 ### based on the machine portion of the configuration name, and an s/*.h
 402 ### file based on the operating system portion.  However, it turns out
 403 ### that each m/*.h file is pretty manufacturer-specific - for
 404 ### example mips.h is MIPS
 405 ### So we basically have to have a special case for each
 406 ### configuration name.
 407 ###
 408 ### As far as handling version numbers on operating systems is
 409 ### concerned, make sure things will fail in a fixable way.  If
 410 ### /etc/MACHINES doesn't say anything about version numbers, be
 411 ### prepared to handle anything reasonably.  If version numbers
 412 ### matter, be sure /etc/MACHINES says something about it.
 413
 414 machine='' opsys='' unported=no
 415 case "${canonical}" in
 416
 417   ## GNU/Linux and similar ports
 418   *-*-linux* )
 419     opsys=gnu-linux
 420     case ${canonical} in
 421       alpha*)   machine=alpha ;;
 422       s390x-*)  machine=ibms390x ;;
 423       powerpc*) machine=macppc ;;
 424       sparc*)   machine=sparc ;;
 425       ia64*)    machine=ia64 ;;
 426       m68k*)    machine=m68k ;;
 427       x86_64*)  machine=amdx86-64 ;;
 428     esac
 429   ;;
 430
 431   ## FreeBSD ports
 432   *-*-freebsd* )
 433     opsys=freebsd
 434     case "${canonical}" in
 435       alpha*)           machine=alpha ;;
 436       amd64-*|x86_64-*) machine=amdx86-64 ;;
 437       ia64-*)           machine=ia64 ;;
 438       i[3456]86-*)      machine=intel386 ;;
 439       powerpc-*)        machine=macppc ;;
 440       sparc-*)          machine=sparc ;;
 441       sparc64-*)        machine=sparc ;;
 442     esac
 443   ;;
 444
 445   ## FreeBSD kernel + glibc based userland
 446   *-*-kfreebsd*gnu* )
 447     opsys=gnu-kfreebsd
 448     case "${canonical}" in
 449       alpha*)           machine=alpha ;;
 450       amd64-*|x86_64-*) machine=amdx86-64 ;;
 451       ia64-*)           machine=ia64 ;;
 452       i[3456]86-*)      machine=intel386 ;;
 453       powerpc-*)        machine=macppc ;;
 454       sparc-*)          machine=sparc ;;
 455       sparc64-*)        machine=sparc ;;
 456     esac
 457   ;;
 458
 459   ## NetBSD ports
 460   *-*-netbsd* )
 461     opsys=netbsd
 462     case "${canonical}" in
 463       alpha*)      machine=alpha ;;
 464       x86_64-*)    machine=amdx86-64 ;;
 465       i[3456]86-*) machine=intel386 ;;
 466       m68k-*)      machine=m68k ;;
 467       powerpc-*)   machine=macppc ;;
 468       sparc*-)     machine=sparc ;;
 469       vax-*)       machine=vax ;;
 470     esac
 471   ;;
 472
 473   ## OpenBSD ports
 474   *-*-openbsd* )
 475     opsys=openbsd
 476     case "${canonical}" in
 477       alpha*)    machine=alpha ;;
 478       x86_64-*)  machine=amdx86-64 ;;
 479       i386-*)    machine=intel386 ;;
 480       powerpc-*) machine=macppc ;;
 481       sparc*)    machine=sparc ;;
 482       vax-*)     machine=vax ;;
 483     esac
 484   ;;
 485
 486   ## Apple Darwin / Mac OS X
 487   *-apple-darwin* )
 488     case "${canonical}" in
 489       i[3456]86-* )  machine=intel386 ;;
 490       powerpc-* )    machine=macppc ;;
 491       x86_64-* )     machine=amdx86-64 ;;
 492       * )            unported=yes ;;
 493     esac
 494     opsys=darwin
 495     # Define CPP as follows to make autoconf work correctly.
 496     CPP="${CC-cc} -E -no-cpp-precomp"
 497     # Use fink packages if available.
 498     if test -d /sw/include && test -d /sw/lib; then
 499       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 500       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 501       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 502     fi
 503   ;;
 504
 505   ## HP 9000 series 700 and 800, running HP/UX
 506   hppa*-hp-hpux10.2* )
 507     opsys=hpux10-20
 508   ;;
 509   hppa*-hp-hpux1[1-9]* )
 510     opsys=hpux11
 511     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 512   ;;
 513
 514   ## IBM machines
 515   rs6000-ibm-aix4.[23]* )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   powerpc-ibm-aix4.[23]*  )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521   rs6000-ibm-aix[56]* )
 522     machine=ibmrs6000 opsys=aix4-2
 523   ;;
 524   powerpc-ibm-aix[56]*  )
 525     machine=ibmrs6000 opsys=aix4-2
 526   ;;
 527
 528   ## Silicon Graphics machines
 529   ## Iris 4D
 530   mips-sgi-irix6.5 )
 531     opsys=irix6-5
 532     # Without defining _LANGUAGE_C, things get masked out in the headers
 533     # so that, for instance, grepping for `free' in stdlib.h fails and
 534     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 535     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 536     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 537   ;;
 538
 539   ## Suns
 540   *-sun-solaris* \
 541     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 542     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 543     case "${canonical}" in
 544       i[3456]86-*-* )     machine=intel386 ;;
 545       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 546       sparc* )          machine=sparc ;;
 547       * )               unported=yes ;;
 548     esac
 549     case "${canonical}" in
 550       *-sunos5.6* | *-solaris2.6* )
 551                 opsys=sol2-6
 552                 NON_GNU_CPP=/usr/ccs/lib/cpp
 553                 RANLIB="ar -ts"
 554                 ;;
 555       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 556                 opsys=sol2-6
 557                 emacs_check_sunpro_c=yes
 558                 NON_GNU_CPP=/usr/ccs/lib/cpp
 559                 ;;
 560       *-sunos5* | *-solaris* )
 561                 opsys=sol2-10
 562                 emacs_check_sunpro_c=yes
 563                 NON_GNU_CPP=/usr/ccs/lib/cpp
 564                 ;;
 565     esac
 566     ## Watch out for a compiler that we know will not work.
 567     case "${canonical}" in
 568      *-solaris* | *-sunos5* )
 569                 if [ "x$CC" = x/usr/ucb/cc ]; then
 570                   ## /usr/ucb/cc doesn't work;
 571                   ## we should find some other compiler that does work.
 572                   unset CC
 573                 fi
 574                 ;;
 575       *) ;;
 576     esac
 577   ;;
 578
 579   ## Intel 386 machines where we don't care about the manufacturer.
 580   i[3456]86-*-* )
 581     machine=intel386
 582     case "${canonical}" in
 583       *-cygwin )                opsys=cygwin ;;
 584       *-darwin* )               opsys=darwin
 585                                 CPP="${CC-cc} -E -no-cpp-precomp"
 586                                 ;;
 587       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 588       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 589       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 590       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 591     esac
 592   ;;
 593
 594   * )
 595     unported=yes
 596   ;;
 597 esac
 598
 599 ### If the code above didn't choose an operating system, just choose
 600 ### an operating system based on the configuration name.  You really
 601 ### only want to use this when you have no idea what the right
 602 ### operating system is; if you know what operating systems a machine
 603 ### runs, it's cleaner to make it explicit in the case statement
 604 ### above.
 605 if test x"${opsys}" = x; then
 606   case "${canonical}" in
 607     *-gnu* )                            opsys=gnu ;;
 608     * )
 609       unported=yes
 610     ;;
 611   esac
 612 fi
 613
 614 ]
 615 dnl quotation ends
 616
 617 if test $unported = yes; then
 618   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 619 Check `etc/MACHINES' for recognized configuration names.])
 620 fi
 621
 622 if test -n "$machine"; then
 623   machfile="m/${machine}.h"
 624 else
 625   machfile=
 626 fi
 627 opsysfile="s/${opsys}.h"
 628
 629
 630 #### Choose a compiler.
 631 test -n "$CC" && cc_specified=yes
 632
 633 # Save the value of CFLAGS that the user specified.
 634 SPECIFIED_CFLAGS="$CFLAGS"
 635
 636 dnl Sets GCC=yes if using gcc.
 637 AC_PROG_CC
 638 AM_PROG_CC_C_O
 639
 640 # Initialize gnulib right after verifying that the C compiler works.
 641 gl_EARLY
 642
 643 # On Suns, sometimes $CPP names a directory.
 644 if test -n "$CPP" && test -d "$CPP"; then
 645   CPP=
 646 fi
 647
 648 ## If not using gcc, and on Solaris, and no CPP specified, see if
 649 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 650 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 651  test x"$CPP" = x; then
 652   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 653   AC_CACHE_VAL(emacs_cv_sunpro_c,
 654   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 655 [[#ifndef __SUNPRO_C
 656 fail;
 657 #endif
 658 ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 659   AC_MSG_RESULT($emacs_cv_sunpro_c)
 660
 661   if test x"$emacs_cv_sunpro_c" = xyes; then
 662     NON_GNU_CPP="$CC -E -Xs"
 663   fi
 664 fi
 665
 666 #### Some systems specify a CPP to use unless we are using GCC.
 667 #### Now that we know whether we are using GCC, we can decide whether
 668 #### to use that one.
 669 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 670 then
 671   CPP="$NON_GNU_CPP"
 672 fi
 673
 674 #### Some systems specify a CC to use unless we are using GCC.
 675 #### Now that we know whether we are using GCC, we can decide whether
 676 #### to use that one.
 677 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 678   test x$cc_specified != xyes
 679 then
 680   CC="$NON_GNU_CC"
 681 fi
 682
 683 if test x$GCC = xyes; then
 684   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 685 else
 686   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 687 fi
 688
 689 AC_ARG_ENABLE([gcc-warnings],
 690   [AS_HELP_STRING([--enable-gcc-warnings],
 691                   [turn on lots of GCC warnings (for developers)])],
 692   [case $enableval in
 693      yes|no) ;;
 694      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 695    esac
 696    gl_gcc_warnings=$enableval],
 697   [gl_gcc_warnings=no]
 698 )
 699
 700 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 701 # ------------------------------------------------
 702 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 703 # Otherwise, run RUN-IF-NOT-FOUND.
 704 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 705   [AC_PREPROC_IFELSE(
 706     [AC_LANG_PROGRAM(
 707       [[
 708 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 709 /* ok */
 710 #else
 711 # error "your version of gcc is older than $1.$2"
 712 #endif
 713       ]]),
 714     ], [$3], [$4])
 715   ]
 716 )
 717
 718 # When compiling with GCC, prefer -isystem to -I when including system
 719 # include files, to avoid generating useless diagnostics for the files.
 720 if test "$gl_gcc_warnings" != yes; then
 721   isystem='-I'
 722 else
 723   isystem='-isystem '
 724
 725   # This, $nw, is the list of warnings we disable.
 726   nw=
 727
 728   case $with_x_toolkit in
 729     lucid | athena | motif)
 730        # Old toolkits mishandle 'const'.
 731        nw="$nw -Wwrite-strings"
 732        ;;
 733     *)
 734        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 735        ;;
 736   esac
 737   AC_SUBST([WERROR_CFLAGS])
 738
 739   nw="$nw -Waggregate-return"       # anachronistic
 740   nw="$nw -Wlong-long"              # C90 is anachronistic
 741   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 742   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 743   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 744   nw="$nw -Wcast-qual"              # Too many warnings for now
 745   nw="$nw -Wconversion"             # Too many warnings for now
 746   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 747   nw="$nw -Wsign-conversion"        # Too many warnings for now
 748   nw="$nw -Woverlength-strings"     # Not a problem these days
 749   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 750   nw="$nw -Wpadded"                 # Our structs are not padded
 751   nw="$nw -Wredundant-decls"        # We regularly (re)declare getenv etc.
 752   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 753   nw="$nw -Wformat-nonliteral"      # Emacs does this a lot
 754   nw="$nw -Wvla"                    # warnings in gettext.h
 755   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 756   nw="$nw -Wswitch-enum"            # Too many warnings for now
 757   nw="$nw -Wswitch-default"         # Too many warnings for now
 758   nw="$nw -Wfloat-equal"            # e.g., ftoastr.c
 759   nw="$nw -Winline"                 # e.g., dispnew.c's inlining of row_equal_p
 760
 761   # Emacs doesn't care about shadowing; see
 762   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 763   nw="$nw -Wshadow"
 764
 765   # The following lines should be removable at some point.
 766   nw="$nw -Wstack-protector"
 767   nw="$nw -Wstrict-overflow"
 768   nw="$nw -Wsuggest-attribute=const"
 769   nw="$nw -Wsuggest-attribute=pure"
 770
 771   gl_MANYWARN_ALL_GCC([ws])
 772   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 773   for w in $ws; do
 774     gl_WARN_ADD([$w])
 775   done
 776   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 777   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 778   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 779   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 780   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 781   gl_WARN_ADD([-Wno-format-nonliteral])
 782
 783   # In spite of excluding -Wlogical-op above, it is enabled, as of
 784   # gcc 4.5.0 20090517.
 785   gl_WARN_ADD([-Wno-logical-op])
 786
 787   gl_WARN_ADD([-fdiagnostics-show-option])
 788   gl_WARN_ADD([-funit-at-a-time])
 789
 790   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 791   AC_DEFINE([_FORTIFY_SOURCE], [2],
 792     [enable compile-time and run-time bounds-checking, and some warnings])
 793   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 794
 795   # We use a slightly smaller set of warning options for lib/.
 796   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 797   nw=
 798   nw="$nw -Wunused-macros"
 799
 800   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 801   AC_SUBST([GNULIB_WARN_CFLAGS])
 802 fi
 803
 804
 805
 806 #### Some other nice autoconf tests.
 807
 808 dnl checks for programs
 809 AC_PROG_CPP
 810 AC_PROG_INSTALL
 811 AC_PROG_MKDIR_P
 812 if test "x$RANLIB" = x; then
 813   AC_PROG_RANLIB
 814 fi
 815
 816 ## Although we're running on an amd64 kernel, we're actually compiling for
 817 ## the x86 architecture.  The user should probably have provided an
 818 ## explicit --build to `configure', but if everything else than the kernel
 819 ## is running in i386 mode, we can help them out.
 820 if test "$machine" = "amdx86-64"; then
 821   AC_CHECK_DECL([i386])
 822   if test "$ac_cv_have_decl_i386" = "yes"; then
 823     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 824     machine=intel386
 825     machfile="m/${machine}.h"
 826   fi
 827 fi
 828
 829 AC_PATH_PROG(INSTALL_INFO, install-info)
 830 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 831 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 832 dnl Don't use GZIP, which is used by gzip for additional parameters.
 833 AC_PATH_PROG(GZIP_PROG, gzip)
 834
 835
 836 ## Need makeinfo >= 4.7 (?) to build the manuals.
 837 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 838 dnl By this stage, configure has already checked for egrep and set EGREP,
 839 dnl or exited with an error if no egrep was found.
 840 if test "$MAKEINFO" != "no" && \
 841   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 842    MAKEINFO=no
 843 fi
 844
 845 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 846 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 847 ## therefore in the category of "special tools" not normally required, which
 848 ## configure does not have to check for (eg autoconf itself).
 849 ## In a Bazaar checkout on the other hand, the manuals are not included.
 850 ## So makeinfo is a requirement to build from Bazaar, and configure
 851 ## should test for it as it does for any other build requirement.
 852 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 853 ## with pre-built manuals, from a Bazaar checkout.
 854 HAVE_MAKEINFO=yes
 855
 856 if test "$MAKEINFO" = "no"; then
 857   MAKEINFO=makeinfo
 858   if test "x${with_makeinfo}" = "xno"; then
 859     HAVE_MAKEINFO=no
 860   elif test ! -e $srcdir/info/emacs; then
 861     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 862 source tree does not seem to have pre-built manuals in the `info' directory.
 863 Either install a suitable version of makeinfo, or re-run configure
 864 with the `--without-makeinfo' option to build without the manuals.] )
 865   fi
 866 fi
 867 AC_SUBST(HAVE_MAKEINFO)
 868
 869 dnl Just so that there is only a single place we need to edit.
 870 INFO_EXT=.info
 871 INFO_OPTS=--no-split
 872 AC_SUBST(INFO_EXT)
 873 AC_SUBST(INFO_OPTS)
 874
 875 dnl Add our options to ac_link now, after it is set up.
 876
 877 if test x$GCC = xyes; then
 878   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 879     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 880 else
 881   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 882     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 883 fi
 884
 885 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 886 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 887 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 888 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 889 dnl if not built to support GNU ld.
 890
 891 late_LDFLAGS=$LDFLAGS
 892 if test x$GCC = xyes; then
 893   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 894 else
 895   LDFLAGS="$LDFLAGS -znocombreloc"
 896 fi
 897
 898 AC_MSG_CHECKING([for -znocombreloc])
 899 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 900   [AC_MSG_RESULT(yes)],
 901   LDFLAGS=$late_LDFLAGS
 902   [AC_MSG_RESULT(no)])
 903
 904
 905 # The value of CPP is a quoted variable reference, so we need to do this
 906 # to get its actual value...
 907 CPP=`eval "echo $CPP"`
 908
 909
 910 dnl The function dump-emacs will not be defined and temacs will do
 911 dnl (load "loadup") automatically unless told otherwise.
 912 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 913 case "$opsys" in
 914   your-opsys-here) CANNOT_DUMP=yes ;;
 915 esac
 916
 917 test "$CANNOT_DUMP" = "yes" && \
 918   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 919
 920 AC_SUBST(CANNOT_DUMP)
 921
 922
 923 UNEXEC_OBJ=unexelf.o
 924 case "$opsys" in
 925   # MSDOS uses unexcoff.o
 926   # MSWindows uses unexw32.o
 927   aix4-2)
 928    UNEXEC_OBJ=unexaix.o
 929    ;;
 930   cygwin)
 931    UNEXEC_OBJ=unexcw.o
 932    ;;
 933   darwin)
 934    UNEXEC_OBJ=unexmacosx.o
 935    ;;
 936   hpux10-20 | hpux11)
 937    UNEXEC_OBJ=unexhp9k800.o
 938    ;;
 939   sol2-10)
 940    # Use the Solaris dldump() function, called from unexsol.c, to dump
 941    # emacs, instead of the generic ELF dump code found in unexelf.c.
 942    # The resulting binary has a complete symbol table, and is better
 943    # for debugging and other observability tools (debuggers, pstack, etc).
 944    #
 945    # If you encounter a problem using dldump(), please consider sending
 946    # a message to the OpenSolaris tools-linking mailing list:
 947    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 948    #
 949    # It is likely that dldump() works with older Solaris too, but this has
 950    # not been tested, so for now this change is for Solaris 10 or newer.
 951    UNEXEC_OBJ=unexsol.o
 952    ;;
 953 esac
 954
 955 LD_SWITCH_SYSTEM=
 956 case "$opsys" in
 957   freebsd)
 958    ## Let `ld' find image libs and similar things in /usr/local/lib.
 959    ## The system compiler, GCC, has apparently been modified to not
 960    ## look there, contrary to what a stock GCC would do.
 961 ### It's not our place to do this.  See bug#10313#17.
 962 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 963       :
 964    ;;
 965
 966   gnu-linux)
 967    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 968    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 969    ;;
 970
 971   netbsd)
 972 ### It's not our place to do this.  See bug#10313#17.
 973 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 974       :
 975    ;;
 976
 977   openbsd)
 978    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 979    ## otherwise Emacs dumps core on elf systems.
 980    LD_SWITCH_SYSTEM="-Z"
 981    ;;
 982 esac
 983 AC_SUBST(LD_SWITCH_SYSTEM)
 984
 985 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 986
 987 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 988 ## which has not been defined yet.  When this was handled with cpp,
 989 ## it was expanded to null when configure sourced the s/*.h file.
 990 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 991 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 992 ## (or somesuch), but because it is supposed to go at the _front_
 993 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 994 ## Compare with the gnu-linux case below, which added to the end
 995 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 996 ## LD_SWITCH_SYSTEM_TEMACS.
 997 case "$opsys" in
 998   netbsd|openbsd)
 999    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1000 esac
1001
1002
1003 C_SWITCH_MACHINE=
1004 if test "$machine" = "alpha"; then
1005   AC_CHECK_DECL([__ELF__])
1006   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1007     ## With ELF, make sure that all common symbols get allocated to in the
1008     ## data section.  Otherwise, the dump of temacs may miss variables in
1009     ## the shared library that have been initialized.  For example, with
1010     ## GNU libc, __malloc_initialized would normally be resolved to the
1011     ## shared library's .bss section, which is fatal.
1012     if test "x$GCC" = "xyes"; then
1013       C_SWITCH_MACHINE="-fno-common"
1014     else
1015       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
1016     fi
1017   else
1018     UNEXEC_OBJ=unexalpha.o
1019   fi
1020 fi
1021 AC_SUBST(C_SWITCH_MACHINE)
1022
1023 AC_SUBST(UNEXEC_OBJ)
1024
1025 C_SWITCH_SYSTEM=
1026 ## Some programs in src produce warnings saying certain subprograms
1027 ## are too complex and need a MAXMEM value greater than 2000 for
1028 ## additional optimization.  --nils@exp-math.uni-essen.de
1029 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1030   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1031 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1032 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1033 AC_SUBST(C_SWITCH_SYSTEM)
1034
1035
1036 LIBS_SYSTEM=
1037 case "$opsys" in
1038   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1039   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1040
1041   freebsd) LIBS_SYSTEM="-lutil" ;;
1042
1043   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1044
1045   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1046
1047   ## Motif needs -lgen.
1048   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1049 esac
1050 AC_SUBST(LIBS_SYSTEM)
1051
1052
1053 ### Make sure subsequent tests use flags consistent with the build flags.
1054
1055 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1056   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1057 else
1058   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1059 fi
1060
1061 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1062 AC_DEFUN([AC_TYPE_SIZE_T])
1063 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1064 AC_DEFUN([AC_TYPE_UID_T])
1065
1066 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1067 AC_SYS_LARGEFILE
1068
1069
1070 LIB_MATH=-lm
1071 LIB_STANDARD=
1072 START_FILES=
1073
1074 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
1075 case $opsys in
1076   cygwin )
1077     LIB_MATH=
1078     START_FILES='pre-crt0.o'
1079     ;;
1080   darwin )
1081     ## Adding -lm confuses the dynamic linker, so omit it.
1082     LIB_MATH=
1083     START_FILES='pre-crt0.o'
1084     ;;
1085   freebsd )
1086     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1087     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1088     ;;
1089   gnu-linux | gnu-kfreebsd )
1090     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1091     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1092     ;;
1093   hpux10-20 | hpux11 )
1094     LIB_STANDARD=-lc
1095     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1096     ;;
1097   dnl NB this may be adjusted below.
1098   netbsd | openbsd )
1099     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1100     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1101     ;;
1102 esac
1103
1104 AC_SUBST(LIB_MATH)
1105 AC_SUBST(START_FILES)
1106
1107 dnl Not all platforms use crtn.o files.  Check if the current one does.
1108 crt_files=
1109
1110 for file in x $LIB_STANDARD $START_FILES; do
1111   case "$file" in
1112     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1113   esac
1114 done
1115
1116 if test "x$crt_files" != x; then
1117
1118   ## If user specified a crt-dir, use that unconditionally.
1119   crt_gcc=no
1120
1121   if test "X$CRT_DIR" = "X"; then
1122
1123     CRT_DIR=/usr/lib            # default
1124
1125     case "$canonical" in
1126       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1127       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1128       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1129       ## For anything else (eg /usr/lib32), it is up the user to specify
1130       ## the location (bug#5655).
1131       ## Test for crtn.o, not just the directory, because sometimes the
1132       ## directory exists but does not have the relevant files (bug#1287).
1133       ## FIXME better to test for binary compatibility somehow.
1134       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1135       ;;
1136
1137       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1138     esac
1139
1140     case "$opsys" in
1141       hpux10-20) CRT_DIR=/lib ;;
1142     esac
1143
1144     test "x${GCC}" = xyes && crt_gcc=yes
1145
1146   fi                            # CRT_DIR = ""
1147
1148   crt_missing=
1149
1150   for file in $crt_files; do
1151
1152     ## If we're using gcc, try to determine it automatically by asking
1153     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1154     ## system-dependent default from above.]
1155     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1156
1157        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1158        case "$crt_file" in
1159          */*)
1160            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1161            ;;
1162        esac
1163     fi
1164
1165     dnl We expect all the files to be in a single directory, so after the
1166     dnl first there is no point asking gcc.
1167     crt_gcc=no
1168
1169     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1170   done                          # $crt_files
1171
1172   test "x$crt_missing" = x || \
1173     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1174 Try using the --with-crt-dir option.])
1175
1176 fi                              # crt_files != ""
1177
1178 AC_SUBST(CRT_DIR)
1179
1180 case $opsys in
1181   netbsd | openbsd )
1182     if test -f $CRT_DIR/crti.o; then
1183
1184         test -f $CRT_DIR/crtn.o || \
1185           AC_MSG_ERROR([Required file not found: crtn.o])
1186
1187         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1188         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1189     fi
1190     ;;
1191 esac
1192
1193
1194 dnl This function definition taken from Gnome 2.0
1195 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1196 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1197 dnl also defines GSTUFF_PKG_ERRORS on error
1198 AC_DEFUN([PKG_CHECK_MODULES], [
1199   succeeded=no
1200
1201   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1202
1203   if test "$PKG_CONFIG" = "no" ; then
1204      ifelse([$4], , [AC_MSG_ERROR([
1205       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1206   else
1207      PKG_CONFIG_MIN_VERSION=0.9.0
1208      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1209         AC_MSG_CHECKING(for $2)
1210
1211         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1212            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1213            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1214             edit_cflags="
1215               s,///*,/,g
1216               s/^/ /
1217               s/ -I/ $isystem/g
1218               s/^ //
1219             "
1220             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1221             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1222             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1223             succeeded=yes
1224         else
1225             AC_MSG_RESULT(no)
1226             $1_CFLAGS=""
1227             $1_LIBS=""
1228             ## If we have a custom action on failure, don't print errors, but
1229             ## do set a variable so people can do so.
1230             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1231             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1232         fi
1233
1234         AC_SUBST($1_CFLAGS)
1235         AC_SUBST($1_LIBS)
1236      else
1237         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1238         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1239      fi
1240   fi
1241
1242   if test $succeeded = yes; then
1243      ifelse([$3], , :, [$3])
1244   else
1245      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1246   fi
1247 ])
1248
1249
1250 if test "${with_sound}" != "no"; then
1251   # Sound support for GNU/Linux and the free BSDs.
1252   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1253     have_sound_header=yes)
1254   # Emulation library used on NetBSD.
1255   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1256   AC_SUBST(LIBSOUND)
1257
1258   ALSA_REQUIRED=1.0.0
1259   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1260   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1261   if test $HAVE_ALSA = yes; then
1262     SAVE_CFLAGS="$CFLAGS"
1263     SAVE_LIBS="$LIBS"
1264     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1265     LIBS="$ALSA_LIBS $LIBS"
1266     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1267                     emacs_alsa_normal=yes,
1268                     emacs_alsa_normal=no)
1269     if test "$emacs_alsa_normal" != yes; then
1270       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1271                      [[snd_lib_error_set_handler (0);]])],
1272                      emacs_alsa_subdir=yes,
1273                      emacs_alsa_subdir=no)
1274       if test "$emacs_alsa_subdir" != yes; then
1275         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1276       fi
1277       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1278     fi
1279
1280     CFLAGS="$SAVE_CFLAGS"
1281     LIBS="$SAVE_LIBS"
1282     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1283     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1284     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1285   fi
1286
1287   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1288   dnl compiles only on the specified platforms.  For others, it
1289   dnl probably doesn't make sense to try.
1290   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1291      case "$opsys" in
1292        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1293        gnu-linux|freebsd|netbsd)
1294          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1295          ;;
1296      esac
1297   fi
1298
1299   AC_SUBST(CFLAGS_SOUND)
1300 fi
1301
1302 dnl checks for header files
1303 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1304   linux/version.h sys/systeminfo.h \
1305   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1306   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1307   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1308
1309 AC_MSG_CHECKING(if personality LINUX32 can be set)
1310 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1311                emacs_cv_personality_linux32=yes,
1312                emacs_cv_personality_linux32=no)
1313 AC_MSG_RESULT($emacs_cv_personality_linux32)
1314
1315 if test $emacs_cv_personality_linux32 = yes; then
1316   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1317             [Define to 1 if personality LINUX32 can be set.])
1318 fi
1319
1320 dnl On Solaris 8 there's a compilation warning for term.h because
1321 dnl it doesn't define `bool'.
1322 AC_CHECK_HEADERS(term.h, , , -)
1323 AC_HEADER_TIME
1324 AC_CHECK_DECLS([sys_siglist])
1325 if test $ac_cv_have_decl_sys_siglist != yes; then
1326   # For Tru64, at least:
1327   AC_CHECK_DECLS([__sys_siglist])
1328   if test $ac_cv_have_decl___sys_siglist = yes; then
1329     AC_DEFINE(sys_siglist, __sys_siglist,
1330               [Define to any substitute for sys_siglist.])
1331   fi
1332 fi
1333 AC_HEADER_SYS_WAIT
1334
1335 dnl Some systems have utime.h but don't declare the struct anyplace.
1336 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1337 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1338 #include <sys/time.h>
1339 #include <time.h>
1340 #else
1341 #ifdef HAVE_SYS_TIME_H
1342 #include <sys/time.h>
1343 #else
1344 #include <time.h>
1345 #endif
1346 #endif
1347 #ifdef HAVE_UTIME_H
1348 #include <utime.h>
1349 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1350   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1351 if test $emacs_cv_struct_utimbuf = yes; then
1352   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1353 fi
1354
1355 dnl Check for speed_t typedef.
1356 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1357   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1358     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1359 if test $emacs_cv_speed_t = yes; then
1360   AC_DEFINE(HAVE_SPEED_T, 1,
1361            [Define to 1 if `speed_t' is declared by <termios.h>.])
1362 fi
1363
1364 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1365 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1366 #include <sys/time.h>
1367 #include <time.h>
1368 #else
1369 #ifdef HAVE_SYS_TIME_H
1370 #include <sys/time.h>
1371 #else
1372 #include <time.h>
1373 #endif
1374 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1375   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1376 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1377 if test $emacs_cv_struct_timeval = yes; then
1378   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1379 fi
1380
1381 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1382 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1383 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1384   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1385 HAVE_EXCEPTION=$emacs_cv_struct_exception
1386 if test $emacs_cv_struct_exception != yes; then
1387   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1388 fi
1389
1390 AC_CHECK_HEADERS(sys/socket.h)
1391 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1392 #if HAVE_SYS_SOCKET_H
1393 #include <sys/socket.h>
1394 #endif])
1395 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1396 #if HAVE_SYS_SOCKET_H
1397 #include <sys/socket.h>
1398 #endif])
1399 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1400 #if HAVE_SYS_SOCKET_H
1401 #include <sys/socket.h>
1402 #endif])
1403 AC_CHECK_FUNCS(getifaddrs freeifaddrs)
1404
1405 dnl checks for structure members
1406 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1407                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1408                   struct ifreq.ifr_addr,
1409                   struct ifreq.ifr_addr.sa_len], , ,
1410                  [AC_INCLUDES_DEFAULT
1411 #if HAVE_SYS_SOCKET_H
1412 #include <sys/socket.h>
1413 #endif
1414 #if HAVE_NET_IF_H
1415 #include <net/if.h>
1416 #endif])
1417
1418 dnl checks for compiler characteristics
1419
1420 dnl Testing __STDC__ to determine prototype support isn't good enough.
1421 dnl DEC C, for instance, doesn't define it with default options, and
1422 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1423 dnl and void *.
1424 AC_C_PROTOTYPES
1425 AC_C_VOLATILE
1426 AC_C_CONST
1427 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1428   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1429                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1430 if test $emacs_cv_void_star = yes; then
1431   AC_DEFINE(POINTER_TYPE, void)
1432 else
1433   AC_DEFINE(POINTER_TYPE, char)
1434 fi
1435 AH_TEMPLATE(POINTER_TYPE,
1436             [Define as `void' if your compiler accepts `void *'; otherwise
1437              define as `char'.])dnl
1438
1439 dnl Check for endianness.
1440 AC_C_BIGENDIAN
1441
1442 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1443   [emacs_cv_attribute_aligned],
1444   [AC_COMPILE_IFELSE(
1445      [AC_LANG_PROGRAM(
1446         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1447         [[]])],
1448      [emacs_cv_attribute_aligned=yes],
1449      [emacs_cv_attribute_aligned=no])])
1450 if test $emacs_cv_attribute_aligned = yes; then
1451   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1452     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1453 fi
1454
1455 dnl check for Make feature
1456 AC_PROG_MAKE_SET
1457
1458 DEPFLAGS=
1459 MKDEPDIR=":"
1460 deps_frag=deps.mk
1461 dnl check for GNU Make if we have GCC and autodepend is on.
1462 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1463    AC_MSG_CHECKING([whether we are using GNU Make])
1464    HAVE_GNU_MAKE=no
1465    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1466    if test "x$testval" != x; then
1467       HAVE_GNU_MAKE=yes
1468    else
1469       ac_enable_autodepend=no
1470    fi
1471    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1472    if test $HAVE_GNU_MAKE = yes; then
1473       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1474       SAVE_CFLAGS="$CFLAGS"
1475       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1476       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1477       CFLAGS="$SAVE_CFLAGS"
1478       test -f deps.d || ac_enable_autodepend=no
1479       rm -rf deps.d
1480       AC_MSG_RESULT([$ac_enable_autodepend])
1481    fi
1482    if test $ac_enable_autodepend = yes; then
1483       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1484       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1485       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1486       deps_frag=autodeps.mk
1487    fi
1488 fi
1489 deps_frag=$srcdir/src/$deps_frag
1490 AC_SUBST(MKDEPDIR)
1491 AC_SUBST(DEPFLAGS)
1492 AC_SUBST_FILE(deps_frag)
1493
1494
1495 lisp_frag=$srcdir/src/lisp.mk
1496 AC_SUBST_FILE(lisp_frag)
1497
1498
1499 dnl checks for operating system services
1500 AC_SYS_LONG_FILE_NAMES
1501
1502 #### Choose a window system.
1503
1504 AC_PATH_X
1505 if test "$no_x" = yes; then
1506   window_system=none
1507 else
1508   window_system=x11
1509 fi
1510
1511 LD_SWITCH_X_SITE_RPATH=
1512 if test "${x_libraries}" != NONE; then
1513   if test -n "${x_libraries}"; then
1514     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1515     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1516   fi
1517   x_default_search_path=""
1518   x_search_path=${x_libraries}
1519   if test -z "${x_search_path}"; then
1520     x_search_path=/usr/lib
1521   fi
1522   for x_library in `echo ${x_search_path}: | \
1523                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1524     x_search_path="\
1525 ${x_library}/X11/%L/%T/%N%C%S:\
1526 ${x_library}/X11/%l/%T/%N%C%S:\
1527 ${x_library}/X11/%T/%N%C%S:\
1528 ${x_library}/X11/%L/%T/%N%S:\
1529 ${x_library}/X11/%l/%T/%N%S:\
1530 ${x_library}/X11/%T/%N%S"
1531     if test x"${x_default_search_path}" = x; then
1532       x_default_search_path=${x_search_path}
1533     else
1534       x_default_search_path="${x_search_path}:${x_default_search_path}"
1535     fi
1536   done
1537 fi
1538 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1539
1540 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1541   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1542 fi
1543
1544 if test x"${x_includes}" = x; then
1545   bitmapdir=/usr/include/X11/bitmaps
1546 else
1547   # accumulate include directories that have X11 bitmap subdirectories
1548   bmd_acc="dummyval"
1549   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1550     if test -d "${bmd}/X11/bitmaps"; then
1551       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1552     fi
1553     if test -d "${bmd}/bitmaps"; then
1554       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1555     fi
1556   done
1557   if test ${bmd_acc} != "dummyval"; then
1558     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1559   fi
1560 fi
1561
1562 HAVE_NS=no
1563 NS_IMPL_COCOA=no
1564 NS_IMPL_GNUSTEP=no
1565 tmp_CPPFLAGS="$CPPFLAGS"
1566 tmp_CFLAGS="$CFLAGS"
1567 CPPFLAGS="$CPPFLAGS -x objective-c"
1568 CFLAGS="$CFLAGS -x objective-c"
1569 TEMACS_LDFLAGS2="\${LDFLAGS}"
1570 GNU_OBJC_CFLAGS=
1571 dnl I don't think it's especially important, but src/Makefile.in
1572 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1573 dnl trailing "/" to it, so now we do it here.
1574 if test "${with_ns}" != no; then
1575   if test "${opsys}" = darwin; then
1576      NS_IMPL_COCOA=yes
1577      ns_appdir=`pwd`/nextstep/Emacs.app
1578      ns_appbindir=${ns_appdir}/Contents/MacOS/
1579      ns_appresdir=${ns_appdir}/Contents/Resources
1580      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1581   elif test -f $GNUSTEP_CONFIG_FILE; then
1582      NS_IMPL_GNUSTEP=yes
1583      ns_appdir=`pwd`/nextstep/Emacs.app
1584      ns_appbindir=${ns_appdir}/
1585      ns_appresdir=${ns_appdir}/Resources
1586      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1587      dnl FIXME sourcing this several times in subshells seems inefficient.
1588      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1589      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1590      dnl I seemed to need these as well with GNUstep-startup 0.25.
1591      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1592      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1593      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1594        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1595      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1596        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1597      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1598      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1599      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1600      LIB_STANDARD=
1601      START_FILES=
1602      TEMACS_LDFLAGS2=
1603      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1604      dnl If they had chosen to either define it or not, we could have
1605      dnl just used AC_CHECK_DECL here.
1606      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1607        emacs_cv_objc_exceptions,
1608 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1609 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1610 1;
1611 #else
1612 fail;
1613 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1614      if test $emacs_cv_objc_exceptions = yes; then
1615        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1616        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1617          [Define if GNUstep uses ObjC exceptions.])
1618        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1619      fi
1620   fi
1621
1622   dnl This is only used while we test the NS headers, it gets reset below.
1623   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1624
1625   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1626                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1627   files are missing or cannot be compiled.])])
1628   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1629                                      [NSInteger i;])],
1630                     ns_have_nsinteger=yes,
1631                     ns_have_nsinteger=no)
1632   if test $ns_have_nsinteger = yes; then
1633     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1634   fi
1635 fi
1636 AC_SUBST(TEMACS_LDFLAGS2)
1637
1638 LEIM_INSTALLDIR="\${install_prefix}/leim"
1639 ns_frag=/dev/null
1640 NS_OBJ=
1641 NS_OBJC_OBJ=
1642 if test "${HAVE_NS}" = yes; then
1643   if test "$with_toolkit_scroll_bars" = "no"; then
1644     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1645   fi
1646
1647   window_system=nextstep
1648   with_xft=no
1649   # set up packaging dirs
1650   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1651      prefix=${ns_appresdir}
1652      exec_prefix=${ns_appbindir}
1653      libexecdir=${ns_appbindir}/libexec
1654      LEIM_INSTALLDIR="\${ns_appresdir}/leim"
1655   fi
1656   ns_frag=$srcdir/src/ns.mk
1657   NS_OBJ="fontset.o fringe.o image.o"
1658   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1659 fi
1660 CFLAGS="$tmp_CFLAGS"
1661 CPPFLAGS="$tmp_CPPFLAGS"
1662 AC_SUBST(LEIM_INSTALLDIR)
1663 AC_SUBST(NS_OBJ)
1664 AC_SUBST(NS_OBJC_OBJ)
1665 AC_SUBST(LIB_STANDARD)
1666 AC_SUBST_FILE(ns_frag)
1667
1668 case "${window_system}" in
1669   x11 )
1670     HAVE_X_WINDOWS=yes
1671     HAVE_X11=yes
1672     case "${with_x_toolkit}" in
1673       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1674       motif ) USE_X_TOOLKIT=MOTIF ;;
1675       gtk ) with_gtk=yes
1676 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1677 dnl USE_X_TOOLKIT is set.
1678             USE_X_TOOLKIT=none ;;
1679       gtk3 ) with_gtk3=yes
1680              USE_X_TOOLKIT=none ;;
1681       no ) USE_X_TOOLKIT=none ;;
1682 dnl If user did not say whether to use a toolkit, make this decision later:
1683 dnl use the toolkit if we have gtk, or X11R5 or newer.
1684       * ) USE_X_TOOLKIT=maybe ;;
1685     esac
1686   ;;
1687   nextstep | none )
1688     HAVE_X_WINDOWS=no
1689     HAVE_X11=no
1690     USE_X_TOOLKIT=none
1691   ;;
1692 esac
1693
1694 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1695    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1696    if test "$HAVE_XSERVER" = true ||
1697       test -n "$DISPLAY" ||
1698       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1699         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1700 were found.  You should install the relevant development files for X
1701 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1702 sure you have development files for image handling, i.e.
1703 tiff, gif, jpeg, png and xpm.
1704 If you are sure you want Emacs compiled without X window support, pass
1705   --without-x
1706 to configure.])
1707    fi
1708 fi
1709
1710 ### If we're using X11, we should use the X menu package.
1711 HAVE_MENUS=no
1712 case ${HAVE_X11} in
1713   yes ) HAVE_MENUS=yes ;;
1714 esac
1715
1716 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1717 # Assume not, until told otherwise.
1718 GNU_MALLOC=yes
1719
1720 AC_CACHE_CHECK(
1721   [whether malloc is Doug Lea style],
1722   [emacs_cv_var_doug_lea_malloc],
1723   [AC_LINK_IFELSE(
1724      [AC_LANG_PROGRAM(
1725         [[#include <malloc.h>
1726           static void hook (void) {}]],
1727         [[malloc_set_state (malloc_get_state ());
1728           __after_morecore_hook = hook;
1729           __malloc_initialize_hook = hook;]])],
1730      [emacs_cv_var_doug_lea_malloc=yes],
1731      [emacs_cv_var_doug_lea_malloc=no])])
1732 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1733
1734
1735 dnl See comments in aix4-2.h about maybe using system malloc there.
1736 system_malloc=no
1737 case "$opsys" in
1738   ## darwin ld insists on the use of malloc routines in the System framework.
1739   darwin|sol2-10) system_malloc=yes ;;
1740 esac
1741
1742 if test "${system_malloc}" = "yes"; then
1743   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1744   GNU_MALLOC=no
1745   GNU_MALLOC_reason="
1746     (The GNU allocators don't work with this system configuration.)"
1747   GMALLOC_OBJ=
1748   VMLIMIT_OBJ=
1749 else
1750   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1751   VMLIMIT_OBJ=vm-limit.o
1752 fi
1753 AC_SUBST(GMALLOC_OBJ)
1754 AC_SUBST(VMLIMIT_OBJ)
1755
1756 if test "$doug_lea_malloc" = "yes" ; then
1757   if test "$GNU_MALLOC" = yes ; then
1758     GNU_MALLOC_reason="
1759       (Using Doug Lea's new malloc from the GNU C Library.)"
1760   fi
1761   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1762             [Define to 1 if you are using the GNU C Library.])
1763
1764   ## Use mmap directly for allocating larger buffers.
1765   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1766   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1767   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1768   case "$opsys" in
1769     gnu*) REL_ALLOC=no ;;
1770   esac
1771 fi
1772
1773 if test x"${REL_ALLOC}" = x; then
1774   REL_ALLOC=${GNU_MALLOC}
1775 fi
1776
1777 use_mmap_for_buffers=no
1778 case "$opsys" in
1779   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1780 esac
1781
1782 AC_FUNC_MMAP
1783 if test $use_mmap_for_buffers = yes; then
1784   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1785   REL_ALLOC=no
1786 fi
1787
1788 LIBS="$LIBS_SYSTEM $LIBS"
1789
1790 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1791 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1792 AC_CHECK_LIB(dnet, dnet_ntoa)
1793 dnl This causes -lresolv to get used in subsequent tests,
1794 dnl which causes failures on some systems such as HPUX 9.
1795 dnl AC_CHECK_LIB(resolv, gethostbyname)
1796
1797 dnl FIXME replace main with a function we actually want from this library.
1798 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1799
1800 dnl Check if pthreads is available.
1801 LIB_PTHREAD=
1802 AC_CHECK_HEADERS(pthread.h)
1803 if test "$ac_cv_header_pthread_h"; then
1804   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1805   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1806   dnl testing for pthread_self if Emacs uses gmalloc.c.
1807   if test "$GMALLOC_OBJ" = gmalloc.o; then
1808     emacs_pthread_function=pthread_atfork
1809   else
1810     emacs_pthread_function=pthread_self
1811   fi
1812   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1813 fi
1814 if test "$HAVE_PTHREAD" = yes; then
1815   case "${canonical}" in
1816     *-hpux*) ;;
1817     *) LIB_PTHREAD="-lpthread"
1818        LIBS="$LIB_PTHREAD $LIBS" ;;
1819   esac
1820   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1821 fi
1822 AC_SUBST([LIB_PTHREAD])
1823
1824 AC_CHECK_LIB(pthreads, cma_open)
1825
1826 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1827 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1828 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1829 ## added to LIBS in configure would never contain the pthreads part,
1830 ## but the value used in Makefiles might.  FIXME?
1831 ##
1832 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1833 ## be harmless on older versions of X where it happens to exist.
1834 test "$opsys" = "aix4-2" && \
1835   test $ac_cv_lib_pthreads_cma_open = yes && \
1836   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1837
1838 dnl Check for need for bigtoc support on IBM AIX
1839
1840 case ${host_os} in
1841 aix*)
1842   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1843     case $GCC in
1844     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1845     *) gdb_cv_bigtoc=-bbigtoc ;;
1846     esac
1847
1848     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1849     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1850   ])
1851   ;;
1852 esac
1853
1854 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1855 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1856 # REAL_CPPFLAGS later on.
1857
1858 REAL_CFLAGS="$CFLAGS"
1859 REAL_CPPFLAGS="$CPPFLAGS"
1860
1861 if test "${HAVE_X11}" = "yes"; then
1862   DEFS="$C_SWITCH_X_SITE $DEFS"
1863   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1864   LIBS="-lX11 $LIBS"
1865   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1866   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1867
1868   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1869   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1870   # but it's more convenient here to set LD_RUN_PATH since this
1871   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1872   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1873     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1874     export LD_RUN_PATH
1875   fi
1876
1877   if test "${opsys}" = "gnu-linux"; then
1878     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1879     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1880      [[XOpenDisplay ("foo");]])],
1881      [xgnu_linux_first_failure=no],
1882      [xgnu_linux_first_failure=yes])
1883     if test "${xgnu_linux_first_failure}" = "yes"; then
1884       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1885       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1886       OLD_CPPFLAGS="$CPPFLAGS"
1887       OLD_LIBS="$LIBS"
1888       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1889       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1890       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1891       LIBS="$LIBS -b i486-linuxaout"
1892       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1893        [[XOpenDisplay ("foo");]])],
1894        [xgnu_linux_second_failure=no],
1895        [xgnu_linux_second_failure=yes])
1896       if test "${xgnu_linux_second_failure}" = "yes"; then
1897         # If we get the same failure with -b, there is no use adding -b.
1898         # So take it out.  This plays safe.
1899         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1900         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1901         CPPFLAGS="$OLD_CPPFLAGS"
1902         LIBS="$OLD_LIBS"
1903         AC_MSG_RESULT(no)
1904       else
1905         AC_MSG_RESULT(yes)
1906       fi
1907     else
1908       AC_MSG_RESULT(no)
1909     fi
1910   fi
1911
1912   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1913   # header files included from there.
1914   AC_MSG_CHECKING(for Xkb)
1915   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1916 #include <X11/XKBlib.h>]],
1917         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1918         emacs_xkb=yes, emacs_xkb=no)
1919   AC_MSG_RESULT($emacs_xkb)
1920   if test $emacs_xkb = yes; then
1921     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1922   fi
1923
1924   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1925 XScreenNumberOfScreen XSetWMProtocols)
1926 fi
1927
1928 if test "${window_system}" = "x11"; then
1929   AC_MSG_CHECKING(X11 version 6)
1930   AC_CACHE_VAL(emacs_cv_x11_version_6,
1931   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1932 [[#if XlibSpecificationRelease < 6
1933 fail;
1934 #endif
1935 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1936   if test $emacs_cv_x11_version_6 = yes; then
1937     AC_MSG_RESULT(6 or newer)
1938     AC_DEFINE(HAVE_X11R6, 1,
1939               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1940     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1941     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1942     ## XIM support.
1943     case "$opsys" in
1944       sol2-*) : ;;
1945       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1946            [Define if you have usable X11R6-style XIM support.])
1947          ;;
1948     esac
1949   else
1950     AC_MSG_RESULT(before 6)
1951   fi
1952 fi
1953
1954
1955 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1956 HAVE_RSVG=no
1957 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1958   if test "${with_rsvg}" != "no"; then
1959     RSVG_REQUIRED=2.11.0
1960     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1961
1962     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1963     AC_SUBST(RSVG_CFLAGS)
1964     AC_SUBST(RSVG_LIBS)
1965
1966     if test $HAVE_RSVG = yes; then
1967       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1968       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1969       LIBS="$RSVG_LIBS $LIBS"
1970     fi
1971   fi
1972 fi
1973
1974 HAVE_IMAGEMAGICK=no
1975 if test "${HAVE_X11}" = "yes"; then
1976   if test "${with_imagemagick}" != "no"; then
1977     ## 6.2.8 is the earliest version known to work, but earlier versions
1978     ## might work - let us know if you find one.
1979     ## 6.0.7 does not work.  See bug#7955.
1980     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1981     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1982     AC_SUBST(IMAGEMAGICK_CFLAGS)
1983     AC_SUBST(IMAGEMAGICK_LIBS)
1984
1985     if test $HAVE_IMAGEMAGICK = yes; then
1986       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1987       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1988       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1989       AC_CHECK_FUNCS(MagickExportImagePixels)
1990     fi
1991   fi
1992 fi
1993
1994
1995 HAVE_GTK=no
1996 GTK_OBJ=
1997 if test "${with_gtk3}" = "yes"; then
1998   GLIB_REQUIRED=2.28
1999   GTK_REQUIRED=3.0
2000   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2001
2002   dnl Checks for libraries.
2003   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2004   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
2005      AC_MSG_ERROR($GTK_PKG_ERRORS)
2006   fi
2007   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2008   GTK_OBJ=emacsgtkfixed.o
2009 fi
2010
2011 if test "$pkg_check_gtk" != "yes"; then
2012   HAVE_GTK=no
2013 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2014   GLIB_REQUIRED=2.10
2015   GTK_REQUIRED=2.10
2016   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2017
2018   dnl Checks for libraries.
2019   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2020   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
2021      AC_MSG_ERROR($GTK_PKG_ERRORS)
2022   fi
2023 fi
2024 fi
2025
2026 if test x"$pkg_check_gtk" = xyes; then
2027
2028   AC_SUBST(GTK_CFLAGS)
2029   AC_SUBST(GTK_LIBS)
2030   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2031   CFLAGS="$CFLAGS $GTK_CFLAGS"
2032   LIBS="$GTK_LIBS $LIBS"
2033   dnl Try to compile a simple GTK program.
2034   GTK_COMPILES=no
2035   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
2036   if test "${GTK_COMPILES}" != "yes"; then
2037     if test "$USE_X_TOOLKIT" != "maybe"; then
2038       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2039     fi
2040   else
2041     HAVE_GTK=yes
2042     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2043     GTK_OBJ="gtkutil.o $GTK_OBJ"
2044     USE_X_TOOLKIT=none
2045     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
2046       :
2047     else
2048       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2049        closing open displays.  This is no problem if you just use
2050        one display, but if you use more than one and close one of them
2051        Emacs may crash.]])
2052       sleep 3
2053     fi
2054   fi
2055
2056 fi
2057 AC_SUBST(GTK_OBJ)
2058
2059
2060 if test "${HAVE_GTK}" = "yes"; then
2061
2062   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2063   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2064   if test "$with_toolkit_scroll_bars" != no; then
2065     with_toolkit_scroll_bars=yes
2066   fi
2067
2068   dnl  Check if we have the old file selection dialog declared and
2069   dnl  in the link library.  In 2.x it may be in the library,
2070   dnl  but not declared if deprecated featured has been selected out.
2071   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2072   HAVE_GTK_FILE_SELECTION=no
2073   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2074                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2075 #include <gtk/gtk.h>])
2076   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2077     AC_CHECK_FUNCS(gtk_file_selection_new)
2078   fi
2079
2080
2081   dnl Check for functions introduced in 2.14 and later.
2082   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2083                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2084                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2085                  gtk_orientable_set_orientation \
2086                  gtk_window_set_has_resize_grip)
2087 fi
2088
2089 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2090 dnl other platforms.
2091 HAVE_DBUS=no
2092 DBUS_OBJ=
2093 if test "${with_dbus}" = "yes"; then
2094    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2095    if test "$HAVE_DBUS" = yes; then
2096      LIBS="$LIBS $DBUS_LIBS"
2097      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2098      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2099      dnl dbus_validate_* have been introduced in D-Bus 1.5.12.
2100      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2101                     dbus_validate_bus_name \
2102                     dbus_validate_path \
2103                     dbus_validate_interface \
2104                     dbus_validate_member)
2105      DBUS_OBJ=dbusbind.o
2106    fi
2107 fi
2108 AC_SUBST(DBUS_OBJ)
2109
2110 dnl GSettings has been tested under GNU/Linux only.
2111 HAVE_GSETTINGS=no
2112 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2113    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2114    if test "$HAVE_GSETTINGS" = "yes"; then
2115       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2116       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2117       SETTINGS_LIBS="$GSETTINGS_LIBS"
2118    fi
2119 fi
2120
2121 dnl GConf has been tested under GNU/Linux only.
2122 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2123 HAVE_GCONF=no
2124 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2125    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2126    if test "$HAVE_GCONF" = yes; then
2127       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2128       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2129       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2130       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2131    fi
2132 fi
2133
2134 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2135     SAVE_CFLAGS="$CFLAGS"
2136     SAVE_LIBS="$LIBS"
2137     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2138     LIBS="$SETTINGS_LIBS $LIBS"
2139     AC_CHECK_FUNCS([g_type_init])
2140     CFLAGS="$SAVE_CFLAGS"
2141     LIBS="$SAVE_LIBS"
2142 fi
2143 AC_SUBST(SETTINGS_CFLAGS)
2144 AC_SUBST(SETTINGS_LIBS)
2145
2146
2147 dnl SELinux is available for GNU/Linux only.
2148 HAVE_LIBSELINUX=no
2149 LIBSELINUX_LIBS=
2150 if test "${with_selinux}" = "yes"; then
2151    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2152    if test "$HAVE_LIBSELINUX" = yes; then
2153       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2154       LIBSELINUX_LIBS=-lselinux
2155    fi
2156 fi
2157 AC_SUBST(LIBSELINUX_LIBS)
2158
2159 HAVE_GNUTLS=no
2160 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2161 if test "${with_gnutls}" = "yes" ; then
2162   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2163   if test "${HAVE_GNUTLS}" = "yes"; then
2164     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2165   fi
2166
2167   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2168   LIBS="$LIBGNUTLS_LIBS $LIBS"
2169   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2170
2171   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2172     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2173   fi
2174 fi
2175
2176 AC_SUBST(LIBGNUTLS_LIBS)
2177 AC_SUBST(LIBGNUTLS_CFLAGS)
2178
2179 dnl Do not put whitespace before the #include statements below.
2180 dnl Older compilers (eg sunos4 cc) choke on it.
2181 HAVE_XAW3D=no
2182 LUCID_LIBW=
2183 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2184   if test "$with_xaw3d" != no; then
2185     AC_MSG_CHECKING(for xaw3d)
2186     AC_CACHE_VAL(emacs_cv_xaw3d,
2187     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2188 #include <X11/Intrinsic.h>
2189 #include <X11/Xaw3d/Simple.h>]],
2190       [[]])],
2191       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2192                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2193       emacs_cv_xaw3d=no)])
2194   else
2195     emacs_cv_xaw3d=no
2196   fi
2197   if test $emacs_cv_xaw3d = yes; then
2198     AC_MSG_RESULT([yes; using Lucid toolkit])
2199     USE_X_TOOLKIT=LUCID
2200     HAVE_XAW3D=yes
2201     LUCID_LIBW=-lXaw3d
2202     AC_DEFINE(HAVE_XAW3D, 1,
2203               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2204   else
2205     AC_MSG_RESULT(no)
2206     AC_MSG_CHECKING(for libXaw)
2207     AC_CACHE_VAL(emacs_cv_xaw,
2208     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2209 #include <X11/Intrinsic.h>
2210 #include <X11/Xaw/Simple.h>]],
2211       [[]])],
2212       emacs_cv_xaw=yes,
2213       emacs_cv_xaw=no)])
2214     if test $emacs_cv_xaw = yes; then
2215       AC_MSG_RESULT([yes; using Lucid toolkit])
2216       USE_X_TOOLKIT=LUCID
2217       LUCID_LIBW=-lXaw
2218     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2219       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2220     else
2221       AC_MSG_ERROR([No X toolkit could be found.
2222 If you are sure you want Emacs compiled without an X toolkit, pass
2223   --with-x-toolkit=no
2224 to configure.  Otherwise, install the development libraries for the toolkit
2225 that you want to use (e.g. Gtk+) and re-run configure.])
2226     fi
2227   fi
2228 fi
2229
2230 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2231
2232 LIBXTR6=
2233 if test "${USE_X_TOOLKIT}" != "none"; then
2234   AC_MSG_CHECKING(X11 toolkit version)
2235   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2236   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2237 [[#if XtSpecificationRelease < 6
2238 fail;
2239 #endif
2240 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2241   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2242   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2243     AC_MSG_RESULT(6 or newer)
2244     AC_DEFINE(HAVE_X11XTR6, 1,
2245               [Define to 1 if you have the X11R6 or newer version of Xt.])
2246     LIBXTR6="-lSM -lICE"
2247     case "$opsys" in
2248       ## Use libw.a along with X11R6 Xt.
2249       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2250     esac
2251   else
2252     AC_MSG_RESULT(before 6)
2253   fi
2254
2255 dnl If using toolkit, check whether libXmu.a exists.
2256 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2257   OLDLIBS="$LIBS"
2258   if test x$HAVE_X11XTR6 = xyes; then
2259     LIBS="-lXt -lSM -lICE $LIBS"
2260   else
2261     LIBS="-lXt $LIBS"
2262   fi
2263   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2264   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2265 fi
2266 AC_SUBST(LIBXTR6)
2267
2268 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2269 dnl Why not just test for libxmu in the normal way?
2270 LIBXMU=-lXmu
2271 case $opsys in
2272   ## These systems don't supply Xmu.
2273   hpux* | aix4-2 )
2274     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2275     ;;
2276 esac
2277 AC_SUBST(LIBXMU)
2278
2279 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2280 if test "${HAVE_X11}" = "yes"; then
2281   if test "${USE_X_TOOLKIT}" != "none"; then
2282     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2283   fi
2284 fi
2285
2286 LIBXP=
2287 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2288   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2289   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2290     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2291 int x = 5;
2292 #else
2293 Motif version prior to 2.1.
2294 #endif]])],
2295     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2296   if test $emacs_cv_motif_version_2_1 = yes; then
2297     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2298   else
2299     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2300     # We put this in CFLAGS temporarily to precede other -I options
2301     # that might be in CFLAGS temporarily.
2302     # We put this in CPPFLAGS where it precedes the other -I options.
2303     OLD_CPPFLAGS=$CPPFLAGS
2304     OLD_CFLAGS=$CFLAGS
2305     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2306     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2307     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2308       [[int x = 5;]])],
2309       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2310     if test $emacs_cv_lesstif = yes; then
2311       # Make sure this -I option remains in CPPFLAGS after it is set
2312       # back to REAL_CPPFLAGS.
2313       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2314       # have those other -I options anyway.  Ultimately, having this
2315       # directory ultimately in CPPFLAGS will be enough.
2316       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2317       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2318     else
2319       CFLAGS=$OLD_CFLAGS
2320       CPPFLAGS=$OLD_CPPFLAGS
2321     fi
2322   fi
2323   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2324     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2325 fi
2326
2327 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2328 dnl using Motif or Xaw3d is available, and unless
2329 dnl --with-toolkit-scroll-bars=no was specified.
2330
2331 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2332             [Define to 1 if we should use toolkit scroll bars.])dnl
2333 USE_TOOLKIT_SCROLL_BARS=no
2334 if test "${with_toolkit_scroll_bars}" != "no"; then
2335   if test "${USE_X_TOOLKIT}" != "none"; then
2336     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2337       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2338       HAVE_XAW3D=no
2339       USE_TOOLKIT_SCROLL_BARS=yes
2340     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2341       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2342       USE_TOOLKIT_SCROLL_BARS=yes
2343     fi
2344   elif test "${HAVE_GTK}" = "yes"; then
2345     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2346     USE_TOOLKIT_SCROLL_BARS=yes
2347   elif test "${HAVE_NS}" = "yes"; then
2348     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2349     USE_TOOLKIT_SCROLL_BARS=yes
2350   fi
2351 fi
2352
2353 dnl See if XIM is available.
2354 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2355           #include <X11/Xlib.h>
2356           #include <X11/Xresource.h>]],
2357          [[XIMProc  callback;]])],
2358          [HAVE_XIM=yes
2359          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2360          HAVE_XIM=no)
2361
2362 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2363
2364 if test "${with_xim}" != "no"; then
2365   AC_DEFINE(USE_XIM, 1,
2366             [Define to 1 if we should use XIM, if it is available.])
2367 fi
2368
2369
2370 if test "${HAVE_XIM}" != "no"; then
2371   late_CFLAGS=$CFLAGS
2372   if test "$GCC" = yes; then
2373     CFLAGS="$CFLAGS --pedantic-errors"
2374   fi
2375   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2376 #include <X11/Xlib.h>
2377 #include <X11/Xresource.h>]],
2378 [[Display *display;
2379 XrmDatabase db;
2380 char *res_name;
2381 char *res_class;
2382 XIMProc  callback;
2383 XPointer *client_data;
2384 #ifndef __GNUC__
2385 /* If we're not using GCC, it's probably not XFree86, and this is
2386    probably right, but we can't use something like --pedantic-errors.  */
2387 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2388                                            char*, XIMProc, XPointer*);
2389 #endif
2390 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2391    client_data);]])],
2392     [emacs_cv_arg6_star=yes])
2393   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2394          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2395 either XPointer or XPointer*.])dnl
2396   if test "$emacs_cv_arg6_star" = yes; then
2397     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2398   else
2399     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2400   fi
2401   CFLAGS=$late_CFLAGS
2402 fi
2403
2404 ### Start of font-backend (under any platform) section.
2405 # (nothing here yet -- this is a placeholder)
2406 ### End of font-backend (under any platform) section.
2407
2408 ### Start of font-backend (under X11) section.
2409 if test "${HAVE_X11}" = "yes"; then
2410    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2411
2412    ## Use -lXft if available, unless `--with-xft=no'.
2413    HAVE_XFT=maybe
2414     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2415       with_xft="no";
2416     fi
2417     if test "x${with_xft}" != "xno"; then
2418
2419       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2420       ## Because xftfont.c uses XRenderQueryExtension, we also
2421       ## need to link to -lXrender.
2422       HAVE_XRENDER=no
2423       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2424       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2425         OLD_CPPFLAGS="$CPPFLAGS"
2426         OLD_CFLAGS="$CFLAGS"
2427         OLD_LIBS="$LIBS"
2428         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2429         CFLAGS="$CFLAGS $XFT_CFLAGS"
2430         XFT_LIBS="-lXrender $XFT_LIBS"
2431         LIBS="$XFT_LIBS $LIBS"
2432         AC_CHECK_HEADER(X11/Xft/Xft.h,
2433           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2434
2435         if test "${HAVE_XFT}" = "yes"; then
2436           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2437             AC_SUBST(XFT_LIBS)
2438           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2439         else
2440           CPPFLAGS="$OLD_CPPFLAGS"
2441           CFLAGS="$OLD_CFLAGS"
2442           LIBS="$OLD_LIBS"
2443         fi                        # "${HAVE_XFT}" = "yes"
2444       fi                          # "$HAVE_XFT" != no
2445     fi                            # "x${with_xft}" != "xno"
2446
2447     ## We used to allow building with FreeType and without Xft.
2448     ## However, the ftx font backend driver is not in good shape.
2449     if test "$HAVE_XFT" != "yes"; then
2450        dnl For the "Does Emacs use" message at the end.
2451        HAVE_XFT=no
2452        HAVE_FREETYPE=no
2453     else
2454        dnl Strict linkers fail with
2455        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2456        dnl if -lfreetype is not specified.
2457        dnl The following is needed to set FREETYPE_LIBS.
2458        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2459                          HAVE_FREETYPE=no)
2460
2461        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2462     fi
2463
2464     HAVE_LIBOTF=no
2465     if test "${HAVE_FREETYPE}" = "yes"; then
2466       AC_DEFINE(HAVE_FREETYPE, 1,
2467                 [Define to 1 if using the freetype and fontconfig libraries.])
2468       if test "${with_libotf}" != "no"; then
2469         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2470                           HAVE_LIBOTF=no)
2471         if test "$HAVE_LIBOTF" = "yes"; then
2472           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2473           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2474                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2475                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2476           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2477             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2478                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2479           fi
2480         fi
2481       fi
2482     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2483     dnl Does the new font backend require it, or can it work without it?
2484     fi
2485
2486     HAVE_M17N_FLT=no
2487     if test "${HAVE_LIBOTF}" = yes; then
2488       if test "${with_m17n_flt}" != "no"; then
2489         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2490         if test "$HAVE_M17N_FLT" = "yes"; then
2491           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2492         fi
2493       fi
2494     fi
2495 else
2496     HAVE_XFT=no
2497     HAVE_FREETYPE=no
2498     HAVE_LIBOTF=no
2499     HAVE_M17N_FLT=no
2500 fi
2501
2502 ### End of font-backend (under X11) section.
2503
2504 AC_SUBST(FREETYPE_CFLAGS)
2505 AC_SUBST(FREETYPE_LIBS)
2506 AC_SUBST(FONTCONFIG_CFLAGS)
2507 AC_SUBST(FONTCONFIG_LIBS)
2508 AC_SUBST(LIBOTF_CFLAGS)
2509 AC_SUBST(LIBOTF_LIBS)
2510 AC_SUBST(M17N_FLT_CFLAGS)
2511 AC_SUBST(M17N_FLT_LIBS)
2512
2513 ### Use -lXpm if available, unless `--with-xpm=no'.
2514 HAVE_XPM=no
2515 LIBXPM=
2516 if test "${HAVE_X11}" = "yes"; then
2517   if test "${with_xpm}" != "no"; then
2518     AC_CHECK_HEADER(X11/xpm.h,
2519       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2520     if test "${HAVE_XPM}" = "yes"; then
2521       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2522       AC_EGREP_CPP(no_return_alloc_pixels,
2523       [#include "X11/xpm.h"
2524 #ifndef XpmReturnAllocPixels
2525 no_return_alloc_pixels
2526 #endif
2527       ], HAVE_XPM=no, HAVE_XPM=yes)
2528
2529       if test "${HAVE_XPM}" = "yes"; then
2530         AC_MSG_RESULT(yes)
2531       else
2532         AC_MSG_RESULT(no)
2533       fi
2534     fi
2535   fi
2536
2537   if test "${HAVE_XPM}" = "yes"; then
2538     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2539     LIBXPM=-lXpm
2540   fi
2541 fi
2542 AC_SUBST(LIBXPM)
2543
2544 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2545 HAVE_JPEG=no
2546 LIBJPEG=
2547 if test "${HAVE_X11}" = "yes"; then
2548   if test "${with_jpeg}" != "no"; then
2549     dnl Checking for jpeglib.h can lose because of a redefinition of
2550     dnl  HAVE_STDLIB_H.
2551     AC_CHECK_HEADER(jerror.h,
2552       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2553   fi
2554
2555   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2556   if test "${HAVE_JPEG}" = "yes"; then
2557     AC_DEFINE(HAVE_JPEG)
2558     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2559         [#include <jpeglib.h>
2560          version=JPEG_LIB_VERSION
2561 ],
2562         [AC_DEFINE(HAVE_JPEG)],
2563         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2564         HAVE_JPEG=no])
2565   fi
2566   if test "${HAVE_JPEG}" = "yes"; then
2567     LIBJPEG=-ljpeg
2568   fi
2569 fi
2570 AC_SUBST(LIBJPEG)
2571
2572 ### Use -lpng if available, unless `--with-png=no'.
2573 HAVE_PNG=no
2574 LIBPNG=
2575 if test "${HAVE_X11}" = "yes"; then
2576   if test "${with_png}" != "no"; then
2577     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2578     # in /usr/include/libpng.
2579     AC_CHECK_HEADERS(png.h libpng/png.h)
2580     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2581       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2582     fi
2583   fi
2584
2585   if test "${HAVE_PNG}" = "yes"; then
2586     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2587     LIBPNG="-lpng -lz -lm"
2588   fi
2589 fi
2590 AC_SUBST(LIBPNG)
2591
2592 ### Use -ltiff if available, unless `--with-tiff=no'.
2593 HAVE_TIFF=no
2594 LIBTIFF=
2595 if test "${HAVE_X11}" = "yes"; then
2596   if test "${with_tiff}" != "no"; then
2597     AC_CHECK_HEADER(tiffio.h,
2598       [tifflibs="-lz -lm"
2599       # At least one tiff package requires the jpeg library.
2600       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2601       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2602   fi
2603
2604   if test "${HAVE_TIFF}" = "yes"; then
2605     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2606     dnl FIXME -lz -lm, as per libpng?
2607     LIBTIFF=-ltiff
2608   fi
2609 fi
2610 AC_SUBST(LIBTIFF)
2611
2612 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2613 HAVE_GIF=no
2614 LIBGIF=
2615 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2616   AC_CHECK_HEADER(gif_lib.h,
2617 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2618 # Earlier versions can crash Emacs.
2619     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2620
2621   if test "$HAVE_GIF" = yes; then
2622     LIBGIF=-lgif
2623   elif test "$HAVE_GIF" = maybe; then
2624 # If gif_lib.h but no libgif, try libungif.
2625     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2626     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2627   fi
2628
2629   if test "${HAVE_GIF}" = "yes"; then
2630     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2631   fi
2632 fi
2633 AC_SUBST(LIBGIF)
2634
2635 dnl Check for required libraries.
2636 if test "${HAVE_X11}" = "yes"; then
2637   MISSING=""
2638   WITH_NO=""
2639   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2640     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2641   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2642     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2643   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2644     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2645   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2646     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2647   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2648     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2649
2650   if test "X${MISSING}" != X; then
2651     AC_MSG_ERROR([The following required libraries were not found:
2652     $MISSING
2653 Maybe some development libraries/packages are missing?
2654 If you don't want to link with them give
2655     $WITH_NO
2656 as options to configure])
2657   fi
2658 fi
2659
2660 ### Use -lgpm if available, unless `--with-gpm=no'.
2661 HAVE_GPM=no
2662 LIBGPM=
2663 if test "${with_gpm}" != "no"; then
2664   AC_CHECK_HEADER(gpm.h,
2665     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2666
2667   if test "${HAVE_GPM}" = "yes"; then
2668     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2669     LIBGPM=-lgpm
2670   fi
2671 fi
2672 AC_SUBST(LIBGPM)
2673
2674 dnl Check for malloc/malloc.h on darwin
2675 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2676
2677 GNUSTEP_CFLAGS=
2678 ### Use NeXTstep API to implement GUI.
2679 if test "${HAVE_NS}" = "yes"; then
2680   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2681   if test "${NS_IMPL_COCOA}" = "yes"; then
2682     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2683   fi
2684   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2685     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2686     # See also .m.o rule in Makefile.in */
2687     # FIXME: are all these flags really needed?  Document here why.  */
2688     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2689     ## Extra CFLAGS applied to src/*.m files.
2690     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2691   fi
2692   # We also have mouse menus.
2693   HAVE_MENUS=yes
2694   OTHER_FILES=ns-app
2695 fi
2696
2697
2698 ### Use session management (-lSM -lICE) if available
2699 HAVE_X_SM=no
2700 LIBXSM=
2701 if test "${HAVE_X11}" = "yes"; then
2702   AC_CHECK_HEADER(X11/SM/SMlib.h,
2703     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2704
2705   if test "${HAVE_X_SM}" = "yes"; then
2706     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2707     LIBXSM="-lSM -lICE"
2708     case "$LIBS" in
2709       *-lSM*) ;;
2710       *)      LIBS="$LIBXSM $LIBS" ;;
2711     esac
2712   fi
2713 fi
2714 AC_SUBST(LIBXSM)
2715
2716 ### Use libxml (-lxml2) if available
2717 HAVE_LIBXML2=no
2718 if test "${with_xml2}" != "no"; then
2719   ### I'm not sure what the version number should be, so I just guessed.
2720   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2721   if test "${HAVE_LIBXML2}" = "yes"; then
2722     LIBS="$LIBXML2_LIBS $LIBS"
2723     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2724     if test "${HAVE_LIBXML2}" = "yes"; then
2725       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2726     else
2727       LIBXML2_LIBS=""
2728       LIBXML2_CFLAGS=""
2729     fi
2730   fi
2731 fi
2732 AC_SUBST(LIBXML2_LIBS)
2733 AC_SUBST(LIBXML2_CFLAGS)
2734
2735 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2736 AC_CACHE_CHECK(whether netdb declares h_errno,
2737                emacs_cv_netdb_declares_h_errno,
2738 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2739   [[return h_errno;]])],
2740   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2741 if test $emacs_cv_netdb_declares_h_errno = yes; then
2742   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2743 fi
2744
2745 # fmod, logb, and frexp are found in -lm on most systems.
2746 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2747 AC_CHECK_LIB(m, sqrt)
2748
2749 # Check for mail-locking functions in a "mail" library.  Probably this should
2750 # have the same check as for liblockfile below.
2751 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2752 if test $have_mail = yes; then
2753   LIBS_MAIL=-lmail
2754   LIBS="$LIBS_MAIL $LIBS"
2755   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2756 else
2757   LIBS_MAIL=
2758 fi
2759 dnl Debian, at least:
2760 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2761 if test $have_lockfile = yes; then
2762    LIBS_MAIL=-llockfile
2763    LIBS="$LIBS_MAIL $LIBS"
2764    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2765 else
2766 # If we have the shared liblockfile, assume we must use it for mail
2767 # locking (e.g. Debian).  If we couldn't link against liblockfile
2768 # (no liblockfile.a installed), ensure that we don't need to.
2769   dnl This works for files generally, not just executables.
2770   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2771   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2772                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2773   if test $ac_cv_prog_liblockfile = yes; then
2774     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2775 This probably means that movemail could lose mail.
2776 There may be a `development' package to install containing liblockfile.])
2777   fi
2778 fi
2779 AC_CHECK_FUNCS(touchlock)
2780 AC_CHECK_HEADERS(maillock.h)
2781 AC_SUBST(LIBS_MAIL)
2782
2783 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2784 ## interlock access to the mail spool.  The alternative is a lock file named
2785 ## /usr/spool/mail/$USER.lock.
2786 mail_lock=no
2787 case "$opsys" in
2788   aix4-2) mail_lock="lockf" ;;
2789
2790   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2791
2792   ## On GNU/Linux systems, both methods are used by various mail programs.
2793   ## I assume most people are using newer mailers that have heard of flock.
2794   ## Change this if you need to.
2795   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2796   ## configure gets the right answers, and that means *NOT* using flock.
2797   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2798   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2799   ## Debian maintainer hasn't provided a clean fix for Emacs.
2800   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2801   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2802   ## correct logic.  -- fx
2803   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2804   ## liblockfile is a Free Software replacement for libmail, used on
2805   ## Debian systems and elsewhere. -rfr.
2806   gnu-*)
2807     mail_lock="flock"
2808     if test $have_mail = yes || test $have_lockfile = yes; then
2809       test $ac_cv_header_maillock_h = yes && mail_lock=no
2810     fi
2811     ;;
2812 esac
2813
2814 BLESSMAIL_TARGET=
2815 case "$mail_lock" in
2816   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2817
2818   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2819
2820   *) BLESSMAIL_TARGET="need-blessmail" ;;
2821 esac
2822 AC_SUBST(BLESSMAIL_TARGET)
2823
2824
2825 AC_CHECK_FUNCS(gethostname getdomainname \
2826 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2827 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2828 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2829 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2830 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm \
2831 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2832 gai_strerror mkstemp getline getdelim mremap fsync sync \
2833 difftime mempcpy mblen mbrlen posix_memalign \
2834 getpwent endpwent getgrent endgrent \
2835 cfmakeraw cfsetspeed copysign __executable_start)
2836
2837 dnl Cannot use AC_CHECK_FUNCS
2838 AC_CACHE_CHECK([for __builtin_unwind_init],
2839                emacs_cv_func___builtin_unwind_init,
2840 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2841                 emacs_cv_func___builtin_unwind_init=yes,
2842                 emacs_cv_func___builtin_unwind_init=no)])
2843 if test $emacs_cv_func___builtin_unwind_init = yes; then
2844   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2845             [Define to 1 if you have the `__builtin_unwind_init' function.])
2846 fi
2847
2848 AC_CHECK_HEADERS(sys/un.h)
2849
2850 AC_FUNC_FSEEKO
2851
2852 AC_FUNC_GETPGRP
2853
2854 # UNIX98 PTYs.
2855 AC_CHECK_FUNCS(grantpt)
2856
2857 # PTY-related GNU extensions.
2858 AC_CHECK_FUNCS(getpt)
2859
2860 # Check this now, so that we will NOT find the above functions in ncurses.
2861 # That is because we have not set up to link ncurses in lib-src.
2862 # It's better to believe a function is not available
2863 # than to expect to find it in ncurses.
2864 # Also we need tputs and friends to be able to build at all.
2865 AC_MSG_CHECKING([for library containing tputs])
2866 # Run a test program that contains a call to tputs, a call that is
2867 # never executed.  This tests whether a pre-'main' dynamic linker
2868 # works with the library.  It's too much trouble to actually call
2869 # tputs in the test program, due to portability hassles.  When
2870 # cross-compiling, assume the test program will run if it links.
2871 AC_DEFUN([tputs_link_source], [
2872   AC_LANG_SOURCE(
2873      [[extern void tputs (const char *, int, int (*)(int));
2874        int main (int argc, char **argv)
2875        {
2876           if (argc == 10000)
2877             tputs (argv[0], 0, 0);
2878           return 0;
2879        }]])
2880 ])
2881 # Maybe curses should be tried earlier?
2882 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2883 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2884   OLIBS=$LIBS
2885   if test -z "$tputs_library"; then
2886     LIBS_TERMCAP=
2887     msg='none required'
2888   else
2889     LIBS_TERMCAP=-l$tputs_library
2890     msg=$LIBS_TERMCAP
2891     LIBS="$LIBS_TERMCAP $LIBS"
2892   fi
2893   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2894     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2895   LIBS=$OLIBS
2896   if test "X$msg" != Xno; then
2897     break
2898   fi
2899 done
2900 AC_MSG_RESULT([$msg])
2901 if test "X$msg" = Xno; then
2902   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2903 The following libraries were tried (in order):
2904   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2905 Please try installing whichever of these libraries is most appropriate
2906 for your system, together with its header files.
2907 For example, a libncurses-dev(el) or similar package.])
2908 fi
2909
2910 ## Use termcap instead of terminfo?
2911 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2912 TERMINFO=yes
2913 ## FIXME?  In the cases below where we unconditionally set
2914 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2915 ## if that was found above to have tputs.
2916 ## Should we use the gnu* logic everywhere?
2917 case "$opsys" in
2918   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2919   ##  The ncurses library has been moved out of the System framework in
2920   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2921   ##  option to use it.
2922   darwin) LIBS_TERMCAP="-lncurses" ;;
2923
2924   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2925
2926   freebsd)
2927     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2928     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2929     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2930 [[#if __FreeBSD_version < 400000
2931 fail;
2932 #endif
2933 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2934
2935     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2936
2937     if test $emacs_cv_freebsd_terminfo = yes; then
2938       LIBS_TERMCAP="-lncurses"
2939     else
2940       TERMINFO=no
2941       LIBS_TERMCAP="-ltermcap"
2942     fi
2943     ;;
2944
2945   netbsd)
2946     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2947       TERMINFO=no
2948       LIBS_TERMCAP="-ltermcap"
2949     fi
2950     ;;
2951
2952   openbsd) LIBS_TERMCAP="-lncurses" ;;
2953
2954   ## hpux: Make sure we get select from libc rather than from libcurses
2955   ##  because libcurses on HPUX 10.10 has a broken version of select.
2956   ##  We used to use -lc -lcurses, but this may be cleaner.
2957   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2958   # set that way, now it uses the default).  Isn't this a contradiction?
2959   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2960
2961 esac
2962
2963 TERMCAP_OBJ=tparam.o
2964 if test $TERMINFO = yes; then
2965   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2966   TERMCAP_OBJ=terminfo.o
2967 fi
2968 AC_SUBST(LIBS_TERMCAP)
2969 AC_SUBST(TERMCAP_OBJ)
2970
2971
2972 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2973 resolv=no
2974 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2975 #include <arpa/nameser.h>
2976 #include <resolv.h>]],
2977     [[return res_init();]])],
2978     have_res_init=yes, have_res_init=no)
2979 if test "$have_res_init" = no; then
2980   OLIBS="$LIBS"
2981   LIBS="$LIBS -lresolv"
2982   AC_MSG_CHECKING(for res_init with -lresolv)
2983   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2984 #include <arpa/nameser.h>
2985 #include <resolv.h>]],
2986     [[return res_init();]])],
2987     have_res_init=yes, have_res_init=no)
2988   AC_MSG_RESULT($have_res_init)
2989   if test "$have_res_init" = yes ; then
2990     resolv=yes
2991   fi
2992   LIBS="$OLIBS"
2993 fi
2994
2995 if test "$have_res_init" = yes; then
2996   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2997 fi
2998
2999 # Do we need the Hesiod library to provide the support routines?
3000 LIBHESIOD=
3001 if test "$with_hesiod" != no ; then
3002   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3003   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3004      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3005                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3006   if test "$resolv" = yes ; then
3007     RESOLVLIB=-lresolv
3008   else
3009     RESOLVLIB=
3010   fi
3011   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3012         hesiod=yes, :, $RESOLVLIB)])
3013
3014   if test x"$hesiod" = xyes; then
3015     AC_DEFINE(HAVE_LIBHESIOD, 1,
3016               [Define to 1 if you have the hesiod library (-lhesiod).])
3017     LIBHESIOD=-lhesiod
3018   fi
3019 fi
3020 AC_SUBST(LIBHESIOD)
3021
3022 # Do we need libresolv (due to res_init or Hesiod)?
3023 if test "$resolv" = yes ; then
3024   AC_DEFINE(HAVE_LIBRESOLV, 1,
3025             [Define to 1 if you have the resolv library (-lresolv).])
3026   LIBRESOLV=-lresolv
3027 else
3028   LIBRESOLV=
3029 fi
3030 AC_SUBST(LIBRESOLV)
3031
3032 # These tell us which Kerberos-related libraries to use.
3033 COM_ERRLIB=
3034 CRYPTOLIB=
3035 KRB5LIB=
3036 DESLIB=
3037 KRB4LIB=
3038
3039 if test "${with_kerberos}" != no; then
3040   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3041   if test $have_com_err = yes; then
3042     COM_ERRLIB=-lcom_err
3043     LIBS="$COM_ERRLIB $LIBS"
3044     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
3045   fi
3046   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3047   if test $have_crypto = yes; then
3048     CRYPTOLIB=-lcrypto
3049     LIBS="$CRYPTOLIB $LIBS"
3050     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3051   fi
3052   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3053   if test $have_k5crypto = yes; then
3054     CRYPTOLIB=-lk5crypto
3055     LIBS="$CRYPTOLIB $LIBS"
3056     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3057   fi
3058   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3059   if test $have_krb5=yes; then
3060     KRB5LIB=-lkrb5
3061     LIBS="$KRB5LIB $LIBS"
3062     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3063   fi
3064   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3065   if test "${with_kerberos5}" = no; then
3066     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3067     if test $have_des425 = yes; then
3068       DESLIB=-ldes425
3069       LIBS="$DESLIB $LIBS"
3070       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3071     else
3072       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3073       if test $have_des = yes; then
3074         DESLIB=-ldes
3075         LIBS="$DESLIB $LIBS"
3076         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3077       fi
3078     fi
3079     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3080     if test $have_krb4 = yes; then
3081       KRB4LIB=-lkrb4
3082       LIBS="$KRB4LIB $LIBS"
3083       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3084     else
3085       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3086       if test $have_krb = yes; then
3087         KRB4LIB=-lkrb
3088         LIBS="$KRB4LIB $LIBS"
3089         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3090       fi
3091     fi
3092   fi
3093
3094   if test "${with_kerberos5}" != no; then
3095     AC_CHECK_HEADERS(krb5.h,
3096       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3097                         [#include <krb5.h>])])
3098   else
3099     AC_CHECK_HEADERS(des.h,,
3100                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3101                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3102     AC_CHECK_HEADERS(krb.h,,
3103                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3104                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3105   fi
3106   AC_CHECK_HEADERS(com_err.h)
3107 fi
3108
3109 AC_SUBST(COM_ERRLIB)
3110 AC_SUBST(CRYPTOLIB)
3111 AC_SUBST(KRB5LIB)
3112 AC_SUBST(DESLIB)
3113 AC_SUBST(KRB4LIB)
3114
3115 AC_MSG_CHECKING(whether localtime caches TZ)
3116 AC_CACHE_VAL(emacs_cv_localtime_cache,
3117 [if test x$ac_cv_func_tzset = xyes; then
3118 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3119 char TZ_GMT0[] = "TZ=GMT0";
3120 char TZ_PST8[] = "TZ=PST8";
3121 main()
3122 {
3123   time_t now = time ((time_t *) 0);
3124   int hour_GMT0, hour_unset;
3125   if (putenv (TZ_GMT0) != 0)
3126     exit (1);
3127   hour_GMT0 = localtime (&now)->tm_hour;
3128   unsetenv("TZ");
3129   hour_unset = localtime (&now)->tm_hour;
3130   if (putenv (TZ_PST8) != 0)
3131     exit (1);
3132   if (localtime (&now)->tm_hour == hour_GMT0)
3133     exit (1);
3134   unsetenv("TZ");
3135   if (localtime (&now)->tm_hour != hour_unset)
3136     exit (1);
3137   exit (0);
3138 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3139 [# If we have tzset, assume the worst when cross-compiling.
3140 emacs_cv_localtime_cache=yes])
3141 else
3142         # If we lack tzset, report that localtime does not cache TZ,
3143         # since we can't invalidate the cache if we don't have tzset.
3144         emacs_cv_localtime_cache=no
3145 fi])dnl
3146 AC_MSG_RESULT($emacs_cv_localtime_cache)
3147 if test $emacs_cv_localtime_cache = yes; then
3148   AC_DEFINE(LOCALTIME_CACHE, 1,
3149             [Define to 1 if localtime caches TZ.])
3150 fi
3151
3152 if test "x$HAVE_TIMEVAL" = xyes; then
3153   AC_CHECK_FUNCS(gettimeofday)
3154   if test $ac_cv_func_gettimeofday = yes; then
3155     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3156                    emacs_cv_gettimeofday_two_arguments,
3157     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3158 #ifdef TIME_WITH_SYS_TIME
3159 #include <sys/time.h>
3160 #include <time.h>
3161 #else
3162 #ifdef HAVE_SYS_TIME_H
3163 #include <sys/time.h>
3164 #else
3165 #include <time.h>
3166 #endif
3167 #endif]],
3168       [[struct timeval time;
3169        gettimeofday (&time, 0);]])],
3170       emacs_cv_gettimeofday_two_arguments=yes,
3171       emacs_cv_gettimeofday_two_arguments=no)])
3172     if test $emacs_cv_gettimeofday_two_arguments = no; then
3173       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3174                 [Define to 1 if gettimeofday accepts only one argument.])
3175     fi
3176   fi
3177 fi
3178
3179 ok_so_far=yes
3180 AC_CHECK_FUNC(socket, , ok_so_far=no)
3181 if test $ok_so_far = yes; then
3182   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3183 fi
3184 if test $ok_so_far = yes; then
3185   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3186 fi
3187 if test $ok_so_far = yes; then
3188 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3189   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3190             [Define to 1 if you have inet sockets.])
3191 fi
3192
3193 if test -f /usr/lpp/X11/bin/smt.exp; then
3194   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3195             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3196 fi
3197
3198 AC_MSG_CHECKING(whether system supports dynamic ptys)
3199 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3200   AC_MSG_RESULT(yes)
3201   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3202 else
3203   AC_MSG_RESULT(no)
3204 fi
3205
3206 AC_FUNC_FORK
3207
3208 AC_CHECK_FUNCS(snprintf)
3209
3210 dnl Adapted from Haible's version.
3211 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3212   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3213     [[char* cs = nl_langinfo(CODESET);]])],
3214     emacs_cv_langinfo_codeset=yes,
3215     emacs_cv_langinfo_codeset=no)
3216   ])
3217 if test $emacs_cv_langinfo_codeset = yes; then
3218   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3219     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3220 fi
3221
3222 AC_TYPE_MBSTATE_T
3223
3224 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3225   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3226                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3227 if test "$emacs_cv_c_restrict_arr" = yes; then
3228   AC_DEFINE(__restrict_arr, __restrict,
3229     [Define to compiler's equivalent of C99 restrict keyword in array
3230      declarations.  Define as empty for no equivalent.])
3231 fi
3232
3233 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3234 dnl how the tty code is related to POSIX and/or other versions of termios.
3235 dnl The following looks like a useful start.
3236 dnl
3237 dnl AC_SYS_POSIX_TERMIOS
3238 dnl if test $ac_cv_sys_posix_termios = yes; then
3239 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3240 dnl                                and macros for terminal control.])
3241 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3242 dnl fi
3243
3244 # Set up the CFLAGS for real compilation, so we can substitute it.
3245 CFLAGS="$REAL_CFLAGS"
3246 CPPFLAGS="$REAL_CPPFLAGS"
3247
3248 ## Hack to detect a buggy GCC version.
3249 if test "x$GCC" = xyes \
3250    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3251    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3252    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3253    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3254 fi
3255
3256 version=$PACKAGE_VERSION
3257
3258 ### Specify what sort of things we'll be editing into Makefile and config.h.
3259 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3260 AC_SUBST(version)
3261 AC_SUBST(configuration)
3262 ## Unused?
3263 AC_SUBST(canonical)
3264 AC_SUBST(srcdir)
3265 AC_SUBST(prefix)
3266 AC_SUBST(exec_prefix)
3267 AC_SUBST(bindir)
3268 AC_SUBST(datadir)
3269 AC_SUBST(sharedstatedir)
3270 AC_SUBST(libexecdir)
3271 AC_SUBST(mandir)
3272 AC_SUBST(infodir)
3273 AC_SUBST(lispdir)
3274 AC_SUBST(locallisppath)
3275 AC_SUBST(lisppath)
3276 AC_SUBST(x_default_search_path)
3277 AC_SUBST(etcdir)
3278 AC_SUBST(archlibdir)
3279 AC_SUBST(docdir)
3280 AC_SUBST(bitmapdir)
3281 AC_SUBST(gamedir)
3282 AC_SUBST(gameuser)
3283 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3284 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3285 ## end of LIBX_BASE, but nothing ever set it.
3286 AC_SUBST(LD_SWITCH_X_SITE)
3287 AC_SUBST(C_SWITCH_X_SITE)
3288 AC_SUBST(GNUSTEP_CFLAGS)
3289 AC_SUBST(CFLAGS)
3290 ## Used in lwlib/Makefile.in.
3291 AC_SUBST(X_TOOLKIT_TYPE)
3292 if test -n "${machfile}"; then
3293   M_FILE="\$(srcdir)/${machfile}"
3294 else
3295   M_FILE=
3296 fi
3297 S_FILE="\$(srcdir)/${opsysfile}"
3298 AC_SUBST(M_FILE)
3299 AC_SUBST(S_FILE)
3300 AC_SUBST(ns_appdir)
3301 AC_SUBST(ns_appbindir)
3302 AC_SUBST(ns_appresdir)
3303 AC_SUBST(ns_appsrc)
3304 AC_SUBST(GNU_OBJC_CFLAGS)
3305 AC_SUBST(OTHER_FILES)
3306
3307 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3308                    [Define to the canonical Emacs configuration name.])
3309 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3310                    [Define to the options passed to configure.])
3311 if test -n "$machfile"; then
3312   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3313                      [Define to the used machine dependent file.])
3314 fi
3315 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3316                    [Define to the used os dependent file.])
3317
3318 XMENU_OBJ=
3319 XOBJ=
3320 FONT_OBJ=
3321 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3322   AC_DEFINE(HAVE_X_WINDOWS, 1,
3323             [Define to 1 if you want to use the X window system.])
3324   XMENU_OBJ=xmenu.o
3325   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3326   FONT_OBJ=xfont.o
3327   if test "$HAVE_XFT" = "yes"; then
3328     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3329   elif test "$HAVE_FREETYPE" = "yes"; then
3330     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3331   fi
3332   AC_SUBST(FONT_OBJ)
3333 fi
3334 AC_SUBST(XMENU_OBJ)
3335 AC_SUBST(XOBJ)
3336 AC_SUBST(FONT_OBJ)
3337
3338 WIDGET_OBJ=
3339 MOTIF_LIBW=
3340 if test "${USE_X_TOOLKIT}" != "none" ; then
3341   WIDGET_OBJ=widget.o
3342   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3343   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3344     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3345   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3346     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3347     MOTIF_LIBW=-lXm
3348     case "$opsys" in
3349       gnu-linux)
3350         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3351         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3352         ;;
3353
3354       unixware)
3355         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3356         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3357         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3358         ;;
3359
3360       aix4-2)
3361         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3362         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3363         ;;
3364     esac
3365     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3366   fi
3367 fi
3368 AC_SUBST(WIDGET_OBJ)
3369
3370 TOOLKIT_LIBW=
3371 case "$USE_X_TOOLKIT" in
3372   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3373   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3374   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3375 esac
3376 AC_SUBST(TOOLKIT_LIBW)
3377
3378 if test "$USE_X_TOOLKIT" = "none"; then
3379   LIBXT_OTHER="\$(LIBXSM)"
3380   OLDXMENU_TARGET="really-oldXMenu"
3381 else
3382   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3383   OLDXMENU_TARGET="really-lwlib"
3384 fi
3385 AC_SUBST(LIBXT_OTHER)
3386
3387 ## The X Menu stuff is present in the X10 distribution, but missing
3388 ## from X11.  If we have X10, just use the installed library;
3389 ## otherwise, use our own copy.
3390 if test "${HAVE_X11}" = "yes" ; then
3391   AC_DEFINE(HAVE_X11, 1,
3392             [Define to 1 if you want to use version 11 of X windows.
3393              Otherwise, Emacs expects to use version 10.])
3394
3395   if test "$USE_X_TOOLKIT" = "none"; then
3396     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3397   else
3398     OLDXMENU="\${lwlibdir}/liblw.a"
3399   fi
3400   LIBXMENU="\$(OLDXMENU)"
3401   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3402   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3403 else
3404   ## For a syntactically valid Makefile; not actually used for anything.
3405   ## See comments in src/Makefile.in.
3406   OLDXMENU=nothing
3407   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3408   if test "${HAVE_X_WINDOWS}" = "yes"; then
3409     LIBXMENU="-lXMenu"
3410   else
3411     LIBXMENU=
3412   fi
3413   LIBX_OTHER=
3414   OLDXMENU_DEPS=
3415 fi
3416
3417 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3418   OLDXMENU_TARGET=
3419   OLDXMENU=nothing
3420   LIBXMENU=
3421   OLDXMENU_DEPS=
3422 fi
3423
3424 AC_SUBST(OLDXMENU_TARGET)
3425 AC_SUBST(OLDXMENU)
3426 AC_SUBST(LIBXMENU)
3427 AC_SUBST(LIBX_OTHER)
3428 AC_SUBST(OLDXMENU_DEPS)
3429
3430 if test "${HAVE_MENUS}" = "yes" ; then
3431   AC_DEFINE(HAVE_MENUS, 1,
3432             [Define to 1 if you have mouse menus.
3433              (This is automatic if you use X, but the option to specify it remains.)
3434              It is also defined with other window systems that support xmenu.c.])
3435 fi
3436
3437 if test "${GNU_MALLOC}" = "yes" ; then
3438   AC_DEFINE(GNU_MALLOC, 1,
3439             [Define to 1 if you want to use the GNU memory allocator.])
3440 fi
3441
3442 RALLOC_OBJ=
3443 if test "${REL_ALLOC}" = "yes" ; then
3444   AC_DEFINE(REL_ALLOC, 1,
3445             [Define REL_ALLOC if you want to use the relocating allocator for
3446              buffer space.])
3447
3448   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3449 fi
3450 AC_SUBST(RALLOC_OBJ)
3451
3452 if test "$opsys" = "cygwin"; then
3453   CYGWIN_OBJ="sheap.o"
3454   ## Cygwin differs because of its unexec().
3455   PRE_ALLOC_OBJ=
3456   POST_ALLOC_OBJ=lastfile.o
3457 else
3458   CYGWIN_OBJ=
3459   PRE_ALLOC_OBJ=lastfile.o
3460   POST_ALLOC_OBJ=
3461 fi
3462 AC_SUBST(CYGWIN_OBJ)
3463 AC_SUBST(PRE_ALLOC_OBJ)
3464 AC_SUBST(POST_ALLOC_OBJ)
3465
3466 # Configure gnulib here, now that we know LIBS.
3467 gl_ASSERT_NO_GNULIB_POSIXCHECK
3468 gl_ASSERT_NO_GNULIB_TESTS
3469 gl_INIT
3470
3471 case "$opsys" in
3472   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3473
3474   darwin)
3475    ## The -headerpad option tells ld (see man page) to leave room at the
3476    ## end of the header for adding load commands.  Needed for dumping.
3477    ## 0x690 is the total size of 30 segment load commands (at 56
3478    ## each); under Cocoa 31 commands are required.
3479    if test "$HAVE_NS" = "yes"; then
3480      libs_nsgui="-framework AppKit"
3481      headerpad_extra=6C8
3482    else
3483      libs_nsgui=
3484      headerpad_extra=690
3485    fi
3486    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3487
3488    ## This is here because src/Makefile.in did some extra fiddling around
3489    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3490    ##   #ifndef LD_SWITCH_SYSTEM
3491    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3492    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3493    ## not using gcc, darwin system not on an alpha (ie darwin, since
3494    ## darwin + alpha does not occur).
3495    ## Because this was done in src/Makefile.in, the resulting part of
3496    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3497    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3498    ## rather than LD_SWITCH_SYSTEM.
3499    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3500      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3501    ;;
3502
3503   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3504   ## find X at run-time.
3505   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3506   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3507   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3508   ## had different values in configure (in ac_link) and src/Makefile.in.
3509   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3510   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3511
3512   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3513 esac
3514
3515 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3516   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3517 fi
3518
3519 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3520
3521
3522 LD_FIRSTFLAG=
3523 ORDINARY_LINK=
3524 case "$opsys" in
3525   ## gnu: GNU needs its own crt0.
3526   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3527
3528   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3529   ## library search parth, i.e. it won't search /usr/lib for libc and
3530   ## friends.  Using -nostartfiles instead avoids this problem, and
3531   ## will also work on earlier NetBSD releases.
3532   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3533
3534   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3535   ##   MkLinux/LinuxPPC needs this.
3536   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3537   gnu-*)
3538     case "$machine" in
3539       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3540     esac
3541     ;;
3542 esac
3543
3544
3545 if test "x$ORDINARY_LINK" = "xyes"; then
3546
3547   LD_FIRSTFLAG=""
3548   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3549
3550 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3551 ## freebsd, gnu-* not on macppc|ibms390x.
3552 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3553
3554   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3555   ## places that are difficult to figure out at make time.  Fortunately,
3556   ## these same versions allow you to pass arbitrary flags on to the
3557   ## linker, so there is no reason not to use it as a linker.
3558   ##
3559   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3560   ## searching for libraries in its internal directories, so we have to
3561   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3562   LD_FIRSTFLAG="-nostdlib"
3563 fi
3564
3565 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3566 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3567
3568 AC_SUBST(LD_FIRSTFLAG)
3569
3570
3571 ## FIXME? The logic here is not precisely the same as that above.
3572 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3573 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3574 LIB_GCC=
3575 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3576
3577   case "$opsys" in
3578     freebsd|netbsd|openbsd) LIB_GCC= ;;
3579
3580     gnu-*)
3581       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3582       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3583       case $host_cpu in
3584       arm*)
3585         LIB_GCC="-lgcc_s"
3586         ;;
3587       *)
3588         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3589         ## immediately undefine it again and redefine it to empty.
3590         ## Was the C_SWITCH_X_SITE part really necessary?
3591 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3592         LIB_GCC=
3593         ;;
3594       esac
3595       ;;
3596
3597     ## Ask GCC where to find libgcc.a.
3598     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3599   esac
3600 fi                              dnl if $GCC
3601 AC_SUBST(LIB_GCC)
3602
3603
3604 ## If we're using X11/GNUstep, define some consequences.
3605 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3606   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3607   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3608 fi
3609
3610
3611 AH_TOP([/* GNU Emacs site configuration template file.
3612
3613 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3614   Free Software Foundation, Inc.
3615
3616 This file is part of GNU Emacs.
3617
3618 GNU Emacs is free software: you can redistribute it and/or modify
3619 it under the terms of the GNU General Public License as published by
3620 the Free Software Foundation, either version 3 of the License, or
3621 (at your option) any later version.
3622
3623 GNU Emacs is distributed in the hope that it will be useful,
3624 but WITHOUT ANY WARRANTY; without even the implied warranty of
3625 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3626 GNU General Public License for more details.
3627
3628 You should have received a copy of the GNU General Public License
3629 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3630
3631
3632 /* No code in Emacs #includes config.h twice, but some bits of code
3633    intended to work with other packages as well (like gmalloc.c)
3634    think they can include it as many times as they like.  */
3635 #ifndef EMACS_CONFIG_H
3636 #define EMACS_CONFIG_H
3637 ])dnl
3638
3639 AH_BOTTOM([
3640 /* On AIX 3 this must be included before any other include file.  */
3641 #include <alloca.h>
3642 #if ! HAVE_ALLOCA
3643 # error "alloca not available on this machine"
3644 #endif
3645
3646 /* Define AMPERSAND_FULL_NAME if you use the convention
3647    that & in the full name stands for the login id.  */
3648 /* Turned on June 1996 supposing nobody will mind it.  */
3649 #define AMPERSAND_FULL_NAME
3650
3651 /* `subprocesses' should be defined if you want to
3652    have code for asynchronous subprocesses
3653    (as used in M-x compile and M-x shell).
3654    Only MSDOS does not support this (it overrides
3655    this in its config_opsysfile below).  */
3656
3657 #define subprocesses
3658
3659 /* Include the os and machine dependent files.  */
3660 #include config_opsysfile
3661 #ifdef config_machfile
3662 # include config_machfile
3663 #endif
3664
3665 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3666    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3667   (There is probably a better place to do this, but right now the
3668    Cocoa side does this in s/darwin.h and we cannot parallel this
3669    exactly since GNUstep is multi-OS.  */
3670 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3671 #  define SYSTEM_PURESIZE_EXTRA 30000
3672 #endif
3673
3674 #ifdef emacs /* Don't do this for lib-src.  */
3675 /* Tell regex.c to use a type compatible with Emacs.  */
3676 #define RE_TRANSLATE_TYPE Lisp_Object
3677 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3678 #ifdef make_number
3679 /* If make_number is a macro, use it.  */
3680 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3681 #else
3682 /* If make_number is a function, avoid it.  */
3683 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3684 #endif
3685 #endif
3686
3687 /* These default definitions are good for almost all machines.
3688    Any exceptions should override them in m/MACHINE.h.
3689    They must be usable in preprocessor conditionals.  */
3690
3691 #ifndef BITS_PER_CHAR
3692 #define BITS_PER_CHAR 8
3693 #endif
3694
3695 #ifndef BITS_PER_SHORT
3696 #define BITS_PER_SHORT 16
3697 #endif
3698
3699 #ifndef BITS_PER_INT
3700 #define BITS_PER_INT 32
3701 #endif
3702
3703 #ifndef BITS_PER_LONG
3704 #ifdef _LP64
3705 #define BITS_PER_LONG 64
3706 #else
3707 #define BITS_PER_LONG 32
3708 #endif
3709 #endif
3710
3711 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3712 #define BITS_PER_LONG_LONG 64
3713 #endif
3714
3715 /* Define if the compiler supports function prototypes.  It may do so but
3716    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3717 #undef PROTOTYPES
3718
3719 #include <string.h>
3720 #include <stdlib.h>
3721
3722 #if defined __GNUC__ && (__GNUC__ > 2 \
3723                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3724 #define NO_RETURN       __attribute__ ((__noreturn__))
3725 #else
3726 #define NO_RETURN       /* nothing */
3727 #endif
3728
3729 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3730 #define NO_INLINE __attribute__((noinline))
3731 #else
3732 #define NO_INLINE
3733 #endif
3734
3735 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3736 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3737 #else
3738 #define EXTERNALLY_VISIBLE
3739 #endif
3740
3741 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3742 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3743 #else
3744 # define ATTRIBUTE_FORMAT(spec) /* empty */
3745 #endif
3746
3747 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3748 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3749    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3750 #else
3751 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3752    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3753 #endif
3754
3755 /* Some versions of GNU/Linux define noinline in their headers.  */
3756 #ifdef noinline
3757 #undef noinline
3758 #endif
3759
3760 /* These won't be used automatically yet.  We also need to know, at least,
3761    that the stack is continuous.  */
3762 #ifdef __GNUC__
3763 #  ifndef GC_SETJMP_WORKS
3764   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3765 #    define GC_SETJMP_WORKS 1
3766 #  endif
3767 #endif
3768
3769 #endif /* EMACS_CONFIG_H */
3770
3771 /*
3772 Local Variables:
3773 mode: c
3774 End:
3775 */
3776 ])dnl
3777
3778 #### Report on what we decided to do.
3779 #### Report GTK as a toolkit, even if it doesn't use Xt.
3780 #### It makes printing result more understandable as using GTK sets
3781 #### toolkit_scroll_bars to yes by default.
3782 if test "${HAVE_GTK}" = "yes"; then
3783   USE_X_TOOLKIT=GTK
3784 fi
3785
3786 and_machfile=
3787 if test -n "$machfile"; then
3788   and_machfile=" and \`${machfile}'"
3789 fi
3790
3791 echo "
3792 Configured for \`${canonical}'.
3793
3794   Where should the build process find the source code?    ${srcdir}
3795   What operating system and machine description files should Emacs use?
3796         \`${opsysfile}'${and_machfile}
3797   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3798   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3799   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3800   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3801   What window system should Emacs use?                    ${window_system}
3802   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3803
3804 if test -n "${x_includes}"; then
3805 echo "  Where do we find X Windows header files?                ${x_includes}"
3806 else
3807 echo "  Where do we find X Windows header files?                Standard dirs"
3808 fi
3809 if test -n "${x_libraries}"; then
3810 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3811 else
3812 echo "  Where do we find X Windows libraries?                   Standard dirs"
3813 fi
3814
3815 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3816 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3817 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3818 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3819 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3820 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3821 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3822 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3823
3824 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3825 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3826 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3827 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3828 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3829 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3830 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3831
3832 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3833 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3834 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3835 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3836
3837 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3838 echo
3839
3840 if test -n "${EMACSDATA}"; then
3841    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3842 fi
3843 if test -n "${EMACSDOC}"; then
3844    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3845 fi
3846
3847 if test $USE_XASSERTS = yes; then
3848    echo "  Compiling with asserts turned on."
3849    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3850 fi
3851
3852 echo
3853
3854 if test "$HAVE_NS" = "yes"; then
3855    echo
3856    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3857 The installed application will go to nextstep/Emacs.app and can be
3858 run or moved from there."
3859    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3860       echo "The application will be fully self-contained."
3861     else
3862       echo "The lisp resources for the application will be installed under ${prefix}.
3863 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3864 to run if these resources are not installed."
3865    fi
3866    echo
3867 fi
3868
3869 if test "${opsys}" = "cygwin"; then
3870   case `uname -r` in
3871     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3872            echo
3873            ;;
3874   esac
3875 fi
3876
3877 # Remove any trailing slashes in these variables.
3878 [test "${prefix}" != NONE &&
3879   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3880 test "${exec_prefix}" != NONE &&
3881   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3882
3883 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3884 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3885 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3886 dnl (else you get "no `Makefile.am' found for any configure output").
3887 dnl This will work, but you get a config.status that is not quite right
3888 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3889 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3890 dnl it seems better to just live with the duplication.
3891 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3892
3893 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3894        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3895        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3896        leim/Makefile])
3897
3898 dnl test/ is not present in release tarfiles.
3899 opt_makefile=test/automated/Makefile
3900
3901 if test -f $srcdir/${opt_makefile}.in; then
3902   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3903   dnl Again, it's best not to use a variable.  Though you can add
3904   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3905   AC_CONFIG_FILES([test/automated/Makefile])
3906 fi
3907
3908
3909 dnl admin/ may or may not be present.
3910 opt_makefile=admin/unidata/Makefile
3911
3912 if test -f $srcdir/${opt_makefile}.in; then
3913   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3914   AC_CONFIG_FILES([admin/unidata/Makefile])
3915 fi
3916
3917
3918 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3919
3920 AC_SUBST(SUBDIR_MAKEFILES_IN)
3921
3922 dnl Make the necessary directories, if they don't exist.
3923 AC_CONFIG_COMMANDS([mkdirs], [
3924 for dir in etc lisp ; do
3925   test -d ${dir} || mkdir ${dir}
3926 done
3927 ])
3928
3929 dnl You might wonder (I did) why epaths.h is generated by running make,
3930 dnl rather than just letting configure generate it from epaths.in.
3931 dnl One reason is that the various paths are not fully expanded (see above);
3932 dnl eg gamedir=${prefix}/var/games/emacs.
3933 dnl Secondly, the GNU Coding standards require that one should be able
3934 dnl to run `make prefix=/some/where/else' and override the values set
3935 dnl by configure.  This also explains the `move-if-change' test and
3936 dnl the use of force in the `epaths-force' rule in Makefile.in.
3937 AC_CONFIG_COMMANDS([epaths], [
3938 echo creating src/epaths.h
3939 ${MAKE-make} epaths-force
3940 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3941
3942 AC_CONFIG_COMMANDS([gdbinit], [
3943 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3944   echo creating src/.gdbinit
3945   echo source $srcdir/src/.gdbinit > src/.gdbinit
3946 fi
3947 ])
3948
3949 AC_OUTPUT
3950
3951 dnl configure.in ends here