lisp/composite.el

   1 ;;; composite.el --- support character composition
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008, 2009, 2010
   5 ;;   National Institute of Advanced Industrial Science and Technology (AIST)
   6 ;;   Registration Number H14PRO021
   7
   8 ;; Author: Kenichi HANDA <handa@etl.go.jp>
   9 ;; (according to ack.texi)
  10 ;; Keywords: mule, multilingual, character composition
  11 ;; Package: emacs
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl))
  33
  34 (defconst reference-point-alist
  35   '((tl . 0) (tc . 1) (tr . 2)
  36     (Bl . 3) (Bc . 4) (Br . 5)
  37     (bl . 6) (bc . 7) (br . 8)
  38     (cl . 9) (cc . 10) (cr . 11)
  39     (top-left . 0) (top-center . 1) (top-right . 2)
  40     (base-left . 3) (base-center . 4) (base-right . 5)
  41     (bottom-left . 6) (bottom-center . 7) (bottom-right . 8)
  42     (center-left . 9) (center-center . 10) (center-right . 11)
  43     ;; For backward compatibility...
  44     (ml . 3) (mc . 10) (mr . 5)
  45     (mid-left . 3) (mid-center . 10) (mid-right . 5))
  46   "Alist of symbols vs integer codes of glyph reference points.
  47 A glyph reference point symbol is to be used to specify a composition
  48 rule in COMPONENTS argument to such functions as `compose-region'.
  49
  50 The meaning of glyph reference point codes is as follows:
  51
  52     0----1----2 <---- ascent    0:tl or top-left
  53     |         |                 1:tc or top-center
  54     |         |                 2:tr or top-right
  55     |         |                 3:Bl or base-left     9:cl or center-left
  56     9   10   11 <---- center    4:Bc or base-center  10:cc or center-center
  57     |         |                 5:Br or base-right   11:cr or center-right
  58   --3----4----5-- <-- baseline  6:bl or bottom-left
  59     |         |                 7:bc or bottom-center
  60     6----7----8 <---- descent   8:br or bottom-right
  61
  62 Glyph reference point symbols are to be used to specify composition
  63 rule of the form \(GLOBAL-REF-POINT . NEW-REF-POINT), where
  64 GLOBAL-REF-POINT is a reference point in the overall glyphs already
  65 composed, and NEW-REF-POINT is a reference point in the new glyph to
  66 be added.
  67
  68 For instance, if GLOBAL-REF-POINT is `br' (bottom-right) and
  69 NEW-REF-POINT is `tc' (top-center), the overall glyph is updated as
  70 follows (the point `*' corresponds to both reference points):
  71
  72     +-------+--+ <--- new ascent
  73     |       |  |
  74     | global|  |
  75     | glyph |  |
  76  -- |       |  |-- <--- baseline \(doesn't change)
  77     +----+--*--+
  78     |    | new |
  79     |    |glyph|
  80     +----+-----+ <--- new descent
  81
  82 A composition rule may have the form \(GLOBAL-REF-POINT
  83 NEW-REF-POINT XOFF YOFF), where XOFF and YOFF specify how much
  84 to shift NEW-REF-POINT from GLOBAL-REF-POINT.  In this case, XOFF
  85 and YOFF are integers in the range -100..100 representing the
  86 shifting percentage against the font size.")
  87
  88
  89 ;;;###autoload
  90 (defun encode-composition-rule (rule)
  91   "Encode composition rule RULE into an integer value.
  92 RULE is a cons of global and new reference point symbols
  93 \(see `reference-point-alist')."
  94
  95   ;; This must be compatible with C macro COMPOSITION_ENCODE_RULE
  96   ;; defined in composite.h.
  97
  98   (if (and (integerp rule) (< rule 144))
  99       ;; Already encoded.
 100       rule
 101     (if (consp rule)
 102         (let ((gref (car rule))
 103               (nref (cdr rule))
 104               xoff yoff)
 105           (if (consp nref)              ; (GREF NREF XOFF YOFF)
 106               (progn
 107                 (setq xoff (nth 1 nref)
 108                       yoff (nth 2 nref)
 109                       nref (car nref))
 110                 (or (and (>= xoff -100) (<= xoff 100)
 111                          (>= yoff -100) (<= yoff 100))
 112                     (error "Invalid composition rule: %s" rule))
 113                 (setq xoff (+ xoff 128) yoff (+ yoff 128)))
 114             ;; (GREF . NREF)
 115             (setq xoff 0 yoff 0))
 116           (or (integerp gref)
 117               (setq gref (cdr (assq gref reference-point-alist))))
 118           (or (integerp nref)
 119               (setq nref (cdr (assq nref reference-point-alist))))
 120           (or (and (>= gref 0) (< gref 12) (>= nref 0) (< nref 12))
 121               (error "Invalid composition rule: %S" rule))
 122           (logior (lsh xoff 16) (lsh yoff 8) (+ (* gref 12) nref)))
 123       (error "Invalid composition rule: %S" rule))))
 124
 125 ;; Decode encoded composition rule RULE-CODE.  The value is a cons of
 126 ;; global and new reference point symbols.
 127 ;; This must be compatible with C macro COMPOSITION_DECODE_RULE
 128 ;; defined in composite.h.
 129
 130 (defun decode-composition-rule (rule-code)
 131   (or (and (natnump rule-code) (< rule-code #x1000000))
 132       (error "Invalid encoded composition rule: %S" rule-code))
 133   (let ((xoff (lsh rule-code -16))
 134         (yoff (logand (lsh rule-code -8) #xFF))
 135         gref nref)
 136     (setq rule-code (logand rule-code #xFF)
 137           gref (car (rassq (/ rule-code 12) reference-point-alist))
 138           nref (car (rassq (% rule-code 12) reference-point-alist)))
 139     (or (and gref (symbolp gref) nref (symbolp nref))
 140         (error "Invalid composition rule code: %S" rule-code))
 141     (if (and (= xoff 0) (= yoff 0))
 142         (cons gref nref)
 143       (setq xoff (- xoff 128) yoff (- yoff 128))
 144       (list gref xoff yoff nref))))
 145
 146 ;; Encode composition rules in composition components COMPONENTS.  The
 147 ;; value is a copy of COMPONENTS, where composition rules (cons of
 148 ;; global and new glyph reference point symbols) are replaced with
 149 ;; encoded composition rules.  Optional 2nd argument NOCOPY non-nil
 150 ;; means don't make a copy but modify COMPONENTS directly.
 151
 152 (defun encode-composition-components (components &optional nocopy)
 153   (or nocopy
 154       (setq components (copy-sequence components)))
 155   (if (vectorp components)
 156       (let ((len (length components))
 157             (i 1))
 158         (while (< i len)
 159           (aset components i
 160                 (encode-composition-rule (aref components i)))
 161           (setq i (+ i 2))))
 162     (let ((tail (cdr components)))
 163       (while tail
 164         (setcar tail
 165                 (encode-composition-rule (car tail)))
 166         (setq tail (nthcdr 2 tail)))))
 167   components)
 168
 169 ;; Decode composition rule codes in composition components COMPONENTS.
 170 ;; The value is a copy of COMPONENTS, where composition rule codes are
 171 ;; replaced with composition rules (cons of global and new glyph
 172 ;; reference point symbols).  Optional 2nd argument NOCOPY non-nil
 173 ;; means don't make a copy but modify COMPONENTS directly.
 174 ;; It is assumed that COMPONENTS is a vector and is for rule-base
 175 ;; composition, thus (2N+1)th elements are rule codes.
 176
 177 (defun decode-composition-components (components &optional nocopy)
 178   (or nocopy
 179       (setq components (copy-sequence components)))
 180   (let ((len (length components))
 181         (i 1))
 182     (while (< i len)
 183       (aset components i
 184             (decode-composition-rule (aref components i)))
 185       (setq i (+ i 2))))
 186   components)
 187
 188 (defun compose-region (start end &optional components modification-func)
 189   "Compose characters in the current region.
 190
 191 Characters are composed relatively, i.e. composed by overstriking
 192 or stacking depending on ascent, descent and other metrics of
 193 glyphs.
 194
 195 For instance, if the region has three characters \"XYZ\", X is
 196 regarded as BASE glyph, and Y is displayed:
 197   (1) above BASE if Y's descent value is not positive
 198   (2) below BASE if Y's ascent value is not positive
 199   (3) on BASE (i.e. at the BASE position) otherwise
 200 and Z is displayed with the same rule while regarding the whole
 201 XY glyphs as BASE.
 202
 203 When called from a program, expects these four arguments.
 204
 205 First two arguments START and END are positions (integers or markers)
 206 specifying the region.
 207
 208 Optional 3rd argument COMPONENTS, if non-nil, is a character, a string
 209 or a vector or list of integers and rules.
 210
 211 If it is a character, it is an alternate character to display instead
 212 of the text in the region.
 213
 214 If it is a string, the elements are alternate characters.  In
 215 this case, TAB element has a special meaning.  If the first
 216 character is TAB, the glyphs are displayed with left padding space
 217 so that no pixel overlaps with the previous column.  If the last
 218 character is TAB, the glyphs are displayed with right padding
 219 space so that no pixel overlaps with the following column.
 220
 221 If it is a vector or list, it is a sequence of alternate characters and
 222 composition rules, where (2N)th elements are characters and (2N+1)th
 223 elements are composition rules to specify how to compose (2N+2)th
 224 elements with previously composed N glyphs.
 225
 226 A composition rule is a cons of global and new glyph reference point
 227 symbols.  See the documentation of `reference-point-alist' for more
 228 details.
 229
 230 Optional 4th argument MODIFICATION-FUNC is a function to call to
 231 adjust the composition when it gets invalid because of a change of
 232 text in the composition."
 233   (interactive "r")
 234   (let ((modified-p (buffer-modified-p))
 235         (inhibit-read-only t))
 236     (if (or (vectorp components) (listp components))
 237         (setq components (encode-composition-components components)))
 238     (compose-region-internal start end components modification-func)
 239     (restore-buffer-modified-p modified-p)))
 240
 241 (defun decompose-region (start end)
 242   "Decompose text in the current region.
 243
 244 When called from a program, expects two arguments,
 245 positions (integers or markers) specifying the region."
 246   (interactive "r")
 247   (let ((modified-p (buffer-modified-p))
 248         (inhibit-read-only t))
 249     (remove-text-properties start end '(composition nil))
 250     (restore-buffer-modified-p modified-p)))
 251
 252 (defun compose-string (string &optional start end components modification-func)
 253   "Compose characters in string STRING.
 254
 255 The return value is STRING with the `composition' property put on all
 256 the characters in it.
 257
 258 Optional 2nd and 3rd arguments START and END specify the range of
 259 STRING to be composed.  They default to the beginning and the end of
 260 STRING respectively.
 261
 262 Optional 4th argument COMPONENTS, if non-nil, is a character or a
 263 sequence (vector, list, or string) of integers.  See the function
 264 `compose-region' for more detail.
 265
 266 Optional 5th argument MODIFICATION-FUNC is a function to call to
 267 adjust the composition when it gets invalid because of a change of
 268 text in the composition."
 269   (if (or (vectorp components) (listp components))
 270       (setq components (encode-composition-components components)))
 271   (or start (setq start 0))
 272   (or end (setq end (length string)))
 273   (compose-string-internal string start end components modification-func)
 274   string)
 275
 276 (defun decompose-string (string)
 277   "Return STRING where `composition' property is removed."
 278   (remove-text-properties 0 (length string) '(composition nil) string)
 279   string)
 280
 281 (defun compose-chars (&rest args)
 282   "Return a string from arguments in which all characters are composed.
 283 For relative composition, arguments are characters.
 284 For rule-based composition, Mth \(where M is odd) arguments are
 285 characters, and Nth \(where N is even) arguments are composition rules.
 286 A composition rule is a cons of glyph reference points of the form
 287 \(GLOBAL-REF-POINT . NEW-REF-POINT).  See the documentation of
 288 `reference-point-alist' for more detail."
 289   (let (str components)
 290     (if (consp (car (cdr args)))
 291         ;; Rule-base composition.
 292         (let ((len (length args))
 293               (tail (encode-composition-components args 'nocopy)))
 294
 295           (while tail
 296             (setq str (cons (car tail) str))
 297             (setq tail (nthcdr 2 tail)))
 298           (setq str (concat (nreverse str))
 299                 components args))
 300       ;; Relative composition.
 301       (setq str (concat args)))
 302     (compose-string-internal str 0 (length str) components)))
 303
 304 (defun find-composition (pos &optional limit string detail-p)
 305   "Return information about a composition at or near buffer position POS.
 306
 307 If the character at POS has `composition' property, the value is a list
 308 \(FROM TO VALID-P).
 309
 310 FROM and TO specify the range of text that has the same `composition'
 311 property, VALID-P is t if this composition is valid, and nil if not.
 312
 313 If there's no composition at POS, and the optional 2nd argument LIMIT
 314 is non-nil, search for a composition toward the position given by LIMIT.
 315
 316 If no composition is found, return nil.
 317
 318 Optional 3rd argument STRING, if non-nil, is a string to look for a
 319 composition in; nil means the current buffer.
 320
 321 If a valid composition is found and the optional 4th argument DETAIL-P
 322 is non-nil, the return value is a list of the form
 323
 324    (FROM TO COMPONENTS RELATIVE-P MOD-FUNC WIDTH)
 325
 326 COMPONENTS is a vector of integers, the meaning depends on RELATIVE-P.
 327
 328 RELATIVE-P is t if the composition method is relative, else nil.
 329
 330 If RELATIVE-P is t, COMPONENTS is a vector of characters to be
 331 composed.  If RELATIVE-P is nil, COMPONENTS is a vector of characters
 332 and composition rules as described in `compose-region'.
 333
 334 MOD-FUNC is a modification function of the composition.
 335
 336 WIDTH is a number of columns the composition occupies on the screen.
 337
 338 When Automatic Composition mode is on, this function also finds a
 339 chunk of text that is automatically composed.  If such a chunk is
 340 found closer to POS than the position that has `composition'
 341 property, the value is a list of FROM, TO, and a glyph-string
 342 that specifies how the chunk is to be composed.  See the function
 343 `composition-get-gstring' for the format of the glyph-string."
 344   (let ((result (find-composition-internal pos limit string detail-p)))
 345     (if (and detail-p (> (length result) 3) (nth 2 result) (not (nth 3 result)))
 346         ;; This is a valid rule-base composition.
 347         (decode-composition-components (nth 2 result) 'nocopy))
 348     result))
 349
 350 \f
 351 (defun compose-chars-after (pos &optional limit object)
 352   "Compose characters in current buffer after position POS.
 353
 354 It looks up the char-table `composition-function-table' (which
 355 see) by a character at POS, and compose characters after POS
 356 according to the contents of `composition-function-table'.
 357
 358 Optional 2nd arg LIMIT, if non-nil, limits characters to compose.
 359
 360 Optional 3rd arg OBJECT, if non-nil, is a string that contains the
 361 text to compose.  In that case, POS and LIMIT index into the string.
 362
 363 This function is the default value of `compose-chars-after-function'."
 364   (let ((tail (aref composition-function-table (char-after pos)))
 365         (font-obj (and (display-multi-font-p)
 366                        (and (not (stringp object))
 367                             (font-at pos (selected-window)))))
 368         pattern func result)
 369     (or limit
 370         (setq limit (if (stringp object) (length object) (point-max))))
 371     (when (and font-obj tail)
 372       (save-match-data
 373         (save-excursion
 374           (while tail
 375             (if (functionp (car tail))
 376                 (setq pattern nil func (car tail))
 377               (setq pattern (car (car tail))
 378                     func (cdr (car tail))))
 379             (goto-char pos)
 380             (if pattern
 381                 (if (and (if (stringp object)
 382                              (eq (string-match pattern object) 0)
 383                            (looking-at pattern))
 384                          (<= (match-end 0) limit))
 385                     (setq result
 386                           (funcall func pos (match-end 0) font-obj object)))
 387               (setq result (funcall func pos limit font-obj  object)))
 388             (if result (setq tail nil))))))
 389     result))
 390
 391 (defun compose-last-chars (args)
 392   "Compose last characters.
 393 The argument is a parameterized event of the form
 394         \(compose-last-chars N COMPONENTS),
 395 where N is the number of characters before point to compose,
 396 COMPONENTS, if non-nil, is the same as the argument to `compose-region'
 397 \(which see).  If it is nil, `compose-chars-after' is called,
 398 and that function finds a proper rule to compose the target characters.
 399 This function is intended to be used from input methods.
 400 The global keymap binds special event `compose-last-chars' to this
 401 function.  Input method may generate an event (compose-last-chars N COMPONENTS)
 402 after a sequence of character events."
 403   (interactive "e")
 404   (let ((chars (nth 1 args)))
 405     (if (and (numberp chars)
 406              (>= (- (point) (point-min)) chars))
 407         (if (nth 2 args)
 408             (compose-region (- (point) chars) (point) (nth 2 args))
 409           (compose-chars-after (- (point) chars) (point))))))
 410
 411 (global-set-key [compose-last-chars] 'compose-last-chars)
 412
 413 \f
 414 ;;; Automatic character composition.
 415
 416 ;; These macros must match with C macros LGSTRING_XXX and LGLYPH_XXX in font.h
 417 (defsubst lgstring-header (gstring) (aref gstring 0))
 418 (defsubst lgstring-set-header (gstring header) (aset gstring 0 header))
 419 (defsubst lgstring-font (gstring) (aref (lgstring-header gstring) 0))
 420 (defsubst lgstring-char (gstring i) (aref (lgstring-header gstring) (1+ i)))
 421 (defsubst lgstring-char-len (gstring) (1- (length (lgstring-header gstring))))
 422 (defsubst lgstring-shaped-p (gstring) (aref gstring 1))
 423 (defsubst lgstring-set-id (gstring id) (aset gstring 1 id))
 424 (defsubst lgstring-glyph (gstring i) (aref gstring (+ i 2)))
 425 (defsubst lgstring-glyph-len (gstring) (- (length gstring) 2))
 426 (defsubst lgstring-set-glyph (gstring i glyph) (aset gstring (+ i 2) glyph))
 427
 428 (defsubst lglyph-from (glyph) (aref glyph 0))
 429 (defsubst lglyph-to (glyph) (aref glyph 1))
 430 (defsubst lglyph-char (glyph) (aref glyph 2))
 431 (defsubst lglyph-code (glyph) (aref glyph 3))
 432 (defsubst lglyph-width (glyph) (aref glyph 4))
 433 (defsubst lglyph-lbearing (glyph) (aref glyph 5))
 434 (defsubst lglyph-rbearing (glyph) (aref glyph 6))
 435 (defsubst lglyph-ascent (glyph) (aref glyph 7))
 436 (defsubst lglyph-descent (glyph) (aref glyph 8))
 437 (defsubst lglyph-adjustment (glyph) (aref glyph 9))
 438
 439 (defsubst lglyph-set-from-to (glyph from to)
 440   (progn (aset glyph 0 from) (aset glyph 1 to)))
 441 (defsubst lglyph-set-char (glyph char) (aset glyph 2 char))
 442 (defsubst lglyph-set-code (glyph code) (aset glyph 3 code))
 443 (defsubst lglyph-set-width (glyph width) (aset glyph 4 width))
 444 (defsubst lglyph-set-adjustment (glyph &optional xoff yoff wadjust)
 445   (aset glyph 9 (vector (or xoff 0) (or yoff 0) (or wadjust 0))))
 446
 447 (defsubst lglyph-copy (glyph) (copy-sequence glyph))
 448
 449 (defun lgstring-insert-glyph (gstring idx glyph)
 450   (let ((nglyphs (lgstring-glyph-len gstring))
 451         (i idx) g)
 452     (while (and (< i nglyphs) (setq g (lgstring-glyph gstring i)))
 453       (setq i (1+ i)))
 454     (if (= i nglyphs)
 455         (setq gstring (vconcat gstring (vector glyph)))
 456       (if (< (1+ i) nglyphs)
 457           (lgstring-set-glyph gstring (1+ i) nil)))
 458     (while (> i idx)
 459       (lgstring-set-glyph gstring i (lgstring-glyph gstring (1- i)))
 460       (setq i (1- i)))
 461     (lgstring-set-glyph gstring i glyph)
 462     gstring))
 463
 464 (defun compose-glyph-string (gstring from to)
 465   (let ((glyph (lgstring-glyph gstring from))
 466         from-pos to-pos
 467         ascent descent lbearing rbearing)
 468     (setq from-pos (lglyph-from glyph)
 469           to-pos (lglyph-to (lgstring-glyph gstring (1- to))))
 470     (lglyph-set-from-to glyph from-pos to-pos)
 471     (setq from (1+ from))
 472     (while (and (< from to)
 473                 (setq glyph (lgstring-glyph gstring from)))
 474       (lglyph-set-from-to glyph from-pos to-pos)
 475       (let ((xoff (if (<= (lglyph-rbearing glyph) 0) 0
 476                     (- (lglyph-width glyph)))))
 477         (lglyph-set-adjustment glyph xoff 0 0))
 478       (setq from (1+ from)))
 479     gstring))
 480
 481 (defun compose-glyph-string-relative (gstring from to &optional gap)
 482   (let ((font-object (lgstring-font gstring))
 483         (glyph (lgstring-glyph gstring from))
 484         from-pos to-pos
 485         ascent descent lbearing rbearing)
 486     (if gap
 487         (setq gap (floor (* (font-get font-object :size) gap)))
 488       (setq gap 0))
 489     (setq from-pos (lglyph-from glyph)
 490           to-pos (lglyph-to (lgstring-glyph gstring (1- to)))
 491           ascent (lglyph-ascent glyph)
 492           descent (lglyph-descent glyph))
 493     (lglyph-set-from-to glyph from-pos to-pos)
 494     (setq from (1+ from))
 495     (while (< from to)
 496       (setq glyph (lgstring-glyph gstring from))
 497       (lglyph-set-from-to glyph from-pos to-pos)
 498       (let ((this-ascent (lglyph-ascent glyph))
 499             (this-descent (lglyph-descent glyph))
 500             xoff yoff wadjust)
 501         (setq xoff (if (<= (lglyph-rbearing glyph) 0) 0
 502                      (- (lglyph-width glyph))))
 503         (if (> this-ascent 0)
 504             (if (< this-descent 0)
 505                 (setq yoff (- 0 ascent gap this-descent)
 506                       ascent (+ ascent gap this-ascent this-descent))
 507               (setq yoff 0))
 508           (setq yoff (+ descent gap this-ascent)
 509                 descent (+ descent gap this-ascent this-descent)))
 510         (if (or (/= xoff 0) (/= yoff 0))
 511             (lglyph-set-adjustment glyph xoff yoff 0)))
 512       (setq from (1+ from)))
 513     gstring))
 514
 515 (defun compose-gstring-for-graphic (gstring)
 516   "Compose glyph-string GSTRING for graphic display.
 517 Combining characters are composed with the preceding base
 518 character.  If the preceding character is not a base character,
 519 each combining character is composed as a spacing character by
 520 a padding space before and/or after the character.
 521
 522 All non-spacing characters have this function in
 523 `composition-function-table' unless overwritten."
 524   (let* ((header (lgstring-header gstring))
 525          (nchars (lgstring-char-len gstring))
 526          (nglyphs (lgstring-glyph-len gstring))
 527          (glyph (lgstring-glyph gstring 0)))
 528     (cond
 529      ;; A non-spacing character not following a proper base character.
 530      ((= nchars 1)
 531       (let ((lbearing (lglyph-lbearing glyph))
 532             (rbearing (lglyph-rbearing glyph))
 533             (width (lglyph-width glyph))
 534             xoff wadjust)
 535         (if (< lbearing 0)
 536             (setq xoff (- lbearing))
 537           (setq xoff 0 lbearing 0))
 538         (if (< rbearing width)
 539             (setq rbearing width))
 540         (lglyph-set-adjustment glyph xoff 0 (- rbearing lbearing))
 541         gstring))
 542
 543      ;; This sequence doesn't start with a proper base character.
 544      ((memq (get-char-code-property (lgstring-char gstring 0)
 545                                     'general-category)
 546             '(Mn Mc Me Zs Zl Zp Cc Cf Cs))
 547       nil)
 548
 549      ;; A base character and the following non-spacing characters.
 550      (t
 551       (let ((gstr (font-shape-gstring gstring)))
 552         (if (and gstr
 553                  (> (lglyph-to (lgstring-glyph gstr 0)) 0))
 554             gstr
 555           ;; The shaper of the font couldn't shape the gstring.
 556           ;; Shape them according to canonical-combining-class.
 557           (lgstring-set-id gstring nil)
 558           (let* ((width (lglyph-width glyph))
 559                  (ascent (lglyph-ascent glyph))
 560                  (descent (lglyph-descent glyph))
 561                  (rbearing (lglyph-rbearing glyph))
 562                  (lbearing (lglyph-lbearing glyph))
 563                  (center (/ (+ lbearing rbearing) 2))
 564                  (gap (round (* (font-get (lgstring-font gstring) :size) 0.1)))
 565                  xoff yoff)
 566             (dotimes (i nchars)
 567               (setq glyph (lgstring-glyph gstring i))
 568               (when (> i 0)
 569                 (let* ((class (get-char-code-property
 570                                (lglyph-char glyph) 'canonical-combining-class))
 571                        (lb (lglyph-lbearing glyph))
 572                        (rb (lglyph-rbearing glyph))
 573                        (as (lglyph-ascent glyph))
 574                        (de (lglyph-descent glyph))
 575                        (ce (/ (+ lb rb) 2))
 576                        xoff yoff)
 577                   (when (and class (>= class 200) (<= class 240))
 578                     (setq xoff 0 yoff 0)
 579                     (cond
 580                      ((= class 200)
 581                       (setq xoff (- lbearing ce)
 582                             yoff (if (> as 0) 0 (+ descent as))))
 583                      ((= class 202)
 584                       (if (> as 0) (setq as 0))
 585                       (setq xoff (- center ce)
 586                             yoff (if (> as 0) 0 (+ descent as))))
 587                      ((= class 204)
 588                       (if (> as 0) (setq as 0))
 589                       (setq xoff (- rbearing ce)
 590                             yoff (if (> as 0) 0 (+ descent as))))
 591                      ((= class 208)
 592                       (setq xoff (- lbearing rb)))
 593                      ((= class 210)
 594                       (setq xoff (- rbearing lb)))
 595                      ((= class 212)
 596                       (setq xoff (- lbearing ce)
 597                             yoff (if (>= de 0) 0 (- (- ascent) de))))
 598                      ((= class 214)
 599                       (setq xoff (- center ce)
 600                             yoff (if (>= de 0) 0 (- (- ascent) de))))
 601                      ((= class 216)
 602                       (setq xoff (- rbearing ce)
 603                             yoff (if (>= de 0) 0 (- (- ascent) de))))
 604                      ((= class 218)
 605                       (setq xoff (- lbearing ce)
 606                             yoff (if (> as 0) 0 (+ descent as gap))))
 607                      ((= class 220)
 608                       (setq xoff (- center ce)
 609                             yoff (if (> as 0) 0 (+ descent as gap))))
 610                      ((= class 222)
 611                       (setq xoff (- rbearing ce)
 612                             yoff (if (> as 0) 0 (+ descent as gap))))
 613                      ((= class 224)
 614                       (setq xoff (- lbearing rb)))
 615                      ((= class 226)
 616                       (setq xoff (- rbearing lb)))
 617                      ((= class 228)
 618                       (setq xoff (- lbearing ce)
 619                             yoff (if (>= de 0) 0 (- (- ascent) de gap))))
 620                      ((= class 230)
 621                       (setq xoff (- center ce)
 622                             yoff (if (>= de 0) 0 (- (- ascent) de gap))))
 623                      ((= class 232)
 624                       (setq xoff (- rbearing ce)
 625                             yoff (if (>= de 0) 0 (- (+ ascent de) gap)))))
 626                     (lglyph-set-adjustment glyph (- xoff width) yoff)
 627                     (setq lb (+ lb xoff)
 628                           rb (+ lb xoff)
 629                           as (- as yoff)
 630                           de (+ de yoff)))
 631                   (if (< ascent as)
 632                       (setq ascent as))
 633                   (if (< descent de)
 634                       (setq descent de))))))
 635           (let ((i 0))
 636             (while (and (< i nglyphs) (setq glyph (lgstring-glyph gstring i)))
 637               (lglyph-set-from-to glyph 0 (1- nchars))
 638               (setq i (1+ i))))
 639           gstring))))))
 640
 641 (let ((elt `([,(purecopy "\\c.\\c^+") 1 compose-gstring-for-graphic]
 642              [nil 0 compose-gstring-for-graphic])))
 643   (map-char-table
 644    #'(lambda (key val)
 645        (if (memq val '(Mn Mc Me))
 646            (set-char-table-range composition-function-table key elt)))
 647    unicode-category-table))
 648
 649 (defun compose-gstring-for-terminal (gstring)
 650   "Compose glyph string GSTRING for terminal display.
 651 Non-spacing characters are composed with the preceding base
 652 character.  If the preceding character is not a base character,
 653 each non-spacing character is composed as a spacing character by
 654 prepending a space before it."
 655   (let* ((header (lgstring-header gstring))
 656          (nchars (lgstring-char-len gstring))
 657          (nglyphs (lgstring-glyph-len gstring))
 658          (i 0)
 659          (coding (lgstring-font gstring))
 660          glyph)
 661     (while (and (< i nglyphs)
 662                 (setq glyph (lgstring-glyph gstring i)))
 663       (if (not (char-charset (lglyph-char glyph) coding))
 664           (progn
 665             ;; As the terminal doesn't support this glyph, return a
 666             ;; gstring in which each glyph is its own graphme-cluster
 667             ;; of width 1..
 668             (setq i 0)
 669             (while (and (< i nglyphs)
 670                         (setq glyph (lgstring-glyph gstring i)))
 671               (if (< (lglyph-width glyph) 1)
 672                   (lglyph-set-width glyph 1))
 673               (lglyph-set-from-to glyph i i)
 674               (setq i (1+ i))))
 675         (if (= (lglyph-width glyph) 0)
 676             (if (eq (get-char-code-property (lglyph-char glyph)
 677                                             'general-category)
 678                     'Cf)
 679                 (progn
 680                   ;; Compose by replacing with a space.
 681                   (lglyph-set-char glyph 32)
 682                   (lglyph-set-width glyph 1)
 683                   (setq i (1+ i)))
 684               ;; Compose by prepending a space.
 685               (setq gstring (lgstring-insert-glyph gstring i
 686                                                    (lglyph-copy glyph))
 687                     nglyphs (lgstring-glyph-len gstring))
 688               (setq glyph (lgstring-glyph gstring i))
 689               (lglyph-set-char glyph 32)
 690               (lglyph-set-width glyph 1)
 691               (setq i (+ 2)))
 692           (let ((from (lglyph-from glyph))
 693                 (to (lglyph-to glyph))
 694                 (j (1+ i)))
 695             (while (and (< j nglyphs)
 696                         (setq glyph (lgstring-glyph gstring j))
 697                         (char-charset (lglyph-char glyph) coding)
 698                         (= (lglyph-width glyph) 0))
 699               (setq to (lglyph-to glyph)
 700                     j (1+ j)))
 701             (while (< i j)
 702               (setq glyph (lgstring-glyph gstring i))
 703               (lglyph-set-from-to glyph from to)
 704               (setq i (1+ i)))))))
 705     gstring))
 706
 707
 708 (defun auto-compose-chars (func from to font-object string)
 709   "Compose the characters at FROM by FUNC.
 710 FUNC is called with one argument GSTRING which is built for characters
 711 in the region FROM (inclusive) and TO (exclusive).
 712
 713 If the character are composed on a graphic display, FONT-OBJECT
 714 is a font to use.  Otherwise, FONT-OBJECT is nil, and the function
 715 `compose-gstring-for-terminal' is used instead of FUNC.
 716
 717 If STRING is non-nil, it is a string, and FROM and TO are indices
 718 into the string.  In that case, compose characters in the string.
 719
 720 The value is a gstring containing information for shaping the characters.
 721
 722 This function is the default value of `auto-composition-function' (which see)."
 723   (let ((gstring (composition-get-gstring from to font-object string)))
 724     (if (lgstring-shaped-p gstring)
 725         gstring
 726       (or (fontp font-object 'font-object)
 727           (setq func 'compose-gstring-for-terminal))
 728       (funcall func gstring))))
 729
 730 (put 'auto-composition-mode 'permanent-local t)
 731
 732 (make-variable-buffer-local 'auto-composition-function)
 733 (setq-default auto-composition-function 'auto-compose-chars)
 734
 735 ;;;###autoload
 736 (define-minor-mode auto-composition-mode
 737   "Toggle Auto Composition mode.
 738 With ARG, turn Auto Composition mode off if and only if ARG is a non-positive
 739 number; if ARG is nil, toggle Auto Composition mode; anything else turns Auto
 740 Composition on.
 741
 742 When Auto Composition is enabled, text characters are automatically composed
 743 by functions registered in `composition-function-table' (which see).
 744
 745 You can use `global-auto-composition-mode' to turn on
 746 Auto Composition mode in all buffers (this is the default).")
 747
 748 ;;;###autoload
 749 (define-minor-mode global-auto-composition-mode
 750   "Toggle Auto-Composition mode in every possible buffer.
 751 With prefix arg, turn Global-Auto-Composition mode on if and only if arg
 752 is positive.
 753 See `auto-composition-mode' for more information on Auto-Composition mode."
 754   :variable (default-value 'auto-composition-mode))
 755
 756 (defalias 'toggle-auto-composition 'auto-composition-mode)
 757
 758 \f
 759
 760 ;; arch-tag: ee703d77-1723-45d4-a31f-e9f0f867aa33
 761 ;;; composite.el ends here