Make --without-x compatible with --enable-gcc-warnings.
[bpt/emacs.git] / configure.ac
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl If you changed any AC_DEFINES, also run autoheader.
6 dnl
7 dnl Copyright (C) 1994-1996, 1999-2013 Free Software Foundation, Inc.
8 dnl
9 dnl This file is part of GNU Emacs.
10 dnl
11 dnl GNU Emacs is free software: you can redistribute it and/or modify
12 dnl it under the terms of the GNU General Public License as published by
13 dnl the Free Software Foundation, either version 3 of the License, or
14 dnl (at your option) any later version.
15 dnl
16 dnl GNU Emacs is distributed in the hope that it will be useful,
17 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
18 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19 dnl GNU General Public License for more details.
20 dnl
21 dnl You should have received a copy of the GNU General Public License
22 dnl along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
23
24 AC_PREREQ(2.65)
25 AC_INIT(emacs, 24.3.50)
26
27 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
28 dnl and then quoted again for a C string. Separate options with spaces.
29 dnl Add some environment variables, if they were passed via the environment
30 dnl rather than on the command-line.
31 emacs_config_options=
32 optsep=
33 dnl This is the documented way to record the args passed to configure,
34 dnl rather than $ac_configure_args.
35 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
36 case $opt in
37 -n | --no-create | --no-recursion)
38 continue ;;
39 CFLAGS | CPPFLAGS | LDFLAGS)
40 eval 'test "${'$opt'+set}" = set' || continue
41 case " $*" in
42 *" $opt="*) continue ;;
43 esac
44 eval opt=$opt=\$$opt ;;
45 esac
46
47 emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
48 case $opt in
49 *[["$emacs_shell_specials"]]*)
50 case $opt in
51 *\'*)
52 emacs_quote_apostrophes="s/'/'\\\\''/g"
53 opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
54 esac
55 opt="'$opt'"
56 case $opt in
57 *[['"\\']]*)
58 emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
59 opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
60 esac ;;
61 esac
62 AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
63 optsep=' '
64 done
65
66 AC_CONFIG_HEADER(src/config.h:src/config.in)
67 AC_CONFIG_SRCDIR(src/lisp.h)
68 AC_CONFIG_AUX_DIR(build-aux)
69 dnl Fairly arbitrary, older versions might work too.
70 AM_INIT_AUTOMAKE(1.11)
71
72 dnl Support for --program-prefix, --program-suffix and
73 dnl --program-transform-name options
74 AC_ARG_PROGRAM
75
76 dnl It is important that variables on the RHS not be expanded here,
77 dnl hence the single quotes. This is per the GNU coding standards, see
78 dnl (autoconf) Installation Directory Variables
79 dnl See also epaths.h below.
80 lispdir='${datadir}/emacs/${version}/lisp'
81 leimdir='${datadir}/emacs/${version}/leim'
82 standardlisppath='${lispdir}:${leimdir}'
83 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
84 '${datadir}/emacs/site-lisp'
85 lisppath='${locallisppath}:${standardlisppath}'
86 etcdir='${datadir}/emacs/${version}/etc'
87 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
88 etcdocdir='${datadir}/emacs/${version}/etc'
89 gamedir='${localstatedir}/games/emacs'
90
91 dnl Special option to disable the most of other options.
92 AC_ARG_WITH(all,
93 [AS_HELP_STRING([--without-all],
94 [omit almost all features and build
95 small executable with minimal dependencies])],
96 with_features=$withval,
97 with_features=yes)
98
99 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
100 dnl Create a new --with option that defaults to being disabled.
101 dnl NAME is the base name of the option. The shell variable with_NAME
102 dnl will be set to either the user's value (if the option is
103 dnl specified; 'yes' for a plain --with-NAME) or to 'no' (if the
104 dnl option is not specified). Note that the shell variable name is
105 dnl constructed as autoconf does, by replacing non-alphanumeric
106 dnl characters with "_".
107 dnl HELP-STRING is the help text for the option.
108 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
109 AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
110 m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
111 ])dnl
112
113 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
114 dnl Create a new --with option that defaults to $with_features.
115 dnl NAME is the base name of the option. The shell variable with_NAME
116 dnl will be set either to 'no' (for a plain --without-NAME) or to
117 dnl 'yes' (if the option is not specified). Note that the shell
118 dnl variable name is constructed as autoconf does, by replacing
119 dnl non-alphanumeric characters with "_".
120 dnl HELP-STRING is the help text for the option.
121 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
122 AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
123 m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
124 ])dnl
125
126 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
127 if test "$with_pop" = yes; then
128 AC_DEFINE(MAIL_USE_POP)
129 fi
130 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
131
132 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
133 if test "$with_kerberos" != no; then
134 AC_DEFINE(KERBEROS)
135 fi
136 AH_TEMPLATE(KERBEROS,
137 [Define to support Kerberos-authenticated POP mail retrieval.])dnl
138
139 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
140 if test "${with_kerberos5}" != no; then
141 if test "${with_kerberos}" = no; then
142 with_kerberos=yes
143 AC_DEFINE(KERBEROS)
144 fi
145 AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
146 fi
147
148 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
149 dnl FIXME hesiod support may not be present, so it seems like an error
150 dnl to define, or at least use, this unconditionally.
151 if test "$with_hesiod" != no; then
152 AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
153 fi
154
155 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
156 if test "$with_mmdf" != no; then
157 AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
158 fi
159
160 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
161 if test "$with_mail_unlink" != no; then
162 AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
163 fi
164
165 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
166 [string giving default POP mail host])],
167 AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
168
169 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
170 [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
171 default yes). Only for GNU/Linux, FreeBSD, NetBSD, MinGW.])],
172 [ case "${withval}" in
173 yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
174 *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
175 this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
176 ;;
177 esac
178 with_sound=$val
179 ],
180 [with_sound=$with_features])
181
182 dnl FIXME currently it is not the last.
183 dnl This should be the last --with option, because --with-x is
184 dnl added later on when we find the file name of X, and it's best to
185 dnl keep them together visually.
186 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
187 [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
188 [ case "${withval}" in
189 y | ye | yes ) val=gtk ;;
190 n | no ) val=no ;;
191 l | lu | luc | luci | lucid ) val=lucid ;;
192 a | at | ath | athe | athen | athena ) val=athena ;;
193 m | mo | mot | moti | motif ) val=motif ;;
194 g | gt | gtk ) val=gtk ;;
195 gtk2 ) val=gtk2 ;;
196 gtk3 ) val=gtk3 ;;
197 * )
198 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
199 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
200 `gtk2' or `gtk3'. `yes' and `gtk' are synonyms.
201 `athena' and `lucid' are synonyms.])
202 ;;
203 esac
204 with_x_toolkit=$val
205 ])
206
207 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
208 if test "$with_wide_int" = yes; then
209 AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
210 fi
211
212 dnl _ON results in a '--without' option in the --help output, so
213 dnl the help text should refer to "don't compile", etc.
214 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
215 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
216 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
217 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
218 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
219 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
220 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
221 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
222
223 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
224 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
225 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
226
227 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
228 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
229 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
230 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
231 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
232
233 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
234 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
235 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
236 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
237 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
238 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
239 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
240
241 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
242 [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
243 [ case "${withval}" in
244 y | ye | yes ) val=yes ;;
245 n | no ) val=no ;;
246 g | gf | gfi | gfil | gfile ) val=gfile ;;
247 i | in | ino | inot | inoti | inotif | inotify ) val=inotify ;;
248 w | w3 | w32 ) val=w32 ;;
249 * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
250 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
251 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
252 otherwise for the first of `gfile' or `inotify' that is usable.])
253 ;;
254 esac
255 with_file_notification=$val
256 ],
257 [with_file_notification=$with_features])
258
259 ## For the times when you want to build Emacs but don't have
260 ## a suitable makeinfo, and can live without the manuals.
261 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
262 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
263
264 ## Makefile.in needs the cache file name.
265 AC_SUBST(cache_file)
266
267 ## This is an option because I do not know if all info/man support
268 ## compressed files, nor how to test if they do so.
269 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
270 if test $with_compress_info = yes; then
271 GZIP_INFO=yes
272 else
273 GZIP_INFO=
274 fi
275 AC_SUBST(GZIP_INFO)
276
277 AC_ARG_WITH([pkg-config-prog],dnl
278 [AS_HELP_STRING([--with-pkg-config-prog=FILENAME],
279 [file name of pkg-config for finding GTK and librsvg])])
280 if test "X${with_pkg_config_prog}" != X; then
281 if test "${with_pkg_config_prog}" != yes; then
282 PKG_CONFIG="${with_pkg_config_prog}"
283 fi
284 fi
285
286 AC_ARG_WITH(gameuser,dnl
287 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
288 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
289 && gameuser="${with_gameuser}"
290 test "X$gameuser" = X && gameuser=games
291
292 AC_ARG_WITH([gnustep-conf],dnl
293 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
294 [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
295 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
296 GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
297 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
298 GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
299
300 AC_ARG_ENABLE(ns-self-contained,
301 [AS_HELP_STRING([--disable-ns-self-contained],
302 [disable self contained build under NeXTstep])],
303 EN_NS_SELF_CONTAINED=$enableval,
304 EN_NS_SELF_CONTAINED=yes)
305
306 AC_ARG_ENABLE(locallisppath,
307 [AS_HELP_STRING([--enable-locallisppath=PATH],
308 [directories Emacs should search for lisp files specific
309 to this site])],
310 if test "${enableval}" = "no"; then
311 locallisppath=
312 elif test "${enableval}" != "yes"; then
313 locallisppath=${enableval}
314 fi)
315
316 AC_ARG_ENABLE(checking,
317 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
318 [enable expensive run-time checks. With LIST,
319 enable only specific categories of checks.
320 Categories are: all,yes,no.
321 Flags are: stringbytes, stringoverrun, stringfreelist,
322 xmallocoverrun, conslist, glyphs])],
323 [ac_checking_flags="${enableval}"],[])
324 IFS="${IFS= }"; ac_save_IFS="$IFS"; IFS="$IFS,"
325 for check in $ac_checking_flags
326 do
327 case $check in
328 # these set all the flags to specific states
329 yes) ac_enable_checking=1 ;;
330 no) ac_enable_checking= ;
331 ac_gc_check_stringbytes= ;
332 ac_gc_check_string_overrun= ;
333 ac_gc_check_string_free_list= ;
334 ac_xmalloc_overrun= ;
335 ac_gc_check_cons_list= ;
336 ac_glyphs_debug= ;;
337 all) ac_enable_checking=1 ;
338 ac_gc_check_stringbytes=1 ;
339 ac_gc_check_string_overrun=1 ;
340 ac_gc_check_string_free_list=1 ;
341 ac_xmalloc_overrun=1 ;
342 ac_gc_check_cons_list=1 ;
343 ac_glyphs_debug=1 ;;
344 # these enable particular checks
345 stringbytes) ac_gc_check_stringbytes=1 ;;
346 stringoverrun) ac_gc_check_string_overrun=1 ;;
347 stringfreelist) ac_gc_check_string_free_list=1 ;;
348 xmallocoverrun) ac_xmalloc_overrun=1 ;;
349 conslist) ac_gc_check_cons_list=1 ;;
350 glyphs) ac_glyphs_debug=1 ;;
351 *) AC_MSG_ERROR(unknown check category $check) ;;
352 esac
353 done
354 IFS="$ac_save_IFS"
355
356 if test x$ac_enable_checking != x ; then
357 AC_DEFINE(ENABLE_CHECKING, 1,
358 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
359 fi
360 if test x$ac_gc_check_stringbytes != x ; then
361 AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
362 [Define this temporarily to hunt a bug. If defined, the size of
363 strings is redundantly recorded in sdata structures so that it can
364 be compared to the sizes recorded in Lisp strings.])
365 fi
366 if test x$ac_gc_check_string_overrun != x ; then
367 AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
368 [Define this to check for short string overrun.])
369 fi
370 if test x$ac_gc_check_string_free_list != x ; then
371 AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
372 [Define this to check the string free list.])
373 fi
374 if test x$ac_xmalloc_overrun != x ; then
375 AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
376 [Define this to check for malloc buffer overrun.])
377 fi
378 if test x$ac_gc_check_cons_list != x ; then
379 AC_DEFINE(GC_CHECK_CONS_LIST, 1,
380 [Define this to check for errors in cons list.])
381 fi
382 if test x$ac_glyphs_debug != x ; then
383 AC_DEFINE(GLYPH_DEBUG, 1,
384 [Define this to enable glyphs debugging code.])
385 fi
386
387 AC_ARG_ENABLE(check-lisp-object-type,
388 [AS_HELP_STRING([--enable-check-lisp-object-type],
389 [enable compile time checks for the Lisp_Object data type.
390 This is useful for development for catching certain types of bugs.])],
391 if test "${enableval}" != "no"; then
392 AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
393 [Define this to enable compile time checks for the Lisp_Object data type.])
394 fi)
395
396
397 dnl The name of this option is unfortunate. It predates, and has no
398 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
399 dnl Actually, it stops it working.
400 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
401 AC_ARG_ENABLE(profiling,
402 [AS_HELP_STRING([--enable-profiling],
403 [build emacs with low-level, gprof profiling support.
404 Mainly useful for debugging Emacs itself. May not work on
405 all platforms. Stops profiler.el working.])],
406 [ac_enable_profiling="${enableval}"],[])
407 if test x$ac_enable_profiling != x ; then
408 PROFILING_CFLAGS="-DPROFILING=1 -pg"
409 else
410 PROFILING_CFLAGS=
411 fi
412 AC_SUBST(PROFILING_CFLAGS)
413
414 AC_ARG_ENABLE(autodepend,
415 [AS_HELP_STRING([--enable-autodepend],
416 [automatically generate dependencies to .h-files.
417 Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
418 found])],
419 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
420
421 AC_ARG_ENABLE(gtk-deprecation-warnings,
422 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
423 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
424 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
425
426 #### Make srcdir absolute, if it isn't already. It's important to
427 #### avoid running the file name through pwd unnecessarily, since pwd can
428 #### give you automounter prefixes, which can go away. We do all this
429 #### so Emacs can find its files when run uninstalled.
430 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
431 unset CDPATH
432 case "${srcdir}" in
433 [[\\/]]* | ?:[[\\/]]*) ;;
434 . )
435 ## We may be able to use the $PWD environment variable to make this
436 ## absolute. But sometimes PWD is inaccurate.
437 ## Note: we used to use $PWD at the end instead of `pwd`,
438 ## but that tested only for a well-formed and valid PWD,
439 ## it did not object when PWD was well-formed and valid but just wrong.
440 if test ".$PWD" != "." && test ".`(cd "$PWD" ; sh -c pwd)`" = ".`pwd`" ;
441 then
442 srcdir="$PWD"
443 else
444 srcdir=`(cd "$srcdir"; pwd)`
445 fi
446 ;;
447 * ) srcdir=`(cd "$srcdir"; pwd)` ;;
448 esac
449
450 ### Canonicalize the configuration name.
451
452 AC_CANONICAL_HOST
453 canonical=$host
454 configuration=${host_alias-${build_alias-$host}}
455
456 dnl This used to use changequote, but, apart from `changequote is evil'
457 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
458 dnl the great gob of text. Thus it's not processed for possible expansion.
459 dnl Just make sure the brackets remain balanced.
460 dnl
461 dnl Since Emacs can't find matching pairs of quotes, boundaries are
462 dnl indicated by comments.
463 dnl quotation begins
464 [
465
466 ### If you add support for a new configuration, add code to this
467 ### switch statement to recognize your configuration name and select
468 ### the appropriate operating system file.
469
470 ### You would hope that you could choose an s/*.h
471 ### file based on the operating system portion. However, it turns out
472 ### that each s/*.h file is pretty manufacturer-specific.
473 ### So we basically have to have a special case for each
474 ### configuration name.
475 ###
476 ### As far as handling version numbers on operating systems is
477 ### concerned, make sure things will fail in a fixable way. If
478 ### /etc/MACHINES doesn't say anything about version numbers, be
479 ### prepared to handle anything reasonably. If version numbers
480 ### matter, be sure /etc/MACHINES says something about it.
481
482 opsys='' unported=no
483 case "${canonical}" in
484
485 ## GNU/Linux and similar ports
486 *-*-linux* )
487 opsys=gnu-linux
488 ;;
489
490 ## FreeBSD ports
491 *-*-freebsd* )
492 opsys=freebsd
493 ;;
494
495 ## DragonFly ports
496 *-*-dragonfly* )
497 opsys=dragonfly
498 ;;
499
500 ## FreeBSD kernel + glibc based userland
501 *-*-kfreebsd*gnu* )
502 opsys=gnu-kfreebsd
503 ;;
504
505 ## NetBSD ports
506 *-*-netbsd* )
507 opsys=netbsd
508 ;;
509
510 ## OpenBSD ports
511 *-*-openbsd* )
512 opsys=openbsd
513 ;;
514
515 ## Apple Darwin / Mac OS X
516 *-apple-darwin* )
517 case "${canonical}" in
518 i[3456]86-* ) ;;
519 powerpc-* ) ;;
520 x86_64-* ) ;;
521 * ) unported=yes ;;
522 esac
523 opsys=darwin
524 ## Use fink packages if available.
525 ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
526 ## if test -d /sw/include && test -d /sw/lib; then
527 ## GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
528 ## NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
529 ## fi
530 ;;
531
532 ## Cygwin ports
533 *-*-cygwin )
534 opsys=cygwin
535 ;;
536
537 ## HP 9000 series 700 and 800, running HP/UX
538 hppa*-hp-hpux10.2* )
539 opsys=hpux10-20
540 ;;
541 hppa*-hp-hpux1[1-9]* )
542 opsys=hpux11
543 CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
544 ;;
545
546 ## IBM machines
547 rs6000-ibm-aix4.[23]* )
548 opsys=aix4-2
549 ;;
550 powerpc-ibm-aix4.[23]* )
551 opsys=aix4-2
552 ;;
553 rs6000-ibm-aix[56]* )
554 opsys=aix4-2
555 ;;
556 powerpc-ibm-aix[56]* )
557 opsys=aix4-2
558 ;;
559
560 ## Silicon Graphics machines
561 ## Iris 4D
562 mips-sgi-irix6.5 )
563 opsys=irix6-5
564 # Without defining _LANGUAGE_C, things get masked out in the headers
565 # so that, for instance, grepping for `free' in stdlib.h fails and
566 # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
567 NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
568 ;;
569
570 ## Suns
571 *-sun-solaris* \
572 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
573 | x86_64-*-solaris2* | x86_64-*-sunos5*)
574 case "${canonical}" in
575 i[3456]86-*-* ) ;;
576 amd64-*-*|x86_64-*-*) ;;
577 sparc* ) ;;
578 * ) unported=yes ;;
579 esac
580 case "${canonical}" in
581 *-sunos5.6* | *-solaris2.6* )
582 opsys=sol2-6
583 RANLIB="ar -ts"
584 ;;
585 *-sunos5.[7-9]* | *-solaris2.[7-9]* )
586 opsys=sol2-6
587 emacs_check_sunpro_c=yes
588 ;;
589 *-sunos5* | *-solaris* )
590 opsys=sol2-10
591 emacs_check_sunpro_c=yes
592 ;;
593 esac
594 ## Watch out for a compiler that we know will not work.
595 case "${canonical}" in
596 *-solaris* | *-sunos5* )
597 if [ "x$CC" = x/usr/ucb/cc ]; then
598 ## /usr/ucb/cc doesn't work;
599 ## we should find some other compiler that does work.
600 unset CC
601 fi
602 ;;
603 *) ;;
604 esac
605 ;;
606
607 ## Intel 386 machines where we don't care about the manufacturer.
608 i[3456]86-*-* )
609 case "${canonical}" in
610 *-darwin* ) opsys=darwin ;;
611 *-mingw32 )
612 opsys=mingw32
613 # MinGW overrides and adds some system headers in nt/inc.
614 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
615 ;;
616 *-sysv4.2uw* ) opsys=unixware ;;
617 *-sysv5uw* ) opsys=unixware ;;
618 *-sysv5OpenUNIX* ) opsys=unixware ;;
619 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
620 esac
621 ;;
622
623 * )
624 unported=yes
625 ;;
626 esac
627
628 ### If the code above didn't choose an operating system, just choose
629 ### an operating system based on the configuration name. You really
630 ### only want to use this when you have no idea what the right
631 ### operating system is; if you know what operating systems a machine
632 ### runs, it's cleaner to make it explicit in the case statement
633 ### above.
634 if test x"${opsys}" = x; then
635 case "${canonical}" in
636 *-gnu* ) opsys=gnu ;;
637 * )
638 unported=yes
639 ;;
640 esac
641 fi
642
643 ]
644 dnl quotation ends
645
646 if test $unported = yes; then
647 AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
648 Check `etc/MACHINES' for recognized configuration names.])
649 fi
650
651
652 #### Choose a compiler.
653
654 dnl Sets GCC=yes if using gcc.
655 AC_PROG_CC
656 AM_PROG_CC_C_O
657
658 if test x$GCC = xyes; then
659 test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
660 else
661 test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
662 fi
663
664 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
665 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
666 dnl that clash with MinGW.
667 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
668
669 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
670 # as we don't use them.
671 AC_DEFUN([gl_FCNTL_O_FLAGS])
672 # Avoid gnulib's threadlib module, as we do threads our own way.
673 AC_DEFUN([gl_THREADLIB])
674
675 # Initialize gnulib right after choosing the compiler.
676 dnl Amongst other things, this sets AR and ARFLAGS.
677 gl_EARLY
678
679 if test "$ac_test_CFLAGS" != set; then
680 # It's helpful to have C macros available to GDB, so prefer -g3 to -g
681 # if -g3 works and the user does not specify CFLAGS.
682 # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
683 case $CFLAGS in
684 '-g')
685 emacs_g3_CFLAGS='-g3';;
686 '-g -O2')
687 emacs_g3_CFLAGS='-g3 -O2';;
688 *)
689 emacs_g3_CFLAGS='';;
690 esac
691 if test -n "$emacs_g3_CFLAGS"; then
692 emacs_save_CFLAGS=$CFLAGS
693 CFLAGS=$emacs_g3_CFLAGS
694 AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
695 [emacs_cv_prog_cc_g3],
696 [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
697 [emacs_cv_prog_cc_g3=yes],
698 [emacs_cv_prog_cc_g3=no])])
699 if test $emacs_cv_prog_cc_g3 != yes; then
700 CFLAGS=$emacs_save_CFLAGS
701 fi
702 if test $opsys = mingw32; then
703 CFLAGS="$CFLAGS -gdwarf-2"
704 fi
705 fi
706
707 case $CFLAGS in
708 *-O*) ;;
709 *)
710 # No optimization flag was inferred for this non-GCC compiler.
711 # Try -O. This is needed for xlc on AIX; see Bug#14258.
712 emacs_save_CFLAGS=$CFLAGS
713 test -z "$CFLAGS" || CFLAGS="$CFLAGS "
714 CFLAGS=${CFLAGS}-O
715 AC_CACHE_CHECK([whether $CC accepts -O],
716 [emacs_cv_prog_cc_o],
717 [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
718 [emacs_cv_prog_cc_o=yes],
719 [emacs_cv_prog_cc_o=no])])
720 if test $emacs_cv_prog_cc_o != yes; then
721 CFLAGS=$emacs_save_CFLAGS
722 fi ;;
723 esac
724 fi
725
726 AC_ARG_ENABLE([gcc-warnings],
727 [AS_HELP_STRING([--enable-gcc-warnings],
728 [turn on lots of GCC warnings/errors. This is intended for
729 developers, and may generate false alarms when used
730 with older or non-GNU development tools.])],
731 [case $enableval in
732 yes|no) ;;
733 *) AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
734 esac
735 gl_gcc_warnings=$enableval],
736 [gl_gcc_warnings=no]
737 )
738
739 AC_ARG_ENABLE(link-time-optimization,
740 [AS_HELP_STRING([--enable-link-time-optimization],
741 [build emacs with link-time optimization.
742 This is supported only for GCC since 4.5.0.])],
743 if test "${enableval}" != "no"; then
744 AC_MSG_CHECKING([whether link-time optimization is supported])
745 ac_lto_supported=no
746 if test x$GCC = xyes; then
747 CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
748 if test x$CPUS != x; then
749 LTO="-flto=$CPUS"
750 else
751 LTO="-flto"
752 fi
753 old_CFLAGS=$CFLAGS
754 CFLAGS="$CFLAGS $LTO"
755 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
756 [ac_lto_supported=yes], [ac_lto_supported=no])
757 CFLAGS="$old_CFLAGS"
758 fi
759 AC_MSG_RESULT([$ac_lto_supported])
760 if test "$ac_lto_supported" = "yes"; then
761 CFLAGS="$CFLAGS $LTO"
762 fi
763 fi)
764
765 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
766 # ------------------------------------------------
767 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
768 # Otherwise, run RUN-IF-NOT-FOUND.
769 AC_DEFUN([gl_GCC_VERSION_IFELSE],
770 [AC_PREPROC_IFELSE(
771 [AC_LANG_PROGRAM(
772 [[
773 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
774 /* ok */
775 #else
776 # error "your version of gcc is older than $1.$2"
777 #endif
778 ]]),
779 ], [$3], [$4])
780 ]
781 )
782
783 # When compiling with GCC, prefer -isystem to -I when including system
784 # include files, to avoid generating useless diagnostics for the files.
785 if test "$gl_gcc_warnings" != yes; then
786 isystem='-I'
787 else
788 isystem='-isystem '
789
790 # This, $nw, is the list of warnings we disable.
791 nw=
792
793 case $with_x_toolkit in
794 lucid | athena | motif)
795 # Old toolkits mishandle 'const'.
796 nw="$nw -Wwrite-strings"
797 ;;
798 *)
799 gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
800 ;;
801 esac
802 AC_SUBST([WERROR_CFLAGS])
803
804 nw="$nw -Wsystem-headers" # Don't let system headers trigger warnings
805 nw="$nw -Woverlength-strings" # Not a problem these days
806 nw="$nw -Wlogical-op" # any use of fwrite provokes this
807 nw="$nw -Wformat-nonliteral" # we do this a lot
808 nw="$nw -Wvla" # warnings in gettext.h
809 nw="$nw -Wnested-externs" # use of XARGMATCH/verify_function__
810 nw="$nw -Wswitch-default" # Too many warnings for now
811 nw="$nw -Winline" # OK to ignore 'inline'
812 nw="$nw -Wjump-misses-init" # We sometimes safely jump over init.
813 nw="$nw -Wstrict-overflow" # OK to optimize assuming that
814 # signed overflow has undefined behavior
815 nw="$nw -Wsync-nand" # irrelevant here, and provokes ObjC warning
816 nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
817 nw="$nw -Wbad-function-cast" # These casts are no worse than others.
818
819 # Emacs doesn't care about shadowing; see
820 # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
821 nw="$nw -Wshadow"
822
823 # Emacs's use of alloca inhibits protecting the stack.
824 nw="$nw -Wstack-protector"
825
826 # The following line should be removable at some point.
827 nw="$nw -Wsuggest-attribute=pure"
828
829 # clang is unduly picky about some things.
830 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
831 [AC_COMPILE_IFELSE(
832 [AC_LANG_PROGRAM([[
833 #ifndef __clang__
834 #error "not clang"
835 #endif
836 ]])],
837 [emacs_cv_clang=yes],
838 [emacs_cv_clang=no])])
839 if test $emacs_cv_clang = yes; then
840 nw="$nw -Wcast-align"
841 fi
842
843 gl_MANYWARN_ALL_GCC([ws])
844 gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
845 for w in $ws; do
846 gl_WARN_ADD([$w])
847 done
848 gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
849 gl_WARN_ADD([-Wno-sign-compare]) # Too many warnings for now
850 gl_WARN_ADD([-Wno-type-limits]) # Too many warnings for now
851 gl_WARN_ADD([-Wno-switch]) # Too many warnings for now
852 gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
853 gl_WARN_ADD([-Wno-format-nonliteral])
854
855 # In spite of excluding -Wlogical-op above, it is enabled, as of
856 # gcc 4.5.0 20090517.
857 gl_WARN_ADD([-Wno-logical-op])
858
859 # More things that clang is unduly picky about.
860 if test $emacs_cv_clang = yes; then
861 gl_WARN_ADD([-Wno-format-extra-args])
862 gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
863 gl_WARN_ADD([-Wno-unused-command-line-argument])
864 gl_WARN_ADD([-Wno-unused-value])
865 fi
866
867 gl_WARN_ADD([-fdiagnostics-show-option])
868 gl_WARN_ADD([-funit-at-a-time])
869
870 AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
871 AH_VERBATIM([FORTIFY_SOURCE],
872 [/* Enable compile-time and run-time bounds-checking, and some warnings,
873 without upsetting glibc 2.15+. */
874 #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
875 # define _FORTIFY_SOURCE 2
876 #endif
877 ])
878 AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
879
880 # We use a slightly smaller set of warning options for lib/.
881 # Remove the following and save the result in GNULIB_WARN_CFLAGS.
882 nw=
883 nw="$nw -Wunused-macros"
884
885 gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
886 AC_SUBST([GNULIB_WARN_CFLAGS])
887 fi
888
889
890
891 dnl Some other nice autoconf tests.
892 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
893 dnl AC_PROG_INSTALL
894 dnl AC_PROG_MKDIR_P
895 dnl if test "x$RANLIB" = x; then
896 dnl AC_PROG_RANLIB
897 dnl fi
898
899
900 dnl Sadly, AC_PROG_LN_S is too restrictive. It also tests whether links
901 dnl can be made to directories. This is not relevant for our usage, and
902 dnl excludes some cases that work fine for us. Eg MS Windows or files
903 dnl hosted on AFS, both examples where simple links work, but links to
904 dnl directories fail. We use a cut-down version instead.
905 dnl AC_PROG_LN_S
906
907 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
908 rm -f conf$$ conf$$.file
909
910 LN_S_FILEONLY='cp -p'
911
912 if (echo >conf$$.file) 2>/dev/null; then
913 if ln -s conf$$.file conf$$ 2>/dev/null; then
914 LN_S_FILEONLY='ln -s'
915 elif ln conf$$.file conf$$ 2>/dev/null; then
916 LN_S_FILEONLY=ln
917 fi
918 fi
919
920 rm -f conf$$ conf$$.file
921
922 if test "$LN_S_FILEONLY" = "ln -s"; then
923 AC_MSG_RESULT([yes])
924 else
925 AC_MSG_RESULT([no, using $LN_S_FILEONLY])
926 fi
927
928 AC_SUBST(LN_S_FILEONLY)
929
930
931 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
932 dnl doesn't support links to directories, as in "ln file dir". But that
933 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
934 dnl executables at "make install" time.
935 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
936 dnl for more details.
937 if test "$opsys" = "mingw32"; then
938 LN_S="ln"
939 fi
940
941 AC_PATH_PROG(INSTALL_INFO, install-info, :,
942 $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
943 dnl Don't use GZIP, which is used by gzip for additional parameters.
944 AC_PATH_PROG(GZIP_PROG, gzip)
945
946 if test $opsys = gnu-linux; then
947 AC_PATH_PROG(PAXCTL, paxctl,,
948 [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
949 if test "X$PAXCTL" != X; then
950 AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
951 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
952 [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
953 else AC_MSG_RESULT(no); PAXCTL=""; fi])
954 fi
955 fi
956
957 ## Need makeinfo >= 4.7 (?) to build the manuals.
958 AC_PATH_PROG(MAKEINFO, makeinfo, no)
959 dnl By this stage, configure has already checked for egrep and set EGREP,
960 dnl or exited with an error if no egrep was found.
961 if test "$MAKEINFO" != "no"; then
962 case `
963 $MAKEINFO --version 2> /dev/null |
964 $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
965 ` in
966 '') MAKEINFO=no;;
967 esac
968 fi
969
970 ## Makeinfo is unusual. For a released Emacs, the manuals are
971 ## pre-built, and not deleted by the normal clean rules. makeinfo is
972 ## therefore in the category of "special tools" not normally required, which
973 ## configure does not have to check for (eg autoconf itself).
974 ## In a Bazaar checkout on the other hand, the manuals are not included.
975 ## So makeinfo is a requirement to build from Bazaar, and configure
976 ## should test for it as it does for any other build requirement.
977 ## We use the presence of $srcdir/info/emacs to distinguish a release,
978 ## with pre-built manuals, from a Bazaar checkout.
979 HAVE_MAKEINFO=yes
980
981 if test "$MAKEINFO" = "no"; then
982 MAKEINFO=makeinfo
983 if test "x${with_makeinfo}" = "xno"; then
984 HAVE_MAKEINFO=no
985 elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
986 AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
987 source tree does not seem to have pre-built manuals in the `info' directory.
988 Either install a suitable version of makeinfo, or re-run configure
989 with the `--without-makeinfo' option to build without the manuals.] )
990 fi
991 fi
992 AC_SUBST(HAVE_MAKEINFO)
993
994 dnl Just so that there is only a single place we need to edit.
995 INFO_EXT=.info
996 INFO_OPTS=--no-split
997 AC_SUBST(INFO_EXT)
998 AC_SUBST(INFO_OPTS)
999
1000 if test $opsys = mingw32; then
1001 DOCMISC_W32=efaq-w32
1002 else
1003 DOCMISC_W32=
1004 fi
1005 AC_SUBST(DOCMISC_W32)
1006
1007 dnl Add our options to ac_link now, after it is set up.
1008
1009 if test x$GCC = xyes; then
1010 test "x$GCC_LINK_TEST_OPTIONS" != x && \
1011 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1012 else
1013 test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1014 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1015 fi
1016
1017 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1018 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1019 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1020 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1021 dnl if not built to support GNU ld.
1022
1023 late_LDFLAGS=$LDFLAGS
1024 if test x$GCC = xyes; then
1025 LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
1026 else
1027 LDFLAGS="$LDFLAGS -znocombreloc"
1028 fi
1029
1030 AC_MSG_CHECKING([for -znocombreloc])
1031 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1032 [AC_MSG_RESULT(yes)],
1033 LDFLAGS=$late_LDFLAGS
1034 [AC_MSG_RESULT(no)])
1035
1036
1037 dnl The function dump-emacs will not be defined and temacs will do
1038 dnl (load "loadup") automatically unless told otherwise.
1039 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1040 case "$opsys" in
1041 your-opsys-here) CANNOT_DUMP=yes ;;
1042 esac
1043
1044 test "$CANNOT_DUMP" = "yes" && \
1045 AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1046
1047 AC_SUBST(CANNOT_DUMP)
1048
1049
1050 UNEXEC_OBJ=unexelf.o
1051 case "$opsys" in
1052 # MSDOS uses unexcoff.o
1053 aix4-2)
1054 UNEXEC_OBJ=unexaix.o
1055 ;;
1056 cygwin)
1057 UNEXEC_OBJ=unexcw.o
1058 ;;
1059 darwin)
1060 UNEXEC_OBJ=unexmacosx.o
1061 ;;
1062 hpux10-20 | hpux11)
1063 UNEXEC_OBJ=unexhp9k800.o
1064 ;;
1065 mingw32)
1066 UNEXEC_OBJ=unexw32.o
1067 ;;
1068 sol2-10)
1069 # Use the Solaris dldump() function, called from unexsol.c, to dump
1070 # emacs, instead of the generic ELF dump code found in unexelf.c.
1071 # The resulting binary has a complete symbol table, and is better
1072 # for debugging and other observability tools (debuggers, pstack, etc).
1073 #
1074 # If you encounter a problem using dldump(), please consider sending
1075 # a message to the OpenSolaris tools-linking mailing list:
1076 # http://mail.opensolaris.org/mailman/listinfo/tools-linking
1077 #
1078 # It is likely that dldump() works with older Solaris too, but this has
1079 # not been tested, so for now this change is for Solaris 10 or newer.
1080 UNEXEC_OBJ=unexsol.o
1081 ;;
1082 esac
1083
1084 LD_SWITCH_SYSTEM=
1085 case "$opsys" in
1086 freebsd|dragonfly)
1087 ## Let `ld' find image libs and similar things in /usr/local/lib.
1088 ## The system compiler, GCC, has apparently been modified to not
1089 ## look there, contrary to what a stock GCC would do.
1090 ### It's not our place to do this. See bug#10313#17.
1091 ### LD_SWITCH_SYSTEM=-L/usr/local/lib
1092 :
1093 ;;
1094
1095 gnu-linux)
1096 ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1097 case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1098 ;;
1099
1100 netbsd)
1101 ### It's not our place to do this. See bug#10313#17.
1102 ### LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1103 :
1104 ;;
1105
1106 openbsd)
1107 ## Han Boetes <han@boetes.org> says this is necessary,
1108 ## otherwise Emacs dumps core on elf systems.
1109 LD_SWITCH_SYSTEM="-Z"
1110 ;;
1111 esac
1112 AC_SUBST(LD_SWITCH_SYSTEM)
1113
1114 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1115
1116 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1117 ## which has not been defined yet. When this was handled with cpp,
1118 ## it was expanded to null when configure sourced the s/*.h file.
1119 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1120 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1121 ## (or somesuch), but because it is supposed to go at the _front_
1122 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1123 ## Compare with the gnu-linux case below, which added to the end
1124 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1125 ## LD_SWITCH_SYSTEM_TEMACS.
1126 case "$opsys" in
1127 netbsd|openbsd)
1128 LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1129 esac
1130
1131
1132 C_SWITCH_MACHINE=
1133 case $canonical in
1134 alpha*)
1135 AC_CHECK_DECL([__ELF__])
1136 if test "$ac_cv_have_decl___ELF__" = "yes"; then
1137 ## With ELF, make sure that all common symbols get allocated to in the
1138 ## data section. Otherwise, the dump of temacs may miss variables in
1139 ## the shared library that have been initialized. For example, with
1140 ## GNU libc, __malloc_initialized would normally be resolved to the
1141 ## shared library's .bss section, which is fatal.
1142 if test "x$GCC" = "xyes"; then
1143 C_SWITCH_MACHINE="-fno-common"
1144 else
1145 AC_MSG_ERROR([What gives? Fix me if DEC Unix supports ELF now.])
1146 fi
1147 else
1148 UNEXEC_OBJ=unexalpha.o
1149 fi
1150 ;;
1151 esac
1152 AC_SUBST(C_SWITCH_MACHINE)
1153
1154 AC_SUBST(UNEXEC_OBJ)
1155
1156 C_SWITCH_SYSTEM=
1157 ## Some programs in src produce warnings saying certain subprograms
1158 ## are too complex and need a MAXMEM value greater than 2000 for
1159 ## additional optimization. --nils@exp-math.uni-essen.de
1160 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1161 C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1162 test "$opsys" = "mingw32" && C_SWITCH_SYSTEM="-mtune=pentium4"
1163 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1164 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1165 AC_SUBST(C_SWITCH_SYSTEM)
1166
1167
1168 LIBS_SYSTEM=
1169 case "$opsys" in
1170 ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1171 aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1172
1173 freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1174
1175 hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1176
1177 sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1178
1179 ## Motif needs -lgen.
1180 unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1181 esac
1182
1183 AC_SUBST(LIBS_SYSTEM)
1184
1185 ### Make sure subsequent tests use flags consistent with the build flags.
1186
1187 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1188 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1189 else
1190 CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1191 fi
1192
1193 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1194 AC_DEFUN([AC_TYPE_SIZE_T])
1195 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1196 AC_DEFUN([AC_TYPE_UID_T])
1197
1198
1199 LIB_MATH=-lm
1200 dnl Current possibilities handled by sed (aix4-2 -> aix,
1201 dnl gnu-linux -> gnu/linux, etc.):
1202 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1203 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1204 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1205
1206 case $opsys in
1207 cygwin )
1208 LIB_MATH=
1209 ;;
1210 darwin )
1211 ## Adding -lm confuses the dynamic linker, so omit it.
1212 LIB_MATH=
1213 ;;
1214 freebsd | dragonfly )
1215 SYSTEM_TYPE=berkeley-unix
1216 ;;
1217 gnu-linux | gnu-kfreebsd )
1218 ;;
1219 hpux10-20 | hpux11 )
1220 ;;
1221 mingw32 )
1222 LIB_MATH=
1223 SYSTEM_TYPE=windows-nt
1224 ;;
1225 dnl NB this may be adjusted below.
1226 netbsd | openbsd )
1227 SYSTEM_TYPE=berkeley-unix
1228 ;;
1229
1230 sol2* | unixware )
1231 SYSTEM_TYPE=usg-unix-v
1232 ;;
1233
1234 esac
1235
1236 AC_SUBST(LIB_MATH)
1237 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1238 [The type of system you are compiling for; sets `system-type'.])
1239
1240
1241 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1242 pre_PKG_CONFIG_LIBS=$LIBS
1243
1244 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1245
1246 dnl This function definition taken from Gnome 2.0
1247 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1248 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1249 dnl also defines GSTUFF_PKG_ERRORS on error
1250 AC_DEFUN([PKG_CHECK_MODULES], [
1251 succeeded=no
1252
1253 if test "$PKG_CONFIG" = "no" ; then
1254 ifelse([$4], , [AC_MSG_ERROR([
1255 *** The pkg-config script could not be found. Make sure it is in your path, or give the full name of pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog. Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1256 else
1257 PKG_CONFIG_MIN_VERSION=0.9.0
1258 if "$PKG_CONFIG" --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1259 AC_MSG_CHECKING(for $2)
1260
1261 if "$PKG_CONFIG" --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1262 $1_CFLAGS=`"$PKG_CONFIG" --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1263 $1_LIBS=`"$PKG_CONFIG" --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1264 edit_cflags="
1265 s,///*,/,g
1266 s/^/ /
1267 s/ -I/ $isystem/g
1268 s/^ //
1269 "
1270 $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1271 $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1272 AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1273 succeeded=yes
1274 else
1275 AC_MSG_RESULT(no)
1276 $1_CFLAGS=""
1277 $1_LIBS=""
1278 ## If we have a custom action on failure, don't print errors, but
1279 ## do set a variable so people can do so. Do it in a subshell
1280 ## to capture any diagnostics in invoking pkg-config.
1281 $1_PKG_ERRORS=`("$PKG_CONFIG" --print-errors "$2") 2>&1`
1282 ifelse([$4], ,echo "$$1_PKG_ERRORS",)
1283 fi
1284
1285 AC_SUBST($1_CFLAGS)
1286 AC_SUBST($1_LIBS)
1287 else
1288 echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1289 echo "*** See http://www.freedesktop.org/software/pkgconfig"
1290 fi
1291 fi
1292
1293 if test $succeeded = yes; then
1294 ifelse([$3], , :, [$3])
1295 else
1296 ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1297 fi
1298 ])
1299
1300 HAVE_SOUND=no
1301 if test "${with_sound}" != "no"; then
1302 # Sound support for GNU/Linux, the free BSDs, and MinGW.
1303 AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h],
1304 have_sound_header=yes, [], [
1305 #ifdef __MINGW32__
1306 #define WIN32_LEAN_AND_MEAN
1307 #include <windows.h>
1308 #endif
1309 ])
1310 test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1311 AC_MSG_ERROR([OSS sound support requested but not found.])
1312
1313 if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1314 # Emulation library used on NetBSD.
1315 AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1316 test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1317 AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1318 dnl FIXME? If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1319 dnl Traditionally, we go on to check for alsa too. Does that make sense?
1320 fi
1321 AC_SUBST(LIBSOUND)
1322
1323 if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1324 ALSA_REQUIRED=1.0.0
1325 ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1326 PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1327 if test $HAVE_ALSA = yes; then
1328 SAVE_CFLAGS="$CFLAGS"
1329 SAVE_LIBS="$LIBS"
1330 CFLAGS="$ALSA_CFLAGS $CFLAGS"
1331 LIBS="$ALSA_LIBS $LIBS"
1332 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1333 emacs_alsa_normal=yes,
1334 emacs_alsa_normal=no)
1335 if test "$emacs_alsa_normal" != yes; then
1336 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1337 [[snd_lib_error_set_handler (0);]])],
1338 emacs_alsa_subdir=yes,
1339 emacs_alsa_subdir=no)
1340 if test "$emacs_alsa_subdir" != yes; then
1341 AC_MSG_ERROR([pkg-config found alsa, but it does not compile. See config.log for error messages.])
1342 fi
1343 ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1344 fi
1345
1346 CFLAGS="$SAVE_CFLAGS"
1347 LIBS="$SAVE_LIBS"
1348 LIBSOUND="$LIBSOUND $ALSA_LIBS"
1349 CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1350 AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1351 elif test "${with_sound}" = "alsa"; then
1352 AC_MSG_ERROR([ALSA sound support requested but not found.])
1353 fi
1354 fi dnl with_sound = alsa|yes
1355
1356 dnl Define HAVE_SOUND if we have sound support. We know it works and
1357 dnl compiles only on the specified platforms. For others, it
1358 dnl probably doesn't make sense to try.
1359 dnl FIXME So surely we should bypass this whole section if not using
1360 dnl one of these platforms?
1361 if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1362 case "$opsys" in
1363 dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1364 dnl Adjust the --with-sound help text if you change this.
1365 gnu-linux|freebsd|netbsd|mingw32)
1366 AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1367 HAVE_SOUND=yes
1368 ;;
1369 esac
1370 fi
1371
1372 AC_SUBST(CFLAGS_SOUND)
1373 fi
1374
1375 dnl checks for header files
1376 AC_CHECK_HEADERS_ONCE(
1377 sys/systeminfo.h
1378 coff.h pty.h
1379 sys/resource.h
1380 sys/utsname.h pwd.h utmp.h util.h)
1381
1382 AC_MSG_CHECKING(if personality LINUX32 can be set)
1383 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1384 emacs_cv_personality_linux32=yes,
1385 emacs_cv_personality_linux32=no)
1386 AC_MSG_RESULT($emacs_cv_personality_linux32)
1387
1388 if test $emacs_cv_personality_linux32 = yes; then
1389 AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1390 [Define to 1 if personality LINUX32 can be set.])
1391 fi
1392
1393 dnl On Solaris 8 there's a compilation warning for term.h because
1394 dnl it doesn't define `bool'.
1395 AC_CHECK_HEADERS(term.h, , , -)
1396 AC_HEADER_TIME
1397 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1398 ]])
1399 if test $ac_cv_have_decl_sys_siglist != yes; then
1400 # For Tru64, at least:
1401 AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1402 ]])
1403 fi
1404 AC_HEADER_SYS_WAIT
1405
1406 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1407 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1408 #if HAVE_SYS_SOCKET_H
1409 #include <sys/socket.h>
1410 #endif])
1411 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1412 #if HAVE_SYS_SOCKET_H
1413 #include <sys/socket.h>
1414 #endif])
1415 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1416 #if HAVE_SYS_SOCKET_H
1417 #include <sys/socket.h>
1418 #endif])
1419
1420 dnl checks for structure members
1421 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1422 struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1423 struct ifreq.ifr_addr,
1424 struct ifreq.ifr_addr.sa_len], , ,
1425 [AC_INCLUDES_DEFAULT
1426 #if HAVE_SYS_SOCKET_H
1427 #include <sys/socket.h>
1428 #endif
1429 #if HAVE_NET_IF_H
1430 #include <net/if.h>
1431 #endif])
1432
1433 dnl Check for endianness.
1434 dnl AC_C_BIGENDIAN is done by gnulib.
1435
1436 dnl check for Make feature
1437 dnl AC_PROG_MAKE_SET is done by Automake.
1438
1439 DEPFLAGS=
1440 MKDEPDIR=":"
1441 deps_frag=deps.mk
1442 dnl check for GNU Make if we have GCC and autodepend is on.
1443 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1444 AC_MSG_CHECKING([whether we are using GNU Make])
1445 HAVE_GNU_MAKE=no
1446 testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1447 if test "x$testval" != x; then
1448 HAVE_GNU_MAKE=yes
1449 else
1450 ac_enable_autodepend=no
1451 fi
1452 AC_MSG_RESULT([$HAVE_GNU_MAKE])
1453 if test $HAVE_GNU_MAKE = yes; then
1454 AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1455 SAVE_CFLAGS="$CFLAGS"
1456 CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1457 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1458 CFLAGS="$SAVE_CFLAGS"
1459 test -f deps.d || ac_enable_autodepend=no
1460 rm -rf deps.d
1461 AC_MSG_RESULT([$ac_enable_autodepend])
1462 fi
1463 if test $ac_enable_autodepend = yes; then
1464 DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1465 ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1466 MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1467 deps_frag=autodeps.mk
1468 fi
1469 fi
1470 deps_frag=$srcdir/src/$deps_frag
1471 AC_SUBST(MKDEPDIR)
1472 AC_SUBST(DEPFLAGS)
1473 AC_SUBST_FILE(deps_frag)
1474
1475
1476 lisp_frag=$srcdir/src/lisp.mk
1477 AC_SUBST_FILE(lisp_frag)
1478
1479
1480 dnl checks for operating system services
1481 AC_SYS_LONG_FILE_NAMES
1482
1483 #### Choose a window system.
1484
1485 ## We leave window_system equal to none if
1486 ## we end up building without one. Any new window system should
1487 ## set window_system to an appropriate value and add objects to
1488 ## window-system-specific substs.
1489
1490 window_system=none
1491 AC_PATH_X
1492 if test "$no_x" != yes; then
1493 window_system=x11
1494 fi
1495
1496 LD_SWITCH_X_SITE_RPATH=
1497 if test "${x_libraries}" != NONE; then
1498 if test -n "${x_libraries}"; then
1499 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1500 LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1501 fi
1502 x_default_search_path=""
1503 x_search_path=${x_libraries}
1504 if test -z "${x_search_path}"; then
1505 x_search_path=/usr/lib
1506 fi
1507 for x_library in `echo ${x_search_path}: | \
1508 sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1509 x_search_path="\
1510 ${x_library}/X11/%L/%T/%N%C%S:\
1511 ${x_library}/X11/%l/%T/%N%C%S:\
1512 ${x_library}/X11/%T/%N%C%S:\
1513 ${x_library}/X11/%L/%T/%N%S:\
1514 ${x_library}/X11/%l/%T/%N%S:\
1515 ${x_library}/X11/%T/%N%S"
1516 if test x"${x_default_search_path}" = x; then
1517 x_default_search_path=${x_search_path}
1518 else
1519 x_default_search_path="${x_search_path}:${x_default_search_path}"
1520 fi
1521 done
1522 fi
1523 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1524
1525 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1526 C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1527 fi
1528
1529 if test x"${x_includes}" = x; then
1530 bitmapdir=/usr/include/X11/bitmaps
1531 else
1532 # accumulate include directories that have X11 bitmap subdirectories
1533 bmd_acc="dummyval"
1534 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1535 if test -d "${bmd}/X11/bitmaps"; then
1536 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1537 fi
1538 if test -d "${bmd}/bitmaps"; then
1539 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1540 fi
1541 done
1542 if test ${bmd_acc} != "dummyval"; then
1543 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1544 fi
1545 fi
1546
1547 HAVE_NS=no
1548 NS_IMPL_COCOA=no
1549 NS_IMPL_GNUSTEP=no
1550 tmp_CPPFLAGS="$CPPFLAGS"
1551 tmp_CFLAGS="$CFLAGS"
1552 CPPFLAGS="$CPPFLAGS -x objective-c"
1553 CFLAGS="$CFLAGS -x objective-c"
1554 GNU_OBJC_CFLAGS=
1555 LIBS_GNUSTEP=
1556 if test "${with_ns}" != no; then
1557 if test "${opsys}" = darwin; then
1558 NS_IMPL_COCOA=yes
1559 ns_appdir=`pwd`/nextstep/Emacs.app
1560 ns_appbindir=${ns_appdir}/Contents/MacOS
1561 ns_appresdir=${ns_appdir}/Contents/Resources
1562 ns_appsrc=Cocoa/Emacs.base
1563 elif test -f $GNUSTEP_CONFIG_FILE; then
1564 NS_IMPL_GNUSTEP=yes
1565 ns_appdir=`pwd`/nextstep/Emacs.app
1566 ns_appbindir=${ns_appdir}
1567 ns_appresdir=${ns_appdir}/Resources
1568 ns_appsrc=GNUstep/Emacs.base
1569 dnl FIXME sourcing this several times in subshells seems inefficient.
1570 GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1571 GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1572 dnl I seemed to need these as well with GNUstep-startup 0.25.
1573 GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1574 GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1575 test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1576 GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1577 test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1578 GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1579 CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1580 CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1581 LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1582 LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1583 dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1584 dnl If they had chosen to either define it or not, we could have
1585 dnl just used AC_CHECK_DECL here.
1586 AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1587 emacs_cv_objc_exceptions,
1588 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1589 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1590 1;
1591 #else
1592 fail;
1593 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1594 if test $emacs_cv_objc_exceptions = yes; then
1595 dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1596 AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1597 [Define if GNUstep uses ObjC exceptions.])
1598 GNU_OBJC_CFLAGS="-fobjc-exceptions"
1599 fi
1600 fi
1601
1602 dnl This is only used while we test the NS headers, it gets reset below.
1603 CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1604
1605 AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1606 [AC_MSG_ERROR([`--with-ns' was specified, but the include
1607 files are missing or cannot be compiled.])])
1608
1609 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1610 [
1611 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1612 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1613 ; /* OK */
1614 #else
1615 #error "OSX 10.4 or newer required"
1616 #endif
1617 #endif
1618 ])],
1619 ns_osx_have_104=yes,
1620 ns_osx_have_104=no)
1621 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1622 [NSInteger i;])],
1623 ns_have_nsinteger=yes,
1624 ns_have_nsinteger=no)
1625 if test $ns_osx_have_104 = no; then
1626 AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1627 fi
1628 if test $ns_have_nsinteger = yes; then
1629 AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1630 fi
1631 fi
1632
1633 AC_SUBST(LIBS_GNUSTEP)
1634
1635 INSTALL_ARCH_INDEP_EXTRA=install-etc
1636 ns_self_contained=no
1637 NS_OBJ=
1638 NS_OBJC_OBJ=
1639 if test "${HAVE_NS}" = yes; then
1640 if test "$with_toolkit_scroll_bars" = "no"; then
1641 AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1642 fi
1643
1644 window_system=nextstep
1645 # set up packaging dirs
1646 if test "${EN_NS_SELF_CONTAINED}" = yes; then
1647 ns_self_contained=yes
1648 prefix=${ns_appresdir}
1649 exec_prefix=${ns_appbindir}
1650 dnl This one isn't really used, only archlibdir is.
1651 libexecdir="\${ns_appbindir}/libexec"
1652 archlibdir="\${ns_appbindir}/libexec"
1653 etcdocdir="\${ns_appresdir}/etc"
1654 etcdir="\${ns_appresdir}/etc"
1655 dnl FIXME maybe set datarootdir instead.
1656 dnl That would also get applications, icons, man.
1657 infodir="\${ns_appresdir}/info"
1658 mandir="\${ns_appresdir}/man"
1659 lispdir="\${ns_appresdir}/lisp"
1660 leimdir="\${ns_appresdir}/leim"
1661 INSTALL_ARCH_INDEP_EXTRA=
1662 fi
1663 NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1664 fi
1665 CFLAGS="$tmp_CFLAGS"
1666 CPPFLAGS="$tmp_CPPFLAGS"
1667 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1668 AC_SUBST(ns_self_contained)
1669 AC_SUBST(NS_OBJ)
1670 AC_SUBST(NS_OBJC_OBJ)
1671
1672 HAVE_W32=no
1673 W32_OBJ=
1674 W32_LIBS=
1675 EMACSRES=
1676 CLIENTRES=
1677 CLIENTW=
1678 W32_RES_LINK=
1679 EMACS_MANIFEST=
1680 UPDATE_MANIFEST=
1681 if test "${with_w32}" != no; then
1682 case "${opsys}" in
1683 cygwin)
1684 AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1685 [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1686 cannot be found.])])
1687 ;;
1688 mingw32)
1689 ## Using --with-w32 with MinGW is a no-op, but we allow it.
1690 ;;
1691 *)
1692 AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1693 ;;
1694 esac
1695 fi
1696
1697 if test "${opsys}" = "mingw32"; then
1698 AC_MSG_CHECKING([whether Windows API headers are recent enough])
1699 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1700 #include <windows.h>
1701 #include <usp10.h>]],
1702 [[PIMAGE_NT_HEADERS pHeader;
1703 PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1704 [emacs_cv_w32api=yes
1705 HAVE_W32=yes],
1706 emacs_cv_w32api=no)
1707 AC_MSG_RESULT($emacs_cv_w32api)
1708 if test "${emacs_cv_w32api}" = "no"; then
1709 AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1710 fi
1711 fi
1712
1713 FIRSTFILE_OBJ=
1714 NTDIR=
1715 LIBS_ECLIENT=
1716 LIB_WSOCK32=
1717 NTLIB=
1718 CM_OBJ="cm.o"
1719 XARGS_LIMIT=
1720 if test "${HAVE_W32}" = "yes"; then
1721 AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1722 AC_CHECK_TOOL(WINDRES, [windres],
1723 [AC_MSG_ERROR([No resource compiler found.])])
1724 W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1725 W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1726 EMACSRES="emacs.res"
1727 case "$canonical" in
1728 x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1729 *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1730 esac
1731 UPDATE_MANIFEST=update-game-score.exe.manifest
1732 if test "${opsys}" = "cygwin"; then
1733 W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1734 W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1735 # Tell the linker that emacs.res is an object (which we compile from
1736 # the rc file), not a linker script.
1737 W32_RES_LINK="-Wl,emacs.res"
1738 else
1739 W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1740 W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1741 W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1742 W32_RES_LINK="\$(EMACSRES)"
1743 CLIENTRES="emacsclient.res"
1744 CLIENTW="emacsclientw\$(EXEEXT)"
1745 FIRSTFILE_OBJ=firstfile.o
1746 NTDIR=nt
1747 CM_OBJ=
1748 LIBS_ECLIENT="-lcomctl32"
1749 LIB_WSOCK32="-lwsock32"
1750 NTLIB="ntlib.$ac_objext"
1751 XARGS_LIMIT="-s 10000"
1752 fi
1753 fi
1754 AC_SUBST(W32_OBJ)
1755 AC_SUBST(W32_LIBS)
1756 AC_SUBST(EMACSRES)
1757 AC_SUBST(EMACS_MANIFEST)
1758 AC_SUBST(UPDATE_MANIFEST)
1759 AC_SUBST(CLIENTRES)
1760 AC_SUBST(CLIENTW)
1761 AC_SUBST(W32_RES_LINK)
1762 AC_SUBST(FIRSTFILE_OBJ)
1763 AC_SUBST(NTDIR)
1764 AC_SUBST(CM_OBJ)
1765 AC_SUBST(LIBS_ECLIENT)
1766 AC_SUBST(LIB_WSOCK32)
1767 AC_SUBST(NTLIB)
1768 AC_SUBST(XARGS_LIMIT)
1769
1770 if test "${HAVE_W32}" = "yes"; then
1771 window_system=w32
1772 with_xft=no
1773 fi
1774
1775 ## $window_system is now set to the window system we will
1776 ## ultimately use.
1777
1778 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
1779 # Too many warnings for now.
1780 gl_WARN_ADD([-Wno-unused-variable])
1781 gl_WARN_ADD([-Wno-unused-but-set-variable])
1782 gl_WARN_ADD([-Wno-unused-but-set-parameter])
1783 fi
1784
1785 term_header=
1786 HAVE_X_WINDOWS=no
1787 HAVE_X11=no
1788 USE_X_TOOLKIT=none
1789
1790 case "${window_system}" in
1791 x11 )
1792 HAVE_X_WINDOWS=yes
1793 HAVE_X11=yes
1794 term_header=xterm.h
1795 case "${with_x_toolkit}" in
1796 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1797 motif ) USE_X_TOOLKIT=MOTIF ;;
1798 gtk ) with_gtk=yes
1799 term_header=gtkutil.h
1800 dnl Don't set this for GTK. A lot of tests below assumes Xt when
1801 dnl USE_X_TOOLKIT is set.
1802 USE_X_TOOLKIT=none ;;
1803 gtk2 ) with_gtk2=yes
1804 term_header=gtkutil.h
1805 USE_X_TOOLKIT=none ;;
1806 gtk3 ) with_gtk3=yes
1807 term_header=gtkutil.h
1808 USE_X_TOOLKIT=none ;;
1809 no ) USE_X_TOOLKIT=none ;;
1810 dnl If user did not say whether to use a toolkit, make this decision later:
1811 dnl use the toolkit if we have gtk, or X11R5 or newer.
1812 * ) USE_X_TOOLKIT=maybe ;;
1813 esac
1814 ;;
1815 nextstep )
1816 term_header=nsterm.h
1817 ;;
1818 w32 )
1819 term_header=w32term.h
1820 ;;
1821 esac
1822
1823 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1824 AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1825 if test "$HAVE_XSERVER" = true ||
1826 test -n "$DISPLAY" ||
1827 test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1828 AC_MSG_ERROR([You seem to be running X, but no X development libraries
1829 were found. You should install the relevant development files for X
1830 and for the toolkit you want, such as Gtk+, Lesstif or Motif. Also make
1831 sure you have development files for image handling, i.e.
1832 tiff, gif, jpeg, png and xpm.
1833 If you are sure you want Emacs compiled without X window support, pass
1834 --without-x
1835 to configure.])
1836 fi
1837 fi
1838
1839 ### If we're using X11, we should use the X menu package.
1840 HAVE_MENUS=no
1841 case ${HAVE_X11} in
1842 yes ) HAVE_MENUS=yes ;;
1843 esac
1844
1845 # Does the opsystem file prohibit the use of the GNU malloc?
1846 # Assume not, until told otherwise.
1847 GNU_MALLOC=yes
1848
1849 AC_CACHE_CHECK(
1850 [whether malloc is Doug Lea style],
1851 [emacs_cv_var_doug_lea_malloc],
1852 [AC_LINK_IFELSE(
1853 [AC_LANG_PROGRAM(
1854 [[#include <malloc.h>
1855 static void hook (void) {}]],
1856 [[malloc_set_state (malloc_get_state ());
1857 __after_morecore_hook = hook;
1858 __malloc_initialize_hook = hook;]])],
1859 [emacs_cv_var_doug_lea_malloc=yes],
1860 [emacs_cv_var_doug_lea_malloc=no])])
1861 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1862
1863
1864 dnl See comments in aix4-2.h about maybe using system malloc there.
1865 system_malloc=no
1866 case "$opsys" in
1867 ## darwin ld insists on the use of malloc routines in the System framework.
1868 darwin|sol2-10) system_malloc=yes ;;
1869 esac
1870
1871 if test "${system_malloc}" = "yes"; then
1872 AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1873 GNU_MALLOC=no
1874 GNU_MALLOC_reason="
1875 (The GNU allocators don't work with this system configuration.)"
1876 GMALLOC_OBJ=
1877 VMLIMIT_OBJ=
1878 else
1879 test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1880 VMLIMIT_OBJ=vm-limit.o
1881
1882 AC_CHECK_HEADERS([sys/vlimit.h])
1883 AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
1884 [AC_LINK_IFELSE(
1885 [AC_LANG_PROGRAM(
1886 [[extern char data_start[]; char ch;]],
1887 [[return data_start < &ch;]])],
1888 [emacs_cv_data_start=yes],
1889 [emacs_cv_data_start=no])])
1890 if test $emacs_cv_data_start = yes; then
1891 AC_DEFINE([HAVE_DATA_START], 1,
1892 [Define to 1 if data_start is the address of the start
1893 of the main data segment.])
1894 fi
1895 fi
1896 AC_SUBST(GMALLOC_OBJ)
1897 AC_SUBST(VMLIMIT_OBJ)
1898
1899 if test "$doug_lea_malloc" = "yes" ; then
1900 if test "$GNU_MALLOC" = yes ; then
1901 GNU_MALLOC_reason="
1902 (Using Doug Lea's new malloc from the GNU C Library.)"
1903 fi
1904 AC_DEFINE(DOUG_LEA_MALLOC, 1,
1905 [Define to 1 if you are using the GNU C Library.])
1906
1907 ## Use mmap directly for allocating larger buffers.
1908 ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1909 ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1910 ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1911 case "$opsys" in
1912 gnu*) REL_ALLOC=no ;;
1913 esac
1914 fi
1915
1916 if test x"${REL_ALLOC}" = x; then
1917 REL_ALLOC=${GNU_MALLOC}
1918 fi
1919
1920 use_mmap_for_buffers=no
1921 case "$opsys" in
1922 cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1923 esac
1924
1925 AC_FUNC_MMAP
1926 if test $use_mmap_for_buffers = yes; then
1927 AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1928 REL_ALLOC=no
1929 fi
1930
1931 LIBS="$LIBS_SYSTEM $LIBS"
1932
1933 dnl If found, this adds -ldnet to LIBS, which Autoconf uses for checks.
1934 AC_CHECK_LIB(dnet, dnet_ntoa)
1935 dnl This causes -lresolv to get used in subsequent tests,
1936 dnl which causes failures on some systems such as HPUX 9.
1937 dnl AC_CHECK_LIB(resolv, gethostbyname)
1938
1939 dnl FIXME replace main with a function we actually want from this library.
1940 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1941
1942 dnl Check if pthreads is available.
1943 LIB_PTHREAD=
1944 AC_CHECK_HEADERS_ONCE(pthread.h)
1945 if test "$ac_cv_header_pthread_h"; then
1946 dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1947 dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1948 dnl testing for pthread_self if Emacs uses gmalloc.c.
1949 if test "$GMALLOC_OBJ" = gmalloc.o; then
1950 emacs_pthread_function=pthread_atfork
1951 else
1952 emacs_pthread_function=pthread_self
1953 fi
1954 AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1955 fi
1956 if test "$HAVE_PTHREAD" = yes; then
1957 case "${canonical}" in
1958 *-hpux*) ;;
1959 *) LIB_PTHREAD="-lpthread"
1960 LIBS="$LIB_PTHREAD $LIBS" ;;
1961 esac
1962 AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1963 fi
1964 AC_SUBST([LIB_PTHREAD])
1965
1966 AC_CHECK_LIB(pthreads, cma_open)
1967
1968 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1969 ## HAVE_LIBPTHREADS. That was not defined earlier in configure when
1970 ## the system file was sourced. Hence the value of LIBS_SYSTEM
1971 ## added to LIBS in configure would never contain the pthreads part,
1972 ## but the value used in Makefiles might. FIXME?
1973 ##
1974 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1975 ## be harmless on older versions of X where it happens to exist.
1976 test "$opsys" = "aix4-2" && \
1977 test $ac_cv_lib_pthreads_cma_open = yes && \
1978 LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1979
1980 dnl Check for need for bigtoc support on IBM AIX
1981
1982 case ${host_os} in
1983 aix*)
1984 AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1985 case $GCC in
1986 yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1987 *) gdb_cv_bigtoc=-bbigtoc ;;
1988 esac
1989
1990 LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1991 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1992 ])
1993 ;;
1994 esac
1995
1996 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1997 # used for the tests that follow. We set them back to REAL_CFLAGS and
1998 # REAL_CPPFLAGS later on.
1999
2000 REAL_CFLAGS="$CFLAGS"
2001 REAL_CPPFLAGS="$CPPFLAGS"
2002
2003 if test "${HAVE_X11}" = "yes"; then
2004 DEFS="$C_SWITCH_X_SITE $DEFS"
2005 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2006 LIBS="-lX11 $LIBS"
2007 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2008 CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2009
2010 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2011 # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2012 # but it's more convenient here to set LD_RUN_PATH since this
2013 # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2014 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2015 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2016 export LD_RUN_PATH
2017 fi
2018
2019 if test "${opsys}" = "gnu-linux"; then
2020 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2021 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2022 [[XOpenDisplay ("foo");]])],
2023 [xgnu_linux_first_failure=no],
2024 [xgnu_linux_first_failure=yes])
2025 if test "${xgnu_linux_first_failure}" = "yes"; then
2026 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
2027 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
2028 OLD_CPPFLAGS="$CPPFLAGS"
2029 OLD_LIBS="$LIBS"
2030 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2031 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2032 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2033 LIBS="$LIBS -b i486-linuxaout"
2034 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2035 [[XOpenDisplay ("foo");]])],
2036 [xgnu_linux_second_failure=no],
2037 [xgnu_linux_second_failure=yes])
2038 if test "${xgnu_linux_second_failure}" = "yes"; then
2039 # If we get the same failure with -b, there is no use adding -b.
2040 # So take it out. This plays safe.
2041 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
2042 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
2043 CPPFLAGS="$OLD_CPPFLAGS"
2044 LIBS="$OLD_LIBS"
2045 AC_MSG_RESULT(no)
2046 else
2047 AC_MSG_RESULT(yes)
2048 fi
2049 else
2050 AC_MSG_RESULT(no)
2051 fi
2052 fi
2053
2054 # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2055 # header files included from there.
2056 AC_MSG_CHECKING(for Xkb)
2057 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2058 #include <X11/XKBlib.h>]],
2059 [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2060 emacs_xkb=yes, emacs_xkb=no)
2061 AC_MSG_RESULT($emacs_xkb)
2062 if test $emacs_xkb = yes; then
2063 AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2064 fi
2065
2066 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2067 XScreenNumberOfScreen)
2068 fi
2069
2070 if test "${window_system}" = "x11"; then
2071 AC_MSG_CHECKING(X11 version 6)
2072 AC_CACHE_VAL(emacs_cv_x11_version_6,
2073 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2074 [[#if XlibSpecificationRelease < 6
2075 fail;
2076 #endif
2077 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2078 if test $emacs_cv_x11_version_6 = yes; then
2079 AC_MSG_RESULT(6 or newer)
2080 AC_DEFINE(HAVE_X11R6, 1,
2081 [Define to 1 if you have the X11R6 or newer version of Xlib.])
2082 AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2083 ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2084 ## XIM support.
2085 case "$opsys" in
2086 sol2-*) : ;;
2087 *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2088 [Define if you have usable X11R6-style XIM support.])
2089 ;;
2090 esac
2091 else
2092 AC_MSG_RESULT(before 6)
2093 fi
2094 fi
2095
2096
2097 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2098 HAVE_RSVG=no
2099 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2100 if test "${with_rsvg}" != "no"; then
2101 RSVG_REQUIRED=2.11.0
2102 RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2103
2104 PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
2105 AC_SUBST(RSVG_CFLAGS)
2106 AC_SUBST(RSVG_LIBS)
2107
2108 if test $HAVE_RSVG = yes; then
2109 AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2110 CFLAGS="$CFLAGS $RSVG_CFLAGS"
2111 LIBS="$RSVG_LIBS $LIBS"
2112 fi
2113 fi
2114 fi
2115
2116 HAVE_IMAGEMAGICK=no
2117 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
2118 if test "${with_imagemagick}" != "no"; then
2119 ## 6.2.8 is the earliest version known to work, but earlier versions
2120 ## might work - let us know if you find one.
2121 ## 6.0.7 does not work. See bug#7955.
2122 ## 6.8.2 makes Emacs crash; see Bug#13867.
2123 IMAGEMAGICK_MODULE="Wand >= 6.2.8 Wand != 6.8.2"
2124 PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
2125 AC_SUBST(IMAGEMAGICK_CFLAGS)
2126 AC_SUBST(IMAGEMAGICK_LIBS)
2127
2128 if test $HAVE_IMAGEMAGICK = yes; then
2129 AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2130 CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2131 LIBS="$IMAGEMAGICK_LIBS $LIBS"
2132 AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2133 fi
2134 fi
2135 fi
2136
2137
2138 HAVE_GTK=no
2139 GTK_OBJ=
2140 gtk_term_header=$term_header
2141 check_gtk2=no
2142 gtk3_pkg_errors=
2143 if test "${opsys}" != "mingw32"; then
2144 if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2145 GLIB_REQUIRED=2.28
2146 GTK_REQUIRED=3.0
2147 GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2148
2149 dnl Checks for libraries.
2150 PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2151 if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2152 AC_MSG_ERROR($GTK_PKG_ERRORS)
2153 fi
2154 if test "$pkg_check_gtk" = "yes"; then
2155 AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2156 GTK_OBJ=emacsgtkfixed.o
2157 gtk_term_header=gtkutil.h
2158 USE_GTK_TOOLKIT="GTK3"
2159 if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2160 GTK_CFLAGS="$GTK_CFLAGS -DGDK_DISABLE_DEPRECATION_WARNINGS"
2161 GTK_CFLAGS="$GTK_CFLAGS -DGLIB_DISABLE_DEPRECATION_WARNINGS"
2162 fi
2163 else
2164 check_gtk2=yes
2165 gtk3_pkg_errors="$GTK_PKG_ERRORS "
2166 fi
2167 fi
2168
2169 if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2170 GLIB_REQUIRED=2.10
2171 GTK_REQUIRED=2.10
2172 GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2173
2174 dnl Checks for libraries.
2175 PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2176 if test "$pkg_check_gtk" = "no" &&
2177 { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2178 then
2179 AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2180 fi
2181 test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2182 fi
2183 fi
2184
2185 if test x"$pkg_check_gtk" = xyes; then
2186
2187 AC_SUBST(GTK_CFLAGS)
2188 AC_SUBST(GTK_LIBS)
2189 C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2190 CFLAGS="$CFLAGS $GTK_CFLAGS"
2191 LIBS="$GTK_LIBS $LIBS"
2192 dnl Try to compile a simple GTK program.
2193 AC_MSG_CHECKING([whether GTK compiles])
2194 GTK_COMPILES=no
2195 AC_LINK_IFELSE(
2196 [AC_LANG_PROGRAM(
2197 [[/* Check the Gtk and Glib APIs. */
2198 #include <gtk/gtk.h>
2199 #include <glib-object.h>
2200 static void
2201 callback (GObject *go, GParamSpec *spec, gpointer user_data)
2202 {}
2203 ]],
2204 [[
2205 GtkSettings *gs = 0;
2206 /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2207 strict C prohibits this. Use gtk_main_iteration to test that the
2208 libraries are there. */
2209 if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2210 0, 0, 0, G_CALLBACK (callback), 0))
2211 gtk_main_iteration ();
2212 ]])],
2213 [GTK_COMPILES=yes])
2214 AC_MSG_RESULT([$GTK_COMPILES])
2215 if test "${GTK_COMPILES}" != "yes"; then
2216 GTK_OBJ=
2217 if test "$USE_X_TOOLKIT" != "maybe"; then
2218 AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log. Maybe some x11-devel files missing?]);
2219 fi
2220 else
2221 HAVE_GTK=yes
2222 AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2223 GTK_OBJ="gtkutil.o $GTK_OBJ"
2224 term_header=$gtk_term_header
2225 USE_X_TOOLKIT=none
2226 if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2227 :
2228 else
2229 AC_MSG_WARN([[Your version of Gtk+ will have problems with
2230 closing open displays. This is no problem if you just use
2231 one display, but if you use more than one and close one of them
2232 Emacs may crash.]])
2233 sleep 3
2234 fi
2235 fi
2236
2237 fi
2238 AC_SUBST(GTK_OBJ)
2239
2240
2241 if test "${HAVE_GTK}" = "yes"; then
2242
2243 dnl GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2244 dnl a lot if #ifdef:s, say we have toolkit scrollbars.
2245 if test "$with_toolkit_scroll_bars" != no; then
2246 with_toolkit_scroll_bars=yes
2247 fi
2248
2249 dnl Check if we have the old file selection dialog declared and
2250 dnl in the link library. In 2.x it may be in the library,
2251 dnl but not declared if deprecated featured has been selected out.
2252 dnl AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2253 HAVE_GTK_FILE_SELECTION=no
2254 AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2255 HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2256 #include <gtk/gtk.h>])
2257 if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2258 AC_CHECK_FUNCS(gtk_file_selection_new)
2259 fi
2260
2261 dnl Same as above for gtk_handle_box.
2262 HAVE_GTK_HANDLE_BOX=no
2263 AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2264 HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2265 #include <gtk/gtk.h>])
2266 if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2267 AC_CHECK_FUNCS(gtk_handle_box_new)
2268 fi
2269
2270 dnl Same as above for gtk_tearoff_menu_item.
2271 HAVE_GTK_TEAROFF_MENU_ITEM=no
2272 AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2273 HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2274 #include <gtk/gtk.h>])
2275 if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2276 AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2277 fi
2278
2279 dnl Check for functions introduced in 2.14 and later.
2280 AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2281 gtk_dialog_get_action_area gtk_widget_get_sensitive \
2282 gtk_widget_get_mapped gtk_adjustment_get_page_size \
2283 gtk_orientable_set_orientation \
2284 gtk_window_set_has_resize_grip)
2285
2286 term_header=gtkutil.h
2287 fi
2288
2289 dnl D-Bus has been tested under GNU/Linux only. Must be adapted for
2290 dnl other platforms.
2291 HAVE_DBUS=no
2292 DBUS_OBJ=
2293 if test "${with_dbus}" = "yes"; then
2294 PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2295 if test "$HAVE_DBUS" = yes; then
2296 LIBS="$LIBS $DBUS_LIBS"
2297 AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2298 dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2299 dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2300 dnl D-Bus 1.5.12.
2301 AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2302 dbus_type_is_valid \
2303 dbus_validate_bus_name \
2304 dbus_validate_path \
2305 dbus_validate_interface \
2306 dbus_validate_member)
2307 DBUS_OBJ=dbusbind.o
2308 fi
2309 fi
2310 AC_SUBST(DBUS_OBJ)
2311
2312 dnl GSettings has been tested under GNU/Linux only.
2313 HAVE_GSETTINGS=no
2314 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2315 PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2316 if test "$HAVE_GSETTINGS" = "yes"; then
2317 AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2318 SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2319 SETTINGS_LIBS="$GSETTINGS_LIBS"
2320 fi
2321 fi
2322
2323 dnl GConf has been tested under GNU/Linux only.
2324 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2325 HAVE_GCONF=no
2326 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2327 PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2328 if test "$HAVE_GCONF" = yes; then
2329 AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2330 dnl Newer GConf doesn't link with g_objects, so this is not defined.
2331 SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2332 SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2333 fi
2334 fi
2335
2336 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2337 PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2338 if test "$HAVE_GOBJECT" = "yes"; then
2339 SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2340 SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2341 fi
2342 SAVE_CFLAGS="$CFLAGS"
2343 SAVE_LIBS="$LIBS"
2344 CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2345 LIBS="$SETTINGS_LIBS $LIBS"
2346 AC_CHECK_FUNCS([g_type_init])
2347 CFLAGS="$SAVE_CFLAGS"
2348 LIBS="$SAVE_LIBS"
2349 fi
2350 AC_SUBST(SETTINGS_CFLAGS)
2351 AC_SUBST(SETTINGS_LIBS)
2352
2353
2354 dnl SELinux is available for GNU/Linux only.
2355 HAVE_LIBSELINUX=no
2356 LIBSELINUX_LIBS=
2357 if test "${with_selinux}" = "yes"; then
2358 AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2359 if test "$HAVE_LIBSELINUX" = yes; then
2360 AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2361 LIBSELINUX_LIBS=-lselinux
2362 fi
2363 fi
2364 AC_SUBST(LIBSELINUX_LIBS)
2365
2366 HAVE_GNUTLS=no
2367 if test "${with_gnutls}" = "yes" ; then
2368 PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2369 if test "${HAVE_GNUTLS}" = "yes"; then
2370 AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2371 fi
2372
2373 # Windows loads GnuTLS dynamically
2374 if test "${opsys}" = "mingw32"; then
2375 LIBGNUTLS_LIBS=
2376 else
2377 CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2378 LIBS="$LIBGNUTLS_LIBS $LIBS"
2379 fi
2380 fi
2381
2382 AC_SUBST(LIBGNUTLS_LIBS)
2383 AC_SUBST(LIBGNUTLS_CFLAGS)
2384
2385 NOTIFY_OBJ=
2386 NOTIFY_SUMMARY=no
2387
2388 dnl FIXME? Don't auto-detect on NS, but do allow someone to specify
2389 dnl a particular library. This doesn't make much sense?
2390 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2391 with_file_notification=no
2392 fi
2393
2394 dnl MS Windows native file monitor is available for mingw32 only.
2395 case $with_file_notification,$opsys in
2396 w32,* | yes,mingw32)
2397 AC_CHECK_HEADER(windows.h)
2398 if test "$ac_cv_header_windows_h" = yes ; then
2399 AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2400 NOTIFY_OBJ=w32notify.o
2401 NOTIFY_SUMMARY="yes (w32)"
2402 fi ;;
2403 esac
2404
2405 dnl g_file_monitor exists since glib 2.18. G_FILE_MONITOR_EVENT_MOVED
2406 dnl has been added in glib 2.24. It has been tested under
2407 dnl GNU/Linux only. We take precedence over inotify, but this makes
2408 dnl only sense when glib has been compiled with inotify support. How
2409 dnl to check?
2410 case $with_file_notification,$NOTIFY_OBJ in
2411 gfile, | yes,)
2412 PKG_CHECK_MODULES(GFILENOTIFY, gio-2.0 >= 2.24, HAVE_GFILENOTIFY=yes, HAVE_GFILENOTIFY=no)
2413 if test "$HAVE_GFILENOTIFY" = "yes"; then
2414 AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2415 NOTIFY_OBJ=gfilenotify.o
2416 NOTIFY_SUMMARY="yes -lgio (gfile)"
2417 fi ;;
2418 esac
2419
2420 dnl inotify is only available on GNU/Linux.
2421 case $with_file_notification,$NOTIFY_OBJ in
2422 inotify, | yes,)
2423 AC_CHECK_HEADER(sys/inotify.h)
2424 if test "$ac_cv_header_sys_inotify_h" = yes ; then
2425 AC_CHECK_FUNC(inotify_init1)
2426 if test "$ac_cv_func_inotify_init1" = yes; then
2427 AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2428 NOTIFY_OBJ=inotify.o
2429 NOTIFY_SUMMARY="yes -lglibc (inotify)"
2430 fi
2431 fi ;;
2432 esac
2433
2434 case $with_file_notification,$NOTIFY_OBJ in
2435 yes,* | no,* | *,?*) ;;
2436 *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;;
2437 esac
2438
2439 if test -n "$NOTIFY_OBJ"; then
2440 AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2441 fi
2442 AC_SUBST(NOTIFY_OBJ)
2443 AC_SUBST(GFILENOTIFY_CFLAGS)
2444 AC_SUBST(GFILENOTIFY_LIBS)
2445
2446 dnl Do not put whitespace before the #include statements below.
2447 dnl Older compilers (eg sunos4 cc) choke on it.
2448 HAVE_XAW3D=no
2449 LUCID_LIBW=
2450 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2451 if test "$with_xaw3d" != no; then
2452 AC_CACHE_VAL(emacs_cv_xaw3d,
2453 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2454 #include <X11/Intrinsic.h>
2455 #include <X11/Xaw3d/Simple.h>]],
2456 [[]])],
2457 [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2458 emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2459 emacs_cv_xaw3d=no)])
2460 else
2461 emacs_cv_xaw3d=no
2462 fi
2463 if test $emacs_cv_xaw3d = yes; then
2464 AC_MSG_CHECKING(for xaw3d)
2465 AC_MSG_RESULT([yes; using Lucid toolkit])
2466 USE_X_TOOLKIT=LUCID
2467 HAVE_XAW3D=yes
2468 LUCID_LIBW=-lXaw3d
2469 AC_DEFINE(HAVE_XAW3D, 1,
2470 [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2471 else
2472 AC_MSG_CHECKING(for xaw3d)
2473 AC_MSG_RESULT(no)
2474 AC_MSG_CHECKING(for libXaw)
2475 AC_CACHE_VAL(emacs_cv_xaw,
2476 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2477 #include <X11/Intrinsic.h>
2478 #include <X11/Xaw/Simple.h>]],
2479 [[]])],
2480 emacs_cv_xaw=yes,
2481 emacs_cv_xaw=no)])
2482 if test $emacs_cv_xaw = yes; then
2483 AC_MSG_RESULT([yes; using Lucid toolkit])
2484 USE_X_TOOLKIT=LUCID
2485 LUCID_LIBW=-lXaw
2486 elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2487 AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2488 else
2489 AC_MSG_ERROR([No X toolkit could be found.
2490 If you are sure you want Emacs compiled without an X toolkit, pass
2491 --with-x-toolkit=no
2492 to configure. Otherwise, install the development libraries for the toolkit
2493 that you want to use (e.g. Gtk+) and re-run configure.])
2494 fi
2495 fi
2496 fi
2497
2498 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2499
2500 LIBXTR6=
2501 if test "${USE_X_TOOLKIT}" != "none"; then
2502 AC_MSG_CHECKING(X11 toolkit version)
2503 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2504 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2505 [[#if XtSpecificationRelease < 6
2506 fail;
2507 #endif
2508 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2509 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2510 if test $emacs_cv_x11_toolkit_version_6 = yes; then
2511 AC_MSG_RESULT(6 or newer)
2512 AC_DEFINE(HAVE_X11XTR6, 1,
2513 [Define to 1 if you have the X11R6 or newer version of Xt.])
2514 LIBXTR6="-lSM -lICE"
2515 case "$opsys" in
2516 ## Use libw.a along with X11R6 Xt.
2517 unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2518 esac
2519 else
2520 AC_MSG_RESULT(before 6)
2521 fi
2522
2523 dnl If using toolkit, check whether libXmu.a exists.
2524 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2525 OLDLIBS="$LIBS"
2526 if test x$HAVE_X11XTR6 = xyes; then
2527 LIBS="-lXt -lSM -lICE $LIBS"
2528 else
2529 LIBS="-lXt $LIBS"
2530 fi
2531 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2532 test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2533 dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2534 fi
2535 AC_SUBST(LIBXTR6)
2536
2537 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2538 dnl Why not just test for libxmu in the normal way?
2539 LIBXMU=-lXmu
2540 case $opsys in
2541 ## These systems don't supply Xmu.
2542 hpux* | aix4-2 )
2543 test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2544 ;;
2545 mingw32 )
2546 LIBXMU=
2547 ;;
2548 esac
2549 AC_SUBST(LIBXMU)
2550
2551 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2552 if test "${HAVE_X11}" = "yes"; then
2553 if test "${USE_X_TOOLKIT}" != "none"; then
2554 AC_CHECK_LIB(Xext, XShapeQueryExtension)
2555 fi
2556 fi
2557
2558 LIBXP=
2559 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2560 # OpenMotif may be installed in such a way on some GNU/Linux systems.
2561 if test -d /usr/include/openmotif; then
2562 CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2563 emacs_cv_openmotif=yes
2564 case "$canonical" in
2565 x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2566 test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2567 ;;
2568 *)
2569 test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2570 esac
2571 else
2572 emacs_cv_openmotif=no
2573 fi
2574 AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2575 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2576 [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2577 int x = 5;
2578 #else
2579 Motif version prior to 2.1.
2580 #endif]])],
2581 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2582 if test $emacs_cv_motif_version_2_1 = yes; then
2583 AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2584 if test x$emacs_cv_openmotif = xyes; then
2585 REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2586 fi
2587 else
2588 AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2589 # We put this in CFLAGS temporarily to precede other -I options
2590 # that might be in CFLAGS temporarily.
2591 # We put this in CPPFLAGS where it precedes the other -I options.
2592 OLD_CPPFLAGS=$CPPFLAGS
2593 OLD_CFLAGS=$CFLAGS
2594 CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2595 CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2596 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2597 [[int x = 5;]])],
2598 emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2599 if test $emacs_cv_lesstif = yes; then
2600 # Make sure this -I option remains in CPPFLAGS after it is set
2601 # back to REAL_CPPFLAGS.
2602 # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2603 # have those other -I options anyway. Ultimately, having this
2604 # directory ultimately in CPPFLAGS will be enough.
2605 REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2606 LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2607 else
2608 CFLAGS=$OLD_CFLAGS
2609 CPPFLAGS=$OLD_CPPFLAGS
2610 fi
2611 fi
2612 AC_CHECK_HEADER([Xm/BulletinB.h], [],
2613 [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2614 fi
2615
2616 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2617 dnl using Motif or Xaw3d is available, and unless
2618 dnl --with-toolkit-scroll-bars=no was specified.
2619
2620 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2621 [Define to 1 if we should use toolkit scroll bars.])dnl
2622 USE_TOOLKIT_SCROLL_BARS=no
2623 if test "${with_toolkit_scroll_bars}" != "no"; then
2624 if test "${USE_X_TOOLKIT}" != "none"; then
2625 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2626 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2627 HAVE_XAW3D=no
2628 USE_TOOLKIT_SCROLL_BARS=yes
2629 elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2630 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2631 USE_TOOLKIT_SCROLL_BARS=yes
2632 fi
2633 elif test "${HAVE_GTK}" = "yes"; then
2634 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2635 USE_TOOLKIT_SCROLL_BARS=yes
2636 elif test "${HAVE_NS}" = "yes"; then
2637 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2638 USE_TOOLKIT_SCROLL_BARS=yes
2639 elif test "${HAVE_W32}" = "yes"; then
2640 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2641 USE_TOOLKIT_SCROLL_BARS=yes
2642 fi
2643 fi
2644
2645 dnl See if XIM is available.
2646 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2647 #include <X11/Xlib.h>
2648 #include <X11/Xresource.h>]],
2649 [[XIMProc callback;]])],
2650 [HAVE_XIM=yes
2651 AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2652 HAVE_XIM=no)
2653
2654 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2655
2656 if test "${with_xim}" != "no"; then
2657 AC_DEFINE(USE_XIM, 1,
2658 [Define to 1 if we should use XIM, if it is available.])
2659 fi
2660
2661
2662 if test "${HAVE_XIM}" != "no"; then
2663 late_CFLAGS=$CFLAGS
2664 if test "$GCC" = yes; then
2665 CFLAGS="$CFLAGS --pedantic-errors"
2666 fi
2667 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2668 #include <X11/Xlib.h>
2669 #include <X11/Xresource.h>]],
2670 [[Display *display;
2671 XrmDatabase db;
2672 char *res_name;
2673 char *res_class;
2674 XIMProc callback;
2675 XPointer *client_data;
2676 #ifndef __GNUC__
2677 /* If we're not using GCC, it's probably not XFree86, and this is
2678 probably right, but we can't use something like --pedantic-errors. */
2679 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2680 char*, XIMProc, XPointer*);
2681 #endif
2682 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2683 client_data);]])],
2684 [emacs_cv_arg6_star=yes])
2685 AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2686 [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2687 either XPointer or XPointer*.])dnl
2688 if test "$emacs_cv_arg6_star" = yes; then
2689 AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2690 else
2691 AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2692 fi
2693 CFLAGS=$late_CFLAGS
2694 fi
2695
2696 ### Start of font-backend (under any platform) section.
2697 # (nothing here yet -- this is a placeholder)
2698 ### End of font-backend (under any platform) section.
2699
2700 ### Start of font-backend (under X11) section.
2701 if test "${HAVE_X11}" = "yes"; then
2702 PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2703
2704 ## Use -lXft if available, unless `--with-xft=no'.
2705 HAVE_XFT=maybe
2706 if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2707 with_xft="no";
2708 fi
2709 if test "x${with_xft}" != "xno"; then
2710
2711 PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2712 ## Because xftfont.c uses XRenderQueryExtension, we also
2713 ## need to link to -lXrender.
2714 HAVE_XRENDER=no
2715 AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2716 if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2717 OLD_CPPFLAGS="$CPPFLAGS"
2718 OLD_CFLAGS="$CFLAGS"
2719 OLD_LIBS="$LIBS"
2720 CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2721 CFLAGS="$CFLAGS $XFT_CFLAGS"
2722 XFT_LIBS="-lXrender $XFT_LIBS"
2723 LIBS="$XFT_LIBS $LIBS"
2724 AC_CHECK_HEADER(X11/Xft/Xft.h,
2725 AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2726 [[#include <X11/X.h>]])
2727
2728 if test "${HAVE_XFT}" = "yes"; then
2729 AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2730 AC_SUBST(XFT_LIBS)
2731 C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2732 else
2733 CPPFLAGS="$OLD_CPPFLAGS"
2734 CFLAGS="$OLD_CFLAGS"
2735 LIBS="$OLD_LIBS"
2736 fi # "${HAVE_XFT}" = "yes"
2737 fi # "$HAVE_XFT" != no
2738 fi # "x${with_xft}" != "xno"
2739
2740 ## We used to allow building with FreeType and without Xft.
2741 ## However, the ftx font backend driver is not in good shape.
2742 if test "$HAVE_XFT" != "yes"; then
2743 dnl For the "Does Emacs use" message at the end.
2744 HAVE_XFT=no
2745 HAVE_FREETYPE=no
2746 else
2747 dnl Strict linkers fail with
2748 dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2749 dnl if -lfreetype is not specified.
2750 dnl The following is needed to set FREETYPE_LIBS.
2751 PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2752 HAVE_FREETYPE=no)
2753
2754 test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2755 fi
2756
2757 HAVE_LIBOTF=no
2758 if test "${HAVE_FREETYPE}" = "yes"; then
2759 AC_DEFINE(HAVE_FREETYPE, 1,
2760 [Define to 1 if using the freetype and fontconfig libraries.])
2761 if test "${with_libotf}" != "no"; then
2762 PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2763 HAVE_LIBOTF=no)
2764 if test "$HAVE_LIBOTF" = "yes"; then
2765 AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2766 AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2767 HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2768 HAVE_OTF_GET_VARIATION_GLYPHS=no)
2769 if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2770 AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2771 [Define to 1 if libotf has OTF_get_variation_glyphs.])
2772 fi
2773 fi
2774 fi
2775 dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2776 dnl Does the new font backend require it, or can it work without it?
2777 fi
2778
2779 HAVE_M17N_FLT=no
2780 if test "${HAVE_LIBOTF}" = yes; then
2781 if test "${with_m17n_flt}" != "no"; then
2782 PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2783 if test "$HAVE_M17N_FLT" = "yes"; then
2784 AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2785 fi
2786 fi
2787 fi
2788 else
2789 HAVE_XFT=no
2790 HAVE_FREETYPE=no
2791 HAVE_LIBOTF=no
2792 HAVE_M17N_FLT=no
2793 fi
2794
2795 ### End of font-backend (under X11) section.
2796
2797 AC_SUBST(FREETYPE_CFLAGS)
2798 AC_SUBST(FREETYPE_LIBS)
2799 AC_SUBST(FONTCONFIG_CFLAGS)
2800 AC_SUBST(FONTCONFIG_LIBS)
2801 AC_SUBST(LIBOTF_CFLAGS)
2802 AC_SUBST(LIBOTF_LIBS)
2803 AC_SUBST(M17N_FLT_CFLAGS)
2804 AC_SUBST(M17N_FLT_LIBS)
2805
2806 ### Use -lXpm if available, unless `--with-xpm=no'.
2807 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
2808 HAVE_XPM=no
2809 LIBXPM=
2810 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
2811 if test "${with_xpm}" != "no"; then
2812 SAVE_CPPFLAGS="$CPPFLAGS"
2813 SAVE_LDFLAGS="$LDFLAGS"
2814 CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2815 LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2816 AC_CHECK_HEADER(X11/xpm.h,
2817 [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2818 if test "${HAVE_XPM}" = "yes"; then
2819 AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2820 AC_EGREP_CPP(no_return_alloc_pixels,
2821 [#include "X11/xpm.h"
2822 #ifndef XpmReturnAllocPixels
2823 no_return_alloc_pixels
2824 #endif
2825 ], HAVE_XPM=no, HAVE_XPM=yes)
2826
2827 if test "${HAVE_XPM}" = "yes"; then
2828 REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2829 AC_MSG_RESULT(yes)
2830 else
2831 AC_MSG_RESULT(no)
2832 CPPFLAGS="$SAVE_CPPFLAGS"
2833 LDFLAGS="$SAVE_LDFLAGS"
2834 fi
2835 fi
2836 fi
2837
2838 if test "${HAVE_XPM}" = "yes"; then
2839 AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2840 LIBXPM=-lXpm
2841 fi
2842 fi
2843
2844 if test "${HAVE_X11}" = "yes"; then
2845 if test "${with_xpm}" != "no"; then
2846 AC_CHECK_HEADER(X11/xpm.h,
2847 [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2848 if test "${HAVE_XPM}" = "yes"; then
2849 AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2850 AC_EGREP_CPP(no_return_alloc_pixels,
2851 [#include "X11/xpm.h"
2852 #ifndef XpmReturnAllocPixels
2853 no_return_alloc_pixels
2854 #endif
2855 ], HAVE_XPM=no, HAVE_XPM=yes)
2856
2857 if test "${HAVE_XPM}" = "yes"; then
2858 AC_MSG_RESULT(yes)
2859 else
2860 AC_MSG_RESULT(no)
2861 fi
2862 fi
2863 fi
2864
2865 if test "${HAVE_XPM}" = "yes"; then
2866 AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2867 LIBXPM=-lXpm
2868 fi
2869 fi
2870
2871 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
2872 ### slightly different requirements wrt image libraries (it doesn't
2873 ### use -lXpm because it loads the xpm shared library dynamically at
2874 ### run time).
2875 if test "${opsys}" = "mingw32"; then
2876 if test "${with_xpm}" != "no"; then
2877 AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
2878 #define FOR_MSW 1])
2879 fi
2880
2881 if test "${HAVE_XPM}" = "yes"; then
2882 AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2883 fi
2884 fi
2885
2886 AC_SUBST(LIBXPM)
2887
2888 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2889 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
2890 HAVE_JPEG=no
2891 LIBJPEG=
2892 if test "${opsys}" = "mingw32"; then
2893 if test "${with_jpeg}" != "no"; then
2894 dnl Checking for jpeglib.h can lose because of a redefinition of
2895 dnl HAVE_STDLIB_H.
2896 AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
2897 fi
2898 AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2899 if test "${HAVE_JPEG}" = "yes"; then
2900 AC_DEFINE(HAVE_JPEG)
2901 AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2902 [#include <jpeglib.h>
2903 version=JPEG_LIB_VERSION
2904 ],
2905 [AC_DEFINE(HAVE_JPEG)],
2906 [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2907 HAVE_JPEG=no])
2908 fi
2909 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2910 if test "${with_jpeg}" != "no"; then
2911 dnl Checking for jpeglib.h can lose because of a redefinition of
2912 dnl HAVE_STDLIB_H.
2913 AC_CHECK_HEADER(jerror.h,
2914 [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2915 fi
2916
2917 AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2918 if test "${HAVE_JPEG}" = "yes"; then
2919 AC_DEFINE(HAVE_JPEG)
2920 AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2921 [#include <jpeglib.h>
2922 version=JPEG_LIB_VERSION
2923 ],
2924 [AC_DEFINE(HAVE_JPEG)],
2925 [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2926 HAVE_JPEG=no])
2927 fi
2928 if test "${HAVE_JPEG}" = "yes"; then
2929 LIBJPEG=-ljpeg
2930 fi
2931 fi
2932 AC_SUBST(LIBJPEG)
2933
2934 ### Use -lpng if available, unless `--with-png=no'.
2935 ### mingw32 doesn't use -lpng, since it loads the library dynamically.
2936 HAVE_PNG=no
2937 LIBPNG=
2938 if test "${opsys}" = "mingw32"; then
2939 if test "${with_png}" != "no"; then
2940 AC_CHECK_HEADER(png.h, HAVE_PNG=yes, HAVE_PNG=no)
2941 fi
2942 if test "${HAVE_PNG}" = "yes"; then
2943 AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2944
2945 AC_CHECK_DECL(png_longjmp,
2946 [],
2947 [AC_DEFINE(PNG_DEPSTRUCT, [],
2948 [Define to empty to suppress deprecation warnings when building
2949 with --enable-gcc-warnings and with libpng versions before 1.5,
2950 which lack png_longjmp.])],
2951 [[#ifdef HAVE_LIBPNG_PNG_H
2952 # include <libpng/png.h>
2953 #else
2954 # include <png.h>
2955 #endif
2956 ]])
2957 fi
2958 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2959 if test "${with_png}" != "no"; then
2960 # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2961 # in /usr/include/libpng.
2962 AC_CHECK_HEADERS(png.h libpng/png.h, break)
2963 if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2964 AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2965 fi
2966 fi
2967
2968 if test "${HAVE_PNG}" = "yes"; then
2969 AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2970 LIBPNG="-lpng -lz -lm"
2971
2972 AC_CHECK_DECL(png_longjmp,
2973 [],
2974 [AC_DEFINE(PNG_DEPSTRUCT, [],
2975 [Define to empty to suppress deprecation warnings when building
2976 with --enable-gcc-warnings and with libpng versions before 1.5,
2977 which lack png_longjmp.])],
2978 [[#ifdef HAVE_LIBPNG_PNG_H
2979 # include <libpng/png.h>
2980 #else
2981 # include <png.h>
2982 #endif
2983 ]])
2984 fi
2985 fi
2986 AC_SUBST(LIBPNG)
2987
2988 HAVE_ZLIB=no
2989 LIBZ=
2990 if test "${with_zlib}" != "no"; then
2991 OLIBS=$LIBS
2992 AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
2993 LIBS=$OLIBS
2994 case $ac_cv_search_inflateEnd in
2995 -*) LIBZ=$ac_cv_search_inflateEnd ;;
2996 esac
2997 fi
2998 if test "${HAVE_ZLIB}" = "yes"; then
2999 AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3000 ### mingw32 doesn't use -lz, since it loads the library dynamically.
3001 if test "${opsys}" = "mingw32"; then
3002 LIBZ=
3003 fi
3004 fi
3005 AC_SUBST(LIBZ)
3006
3007
3008 ### Use -ltiff if available, unless `--with-tiff=no'.
3009 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3010 HAVE_TIFF=no
3011 LIBTIFF=
3012 if test "${opsys}" = "mingw32"; then
3013 if test "${with_tiff}" != "no"; then
3014 AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3015 fi
3016 if test "${HAVE_TIFF}" = "yes"; then
3017 AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3018 fi
3019 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3020 if test "${with_tiff}" != "no"; then
3021 AC_CHECK_HEADER(tiffio.h,
3022 [tifflibs="-lz -lm"
3023 # At least one tiff package requires the jpeg library.
3024 if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3025 AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3026 fi
3027
3028 if test "${HAVE_TIFF}" = "yes"; then
3029 AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3030 dnl FIXME -lz -lm, as per libpng?
3031 LIBTIFF=-ltiff
3032 fi
3033 fi
3034 AC_SUBST(LIBTIFF)
3035
3036 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
3037 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3038 HAVE_GIF=no
3039 LIBGIF=
3040 if test "${opsys}" = "mingw32"; then
3041 if test "${with_gif}" != "no"; then
3042 AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3043 fi
3044 if test "${HAVE_GIF}" = "yes"; then
3045 AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3046 fi
3047 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3048 || test "${HAVE_W32}" = "yes"; then
3049 AC_CHECK_HEADER(gif_lib.h,
3050 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3051 # Earlier versions can crash Emacs.
3052 [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
3053
3054 if test "$HAVE_GIF" = yes; then
3055 LIBGIF=-lgif
3056 elif test "$HAVE_GIF" = maybe; then
3057 # If gif_lib.h but no libgif, try libungif.
3058 AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3059 test "$HAVE_GIF" = yes && LIBGIF=-lungif
3060 fi
3061
3062 if test "${HAVE_GIF}" = "yes"; then
3063 AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3064 fi
3065 fi
3066 AC_SUBST(LIBGIF)
3067
3068 dnl Check for required libraries.
3069 if test "${HAVE_X11}" = "yes"; then
3070 MISSING=""
3071 WITH_NO=""
3072 test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3073 MISSING="libXpm" && WITH_NO="--with-xpm=no"
3074 test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3075 MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3076 test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3077 MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3078 test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3079 MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3080 test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3081 MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3082
3083 if test "X${MISSING}" != X; then
3084 AC_MSG_ERROR([The following required libraries were not found:
3085 $MISSING
3086 Maybe some development libraries/packages are missing?
3087 If you don't want to link with them give
3088 $WITH_NO
3089 as options to configure])
3090 fi
3091 fi
3092
3093 ### Use -lgpm if available, unless `--with-gpm=no'.
3094 HAVE_GPM=no
3095 LIBGPM=
3096 if test "${with_gpm}" != "no"; then
3097 AC_CHECK_HEADER(gpm.h,
3098 [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3099
3100 if test "${HAVE_GPM}" = "yes"; then
3101 AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3102 LIBGPM=-lgpm
3103 fi
3104 fi
3105 AC_SUBST(LIBGPM)
3106
3107 dnl Check for malloc/malloc.h on darwin
3108 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3109
3110 GNUSTEP_CFLAGS=
3111 ### Use NeXTstep API to implement GUI.
3112 if test "${HAVE_NS}" = "yes"; then
3113 AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3114 if test "${NS_IMPL_COCOA}" = "yes"; then
3115 AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3116 fi
3117 if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3118 AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3119 # See also .m.o rule in Makefile.in */
3120 # FIXME: are all these flags really needed? Document here why. */
3121 GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3122 ## Extra CFLAGS applied to src/*.m files.
3123 GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3124 fi
3125 # We also have mouse menus.
3126 HAVE_MENUS=yes
3127 OTHER_FILES=ns-app
3128 fi
3129
3130 if test "${HAVE_W32}" = "yes"; then
3131 HAVE_MENUS=yes
3132 fi
3133
3134 ### Use session management (-lSM -lICE) if available
3135 HAVE_X_SM=no
3136 LIBXSM=
3137 if test "${HAVE_X11}" = "yes"; then
3138 AC_CHECK_HEADER(X11/SM/SMlib.h,
3139 [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3140
3141 if test "${HAVE_X_SM}" = "yes"; then
3142 AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3143 LIBXSM="-lSM -lICE"
3144 case "$LIBS" in
3145 *-lSM*) ;;
3146 *) LIBS="$LIBXSM $LIBS" ;;
3147 esac
3148 fi
3149 fi
3150 AC_SUBST(LIBXSM)
3151
3152 ### Use XRandr (-lXrandr) if available
3153 HAVE_XRANDR=no
3154 if test "${HAVE_X11}" = "yes"; then
3155 XRANDR_REQUIRED=1.2.2
3156 XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3157 PKG_CHECK_MODULES(XRANDR, $XRANDR_MODULES, HAVE_XRANDR=yes, HAVE_XRANDR=no)
3158 if test $HAVE_XRANDR = no; then
3159 # Test old way in case pkg-config doesn't have it (older machines).
3160 AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3161 [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)])
3162 if test $HAVE_XRANDR = yes; then
3163 XRANDR_LIBS=-lXrandr
3164 AC_SUBST(XRANDR_LIBS)
3165 fi
3166 fi
3167 if test $HAVE_XRANDR = yes; then
3168 SAVE_CFLAGS="$CFLAGS"
3169 SAVE_LIBS="$LIBS"
3170 CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3171 LIBS="$XRANDR_LIBS $LIBS"
3172 AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3173 CFLAGS="$SAVE_CFLAGS"
3174 LIBS="$SAVE_LIBS"
3175
3176 AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3177 fi
3178 fi
3179
3180 ### Use Xinerama (-lXinerama) if available
3181 HAVE_XINERAMA=no
3182 if test "${HAVE_X11}" = "yes"; then
3183 XINERAMA_REQUIRED=1.0.2
3184 XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3185 PKG_CHECK_MODULES(XINERAMA, $XINERAMA_MODULES, HAVE_XINERAMA=yes,
3186 HAVE_XINERAMA=no)
3187 if test $HAVE_XINERAMA = no; then
3188 # Test old way in case pkg-config doesn't have it (older machines).
3189 AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3190 [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3191 if test $HAVE_XINERAMA = yes; then
3192 XINERAMA_LIBS=-lXinerama
3193 AC_SUBST(XINERAMA_LIBS)
3194 fi
3195 fi
3196 if test $HAVE_XINERAMA = yes; then
3197 AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3198 fi
3199 fi
3200
3201
3202 ### Use libxml (-lxml2) if available
3203 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3204 HAVE_LIBXML2=no
3205 if test "${with_xml2}" != "no"; then
3206 ### I'm not sure what the version number should be, so I just guessed.
3207 PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3208 # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3209 if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3210 SAVE_CPPFLAGS="$CPPFLAGS"
3211 CPPFLAGS="$CPPFLAGS -I/usr/include/libxml2"
3212 AC_CHECK_HEADER(libxml/HTMLparser.h,
3213 [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3214 [#include <libxml/HTMLparser.h>])])
3215 CPPFLAGS="$SAVE_CPPFLAGS"
3216 if test "${HAVE_LIBXML2}" = "yes"; then
3217 LIBXML2_LIBS="-lxml2"
3218 LIBXML2_CFLAGS="-I/usr/include/libxml2"
3219 fi
3220 fi
3221 if test "${HAVE_LIBXML2}" = "yes"; then
3222 if test "${opsys}" != "mingw32"; then
3223 LIBS="$LIBXML2_LIBS $LIBS"
3224 AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3225 else
3226 LIBXML2_LIBS=""
3227 fi
3228 if test "${HAVE_LIBXML2}" = "yes"; then
3229 AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3230 else
3231 LIBXML2_LIBS=""
3232 LIBXML2_CFLAGS=""
3233 fi
3234 fi
3235 fi
3236 AC_SUBST(LIBXML2_LIBS)
3237 AC_SUBST(LIBXML2_CFLAGS)
3238
3239 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3240 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3241 if test "${opsys}" = "mingw32"; then
3242 emacs_cv_netdb_declares_h_errno=yes
3243 fi
3244 AC_CACHE_CHECK(whether netdb declares h_errno,
3245 emacs_cv_netdb_declares_h_errno,
3246 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3247 [[return h_errno;]])],
3248 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3249 if test $emacs_cv_netdb_declares_h_errno = yes; then
3250 AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3251 fi
3252
3253 # sqrt and other floating-point functions such as fmod and frexp
3254 # are found in -lm on most systems, but mingw32 doesn't use -lm.
3255 if test "${opsys}" != "mingw32"; then
3256 AC_CHECK_LIB(m, sqrt)
3257 fi
3258
3259 # Check for mail-locking functions in a "mail" library. Probably this should
3260 # have the same check as for liblockfile below.
3261 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3262 if test $have_mail = yes; then
3263 LIBS_MAIL=-lmail
3264 LIBS="$LIBS_MAIL $LIBS"
3265 AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3266 else
3267 LIBS_MAIL=
3268 fi
3269 dnl Debian, at least:
3270 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3271 if test $have_lockfile = yes; then
3272 LIBS_MAIL=-llockfile
3273 LIBS="$LIBS_MAIL $LIBS"
3274 AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3275 else
3276 # If we have the shared liblockfile, assume we must use it for mail
3277 # locking (e.g. Debian). If we couldn't link against liblockfile
3278 # (no liblockfile.a installed), ensure that we don't need to.
3279 dnl This works for files generally, not just executables.
3280 dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf?
3281 AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3282 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3283 if test $ac_cv_prog_liblockfile = yes; then
3284 AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3285 This probably means that movemail could lose mail.
3286 There may be a `development' package to install containing liblockfile.])
3287 fi
3288 fi
3289 AC_CHECK_HEADERS_ONCE(maillock.h)
3290 AC_SUBST(LIBS_MAIL)
3291
3292 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3293 ## interlock access to the mail spool. The alternative is a lock file named
3294 ## /usr/spool/mail/$USER.lock.
3295 mail_lock=no
3296 case "$opsys" in
3297 aix4-2) mail_lock="lockf" ;;
3298
3299 gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3300
3301 ## On GNU/Linux systems, both methods are used by various mail programs.
3302 ## I assume most people are using newer mailers that have heard of flock.
3303 ## Change this if you need to.
3304 ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3305 ## configure gets the right answers, and that means *NOT* using flock.
3306 ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3307 ## for details.'' and then uses `#ifdef DEBIAN'. Unfortunately the
3308 ## Debian maintainer hasn't provided a clean fix for Emacs.
3309 ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3310 ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3311 ## correct logic. -- fx
3312 ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3313 ## liblockfile is a Free Software replacement for libmail, used on
3314 ## Debian systems and elsewhere. -rfr.
3315 gnu-*)
3316 mail_lock="flock"
3317 if test $have_mail = yes || test $have_lockfile = yes; then
3318 test $ac_cv_header_maillock_h = yes && mail_lock=no
3319 fi
3320 ;;
3321
3322 mingw32)
3323 mail_lock="none-needed" ;;
3324 esac
3325
3326 BLESSMAIL_TARGET=
3327 case "$mail_lock" in
3328 flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3329
3330 lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3331
3332 none-needed) ;;
3333
3334 *) BLESSMAIL_TARGET="need-blessmail" ;;
3335 esac
3336 AC_SUBST(BLESSMAIL_TARGET)
3337
3338
3339 AC_CHECK_FUNCS(accept4 gethostname \
3340 getrusage get_current_dir_name \
3341 lrand48 \
3342 select getpagesize setlocale \
3343 getrlimit setrlimit shutdown getaddrinfo \
3344 strsignal setitimer \
3345 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3346 gai_strerror getline getdelim sync \
3347 difftime posix_memalign \
3348 getpwent endpwent getgrent endgrent \
3349 touchlock \
3350 cfmakeraw cfsetspeed copysign __executable_start log2)
3351
3352 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
3353 ## has a broken `rint' in some library versions including math library
3354 ## version number A.09.05.
3355 ## You can fix the math library by installing patch number PHSS_4630.
3356 ## But we can fix it more reliably for Emacs by just not using rint.
3357 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
3358 case $opsys in
3359 hpux*) : ;;
3360 *) AC_CHECK_FUNCS(random rint) ;;
3361 esac
3362
3363 dnl Cannot use AC_CHECK_FUNCS
3364 AC_CACHE_CHECK([for __builtin_unwind_init],
3365 emacs_cv_func___builtin_unwind_init,
3366 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3367 emacs_cv_func___builtin_unwind_init=yes,
3368 emacs_cv_func___builtin_unwind_init=no)])
3369 if test $emacs_cv_func___builtin_unwind_init = yes; then
3370 AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3371 [Define to 1 if you have the `__builtin_unwind_init' function.])
3372 fi
3373
3374 AC_CHECK_HEADERS_ONCE(sys/un.h)
3375
3376 AC_FUNC_FSEEKO
3377
3378 # UNIX98 PTYs.
3379 AC_CHECK_FUNCS(grantpt)
3380
3381 # PTY-related GNU extensions.
3382 AC_CHECK_FUNCS(getpt posix_openpt)
3383
3384 # Check this now, so that we will NOT find the above functions in ncurses.
3385 # That is because we have not set up to link ncurses in lib-src.
3386 # It's better to believe a function is not available
3387 # than to expect to find it in ncurses.
3388 # Also we need tputs and friends to be able to build at all.
3389 AC_MSG_CHECKING([for library containing tputs])
3390 # Run a test program that contains a call to tputs, a call that is
3391 # never executed. This tests whether a pre-'main' dynamic linker
3392 # works with the library. It's too much trouble to actually call
3393 # tputs in the test program, due to portability hassles. When
3394 # cross-compiling, assume the test program will run if it links.
3395 AC_DEFUN([tputs_link_source], [
3396 AC_LANG_SOURCE(
3397 [[extern void tputs (const char *, int, int (*)(int));
3398 int main (int argc, char **argv)
3399 {
3400 if (argc == 10000)
3401 tputs (argv[0], 0, 0);
3402 return 0;
3403 }]])
3404 ])
3405 if test "${opsys}" = "mingw32"; then
3406 msg='none required'
3407 else
3408 # Maybe curses should be tried earlier?
3409 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3410 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3411 OLIBS=$LIBS
3412 if test -z "$tputs_library"; then
3413 LIBS_TERMCAP=
3414 msg='none required'
3415 else
3416 LIBS_TERMCAP=-l$tputs_library
3417 msg=$LIBS_TERMCAP
3418 LIBS="$LIBS_TERMCAP $LIBS"
3419 fi
3420 AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3421 [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3422 LIBS=$OLIBS
3423 if test "X$msg" != Xno; then
3424 break
3425 fi
3426 done
3427 fi
3428 AC_MSG_RESULT([$msg])
3429 if test "X$msg" = Xno; then
3430 AC_MSG_ERROR([The required function `tputs' was not found in any library.
3431 The following libraries were tried (in order):
3432 libtinfo, libncurses, libterminfo, libtermcap, libcurses
3433 Please try installing whichever of these libraries is most appropriate
3434 for your system, together with its header files.
3435 For example, a libncurses-dev(el) or similar package.])
3436 fi
3437
3438 ## Use termcap instead of terminfo?
3439 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3440 TERMINFO=yes
3441 ## FIXME? In the cases below where we unconditionally set
3442 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3443 ## if that was found above to have tputs.
3444 ## Should we use the gnu* logic everywhere?
3445 case "$opsys" in
3446 ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3447 ## The ncurses library has been moved out of the System framework in
3448 ## Mac OS X 10.2. So if configure detects it, set the command-line
3449 ## option to use it.
3450 darwin) LIBS_TERMCAP="-lncurses" ;;
3451
3452 gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3453
3454 freebsd)
3455 AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3456 AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3457 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3458 [[#if __FreeBSD_version < 400000
3459 fail;
3460 #endif
3461 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3462
3463 AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3464
3465 if test $emacs_cv_freebsd_terminfo = yes; then
3466 LIBS_TERMCAP="-lncurses"
3467 else
3468 TERMINFO=no
3469 LIBS_TERMCAP="-ltermcap"
3470 fi
3471 ;;
3472
3473 mingw32)
3474 TERMINFO=no
3475 LIBS_TERMCAP=
3476 ;;
3477
3478 netbsd)
3479 if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3480 TERMINFO=no
3481 LIBS_TERMCAP="-ltermcap"
3482 fi
3483 ;;
3484
3485 openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3486
3487 ## hpux: Make sure we get select from libc rather than from libcurses
3488 ## because libcurses on HPUX 10.10 has a broken version of select.
3489 ## We used to use -lc -lcurses, but this may be cleaner.
3490 ## FIXME? But TERMINFO = yes on hpux (it used to be explicitly
3491 # set that way, now it uses the default). Isn't this a contradiction?
3492 hpux*) LIBS_TERMCAP="-ltermcap" ;;
3493
3494 esac
3495
3496 TERMCAP_OBJ=tparam.o
3497 if test $TERMINFO = yes; then
3498 AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3499 TERMCAP_OBJ=terminfo.o
3500 fi
3501 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3502 AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3503 fi
3504 AC_SUBST(LIBS_TERMCAP)
3505 AC_SUBST(TERMCAP_OBJ)
3506
3507
3508 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3509 # On Darwin, res_init appears not to be useful: see bug#562 and
3510 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3511 resolv=no
3512
3513 if test $opsys != darwin; then
3514
3515 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3516 #include <arpa/nameser.h>
3517 #include <resolv.h>]],
3518 [[return res_init();]])],
3519 have_res_init=yes, have_res_init=no)
3520 if test "$have_res_init" = no; then
3521 OLIBS="$LIBS"
3522 LIBS="$LIBS -lresolv"
3523 AC_MSG_CHECKING(for res_init with -lresolv)
3524 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3525 #include <arpa/nameser.h>
3526 #include <resolv.h>]],
3527 [[return res_init();]])],
3528 have_res_init=yes, have_res_init=no)
3529 AC_MSG_RESULT($have_res_init)
3530 if test "$have_res_init" = yes ; then
3531 resolv=yes
3532 fi
3533 LIBS="$OLIBS"
3534 fi
3535
3536 if test "$have_res_init" = yes; then
3537 AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3538 fi
3539 fi dnl !darwin
3540
3541 # Do we need the Hesiod library to provide the support routines?
3542 dnl FIXME? Should we be skipping this on Darwin too?
3543 LIBHESIOD=
3544 if test "$with_hesiod" != no ; then
3545 # Don't set $LIBS here -- see comments above. FIXME which comments?
3546 AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3547 [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3548 [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3549 if test "$resolv" = yes ; then
3550 RESOLVLIB=-lresolv
3551 else
3552 RESOLVLIB=
3553 fi
3554 AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3555 hesiod=yes, :, $RESOLVLIB)])
3556
3557 if test x"$hesiod" = xyes; then
3558 LIBHESIOD=-lhesiod
3559 fi
3560 fi
3561 AC_SUBST(LIBHESIOD)
3562
3563 # Do we need libresolv (due to res_init or Hesiod)?
3564 if test "$resolv" = yes && test $opsys != darwin; then
3565 LIBRESOLV=-lresolv
3566 else
3567 LIBRESOLV=
3568 fi
3569 AC_SUBST(LIBRESOLV)
3570
3571 # These tell us which Kerberos-related libraries to use.
3572 COM_ERRLIB=
3573 CRYPTOLIB=
3574 KRB5LIB=
3575 DESLIB=
3576 KRB4LIB=
3577
3578 if test "${with_kerberos}" != no; then
3579 AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3580 if test $have_com_err = yes; then
3581 COM_ERRLIB=-lcom_err
3582 LIBS="$COM_ERRLIB $LIBS"
3583 fi
3584 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3585 if test $have_crypto = yes; then
3586 CRYPTOLIB=-lcrypto
3587 LIBS="$CRYPTOLIB $LIBS"
3588 fi
3589 AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3590 if test $have_k5crypto = yes; then
3591 CRYPTOLIB=-lk5crypto
3592 LIBS="$CRYPTOLIB $LIBS"
3593 fi
3594 AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3595 if test $have_krb5=yes; then
3596 KRB5LIB=-lkrb5
3597 LIBS="$KRB5LIB $LIBS"
3598 fi
3599 dnl FIXME Simplify. Does not match 22 logic, thanks to default_off?
3600 if test "${with_kerberos5}" = no; then
3601 AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3602 if test $have_des425 = yes; then
3603 DESLIB=-ldes425
3604 LIBS="$DESLIB $LIBS"
3605 else
3606 AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3607 if test $have_des = yes; then
3608 DESLIB=-ldes
3609 LIBS="$DESLIB $LIBS"
3610 fi
3611 fi
3612 AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3613 if test $have_krb4 = yes; then
3614 KRB4LIB=-lkrb4
3615 LIBS="$KRB4LIB $LIBS"
3616 else
3617 AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3618 if test $have_krb = yes; then
3619 KRB4LIB=-lkrb
3620 LIBS="$KRB4LIB $LIBS"
3621 fi
3622 fi
3623 fi
3624
3625 if test "${with_kerberos5}" != no; then
3626 AC_CHECK_HEADERS(krb5.h,
3627 [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3628 [#include <krb5.h>])])
3629 else
3630 AC_CHECK_HEADERS(krb.h,,
3631 [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3632 [AC_CHECK_HEADERS(kerberos/krb.h)])])
3633 fi
3634 AC_CHECK_HEADERS(com_err.h)
3635 fi
3636
3637 AC_SUBST(COM_ERRLIB)
3638 AC_SUBST(CRYPTOLIB)
3639 AC_SUBST(KRB5LIB)
3640 AC_SUBST(DESLIB)
3641 AC_SUBST(KRB4LIB)
3642
3643 AC_CHECK_FUNCS_ONCE(tzset)
3644 AC_MSG_CHECKING(whether localtime caches TZ)
3645 AC_CACHE_VAL(emacs_cv_localtime_cache,
3646 [if test x$ac_cv_func_tzset = xyes; then
3647 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3648 char TZ_GMT0[] = "TZ=GMT0";
3649 char TZ_PST8[] = "TZ=PST8";
3650 main()
3651 {
3652 time_t now = time ((time_t *) 0);
3653 int hour_GMT0, hour_unset;
3654 if (putenv (TZ_GMT0) != 0)
3655 exit (1);
3656 hour_GMT0 = localtime (&now)->tm_hour;
3657 unsetenv("TZ");
3658 hour_unset = localtime (&now)->tm_hour;
3659 if (putenv (TZ_PST8) != 0)
3660 exit (1);
3661 if (localtime (&now)->tm_hour == hour_GMT0)
3662 exit (1);
3663 unsetenv("TZ");
3664 if (localtime (&now)->tm_hour != hour_unset)
3665 exit (1);
3666 exit (0);
3667 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3668 [# If we have tzset, assume the worst when cross-compiling.
3669 emacs_cv_localtime_cache=yes])
3670 else
3671 # If we lack tzset, report that localtime does not cache TZ,
3672 # since we can't invalidate the cache if we don't have tzset.
3673 emacs_cv_localtime_cache=no
3674 fi])dnl
3675 AC_MSG_RESULT($emacs_cv_localtime_cache)
3676 if test $emacs_cv_localtime_cache = yes; then
3677 AC_DEFINE(LOCALTIME_CACHE, 1,
3678 [Define to 1 if localtime caches TZ.])
3679 fi
3680
3681 ok_so_far=yes
3682 AC_CHECK_FUNC(socket, , ok_so_far=no)
3683 if test $ok_so_far = yes; then
3684 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3685 fi
3686 if test $ok_so_far = yes; then
3687 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3688 fi
3689 if test $ok_so_far = yes; then
3690 dnl Fixme: Not used. Should this be HAVE_SOCKETS?
3691 AC_DEFINE(HAVE_INET_SOCKETS, 1,
3692 [Define to 1 if you have inet sockets.])
3693 fi
3694
3695 dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69).
3696 dnl This can be removed once we assume Autoconf 2.70.
3697 case $canonical in
3698 *-solaris2.4 | *-solaris2.4.*)
3699 dnl Disable the Autoconf-generated vfork test.
3700 : ${ac_cv_func_vfork_works=no};;
3701 esac
3702
3703 AC_FUNC_FORK
3704
3705 AC_CHECK_FUNCS(snprintf)
3706
3707 dnl Check this late. It depends on what other libraries (lrsvg, Gtk+ etc)
3708 dnl Emacs uses.
3709 XGSELOBJ=
3710 AC_MSG_CHECKING([whether GLib is linked in])
3711 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3712 [[#include <glib.h>
3713 ]],
3714 [[g_print ("Hello world");]])],
3715 [links_glib=yes],
3716 [links_glib=no])
3717 AC_MSG_RESULT([$links_glib])
3718 if test "${links_glib}" = "yes"; then
3719 AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
3720 if test "$HAVE_NS" = no;then
3721 XGSELOBJ=xgselect.o
3722 fi
3723 fi
3724 AC_SUBST(XGSELOBJ)
3725
3726 dnl Adapted from Haible's version.
3727 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3728 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3729 [[char* cs = nl_langinfo(CODESET);]])],
3730 emacs_cv_langinfo_codeset=yes,
3731 emacs_cv_langinfo_codeset=no)
3732 ])
3733 if test $emacs_cv_langinfo_codeset = yes; then
3734 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3735 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3736 fi
3737
3738 AC_TYPE_MBSTATE_T
3739
3740 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3741 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3742 emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3743 if test "$emacs_cv_c_restrict_arr" = yes; then
3744 AC_DEFINE(__restrict_arr, __restrict,
3745 [Define to compiler's equivalent of C99 restrict keyword in array
3746 declarations. Define as empty for no equivalent.])
3747 fi
3748
3749 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3750 dnl how the tty code is related to POSIX and/or other versions of termios.
3751 dnl The following looks like a useful start.
3752 dnl
3753 dnl AC_SYS_POSIX_TERMIOS
3754 dnl if test $ac_cv_sys_posix_termios = yes; then
3755 dnl AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3756 dnl and macros for terminal control.])
3757 dnl AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3758 dnl fi
3759
3760 dnl Turned on June 1996 supposing nobody will mind it.
3761 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
3762 if test "${opsys}" != "mingw32"; then
3763 AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3764 in the full name stands for the login id.])
3765 fi
3766
3767 dnl Every platform that uses configure supports this.
3768 dnl There is a create-lockfiles option you can
3769 dnl customize if you do not want the lock files to be written.
3770 dnl So it is not clear that this #define still needs to exist.
3771 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3772 so that Emacs can tell instantly when you try to modify a file that
3773 someone else has modified in his/her Emacs.])
3774
3775 dnl Everybody supports this, except MS.
3776 dnl Seems like the kind of thing we should be testing for, though.
3777 ## Note: PTYs are broken on darwin <6. Use at your own risk.
3778 if test "${opsys}" != "mingw32"; then
3779 AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3780 fi
3781
3782 dnl Everybody supports this, except MS-DOS.
3783 dnl Seems like the kind of thing we should be testing for, though.
3784 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3785 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3786 4.2-compatible sockets.])
3787
3788 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3789
3790 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
3791 a null file, or a data sink.])
3792 if test "${opsys}" = "mingw32"; then
3793 AC_DEFINE(NULL_DEVICE, ["NUL:"])
3794 else
3795 AC_DEFINE(NULL_DEVICE, ["/dev/null"])
3796 fi
3797
3798 AH_TEMPLATE(SEPCHAR, [Character that separates PATH elements.])
3799 if test "${opsys}" = "mingw32"; then
3800 AC_DEFINE(SEPCHAR, [';'])
3801 else
3802 AC_DEFINE(SEPCHAR, [':'])
3803 fi
3804
3805 dnl Everybody supports this, except MS-DOS.
3806 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3807
3808 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3809
3810
3811 AC_DEFINE(DIRECTORY_SEP, ['/'],
3812 [Character that separates directories in a file name.])
3813
3814 if test "${opsys}" = "mingw32"; then
3815 AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
3816 [Returns true if character is a device separator.])
3817
3818 AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
3819 [Returns true if character is a directory separator.])
3820
3821 AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
3822 [Returns true if character is any form of separator.])
3823 else
3824 AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3825 [Returns true if character is a device separator.])
3826
3827 AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3828 [Returns true if character is a directory separator.])
3829
3830 AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3831 [Returns true if character is any form of separator.])
3832 fi
3833
3834 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3835
3836 case $opsys in
3837 aix4-2)
3838 dnl Unfortunately without libXmu we cannot support EditRes.
3839 if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3840 AC_DEFINE(NO_EDITRES, 1)
3841 fi
3842 ;;
3843
3844 hpux*)
3845 dnl Assar Westerlund <assar@sics.se> says this is necessary for
3846 dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3847 AC_DEFINE(NO_EDITRES, 1)
3848 ;;
3849 esac
3850
3851
3852 case $opsys in
3853 irix6-5 | sol2* | unixware )
3854 dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3855 dnl instead, there's a system variable _sys_nsig. Unfortunately, we
3856 dnl need the constant to dimension an array. So wire in the appropriate
3857 dnl value here.
3858 AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3859 ;;
3860 esac
3861
3862 emacs_broken_SIGIO=no
3863
3864 case $opsys in
3865 dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3866 dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3867 hpux* | irix6-5 | openbsd | sol2* | unixware )
3868 emacs_broken_SIGIO=yes
3869 ;;
3870
3871 aix4-2)
3872 dnl On AIX Emacs uses the gmalloc.c malloc implementation. But given
3873 dnl the way this system works, libc functions that return malloced
3874 dnl memory use the libc malloc implementation. Calling xfree or
3875 dnl xrealloc on the results of such functions results in a crash.
3876 dnl
3877 dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3878 dnl but that does not currently work on this system.
3879 dnl
3880 dnl It is possible to completely override the malloc implementation on
3881 dnl AIX, but that involves putting the malloc functions in a shared
3882 dnl library and setting the MALLOCTYPE environment variable to point to
3883 dnl that shared library.
3884 dnl
3885 dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3886 dnl to avoid a crash just use the Emacs implementation for that function.
3887 dnl
3888 dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3889 dnl of this file, so that we do not check for get_current_dir_name
3890 dnl on AIX. But that might be fragile if something else ends
3891 dnl up testing for get_current_dir_name as a dependency.
3892 AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3893 get_current_dir_name should not be used.])
3894 ;;
3895
3896 freebsd)
3897 dnl Circumvent a bug in FreeBSD. In the following sequence of
3898 dnl writes/reads on a PTY, read(2) returns bogus data:
3899 dnl
3900 dnl write(2) 1022 bytes
3901 dnl write(2) 954 bytes, get EAGAIN
3902 dnl read(2) 1024 bytes in process_read_output
3903 dnl read(2) 11 bytes in process_read_output
3904 dnl
3905 dnl That is, read(2) returns more bytes than have ever been written
3906 dnl successfully. The 1033 bytes read are the 1022 bytes written
3907 dnl successfully after processing (for example with CRs added if the
3908 dnl terminal is set up that way which it is here). The same bytes will
3909 dnl be seen again in a later read(2), without the CRs.
3910 AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3911 work around an issue when reading from a PTY.])
3912 ;;
3913 esac
3914
3915 case $opsys in
3916 gnu-* | sol2-10 )
3917 dnl FIXME Can't we test if this exists (eg /proc/$$)?
3918 AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3919 ;;
3920 esac
3921
3922 case $opsys in
3923 darwin | dragonfly | freebsd | netbsd | openbsd )
3924 AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3925 close a pty to make it a controlling terminal (it is already a
3926 controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3927 ;;
3928 esac
3929
3930 dnl FIXME Surely we can test for this rather than hard-code it.
3931 case $opsys in
3932 netbsd | openbsd) sound_device="/dev/audio" ;;
3933 *) sound_device="/dev/dsp" ;;
3934 esac
3935
3936 dnl Used in sound.c
3937 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3938 [Name of the default sound device.])
3939
3940
3941 dnl Emacs can read input using SIGIO and buffering characters itself,
3942 dnl or using CBREAK mode and making C-g cause SIGINT.
3943 dnl The choice is controlled by the variable interrupt_input.
3944 dnl
3945 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3946 dnl
3947 dnl Emacs uses the presence of the USABLE_SIGIO macro
3948 dnl to indicate whether or not signal-driven I/O is possible. It uses
3949 dnl INTERRUPT_INPUT to decide whether to use it by default.
3950 dnl
3951 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3952 dnl CBREAK mode has two disadvantages
3953 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3954 dnl I hear that in system V this problem does not exist.
3955 dnl 2) Control-G causes output to be discarded.
3956 dnl I do not know whether this can be fixed in system V.
3957 dnl
3958 dnl Another method of doing input is planned but not implemented.
3959 dnl It would have Emacs fork off a separate process
3960 dnl to read the input and send it to the true Emacs process
3961 dnl through a pipe.
3962 case $opsys in
3963 darwin | gnu-linux | gnu-kfreebsd )
3964 AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3965 ;;
3966 esac
3967
3968
3969 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3970 dnl as `NO', we must define NARROWPROTO manually. Such a define is
3971 dnl generated in the Makefile generated by `xmkmf'. If we don't define
3972 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3973 dnl taking float or double parameters.
3974 case $opsys in
3975 cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3976 AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3977 file defines `NeedWidePrototypes' as `NO'.])
3978 ;;
3979 esac
3980
3981
3982 dnl Used in process.c, this must be a loop, even if it only runs once.
3983 dnl (Except on SGI; see below. Take that, clarity and consistency!)
3984 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3985 dnl Only used if !PTY_ITERATION. Iterate from FIRST_PTY_LETTER to z,
3986 dnl trying suffixes 0-16.
3987 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3988 first PTY, if PTYs are supported.])
3989 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3990 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3991 end of a PTY, if non-standard.])
3992 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3993 end of a PTY, if non-standard.])
3994
3995 case $opsys in
3996 aix4-2 )
3997 AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
3998 dnl You allocate a pty by opening /dev/ptc to get the master side.
3999 dnl To get the name of the slave side, you just ttyname() the master side.
4000 AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4001 AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4002 ;;
4003
4004 cygwin )
4005 AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4006 dnl multi-line AC_DEFINEs are hard. :(
4007 AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (0)])
4008 AC_DEFINE(PTY_NAME_SPRINTF, [])
4009 AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4010 ;;
4011
4012 dnl FIXME? Maybe use same as freebsd - see bug#12040.
4013 darwin )
4014 AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4015 dnl Not used, because PTY_ITERATION is defined.
4016 AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4017 dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4018 dnl But we don't have to block SIGCHLD because it is blocked in the
4019 dnl implementation of grantpt.
4020 AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)])
4021 AC_DEFINE(PTY_NAME_SPRINTF, [])
4022 AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4023 ;;
4024
4025 gnu | openbsd )
4026 AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4027 ;;
4028
4029 gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
4030 dnl if HAVE_GRANTPT
4031 if test "x$ac_cv_func_grantpt" = xyes; then
4032 AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4033 AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4034 dnl Note that grantpt and unlockpt may fork. We must block SIGCHLD
4035 dnl to prevent sigchld_handler from intercepting the child's death.
4036 AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4037 dnl if HAVE_POSIX_OPENPT
4038 if test "x$ac_cv_func_posix_openpt" = xyes; then
4039 AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (0)])
4040 AC_DEFINE(PTY_NAME_SPRINTF, [])
4041 dnl if HAVE_GETPT
4042 elif test "x$ac_cv_func_getpt" = xyes; then
4043 AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4044 AC_DEFINE(PTY_NAME_SPRINTF, [])
4045 else
4046 AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4047 fi
4048 else
4049 AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4050 fi
4051 ;;
4052
4053 hpux*)
4054 AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4055 AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4056 AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4057 ;;
4058
4059 irix6-5 )
4060 dnl It looks like this cannot be right, because it is not a loop.
4061 dnl However, process.c actually does this:
4062 dnl # ifndef __sgi
4063 dnl continue;
4064 dnl # else
4065 dnl return -1;
4066 dnl # endif
4067 dnl which presumably makes it OK, since irix == sgi (?).
4068 dnl FIXME it seems like this special treatment is unnecessary?
4069 dnl Why can't irix use a single-trip loop like eg cygwin?
4070 AC_DEFINE(PTY_ITERATION, [])
4071 dnl Not used, because PTY_ITERATION is defined.
4072 AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4073 AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4074 dnl No need to get the pty name at all.
4075 AC_DEFINE(PTY_NAME_SPRINTF, [])
4076 dnl No need to use sprintf to get the tty name--we get that from _getpty.
4077 AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4078 ;;
4079
4080 sol2* )
4081 dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4082 dnl from intercepting that death. If any child but grantpt's should die
4083 dnl within, it should be caught after sigrelse(2).
4084 AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4085 ;;
4086
4087 unixware )
4088 dnl Comments are as per sol2*.
4089 AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4090 ;;
4091 esac
4092
4093
4094 case $opsys in
4095 sol2* | unixware )
4096 dnl This change means that we don't loop through allocate_pty too
4097 dnl many times in the (rare) event of a failure.
4098 AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4099 AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4100 dnl Push various streams modules onto a PTY channel. Used in process.c.
4101 AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4102 ;;
4103 esac
4104
4105
4106 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4107 "typing" a signal character on the pty.])
4108
4109 case $opsys in
4110 dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4111 dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4112 aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4113 AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4114 ;;
4115
4116 dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4117 dnl FIXME Does gnu-kfreebsd have linux/version.h? It seems unlikely...
4118 gnu-linux | gnu-kfreebsd )
4119
4120 AC_MSG_CHECKING([for signals via characters])
4121 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4122 #include <linux/version.h>
4123 #if LINUX_VERSION_CODE < 0x20400
4124 # error "Linux version too old"
4125 #endif
4126 ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4127
4128 AC_MSG_RESULT([$emacs_signals_via_chars])
4129 test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4130 ;;
4131 esac
4132
4133
4134 dnl Used in lisp.h, emacs.c, vm-limit.c
4135 dnl NEWS.18 describes this as "a number which contains
4136 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
4137 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
4138 stored in a Lisp_Object.])
4139 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
4140
4141 case $opsys in
4142 aix*)
4143 dnl This works with 32-bit executables; Emacs doesn't support 64-bit.
4144 AC_DEFINE(DATA_SEG_BITS, [0x20000000])
4145 ;;
4146 hpux*)
4147 dnl The data segment on this machine always starts at address 0x40000000.
4148 AC_DEFINE(DATA_SEG_BITS, [0x40000000])
4149 ;;
4150 irix6-5)
4151 AC_DEFINE(DATA_SEG_BITS, [0x10000000])
4152 ;;
4153 esac
4154
4155
4156 AH_TEMPLATE(TAB3, [Undocumented.])
4157
4158 case $opsys in
4159 darwin) AC_DEFINE(TAB3, OXTABS) ;;
4160
4161 gnu | dragonfly | freebsd | netbsd | openbsd )
4162 AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4163 AC_DEFINE(TAB3, OXTABS)
4164 ;;
4165
4166 gnu-linux | gnu-kfreebsd )
4167 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4168 #ifndef __ia64__
4169 # error "not ia64"
4170 #endif
4171 ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4172 [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
4173 [Mark a secondary stack, like the register stack on the ia64.]), [])
4174 ;;
4175
4176 hpux*)
4177 AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4178 run_time_remap; for HPUX.])
4179 ;;
4180 esac
4181
4182
4183 dnl This won't be used automatically yet. We also need to know, at least,
4184 dnl that the stack is continuous.
4185 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4186 registers relevant for conservative garbage collection in the jmp_buf.])
4187
4188
4189 case $opsys in
4190 dnl Not all the architectures are tested, but there are Debian packages
4191 dnl for SCM and/or Guile on them, so the technique must work. See also
4192 dnl comments in alloc.c concerning setjmp and gcc.
4193 dnl Fixme: it's probably safe to just use the GCC conditional below.
4194 gnu-linux | gnu-kfreebsd )
4195 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4196 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4197 || defined __alpha__ || defined __mips__ || defined __s390__ \
4198 || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4199 || defined __ia64__ || defined __sh__
4200 /* ok */
4201 #else
4202 # error "setjmp not known to work on this arch"
4203 #endif
4204 ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4205 ;;
4206 esac
4207
4208
4209 if test x$GCC = xyes; then
4210 dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4211 AC_DEFINE(GC_SETJMP_WORKS, 1)
4212 else
4213 case $opsys in
4214 dnl irix: Tested on Irix 6.5. SCM worked on earlier versions.
4215 dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4216 AC_DEFINE(GC_SETJMP_WORKS, 1)
4217 ;;
4218 esac
4219 fi dnl GCC?
4220
4221 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4222 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4223 [AC_LINK_IFELSE(
4224 [AC_LANG_PROGRAM(
4225 [[#include <setjmp.h>
4226 #ifdef __MINGW32__
4227 # define _longjmp longjmp
4228 #endif
4229 ]],
4230 [[jmp_buf j;
4231 if (! _setjmp (j))
4232 _longjmp (j, 1);]])],
4233 [emacs_cv_func__setjmp=yes],
4234 [emacs_cv_func__setjmp=no])])
4235 if test $emacs_cv_func__setjmp = yes; then
4236 AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4237 else
4238 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4239 [AC_LINK_IFELSE(
4240 [AC_LANG_PROGRAM(
4241 [[#include <setjmp.h>
4242 ]],
4243 [[sigjmp_buf j;
4244 if (! sigsetjmp (j, 1))
4245 siglongjmp (j, 1);]])],
4246 [emacs_cv_func_sigsetjmp=yes],
4247 [emacs_cv_func_sigsetjmp=no])])
4248 if test $emacs_cv_func_sigsetjmp = yes; then
4249 AC_DEFINE([HAVE_SIGSETJMP], 1,
4250 [Define to 1 if sigsetjmp and siglongjmp work.
4251 The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
4252 fi
4253 fi
4254
4255 case $opsys in
4256 sol2* | unixware )
4257 dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4258 dnl subprocesses the usual way. But TIOCSIGNAL does work for PTYs,
4259 dnl and this is all we need.
4260 AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4261 ;;
4262 esac
4263
4264
4265 case $opsys in
4266 hpux* | sol2* )
4267 dnl Used in xfaces.c.
4268 AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4269 some systems, where it requires time.h.])
4270 ;;
4271 esac
4272
4273
4274 dnl Define symbols to identify the version of Unix this is.
4275 dnl Define all the symbols that apply correctly.
4276 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4277 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4278 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4279 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4280
4281 case $opsys in
4282 aix4-2)
4283 AC_DEFINE(USG, [])
4284 dnl This symbol should be defined on AIX Version 3 ???????
4285 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4286 #ifndef _AIX
4287 # error "_AIX not defined"
4288 #endif
4289 ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4290 ;;
4291
4292 cygwin)
4293 AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4294 ;;
4295
4296 darwin)
4297 dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4298 dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4299 dnl distinguish OS X from pure Darwin.
4300 AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4301 ;;
4302
4303 gnu-linux | gnu-kfreebsd )
4304 AC_DEFINE(USG, [])
4305 AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4306 ;;
4307
4308 hpux*)
4309 AC_DEFINE(USG, [])
4310 AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4311 ;;
4312
4313 irix6-5)
4314 AC_DEFINE(USG, [])
4315 AC_DEFINE(USG5_4, [])
4316 AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4317 ;;
4318
4319 mingw32)
4320 AC_DEFINE(DOS_NT, [])
4321 AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4322 if test "x$ac_enable_checking" != "x" ; then
4323 AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4324 fi
4325 ;;
4326
4327 sol2*)
4328 AC_DEFINE(USG, [])
4329 AC_DEFINE(USG5_4, [])
4330 AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4331 ;;
4332
4333 unixware)
4334 AC_DEFINE(USG, [])
4335 AC_DEFINE(USG5_4, [])
4336 ;;
4337 esac
4338
4339 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4340 [case $opsys in
4341 aix4-2)
4342 dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4343 emacs_cv_usable_FIONREAD=no
4344 ;;
4345
4346 mingw32)
4347 emacs_cv_usable_FIONREAD=yes
4348 ;;
4349
4350 *)
4351 AC_COMPILE_IFELSE(
4352 [AC_LANG_PROGRAM([[#include <sys/types.h>
4353 #include <sys/ioctl.h>
4354 #ifdef USG5_4
4355 # include <sys/filio.h>
4356 #endif
4357 ]],
4358 [[int foo = ioctl (0, FIONREAD, &foo);]])],
4359 [emacs_cv_usable_FIONREAD=yes],
4360 [emacs_cv_usable_FIONREAD=no])
4361 ;;
4362 esac])
4363 if test $emacs_cv_usable_FIONREAD = yes; then
4364 AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4365
4366 if test $emacs_broken_SIGIO = no; then
4367 AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4368 [AC_COMPILE_IFELSE(
4369 [AC_LANG_PROGRAM([[#include <fcntl.h>
4370 #include <signal.h>
4371 ]],
4372 [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4373 [emacs_cv_usable_SIGIO=yes],
4374 [emacs_cv_usable_SIGIO=no])],
4375 [emacs_cv_usable_SIGIO=yes],
4376 [emacs_cv_usable_SIGIO=no])
4377 if test $emacs_cv_usable_SIGIO = yes; then
4378 AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4379 fi
4380 fi
4381 fi
4382
4383
4384 case $opsys in
4385 dnl Emacs supplies its own malloc, but glib calls posix_memalign,
4386 dnl and on Cygwin prior to version 1.7.24 that becomes the
4387 dnl Cygwin-supplied posix_memalign. As malloc is not the Cygwin
4388 dnl malloc, the Cygwin posix_memalign always returns ENOSYS. A
4389 dnl workaround is to set G_SLICE=always-malloc. This is no longer
4390 dnl needed starting with cygwin-1.7.24, and it is no longer
4391 dnl effective starting with glib-2.36. */
4392 cygwin)
4393 AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
4394 G_SLICE environment variable to "always-malloc" at startup.])
4395 ;;
4396
4397 hpux11)
4398 dnl It works to open the pty's tty in the parent (Emacs), then
4399 dnl close and reopen it in the child.
4400 AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4401 works to open a pty's tty in the parent process, then close and
4402 reopen it in the child.])
4403 ;;
4404
4405 irix6-5)
4406 AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4407 use VSUSP instead of VSWTCH.])
4408 ;;
4409
4410 sol2-10)
4411 AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4412 on Solaris.])
4413 ;;
4414 esac
4415
4416 # Set up the CFLAGS for real compilation, so we can substitute it.
4417 CFLAGS="$REAL_CFLAGS"
4418 CPPFLAGS="$REAL_CPPFLAGS"
4419
4420 ## Hack to detect a buggy GCC version.
4421 if test "x$GCC" = xyes \
4422 && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4423 && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4424 && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4425 AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4426 fi
4427
4428 version=$PACKAGE_VERSION
4429
4430 copyright="Copyright (C) 2013 Free Software Foundation, Inc."
4431 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4432 [Short copyright string for this version of Emacs.])
4433 AC_SUBST(copyright)
4434
4435 ### Specify what sort of things we'll be editing into Makefile and config.h.
4436 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4437 AC_SUBST(version)
4438 AC_SUBST(configuration)
4439 ## Unused?
4440 AC_SUBST(canonical)
4441 AC_SUBST(srcdir)
4442 AC_SUBST(prefix)
4443 AC_SUBST(exec_prefix)
4444 AC_SUBST(bindir)
4445 AC_SUBST(datadir)
4446 AC_SUBST(sharedstatedir)
4447 AC_SUBST(libexecdir)
4448 AC_SUBST(mandir)
4449 AC_SUBST(infodir)
4450 AC_SUBST(lispdir)
4451 AC_SUBST(leimdir)
4452 AC_SUBST(standardlisppath)
4453 AC_SUBST(locallisppath)
4454 AC_SUBST(lisppath)
4455 AC_SUBST(x_default_search_path)
4456 AC_SUBST(etcdir)
4457 AC_SUBST(archlibdir)
4458 AC_SUBST(etcdocdir)
4459 AC_SUBST(bitmapdir)
4460 AC_SUBST(gamedir)
4461 AC_SUBST(gameuser)
4462 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4463 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4464 ## end of LIBX_BASE, but nothing ever set it.
4465 AC_SUBST(LD_SWITCH_X_SITE)
4466 AC_SUBST(C_SWITCH_X_SITE)
4467 AC_SUBST(GNUSTEP_CFLAGS)
4468 AC_SUBST(CFLAGS)
4469 ## Used in lwlib/Makefile.in.
4470 AC_SUBST(X_TOOLKIT_TYPE)
4471 AC_SUBST(ns_appdir)
4472 AC_SUBST(ns_appbindir)
4473 AC_SUBST(ns_appresdir)
4474 AC_SUBST(ns_appsrc)
4475 AC_SUBST(GNU_OBJC_CFLAGS)
4476 AC_SUBST(OTHER_FILES)
4477
4478 if test -n "${term_header}"; then
4479 AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4480 [Define to the header for the built-in window system.])
4481 fi
4482
4483 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}",
4484 [Define to the canonical Emacs configuration name.])
4485 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4486 [Define to the options passed to configure.])
4487 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4488 define this to include extra configuration information.])
4489
4490 case $opsys in
4491 mingw32)
4492 AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4493 ;;
4494 esac
4495
4496 XMENU_OBJ=
4497 XOBJ=
4498 FONT_OBJ=
4499 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4500 AC_DEFINE(HAVE_X_WINDOWS, 1,
4501 [Define to 1 if you want to use the X window system.])
4502 XMENU_OBJ=xmenu.o
4503 XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4504 FONT_OBJ=xfont.o
4505 if test "$HAVE_XFT" = "yes"; then
4506 FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4507 elif test "$HAVE_FREETYPE" = "yes"; then
4508 FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4509 fi
4510 AC_SUBST(FONT_OBJ)
4511 fi
4512 AC_SUBST(XMENU_OBJ)
4513 AC_SUBST(XOBJ)
4514 AC_SUBST(FONT_OBJ)
4515
4516 WIDGET_OBJ=
4517 MOTIF_LIBW=
4518 if test "${USE_X_TOOLKIT}" != "none" ; then
4519 WIDGET_OBJ=widget.o
4520 AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4521 if test "${USE_X_TOOLKIT}" = "LUCID"; then
4522 AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4523 elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4524 AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4525 MOTIF_LIBW=-lXm
4526 case "$opsys" in
4527 gnu-linux)
4528 ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4529 MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4530 ;;
4531
4532 unixware)
4533 ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4534 ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4535 MOTIF_LIBW="MOTIF_LIBW -lXimp"
4536 ;;
4537
4538 aix4-2)
4539 ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4540 MOTIF_LIBW="$MOTIF_LIBW -li18n"
4541 ;;
4542 esac
4543 MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4544 fi
4545 fi
4546 AC_SUBST(WIDGET_OBJ)
4547
4548 TOOLKIT_LIBW=
4549 case "$USE_X_TOOLKIT" in
4550 MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4551 LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4552 none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4553 esac
4554 AC_SUBST(TOOLKIT_LIBW)
4555
4556 if test "${opsys}" != "mingw32"; then
4557 if test "$USE_X_TOOLKIT" = "none"; then
4558 LIBXT_OTHER="\$(LIBXSM)"
4559 OLDXMENU_TARGET="really-oldXMenu"
4560 else
4561 LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4562 OLDXMENU_TARGET="really-lwlib"
4563 fi
4564 fi
4565 AC_SUBST(LIBXT_OTHER)
4566
4567 ## The X Menu stuff is present in the X10 distribution, but missing
4568 ## from X11. If we have X10, just use the installed library;
4569 ## otherwise, use our own copy.
4570 if test "${HAVE_X11}" = "yes" ; then
4571 AC_DEFINE(HAVE_X11, 1,
4572 [Define to 1 if you want to use version 11 of X windows.
4573 Otherwise, Emacs expects to use version 10.])
4574
4575 if test "$USE_X_TOOLKIT" = "none"; then
4576 OLDXMENU="\${oldXMenudir}/libXMenu11.a"
4577 else
4578 OLDXMENU="\${lwlibdir}/liblw.a"
4579 fi
4580 LIBXMENU="\$(OLDXMENU)"
4581 LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4582 OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
4583 else
4584 ## For a syntactically valid Makefile; not actually used for anything.
4585 ## See comments in src/Makefile.in.
4586 OLDXMENU=nothing
4587 ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
4588 if test "${HAVE_X_WINDOWS}" = "yes"; then
4589 LIBXMENU="-lXMenu"
4590 else
4591 LIBXMENU=
4592 fi
4593 LIBX_OTHER=
4594 OLDXMENU_DEPS=
4595 fi
4596
4597 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
4598 OLDXMENU_TARGET=
4599 OLDXMENU=nothing
4600 LIBXMENU=
4601 OLDXMENU_DEPS=
4602 fi
4603
4604 AC_SUBST(OLDXMENU_TARGET)
4605 AC_SUBST(OLDXMENU)
4606 AC_SUBST(LIBXMENU)
4607 AC_SUBST(LIBX_OTHER)
4608 AC_SUBST(OLDXMENU_DEPS)
4609
4610 if test "${HAVE_MENUS}" = "yes" ; then
4611 AC_DEFINE(HAVE_MENUS, 1,
4612 [Define to 1 if you have mouse menus.
4613 (This is automatic if you use X, but the option to specify it remains.)
4614 It is also defined with other window systems that support xmenu.c.])
4615 fi
4616
4617 if test "${GNU_MALLOC}" = "yes" ; then
4618 AC_DEFINE(GNU_MALLOC, 1,
4619 [Define to 1 if you want to use the GNU memory allocator.])
4620 fi
4621
4622 RALLOC_OBJ=
4623 if test "${REL_ALLOC}" = "yes" ; then
4624 AC_DEFINE(REL_ALLOC, 1,
4625 [Define REL_ALLOC if you want to use the relocating allocator for
4626 buffer space.])
4627
4628 test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4629 fi
4630 AC_SUBST(RALLOC_OBJ)
4631
4632 if test "$opsys" = "cygwin"; then
4633 CYGWIN_OBJ="sheap.o cygw32.o"
4634 ## Cygwin differs because of its unexec().
4635 PRE_ALLOC_OBJ=
4636 POST_ALLOC_OBJ=lastfile.o
4637 elif test "$opsys" = "mingw32"; then
4638 CYGWIN_OBJ=
4639 PRE_ALLOC_OBJ=
4640 POST_ALLOC_OBJ=lastfile.o
4641 else
4642 CYGWIN_OBJ=
4643 PRE_ALLOC_OBJ=lastfile.o
4644 POST_ALLOC_OBJ=
4645 fi
4646 AC_SUBST(CYGWIN_OBJ)
4647 AC_SUBST(PRE_ALLOC_OBJ)
4648 AC_SUBST(POST_ALLOC_OBJ)
4649
4650 # Configure gnulib. Although this does not affect CFLAGS or LIBS permanently.
4651 # it temporarily reverts them to their pre-pkg-config values,
4652 # because gnulib needs to work with both src (which uses the
4653 # pkg-config stuff) and lib-src (which does not). For example, gnulib
4654 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4655 # and it therefore needs to run in an environment where LIBS does not
4656 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4657 # for some package unrelated to lib-src.
4658 SAVE_CFLAGS=$CFLAGS
4659 SAVE_LIBS=$LIBS
4660 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4661 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4662 gl_ASSERT_NO_GNULIB_POSIXCHECK
4663 gl_ASSERT_NO_GNULIB_TESTS
4664 gl_INIT
4665 CFLAGS=$SAVE_CFLAGS
4666 LIBS=$SAVE_LIBS
4667
4668 if test "${opsys}" = "mingw32"; then
4669 CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I $srcdir/nt/inc"
4670 # Remove unneeded switches from the value of CC that goes to Makefiles
4671 CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4672 fi
4673
4674 case "$opsys" in
4675 aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4676
4677 darwin)
4678 ## The -headerpad option tells ld (see man page) to leave room at the
4679 ## end of the header for adding load commands. Needed for dumping.
4680 ## 0x690 is the total size of 30 segment load commands (at 56
4681 ## each); under Cocoa 31 commands are required.
4682 if test "$HAVE_NS" = "yes"; then
4683 libs_nsgui="-framework AppKit"
4684 if test "$NS_IMPL_COCOA" = "yes"; then
4685 libs_nsgui="$libs_nsgui -framework IOKit"
4686 fi
4687 headerpad_extra=6C8
4688 else
4689 libs_nsgui=
4690 headerpad_extra=690
4691 fi
4692 LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4693
4694 ## This is here because src/Makefile.in did some extra fiddling around
4695 ## with LD_SWITCH_SYSTEM. It seems cleaner to put this in
4696 ## LD_SWITCH_SYSTEM_TEMACS instead,
4697 test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4698 LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4699 ;;
4700
4701 ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4702 ## find X at run-time.
4703 ## When handled by cpp, this was in LD_SWITCH_SYSTEM. However, at the
4704 ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4705 ## had not yet been defined and was expanded to null. Hence LD_SWITCH_SYSTEM
4706 ## had different values in configure (in ac_link) and src/Makefile.in.
4707 ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4708 gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4709
4710 mingw32)
4711 ## MinGW64 does not prepend an underscore to symbols, so we must
4712 ## pass a different -entry switch to linker. FIXME: It is better
4713 ## to make the entry points the same by changing unexw32.c.
4714 case "$canonical" in
4715 x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,_start -Wl,-Map,./temacs.map" ;;
4716 *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4717 esac
4718 ;;
4719
4720 openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4721
4722 *) LD_SWITCH_SYSTEM_TEMACS= ;;
4723 esac
4724
4725 if test x$ac_enable_profiling != x ; then
4726 case $opsys in
4727 *freebsd | gnu-linux) ;;
4728 *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4729 esac
4730 fi
4731
4732 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4733
4734 ## MinGW-specific post-link processing of temacs.
4735 TEMACS_POST_LINK=":"
4736 ADDSECTION=
4737 EMACS_HEAPSIZE=
4738 if test "${opsys}" = "mingw32"; then
4739 TEMACS_POST_LINK="\$(MINGW_TEMACS_POST_LINK)"
4740 ADDSECTION="../nt/addsection\$(EXEEXT)"
4741 ## Preload heap size of temacs.exe in MB.
4742 case "$canonical" in
4743 x86_64-*-*) EMACS_HEAPSIZE=42 ;;
4744 *) EMACS_HEAPSIZE=27 ;;
4745 esac
4746 fi
4747
4748 AC_SUBST(ADDSECTION)
4749 AC_SUBST(TEMACS_POST_LINK)
4750 AC_SUBST(EMACS_HEAPSIZE)
4751
4752 ## Common for all window systems
4753 if test "$window_system" != "none"; then
4754 AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4755 WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4756 fi
4757
4758 AC_SUBST(WINDOW_SYSTEM_OBJ)
4759
4760 AH_TOP([/* GNU Emacs site configuration template file.
4761
4762 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2013
4763 Free Software Foundation, Inc.
4764
4765 This file is part of GNU Emacs.
4766
4767 GNU Emacs is free software: you can redistribute it and/or modify
4768 it under the terms of the GNU General Public License as published by
4769 the Free Software Foundation, either version 3 of the License, or
4770 (at your option) any later version.
4771
4772 GNU Emacs is distributed in the hope that it will be useful,
4773 but WITHOUT ANY WARRANTY; without even the implied warranty of
4774 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
4775 GNU General Public License for more details.
4776
4777 You should have received a copy of the GNU General Public License
4778 along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. */
4779
4780
4781 /* No code in Emacs #includes config.h twice, but some bits of code
4782 intended to work with other packages as well (like gmalloc.c)
4783 think they can include it as many times as they like. */
4784 #ifndef EMACS_CONFIG_H
4785 #define EMACS_CONFIG_H
4786 ])dnl
4787
4788 AH_BOTTOM([#include <conf_post.h>
4789
4790 #endif /* EMACS_CONFIG_H */
4791
4792 /*
4793 Local Variables:
4794 mode: c
4795 End:
4796 */
4797 ])dnl
4798
4799 #### Report on what we decided to do.
4800 #### Report GTK as a toolkit, even if it doesn't use Xt.
4801 #### It makes printing result more understandable as using GTK sets
4802 #### toolkit_scroll_bars to yes by default.
4803 if test "${HAVE_GTK}" = "yes"; then
4804 USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4805 fi
4806
4807 if test $USE_ACL -ne 0; then
4808 acl_summary="yes $LIB_ACL"
4809 else
4810 acl_summary=no
4811 fi
4812
4813 echo "
4814 Configured for \`${canonical}'.
4815
4816 Where should the build process find the source code? ${srcdir}
4817 What compiler should emacs be built with? ${CC} ${CFLAGS}
4818 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
4819 Should Emacs use a relocating allocator for buffers? ${REL_ALLOC}
4820 Should Emacs use mmap(2) for buffer allocation? $use_mmap_for_buffers
4821 What window system should Emacs use? ${window_system}
4822 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
4823
4824 if test -n "${x_includes}"; then
4825 echo " Where do we find X Windows header files? ${x_includes}"
4826 else
4827 echo " Where do we find X Windows header files? Standard dirs"
4828 fi
4829 if test -n "${x_libraries}"; then
4830 echo " Where do we find X Windows libraries? ${x_libraries}"
4831 else
4832 echo " Where do we find X Windows libraries? Standard dirs"
4833 fi
4834
4835 echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}"
4836 echo " Does Emacs use -lXpm? ${HAVE_XPM}"
4837 echo " Does Emacs use -ljpeg? ${HAVE_JPEG}"
4838 echo " Does Emacs use -ltiff? ${HAVE_TIFF}"
4839 echo " Does Emacs use a gif library? ${HAVE_GIF} $LIBGIF"
4840 echo " Does Emacs use -lpng? ${HAVE_PNG}"
4841 echo " Does Emacs use -lrsvg-2? ${HAVE_RSVG}"
4842 echo " Does Emacs use imagemagick? ${HAVE_IMAGEMAGICK}"
4843
4844 echo " Does Emacs support sound? ${HAVE_SOUND}"
4845
4846 echo " Does Emacs use -lgpm? ${HAVE_GPM}"
4847 echo " Does Emacs use -ldbus? ${HAVE_DBUS}"
4848 echo " Does Emacs use -lgconf? ${HAVE_GCONF}"
4849 echo " Does Emacs use GSettings? ${HAVE_GSETTINGS}"
4850 echo " Does Emacs use a file notification library? ${NOTIFY_SUMMARY}"
4851 echo " Does Emacs use access control lists? ${acl_summary}"
4852 echo " Does Emacs use -lselinux? ${HAVE_LIBSELINUX}"
4853 echo " Does Emacs use -lgnutls? ${HAVE_GNUTLS}"
4854 echo " Does Emacs use -lxml2? ${HAVE_LIBXML2}"
4855
4856 echo " Does Emacs use -lfreetype? ${HAVE_FREETYPE}"
4857 echo " Does Emacs use -lm17n-flt? ${HAVE_M17N_FLT}"
4858 echo " Does Emacs use -lotf? ${HAVE_LIBOTF}"
4859 echo " Does Emacs use -lxft? ${HAVE_XFT}"
4860 echo " Does Emacs directly use zlib? ${HAVE_ZLIB}"
4861
4862 echo " Does Emacs use toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}"
4863 echo
4864
4865 if test -n "${EMACSDATA}"; then
4866 echo " Environment variable EMACSDATA set to: $EMACSDATA"
4867 fi
4868 if test -n "${EMACSDOC}"; then
4869 echo " Environment variable EMACSDOC set to: $EMACSDOC"
4870 fi
4871
4872 echo
4873
4874 if test "$HAVE_NS" = "yes"; then
4875 echo
4876 echo "You must run \"${MAKE-make} install\" in order to test the built application.
4877 The installed application will go to nextstep/Emacs.app and can be
4878 run or moved from there."
4879 if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4880 echo "The application will be fully self-contained."
4881 else
4882 echo "The lisp resources for the application will be installed under ${prefix}.
4883 You may need to run \"${MAKE-make} install\" with sudo. The application will fail
4884 to run if these resources are not installed."
4885 fi
4886 echo
4887 fi
4888
4889 if test "${opsys}" = "cygwin"; then
4890 case `uname -r` in
4891 1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4892 echo
4893 ;;
4894 esac
4895 fi
4896
4897 # Remove any trailing slashes in these variables.
4898 [test "${prefix}" != NONE &&
4899 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4900 test "${exec_prefix}" != NONE &&
4901 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4902
4903 if test "$HAVE_NS" = "yes"; then
4904 if test "$NS_IMPL_GNUSTEP" = yes; then
4905 AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
4906 nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
4907 ns_check_file=Resources/Info-gnustep.plist
4908 else
4909 AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
4910 nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
4911 ns_check_file=Contents/Info.plist
4912 fi
4913 AC_SUBST(ns_check_file)
4914 fi
4915
4916 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4917 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4918 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4919 dnl (else you get "no `Makefile.am' found for any configure output").
4920 dnl This will work, but you get a config.status that is not quite right
4921 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4922 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4923 dnl it seems better to just live with the duplication.
4924 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
4925
4926 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4927 doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4928 doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4929 leim/Makefile nextstep/Makefile nt/Makefile])
4930
4931 dnl test/ is not present in release tarfiles.
4932 opt_makefile=test/automated/Makefile
4933
4934 if test -f "$srcdir/$opt_makefile.in"; then
4935 SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4936 dnl Again, it's best not to use a variable. Though you can add
4937 dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4938 AC_CONFIG_FILES([test/automated/Makefile])
4939 fi
4940
4941
4942 dnl admin/ may or may not be present.
4943 opt_makefile=admin/unidata/Makefile
4944
4945 if test -f "$srcdir/$opt_makefile.in"; then
4946 SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4947 AC_CONFIG_FILES([admin/unidata/Makefile])
4948 fi
4949
4950
4951 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4952
4953 AC_SUBST(SUBDIR_MAKEFILES_IN)
4954
4955 dnl You might wonder (I did) why epaths.h is generated by running make,
4956 dnl rather than just letting configure generate it from epaths.in.
4957 dnl One reason is that the various paths are not fully expanded (see above);
4958 dnl eg gamedir=${prefix}/var/games/emacs.
4959 dnl Secondly, the GNU Coding standards require that one should be able
4960 dnl to run `make prefix=/some/where/else' and override the values set
4961 dnl by configure. This also explains the `move-if-change' test and
4962 dnl the use of force in the `epaths-force' rule in Makefile.in.
4963 AC_CONFIG_COMMANDS([src/epaths.h], [
4964 if test "${opsys}" = "mingw32"; then
4965 ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
4966 else
4967 ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
4968 fi
4969 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
4970
4971 AC_CONFIG_COMMANDS([src/.gdbinit], [
4972 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
4973 echo "source $srcdir/src/.gdbinit" > src/.gdbinit
4974 fi
4975 ])
4976
4977 AC_OUTPUT