lisp/net/tramp-gvfs.el

   1 ;;; tramp-gvfs.el --- Tramp access functions for GVFS daemon
   2
   3 ;; Copyright (C) 2009 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Albinus <michael.albinus@gmx.de>
   6 ;; Keywords: comm, processes
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Access functions for the GVFS daemon from Tramp.  Tested with GVFS
  26 ;; 1.0.2 (Ubuntu 8.10, Gnome 2.24).  It has been reported also to run
  27 ;; with GVFS 0.2.5 (Ubuntu 8.04, Gnome 2.22), but there is an
  28 ;; incompatibility with the mount_info structure, which has been
  29 ;; worked around.
  30
  31 ;; All actions to mount a remote location, and to retrieve mount
  32 ;; information, are performed by D-Bus messages.  File operations
  33 ;; themselves are performed via the mounted filesystem in ~/.gvfs.
  34 ;; Consequently, GNU Emacs 23.1 with enabled D-Bus bindings is a
  35 ;; precondition.
  36
  37 ;; The GVFS D-Bus interface is said to be instable.  There are even no
  38 ;; introspection data.  The interface, as discovered during
  39 ;; development time, is given in respective comments.
  40
  41 ;; The customer option `tramp-gvfs-methods' contains the list of
  42 ;; supported connection methods.  Per default, these are "dav",
  43 ;; "davs", "obex" and "synce".  Note that with "obex" it might be
  44 ;; necessary to pair with the other bluetooth device, if it hasn't
  45 ;; been done already.  There might be also some few seconds delay in
  46 ;; discovering available bluetooth devices.
  47
  48 ;; Other possible connection methods are "ftp", "sftp" and "smb".
  49 ;; When one of these methods is added to the list, the remote access
  50 ;; for that method is performed via GVFS instead of the native Tramp
  51 ;; implementation.
  52
  53 ;; GVFS offers even more connection methods.  The complete list of
  54 ;; connection methods of the actual GVFS implementation can be
  55 ;; retrieved by:
  56 ;;
  57 ;; (message
  58 ;;  "%s"
  59 ;;  (mapcar
  60 ;;   'car
  61 ;;   (dbus-call-method
  62 ;;    :session tramp-gvfs-service-daemon tramp-gvfs-path-mounttracker
  63 ;;    tramp-gvfs-interface-mounttracker "listMountableInfo")))
  64
  65 ;; Note that all other connection methods are not tested, beside the
  66 ;; ones offered for customization in `tramp-gvfs-methods'.  If you
  67 ;; request an additional connection method to be supported, please
  68 ;; drop me a note.
  69
  70 ;; For hostname completion, information is retrieved either from the
  71 ;; bluez daemon (for the "obex" method), the hal daemon (for the
  72 ;; "synce" method), or from the zeroconf daemon (for the "dav",
  73 ;; "davs", and "sftp" methods).  The zeroconf daemon is pre-configured
  74 ;; to discover services in the "local" domain.  If another domain
  75 ;; shall be used for discovering services, the customer option
  76 ;; `tramp-gvfs-zeroconf-domain' can be set accordingly.
  77
  78 ;; Restrictions:
  79
  80 ;; * The current GVFS implementation does not allow to write on the
  81 ;;   remote bluetooth device via OBEX.
  82 ;;
  83 ;; * Two shares of the same SMB server cannot be mounted in parallel.
  84
  85 ;;; Code:
  86
  87 ;; D-Bus support in the Emacs core can be disabled with configuration
  88 ;; option "--without-dbus".  Declare used subroutines and variables.
  89 (declare-function dbus-call-method "dbusbind.c")
  90 (declare-function dbus-call-method-asynchronously "dbusbind.c")
  91 (declare-function dbus-get-unique-name "dbusbind.c")
  92 (declare-function dbus-register-method "dbusbind.c")
  93 (declare-function dbus-register-signal "dbusbind.c")
  94
  95 ;; Pacify byte-compiler
  96 (eval-when-compile
  97   (require 'cl)
  98   (require 'custom))
  99
 100 (require 'tramp)
 101 (require 'dbus)
 102 (require 'url-parse)
 103 (require 'zeroconf)
 104
 105 (defcustom tramp-gvfs-methods '("dav" "davs" "obex" "synce")
 106   "*List of methods for remote files, accessed with GVFS."
 107   :group 'tramp
 108   :version "23.2"
 109   :type '(repeat (choice (const "dav")
 110                          (const "davs")
 111                          (const "ftp")
 112                          (const "obex")
 113                          (const "sftp")
 114                          (const "smb")
 115                          (const "synce"))))
 116
 117 ;; Add a default for `tramp-default-user-alist'.  Rule: For the SYNCE
 118 ;; method, no user is chosen.
 119 (add-to-list 'tramp-default-user-alist
 120              '("synce" nil nil))
 121
 122 (defcustom tramp-gvfs-zeroconf-domain "local"
 123   "*Zeroconf domain to be used for discovering services, like host names."
 124   :group 'tramp
 125   :version "23.2"
 126   :type 'string)
 127
 128 ;; Add the methods to `tramp-methods', in order to allow minibuffer
 129 ;; completion.
 130 (eval-after-load "tramp-gvfs"
 131   '(when (featurep 'tramp-gvfs)
 132      (dolist (elt tramp-gvfs-methods)
 133        (unless (assoc elt tramp-methods)
 134          (add-to-list 'tramp-methods (cons elt nil))))))
 135
 136 (defconst tramp-gvfs-mount-point
 137   (file-name-as-directory (expand-file-name ".gvfs" "~/"))
 138   "The directory name, fuses mounts remote ressources.")
 139
 140 (defconst tramp-gvfs-path-tramp (concat dbus-path-emacs "/Tramp")
 141   "The preceeding object path for own objects.")
 142
 143 (defconst tramp-gvfs-service-daemon "org.gtk.vfs.Daemon"
 144   "The well known name of the GVFS daemon.")
 145
 146 ;; Check that GVFS is available.
 147 (unless (dbus-ping :session tramp-gvfs-service-daemon)
 148   (throw 'tramp-loading nil))
 149
 150 (defconst tramp-gvfs-path-mounttracker "/org/gtk/vfs/mounttracker"
 151   "The object path of the GVFS daemon.")
 152
 153 (defconst tramp-gvfs-interface-mounttracker "org.gtk.vfs.MountTracker"
 154   "The mount tracking interface in the GVFS daemon.")
 155
 156 ;; <interface name='org.gtk.vfs.MountTracker'>
 157 ;;   <method name='listMounts'>
 158 ;;     <arg name='mount_info_list'
 159 ;;          type='a{sosssssbay{aya{say}}}'
 160 ;;          direction='out'/>
 161 ;;   </method>
 162 ;;   <method name='mountLocation'>
 163 ;;     <arg name='mount_spec'  type='{aya{say}}' direction='in'/>
 164 ;;     <arg name='dbus_id'     type='s'          direction='in'/>
 165 ;;     <arg name='object_path' type='o'          direction='in'/>
 166 ;;   </method>
 167 ;;   <signal name='mounted'>
 168 ;;     <arg name='mount_info'
 169 ;;          type='{sosssssbay{aya{say}}}'/>
 170 ;;   </signal>
 171 ;;   <signal name='unmounted'>
 172 ;;     <arg name='mount_info'
 173 ;;          type='{sosssssbay{aya{say}}}'/>
 174 ;;   </signal>
 175 ;; </interface>
 176 ;;
 177 ;; STRUCT               mount_info
 178 ;;   STRING               dbus_id
 179 ;;   OBJECT_PATH          object_path
 180 ;;   STRING               display_name
 181 ;;   STRING               stable_name
 182 ;;   STRING               x_content_types       Since GVFS 1.0 only !!!
 183 ;;   STRING               icon
 184 ;;   STRING               prefered_filename_encoding
 185 ;;   BOOLEAN              user_visible
 186 ;;   ARRAY BYTE           fuse_mountpoint
 187 ;;   STRUCT               mount_spec
 188 ;;     ARRAY BYTE           mount_prefix
 189 ;;     ARRAY
 190 ;;       STRUCT             mount_spec_item
 191 ;;         STRING             key (server, share, type, user, host, port)
 192 ;;         ARRAY BYTE         value
 193
 194 (defconst tramp-gvfs-interface-mountoperation "org.gtk.vfs.MountOperation"
 195   "Used by the dbus-proxying implementation of GMountOperation.")
 196
 197 ;; <interface name='org.gtk.vfs.MountOperation'>
 198 ;;   <method name='askPassword'>
 199 ;;     <arg name='message' type='s'  direction='in'/>
 200 ;;     <arg name='default_user'   type='s' direction='in'/>
 201 ;;     <arg name='default_domain' type='s' direction='in'/>
 202 ;;     <arg name='flags'          type='u' direction='in'/>
 203 ;;     <arg name='handled'        type='b' direction='out'/>
 204 ;;     <arg name='aborted'        type='b' direction='out'/>
 205 ;;     <arg name='password'       type='s' direction='out'/>
 206 ;;     <arg name='username'       type='s' direction='out'/>
 207 ;;     <arg name='domain'         type='s' direction='out'/>
 208 ;;     <arg name='anonymous'      type='b' direction='out'/>
 209 ;;     <arg name='password_save'  type='u' direction='out'/>
 210 ;;   </method>
 211 ;;   <method name='askQuestion'>
 212 ;;     <arg name='message' type='s'  direction='in'/>
 213 ;;     <arg name='choices' type='as' direction='in'/>
 214 ;;     <arg name='handled' type='b'  direction='out'/>
 215 ;;     <arg name='aborted' type='b'  direction='out'/>
 216 ;;     <arg name='choice'  type='u'  direction='out'/>
 217 ;;   </method>
 218 ;; </interface>
 219
 220 ;; The following flags are used in "askPassword".  They are defined in
 221 ;; /usr/include/glib-2.0/gio/gioenums.h.
 222
 223 (defconst tramp-gvfs-password-need-password 1
 224   "Operation requires a password.")
 225
 226 (defconst tramp-gvfs-password-need-username 2
 227   "Operation requires a username.")
 228
 229 (defconst tramp-gvfs-password-need-domain 4
 230   "Operation requires a domain.")
 231
 232 (defconst tramp-gvfs-password-saving-supported 8
 233   "Operation supports saving settings.")
 234
 235 (defconst tramp-gvfs-password-anonymous-supported 16
 236   "Operation supports anonymous users.")
 237
 238 (defconst tramp-bluez-service "org.bluez"
 239   "The well known name of the BLUEZ service.")
 240
 241 (defconst tramp-bluez-interface-manager "org.bluez.Manager"
 242   "The manager interface of the BLUEZ daemon.")
 243
 244 ;; <interface name='org.bluez.Manager'>
 245 ;;   <method name='DefaultAdapter'>
 246 ;;     <arg type='o' direction='out'/>
 247 ;;   </method>
 248 ;;   <method name='FindAdapter'>
 249 ;;     <arg type='s' direction='in'/>
 250 ;;     <arg type='o' direction='out'/>
 251 ;;   </method>
 252 ;;   <method name='ListAdapters'>
 253 ;;     <arg type='ao' direction='out'/>
 254 ;;   </method>
 255 ;;   <signal name='AdapterAdded'>
 256 ;;     <arg type='o'/>
 257 ;;   </signal>
 258 ;;   <signal name='AdapterRemoved'>
 259 ;;     <arg type='o'/>
 260 ;;   </signal>
 261 ;;   <signal name='DefaultAdapterChanged'>
 262 ;;     <arg type='o'/>
 263 ;;   </signal>
 264 ;; </interface>
 265
 266 (defconst tramp-bluez-interface-adapter "org.bluez.Adapter"
 267   "The adapter interface of the BLUEZ daemon.")
 268
 269 ;; <interface name='org.bluez.Adapter'>
 270 ;;   <method name='GetProperties'>
 271 ;;     <arg type='a{sv}' direction='out'/>
 272 ;;   </method>
 273 ;;   <method name='SetProperty'>
 274 ;;     <arg type='s' direction='in'/>
 275 ;;     <arg type='v' direction='in'/>
 276 ;;   </method>
 277 ;;   <method name='RequestMode'>
 278 ;;     <arg type='s' direction='in'/>
 279 ;;   </method>
 280 ;;   <method name='ReleaseMode'/>
 281 ;;   <method name='RequestSession'/>
 282 ;;   <method name='ReleaseSession'/>
 283 ;;   <method name='StartDiscovery'/>
 284 ;;   <method name='StopDiscovery'/>
 285 ;;   <method name='ListDevices'>
 286 ;;     <arg type='ao' direction='out'/>
 287 ;;   </method>
 288 ;;   <method name='CreateDevice'>
 289 ;;     <arg type='s' direction='in'/>
 290 ;;     <arg type='o' direction='out'/>
 291 ;;   </method>
 292 ;;   <method name='CreatePairedDevice'>
 293 ;;     <arg type='s' direction='in'/>
 294 ;;     <arg type='o' direction='in'/>
 295 ;;     <arg type='s' direction='in'/>
 296 ;;     <arg type='o' direction='out'/>
 297 ;;   </method>
 298 ;;   <method name='CancelDeviceCreation'>
 299 ;;     <arg type='s' direction='in'/>
 300 ;;   </method>
 301 ;;   <method name='RemoveDevice'>
 302 ;;     <arg type='o' direction='in'/>
 303 ;;   </method>
 304 ;;   <method name='FindDevice'>
 305 ;;     <arg type='s' direction='in'/>
 306 ;;     <arg type='o' direction='out'/>
 307 ;;   </method>
 308 ;;   <method name='RegisterAgent'>
 309 ;;     <arg type='o' direction='in'/>
 310 ;;     <arg type='s' direction='in'/>
 311 ;;   </method>
 312 ;;   <method name='UnregisterAgent'>
 313 ;;     <arg type='o' direction='in'/>
 314 ;;   </method>
 315 ;;   <signal name='DeviceCreated'>
 316 ;;     <arg type='o'/>
 317 ;;   </signal>
 318 ;;   <signal name='DeviceRemoved'>
 319 ;;     <arg type='o'/>
 320 ;;   </signal>
 321 ;;   <signal name='DeviceFound'>
 322 ;;     <arg type='s'/>
 323 ;;     <arg type='a{sv}'/>
 324 ;;   </signal>
 325 ;;   <signal name='PropertyChanged'>
 326 ;;     <arg type='s'/>
 327 ;;     <arg type='v'/>
 328 ;;   </signal>
 329 ;;   <signal name='DeviceDisappeared'>
 330 ;;     <arg type='s'/>
 331 ;;   </signal>
 332 ;; </interface>
 333
 334 (defcustom tramp-bluez-discover-devices-timeout 60
 335   "Defines seconds since last bluetooth device discovery before rescanning.
 336 A value of 0 would require an immediate discovery during hostname
 337 completion, nil means to use always cached values for discovered
 338 devices."
 339   :group 'tramp
 340   :version "23.2"
 341   :type '(choice (const nil) integer))
 342
 343 (defvar tramp-bluez-discovery nil
 344   "Indicator for a running bluetooth device discovery.
 345 It keeps the timestamp of last discovery.")
 346
 347 (defvar tramp-bluez-devices nil
 348   "Alist of detected bluetooth devices.
 349 Every entry is a list (NAME ADDRESS).")
 350
 351 (defconst tramp-hal-service "org.freedesktop.Hal"
 352   "The well known name of the HAL service.")
 353
 354 (defconst tramp-hal-path-manager "/org/freedesktop/Hal/Manager"
 355   "The object path of the HAL daemon manager.")
 356
 357 (defconst tramp-hal-interface-manager "org.freedesktop.Hal.Manager"
 358   "The manager interface of the HAL daemon.")
 359
 360 (defconst tramp-hal-interface-device "org.freedesktop.Hal.Device"
 361   "The device interface of the HAL daemon.")
 362
 363 \f
 364 ;; New handlers should be added here.
 365 (defconst tramp-gvfs-file-name-handler-alist
 366   '(
 367     (access-file . ignore)
 368     (add-name-to-file . tramp-gvfs-handle-copy-file)
 369     ;; `byte-compiler-base-file-name' performed by default handler.
 370     (copy-file . tramp-gvfs-handle-copy-file)
 371     (delete-directory . tramp-gvfs-handle-delete-directory)
 372     (delete-file . tramp-gvfs-handle-delete-file)
 373     ;; `diff-latest-backup-file' performed by default handler.
 374     (directory-file-name . tramp-handle-directory-file-name)
 375     (directory-files . tramp-gvfs-handle-directory-files)
 376     (directory-files-and-attributes
 377      . tramp-gvfs-handle-directory-files-and-attributes)
 378     (dired-call-process . ignore)
 379     (dired-compress-file . ignore)
 380     (dired-uncache . tramp-handle-dired-uncache)
 381     ;; `executable-find' is not official yet. performed by default handler.
 382     (expand-file-name . tramp-gvfs-handle-expand-file-name)
 383     ;; `file-accessible-directory-p' performed by default handler.
 384     (file-attributes . tramp-gvfs-handle-file-attributes)
 385     (file-directory-p . tramp-smb-handle-file-directory-p)
 386     (file-executable-p . tramp-gvfs-handle-file-executable-p)
 387     (file-exists-p . tramp-gvfs-handle-file-exists-p)
 388     (file-local-copy . tramp-gvfs-handle-file-local-copy)
 389     (file-remote-p . tramp-handle-file-remote-p)
 390     ;; `file-modes' performed by default handler.
 391     (file-name-all-completions . tramp-gvfs-handle-file-name-all-completions)
 392     (file-name-as-directory . tramp-handle-file-name-as-directory)
 393     (file-name-completion . tramp-handle-file-name-completion)
 394     (file-name-directory . tramp-handle-file-name-directory)
 395     (file-name-nondirectory . tramp-handle-file-name-nondirectory)
 396     ;; `file-name-sans-versions' performed by default handler.
 397     (file-newer-than-file-p . tramp-handle-file-newer-than-file-p)
 398     (file-ownership-preserved-p . ignore)
 399     (file-readable-p . tramp-gvfs-handle-file-readable-p)
 400     (file-regular-p . tramp-handle-file-regular-p)
 401     (file-symlink-p . tramp-handle-file-symlink-p)
 402     ;; `file-truename' performed by default handler.
 403     (file-writable-p . tramp-gvfs-handle-file-writable-p)
 404     (find-backup-file-name . tramp-handle-find-backup-file-name)
 405     ;; `find-file-noselect' performed by default handler.
 406     ;; `get-file-buffer' performed by default handler.
 407     (insert-directory . tramp-gvfs-handle-insert-directory)
 408     (insert-file-contents . tramp-gvfs-handle-insert-file-contents)
 409     (load . tramp-handle-load)
 410     (make-directory . tramp-gvfs-handle-make-directory)
 411     (make-directory-internal . ignore)
 412     (make-symbolic-link . ignore)
 413     (process-file . tramp-gvfs-handle-process-file)
 414     (rename-file . tramp-gvfs-handle-rename-file)
 415     (set-file-modes . tramp-gvfs-handle-set-file-modes)
 416     (set-visited-file-modtime . tramp-gvfs-handle-set-visited-file-modtime)
 417     (shell-command . tramp-gvfs-handle-shell-command)
 418     (start-file-process . tramp-gvfs-handle-start-file-process)
 419     (substitute-in-file-name . tramp-handle-substitute-in-file-name)
 420     (unhandled-file-name-directory . tramp-handle-unhandled-file-name-directory)
 421     (vc-registered . ignore)
 422     (verify-visited-file-modtime
 423      . tramp-gvfs-handle-verify-visited-file-modtime)
 424     (write-region . tramp-gvfs-handle-write-region)
 425 )
 426   "Alist of handler functions for Tramp GVFS method.
 427 Operations not mentioned here will be handled by the default Emacs primitives.")
 428
 429 (defun tramp-gvfs-file-name-p (filename)
 430   "Check if it's a filename handled by the GVFS daemon."
 431   (and (tramp-tramp-file-p filename)
 432        (let ((method
 433               (tramp-file-name-method (tramp-dissect-file-name filename))))
 434          (and (stringp method) (member method tramp-gvfs-methods)))))
 435
 436 (defun tramp-gvfs-file-name-handler (operation &rest args)
 437   "Invoke the GVFS related OPERATION.
 438 First arg specifies the OPERATION, second arg is a list of arguments to
 439 pass to the OPERATION."
 440   (let ((fn (assoc operation tramp-gvfs-file-name-handler-alist)))
 441     (if fn
 442         (save-match-data (apply (cdr fn) args))
 443       (tramp-run-real-handler operation args))))
 444
 445 ;; This might be moved to tramp.el.  It shall be the first file name
 446 ;; handler.
 447 (add-to-list 'tramp-foreign-file-name-handler-alist
 448              (cons 'tramp-gvfs-file-name-p 'tramp-gvfs-file-name-handler))
 449
 450 (defmacro with-tramp-dbus-call-method
 451   (vec synchronous bus service path interface method &rest args)
 452   "Apply a D-Bus call on bus BUS.
 453
 454 If SYNCHRONOUS is non-nil, the call is synchronously.  Otherwise,
 455 it is an asynchronous call, with `ignore' as callback function.
 456
 457 The other arguments have the same meaning as with `dbus-call-method'
 458 or `dbus-call-method-asynchronously'.  Additionally, the call
 459 will be traced by Tramp with trace level 6."
 460   `(let ((func (if ,synchronous
 461                    'dbus-call-method 'dbus-call-method-asynchronously))
 462          (args (append (list ,bus ,service ,path ,interface ,method)
 463                        (if ,synchronous (list ,@args) (list 'ignore ,@args))))
 464          result)
 465      (tramp-message ,vec 6 "%s %s" func args)
 466      (setq result (apply func args))
 467      (tramp-message ,vec 6 "\n%s" result)
 468      result))
 469
 470 (put 'with-tramp-dbus-call-method 'lisp-indent-function 2)
 471 (put 'with-tramp-dbus-call-method 'edebug-form-spec '(form symbolp body))
 472 (font-lock-add-keywords 'emacs-lisp-mode '("\\<with-tramp-dbus-call-method\\>"))
 473
 474 (defmacro with-tramp-gvfs-error-message (filename handler &rest args)
 475   "Apply a Tramp GVFS `handler'.
 476 In case of an error, modify the error message by replacing
 477 `filename' with its GVFS mounted name."
 478   `(let ((fuse-file-name  (regexp-quote (tramp-gvfs-fuse-file-name ,filename)))
 479          elt)
 480      (condition-case err
 481          (apply ,handler (list ,@args))
 482        (error
 483         (setq elt (cdr err))
 484         (while elt
 485           (when (and (stringp (car elt))
 486                      (string-match fuse-file-name (car elt)))
 487             (setcar elt (replace-match ,filename t t (car elt))))
 488           (setq elt (cdr elt)))
 489         (signal (car err) (cdr err))))))
 490
 491 (put 'with-tramp-gvfs-error-message 'lisp-indent-function 2)
 492 (put 'with-tramp-gvfs-error-message 'edebug-form-spec '(form symbolp body))
 493 (font-lock-add-keywords 'emacs-lisp-mode '("\\<with-tramp-gvfs-error-message\\>"))
 494
 495 (defvar tramp-gvfs-dbus-event-vector nil
 496   "Current Tramp file name to be used, as vector.
 497 It is needed when D-Bus signals or errors arrive, because there
 498 is no information where to trace the message.")
 499
 500 (defun tramp-gvfs-dbus-event-error (event err)
 501   "Called when a D-Bus error message arrives, see `dbus-event-error-hooks'."
 502 ;  (tramp-cleanup-connection tramp-gvfs-dbus-event-vector)
 503   (tramp-message tramp-gvfs-dbus-event-vector 1 "%S" event)
 504   (tramp-error tramp-gvfs-dbus-event-vector 'file-error "%s" (cadr err)))
 505
 506 (add-hook 'dbus-event-error-hooks 'tramp-gvfs-dbus-event-error)
 507
 508 \f
 509 ;; File name primitives.
 510
 511 (defun tramp-gvfs-handle-copy-file
 512   (filename newname &optional ok-if-already-exists keep-date preserve-uid-gid)
 513   "Like `copy-file' for Tramp files."
 514   (copy-file
 515    (if (tramp-gvfs-file-name-p filename)
 516        (tramp-gvfs-fuse-file-name filename)
 517      filename)
 518    (if (tramp-gvfs-file-name-p newname)
 519        (tramp-gvfs-fuse-file-name newname)
 520      newname)
 521    ok-if-already-exists keep-date preserve-uid-gid))
 522
 523 (defun tramp-gvfs-handle-delete-directory (directory)
 524   "Like `delete-directory' for Tramp files."
 525   (delete-directory (tramp-gvfs-fuse-file-name directory)))
 526
 527 (defun tramp-gvfs-handle-delete-file (filename)
 528   "Like `delete-file' for Tramp files."
 529   (delete-file (tramp-gvfs-fuse-file-name filename)))
 530
 531 (defun tramp-gvfs-handle-directory-files
 532   (directory &optional full match nosort)
 533   "Like `directory-files' for Tramp files."
 534   (let ((fuse-file-name (tramp-gvfs-fuse-file-name directory)))
 535     (mapcar
 536      (lambda (x)
 537        (if (string-match fuse-file-name x)
 538            (replace-match directory t t x)
 539          x))
 540      (directory-files fuse-file-name full match nosort))))
 541
 542 (defun tramp-gvfs-handle-directory-files-and-attributes
 543   (directory &optional full match nosort id-format)
 544   "Like `directory-files-and-attributes' for Tramp files."
 545   (let ((fuse-file-name (tramp-gvfs-fuse-file-name directory)))
 546     (mapcar
 547      (lambda (x)
 548        (when (string-match fuse-file-name (car x))
 549          (setcar x (replace-match directory t t (car x))))
 550        x)
 551      (directory-files-and-attributes
 552       fuse-file-name full match nosort id-format))))
 553
 554 (defun tramp-gvfs-handle-expand-file-name (name &optional dir)
 555   "Like `expand-file-name' for Tramp files."
 556   ;; If DIR is not given, use DEFAULT-DIRECTORY or "/".
 557   (setq dir (or dir default-directory "/"))
 558   ;; Unless NAME is absolute, concat DIR and NAME.
 559   (unless (file-name-absolute-p name)
 560     (setq name (concat (file-name-as-directory dir) name)))
 561   ;; If NAME is not a Tramp file, run the real handler.
 562   (if (not (tramp-tramp-file-p name))
 563       (tramp-run-real-handler 'expand-file-name (list name nil))
 564     ;; Dissect NAME.
 565     (with-parsed-tramp-file-name name nil
 566       ;; Tilde expansion is not possible.
 567       (when (string-match "\\`\\(~[^/]*\\)\\(.*\\)\\'" localname)
 568         (tramp-error
 569          v 'file-error
 570          "Cannot expand tilde in file `%s'" name))
 571       (unless (tramp-run-real-handler 'file-name-absolute-p (list localname))
 572         (setq localname (concat "/" localname)))
 573       ;; We do not pass "/..".
 574       (if (string-equal "smb" method)
 575           (when (string-match "^/[^/]+\\(/\\.\\./?\\)" localname)
 576             (setq localname (replace-match "/" t t localname 1)))
 577         (when (string-match "^/\\.\\./?" localname)
 578           (setq localname (replace-match "/" t t localname))))
 579       ;; There might be a double slash.  Remove this.
 580       (while (string-match "//" localname)
 581         (setq localname (replace-match "/" t t localname)))
 582       ;; No tilde characters in file name, do normal
 583       ;; `expand-file-name' (this does "/./" and "/../").
 584       (tramp-make-tramp-file-name
 585        method user host
 586        (tramp-run-real-handler
 587         'expand-file-name (list localname))))))
 588
 589 (defun tramp-gvfs-handle-file-attributes (filename &optional id-format)
 590   "Like `file-attributes' for Tramp files."
 591   (file-attributes (tramp-gvfs-fuse-file-name filename) id-format))
 592
 593 (defun tramp-gvfs-handle-file-executable-p (filename)
 594   "Like `file-executable-p' for Tramp files."
 595   (file-executable-p (tramp-gvfs-fuse-file-name filename)))
 596
 597 (defun tramp-gvfs-handle-file-exists-p (filename)
 598   "Like `file-exists-p' for Tramp files."
 599   (file-exists-p (tramp-gvfs-fuse-file-name filename)))
 600
 601 (defun tramp-gvfs-handle-file-local-copy (filename)
 602   "Like `file-local-copy' for Tramp files."
 603   (with-parsed-tramp-file-name filename nil
 604     (let ((tmpfile (tramp-compat-make-temp-file filename)))
 605       (unless (file-exists-p filename)
 606         (tramp-error
 607          v 'file-error
 608          "Cannot make local copy of non-existing file `%s'" filename))
 609       (copy-file filename tmpfile t t)
 610       tmpfile)))
 611
 612 (defun tramp-gvfs-handle-file-name-all-completions (filename directory)
 613   "Like `file-name-all-completions' for Tramp files."
 614   (unless (save-match-data (string-match "/" filename))
 615     (file-name-all-completions filename (tramp-gvfs-fuse-file-name directory))))
 616
 617 (defun tramp-gvfs-handle-file-readable-p (filename)
 618   "Like `file-readable-p' for Tramp files."
 619   (file-readable-p (tramp-gvfs-fuse-file-name filename)))
 620
 621 (defun tramp-gvfs-handle-file-writable-p (filename)
 622   "Like `file-writable-p' for Tramp files."
 623   (file-writable-p (tramp-gvfs-fuse-file-name filename)))
 624
 625 (defun tramp-gvfs-handle-insert-directory
 626   (filename switches &optional wildcard full-directory-p)
 627   "Like `insert-directory' for Tramp files."
 628   (insert-directory
 629    (tramp-gvfs-fuse-file-name filename) switches wildcard full-directory-p))
 630
 631 (defun tramp-gvfs-handle-insert-file-contents
 632   (filename &optional visit beg end replace)
 633   "Like `insert-file-contents' for Tramp files."
 634   (unwind-protect
 635       (let ((fuse-file-name (tramp-gvfs-fuse-file-name filename))
 636             (result
 637              (insert-file-contents
 638               (tramp-gvfs-fuse-file-name filename) visit beg end replace)))
 639         (when (string-match fuse-file-name (car result))
 640           (setcar result (replace-match filename t t (car result))))
 641         result)
 642     (setq buffer-file-name filename)))
 643
 644 (defun tramp-gvfs-handle-make-directory (dir &optional parents)
 645   "Like `make-directory' for Tramp files."
 646   (condition-case err
 647       (with-tramp-gvfs-error-message dir 'make-directory
 648         (tramp-gvfs-fuse-file-name dir) parents)
 649     ;; Error case.  Let's try it with the GVFS utilities.
 650     (error
 651      (with-parsed-tramp-file-name dir nil
 652        (tramp-message v 4 "`make-directory' failed, trying `gvfs-mkdir'")
 653        (unless
 654            (zerop
 655             (tramp-local-call-process
 656              "gvfs-mkdir" nil (tramp-get-buffer v) nil
 657              (tramp-gvfs-url-file-name dir)))
 658          (signal (car err) (cdr err)))))))
 659
 660 (defun tramp-gvfs-handle-process-file
 661   (program &optional infile destination display &rest args)
 662   "Like `process-file' for Tramp files."
 663   (let ((default-directory (tramp-gvfs-fuse-file-name default-directory)))
 664     (apply 'call-process program infile destination display args)))
 665
 666 (defun tramp-gvfs-handle-rename-file
 667   (filename newname &optional ok-if-already-exists)
 668   "Like `rename-file' for Tramp files."
 669   (rename-file
 670    (if (tramp-gvfs-file-name-p filename)
 671        (tramp-gvfs-fuse-file-name filename)
 672      filename)
 673    (if (tramp-gvfs-file-name-p newname)
 674        (tramp-gvfs-fuse-file-name newname)
 675      newname)
 676    ok-if-already-exists))
 677
 678 (defun tramp-gvfs-handle-set-file-modes (filename mode)
 679   "Like `set-file-modes' for Tramp files."
 680   (with-tramp-gvfs-error-message filename 'set-file-modes
 681     (tramp-gvfs-fuse-file-name filename) mode))
 682
 683 (defun tramp-gvfs-handle-set-visited-file-modtime (&optional time-list)
 684   "Like `set-visited-file-modtime' for Tramp files."
 685   (let ((buffer-file-name (tramp-gvfs-fuse-file-name (buffer-file-name))))
 686     (set-visited-file-modtime time-list)))
 687
 688 (defun tramp-gvfs-handle-shell-command
 689   (command &optional output-buffer error-buffer)
 690   "Like `shell-command' for Tramp files."
 691   (let ((default-directory (tramp-gvfs-fuse-file-name default-directory)))
 692     (shell-command command output-buffer error-buffer)))
 693
 694 (defun tramp-gvfs-handle-start-file-process (name buffer program &rest args)
 695   "Like `start-file-process' for Tramp files."
 696   (let ((default-directory (tramp-gvfs-fuse-file-name default-directory)))
 697     (apply 'start-process name buffer program args)))
 698
 699 (defun tramp-gvfs-handle-verify-visited-file-modtime (buf)
 700   "Like `verify-visited-file-modtime' for Tramp files."
 701   (with-current-buffer buf
 702     (let ((buffer-file-name (tramp-gvfs-fuse-file-name (buffer-file-name))))
 703       (verify-visited-file-modtime buf))))
 704
 705 (defun tramp-gvfs-handle-write-region
 706   (start end filename &optional append visit lockname confirm)
 707   "Like `write-region' for Tramp files."
 708   (with-parsed-tramp-file-name filename nil
 709     (condition-case err
 710         (with-tramp-gvfs-error-message filename 'write-region
 711           start end (tramp-gvfs-fuse-file-name filename)
 712           append visit lockname confirm)
 713
 714       ;; Error case.  Let's try it with the GVFS utilities.
 715       (error
 716        (let ((tmpfile (tramp-compat-make-temp-file filename)))
 717          (tramp-message v 4 "`write-region' failed, trying `gvfs-save'")
 718          (write-region start end tmpfile)
 719          (unwind-protect
 720              (unless
 721                  (zerop
 722                   (tramp-local-call-process
 723                    "gvfs-save" tmpfile (tramp-get-buffer v) nil
 724                    (tramp-gvfs-url-file-name filename)))
 725                (signal (car err) (cdr err)))
 726            (delete-file tmpfile)))))
 727
 728     ;; The end.
 729     (when (or (eq visit t) (null visit) (stringp visit))
 730       (tramp-message v 0 "Wrote %s" filename))
 731     (run-hooks 'tramp-handle-write-region-hook)))
 732
 733 \f
 734 ;; File name conversions.
 735
 736 (defun tramp-gvfs-url-file-name (filename)
 737   "Return FILENAME in URL syntax."
 738   (url-recreate-url
 739    (if (tramp-tramp-file-p filename)
 740        (with-parsed-tramp-file-name (file-truename filename) nil
 741          (when (string-match tramp-user-with-domain-regexp user)
 742            (setq user
 743                  (concat (match-string 2 user) ";"  (match-string 2 user))))
 744          (url-parse-make-urlobj
 745           method user nil
 746           (tramp-file-name-real-host v) (tramp-file-name-port v) localname))
 747      (url-parse-make-urlobj "file" nil nil nil nil (file-truename filename)))))
 748
 749 (defun tramp-gvfs-object-path (filename)
 750   "Create a D-Bus object path from FILENAME."
 751   (expand-file-name (dbus-escape-as-identifier filename) tramp-gvfs-path-tramp))
 752
 753 (defun tramp-gvfs-file-name (object-path)
 754   "Retrieve file name from D-Bus OBJECT-PATH."
 755   (dbus-unescape-from-identifier
 756    (replace-regexp-in-string "^.*/\\([^/]+\\)$" "\\1" object-path)))
 757
 758 (defun tramp-gvfs-fuse-file-name (filename)
 759   "Return FUSE file name, which is directly accessible."
 760   (with-parsed-tramp-file-name (expand-file-name filename) nil
 761     (tramp-gvfs-maybe-open-connection v)
 762     (let ((fuse-mountpoint
 763            (tramp-get-file-property v "/" "fuse-mountpoint" nil)))
 764       (unless fuse-mountpoint
 765         (tramp-error
 766          v 'file-error "There is no FUSE mount point for `%s'" filename))
 767       ;; We must remove the share from the local name.
 768       (when (and (string-equal "smb" method) (string-match "/[^/]+" localname))
 769         (setq localname (replace-match "" t t localname)))
 770       (concat tramp-gvfs-mount-point fuse-mountpoint localname))))
 771
 772 (defun tramp-bluez-address (device)
 773   "Return bluetooth device address from a given bluetooth DEVICE name."
 774   (when (stringp device)
 775     (if (string-match tramp-ipv6-regexp device)
 776         (match-string 0 device)
 777       (cadr (assoc device (tramp-bluez-list-devices))))))
 778
 779 (defun tramp-bluez-device (address)
 780   "Return bluetooth device name from a given bluetooth device ADDRESS.
 781 ADDRESS can have the form \"xx:xx:xx:xx:xx:xx\" or \"[xx:xx:xx:xx:xx:xx]\"."
 782   (when (stringp address)
 783     (while (string-match "[][]" address)
 784       (setq address (replace-match "" t t address)))
 785     (let (result)
 786       (dolist (item (tramp-bluez-list-devices) result)
 787         (when (string-match address (cadr item))
 788           (setq result (car item)))))))
 789
 790 \f
 791 ;; D-Bus GVFS functions.
 792
 793 (defun tramp-gvfs-handler-askpassword (message user domain flags)
 794   "Implementation for the \"org.gtk.vfs.MountOperation.askPassword\" method."
 795   (let* ((filename
 796           (tramp-gvfs-file-name (dbus-event-path-name last-input-event)))
 797          (pw-prompt
 798           (format
 799            "%s for %s "
 800            (if (string-match "\\([pP]assword\\|[pP]assphrase\\)" message)
 801                (capitalize (match-string 1 message))
 802              "Password")
 803            filename))
 804          password)
 805
 806     (condition-case nil
 807         (with-parsed-tramp-file-name filename l
 808           (when (and (zerop (length user))
 809                      (not
 810                       (zerop (logand flags tramp-gvfs-password-need-username))))
 811             (setq user (read-string "User name: ")))
 812           (when (and (zerop (length domain))
 813                      (not (zerop (logand flags tramp-gvfs-password-need-domain))))
 814             (setq domain (read-string "Domain name: ")))
 815
 816           (tramp-message l 6 "%S %S %S %d" message user domain flags)
 817           (setq tramp-current-method l-method
 818                 tramp-current-user user
 819                 tramp-current-host l-host
 820                 password (tramp-read-passwd
 821                           (tramp-get-connection-process l) pw-prompt))
 822
 823           ;; Return result.
 824           (if (stringp password)
 825               (list
 826                t ;; password handled.
 827                nil ;; no abort of D-Bus.
 828                password
 829                (tramp-file-name-real-user l)
 830                domain
 831                nil ;; not anonymous.
 832                0) ;; no password save.
 833             ;; No password provided.
 834             (list nil t "" (tramp-file-name-real-user l) domain nil 0)))
 835
 836       ;; When QUIT is raised, we shall return this information to D-Bus.
 837       (quit (list nil t "" "" "" nil 0)))))
 838
 839 (defun tramp-gvfs-handler-askquestion (message choices)
 840   "Implementation for the \"org.gtk.vfs.MountOperation.askQuestion\" method."
 841   (save-window-excursion
 842     (let ((enable-recursive-minibuffers t)
 843           choice)
 844
 845       (condition-case nil
 846           (with-parsed-tramp-file-name
 847               (tramp-gvfs-file-name (dbus-event-path-name last-input-event)) nil
 848             (tramp-message v 6 "%S %S" message choices)
 849
 850             ;; In theory, there can be several choices.  Until now,
 851             ;; there is only the question whether to accept an unknown
 852             ;; host signature.
 853             (with-temp-buffer
 854               (insert message)
 855               (pop-to-buffer (current-buffer))
 856               (setq choice (if (yes-or-no-p (concat (car choices) " ")) 0 1))
 857               (tramp-message v 6 "%d" choice))
 858
 859             ;; When the choice is "no", we set an empty
 860             ;; fuse-mountpoint in order to leave the timeout.
 861             (unless (zerop choice)
 862               (tramp-set-file-property v "/" "fuse-mountpoint" ""))
 863
 864             (list
 865              t ;; handled.
 866              nil ;; no abort of D-Bus.
 867              choice))
 868
 869           ;; When QUIT is raised, we shall return this information to D-Bus.
 870           (quit (list nil t 0))))))
 871
 872 (defun tramp-gvfs-handler-mounted-unmounted (mount-info)
 873   "Signal handler for the \"org.gtk.vfs.MountTracker.mounted\" and
 874 \"org.gtk.vfs.MountTracker.unmounted\" signals."
 875   (ignore-errors
 876     (let* ((signal-name (dbus-event-member-name last-input-event))
 877            (mount-spec (cadar (last mount-info)))
 878            (method (dbus-byte-array-to-string (cadr (assoc "type" mount-spec))))
 879            (user (dbus-byte-array-to-string (cadr (assoc "user" mount-spec))))
 880            (domain (dbus-byte-array-to-string
 881                     (cadr (assoc "domain" mount-spec))))
 882            (host (dbus-byte-array-to-string
 883                   (cadr (or (assoc "host" mount-spec)
 884                             (assoc "server" mount-spec)))))
 885            (port (dbus-byte-array-to-string (cadr (assoc "port" mount-spec))))
 886            (ssl (dbus-byte-array-to-string (cadr (assoc "ssl" mount-spec)))))
 887       (when (string-match "^smb" method)
 888         (setq method "smb"))
 889       (when (string-equal "obex" method)
 890         (setq host (tramp-bluez-device host)))
 891       (when (and (string-equal "dav" method) (string-equal "true" ssl))
 892         (setq method "davs"))
 893       (unless (zerop (length domain))
 894         (setq user (concat user tramp-prefix-domain-format domain)))
 895       (unless (zerop (length port))
 896         (setq host (concat host tramp-prefix-port-format port)))
 897       (with-parsed-tramp-file-name
 898           (tramp-make-tramp-file-name method user host "") nil
 899         (tramp-message v 6 "%s %s" signal-name mount-info)
 900         (tramp-set-file-property v "/" "list-mounts" 'undef)
 901         (if (string-equal signal-name "unmounted")
 902             (tramp-set-file-property v "/" "fuse-mountpoint" nil)
 903           (tramp-set-file-property
 904            v "/" "fuse-mountpoint"
 905            (file-name-nondirectory
 906             (dbus-byte-array-to-string (car (last mount-info 2))))))))))
 907
 908 (dbus-register-signal
 909  :session nil tramp-gvfs-path-mounttracker
 910  tramp-gvfs-interface-mounttracker "mounted"
 911  'tramp-gvfs-handler-mounted-unmounted)
 912
 913 (dbus-register-signal
 914  :session nil tramp-gvfs-path-mounttracker
 915  tramp-gvfs-interface-mounttracker "unmounted"
 916  'tramp-gvfs-handler-mounted-unmounted)
 917
 918 (defun tramp-gvfs-connection-mounted-p (vec)
 919   "Check, whether the location is already mounted."
 920   (catch 'mounted
 921     (dolist
 922         (elt
 923          (with-file-property vec "/" "list-mounts"
 924            (with-tramp-dbus-call-method vec t
 925              :session tramp-gvfs-service-daemon tramp-gvfs-path-mounttracker
 926              tramp-gvfs-interface-mounttracker "listMounts"))
 927          nil)
 928       (let* ((mount-spec (cadar (last elt)))
 929              (method (dbus-byte-array-to-string
 930                       (cadr (assoc "type" mount-spec))))
 931              (user (dbus-byte-array-to-string
 932                     (cadr (assoc "user" mount-spec))))
 933              (domain (dbus-byte-array-to-string
 934                       (cadr (assoc "domain" mount-spec))))
 935              (host (dbus-byte-array-to-string
 936                     (cadr (or (assoc "host" mount-spec)
 937                               (assoc "server" mount-spec)))))
 938              (port (dbus-byte-array-to-string (cadr (assoc "port" mount-spec))))
 939              (ssl (dbus-byte-array-to-string (cadr (assoc "ssl" mount-spec)))))
 940         (when (string-match "^smb" method)
 941           (setq method "smb"))
 942         (when (string-equal "obex" method)
 943           (setq host (tramp-bluez-device host)))
 944         (when (and (string-equal "dav" method) (string-equal "true" ssl))
 945           (setq method "davs"))
 946         (when (and (string-equal "synce" method) (zerop (length user)))
 947           (setq user (or (tramp-file-name-user vec) "")))
 948         (unless (zerop (length domain))
 949           (setq user (concat user tramp-prefix-domain-format domain)))
 950         (unless (zerop (length port))
 951           (setq host (concat host tramp-prefix-port-format port)))
 952         (when (and
 953                (string-equal method (tramp-file-name-method vec))
 954                (string-equal user (or (tramp-file-name-user vec) ""))
 955                (string-equal host (tramp-file-name-host vec)))
 956           (tramp-set-file-property
 957            vec "/" "fuse-mountpoint"
 958            (file-name-nondirectory
 959             (dbus-byte-array-to-string (car (last elt 2)))))
 960           (throw 'mounted t))))))
 961
 962 (defun tramp-gvfs-mount-spec (vec)
 963   "Return a mount-spec for \"org.gtk.vfs.MountTracker.mountLocation\"."
 964   (let* ((method (tramp-file-name-method vec))
 965          (user (tramp-file-name-real-user vec))
 966          (domain (tramp-file-name-domain vec))
 967          (host (tramp-file-name-real-host vec))
 968          (port (tramp-file-name-port vec))
 969          (localname (tramp-file-name-localname vec))
 970          (ssl (if (string-match "^davs" method) "true" "false"))
 971          (mount-spec `(:array)))
 972
 973     (setq
 974      mount-spec
 975      (append
 976       mount-spec
 977       (cond
 978        ((string-equal "smb" method)
 979         (string-match "^/?\\([^/]+\\)" localname)
 980         `((:struct "type" ,(dbus-string-to-byte-array "smb-share"))
 981           (:struct "server" ,(dbus-string-to-byte-array host))
 982           (:struct "share" ,(dbus-string-to-byte-array
 983                              (match-string 1 localname)))))
 984        ((string-equal "obex" method)
 985         `((:struct "type" ,(dbus-string-to-byte-array method))
 986           (:struct "host" ,(dbus-string-to-byte-array
 987                             (concat "[" (tramp-bluez-address host) "]")))))
 988        ((string-match "^dav" method)
 989         `((:struct "type" ,(dbus-string-to-byte-array "dav"))
 990           (:struct "host" ,(dbus-string-to-byte-array host))
 991           (:struct "ssl" ,(dbus-string-to-byte-array ssl))))
 992        (t
 993         `((:struct "type" ,(dbus-string-to-byte-array method))
 994           (:struct "host" ,(dbus-string-to-byte-array host)))))))
 995
 996     (when user
 997       (add-to-list
 998        'mount-spec
 999        `(:struct "user" ,(dbus-string-to-byte-array user))
1000        'append))
1001
1002     (when domain
1003       (add-to-list
1004        'mount-spec
1005        `(:struct "domain" ,(dbus-string-to-byte-array domain))
1006        'append))
1007
1008     (when port
1009       (add-to-list
1010        'mount-spec
1011        `(:struct "port" ,(dbus-string-to-byte-array (number-to-string port)))
1012        'append))
1013
1014     ;; Return.
1015     mount-spec))
1016
1017 \f
1018 ;; Connection functions
1019
1020 (defun tramp-gvfs-maybe-open-connection (vec)
1021   "Maybe open a connection VEC.
1022 Does not do anything if a connection is already open, but re-opens the
1023 connection if a previous connection has died for some reason."
1024
1025   ;; We set the file name, in case there are incoming D-Bus signals or
1026   ;; D-Bus errors.
1027   (setq tramp-gvfs-dbus-event-vector vec)
1028
1029   ;; For password handling, we need a process bound to the connection
1030   ;; buffer.  Therefore, we create a dummy process.  Maybe there is a
1031   ;; better solution?
1032   (unless (get-buffer-process (tramp-get-buffer vec))
1033     (let ((p (make-network-process
1034               :name (tramp-buffer-name vec)
1035               :buffer (tramp-get-buffer vec)
1036               :server t :host 'local :service t)))
1037       (tramp-set-process-query-on-exit-flag p nil)))
1038
1039   (unless (tramp-gvfs-connection-mounted-p vec)
1040     (let* ((method (tramp-file-name-method vec))
1041            (user (tramp-file-name-user vec))
1042            (host (tramp-file-name-host vec))
1043            (object-path
1044             (tramp-gvfs-object-path
1045              (tramp-make-tramp-file-name method user host ""))))
1046
1047       (if (zerop (length (tramp-file-name-user vec)))
1048           (tramp-message
1049            vec 3 "Opening connection for %s using %s..." host method)
1050         (tramp-message
1051          vec 3 "Opening connection for %s@%s using %s..." user host method))
1052
1053       ;; Enable auth-sorce and password-cache.
1054       (tramp-set-connection-property
1055        (tramp-get-connection-process vec) "first-password-request" t)
1056
1057       ;; There will be a callback of "askPassword", when a password is
1058       ;; needed.
1059       (dbus-register-method
1060        :session dbus-service-emacs object-path
1061        tramp-gvfs-interface-mountoperation "askPassword"
1062        'tramp-gvfs-handler-askpassword)
1063
1064       ;; There could be a callback of "askQuestion", when adding fingerprint.
1065       (dbus-register-method
1066        :session dbus-service-emacs object-path
1067        tramp-gvfs-interface-mountoperation "askQuestion"
1068        'tramp-gvfs-handler-askquestion)
1069
1070       ;; The call must be asynchronously, because of the "askPassword"
1071       ;; or "askQuestion"callbacks.
1072       (with-tramp-dbus-call-method vec nil
1073         :session tramp-gvfs-service-daemon tramp-gvfs-path-mounttracker
1074         tramp-gvfs-interface-mounttracker "mountLocation"
1075         `(:struct
1076           ,(dbus-string-to-byte-array "/")
1077           ,(tramp-gvfs-mount-spec vec))
1078         (dbus-get-unique-name :session)
1079         :object-path object-path)
1080
1081       ;; We must wait, until the mount is applied.  This will be
1082       ;; indicated by the "mounted" signal, i.e. the "fuse-mountpoint"
1083       ;; file property.
1084       (with-timeout
1085           (60
1086            (if (zerop (length (tramp-file-name-user vec)))
1087                (tramp-error
1088                 vec 'file-error
1089                 "Timeout reached mounting %s using %s" host method)
1090              (tramp-error
1091               vec 'file-error
1092               "Timeout reached mounting %s@%s using %s" user host method)))
1093         (while (not (tramp-get-file-property vec "/" "fuse-mountpoint" nil))
1094           (sit-for 0.1)))
1095
1096       ;; We set the connection property "started" in order to put the
1097       ;; remote location into the cache, which is helpful for further
1098       ;; completion.
1099       (tramp-set-connection-property vec "started" t)
1100
1101       (if (zerop (length (tramp-file-name-user vec)))
1102           (tramp-message
1103            vec 3 "Opening connection for %s using %s...done" host method)
1104         (tramp-message
1105          vec 3
1106          "Opening connection for %s@%s using %s...done" user host method)))))
1107
1108 \f
1109 ;; D-Bus BLUEZ functions.
1110
1111 (defun tramp-bluez-list-devices ()
1112   "Return all discovered bluetooth devices as list.
1113 Every entry is a list (NAME ADDRESS).
1114
1115 If `tramp-bluez-discover-devices-timeout' is an integer, and the last
1116 discovery happened more time before indicated there, a rescan will be
1117 started, which lasts some ten seconds.  Otherwise, cached results will
1118 be used."
1119   ;; Reset the scanned devices list if time has passed.
1120   (and (integerp tramp-bluez-discover-devices-timeout)
1121        (integerp tramp-bluez-discovery)
1122        (> (tramp-time-diff (current-time) tramp-bluez-discovery)
1123           tramp-bluez-discover-devices-timeout)
1124        (setq tramp-bluez-devices nil))
1125
1126   ;; Rescan if needed.
1127   (unless tramp-bluez-devices
1128     (let ((object-path
1129            (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector t
1130              :system tramp-bluez-service "/"
1131              tramp-bluez-interface-manager "DefaultAdapter")))
1132       (setq tramp-bluez-devices nil
1133             tramp-bluez-discovery t)
1134       (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector nil
1135         :system tramp-bluez-service object-path
1136         tramp-bluez-interface-adapter "StartDiscovery")
1137       (while tramp-bluez-discovery
1138         (read-event nil nil 0.1))))
1139   (setq tramp-bluez-discovery (current-time))
1140   (tramp-message tramp-gvfs-dbus-event-vector 10 "%s" tramp-bluez-devices)
1141   tramp-bluez-devices)
1142
1143 (defun tramp-bluez-property-changed (property value)
1144   "Signal handler for the \"org.bluez.Adapter.PropertyChanged\" signal."
1145   (tramp-message tramp-gvfs-dbus-event-vector 6 "%s %s" property value)
1146   (cond
1147    ((string-equal property "Discovering")
1148     (unless (car value)
1149       ;; "Discovering" FALSE means discovery run has been completed.
1150       ;; We stop it, because we don't need another run.
1151       (setq tramp-bluez-discovery nil)
1152       (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector t
1153         :system tramp-bluez-service (dbus-event-path-name last-input-event)
1154         tramp-bluez-interface-adapter "StopDiscovery")))))
1155
1156 (dbus-register-signal
1157  :system nil nil tramp-bluez-interface-adapter "PropertyChanged"
1158  'tramp-bluez-property-changed)
1159
1160 (defun tramp-bluez-device-found (device args)
1161   "Signal handler for the \"org.bluez.Adapter.DeviceFound\" signal."
1162   (tramp-message tramp-gvfs-dbus-event-vector 6 "%s %s" device args)
1163   (let ((alias (car (cadr (assoc "Alias" args))))
1164         (address (car (cadr (assoc "Address" args)))))
1165     ;; Maybe we shall check the device class for being a proper
1166     ;; device, and call also SDP in order to find the obex service.
1167     (add-to-list 'tramp-bluez-devices (list alias address))))
1168
1169 (dbus-register-signal
1170  :system nil nil tramp-bluez-interface-adapter "DeviceFound"
1171  'tramp-bluez-device-found)
1172
1173 (defun tramp-bluez-parse-device-names (ignore)
1174   "Return a list of (nil host) tuples allowed to access."
1175   (mapcar
1176    (lambda (x) (list nil (car x)))
1177    (tramp-bluez-list-devices)))
1178
1179 ;; Add completion function for OBEX method.
1180 (when (dbus-ping :system tramp-bluez-service)
1181   (tramp-set-completion-function
1182    "obex" '((tramp-bluez-parse-device-names ""))))
1183
1184 \f
1185 ;; D-Bus zeroconf functions.
1186
1187 (defun tramp-zeroconf-parse-workstation-device-names (ignore)
1188   "Return a list of (user host) tuples allowed to access."
1189   (mapcar
1190    (lambda (x)
1191      (list nil (zeroconf-service-host x)))
1192    (zeroconf-list-services "_workstation._tcp")))
1193
1194 (defun tramp-zeroconf-parse-webdav-device-names (ignore)
1195   "Return a list of (user host) tuples allowed to access."
1196   (mapcar
1197    (lambda (x)
1198      (let ((host (zeroconf-service-host x))
1199            (port (zeroconf-service-port x))
1200            (text (zeroconf-service-txt x))
1201            user)
1202        (when port
1203          (setq host (format "%s%s%d" host tramp-prefix-port-regexp port)))
1204        ;; A user is marked in a TXT field like "u=guest".
1205        (while text
1206          (when (string-match "u=\\(.+\\)$" (car text))
1207            (setq user (match-string 1 (car text))))
1208          (setq text (cdr text)))
1209        (list user host)))
1210    (zeroconf-list-services "_webdav._tcp")))
1211
1212 ;; Add completion function for DAV and DAVS methods.
1213 (when (dbus-ping :system zeroconf-service-avahi)
1214   (zeroconf-init tramp-gvfs-zeroconf-domain)
1215   (tramp-set-completion-function
1216    "sftp" '((tramp-zeroconf-parse-workstation-device-names "")))
1217   (tramp-set-completion-function
1218    "dav" '((tramp-zeroconf-parse-webdav-device-names "")))
1219   (tramp-set-completion-function
1220    "davs" '((tramp-zeroconf-parse-webdav-device-names ""))))
1221
1222 \f
1223 ;; D-Bus SYNCE functions.
1224
1225 (defun tramp-synce-list-devices ()
1226   "Return all discovered synce devices as list.
1227 They are retrieved from the hal daemon."
1228   (let (tramp-synce-devices)
1229     (dolist (device
1230              (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector t
1231                :system tramp-hal-service tramp-hal-path-manager
1232                tramp-hal-interface-manager "GetAllDevices"))
1233       (when (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector t
1234               :system tramp-hal-service device tramp-hal-interface-device
1235               "PropertyExists" "sync.plugin")
1236         (add-to-list
1237          'tramp-synce-devices
1238          (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector t
1239            :system tramp-hal-service device tramp-hal-interface-device
1240            "GetPropertyString" "pda.pocketpc.name"))))
1241     (tramp-message tramp-gvfs-dbus-event-vector 10 "%s" tramp-synce-devices)
1242     tramp-synce-devices))
1243
1244 (defun tramp-synce-parse-device-names (ignore)
1245   "Return a list of (nil host) tuples allowed to access."
1246   (mapcar
1247    (lambda (x) (list nil x))
1248    (tramp-synce-list-devices)))
1249
1250 ;; Add completion function for SYNCE method.
1251 (tramp-set-completion-function
1252  "synce" '((tramp-synce-parse-device-names "")))
1253
1254 (provide 'tramp-gvfs)
1255
1256 ;;; TODO:
1257
1258 ;; * Host name completion via smb-server or smb-network.
1259 ;; * Check, how two shares of the same SMB server can be mounted in
1260 ;;   parallel.
1261 ;; * Apply SDP on bluetooth devices, in order to filter out obex
1262 ;;   capability.
1263 ;; * Implement obex for other serial communication but bluetooth.
1264
1265 ;; arch-tag: f7f660ce-77f4-4132-9663-f5c25a47f7ed
1266 ;;; tramp-gvfs.el ends here