lisp/gnus/mm-util.el

   1 ;;; mm-util.el --- Utility functions for Mule and low level things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28 (require 'mail-prsvr)
  29
  30 (eval-and-compile
  31   (mapcar
  32    (lambda (elem)
  33      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  34        (if (fboundp (car elem))
  35            (defalias nfunc (car elem))
  36          (defalias nfunc (cdr elem)))))
  37    '((decode-coding-string . (lambda (s a) s))
  38      (encode-coding-string . (lambda (s a) s))
  39      (encode-coding-region . ignore)
  40      (coding-system-list . ignore)
  41      (decode-coding-region . ignore)
  42      (char-int . identity)
  43      (device-type . ignore)
  44      (coding-system-equal . equal)
  45      (annotationp . ignore)
  46      (set-buffer-file-coding-system . ignore)
  47      (make-char
  48       . (lambda (charset int)
  49           (int-to-char int)))
  50      (read-charset
  51       . (lambda (prompt)
  52           "Return a charset."
  53           (intern
  54            (completing-read
  55             prompt
  56             (mapcar (lambda (e) (list (symbol-name (car e))))
  57                     mm-mime-mule-charset-alist)
  58             nil t))))
  59      (subst-char-in-string
  60       . (lambda (from to string) ;; stolen (and renamed) from nnheader.el
  61           "Replace characters in STRING from FROM to TO."
  62           (let ((string (substring string 0)) ;Copy string.
  63                 (len (length string))
  64                 (idx 0))
  65             ;; Replace all occurrences of FROM with TO.
  66             (while (< idx len)
  67               (when (= (aref string idx) from)
  68                 (aset string idx to))
  69               (setq idx (1+ idx)))
  70             string)))
  71      (string-as-unibyte . identity)
  72      (string-as-multibyte . identity)
  73      (multibyte-string-p . ignore))))
  74
  75 (eval-and-compile
  76   (defalias 'mm-char-or-char-int-p
  77     (cond
  78      ((fboundp 'char-or-char-int-p) 'char-or-char-int-p)
  79      ((fboundp 'char-valid-p) 'char-valid-p)
  80      (t 'identity))))
  81
  82 (eval-and-compile
  83   (defalias 'mm-read-coding-system
  84     (cond
  85      ((fboundp 'read-coding-system)
  86       (if (and (featurep 'xemacs)
  87                (<= (string-to-number emacs-version) 21.1))
  88           (lambda (prompt &optional default-coding-system)
  89             (read-coding-system prompt))
  90         'read-coding-system))
  91      (t (lambda (prompt &optional default-coding-system)
  92           "Prompt the user for a coding system."
  93           (completing-read
  94            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
  95                           mm-mime-mule-charset-alist)))))))
  96
  97 (defvar mm-coding-system-list nil)
  98 (defun mm-get-coding-system-list ()
  99   "Get the coding system list."
 100   (or mm-coding-system-list
 101       (setq mm-coding-system-list (mm-coding-system-list))))
 102
 103 (defun mm-coding-system-p (sym)
 104   "Return non-nil if SYM is a coding system."
 105   (or (and (fboundp 'coding-system-p) (coding-system-p sym))
 106       (memq sym (mm-get-coding-system-list))))
 107
 108 (defvar mm-charset-synonym-alist
 109   `(
 110     ;; Perfectly fine?  A valid MIME name, anyhow.
 111     ,@(unless (mm-coding-system-p 'big5)
 112        '((big5 . cn-big5)))
 113     ;; Not in XEmacs, but it's not a proper MIME charset anyhow.
 114     ,@(unless (mm-coding-system-p 'x-ctext)
 115        '((x-ctext . ctext)))
 116     ;; Apparently not defined in Emacs 20, but is a valid MIME name.
 117     ,@(unless (mm-coding-system-p 'gb2312)
 118        '((gb2312 . cn-gb-2312)))
 119     ;; ISO-8859-15 is very similar to ISO-8859-1.
 120     ,@(unless (mm-coding-system-p 'iso-8859-15) ; Emacs 21 defines it.
 121        '((iso-8859-15 . iso-8859-1)))
 122     ;; Windows-1252 is actually a superset of Latin-1.  See also
 123     ;; `gnus-article-dumbquotes-map'.
 124     ,@(unless (mm-coding-system-p 'windows-1252)
 125        (if (mm-coding-system-p 'cp1252)
 126            '((windows-1252 . cp1252))
 127          '((windows-1252 . iso-8859-1))))
 128     ;; Windows-1250 is a variant of Latin-2 heavily used by Microsoft
 129     ;; Outlook users in Czech republic. Use this to allow reading of their
 130     ;; e-mails. cp1250 should be defined by M-x codepage-setup.
 131     ,@(if (and (not (mm-coding-system-p 'windows-1250))
 132                (mm-coding-system-p 'cp1250))
 133           '((windows-1250 . cp1250)))
 134     )
 135   "A mapping from invalid charset names to the real charset names.")
 136
 137 (defvar mm-binary-coding-system
 138   (cond
 139    ((mm-coding-system-p 'binary) 'binary)
 140    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 141    (t nil))
 142   "100% binary coding system.")
 143
 144 (defvar mm-text-coding-system
 145   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 146           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 147         (and (mm-coding-system-p 'raw-text) 'raw-text))
 148       mm-binary-coding-system)
 149   "Text-safe coding system (For removing ^M).")
 150
 151 (defvar mm-text-coding-system-for-write nil
 152   "Text coding system for write.")
 153
 154 (defvar mm-auto-save-coding-system
 155   (cond
 156    ((mm-coding-system-p 'emacs-mule)
 157     (if (memq system-type '(windows-nt ms-dos ms-windows))
 158         (if (mm-coding-system-p 'emacs-mule-dos)
 159             'emacs-mule-dos mm-binary-coding-system)
 160       'emacs-mule))
 161    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 162    (t mm-binary-coding-system))
 163   "Coding system of auto save file.")
 164
 165 (defvar mm-universal-coding-system mm-auto-save-coding-system
 166   "The universal coding system.")
 167
 168 ;; Fixme: some of the cars here aren't valid MIME charsets.  That
 169 ;; should only matter with XEmacs, though.
 170 (defvar mm-mime-mule-charset-alist
 171   `((us-ascii ascii)
 172     (iso-8859-1 latin-iso8859-1)
 173     (iso-8859-2 latin-iso8859-2)
 174     (iso-8859-3 latin-iso8859-3)
 175     (iso-8859-4 latin-iso8859-4)
 176     (iso-8859-5 cyrillic-iso8859-5)
 177     ;; Non-mule (X)Emacs uses the last mule-charset for 8bit characters.
 178     ;; The fake mule-charset, gnus-koi8-r, tells Gnus that the default
 179     ;; charset is koi8-r, not iso-8859-5.
 180     (koi8-r cyrillic-iso8859-5 gnus-koi8-r)
 181     (iso-8859-6 arabic-iso8859-6)
 182     (iso-8859-7 greek-iso8859-7)
 183     (iso-8859-8 hebrew-iso8859-8)
 184     (iso-8859-9 latin-iso8859-9)
 185     (iso-8859-14 latin-iso8859-14)
 186     (iso-8859-15 latin-iso8859-15)
 187     (viscii vietnamese-viscii-lower)
 188     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
 189     (euc-kr korean-ksc5601)
 190     (gb2312 chinese-gb2312)
 191     (big5 chinese-big5-1 chinese-big5-2)
 192     (tibetan tibetan)
 193     (thai-tis620 thai-tis620)
 194     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
 195     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
 196                    latin-jisx0201 japanese-jisx0208-1978
 197                    chinese-gb2312 japanese-jisx0208
 198                    korean-ksc5601 japanese-jisx0212
 199                    katakana-jisx0201)
 200     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
 201                     latin-jisx0201 japanese-jisx0208-1978
 202                     chinese-gb2312 japanese-jisx0208
 203                     korean-ksc5601 japanese-jisx0212
 204                     chinese-cns11643-1 chinese-cns11643-2)
 205     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
 206                     cyrillic-iso8859-5 greek-iso8859-7
 207                     latin-jisx0201 japanese-jisx0208-1978
 208                     chinese-gb2312 japanese-jisx0208
 209                     korean-ksc5601 japanese-jisx0212
 210                     chinese-cns11643-1 chinese-cns11643-2
 211                     chinese-cns11643-3 chinese-cns11643-4
 212                     chinese-cns11643-5 chinese-cns11643-6
 213                     chinese-cns11643-7)
 214     ,(if (or (not (fboundp 'charsetp)) ;; non-Mule case
 215              (charsetp 'unicode-a)
 216              (not (mm-coding-system-p 'mule-utf-8)))
 217          '(utf-8 unicode-a unicode-b unicode-c unicode-d unicode-e)
 218        ;; If we have utf-8 we're in Mule 5+.
 219        (append '(utf-8)
 220                (delete 'ascii
 221                        (coding-system-get 'mule-utf-8 'safe-charsets)))))
 222   "Alist of MIME-charset/MULE-charsets.")
 223
 224 ;; Correct by construction, but should be unnecessary:
 225 ;; XEmacs hates it.
 226 (when (and (not (featurep 'xemacs))
 227            (fboundp 'coding-system-list)
 228            (fboundp 'sort-coding-systems))
 229   (setq mm-mime-mule-charset-alist
 230         (apply
 231          'nconc
 232          (mapcar
 233           (lambda (cs)
 234             (when (and (coding-system-get cs 'mime-charset)
 235                        (not (eq t (coding-system-get cs 'safe-charsets))))
 236               (list (cons (coding-system-get cs 'mime-charset)
 237                           (delq 'ascii
 238                                 (coding-system-get cs 'safe-charsets))))))
 239           (sort-coding-systems (coding-system-list 'base-only))))))
 240
 241 (defvar mm-hack-charsets '(iso-8859-15 iso-2022-jp-2)
 242   "A list of special charsets.
 243 Valid elements include:
 244 `iso-8859-15'    convert ISO-8859-1, -9 to ISO-8859-15 if ISO-8859-15 exists.
 245 `iso-2022-jp-2'  convert ISO-2022-jp to ISO-2022-jp-2 if ISO-2022-jp-2 exists."
 246 )
 247
 248 (defvar mm-iso-8859-15-compatible
 249   '((iso-8859-1 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE")
 250     (iso-8859-9 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE\xD0\xDD\xDE\xF0\xFD\xFE"))
 251   "ISO-8859-15 exchangeable coding systems and inconvertible characters.")
 252
 253 (defvar mm-iso-8859-x-to-15-table
 254   (and (fboundp 'coding-system-p)
 255        (mm-coding-system-p 'iso-8859-15)
 256        (mapcar
 257         (lambda (cs)
 258           (if (mm-coding-system-p (car cs))
 259               (let ((c (string-to-char
 260                         (decode-coding-string "\341" (car cs)))))
 261                 (cons (char-charset c)
 262                       (cons
 263                        (- (string-to-char
 264                            (decode-coding-string "\341" 'iso-8859-15)) c)
 265                        (string-to-list (decode-coding-string (car (cdr cs))
 266                                                              (car cs))))))
 267             '(gnus-charset 0)))
 268         mm-iso-8859-15-compatible))
 269   "A table of the difference character between ISO-8859-X and ISO-8859-15.")
 270
 271 (defvar mm-coding-system-priorities nil
 272   "Preferred coding systems for encoding outgoing mails.
 273
 274 More than one suitable coding systems may be found for some texts.  By
 275 default, a coding system with the highest priority is used to encode
 276 outgoing mails (see `sort-coding-systems').  If this variable is set,
 277 it overrides the default priority.  For example, Japanese users may
 278 prefer iso-2022-jp to japanese-shift-jis:
 279
 280 \(setq mm-coding-system-priorities
 281   '(iso-2022-jp iso-2022-jp-2 japanese-shift-jis utf-8))
 282 ")
 283
 284 (defvar mm-use-find-coding-systems-region
 285   (fboundp 'find-coding-systems-region)
 286   "Use `find-coding-systems-region' to find proper coding systems.")
 287
 288 ;;; Internal variables:
 289
 290 ;;; Functions:
 291
 292 (defun mm-mule-charset-to-mime-charset (charset)
 293   "Return the MIME charset corresponding to the given Mule CHARSET."
 294   (if (fboundp 'find-coding-systems-for-charsets)
 295       (let (mime)
 296         (dolist (cs (find-coding-systems-for-charsets (list charset)))
 297           (unless mime
 298             (when cs
 299               (setq mime (coding-system-get cs 'mime-charset)))))
 300         mime)
 301     (let ((alist mm-mime-mule-charset-alist)
 302           out)
 303       (while alist
 304         (when (memq charset (cdar alist))
 305           (setq out (caar alist)
 306                 alist nil))
 307         (pop alist))
 308       out)))
 309
 310 (defun mm-charset-to-coding-system (charset &optional lbt)
 311   "Return coding-system corresponding to CHARSET.
 312 CHARSET is a symbol naming a MIME charset.
 313 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 314 used as the line break code type of the coding system."
 315   (when (stringp charset)
 316     (setq charset (intern (downcase charset))))
 317   (when lbt
 318     (setq charset (intern (format "%s-%s" charset lbt))))
 319   (cond
 320    ((null charset)
 321     charset)
 322    ;; Running in a non-MULE environment.
 323    ((null (mm-get-coding-system-list))
 324     charset)
 325    ;; ascii
 326    ((eq charset 'us-ascii)
 327     'ascii)
 328    ;; Check to see whether we can handle this charset.  (This depends
 329    ;; on there being some coding system matching each `mime-charset'
 330    ;; property defined, as there should be.)
 331    ((and (mm-coding-system-p charset)
 332 ;;; Doing this would potentially weed out incorrect charsets.
 333 ;;;      charset
 334 ;;;      (eq charset (coding-system-get charset 'mime-charset))
 335          )
 336     charset)
 337    ;; Translate invalid charsets.
 338    ((let ((cs (cdr (assq charset mm-charset-synonym-alist))))
 339       (and cs (mm-coding-system-p charset) cs)))
 340    ;; Last resort: search the coding system list for entries which
 341    ;; have the right mime-charset in case the canonical name isn't
 342    ;; defined (though it should be).
 343    ((let (cs)
 344       ;; mm-get-coding-system-list returns a list of cs without lbt.
 345       ;; Do we need -lbt?
 346       (dolist (c (mm-get-coding-system-list))
 347         (if (and (null cs)
 348                  (eq charset (coding-system-get c 'mime-charset)))
 349             (setq cs c)))
 350       cs))))
 351
 352 (defsubst mm-replace-chars-in-string (string from to)
 353   (mm-subst-char-in-string from to string))
 354
 355 (eval-and-compile
 356   (defvar mm-emacs-mule (and (not (featurep 'xemacs))
 357                              (boundp 'default-enable-multibyte-characters)
 358                              default-enable-multibyte-characters
 359                              (fboundp 'set-buffer-multibyte))
 360     "Emacs mule.")
 361
 362   (defvar mm-mule4-p (and mm-emacs-mule
 363                           (fboundp 'charsetp)
 364                           (not (charsetp 'eight-bit-control)))
 365     "Mule version 4.")
 366
 367   (if mm-emacs-mule
 368       (defun mm-enable-multibyte ()
 369         "Set the multibyte flag of the current buffer.
 370 Only do this if the default value of `enable-multibyte-characters' is
 371 non-nil.  This is a no-op in XEmacs."
 372         (set-buffer-multibyte t))
 373     (defalias 'mm-enable-multibyte 'ignore))
 374
 375   (if mm-emacs-mule
 376       (defun mm-disable-multibyte ()
 377         "Unset the multibyte flag of in the current buffer.
 378 This is a no-op in XEmacs."
 379         (set-buffer-multibyte nil))
 380     (defalias 'mm-disable-multibyte 'ignore))
 381
 382   (if mm-mule4-p
 383       (defun mm-enable-multibyte-mule4  ()
 384         "Enable multibyte in the current buffer.
 385 Only used in Emacs Mule 4."
 386         (set-buffer-multibyte t))
 387     (defalias 'mm-enable-multibyte-mule4 'ignore))
 388
 389   (if mm-mule4-p
 390       (defun mm-disable-multibyte-mule4 ()
 391         "Disable multibyte in the current buffer.
 392 Only used in Emacs Mule 4."
 393         (set-buffer-multibyte nil))
 394     (defalias 'mm-disable-multibyte-mule4 'ignore)))
 395
 396 (defun mm-preferred-coding-system (charset)
 397   ;; A typo in some Emacs versions.
 398   (or (get-charset-property charset 'preferred-coding-system)
 399       (get-charset-property charset 'prefered-coding-system)))
 400
 401 (defun mm-charset-after (&optional pos)
 402   "Return charset of a character in current buffer at position POS.
 403 If POS is nil, it defauls to the current point.
 404 If POS is out of range, the value is nil.
 405 If the charset is `composition', return the actual one."
 406   (let ((char (char-after pos)) charset)
 407     (if (< (mm-char-int char) 128)
 408         (setq charset 'ascii)
 409       ;; charset-after is fake in some Emacsen.
 410       (setq charset (and (fboundp 'char-charset) (char-charset char)))
 411       (if (eq charset 'composition)
 412           (let ((p (or pos (point))))
 413             (cadr (find-charset-region p (1+ p))))
 414         (if (and charset (not (memq charset '(ascii eight-bit-control
 415                                                     eight-bit-graphic))))
 416             charset
 417           (or
 418            mail-parse-mule-charset ;; cached mule-charset
 419            (progn
 420              (setq mail-parse-mule-charset
 421                    (and (boundp 'current-language-environment)
 422                         (car (last
 423                               (assq 'charset
 424                                     (assoc current-language-environment
 425                                            language-info-alist))))))
 426              (if (or (not mail-parse-mule-charset)
 427                      (eq mail-parse-mule-charset 'ascii))
 428                  (setq mail-parse-mule-charset
 429                        (or (car (last (assq mail-parse-charset
 430                                             mm-mime-mule-charset-alist)))
 431                            ;; Fixme: don't fix that!
 432                            'latin-iso8859-1)))
 433              mail-parse-mule-charset)))))))
 434
 435 (defun mm-mime-charset (charset)
 436   "Return the MIME charset corresponding to the given Mule CHARSET."
 437   (if (eq charset 'unknown)
 438       (error "The message contains non-printable characters, please use attachment"))
 439   (if (and (fboundp 'coding-system-get) (fboundp 'get-charset-property))
 440       ;; This exists in Emacs 20.
 441       (or
 442        (and (mm-preferred-coding-system charset)
 443             (coding-system-get
 444              (mm-preferred-coding-system charset) 'mime-charset))
 445        (and (eq charset 'ascii)
 446             'us-ascii)
 447        (mm-preferred-coding-system charset)
 448        (mm-mule-charset-to-mime-charset charset))
 449     ;; This is for XEmacs.
 450     (mm-mule-charset-to-mime-charset charset)))
 451
 452 (defun mm-delete-duplicates (list)
 453   "Simple  substitute for CL `delete-duplicates', testing with `equal'."
 454   (let (result head)
 455     (while list
 456       (setq head (car list))
 457       (setq list (delete head list))
 458       (setq result (cons head result)))
 459     (nreverse result)))
 460
 461 ;; It's not clear whether this is supposed to mean the global or local
 462 ;; setting.  I think it's used inconsistently.  -- fx
 463 (defsubst mm-multibyte-p ()
 464   "Say whether multibyte is enabled."
 465   (if (and (not (featurep 'xemacs))
 466            (boundp 'enable-multibyte-characters))
 467       enable-multibyte-characters
 468     (featurep 'mule)))
 469
 470 (defun mm-iso-8859-x-to-15-region (&optional b e)
 471   (if (fboundp 'char-charset)
 472       (let (charset item c inconvertible)
 473         (save-restriction
 474           (if e (narrow-to-region b e))
 475           (goto-char (point-min))
 476           (skip-chars-forward "\0-\177")
 477           (while (not (eobp))
 478             (cond
 479              ((not (setq item (assq (char-charset (setq c (char-after)))
 480                                     mm-iso-8859-x-to-15-table)))
 481               (forward-char))
 482              ((memq c (cdr (cdr item)))
 483               (setq inconvertible t)
 484               (forward-char))
 485              (t
 486               (insert (prog1 (+ c (car (cdr item))) (delete-char 1))))
 487             (skip-chars-forward "\0-\177"))))
 488         (not inconvertible))))
 489
 490 (defun mm-sort-coding-systems-predicate (a b)
 491   (> (length (memq a mm-coding-system-priorities))
 492      (length (memq b mm-coding-system-priorities))))
 493
 494 (defun mm-find-mime-charset-region (b e &optional hack-charsets)
 495   "Return the MIME charsets needed to encode the region between B and E.
 496 nil means ASCII, a single-element list represents an appropriate MIME
 497 charset, and a longer list means no appropriate charset."
 498   (let (charsets)
 499     ;; The return possibilities of this function are a mess...
 500     (or (and (mm-multibyte-p)
 501              mm-use-find-coding-systems-region
 502              ;; Find the mime-charset of the most preferred coding
 503              ;; system that has one.
 504              (let ((systems (find-coding-systems-region b e)))
 505                (when mm-coding-system-priorities
 506                  (setq systems
 507                        (sort systems 'mm-sort-coding-systems-predicate)))
 508                ;; Fixme: The `mime-charset' (`x-ctext') of `compound-text'
 509                ;; is not in the IANA list.
 510                (setq systems (delq 'compound-text systems))
 511                (unless (equal systems '(undecided))
 512                  (while systems
 513                    (let ((cs (coding-system-get (pop systems) 'mime-charset)))
 514                      (if cs
 515                          (setq systems nil
 516                                charsets (list cs))))))
 517                charsets))
 518         ;; Otherwise we're not multibyte, XEmacs or a single coding
 519         ;; system won't cover it.
 520         (setq charsets
 521               (mm-delete-duplicates
 522                (mapcar 'mm-mime-charset
 523                        (delq 'ascii
 524                              (mm-find-charset-region b e))))))
 525     (if (and (memq 'iso-8859-15 charsets)
 526              (memq 'iso-8859-15 hack-charsets)
 527              (save-excursion (mm-iso-8859-x-to-15-region b e)))
 528         (mapcar (lambda (x) (setq charsets (delq (car x) charsets)))
 529                 mm-iso-8859-15-compatible))
 530     (if (and (memq 'iso-2022-jp-2 charsets)
 531              (memq 'iso-2022-jp-2 hack-charsets))
 532         (setq charsets (delq 'iso-2022-jp charsets)))
 533     charsets))
 534
 535 (defmacro mm-with-unibyte-buffer (&rest forms)
 536   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 537 Use unibyte mode for this."
 538   `(let (default-enable-multibyte-characters)
 539      (with-temp-buffer ,@forms)))
 540 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 541 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 542
 543 (defmacro mm-with-unibyte-current-buffer (&rest forms)
 544   "Evaluate FORMS with current current buffer temporarily made unibyte.
 545 Also bind `default-enable-multibyte-characters' to nil.
 546 Equivalent to `progn' in XEmacs"
 547   (let ((multibyte (make-symbol "multibyte"))
 548         (buffer (make-symbol "buffer")))
 549     `(if mm-emacs-mule
 550          (let ((,multibyte enable-multibyte-characters)
 551                (,buffer (current-buffer)))
 552            (unwind-protect
 553                (let (default-enable-multibyte-characters)
 554                  (set-buffer-multibyte nil)
 555                  ,@forms)
 556              (set-buffer ,buffer)
 557              (set-buffer-multibyte ,multibyte)))
 558        (let (default-enable-multibyte-characters)
 559          ,@forms))))
 560 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 561 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 562
 563 (defmacro mm-with-unibyte-current-buffer-mule4 (&rest forms)
 564   "Evaluate FORMS there like `progn' in current buffer.
 565 Mule4 only."
 566   (let ((multibyte (make-symbol "multibyte"))
 567         (buffer (make-symbol "buffer")))
 568     `(if mm-mule4-p
 569          (let ((,multibyte enable-multibyte-characters)
 570                (,buffer (current-buffer)))
 571            (unwind-protect
 572                (let (default-enable-multibyte-characters)
 573                  (set-buffer-multibyte nil)
 574                  ,@forms)
 575              (set-buffer ,buffer)
 576              (set-buffer-multibyte ,multibyte)))
 577        (let (default-enable-multibyte-characters)
 578          ,@forms))))
 579 (put 'mm-with-unibyte-current-buffer-mule4 'lisp-indent-function 0)
 580 (put 'mm-with-unibyte-current-buffer-mule4 'edebug-form-spec '(body))
 581
 582 (defmacro mm-with-unibyte (&rest forms)
 583   "Eval the FORMS with the default value of `enable-multibyte-characters' nil, ."
 584   `(let (default-enable-multibyte-characters)
 585      ,@forms))
 586 (put 'mm-with-unibyte 'lisp-indent-function 0)
 587 (put 'mm-with-unibyte 'edebug-form-spec '(body))
 588
 589 (defun mm-find-charset-region (b e)
 590   "Return a list of Emacs charsets in the region B to E."
 591   (cond
 592    ((and (mm-multibyte-p)
 593          (fboundp 'find-charset-region))
 594     ;; Remove composition since the base charsets have been included.
 595     ;; Remove eight-bit-*, treat them as ascii.
 596     (let ((css (find-charset-region b e)))
 597       (mapcar (lambda (cs) (setq css (delq cs css)))
 598               '(composition eight-bit-control eight-bit-graphic
 599                             control-1))
 600       css))
 601    (t
 602     ;; We are in a unibyte buffer or XEmacs non-mule, so we futz around a bit.
 603     (save-excursion
 604       (save-restriction
 605         (narrow-to-region b e)
 606         (goto-char (point-min))
 607         (skip-chars-forward "\0-\177")
 608         (if (eobp)
 609             '(ascii)
 610           (let (charset)
 611             (setq charset
 612                   (and (boundp 'current-language-environment)
 613                        (car (last (assq 'charset
 614                                         (assoc current-language-environment
 615                                                language-info-alist))))))
 616             (if (eq charset 'ascii) (setq charset nil))
 617             (or charset
 618                 (setq charset
 619                       (car (last (assq mail-parse-charset
 620                                        mm-mime-mule-charset-alist)))))
 621             (list 'ascii (or charset 'latin-iso8859-1)))))))))
 622
 623 (if (fboundp 'shell-quote-argument)
 624     (defalias 'mm-quote-arg 'shell-quote-argument)
 625   (defun mm-quote-arg (arg)
 626     "Return a version of ARG that is safe to evaluate in a shell."
 627     (let ((pos 0) new-pos accum)
 628       ;; *** bug: we don't handle newline characters properly
 629       (while (setq new-pos (string-match "[]*[;!'`\"$\\& \t{} |()<>]" arg pos))
 630         (push (substring arg pos new-pos) accum)
 631         (push "\\" accum)
 632         (push (list (aref arg new-pos)) accum)
 633         (setq pos (1+ new-pos)))
 634       (if (= pos 0)
 635           arg
 636         (apply 'concat (nconc (nreverse accum) (list (substring arg pos))))))))
 637
 638 (defun mm-auto-mode-alist ()
 639   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 640   (let ((alist auto-mode-alist)
 641         out)
 642     (while alist
 643       (when (listp (cdar alist))
 644         (push (car alist) out))
 645       (pop alist))
 646     (nreverse out)))
 647
 648 (defvar mm-inhibit-file-name-handlers
 649   '(jka-compr-handler image-file-handler)
 650   "A list of handlers doing (un)compression (etc) thingies.")
 651
 652 (defun mm-insert-file-contents (filename &optional visit beg end replace
 653                                          inhibit)
 654   "Like `insert-file-contents', q.v., but only reads in the file.
 655 A buffer may be modified in several ways after reading into the buffer due
 656 to advanced Emacs features, such as file-name-handlers, format decoding,
 657 find-file-hooks, etc.
 658 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers.
 659   This function ensures that none of these modifications will take place."
 660   (let ((format-alist nil)
 661         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 662         (default-major-mode 'fundamental-mode)
 663         (enable-local-variables nil)
 664         (after-insert-file-functions nil)
 665         (enable-local-eval nil)
 666         (find-file-hooks nil)
 667         (inhibit-file-name-operation (if inhibit
 668                                          'insert-file-contents
 669                                        inhibit-file-name-operation))
 670         (inhibit-file-name-handlers
 671          (if inhibit
 672              (append mm-inhibit-file-name-handlers
 673                      inhibit-file-name-handlers)
 674            inhibit-file-name-handlers)))
 675     (insert-file-contents filename visit beg end replace)))
 676
 677 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 678   "Append the contents of the region to the end of file FILENAME.
 679 When called from a function, expects three arguments,
 680 START, END and FILENAME.  START and END are buffer positions
 681 saying what text to write.
 682 Optional fourth argument specifies the coding system to use when
 683 encoding the file.
 684 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 685   (let ((coding-system-for-write
 686          (or codesys mm-text-coding-system-for-write
 687              mm-text-coding-system))
 688         (inhibit-file-name-operation (if inhibit
 689                                          'append-to-file
 690                                        inhibit-file-name-operation))
 691         (inhibit-file-name-handlers
 692          (if inhibit
 693              (append mm-inhibit-file-name-handlers
 694                      inhibit-file-name-handlers)
 695            inhibit-file-name-handlers)))
 696     (append-to-file start end filename)))
 697
 698 (defun mm-write-region (start end filename &optional append visit lockname
 699                               coding-system inhibit)
 700
 701   "Like `write-region'.
 702 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 703   (let ((coding-system-for-write
 704          (or coding-system mm-text-coding-system-for-write
 705              mm-text-coding-system))
 706         (inhibit-file-name-operation (if inhibit
 707                                          'write-region
 708                                        inhibit-file-name-operation))
 709         (inhibit-file-name-handlers
 710          (if inhibit
 711              (append mm-inhibit-file-name-handlers
 712                      inhibit-file-name-handlers)
 713            inhibit-file-name-handlers)))
 714     (write-region start end filename append visit lockname)))
 715
 716 (defun mm-image-load-path (&optional package)
 717   (let (dir result)
 718     (dolist (path load-path (nreverse result))
 719       (if (file-directory-p
 720            (setq dir (concat (file-name-directory
 721                               (directory-file-name path))
 722                              "etc/" (or package "gnus/"))))
 723           (push dir result))
 724       (push path result))))
 725
 726 (provide 'mm-util)
 727
 728 ;;; mm-util.el ends here