lisp/gnus/mm-encode.el

   1 ;;; mm-encode.el --- Functions for encoding MIME things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29 (require 'mail-parse)
  30 (require 'mailcap)
  31 (eval-and-compile
  32   (autoload 'mm-body-7-or-8 "mm-bodies")
  33   (autoload 'mm-long-lines-p "mm-bodies"))
  34
  35 (defcustom mm-content-transfer-encoding-defaults
  36   '(("text/x-patch" 8bit)
  37     ("text/.*" qp-or-base64)
  38     ("message/rfc822" 8bit)
  39     ("application/emacs-lisp" qp-or-base64)
  40     ("application/x-emacs-lisp" qp-or-base64)
  41     ("application/x-patch" qp-or-base64)
  42     (".*" base64))
  43   "Alist of regexps that match MIME types and their encodings.
  44 If the encoding is `qp-or-base64', then either quoted-printable
  45 or base64 will be used, depending on what is more efficient.
  46
  47 `qp-or-base64' has another effect.  It will fold long lines so that
  48 MIME parts may not be broken by MTA.  So do `quoted-printable' and
  49 `base64'.
  50
  51 Note: It affects body encoding only when a part is a raw forwarded
  52 message (which will be made by `gnus-summary-mail-forward' with the
  53 arg 2 for example) or is neither the text/* type nor the message/*
  54 type.  Even though in those cases, you can use the `encoding' MML tag
  55 to specify encoding of non-ASCII MIME parts."
  56   :type '(repeat (list (regexp :tag "MIME type")
  57                        (choice :tag "encoding"
  58                                (const 7bit)
  59                                (const 8bit)
  60                                (const qp-or-base64)
  61                                (const quoted-printable)
  62                                (const base64))))
  63   :group 'mime)
  64
  65 (defvar mm-use-ultra-safe-encoding nil
  66   "If non-nil, use encodings aimed at Procrustean bed survival.
  67
  68 This means that textual parts are encoded as quoted-printable if they
  69 contain lines longer than 76 characters or starting with \"From \" in
  70 the body.  Non-7bit encodings (8bit, binary) are generally disallowed.
  71 This is to reduce the probability that a broken MTA or MDA changes the
  72 message.
  73
  74 This variable should never be set directly, but bound before a call to
  75 `mml-generate-mime' or similar functions.")
  76
  77 (defun mm-insert-rfc822-headers (charset encoding)
  78   "Insert text/plain headers with CHARSET and ENCODING."
  79   (insert "MIME-Version: 1.0\n")
  80   (insert "Content-Type: text/plain; charset="
  81           (mail-quote-string (downcase (symbol-name charset))) "\n")
  82   (insert "Content-Transfer-Encoding: "
  83           (downcase (symbol-name encoding)) "\n"))
  84
  85 (defun mm-insert-multipart-headers ()
  86   "Insert multipart/mixed headers."
  87   (let ((boundary "=-=-="))
  88     (insert "MIME-Version: 1.0\n")
  89     (insert "Content-Type: multipart/mixed; boundary=\"" boundary "\"\n")
  90     boundary))
  91
  92 (defun mm-default-file-encoding (file)
  93   "Return a default encoding for FILE."
  94   (if (not (string-match "\\.[^.]+$" file))
  95       "application/octet-stream"
  96     (mailcap-extension-to-mime (match-string 0 file))))
  97
  98 (defun mm-safer-encoding (encoding)
  99   "Return an encoding similar to ENCODING but safer than it."
 100   (cond
 101    ((eq encoding '7bit) '7bit) ;; 7bit is considered safe.
 102    ((memq encoding '(8bit quoted-printable)) 'quoted-printable)
 103    ;; The remaining encodings are binary and base64 (and perhaps some
 104    ;; non-standard ones), which are both turned into base64.
 105    (t 'base64)))
 106
 107 (defun mm-encode-content-transfer-encoding (encoding &optional type)
 108   "Encode the current buffer with ENCODING for MIME type TYPE.
 109 ENCODING can be: nil (do nothing); one of `quoted-printable', `base64';
 110 `7bit', `8bit' or `binary' (all do nothing); a function to do the encoding."
 111   (cond
 112    ((eq encoding 'quoted-printable)
 113     ;; This used to try to make a multibyte buffer unibyte.  That's
 114     ;; completely wrong, since you'd get QP-encoded emacs-mule.  If
 115     ;; this gets run on multibyte text it's an error that needs
 116     ;; fixing, and the encoding function will signal an error.
 117     ;; Likewise base64 below.
 118     (quoted-printable-encode-region (point-min) (point-max) t))
 119    ((eq encoding 'base64)
 120     (when (equal type "text/plain")
 121       (goto-char (point-min))
 122       (while (search-forward "\n" nil t)
 123         (replace-match "\r\n" t t)))
 124     (base64-encode-region (point-min) (point-max)))
 125    ((memq encoding '(7bit 8bit binary))
 126     ;; Do nothing.
 127     )
 128    ((null encoding)
 129     ;; Do nothing.
 130     )
 131    ;; Fixme: Ignoring errors here looks bogus.
 132    ((functionp encoding)
 133     (ignore-errors (funcall encoding (point-min) (point-max))))
 134    (t
 135     (error "Unknown encoding %s" encoding))))
 136
 137 (defun mm-encode-buffer (type)
 138   "Encode the buffer which contains data of MIME type TYPE.
 139 TYPE is a string or a list of the components.
 140 The encoding used is returned."
 141   (let* ((mime-type (if (stringp type) type (car type)))
 142          (encoding
 143           (or (and (listp type)
 144                    (cadr (assq 'encoding type)))
 145               (mm-content-transfer-encoding mime-type)))
 146          (bits (mm-body-7-or-8)))
 147     ;; We force buffers that are 7bit to be unencoded, no matter
 148     ;; what the preferred encoding is.
 149     ;; Only if the buffers don't contain lone lines.
 150     (when (and (eq bits '7bit) (not (mm-long-lines-p 76)))
 151       (setq encoding bits))
 152     (mm-encode-content-transfer-encoding encoding mime-type)
 153     encoding))
 154
 155 (defun mm-insert-headers (type encoding &optional file)
 156   "Insert headers for TYPE."
 157   (insert "Content-Type: " type)
 158   (when file
 159     (insert ";\n\tname=\"" (file-name-nondirectory file) "\""))
 160   (insert "\n")
 161   (insert (format "Content-Transfer-Encoding: %s\n" encoding))
 162   (insert "Content-Disposition: inline")
 163   (when file
 164     (insert ";\n\tfilename=\"" (file-name-nondirectory file) "\""))
 165   (insert "\n")
 166   (insert "\n"))
 167
 168 (defun mm-content-transfer-encoding (type)
 169   "Return a CTE suitable for TYPE to encode the current buffer."
 170   (let ((rules mm-content-transfer-encoding-defaults))
 171     (catch 'found
 172       (while rules
 173         (when (string-match (caar rules) type)
 174           (throw 'found
 175                  (let ((encoding
 176                         (if (eq (cadr (car rules)) 'qp-or-base64)
 177                             (mm-qp-or-base64)
 178                           (cadr (car rules)))))
 179                    (if mm-use-ultra-safe-encoding
 180                        (mm-safer-encoding encoding)
 181                      encoding))))
 182         (pop rules)))))
 183
 184 (defun mm-qp-or-base64 ()
 185   "Return the type with which to encode the buffer.
 186 This is either `base64' or `quoted-printable'."
 187   (if (equal mm-use-ultra-safe-encoding '(sign . "pgp"))
 188       ;; perhaps not always accurate?
 189       'quoted-printable
 190     (save-excursion
 191       (let ((limit (min (point-max) (+ 2000 (point-min))))
 192             (n8bit 0))
 193         (goto-char (point-min))
 194         (skip-chars-forward "\x20-\x7f\r\n\t" limit)
 195         (while (< (point) limit)
 196           (incf n8bit)
 197           (forward-char 1)
 198           (skip-chars-forward "\x20-\x7f\r\n\t" limit))
 199         (if (or (< (* 6 n8bit) (- limit (point-min)))
 200                 ;; Don't base64, say, a short line with a single
 201                 ;; non-ASCII char when splitting parts by charset.
 202                 (= n8bit 1))
 203             'quoted-printable
 204           'base64)))))
 205
 206 (provide 'mm-encode)
 207
 208 ;;; arch-tag: 7d01bba4-d469-4851-952b-dc863f84ed66
 209 ;;; mm-encode.el ends here