lisp/textmodes/paragraphs.el

   1 ;;; paragraphs.el --- paragraph and sentence parsing.
   2
   3 ;; Copyright (C) 1985, 86, 87, 91, 94, 95, 96, 1997, 1999
   4 ;;    Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: wp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package provides the paragraph-oriented commands documented in the
  29 ;; Emacs manual.
  30
  31 ;;; Code:
  32
  33 (defgroup paragraphs nil
  34   "Paragraph and sentence parsing."
  35   :group 'editing)
  36
  37 ;; It isn't useful to use defcustom for this variable
  38 ;; because it is always buffer-local.
  39 (defvar use-hard-newlines nil
  40     "Non-nil means to distinguish hard and soft newlines.
  41 See also the documentation for the function `use-hard-newlines'.")
  42 (make-variable-buffer-local 'use-hard-newlines)
  43
  44 (defun use-hard-newlines (&optional arg insert)
  45   "Minor mode to distinguish hard and soft newlines.
  46 When active, the functions `newline' and `open-line' add the
  47 text-property `hard' to newlines that they insert, and a line is
  48 only considered as a candidate to match `paragraph-start' or
  49 `paragraph-separate' if it follows a hard newline.
  50
  51 Prefix argument says to turn mode on if positive, off if negative.
  52 When the mode is turned on, if there are newlines in the buffer but no hard
  53 newlines, ask the user whether to mark as hard any newlines preceeding a
  54 `paragraph-start' line.  From a program, second arg INSERT specifies whether
  55 to do this; it can be `never' to change nothing, t or `always' to force
  56 marking, `guess' to try to do the right thing with no questions, nil
  57 or anything else to ask the user.
  58
  59 Newlines not marked hard are called \"soft\", and are always internal
  60 to paragraphs.  The fill functions insert and delete only soft newlines."
  61   (interactive (list current-prefix-arg nil))
  62   (if (or (<= (prefix-numeric-value arg) 0)
  63           (and use-hard-newlines (null arg)))
  64       ;; Turn mode off
  65       (setq use-hard-newlines nil)
  66     ;; Turn mode on
  67     ;; Intuit hard newlines --
  68     ;;   mark as hard any newlines preceding a paragraph-start line.
  69     (if (or (eq insert t) (eq insert 'always)
  70             (and (not (eq 'never insert))
  71                  (not use-hard-newlines)
  72                  (not (text-property-any (point-min) (point-max) 'hard t))
  73                  (save-excursion
  74                    (goto-char (point-min))
  75                    (search-forward "\n" nil t))
  76                  (or (eq insert 'guess)
  77                      (y-or-n-p "Make newlines between paragraphs hard? "))))
  78         (save-excursion
  79           (goto-char (point-min))
  80           (while (search-forward "\n" nil t)
  81             (let ((pos (point)))
  82               (move-to-left-margin)
  83               (if (looking-at paragraph-start)
  84                   (progn
  85                     (set-hard-newline-properties (1- pos) pos)
  86                     ;; If paragraph-separate, newline after it is hard too.
  87                     (if (looking-at paragraph-separate)
  88                         (progn
  89                           (end-of-line)
  90                           (if (not (eobp))
  91                               (set-hard-newline-properties
  92                                (point) (1+ (point))))))))))))
  93     (setq use-hard-newlines t)))
  94
  95 (defcustom paragraph-start "[ \t\n\f]" "\
  96 *Regexp for beginning of a line that starts OR separates paragraphs.
  97 This regexp should match lines that separate paragraphs
  98 and should also match lines that start a paragraph
  99 \(and are part of that paragraph).
 100
 101 This is matched against the text at the left margin, which is not necessarily
 102 the beginning of the line, so it should never use \"^\" as an anchor.  This
 103 ensures that the paragraph functions will work equally well within a region
 104 of text indented by a margin setting.
 105
 106 The variable `paragraph-separate' specifies how to distinguish
 107 lines that start paragraphs from lines that separate them.
 108
 109 If the variable `use-hard-newlines' is nonnil, then only lines following a
 110 hard newline are considered to match."
 111   :group 'paragraphs
 112   :type 'regexp)
 113
 114 ;; paragraph-start requires a hard newline, but paragraph-separate does not:
 115 ;; It is assumed that paragraph-separate is distinctive enough to be believed
 116 ;; whenever it occurs, while it is reasonable to set paragraph-start to
 117 ;; something very minimal, even including "." (which makes every hard newline
 118 ;; start a new paragraph).
 119
 120 (defcustom paragraph-separate "[ \t\f]*$"
 121   "*Regexp for beginning of a line that separates paragraphs.
 122 If you change this, you may have to change `paragraph-start' also.
 123
 124 This is matched against the text at the left margin, which is not necessarily
 125 the beginning of the line, so it should not use \"^\" as an anchor.  This
 126 ensures that the paragraph functions will work equally within a region of
 127 text indented by a margin setting."
 128   :group 'paragraphs
 129   :type 'regexp)
 130
 131 (defcustom sentence-end (purecopy "[.?!][]\"')}]*\\($\\| $\\|\t\\|  \\)[ \t\n]*")
 132   "*Regexp describing the end of a sentence.
 133 All paragraph boundaries also end sentences, regardless.
 134
 135 The default value specifies that in order to be recognized as the end
 136 of a sentence, the ending period, question mark, or exclamation point
 137 must be followed by two spaces, unless it's inside some sort of quotes
 138 or parenthesis.
 139
 140 See also the variable `sentence-end-double-space' and Info node `Sentences'."
 141   :group 'paragraphs
 142   :type 'regexp)
 143
 144 (defcustom page-delimiter "^\014"
 145   "*Regexp describing line-beginnings that separate pages."
 146   :group 'paragraphs
 147   :type 'regexp)
 148
 149 (defcustom paragraph-ignore-fill-prefix nil
 150   "*Non-nil means the paragraph commands are not affected by `fill-prefix'.
 151 This is desirable in modes where blank lines are the paragraph delimiters."
 152   :group 'paragraphs
 153   :type 'boolean)
 154
 155 (defun forward-paragraph (&optional arg)
 156   "Move forward to end of paragraph.
 157 With argument ARG, do it ARG times;
 158 a negative argument ARG = -N means move backward N paragraphs.
 159
 160 A line which `paragraph-start' matches either separates paragraphs
 161 \(if `paragraph-separate' matches it also) or is the first line of a paragraph.
 162 A paragraph end is the beginning of a line which is not part of the paragraph
 163 to which the end of the previous line belongs, or the end of the buffer."
 164   (interactive "p")
 165   (or arg (setq arg 1))
 166   (let* ((opoint (point))
 167          (fill-prefix-regexp
 168           (and fill-prefix (not (equal fill-prefix ""))
 169                (not paragraph-ignore-fill-prefix)
 170                (regexp-quote fill-prefix)))
 171          ;; Remove ^ from paragraph-start and paragraph-sep if they are there.
 172          ;; These regexps shouldn't be anchored, because we look for them
 173          ;; starting at the left-margin.  This allows paragraph commands to
 174          ;; work normally with indented text.
 175          ;; This hack will not find problem cases like "whatever\\|^something".
 176          (paragraph-start (if (and (not (equal "" paragraph-start))
 177                                    (equal ?^ (aref paragraph-start 0)))
 178                               (substring paragraph-start 1)
 179                             paragraph-start))
 180          (paragraph-separate (if (and (not (equal "" paragraph-separate))
 181                                       (equal ?^ (aref paragraph-separate 0)))
 182                                  (substring paragraph-separate 1)
 183                             paragraph-separate))
 184          (paragraph-separate
 185           (if fill-prefix-regexp
 186               (concat paragraph-separate "\\|"
 187                       fill-prefix-regexp "[ \t]*$")
 188             paragraph-separate))
 189          ;; This is used for searching.
 190          (sp-paragraph-start (concat "^[ \t]*\\(" paragraph-start "\\)"))
 191          start found-start)
 192     (while (and (< arg 0) (not (bobp)))
 193       (if (and (not (looking-at paragraph-separate))
 194                (re-search-backward "^\n" (max (1- (point)) (point-min)) t)
 195                (looking-at paragraph-separate))
 196           nil
 197         (setq start (point))
 198         ;; Move back over paragraph-separating lines.
 199         (forward-char -1) (beginning-of-line)
 200         (while (and (not (bobp))
 201                     (progn (move-to-left-margin)
 202                            (looking-at paragraph-separate)))
 203           (forward-line -1))
 204         (if (bobp)
 205             nil
 206           ;; Go to end of the previous (non-separating) line.
 207           (end-of-line)
 208           ;; Search back for line that starts or separates paragraphs.
 209           (if (if fill-prefix-regexp
 210                   ;; There is a fill prefix; it overrides paragraph-start.
 211                   (let (multiple-lines)
 212                     (while (and (progn (beginning-of-line) (not (bobp)))
 213                                 (progn (move-to-left-margin)
 214                                        (not (looking-at paragraph-separate)))
 215                                 (looking-at fill-prefix-regexp))
 216                       (if (not (= (point) start))
 217                           (setq multiple-lines t))
 218                       (forward-line -1))
 219                     (move-to-left-margin)
 220 ;;; This deleted code caused a long hanging-indent line
 221 ;;; not to be filled together with the following lines.
 222 ;;;                 ;; Don't move back over a line before the paragraph
 223 ;;;                 ;; which doesn't start with fill-prefix
 224 ;;;                 ;; unless that is the only line we've moved over.
 225 ;;;                 (and (not (looking-at fill-prefix-regexp))
 226 ;;;                      multiple-lines
 227 ;;;                      (forward-line 1))
 228                     (not (bobp)))
 229                 (while (and (re-search-backward sp-paragraph-start nil 1)
 230                             (setq found-start t)
 231                             ;; Found a candidate, but need to check if it is a
 232                             ;; REAL paragraph-start.
 233                             (progn (setq start (point))
 234                                    (move-to-left-margin)
 235                                    (not (looking-at paragraph-separate)))
 236                             (not (and (looking-at paragraph-start)
 237                                       (not
 238                                        (and use-hard-newlines
 239                                             (not (bobp))
 240                                             (not (get-text-property (1- start)
 241                                                                     'hard)))))))
 242                   (setq found-start nil)
 243                   (goto-char start))
 244                 found-start)
 245               ;; Found one.
 246               (progn
 247                 ;; Move forward over paragraph separators.
 248                 ;; We know this cannot reach the place we started
 249                 ;; because we know we moved back over a non-separator.
 250                 (while (and (not (eobp))
 251                             (progn (move-to-left-margin)
 252                                    (looking-at paragraph-separate)))
 253                   (forward-line 1))
 254                 ;; If line before paragraph is just margin, back up to there.
 255                 (end-of-line 0)
 256                 (if (> (current-column) (current-left-margin))
 257                     (forward-char 1)
 258                   (skip-chars-backward " \t")
 259                   (if (not (bolp))
 260                       (forward-line 1))))
 261             ;; No starter or separator line => use buffer beg.
 262             (goto-char (point-min)))))
 263       (setq arg (1+ arg)))
 264     (while (and (> arg 0) (not (eobp)))
 265       ;; Move forward over separator lines, and one more line.
 266       (while (prog1 (and (not (eobp))
 267                          (progn (move-to-left-margin) (not (eobp)))
 268                          (looking-at paragraph-separate))
 269                (forward-line 1)))
 270       (if fill-prefix-regexp
 271           ;; There is a fill prefix; it overrides paragraph-start.
 272           (while (and (not (eobp))
 273                       (progn (move-to-left-margin) (not (eobp)))
 274                       (not (looking-at paragraph-separate))
 275                       (looking-at fill-prefix-regexp))
 276             (forward-line 1))
 277         (while (and (re-search-forward sp-paragraph-start nil 1)
 278                     (progn (setq start (match-beginning 0))
 279                            (goto-char start)
 280                            (not (eobp)))
 281                     (progn (move-to-left-margin)
 282                            (not (looking-at paragraph-separate)))
 283                     (or (not (looking-at paragraph-start))
 284                         (and use-hard-newlines
 285                              (not (get-text-property (1- start) 'hard)))))
 286           (forward-char 1))
 287         (if (< (point) (point-max))
 288             (goto-char start)))
 289       (setq arg (1- arg)))
 290     (constrain-to-field nil opoint t)))
 291
 292 (defun backward-paragraph (&optional arg)
 293   "Move backward to start of paragraph.
 294 With argument ARG, do it ARG times;
 295 a negative argument ARG = -N means move forward N paragraphs.
 296
 297 A paragraph start is the beginning of a line which is a
 298 `first-line-of-paragraph' or which is ordinary text and follows a
 299 paragraph-separating line; except: if the first real line of a
 300 paragraph is preceded by a blank line, the paragraph starts at that
 301 blank line.
 302
 303 See `forward-paragraph' for more information."
 304   (interactive "p")
 305   (or arg (setq arg 1))
 306   (forward-paragraph (- arg)))
 307
 308 (defun mark-paragraph ()
 309   "Put point at beginning of this paragraph, mark at end.
 310 The paragraph marked is the one that contains point or follows point."
 311   (interactive)
 312   (forward-paragraph 1)
 313   (push-mark nil t t)
 314   (backward-paragraph 1))
 315
 316 (defun kill-paragraph (arg)
 317   "Kill forward to end of paragraph.
 318 With arg N, kill forward to Nth end of paragraph;
 319 negative arg -N means kill backward to Nth start of paragraph."
 320   (interactive "p")
 321   (kill-region (point) (progn (forward-paragraph arg) (point))))
 322
 323 (defun backward-kill-paragraph (arg)
 324   "Kill back to start of paragraph.
 325 With arg N, kill back to Nth start of paragraph;
 326 negative arg -N means kill forward to Nth end of paragraph."
 327   (interactive "p")
 328   (kill-region (point) (progn (backward-paragraph arg) (point))))
 329
 330 (defun transpose-paragraphs (arg)
 331   "Interchange this (or next) paragraph with previous one."
 332   (interactive "*p")
 333   (transpose-subr 'forward-paragraph arg))
 334
 335 (defun start-of-paragraph-text ()
 336   (let ((opoint (point)) npoint)
 337     (forward-paragraph -1)
 338     (setq npoint (point))
 339     (skip-chars-forward " \t\n")
 340     ;; If the range of blank lines found spans the original start point,
 341     ;; try again from the beginning of it.
 342     ;; Must be careful to avoid infinite loop
 343     ;; when following a single return at start of buffer.
 344     (if (and (>= (point) opoint) (< npoint opoint))
 345         (progn
 346           (goto-char npoint)
 347           (if (> npoint (point-min))
 348               (start-of-paragraph-text))))))
 349
 350 (defun end-of-paragraph-text ()
 351   (let ((opoint (point)))
 352     (forward-paragraph 1)
 353     (if (eq (preceding-char) ?\n) (forward-char -1))
 354     (if (<= (point) opoint)
 355         (progn
 356           (forward-char 1)
 357           (if (< (point) (point-max))
 358               (end-of-paragraph-text))))))
 359
 360 (defun forward-sentence (&optional arg)
 361   "Move forward to next `sentence-end'.  With argument, repeat.
 362 With negative argument, move backward repeatedly to `sentence-beginning'.
 363
 364 The variable `sentence-end' is a regular expression that matches ends of
 365 sentences.  Also, every paragraph boundary terminates sentences as well."
 366   (interactive "p")
 367   (or arg (setq arg 1))
 368   (let ((opoint (point)))
 369     (while (< arg 0)
 370       (let ((par-beg (save-excursion (start-of-paragraph-text) (point))))
 371        (if (re-search-backward (concat sentence-end "[^ \t\n]") par-beg t)
 372            (goto-char (1- (match-end 0)))
 373          (goto-char par-beg)))
 374       (setq arg (1+ arg)))
 375     (while (> arg 0)
 376       (let ((par-end (save-excursion (end-of-paragraph-text) (point))))
 377        (if (re-search-forward sentence-end par-end t)
 378            (skip-chars-backward " \t\n")
 379          (goto-char par-end)))
 380       (setq arg (1- arg)))
 381     (constrain-to-field nil opoint t)))
 382
 383 (defun backward-sentence (&optional arg)
 384   "Move backward to start of sentence.  With arg, do it arg times.
 385 See `forward-sentence' for more information."
 386   (interactive "p")
 387   (or arg (setq arg 1))
 388   (forward-sentence (- arg)))
 389
 390 (defun kill-sentence (&optional arg)
 391   "Kill from point to end of sentence.
 392 With arg, repeat; negative arg -N means kill back to Nth start of sentence."
 393   (interactive "p")
 394   (kill-region (point) (progn (forward-sentence arg) (point))))
 395
 396 (defun backward-kill-sentence (&optional arg)
 397   "Kill back from point to start of sentence.
 398 With arg, repeat, or kill forward to Nth end of sentence if negative arg -N."
 399   (interactive "p")
 400   (kill-region (point) (progn (backward-sentence arg) (point))))
 401
 402 (defun mark-end-of-sentence (arg)
 403   "Put mark at end of sentence.  Arg works as in `forward-sentence'."
 404   (interactive "p")
 405   (push-mark
 406     (save-excursion
 407       (forward-sentence arg)
 408       (point))
 409     nil t))
 410
 411 (defun transpose-sentences (arg)
 412   "Interchange this (next) and previous sentence."
 413   (interactive "*p")
 414   (transpose-subr 'forward-sentence arg))
 415
 416 ;;; paragraphs.el ends here