lisp/dired-x.el

   1 ;;; dired-x.el --- Extra Dired functionality -*-byte-compile-dynamic: t;-*-
   2
   3 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   4 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   5 ;; Maintainer: FSF (unless Dodd can be found)
   6 ;; Version: 2.37+
   7 ;; Date: 1994/08/18 19:27:42
   8 ;; Keywords: dired extensions
   9
  10 ;; Copyright (C) 1993, 1994, 1997 Free Software Foundation, Inc.
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  27 ;; Boston, MA 02111-1307, USA.
  28
  29 ;;; Commentary:
  30
  31 ;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  32 ;; 1.191, hacked up for GNU Emacs 19.  Redundant or conflicting material
  33 ;; has been removed or renamed in order to work properly with dired of
  34 ;; GNU Emacs 19.  All suggestions or comments are most welcomed.
  35
  36 ;;
  37 ;; Please, PLEASE, *PLEASE* see the info pages.
  38 ;;
  39
  40 ;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  41
  42 ;; INSTALLATION: In your ~/.emacs,
  43 ;;
  44 ;; (add-hook 'dired-load-hook
  45 ;;           (function (lambda ()
  46 ;;                       (load "dired-x")
  47 ;;                       ;; Set global variables here.  For example:
  48 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  49 ;;                       )))
  50 ;; (add-hook 'dired-mode-hook
  51 ;;           (function (lambda ()
  52 ;;                       ;; Set buffer-local variables here.  For example:
  53 ;;                       ;; (setq dired-omit-files-p t)
  54 ;;                       )))
  55 ;;
  56 ;; At load time dired-x.el will install itself, redefine some functions, and
  57 ;; bind some dired keys.  *Please* see the info pages for more details.
  58
  59 ;; *Please* see the info pages for more details.
  60
  61 ;; User defined variables:
  62 ;;
  63 ;;      dired-bind-vm
  64 ;;      dired-vm-read-only-folders
  65 ;;      dired-bind-jump
  66 ;;      dired-bind-info
  67 ;;      dired-bind-man
  68 ;;      dired-x-hands-off-my-keys
  69 ;;      dired-find-subdir
  70 ;;      dired-enable-local-variables
  71 ;;      dired-local-variables-file
  72 ;;      dired-guess-shell-gnutar
  73 ;;      dired-guess-shell-gzip-quiet
  74 ;;      dired-guess-shell-znew-switches
  75 ;;      dired-guess-shell-alist-user
  76 ;;      dired-clean-up-buffers-too
  77 ;;      dired-omit-files-p
  78 ;;      dired-omit-files
  79 ;;      dired-omit-extensions
  80 ;;      dired-omit-size-limit
  81 ;;
  82 ;; To find out more about these variables, load this file, put your cursor at
  83 ;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  84 ;; the info pages for more details.
  85
  86 ;; When loaded this code redefines the following functions of GNU Emacs
  87 ;;
  88 ;;   Function                         Found in this file of GNU Emacs
  89 ;;   --------                         -------------------------------
  90 ;;   dired-clean-up-after-deletion    ../lisp/dired.el
  91 ;;   dired-find-buffer-nocreate       ../lisp/dired.el
  92 ;;   dired-initial-position           ../lisp/dired.el
  93 ;;
  94 ;;   dired-add-entry                  ../lisp/dired-aux.el
  95 ;;   dired-read-shell-command         ../lisp/dired-aux.el
  96
  97 \f
  98 ;;; Code:
  99
 100 ;; LOAD.
 101
 102 ;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 103 ;; here in case the user has autoloaded dired-x via the dired-jump key binding
 104 ;; (instead of autoloading to dired as is suggested in the info-pages).
 105
 106 (require 'dired)
 107
 108 ;; We will redefine some functions and also need some macros so we need to
 109 ;; load dired stuff of GNU Emacs.
 110
 111 (require 'dired-aux)
 112
 113 ;;; User-defined variables.
 114
 115 (defgroup dired-x nil
 116   "Extended directory editing (dired-x)."
 117   :group 'dired)
 118
 119 (defgroup dired-keys nil
 120   "Dired keys customizations."
 121   :prefix "dired-"
 122   :group 'dired-x)
 123
 124 (defcustom dired-bind-vm nil
 125   "*Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
 126 Also, RMAIL files contain -*- rmail -*- at the top so \"f\",
 127 `dired-advertised-find-file', will run rmail."
 128   :type 'boolean
 129   :group 'dired-keys)
 130
 131 (defcustom dired-bind-jump t
 132   "*Non-nil means bind `dired-jump' to C-x C-j, otherwise do not."
 133   :type 'boolean
 134   :group 'dired-keys)
 135
 136 (defcustom dired-bind-man t
 137   "*Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not."
 138   :type 'boolean
 139   :group 'dired-keys)
 140
 141 (defcustom dired-bind-info t
 142   "*Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not."
 143   :type 'boolean
 144   :group 'dired-keys)
 145
 146 (defcustom dired-vm-read-only-folders nil
 147   "*If non-nil, \\[dired-vm] will visit all folders read-only.
 148 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 149 files not writable by you are visited read-only.
 150
 151 Read-only folders only work in VM 5, not in VM 4."
 152   :type '(choice (const :tag "off" nil)
 153                  (const :tag "on" t)
 154                  (other :tag "non-writable only" if-file-read-only))
 155   :group 'dired-x)
 156
 157 (defcustom dired-omit-files-p nil
 158   "*If non-nil, \"uninteresting\" files are not listed (buffer-local).
 159 Use \\[dired-omit-toggle] to toggle its value.
 160 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 161 plus those ending with extensions in `dired-omit-extensions'."
 162   :type 'boolean
 163   :group 'dired-x)
 164 (make-variable-buffer-local 'dired-omit-files-p)
 165
 166 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 167   "*Filenames matching this regexp will not be displayed.
 168 This only has effect when `dired-omit-files-p' is t.  See interactive function
 169 `dired-omit-toggle' \(\\[dired-omit-toggle]\) and variable
 170 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 171 files and lock files."
 172   :type 'regexp
 173   :group 'dired-x)
 174
 175 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 176   "*If non-nil, Dired always finds a directory in a buffer of its own.
 177 If nil, Dired finds the directory as a subdirectory in some other buffer
 178 if it is present as one.
 179
 180 If there are several Dired buffers for a directory, the most recently
 181 used is chosen.
 182
 183 Dired avoids switching to the current buffer, so that if you have
 184 a normal and a wildcard buffer for the same directory, \\[dired] will
 185 toggle between those two."
 186   :type 'boolean
 187   :group 'dired-x)
 188
 189 (defcustom dired-omit-size-limit 30000
 190   "*Maximum size for the \"omitting\" feature.
 191 If nil, there is no maximum size."
 192   :type '(choice (const :tag "no maximum" nil) integer)
 193   :group 'dired-x)
 194
 195 (defcustom dired-enable-local-variables t
 196   "*Control use of local-variables lists in dired.
 197 The value can be t, nil or something else.
 198 A value of t means local-variables lists are obeyed;
 199 nil means they are ignored; anything else means query.
 200
 201 This temporarily overrides the value of `enable-local-variables' when listing
 202 a directory.  See also `dired-local-variables-file'."
 203   :type 'boolean
 204   :group 'dired-x)
 205
 206 (defcustom dired-guess-shell-gnutar nil
 207   "*If non-nil, name of GNU tar executable.
 208 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 209 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 210 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 211   :type '(choice (const :tag "Not GNU tar" nil)
 212                  (string :tag "Command name"))
 213   :group 'dired-x)
 214
 215 (defcustom dired-guess-shell-gzip-quiet t
 216   "*Non-nil says pass -q to gzip overriding verbose GZIP environment."
 217   :type 'boolean
 218   :group 'dired-x)
 219
 220 (defcustom dired-guess-shell-znew-switches nil
 221   "*If non-nil, then string of switches passed to `znew', example: \"-K\"."
 222   :type '(choice (const :tag "None" nil)
 223                  (string :tag "Switches"))
 224   :group 'dired-x)
 225
 226 (defcustom dired-clean-up-buffers-too t
 227   "*Non-nil means offer to kill buffers visiting files and dirs deleted in dired."
 228   :type 'boolean
 229   :group 'dired-x)
 230
 231 ;;; KEY BINDINGS.
 232
 233 (define-key dired-mode-map "\M-o" 'dired-omit-toggle)
 234 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 235 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 236 (define-key dired-mode-map "*." 'dired-mark-extension)
 237 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 238 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 239 (define-key dired-mode-map "\M-g" 'dired-goto-file)
 240 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 241 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 242 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 243 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 244 (define-key dired-mode-map "V" 'dired-do-run-mail)
 245
 246 (if dired-bind-man
 247     (define-key dired-mode-map "N" 'dired-man))
 248
 249 (if dired-bind-info
 250     (define-key dired-mode-map "I" 'dired-info))
 251
 252 ;;; GLOBAL BINDING.
 253 (if dired-bind-jump
 254     (progn
 255       (define-key global-map "\C-x\C-j" 'dired-jump)
 256       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 257
 258 \f
 259 ;;; Install into appropriate hooks.
 260
 261 (add-hook 'dired-mode-hook 'dired-extra-startup)
 262 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 263
 264 (defun dired-extra-startup ()
 265   "Automatically put on `dired-mode-hook' to get extra dired features:
 266 \\<dired-mode-map>
 267   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 268   \\[dired-info]\t-- run info on file
 269   \\[dired-man]\t-- run man on file
 270   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 271   \\[dired-omit-toggle]\t-- toggle omitting of files
 272   \\[dired-mark-sexp]\t-- mark by Lisp expression
 273   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring.
 274   \t   You can feed it to other commands using \\[yank].
 275
 276 For more features, see variables
 277
 278   `dired-bind-vm'
 279   `dired-bind-jump'
 280   `dired-bind-info'
 281   `dired-bind-man'
 282   `dired-vm-read-only-folders'
 283   `dired-omit-files-p'
 284   `dired-omit-files'
 285   `dired-omit-extensions'
 286   `dired-omit-size-limit'
 287   `dired-find-subdir'
 288   `dired-enable-local-variables'
 289   `dired-local-variables-file'
 290   `dired-guess-shell-gnutar'
 291   `dired-guess-shell-gzip-quiet'
 292   `dired-guess-shell-znew-switches'
 293   `dired-guess-shell-alist-user'
 294   `dired-clean-up-buffers-too'
 295
 296 See also functions
 297
 298   `dired-flag-extension'
 299   `dired-virtual'
 300   `dired-jump'
 301   `dired-man'
 302   `dired-vm'
 303   `dired-rmail'
 304   `dired-info'
 305   `dired-do-find-marked-files'"
 306   (interactive)
 307
 308   ;; These must be done in each new dired buffer.
 309   (dired-hack-local-variables)
 310   (dired-omit-startup))
 311
 312 \f
 313 ;;; BUFFER CLEANING.
 314
 315 ;; REDEFINE.
 316 (defun dired-clean-up-after-deletion (fn)
 317   "Clean up after a deleted file or directory FN.
 318 Remove expanded subdir of deleted dir, if any."
 319   (save-excursion (and (cdr dired-subdir-alist)
 320                        (dired-goto-subdir fn)
 321                        (dired-kill-subdir)))
 322
 323   ;; Offer to kill buffer of deleted file FN.
 324   (if dired-clean-up-buffers-too
 325       (progn
 326         (let ((buf (get-file-buffer fn)))
 327           (and buf
 328                (funcall (function y-or-n-p)
 329                         (format "Kill buffer of %s, too? "
 330                                 (file-name-nondirectory fn)))
 331                (save-excursion ; you never know where kill-buffer leaves you
 332                  (kill-buffer buf))))
 333         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 334               (buf nil))
 335           (and buf-list
 336                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 337                                  (dired-plural-s (length buf-list))
 338                                  (file-name-nondirectory fn)))
 339                (while buf-list
 340                  (save-excursion (kill-buffer (car buf-list)))
 341                  (setq buf-list (cdr buf-list)))))))
 342   ;; Anything else?
 343   )
 344
 345 \f
 346 ;;; EXTENSION MARKING FUNCTIONS.
 347
 348 ;;; Mark files with some extension.
 349 (defun dired-mark-extension (extension &optional marker-char)
 350   "Mark all files with a certain EXTENSION for use in later commands.
 351 A `.' is not automatically prepended to the string entered."
 352   ;; EXTENSION may also be a list of extensions instead of a single one.
 353   ;; Optional MARKER-CHAR is marker to use.
 354   (interactive "sMarking extension: \nP")
 355   (or (listp extension)
 356       (setq extension (list extension)))
 357   (dired-mark-files-regexp
 358    (concat ".";; don't match names with nothing but an extension
 359            "\\("
 360            (mapconcat 'regexp-quote extension "\\|")
 361            "\\)$")
 362    marker-char))
 363
 364 (defun dired-flag-extension (extension)
 365   "In dired, flag all files with a certain EXTENSION for deletion.
 366 A `.' is *not* automatically prepended to the string entered."
 367   (interactive "sFlagging extension: ")
 368   (dired-mark-extension extension dired-del-marker))
 369
 370 ;;; Define some unpopular file extensions.  Used for cleaning and omitting.
 371
 372 (defvar dired-patch-unclean-extensions
 373   '(".rej" ".orig")
 374   "List of extensions of dispensable files created by the `patch' program.")
 375
 376 (defvar dired-tex-unclean-extensions
 377   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 378   "List of extensions of dispensable files created by TeX.")
 379
 380 (defvar dired-latex-unclean-extensions
 381   '(".idx" ".lof" ".lot" ".glo")
 382   "List of extensions of dispensable files created by LaTeX.")
 383
 384 (defvar dired-bibtex-unclean-extensions
 385   '(".blg" ".bbl")
 386   "List of extensions of dispensable files created by BibTeX.")
 387
 388 (defvar dired-texinfo-unclean-extensions
 389   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 390     ".tp" ".tps" ".vr" ".vrs")
 391   "List of extensions of dispensable files created by texinfo.")
 392
 393 (defun dired-clean-patch ()
 394   "Flag dispensable files created by patch for deletion.
 395 See variable `dired-patch-unclean-extensions'."
 396   (interactive)
 397   (dired-flag-extension dired-patch-unclean-extensions))
 398
 399 (defun dired-clean-tex ()
 400   "Flag dispensable files created by [La]TeX etc. for deletion.
 401 See variables `dired-texinfo-unclean-extensions',
 402 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 403 `dired-texinfo-unclean-extensions'."
 404   (interactive)
 405   (dired-flag-extension (append dired-texinfo-unclean-extensions
 406                                 dired-latex-unclean-extensions
 407                                 dired-bibtex-unclean-extensions
 408                                 dired-tex-unclean-extensions)))
 409
 410 (defun dired-very-clean-tex ()
 411   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 412 See variables `dired-texinfo-unclean-extensions',
 413 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 414 `dired-texinfo-unclean-extensions'."
 415   (interactive)
 416   (dired-flag-extension (append dired-texinfo-unclean-extensions
 417                                 dired-latex-unclean-extensions
 418                                 dired-bibtex-unclean-extensions
 419                                 dired-tex-unclean-extensions
 420                                 (list ".dvi"))))
 421 \f
 422 ;;; JUMP.
 423
 424 ;;;###autoload
 425 (defun dired-jump (&optional other-window)
 426   "Jump to dired buffer corresponding to current buffer.
 427 If in a file, dired the current directory and move to file's line.
 428 If in dired already, pop up a level and goto old directory's line.
 429 In case the proper dired file line cannot be found, refresh the dired
 430 buffer and try again."
 431   (interactive "P")
 432   (let* ((file buffer-file-name)
 433          (dir (if file (file-name-directory file) default-directory)))
 434     (if (eq major-mode 'dired-mode)
 435         (progn
 436           (setq dir (dired-current-directory))
 437           (dired-up-directory other-window)
 438           (or (dired-goto-file dir)
 439               ;; refresh and try again
 440               (progn
 441                 (dired-insert-subdir (file-name-directory dir))
 442                 (dired-goto-file dir))))
 443       (if other-window
 444           (dired-other-window dir)
 445         (dired dir))
 446       (if file
 447           (or (dired-goto-file file)
 448               ;; refresh and try again
 449               (progn
 450                 (dired-insert-subdir (file-name-directory file))
 451                 (dired-goto-file file))
 452               ;; Toggle omitting, if it is on, and try again.
 453               (if dired-omit-files-p
 454                   (progn
 455                     (dired-omit-toggle)
 456                     (dired-goto-file file))))))))
 457
 458 (defun dired-jump-other-window ()
 459   "Like \\[dired-jump] (dired-jump) but in other window."
 460   (interactive)
 461   (dired-jump t))
 462 \f
 463 ;;; COPY NAMES OF MARKED FILES INTO KILL-RING.
 464
 465 (defun dired-copy-filename-as-kill (&optional arg)
 466   "Copy names of marked (or next ARG) files into the kill ring.
 467 The names are separated by a space.
 468 With a zero prefix arg, use the complete pathname of each marked file.
 469 With \\[universal-argument], use the relative pathname of each marked file.
 470
 471 If on a subdir headerline, use subdirname instead; prefix arg is ignored
 472 in this case.
 473
 474 You can then feed the file name(s) to other commands with \\[yank]."
 475   (interactive "P")
 476   (let ((string
 477          (or (dired-get-subdir)
 478              (mapconcat (function identity)
 479                         (if arg
 480                             (cond ((zerop (prefix-numeric-value arg))
 481                                    (dired-get-marked-files))
 482                                   ((integerp arg)
 483                                    (dired-get-marked-files 'no-dir arg))
 484                                   (t    ; else a raw arg
 485                                    (dired-get-marked-files t)))
 486                           (dired-get-marked-files 'no-dir))
 487                         " "))))
 488     (kill-new string)
 489     (message "%s" string)))
 490
 491 \f
 492 ;;; OMITTING.
 493
 494 ;;; Enhanced omitting of lines from directory listings.
 495 ;;; Marked files are never omitted.
 496
 497 ;; should probably get rid of this and always use 'no-dir.
 498 ;; sk 28-Aug-1991 09:37
 499 (defvar dired-omit-localp 'no-dir
 500   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 501 If it is 'no-dir, omitting is much faster, but you can only match
 502 against the basename of the file.  Set it to nil if you need to match the
 503 whole pathname.")
 504
 505 ;; \017=^O for Omit - other packages can chose other control characters.
 506 (defvar dired-omit-marker-char ?\017
 507   "Temporary marker used by by dired-omit.
 508 Should never be used as marker by the user or other packages.")
 509
 510 (defun dired-omit-startup ()
 511   (or (assq 'dired-omit-files-p minor-mode-alist)
 512       (setq minor-mode-alist
 513             (append '((dired-omit-files-p " Omit")) minor-mode-alist))))
 514
 515 (defun dired-omit-toggle (&optional flag)
 516   "Toggle omitting files matching `dired-omit-files' and `dired-omit-extensions'.
 517 With an arg, and if omitting was off, don't toggle and just mark the
 518   files but don't actually omit them.
 519 With an arg, and if omitting was on, turn it off but don't refresh the buffer."
 520   (interactive "P")
 521   (if flag
 522       (if dired-omit-files-p
 523           (setq dired-omit-files-p (not dired-omit-files-p))
 524         (dired-mark-unmarked-files (dired-omit-regexp) nil nil
 525                                    dired-omit-localp))
 526     ;; no FLAG
 527     (setq dired-omit-files-p (not dired-omit-files-p))
 528     (if (not dired-omit-files-p)
 529         (revert-buffer)
 530       ;; this will mention how many were omitted:
 531       (let ((dired-omit-size-limit nil))
 532         (dired-omit-expunge)))))
 533
 534 (defvar dired-omit-extensions
 535   (append completion-ignored-extensions
 536           dired-latex-unclean-extensions
 537           dired-bibtex-unclean-extensions
 538           dired-texinfo-unclean-extensions)
 539   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 540 Defaults to elements of `completion-ignored-extensions',
 541 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 542 `dired-texinfo-unclean-extensions'.
 543
 544 See interactive function `dired-omit-toggle' \(\\[dired-omit-toggle]\) and
 545 variables `dired-omit-files-p' and `dired-omit-files'.")
 546
 547 (defun dired-omit-expunge (&optional regexp)
 548   "Erases all unmarked files matching REGEXP.
 549 Does nothing if global variable `dired-omit-files-p' is nil, or if called
 550   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 551 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 552   filenames ending in `dired-omit-extensions'.
 553 If REGEXP is the empty string, this function is a no-op.
 554
 555 This functions works by temporarily binding `dired-marker-char' to
 556 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 557   (interactive "sOmit files (regexp): ")
 558   (if (and dired-omit-files-p
 559            (or (interactive-p)
 560                (not dired-omit-size-limit)
 561                (< (buffer-size) dired-omit-size-limit)
 562                (progn
 563                  (message "Not omitting: directory larger than %d characters."
 564                           dired-omit-size-limit)
 565                  (setq dired-omit-files-p nil)
 566                  nil)))
 567       (let ((omit-re (or regexp (dired-omit-regexp)))
 568             (old-modified-p (buffer-modified-p))
 569             count)
 570         (or (string= omit-re "")
 571             (let ((dired-marker-char dired-omit-marker-char))
 572               (message "Omitting...")
 573               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 574                   (progn
 575                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 576                     (force-mode-line-update))
 577                 (message "(Nothing to omit)"))))
 578         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 579         ;; in mode-line of omitted buffers.
 580         (set-buffer-modified-p (and old-modified-p
 581                                     (save-excursion
 582                                       (goto-char (point-min))
 583                                       (re-search-forward dired-re-mark nil t))))
 584         count)))
 585
 586 (defun dired-omit-regexp ()
 587   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 588           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 589           (if dired-omit-extensions
 590               (concat ".";; a non-extension part should exist
 591                       "\\("
 592                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 593                       "\\)$")
 594             "")))
 595
 596 ;; Returns t if any work was done, nil otherwise.
 597 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 598   "Mark unmarked files matching REGEXP, displaying MSG.
 599 REGEXP is matched against the complete pathname.
 600 Does not re-mark files which already have a mark.
 601 With prefix argument, unflag all those files.
 602 Second optional argument LOCALP is as in `dired-get-filename'."
 603   (interactive "P")
 604   (let ((dired-marker-char (if unflag-p ?\  dired-marker-char)))
 605     (dired-mark-if
 606      (and
 607       ;; not already marked
 608       (looking-at " ")
 609       ;; uninteresting
 610       (let ((fn (dired-get-filename localp t)))
 611         (and fn (string-match regexp fn))))
 612      msg)))
 613
 614 ;;; REDEFINE.
 615 (defun dired-omit-new-add-entry (filename &optional marker-char relative)
 616   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 617   ;; files that are going to be omitted anyway.
 618   (if dired-omit-files-p
 619       ;; perhaps return t without calling ls
 620       (let ((omit-re (dired-omit-regexp)))
 621         (if (or (string= omit-re "")
 622                 (not
 623                  (string-match omit-re
 624                                (cond
 625                                 ((eq 'no-dir dired-omit-localp)
 626                                  filename)
 627                                 ((eq t dired-omit-localp)
 628                                  (dired-make-relative filename))
 629                                 (t
 630                                  (dired-make-absolute
 631                                   filename
 632                                   (file-name-directory filename)))))))
 633             ;; if it didn't match, go ahead and add the entry
 634             (dired-omit-old-add-entry filename marker-char relative)
 635           ;; dired-add-entry returns t for success, perhaps we should
 636           ;; return file-exists-p
 637           t))
 638     ;; omitting is not turned on at all
 639     (dired-omit-old-add-entry filename marker-char relative)))
 640
 641 ;;; REDEFINE.
 642 ;;; Redefine dired-aux.el's version of `dired-add-entry'
 643 ;;; Save old defun if not already done:
 644 (or (fboundp 'dired-omit-old-add-entry)
 645     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 646 ;; Redefine it.
 647 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 648
 649 \f
 650 ;;; VIRTUAL DIRED MODE.
 651
 652 ;;; For browsing `ls -lR' listings in a dired-like fashion.
 653
 654 (fset 'virtual-dired 'dired-virtual)
 655 (defun dired-virtual (dirname &optional switches)
 656   "Put this buffer into Virtual Dired mode.
 657
 658 In Virtual Dired mode, all commands that do not actually consult the
 659 filesystem will work.
 660
 661 This is useful if you want to peruse and move around in an ls -lR
 662 output file, for example one you got from an ftp server.  With
 663 ange-ftp, you can even dired a directory containing an ls-lR file,
 664 visit that file and turn on virtual dired mode.  But don't try to save
 665 this file, as dired-virtual indents the listing and thus changes the
 666 buffer.
 667
 668 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 669 resume it in a later session.
 670
 671 Type \\<dired-mode-map>\\[revert-buffer] in the
 672 Virtual Dired buffer and answer `y' to convert the virtual to a real
 673 dired buffer again.  You don't have to do this, though: you can relist
 674 single subdirs using \\[dired-do-redisplay]."
 675
 676   ;; DIRNAME is the top level directory of the buffer.  It will become
 677   ;; its `default-directory'.  If nil, the old value of
 678   ;; default-directory is used.
 679
 680   ;; Optional SWITCHES are the ls switches to use.
 681
 682   ;; Shell wildcards will be used if there already is a `wildcard'
 683   ;; line in the buffer (thus it is a saved Dired buffer), but there
 684   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 685   ;; hand if you want them.
 686
 687   (interactive
 688    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 689   (goto-char (point-min))
 690   (or (looking-at "  ")
 691       ;; if not already indented, do it now:
 692       (indent-region (point-min) (point-max) 2))
 693   (or dirname (setq dirname default-directory))
 694   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 695   (setq default-directory dirname)      ; contains no wildcards
 696   (let ((wildcard (save-excursion
 697                     (goto-char (point-min))
 698                     (forward-line 1)
 699                     (and (looking-at "^  wildcard ")
 700                          (buffer-substring (match-end 0)
 701                                            (progn (end-of-line) (point)))))))
 702   (if wildcard
 703         (setq dirname (expand-file-name wildcard default-directory))))
 704   ;; If raw ls listing (not a saved old dired buffer), give it a
 705   ;; decent subdir headerline:
 706   (goto-char (point-min))
 707   (or (looking-at dired-subdir-regexp)
 708       (dired-insert-headerline default-directory))
 709   (dired-mode dirname (or switches dired-listing-switches))
 710   (setq mode-name "Virtual Dired"
 711         revert-buffer-function 'dired-virtual-revert)
 712   (set (make-local-variable 'dired-subdir-alist) nil)
 713   (dired-build-subdir-alist)
 714   (goto-char (point-min))
 715   (dired-initial-position dirname))
 716
 717 (defun dired-virtual-guess-dir ()
 718   "Guess and return appropriate working directory of this buffer.
 719 Th ebuffer is assumed to be in Dired or ls -lR format.  The guess is
 720 based upon buffer contents.  If nothing could be guessed, returns
 721 nil."
 722
 723   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 724         (subexpr 2))
 725     (goto-char (point-min))
 726     (cond ((looking-at regexp)
 727            ;; If a saved dired buffer, look to which dir and
 728            ;; perhaps wildcard it belongs:
 729            (let ((dir (buffer-substring (match-beginning subexpr)
 730                                         (match-end subexpr))))
 731              (file-name-as-directory dir)))
 732           ;; Else no match for headerline found.  It's a raw ls listing.
 733           ;; In raw ls listings the directory does not have a headerline
 734           ;; try parent of first subdir, if any
 735           ((re-search-forward regexp nil t)
 736            (file-name-directory
 737             (directory-file-name
 738              (file-name-as-directory
 739               (buffer-substring (match-beginning subexpr)
 740                                 (match-end subexpr))))))
 741           (t                            ; if all else fails
 742            nil))))
 743
 744
 745 (defun dired-virtual-revert (&optional arg noconfirm)
 746   (if (not
 747        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 748       (error "Cannot revert a Virtual Dired buffer")
 749     (setq mode-name "Dired"
 750           revert-buffer-function 'dired-revert)
 751     (revert-buffer)))
 752
 753 ;; A zero-arg version of dired-virtual.
 754 ;; You need my modified version of set-auto-mode for the
 755 ;; `buffer-contents-mode-alist'.
 756 ;; Or you use infer-mode.el and infer-mode-alist, same syntax.
 757 (defun dired-virtual-mode ()
 758   "Put current buffer into virtual dired mode (see `dired-virtual').
 759 Useful on `buffer-contents-mode-alist' (which see) with the regexp
 760
 761     \"^  \\(/[^ /]+\\)/?+:$\"
 762
 763 to put saved dired buffers automatically into virtual dired mode.
 764
 765 Also useful for `auto-mode-alist' (which see) like this:
 766
 767   \(setq auto-mode-alist (cons '(\"[^/]\\.dired\\'\" . dired-virtual-mode)
 768                               auto-mode-alist)\)"
 769   (interactive)
 770   (dired-virtual (dired-virtual-guess-dir)))
 771
 772 \f
 773 ;;; SMART SHELL.
 774
 775 ;;; An Emacs buffer can have but one working directory, stored in the
 776 ;;; buffer-local variable `default-directory'.  A Dired buffer may have
 777 ;;; several subdirectories inserted, but still has but one working directory:
 778 ;;; that of the top level Dired directory in that buffer.  For some commands
 779 ;;; it is appropriate that they use the current Dired directory instead of
 780 ;;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 781 ;;; mechanism is provided for special handling of the working directory in
 782 ;;; special major modes.
 783
 784 ;; It's easier to add to this alist than redefine function
 785 ;; default-directory while keeping the old information.
 786 (defconst default-directory-alist
 787   '((dired-mode . (if (fboundp 'dired-current-directory)
 788                       (dired-current-directory)
 789                     default-directory)))
 790   "Alist of major modes and their opinion on `default-directory'.
 791 This is given as a Lisp expression to evaluate.  A resulting value of
 792 nil is ignored in favor of `default-directory'.")
 793
 794 (defun dired-default-directory ()
 795   "Usage like variable `default-directory'.
 796 Knows about the special cases in variable `default-directory-alist'."
 797   (or (eval (cdr (assq major-mode default-directory-alist)))
 798       default-directory))
 799
 800 (defun dired-smart-shell-command (cmd &optional insert)
 801   "Like function `shell-command', but in the current Tree Dired directory."
 802   (interactive (list (read-from-minibuffer "Shell command: "
 803                                            nil nil nil 'shell-command-history)
 804                      current-prefix-arg))
 805   (let ((default-directory (dired-default-directory)))
 806     (shell-command cmd insert)))
 807
 808 \f
 809 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 810
 811 ;;; Brief Description:
 812 ;;;
 813 ;;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 814 ;;;
 815 ;;; * `dired-extra-startup' calls `dired-hack-local-variables'
 816 ;;;
 817 ;;; * `dired-hack-local-variables' checks the value of
 818 ;;;   `dired-local-variables-file'
 819 ;;;
 820 ;;; * Check if `dired-local-variables-file' is a non-nil string and is a
 821 ;;;   filename found in the directory of the Dired Buffer being created.
 822 ;;;
 823 ;;; * If `dired-local-variables-file' satisfies the above, then temporarily
 824 ;;;   include it in the Dired Buffer at the bottom.
 825 ;;;
 826 ;;; * Set `enable-local-variables' temporarily to the user variable
 827 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 828 ;;;   Dired Buffer.
 829
 830 (defvar dired-local-variables-file (convert-standard-filename ".dired")
 831   "Filename, as string, containing local dired buffer variables to be hacked.
 832 If this file found in current directory, then it will be inserted into dired
 833 buffer and `hack-local-variables' will be run.  See Emacs Info pages for more
 834 information on local variables.  See also `dired-enable-local-variables'.")
 835
 836 (defun dired-hack-local-variables ()
 837   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 838   (if (and dired-local-variables-file
 839            (stringp dired-local-variables-file)
 840            (file-exists-p dired-local-variables-file))
 841       (let ((opoint (point-max))
 842             buffer-read-only
 843             ;; In case user has `enable-local-variables' set to nil we
 844             ;; override it locally with dired's variable.
 845             (enable-local-variables dired-enable-local-variables))
 846         ;; Insert 'em.
 847         (save-excursion
 848           (goto-char opoint)
 849           (insert "\^L\n")
 850           (insert-file-contents dired-local-variables-file))
 851         ;; Hack 'em.
 852         (let ((buffer-file-name dired-local-variables-file))
 853           (hack-local-variables))
 854         ;; Make sure that the modeline shows the proper information.
 855         (dired-sort-set-modeline)
 856         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 857         (delete-region opoint (point-max)))))
 858
 859 (defun dired-omit-here-always ()
 860   "Create `dired-local-variables-file' for omitting and reverts directory.
 861 Sets dired-omit-file-p to t in a local variables file that is readable by
 862 dired."
 863   (interactive)
 864   (if (file-exists-p dired-local-variables-file)
 865       (message "File `./%s' already exists." dired-local-variables-file)
 866
 867     ;; Create `dired-local-variables-file'.
 868     (save-excursion
 869       (set-buffer (get-buffer-create " *dot-dired*"))
 870       (erase-buffer)
 871       (insert "Local Variables:\ndired-omit-files-p: t\nEnd:\n")
 872       (write-file dired-local-variables-file)
 873       (kill-buffer (current-buffer)))
 874
 875     ;; Run extra-hooks and revert directory.
 876     (dired-extra-startup)
 877     (dired-revert)))
 878
 879 \f
 880 ;;; GUESS SHELL COMMAND.
 881
 882 ;;; Brief Description:
 883 ;;;
 884 ;;; `dired-do-shell-command' is bound to `!' by dired.el.
 885 ;;;
 886 ;;; * Redefine `dired-do-shell-command' so it calls
 887 ;;;   `dired-guess-shell-command'.
 888 ;;;
 889 ;;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 890 ;;;    marked files.
 891 ;;;
 892 ;;; * Parse `dired-guess-shell-alist-user' and
 893 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 894 ;;;   that matches the first file in the file list.
 895 ;;;
 896 ;;; * If the REGEXP matches all the entries of the file list then evaluate
 897 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 898 ;;;   string.  COMMAND may be a list of commands.
 899 ;;;
 900 ;;; * Return this command to `dired-guess-shell-command' which prompts user
 901 ;;;   with it.  The list of commands is temporarily put into the history list.
 902 ;;;   If a command is used successfully then it is stored permanently in
 903 ;;;   `dired-shell-command-history'.
 904
 905 ;;; Guess what shell command to apply to a file.
 906 (defvar dired-shell-command-history nil
 907   "History list for commands that read dired-shell commands.")
 908
 909 ;;; Default list of shell commands.
 910
 911 ;;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 912 ;;; install GNU zip's version of zcat.
 913
 914 (defvar dired-guess-shell-alist-default
 915   (list
 916    (list "\\.tar$" '(if dired-guess-shell-gnutar
 917                         (concat dired-guess-shell-gnutar " xvf")
 918                       "tar xvf"))
 919
 920    ;; REGEXPS for compressed archives must come before the .Z rule to
 921    ;; be recognized:
 922    (list "\\.tar\\.Z$"
 923          ;; Untar it.
 924          '(if dired-guess-shell-gnutar
 925               (concat dired-guess-shell-gnutar " zxvf")
 926             (concat "zcat * | tar xvf -"))
 927          ;; Optional conversion to gzip format.
 928          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 929                   " " dired-guess-shell-znew-switches))
 930
 931    ;; gzip'ed archives
 932    (list "\\.t\\(ar\\.\\)?gz$"
 933          '(if dired-guess-shell-gnutar
 934               (concat dired-guess-shell-gnutar " zxvf")
 935             (concat "gunzip -qc * | tar xvf -"))
 936          ;; Optional decompression.
 937          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" "")))
 938    ;; bzip2'ed archives
 939    (list "\\.tar\\.bz2$"
 940          "bunzip2 -c * | tar xvf -"
 941          ;; Optional decompression.
 942          "bunzip2")
 943
 944    '("\\.shar.Z$" "zcat * | unshar")
 945    '("\\.shar.g?z$" "gunzip -qc * | unshar")
 946
 947    '("\\.e?ps$" "ghostview" "xloadimage" "lpr")
 948    (list "\\.e?ps.g?z$" "gunzip -qc * | ghostview -"
 949          ;; Optional decompression.
 950          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 951    (list "\\.e?ps.Z$" "zcat * | ghostview -"
 952          ;; Optional conversion to gzip format.
 953          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 954                   " " dired-guess-shell-znew-switches))
 955    '("\\.patch$" "cat * | patch")
 956    '("\\.patch.g?z$" "gunzip -qc * | patch")
 957    (list "\\.patch.Z$" "zcat * | patch"
 958          ;; Optional conversion to gzip format.
 959          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 960                   " " dired-guess-shell-znew-switches))
 961
 962    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
 963    '("\\.au$" "play")                   ; play Sun audiofiles
 964    '("\\.mpg$" "mpeg_play")
 965    '("\\.uu$" "uudecode")               ; for uudecoded files
 966    '("\\.hqx$" "mcvert")
 967    '("\\.sh$" "sh")                     ; execute shell scripts
 968    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
 969    '("\\.gp$" "gnuplot")
 970    '("\\.p[bgpn]m$" "xloadimage")
 971    '("\\.gif$" "xloadimage")                    ; view gif pictures
 972    '("\\.tif$" "xloadimage")
 973    '("\\.png$" "display")               ; xloadimage 4.1 doesn't grok PNG
 974    '("\\.jpg$" "xloadimage")
 975    '("\\.fig$" "xfig")                  ; edit fig pictures
 976    '("\\.out$" "xgraph")                ; for plotting purposes.
 977    '("\\.tex$" "latex" "tex")
 978    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
 979    '("\\.pdf$" "xpdf")              ; edit PDF files
 980
 981    ;; Some other popular archivers.
 982    '("\\.zoo$" "zoo x//")
 983    '("\\.zip$" "unzip")
 984    '("\\.lzh$" "lharc x")
 985    '("\\.arc$" "arc x")
 986    '("\\.shar$" "unshar")
 987
 988    ;; Compression.
 989    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 990    (list "\\.bz2$" "bunzip2")
 991    (list "\\.Z$" "uncompress"
 992          ;; Optional conversion to gzip format.
 993          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 994                   " " dired-guess-shell-znew-switches))
 995    )
 996
 997   "Default alist used for shell command guessing.
 998 See `dired-guess-shell-alist-user'.")
 999
1000 (defcustom dired-guess-shell-alist-user nil
1001   "User-defined alist of rules for suggested commands.
1002 These rules take precedence over the predefined rules in the variable
1003 `dired-guess-shell-alist-default' (to which they are prepended).
1004
1005 Each element of this list looks like
1006
1007     \(REGEXP COMMAND...\)
1008
1009 where each COMMAND can either be a string or a lisp expression that evaluates
1010 to a string.  If several COMMANDs are given, the first one will be the default
1011 and the rest will be added temporarily to the history and can be retrieved
1012 with \\[previous-history-element] (M-p) .
1013
1014 You can set this variable in your ~/.emacs.  For example, to add rules for
1015 `.foo' and `.bar' files, write
1016
1017  \(setq dired-guess-shell-alist-user
1018        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1019               ;; possibly more rules ...
1020               (list \"\\\\.bar\\\'\";; rule with condition test
1021                     '(if condition
1022                           \"BAR-COMMAND-1\"
1023                         \"BAR-COMMAND-2\")))\)"
1024   :group 'dired-x
1025   :type '(alist :key-type regexp :value-type (repeat sexp)))
1026
1027 (defun dired-guess-default (files)
1028   "Guess a shell commands for FILES.  Return command or list of commands.
1029 See `dired-guess-shell-alist-user'."
1030
1031   (let* ((case-fold-search nil) ; case-sensitive matching
1032          ;; Prepend the user's alist to the default alist.
1033          (alist (append dired-guess-shell-alist-user
1034                         dired-guess-shell-alist-default))
1035          (file (car files))
1036          (flist (cdr files))
1037          elt regexp cmds)
1038
1039     ;; Find the first match in the alist for first file in FILES.
1040     (while alist
1041       (setq elt (car alist)
1042             regexp (car elt)
1043             alist (cdr alist))
1044       (if (string-match regexp file)
1045           (setq cmds (cdr elt)
1046                 alist nil)))
1047
1048     ;; If more than one file, see if all of FILES match regular expression.
1049     (while (and flist
1050                 (string-match regexp (car flist)))
1051       (setq flist (cdr flist)))
1052
1053     ;; If flist is still non-nil, then do not guess since this means that not
1054     ;; all the files in FILES were matched by the regexp.
1055     (setq cmds (and (not flist) cmds))
1056
1057     ;; Return commands or nil if flist is still non-nil.
1058     ;; Evaluate the commands in order that any logical testing will be done.
1059     (cond ((not (cdr cmds))
1060            (eval (car cmds))) ; single command
1061           (t
1062            (mapcar (function eval) cmds)))))
1063
1064 (defun dired-guess-shell-command (prompt files)
1065   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1066
1067   (let ((default (dired-guess-default files))
1068         default-list old-history val (failed t))
1069
1070     (if (null default)
1071         ;; Nothing to guess
1072         (read-from-minibuffer prompt nil nil nil 'dired-shell-command-history)
1073
1074       ;; Save current history list
1075       (setq old-history dired-shell-command-history)
1076
1077       (if (listp default)
1078
1079           ;; More than one guess
1080           (setq default-list default
1081                 default (car default)
1082                 prompt (concat
1083                         prompt
1084                         (format "{%d guesses} " (length default-list))))
1085
1086         ;; Just one guess
1087         (setq default-list (list default)))
1088
1089       ;; Push all guesses onto history so that they can be retrieved with M-p
1090       ;; and put the first guess in the prompt but not in the initial value.
1091       (setq dired-shell-command-history
1092             (append default-list dired-shell-command-history)
1093             prompt (concat prompt (format "[%s] " default)))
1094
1095       ;; The unwind-protect returns VAL, and we too.
1096       (unwind-protect
1097           ;; BODYFORM
1098           (progn
1099             (setq val (read-from-minibuffer prompt nil nil nil
1100                                             'dired-shell-command-history)
1101                   failed nil)
1102             ;; If we got a return, then use default.
1103             (if (equal val "")
1104                 (setq val default))
1105             val)
1106
1107         ;; UNWINDFORMS
1108         ;; Undo pushing onto the history list so that an aborted
1109         ;; command doesn't get the default in the next command.
1110         (setq dired-shell-command-history old-history)
1111         (if (not failed)
1112             (or (equal val (car-safe dired-shell-command-history))
1113                 (setq dired-shell-command-history
1114                       (cons val dired-shell-command-history))))))))
1115
1116
1117 ;;; REDEFINE.
1118 ;;; Redefine dired-aux.el's version:
1119 (defun dired-read-shell-command (prompt arg files)
1120   "Read a dired shell command prompting with PROMPT (using read-string).
1121 ARG is the prefix arg and may be used to indicate in the prompt which
1122   files are affected.
1123 This is an extra function so that you can redefine it."
1124   (dired-mark-pop-up
1125    nil 'shell files
1126    'dired-guess-shell-command
1127    (format prompt (dired-mark-prompt arg files)) ; PROMPT
1128    files))                                       ; FILES
1129
1130 \f
1131 ;;; RELATIVE SYMBOLIC LINKS.
1132
1133 (defvar dired-keep-marker-relsymlink ?S
1134   "See variable `dired-keep-marker-move'.")
1135
1136 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1137   "Make a symbolic link (pointing to FILE1) in FILE2.
1138 The link is relative (if possible), for example
1139
1140     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1141
1142 results in
1143
1144     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1145   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1146   (let (name1 name2 len1 len2 (index 0) sub)
1147     (setq file1 (expand-file-name file1)
1148           file2 (expand-file-name file2)
1149           len1 (length file1)
1150           len2 (length file2))
1151     ;; Find common initial pathname components:
1152     (let (next)
1153       (while (and (setq next (string-match "/" file1 index))
1154                   (setq next (1+ next))
1155                   (< next (min len1 len2))
1156                   ;; For the comparison, both substrings must end in
1157                   ;; `/', so NEXT is *one plus* the result of the
1158                   ;; string-match.
1159                   ;; E.g., consider the case of linking "/tmp/a/abc"
1160                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1161                   ;; of "/tmp/" as common initial component
1162                   (string-equal (substring file1 0 next)
1163                                 (substring file2 0 next)))
1164         (setq index next))
1165       (setq name2 file2
1166             sub (substring file1 0 index)
1167             name1 (substring file1 index)))
1168     (if (string-equal sub "/")
1169         ;; No common initial pathname found
1170         (setq name1 file1)
1171       ;; Else they have a common parent directory
1172       (let ((tem (substring file2 index))
1173             (start 0)
1174             (count 0))
1175         ;; Count number of slashes we must compensate for ...
1176         (while (setq start (string-match "/" tem start))
1177           (setq count (1+ count)
1178                 start (1+ start)))
1179         ;; ... and prepend a "../" for each slash found:
1180         (while (> count 0)
1181           (setq count (1- count)
1182                 name1 (concat "../" name1)))))
1183     (make-symbolic-link
1184      (directory-file-name name1)        ; must not link to foo/
1185                                         ; (trailing slash!)
1186      name2 ok-if-already-exists)))
1187
1188 (defun dired-do-relsymlink (&optional arg)
1189    "Relative symlink all marked (or next ARG) files into a directory.
1190 Otherwise make a relative symbolic link to the current file.
1191 This creates relative symbolic links like
1192
1193     foo -> ../bar/foo
1194
1195 not absolute ones like
1196
1197     foo -> /ugly/path/that/may/change/any/day/bar/foo"
1198   (interactive "P")
1199   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1200                            "RelSymLink" arg dired-keep-marker-relsymlink))
1201
1202 (defun dired-do-relsymlink-regexp (regexp newname &optional whole-path)
1203   "RelSymlink all marked files containing REGEXP to NEWNAME.
1204 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1205 for more info."
1206   (interactive (dired-mark-read-regexp "RelSymLink"))
1207   (dired-do-create-files-regexp
1208    (function dired-make-relative-symlink)
1209    "RelSymLink" nil regexp newname whole-path dired-keep-marker-relsymlink))
1210
1211 \f
1212 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1213
1214 ;;; Brief Description:
1215 ;;;
1216 ;;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1217 ;;;
1218 ;;; * Use `dired-get-marked-files' to collect the marked files in the current
1219 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1220 ;;;
1221 ;;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1222 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1223 ;;;
1224 ;;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1225 ;;;   list each time.
1226 ;;;
1227 ;;; * If NOSELECT is non-nil then just run `find-file-noselect'  on each
1228 ;;;   element of FILE-LIST.
1229 ;;;
1230 ;;; * If NOSELECT is nil then calculate the `size' of the window for each file
1231 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1232 ;;;   cognizant of the window-configuration.
1233 ;;;
1234 ;;; * If `size' is too small abort, otherwise run `find-file' on each element
1235 ;;;   of FILE-LIST giving each a window of height `size'.
1236
1237 (defun dired-do-find-marked-files (&optional noselect)
1238   "Find all marked files displaying all of them simultaneously.
1239 With optional NOSELECT just find files but do not select them.
1240
1241 The current window is split across all files marked, as evenly as possible.
1242 Remaining lines go to bottom-most window.  The number of files that can be
1243 displayed this way is restricted by the height of the current window and
1244 `window-min-height'.
1245
1246 To keep dired buffer displayed, type \\[split-window-vertically] first.
1247 To display just marked files, type \\[delete-other-windows] first."
1248
1249   (interactive "P")
1250   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1251
1252 (defun dired-simultaneous-find-file (file-list noselect)
1253
1254   "Visit all files in FILE-LIST and display them simultaneously.
1255 The current window is split across all files in FILE-LIST, as evenly as
1256 possible.  Remaining lines go to the bottom-most window.  The number of
1257 files that can be displayed this way is restricted by the height of the
1258 current window and the variable `window-min-height'.  With non-nil
1259 NOSELECT the files are merely found but not selected."
1260
1261   ;; We don't make this function interactive because it is usually too clumsy
1262   ;; to specify FILE-LIST interactively unless via dired.
1263
1264   (let (size)
1265
1266     (if noselect
1267         ;; Do not select the buffer.
1268         (find-file-noselect (car file-list))
1269
1270       ;; We will have to select the buffer.  Calculate and check window size.
1271       (setq size (/ (window-height) (length file-list)))
1272       (or (<= window-min-height size)
1273           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1274       (find-file (car file-list)))
1275
1276     ;; Decrement.
1277     (setq file-list (cdr file-list))
1278
1279     (while file-list
1280
1281       (if noselect
1282           ;; Do not select the buffer.
1283           (find-file-noselect (car file-list))
1284
1285         ;; Vertically split off a window of desired size.  Upper window will
1286         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1287         (select-window (split-window nil size))
1288         (find-file (car file-list)))
1289
1290       ;; Decrement.
1291       (setq file-list (cdr file-list)))))
1292
1293 \f
1294 ;;; MISCELLANEOUS COMMANDS.
1295
1296 ;;; Run man on files.
1297
1298 (defun dired-man ()
1299   "Run man on this file.  Display old buffer if buffer name matches filename.
1300 Uses ../lisp/man.el of \\[manual-entry] fame."
1301   (interactive)
1302   (require 'man)
1303   (let ((file (dired-get-filename))
1304         (manual-program "nroff -man -h"))
1305     (Man-getpage-in-background file)))
1306
1307 ;;; Run Info on files.
1308
1309 (defun dired-info ()
1310   "Run info on this file."
1311   (interactive)
1312   (info (dired-get-filename)))
1313
1314 ;;; Run mail on mail folders.
1315
1316 ;;; (and (not (fboundp 'vm-visit-folder))
1317 ;;;      (defun vm-visit-folder (file &optional arg)
1318 ;;;        nil))
1319
1320 (defun dired-vm (&optional read-only)
1321   "Run VM on this file.
1322 With prefix arg, visit folder read-only (this requires at least VM 5).
1323 See also variable `dired-vm-read-only-folders'."
1324   (interactive "P")
1325   (let ((dir (dired-current-directory))
1326         (fil (dired-get-filename)))
1327     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1328     (cond (read-only (vm-visit-folder fil t))
1329           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1330           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1331           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1332     ;; so that pressing `v' inside VM does prompt within current directory:
1333     (set (make-local-variable 'vm-folder-directory) dir)))
1334
1335 (defun dired-rmail ()
1336   "Run RMAIL on this file."
1337   (interactive)
1338   (rmail (dired-get-filename)))
1339
1340 (defun dired-do-run-mail ()
1341   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1342   (interactive)
1343   (if dired-bind-vm
1344       ;; Read mail folder using vm.
1345       (dired-vm)
1346     ;; Read mail folder using rmail.
1347     (dired-rmail)))
1348
1349 \f
1350 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1351
1352 (or (fboundp 'dired-old-find-buffer-nocreate)
1353     (fset 'dired-old-find-buffer-nocreate
1354           (symbol-function 'dired-find-buffer-nocreate)))
1355
1356 ;;; REDEFINE.
1357 ;;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1358 (defun dired-find-buffer-nocreate (dirname &optional mode)
1359   (if (and dired-find-subdir
1360            ;; don't try to find a wildcard as a subdirectory
1361            (string-equal dirname (file-name-directory dirname)))
1362       (let* ((cur-buf (current-buffer))
1363              (buffers (nreverse
1364                        (dired-buffers-for-dir (expand-file-name dirname))))
1365              (cur-buf-matches (and (memq cur-buf buffers)
1366                                    ;; wildcards must match, too:
1367                                    (equal dired-directory dirname))))
1368         ;; We don't want to switch to the same buffer---
1369         (setq buffers (delq cur-buf buffers));;need setq with delq
1370         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1371             ;; ---unless it's the only possibility:
1372             (and cur-buf-matches cur-buf)))
1373     (dired-old-find-buffer-nocreate dirname mode)))
1374
1375 ;; This should be a builtin
1376 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1377   "Return t if BUFFER1 is more recently used than BUFFER2."
1378   (if (equal buffer1 buffer2)
1379       nil
1380     (let ((more-recent nil)
1381           (list (buffer-list)))
1382       (while (and list
1383                   (not (setq more-recent (equal buffer1 (car list))))
1384                   (not (equal buffer2 (car list))))
1385         (setq list (cdr list)))
1386       more-recent)))
1387
1388 ;;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1389 ;;; (defun dired-buffers-for-dir-exact (dir)
1390 ;;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1391 ;;; ;; at top level, or as subdirectory.
1392 ;;; ;; Top level matches must match the wildcard part too, if any.
1393 ;;; ;; The list is in reverse order of buffer creation, most recent last.
1394 ;;; ;; As a side effect, killed dired buffers for DIR are removed from
1395 ;;; ;; dired-buffers.
1396 ;;;   (let ((alist dired-buffers) result elt)
1397 ;;;     (while alist
1398 ;;;       (setq elt (car alist)
1399 ;;;             alist (cdr alist))
1400 ;;;       (let ((buf (cdr elt)))
1401 ;;;         (if (buffer-name buf)
1402 ;;;             ;; Top level must match exactly against dired-directory in
1403 ;;;             ;; case one of them is a wildcard.
1404 ;;;             (if (or (equal dir (save-excursion (set-buffer buf)
1405 ;;;                                                dired-directory))
1406 ;;;                     (assoc dir (save-excursion (set-buffer buf)
1407 ;;;                                                dired-subdir-alist)))
1408 ;;;                 (setq result (cons buf result)))
1409 ;;;           ;; else buffer is killed - clean up:
1410 ;;;           (setq dired-buffers (delq elt dired-buffers)))))
1411 ;;;     result))
1412
1413 ;;; REDEFINE.
1414 ;;; Redefines dired.el's version of `dired-initial-position'
1415 (defun dired-initial-position (dirname)
1416   "Where point should go in a new listing of DIRNAME.
1417 Point assumed at beginning of new subdir line.
1418 You may redefine this function as you wish, e.g. like in dired-x.el."
1419   (end-of-line)
1420   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1421   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1422
1423 \f
1424 ;; Does anyone use this? - lrd 6/29/93.
1425 ;; Apparently people do use it. - lrd 12/22/97.
1426 (defun dired-mark-sexp (predicate &optional unflag-p)
1427   "Mark files for which PREDICATE returns non-nil.
1428 With a prefix arg, unflag those files instead.
1429
1430 PREDICATE is a lisp expression that can refer to the following symbols:
1431
1432     inode  [integer] the inode of the file (only for ls -i output)
1433     s      [integer] the size of the file for ls -s output
1434                      (usually in blocks or, with -k, in KByte)
1435     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1436     nlink  [integer] number of links to file
1437     uid    [string]  owner
1438     gid    [string]  group  (If the gid is not displayed by ls,
1439                      this will still be set (to the same as uid))
1440     size   [integer] file size in bytes
1441     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1442     name   [string]  the name of the file
1443     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1444
1445 For example, use
1446
1447         (equal 0 size)
1448
1449 to mark all zero length files."
1450   ;; Using sym="" instead of nil avoids the trap of
1451   ;; (string-match "foo" sym) into which a user would soon fall.
1452   ;; Give `equal' instead of `=' in the example, as this works on
1453   ;; integers and strings.
1454   (interactive "xMark if (lisp expr): \nP")
1455   (message "%s" predicate)
1456   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1457         inode s mode nlink uid gid size time name sym)
1458     (dired-mark-if
1459      (save-excursion
1460        (and
1461         ;; Sets vars
1462         ;;                inode s mode nlink uid gid size time name sym
1463
1464         ;; according to current file line.  Returns t for success, nil if
1465         ;; there is no file line.  Upon success, all variables are set, either
1466         ;; to nil or the appropriate value, so they need not be initialized.
1467         ;; Moves point within the current line.
1468         (if (dired-move-to-filename)
1469             (let (pos
1470                   (mode-len 10) ; length of mode string
1471                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1472                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1473               (beginning-of-line)
1474               (forward-char 2)
1475               (if (looking-at dired-re-inode-size)
1476                   (progn
1477                     (goto-char (match-end 0))
1478                     (setq inode (string-to-int (buffer-substring (match-beginning 1)
1479                                                                  (match-end 1)))
1480                           s (string-to-int (buffer-substring (match-beginning 2)
1481                                                              (match-end 2)))))
1482                 (setq inode nil
1483                       s nil))
1484               (setq mode (buffer-substring (point) (+ mode-len (point))))
1485               (forward-char mode-len)
1486               (setq nlink (read (current-buffer)))
1487               ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1488               (setq uid (buffer-substring (+ (point) 1)
1489                                           (progn (forward-word 1) (point))))
1490               (re-search-forward "\\(Jan\\|Feb\\|Mar\\|Apr\\|May\\|Jun\\|\
1491 Jul\\|Aug\\|Sep\\|Oct\\|Nov\\|Dec\\)")
1492               (goto-char (match-beginning 1))
1493               (forward-char -1)
1494               (setq size (string-to-int (buffer-substring (save-excursion
1495                                                             (backward-word 1)
1496                                                             (setq pos (point)))
1497                                                           (point))))
1498               (goto-char pos)
1499               (backward-word 1)
1500               ;; if no gid is displayed, gid will be set to uid
1501               ;; but user will then not reference it anyway in PREDICATE.
1502               (setq gid (buffer-substring (save-excursion
1503                                             (forward-word 1) (point))
1504                                           (point))
1505                     time (buffer-substring (match-beginning 1)
1506                                            (1- (dired-move-to-filename)))
1507                     name (buffer-substring (point)
1508                                            (or
1509                                             (dired-move-to-end-of-filename t)
1510                                             (point)))
1511                     sym  (progn
1512                            (if (looking-at " -> ")
1513                                (buffer-substring
1514                                 (progn (forward-char 4) (point))
1515                                 (progn (end-of-line) (point)))
1516                              "")))
1517               t)
1518           nil)
1519                       (eval predicate)))
1520      (format "'%s file" predicate))))
1521
1522 \f
1523 ;;; FIND FILE AT POINT.
1524
1525 (defvar dired-x-hands-off-my-keys t
1526   "*Non-nil means don't bind `dired-x-find-file' over `find-file' on keyboard.
1527 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1528 If you change this variable after dired-x.el is loaded then do
1529 \\[dired-x-bind-find-file].")
1530
1531 ;;; Bind `dired-x-find-file{-other-window}' over wherever
1532 ;;; `find-file{-other-window}' is bound?
1533 (defun dired-x-bind-find-file ()
1534   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1535 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1536 Binding direction based on `dired-x-hands-off-my-keys'.
1537 This function part of `after-init-hook'."
1538   (interactive)
1539   (if (interactive-p)
1540       (setq dired-x-hands-off-my-keys
1541             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1542   (cond ((not dired-x-hands-off-my-keys)
1543          (substitute-key-definition 'find-file
1544                                     'dired-x-find-file
1545                                     (current-global-map))
1546          (substitute-key-definition 'find-file-other-window
1547                                     'dired-x-find-file-other-window
1548                                     (current-global-map)))
1549         (t
1550          (substitute-key-definition 'dired-x-find-file
1551                                     'find-file
1552                                     (current-global-map))
1553          (substitute-key-definition 'dired-x-find-file-other-window
1554                                     'find-file-other-window
1555                                     (current-global-map))))
1556   ;; Clear mini-buffer.
1557   (message nil))
1558
1559 ;;; Now call it so binding is correct and put on `after-init-hook' in case
1560 ;;; user changes binding.
1561 (dired-x-bind-find-file)
1562 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1563
1564 (defun dired-x-find-file (filename)
1565   "Edit file FILENAME.
1566 May create a new window, or reuse an existing one.
1567 See the function `display-buffer'.
1568
1569 Identical to `find-file' except when called interactively, with a prefix arg
1570 \(e.g., \\[universal-argument]\), in which case it guesses filename near
1571 point.  Useful for editing file mentioned in buffer you are viewing, or to
1572 test if that file exists.  Use minibuffer after snatching filename."
1573   (interactive (list (read-filename-at-point "Find file: ")))
1574   (find-file (expand-file-name filename)))
1575
1576 (defun dired-x-find-file-other-window (filename)
1577   "Edit file FILENAME, in another window.
1578 May create a new window, or reuse an existing one.
1579 See the function `display-buffer'.
1580
1581 Identical to `find-file-other-window' except when called interactively, with a
1582 prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename
1583 near point.  Useful for editing file mentioned in buffer you are viewing, or
1584 to test if that file exists.  Use minibuffer after snatching filename."
1585   (interactive (list (read-filename-at-point "Find file: ")))
1586   (find-file-other-window (expand-file-name filename)))
1587
1588 ;;; Internal functions.
1589 (defun dired-filename-at-point ()
1590
1591   "Get the filename closest to point, but do not change position.
1592 Has a preference for looking backward when not directly on a symbol.  Not
1593 perfect - point must be in middle of or end of filename."
1594
1595   (let ((filename-chars ".a-zA-Z0-9---_/:$+@") ; fixme: allow non-ASCII
1596         (bol (save-excursion (beginning-of-line) (point)))
1597         (eol (save-excursion (end-of-line) (point)))
1598         start end filename prefix)
1599
1600     (save-excursion
1601       ;; First see if just past a filename.
1602       (if (not (eobp))
1603           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1604               (progn
1605                 (skip-chars-backward " \n\t\r({[]})")
1606                 (if (not (bobp))
1607                     (backward-char 1)))))
1608
1609       (if (string-match (concat "[" filename-chars "]")
1610                         (char-to-string (following-char)))
1611           (progn
1612             (skip-chars-backward filename-chars)
1613             (setq start (point))
1614             (setq prefix
1615                   (and (string-match "^\\w+@"
1616                                      (buffer-substring start eol))
1617                        "/"))
1618             (goto-char start)
1619             (if (string-match "[/~]" (char-to-string (preceding-char)))
1620                 (setq start (1- start)))
1621             (skip-chars-forward filename-chars))
1622
1623         (error "No file found around point!"))
1624
1625       ;; Return string.
1626       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1627
1628 (defun read-filename-at-point (prompt)
1629   "Return filename prompting with PROMPT with completion.
1630 If `current-prefix-arg' is non-nil, uses name at point as guess."
1631   (if current-prefix-arg
1632       (let ((guess (dired-filename-at-point)))
1633         (read-file-name prompt
1634                         (file-name-directory guess)
1635                         guess
1636                         nil (file-name-nondirectory guess)))
1637     (read-file-name prompt default-directory)))
1638 \f
1639 ;;; BUG REPORTS
1640
1641 ;; Fixme: get rid of this later.
1642
1643 ;;; This section is provided for reports.  It uses Barry A. Warsaw's
1644 ;;; reporter.el which is bundled with GNU Emacs v19.
1645
1646 (defconst dired-x-help-address "bug-gnu-emacs@gnu.org"
1647   "Address(es) accepting submission of reports on dired-x.el.")
1648
1649 (defconst dired-x-variable-list
1650   (list
1651    'dired-bind-vm
1652    'dired-vm-read-only-folders
1653    'dired-bind-jump
1654    'dired-bind-info
1655    'dired-bind-man
1656    'dired-find-subdir
1657    'dired-enable-local-variables
1658    'dired-local-variables-file
1659    'dired-guess-shell-gnutar
1660    'dired-guess-shell-gzip-quiet
1661    'dired-guess-shell-znew-switches
1662    'dired-guess-shell-alist-user
1663    'dired-clean-up-buffers-too
1664    'dired-omit-files-p
1665    'dired-omit-files
1666    'dired-omit-extensions
1667    )
1668   "List of variables to be appended to reports sent by `dired-x-submit-report'.")
1669
1670 (defun dired-x-submit-report ()
1671   "Submit via reporter.el a bug report on program.
1672 Send report on `dired-x-file' version `dired-x-version,' to
1673 `dired-x-maintainer' at address `dired-x-help-address' listing
1674 variables `dired-x-variable-list' in the message."
1675   (interactive)
1676
1677   (reporter-submit-bug-report
1678    dired-x-help-address                 ; address
1679    "dired-x"                            ; pkgname
1680    dired-x-variable-list                ; varlist
1681    nil nil                              ; pre-/post-hooks
1682    ""))
1683
1684 \f
1685 ;; As Barry Warsaw would say: "This might be useful..."
1686 (provide 'dired-x)
1687
1688 ;;; dired-x.el ends here