lisp/gud.el

   1 ;;; gud.el --- Grand Unified Debugger mode for gdb, sdb, dbx, or xdb
   2 ;;;            under Emacs
   3
   4 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   5 ;; Maintainer: FSF
   6 ;; Version: 1.3
   7 ;; Keywords: unix, tools
   8
   9 ;; Copyright (C) 1992, 1993, 1994 Free Software Foundation, Inc.
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  25 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; The ancestral gdb.el was by W. Schelter <wfs@rascal.ics.utexas.edu>
  30 ;; It was later rewritten by rms.  Some ideas were due to Masanobu.
  31 ;; Grand Unification (sdb/dbx support) by Eric S. Raymond <esr@thyrsus.com>
  32 ;; The overloading code was then rewritten by Barry Warsaw <bwarsaw@cen.com>,
  33 ;; who also hacked the mode to use comint.el.  Shane Hartman <shane@spr.com>
  34 ;; added support for xdb (HPUX debugger).  Rick Sladkey <jrs@world.std.com>
  35 ;; wrote the GDB command completion code.  Dave Love <d.love@dl.ac.uk>
  36 ;; added the IRIX kluge and re-implemented the Mips-ish variant.
  37
  38 ;;; Code:
  39
  40 (require 'comint)
  41 (require 'etags)
  42
  43 ;; ======================================================================
  44 ;; GUD commands must be visible in C buffers visited by GUD
  45
  46 (defvar gud-key-prefix "\C-x\C-a"
  47   "Prefix of all GUD commands valid in C buffers.")
  48
  49 (global-set-key (concat gud-key-prefix "\C-l") 'gud-refresh)
  50 (define-key ctl-x-map " " 'gud-break)   ;; backward compatibility hack
  51
  52 ;; ======================================================================
  53 ;; the overloading mechanism
  54
  55 (defun gud-overload-functions (gud-overload-alist)
  56   "Overload functions defined in GUD-OVERLOAD-ALIST.
  57 This association list has elements of the form
  58      (ORIGINAL-FUNCTION-NAME  OVERLOAD-FUNCTION)"
  59   (mapcar
  60    (function (lambda (p) (fset (car p) (symbol-function (cdr p)))))
  61    gud-overload-alist))
  62
  63 (defun gud-massage-args (file args)
  64   (error "GUD not properly entered"))
  65
  66 (defun gud-marker-filter (str)
  67   (error "GUD not properly entered"))
  68
  69 (defun gud-find-file (f)
  70   (error "GUD not properly entered"))
  71 \f
  72 ;; ======================================================================
  73 ;; command definition
  74
  75 ;; This macro is used below to define some basic debugger interface commands.
  76 ;; Of course you may use `gud-def' with any other debugger command, including
  77 ;; user defined ones.
  78
  79 ;; A macro call like (gud-def FUNC NAME KEY DOC) expands to a form
  80 ;; which defines FUNC to send the command NAME to the debugger, gives
  81 ;; it the docstring DOC, and binds that function to KEY in the GUD
  82 ;; major mode.  The function is also bound in the global keymap with the
  83 ;; GUD prefix.
  84
  85 (defmacro gud-def (func cmd key &optional doc)
  86   "Define FUNC to be a command sending STR and bound to KEY, with
  87 optional doc string DOC.  Certain %-escapes in the string arguments
  88 are interpreted specially if present.  These are:
  89
  90   %f    name (without directory) of current source file.
  91   %d    directory of current source file.
  92   %l    number of current source line
  93   %e    text of the C lvalue or function-call expression surrounding point.
  94   %a    text of the hexadecimal address surrounding point
  95   %p    prefix argument to the command (if any) as a number
  96
  97   The `current' source file is the file of the current buffer (if
  98 we're in a C file) or the source file current at the last break or
  99 step (if we're in the GUD buffer).
 100   The `current' line is that of the current buffer (if we're in a
 101 source file) or the source line number at the last break or step (if
 102 we're in the GUD buffer)."
 103   (list 'progn
 104         (list 'defun func '(arg)
 105               (or doc "")
 106               '(interactive "p")
 107               (list 'gud-call cmd 'arg))
 108         (if key
 109             (list 'define-key
 110                   '(current-local-map)
 111                   (concat "\C-c" key)
 112                   (list 'quote func)))
 113         (if key
 114             (list 'global-set-key
 115                   (list 'concat 'gud-key-prefix key)
 116                   (list 'quote func)))))
 117
 118 ;; Where gud-display-frame should put the debugging arrow.  This is
 119 ;; set by the marker-filter, which scans the debugger's output for
 120 ;; indications of the current program counter.
 121 (defvar gud-last-frame nil)
 122
 123 ;; Used by gud-refresh, which should cause gud-display-frame to redisplay
 124 ;; the last frame, even if it's been called before and gud-last-frame has
 125 ;; been set to nil.
 126 (defvar gud-last-last-frame nil)
 127
 128 ;; All debugger-specific information is collected here.
 129 ;; Here's how it works, in case you ever need to add a debugger to the mode.
 130 ;;
 131 ;; Each entry must define the following at startup:
 132 ;;
 133 ;;<name>
 134 ;; comint-prompt-regexp
 135 ;; gud-<name>-massage-args
 136 ;; gud-<name>-marker-filter
 137 ;; gud-<name>-find-file
 138 ;;
 139 ;; The job of the massage-args method is to modify the given list of
 140 ;; debugger arguments before running the debugger.
 141 ;;
 142 ;; The job of the marker-filter method is to detect file/line markers in
 143 ;; strings and set the global gud-last-frame to indicate what display
 144 ;; action (if any) should be triggered by the marker.  Note that only
 145 ;; whatever the method *returns* is displayed in the buffer; thus, you
 146 ;; can filter the debugger's output, interpreting some and passing on
 147 ;; the rest.
 148 ;;
 149 ;; The job of the find-file method is to visit and return the buffer indicated
 150 ;; by the car of gud-tag-frame.  This may be a file name, a tag name, or
 151 ;; something else.
 152 \f
 153 ;; ======================================================================
 154 ;; gdb functions
 155
 156 ;;; History of argument lists passed to gdb.
 157 (defvar gud-gdb-history nil)
 158
 159 (defun gud-gdb-massage-args (file args)
 160   (cons "-fullname" (cons file args)))
 161
 162 ;; There's no guarantee that Emacs will hand the filter the entire
 163 ;; marker at once; it could be broken up across several strings.  We
 164 ;; might even receive a big chunk with several markers in it.  If we
 165 ;; receive a chunk of text which looks like it might contain the
 166 ;; beginning of a marker, we save it here between calls to the
 167 ;; filter.
 168 (defvar gud-marker-acc "")
 169 (make-variable-buffer-local 'gud-marker-acc)
 170
 171 (defun gud-gdb-marker-filter (string)
 172   (save-match-data
 173     (setq gud-marker-acc (concat gud-marker-acc string))
 174     (let ((output ""))
 175
 176       ;; Process all the complete markers in this chunk.
 177       (while (string-match "\032\032\\([^:\n]*\\):\\([0-9]*\\):.*\n"
 178                            gud-marker-acc)
 179         (setq
 180
 181          ;; Extract the frame position from the marker.
 182          gud-last-frame
 183          (cons (substring gud-marker-acc (match-beginning 1) (match-end 1))
 184                (string-to-int (substring gud-marker-acc
 185                                          (match-beginning 2)
 186                                          (match-end 2))))
 187
 188          ;; Append any text before the marker to the output we're going
 189          ;; to return - we don't include the marker in this text.
 190          output (concat output
 191                         (substring gud-marker-acc 0 (match-beginning 0)))
 192
 193          ;; Set the accumulator to the remaining text.
 194          gud-marker-acc (substring gud-marker-acc (match-end 0))))
 195
 196       ;; Does the remaining text look like it might end with the
 197       ;; beginning of another marker?  If it does, then keep it in
 198       ;; gud-marker-acc until we receive the rest of it.  Since we
 199       ;; know the full marker regexp above failed, it's pretty simple to
 200       ;; test for marker starts.
 201       (if (string-match "\032.*\\'" gud-marker-acc)
 202           (progn
 203             ;; Everything before the potential marker start can be output.
 204             (setq output (concat output (substring gud-marker-acc
 205                                                    0 (match-beginning 0))))
 206
 207             ;; Everything after, we save, to combine with later input.
 208             (setq gud-marker-acc
 209                   (substring gud-marker-acc (match-beginning 0))))
 210
 211         (setq output (concat output gud-marker-acc)
 212               gud-marker-acc ""))
 213
 214       output)))
 215
 216 (defun gud-gdb-find-file (f)
 217   (find-file-noselect f))
 218
 219 (defvar gdb-minibuffer-local-map nil
 220   "Keymap for minibuffer prompting of gdb startup command.")
 221 (if gdb-minibuffer-local-map
 222     ()
 223   (setq gdb-minibuffer-local-map (copy-keymap minibuffer-local-map))
 224   (define-key
 225     gdb-minibuffer-local-map "\C-i" 'comint-dynamic-complete-filename))
 226
 227 ;;;###autoload
 228 (defun gdb (command-line)
 229   "Run gdb on program FILE in buffer *gud-FILE*.
 230 The directory containing FILE becomes the initial working directory
 231 and source-file directory for your debugger."
 232   (interactive
 233    (list (read-from-minibuffer "Run gdb (like this): "
 234                                (if (consp gud-gdb-history)
 235                                    (car gud-gdb-history)
 236                                  "gdb ")
 237                                gdb-minibuffer-local-map nil
 238                                '(gud-gdb-history . 1))))
 239   (gud-overload-functions '((gud-massage-args . gud-gdb-massage-args)
 240                             (gud-marker-filter . gud-gdb-marker-filter)
 241                             (gud-find-file . gud-gdb-find-file)
 242                             ))
 243
 244   (gud-common-init command-line)
 245
 246   (gud-def gud-break  "break %f:%l"  "\C-b" "Set breakpoint at current line.")
 247   (gud-def gud-tbreak "tbreak %f:%l" "\C-t" "Set breakpoint at current line.")
 248   (gud-def gud-remove "clear %l"     "\C-d" "Remove breakpoint at current line")
 249   (gud-def gud-step   "step %p"      "\C-s" "Step one source line with display.")
 250   (gud-def gud-stepi  "stepi %p"     "\C-i" "Step one instruction with display.")
 251   (gud-def gud-next   "next %p"      "\C-n" "Step one line (skip functions).")
 252   (gud-def gud-cont   "cont"         "\C-r" "Continue with display.")
 253   (gud-def gud-finish "finish"       "\C-f" "Finish executing current function.")
 254   (gud-def gud-up     "up %p"        "<" "Up N stack frames (numeric arg).")
 255   (gud-def gud-down   "down %p"      ">" "Down N stack frames (numeric arg).")
 256   (gud-def gud-print  "print %e"     "\C-p" "Evaluate C expression at point.")
 257
 258   (local-set-key "\C-i" 'gud-gdb-complete-command)
 259   (setq comint-prompt-regexp "^(.*gdb[+]?) *")
 260   (setq paragraph-start comint-prompt-regexp)
 261   (run-hooks 'gdb-mode-hook)
 262   )
 263
 264 ;; One of the nice features of GDB is its impressive support for
 265 ;; context-sensitive command completion.  We preserve that feature
 266 ;; in the GUD buffer by using a GDB command designed just for Emacs.
 267
 268 ;; The completion process filter indicates when it is finished.
 269 (defvar gud-gdb-complete-in-progress)
 270
 271 ;; Since output may arrive in fragments we accumulate partials strings here.
 272 (defvar gud-gdb-complete-string)
 273
 274 ;; We need to know how much of the completion to chop off.
 275 (defvar gud-gdb-complete-break)
 276
 277 ;; The completion list is constructed by the process filter.
 278 (defvar gud-gdb-complete-list)
 279
 280 (defvar gud-comint-buffer nil)
 281
 282 (defun gud-gdb-complete-command ()
 283   "Perform completion on the GDB command preceding point.
 284 This is implemented using the GDB `complete' command which isn't
 285 available with older versions of GDB."
 286   (interactive)
 287   (let* ((end (point))
 288          (command (save-excursion
 289                     (beginning-of-line)
 290                     (and (looking-at comint-prompt-regexp)
 291                          (goto-char (match-end 0)))
 292                     (buffer-substring (point) end)))
 293          command-word)
 294     ;; Find the word break.  This match will always succeed.
 295     (string-match "\\(\\`\\| \\)\\([^ ]*\\)\\'" command)
 296     (setq gud-gdb-complete-break (match-beginning 2)
 297           command-word (substring command gud-gdb-complete-break))
 298     (unwind-protect
 299         (progn
 300           ;; Temporarily install our filter function.
 301           (gud-overload-functions
 302            '((gud-marker-filter . gud-gdb-complete-filter)))
 303           ;; Issue the command to GDB.
 304           (gud-basic-call (concat "complete " command))
 305           (setq gud-gdb-complete-in-progress t
 306                 gud-gdb-complete-string nil
 307                 gud-gdb-complete-list nil)
 308           ;; Slurp the output.
 309           (while gud-gdb-complete-in-progress
 310             (accept-process-output (get-buffer-process gud-comint-buffer))))
 311       ;; Restore the old filter function.
 312       (gud-overload-functions '((gud-marker-filter . gud-gdb-marker-filter))))
 313     ;; Protect against old versions of GDB.
 314     (and gud-gdb-complete-list
 315          (string-match "^Undefined command: \"complete\""
 316                        (car gud-gdb-complete-list))
 317          (error "This version of GDB doesn't support the `complete' command."))
 318     ;; Sort the list like readline.
 319     (setq gud-gdb-complete-list
 320           (sort gud-gdb-complete-list (function string-lessp)))
 321     ;; Remove duplicates.
 322     (let ((first gud-gdb-complete-list)
 323           (second (cdr gud-gdb-complete-list)))
 324       (while second
 325         (if (string-equal (car first) (car second))
 326             (setcdr first (setq second (cdr second)))
 327           (setq first second
 328                 second (cdr second)))))
 329     ;; Let comint handle the rest.
 330     (comint-dynamic-simple-complete command-word gud-gdb-complete-list)))
 331
 332 ;; The completion process filter is installed temporarily to slurp the
 333 ;; output of GDB up to the next prompt and build the completion list.
 334 (defun gud-gdb-complete-filter (string)
 335   (setq string (concat gud-gdb-complete-string string))
 336   (while (string-match "\n" string)
 337     (setq gud-gdb-complete-list
 338           (cons (substring string gud-gdb-complete-break (match-beginning 0))
 339                 gud-gdb-complete-list))
 340     (setq string (substring string (match-end 0))))
 341   (if (string-match comint-prompt-regexp string)
 342       (progn
 343         (setq gud-gdb-complete-in-progress nil)
 344         string)
 345     (progn
 346       (setq gud-gdb-complete-string string)
 347       "")))
 348
 349 \f
 350 ;; ======================================================================
 351 ;; sdb functions
 352
 353 ;;; History of argument lists passed to sdb.
 354 (defvar gud-sdb-history nil)
 355
 356 (defvar gud-sdb-needs-tags (not (file-exists-p "/var"))
 357   "If nil, we're on a System V Release 4 and don't need the tags hack.")
 358
 359 (defvar gud-sdb-lastfile nil)
 360
 361 (defun gud-sdb-massage-args (file args)
 362   (cons file args))
 363
 364 (defun gud-sdb-marker-filter (string)
 365   (cond
 366    ;; System V Release 3.2 uses this format
 367    ((string-match "\\(^0x\\w* in \\|^\\|\n\\)\\([^:\n]*\\):\\([0-9]*\\):.*\n"
 368                     string)
 369     (setq gud-last-frame
 370           (cons
 371            (substring string (match-beginning 2) (match-end 2))
 372            (string-to-int
 373             (substring string (match-beginning 3) (match-end 3))))))
 374    ;; System V Release 4.0
 375    ((string-match "^\\(BREAKPOINT\\|STEPPED\\) process [0-9]+ function [^ ]+ in \\(.+\\)\n"
 376                        string)
 377     (setq gud-sdb-lastfile
 378           (substring string (match-beginning 2) (match-end 2))))
 379    ((and gud-sdb-lastfile (string-match "^\\([0-9]+\\):" string))
 380          (setq gud-last-frame
 381                (cons
 382                 gud-sdb-lastfile
 383                 (string-to-int
 384                  (substring string (match-beginning 1) (match-end 1))))))
 385    (t
 386     (setq gud-sdb-lastfile nil)))
 387   string)
 388
 389 (defun gud-sdb-find-file (f)
 390   (if gud-sdb-needs-tags
 391       (find-tag-noselect f)
 392     (find-file-noselect f)))
 393
 394 ;;;###autoload
 395 (defun sdb (command-line)
 396   "Run sdb on program FILE in buffer *gud-FILE*.
 397 The directory containing FILE becomes the initial working directory
 398 and source-file directory for your debugger."
 399   (interactive
 400    (list (read-from-minibuffer "Run sdb (like this): "
 401                                (if (consp gud-sdb-history)
 402                                    (car gud-sdb-history)
 403                                  "sdb ")
 404                                nil nil
 405                                '(gud-sdb-history . 1))))
 406   (if (and gud-sdb-needs-tags
 407            (not (and (boundp 'tags-file-name)
 408                      (stringp tags-file-name)
 409                      (file-exists-p tags-file-name))))
 410       (error "The sdb support requires a valid tags table to work."))
 411   (gud-overload-functions '((gud-massage-args . gud-sdb-massage-args)
 412                             (gud-marker-filter . gud-sdb-marker-filter)
 413                             (gud-find-file . gud-sdb-find-file)
 414                             ))
 415
 416   (gud-common-init command-line)
 417
 418   (gud-def gud-break  "%l b" "\C-b"   "Set breakpoint at current line.")
 419   (gud-def gud-tbreak "%l c" "\C-t"   "Set temporary breakpoint at current line.")
 420   (gud-def gud-remove "%l d" "\C-d"   "Remove breakpoint at current line")
 421   (gud-def gud-step   "s %p" "\C-s"   "Step one source line with display.")
 422   (gud-def gud-stepi  "i %p" "\C-i"   "Step one instruction with display.")
 423   (gud-def gud-next   "S %p" "\C-n"   "Step one line (skip functions).")
 424   (gud-def gud-cont   "c"    "\C-r"   "Continue with display.")
 425   (gud-def gud-print  "%e/"  "\C-p"   "Evaluate C expression at point.")
 426
 427   (setq comint-prompt-regexp  "\\(^\\|\n\\)\\*")
 428   (setq paragraph-start comint-prompt-regexp)
 429   (run-hooks 'sdb-mode-hook)
 430   )
 431 \f
 432 ;; ======================================================================
 433 ;; dbx functions
 434
 435 ;;; History of argument lists passed to dbx.
 436 (defvar gud-dbx-history nil)
 437
 438 (defun gud-dbx-massage-args (file args)
 439   (cons file args))
 440
 441 (defun gud-dbx-marker-filter (string)
 442   (if (or (string-match
 443          "stopped in .* at line \\([0-9]*\\) in file \"\\([^\"]*\\)\""
 444          string)
 445         (string-match
 446          "signal .* in .* at line \\([0-9]*\\) in file \"\\([^\"]*\\)\""
 447          string))
 448       (setq gud-last-frame
 449             (cons
 450              (substring string (match-beginning 2) (match-end 2))
 451              (string-to-int
 452               (substring string (match-beginning 1) (match-end 1))))))
 453   string)
 454
 455 ;; Functions for Mips-style dbx.  Given the option `-emacs', documented in
 456 ;; OSF1, not necessarily elsewhere, it produces markers similar to gdb's.
 457 (defvar gud-mips-p
 458   (or (string-match "^mips-[^-]*-ultrix" system-configuration)
 459       ;; We haven't tested gud on this system:
 460       (string-match "^mips-[^-]*-riscos" system-configuration)
 461       ;; It's documented on OSF/1.3
 462       (string-match "^mips-[^-]*-osf1" system-configuration)
 463       (string-match "^alpha-[^-]*-osf" system-configuration))
 464   "Non-nil to assume the MIPS/OSF dbx conventions (argument `-emacs').")
 465
 466 (defun gud-mipsdbx-massage-args (file args)
 467   (cons "-emacs" (cons file args)))
 468
 469 ;; This is just like the gdb one except for the regexps since we need to cope
 470 ;; with an optional breakpoint number in [] before the ^Z^Z
 471 (defun gud-mipsdbx-marker-filter (string)
 472   (save-match-data
 473     (setq gud-marker-acc (concat gud-marker-acc string))
 474     (let ((output ""))
 475
 476       ;; Process all the complete markers in this chunk.
 477       (while (string-match
 478               ;; This is like th gdb marker but with an optional
 479               ;; leading break point number like `[1] '
 480               "[][ 0-9]*\032\032\\([^:\n]*\\):\\([0-9]*\\):.*\n"
 481               gud-marker-acc)
 482         (setq
 483
 484          ;; Extract the frame position from the marker.
 485          gud-last-frame
 486          (cons (substring gud-marker-acc (match-beginning 1) (match-end 1))
 487                (string-to-int (substring gud-marker-acc
 488                                          (match-beginning 2)
 489                                          (match-end 2))))
 490
 491          ;; Append any text before the marker to the output we're going
 492          ;; to return - we don't include the marker in this text.
 493          output (concat output
 494                         (substring gud-marker-acc 0 (match-beginning 0)))
 495
 496          ;; Set the accumulator to the remaining text.
 497          gud-marker-acc (substring gud-marker-acc (match-end 0))))
 498
 499       ;; Does the remaining text look like it might end with the
 500       ;; beginning of another marker?  If it does, then keep it in
 501       ;; gud-marker-acc until we receive the rest of it.  Since we
 502       ;; know the full marker regexp above failed, it's pretty simple to
 503       ;; test for marker starts.
 504       (if (string-match "[][ 0-9]*\032.*\\'" gud-marker-acc)
 505           (progn
 506             ;; Everything before the potential marker start can be output.
 507             (setq output (concat output (substring gud-marker-acc
 508                                                    0 (match-beginning 0))))
 509
 510             ;; Everything after, we save, to combine with later input.
 511             (setq gud-marker-acc
 512                   (substring gud-marker-acc (match-beginning 0))))
 513
 514         (setq output (concat output gud-marker-acc)
 515               gud-marker-acc ""))
 516
 517       output)))
 518
 519 ;; The dbx in IRIX is a pain.  It doesn't print the file name when
 520 ;; stopping at a breakpoint (but you do get it from the `up' and
 521 ;; `down' commands...).  The only way to extract the information seems
 522 ;; to be with a `file' command, although the current line number is
 523 ;; available in $curline.  Thus we have to look for output which
 524 ;; appears to indicate a breakpoint.  Then we prod the dbx sub-process
 525 ;; to output the information we want with a combination of the
 526 ;; `printf' and `file' commands as a pseudo marker which we can
 527 ;; recognise next time through the marker-filter.  This would be like
 528 ;; the gdb marker but you can't get the file name without a newline...
 529 ;; Note that gud-remove won't work since Irix dbx expects a breakpoint
 530 ;; number rather than a line number etc.  Maybe this could be made to
 531 ;; work by listing all the breakpoints and picking the one(s) with the
 532 ;; correct line number, but life's too short.
 533 ;;   d.love@dl.ac.uk (Dave Love) can be blamed for this
 534
 535 (defvar gud-irix-p (string-match "^mips-[^-]*-irix" system-configuration)
 536   "Non-nil to assume the interface appropriate for IRIX dbx.
 537 This works in IRIX 4 and probably IRIX 5.")
 538 ;; (It's been tested in IRIX 4 and the output from dbx on IRIX 5 looks
 539 ;; the same.)
 540
 541 ;; this filter is influenced by the xdb one rather than the gdb one
 542 (defun gud-irixdbx-marker-filter (string)
 543   (save-match-data
 544     (let (result (case-fold-search nil))
 545       (if (or (string-match comint-prompt-regexp string)
 546               (string-match ".*\012" string))
 547           (setq result (concat gud-marker-acc string)
 548                 gud-marker-acc "")
 549         (setq gud-marker-acc (concat gud-marker-acc string)))
 550       (if result
 551           (cond
 552            ;; look for breakpoint or signal indication e.g.:
 553            ;; [2] Process  1267 (pplot) stopped at [params:338 ,0x400ec0]
 554            ;; Process  1281 (pplot) stopped at [params:339 ,0x400ec8]
 555            ;; Process  1270 (pplot) Floating point exception [._read._read:16 ,0x452188]
 556            ((string-match
 557              "^\\(\\[[0-9]+] \\)?Process +[0-9]+ ([^)]*) [^[]+\\[[^]\n]*]\n"
 558              result)
 559             ;; prod dbx into printing out the line number and file
 560             ;; name in a form we can grok as below
 561             (process-send-string (get-buffer-process gud-comint-buffer)
 562                                  "printf \"\032\032%1d:\",$curline;file\n"))
 563            ;; look for result of, say, "up" e.g.:
 564            ;; .pplot.pplot(0x800) ["src/pplot.f":261, 0x400c7c]
 565            ;; (this will also catch one of the lines printed by "where")
 566            ((string-match
 567              "^[^ ][^[]*\\[\"\\([^\"]+\\)\":\\([0-9]+\\), [^]]+]\n"
 568              result)
 569             (let ((file (substring result (match-beginning 1)
 570                                    (match-end 1))))
 571               (if (file-exists-p file)
 572                   (setq gud-last-frame
 573                         (cons
 574                          (substring
 575                           result (match-beginning 1) (match-end 1))
 576                          (string-to-int
 577                           (substring
 578                            result (match-beginning 2) (match-end 2)))))))
 579             result)
 580            ((string-match               ; kluged-up marker as above
 581              "\032\032\\([0-9]*\\):\\(.*\\)\n" result)
 582             (let ((file (substring result (match-beginning 2) (match-end 2))))
 583               (if (file-exists-p file)
 584                   (setq gud-last-frame
 585                         (cons
 586                          file
 587                          (string-to-int
 588                           (substring
 589                            result (match-beginning 1) (match-end 1)))))))
 590             (setq result (substring result 0 (match-beginning 0))))))
 591       (or result ""))))
 592
 593 (defun gud-dbx-find-file (f)
 594   (find-file-noselect f))
 595
 596 ;;;###autoload
 597 (defun dbx (command-line)
 598   "Run dbx on program FILE in buffer *gud-FILE*.
 599 The directory containing FILE becomes the initial working directory
 600 and source-file directory for your debugger."
 601   (interactive
 602    (list (read-from-minibuffer "Run dbx (like this): "
 603                                (if (consp gud-dbx-history)
 604                                    (car gud-dbx-history)
 605                                  "dbx ")
 606                                nil nil
 607                                '(gud-dbx-history . 1))))
 608
 609   (gud-overload-functions
 610    (cond
 611     (gud-mips-p
 612      '((gud-massage-args . gud-mipsdbx-massage-args)
 613        (gud-marker-filter . gud-mipsdbx-marker-filter)
 614        (gud-find-file . gud-dbx-find-file)))
 615     (gud-irix-p
 616      '((gud-massage-args . gud-dbx-massage-args)
 617        (gud-marker-filter . gud-irixdbx-marker-filter)
 618        (gud-find-file . gud-dbx-find-file)))
 619     (t
 620      '((gud-massage-args . gud-dbx-massage-args)
 621        (gud-marker-filter . gud-dbx-marker-filter)
 622        (gud-find-file . gud-dbx-find-file)))))
 623
 624   (gud-common-init command-line)
 625
 626   (cond
 627    (gud-mips-p
 628     (gud-def gud-break "stop at \"%f\":%l"
 629                                   "\C-b" "Set breakpoint at current line.")
 630     (gud-def gud-finish "return"  "\C-f" "Finish executing current function."))
 631    (gud-irix-p
 632     (gud-def gud-break "stop at \"%d%f\":%l"
 633                                   "\C-b" "Set breakpoint at current line.")
 634     (gud-def gud-finish "return"  "\C-f" "Finish executing current function.")
 635     ;; Make dbx give out the source location info that we need.
 636     (process-send-string (get-buffer-process gud-comint-buffer)
 637                          "printf \"\032\032%1d:\",$curline;file\n"))
 638    (t
 639     (gud-def gud-break "file \"%d%f\"\nstop at %l"
 640                                   "\C-b" "Set breakpoint at current line.")))
 641
 642   (gud-def gud-remove "clear %l"  "\C-d" "Remove breakpoint at current line")
 643   (gud-def gud-step   "step %p"   "\C-s" "Step one line with display.")
 644   (gud-def gud-stepi  "stepi %p"  "\C-i" "Step one instruction with display.")
 645   (gud-def gud-next   "next %p"   "\C-n" "Step one line (skip functions).")
 646   (gud-def gud-cont   "cont"      "\C-r" "Continue with display.")
 647   (gud-def gud-up     "up %p"     "<" "Up (numeric arg) stack frames.")
 648   (gud-def gud-down   "down %p"   ">" "Down (numeric arg) stack frames.")
 649   (gud-def gud-print  "print %e"  "\C-p" "Evaluate C expression at point.")
 650
 651   (setq comint-prompt-regexp  "^[^)\n]*dbx) *")
 652   (setq paragraph-start comint-prompt-regexp)
 653   (run-hooks 'dbx-mode-hook)
 654   )
 655 \f
 656 ;; ======================================================================
 657 ;; xdb (HP PARISC debugger) functions
 658
 659 ;;; History of argument lists passed to xdb.
 660 (defvar gud-xdb-history nil)
 661
 662 (defvar gud-xdb-directories nil
 663   "*A list of directories that xdb should search for source code.
 664 If nil, only source files in the program directory
 665 will be known to xdb.
 666
 667 The file names should be absolute, or relative to the directory
 668 containing the executable being debugged.")
 669
 670 (defun gud-xdb-massage-args (file args)
 671   (nconc (let ((directories gud-xdb-directories)
 672                (result nil))
 673            (while directories
 674              (setq result (cons (car directories) (cons "-d" result)))
 675              (setq directories (cdr directories)))
 676            (nreverse (cons file result)))
 677          args))
 678
 679 (defun gud-xdb-file-name (f)
 680   "Transform a relative pathname to a full pathname in xdb mode"
 681   (let ((result nil))
 682     (if (file-exists-p f)
 683         (setq result (expand-file-name f))
 684       (let ((directories gud-xdb-directories))
 685         (while directories
 686           (let ((path (concat (car directories) "/" f)))
 687             (if (file-exists-p path)
 688                 (setq result (expand-file-name path)
 689                       directories nil)))
 690           (setq directories (cdr directories)))))
 691     result))
 692
 693 ;; xdb does not print the lines all at once, so we have to accumulate them
 694 (defun gud-xdb-marker-filter (string)
 695   (let (result)
 696     (if (or (string-match comint-prompt-regexp string)
 697             (string-match ".*\012" string))
 698         (setq result (concat gud-marker-acc string)
 699               gud-marker-acc "")
 700       (setq gud-marker-acc (concat gud-marker-acc string)))
 701     (if result
 702         (if (or (string-match "\\([^\n \t:]+\\): [^:]+: \\([0-9]+\\):" result)
 703                 (string-match "[^: \t]+:[ \t]+\\([^:]+\\): [^:]+: \\([0-9]+\\):"
 704                               result))
 705             (let ((line (string-to-int
 706                          (substring result (match-beginning 2) (match-end 2))))
 707                   (file (gud-xdb-file-name
 708                          (substring result (match-beginning 1) (match-end 1)))))
 709               (if file
 710                   (setq gud-last-frame (cons file line))))))
 711     (or result "")))
 712
 713 (defun gud-xdb-find-file (f)
 714   (let ((realf (gud-xdb-file-name f)))
 715     (if realf (find-file-noselect realf))))
 716
 717 ;;;###autoload
 718 (defun xdb (command-line)
 719   "Run xdb on program FILE in buffer *gud-FILE*.
 720 The directory containing FILE becomes the initial working directory
 721 and source-file directory for your debugger.
 722
 723 You can set the variable 'gud-xdb-directories' to a list of program source
 724 directories if your program contains sources from more than one directory."
 725   (interactive
 726    (list (read-from-minibuffer "Run xdb (like this): "
 727                                (if (consp gud-xdb-history)
 728                                    (car gud-xdb-history)
 729                                  "xdb ")
 730                                nil nil
 731                                '(gud-xdb-history . 1))))
 732   (gud-overload-functions '((gud-massage-args . gud-xdb-massage-args)
 733                             (gud-marker-filter . gud-xdb-marker-filter)
 734                             (gud-find-file . gud-xdb-find-file)))
 735
 736   (gud-common-init command-line)
 737
 738   (gud-def gud-break  "b %f:%l"    "\C-b" "Set breakpoint at current line.")
 739   (gud-def gud-tbreak "b %f:%l\\t" "\C-t"
 740            "Set temporary breakpoint at current line.")
 741   (gud-def gud-remove "db"         "\C-d" "Remove breakpoint at current line")
 742   (gud-def gud-step   "s %p"       "\C-s" "Step one line with display.")
 743   (gud-def gud-next   "S %p"       "\C-n" "Step one line (skip functions).")
 744   (gud-def gud-cont   "c"          "\C-r" "Continue with display.")
 745   (gud-def gud-up     "up %p"      "<"    "Up (numeric arg) stack frames.")
 746   (gud-def gud-down   "down %p"    ">"    "Down (numeric arg) stack frames.")
 747   (gud-def gud-finish "bu\\t"      "\C-f" "Finish executing current function.")
 748   (gud-def gud-print  "p %e"       "\C-p" "Evaluate C expression at point.")
 749
 750   (setq comint-prompt-regexp  "^>")
 751   (setq paragraph-start comint-prompt-regexp)
 752   (run-hooks 'xdb-mode-hook))
 753 \f
 754 ;; ======================================================================
 755 ;; perldb functions
 756
 757 ;;; History of argument lists passed to perldb.
 758 (defvar gud-perldb-history nil)
 759
 760 (defun gud-perldb-massage-args (file args)
 761   (cons "-d" (cons file (cons "-emacs" args))))
 762
 763 ;; There's no guarantee that Emacs will hand the filter the entire
 764 ;; marker at once; it could be broken up across several strings.  We
 765 ;; might even receive a big chunk with several markers in it.  If we
 766 ;; receive a chunk of text which looks like it might contain the
 767 ;; beginning of a marker, we save it here between calls to the
 768 ;; filter.
 769 (defvar gud-perldb-marker-acc "")
 770
 771 (defun gud-perldb-marker-filter (string)
 772   (save-match-data
 773     (setq gud-marker-acc (concat gud-marker-acc string))
 774     (let ((output ""))
 775
 776       ;; Process all the complete markers in this chunk.
 777       (while (string-match "\032\032\\([^:\n]*\\):\\([0-9]*\\):.*\n"
 778                            gud-marker-acc)
 779         (setq
 780
 781          ;; Extract the frame position from the marker.
 782          gud-last-frame
 783          (cons (substring gud-marker-acc (match-beginning 1) (match-end 1))
 784                (string-to-int (substring gud-marker-acc
 785                                          (match-beginning 2)
 786                                          (match-end 2))))
 787
 788          ;; Append any text before the marker to the output we're going
 789          ;; to return - we don't include the marker in this text.
 790          output (concat output
 791                         (substring gud-marker-acc 0 (match-beginning 0)))
 792
 793          ;; Set the accumulator to the remaining text.
 794          gud-marker-acc (substring gud-marker-acc (match-end 0))))
 795
 796       ;; Does the remaining text look like it might end with the
 797       ;; beginning of another marker?  If it does, then keep it in
 798       ;; gud-marker-acc until we receive the rest of it.  Since we
 799       ;; know the full marker regexp above failed, it's pretty simple to
 800       ;; test for marker starts.
 801       (if (string-match "\032.*\\'" gud-marker-acc)
 802           (progn
 803             ;; Everything before the potential marker start can be output.
 804             (setq output (concat output (substring gud-marker-acc
 805                                                    0 (match-beginning 0))))
 806
 807             ;; Everything after, we save, to combine with later input.
 808             (setq gud-marker-acc
 809                   (substring gud-marker-acc (match-beginning 0))))
 810
 811         (setq output (concat output gud-marker-acc)
 812               gud-marker-acc ""))
 813
 814       output)))
 815
 816 (defun gud-perldb-find-file (f)
 817   (find-file-noselect f))
 818
 819 ;;;###autoload
 820 (defun perldb (command-line)
 821   "Run perldb on program FILE in buffer *gud-FILE*.
 822 The directory containing FILE becomes the initial working directory
 823 and source-file directory for your debugger."
 824   (interactive
 825    (list (read-from-minibuffer "Run perldb (like this): "
 826                                (if (consp gud-perldb-history)
 827                                    (car gud-perldb-history)
 828                                  "perl ")
 829                                nil nil
 830                                '(gud-perldb-history . 1))))
 831   (gud-overload-functions '((gud-massage-args . gud-perldb-massage-args)
 832                             (gud-marker-filter . gud-perldb-marker-filter)
 833                             (gud-find-file . gud-perldb-find-file)
 834                             ))
 835
 836   (gud-common-init command-line)
 837
 838   (gud-def gud-break  "b %l"         "\C-b" "Set breakpoint at current line.")
 839   (gud-def gud-remove "d %l"         "\C-d" "Remove breakpoint at current line")
 840   (gud-def gud-step   "s"            "\C-s" "Step one source line with display.")
 841   (gud-def gud-next   "n"            "\C-n" "Step one line (skip functions).")
 842   (gud-def gud-cont   "c"            "\C-r" "Continue with display.")
 843 ;  (gud-def gud-finish "finish"       "\C-f" "Finish executing current function.")
 844 ;  (gud-def gud-up     "up %p"        "<" "Up N stack frames (numeric arg).")
 845 ;  (gud-def gud-down   "down %p"      ">" "Down N stack frames (numeric arg).")
 846   (gud-def gud-print  "%e"           "\C-p" "Evaluate perl expression at point.")
 847
 848   (setq comint-prompt-regexp "^  DB<[0-9]+> ")
 849   (setq paragraph-start comint-prompt-regexp)
 850   (run-hooks 'perldb-mode-hook)
 851   )
 852
 853 ;;
 854 ;; End of debugger-specific information
 855 ;;
 856
 857 \f
 858 ;;; When we send a command to the debugger via gud-call, it's annoying
 859 ;;; to see the command and the new prompt inserted into the debugger's
 860 ;;; buffer; we have other ways of knowing the command has completed.
 861 ;;;
 862 ;;; If the buffer looks like this:
 863 ;;; --------------------
 864 ;;; (gdb) set args foo bar
 865 ;;; (gdb) -!-
 866 ;;; --------------------
 867 ;;; (the -!- marks the location of point), and we type `C-x SPC' in a
 868 ;;; source file to set a breakpoint, we want the buffer to end up like
 869 ;;; this:
 870 ;;; --------------------
 871 ;;; (gdb) set args foo bar
 872 ;;; Breakpoint 1 at 0x92: file make-docfile.c, line 49.
 873 ;;; (gdb) -!-
 874 ;;; --------------------
 875 ;;; Essentially, the old prompt is deleted, and the command's output
 876 ;;; and the new prompt take its place.
 877 ;;;
 878 ;;; Not echoing the command is easy enough; you send it directly using
 879 ;;; process-send-string, and it never enters the buffer.  However,
 880 ;;; getting rid of the old prompt is trickier; you don't want to do it
 881 ;;; when you send the command, since that will result in an annoying
 882 ;;; flicker as the prompt is deleted, redisplay occurs while Emacs
 883 ;;; waits for a response from the debugger, and the new prompt is
 884 ;;; inserted.  Instead, we'll wait until we actually get some output
 885 ;;; from the subprocess before we delete the prompt.  If the command
 886 ;;; produced no output other than a new prompt, that prompt will most
 887 ;;; likely be in the first chunk of output received, so we will delete
 888 ;;; the prompt and then replace it with an identical one.  If the
 889 ;;; command produces output, the prompt is moving anyway, so the
 890 ;;; flicker won't be annoying.
 891 ;;;
 892 ;;; So - when we want to delete the prompt upon receipt of the next
 893 ;;; chunk of debugger output, we position gud-delete-prompt-marker at
 894 ;;; the start of the prompt; the process filter will notice this, and
 895 ;;; delete all text between it and the process output marker.  If
 896 ;;; gud-delete-prompt-marker points nowhere, we leave the current
 897 ;;; prompt alone.
 898 (defvar gud-delete-prompt-marker nil)
 899
 900 \f
 901 (defun gud-mode ()
 902   "Major mode for interacting with an inferior debugger process.
 903
 904    You start it up with one of the commands M-x gdb, M-x sdb, M-x dbx,
 905 or M-x xdb.  Each entry point finishes by executing a hook; `gdb-mode-hook',
 906 `sdb-mode-hook', `dbx-mode-hook' or `xdb-mode-hook' respectively.
 907
 908 After startup, the following commands are available in both the GUD
 909 interaction buffer and any source buffer GUD visits due to a breakpoint stop
 910 or step operation:
 911
 912 \\[gud-break] sets a breakpoint at the current file and line.  In the
 913 GUD buffer, the current file and line are those of the last breakpoint or
 914 step.  In a source buffer, they are the buffer's file and current line.
 915
 916 \\[gud-remove] removes breakpoints on the current file and line.
 917
 918 \\[gud-refresh] displays in the source window the last line referred to
 919 in the gud buffer.
 920
 921 \\[gud-step], \\[gud-next], and \\[gud-stepi] do a step-one-line,
 922 step-one-line (not entering function calls), and step-one-instruction
 923 and then update the source window with the current file and position.
 924 \\[gud-cont] continues execution.
 925
 926 \\[gud-print] tries to find the largest C lvalue or function-call expression
 927 around point, and sends it to the debugger for value display.
 928
 929 The above commands are common to all supported debuggers except xdb which
 930 does not support stepping instructions.
 931
 932 Under gdb, sdb and xdb, \\[gud-tbreak] behaves exactly like \\[gud-break],
 933 except that the breakpoint is temporary; that is, it is removed when
 934 execution stops on it.
 935
 936 Under gdb, dbx, and xdb, \\[gud-up] pops up through an enclosing stack
 937 frame.  \\[gud-down] drops back down through one.
 938
 939 If you are using gdb or xdb, \\[gud-finish] runs execution to the return from
 940 the current function and stops.
 941
 942 All the keystrokes above are accessible in the GUD buffer
 943 with the prefix C-c, and in all buffers through the prefix C-x C-a.
 944
 945 All pre-defined functions for which the concept make sense repeat
 946 themselves the appropriate number of times if you give a prefix
 947 argument.
 948
 949 You may use the `gud-def' macro in the initialization hook to define other
 950 commands.
 951
 952 Other commands for interacting with the debugger process are inherited from
 953 comint mode, which see."
 954   (interactive)
 955   (comint-mode)
 956   (setq major-mode 'gud-mode)
 957   (setq mode-name "Debugger")
 958   (setq mode-line-process '(":%s"))
 959   (use-local-map (copy-keymap comint-mode-map))
 960   (define-key (current-local-map) "\C-c\C-l" 'gud-refresh)
 961   (make-local-variable 'gud-last-frame)
 962   (setq gud-last-frame nil)
 963   (make-local-variable 'comint-prompt-regexp)
 964   (make-local-variable 'paragraph-start)
 965   (make-local-variable 'gud-delete-prompt-marker)
 966   (setq gud-delete-prompt-marker (make-marker))
 967   (run-hooks 'gud-mode-hook)
 968 )
 969
 970 ;; Chop STRING into words separated by SPC or TAB and return a list of them.
 971 (defun gud-chop-words (string)
 972   (let ((i 0) (beg 0)
 973         (len (length string))
 974         (words nil))
 975     (while (< i len)
 976       (if (memq (aref string i) '(?\t ? ))
 977           (progn
 978             (setq words (cons (substring string beg i) words)
 979                   beg (1+ i))
 980             (while (and (< beg len) (memq (aref string beg) '(?\t ? )))
 981               (setq beg (1+ beg)))
 982             (setq i (1+ beg)))
 983         (setq i (1+ i))))
 984     (if (< beg len)
 985         (setq words (cons (substring string beg) words)))
 986     (nreverse words)))
 987
 988 ;; Perform initializations common to all debuggers.
 989 (defun gud-common-init (command-line)
 990   (let* ((words (gud-chop-words command-line))
 991          (program (car words))
 992          (file-word (let ((w (cdr words)))
 993                       (while (and w (= ?- (aref (car w) 0)))
 994                         (setq w (cdr w)))
 995                       (car w)))
 996          (args (delq file-word (cdr words)))
 997          (file (and file-word
 998                     (expand-file-name (substitute-in-file-name file-word))))
 999          (filepart (and file-word (file-name-nondirectory file))))
1000       (switch-to-buffer (concat "*gud-" filepart "*"))
1001       (and file-word (setq default-directory (file-name-directory file)))
1002       (or (bolp) (newline))
1003       (insert "Current directory is " default-directory "\n")
1004       (apply 'make-comint (concat "gud-" filepart) program nil
1005              (if file-word (gud-massage-args file args))))
1006   (gud-mode)
1007   (set-process-filter (get-buffer-process (current-buffer)) 'gud-filter)
1008   (set-process-sentinel (get-buffer-process (current-buffer)) 'gud-sentinel)
1009   (gud-set-buffer)
1010   )
1011
1012 (defun gud-set-buffer ()
1013   (cond ((eq major-mode 'gud-mode)
1014         (setq gud-comint-buffer (current-buffer)))))
1015
1016 ;; These functions are responsible for inserting output from your debugger
1017 ;; into the buffer.  The hard work is done by the method that is
1018 ;; the value of gud-marker-filter.
1019
1020 (defun gud-filter (proc string)
1021   ;; Here's where the actual buffer insertion is done
1022   (let ((inhibit-quit t)
1023         output)
1024     (save-excursion
1025       (set-buffer (process-buffer proc))
1026       ;; If we have been so requested, delete the debugger prompt.
1027       (if (marker-buffer gud-delete-prompt-marker)
1028           (progn
1029             (delete-region (process-mark proc) gud-delete-prompt-marker)
1030             (set-marker gud-delete-prompt-marker nil)))
1031       ;; Save the process output, checking for source file markers.
1032       (setq output (gud-marker-filter string))
1033       ;; Check for a filename-and-line number.
1034       ;; Don't display the specified file
1035       ;; unless (1) point is at or after the position where output appears
1036       ;; and (2) this buffer is on the screen.
1037       (if (and gud-last-frame
1038                (>= (point) (process-mark proc))
1039                (get-buffer-window (current-buffer)))
1040           (gud-display-frame))
1041       ;; Let the comint filter do the actual insertion.
1042       ;; That lets us inherit various comint features.
1043       (comint-output-filter proc output))))
1044
1045 (defun gud-sentinel (proc msg)
1046   (cond ((null (buffer-name (process-buffer proc)))
1047          ;; buffer killed
1048          ;; Stop displaying an arrow in a source file.
1049          (setq overlay-arrow-position nil)
1050          (set-process-buffer proc nil))
1051         ((memq (process-status proc) '(signal exit))
1052          ;; Stop displaying an arrow in a source file.
1053          (setq overlay-arrow-position nil)
1054          ;; Fix the mode line.
1055          (setq mode-line-process
1056                (concat ":"
1057                        (symbol-name (process-status proc))))
1058          (let* ((obuf (current-buffer)))
1059            ;; save-excursion isn't the right thing if
1060            ;;  process-buffer is current-buffer
1061            (unwind-protect
1062                (progn
1063                  ;; Write something in *compilation* and hack its mode line,
1064                  (set-buffer (process-buffer proc))
1065                  ;; Force mode line redisplay soon
1066                  (set-buffer-modified-p (buffer-modified-p))
1067                  (if (eobp)
1068                      (insert ?\n mode-name " " msg)
1069                    (save-excursion
1070                      (goto-char (point-max))
1071                      (insert ?\n mode-name " " msg)))
1072                  ;; If buffer and mode line will show that the process
1073                  ;; is dead, we can delete it now.  Otherwise it
1074                  ;; will stay around until M-x list-processes.
1075                  (delete-process proc))
1076              ;; Restore old buffer, but don't restore old point
1077              ;; if obuf is the gud buffer.
1078              (set-buffer obuf))))))
1079
1080 (defun gud-display-frame ()
1081   "Find and obey the last filename-and-line marker from the debugger.
1082 Obeying it means displaying in another window the specified file and line."
1083   (interactive)
1084   (if gud-last-frame
1085    (progn
1086      (gud-set-buffer)
1087      (gud-display-line (car gud-last-frame) (cdr gud-last-frame))
1088      (setq gud-last-last-frame gud-last-frame
1089            gud-last-frame nil))))
1090
1091 ;; Make sure the file named TRUE-FILE is in a buffer that appears on the screen
1092 ;; and that its line LINE is visible.
1093 ;; Put the overlay-arrow on the line LINE in that buffer.
1094 ;; Most of the trickiness in here comes from wanting to preserve the current
1095 ;; region-restriction if that's possible.  We use an explicit display-buffer
1096 ;; to get around the fact that this is called inside a save-excursion.
1097
1098 (defun gud-display-line (true-file line)
1099   (let* ((last-nonmenu-event t)  ; Prevent use of dialog box for questions.
1100          (buffer (gud-find-file true-file))
1101          (window (display-buffer buffer))
1102          (pos))
1103 ;;;    (if (equal buffer (current-buffer))
1104 ;;;     nil
1105 ;;;      (setq buffer-read-only nil))
1106     (save-excursion
1107 ;;;      (setq buffer-read-only t)
1108       (set-buffer buffer)
1109       (save-restriction
1110         (widen)
1111         (goto-line line)
1112         (setq pos (point))
1113         (setq overlay-arrow-string "=>")
1114         (or overlay-arrow-position
1115             (setq overlay-arrow-position (make-marker)))
1116         (set-marker overlay-arrow-position (point) (current-buffer)))
1117       (cond ((or (< pos (point-min)) (> pos (point-max)))
1118              (widen)
1119              (goto-char pos))))
1120     (set-window-point window overlay-arrow-position)))
1121
1122 ;;; The gud-call function must do the right thing whether its invoking
1123 ;;; keystroke is from the GUD buffer itself (via major-mode binding)
1124 ;;; or a C buffer.  In the former case, we want to supply data from
1125 ;;; gud-last-frame.  Here's how we do it:
1126
1127 (defun gud-format-command (str arg)
1128   (let ((insource (not (eq (current-buffer) gud-comint-buffer)))
1129         (frame (or gud-last-frame gud-last-last-frame))
1130         result)
1131     (while (and str (string-match "\\([^%]*\\)%\\([adeflp]\\)" str))
1132       (let ((key (string-to-char (substring str (match-beginning 2))))
1133             subst)
1134         (cond
1135          ((eq key ?f)
1136           (setq subst (file-name-nondirectory (if insource
1137                                                   (buffer-file-name)
1138                                                 (car frame)))))
1139          ((eq key ?d)
1140           (setq subst (file-name-directory (if insource
1141                                                (buffer-file-name)
1142                                              (car frame)))))
1143          ((eq key ?l)
1144           (setq subst (if insource
1145                           (save-excursion
1146                             (beginning-of-line)
1147                             (save-restriction (widen)
1148                                               (1+ (count-lines 1 (point)))))
1149                         (cdr frame))))
1150          ((eq key ?e)
1151           (setq subst (find-c-expr)))
1152          ((eq key ?a)
1153           (setq subst (gud-read-address)))
1154          ((eq key ?p)
1155           (setq subst (if arg (int-to-string arg) ""))))
1156         (setq result (concat result
1157                              (substring str (match-beginning 1) (match-end 1))
1158                              subst)))
1159       (setq str (substring str (match-end 2))))
1160     ;; There might be text left in STR when the loop ends.
1161     (concat result str)))
1162
1163 (defun gud-read-address ()
1164   "Return a string containing the core-address found in the buffer at point."
1165   (save-excursion
1166     (let ((pt (point)) found begin)
1167       (setq found (if (search-backward "0x" (- pt 7) t) (point)))
1168       (cond
1169        (found (forward-char 2)
1170               (buffer-substring found
1171                                 (progn (re-search-forward "[^0-9a-f]")
1172                                        (forward-char -1)
1173                                        (point))))
1174        (t (setq begin (progn (re-search-backward "[^0-9]")
1175                              (forward-char 1)
1176                              (point)))
1177           (forward-char 1)
1178           (re-search-forward "[^0-9]")
1179           (forward-char -1)
1180           (buffer-substring begin (point)))))))
1181
1182 (defun gud-call (fmt &optional arg)
1183   (let ((msg (gud-format-command fmt arg)))
1184     (message "Command: %s" msg)
1185     (sit-for 0)
1186     (gud-basic-call msg)))
1187
1188 (defun gud-basic-call (command)
1189   "Invoke the debugger COMMAND displaying source in other window."
1190   (interactive)
1191   (gud-set-buffer)
1192   (let ((command (concat command "\n"))
1193         (proc (get-buffer-process gud-comint-buffer)))
1194
1195     ;; Arrange for the current prompt to get deleted.
1196     (save-excursion
1197       (set-buffer gud-comint-buffer)
1198       (goto-char (process-mark proc))
1199       (beginning-of-line)
1200       (if (looking-at comint-prompt-regexp)
1201           (set-marker gud-delete-prompt-marker (point))))
1202     (process-send-string proc command)))
1203
1204 (defun gud-refresh (&optional arg)
1205   "Fix up a possibly garbled display, and redraw the arrow."
1206   (interactive "P")
1207   (recenter arg)
1208   (or gud-last-frame (setq gud-last-frame gud-last-last-frame))
1209   (gud-display-frame))
1210 \f
1211 ;;; Code for parsing expressions out of C code.  The single entry point is
1212 ;;; find-c-expr, which tries to return an lvalue expression from around point.
1213 ;;;
1214 ;;; The rest of this file is a hacked version of gdbsrc.el by
1215 ;;; Debby Ayers <ayers@asc.slb.com>,
1216 ;;; Rich Schaefer <schaefer@asc.slb.com> Schlumberger, Austin, Tx.
1217
1218 (defun find-c-expr ()
1219   "Returns the C expr that surrounds point."
1220   (interactive)
1221   (save-excursion
1222     (let ((p) (expr) (test-expr))
1223       (setq p (point))
1224       (setq expr (expr-cur))
1225       (setq test-expr (expr-prev))
1226       (while (expr-compound test-expr expr)
1227         (setq expr (cons (car test-expr) (cdr expr)))
1228         (goto-char (car expr))
1229         (setq test-expr (expr-prev)))
1230       (goto-char p)
1231       (setq test-expr (expr-next))
1232       (while (expr-compound expr test-expr)
1233         (setq expr (cons (car expr) (cdr test-expr)))
1234         (setq test-expr (expr-next))
1235         )
1236       (buffer-substring (car expr) (cdr expr)))))
1237
1238 (defun expr-cur ()
1239   "Returns the expr that point is in; point is set to beginning of expr.
1240 The expr is represented as a cons cell, where the car specifies the point in
1241 the current buffer that marks the beginning of the expr and the cdr specifies
1242 the character after the end of the expr."
1243   (let ((p (point)) (begin) (end))
1244     (expr-backward-sexp)
1245     (setq begin (point))
1246     (expr-forward-sexp)
1247     (setq end (point))
1248     (if (>= p end)
1249         (progn
1250          (setq begin p)
1251          (goto-char p)
1252          (expr-forward-sexp)
1253          (setq end (point))
1254          )
1255       )
1256     (goto-char begin)
1257     (cons begin end)))
1258
1259 (defun expr-backward-sexp ()
1260   "Version of `backward-sexp' that catches errors."
1261   (condition-case nil
1262       (backward-sexp)
1263     (error t)))
1264
1265 (defun expr-forward-sexp ()
1266   "Version of `forward-sexp' that catches errors."
1267   (condition-case nil
1268      (forward-sexp)
1269     (error t)))
1270
1271 (defun expr-prev ()
1272   "Returns the previous expr, point is set to beginning of that expr.
1273 The expr is represented as a cons cell, where the car specifies the point in
1274 the current buffer that marks the beginning of the expr and the cdr specifies
1275 the character after the end of the expr"
1276   (let ((begin) (end))
1277     (expr-backward-sexp)
1278     (setq begin (point))
1279     (expr-forward-sexp)
1280     (setq end (point))
1281     (goto-char begin)
1282     (cons begin end)))
1283
1284 (defun expr-next ()
1285   "Returns the following expr, point is set to beginning of that expr.
1286 The expr is represented as a cons cell, where the car specifies the point in
1287 the current buffer that marks the beginning of the expr and the cdr specifies
1288 the character after the end of the expr."
1289   (let ((begin) (end))
1290     (expr-forward-sexp)
1291     (expr-forward-sexp)
1292     (setq end (point))
1293     (expr-backward-sexp)
1294     (setq begin (point))
1295     (cons begin end)))
1296
1297 (defun expr-compound-sep (span-start span-end)
1298   "Returns '.' for '->' & '.', returns ' ' for white space,
1299 returns '?' for other punctuation."
1300   (let ((result ? )
1301         (syntax))
1302     (while (< span-start span-end)
1303       (setq syntax (char-syntax (char-after span-start)))
1304       (cond
1305        ((= syntax ? ) t)
1306        ((= syntax ?.) (setq syntax (char-after span-start))
1307         (cond
1308          ((= syntax ?.) (setq result ?.))
1309          ((and (= syntax ?-) (= (char-after (+ span-start 1)) ?>))
1310           (setq result ?.)
1311           (setq span-start (+ span-start 1)))
1312          (t (setq span-start span-end)
1313             (setq result ??)))))
1314       (setq span-start (+ span-start 1)))
1315     result))
1316
1317 (defun expr-compound (first second)
1318   "Non-nil if concatenating FIRST and SECOND makes a single C token.
1319 The two exprs are represented as a cons cells, where the car
1320 specifies the point in the current buffer that marks the beginning of the
1321 expr and the cdr specifies the character after the end of the expr.
1322 Link exprs of the form:
1323       Expr -> Expr
1324       Expr . Expr
1325       Expr (Expr)
1326       Expr [Expr]
1327       (Expr) Expr
1328       [Expr] Expr"
1329   (let ((span-start (cdr first))
1330         (span-end (car second))
1331         (syntax))
1332     (setq syntax (expr-compound-sep span-start span-end))
1333     (cond
1334      ((= (car first) (car second)) nil)
1335      ((= (cdr first) (cdr second)) nil)
1336      ((= syntax ?.) t)
1337      ((= syntax ? )
1338          (setq span-start (char-after (- span-start 1)))
1339          (setq span-end (char-after span-end))
1340          (cond
1341           ((= span-start ?) ) t )
1342           ((= span-start ?] ) t )
1343           ((= span-end ?( ) t )
1344           ((= span-end ?[ ) t )
1345           (t nil))
1346          )
1347      (t nil))))
1348
1349 (provide 'gud)
1350
1351 ;;; gud.el ends here