lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains a VC backend for the git version control
  28 ;; system.
  29 ;;
  30
  31 ;;; Installation:
  32
  33 ;; To install: put this file on the load-path and add Git to the list
  34 ;; of supported backends in `vc-handled-backends'; the following line,
  35 ;; placed in your ~/.emacs, will accomplish this:
  36 ;;
  37 ;;     (add-to-list 'vc-handled-backends 'Git)
  38
  39 ;;; Todo:
  40 ;;  - check if more functions could use vc-git-command instead
  41 ;;     of start-process.
  42 ;;  - changelog generation
  43
  44 ;; Implement the rest of the vc interface. See the comment at the
  45 ;; beginning of vc.el. The current status is:
  46 ;; ("??" means: "figure out what to do about it")
  47 ;;
  48 ;; FUNCTION NAME                                   STATUS
  49 ;; BACKEND PROPERTIES
  50 ;; * revision-granularity                          OK
  51 ;; STATE-QUERYING FUNCTIONS
  52 ;; * registered (file)                             OK
  53 ;; * state (file)                                  OK
  54 ;; - state-heuristic (file)                        NOT NEEDED
  55 ;; - dir-state (dir)                               OK
  56 ;; * working-revision (file)                       OK
  57 ;; - latest-on-branch-p (file)                     NOT NEEDED
  58 ;; * checkout-model (file)                         OK
  59 ;; - workfile-unchanged-p (file)                   OK
  60 ;; - mode-line-string (file)                       OK
  61 ;; - dired-state-info (file)                       OK
  62 ;; STATE-CHANGING FUNCTIONS
  63 ;; * create-repo ()                                OK
  64 ;; * register (files &optional rev comment)        OK
  65 ;; - init-revision (file)                          NOT NEEDED
  66 ;; - responsible-p (file)                          OK
  67 ;; - could-register (file)                         NOT NEEDED, DEFAULT IS GOOD
  68 ;; - receive-file (file rev)                       NOT NEEDED
  69 ;; - unregister (file)                             OK
  70 ;; * checkin (files rev comment)                   OK
  71 ;; * find-revision (file rev buffer)               OK
  72 ;; * checkout (file &optional editable rev)        OK
  73 ;; * revert (file &optional contents-done)         OK
  74 ;; - rollback (files)                              COULD BE SUPPORTED
  75 ;; - merge (file rev1 rev2)                        It would be possible to merge changes into
  76 ;;                                                 a single file, but when committing they
  77 ;;                                                 wouldn't be identified as a merge by git,
  78 ;;                                                 so it's probably not a good idea.
  79 ;; - merge-news (file)                             see `merge'
  80 ;; - steal-lock (file &optional revision)          NOT NEEDED
  81 ;; HISTORY FUNCTIONS
  82 ;; * print-log (files &optional buffer)            OK
  83 ;; - log-view-mode ()                              OK
  84 ;; - show-log-entry (revision)                     NOT NEEDED, DEFAULT IS GOOD
  85 ;; - wash-log (file)                               COULD BE SUPPORTED
  86 ;; - logentry-check ()                             NOT NEEDED
  87 ;; - comment-history (file)                        ??
  88 ;; - update-changelog (files)                      COULD BE SUPPORTED
  89 ;; * diff (file &optional rev1 rev2 buffer)        OK
  90 ;; - revision-completion-table (files)             NEEDED?
  91 ;; - annotate-command (file buf &optional rev)     OK
  92 ;; - annotate-time ()                              OK
  93 ;; - annotate-current-time ()                      NOT NEEDED
  94 ;; - annotate-extract-revision-at-line ()          OK
  95 ;; SNAPSHOT SYSTEM
  96 ;; - create-snapshot (dir name branchp)            OK
  97 ;; - assign-name (file name)                       NOT NEEDED
  98 ;; - retrieve-snapshot (dir name update)           OK, needs to update buffers
  99 ;; MISCELLANEOUS
 100 ;; - make-version-backups-p (file)                 NOT NEEDED
 101 ;; - repository-hostname (dirname)                 NOT NEEDED
 102 ;; - previous-revision (file rev)                  OK
 103 ;; - next-revision (file rev)                      OK
 104 ;; - check-headers ()                              COULD BE SUPPORTED
 105 ;; - clear-headers ()                              NOT NEEDED
 106 ;; - delete-file (file)                            OK
 107 ;; - rename-file (old new)                         OK
 108 ;; - find-file-hook ()                             NOT NEEDED
 109 ;; - find-file-not-found-hook ()                   NOT NEEDED
 110
 111 (eval-when-compile (require 'cl) (require 'vc))
 112
 113 (defvar git-commits-coding-system 'utf-8
 114   "Default coding system for git commits.")
 115
 116 ;;; BACKEND PROPERTIES
 117
 118 (defun vc-git-revision-granularity ()
 119      'repository)
 120
 121 ;;; STATE-QUERYING FUNCTIONS
 122
 123 ;;;###autoload (defun vc-git-registered (file)
 124 ;;;###autoload   "Return non-nil if FILE is registered with git."
 125 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 126 ;;;###autoload       (progn
 127 ;;;###autoload         (load "vc-git")
 128 ;;;###autoload         (vc-git-registered file))))
 129
 130 (defun vc-git-registered (file)
 131   "Check whether FILE is registered with git."
 132   (when (vc-git-root file)
 133     (with-temp-buffer
 134       (let* ((dir (file-name-directory file))
 135              (name (file-relative-name file dir)))
 136         (and (ignore-errors
 137               (when dir (cd dir))
 138               (eq 0 (call-process "git" nil '(t nil) nil "ls-files" "-c" "-z" "--" name)))
 139              (let ((str (buffer-string)))
 140                (and (> (length str) (length name))
 141                     (string= (substring str 0 (1+ (length name))) (concat name "\0")))))))))
 142
 143 (defun vc-git-state (file)
 144   "Git-specific version of `vc-state'."
 145   (call-process "git" nil nil nil "add" "--refresh" "--" (file-relative-name file))
 146   (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 147     (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} [ADMU]\0[^\0]+\0" diff))
 148         'edited
 149       'up-to-date)))
 150
 151 (defun vc-git-dir-state (dir)
 152   (with-temp-buffer
 153     (vc-git-command (current-buffer) nil nil "ls-files" "-t")
 154     (goto-char (point-min))
 155     (let ((status-char nil)
 156           (file nil))
 157       (while (not (eobp))
 158         (setq status-char (char-after))
 159         (setq file
 160               (expand-file-name
 161                (buffer-substring-no-properties (+ (point) 2) (line-end-position))))
 162         (cond
 163          ;; The rest of the possible states in "git ls-files -t" output:
 164          ;;      R              removed/deleted
 165          ;;      K              to be killed
 166          ;; should not show up in vc-dired, so don't deal with them
 167          ;; here.
 168          ((eq status-char ?H)
 169           (vc-file-setprop file 'vc-state 'up-to-date))
 170          ((eq status-char ?M)
 171           (vc-file-setprop file 'vc-state 'edited))
 172          ((eq status-char ?C)
 173           (vc-file-setprop file 'vc-state 'edited))
 174          ((eq status-char ??)
 175           (vc-file-setprop file 'vc-backend 'none)
 176           (vc-file-setprop file 'vc-state 'nil)))
 177         (forward-line)))))
 178
 179 (defun vc-git-working-revision (file)
 180   "Git-specific version of `vc-working-revision'."
 181   (let ((str (with-output-to-string
 182                (with-current-buffer standard-output
 183                  (call-process "git" nil '(t nil) nil "symbolic-ref" "HEAD")))))
 184     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 185         (match-string 2 str)
 186       str)))
 187
 188 (defun vc-git-checkout-model (file)
 189   'implicit)
 190
 191 (defun vc-git-workfile-unchanged-p (file)
 192   (eq 'up-to-date (vc-git-state file)))
 193
 194 (defun vc-git-mode-line-string (file)
 195   "Return string for placement into the modeline for FILE."
 196   (let* ((branch (vc-git-working-revision file))
 197          (def-ml (vc-default-mode-line-string 'Git file))
 198          (help-echo (get-text-property 0 'help-echo def-ml)))
 199     (if (zerop (length branch))
 200         (propertize
 201          (concat def-ml "!")
 202          'help-echo (concat help-echo "\nNo current branch (detached HEAD)"))
 203       (propertize def-ml
 204                   'help-echo (concat help-echo "\nCurrent branch: " branch)))))
 205
 206 (defun vc-git-dired-state-info (file)
 207   "Git-specific version of `vc-dired-state-info'."
 208   (let ((git-state (vc-state file)))
 209     (if (eq git-state 'edited)
 210         "(modified)"
 211       ;; fall back to the default VC representation
 212       (vc-default-dired-state-info 'Git file))))
 213
 214 ;;; STATE-CHANGING FUNCTIONS
 215
 216 (defun vc-git-create-repo ()
 217   "Create a new Git repository."
 218   (vc-git-command nil 0 nil "init"))
 219
 220 (defun vc-git-register (files &optional rev comment)
 221   "Register FILE into the git version-control system."
 222   (vc-git-command nil 0 files "update-index" "--add" "--"))
 223
 224 (defalias 'vc-git-responsible-p 'vc-git-root)
 225
 226 (defun vc-git-unregister (file)
 227   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 228
 229
 230 (defun vc-git-checkin (files rev comment)
 231   (let ((coding-system-for-write git-commits-coding-system))
 232     (vc-git-command nil 0 files "commit" "-m" comment "--only" "--")))
 233
 234 (defun vc-git-find-revision (file rev buffer)
 235   (let ((coding-system-for-read 'binary)
 236         (coding-system-for-write 'binary)
 237         (fullname (substring
 238                    (vc-git--run-command-string
 239                     file "ls-files" "-z" "--full-name" "--")
 240                    0 -1)))
 241     (vc-git-command
 242      buffer 0
 243      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 244
 245 (defun vc-git-checkout (file &optional editable rev)
 246   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 247
 248 (defun vc-git-revert (file &optional contents-done)
 249   "Revert FILE to the version stored in the git repository."
 250   (if contents-done
 251       (vc-git-command nil 0 file "update-index" "--")
 252     (vc-git-command nil 0 file "checkout" "HEAD")))
 253
 254 ;;; HISTORY FUNCTIONS
 255
 256 (defun vc-git-print-log (files &optional buffer)
 257   "Get change log associated with FILES."
 258   (let ((coding-system-for-read git-commits-coding-system)
 259         ;; Support both the old print-log interface that passes a
 260         ;; single file, and the new one that passes a file list.
 261         (flist (if (listp files) files (list files))))
 262     ;; `vc-do-command' creates the buffer, but we need it before running
 263     ;; the command.
 264     (vc-setup-buffer buffer)
 265     ;; If the buffer exists from a previous invocation it might be
 266     ;; read-only.
 267     (let ((inhibit-read-only t))
 268       ;; XXX `log-view-mode' needs to have something to identify where
 269       ;; the log for each individual file starts. It seems that by
 270       ;; default git does not output this info. So loop here and call
 271       ;; "git rev-list" on each file separately to make sure that each
 272       ;; file gets a "File:" header before the corresponding
 273       ;; log. Maybe there is a way to do this with one command...
 274       (dolist (file flist)
 275         (with-current-buffer
 276             buffer
 277           (insert "File: " (file-name-nondirectory file) "\n"))
 278         (vc-git-command buffer 'async (file-relative-name file)
 279                         "rev-list" "--pretty" "HEAD" "--")))))
 280
 281 (defvar log-view-message-re)
 282 (defvar log-view-file-re)
 283 (defvar log-view-font-lock-keywords)
 284
 285 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 286   (require 'add-log) ;; we need the faces add-log
 287   ;; Don't have file markers, so use impossible regexp.
 288   (set (make-local-variable 'log-view-file-re) "^File:[ \t]+\\(.+\\)")
 289   (set (make-local-variable 'log-view-message-re)
 290        "^commit *\\([0-9a-z]+\\)")
 291   (set (make-local-variable 'log-view-font-lock-keywords)
 292        (append
 293        `((,log-view-message-re  (1 'change-log-acknowledgement))
 294          (,log-view-file-re (1 'change-log-file-face)))
 295          ;; Handle the case:
 296          ;; user: foo@bar
 297          '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 298             (1 'change-log-email))
 299            ;; Handle the case:
 300            ;; user: FirstName LastName <foo@bar>
 301            ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 302             (1 'change-log-name)
 303             (2 'change-log-email))
 304            ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 305             (1 'change-log-name))
 306            ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 307             (1 'change-log-name)
 308             (2 'change-log-email))
 309            ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
 310             (1 'change-log-acknowledgement)
 311             (2 'change-log-acknowledgement))
 312            ("^Date:   \\(.+\\)" (1 'change-log-date))
 313            ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 314
 315 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 316   (let ((buf (or buffer "*vc-diff*")))
 317     (if (and rev1 rev2)
 318         (vc-git-command buf 1 files "diff-tree" "--exit-code" "-p" rev1 rev2 "--")
 319       (vc-git-command buf 1 files "diff-index" "--exit-code" "-p" (or rev1 "HEAD") "--"))))
 320
 321 (defun vc-git-revision-table (files)
 322   ;; What about `files'?!?  --Stef
 323   (let ((table (list "HEAD")))
 324     (with-temp-buffer
 325       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
 326       (goto-char (point-min))
 327       (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
 328         (push (match-string 2) table)))
 329     table))
 330
 331 (defun vc-git-revision-completion-table (files)
 332   (lexical-let ((files files)
 333                 table)
 334     (setq table (lazy-completion-table
 335                  table (lambda () (vc-git-revision-table files))))
 336     table))
 337
 338 (defun vc-git-annotate-command (file buf &optional rev)
 339   ;; FIXME: rev is ignored
 340   (let ((name (file-relative-name file)))
 341     (vc-git-command buf 0 name "blame" (if rev (concat "-r" rev)))))
 342
 343 (defun vc-git-annotate-time ()
 344   (and (re-search-forward "[0-9a-f]+ (.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+)" nil t)
 345        (vc-annotate-convert-time
 346         (apply #'encode-time (mapcar (lambda (match) (string-to-number (match-string match))) '(6 5 4 3 2 1 7))))))
 347
 348 (defun vc-git-annotate-extract-revision-at-line ()
 349  (save-excursion
 350    (move-beginning-of-line 1)
 351    (and (looking-at "[0-9a-f]+")
 352         (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
 353
 354 ;;; SNAPSHOT SYSTEM
 355
 356 (defun vc-git-create-snapshot (dir name branchp)
 357   (let ((default-directory dir))
 358     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 359          (if branchp
 360              (vc-git-command nil 0 nil "checkout" "-b" name)
 361            (vc-git-command nil 0 nil "tag" name)))))
 362
 363 (defun vc-git-retrieve-snapshot (dir name update)
 364   (let ((default-directory dir))
 365     (vc-git-command nil 0 nil "checkout" name)
 366     ;; FIXME: update buffers if `update' is true
 367     ))
 368
 369
 370 ;;; MISCELLANEOUS
 371
 372 (defun vc-git-previous-revision (file rev)
 373   "Git-specific version of `vc-previous-revision'."
 374   (let ((default-directory (file-name-directory (expand-file-name file)))
 375         (file (file-name-nondirectory file)))
 376     (vc-git-symbolic-commit
 377      (with-temp-buffer
 378        (and
 379         (zerop
 380          (call-process "git" nil '(t nil) nil "rev-list"
 381                        "-2" rev "--" file))
 382         (goto-char (point-max))
 383         (bolp)
 384         (zerop (forward-line -1))
 385         (not (bobp))
 386         (buffer-substring-no-properties
 387            (point)
 388            (1- (point-max))))))))
 389
 390 (defun vc-git-next-revision (file rev)
 391   "Git-specific version of `vc-next-revision'."
 392   (let* ((default-directory (file-name-directory
 393                              (expand-file-name file)))
 394         (file (file-name-nondirectory file))
 395         (current-rev
 396          (with-temp-buffer
 397            (and
 398             (zerop
 399              (call-process "git" nil '(t nil) nil "rev-list"
 400                            "-1" rev "--" file))
 401             (goto-char (point-max))
 402             (bolp)
 403             (zerop (forward-line -1))
 404             (bobp)
 405             (buffer-substring-no-properties
 406              (point)
 407              (1- (point-max)))))))
 408     (and current-rev
 409          (vc-git-symbolic-commit
 410           (with-temp-buffer
 411             (and
 412              (zerop
 413               (call-process "git" nil '(t nil) nil "rev-list"
 414                             "HEAD" "--" file))
 415              (goto-char (point-min))
 416              (search-forward current-rev nil t)
 417              (zerop (forward-line -1))
 418              (buffer-substring-no-properties
 419               (point)
 420               (progn (forward-line 1) (1- (point))))))))))
 421
 422 (defun vc-git-delete-file (file)
 423   (vc-git-command nil 0 file "rm" "-f" "--"))
 424
 425 (defun vc-git-rename-file (old new)
 426   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 427
 428 \f
 429 ;;; Internal commands
 430
 431 (defun vc-git-root (file)
 432   (vc-find-root file ".git"))
 433
 434 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 435   "A wrapper around `vc-do-command' for use in vc-git.el.
 436 The difference to vc-do-command is that this function always invokes `git'."
 437   (apply 'vc-do-command buffer okstatus "git" file-or-list flags))
 438
 439 (defun vc-git--run-command-string (file &rest args)
 440   "Run a git command on FILE and return its output as string."
 441   (let* ((ok t)
 442          (str (with-output-to-string
 443                 (with-current-buffer standard-output
 444                   (unless (eq 0 (apply #'call-process "git" nil '(t nil) nil
 445                                        (append args (list (file-relative-name file)))))
 446                     (setq ok nil))))))
 447     (and ok str)))
 448
 449 (defun vc-git-symbolic-commit (commit)
 450   "Translate COMMIT string into symbolic form.
 451 Returns nil if not possible."
 452   (and commit
 453        (with-temp-buffer
 454          (and
 455           (zerop
 456            (call-process "git" nil '(t nil) nil "name-rev"
 457                          "--name-only" "--tags"
 458                          commit))
 459           (goto-char (point-min))
 460           (= (forward-line 2) 1)
 461           (bolp)
 462           (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 463
 464 (provide 'vc-git)
 465
 466 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 467 ;;; vc-git.el ends here