lisp/vc-hooks.el

   1 ;;; vc-hooks.el --- resident support for version-control
   2
   3 ;; Copyright (C) 1992,93,94,95,96,98,99,2000  Free Software Foundation, Inc.
   4
   5 ;; Author:     FSF (see vc.el for full credits)
   6 ;; Maintainer: Andre Spiegel <spiegel@gnu.org>
   7
   8 ;; $Id: vc-hooks.el,v 1.138 2002/02/21 20:56:58 spiegel Exp $
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This is the always-loaded portion of VC.  It takes care of
  30 ;; VC-related activities that are done when you visit a file, so that
  31 ;; vc.el itself is loaded only when you use a VC command.  See the
  32 ;; commentary of vc.el.
  33
  34 ;;; Code:
  35
  36 (eval-when-compile
  37   (require 'cl))
  38
  39 ;; Customization Variables (the rest is in vc.el)
  40
  41 (defvar vc-ignore-vc-files nil "Obsolete -- use `vc-handled-backends'.")
  42 (defvar vc-master-templates () "Obsolete -- use vc-BACKEND-master-templates.")
  43 (defvar vc-header-alist () "Obsolete -- use vc-BACKEND-header.")
  44
  45 (defcustom vc-handled-backends '(RCS CVS SCCS)
  46   "*List of version control backends for which VC will be used.
  47 Entries in this list will be tried in order to determine whether a
  48 file is under that sort of version control.
  49 Removing an entry from the list prevents VC from being activated
  50 when visiting a file managed by that backend.
  51 An empty list disables VC altogether."
  52   :type '(repeat symbol)
  53   :version "21.1"
  54   :group 'vc)
  55
  56 (defcustom vc-path
  57   (if (file-directory-p "/usr/sccs")
  58       '("/usr/sccs")
  59     nil)
  60   "*List of extra directories to search for version control commands."
  61   :type '(repeat directory)
  62   :group 'vc)
  63
  64 (defcustom vc-make-backup-files nil
  65   "*If non-nil, backups of registered files are made as with other files.
  66 If nil (the default), files covered by version control don't get backups."
  67   :type 'boolean
  68   :group 'vc)
  69
  70 (defcustom vc-follow-symlinks 'ask
  71   "*What to do if visiting a symbolic link to a file under version control.
  72 Editing such a file through the link bypasses the version control system,
  73 which is dangerous and probably not what you want.
  74
  75 If this variable is t, VC follows the link and visits the real file,
  76 telling you about it in the echo area.  If it is `ask', VC asks for
  77 confirmation whether it should follow the link.  If nil, the link is
  78 visited and a warning displayed."
  79   :type '(choice (const :tag "Ask for confirmation" ask)
  80                  (const :tag "Visit link and warn" nil)
  81                  (const :tag "Follow link" t))
  82   :group 'vc)
  83
  84 (defcustom vc-display-status t
  85   "*If non-nil, display revision number and lock status in modeline.
  86 Otherwise, not displayed."
  87   :type 'boolean
  88   :group 'vc)
  89
  90
  91 (defcustom vc-consult-headers t
  92   "*If non-nil, identify work files by searching for version headers."
  93   :type 'boolean
  94   :group 'vc)
  95
  96 (defcustom vc-keep-workfiles t
  97   "*If non-nil, don't delete working files after registering changes.
  98 If the back-end is CVS, workfiles are always kept, regardless of the
  99 value of this flag."
 100   :type 'boolean
 101   :group 'vc)
 102
 103 (defcustom vc-mistrust-permissions nil
 104   "*If non-nil, don't assume permissions/ownership track version-control status.
 105 If nil, do rely on the permissions.
 106 See also variable `vc-consult-headers'."
 107   :type 'boolean
 108   :group 'vc)
 109
 110 (defun vc-mistrust-permissions (file)
 111   "Internal access function to variable `vc-mistrust-permissions' for FILE."
 112   (or (eq vc-mistrust-permissions 't)
 113       (and vc-mistrust-permissions
 114            (funcall vc-mistrust-permissions
 115                     (vc-backend-subdirectory-name file)))))
 116
 117 ;; Tell Emacs about this new kind of minor mode
 118 (add-to-list 'minor-mode-alist '(vc-mode vc-mode))
 119
 120 (make-variable-buffer-local 'vc-mode)
 121 (put 'vc-mode 'permanent-local t)
 122
 123 (defun vc-mode (&optional arg)
 124   ;; Dummy function for C-h m
 125   "Version Control minor mode.
 126 This minor mode is automatically activated whenever you visit a file under
 127 control of one of the revision control systems in `vc-handled-backends'.
 128 VC commands are globally reachable under the prefix `\\[vc-prefix-map]':
 129 \\{vc-prefix-map}")
 130
 131 (defmacro vc-error-occurred (&rest body)
 132   `(condition-case nil (progn ,@body nil) (error t)))
 133
 134 ;; We need a notion of per-file properties because the version
 135 ;; control state of a file is expensive to derive --- we compute
 136 ;; them when the file is initially found, keep them up to date
 137 ;; during any subsequent VC operations, and forget them when
 138 ;; the buffer is killed.
 139
 140 (defvar vc-file-prop-obarray (make-vector 17 0)
 141   "Obarray for per-file properties.")
 142
 143 (defvar vc-touched-properties nil)
 144
 145 (defun vc-file-setprop (file property value)
 146   "Set per-file VC PROPERTY for FILE to VALUE."
 147   (if (and vc-touched-properties
 148            (not (memq property vc-touched-properties)))
 149       (setq vc-touched-properties (append (list property)
 150                                           vc-touched-properties)))
 151   (put (intern file vc-file-prop-obarray) property value))
 152
 153 (defun vc-file-getprop (file property)
 154   "Get per-file VC PROPERTY for FILE."
 155   (get (intern file vc-file-prop-obarray) property))
 156
 157 (defun vc-file-clearprops (file)
 158   "Clear all VC properties of FILE."
 159   (setplist (intern file vc-file-prop-obarray) nil))
 160
 161 \f
 162 ;; We keep properties on each symbol naming a backend as follows:
 163 ;;  * `vc-functions': an alist mapping vc-FUNCTION to vc-BACKEND-FUNCTION.
 164
 165 (defun vc-make-backend-sym (backend sym)
 166   "Return BACKEND-specific version of VC symbol SYM."
 167   (intern (concat "vc-" (downcase (symbol-name backend))
 168                   "-" (symbol-name sym))))
 169
 170 (defun vc-find-backend-function (backend fun)
 171   "Return BACKEND-specific implementation of FUN.
 172 If there is no such implementation, return the default implementation;
 173 if that doesn't exist either, return nil."
 174   (let ((f (vc-make-backend-sym backend fun)))
 175     (if (fboundp f) f
 176       ;; Load vc-BACKEND.el if needed.
 177       (require (intern (concat "vc-" (downcase (symbol-name backend)))))
 178       (if (fboundp f) f
 179         (let ((def (vc-make-backend-sym 'default fun)))
 180           (if (fboundp def) (cons def backend) nil))))))
 181
 182 (defun vc-call-backend (backend function-name &rest args)
 183   "Call for BACKEND the implementation of FUNCTION-NAME with the given ARGS.
 184 Calls
 185
 186     (apply 'vc-BACKEND-FUN ARGS)
 187
 188 if vc-BACKEND-FUN exists (after trying to find it in vc-BACKEND.el)
 189 and else calls
 190
 191     (apply 'vc-default-FUN BACKEND ARGS)
 192
 193 It is usually called via the `vc-call' macro."
 194   (let ((f (cdr (assoc function-name (get backend 'vc-functions)))))
 195     (unless f
 196       (setq f (vc-find-backend-function backend function-name))
 197       (put backend 'vc-functions (cons (cons function-name f)
 198                                        (get backend 'vc-functions))))
 199     (if (consp f)
 200         (apply (car f) (cdr f) args)
 201       (apply f args))))
 202
 203 (defmacro vc-call (fun file &rest args)
 204   ;; BEWARE!! `file' is evaluated twice!!
 205   `(vc-call-backend (vc-backend ,file) ',fun ,file ,@args))
 206
 207 \f
 208 (defsubst vc-parse-buffer (pattern i)
 209   "Find PATTERN in the current buffer and return its Ith submatch."
 210   (goto-char (point-min))
 211   (if (re-search-forward pattern nil t)
 212       (match-string i)))
 213
 214 (defun vc-insert-file (file &optional limit blocksize)
 215   "Insert the contents of FILE into the current buffer.
 216
 217 Optional argument LIMIT is a regexp.  If present, the file is inserted
 218 in chunks of size BLOCKSIZE (default 8 kByte), until the first
 219 occurrence of LIMIT is found.  The function returns non-nil if FILE
 220 exists and its contents were successfully inserted."
 221   (erase-buffer)
 222   (when (file-exists-p file)
 223     (if (not limit)
 224         (insert-file-contents file)
 225       (if (not blocksize) (setq blocksize 8192))
 226       (let ((filepos 0))
 227         (while
 228             (and (< 0 (cadr (insert-file-contents
 229                              file nil filepos (incf filepos blocksize))))
 230                  (progn (beginning-of-line)
 231                         (not (re-search-forward limit nil 'move)))))))
 232     (set-buffer-modified-p nil)
 233     t))
 234
 235 ;; Access functions to file properties
 236 ;; (Properties should be _set_ using vc-file-setprop, but
 237 ;; _retrieved_ only through these functions, which decide
 238 ;; if the property is already known or not. A property should
 239 ;; only be retrieved by vc-file-getprop if there is no
 240 ;; access function.)
 241
 242 ;; properties indicating the backend being used for FILE
 243
 244 (defun vc-registered (file)
 245   "Return non-nil if FILE is registered in a version control system.
 246
 247 This function performs the check each time it is called.  To rely
 248 on the result of a previous call, use `vc-backend' instead.  If the
 249 file was previously registered under a certain backend, then that
 250 backend is tried first."
 251   (let (handler)
 252     (if (boundp 'file-name-handler-alist)
 253         (setq handler (find-file-name-handler file 'vc-registered)))
 254     (if handler
 255         ;; handler should set vc-backend and return t if registered
 256         (funcall handler 'vc-registered file)
 257       ;; There is no file name handler.
 258       ;; Try vc-BACKEND-registered for each handled BACKEND.
 259       (catch 'found
 260         (let ((backend (vc-file-getprop file 'vc-backend)))
 261           (mapcar
 262            (lambda (b)
 263              (and (vc-call-backend b 'registered file)
 264                   (vc-file-setprop file 'vc-backend b)
 265                   (throw 'found t)))
 266            (if (or (not backend) (eq backend 'none))
 267                vc-handled-backends
 268              (cons backend vc-handled-backends))))
 269         ;; File is not registered.
 270         (vc-file-setprop file 'vc-backend 'none)
 271         nil))))
 272
 273 (defun vc-backend (file)
 274   "Return the version control type of FILE, nil if it is not registered."
 275   ;; `file' can be nil in several places (typically due to the use of
 276   ;; code like (vc-backend (buffer-file-name))).
 277   (when (stringp file)
 278     (let ((property (vc-file-getprop file 'vc-backend)))
 279       ;; Note that internally, Emacs remembers unregistered
 280       ;; files by setting the property to `none'.
 281       (cond ((eq property 'none) nil)
 282             (property)
 283             ;; vc-registered sets the vc-backend property
 284             (t (if (vc-registered file)
 285                    (vc-file-getprop file 'vc-backend)
 286                  nil))))))
 287
 288 (defun vc-backend-subdirectory-name (file)
 289   "Return where the master and lock FILEs for the current directory are kept."
 290   (symbol-name (vc-backend file)))
 291
 292 (defun vc-name (file)
 293   "Return the master name of FILE.
 294 If the file is not registered, or the master name is not known, return nil."
 295   ;; TODO: This should ultimately become obsolete, at least up here
 296   ;; in vc-hooks.
 297   (or (vc-file-getprop file 'vc-name)
 298       ;; force computation of the property by calling
 299       ;; vc-BACKEND-registered explicitly
 300       (if (and (vc-backend file)
 301                (vc-call-backend (vc-backend file) 'registered file))
 302           (vc-file-getprop file 'vc-name))))
 303
 304 (defun vc-checkout-model (file)
 305   "Indicate how FILE is checked out.
 306
 307 If FILE is not registered, this function always returns nil.
 308 For registered files, the possible values are:
 309
 310   'implicit   FILE is always writeable, and checked out `implicitly'
 311               when the user saves the first changes to the file.
 312
 313   'locking    FILE is read-only if up-to-date; user must type
 314               \\[vc-toggle-read-only] before editing.  Strict locking
 315               is assumed.
 316
 317   'announce   FILE is read-only if up-to-date; user must type
 318               \\[vc-toggle-read-only] before editing.  But other users
 319               may be editing at the same time."
 320   (or (vc-file-getprop file 'vc-checkout-model)
 321       (if (vc-backend file)
 322           (vc-file-setprop file 'vc-checkout-model
 323                            (vc-call checkout-model file)))))
 324
 325 (defun vc-user-login-name (&optional uid)
 326   "Return the name under which the user is logged in, as a string.
 327 \(With optional argument UID, return the name of that user.)
 328 This function does the same as function `user-login-name', but unlike
 329 that, it never returns nil.  If a UID cannot be resolved, that
 330 UID is returned as a string."
 331   (or (user-login-name uid)
 332       (number-to-string (or uid (user-uid)))))
 333
 334 (defun vc-state (file)
 335   "Return the version control state of FILE.
 336
 337 If FILE is not registered, this function always returns nil.
 338 For registered files, the value returned is one of:
 339
 340   'up-to-date        The working file is unmodified with respect to the
 341                      latest version on the current branch, and not locked.
 342
 343   'edited            The working file has been edited by the user.  If
 344                      locking is used for the file, this state means that
 345                      the current version is locked by the calling user.
 346
 347   USER               The current version of the working file is locked by
 348                      some other USER (a string).
 349
 350   'needs-patch       The file has not been edited by the user, but there is
 351                      a more recent version on the current branch stored
 352                      in the master file.
 353
 354   'needs-merge       The file has been edited by the user, and there is also
 355                      a more recent version on the current branch stored in
 356                      the master file.  This state can only occur if locking
 357                      is not used for the file.
 358
 359   'unlocked-changes  The current version of the working file is not locked,
 360                      but the working file has been changed with respect
 361                      to that version.  This state can only occur for files
 362                      with locking; it represents an erroneous condition that
 363                      should be resolved by the user (vc-next-action will
 364                      prompt the user to do it)."
 365   (or (vc-file-getprop file 'vc-state)
 366       (if (vc-backend file)
 367           (vc-file-setprop file 'vc-state
 368                            (vc-call state-heuristic file)))))
 369
 370 (defsubst vc-up-to-date-p (file)
 371   "Convenience function that checks whether `vc-state' of FILE is `up-to-date'."
 372   (eq (vc-state file) 'up-to-date))
 373
 374 (defun vc-default-state-heuristic (backend file)
 375   "Default implementation of vc-state-heuristic.
 376 It simply calls the real state computation function `vc-BACKEND-state'
 377 and does not employ any heuristic at all."
 378    (vc-call-backend backend 'state file))
 379
 380 (defun vc-workfile-version (file)
 381   "Return the version level of the current workfile FILE.
 382 If FILE is not registered, this function always returns nil."
 383   (or (vc-file-getprop file 'vc-workfile-version)
 384       (if (vc-backend file)
 385           (vc-file-setprop file 'vc-workfile-version
 386                            (vc-call workfile-version file)))))
 387
 388 ;;; actual version-control code starts here
 389
 390 (defun vc-default-registered (backend file)
 391   "Check if FILE is registered in BACKEND using vc-BACKEND-master-templates."
 392   (let ((sym (vc-make-backend-sym backend 'master-templates)))
 393     (unless (get backend 'vc-templates-grabbed)
 394       (put backend 'vc-templates-grabbed t)
 395       (set sym (append (delq nil
 396                              (mapcar
 397                               (lambda (template)
 398                                 (and (consp template)
 399                                      (eq (cdr template) backend)
 400                                      (car template)))
 401                               vc-master-templates))
 402                        (symbol-value sym))))
 403     (let ((result (vc-check-master-templates file (symbol-value sym))))
 404       (if (stringp result)
 405           (vc-file-setprop file 'vc-name result)
 406         nil))))                         ; Not registered
 407
 408 (defun vc-possible-master (s dirname basename)
 409   (cond
 410    ((stringp s) (format s dirname basename))
 411    ((functionp s)
 412     ;; The template is a function to invoke.  If the
 413     ;; function returns non-nil, that means it has found a
 414     ;; master.  For backward compatibility, we also handle
 415     ;; the case that the function throws a 'found atom
 416     ;; and a pair (cons MASTER-FILE BACKEND).
 417     (let ((result (catch 'found (funcall s dirname basename))))
 418       (if (consp result) (car result) result)))))
 419
 420 (defun vc-check-master-templates (file templates)
 421   "Return non-nil if there is a master corresponding to FILE.
 422
 423 TEMPLATES is a list of strings or functions.  If an element is a
 424 string, it must be a control string as required by `format', with two
 425 string placeholders, such as \"%sRCS/%s,v\".  The directory part of
 426 FILE is substituted for the first placeholder, the basename of FILE
 427 for the second.  If a file with the resulting name exists, it is taken
 428 as the master of FILE, and returned.
 429
 430 If an element of TEMPLATES is a function, it is called with the
 431 directory part and the basename of FILE as arguments.  It should
 432 return non-nil if it finds a master; that value is then returned by
 433 this function."
 434   (let ((dirname (or (file-name-directory file) ""))
 435         (basename (file-name-nondirectory file)))
 436     (catch 'found
 437       (mapcar
 438        (lambda (s)
 439          (let ((trial (vc-possible-master s dirname basename)))
 440            (if (and trial (file-exists-p trial)
 441                     ;; Make sure the file we found with name
 442                     ;; TRIAL is not the source file itself.
 443                     ;; That can happen with RCS-style names if
 444                     ;; the file name is truncated (e.g. to 14
 445                     ;; chars).  See if either directory or
 446                     ;; attributes differ.
 447                     (or (not (string= dirname
 448                                       (file-name-directory trial)))
 449                         (not (equal (file-attributes file)
 450                                     (file-attributes trial)))))
 451                (throw 'found trial))))
 452        templates))))
 453
 454 (defun vc-toggle-read-only (&optional verbose)
 455   "Change read-only status of current buffer, perhaps via version control.
 456 If the buffer is visiting a file registered with version control,
 457 then check the file in or out.  Otherwise, just change the read-only flag
 458 of the buffer.
 459 With prefix argument, ask for version number to check in or check out.
 460 Check-out of a specified version number does not lock the file;
 461 to do that, use this command a second time with no argument."
 462   (interactive "P")
 463   (if (or (and (boundp 'vc-dired-mode) vc-dired-mode)
 464           ;; use boundp because vc.el might not be loaded
 465           (vc-backend (buffer-file-name)))
 466       (vc-next-action verbose)
 467     (toggle-read-only)))
 468 (define-key global-map "\C-x\C-q" 'vc-toggle-read-only)
 469
 470 (defun vc-default-make-version-backups-p (backend file)
 471   "Return non-nil if unmodified versions should be backed up locally.
 472 The default is to switch off this feature."
 473   nil)
 474
 475 (defun vc-version-backup-file-name (file &optional rev manual regexp)
 476   "Return a backup file name for REV or the current version of FILE.
 477 If MANUAL is non-nil it means that a name for backups created by
 478 the user should be returned; if REGEXP is non-nil that means to return
 479 a regexp for matching all such backup files, regardless of the version."
 480   (if regexp
 481       (concat (regexp-quote (file-name-nondirectory file))
 482               "\\.~[0-9.]+" (unless manual "\\.") "~")
 483     (expand-file-name (concat (file-name-nondirectory file)
 484                               ".~" (or rev (vc-workfile-version file))
 485                               (unless manual ".") "~")
 486                       (file-name-directory file))))
 487
 488 (defun vc-delete-automatic-version-backups (file)
 489   "Delete all existing automatic version backups for FILE."
 490   (condition-case nil
 491       (mapcar
 492        'delete-file
 493        (directory-files (or (file-name-directory file) default-directory) t
 494                         (vc-version-backup-file-name file nil nil t)))
 495     ;; Don't fail when the directory doesn't exist.
 496     (file-error nil)))
 497
 498 (defun vc-make-version-backup (file)
 499   "Make a backup copy of FILE, which is assumed in sync with the repository.
 500 Before doing that, check if there are any old backups and get rid of them."
 501   (unless (and (fboundp 'msdos-long-file-names)
 502                (not (msdos-long-file-names)))
 503     (vc-delete-automatic-version-backups file)
 504     (copy-file file (vc-version-backup-file-name file)
 505                nil 'keep-date)))
 506
 507 (defun vc-before-save ()
 508   "Function to be called by `basic-save-buffer' (in files.el)."
 509   ;; If the file on disk is still in sync with the repository,
 510   ;; and version backups should be made, copy the file to
 511   ;; another name.  This enables local diffs and local reverting.
 512   (let ((file (buffer-file-name)))
 513     (and (vc-backend file)
 514          (vc-up-to-date-p file)
 515          (eq (vc-checkout-model file) 'implicit)
 516          (vc-call make-version-backups-p file)
 517          (vc-make-version-backup file))))
 518
 519 (defun vc-after-save ()
 520   "Function to be called by `basic-save-buffer' (in files.el)."
 521   ;; If the file in the current buffer is under version control,
 522   ;; up-to-date, and locking is not used for the file, set
 523   ;; the state to 'edited and redisplay the mode line.
 524   (let ((file (buffer-file-name)))
 525     (and (vc-backend file)
 526          (or (and (equal (vc-file-getprop file 'vc-checkout-time)
 527                          (nth 5 (file-attributes file)))
 528                   ;; File has been saved in the same second in which
 529                   ;; it was checked out.  Clear the checkout-time
 530                   ;; to avoid confusion.
 531                   (vc-file-setprop file 'vc-checkout-time nil))
 532              t)
 533          (vc-up-to-date-p file)
 534          (eq (vc-checkout-model file) 'implicit)
 535          (vc-file-setprop file 'vc-state 'edited)
 536          (vc-mode-line file)
 537          (if (featurep 'vc)
 538              ;; If VC is not loaded, then there can't be
 539              ;; any VC Dired buffer to synchronize.
 540              (vc-dired-resynch-file file)))))
 541
 542 (defun vc-mode-line (file)
 543   "Set `vc-mode' to display type of version control for FILE.
 544 The value is set in the current buffer, which should be the buffer
 545 visiting FILE."
 546   (interactive (list buffer-file-name))
 547   (if (not (vc-backend file))
 548       (setq vc-mode nil)
 549     (setq vc-mode (concat " " (if vc-display-status
 550                                   (vc-call mode-line-string file)
 551                                 (symbol-name (vc-backend file)))))
 552     ;; If the file is locked by some other user, make
 553     ;; the buffer read-only.  Like this, even root
 554     ;; cannot modify a file that someone else has locked.
 555     (and (equal file (buffer-file-name))
 556          (stringp (vc-state file))
 557          (setq buffer-read-only t))
 558     ;; If the user is root, and the file is not owner-writable,
 559     ;; then pretend that we can't write it
 560     ;; even though we can (because root can write anything).
 561     ;; This way, even root cannot modify a file that isn't locked.
 562     (and (equal file (buffer-file-name))
 563          (not buffer-read-only)
 564          (zerop (user-real-uid))
 565          (zerop (logand (file-modes (buffer-file-name)) 128))
 566          (setq buffer-read-only t)))
 567   (force-mode-line-update)
 568   (vc-backend file))
 569
 570 (defun vc-default-mode-line-string (backend file)
 571   "Return string for placement in modeline by `vc-mode-line' for FILE.
 572 Format:
 573
 574   \"BACKEND-REV\"        if the file is up-to-date
 575   \"BACKEND:REV\"        if the file is edited (or locked by the calling user)
 576   \"BACKEND:LOCKER:REV\" if the file is locked by somebody else
 577
 578 This function assumes that the file is registered."
 579   (setq backend (symbol-name backend))
 580   (let ((state   (vc-state file))
 581         (rev     (vc-workfile-version file)))
 582     (cond ((or (eq state 'up-to-date)
 583                (eq state 'needs-patch))
 584            (concat backend "-" rev))
 585           ((stringp state)
 586            (concat backend ":" state ":" rev))
 587           (t
 588            ;; Not just for the 'edited state, but also a fallback
 589            ;; for all other states.  Think about different symbols
 590            ;; for 'needs-patch and 'needs-merge.
 591            (concat backend ":" rev)))))
 592
 593 (defun vc-follow-link ()
 594   "If current buffer visits a symbolic link, visit the real file.
 595 If the real file is already visited in another buffer, make that buffer
 596 current, and kill the buffer that visits the link."
 597   (let* ((truename (abbreviate-file-name (file-chase-links buffer-file-name)))
 598          (true-buffer (find-buffer-visiting truename))
 599          (this-buffer (current-buffer)))
 600     (if (eq true-buffer this-buffer)
 601         (progn
 602           (kill-buffer this-buffer)
 603           ;; In principle, we could do something like set-visited-file-name.
 604           ;; However, it can't be exactly the same as set-visited-file-name.
 605           ;; I'm not going to work out the details right now. -- rms.
 606           (set-buffer (find-file-noselect truename)))
 607       (set-buffer true-buffer)
 608       (kill-buffer this-buffer))))
 609
 610 (defun vc-find-file-hook ()
 611   "Function for `find-file-hooks' activating VC mode if appropriate."
 612   ;; Recompute whether file is version controlled,
 613   ;; if user has killed the buffer and revisited.
 614   (if vc-mode
 615       (setq vc-mode nil))
 616   (when buffer-file-name
 617     (vc-file-clearprops buffer-file-name)
 618     (cond
 619      ((vc-backend buffer-file-name)
 620       (vc-mode-line buffer-file-name)
 621       (cond ((not vc-make-backup-files)
 622              ;; Use this variable, not make-backup-files,
 623              ;; because this is for things that depend on the file name.
 624              (make-local-variable 'backup-inhibited)
 625              (setq backup-inhibited t))))
 626      ((let* ((link (file-symlink-p buffer-file-name))
 627              (link-type (and link (vc-backend (file-chase-links link)))))
 628         (if link-type
 629             (cond ((eq vc-follow-symlinks nil)
 630                    (message
 631         "Warning: symbolic link to %s-controlled source file" link-type))
 632                   ((or (not (eq vc-follow-symlinks 'ask))
 633                        ;; If we already visited this file by following
 634                        ;; the link, don't ask again if we try to visit
 635                        ;; it again.  GUD does that, and repeated questions
 636                        ;; are painful.
 637                        (get-file-buffer
 638                         (abbreviate-file-name
 639                          (file-chase-links buffer-file-name))))
 640
 641                    (vc-follow-link)
 642                    (message "Followed link to %s" buffer-file-name)
 643                    (vc-find-file-hook))
 644                   (t
 645                    (if (yes-or-no-p (format
 646         "Symbolic link to %s-controlled source file; follow link? " link-type))
 647                        (progn (vc-follow-link)
 648                               (message "Followed link to %s" buffer-file-name)
 649                               (vc-find-file-hook))
 650                      (message
 651         "Warning: editing through the link bypasses version control")
 652                      )))))))))
 653
 654 (add-hook 'find-file-hooks 'vc-find-file-hook)
 655
 656 ;; more hooks, this time for file-not-found
 657 (defun vc-file-not-found-hook ()
 658   "When file is not found, try to check it out from version control.
 659 Returns t if checkout was successful, nil otherwise.
 660 Used in `find-file-not-found-hooks'."
 661   ;; When a file does not exist, ignore cached info about it
 662   ;; from a previous visit.
 663   (vc-file-clearprops buffer-file-name)
 664   (if (and (vc-backend buffer-file-name)
 665            (yes-or-no-p
 666             (format "File %s was lost; check out from version control? "
 667                     (file-name-nondirectory buffer-file-name))))
 668     (save-excursion
 669       (require 'vc)
 670       (setq default-directory (file-name-directory buffer-file-name))
 671       (not (vc-error-occurred (vc-checkout buffer-file-name))))))
 672
 673 (add-hook 'find-file-not-found-hooks 'vc-file-not-found-hook)
 674
 675 (defun vc-kill-buffer-hook ()
 676   "Discard VC info about a file when we kill its buffer."
 677   (if (buffer-file-name)
 678       (vc-file-clearprops (buffer-file-name))))
 679
 680 ;; ??? DL: why is this not done?
 681 ;;;(add-hook 'kill-buffer-hook 'vc-kill-buffer-hook)
 682
 683 ;; Now arrange for (autoloaded) bindings of the main package.
 684 ;; Bindings for this have to go in the global map, as we'll often
 685 ;; want to call them from random buffers.
 686
 687 ;; Autoloading works fine, but it prevents shortcuts from appearing
 688 ;; in the menu because they don't exist yet when the menu is built.
 689 ;; (autoload 'vc-prefix-map "vc" nil nil 'keymap)
 690 (defvar vc-prefix-map
 691   (let ((map (make-sparse-keymap)))
 692     (define-key map "a" 'vc-update-change-log)
 693     (define-key map "b" 'vc-switch-backend)
 694     (define-key map "c" 'vc-cancel-version)
 695     (define-key map "d" 'vc-directory)
 696     (define-key map "g" 'vc-annotate)
 697     (define-key map "h" 'vc-insert-headers)
 698     (define-key map "i" 'vc-register)
 699     (define-key map "l" 'vc-print-log)
 700     (define-key map "m" 'vc-merge)
 701     (define-key map "r" 'vc-retrieve-snapshot)
 702     (define-key map "s" 'vc-create-snapshot)
 703     (define-key map "u" 'vc-revert-buffer)
 704     (define-key map "v" 'vc-next-action)
 705     (define-key map "=" 'vc-diff)
 706     (define-key map "~" 'vc-version-other-window)
 707     map))
 708 (fset 'vc-prefix-map vc-prefix-map)
 709 (define-key global-map "\C-xv" 'vc-prefix-map)
 710
 711 (if (not (boundp 'vc-menu-map))
 712     ;; Don't do the menu bindings if menu-bar.el wasn't loaded to defvar
 713     ;; vc-menu-map.
 714     ()
 715   ;;(define-key vc-menu-map [show-files]
 716   ;;  '("Show Files under VC" . (vc-directory t)))
 717   (define-key vc-menu-map [vc-retrieve-snapshot]
 718     '("Retrieve Snapshot" . vc-retrieve-snapshot))
 719   (define-key vc-menu-map [vc-create-snapshot]
 720     '("Create Snapshot" . vc-create-snapshot))
 721   (define-key vc-menu-map [vc-directory] '("VC Directory Listing" . vc-directory))
 722   (define-key vc-menu-map [separator1] '("----"))
 723   (define-key vc-menu-map [vc-annotate] '("Annotate" . vc-annotate))
 724   (define-key vc-menu-map [vc-rename-file] '("Rename File" . vc-rename-file))
 725   (define-key vc-menu-map [vc-version-other-window]
 726     '("Show Other Version" . vc-version-other-window))
 727   (define-key vc-menu-map [vc-diff] '("Compare with Base Version" . vc-diff))
 728   (define-key vc-menu-map [vc-update-change-log]
 729     '("Update ChangeLog" . vc-update-change-log))
 730   (define-key vc-menu-map [vc-print-log] '("Show History" . vc-print-log))
 731   (define-key vc-menu-map [separator2] '("----"))
 732   (define-key vc-menu-map [vc-insert-header]
 733     '("Insert Header" . vc-insert-headers))
 734   (define-key vc-menu-map [undo] '("Undo Last Check-In" . vc-cancel-version))
 735   (define-key vc-menu-map [vc-revert-buffer]
 736     '("Revert to Base Version" . vc-revert-buffer))
 737   (define-key vc-menu-map [vc-update]
 738     '("Update to Latest Version" . vc-update))
 739   (define-key vc-menu-map [vc-next-action] '("Check In/Out" . vc-next-action))
 740   (define-key vc-menu-map [vc-register] '("Register" . vc-register)))
 741
 742 ;; These are not correct and it's not currently clear how doing it
 743 ;; better (with more complicated expressions) might slow things down
 744 ;; on older systems.
 745
 746 ;;(put 'vc-rename-file 'menu-enable 'vc-mode)
 747 ;;(put 'vc-annotate 'menu-enable '(eq (vc-buffer-backend) 'CVS))
 748 ;;(put 'vc-version-other-window 'menu-enable 'vc-mode)
 749 ;;(put 'vc-diff 'menu-enable 'vc-mode)
 750 ;;(put 'vc-update-change-log 'menu-enable
 751 ;;     '(member (vc-buffer-backend) '(RCS CVS)))
 752 ;;(put 'vc-print-log 'menu-enable 'vc-mode)
 753 ;;(put 'vc-cancel-version 'menu-enable 'vc-mode)
 754 ;;(put 'vc-revert-buffer 'menu-enable 'vc-mode)
 755 ;;(put 'vc-insert-headers 'menu-enable 'vc-mode)
 756 ;;(put 'vc-next-action 'menu-enable 'vc-mode)
 757 ;;(put 'vc-register 'menu-enable '(and buffer-file-name (not vc-mode)))
 758
 759 (provide 'vc-hooks)
 760
 761 ;;; vc-hooks.el ends here