lisp/hexl.el

   1 ;;; hexl.el --- edit a file in a hex dump format using the hexl filter.
   2
   3 ;; Copyright (C) 1989, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Keith Gabryelski <ag@wheaties.ai.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package implements a major mode for editing binary files.  It uses
  28 ;; a program called hexl, supplied with the GNU Emacs distribution, that
  29 ;; can filter a binary into an editable format or from the format back into
  30 ;; binary.  For full instructions, invoke `hexl-mode' on an empty buffer and
  31 ;; do `M-x describe-mode'.
  32 ;;
  33 ;; This may be useful in your .emacs:
  34 ;;
  35 ;;      (autoload 'hexl-find-file "hexl"
  36 ;;        "Edit file FILENAME in hexl-mode." t)
  37 ;;
  38 ;;      (define-key global-map "\C-c\C-h" 'hexl-find-file)
  39 ;;
  40 ;; NOTE: Remember to change HEXL-PROGRAM or HEXL-OPTIONS if needed.
  41 ;;
  42 ;; Currently hexl only supports big endian hex output with 16 bit
  43 ;; grouping.
  44 ;;
  45 ;; -iso in `hexl-options' will allow iso characters to display in the
  46 ;; ASCII region of the screen (if your emacs supports this) instead of
  47 ;; changing them to dots.
  48
  49 ;;; Code:
  50
  51 ;;
  52 ;; vars here
  53 ;;
  54
  55 (defvar hexl-program "hexl"
  56   "The program that will hexlify and de-hexlify its stdin.
  57 `hexl-program' will always be concatenated with `hexl-options'
  58 and \"-de\" when dehexlfying a buffer.")
  59
  60 (defvar hexl-iso ""
  61   "If your emacs can handle ISO characters, this should be set to
  62 \"-iso\" otherwise it should be \"\".")
  63
  64 (defvar hexl-options (format "-hex %s" hexl-iso)
  65   "Options to hexl-program that suit your needs.")
  66
  67 (defvar hexlify-command
  68   (format "%s%s %s" exec-directory hexl-program hexl-options)
  69   "The command to use to hexlify a buffer.")
  70
  71 (defvar dehexlify-command
  72   (format "%s%s -de %s" exec-directory hexl-program hexl-options)
  73   "The command to use to unhexlify a buffer.")
  74
  75 (defvar hexl-max-address 0
  76   "Maximum offset into hexl buffer.")
  77
  78 (defvar hexl-mode-map nil)
  79
  80 ;; routines
  81
  82 ;;;###autoload
  83 (defun hexl-mode (&optional arg)
  84   "\\<hexl-mode-map>
  85 A major mode for editing binary files in hex dump format.
  86
  87 This function automatically converts a buffer into the hexl format
  88 using the function `hexlify-buffer'.
  89
  90 Each line in the buffer has an \"address\" (displayed in hexadecimal)
  91 representing the offset into the file that the characters on this line
  92 are at and 16 characters from the file (displayed as hexadecimal
  93 values grouped every 16 bits) and as their ASCII values.
  94
  95 If any of the characters (displayed as ASCII characters) are
  96 unprintable (control or meta characters) they will be replaced as
  97 periods.
  98
  99 If `hexl-mode' is invoked with an argument the buffer is assumed to be
 100 in hexl format.
 101
 102 A sample format:
 103
 104   HEX ADDR: 0001 0203 0405 0607 0809 0a0b 0c0d 0e0f     ASCII-TEXT
 105   --------  ---- ---- ---- ---- ---- ---- ---- ----  ----------------
 106   00000000: 5468 6973 2069 7320 6865 786c 2d6d 6f64  This is hexl-mod
 107   00000010: 652e 2020 4561 6368 206c 696e 6520 7265  e.  Each line re
 108   00000020: 7072 6573 656e 7473 2031 3620 6279 7465  presents 16 byte
 109   00000030: 7320 6173 2068 6578 6164 6563 696d 616c  s as hexadecimal
 110   00000040: 2041 5343 4949 0a61 6e64 2070 7269 6e74   ASCII.and print
 111   00000050: 6162 6c65 2041 5343 4949 2063 6861 7261  able ASCII chara
 112   00000060: 6374 6572 732e 2020 416e 7920 636f 6e74  cters.  Any cont
 113   00000070: 726f 6c20 6f72 206e 6f6e 2d41 5343 4949  rol or non-ASCII
 114   00000080: 2063 6861 7261 6374 6572 730a 6172 6520   characters.are
 115   00000090: 6469 7370 6c61 7965 6420 6173 2070 6572  displayed as per
 116   000000a0: 696f 6473 2069 6e20 7468 6520 7072 696e  iods in the prin
 117   000000b0: 7461 626c 6520 6368 6172 6163 7465 7220  table character
 118   000000c0: 7265 6769 6f6e 2e0a                      region..
 119
 120 Movement is as simple as movement in a normal emacs text buffer.  Most
 121 cursor movement bindings are the same (ie. Use \\[hexl-backward-char], \\[hexl-forward-char], \\[hexl-next-line], and \\[hexl-previous-line]
 122 to move the cursor left, right, down, and up).
 123
 124 Advanced cursor movement commands (ala \\[hexl-beginning-of-line], \\[hexl-end-of-line], \\[hexl-beginning-of-buffer], and \\[hexl-end-of-buffer]) are
 125 also supported.
 126
 127 There are several ways to change text in hexl mode:
 128
 129 ASCII characters (character between space (0x20) and tilde (0x7E)) are
 130 bound to self-insert so you can simply type the character and it will
 131 insert itself (actually overstrike) into the buffer.
 132
 133 \\[hexl-quoted-insert] followed by another keystroke allows you to insert the key even if
 134 it isn't bound to self-insert.  An octal number can be supplied in place
 135 of another key to insert the octal number's ASCII representation.
 136
 137 \\[hexl-insert-hex-char] will insert a given hexadecimal value (if it is between 0 and 0xFF)
 138 into the buffer at the current point.
 139
 140 \\[hexl-insert-octal-char] will insert a given octal value (if it is between 0 and 0377)
 141 into the buffer at the current point.
 142
 143 \\[hexl-insert-decimal-char] will insert a given decimal value (if it is between 0 and 255)
 144 into the buffer at the current point.
 145
 146 \\[hexl-mode-exit] will exit hexl-mode.
 147
 148 Note: saving the file with any of the usual Emacs commands
 149 will actually convert it back to binary format while saving.
 150
 151 You can use \\[hexl-find-file] to visit a file in hexl-mode.
 152
 153 \\[describe-bindings] for advanced commands."
 154   (interactive "p")
 155   (if (eq major-mode 'hexl-mode)
 156       (error "You are already in hexl mode.")
 157     (kill-all-local-variables)
 158     (make-local-variable 'hexl-mode-old-local-map)
 159     (setq hexl-mode-old-local-map (current-local-map))
 160     (use-local-map hexl-mode-map)
 161
 162     (make-local-variable 'hexl-mode-old-mode-name)
 163     (setq hexl-mode-old-mode-name mode-name)
 164     (setq mode-name "Hexl")
 165
 166     (make-local-variable 'hexl-mode-old-major-mode)
 167     (setq hexl-mode-old-major-mode major-mode)
 168     (setq major-mode 'hexl-mode)
 169
 170     (make-local-variable 'write-contents-hooks)
 171     (add-hook 'write-contents-hooks 'hexl-save-buffer)
 172
 173     (make-local-variable 'hexl-max-address)
 174
 175     (let ((modified (buffer-modified-p))
 176           (inhibit-read-only t)
 177           (original-point (1- (point))))
 178       (if (not (or (eq arg 1) (not arg)))
 179           ;; if no argument then we guess at hexl-max-address
 180           (setq hexl-max-address (+ (* (/ (1- (buffer-size)) 68) 16) 15))
 181         (setq hexl-max-address (1- (buffer-size)))
 182         (hexlify-buffer)
 183         (set-buffer-modified-p modified)
 184         (hexl-goto-address original-point)))))
 185
 186 (defvar hexl-in-save-buffer nil)
 187
 188 (defun hexl-save-buffer ()
 189   "Save a hexl format buffer as binary in visited file if modified."
 190   (interactive)
 191   (if hexl-in-save-buffer nil
 192     (set-buffer-modified-p (if (buffer-modified-p)
 193                                (save-excursion
 194                                  (let ((buf (generate-new-buffer " hexl"))
 195                                        (name (buffer-name))
 196                                        (file-name (buffer-file-name))
 197                                        (start (point-min))
 198                                        (end (point-max))
 199                                        modified)
 200                                    (set-buffer buf)
 201                                    (insert-buffer-substring name start end)
 202                                    (set-buffer name)
 203                                    (dehexlify-buffer)
 204                                    ;; Prevent infinite recursion.
 205                                    (let ((hexl-in-save-buffer t)
 206                                          (buffer-file-type t)) ; for ms-dos
 207                                      (save-buffer))
 208                                    (setq modified (buffer-modified-p))
 209                                    (delete-region (point-min) (point-max))
 210                                    (insert-buffer-substring buf start end)
 211                                    (kill-buffer buf)
 212                                    modified))
 213                              (message "(No changes need to be saved)")
 214                              nil))
 215     ;; Return t to indicate we have saved t
 216     t))
 217
 218 ;;;###autoload
 219 (defun hexl-find-file (filename)
 220   "Edit file FILENAME in hexl-mode.
 221 Switch to a buffer visiting file FILENAME, creating one in none exists."
 222   (interactive "fFilename: ")
 223   (if (eq system-type 'ms-dos)
 224       (find-file-binary filename)
 225     (find-file filename))
 226   (if (not (eq major-mode 'hexl-mode))
 227       (hexl-mode)))
 228
 229 (defun hexl-mode-exit (&optional arg)
 230   "Exit Hexl mode, returning to previous mode.
 231 With arg, don't unhexlify buffer."
 232   (interactive "p")
 233   (if (or (eq arg 1) (not arg))
 234       (let ((modified (buffer-modified-p))
 235             (inhibit-read-only t)
 236             (original-point (1+ (hexl-current-address))))
 237         (dehexlify-buffer)
 238         (remove-hook 'write-contents-hook 'hexl-save-buffer)
 239         (set-buffer-modified-p modified)
 240         (goto-char original-point)))
 241   (setq mode-name hexl-mode-old-mode-name)
 242   (use-local-map hexl-mode-old-local-map)
 243   (setq major-mode hexl-mode-old-major-mode)
 244 ;; Kludge to update mode-line
 245   (switch-to-buffer (current-buffer))
 246 )
 247
 248 (defun hexl-current-address ()
 249   "Return current hexl-address."
 250   (interactive)
 251   (let ((current-column (- (% (point) 68) 11))
 252         (hexl-address 0))
 253     (setq hexl-address (+ (* (/ (point) 68) 16)
 254                           (/ (- current-column  (/ current-column 5)) 2)))
 255     hexl-address))
 256
 257 (defun hexl-address-to-marker (address)
 258   "Return marker for ADDRESS."
 259   (interactive "nAddress: ")
 260   (+ (* (/ address 16) 68) 11 (/ (* (% address 16) 5) 2)))
 261
 262 (defun hexl-goto-address (address)
 263   "Goto hexl-mode (decimal) address ADDRESS.
 264
 265 Signal error if ADDRESS out of range."
 266   (interactive "nAddress: ")
 267   (if (or (< address 0) (> address hexl-max-address))
 268           (error "Out of hexl region."))
 269   (goto-char (hexl-address-to-marker address)))
 270
 271 (defun hexl-goto-hex-address (hex-address)
 272   "Go to hexl-mode address (hex string) HEX-ADDRESS.
 273
 274 Signal error if HEX-ADDRESS is out of range."
 275   (interactive "sHex Address: ")
 276   (hexl-goto-address (hexl-hex-string-to-integer hex-address)))
 277
 278 (defun hexl-hex-string-to-integer (hex-string)
 279   "Return decimal integer for HEX-STRING."
 280   (interactive "sHex number: ")
 281   (let ((hex-num 0))
 282     (while (not (equal hex-string ""))
 283       (setq hex-num (+ (* hex-num 16)
 284                        (hexl-hex-char-to-integer (string-to-char hex-string))))
 285       (setq hex-string (substring hex-string 1)))
 286     hex-num))
 287
 288 (defun hexl-octal-string-to-integer (octal-string)
 289   "Return decimal integer for OCTAL-STRING."
 290   (interactive "sOctal number: ")
 291   (let ((oct-num 0))
 292     (while (not (equal octal-string ""))
 293       (setq oct-num (+ (* oct-num 8)
 294                        (hexl-oct-char-to-integer
 295                         (string-to-char octal-string))))
 296       (setq octal-string (substring octal-string 1)))
 297     oct-num))
 298
 299 ;; move point functions
 300
 301 (defun hexl-backward-char (arg)
 302   "Move to left ARG bytes (right if ARG negative) in hexl-mode."
 303   (interactive "p")
 304   (hexl-goto-address (- (hexl-current-address) arg)))
 305
 306 (defun hexl-forward-char (arg)
 307   "Move right ARG bytes (left if ARG negative) in hexl-mode."
 308   (interactive "p")
 309   (hexl-goto-address (+ (hexl-current-address) arg)))
 310
 311 (defun hexl-backward-short (arg)
 312   "Move to left ARG shorts (right if ARG negative) in hexl-mode."
 313   (interactive "p")
 314   (hexl-goto-address (let ((address (hexl-current-address)))
 315                        (if (< arg 0)
 316                            (progn
 317                              (setq arg (- arg))
 318                              (while (> arg 0)
 319                                (if (not (equal address (logior address 3)))
 320                                    (if (> address hexl-max-address)
 321                                        (progn
 322                                          (message "End of buffer.")
 323                                          (setq address hexl-max-address))
 324                                      (setq address (logior address 3)))
 325                                  (if (> address hexl-max-address)
 326                                      (progn
 327                                        (message "End of buffer.")
 328                                        (setq address hexl-max-address))
 329                                    (setq address (+ address 4))))
 330                                (setq arg (1- arg)))
 331                              (if (> address hexl-max-address)
 332                                  (progn
 333                                    (message "End of buffer.")
 334                                    (setq address hexl-max-address))
 335                                (setq address (logior address 3))))
 336                          (while (> arg 0)
 337                            (if (not (equal address (logand address -4)))
 338                                (setq address (logand address -4))
 339                              (if (not (equal address 0))
 340                                  (setq address (- address 4))
 341                                (message "Beginning of buffer.")))
 342                            (setq arg (1- arg))))
 343                        address)))
 344
 345 (defun hexl-forward-short (arg)
 346   "Move right ARG shorts (left if ARG negative) in hexl-mode."
 347   (interactive "p")
 348   (hexl-backward-short (- arg)))
 349
 350 (defun hexl-backward-word (arg)
 351   "Move to left ARG words (right if ARG negative) in hexl-mode."
 352   (interactive "p")
 353   (hexl-goto-address (let ((address (hexl-current-address)))
 354                        (if (< arg 0)
 355                            (progn
 356                              (setq arg (- arg))
 357                              (while (> arg 0)
 358                                (if (not (equal address (logior address 7)))
 359                                    (if (> address hexl-max-address)
 360                                        (progn
 361                                          (message "End of buffer.")
 362                                          (setq address hexl-max-address))
 363                                      (setq address (logior address 7)))
 364                                  (if (> address hexl-max-address)
 365                                      (progn
 366                                        (message "End of buffer.")
 367                                        (setq address hexl-max-address))
 368                                    (setq address (+ address 8))))
 369                                (setq arg (1- arg)))
 370                              (if (> address hexl-max-address)
 371                                  (progn
 372                                    (message "End of buffer.")
 373                                    (setq address hexl-max-address))
 374                                (setq address (logior address 7))))
 375                          (while (> arg 0)
 376                            (if (not (equal address (logand address -8)))
 377                                (setq address (logand address -8))
 378                              (if (not (equal address 0))
 379                                  (setq address (- address 8))
 380                                (message "Beginning of buffer.")))
 381                            (setq arg (1- arg))))
 382                        address)))
 383
 384 (defun hexl-forward-word (arg)
 385   "Move right ARG words (left if ARG negative) in hexl-mode."
 386   (interactive "p")
 387   (hexl-backward-word (- arg)))
 388
 389 (defun hexl-previous-line (arg)
 390   "Move vertically up ARG lines [16 bytes] (down if ARG negative) in hexl-mode.
 391 If there is byte at the target address move to the last byte in that line."
 392   (interactive "p")
 393   (hexl-next-line (- arg)))
 394
 395 (defun hexl-next-line (arg)
 396   "Move vertically down ARG lines [16 bytes] (up if ARG negative) in hexl-mode.
 397 If there is no byte at the target address move to the last byte in that line."
 398   (interactive "p")
 399   (hexl-goto-address (let ((address (+ (hexl-current-address) (* arg 16))))
 400                        (if (and (< arg 0) (< address 0))
 401                                 (progn (message "Out of hexl region.")
 402                                        (setq address
 403                                              (% (hexl-current-address) 16)))
 404                          (if (and (> address hexl-max-address)
 405                                   (< (% hexl-max-address 16) (% address 16)))
 406                              (setq address hexl-max-address)
 407                            (if (> address hexl-max-address)
 408                                (progn (message "Out of hexl region.")
 409                                       (setq
 410                                        address
 411                                        (+ (logand hexl-max-address -16)
 412                                           (% (hexl-current-address) 16)))))))
 413                        address)))
 414
 415 (defun hexl-beginning-of-buffer (arg)
 416   "Move to the beginning of the hexl buffer.
 417 Leaves `hexl-mark' at previous position.
 418 With prefix arg N, puts point N bytes of the way from the true beginning."
 419   (interactive "p")
 420   (push-mark (point))
 421   (hexl-goto-address (+ 0 (1- arg))))
 422
 423 (defun hexl-end-of-buffer (arg)
 424   "Go to `hexl-max-address' minus ARG."
 425   (interactive "p")
 426   (push-mark (point))
 427   (hexl-goto-address (- hexl-max-address (1- arg))))
 428
 429 (defun hexl-beginning-of-line ()
 430   "Goto beginning of line in hexl mode."
 431   (interactive)
 432   (goto-char (+ (* (/ (point) 68) 68) 11)))
 433
 434 (defun hexl-end-of-line ()
 435   "Goto end of line in hexl mode."
 436   (interactive)
 437   (hexl-goto-address (let ((address (logior (hexl-current-address) 15)))
 438                        (if (> address hexl-max-address)
 439                            (setq address hexl-max-address))
 440                        address)))
 441
 442 (defun hexl-scroll-down (arg)
 443   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 444   (interactive "P")
 445   (if (null arg)
 446       (setq arg (1- (window-height)))
 447     (setq arg (prefix-numeric-value arg)))
 448   (hexl-scroll-up (- arg)))
 449
 450 (defun hexl-scroll-up (arg)
 451   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 452   (interactive "P")
 453   (if (null arg)
 454       (setq arg (1- (window-height)))
 455     (setq arg (prefix-numeric-value arg)))
 456   (let ((movement (* arg 16))
 457         (address (hexl-current-address)))
 458     (if (or (> (+ address movement) hexl-max-address)
 459             (< (+ address movement) 0))
 460         (message "Out of hexl region.")
 461       (hexl-goto-address (+ address movement))
 462       (recenter 0))))
 463
 464 (defun hexl-beginning-of-1k-page ()
 465   "Goto to beginning of 1k boundry."
 466   (interactive)
 467   (hexl-goto-address (logand (hexl-current-address) -1024)))
 468
 469 (defun hexl-end-of-1k-page ()
 470   "Goto to end of 1k boundry."
 471   (interactive)
 472   (hexl-goto-address (let ((address (logior (hexl-current-address) 1023)))
 473                        (if (> address hexl-max-address)
 474                            (setq address hexl-max-address))
 475                        address)))
 476
 477 (defun hexl-beginning-of-512b-page ()
 478   "Goto to beginning of 512 byte boundry."
 479   (interactive)
 480   (hexl-goto-address (logand (hexl-current-address) -512)))
 481
 482 (defun hexl-end-of-512b-page ()
 483   "Goto to end of 512 byte boundry."
 484   (interactive)
 485   (hexl-goto-address (let ((address (logior (hexl-current-address) 511)))
 486                        (if (> address hexl-max-address)
 487                            (setq address hexl-max-address))
 488                        address)))
 489
 490 (defun hexl-quoted-insert (arg)
 491   "Read next input character and insert it.
 492 Useful for inserting control characters.
 493 You may also type up to 3 octal digits, to insert a character with that code"
 494   (interactive "p")
 495   (hexl-insert-char (read-quoted-char) arg))
 496
 497 ;00000000: 0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789ABCDEF
 498
 499 ;;;###autoload
 500 (defun hexlify-buffer ()
 501   "Convert a binary buffer to hexl format"
 502   (interactive)
 503   (let ((binary-process-output nil) ; for Ms-Dos
 504         (binary-process-input t))
 505     (shell-command-on-region (point-min) (point-max) hexlify-command t)))
 506
 507 (defun dehexlify-buffer ()
 508   "Convert a hexl format buffer to binary."
 509   (interactive)
 510   (let ((binary-process-output t) ; for Ms-Dos
 511         (binary-process-input nil))
 512     (shell-command-on-region (point-min) (point-max) dehexlify-command t)))
 513
 514 (defun hexl-char-after-point ()
 515   "Return char for ASCII hex digits at point."
 516   (hexl-htoi (char-after (point))
 517              (char-after (1+ (point)))))
 518
 519 (defun hexl-htoi (lh rh)
 520   "Hex (char) LH (char) RH to integer."
 521     (+ (* (hexl-hex-char-to-integer lh) 16)
 522        (hexl-hex-char-to-integer rh)))
 523
 524 (defun hexl-hex-char-to-integer (character)
 525   "Take a char and return its value as if it was a hex digit."
 526   (if (and (>= character ?0) (<= character ?9))
 527       (- character ?0)
 528     (let ((ch (logior character 32)))
 529       (if (and (>= ch ?a) (<= ch ?f))
 530           (- ch (- ?a 10))
 531         (error (format "Invalid hex digit `%c'." ch))))))
 532
 533 (defun hexl-oct-char-to-integer (character)
 534   "Take a char and return its value as if it was a octal digit."
 535   (if (and (>= character ?0) (<= character ?7))
 536       (- character ?0)
 537     (error (format "Invalid octal digit `%c'." character))))
 538
 539 (defun hexl-printable-character (ch)
 540   "Return a displayable string for character CH."
 541   (format "%c" (if hexl-iso
 542                    (if (or (< ch 32) (and (>= ch 127) (< ch 160)))
 543                        46
 544                      ch)
 545                  (if (or (< ch 32) (>= ch 127))
 546                      46
 547                    ch))))
 548
 549 (defun hexl-self-insert-command (arg)
 550   "Insert this character."
 551   (interactive "p")
 552   (hexl-insert-char last-command-char arg))
 553
 554 (defun hexl-insert-char (ch num)
 555   "Insert a character in a hexl buffer."
 556   (let ((address (hexl-current-address)))
 557     (while (> num 0)
 558       (delete-char 2)
 559       (insert (format "%02x" ch))
 560       (goto-char
 561        (+ (* (/ address 16) 68) 52 (% address 16)))
 562       (delete-char 1)
 563       (insert (hexl-printable-character ch))
 564       (or (eq address hexl-max-address)
 565           (setq address (1+ address)))
 566       (hexl-goto-address address)
 567       (setq num (1- num)))))
 568
 569 ;; hex conversion
 570
 571 (defun hexl-insert-hex-char (arg)
 572   "Insert a ASCII char ARG times at point for a given hexadecimal number."
 573   (interactive "p")
 574   (let ((num (hexl-hex-string-to-integer (read-string "Hex number: "))))
 575     (if (or (> num 255) (< num 0))
 576         (error "Hex number out of range.")
 577       (hexl-insert-char num arg))))
 578
 579 (defun hexl-insert-decimal-char (arg)
 580   "Insert a ASCII char ARG times at point for a given decimal number."
 581   (interactive "p")
 582   (let ((num (string-to-int (read-string "Decimal Number: "))))
 583     (if (or (> num 255) (< num 0))
 584         (error "Decimal number out of range.")
 585       (hexl-insert-char num arg))))
 586
 587 (defun hexl-insert-octal-char (arg)
 588   "Insert a ASCII char ARG times at point for a given octal number."
 589   (interactive "p")
 590   (let ((num (hexl-octal-string-to-integer (read-string "Octal Number: "))))
 591     (if (or (> num 255) (< num 0))
 592         (error "Decimal number out of range.")
 593       (hexl-insert-char num arg))))
 594
 595 ;; startup stuff.
 596
 597 (if hexl-mode-map
 598     nil
 599     (setq hexl-mode-map (make-sparse-keymap))
 600
 601     (define-key hexl-mode-map [left] 'hexl-backward-char)
 602     (define-key hexl-mode-map [right] 'hexl-forward-char)
 603     (define-key hexl-mode-map [up] 'hexl-previous-line)
 604     (define-key hexl-mode-map [down] 'hexl-next-line)
 605     (define-key hexl-mode-map [M-left] 'hexl-backward-short)
 606     (define-key hexl-mode-map [M-right] 'hexl-forward-short)
 607     (define-key hexl-mode-map [next] 'hexl-scroll-up)
 608     (define-key hexl-mode-map [prev] 'hexl-scroll-down)
 609
 610     (define-key hexl-mode-map "\C-a" 'hexl-beginning-of-line)
 611     (define-key hexl-mode-map "\C-b" 'hexl-backward-char)
 612     (define-key hexl-mode-map "\C-d" 'undefined)
 613     (define-key hexl-mode-map "\C-e" 'hexl-end-of-line)
 614     (define-key hexl-mode-map "\C-f" 'hexl-forward-char)
 615
 616     (if (not (eq (key-binding (char-to-string help-char)) 'help-command))
 617         (define-key hexl-mode-map help-char 'undefined))
 618
 619     (define-key hexl-mode-map "\C-i" 'hexl-self-insert-command)
 620     (define-key hexl-mode-map "\C-j" 'hexl-self-insert-command)
 621     (define-key hexl-mode-map "\C-k" 'undefined)
 622     (define-key hexl-mode-map "\C-m" 'hexl-self-insert-command)
 623     (define-key hexl-mode-map "\C-n" 'hexl-next-line)
 624     (define-key hexl-mode-map "\C-o" 'undefined)
 625     (define-key hexl-mode-map "\C-p" 'hexl-previous-line)
 626     (define-key hexl-mode-map "\C-q" 'hexl-quoted-insert)
 627     (define-key hexl-mode-map "\C-t" 'undefined)
 628     (define-key hexl-mode-map "\C-v" 'hexl-scroll-up)
 629     (define-key hexl-mode-map "\C-w" 'undefined)
 630     (define-key hexl-mode-map "\C-y" 'undefined)
 631
 632     (let ((ch 32))
 633       (while (< ch 127)
 634         (define-key hexl-mode-map (format "%c" ch) 'hexl-self-insert-command)
 635         (setq ch (1+ ch))))
 636
 637     (define-key hexl-mode-map "\e\C-a" 'hexl-beginning-of-512b-page)
 638     (define-key hexl-mode-map "\e\C-b" 'hexl-backward-short)
 639     (define-key hexl-mode-map "\e\C-c" 'undefined)
 640     (define-key hexl-mode-map "\e\C-d" 'hexl-insert-decimal-char)
 641     (define-key hexl-mode-map "\e\C-e" 'hexl-end-of-512b-page)
 642     (define-key hexl-mode-map "\e\C-f" 'hexl-forward-short)
 643     (define-key hexl-mode-map "\e\C-g" 'undefined)
 644     (define-key hexl-mode-map "\e\C-h" 'undefined)
 645     (define-key hexl-mode-map "\e\C-i" 'undefined)
 646     (define-key hexl-mode-map "\e\C-j" 'undefined)
 647     (define-key hexl-mode-map "\e\C-k" 'undefined)
 648     (define-key hexl-mode-map "\e\C-l" 'undefined)
 649     (define-key hexl-mode-map "\e\C-m" 'undefined)
 650     (define-key hexl-mode-map "\e\C-n" 'undefined)
 651     (define-key hexl-mode-map "\e\C-o" 'hexl-insert-octal-char)
 652     (define-key hexl-mode-map "\e\C-p" 'undefined)
 653     (define-key hexl-mode-map "\e\C-q" 'undefined)
 654     (define-key hexl-mode-map "\e\C-r" 'undefined)
 655     (define-key hexl-mode-map "\e\C-s" 'undefined)
 656     (define-key hexl-mode-map "\e\C-t" 'undefined)
 657     (define-key hexl-mode-map "\e\C-u" 'undefined)
 658
 659     (define-key hexl-mode-map "\e\C-w" 'undefined)
 660     (define-key hexl-mode-map "\e\C-x" 'hexl-insert-hex-char)
 661     (define-key hexl-mode-map "\e\C-y" 'undefined)
 662
 663     (define-key hexl-mode-map "\ea" 'undefined)
 664     (define-key hexl-mode-map "\eb" 'hexl-backward-word)
 665     (define-key hexl-mode-map "\ec" 'undefined)
 666     (define-key hexl-mode-map "\ed" 'undefined)
 667     (define-key hexl-mode-map "\ee" 'undefined)
 668     (define-key hexl-mode-map "\ef" 'hexl-forward-word)
 669     (define-key hexl-mode-map "\eg" 'hexl-goto-hex-address)
 670     (define-key hexl-mode-map "\eh" 'undefined)
 671     (define-key hexl-mode-map "\ei" 'undefined)
 672     (define-key hexl-mode-map "\ej" 'hexl-goto-address)
 673     (define-key hexl-mode-map "\ek" 'undefined)
 674     (define-key hexl-mode-map "\el" 'undefined)
 675     (define-key hexl-mode-map "\em" 'undefined)
 676     (define-key hexl-mode-map "\en" 'undefined)
 677     (define-key hexl-mode-map "\eo" 'undefined)
 678     (define-key hexl-mode-map "\ep" 'undefined)
 679     (define-key hexl-mode-map "\eq" 'undefined)
 680     (define-key hexl-mode-map "\er" 'undefined)
 681     (define-key hexl-mode-map "\es" 'undefined)
 682     (define-key hexl-mode-map "\et" 'undefined)
 683     (define-key hexl-mode-map "\eu" 'undefined)
 684     (define-key hexl-mode-map "\ev" 'hexl-scroll-down)
 685     (define-key hexl-mode-map "\ey" 'undefined)
 686     (define-key hexl-mode-map "\ez" 'undefined)
 687     (define-key hexl-mode-map "\e<" 'hexl-beginning-of-buffer)
 688     (define-key hexl-mode-map "\e>" 'hexl-end-of-buffer)
 689
 690     (define-key hexl-mode-map "\C-c\C-c" 'hexl-mode-exit)
 691
 692     (define-key hexl-mode-map "\C-x[" 'hexl-beginning-of-1k-page)
 693     (define-key hexl-mode-map "\C-x]" 'hexl-end-of-1k-page)
 694     (define-key hexl-mode-map "\C-x\C-p" 'undefined)
 695     (define-key hexl-mode-map "\C-x\C-s" 'hexl-save-buffer)
 696     (define-key hexl-mode-map "\C-x\C-t" 'undefined))
 697
 698 ;;; hexl.el ends here