configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation; either version 3, or (at your option)
  14 dnl  any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  23 dnl  Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 dnl  Boston, MA 02110-1301, USA.
  25
  26 AC_PREREQ(2.61)dnl
  27 AC_INIT(emacs, 23.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 lispdir='${datadir}/emacs/${version}/lisp'
  36 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  37 '${datadir}/emacs/site-lisp'
  38 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  39 etcdir='${datadir}/emacs/${version}/etc'
  40 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  41 docdir='${datadir}/emacs/${version}/etc'
  42 gamedir='${localstatedir}/games/emacs'
  43
  44 gameuser=games
  45
  46 dnl Autoconf is so much less fun under VMS, maybe
  47 dnl because everything is less fun under VMS. --ttn
  48 AC_DEFUN([EMACS_ARG_Y],[dnl
  49 AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[$3],[$4])dnl
  50 ])dnl
  51 AC_DEFUN([EMACS_ARG_N],[dnl
  52 AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[$3],[$4])dnl
  53 ])dnl
  54
  55 EMACS_ARG_N([gcc],[don't use GCC to compile Emacs if GCC is found])
  56
  57 EMACS_ARG_N([pop],[don't support POP mail retrieval with movemail],
  58 [if test "$withval" = yes; then
  59    AC_DEFINE(MAIL_USE_POP)
  60 else :
  61 fi],
  62 AC_DEFINE(MAIL_USE_POP))
  63 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  64
  65 EMACS_ARG_Y([kerberos],[support Kerberos-authenticated POP],
  66 [if test "$withval" = yes; then
  67    AC_DEFINE(KERBEROS)
  68 fi])
  69 AH_TEMPLATE(KERBEROS,
  70             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  71
  72 EMACS_ARG_Y([kerberos5],[support Kerberos version 5 authenticated POP],
  73 [if test "${with_kerberos5+set}" = set; then
  74   if test "${with_kerberos+set}" != set; then
  75     with_kerberos=yes
  76     AC_DEFINE(KERBEROS)
  77   fi
  78   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  79 fi])
  80
  81 EMACS_ARG_Y([hesiod],[support Hesiod to get the POP server host],
  82 [if test "$withval" = yes; then
  83   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  84 fi])
  85
  86 EMACS_ARG_N([sound],[don't compile with sound support])
  87
  88 dnl This should be the last --with option, because --with-x is
  89 dnl added later on when we find the path of X, and it's best to
  90 dnl keep them together visually.
  91 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
  92  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
  93 [         case "${withval}" in
  94             y | ye | yes )      val=gtk ;;
  95             n | no )            val=no  ;;
  96             l | lu | luc | luci | lucid )       val=lucid ;;
  97             a | at | ath | athe | athen | athena )      val=athena ;;
  98             m | mo | mot | moti | motif )       val=motif ;;
  99             g | gt | gtk  )     val=gtk ;;
 100             * )
 101 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 102 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 103 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 104             ;;
 105           esac
 106           with_x_toolkit=$val
 107 ])
 108
 109 EMACS_ARG_Y([xpm],[use -lXpm for displaying XPM images])
 110 EMACS_ARG_Y([jpeg],[use -ljpeg for displaying JPEG images])
 111 EMACS_ARG_Y([tiff],[use -ltiff for displaying TIFF images])
 112 EMACS_ARG_Y([gif],[use -lgif (or -lungif) for displaying GIF images])
 113 EMACS_ARG_Y([png],[use -lpng for displaying PNG images])
 114 EMACS_ARG_Y([gpm],[use -lgpm for mouse support on a GNU/Linux console])
 115 EMACS_ARG_Y([rsvg],[use -lrsvg-2 for displaying SVG images])
 116 EMACS_ARG_Y([gtk],[use GTK (same as --with-x-toolkit=gtk)])
 117 EMACS_ARG_Y([pkg-config-prog],[Path to pkg-config for finding GTK and librsvg])
 118 EMACS_ARG_N([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 119 EMACS_ARG_N([xaw3d],[don't use Xaw3d])
 120 EMACS_ARG_N([xim],[don't use X11 XIM])
 121 EMACS_ARG_N([carbon],[don't use Carbon GUI on Mac OS X])
 122 EMACS_ARG_Y([dbus],[use D-Bus])
 123
 124 AC_ARG_ENABLE(carbon-app,
 125 [AS_HELP_STRING([--enable-carbon-app@<:@=DIR@:>@],
 126                 [specify install directory for Emacs.app on Mac OS X
 127                  [DIR=/Application]])],
 128 [ carbon_appdir_x=${enableval}])
 129
 130 AC_ARG_ENABLE(asserts,
 131 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 132       USE_XASSERTS=$enableval,
 133       USE_XASSERTS=no)
 134
 135 AC_ARG_ENABLE(maintainer-mode,
 136 [AS_HELP_STRING([--enable-maintainer-mode],
 137                 [enable make rules and dependencies not useful (and sometimes
 138                  confusing) to the casual installer])],
 139       USE_MAINTAINER_MODE=$enableval,
 140       USE_MAINTAINER_MODE=no)
 141 if test $USE_MAINTAINER_MODE = yes; then
 142   MAINT=
 143 else
 144   MAINT=#
 145 fi
 146 AC_SUBST(MAINT)
 147
 148 AC_ARG_ENABLE(locallisppath,
 149 [AS_HELP_STRING([--enable-locallisppath=PATH],
 150                 [directories Emacs should search for lisp files specific
 151                  to this site])],
 152 if test "${enableval}" = "no"; then
 153   locallisppath=
 154 elif test "${enableval}" != "yes"; then
 155   locallisppath=${enableval}
 156 fi)
 157
 158 #### Make srcdir absolute, if it isn't already.  It's important to
 159 #### avoid running the path through pwd unnecessarily, since pwd can
 160 #### give you automounter prefixes, which can go away.  We do all this
 161 #### so Emacs can find its files when run uninstalled.
 162 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 163 unset CDPATH
 164 case "${srcdir}" in
 165   /* ) ;;
 166   . )
 167     ## We may be able to use the $PWD environment variable to make this
 168     ## absolute.  But sometimes PWD is inaccurate.
 169     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 170     ## but that tested only for a well-formed and valid PWD,
 171     ## it did not object when PWD was well-formed and valid but just wrong.
 172     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 173     then
 174       srcdir="$PWD"
 175     else
 176       srcdir="`(cd ${srcdir}; pwd)`"
 177     fi
 178   ;;
 179   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 180 esac
 181
 182 #### Check if the source directory already has a configured system in it.
 183 if test `pwd` != `(cd ${srcdir} && pwd)` \
 184    && test -f "${srcdir}/src/config.h" ; then
 185   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 186    as a build directory right now; it has been configured in its own
 187    right.  To configure in another directory as well, you MUST
 188    use GNU make.  If you do not have GNU make, then you must
 189    now do `make distclean' in ${srcdir},
 190    and then run $0 again.]])
 191 fi
 192
 193 #### Given the configuration name, set machfile and opsysfile to the
 194 #### names of the m/*.h and s/*.h files we should use.
 195
 196 ### Canonicalize the configuration name.
 197
 198 AC_CANONICAL_HOST
 199 canonical=$host
 200 configuration=${host_alias-${build_alias-$host}}
 201
 202 dnl This used to use changequote, but, apart from `changequote is evil'
 203 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 204 dnl the great gob of text.  Thus it's not processed for possible expansion.
 205 dnl Just make sure the brackets remain balanced.
 206 dnl
 207 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 208 dnl indicated by comments.
 209 dnl quotation begins
 210 [
 211
 212 ### If you add support for a new configuration, add code to this
 213 ### switch statement to recognize your configuration name and select
 214 ### the appropriate operating system and machine description files.
 215
 216 ### You would hope that you could choose an m/*.h file pretty much
 217 ### based on the machine portion of the configuration name, and an s-
 218 ### file based on the operating system portion.  However, it turns out
 219 ### that each m/*.h file is pretty manufacturer-specific - for
 220 ### example hp9000s300.h is a 68000 machine;
 221 ### mips.h, pmax.h are all MIPS
 222 ### machines.  So we basically have to have a special case for each
 223 ### configuration name.
 224 ###
 225 ### As far as handling version numbers on operating systems is
 226 ### concerned, make sure things will fail in a fixable way.  If
 227 ### /etc/MACHINES doesn't say anything about version numbers, be
 228 ### prepared to handle anything reasonably.  If version numbers
 229 ### matter, be sure /etc/MACHINES says something about it.
 230 ###
 231 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 232 ### "System V Release 4"; he writes, "The old convention encouraged
 233 ### confusion between `system' and `release' levels'."
 234
 235 machine='' opsys='' unported=no
 236 case "${canonical}" in
 237
 238   ## FreeBSD ports
 239   *-*-freebsd* )
 240     opsys=freebsd
 241     case "${canonical}" in
 242       alpha*-*-freebsd*)        machine=alpha ;;
 243       ia64-*-freebsd*)          machine=ia64 ;;
 244       sparc64-*-freebsd*)       machine=sparc ;;
 245       powerpc-*-freebsd*)       machine=macppc ;;
 246       i[3456]86-*-freebsd*)     machine=intel386 ;;
 247       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 248     esac
 249   ;;
 250
 251   ## FreeBSD kernel + glibc based userland
 252   *-*-kfreebsd*gnu* )
 253     opsys=gnu-kfreebsd
 254     case "${canonical}" in
 255       alpha*-*-kfreebsd*)       machine=alpha ;;
 256       ia64-*-kfreebsd*)         machine=ia64 ;;
 257       sparc64-*-kfreebsd*)      machine=sparc ;;
 258       powerpc-*-kfreebsd*)      machine=macppc ;;
 259       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 260       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 261     esac
 262   ;;
 263
 264   ## NetBSD ports
 265   *-*-netbsd* )
 266     opsys=netbsd
 267     if test -f /usr/lib/crti.o; then]
 268 dnl The close and open brackets here are because this section is quoted --
 269 dnl see the `changequote' comment above.
 270       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 271 [   fi
 272
 273     case "${canonical}" in
 274       alpha*-*-netbsd*) machine=alpha ;;
 275       i[3456]86-*-netbsd*) machine=intel386 ;;
 276       m68k-*-netbsd*)
 277                         # This is somewhat bogus.
 278                         machine=hp9000s300 ;;
 279       mips-*-netbsd*)   machine=pmax ;;
 280       mipsel-*-netbsd*) machine=pmax ;;
 281       mipseb-*-netbsd*) machine=pmax ;;
 282       powerpc-*-netbsd*) machine=macppc ;;
 283       sparc*-*-netbsd*) machine=sparc ;;
 284       vax-*-netbsd*)    machine=vax ;;
 285       arm-*-netbsd*)    machine=arm ;;
 286       x86_64-*-netbsd*) machine=amdx86-64 ;;
 287       hppa-*-netbsd*)   machine=hp800 ;;
 288     esac
 289   ;;
 290
 291   ## OpenBSD ports
 292   *-*-openbsd* )
 293     opsys=openbsd
 294     case "${canonical}" in
 295       alpha*-*-openbsd*)        machine=alpha ;;
 296       arm-*-openbsd*)          machine=arm ;;
 297       hppa-*-openbsd*)         machine=hp9000s300 ;;
 298       i386-*-openbsd*)         machine=intel386 ;;
 299       m68k-*-openbsd*)         machine=hp9000s300 ;;
 300       mips64-*-openbsd*)       machine=mips64 ;;
 301       powerpc-*-openbsd*)      machine=macppc ;;
 302       sparc*-*-openbsd*)       machine=sparc ;;
 303       vax-*-openbsd*)          machine=vax ;;
 304       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 305     esac
 306   ;;
 307
 308   ## LynxOS ports
 309   *-*-lynxos* )
 310     opsys=lynxos
 311     case "${canonical}" in
 312       i[3456]86-*-lynxos*) machine=intel386 ;;
 313       powerpc-*-lynxos*) machine=powerpc ;;
 314     esac
 315   ;;
 316
 317   ## BSDI ports
 318   *-*-bsdi* )
 319     opsys=bsdi
 320     case "${canonical}" in
 321       i[345]86-*-bsdi*) machine=intel386 ;;
 322       sparc-*-bsdi*)  machine=sparc ;;
 323       powerpc-*-bsdi*)  machine=macppc ;;
 324     esac
 325     case "${canonical}" in
 326       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 327       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 328       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 329       *-*-bsdi3* )              opsys=bsdos3 ;;
 330       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 331     esac
 332   ;;
 333
 334   ## Alpha (DEC) machines.
 335   alpha*-dec-osf* )
 336     machine=alpha opsys=osf1
 337     # This is needed to find X11R6.1 libraries for certain tests.
 338     NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 339     GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 340     # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
 341     # due to non-traditional preprocessing with the current compiler
 342     # defaults.  OSF 4 can also have that compiler version, and there
 343     # seems always to have been a usable /usr/bin/cpp.
 344     NON_GNU_CPP=/usr/bin/cpp
 345     case "${canonical}" in
 346     alpha*-dec-osf[5-9]*)
 347       opsys=osf5-0 ;;
 348     esac
 349   ;;
 350
 351   alpha*-*-linux-gnu* )
 352     machine=alpha opsys=gnu-linux
 353   ;;
 354
 355   arm*-*-linux-gnu* )
 356     machine=arm opsys=gnu-linux
 357   ;;
 358
 359   ## Apple Darwin / Mac OS X
 360   *-apple-darwin* )
 361     case "${canonical}" in
 362       i[3456]86-* )  machine=intel386 ;;
 363       powerpc-* )    machine=powermac ;;
 364       * )            unported=yes ;;
 365     esac
 366     opsys=darwin
 367     # Define CPP as follows to make autoconf work correctly.
 368     CPP="${CC-cc} -E -no-cpp-precomp"
 369     # Use fink packages if available.
 370     if test -d /sw/include && test -d /sw/lib; then
 371       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 372       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 373       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 374     fi
 375   ;;
 376
 377   ## Compaq Nonstop
 378   mips-compaq-nonstopux* )
 379     machine=nonstopux opsys=nonstopux
 380     ;;
 381
 382   ## Cubix QBx/386
 383   i[3456]86-cubix-sysv* )
 384     machine=intel386 opsys=usg5-3
 385   ;;
 386
 387   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 388     machine=pmax opsys=bsd4-2
 389   ;;
 390   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 391     machine=pmax opsys=bsd4-3
 392   ;;
 393   mips-dec-ultrix* )
 394     machine=pmax opsys=ultrix4-3
 395   ;;
 396   mips-dec-osf* )
 397     machine=pmax opsys=osf1
 398   ;;
 399   mips-dec-mach_bsd4.3* )
 400     machine=pmax opsys=mach-bsd4-3
 401   ;;
 402
 403   ## HP 9000 series 200 or 300
 404   m68*-hp-bsd* )
 405     machine=hp9000s300 opsys=bsd4-3
 406   ;;
 407   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 408   m68*-hp-hpux* )
 409     case "`uname -r`" in
 410       ## Someone's system reports A.B8.05 for this.
 411       ## I wonder what other possibilities there are.
 412       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 413       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 414       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 415       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 416       *) machine=hp9000s300 opsys=hpux ;;
 417     esac
 418   ;;
 419
 420   ## HP 9000 series 700 and 800, running HP/UX
 421   hppa*-hp-hpux7* )
 422     machine=hp800 opsys=hpux
 423   ;;
 424   hppa*-hp-hpux8* )
 425     machine=hp800 opsys=hpux8
 426   ;;
 427   hppa*-hp-hpux9shr* )
 428     machine=hp800 opsys=hpux9shr
 429   ;;
 430   hppa*-hp-hpux9* )
 431     machine=hp800 opsys=hpux9
 432   ;;
 433   hppa*-hp-hpux10.2* )
 434     machine=hp800 opsys=hpux10-20
 435   ;;
 436   hppa*-hp-hpux10* )
 437     machine=hp800 opsys=hpux10
 438   ;;
 439   hppa*-hp-hpux1[1-9]* )
 440     machine=hp800 opsys=hpux11
 441     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 442   ;;
 443
 444   hppa*-*-linux-gnu* )
 445     machine=hp800 opsys=gnu-linux
 446   ;;
 447
 448   ## HP 9000 series 700 and 800, running HP/UX
 449   hppa*-hp-hpux* )
 450     ## Cross-compilation?  Nah!
 451     case "`uname -r`" in
 452       ## Someone's system reports A.B8.05 for this.
 453       ## I wonder what other possibilities there are.
 454       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 455       *.08.* ) machine=hp800 opsys=hpux8 ;;
 456       *.09.* ) machine=hp800 opsys=hpux9 ;;
 457       *) machine=hp800 opsys=hpux10 ;;
 458     esac
 459   ;;
 460   hppa*-*-nextstep* )
 461     machine=hp800 opsys=nextstep
 462   ;;
 463
 464   ## IBM machines
 465   i370-ibm-aix*)
 466     machine=ibm370aix opsys=usg5-3
 467   ;;
 468   s390-*-linux-gnu* )
 469     machine=ibms390 opsys=gnu-linux
 470   ;;
 471   s390x-*-linux-gnu* )
 472     machine=ibms390x opsys=gnu-linux
 473   ;;
 474   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 475     machine=ibmrs6000 opsys=aix3-1
 476   ;;
 477   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 478     machine=ibmrs6000 opsys=aix3-2-5
 479   ;;
 480   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 481     machine=ibmrs6000 opsys=aix4-1
 482   ;;
 483   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 484     machine=ibmrs6000 opsys=aix4-2
 485   ;;
 486   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 487     machine=ibmrs6000 opsys=aix4-2
 488   ;;
 489   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 490     machine=ibmrs6000 opsys=aix4-2
 491   ;;
 492   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 493     machine=ibmrs6000 opsys=aix4
 494   ;;
 495   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 496     machine=ibmrs6000 opsys=aix4-1
 497   ;;
 498   rs6000-ibm-aix* | powerpc-ibm-aix* )
 499     machine=ibmrs6000 opsys=aix3-2
 500   ;;
 501
 502   ## Prime EXL
 503   i[3456]86-prime-sysv* )
 504     machine=i386 opsys=usg5-3
 505   ;;
 506
 507   ## ncr machine running svr4.3.
 508   i[3456]86-ncr-sysv4.3 )
 509     machine=ncr386 opsys=usg5-4-3
 510   ;;
 511
 512   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 513   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 514   i[3456]86-ncr-sysv* )
 515     machine=ncr386 opsys=usg5-4-2
 516   ;;
 517
 518   ## Macintosh PowerPC
 519   powerpc*-*-linux-gnu* )
 520     machine=macppc opsys=gnu-linux
 521   ;;
 522
 523   ## Workstations sold by MIPS
 524   ## This is not necessarily all workstations using the MIPS processor -
 525   ## Irises are produced by SGI, and DECstations by DEC.
 526
 527   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 528   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 529   ## it gives for choosing between the alternatives seems to be "Use
 530   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 531   ## the BSD world."  I'll assume that these are instructions for
 532   ## handling two odd situations, and that every other situation
 533   ## should use mips.h and usg5-2-2, they being listed first.
 534   mips-mips-usg* )
 535     machine=mips4
 536     ## Fall through to the general code at the bottom to decide on the OS.
 537   ;;
 538   mips-mips-riscos4* )
 539     machine=mips4 opsys=bsd4-3
 540     NON_GNU_CC="cc -systype bsd43"
 541     NON_GNU_CPP="cc -systype bsd43 -E"
 542   ;;
 543   mips-mips-riscos5* )
 544     machine=mips4 opsys=riscos5
 545     NON_GNU_CC="cc -systype bsd43"
 546     NON_GNU_CPP="cc -systype bsd43 -E"
 547   ;;
 548   mips-mips-bsd* )
 549     machine=mips opsys=bsd4-3
 550   ;;
 551   mips-mips-* )
 552     machine=mips opsys=usg5-2-2
 553   ;;
 554
 555   ## NeXT
 556   m68*-next-* | m68k-*-nextstep* )
 557     machine=m68k opsys=nextstep
 558   ;;
 559
 560   ## NEC EWS4800
 561   mips-nec-sysv4*)
 562   machine=ews4800 opsys=ux4800
 563   ;;
 564
 565   ## Siemens Nixdorf
 566   mips-siemens-sysv* | mips-sni-sysv*)
 567     machine=mips-siemens opsys=usg5-4
 568     NON_GNU_CC=/usr/ccs/bin/cc
 569     NON_GNU_CPP=/usr/ccs/lib/cpp
 570   ;;
 571
 572   ## Silicon Graphics machines
 573   ## Iris 4D
 574   mips-sgi-irix6.5 )
 575     machine=iris4d opsys=irix6-5
 576     # Without defining _LANGUAGE_C, things get masked out in the headers
 577     # so that, for instance, grepping for `free' in stdlib.h fails and
 578     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 579     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 580     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 581   ;;
 582   mips-sgi-irix6* )
 583     machine=iris4d opsys=irix6-0
 584     # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
 585     # but presumably it does no harm.
 586     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 587     # -32 probably isn't necessary in later v.6s -- anyone know which?
 588     NON_GCC_TEST_OPTIONS=-32
 589   ;;
 590   mips-sgi-irix5.[01]* )
 591     machine=iris4d opsys=irix5-0
 592   ;;
 593   mips-sgi-irix5* | mips-sgi-irix* )
 594     machine=iris4d opsys=irix5-2
 595   ;;
 596
 597   ## Suns
 598   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 599     machine=sparc opsys=gnu-linux
 600   ;;
 601
 602   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 603     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 604     | rs6000-*-solaris2*)
 605     case "${canonical}" in
 606       i[3456]86-*-* )     machine=intel386 ;;
 607       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 608       powerpcle* )      machine=powerpcle ;;
 609       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 610       sparc* )          machine=sparc ;;
 611       * )               unported=yes ;;
 612     esac
 613     case "${canonical}" in
 614       *-sunos5.3* | *-solaris2.3* )
 615                 opsys=sol2-3
 616                 NON_GNU_CPP=/usr/ccs/lib/cpp
 617                 ;;
 618       *-sunos5.4* | *-solaris2.4* )
 619                 opsys=sol2-4
 620                 NON_GNU_CPP=/usr/ccs/lib/cpp
 621                 RANLIB="ar -ts"
 622                 ;;
 623       *-sunos5.5* | *-solaris2.5* )
 624                 opsys=sol2-5
 625                 NON_GNU_CPP=/usr/ccs/lib/cpp
 626                 RANLIB="ar -ts"
 627                 ;;
 628       *-sunos5.6* | *-solaris2.6* )
 629                 opsys=sol2-6
 630                 NON_GNU_CPP=/usr/ccs/lib/cpp
 631                 RANLIB="ar -ts"
 632                 ;;
 633       *-sunos5* | *-solaris* )
 634                 opsys=sol2-6
 635                 emacs_check_sunpro_c=yes
 636                 NON_GNU_CPP=/usr/ccs/lib/cpp
 637                 ;;
 638       *                   ) opsys=bsd4-2   ;;
 639     esac
 640     ## Watch out for a compiler that we know will not work.
 641     case "${canonical}" in
 642      *-solaris* | *-sunos5* )
 643                 if [ "x$CC" = x/usr/ucb/cc ]; then
 644                   ## /usr/ucb/cc doesn't work;
 645                   ## we should find some other compiler that does work.
 646                   unset CC
 647                 fi
 648                 ;;
 649       *) ;;
 650     esac
 651   ;;
 652   sparc-*-nextstep* )
 653     machine=sparc opsys=nextstep
 654   ;;
 655
 656   ## Tandem Integrity S2
 657   mips-tandem-sysv* )
 658     machine=tandem-s2 opsys=usg5-3
 659   ;;
 660
 661   ## Vaxen.
 662   vax-dec-* )
 663     machine=vax
 664     case "${canonical}" in
 665       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 666       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 667       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 668       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 669       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 670       *-vms* )                                          opsys=vms ;;
 671       * )                                               unported=yes
 672     esac
 673   ;;
 674
 675   ## IA-64
 676   ia64*-*-linux* )
 677     machine=ia64 opsys=gnu-linux
 678   ;;
 679
 680   ## Intel 386 machines where we don't care about the manufacturer
 681   i[3456]86-*-* )
 682     machine=intel386
 683     case "${canonical}" in
 684       *-cygwin )                opsys=cygwin ;;
 685       *-darwin* )               opsys=darwin
 686                                 CPP="${CC-cc} -E -no-cpp-precomp"
 687                                 ;;
 688       *-xenix* )                opsys=xenix ;;
 689       *-linux-gnu* )            opsys=gnu-linux ;;
 690       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 691       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 692       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 693       *-386bsd* )               opsys=386bsd ;;
 694       *-nextstep* )             opsys=nextstep ;;
 695       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 696     esac
 697   ;;
 698
 699   ## m68k Linux-based GNU system
 700   m68k-*-linux-gnu* )
 701     machine=m68k opsys=gnu-linux
 702   ;;
 703
 704   ## Mips Linux-based GNU system
 705   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 706     machine=mips opsys=gnu-linux
 707   ;;
 708
 709   ## UXP/DS
 710   sparc-fujitsu-sysv4* )
 711     machine=sparc opsys=uxpds
 712     NON_GNU_CPP=/usr/ccs/lib/cpp
 713     RANLIB="ar -ts"
 714   ;;
 715
 716   ## AMD x86-64 Linux-based GNU system
 717   x86_64-*-linux-gnu* )
 718     machine=amdx86-64 opsys=gnu-linux
 719   ;;
 720
 721   ## Tensilica Xtensa Linux-based GNU system
 722   xtensa-*-linux-gnu* )
 723     machine=xtensa opsys=gnu-linux
 724     ;;
 725
 726   * )
 727     unported=yes
 728   ;;
 729 esac
 730
 731 ### If the code above didn't choose an operating system, just choose
 732 ### an operating system based on the configuration name.  You really
 733 ### only want to use this when you have no idea what the right
 734 ### operating system is; if you know what operating systems a machine
 735 ### runs, it's cleaner to make it explicit in the case statement
 736 ### above.
 737 if test x"${opsys}" = x; then
 738   case "${canonical}" in
 739     *-gnu* )                            opsys=gnu ;;
 740     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 741     *-bsd4.2 )                          opsys=bsd4-2 ;;
 742     *-bsd4.3 )                          opsys=bsd4-3 ;;
 743     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 744     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 745     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 746     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 747     *-sysv4.2uw* )                      opsys=unixware ;;
 748     *-sysv5uw* )                        opsys=unixware ;;
 749     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 750     *-sysv4.1* | *-sysvr4.1* )
 751         NON_GNU_CPP=/usr/lib/cpp
 752         opsys=usg5-4 ;;
 753     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 754         if [ x$NON_GNU_CPP = x ]; then
 755           if [ -f /usr/ccs/lib/cpp ]; then
 756             NON_GNU_CPP=/usr/ccs/lib/cpp
 757           else
 758             NON_GNU_CPP=/lib/cpp
 759           fi
 760         fi
 761         opsys=usg5-4-2 ;;
 762     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 763     * )
 764       unported=yes
 765     ;;
 766   esac
 767 fi
 768
 769 ]
 770 dnl quotation ends
 771
 772 if test $unported = yes; then
 773   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 774 Check `etc/MACHINES' for recognized configuration names.])
 775 fi
 776
 777 machfile="m/${machine}.h"
 778 opsysfile="s/${opsys}.h"
 779
 780
 781 #### Choose a compiler.
 782 test -n "$CC" && cc_specified=yes
 783
 784 # Save the value of CFLAGS that the user specified.
 785 SPECIFIED_CFLAGS="$CFLAGS"
 786
 787 case ${with_gcc} in
 788   "yes" ) CC="gcc" GCC=yes ;;
 789   "no"  ) : ${CC=cc} ;;
 790   * )
 791 esac
 792 AC_PROG_CC
 793
 794 # On Suns, sometimes $CPP names a directory.
 795 if test -n "$CPP" && test -d "$CPP"; then
 796   CPP=
 797 fi
 798
 799 ## If not using gcc, and on Solaris, and no CPP specified, see if
 800 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 801 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 802  test x"$CPP" = x; then
 803   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 804   AC_CACHE_VAL(emacs_cv_sunpro_c,
 805   [AC_TRY_LINK([],
 806 [#ifndef __SUNPRO_C
 807 fail;
 808 #endif
 809 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 810   AC_MSG_RESULT($emacs_cv_sunpro_c)
 811
 812   if test x"$emacs_cv_sunpro_c" = xyes; then
 813     NON_GNU_CPP="$CC -E -Xs"
 814   fi
 815 fi
 816
 817 #### Some systems specify a CPP to use unless we are using GCC.
 818 #### Now that we know whether we are using GCC, we can decide whether
 819 #### to use that one.
 820 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 821 then
 822   CPP="$NON_GNU_CPP"
 823 fi
 824
 825 #### Some systems specify a CC to use unless we are using GCC.
 826 #### Now that we know whether we are using GCC, we can decide whether
 827 #### to use that one.
 828 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 829   test x$cc_specified != xyes
 830 then
 831   CC="$NON_GNU_CC"
 832 fi
 833
 834 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 835 then
 836   CC="$CC $GCC_TEST_OPTIONS"
 837 fi
 838
 839 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 840 then
 841   CC="$CC $NON_GCC_TEST_OPTIONS"
 842 fi
 843
 844 dnl checks for Unix variants
 845 AC_AIX
 846 AC_GNU_SOURCE
 847
 848 ### Use -Wno-pointer-sign if the compiler supports it
 849 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 850 SAVE_CFLAGS="$CFLAGS"
 851 CFLAGS="$CFLAGS -Wno-pointer-sign"
 852 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 853 if test $has_option = yes; then
 854    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 855 fi
 856 AC_MSG_RESULT($has_option)
 857 CFLAGS="$SAVE_CFLAGS"
 858 unset has_option
 859 unset SAVE_CFLAGS
 860
 861 #### Some other nice autoconf tests.
 862
 863 dnl checks for programs
 864 AC_PROG_LN_S
 865 AC_PROG_CPP
 866 AC_PROG_INSTALL
 867 if test "x$RANLIB" = x; then
 868   AC_PROG_RANLIB
 869 fi
 870 AC_PATH_PROG(INSTALL_INFO, install-info)
 871 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 872 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 873 dnl Don't use GZIP, which is used by gzip for additional parameters.
 874 AC_PATH_PROG(GZIP_PROG, gzip)
 875
 876
 877 ## Need makeinfo >= 4.6 (?) to build the manuals.
 878 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 879 dnl By this stage, configure has already checked for egrep and set EGREP,
 880 dnl or exited with an error if no egrep was found.
 881 if test "$MAKEINFO" != "no" && \
 882   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 883    MAKEINFO=no
 884 fi
 885
 886 if test "$MAKEINFO" = "no"; then
 887   AC_MSG_ERROR( [makeinfo >= 4.6 is required] )
 888 fi
 889
 890
 891 dnl Add our options to ac_link now, after it is set up.
 892
 893 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 894 then
 895   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 896 fi
 897
 898 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 899 then
 900   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 901 fi
 902
 903 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 904 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 905 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 906 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 907 dnl if not built to support GNU ld.
 908
 909 late_LDFLAGS=$LDFLAGS
 910 if test "$GCC" = yes; then
 911   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 912 else
 913   LDFLAGS="$LDFLAGS -znocombreloc"
 914 fi
 915
 916 AC_MSG_CHECKING([for -znocombreloc])
 917 AC_LINK_IFELSE([main(){return 0;}],
 918   [AC_MSG_RESULT(yes)],
 919   LDFLAGS=$late_LDFLAGS
 920   [AC_MSG_RESULT(no)])
 921
 922 #### Extract some information from the operating system and machine files.
 923
 924 AC_CHECKING([the machine- and system-dependent files to find out
 925  - which libraries the lib-src programs will want, and
 926  - whether the GNU malloc routines are usable])
 927
 928 ### First figure out CFLAGS (which we use for running the compiler here)
 929 ### and REAL_CFLAGS (which we use for real compilation).
 930 ### The two are the same except on a few systems, where they are made
 931 ### different to work around various lossages.  For example,
 932 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 933 ### as implying static linking.
 934
 935 ### If the CFLAGS env var is specified, we use that value
 936 ### instead of the default.
 937
 938 ### It's not important that this name contain the PID; you can't run
 939 ### two configures in the same directory and have anything work
 940 ### anyway.
 941 tempcname="conftest.c"
 942
 943 echo '
 944 #include "'${srcdir}'/src/'${opsysfile}'"
 945 #include "'${srcdir}'/src/'${machfile}'"
 946 #ifndef LIBS_MACHINE
 947 #define LIBS_MACHINE
 948 #endif
 949 #ifndef LIBS_SYSTEM
 950 #define LIBS_SYSTEM
 951 #endif
 952 #ifndef C_SWITCH_SYSTEM
 953 #define C_SWITCH_SYSTEM
 954 #endif
 955 #ifndef C_SWITCH_MACHINE
 956 #define C_SWITCH_MACHINE
 957 #endif
 958 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 959 configure___ c_switch_system=C_SWITCH_SYSTEM
 960 configure___ c_switch_machine=C_SWITCH_MACHINE
 961
 962 #ifndef LIB_X11_LIB
 963 #define LIB_X11_LIB -lX11
 964 #endif
 965
 966 #ifndef LIBX11_MACHINE
 967 #define LIBX11_MACHINE
 968 #endif
 969
 970 #ifndef LIBX11_SYSTEM
 971 #define LIBX11_SYSTEM
 972 #endif
 973 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
 974
 975 #ifdef UNEXEC
 976 configure___ unexec=UNEXEC
 977 #else
 978 configure___ unexec=unexec.o
 979 #endif
 980
 981 #ifdef SYSTEM_MALLOC
 982 configure___ system_malloc=yes
 983 #else
 984 configure___ system_malloc=no
 985 #endif
 986
 987 #ifdef USE_MMAP_FOR_BUFFERS
 988 configure___ use_mmap_for_buffers=yes
 989 #else
 990 configure___ use_mmap_for_buffers=no
 991 #endif
 992
 993 #ifndef C_DEBUG_SWITCH
 994 #define C_DEBUG_SWITCH -g
 995 #endif
 996
 997 #ifndef C_OPTIMIZE_SWITCH
 998 #ifdef __GNUC__
 999 #define C_OPTIMIZE_SWITCH -O2
1000 #else
1001 #define C_OPTIMIZE_SWITCH -O
1002 #endif
1003 #endif
1004
1005 #ifndef C_WARNINGS_SWITCH
1006 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
1007 #endif
1008
1009 #ifndef LD_SWITCH_MACHINE
1010 #define LD_SWITCH_MACHINE
1011 #endif
1012
1013 #ifndef LD_SWITCH_SYSTEM
1014 #define LD_SWITCH_SYSTEM
1015 #endif
1016
1017 #ifndef LD_SWITCH_X_SITE_AUX
1018 #define LD_SWITCH_X_SITE_AUX
1019 #endif
1020
1021 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1022 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1023
1024 #ifdef THIS_IS_CONFIGURE
1025
1026 /* Get the CFLAGS for tests in configure.  */
1027 #ifdef __GNUC__
1028 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1029 #else
1030 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1031 #endif
1032
1033 #else /* not THIS_IS_CONFIGURE */
1034
1035 /* Get the CFLAGS for real compilation.  */
1036 #ifdef __GNUC__
1037 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
1038 #else
1039 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1040 #endif
1041
1042 #endif /* not THIS_IS_CONFIGURE */
1043 ' > ${tempcname}
1044
1045 # The value of CPP is a quoted variable reference, so we need to do this
1046 # to get its actual value...
1047 CPP=`eval "echo $CPP"`
1048 [eval `${CPP} -Isrc ${tempcname} \
1049        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1050 if test "x$SPECIFIED_CFLAGS" = x; then
1051   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1052          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1053 else
1054   REAL_CFLAGS="$CFLAGS"
1055 fi]
1056 rm ${tempcname}
1057
1058 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1059
1060 ### Make sure subsequent tests use flags consistent with the build flags.
1061
1062 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1063   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1064 else
1065   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1066 fi
1067
1068 dnl For AC_FUNC_GETLOADAVG, at least:
1069 AC_CONFIG_LIBOBJ_DIR(src)
1070
1071 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1072 AC_SYS_LARGEFILE
1073
1074
1075 ### The standard library on x86-64 and s390x GNU/Linux distributions can
1076 ### be located in either /usr/lib64 or /usr/lib.
1077 case "${canonical}" in
1078   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1079     if test -d /usr/lib64; then
1080       AC_DEFINE(HAVE_LIB64_DIR, 1,
1081         [Define to 1 if the directory /usr/lib64 exists.])
1082 fi
1083 esac
1084
1085 dnl This function defintion taken from Gnome 2.0
1086 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1087 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1088 dnl also defines GSTUFF_PKG_ERRORS on error
1089 AC_DEFUN([PKG_CHECK_MODULES], [
1090   succeeded=no
1091
1092   if test -z "$PKG_CONFIG"; then
1093     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1094   fi
1095
1096   if test "$PKG_CONFIG" = "no" ; then
1097      ifelse([$4], , [AC_MSG_ERROR([
1098       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1099   else
1100      PKG_CONFIG_MIN_VERSION=0.9.0
1101      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1102         AC_MSG_CHECKING(for $2)
1103
1104         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1105             AC_MSG_RESULT(yes)
1106             succeeded=yes
1107
1108             AC_MSG_CHECKING($1_CFLAGS)
1109             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1110             AC_MSG_RESULT($$1_CFLAGS)
1111
1112             AC_MSG_CHECKING($1_LIBS)
1113             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1114             AC_MSG_RESULT($$1_LIBS)
1115         else
1116             AC_MSG_RESULT(no)
1117             $1_CFLAGS=""
1118             $1_LIBS=""
1119             ## If we have a custom action on failure, don't print errors, but
1120             ## do set a variable so people can do so.
1121             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1122             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1123         fi
1124
1125         AC_SUBST($1_CFLAGS)
1126         AC_SUBST($1_LIBS)
1127      else
1128         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1129         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1130      fi
1131   fi
1132
1133   if test $succeeded = yes; then
1134      ifelse([$3], , :, [$3])
1135   else
1136      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1137   fi
1138 ])
1139
1140
1141 if test "${with_sound}" != "no"; then
1142   # Sound support for GNU/Linux and the free BSDs.
1143   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1144   # Emulation library used on NetBSD.
1145   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1146   AC_SUBST(LIBSOUND)
1147
1148   ALSA_REQUIRED=1.0.0
1149   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1150   dnl Check if --with-pkg-config-prog has been given.
1151   if test "X${with_pkg_config_prog}" != X; then
1152     PKG_CONFIG="${with_pkg_config_prog}"
1153   fi
1154   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1155   if test $HAVE_ALSA = yes; then
1156     SAVE_CFLAGS="$CFLAGS"
1157     SAVE_LDFLAGS="$LDFLAGS"
1158     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1159     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1160     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1161                     emacs_alsa_normal=yes,
1162                     emacs_alsa_normal=no)
1163     if test "$emacs_alsa_normal" != yes; then
1164       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1165                      [snd_lib_error_set_handler (0);],
1166                      emacs_alsa_subdir=yes,
1167                      emacs_alsa_subdir=no)
1168       if test "$emacs_alsa_subdir" != yes; then
1169         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1170       fi
1171       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1172     fi
1173
1174     CFLAGS="$SAVE_CFLAGS"
1175     LDFLAGS="$SAVE_LDFLAGS"
1176     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1177     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1178     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1179   fi
1180   AC_SUBST(CFLAGS_SOUND)
1181 fi
1182
1183 dnl checks for header files
1184 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1185   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1186   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1187   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1188   sys/utsname.h pwd.h)
1189
1190 AC_MSG_CHECKING(if personality LINUX32 can be set)
1191 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1192                emacs_cv_personality_linux32=yes,
1193                emacs_cv_personality_linux32=no)
1194 AC_MSG_RESULT($emacs_cv_personality_linux32)
1195
1196 if test $emacs_cv_personality_linux32 = yes; then
1197   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1198             [Define to 1 if personality LINUX32 can be set.])
1199 fi
1200
1201 dnl On Solaris 8 there's a compilation warning for term.h because
1202 dnl it doesn't define `bool'.
1203 AC_CHECK_HEADERS(term.h, , , -)
1204 AC_HEADER_STDC
1205 AC_HEADER_TIME
1206 AC_CHECK_DECLS([sys_siglist])
1207 if test $ac_cv_have_decl_sys_siglist != yes; then
1208   # For Tru64, at least:
1209   AC_CHECK_DECLS([__sys_siglist])
1210   if test $ac_cv_have_decl___sys_siglist = yes; then
1211     AC_DEFINE(sys_siglist, __sys_siglist,
1212               [Define to any substitute for sys_siglist.])
1213   fi
1214 fi
1215 AC_HEADER_SYS_WAIT
1216
1217 dnl Some systems have utime.h but don't declare the struct anyplace.
1218 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1219 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1220 #include <sys/time.h>
1221 #include <time.h>
1222 #else
1223 #ifdef HAVE_SYS_TIME_H
1224 #include <sys/time.h>
1225 #else
1226 #include <time.h>
1227 #endif
1228 #endif
1229 #ifdef HAVE_UTIME_H
1230 #include <utime.h>
1231 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1232   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1233 if test $emacs_cv_struct_utimbuf = yes; then
1234   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1235 fi
1236
1237 dnl checks for typedefs
1238 AC_TYPE_SIGNAL
1239
1240 dnl Check for speed_t typedef.
1241 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1242   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1243     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1244 if test $emacs_cv_speed_t = yes; then
1245   AC_DEFINE(HAVE_SPEED_T, 1,
1246            [Define to 1 if `speed_t' is declared by <termios.h>.])
1247 fi
1248
1249 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1250 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1251 #include <sys/time.h>
1252 #include <time.h>
1253 #else
1254 #ifdef HAVE_SYS_TIME_H
1255 #include <sys/time.h>
1256 #else
1257 #include <time.h>
1258 #endif
1259 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1260   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1261 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1262 if test $emacs_cv_struct_timeval = yes; then
1263   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1264 fi
1265
1266 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1267 AC_TRY_COMPILE([#include <math.h>],
1268 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1269   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1270 HAVE_EXCEPTION=$emacs_cv_struct_exception
1271 if test $emacs_cv_struct_exception != yes; then
1272   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1273 fi
1274
1275 AC_CHECK_HEADERS(sys/socket.h)
1276 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1277 #if HAVE_SYS_SOCKET_H
1278 #include <sys/socket.h>
1279 #endif])
1280
1281 dnl checks for structure members
1282 AC_STRUCT_TM
1283 AC_STRUCT_TIMEZONE
1284 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1285                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1286                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1287                 [#include <time.h>])
1288 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1289                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1290                   struct ifreq.ifr_addr], , ,
1291                  [AC_INCLUDES_DEFAULT
1292 #if HAVE_SYS_SOCKET_H
1293 #include <sys/socket.h>
1294 #endif
1295 #if HAVE_NET_IF_H
1296 #include <net/if.h>
1297 #endif])
1298
1299 dnl checks for compiler characteristics
1300
1301 dnl Testing __STDC__ to determine prototype support isn't good enough.
1302 dnl DEC C, for instance, doesn't define it with default options, and
1303 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1304 dnl and void *.
1305 AC_C_PROTOTYPES
1306 AC_C_VOLATILE
1307 AC_C_CONST
1308 dnl This isn't useful because we can't turn on use of `inline' unless
1309 dnl the compiler groks `extern inline'.
1310 dnl AC_C_INLINE
1311 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1312   [AC_TRY_COMPILE(, [void * foo;],
1313                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1314 if test $emacs_cv_void_star = yes; then
1315   AC_DEFINE(POINTER_TYPE, void)
1316 else
1317   AC_DEFINE(POINTER_TYPE, char)
1318 fi
1319 AH_TEMPLATE(POINTER_TYPE,
1320             [Define as `void' if your compiler accepts `void *'; otherwise
1321              define as `char'.])dnl
1322
1323
1324
1325 dnl This could be used for targets which can have both byte sexes.
1326 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1327 dnl AC_C_BIGENDIAN
1328
1329 dnl check for Make feature
1330 AC_PROG_MAKE_SET
1331
1332 dnl checks for operating system services
1333 AC_SYS_LONG_FILE_NAMES
1334
1335 #### Choose a window system.
1336
1337 AC_PATH_X
1338 if test "$no_x" = yes; then
1339   window_system=none
1340 else
1341   window_system=x11
1342 fi
1343
1344 if test "${x_libraries}" != NONE; then
1345   if test -n "${x_libraries}"; then
1346     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1347     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1348   fi
1349   x_default_search_path=""
1350   x_search_path=${x_libraries}
1351   if test -z "${x_search_path}"; then
1352     x_search_path=/usr/lib
1353   fi
1354   for x_library in `echo ${x_search_path}: | \
1355                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1356     x_search_path="\
1357 ${x_library}/X11/%L/%T/%N%C%S:\
1358 ${x_library}/X11/%l/%T/%N%C%S:\
1359 ${x_library}/X11/%T/%N%C%S:\
1360 ${x_library}/X11/%L/%T/%N%S:\
1361 ${x_library}/X11/%l/%T/%N%S:\
1362 ${x_library}/X11/%T/%N%S"
1363     if test x"${x_default_search_path}" = x; then
1364       x_default_search_path=${x_search_path}
1365     else
1366       x_default_search_path="${x_search_path}:${x_default_search_path}"
1367     fi
1368   done
1369 fi
1370 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1371   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1372 fi
1373
1374 if test x"${x_includes}" = x; then
1375   bitmapdir=/usr/include/X11/bitmaps
1376 else
1377   # accumulate include directories that have X11 bitmap subdirectories
1378   bmd_acc="dummyval"
1379   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1380     if test -d "${bmd}/X11/bitmaps"; then
1381       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1382     fi
1383     if test -d "${bmd}/bitmaps"; then
1384       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1385     fi
1386   done
1387   if test ${bmd_acc} != "dummyval"; then
1388     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1389   fi
1390 fi
1391
1392 HAVE_CARBON=no
1393 if test "${with_carbon}" != no; then
1394   AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1395 fi
1396 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1397   if test "${with_carbon+set}" != set \
1398      && test "${carbon_appdir_x+set}" != set; then
1399     for var in with_x with_x_toolkit with_gtk with_xim \
1400                with_xpm with_jpeg with_tiff with_gif with_png; do
1401       if eval test \"\${$var+set}\" = set; then
1402         HAVE_CARBON=no
1403         break
1404       fi
1405     done
1406   fi
1407 fi
1408 if test "${HAVE_CARBON}" = yes; then
1409   window_system=mac
1410 fi
1411
1412 case "${window_system}" in
1413   x11 )
1414     HAVE_X_WINDOWS=yes
1415     HAVE_X11=yes
1416     case "${with_x_toolkit}" in
1417       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1418       motif ) USE_X_TOOLKIT=MOTIF ;;
1419       gtk ) with_gtk=yes
1420 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1421 dnl USE_X_TOOLKIT is set.
1422             USE_X_TOOLKIT=none ;;
1423       no ) USE_X_TOOLKIT=none ;;
1424 dnl If user did not say whether to use a toolkit, make this decision later:
1425 dnl use the toolkit if we have gtk, or X11R5 or newer.
1426       * )
1427           if test x"$with_gtk" = xyes; then
1428              USE_X_TOOLKIT=none
1429           else
1430              USE_X_TOOLKIT=maybe
1431           fi
1432           ;;
1433     esac
1434   ;;
1435   mac | none )
1436     HAVE_X_WINDOWS=no
1437     HAVE_X11=no
1438     USE_X_TOOLKIT=none
1439   ;;
1440 esac
1441
1442 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1443    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1444    if test "$HAVE_XSERVER" = true ||
1445       test -n "$DISPLAY" ||
1446       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1447         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1448 were found.  You should install the relevant development files for X
1449 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1450 sure you have development files for image handling, i.e.
1451 tiff, gif, jpeg, png and xpm.
1452 If you are sure you want Emacs compiled without X window support, pass
1453   --without-x
1454 to configure.])
1455    fi
1456 fi
1457
1458 ### If we're using X11, we should use the X menu package.
1459 HAVE_MENUS=no
1460 case ${HAVE_X11} in
1461   yes ) HAVE_MENUS=yes ;;
1462 esac
1463
1464 ### Compute the unexec source name from the object name.
1465 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1466
1467 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1468 # Assume not, until told otherwise.
1469 GNU_MALLOC=yes
1470 doug_lea_malloc=yes
1471 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1472 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1473 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1474                emacs_cv_var___after_morecore_hook,
1475 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1476   emacs_cv_var___after_morecore_hook=yes,
1477   emacs_cv_var___after_morecore_hook=no)])
1478 if test $emacs_cv_var___after_morecore_hook = no; then
1479   doug_lea_malloc=no
1480 fi
1481 if test "${system_malloc}" = "yes"; then
1482   GNU_MALLOC=no
1483   GNU_MALLOC_reason="
1484     (The GNU allocators don't work with this system configuration.)"
1485 fi
1486 if test "$doug_lea_malloc" = "yes" ; then
1487   if test "$GNU_MALLOC" = yes ; then
1488     GNU_MALLOC_reason="
1489       (Using Doug Lea's new malloc from the GNU C Library.)"
1490   fi
1491   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1492             [Define to 1 if you are using the GNU C Library.])
1493 fi
1494
1495 if test x"${REL_ALLOC}" = x; then
1496   REL_ALLOC=${GNU_MALLOC}
1497 fi
1498
1499 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1500 dnl the system configuration file (s/*.h) to turn the use of mmap
1501 dnl in the relocating allocator on.
1502
1503 AC_FUNC_MMAP
1504 if test $use_mmap_for_buffers = yes; then
1505   REL_ALLOC=no
1506 fi
1507
1508 LIBS="$libsrc_libs $LIBS"
1509
1510 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1511 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1512 AC_CHECK_LIB(dnet, dnet_ntoa)
1513 dnl This causes -lresolv to get used in subsequent tests,
1514 dnl which causes failures on some systems such as HPUX 9.
1515 dnl AC_CHECK_LIB(resolv, gethostbyname)
1516
1517 dnl FIXME replace main with a function we actually want from this library.
1518 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1519
1520 AC_CHECK_LIB(pthreads, cma_open)
1521
1522 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1523 if test -d /usr/X386/include; then
1524   HAVE_XFREE386=yes
1525   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1526 else
1527   HAVE_XFREE386=no
1528 fi
1529 AC_MSG_RESULT($HAVE_XFREE386)
1530
1531 dnl Check for need for bigtoc support on IBM AIX
1532
1533 case ${host_os} in
1534 aix*)
1535   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1536     case $GCC in
1537     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1538     *) gdb_cv_bigtoc=-bbigtoc ;;
1539     esac
1540
1541     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1542     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1543   ])
1544   ;;
1545 esac
1546
1547 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1548 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1549 # REAL_CPPFLAGS later on.
1550
1551 REAL_CPPFLAGS="$CPPFLAGS"
1552
1553 if test "${HAVE_X11}" = "yes"; then
1554   DEFS="$C_SWITCH_X_SITE $DEFS"
1555   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1556   LIBS="$LIBX $LIBS"
1557   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1558   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1559
1560   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1561   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1562   # but it's more convenient here to set LD_RUN_PATH
1563   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1564   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1565     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1566     export LD_RUN_PATH
1567   fi
1568
1569   if test "${opsys}" = "gnu-linux"; then
1570     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1571     AC_TRY_LINK([],
1572      [XOpenDisplay ("foo");],
1573      [xlinux_first_failure=no],
1574      [xlinux_first_failure=yes])
1575     if test "${xlinux_first_failure}" = "yes"; then
1576       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1577       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1578       OLD_CPPFLAGS="$CPPFLAGS"
1579       OLD_LIBS="$LIBS"
1580       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1581       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1582       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1583       LIBS="$LIBS -b i486-linuxaout"
1584       AC_TRY_LINK([],
1585        [XOpenDisplay ("foo");],
1586        [xlinux_second_failure=no],
1587        [xlinux_second_failure=yes])
1588       if test "${xlinux_second_failure}" = "yes"; then
1589         # If we get the same failure with -b, there is no use adding -b.
1590         # So take it out.  This plays safe.
1591         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1592         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1593         CPPFLAGS="$OLD_CPPFLAGS"
1594         LIBS="$OLD_LIBS"
1595         AC_MSG_RESULT(no)
1596       else
1597         AC_MSG_RESULT(yes)
1598       fi
1599     else
1600       AC_MSG_RESULT(no)
1601     fi
1602   fi
1603
1604   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1605   # header files included from there.
1606   AC_MSG_CHECKING(for Xkb)
1607   AC_TRY_LINK([#include <X11/Xlib.h>
1608 #include <X11/XKBlib.h>],
1609         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1610         emacs_xkb=yes, emacs_xkb=no)
1611   AC_MSG_RESULT($emacs_xkb)
1612   if test $emacs_xkb = yes; then
1613     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1614   fi
1615
1616   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1617 XScreenNumberOfScreen XSetWMProtocols)
1618 fi
1619
1620 if test "${window_system}" = "x11"; then
1621   AC_MSG_CHECKING(X11 version 6)
1622   AC_CACHE_VAL(emacs_cv_x11_version_6,
1623   [AC_TRY_LINK([#include <X11/Xlib.h>],
1624 [#if XlibSpecificationRelease < 6
1625 fail;
1626 #endif
1627 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1628   if test $emacs_cv_x11_version_6 = yes; then
1629     AC_MSG_RESULT(6 or newer)
1630     AC_DEFINE(HAVE_X11R6, 1,
1631               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1632   else
1633     AC_MSG_RESULT(before 6)
1634   fi
1635 fi
1636
1637
1638 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1639 HAVE_RSVG=no
1640 if test "${HAVE_X11}" = "yes" || test "${HAVE_CARBON}" = "yes"; then
1641   if test "${with_rsvg}" != "no"; then
1642     dnl Check if `--with-pkg-config-prog' has been given.
1643     if test "X${with_pkg_config_prog}" != X; then
1644       PKG_CONFIG="${with_pkg_config_prog}"
1645     fi
1646
1647     RSVG_REQUIRED=2.0.0
1648     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1649
1650     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1651     AC_SUBST(RSVG_CFLAGS)
1652     AC_SUBST(RSVG_LIBS)
1653
1654     if test ".${RSVG_CFLAGS}" != "."; then
1655       HAVE_RSVG=yes
1656       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1657       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1658       LIBS="$RSVG_LIBS $LIBS"
1659     fi
1660   fi
1661 fi
1662
1663
1664 HAVE_GTK=no
1665 if test "${with_gtk}" = "yes" && test "$USE_X_TOOLKIT" = "gtk"; then
1666   USE_X_TOOLKIT=none
1667 fi
1668 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "gtk" || \
1669  test "$USE_X_TOOLKIT" = "maybe"; then
1670   if test "$USE_X_TOOLKIT" != "none" && test "$USE_X_TOOLKIT" != "maybe"; then
1671     AC_MSG_ERROR([Conflicting options, --with-gtk is incompatible with --with-x-toolkit=${with_x_toolkit}]);
1672   fi
1673   GLIB_REQUIRED=2.6
1674   GTK_REQUIRED=2.6
1675   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1676
1677   dnl Check if --with-pkg-config-prog has been given.
1678   if test "X${with_pkg_config_prog}" != X; then
1679     PKG_CONFIG="${with_pkg_config_prog}"
1680   fi
1681   dnl Checks for libraries.
1682   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1683   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1684      AC_MSG_ERROR($GTK_PKG_ERRORS)
1685   fi
1686 fi
1687
1688
1689 if test x"$pkg_check_gtk" = xyes; then
1690
1691   AC_SUBST(GTK_CFLAGS)
1692   AC_SUBST(GTK_LIBS)
1693   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1694   CFLAGS="$CFLAGS $GTK_CFLAGS"
1695   LIBS="$GTK_LIBS $LIBS"
1696   dnl Try to compile a simple GTK program.
1697   GTK_COMPILES=no
1698   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1699   if test "${GTK_COMPILES}" != "yes"; then
1700     if test "$USE_X_TOOLKIT" != "maybe"; then
1701       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1702     fi
1703   else
1704     HAVE_GTK=yes
1705     AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
1706     USE_X_TOOLKIT=none
1707   fi
1708
1709 fi
1710
1711
1712 if test "${HAVE_GTK}" = "yes"; then
1713
1714   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1715   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1716   if test "$with_toolkit_scroll_bars" != no; then
1717     with_toolkit_scroll_bars=yes
1718   fi
1719
1720   dnl  Check if we can use multiple displays with this GTK version.
1721   dnl  If gdk_display_open exists, assume all others are there also.
1722   HAVE_GTK_MULTIDISPLAY=no
1723   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1724   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1725     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1726               [Define to 1 if GTK can handle more than one display.])
1727   fi
1728
1729   dnl  Check if we have the old file selection dialog.
1730   dnl  If gdk_display_open exists, assume all others are there also.
1731   HAVE_GTK_FILE_SELECTION=no
1732   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1733
1734   dnl  Check if we have the new file chooser dialog
1735   dnl  If gdk_display_open exists, assume all others are there also.
1736   HAVE_GTK_FILE_CHOOSER=no
1737   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1738
1739   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1740      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1741     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1742               [Define to 1 if GTK has both file selection and chooser dialog.])
1743   fi
1744
1745   dnl Check if pthreads are available.  Emacs only needs this when using
1746   dnl gtk_file_chooser under Gnome.
1747   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1748     HAVE_GTK_AND_PTHREAD=no
1749     AC_CHECK_HEADERS(pthread.h)
1750     if test "$ac_cv_header_pthread_h"; then
1751       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1752     fi
1753     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1754       case "${canonical}" in
1755         *-hpux*) ;;
1756         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1757       esac
1758       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1759                [Define to 1 if you have GTK and pthread (-lpthread).])
1760     fi
1761   fi
1762 fi
1763
1764 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1765 dnl other platforms.  Support for higher D-Bus versions but 1.0 is
1766 dnl also not configured.
1767 HAVE_DBUS=no
1768 if test "${with_dbus}" = "yes"; then
1769    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1770    if test "$HAVE_DBUS" = yes; then
1771       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1772    fi
1773 fi
1774
1775 ### Link with -lXft if available to work around a bug.
1776 HAVE_XFT=maybe
1777 if test "${HAVE_GTK}" = "yes"; then
1778   dnl Check if --with-pkg-config-prog has been given.
1779   if test "X${with_pkg_config_prog}" != X; then
1780     PKG_CONFIG="${with_pkg_config_prog}"
1781   fi
1782
1783   PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1784   if test "$HAVE_XFT" != no; then
1785     OLD_CFLAGS="$CPPFLAGS"
1786     OLD_CPPFLAGS="$CFLAGS"
1787     OLD_LIBS="$LIBS"
1788     CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1789     CFLAGS="$CFLAGS $XFT_CFLAGS"
1790     LIBS="$XFT_LIBS $LIBS"
1791     AC_CHECK_HEADER(X11/Xft/Xft.h,
1792       [AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS)])
1793
1794     if test "${HAVE_XFT}" = "yes"; then
1795       AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1796       AC_SUBST(XFT_LIBS)
1797       C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1798     else
1799       CFLAGS="$OLD_CPPFLAGS"
1800       CFLAGS="$OLD_CFLAGS"
1801       LIBS="$OLD_LIBS"
1802     fi
1803   fi
1804 fi
1805
1806 dnl Do not put whitespace before the #include statements below.
1807 dnl Older compilers (eg sunos4 cc) choke on it.
1808 HAVE_XAW3D=no
1809 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1810   if test "$with_xaw3d" != no; then
1811     AC_MSG_CHECKING(for xaw3d)
1812     AC_CACHE_VAL(emacs_cv_xaw3d,
1813     [AC_TRY_LINK([
1814 #include <X11/Intrinsic.h>
1815 #include <X11/Xaw3d/Simple.h>],
1816       [],
1817       emacs_cv_xaw3d=yes,
1818       emacs_cv_xaw3d=no)])
1819   else
1820     emacs_cv_xaw3d=no
1821   fi
1822   if test $emacs_cv_xaw3d = yes; then
1823     AC_MSG_RESULT([yes; using Lucid toolkit])
1824     USE_X_TOOLKIT=LUCID
1825     HAVE_XAW3D=yes
1826     AC_DEFINE(HAVE_XAW3D, 1,
1827               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1828   else
1829     AC_MSG_RESULT(no)
1830     AC_MSG_CHECKING(for libXaw)
1831     AC_CACHE_VAL(emacs_cv_xaw,
1832     [AC_TRY_LINK([
1833 #include <X11/Intrinsic.h>
1834 #include <X11/Xaw/Simple.h>],
1835       [],
1836       emacs_cv_xaw=yes,
1837       emacs_cv_xaw=no)])
1838     if test $emacs_cv_xaw = yes; then
1839       AC_MSG_RESULT([yes; using Lucid toolkit])
1840       USE_X_TOOLKIT=LUCID
1841     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1842       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1843     else
1844       AC_MSG_RESULT([no; do not use toolkit by default])
1845       USE_X_TOOLKIT=none
1846     fi
1847   fi
1848 fi
1849
1850 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1851
1852 if test "${USE_X_TOOLKIT}" != "none"; then
1853   AC_MSG_CHECKING(X11 toolkit version)
1854   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1855   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1856 [#if XtSpecificationRelease < 6
1857 fail;
1858 #endif
1859 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1860   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1861   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1862     AC_MSG_RESULT(6 or newer)
1863     AC_DEFINE(HAVE_X11XTR6, 1,
1864               [Define to 1 if you have the X11R6 or newer version of Xt.])
1865   else
1866     AC_MSG_RESULT(before 6)
1867   fi
1868
1869 dnl If using toolkit, check whether libXmu.a exists.
1870 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1871   OLDLIBS="$LIBS"
1872   if test x$HAVE_X11XTR6 = xyes; then
1873     LIBS="-lXt -lSM -lICE $LIBS"
1874   else
1875     LIBS="-lXt $LIBS"
1876   fi
1877   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1878   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1879 fi
1880
1881 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1882 if test "${HAVE_X11}" = "yes"; then
1883   if test "${USE_X_TOOLKIT}" != "none"; then
1884     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1885   fi
1886 fi
1887
1888 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1889   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1890   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1891     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1892 int x = 5;
1893 #else
1894 Motif version prior to 2.1.
1895 #endif],
1896     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1897   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1898   if test $emacs_cv_motif_version_2_1 = yes; then
1899     HAVE_LIBXP=no
1900     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1901               [Define to 1 if you have Motif 2.1 or newer.])
1902     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1903     if test ${HAVE_LIBXP} = yes; then
1904       AC_DEFINE(HAVE_LIBXP, 1,
1905                 [Define to 1 if you have the Xp library (-lXp).])
1906     fi
1907   else
1908     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1909     # We put this in CFLAGS temporarily to precede other -I options
1910     # that might be in CFLAGS temporarily.
1911     # We put this in CPPFLAGS where it precedes the other -I options.
1912     OLD_CPPFLAGS=$CPPFLAGS
1913     OLD_CFLAGS=$CFLAGS
1914     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1915     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1916     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1917       [int x = 5;],
1918       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1919     if test $emacs_cv_lesstif = yes; then
1920       # Make sure this -I option remains in CPPFLAGS after it is set
1921       # back to REAL_CPPFLAGS.
1922       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1923       # have those other -I options anyway.  Ultimately, having this
1924       # directory ultimately in CPPFLAGS will be enough.
1925       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1926       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1927     else
1928       CFLAGS=$OLD_CFLAGS
1929       CPPFLAGS=$OLD_CPPFLAGS
1930     fi
1931   fi
1932 fi
1933
1934 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1935 dnl using Motif or Xaw3d is available, and unless
1936 dnl --with-toolkit-scroll-bars=no was specified.
1937
1938 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1939             [Define to 1 if we should use toolkit scroll bars.])dnl
1940 USE_TOOLKIT_SCROLL_BARS=no
1941 if test "${with_toolkit_scroll_bars}" != "no"; then
1942   if test "${USE_X_TOOLKIT}" != "none"; then
1943     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1944       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1945       HAVE_XAW3D=no
1946       USE_TOOLKIT_SCROLL_BARS=yes
1947     elif test "${HAVE_XAW3D}" = "yes"; then
1948       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1949       USE_TOOLKIT_SCROLL_BARS=yes
1950     fi
1951   elif test "${HAVE_GTK}" = "yes"; then
1952     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1953     USE_TOOLKIT_SCROLL_BARS=yes
1954   elif test "${HAVE_CARBON}" = "yes"; then
1955     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1956     USE_TOOLKIT_SCROLL_BARS=yes
1957   fi
1958 fi
1959
1960 dnl See if XIM is available.
1961 AC_TRY_COMPILE([
1962           #include <X11/Xlib.h>
1963           #include <X11/Xresource.h>],
1964          [XIMProc  callback;],
1965          [HAVE_XIM=yes
1966          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1967          HAVE_XIM=no)
1968
1969 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1970
1971 if test "${with_xim}" != "no"; then
1972   AC_DEFINE(USE_XIM, 1,
1973             [Define to 1 if we should use XIM, if it is available.])
1974 fi
1975
1976
1977 if test "${HAVE_XIM}" != "no"; then
1978   late_CFLAGS=$CFLAGS
1979   if test "$GCC" = yes; then
1980     CFLAGS="$CFLAGS --pedantic-errors"
1981   fi
1982   AC_TRY_COMPILE([
1983 #include <X11/Xlib.h>
1984 #include <X11/Xresource.h>],
1985 [Display *display;
1986 XrmDatabase db;
1987 char *res_name;
1988 char *res_class;
1989 XIMProc  callback;
1990 XPointer *client_data;
1991 #ifndef __GNUC__
1992 /* If we're not using GCC, it's probably not XFree86, and this is
1993    probably right, but we can't use something like --pedantic-errors.  */
1994 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1995                                            char*, XIMProc, XPointer*);
1996 #endif
1997 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1998    client_data);],
1999     [emacs_cv_arg6_star=yes])
2000   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2001          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2002 either XPointer or XPointer*.])dnl
2003   if test "$emacs_cv_arg6_star" = yes; then
2004     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2005   else
2006     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2007   fi
2008   CFLAGS=$late_CFLAGS
2009 fi
2010
2011 ### Use -lXpm if available, unless `--with-xpm=no'.
2012 HAVE_XPM=no
2013 if test "${HAVE_X11}" = "yes"; then
2014   if test "${with_xpm}" != "no"; then
2015     AC_CHECK_HEADER(X11/xpm.h,
2016       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2017     if test "${HAVE_XPM}" = "yes"; then
2018       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2019       AC_EGREP_CPP(no_return_alloc_pixels,
2020       [#include "X11/xpm.h"
2021 #ifndef XpmReturnAllocPixels
2022 no_return_alloc_pixels
2023 #endif
2024       ], HAVE_XPM=no, HAVE_XPM=yes)
2025
2026       if test "${HAVE_XPM}" = "yes"; then
2027         AC_MSG_RESULT(yes)
2028       else
2029         AC_MSG_RESULT(no)
2030       fi
2031     fi
2032   fi
2033
2034   if test "${HAVE_XPM}" = "yes"; then
2035     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2036   fi
2037 fi
2038
2039 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2040 HAVE_JPEG=no
2041 if test "${HAVE_X11}" = "yes"; then
2042   if test "${with_jpeg}" != "no"; then
2043     dnl Checking for jpeglib.h can lose because of a redefinition of
2044     dnl  HAVE_STDLIB_H.
2045     AC_CHECK_HEADER(jerror.h,
2046       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2047   fi
2048
2049   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2050   if test "${HAVE_JPEG}" = "yes"; then
2051     AC_DEFINE(HAVE_JPEG)
2052     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2053         [#include <jpeglib.h>
2054          version=JPEG_LIB_VERSION
2055 ],
2056         [AC_DEFINE(HAVE_JPEG)],
2057         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2058         HAVE_JPEG=no])
2059   fi
2060 fi
2061
2062 ### Use -lpng if available, unless `--with-png=no'.
2063 HAVE_PNG=no
2064 if test "${HAVE_X11}" = "yes"; then
2065   if test "${with_png}" != "no"; then
2066     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2067     # in /usr/include/libpng.
2068     AC_CHECK_HEADERS(png.h libpng/png.h)
2069     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2070       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2071     fi
2072   fi
2073
2074   if test "${HAVE_PNG}" = "yes"; then
2075     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2076   fi
2077 fi
2078
2079 ### Use -ltiff if available, unless `--with-tiff=no'.
2080 HAVE_TIFF=no
2081 if test "${HAVE_X11}" = "yes"; then
2082   if test "${with_tiff}" != "no"; then
2083     AC_CHECK_HEADER(tiffio.h,
2084       [tifflibs="-lz -lm"
2085       # At least one tiff package requires the jpeg library.
2086       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2087       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2088   fi
2089
2090   if test "${HAVE_TIFF}" = "yes"; then
2091     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2092   fi
2093 fi
2094
2095 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2096 HAVE_GIF=no
2097 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2098   AC_CHECK_HEADER(gif_lib.h,
2099 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2100 # Earlier versions can crash Emacs.
2101     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2102
2103   if test "$HAVE_GIF" = yes; then
2104       ac_gif_lib_name="-lgif"
2105   fi
2106
2107 # If gif_lib.h but no libgif, try libungif.
2108   if test x"$try_libungif" = xyes; then
2109     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2110
2111     if test "$HAVE_GIF" = yes; then
2112       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2113       ac_gif_lib_name="-lungif"
2114     fi
2115   fi
2116
2117   if test "${HAVE_GIF}" = "yes"; then
2118     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2119   fi
2120 fi
2121
2122 dnl Check for required libraries.
2123 if test "${HAVE_X11}" = "yes"; then
2124   MISSING=""
2125   WITH_NO=""
2126   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2127     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2128   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2129     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2130   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2131     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2132   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2133     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2134   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2135     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2136
2137   if test "X${MISSING}" != X; then
2138     AC_MSG_ERROR([The following required libraries were not found:
2139     $MISSING
2140 Maybe some development libraries/packages are missing?
2141 If you don't want to link with them give
2142     $WITH_NO
2143 as options to configure])
2144   fi
2145 fi
2146
2147 ### Use -lgpm if available, unless `--with-gpm=no'.
2148 HAVE_GPM=no
2149 if test "${with_gpm}" != "no"; then
2150   AC_CHECK_HEADER(gpm.h,
2151     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2152 fi
2153
2154 if test "${HAVE_GPM}" = "yes"; then
2155   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2156 fi
2157
2158 dnl Check for malloc/malloc.h on darwin
2159 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2160
2161 ### Use Mac OS X Carbon API to implement GUI.
2162 if test "${HAVE_CARBON}" = "yes"; then
2163   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2164   ## Specify the install directory
2165   carbon_appdir=
2166   if test "${carbon_appdir_x}" != ""; then
2167     case ${carbon_appdir_x} in
2168       y | ye | yes)  carbon_appdir=/Applications ;;
2169       * ) carbon_appdir=${carbon_appdir_x} ;;
2170     esac
2171   fi
2172   # We also have mouse menus.
2173   HAVE_MENUS=yes
2174 fi
2175
2176 ### Use session management (-lSM -lICE) if available
2177 HAVE_X_SM=no
2178 if test "${HAVE_X11}" = "yes"; then
2179   AC_CHECK_HEADER(X11/SM/SMlib.h,
2180     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2181
2182   if test "${HAVE_X_SM}" = "yes"; then
2183     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2184     case "$LIBS" in
2185       *-lSM*) ;;
2186       *)      LIBS="-lSM -lICE $LIBS" ;;
2187     esac
2188   fi
2189 fi
2190
2191 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2192 AC_CACHE_CHECK(whether netdb declares h_errno,
2193                emacs_cv_netdb_declares_h_errno,
2194 [AC_TRY_LINK([#include <netdb.h>],
2195   [return h_errno;],
2196   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2197 if test $emacs_cv_netdb_declares_h_errno = yes; then
2198   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2199 fi
2200
2201 AC_FUNC_ALLOCA
2202
2203 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2204 dnl FIXME is there an autoconf test that does the right thing, without
2205 dnl needing to call A_M_E afterwards?
2206 if test x"$ac_cv_func_alloca_works" != xyes; then
2207    AC_MSG_ERROR( [a system implementation of alloca is required] )
2208 fi
2209
2210 # fmod, logb, and frexp are found in -lm on most systems.
2211 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2212 AC_CHECK_LIB(m, sqrt)
2213
2214 # Check for mail-locking functions in a "mail" library.  Probably this should
2215 # have the same check as for liblockfile below.
2216 AC_CHECK_LIB(mail, maillock)
2217 dnl Debian, at least:
2218 AC_CHECK_LIB(lockfile, maillock)
2219 # If we have the shared liblockfile, assume we must use it for mail
2220 # locking (e.g. Debian).  If we couldn't link against liblockfile
2221 # (no liblockfile.a installed), ensure that we don't need to.
2222 if test "$ac_cv_lib_lockfile_maillock" = no; then
2223   dnl This works for files generally, not just executables.
2224   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2225   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2226                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2227   if test $ac_cv_prog_liblockfile = yes; then
2228     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2229 This probably means that movemail could lose mail.
2230 There may be a `development' package to install containing liblockfile.])
2231   else :
2232   fi
2233 fi
2234 AC_CHECK_FUNCS(touchlock)
2235 AC_CHECK_HEADERS(maillock.h)
2236
2237 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2238 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2239 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2240 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2241 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2242 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2243 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2244 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2245 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2246
2247 AC_CHECK_HEADERS(sys/un.h)
2248
2249 AC_FUNC_MKTIME
2250 if test "$ac_cv_func_working_mktime" = no; then
2251   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2252 fi
2253
2254 AC_FUNC_GETLOADAVG
2255
2256 AC_FUNC_FSEEKO
2257
2258 # Configure getopt.
2259 m4_include([m4/getopt.m4])
2260 gl_GETOPT_IFELSE([
2261   gl_GETOPT_SUBSTITUTE_HEADER
2262   gl_PREREQ_GETOPT
2263   GETOPTOBJS='getopt.o getopt1.o'
2264 ])
2265 AC_SUBST(GETOPTOBJS)
2266
2267 AC_FUNC_GETPGRP
2268
2269 AC_FUNC_STRFTIME
2270
2271 # UNIX98 PTYs.
2272 AC_CHECK_FUNCS(grantpt)
2273
2274 # PTY-related GNU extensions.
2275 AC_CHECK_FUNCS(getpt)
2276
2277 # Check this now, so that we will NOT find the above functions in ncurses.
2278 # That is because we have not set up to link ncurses in lib-src.
2279 # It's better to believe a function is not available
2280 # than to expect to find it in ncurses.
2281 AC_CHECK_LIB(ncurses, tparm)
2282
2283 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2284
2285 resolv=no
2286 AC_TRY_LINK([#include <netinet/in.h>
2287 #include <arpa/nameser.h>
2288 #include <resolv.h>],
2289     [return res_init();],
2290     have_res_init=yes, have_res_init=no)
2291 if test "$have_res_init" = no; then
2292   OLIBS="$LIBS"
2293   LIBS="$LIBS -lresolv"
2294   AC_MSG_CHECKING(for res_init with -lresolv)
2295   AC_TRY_LINK([#include <netinet/in.h>
2296 #include <arpa/nameser.h>
2297 #include <resolv.h>],
2298     [return res_init();],
2299     have_res_init=yes, have_res_init=no)
2300   AC_MSG_RESULT($have_res_init)
2301   if test "$have_res_init" = yes ; then
2302     resolv=yes
2303   fi
2304   LIBS="$OLIBS"
2305 fi
2306
2307 if test "$have_res_init" = yes; then
2308   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2309 fi
2310
2311 # Do we need the Hesiod library to provide the support routines?
2312 if test "$with_hesiod" = yes ; then
2313   # Don't set $LIBS here -- see comments above.
2314   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2315      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2316                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2317   if test "$resolv" = yes ; then
2318     RESOLVLIB=-lresolv
2319   else
2320     RESOLVLIB=
2321   fi
2322   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2323         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2324                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2325         :, $RESOLVLIB)])
2326 fi
2327
2328 # Do we need libresolv (due to res_init or Hesiod)?
2329 if test "$resolv" = yes ; then
2330   AC_DEFINE(HAVE_LIBRESOLV, 1,
2331             [Define to 1 if you have the resolv library (-lresolv).])
2332 fi
2333
2334 # These tell us which Kerberos-related libraries to use.
2335 if test "${with_kerberos+set}" = set; then
2336   AC_CHECK_LIB(com_err, com_err)
2337   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2338   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2339   AC_CHECK_LIB(krb5, krb5_init_context)
2340   if test "${with_kerberos5+set}" != set; then
2341     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2342                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2343     AC_CHECK_LIB(krb4, krb_get_cred,,
2344                  [AC_CHECK_LIB(krb, krb_get_cred)])
2345   fi
2346
2347   if test "${with_kerberos5+set}" = set; then
2348     AC_CHECK_HEADERS(krb5.h)
2349   else
2350     AC_CHECK_HEADERS(des.h,,
2351                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2352                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2353     AC_CHECK_HEADERS(krb.h,,
2354                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2355                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2356   fi
2357   AC_CHECK_HEADERS(com_err.h)
2358 fi
2359
2360 # Solaris requires -lintl if you want strerror (which calls dgettext)
2361 # to return localized messages.
2362 AC_CHECK_LIB(intl, dgettext)
2363
2364 AC_MSG_CHECKING(whether localtime caches TZ)
2365 AC_CACHE_VAL(emacs_cv_localtime_cache,
2366 [if test x$ac_cv_func_tzset = xyes; then
2367 AC_TRY_RUN([#include <time.h>
2368 extern char **environ;
2369 unset_TZ ()
2370 {
2371   char **from, **to;
2372   for (to = from = environ; (*to = *from); from++)
2373     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2374       to++;
2375 }
2376 char TZ_GMT0[] = "TZ=GMT0";
2377 char TZ_PST8[] = "TZ=PST8";
2378 main()
2379 {
2380   time_t now = time ((time_t *) 0);
2381   int hour_GMT0, hour_unset;
2382   if (putenv (TZ_GMT0) != 0)
2383     exit (1);
2384   hour_GMT0 = localtime (&now)->tm_hour;
2385   unset_TZ ();
2386   hour_unset = localtime (&now)->tm_hour;
2387   if (putenv (TZ_PST8) != 0)
2388     exit (1);
2389   if (localtime (&now)->tm_hour == hour_GMT0)
2390     exit (1);
2391   unset_TZ ();
2392   if (localtime (&now)->tm_hour != hour_unset)
2393     exit (1);
2394   exit (0);
2395 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2396 [# If we have tzset, assume the worst when cross-compiling.
2397 emacs_cv_localtime_cache=yes])
2398 else
2399         # If we lack tzset, report that localtime does not cache TZ,
2400         # since we can't invalidate the cache if we don't have tzset.
2401         emacs_cv_localtime_cache=no
2402 fi])dnl
2403 AC_MSG_RESULT($emacs_cv_localtime_cache)
2404 if test $emacs_cv_localtime_cache = yes; then
2405   AC_DEFINE(LOCALTIME_CACHE, 1,
2406             [Define to 1 if localtime caches TZ.])
2407 fi
2408
2409 if test "x$HAVE_TIMEVAL" = xyes; then
2410   AC_CHECK_FUNCS(gettimeofday)
2411   if test $ac_cv_func_gettimeofday = yes; then
2412     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2413                    emacs_cv_gettimeofday_two_arguments,
2414     [AC_TRY_COMPILE([
2415 #ifdef TIME_WITH_SYS_TIME
2416 #include <sys/time.h>
2417 #include <time.h>
2418 #else
2419 #ifdef HAVE_SYS_TIME_H
2420 #include <sys/time.h>
2421 #else
2422 #include <time.h>
2423 #endif
2424 #endif],
2425       [struct timeval time;
2426        gettimeofday (&time, 0);],
2427       emacs_cv_gettimeofday_two_arguments=yes,
2428       emacs_cv_gettimeofday_two_arguments=no)])
2429     if test $emacs_cv_gettimeofday_two_arguments = no; then
2430       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2431                 [Define to 1 if gettimeofday accepts only one argument.])
2432     fi
2433   fi
2434 fi
2435
2436 ok_so_far=yes
2437 AC_CHECK_FUNC(socket, , ok_so_far=no)
2438 if test $ok_so_far = yes; then
2439   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2440 fi
2441 if test $ok_so_far = yes; then
2442   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2443 fi
2444 if test $ok_so_far = yes; then
2445 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2446   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2447             [Define to 1 if you have inet sockets.])
2448 fi
2449
2450 AC_CHECK_HEADERS(sys/ioctl.h)
2451
2452 if test -f /usr/lpp/X11/bin/smt.exp; then
2453   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2454             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2455 fi
2456
2457 AC_MSG_CHECKING(whether system supports dynamic ptys)
2458 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2459   AC_MSG_RESULT(yes)
2460   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2461 else
2462   AC_MSG_RESULT(no)
2463 fi
2464
2465 AC_FUNC_FORK
2466
2467 dnl Adapted from Haible's version.
2468 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2469   [AC_TRY_LINK([#include <langinfo.h>],
2470     [char* cs = nl_langinfo(CODESET);],
2471     emacs_cv_langinfo_codeset=yes,
2472     emacs_cv_langinfo_codeset=no)
2473   ])
2474 if test $emacs_cv_langinfo_codeset = yes; then
2475   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2476     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2477 fi
2478
2479 AC_CHECK_TYPES(size_t)
2480
2481 AC_TYPE_MBSTATE_T
2482
2483 dnl Restrict could probably be used effectively other than in regex.c.
2484 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2485   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2486                   emacs_cv_c_restrict=yes,
2487                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2488                                   emacs_cv_c_restrict=__restrict,
2489                                   emacs_cv_c_restrict=no)])])
2490 case "$emacs_cv_c_restrict" in
2491   yes) emacs_restrict=restrict;;
2492   no) emacs_restrict="";;
2493   *) emacs_restrict="$emacs_cv_c_restrict";;
2494 esac
2495 if test "$emacs_restrict" != __restrict; then
2496   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2497     [Define to compiler's equivalent of C99 restrict keyword.
2498      Don't define if equivalent is `__restrict'.])
2499 fi
2500
2501 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2502   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2503                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2504 if test "$emacs_cv_c_restrict_arr" = yes; then
2505   AC_DEFINE(__restrict_arr, __restrict,
2506     [Define to compiler's equivalent of C99 restrict keyword in array
2507      declarations.  Define as empty for no equivalent.])
2508 fi
2509
2510 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2511 dnl how the tty code is related to POSIX and/or other versions of termios.
2512 dnl The following looks like a useful start.
2513 dnl
2514 dnl AC_SYS_POSIX_TERMIOS
2515 dnl if test $ac_cv_sys_posix_termios = yes; then
2516 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2517 dnl                                and macros for terminal control.])
2518 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2519 dnl fi
2520
2521 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2522
2523 # Set up the CFLAGS for real compilation, so we can substitute it.
2524 CFLAGS="$REAL_CFLAGS"
2525 CPPFLAGS="$REAL_CPPFLAGS"
2526
2527 #### Find out which version of Emacs this is.
2528 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2529          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2530 if test x"${version}" = x; then
2531   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2532 fi
2533
2534 ### Specify what sort of things we'll be editing into Makefile and config.h.
2535 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2536 AC_SUBST(version)
2537 AC_SUBST(configuration)
2538 AC_SUBST(canonical)
2539 AC_SUBST(srcdir)
2540 AC_SUBST(prefix)
2541 AC_SUBST(exec_prefix)
2542 AC_SUBST(bindir)
2543 AC_SUBST(datadir)
2544 AC_SUBST(sharedstatedir)
2545 AC_SUBST(libexecdir)
2546 AC_SUBST(mandir)
2547 AC_SUBST(infodir)
2548 AC_SUBST(lispdir)
2549 AC_SUBST(locallisppath)
2550 AC_SUBST(lisppath)
2551 AC_SUBST(x_default_search_path)
2552 AC_SUBST(etcdir)
2553 AC_SUBST(archlibdir)
2554 AC_SUBST(docdir)
2555 AC_SUBST(bitmapdir)
2556 AC_SUBST(gamedir)
2557 AC_SUBST(gameuser)
2558 AC_SUBST(c_switch_system)
2559 AC_SUBST(c_switch_machine)
2560 AC_SUBST(LD_SWITCH_X_SITE)
2561 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2562 AC_SUBST(C_SWITCH_X_SITE)
2563 AC_SUBST(CFLAGS)
2564 AC_SUBST(X_TOOLKIT_TYPE)
2565 AC_SUBST(machfile)
2566 AC_SUBST(opsysfile)
2567 AC_SUBST(GETLOADAVG_LIBS)
2568 AC_SUBST(carbon_appdir)
2569
2570 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2571                    [Define to the canonical Emacs configuration name.])
2572 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2573                    [Define to the options passed to configure.])
2574 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2575                    [Define to the used machine dependent file.])
2576 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2577                    [Define to the used os dependent file.])
2578 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2579 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2580  may need to deal with X Windows.  For instance, if you've defined
2581  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2582  your loader can find on its own, you might want to add "-L/..." or
2583  something similar.])
2584 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2585                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2586                     in case it's needed (for Solaris, for example).])
2587 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2588 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2589  may need to deal with X Windows.  For instance, if you've defined
2590  HAVE_X_WINDOWS above and your X include files aren't in a place
2591  that your compiler can find on its own, you might want to add
2592  "-I/..." or something similar.])
2593 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2594                    [Define to the unexec source file name.])
2595
2596 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2597   AC_DEFINE(HAVE_X_WINDOWS, 1,
2598             [Define to 1 if you want to use the X window system.])
2599 fi
2600 if test "${USE_X_TOOLKIT}" != "none" ; then
2601   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2602 fi
2603 if test "${HAVE_X11}" = "yes" ; then
2604   AC_DEFINE(HAVE_X11, 1,
2605             [Define to 1 if you want to use version 11 of X windows.
2606              Otherwise, Emacs expects to use version 10.])
2607 fi
2608 if test "${HAVE_XFREE386}" = "yes" ; then
2609   AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2610 fi
2611 if test "${HAVE_MENUS}" = "yes" ; then
2612   AC_DEFINE(HAVE_MENUS, 1,
2613             [Define to 1 if you have mouse menus.
2614              (This is automatic if you use X, but the option to specify it remains.)
2615              It is also defined with other window systems that support xmenu.c.])
2616 fi
2617 if test "${GNU_MALLOC}" = "yes" ; then
2618   AC_DEFINE(GNU_MALLOC, 1,
2619             [Define to 1 if you want to use the GNU memory allocator.])
2620 fi
2621 if test "${REL_ALLOC}" = "yes" ; then
2622   AC_DEFINE(REL_ALLOC, 1,
2623             [Define REL_ALLOC if you want to use the relocating allocator for
2624              buffer space.])
2625 fi
2626
2627
2628 AH_TOP([/* GNU Emacs site configuration template file.
2629    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2630      2006, 2007, 2008  Free Software Foundation, Inc.
2631
2632 This file is part of GNU Emacs.
2633
2634 GNU Emacs is free software; you can redistribute it and/or modify
2635 it under the terms of the GNU General Public License as published by
2636 the Free Software Foundation; either version 3, or (at your option)
2637 any later version.
2638
2639 GNU Emacs is distributed in the hope that it will be useful,
2640 but WITHOUT ANY WARRANTY; without even the implied warranty of
2641 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2642 GNU General Public License for more details.
2643
2644 You should have received a copy of the GNU General Public License
2645 along with GNU Emacs; see the file COPYING.  If not, write to the
2646 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
2647 Boston, MA 02110-1301, USA.  */
2648
2649
2650 /* No code in Emacs #includes config.h twice, but some bits of code
2651    intended to work with other packages as well (like gmalloc.c)
2652    think they can include it as many times as they like.  */
2653 #ifndef EMACS_CONFIG_H
2654 #define EMACS_CONFIG_H
2655 ])dnl
2656
2657 AH_BOTTOM([
2658 /* If we're using any sort of window system, define some consequences.  */
2659 #ifdef HAVE_X_WINDOWS
2660 #define HAVE_WINDOW_SYSTEM
2661 #define MULTI_KBOARD
2662 #define HAVE_MOUSE
2663 #endif
2664
2665 /* Multi-tty support relies on MULTI_KBOARD.  It seems safe to turn it
2666    on unconditionally.  Note that src/s/darwin.h disables this at
2667    present.  */
2668 #ifndef MULTI_KBOARD
2669 #define MULTI_KBOARD
2670 #endif
2671
2672 /* If we're using the Carbon API on Mac OS X, define a few more
2673    variables as well.  */
2674 #ifdef HAVE_CARBON
2675 #define HAVE_WINDOW_SYSTEM
2676 #define HAVE_MOUSE
2677 #endif
2678
2679 /* Define USER_FULL_NAME to return a string
2680    that is the user's full name.
2681    It can assume that the variable `pw'
2682    points to the password file entry for this user.
2683
2684    At some sites, the pw_gecos field contains
2685    the user's full name.  If neither this nor any other
2686    field contains the right thing, use pw_name,
2687    giving the user's login name, since that is better than nothing.  */
2688 #define USER_FULL_NAME pw->pw_gecos
2689
2690 /* Define AMPERSAND_FULL_NAME if you use the convention
2691    that & in the full name stands for the login id.  */
2692 /* Turned on June 1996 supposing nobody will mind it.  */
2693 #define AMPERSAND_FULL_NAME
2694
2695 /* We have blockinput.h.  */
2696 #define DO_BLOCK_INPUT
2697
2698 /* Define HAVE_SOUND if we have sound support.  We know it works
2699    and compiles only on the specified platforms.   For others,
2700    it probably doesn't make sense to try.  */
2701
2702 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2703 #ifdef HAVE_MACHINE_SOUNDCARD_H
2704 #define HAVE_SOUND 1
2705 #endif
2706 #ifdef HAVE_SYS_SOUNDCARD_H
2707 #define HAVE_SOUND 1
2708 #endif
2709 #ifdef HAVE_SOUNDCARD_H
2710 #define HAVE_SOUND 1
2711 #endif
2712 #ifdef HAVE_ALSA
2713 #define HAVE_SOUND 1
2714 #endif
2715 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2716
2717 /* If using GNU, then support inline function declarations. */
2718 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2719    generally, because even if non-gcc compilers accept `inline', they
2720    may reject `extern inline'.  */
2721 #if defined (__GNUC__) && defined (OPTIMIZE)
2722 #define INLINE __inline__
2723 #else
2724 #define INLINE
2725 #endif
2726
2727 /* Include the os and machine dependent files.  */
2728 #include config_opsysfile
2729 #include config_machfile
2730
2731 /* Load in the conversion definitions if this system
2732    needs them and the source file being compiled has not
2733    said to inhibit this.  There should be no need for you
2734    to alter these lines.  */
2735
2736 #ifdef SHORTNAMES
2737 #ifndef NO_SHORTNAMES
2738 #include "../shortnames/remap.h"
2739 #endif /* not NO_SHORTNAMES */
2740 #endif /* SHORTNAMES */
2741
2742 /* If no remapping takes place, static variables cannot be dumped as
2743    pure, so don't worry about the `static' keyword. */
2744 #ifdef NO_REMAP
2745 #undef static
2746 #endif
2747
2748 /* Define `subprocesses' should be defined if you want to
2749    have code for asynchronous subprocesses
2750    (as used in M-x compile and M-x shell).
2751    These do not work for some USG systems yet;
2752    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
2753
2754 #ifndef VMS
2755 #ifndef USG
2756 /* #define subprocesses */
2757 #endif
2758 #endif
2759
2760 /* SIGTYPE is the macro we actually use.  */
2761 #ifndef SIGTYPE
2762 #define SIGTYPE RETSIGTYPE
2763 #endif
2764
2765 #ifdef emacs /* Don't do this for lib-src.  */
2766 /* Tell regex.c to use a type compatible with Emacs.  */
2767 #define RE_TRANSLATE_TYPE Lisp_Object
2768 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2769 #ifdef make_number
2770 /* If make_number is a macro, use it.  */
2771 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2772 #else
2773 /* If make_number is a function, avoid it.  */
2774 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2775 #endif
2776 #endif
2777
2778 /* Avoid link-time collision with system mktime if we will use our own.  */
2779 #if ! HAVE_MKTIME || BROKEN_MKTIME
2780 #define mktime emacs_mktime
2781 #endif
2782
2783 #define my_strftime nstrftime   /* for strftime.c */
2784
2785 /* The rest of the code currently tests the CPP symbol BSTRING.
2786    Override any claims made by the system-description files.
2787    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2788 #undef BSTRING
2789 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2790 #define BSTRING
2791 #endif
2792
2793 /* Some of the files of Emacs which are intended for use with other
2794    programs assume that if you have a config.h file, you must declare
2795    the type of getenv.
2796
2797    This declaration shouldn't appear when alloca.s or Makefile.in
2798    includes config.h.  */
2799 #ifndef NOT_C_CODE
2800 extern char *getenv ();
2801 #endif
2802
2803 /* These default definitions are good for almost all machines.
2804    The exceptions override them in m/MACHINE.h.  */
2805
2806 #ifndef BITS_PER_CHAR
2807 #define BITS_PER_CHAR 8
2808 #endif
2809
2810 #ifndef BITS_PER_SHORT
2811 #define BITS_PER_SHORT 16
2812 #endif
2813
2814 /* Note that lisp.h uses this in a preprocessor conditional, so it
2815    would not work to use sizeof.  That being so, we do all of them
2816    without sizeof, for uniformity's sake.  */
2817 #ifndef BITS_PER_INT
2818 #define BITS_PER_INT 32
2819 #endif
2820
2821 #ifndef BITS_PER_LONG
2822 #ifdef _LP64
2823 #define BITS_PER_LONG 64
2824 #else
2825 #define BITS_PER_LONG 32
2826 #endif
2827 #endif
2828
2829 /* Define if the compiler supports function prototypes.  It may do so
2830    but not define __STDC__ (e.g. DEC C by default) or may define it as
2831    zero.  */
2832 #undef PROTOTYPES
2833 /* For mktime.c:  */
2834 #ifndef __P
2835 # if defined PROTOTYPES
2836 #  define __P(args) args
2837 # else
2838 #  define __P(args) ()
2839 # endif  /* GCC.  */
2840 #endif /* __P */
2841
2842 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2843 #ifndef NOT_C_CODE
2844 #ifdef HAVE_STRING_H
2845 #include "string.h"
2846 #endif
2847 #ifdef HAVE_STRINGS_H
2848 #include "strings.h"  /* May be needed for bcopy & al. */
2849 #endif
2850 #ifdef HAVE_STDLIB_H
2851 #include <stdlib.h>
2852 #endif
2853 #ifndef __GNUC__
2854 # ifdef HAVE_ALLOCA_H
2855 #  include <alloca.h>
2856 # else /* AIX files deal with #pragma.  */
2857 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2858 char *alloca ();
2859 #  endif
2860 # endif /* HAVE_ALLOCA_H */
2861 #endif /* __GNUC__ */
2862 #ifndef HAVE_SIZE_T
2863 typedef unsigned size_t;
2864 #endif
2865 #endif /* NOT_C_CODE */
2866
2867 /* Define HAVE_X_I18N if we have usable i18n support.  */
2868
2869 #ifdef HAVE_X11R6
2870 #define HAVE_X_I18N
2871 #elif !defined X11R5_INHIBIT_I18N
2872 #define HAVE_X_I18N
2873 #endif
2874
2875 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2876
2877 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2878 #define HAVE_X11R6_XIM
2879 #endif
2880
2881 /* Should we enable expensive run-time checking of data types?  */
2882 #undef ENABLE_CHECKING
2883
2884 #if defined __GNUC__ && (__GNUC__ > 2 \
2885                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2886 #define NO_RETURN       __attribute__ ((__noreturn__))
2887 #else
2888 #define NO_RETURN       /* nothing */
2889 #endif
2890
2891 /* These won't be used automatically yet.  We also need to know, at least,
2892    that the stack is continuous.  */
2893 #ifdef __GNUC__
2894 #  ifndef GC_SETJMP_WORKS
2895   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2896      see NON_SAVING_SETJMP in the target descriptions.  */
2897   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2898      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2899      Fixme: Deal with SVR3.  */
2900 #    define GC_SETJMP_WORKS 1
2901 #  endif
2902 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2903 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2904 #  endif
2905 #endif
2906
2907 #ifndef HAVE_BCOPY
2908 #define bcopy(a,b,s) memcpy (b,a,s)
2909 #endif
2910 #ifndef HAVE_BZERO
2911 #define bzero(a,s) memset (a,0,s)
2912 #endif
2913 #ifndef HAVE_BCMP
2914 #define BCMP memcmp
2915 #endif
2916
2917 #endif /* EMACS_CONFIG_H */
2918
2919 /*
2920 Local Variables:
2921 mode: c
2922 End:
2923 */
2924 ])dnl
2925
2926 #### Report on what we decided to do.
2927 #### Report GTK as a toolkit, even if it doesn't use Xt.
2928 #### It makes printing result more understandable as using GTK sets
2929 #### toolkit_scroll_bars to yes by default.
2930 if test "${HAVE_GTK}" = "yes"; then
2931   USE_X_TOOLKIT=GTK
2932 fi
2933
2934 echo "
2935 Configured for \`${canonical}'.
2936
2937   Where should the build process find the source code?    ${srcdir}
2938   What operating system and machine description files should Emacs use?
2939         \`${opsysfile}' and \`${machfile}'
2940   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2941   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2942   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2943   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2944   What window system should Emacs use?                    ${window_system}
2945   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2946
2947 if test -n "${x_includes}"; then
2948 echo "  Where do we find X Windows header files?                ${x_includes}"
2949 else
2950 echo "  Where do we find X Windows header files?                Standard dirs"
2951 fi
2952 if test -n "${x_libraries}"; then
2953 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2954 else
2955 echo "  Where do we find X Windows libraries?                   Standard dirs"
2956 fi
2957
2958 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2959 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2960 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2961 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2962 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2963 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2964 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2965 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2966 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
2967 echo
2968
2969 if test $USE_XASSERTS = yes; then
2970    echo "  Compiling with asserts turned on."
2971    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2972    echo
2973 fi
2974
2975 if test "$USE_X_TOOLKIT" = GTK; then
2976   case "$canonical" in
2977   *cygwin*)
2978     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2979   will probably get a crash on startup.  If this happens, please use another
2980   toolkit for Emacs.  See etc/PROBLEMS for more information."
2981   ;;
2982   esac
2983 fi
2984
2985
2986 if test "$HAVE_CARBON" = "yes"; then
2987    echo
2988    echo "Warning: The Mac Carbon port is currently unsupported and has
2989 known problems.  It is not recommended for use by non-developers.
2990 Read the emacs-devel archives for more information."
2991    echo
2992 fi
2993
2994 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
2995   echo "D-Bus integration has been tested for GNU/Linux only."
2996   echo
2997 fi
2998
2999
3000 # Remove any trailing slashes in these variables.
3001 [test "${prefix}" != NONE &&
3002   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3003 test "${exec_prefix}" != NONE &&
3004   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3005
3006 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3007 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3008 ## from Makefile.c can correctly provide the arg `-traditional' to the
3009 ## C preprocessor.
3010
3011 AC_EGREP_CPP(yes..yes,
3012         [yes..yes],
3013         CPP_NEED_TRADITIONAL=no,
3014         CPP_NEED_TRADITIONAL=yes)
3015
3016 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3017         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3018         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3019         lwlib/Makefile lisp/Makefile leim/Makefile, [
3020
3021 ### Make the necessary directories, if they don't exist.
3022 for dir in etc lisp ; do
3023   test -d ${dir} || mkdir ${dir}
3024 done
3025
3026 # Build src/Makefile from ${srcdir}/src/Makefile.c
3027 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3028 # This must be done after src/config.h is built, since we rely on that file.
3029
3030 # Now get this: Some word that is part of the ${srcdir} directory name
3031 # or the ${configuration} value might, just might, happen to be an
3032 # identifier like `sun4' or `i386' or something, and be predefined by
3033 # the C preprocessor to some helpful value like 1, or maybe the empty
3034 # string.  Needless to say consequent macro substitutions are less
3035 # than conducive to the makefile finding the correct directory.
3036 [undefs="`echo $top_srcdir $configuration $canonical |
3037 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3038     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3039 `"]
3040
3041 echo creating src/epaths.h
3042 ${MAKE-make} epaths-force
3043
3044 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3045 # `..' to `. .'  unless invoked with -traditional
3046
3047 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3048   CPPFLAGS="$CPPFLAGS -traditional"
3049 fi
3050
3051 echo creating lib-src/Makefile
3052 ( cd lib-src
3053   rm -f junk.c junk1.c junk2.c
3054   sed -e '/start of cpp stuff/q' \
3055       < Makefile.c > junk1.c
3056   sed -e '1,/start of cpp stuff/d'\
3057       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3058       < Makefile.c > junk.c
3059   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3060       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3061   cat junk1.c junk2.c > Makefile.new
3062   rm -f junk.c junk1.c junk2.c
3063   chmod 444 Makefile.new
3064   mv -f Makefile.new Makefile
3065 )
3066
3067 echo creating src/Makefile
3068 ( cd src
3069   rm -f junk.c junk1.c junk2.c
3070   sed -e '/start of cpp stuff/q' \
3071       < Makefile.c > junk1.c
3072   sed -e '1,/start of cpp stuff/d'\
3073       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3074       < Makefile.c > junk.c
3075   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3076       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3077   cat junk1.c junk2.c > Makefile.new
3078   rm -f junk.c junk1.c junk2.c
3079   chmod 444 Makefile.new
3080   mv -f Makefile.new Makefile
3081 )
3082
3083 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3084   echo creating src/.gdbinit
3085   echo source $srcdir/src/.gdbinit > src/.gdbinit
3086 fi
3087
3088 # This is how we know whether to re-run configure in certain cases.
3089 touch src/config.stamp
3090
3091 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3092
3093 m4_if(dnl       Do not change this comment
3094    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3095 )dnl