lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This file contains a VC backend for the git version control
  26 ;; system.
  27 ;;
  28
  29 ;;; Installation:
  30
  31 ;; To install: put this file on the load-path and add Git to the list
  32 ;; of supported backends in `vc-handled-backends'; the following line,
  33 ;; placed in your ~/.emacs, will accomplish this:
  34 ;;
  35 ;;     (add-to-list 'vc-handled-backends 'Git)
  36
  37 ;;; Todo:
  38 ;;  - check if more functions could use vc-git-command instead
  39 ;;     of start-process.
  40 ;;  - changelog generation
  41
  42 ;; Implement the rest of the vc interface. See the comment at the
  43 ;; beginning of vc.el. The current status is:
  44 ;; ("??" means: "figure out what to do about it")
  45 ;;
  46 ;; FUNCTION NAME                        STATUS
  47 ;; BACKEND PROPERTIES
  48 ;; * revision-granularity                      OK
  49 ;; STATE-QUERYING FUNCTIONS
  50 ;; * registered (file)                     OK
  51 ;; * state (file)                                  OK
  52 ;; - state-heuristic (file)                        NOT NEEDED
  53 ;; * working-revision (file)               OK
  54 ;; - latest-on-branch-p (file)             NOT NEEDED
  55 ;; * checkout-model (files)                OK
  56 ;; - workfile-unchanged-p (file)                   OK
  57 ;; - mode-line-string (file)                       OK
  58 ;; STATE-CHANGING FUNCTIONS
  59 ;; * create-repo ()                        OK
  60 ;; * register (files &optional rev comment)    OK
  61 ;; - init-revision (file)                          NOT NEEDED
  62 ;; - responsible-p (file)                          OK
  63 ;; - could-register (file)                         NOT NEEDED, DEFAULT IS GOOD
  64 ;; - receive-file (file rev)                       NOT NEEDED
  65 ;; - unregister (file)                     OK
  66 ;; * checkin (files rev comment)                   OK
  67 ;; * find-revision (file rev buffer)               OK
  68 ;; * checkout (file &optional editable rev)        OK
  69 ;; * revert (file &optional contents-done)         OK
  70 ;; - rollback (files)                      COULD BE SUPPORTED
  71 ;; - merge (file rev1 rev2)                   It would be possible to merge
  72 ;;                                          changes into a single file, but when
  73 ;;                                          committing they wouldn't
  74 ;;                                          be identified as a merge
  75 ;;                                          by git, so it's probably
  76 ;;                                          not a good idea.
  77 ;; - merge-news (file)                     see `merge'
  78 ;; - steal-lock (file &optional revision)          NOT NEEDED
  79 ;; HISTORY FUNCTIONS
  80 ;; * print-log (files &optional buffer)            OK
  81 ;; - log-view-mode ()                              OK
  82 ;; - show-log-entry (revision)                     OK
  83 ;; - comment-history (file)                        ??
  84 ;; - update-changelog (files)                      COULD BE SUPPORTED
  85 ;; * diff (file &optional rev1 rev2 buffer)                OK
  86 ;; - revision-completion-table (files)             OK
  87 ;; - annotate-command (file buf &optional rev)     OK
  88 ;; - annotate-time ()                              OK
  89 ;; - annotate-current-time ()                      NOT NEEDED
  90 ;; - annotate-extract-revision-at-line ()                  OK
  91 ;; TAG SYSTEM
  92 ;; - create-tag (dir name branchp)         OK
  93 ;; - retrieve-tag (dir name update)        OK, needs to update buffers
  94 ;; MISCELLANEOUS
  95 ;; - make-version-backups-p (file)         NOT NEEDED
  96 ;; - repository-hostname (dirname)         NOT NEEDED
  97 ;; - previous-revision (file rev)                  OK
  98 ;; - next-revision (file rev)              OK
  99 ;; - check-headers ()                      COULD BE SUPPORTED
 100 ;; - clear-headers ()                      NOT NEEDED
 101 ;; - delete-file (file)                    OK
 102 ;; - rename-file (old new)                 OK
 103 ;; - find-file-hook ()                     NOT NEEDED
 104
 105 (eval-when-compile
 106   (require 'cl)
 107   (require 'vc)
 108   (require 'vc-dir)
 109   (require 'grep))
 110
 111 (defcustom vc-git-diff-switches t
 112   "String or list of strings specifying switches for Git diff under VC.
 113 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
 114   :type '(choice (const :tag "Unspecified" nil)
 115                  (const :tag "None" t)
 116                  (string :tag "Argument String")
 117                  (repeat :tag "Argument List" :value ("") string))
 118   :version "23.1"
 119   :group 'vc)
 120
 121 (defcustom vc-git-add-signoff nil
 122   "Add a Signed-off-by line when committing."
 123   :type 'boolean
 124   :version "23.2"
 125   :group 'vc)
 126
 127
 128 (defvar git-commits-coding-system 'utf-8
 129   "Default coding system for git commits.")
 130
 131 ;;; BACKEND PROPERTIES
 132
 133 (defun vc-git-revision-granularity () 'repository)
 134 (defun vc-git-checkout-model (files) 'implicit)
 135
 136 ;;; STATE-QUERYING FUNCTIONS
 137
 138 ;;;###autoload (defun vc-git-registered (file)
 139 ;;;###autoload   "Return non-nil if FILE is registered with git."
 140 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 141 ;;;###autoload       (progn
 142 ;;;###autoload         (load "vc-git")
 143 ;;;###autoload         (vc-git-registered file))))
 144
 145 (defun vc-git-registered (file)
 146   "Check whether FILE is registered with git."
 147   (when (vc-git-root file)
 148     (with-temp-buffer
 149       (let* (process-file-side-effects
 150              (dir (file-name-directory file))
 151              (name (file-relative-name file dir))
 152              (str (ignore-errors
 153                     (when dir (cd dir))
 154                     (vc-git--out-ok "ls-files" "-c" "-z" "--" name)
 155                     ;; if result is empty, use ls-tree to check for deleted file
 156                     (when (eq (point-min) (point-max))
 157                       (vc-git--out-ok "ls-tree" "--name-only" "-z" "HEAD" "--" name))
 158                     (buffer-string))))
 159         (and str
 160              (> (length str) (length name))
 161              (string= (substring str 0 (1+ (length name)))
 162                       (concat name "\0")))))))
 163
 164 (defun vc-git--state-code (code)
 165   "Convert from a string to a added/deleted/modified state."
 166   (case (string-to-char code)
 167     (?M 'edited)
 168     (?A 'added)
 169     (?D 'removed)
 170     (?U 'edited)     ;; FIXME
 171     (?T 'edited)))   ;; FIXME
 172
 173 (defun vc-git-state (file)
 174   "Git-specific version of `vc-state'."
 175   ;; FIXME: This can't set 'ignored yet
 176   (if (not (vc-git-registered file))
 177       'unregistered
 178     (vc-git--call nil "add" "--refresh" "--" (file-relative-name file))
 179     (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 180       (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\([ADMUT]\\)\0[^\0]+\0"
 181                                   diff))
 182           (vc-git--state-code (match-string 1 diff))
 183         (if (vc-git--empty-db-p) 'added 'up-to-date)))))
 184
 185 (defun vc-git-working-revision (file)
 186   "Git-specific version of `vc-working-revision'."
 187   (let* (process-file-side-effects
 188          (str (with-output-to-string
 189                 (with-current-buffer standard-output
 190                   (vc-git--out-ok "symbolic-ref" "HEAD")))))
 191     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 192         (match-string 2 str)
 193       str)))
 194
 195 (defun vc-git-workfile-unchanged-p (file)
 196   (eq 'up-to-date (vc-git-state file)))
 197
 198 (defun vc-git-mode-line-string (file)
 199   "Return string for placement into the modeline for FILE."
 200   (let* ((branch (vc-git-working-revision file))
 201          (def-ml (vc-default-mode-line-string 'Git file))
 202          (help-echo (get-text-property 0 'help-echo def-ml)))
 203     (if (zerop (length branch))
 204         (propertize
 205          (concat def-ml "!")
 206          'help-echo (concat help-echo "\nNo current branch (detached HEAD)"))
 207       (propertize def-ml
 208                   'help-echo (concat help-echo "\nCurrent branch: " branch)))))
 209
 210 (defstruct (vc-git-extra-fileinfo
 211             (:copier nil)
 212             (:constructor vc-git-create-extra-fileinfo (old-perm new-perm &optional rename-state orig-name))
 213             (:conc-name vc-git-extra-fileinfo->))
 214   old-perm new-perm   ;; permission flags
 215   rename-state        ;; rename or copy state
 216   orig-name)          ;; original name for renames or copies
 217
 218 (defun vc-git-escape-file-name (name)
 219   "Escape a file name if necessary."
 220   (if (string-match "[\n\t\"\\]" name)
 221       (concat "\""
 222               (mapconcat (lambda (c)
 223                    (case c
 224                      (?\n "\\n")
 225                      (?\t "\\t")
 226                      (?\\ "\\\\")
 227                      (?\" "\\\"")
 228                      (t (char-to-string c))))
 229                  name "")
 230               "\"")
 231     name))
 232
 233 (defun vc-git-file-type-as-string (old-perm new-perm)
 234   "Return a string describing the file type based on its permissions."
 235   (let* ((old-type (lsh (or old-perm 0) -9))
 236          (new-type (lsh (or new-perm 0) -9))
 237          (str (case new-type
 238                 (?\100  ;; file
 239                  (case old-type
 240                    (?\100 nil)
 241                    (?\120 "   (type change symlink -> file)")
 242                    (?\160 "   (type change subproject -> file)")))
 243                  (?\120  ;; symlink
 244                   (case old-type
 245                     (?\100 "   (type change file -> symlink)")
 246                     (?\160 "   (type change subproject -> symlink)")
 247                     (t "   (symlink)")))
 248                   (?\160  ;; subproject
 249                    (case old-type
 250                      (?\100 "   (type change file -> subproject)")
 251                      (?\120 "   (type change symlink -> subproject)")
 252                      (t "   (subproject)")))
 253                   (?\110 nil)  ;; directory (internal, not a real git state)
 254                   (?\000  ;; deleted or unknown
 255                    (case old-type
 256                      (?\120 "   (symlink)")
 257                      (?\160 "   (subproject)")))
 258                   (t (format "   (unknown type %o)" new-type)))))
 259     (cond (str (propertize str 'face 'font-lock-comment-face))
 260           ((eq new-type ?\110) "/")
 261           (t ""))))
 262
 263 (defun vc-git-rename-as-string (state extra)
 264   "Return a string describing the copy or rename associated with INFO, or an empty string if none."
 265   (let ((rename-state (when extra
 266                         (vc-git-extra-fileinfo->rename-state extra))))
 267     (if rename-state
 268         (propertize
 269          (concat "   ("
 270                  (if (eq rename-state 'copy) "copied from "
 271                    (if (eq state 'added) "renamed from "
 272                      "renamed to "))
 273                  (vc-git-escape-file-name (vc-git-extra-fileinfo->orig-name extra))
 274                  ")") 'face 'font-lock-comment-face)
 275       "")))
 276
 277 (defun vc-git-permissions-as-string (old-perm new-perm)
 278   "Format a permission change as string."
 279   (propertize
 280    (if (or (not old-perm)
 281            (not new-perm)
 282            (eq 0 (logand ?\111 (logxor old-perm new-perm))))
 283        "  "
 284      (if (eq 0 (logand ?\111 old-perm)) "+x" "-x"))
 285   'face 'font-lock-type-face))
 286
 287 (defun vc-git-dir-printer (info)
 288   "Pretty-printer for the vc-dir-fileinfo structure."
 289   (let* ((isdir (vc-dir-fileinfo->directory info))
 290          (state (if isdir "" (vc-dir-fileinfo->state info)))
 291          (extra (vc-dir-fileinfo->extra info))
 292          (old-perm (when extra (vc-git-extra-fileinfo->old-perm extra)))
 293          (new-perm (when extra (vc-git-extra-fileinfo->new-perm extra))))
 294     (insert
 295      "  "
 296      (propertize (format "%c" (if (vc-dir-fileinfo->marked info) ?* ? ))
 297                  'face 'font-lock-type-face)
 298      "  "
 299      (propertize
 300       (format "%-12s" state)
 301       'face (cond ((eq state 'up-to-date) 'font-lock-builtin-face)
 302                   ((eq state 'missing) 'font-lock-warning-face)
 303                   (t 'font-lock-variable-name-face))
 304       'mouse-face 'highlight)
 305      "  " (vc-git-permissions-as-string old-perm new-perm)
 306      "    "
 307      (propertize (vc-git-escape-file-name (vc-dir-fileinfo->name info))
 308                  'face (if isdir 'font-lock-comment-delimiter-face 'font-lock-function-name-face)
 309                  'help-echo
 310                  (if isdir
 311                      "Directory\nVC operations can be applied to it\nmouse-3: Pop-up menu"
 312                    "File\nmouse-3: Pop-up menu")
 313                  'keymap vc-dir-filename-mouse-map
 314                  'mouse-face 'highlight)
 315      (vc-git-file-type-as-string old-perm new-perm)
 316      (vc-git-rename-as-string state extra))))
 317
 318 (defun vc-git-after-dir-status-stage (stage files update-function)
 319   "Process sentinel for the various dir-status stages."
 320   (let (remaining next-stage result)
 321     (goto-char (point-min))
 322     (case stage
 323       ('update-index
 324        (setq next-stage (if (vc-git--empty-db-p) 'ls-files-added
 325                           (if files 'ls-files-up-to-date 'diff-index))))
 326       ('ls-files-added
 327        (setq next-stage 'ls-files-unknown)
 328        (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 329          (let ((new-perm (string-to-number (match-string 1) 8))
 330                (name (match-string 2)))
 331            (push (list name 'added (vc-git-create-extra-fileinfo 0 new-perm)) result))))
 332       ('ls-files-up-to-date
 333        (setq next-stage 'diff-index)
 334        (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 335          (let ((perm (string-to-number (match-string 1) 8))
 336                (name (match-string 2)))
 337            (push (list name 'up-to-date (vc-git-create-extra-fileinfo perm perm)) result))))
 338       ('ls-files-unknown
 339        (when files (setq next-stage 'ls-files-ignored))
 340        (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 341          (push (list (match-string 1) 'unregistered (vc-git-create-extra-fileinfo 0 0)) result)))
 342       ('ls-files-ignored
 343        (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 344          (push (list (match-string 1) 'ignored (vc-git-create-extra-fileinfo 0 0)) result)))
 345       ('diff-index
 346        (setq next-stage 'ls-files-unknown)
 347        (while (re-search-forward
 348                ":\\([0-7]\\{6\\}\\) \\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\(\\([ADMUT]\\)\0\\([^\0]+\\)\\|\\([CR]\\)[0-9]*\0\\([^\0]+\\)\0\\([^\0]+\\)\\)\0"
 349                nil t 1)
 350          (let ((old-perm (string-to-number (match-string 1) 8))
 351                (new-perm (string-to-number (match-string 2) 8))
 352                (state (or (match-string 4) (match-string 6)))
 353                (name (or (match-string 5) (match-string 7)))
 354                (new-name (match-string 8)))
 355            (if new-name  ; copy or rename
 356                (if (eq ?C (string-to-char state))
 357                    (push (list new-name 'added (vc-git-create-extra-fileinfo old-perm new-perm 'copy name)) result)
 358                  (push (list name 'removed (vc-git-create-extra-fileinfo 0 0 'rename new-name)) result)
 359                  (push (list new-name 'added (vc-git-create-extra-fileinfo old-perm new-perm 'rename name)) result))
 360              (push (list name (vc-git--state-code state) (vc-git-create-extra-fileinfo old-perm new-perm)) result))))))
 361     (when result
 362       (setq result (nreverse result))
 363       (when files
 364         (dolist (entry result) (setq files (delete (car entry) files)))
 365         (unless files (setq next-stage nil))))
 366     (when (or result (not next-stage)) (funcall update-function result next-stage))
 367     (when next-stage (vc-git-dir-status-goto-stage next-stage files update-function))))
 368
 369 (defun vc-git-dir-status-goto-stage (stage files update-function)
 370   (erase-buffer)
 371   (case stage
 372     ('update-index
 373      (if files
 374          (vc-git-command (current-buffer) 'async files "add" "--refresh" "--")
 375        (vc-git-command (current-buffer) 'async nil "update-index" "--refresh")))
 376     ('ls-files-added
 377      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-c" "-s" "--"))
 378     ('ls-files-up-to-date
 379      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-c" "-s" "--"))
 380     ('ls-files-unknown
 381      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-o"
 382                      "--directory" "--no-empty-directory" "--exclude-standard" "--"))
 383     ('ls-files-ignored
 384      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-o" "-i"
 385                      "--directory" "--no-empty-directory" "--exclude-standard" "--"))
 386     ('diff-index
 387      (vc-git-command (current-buffer) 'async files "diff-index" "-z" "-M" "HEAD" "--")))
 388   (vc-exec-after
 389    `(vc-git-after-dir-status-stage (quote ,stage) (quote ,files) (quote ,update-function))))
 390
 391 (defun vc-git-dir-status (dir update-function)
 392   "Return a list of (FILE STATE EXTRA) entries for DIR."
 393   ;; Further things that would have to be fixed later:
 394   ;; - how to handle unregistered directories
 395   ;; - how to support vc-dir on a subdir of the project tree
 396   (vc-git-dir-status-goto-stage 'update-index nil update-function))
 397
 398 (defun vc-git-dir-status-files (dir files default-state update-function)
 399   "Return a list of (FILE STATE EXTRA) entries for FILES in DIR."
 400   (vc-git-dir-status-goto-stage 'update-index files update-function))
 401
 402 (defun vc-git-dir-extra-headers (dir)
 403   (let ((str (with-output-to-string
 404                (with-current-buffer standard-output
 405                  (vc-git--out-ok "symbolic-ref" "HEAD"))))
 406         (stash (vc-git-stash-list)))
 407     ;; FIXME: maybe use a different face when nothing is stashed.
 408     (when (string= stash "") (setq stash "Nothing stashed"))
 409     (concat
 410      (propertize "Branch     : " 'face 'font-lock-type-face)
 411      (propertize
 412       (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 413           (match-string 2 str)
 414         "not (detached HEAD)")
 415        'face 'font-lock-variable-name-face)
 416      "\n"
 417      (propertize "Stash      : " 'face 'font-lock-type-face)
 418      (propertize
 419       stash
 420        'face 'font-lock-variable-name-face))))
 421
 422 ;;; STATE-CHANGING FUNCTIONS
 423
 424 (defun vc-git-create-repo ()
 425   "Create a new Git repository."
 426   (vc-git-command nil 0 nil "init"))
 427
 428 (defun vc-git-register (files &optional rev comment)
 429   "Register FILE into the git version-control system."
 430   (vc-git-command nil 0 files "update-index" "--add" "--"))
 431
 432 (defalias 'vc-git-responsible-p 'vc-git-root)
 433
 434 (defun vc-git-unregister (file)
 435   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 436
 437
 438 (defun vc-git-checkin (files rev comment)
 439   (let ((coding-system-for-write git-commits-coding-system))
 440     (vc-git-command nil 0 files "commit"
 441                     (if vc-git-add-signoff "-s") "-m" comment "--only" "--")))
 442
 443 (defun vc-git-find-revision (file rev buffer)
 444   (let* (process-file-side-effects
 445          (coding-system-for-read 'binary)
 446          (coding-system-for-write 'binary)
 447          (fullname (substring
 448                     (vc-git--run-command-string
 449                      file "ls-files" "-z" "--full-name" "--")
 450                     0 -1)))
 451     (vc-git-command
 452      buffer 0
 453      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 454
 455 (defun vc-git-checkout (file &optional editable rev)
 456   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 457
 458 (defun vc-git-revert (file &optional contents-done)
 459   "Revert FILE to the version stored in the git repository."
 460   (if contents-done
 461       (vc-git-command nil 0 file "update-index" "--")
 462     (vc-git-command nil 0 file "checkout" "HEAD")))
 463
 464 ;;; HISTORY FUNCTIONS
 465
 466 (defun vc-git-print-log (files &optional buffer)
 467   "Get change log associated with FILES."
 468   (let ((coding-system-for-read git-commits-coding-system)
 469         ;; Support both the old print-log interface that passes a
 470         ;; single file, and the new one that passes a file list.
 471         (flist (if (listp files) files (list files))))
 472     ;; `vc-do-command' creates the buffer, but we need it before running
 473     ;; the command.
 474     (vc-setup-buffer buffer)
 475     ;; If the buffer exists from a previous invocation it might be
 476     ;; read-only.
 477     (let ((inhibit-read-only t))
 478       (with-current-buffer
 479           buffer
 480         (vc-git-command buffer 'async files
 481                         "rev-list" "--pretty" "HEAD" "--")))))
 482
 483 (defvar log-view-message-re)
 484 (defvar log-view-file-re)
 485 (defvar log-view-font-lock-keywords)
 486 (defvar log-view-per-file-logs)
 487
 488 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 489   (require 'add-log) ;; we need the faces add-log
 490   ;; Don't have file markers, so use impossible regexp.
 491   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 492   (set (make-local-variable 'log-view-per-file-logs) nil)
 493   (set (make-local-variable 'log-view-message-re)
 494        "^commit *\\([0-9a-z]+\\)")
 495   (set (make-local-variable 'log-view-font-lock-keywords)
 496        (append
 497         `((,log-view-message-re  (1 'change-log-acknowledgement)))
 498         ;; Handle the case:
 499         ;; user: foo@bar
 500         '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 501            (1 'change-log-email))
 502           ;; Handle the case:
 503           ;; user: FirstName LastName <foo@bar>
 504           ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 505            (1 'change-log-name)
 506            (2 'change-log-email))
 507           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 508            (1 'change-log-name))
 509           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 510            (1 'change-log-name)
 511            (2 'change-log-email))
 512           ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
 513            (1 'change-log-acknowledgement)
 514            (2 'change-log-acknowledgement))
 515           ("^Date:   \\(.+\\)" (1 'change-log-date))
 516           ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 517
 518 (defun vc-git-show-log-entry (revision)
 519   "Move to the log entry for REVISION.
 520 REVISION may have the form BRANCH, BRANCH~N,
 521 or BRANCH^ (where \"^\" can be repeated)."
 522   (goto-char (point-min))
 523   (when revision
 524     (search-forward (format "\ncommit %s" revision) nil t
 525                     (cond ((string-match "~\\([0-9]\\)$" revision)
 526                            (1+ (string-to-number (match-string 1 revision))))
 527                           ((string-match "\\^+$" revision)
 528                            (1+ (length (match-string 0 revision))))
 529                           (t nil))))
 530   (beginning-of-line))
 531
 532 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 533   "Get a difference report using Git between two revisions of FILES."
 534   (let (process-file-side-effects)
 535     (apply #'vc-git-command (or buffer "*vc-diff*") 1 files
 536            (if (and rev1 rev2) "diff-tree" "diff-index")
 537            "--exit-code"
 538            (append (vc-switches 'git 'diff)
 539                    (list "-p" (or rev1 "HEAD") rev2 "--")))))
 540
 541 (defun vc-git-revision-table (files)
 542   ;; What about `files'?!?  --Stef
 543   (let (process-file-side-effects
 544         (table (list "HEAD")))
 545     (with-temp-buffer
 546       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
 547       (goto-char (point-min))
 548       (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
 549         (push (match-string 2) table)))
 550     table))
 551
 552 (defun vc-git-revision-completion-table (files)
 553   (lexical-let ((files files)
 554                 table)
 555     (setq table (lazy-completion-table
 556                  table (lambda () (vc-git-revision-table files))))
 557     table))
 558
 559 (defun vc-git-annotate-command (file buf &optional rev)
 560   (let ((name (file-relative-name file)))
 561     (vc-git-command buf 'async name "blame" "--date=iso" rev)))
 562
 563 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 564
 565 (defun vc-git-annotate-time ()
 566   (and (re-search-forward "[0-9a-f]+[^()]+(.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+) " nil t)
 567        (vc-annotate-convert-time
 568         (apply #'encode-time (mapcar (lambda (match)
 569                                        (string-to-number (match-string match)))
 570                                      '(6 5 4 3 2 1 7))))))
 571
 572 (defun vc-git-annotate-extract-revision-at-line ()
 573   (save-excursion
 574     (move-beginning-of-line 1)
 575     (and (looking-at "[0-9a-f^][0-9a-f]+")
 576          (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
 577
 578 ;;; TAG SYSTEM
 579
 580 (defun vc-git-create-tag (dir name branchp)
 581   (let ((default-directory dir))
 582     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 583          (if branchp
 584              (vc-git-command nil 0 nil "checkout" "-b" name)
 585            (vc-git-command nil 0 nil "tag" name)))))
 586
 587 (defun vc-git-retrieve-tag (dir name update)
 588   (let ((default-directory dir))
 589     (vc-git-command nil 0 nil "checkout" name)
 590     ;; FIXME: update buffers if `update' is true
 591     ))
 592
 593
 594 ;;; MISCELLANEOUS
 595
 596 (defun vc-git-previous-revision (file rev)
 597   "Git-specific version of `vc-previous-revision'."
 598   (if file
 599       (let* ((default-directory (file-name-directory (expand-file-name file)))
 600              (file (file-name-nondirectory file))
 601              (prev-rev (with-temp-buffer
 602                          (and
 603                           (vc-git--out-ok "rev-list" "-2" rev "--" file)
 604                           (goto-char (point-max))
 605                           (bolp)
 606                           (zerop (forward-line -1))
 607                           (not (bobp))
 608                           (buffer-substring-no-properties
 609                            (point)
 610                            (1- (point-max)))))))
 611         (or (vc-git-symbolic-commit prev-rev) prev-rev))
 612     (with-temp-buffer
 613       (and
 614        (vc-git--out-ok "rev-parse" (concat rev "^"))
 615        (buffer-substring-no-properties (point-min) (+ (point-min) 40))))))
 616
 617 (defun vc-git-next-revision (file rev)
 618   "Git-specific version of `vc-next-revision'."
 619   (let* ((default-directory (file-name-directory
 620                              (expand-file-name file)))
 621          (file (file-name-nondirectory file))
 622          (current-rev
 623           (with-temp-buffer
 624             (and
 625              (vc-git--out-ok "rev-list" "-1" rev "--" file)
 626              (goto-char (point-max))
 627              (bolp)
 628              (zerop (forward-line -1))
 629              (bobp)
 630              (buffer-substring-no-properties
 631               (point)
 632               (1- (point-max))))))
 633          (next-rev
 634           (and current-rev
 635                (with-temp-buffer
 636                  (and
 637                   (vc-git--out-ok "rev-list" "HEAD" "--" file)
 638                   (goto-char (point-min))
 639                   (search-forward current-rev nil t)
 640                   (zerop (forward-line -1))
 641                   (buffer-substring-no-properties
 642                    (point)
 643                    (progn (forward-line 1) (1- (point)))))))))
 644     (or (vc-git-symbolic-commit next-rev) next-rev)))
 645
 646 (defun vc-git-delete-file (file)
 647   (vc-git-command nil 0 file "rm" "-f" "--"))
 648
 649 (defun vc-git-rename-file (old new)
 650   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 651
 652 (defvar vc-git-extra-menu-map
 653   (let ((map (make-sparse-keymap)))
 654     (define-key map [git-grep]
 655       '(menu-item "Git grep..." vc-git-grep
 656                   :help "Run the `git grep' command"))
 657     (define-key map [git-sig]
 658       '(menu-item "Add Signed-off-by on commit" vc-git-toggle-signoff
 659               :help "Add Add Signed-off-by when commiting (i.e. add the -s flag)"
 660               :button (:toggle . vc-git-add-signoff)))
 661     map))
 662
 663 (defun vc-git-extra-menu () vc-git-extra-menu-map)
 664
 665 (defun vc-git-extra-status-menu () vc-git-extra-menu-map)
 666
 667 (defun vc-git-toggle-signoff ()
 668   (interactive)
 669   (setq vc-git-add-signoff (not vc-git-add-signoff)))
 670
 671 ;; Derived from `lgrep'.
 672 (defun vc-git-grep (regexp &optional files dir)
 673   "Run git grep, searching for REGEXP in FILES in directory DIR.
 674 The search is limited to file names matching shell pattern FILES.
 675 FILES may use abbreviations defined in `grep-files-aliases', e.g.
 676 entering `ch' is equivalent to `*.[ch]'.
 677
 678 With \\[universal-argument] prefix, you can edit the constructed shell command line
 679 before it is executed.
 680 With two \\[universal-argument] prefixes, directly edit and run `grep-command'.
 681
 682 Collect output in a buffer.  While git grep runs asynchronously, you
 683 can use \\[next-error] (M-x next-error), or \\<grep-mode-map>\\[compile-goto-error] \
 684 in the grep output buffer,
 685 to go to the lines where grep found matches.
 686
 687 This command shares argument histories with \\[rgrep] and \\[grep]."
 688   (interactive
 689    (progn
 690      (grep-compute-defaults)
 691      (cond
 692       ((equal current-prefix-arg '(16))
 693        (list (read-from-minibuffer "Run: " "git grep"
 694                                    nil nil 'grep-history)
 695              nil))
 696       (t (let* ((regexp (grep-read-regexp))
 697                 (files (grep-read-files regexp))
 698                 (dir (read-directory-name "In directory: "
 699                                           nil default-directory t)))
 700            (list regexp files dir))))))
 701   (require 'grep)
 702   (when (and (stringp regexp) (> (length regexp) 0))
 703     (let ((command regexp))
 704       (if (null files)
 705           (if (string= command "git grep")
 706               (setq command nil))
 707         (setq dir (file-name-as-directory (expand-file-name dir)))
 708         (setq command
 709               (grep-expand-template "git grep -n -e <R> -- <F>" regexp files))
 710         (when command
 711           (if (equal current-prefix-arg '(4))
 712               (setq command
 713                     (read-from-minibuffer "Confirm: "
 714                                           command nil nil 'grep-history))
 715             (add-to-history 'grep-history command))))
 716       (when command
 717         (let ((default-directory dir)
 718               (compilation-environment '("PAGER=")))
 719           ;; Setting process-setup-function makes exit-message-function work
 720           ;; even when async processes aren't supported.
 721           (compilation-start command 'grep-mode))
 722         (if (eq next-error-last-buffer (current-buffer))
 723             (setq default-directory dir))))))
 724
 725 (defun vc-git-stash-list ()
 726   (replace-regexp-in-string
 727    "\n" "\n             "
 728    (replace-regexp-in-string
 729     "^stash@" "" (vc-git--run-command-string nil "stash" "list"))))
 730
 731 \f
 732 ;;; Internal commands
 733
 734 (defun vc-git-root (file)
 735   (vc-find-root file ".git"))
 736
 737 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 738   "A wrapper around `vc-do-command' for use in vc-git.el.
 739 The difference to vc-do-command is that this function always invokes `git'."
 740   (apply 'vc-do-command (or buffer "*vc*") okstatus "git" file-or-list flags))
 741
 742 (defun vc-git--empty-db-p ()
 743   "Check if the git db is empty (no commit done yet)."
 744   (let (process-file-side-effects)
 745     (not (eq 0 (vc-git--call nil "rev-parse" "--verify" "HEAD")))))
 746
 747 (defun vc-git--call (buffer command &rest args)
 748   ;; We don't need to care the arguments.  If there is a file name, it
 749   ;; is always a relative one.  This works also for remote
 750   ;; directories.
 751   (apply 'process-file "git" nil buffer nil command args))
 752
 753 (defun vc-git--out-ok (command &rest args)
 754   (zerop (apply 'vc-git--call '(t nil) command args)))
 755
 756 (defun vc-git--run-command-string (file &rest args)
 757   "Run a git command on FILE and return its output as string.
 758 FILE can be nil."
 759   (let* ((ok t)
 760          (str (with-output-to-string
 761                 (with-current-buffer standard-output
 762                   (unless (apply 'vc-git--out-ok
 763                                  (if file
 764                                      (append args (list (file-relative-name
 765                                                          file)))
 766                                    args))
 767                     (setq ok nil))))))
 768     (and ok str)))
 769
 770 (defun vc-git-symbolic-commit (commit)
 771   "Translate COMMIT string into symbolic form.
 772 Returns nil if not possible."
 773   (and commit
 774        (let ((name (with-temp-buffer
 775                      (and
 776                       (vc-git--out-ok "name-rev" "--name-only" commit)
 777                       (goto-char (point-min))
 778                       (= (forward-line 2) 1)
 779                       (bolp)
 780                       (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 781          (and name (not (string= name "undefined")) name))))
 782
 783 (provide 'vc-git)
 784
 785 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 786 ;;; vc-git.el ends here