lisp/whitespace.el

   1 ;;; whitespace.el --- warn about and clean bogus whitespaces in the file
   2
   3 ;; Copyright (C) 1999, 2000, 2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Rajesh Vaidheeswarran <rv@gnu.org>
   6 ;; Keywords: convenience
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26 ;;
  27 ;; URL: http://www.dsmit.com/lisp/
  28 ;;
  29 ;; The whitespace library is intended to find and help fix five different types
  30 ;; of whitespace problems that commonly exist in source code.
  31 ;;
  32 ;; 1. Leading space (empty lines at the top of a file).
  33 ;; 2. Trailing space (empty lines at the end of a file).
  34 ;; 3. Indentation space (8 or more spaces at beginning of line, that should be
  35 ;;                    replaced with TABS).
  36 ;; 4. Spaces followed by a TAB.  (Almost always, we never want that).
  37 ;; 5. Spaces or TABS at the end of a line.
  38 ;;
  39 ;; Whitespace errors are reported in a buffer, and on the modeline.
  40 ;;
  41 ;; Modeline will show a W:<x>!<y> to denote a particular type of whitespace,
  42 ;; where `x' and `y' can be one (or more) of:
  43 ;;
  44 ;; e - End-of-Line whitespace.
  45 ;; i - Indentation whitespace.
  46 ;; l - Leading whitespace.
  47 ;; s - Space followed by Tab.
  48 ;; t - Trailing whitespace.
  49 ;;
  50 ;; If any of the whitespace checks is turned off, the modeline will display a
  51 ;; !<y>.
  52 ;;
  53 ;;     (since (3) is the most controversial one, here is the rationale: Most
  54 ;;     terminal drivers and printer drivers have TAB configured or even
  55 ;;     hardcoded to be 8 spaces.  (Some of them allow configuration, but almost
  56 ;;     always they default to 8.)
  57 ;;
  58 ;;     Changing `tab-width' to other than 8 and editing will cause your code to
  59 ;;     look different from within Emacs, and say, if you cat it or more it, or
  60 ;;     even print it.
  61 ;;
  62 ;;     Almost all the popular programming modes let you define an offset (like
  63 ;;     c-basic-offset or perl-indent-level) to configure the offset, so you
  64 ;;     should never have to set your `tab-width' to be other than 8 in all
  65 ;;     these modes.  In fact, with an indent level of say, 4, 2 TABS will cause
  66 ;;     Emacs to replace your 8 spaces with one \t (try it).  If vi users in
  67 ;;     your office complain, tell them to use vim, which distinguishes between
  68 ;;     tabstop and shiftwidth (vi equivalent of our offsets), and also ask them
  69 ;;     to set smarttab.)
  70 ;;
  71 ;; All the above have caused (and will cause) unwanted codeline integration and
  72 ;; merge problems.
  73 ;;
  74 ;; whitespace.el will complain if it detects whitespaces on opening a file, and
  75 ;; warn you on closing a file also (in case you had inserted any
  76 ;; whitespaces during the process of your editing).
  77 ;;
  78 ;; Exported functions:
  79 ;;
  80 ;; `whitespace-buffer' - To check the current buffer for whitespace problems.
  81 ;; `whitespace-cleanup' - To cleanup all whitespaces in the current buffer.
  82 ;; `whitespace-region' - To check between point and mark for whitespace
  83 ;;                       problems.
  84 ;; `whitespace-cleanup-region' - To cleanup all whitespaces between point
  85 ;;                               and mark in the current buffer.
  86
  87 ;;; Code:
  88
  89 (defvar whitespace-version "3.5" "Version of the whitespace library.")
  90
  91 (defvar whitespace-all-buffer-files nil
  92   "An associated list of buffers and files checked for whitespace cleanliness.
  93
  94 This is to enable periodic checking of whitespace cleanliness in the files
  95 visited by the buffers.")
  96
  97 (defvar whitespace-rescan-timer nil
  98   "Timer object used to rescan the files in buffers that have been modified.")
  99
 100 ;; Tell Emacs about this new kind of minor mode
 101 (defvar whitespace-mode nil
 102   "Non-nil when Whitespace mode (a minor mode) is enabled.")
 103 (make-variable-buffer-local 'whitespace-mode)
 104 (put 'whitespace-mode 'permanent-local nil)
 105
 106 (defvar whitespace-mode-line nil
 107   "String to display in the mode line for Whitespace mode.")
 108 (make-variable-buffer-local 'whitespace-mode-line)
 109 (put 'whitespace-mode-line 'permanent-local nil)
 110
 111 (defvar whitespace-check-buffer-leading nil
 112   "Test leading whitespace for file in current buffer if t")
 113 (make-variable-buffer-local 'whitespace-check-buffer-leading)
 114 (put 'whitespace-check-buffer-leading 'permanent-local nil)
 115
 116 (defvar whitespace-check-buffer-trailing nil
 117   "Test trailing whitespace for file in current buffer if t")
 118 (make-variable-buffer-local 'whitespace-check-buffer-trailing)
 119 (put 'whitespace-check-buffer-trailing 'permanent-local nil)
 120
 121 (defvar whitespace-check-buffer-indent nil
 122   "Test indentation whitespace for file in current buffer if t")
 123 (make-variable-buffer-local 'whitespace-check-buffer-indent)
 124 (put 'whitespace-check-buffer-indent 'permanent-local nil)
 125
 126 (defvar whitespace-check-buffer-spacetab nil
 127   "Test Space-followed-by-TABS whitespace for file in current buffer if t")
 128 (make-variable-buffer-local 'whitespace-check-buffer-spacetab)
 129 (put 'whitespace-check-buffer-spacetab 'permanent-local nil)
 130
 131 (defvar whitespace-check-buffer-ateol nil
 132   "Test end-of-line whitespace for file in current buffer if t")
 133 (make-variable-buffer-local 'whitespace-check-buffer-ateol)
 134 (put 'whitespace-check-buffer-ateol 'permanent-local nil)
 135
 136 (defvar whitespace-highlighted-space nil
 137   "The variable to store the extent to highlight")
 138 (make-variable-buffer-local 'whitespace-highlighted-space)
 139 (put 'whitespace-highlighted-space 'permanent-local nil)
 140
 141 ;; For flavors of Emacs which don't define `defgroup' and `defcustom'.
 142 (eval-when-compile
 143   (if (not (fboundp 'defgroup))
 144       (defmacro defgroup (sym memb doc &rest args)
 145         "Null macro for defgroup in all versions of Emacs that don't define
 146 defgroup"
 147         t))
 148   (if (not (fboundp 'defcustom))
 149       (defmacro defcustom (sym val doc &rest args)
 150         "Macro to alias defcustom to defvar in all versions of Emacs that
 151 don't define defcustom"
 152         `(defvar ,sym ,val ,doc))))
 153
 154 (if (fboundp 'make-overlay)
 155     (progn
 156       (defalias 'whitespace-make-overlay 'make-overlay)
 157       (defalias 'whitespace-overlay-put 'overlay-put)
 158       (defalias 'whitespace-delete-overlay 'delete-overlay)
 159       (defalias 'whitespace-overlay-start 'overlay-start)
 160       (defalias 'whitespace-overlay-end 'overlay-end)
 161       (defalias 'whitespace-mode-line-update 'force-mode-line-update))
 162   (defalias 'whitespace-make-overlay 'make-extent)
 163   (defalias 'whitespace-overlay-put 'set-extent-property)
 164   (defalias 'whitespace-delete-overlay 'delete-extent)
 165   (defalias 'whitespace-overlay-start 'extent-start)
 166   (defalias 'whitespace-overlay-end 'extent-end)
 167   (defalias 'whitespace-mode-line-update 'redraw-modeline))
 168
 169 (if (featurep 'xemacs)
 170 (defgroup whitespace nil
 171   "Check for and fix five different types of whitespaces in source code."
 172   ;; Since XEmacs doesn't have a 'convenience group, use the next best group
 173   ;; which is 'editing?
 174   :link '(emacs-commentary-link "whitespace.el")
 175   :group 'editing)
 176 (defgroup whitespace nil
 177   "Check for and fix five different types of whitespaces in source code."
 178   :version "21.1"
 179   :link '(emacs-commentary-link "whitespace.el")
 180   :group 'convenience))
 181
 182 (defcustom whitespace-check-leading-whitespace t
 183   "Flag to check leading whitespace. This is the global for the system.
 184 It can be overriden by setting a buffer local variable
 185 `whitespace-check-buffer-leading'"
 186   :type 'boolean
 187   :group 'whitespace)
 188
 189 (defcustom whitespace-check-trailing-whitespace t
 190   "Flag to check trailing whitespace. This is the global for the system.
 191 It can be overriden by setting a buffer local variable
 192 `whitespace-check-buffer-trailing'"
 193   :type 'boolean
 194   :group 'whitespace)
 195
 196 (defcustom whitespace-check-spacetab-whitespace t
 197   "Flag to check space followed by a TAB. This is the global for the system.
 198 It can be overriden by setting a buffer local variable
 199 `whitespace-check-buffer-spacetab'"
 200   :type 'boolean
 201   :group 'whitespace)
 202
 203 (defcustom whitespace-spacetab-regexp "[ ]+\t"
 204   "Regexp to match a space followed by a TAB."
 205   :type 'regexp
 206   :group 'whitespace)
 207
 208 (defcustom whitespace-check-indent-whitespace indent-tabs-mode
 209   "Flag to check indentation whitespace. This is the global for the system.
 210 It can be overriden by setting a buffer local variable
 211 `whitespace-check-buffer-indent'"
 212   :type 'boolean
 213   :group 'whitespace)
 214
 215 (defcustom whitespace-indent-regexp (concat "^\\(\t*\\)    " "    ")
 216   "Regexp to match (any TABS followed by) 8/more whitespaces at start of line."
 217   :type 'regexp
 218   :group 'whitespace)
 219
 220 (defcustom whitespace-check-ateol-whitespace t
 221   "Flag to check end-of-line whitespace. This is the global for the system.
 222 It can be overriden by setting a buffer local variable
 223 `whitespace-check-buffer-ateol'"
 224   :type 'boolean
 225   :group 'whitespace)
 226
 227 ;; (defcustom whitespace-ateol-regexp "[ \t]$"
 228 (defcustom whitespace-ateol-regexp "[ \t]+$"
 229   "Regexp to match a TAB or a space at the EOL."
 230   :type 'regexp
 231   :group 'whitespace)
 232
 233 (defcustom whitespace-errbuf "*Whitespace Errors*"
 234   "The name of the buffer where whitespace related messages will be logged."
 235   :type 'string
 236   :group 'whitespace)
 237
 238 (defcustom whitespace-clean-msg "clean."
 239   "If non-nil, this message will be displayed after a whitespace check
 240 determines a file to be clean."
 241   :type 'string
 242   :group 'whitespace)
 243
 244 (defcustom whitespace-abort-on-error nil
 245   "While writing a file, abort if the file is unclean. If
 246 `whitespace-auto-cleanup' is set, that takes precedence over this
 247 variable."
 248   :type  'boolean
 249   :group 'whitespace)
 250
 251 (defcustom whitespace-auto-cleanup nil
 252   "Cleanup a buffer automatically on finding it whitespace unclean."
 253   :type  'boolean
 254   :group 'whitespace)
 255
 256 (defcustom whitespace-silent nil
 257   "All whitespace errors will be shown only in the modeline when t.
 258
 259 Note that setting this may cause all whitespaces introduced in a file to go
 260 unnoticed when the buffer is killed, unless the user visits the `*Whitespace
 261 Errors*' buffer before opening (or closing) another file."
 262   :type 'boolean
 263   :group 'whitespace)
 264
 265 (defcustom whitespace-modes '(ada-mode asm-mode autoconf-mode awk-mode
 266                                        c-mode c++-mode cc-mode
 267                                        change-log-mode cperl-mode
 268                                        electric-nroff-mode emacs-lisp-mode
 269                                        f90-mode fortran-mode html-mode
 270                                        html3-mode java-mode jde-mode
 271                                        ksh-mode latex-mode LaTeX-mode
 272                                        lisp-mode m4-mode makefile-mode
 273                                        modula-2-mode nroff-mode objc-mode
 274                                        pascal-mode perl-mode prolog-mode
 275                                        python-mode scheme-mode sgml-mode
 276                                        sh-mode shell-script-mode simula-mode
 277                                        tcl-mode tex-mode texinfo-mode
 278                                        vrml-mode xml-mode)
 279
 280   "Major Modes in which we turn on whitespace checking.
 281
 282 These are mostly programming and documentation modes.  But you may add other
 283 modes that you want whitespaces checked in by adding something like the
 284 following to your `.emacs':
 285
 286 \(setq whitespace-modes (cons 'my-mode (cons 'my-other-mode
 287                                             whitespace-modes))\)
 288
 289 Or, alternately, you can use the Emacs `customize' command to set this."
 290   :type '(repeat symbol)
 291   :group 'whitespace)
 292
 293 (defcustom whitespace-rescan-timer-time 600
 294   "Period in seconds to rescan modified buffers for whitespace creep.
 295
 296 This is the period after which the timer will fire causing
 297 `whitespace-rescan-files-in-buffers' to check for whitespace creep in
 298 modified buffers.
 299
 300 To disable timer scans, set this to zero."
 301   :type 'integer
 302   :group 'whitespace)
 303
 304 (defcustom whitespace-display-in-modeline t
 305   "Display whitespace errors on the modeline."
 306   :type 'boolean
 307   :group 'whitespace)
 308
 309 (defcustom whitespace-display-spaces-in-color t
 310   "Display the bogus whitespaces by coloring them with the face
 311 `whitespace-highlight'."
 312   :type 'boolean
 313   :group 'whitespace)
 314
 315 (defgroup whitespace-faces nil
 316   "Faces used in whitespace."
 317   :prefix "whitespace-"
 318   :group 'whitespace
 319   :group 'faces)
 320
 321 (defface whitespace-highlight '((((class color) (background light))
 322                                  (:background "green1"))
 323                                 (((class color) (background dark))
 324                                  (:background "sea green"))
 325                                 (((class grayscale mono)
 326                                   (background light))
 327                                  (:background "black"))
 328                                 (((class grayscale mono)
 329                                   (background dark))
 330                                  (:background "white")))
 331   "Face used for highlighting the bogus whitespaces that exist in the buffer."
 332   :group 'whitespace-faces)
 333 ;; backward-compatibility alias
 334 (put 'whitespace-highlight-face 'face-alias 'whitespace-highlight)
 335
 336 (if (not (assoc 'whitespace-mode minor-mode-alist))
 337     (setq minor-mode-alist (cons '(whitespace-mode whitespace-mode-line)
 338                                  minor-mode-alist)))
 339
 340 (set-default 'whitespace-check-buffer-leading
 341              whitespace-check-leading-whitespace)
 342 (set-default 'whitespace-check-buffer-trailing
 343              whitespace-check-trailing-whitespace)
 344 (set-default 'whitespace-check-buffer-indent
 345              whitespace-check-indent-whitespace)
 346 (set-default 'whitespace-check-buffer-spacetab
 347              whitespace-check-spacetab-whitespace)
 348 (set-default 'whitespace-check-buffer-ateol
 349              whitespace-check-ateol-whitespace)
 350
 351 (defun whitespace-check-whitespace-mode (&optional arg)
 352   "Test and set the whitespace-mode in qualifying buffers."
 353   (if (null whitespace-mode)
 354       (setq whitespace-mode
 355             (if (or arg (member major-mode whitespace-modes))
 356                 t
 357               nil))))
 358
 359 ;;;###autoload
 360 (defun whitespace-toggle-leading-check ()
 361   "Toggle the check for leading space in the local buffer."
 362   (interactive)
 363   (let ((current-val whitespace-check-buffer-leading))
 364     (setq whitespace-check-buffer-leading (not current-val))
 365     (message "Will%s check for leading space in buffer."
 366              (if whitespace-check-buffer-leading "" " not"))
 367     (if whitespace-check-buffer-leading (whitespace-buffer-leading))))
 368
 369 ;;;###autoload
 370 (defun whitespace-toggle-trailing-check ()
 371   "Toggle the check for trailing space in the local buffer."
 372   (interactive)
 373   (let ((current-val whitespace-check-buffer-trailing))
 374     (setq whitespace-check-buffer-trailing (not current-val))
 375     (message "Will%s check for trailing space in buffer."
 376              (if whitespace-check-buffer-trailing "" " not"))
 377     (if whitespace-check-buffer-trailing (whitespace-buffer-trailing))))
 378
 379 ;;;###autoload
 380 (defun whitespace-toggle-indent-check ()
 381   "Toggle the check for indentation space in the local buffer."
 382   (interactive)
 383   (let ((current-val whitespace-check-buffer-indent))
 384     (setq whitespace-check-buffer-indent (not current-val))
 385     (message "Will%s check for indentation space in buffer."
 386              (if whitespace-check-buffer-indent "" " not"))
 387     (if whitespace-check-buffer-indent
 388         (whitespace-buffer-search whitespace-indent-regexp))))
 389
 390 ;;;###autoload
 391 (defun whitespace-toggle-spacetab-check ()
 392   "Toggle the check for space-followed-by-TABs in the local buffer."
 393   (interactive)
 394   (let ((current-val whitespace-check-buffer-spacetab))
 395     (setq whitespace-check-buffer-spacetab (not current-val))
 396     (message "Will%s check for space-followed-by-TABs in buffer."
 397              (if whitespace-check-buffer-spacetab "" " not"))
 398     (if whitespace-check-buffer-spacetab
 399         (whitespace-buffer-search whitespace-spacetab-regexp))))
 400
 401
 402 ;;;###autoload
 403 (defun whitespace-toggle-ateol-check ()
 404   "Toggle the check for end-of-line space in the local buffer."
 405   (interactive)
 406   (let ((current-val whitespace-check-buffer-ateol))
 407     (setq whitespace-check-buffer-ateol (not current-val))
 408     (message "Will%s check for end-of-line space in buffer."
 409              (if whitespace-check-buffer-ateol "" " not"))
 410     (if whitespace-check-buffer-ateol
 411         (whitespace-buffer-search whitespace-ateol-regexp))))
 412
 413
 414 ;;;###autoload
 415 (defun whitespace-buffer (&optional quiet)
 416   "Find five different types of white spaces in buffer.
 417 These are:
 418 1. Leading space \(empty lines at the top of a file\).
 419 2. Trailing space \(empty lines at the end of a file\).
 420 3. Indentation space \(8 or more spaces, that should be replaced with TABS\).
 421 4. Spaces followed by a TAB. \(Almost always, we never want that\).
 422 5. Spaces or TABS at the end of a line.
 423
 424 Check for whitespace only if this buffer really contains a non-empty file
 425 and:
 426 1. the major mode is one of the whitespace-modes, or
 427 2. `whitespace-buffer' was explicitly called with a prefix argument."
 428   (interactive)
 429   (let ((whitespace-error nil))
 430     (whitespace-check-whitespace-mode current-prefix-arg)
 431     (if (and buffer-file-name (> (buffer-size) 0) whitespace-mode)
 432         (progn
 433           (whitespace-check-buffer-list (buffer-name) buffer-file-name)
 434           (whitespace-tickle-timer)
 435           (whitespace-unhighlight-the-space)
 436           (if whitespace-auto-cleanup
 437               (if buffer-read-only
 438                   (if (not quiet)
 439                       (message "Can't cleanup: %s is read-only" (buffer-name)))
 440                 (whitespace-cleanup))
 441             (let ((whitespace-leading (if whitespace-check-buffer-leading
 442                                           (whitespace-buffer-leading)
 443                                         nil))
 444                   (whitespace-trailing (if whitespace-check-buffer-trailing
 445                                            (whitespace-buffer-trailing)
 446                                          nil))
 447                   (whitespace-indent (if whitespace-check-buffer-indent
 448                                          (whitespace-buffer-search
 449                                           whitespace-indent-regexp)
 450                                        nil))
 451                   (whitespace-spacetab (if whitespace-check-buffer-spacetab
 452                                            (whitespace-buffer-search
 453                                             whitespace-spacetab-regexp)
 454                                          nil))
 455                   (whitespace-ateol (if whitespace-check-buffer-ateol
 456                                         (whitespace-buffer-search
 457                                          whitespace-ateol-regexp)
 458                                       nil))
 459                   (whitespace-errmsg nil)
 460                   (whitespace-filename buffer-file-name)
 461                   (whitespace-this-modeline ""))
 462
 463               ;; Now let's complain if we found any of the above.
 464               (setq whitespace-error (or whitespace-leading whitespace-indent
 465                                          whitespace-spacetab whitespace-ateol
 466                                          whitespace-trailing))
 467
 468               (if whitespace-error
 469                   (progn
 470                     (setq whitespace-errmsg
 471                           (concat whitespace-filename " contains:\n"
 472                                   (if whitespace-leading
 473                                       "Leading whitespace\n")
 474                                   (if whitespace-indent
 475                                       (concat "Indentation whitespace"
 476                                               whitespace-indent "\n"))
 477                                   (if whitespace-spacetab
 478                                       (concat "Space followed by Tab"
 479                                               whitespace-spacetab "\n"))
 480                                   (if whitespace-ateol
 481                                       (concat "End-of-line whitespace"
 482                                               whitespace-ateol "\n"))
 483                                   (if whitespace-trailing
 484                                       "Trailing whitespace\n")
 485                                   "\ntype `M-x whitespace-cleanup' to "
 486                                   "cleanup the file."))
 487                     (setq whitespace-this-modeline
 488                           (concat (if whitespace-ateol "e")
 489                                   (if whitespace-indent "i")
 490                                   (if whitespace-leading "l")
 491                                   (if whitespace-spacetab "s")
 492                                   (if whitespace-trailing "t")))))
 493               (whitespace-update-modeline whitespace-this-modeline)
 494               (if (get-buffer whitespace-errbuf)
 495                   (kill-buffer whitespace-errbuf))
 496               (with-current-buffer (get-buffer-create whitespace-errbuf)
 497                 (if whitespace-errmsg
 498                     (progn
 499                       (insert whitespace-errmsg)
 500                       (if (not (or quiet whitespace-silent))
 501                           (display-buffer (current-buffer) t))
 502                       (if (not quiet)
 503                           (message "Whitespaces: [%s%s] in %s"
 504                                    whitespace-this-modeline
 505                                    (let ((whitespace-unchecked
 506                                           (whitespace-unchecked-whitespaces)))
 507                                      (if whitespace-unchecked
 508                                          (concat "!" whitespace-unchecked)
 509                                        ""))
 510                                    whitespace-filename)))
 511                   (if (and (not quiet) (not (equal whitespace-clean-msg "")))
 512                       (message "%s %s" whitespace-filename
 513                                whitespace-clean-msg))))))))
 514     whitespace-error))
 515
 516 ;;;###autoload
 517 (defun whitespace-region (s e)
 518   "Check the region for whitespace errors."
 519   (interactive "r")
 520   (save-excursion
 521     (save-restriction
 522       (narrow-to-region s e)
 523       (whitespace-buffer))))
 524
 525 ;;;###autoload
 526 (defun whitespace-cleanup ()
 527   "Cleanup the five different kinds of whitespace problems.
 528
 529 Use \\[describe-function] whitespace-describe to read a summary of the
 530 whitespace problems."
 531   (interactive)
 532   ;; If this buffer really contains a file, then run, else quit.
 533   (whitespace-check-whitespace-mode current-prefix-arg)
 534   (if (and buffer-file-name whitespace-mode)
 535       (let ((whitespace-any nil)
 536             (whitespace-tabwith 8)
 537             (whitespace-tabwith-saved tab-width))
 538
 539         ;; since all printable TABS should be 8, irrespective of how
 540         ;; they are displayed.
 541         (setq tab-width whitespace-tabwith)
 542
 543         (if (and whitespace-check-buffer-leading
 544                  (whitespace-buffer-leading))
 545             (progn
 546               (whitespace-buffer-leading-cleanup)
 547               (setq whitespace-any t)))
 548
 549         (if (and whitespace-check-buffer-trailing
 550                  (whitespace-buffer-trailing))
 551             (progn
 552               (whitespace-buffer-trailing-cleanup)
 553               (setq whitespace-any t)))
 554
 555         (if (and whitespace-check-buffer-indent
 556                  (whitespace-buffer-search whitespace-indent-regexp))
 557             (progn
 558               (whitespace-indent-cleanup)
 559               (setq whitespace-any t)))
 560
 561         (if (and whitespace-check-buffer-spacetab
 562                  (whitespace-buffer-search whitespace-spacetab-regexp))
 563             (progn
 564               (whitespace-buffer-cleanup whitespace-spacetab-regexp "\t")
 565               (setq whitespace-any t)))
 566
 567         (if (and whitespace-check-buffer-ateol
 568                  (whitespace-buffer-search whitespace-ateol-regexp))
 569             (progn
 570               (whitespace-buffer-cleanup whitespace-ateol-regexp "")
 571               (setq whitespace-any t)))
 572
 573         ;; Call this recursively till everything is taken care of
 574         (if whitespace-any
 575             (whitespace-cleanup)
 576           (progn
 577             (if (not whitespace-silent)
 578                 (message "%s clean" buffer-file-name))
 579             (whitespace-update-modeline)))
 580         (setq tab-width whitespace-tabwith-saved))))
 581
 582 ;;;###autoload
 583 (defun whitespace-cleanup-region (s e)
 584   "Whitespace cleanup on the region."
 585   (interactive "r")
 586   (save-excursion
 587     (save-restriction
 588       (narrow-to-region s e)
 589       (whitespace-cleanup))
 590     (whitespace-buffer t)))
 591
 592 (defun whitespace-buffer-leading ()
 593   "Check to see if there are any empty lines at the top of the file."
 594   (save-excursion
 595     (let ((pmin nil)
 596           (pmax nil))
 597       (goto-char (point-min))
 598       (beginning-of-line)
 599       (setq pmin (point))
 600       (end-of-line)
 601       (setq pmax (point))
 602       (if (equal pmin pmax)
 603           (progn
 604             (whitespace-highlight-the-space pmin (1+ pmax))
 605             t)
 606         nil))))
 607
 608 (defun whitespace-buffer-leading-cleanup ()
 609   "Remove any empty lines at the top of the file."
 610   (save-excursion
 611     (let ((pmin nil)
 612           (pmax nil))
 613       (goto-char (point-min))
 614       (beginning-of-line)
 615       (setq pmin (point))
 616       (end-of-line)
 617       (setq pmax (point))
 618       (if (equal pmin pmax)
 619           (progn
 620             (kill-line)
 621             (whitespace-buffer-leading-cleanup))))))
 622
 623 (defun whitespace-buffer-trailing ()
 624   "Check to see if are is more than one empty line at the bottom."
 625   (save-excursion
 626     (let ((pmin nil)
 627           (pmax nil))
 628       (goto-char (point-max))
 629       (beginning-of-line)
 630       (setq pmin (point))
 631       (end-of-line)
 632       (setq pmax (point))
 633       (if (equal pmin pmax)
 634           (progn
 635             (goto-char (- (point) 1))
 636             (beginning-of-line)
 637             (setq pmin (point))
 638             (end-of-line)
 639             (setq pmax (point))
 640             (if (equal pmin pmax)
 641                 (progn
 642                   (whitespace-highlight-the-space (- pmin 1) pmax)
 643                   t)
 644               nil))
 645         nil))))
 646
 647 (defun whitespace-buffer-trailing-cleanup ()
 648   "Delete all the empty lines at the bottom."
 649   (save-excursion
 650     (let ((pmin nil)
 651           (pmax nil))
 652       (goto-char (point-max))
 653       (beginning-of-line)
 654       (setq pmin (point))
 655       (end-of-line)
 656       (setq pmax (point))
 657       (if (equal pmin pmax)
 658           (progn
 659             (goto-char (1- pmin))
 660             (beginning-of-line)
 661             (setq pmin (point))
 662             (end-of-line)
 663             (setq pmax (point))
 664             (if (equal pmin pmax)
 665                 (progn
 666                   (goto-char (1- (point-max)))
 667                   (beginning-of-line)
 668                   (kill-line)
 669                   (whitespace-buffer-trailing-cleanup))))))))
 670
 671 (defun whitespace-buffer-search (regexp)
 672   "Search for any given whitespace REGEXP."
 673   (let ((whitespace-retval ""))
 674     (save-excursion
 675       (goto-char (point-min))
 676       (while (re-search-forward regexp nil t)
 677         (progn
 678           (setq whitespace-retval (format "%s %s" whitespace-retval
 679                                         (match-beginning 0)))
 680         (whitespace-highlight-the-space (match-beginning 0) (match-end 0))))
 681       (if (equal "" whitespace-retval)
 682           nil
 683         whitespace-retval))))
 684
 685 (defun whitespace-buffer-cleanup (regexp newregexp)
 686   "Search for any given whitespace REGEXP and replace it with the NEWREGEXP."
 687   (save-excursion
 688     (goto-char (point-min))
 689     (while (re-search-forward regexp nil t)
 690       (replace-match newregexp))))
 691
 692 (defun whitespace-indent-cleanup ()
 693   "Search for 8/more spaces at the start of a line and replace it with tabs."
 694   (save-excursion
 695     (goto-char (point-min))
 696     (while (re-search-forward whitespace-indent-regexp nil t)
 697       (let ((column (current-column))
 698             (indent-tabs-mode t))
 699         (delete-region (match-beginning 0) (point))
 700         (indent-to column)))))
 701
 702 (defun whitespace-unchecked-whitespaces ()
 703   "Return the list of whitespaces whose testing has been suppressed."
 704   (let ((unchecked-spaces
 705          (concat (if (not whitespace-check-buffer-ateol) "e")
 706                  (if (not whitespace-check-buffer-indent) "i")
 707                  (if (not whitespace-check-buffer-leading) "l")
 708                  (if (not whitespace-check-buffer-spacetab) "s")
 709                  (if (not whitespace-check-buffer-trailing) "t"))))
 710     (if (not (equal unchecked-spaces ""))
 711         unchecked-spaces
 712       nil)))
 713
 714 (defun whitespace-update-modeline (&optional whitespace-err)
 715   "Update modeline with whitespace errors.
 716 Also with whitespaces whose testing has been turned off."
 717   (if whitespace-display-in-modeline
 718       (progn
 719         (setq whitespace-mode-line nil)
 720         ;; Whitespace errors
 721         (if (and whitespace-err (not (equal whitespace-err "")))
 722             (setq whitespace-mode-line whitespace-err))
 723         ;; Whitespace suppressed errors
 724         (let ((whitespace-unchecked (whitespace-unchecked-whitespaces)))
 725           (if whitespace-unchecked
 726               (setq whitespace-mode-line
 727                     (concat whitespace-mode-line "!" whitespace-unchecked))))
 728         ;; Add the whitespace modeline prefix
 729         (setq whitespace-mode-line (if whitespace-mode-line
 730                                        (concat " W:" whitespace-mode-line)
 731                                      nil))
 732         (whitespace-mode-line-update))))
 733
 734 (defun whitespace-highlight-the-space (b e)
 735   "Highlight the current line, unhighlighting a previously jumped to line."
 736   (if whitespace-display-spaces-in-color
 737       (let ((ol (whitespace-make-overlay b e)))
 738         (push ol whitespace-highlighted-space)
 739         (whitespace-overlay-put ol 'face 'whitespace-highlight))))
 740 ;;  (add-hook 'pre-command-hook 'whitespace-unhighlight-the-space))
 741
 742 (defun whitespace-unhighlight-the-space()
 743   "Unhighlight the currently highlight line."
 744   (if (and whitespace-display-spaces-in-color whitespace-highlighted-space)
 745       (progn
 746         (mapc 'whitespace-delete-overlay whitespace-highlighted-space)
 747         (setq whitespace-highlighted-space nil))
 748     (remove-hook 'pre-command-hook 'whitespace-unhighlight-the-space)))
 749
 750 (defun whitespace-check-buffer-list (buf-name buf-file)
 751   "Add a buffer and its file to the whitespace monitor list.
 752
 753 The buffer named BUF-NAME and its associated file BUF-FILE are now monitored
 754 periodically for whitespace."
 755   (if (and whitespace-mode (not (member (list buf-file buf-name)
 756                                         whitespace-all-buffer-files)))
 757       (add-to-list 'whitespace-all-buffer-files (list buf-file buf-name))))
 758
 759 (defun whitespace-tickle-timer ()
 760   "Tickle timer to periodically to scan qualifying files for whitespace creep.
 761
 762 If timer is not set, then set it to scan the files in
 763 `whitespace-all-buffer-files' periodically (defined by
 764 `whitespace-rescan-timer-time') for whitespace creep."
 765   (if (and whitespace-rescan-timer-time (not whitespace-rescan-timer))
 766       (setq whitespace-rescan-timer
 767             (add-timeout whitespace-rescan-timer-time
 768                          'whitespace-rescan-files-in-buffers nil
 769                          whitespace-rescan-timer-time))))
 770
 771 (defun whitespace-rescan-files-in-buffers (&optional arg)
 772   "Check monitored files for whitespace creep since last scan."
 773   (let ((whitespace-all-my-files whitespace-all-buffer-files)
 774         buffile bufname thiselt buf)
 775     (if (not whitespace-all-my-files)
 776         (progn
 777           (disable-timeout whitespace-rescan-timer)
 778           (setq whitespace-rescan-timer nil))
 779       (while whitespace-all-my-files
 780         (setq thiselt (car whitespace-all-my-files))
 781         (setq whitespace-all-my-files (cdr whitespace-all-my-files))
 782         (setq buffile (car thiselt))
 783         (setq bufname (cadr thiselt))
 784         (setq buf (get-buffer bufname))
 785         (if (buffer-live-p buf)
 786             (save-excursion
 787               ;;(message "buffer %s live" bufname)
 788               (set-buffer bufname)
 789               (if whitespace-mode
 790                   (progn
 791                     ;;(message "checking for whitespace in %s" bufname)
 792                     (if whitespace-auto-cleanup
 793                         (progn
 794                           ;;(message "cleaning up whitespace in %s" bufname)
 795                           (whitespace-cleanup))
 796                       (progn
 797                         ;;(message "whitespace-buffer %s." (buffer-name))
 798                         (whitespace-buffer t))))
 799                 ;;(message "Removing %s from refresh list" bufname)
 800                 (whitespace-refresh-rescan-list buffile bufname)))
 801           ;;(message "Removing %s from refresh list" bufname)
 802           (whitespace-refresh-rescan-list buffile bufname))))))
 803
 804 (defun whitespace-refresh-rescan-list (buffile bufname)
 805   "Refresh the list of files to be rescaned for whitespace creep."
 806   (if whitespace-all-buffer-files
 807       (setq whitespace-all-buffer-files
 808             (delete (list buffile bufname) whitespace-all-buffer-files))
 809     (when whitespace-rescan-timer
 810       (disable-timeout whitespace-rescan-timer)
 811       (setq whitespace-rescan-timer nil))))
 812
 813 ;;;###autoload
 814 (defalias 'global-whitespace-mode 'whitespace-global-mode)
 815
 816 ;;;###autoload
 817 (define-minor-mode whitespace-global-mode
 818   "Toggle using Whitespace mode in new buffers.
 819 With ARG, turn the mode on iff ARG is positive.
 820
 821 When this mode is active, `whitespace-buffer' is added to
 822 `find-file-hook' and `kill-buffer-hook'."
 823   :global t
 824   :group 'whitespace
 825   (if whitespace-global-mode
 826       (progn
 827         (add-hook 'find-file-hook 'whitespace-buffer)
 828         (add-hook 'write-file-functions 'whitespace-write-file-hook nil t)
 829         (add-hook 'kill-buffer-hook 'whitespace-buffer))
 830     (remove-hook 'find-file-hook 'whitespace-buffer)
 831     (remove-hook 'write-file-functions 'whitespace-write-file-hook t)
 832     (remove-hook 'kill-buffer-hook 'whitespace-buffer)))
 833
 834 ;;;###autoload
 835 (defun whitespace-write-file-hook ()
 836   "Hook function to be called on the buffer when whitespace check is enabled.
 837 This is meant to be added buffer-locally to `write-file-functions'."
 838   (interactive)
 839   (let ((werr nil))
 840     (if whitespace-auto-cleanup
 841         (whitespace-cleanup)
 842       (setq werr (whitespace-buffer)))
 843     (if (and whitespace-abort-on-error werr)
 844         (error (concat "Abort write due to whitespaces in "
 845                        buffer-file-name))))
 846   nil)
 847
 848 (defun whitespace-unload-hook ()
 849   (remove-hook 'find-file-hook 'whitespace-buffer)
 850   (remove-hook 'write-file-functions 'whitespace-write-file-hook t)
 851   (remove-hook 'kill-buffer-hook 'whitespace-buffer))
 852
 853 (add-hook 'whitespace-unload-hook 'whitespace-unload-hook)
 854
 855 (provide 'whitespace)
 856
 857 ;; arch-tag: 4ff44e87-b63c-402d-95a6-15e51e58bd0c
 858 ;;; whitespace.el ends here