lisp/textmodes/nroff-mode.el

   1 ;;; nroff-mode.el --- GNU Emacs major mode for editing nroff source
   2
   3 ;; Copyright (C) 1985, 1986, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: wp
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package is a major mode for editing nroff source code.  It knows
  28 ;; about various nroff constructs, ms, mm, and me macros, and will fill
  29 ;; and indent paragraphs properly in their presence.  It also includes
  30 ;; a command to count text lines (excluding nroff constructs), a command
  31 ;; to center a line, and movement commands that know how to skip macros.
  32
  33 ;; Paragraph filling and line-counting currently don't respect comments,
  34 ;; as they should.
  35
  36 ;;; Code:
  37
  38 (defgroup nroff nil
  39   "Nroff mode."
  40   :group 'wp
  41   :prefix "nroff-")
  42
  43 (defvar nroff-mode-abbrev-table nil
  44   "Abbrev table used while in nroff mode.")
  45 (define-abbrev-table 'nroff-mode-abbrev-table ())
  46
  47 (defcustom nroff-electric-mode nil
  48   "*Non-nil means automatically closing requests when you insert an open."
  49   :group 'nroff
  50   :type 'boolean)
  51
  52 (defvar nroff-mode-map nil
  53      "Major mode keymap for nroff mode.")
  54 (if (not nroff-mode-map)
  55     (progn
  56       (setq nroff-mode-map (make-sparse-keymap))
  57       (define-key nroff-mode-map "\t"  'tab-to-tab-stop)
  58       (define-key nroff-mode-map "\es" 'center-line)
  59       (define-key nroff-mode-map "\e?" 'count-text-lines)
  60       (define-key nroff-mode-map "\n"  'electric-nroff-newline)
  61       (define-key nroff-mode-map "\en" 'forward-text-line)
  62       (define-key nroff-mode-map "\ep" 'backward-text-line)))
  63
  64 (defvar nroff-mode-syntax-table nil
  65   "Syntax table used while in nroff mode.")
  66
  67 (defcustom nroff-font-lock-keywords
  68   (list
  69    ;; Directives are . or ' at start of line, followed by
  70    ;; optional whitespace, then command (which my be longer than
  71    ;; 2 characters in groff).  Perhaps the arguments should be
  72    ;; fontified as well.
  73    "^[.']\\s-*\\sw+"
  74    ;; There are numerous groff escapes; the following get things
  75    ;; like \-, \(em (standard troff) and \f[bar] (groff
  76    ;; variants).  This won't currently do groff's \A'foo' and
  77    ;; the like properly.  One might expect it to highlight an escape's
  78    ;; arguments in common cases, like \f.
  79    (concat "\\\\"                     ; backslash
  80          "\\("                        ; followed by various possibilities
  81          (mapconcat 'identity
  82                     '("[f*n]*\\[.+]"  ; some groff extensions
  83                       "(.."           ; two chars after (
  84                       "[^(\"]"        ; single char escape
  85                       ) "\\|")
  86          "\\)")
  87    )
  88   "Font-lock highlighting control in nroff-mode."
  89   :group 'nroff
  90   :type '(repeat regexp))
  91
  92 ;;;###autoload
  93 (defun nroff-mode ()
  94   "Major mode for editing text intended for nroff to format.
  95 \\{nroff-mode-map}
  96 Turning on Nroff mode runs `text-mode-hook', then `nroff-mode-hook'.
  97 Also, try `nroff-electric-mode', for automatically inserting
  98 closing requests for requests that are used in matched pairs."
  99   (interactive)
 100   (kill-all-local-variables)
 101   (use-local-map nroff-mode-map)
 102   (setq mode-name "Nroff")
 103   (setq major-mode 'nroff-mode)
 104   (if nroff-mode-syntax-table
 105       ()
 106     (setq nroff-mode-syntax-table (copy-syntax-table text-mode-syntax-table))
 107     ;; " isn't given string quote syntax in text-mode but it
 108     ;; (arguably) should be for use round nroff arguments (with ` and
 109     ;; ' used otherwise).
 110     (modify-syntax-entry ?\" "\"  2" nroff-mode-syntax-table)
 111     ;; Comments are delimited by \" and newline.
 112     (modify-syntax-entry ?\\ "\\  1" nroff-mode-syntax-table)
 113     (modify-syntax-entry ?\n ">  1" nroff-mode-syntax-table))
 114   (set-syntax-table nroff-mode-syntax-table)
 115   (make-local-variable 'font-lock-defaults)
 116   (setq font-lock-defaults
 117         ;; SYNTAX-BEGIN is set to backward-paragraph to avoid slow-down
 118         ;; near the end of large buffers due to searching to buffer's
 119         ;; beginning.
 120         '(nroff-font-lock-keywords nil t nil backward-paragraph))
 121   (setq local-abbrev-table nroff-mode-abbrev-table)
 122   (make-local-variable 'nroff-electric-mode)
 123   (setq nroff-electric-mode nil)
 124   (make-local-variable 'outline-regexp)
 125   (setq outline-regexp "\\.H[ ]+[1-7]+ ")
 126   (make-local-variable 'outline-level)
 127   (setq outline-level 'nroff-outline-level)
 128   ;; now define a bunch of variables for use by commands in this mode
 129   (make-local-variable 'page-delimiter)
 130   (setq page-delimiter "^\\.\\(bp\\|SK\\|OP\\)")
 131   (make-local-variable 'paragraph-start)
 132   (setq paragraph-start (concat "[.']\\|" paragraph-start))
 133   (make-local-variable 'paragraph-separate)
 134   (setq paragraph-separate (concat "[.']\\|" paragraph-separate))
 135   ;; comment syntax added by mit-erl!gildea 18 Apr 86
 136   (make-local-variable 'comment-start)
 137   (setq comment-start "\\\" ")
 138   (make-local-variable 'comment-start-skip)
 139   (setq comment-start-skip "\\\\\"[ \t]*")
 140   (make-local-variable 'comment-column)
 141   (setq comment-column 24)
 142   (make-local-variable 'comment-indent-function)
 143   (setq comment-indent-function 'nroff-comment-indent)
 144   (run-hooks 'text-mode-hook 'nroff-mode-hook))
 145
 146 (defun nroff-outline-level ()
 147   (save-excursion
 148     (looking-at outline-regexp)
 149     (skip-chars-forward ".H ")
 150     (string-to-int (buffer-substring (point) (+ 1 (point))))))
 151
 152 ;;; Compute how much to indent a comment in nroff/troff source.
 153 ;;; By mit-erl!gildea April 86
 154 (defun nroff-comment-indent ()
 155   "Compute indent for an nroff/troff comment.
 156 Puts a full-stop before comments on a line by themselves."
 157   (let ((pt (point)))
 158     (unwind-protect
 159         (progn
 160           (skip-chars-backward " \t")
 161           (if (bolp)
 162               (progn
 163                 (setq pt (1+ pt))
 164                 (insert ?.)
 165                 1)
 166             (if (save-excursion
 167                   (backward-char 1)
 168                   (looking-at "^[.']"))
 169                 1
 170               (max comment-column
 171                    (* 8 (/ (+ (current-column)
 172                               9) 8)))))) ; add 9 to ensure at least two blanks
 173       (goto-char pt))))
 174
 175 (defun count-text-lines (start end &optional print)
 176   "Count lines in region, except for nroff request lines.
 177 All lines not starting with a period are counted up.
 178 Interactively, print result in echo area.
 179 Noninteractively, return number of non-request lines from START to END."
 180   (interactive "r\np")
 181   (if print
 182       (message "Region has %d text lines" (count-text-lines start end))
 183     (save-excursion
 184       (save-restriction
 185         (narrow-to-region start end)
 186         (goto-char (point-min))
 187         (- (buffer-size) (forward-text-line (buffer-size)))))))
 188
 189 (defun forward-text-line (&optional cnt)
 190   "Go forward one nroff text line, skipping lines of nroff requests.
 191 An argument is a repeat count; if negative, move backward."
 192   (interactive "p")
 193   (if (not cnt) (setq cnt 1))
 194   (while (and (> cnt 0) (not (eobp)))
 195     (forward-line 1)
 196     (while (and (not (eobp)) (looking-at "[.']."))
 197       (forward-line 1))
 198     (setq cnt (- cnt 1)))
 199   (while (and (< cnt 0) (not (bobp)))
 200     (forward-line -1)
 201     (while (and (not (bobp))
 202                 (looking-at "[.']."))
 203       (forward-line -1))
 204     (setq cnt (+ cnt 1)))
 205   cnt)
 206
 207 (defun backward-text-line (&optional cnt)
 208   "Go backward one nroff text line, skipping lines of nroff requests.
 209 An argument is a repeat count; negative means move forward."
 210   (interactive "p")
 211   (forward-text-line (- cnt)))
 212
 213 (defconst nroff-brace-table
 214   '((".(b" . ".)b")
 215     (".(l" . ".)l")
 216     (".(q" . ".)q")
 217     (".(c" . ".)c")
 218     (".(x" . ".)x")
 219     (".(z" . ".)z")
 220     (".(d" . ".)d")
 221     (".(f" . ".)f")
 222     (".LG" . ".NL")
 223     (".SM" . ".NL")
 224     (".LD" . ".DE")
 225     (".CD" . ".DE")
 226     (".BD" . ".DE")
 227     (".DS" . ".DE")
 228     (".DF" . ".DE")
 229     (".FS" . ".FE")
 230     (".KS" . ".KE")
 231     (".KF" . ".KE")
 232     (".LB" . ".LE")
 233     (".AL" . ".LE")
 234     (".BL" . ".LE")
 235     (".DL" . ".LE")
 236     (".ML" . ".LE")
 237     (".RL" . ".LE")
 238     (".VL" . ".LE")
 239     (".RS" . ".RE")
 240     (".TS" . ".TE")
 241     (".EQ" . ".EN")
 242     (".PS" . ".PE")
 243     (".BS" . ".BE")
 244     (".G1" . ".G2")                     ; grap
 245     (".na" . ".ad b")
 246     (".nf" . ".fi")
 247     (".de" . "..")))
 248
 249 (defun electric-nroff-newline (arg)
 250   "Insert newline for nroff mode; special if electric-nroff mode.
 251 In `electric-nroff-mode', if ending a line containing an nroff opening request,
 252 automatically inserts the matching closing request after point."
 253   (interactive "P")
 254   (let ((completion (save-excursion
 255                       (beginning-of-line)
 256                       (and (null arg)
 257                            nroff-electric-mode
 258                            (<= (point) (- (point-max) 3))
 259                            (cdr (assoc (buffer-substring (point)
 260                                                          (+ 3 (point)))
 261                                        nroff-brace-table)))))
 262         (needs-nl (not (looking-at "[ \t]*$"))))
 263     (if (null completion)
 264         (newline (prefix-numeric-value arg))
 265       (save-excursion
 266         (insert "\n\n" completion)
 267         (if needs-nl (insert "\n")))
 268       (forward-char 1))))
 269
 270 (defun electric-nroff-mode (&optional arg)
 271   "Toggle `nroff-electric-newline' minor mode.
 272 `nroff-electric-newline' forces Emacs to check for an nroff request at the
 273 beginning of the line, and insert the matching closing request if necessary.
 274 This command toggles that mode (off->on, on->off), with an argument,
 275 turns it on iff arg is positive, otherwise off."
 276   (interactive "P")
 277   (or (eq major-mode 'nroff-mode) (error "Must be in nroff mode"))
 278   (or (assq 'nroff-electric-mode minor-mode-alist)
 279       (setq minor-mode-alist (append minor-mode-alist
 280                                      (list '(nroff-electric-mode
 281                                              " Electric")))))
 282   (setq nroff-electric-mode
 283         (cond ((null arg) (null nroff-electric-mode))
 284               (t (> (prefix-numeric-value arg) 0)))))
 285
 286 (provide 'nroff-mode)
 287
 288 ;;; nroff-mode.el ends here