lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems
   2
   3 ;; Copyright (C) 1993, 1994, 1996, 1997, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar frame-creation-function-alist
  31   (list (cons nil
  32               (if (fboundp 'tty-create-frame-with-faces)
  33                   'tty-create-frame-with-faces
  34                 (function
  35                  (lambda (parameters)
  36                    (error "Can't create multiple frames without a window system"))))))
  37   "Alist of window-system dependent functions to call to create a new frame.
  38 The window system startup file should add its frame creation
  39 function to this list, which should take an alist of parameters
  40 as its argument.")
  41
  42 (defvar window-system-default-frame-alist nil
  43   "Alist of window-system dependent default frame parameters.
  44 You can set this in your `.emacs' file; for example,
  45
  46     ;; Disable menubar and toolbar on the console, but enable them under X.
  47     (setq window-system-default-frame-alist
  48           '((x (menu-bar-lines . 1) (tool-bar-lines . 1))
  49             (nil (menu-bar-lines . 0) (tool-bar-lines . 0))))
  50
  51 Parameters specified here supersede the values given in `default-frame-alist'.")
  52
  53 ;; The initial value given here used to ask for a minibuffer.
  54 ;; But that's not necessary, because the default is to have one.
  55 ;; By not specifying it here, we let an X resource specify it.
  56 (defcustom initial-frame-alist nil
  57   "*Alist of frame parameters for creating the initial X window frame.
  58 You can set this in your `.emacs' file; for example,
  59  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  60 Parameters specified here supersede the values given in `default-frame-alist'.
  61
  62 If the value calls for a frame without a minibuffer, and you have not created
  63 a minibuffer frame on your own, one is created according to
  64 `minibuffer-frame-alist'.
  65
  66 You can specify geometry-related options for just the initial frame
  67 by setting this variable in your `.emacs' file; however, they won't
  68 take effect until Emacs reads `.emacs', which happens after first creating
  69 the frame.  If you want the frame to have the proper geometry as soon
  70 as it appears, you need to use this three-step process:
  71 * Specify X resources to give the geometry you want.
  72 * Set `default-frame-alist' to override these options so that they
  73   don't affect subsequent frames.
  74 * Set `initial-frame-alist' in a way that matches the X resources,
  75   to override what you put in `default-frame-alist'."
  76   :type '(repeat (cons :format "%v"
  77                        (symbol :tag "Parameter")
  78                        (sexp :tag "Value")))
  79   :group 'frames)
  80
  81 (defcustom minibuffer-frame-alist '((width . 80) (height . 2))
  82   "*Alist of frame parameters for initially creating a minibuffer frame.
  83 You can set this in your `.emacs' file; for example,
  84  (setq minibuffer-frame-alist
  85    '((top . 1) (left . 1) (width . 80) (height . 2)))
  86 Parameters specified here supersede the values given in
  87 `default-frame-alist', for a minibuffer frame."
  88   :type '(repeat (cons :format "%v"
  89                        (symbol :tag "Parameter")
  90                        (sexp :tag "Value")))
  91   :group 'frames)
  92
  93 (defcustom pop-up-frame-alist nil
  94   "*Alist of frame parameters used when creating pop-up frames.
  95 Pop-up frames are used for completions, help, and the like.
  96 This variable can be set in your init file, like this:
  97   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  98 These supersede the values given in `default-frame-alist',
  99 for pop-up frames."
 100   :type '(repeat (cons :format "%v"
 101                        (symbol :tag "Parameter")
 102                        (sexp :tag "Value")))
 103   :group 'frames)
 104
 105 (setq pop-up-frame-function
 106       ;; Using `function' here caused some sort of problem.
 107       '(lambda ()
 108          (make-frame pop-up-frame-alist)))
 109
 110 (defcustom special-display-frame-alist
 111   '((height . 14) (width . 80) (unsplittable . t))
 112   "*Alist of frame parameters used when creating special frames.
 113 Special frames are used for buffers whose names are in
 114 `special-display-buffer-names' and for buffers whose names match
 115 one of the regular expressions in `special-display-regexps'.
 116 This variable can be set in your init file, like this:
 117   (setq special-display-frame-alist '((width . 80) (height . 20)))
 118 These supersede the values given in `default-frame-alist'."
 119   :type '(repeat (cons :format "%v"
 120                          (symbol :tag "Parameter")
 121                          (sexp :tag "Value")))
 122   :group 'frames)
 123
 124 (defun special-display-popup-frame (buffer &optional args)
 125   "Display BUFFER in its own frame, reusing an existing window if any.
 126 Return the window chosen.
 127 Currently we do not insist on selecting the window within its frame.
 128 If ARGS is an alist, use it as a list of frame parameter specs.
 129 If ARGS is a list whose car is a symbol,
 130 use (car ARGS) as a function to do the work.
 131 Pass it BUFFER as first arg, and (cdr ARGS) gives the rest of the args."
 132   (if (and args (symbolp (car args)))
 133       (apply (car args) buffer (cdr args))
 134     (let ((window (get-buffer-window buffer 0)))
 135       (or
 136        ;; If we have a window already, make it visible.
 137        (when window
 138          (let ((frame (window-frame window)))
 139            (make-frame-visible frame)
 140            (raise-frame frame)
 141            window))
 142        ;; Reuse the current window if the user requested it.
 143        (when (cdr (assq 'same-window args))
 144          (condition-case nil
 145              (progn (switch-to-buffer buffer) (selected-window))
 146            (error nil)))
 147        ;; Stay on the same frame if requested.
 148        (when (or (cdr (assq 'same-frame args)) (cdr (assq 'same-window args)))
 149          (let* ((pop-up-frames nil) (pop-up-windows t)
 150                 special-display-regexps special-display-buffer-names
 151                 (window (display-buffer buffer)))
 152            ;; Only do it if this is a new window:
 153            ;; (set-window-dedicated-p window t)
 154            window))
 155        ;; If no window yet, make one in a new frame.
 156        (let ((frame
 157               (with-current-buffer buffer
 158                 (make-frame (append args special-display-frame-alist)))))
 159          (set-window-buffer (frame-selected-window frame) buffer)
 160          (set-window-dedicated-p (frame-selected-window frame) t)
 161          (frame-selected-window frame))))))
 162
 163 (defun handle-delete-frame (event)
 164   "Handle delete-frame events from the X server."
 165   (interactive "e")
 166   (let ((frame (posn-window (event-start event)))
 167         (i 0)
 168         (tail (frame-list)))
 169     (while tail
 170       (and (frame-visible-p (car tail))
 171            (not (eq (car tail) frame))
 172           (setq i (1+ i)))
 173       (setq tail (cdr tail)))
 174     (if (> i 0)
 175         (delete-frame frame t)
 176       ;; Gildea@x.org says it is ok to ask questions before terminating.
 177       (save-buffers-kill-emacs))))
 178 \f
 179 ;;;; Arrangement of frames at startup
 180
 181 ;; 1) Load the window system startup file from the lisp library and read the
 182 ;; high-priority arguments (-q and the like).  The window system startup
 183 ;; file should create any frames specified in the window system defaults.
 184 ;;
 185 ;; 2) If no frames have been opened, we open an initial text frame.
 186 ;;
 187 ;; 3) Once the init file is done, we apply any newly set parameters
 188 ;; in initial-frame-alist to the frame.
 189
 190 ;; These are now called explicitly at the proper times,
 191 ;; since that is easier to understand.
 192 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
 193 ;; (add-hook 'before-init-hook 'frame-initialize)
 194 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
 195
 196 ;; If we create the initial frame, this is it.
 197 (defvar frame-initial-frame nil)
 198
 199 ;; Record the parameters used in frame-initialize to make the initial frame.
 200 (defvar frame-initial-frame-alist)
 201
 202 (defvar frame-initial-geometry-arguments nil)
 203
 204 ;; startup.el calls this function before loading the user's init
 205 ;; file - if there is no frame with a minibuffer open now, create
 206 ;; one to display messages while loading the init file.
 207 (defun frame-initialize ()
 208   "Create an initial frame if necessary."
 209   ;; Are we actually running under a window system at all?
 210   (if (and initial-window-system
 211            (not noninteractive)
 212            (not (eq initial-window-system 'pc)))
 213       (progn
 214         ;; Turn on special-display processing only if there's a window system.
 215         (setq special-display-function 'special-display-popup-frame)
 216
 217         ;; If there is no frame with a minibuffer besides the terminal
 218         ;; frame, then we need to create the opening frame.  Make sure
 219         ;; it has a minibuffer, but let initial-frame-alist omit the
 220         ;; minibuffer spec.
 221         (or (delq terminal-frame (minibuffer-frame-list))
 222             (progn
 223               (setq frame-initial-frame-alist
 224                     (append initial-frame-alist default-frame-alist nil))
 225               (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
 226                   (setq frame-initial-frame-alist
 227                         (cons '(horizontal-scroll-bars . t)
 228                               frame-initial-frame-alist)))
 229               (setq frame-initial-frame-alist
 230                     (cons (cons 'window-system initial-window-system)
 231                           frame-initial-frame-alist))
 232               (setq default-minibuffer-frame
 233                     (setq frame-initial-frame
 234                           (make-frame frame-initial-frame-alist)))
 235               ;; Delete any specifications for window geometry parameters
 236               ;; so that we won't reapply them in frame-notice-user-settings.
 237               ;; It would be wrong to reapply them then,
 238               ;; because that would override explicit user resizing.
 239               (setq initial-frame-alist
 240                     (frame-remove-geometry-params initial-frame-alist))))
 241         ;; Copy the environment of the Emacs process into the new frame.
 242         (set-frame-parameter frame-initial-frame 'environment
 243                              (frame-parameter terminal-frame 'environment))
 244         ;; At this point, we know that we have a frame open, so we
 245         ;; can delete the terminal frame.
 246         (delete-frame terminal-frame)
 247         (setq terminal-frame nil))))
 248
 249 (defvar frame-notice-user-settings t
 250   "Non-nil means function `frame-notice-user-settings' wasn't run yet.")
 251
 252 ;; startup.el calls this function after loading the user's init
 253 ;; file.  Now default-frame-alist and initial-frame-alist contain
 254 ;; information to which we must react; do what needs to be done.
 255 (defun frame-notice-user-settings ()
 256   "Act on user's init file settings of frame parameters.
 257 React to settings of `initial-frame-alist',
 258 `window-system-default-frame-alist' and `default-frame-alist'
 259 there (in decreasing order of priority)."
 260   ;; Make menu-bar-mode and default-frame-alist consistent.
 261   (when (boundp 'menu-bar-mode)
 262     (let ((default (assq 'menu-bar-lines default-frame-alist)))
 263       (if default
 264           (setq menu-bar-mode (not (eq (cdr default) 0)))
 265         (setq default-frame-alist
 266               (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
 267                     default-frame-alist)))))
 268
 269   ;; Make tool-bar-mode and default-frame-alist consistent.  Don't do
 270   ;; it in batch mode since that would leave a tool-bar-lines
 271   ;; parameter in default-frame-alist in a dumped Emacs, which is not
 272   ;; what we want.
 273   (when (and (boundp 'tool-bar-mode)
 274              (not noninteractive))
 275     (let ((default (assq 'tool-bar-lines default-frame-alist)))
 276       (if default
 277           (setq tool-bar-mode (not (eq (cdr default) 0)))
 278         ;; If Emacs was started on a tty, changing default-frame-alist
 279         ;; would disable the toolbar on X frames created later.  We
 280         ;; want to keep the default of showing a toolbar under X even
 281         ;; in this case.
 282         ;;
 283         ;; If the user explicitly called `tool-bar-mode' in .emacs,
 284         ;; then default-frame-alist is already changed anyway.
 285         (when initial-window-system
 286           (setq default-frame-alist
 287                 (cons (cons 'tool-bar-lines (if tool-bar-mode 1 0))
 288                       default-frame-alist))))))
 289
 290   ;; Creating and deleting frames may shift the selected frame around,
 291   ;; and thus the current buffer.  Protect against that.  We don't
 292   ;; want to use save-excursion here, because that may also try to set
 293   ;; the buffer of the selected window, which fails when the selected
 294   ;; window is the minibuffer.
 295   (let ((old-buffer (current-buffer))
 296         (window-system-frame-alist (cdr (assq initial-window-system
 297                                               window-system-default-frame-alist))))
 298
 299     (when (and frame-notice-user-settings
 300                (null frame-initial-frame))
 301       ;; This case happens when we don't have a window system, and
 302       ;; also for MS-DOS frames.
 303       (let ((parms (frame-parameters frame-initial-frame)))
 304         ;; Don't change the frame names.
 305         (setq parms (delq (assq 'name parms) parms))
 306         ;; Can't modify the minibuffer parameter, so don't try.
 307         (setq parms (delq (assq 'minibuffer parms) parms))
 308         (modify-frame-parameters nil
 309                                  (if (null initial-window-system)
 310                                      (append initial-frame-alist
 311                                              window-system-frame-alist
 312                                              default-frame-alist
 313                                              parms
 314                                              nil)
 315                                    ;; initial-frame-alist and
 316                                    ;; default-frame-alist were already
 317                                    ;; applied in pc-win.el.
 318                                    parms))
 319         (if (null initial-window-system) ;; MS-DOS does this differently in pc-win.el
 320             (let ((newparms (frame-parameters))
 321                   (frame (selected-frame)))
 322               (tty-handle-reverse-video frame newparms)
 323               ;; If we changed the background color, we need to update
 324               ;; the background-mode parameter, and maybe some faces,
 325               ;; too.
 326               (when (assq 'background-color newparms)
 327                 (unless (or (assq 'background-mode initial-frame-alist)
 328                             (assq 'background-mode default-frame-alist))
 329                   (frame-set-background-mode frame))
 330                 (face-set-after-frame-default frame))))))
 331
 332     ;; If the initial frame is still around, apply initial-frame-alist
 333     ;; and default-frame-alist to it.
 334     (when (frame-live-p frame-initial-frame)
 335
 336       ;; When tool-bar has been switched off, correct the frame size
 337       ;; by the lines added in x-create-frame for the tool-bar and
 338       ;; switch `tool-bar-mode' off.
 339       (when (display-graphic-p)
 340         (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 341                                   (assq 'tool-bar-lines window-system-frame-alist)
 342                                   (assq 'tool-bar-lines default-frame-alist))))
 343           (when (and tool-bar-originally-present
 344                      (or (null tool-bar-lines)
 345                          (null (cdr tool-bar-lines))
 346                          (eq 0 (cdr tool-bar-lines))))
 347             (let* ((char-height (frame-char-height frame-initial-frame))
 348                    (image-height tool-bar-images-pixel-height)
 349                    (margin (cond ((and (consp tool-bar-button-margin)
 350                                        (integerp (cdr tool-bar-button-margin))
 351                                        (> tool-bar-button-margin 0))
 352                                   (cdr tool-bar-button-margin))
 353                                  ((and (integerp tool-bar-button-margin)
 354                                        (> tool-bar-button-margin 0))
 355                                   tool-bar-button-margin)
 356                                  (t 0)))
 357                    (relief (if (and (integerp tool-bar-button-relief)
 358                                     (> tool-bar-button-relief 0))
 359                                tool-bar-button-relief 3))
 360                    (lines (/ (+ image-height
 361                                 (* 2 margin)
 362                                 (* 2 relief)
 363                                 (1- char-height))
 364                              char-height))
 365                    (height (frame-parameter frame-initial-frame 'height))
 366                    (newparms (list (cons 'height (- height lines))))
 367                    (initial-top (cdr (assq 'top
 368                                            frame-initial-geometry-arguments)))
 369                    (top (frame-parameter frame-initial-frame 'top)))
 370               (when (and (consp initial-top) (eq '- (car initial-top)))
 371                 (let ((adjusted-top
 372                        (cond ((and (consp top)
 373                                    (eq '+ (car top)))
 374                               (list '+
 375                                     (+ (cadr top)
 376                                        (* lines char-height))))
 377                              ((and (consp top)
 378                                    (eq '- (car top)))
 379                               (list '-
 380                                     (- (cadr top)
 381                                        (* lines char-height))))
 382                              (t (+ top (* lines char-height))))))
 383                   (setq newparms
 384                         (append newparms
 385                                 `((top . ,adjusted-top))
 386                                 nil))))
 387               (modify-frame-parameters frame-initial-frame newparms)
 388               (tool-bar-mode -1)))))
 389
 390       ;; The initial frame we create above always has a minibuffer.
 391       ;; If the user wants to remove it, or make it a minibuffer-only
 392       ;; frame, then we'll have to delete the current frame and make a
 393       ;; new one; you can't remove or add a root window to/from an
 394       ;; existing frame.
 395       ;;
 396       ;; NOTE: default-frame-alist was nil when we created the
 397       ;; existing frame.  We need to explicitly include
 398       ;; default-frame-alist in the parameters of the screen we
 399       ;; create here, so that its new value, gleaned from the user's
 400       ;; .emacs file, will be applied to the existing screen.
 401       (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 402                             (assq 'minibuffer window-system-frame-alist)
 403                             (assq 'minibuffer default-frame-alist)
 404                             '(minibuffer . t)))
 405                    t))
 406           ;; Create the new frame.
 407           (let (parms new)
 408             ;; If the frame isn't visible yet, wait till it is.
 409             ;; If the user has to position the window,
 410             ;; Emacs doesn't know its real position until
 411             ;; the frame is seen to be visible.
 412             (while (not (cdr (assq 'visibility
 413                                    (frame-parameters frame-initial-frame))))
 414               (sleep-for 1))
 415             (setq parms (frame-parameters frame-initial-frame))
 416
 417             ;; Get rid of `name' unless it was specified explicitly before.
 418             (or (assq 'name frame-initial-frame-alist)
 419                 (setq parms (delq (assq 'name parms) parms)))
 420
 421             (setq parms (append initial-frame-alist
 422                                 window-system-frame-alist
 423                                 default-frame-alist
 424                                 parms
 425                                 nil))
 426
 427             ;; Get rid of `reverse', because that was handled
 428             ;; when we first made the frame.
 429             (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))
 430
 431             (if (assq 'height frame-initial-geometry-arguments)
 432                 (setq parms (assq-delete-all 'height parms)))
 433             (if (assq 'width frame-initial-geometry-arguments)
 434                 (setq parms (assq-delete-all 'width parms)))
 435             (if (assq 'left frame-initial-geometry-arguments)
 436                 (setq parms (assq-delete-all 'left parms)))
 437             (if (assq 'top frame-initial-geometry-arguments)
 438                 (setq parms (assq-delete-all 'top parms)))
 439             (setq new
 440                   (make-frame
 441                    ;; Use the geometry args that created the existing
 442                    ;; frame, rather than the parms we get for it.
 443                    (append frame-initial-geometry-arguments
 444                            '((user-size . t) (user-position . t))
 445                            parms)))
 446             ;; The initial frame, which we are about to delete, may be
 447             ;; the only frame with a minibuffer.  If it is, create a
 448             ;; new one.
 449             (or (delq frame-initial-frame (minibuffer-frame-list))
 450                 (make-initial-minibuffer-frame nil))
 451
 452             ;; If the initial frame is serving as a surrogate
 453             ;; minibuffer frame for any frames, we need to wean them
 454             ;; onto a new frame.  The default-minibuffer-frame
 455             ;; variable must be handled similarly.
 456             (let ((users-of-initial
 457                    (filtered-frame-list
 458                     (function (lambda (frame)
 459                                 (and (not (eq frame frame-initial-frame))
 460                                      (eq (window-frame
 461                                           (minibuffer-window frame))
 462                                          frame-initial-frame)))))))
 463               (if (or users-of-initial
 464                       (eq default-minibuffer-frame frame-initial-frame))
 465
 466                   ;; Choose an appropriate frame.  Prefer frames which
 467                   ;; are only minibuffers.
 468                   (let* ((new-surrogate
 469                           (car
 470                            (or (filtered-frame-list
 471                                 (function
 472                                  (lambda (frame)
 473                                    (eq (cdr (assq 'minibuffer
 474                                                   (frame-parameters frame)))
 475                                        'only))))
 476                                (minibuffer-frame-list))))
 477                          (new-minibuffer (minibuffer-window new-surrogate)))
 478
 479                     (if (eq default-minibuffer-frame frame-initial-frame)
 480                         (setq default-minibuffer-frame new-surrogate))
 481
 482                     ;; Wean the frames using frame-initial-frame as
 483                     ;; their minibuffer frame.
 484                     (mapcar
 485                      (function
 486                       (lambda (frame)
 487                         (modify-frame-parameters
 488                          frame (list (cons 'minibuffer new-minibuffer)))))
 489                      users-of-initial))))
 490
 491            ;; Redirect events enqueued at this frame to the new frame.
 492             ;; Is this a good idea?
 493             (redirect-frame-focus frame-initial-frame new)
 494
 495             ;; Finally, get rid of the old frame.
 496             (delete-frame frame-initial-frame t))
 497
 498         ;; Otherwise, we don't need all that rigamarole; just apply
 499         ;; the new parameters.
 500         (let (newparms allparms tail)
 501           (setq allparms (append initial-frame-alist
 502                                  window-system-frame-alist
 503                                  default-frame-alist nil))
 504           (if (assq 'height frame-initial-geometry-arguments)
 505               (setq allparms (assq-delete-all 'height allparms)))
 506           (if (assq 'width frame-initial-geometry-arguments)
 507               (setq allparms (assq-delete-all 'width allparms)))
 508           (if (assq 'left frame-initial-geometry-arguments)
 509               (setq allparms (assq-delete-all 'left allparms)))
 510           (if (assq 'top frame-initial-geometry-arguments)
 511               (setq allparms (assq-delete-all 'top allparms)))
 512           (setq tail allparms)
 513           ;; Find just the parms that have changed since we first
 514           ;; made this frame.  Those are the ones actually set by
 515           ;; the init file.  For those parms whose values we already knew
 516           ;; (such as those spec'd by command line options)
 517           ;; it is undesirable to specify the parm again
 518           ;; once the user has seen the frame and been able to alter it
 519           ;; manually.
 520           (while tail
 521             (let (newval oldval)
 522               (setq oldval (assq (car (car tail))
 523                                  frame-initial-frame-alist))
 524               (setq newval (cdr (assq (car (car tail)) allparms)))
 525               (or (and oldval (eq (cdr oldval) newval))
 526                   (setq newparms
 527                         (cons (cons (car (car tail)) newval) newparms))))
 528             (setq tail (cdr tail)))
 529           (setq newparms (nreverse newparms))
 530           (modify-frame-parameters frame-initial-frame
 531                                    newparms)
 532           ;; If we changed the background color,
 533           ;; we need to update the background-mode parameter
 534           ;; and maybe some faces too.
 535           (when (assq 'background-color newparms)
 536             (unless (assq 'background-mode newparms)
 537               (frame-set-background-mode frame-initial-frame))
 538             (face-set-after-frame-default frame-initial-frame)))))
 539
 540     ;; Restore the original buffer.
 541     (set-buffer old-buffer)
 542
 543     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 544     ;; Make sure frame-notice-user-settings does nothing if called twice.
 545     (setq frame-notice-user-settings nil)
 546     (setq frame-initial-frame nil)))
 547
 548 (defun make-initial-minibuffer-frame (display)
 549   (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
 550     (if display
 551         (make-frame-on-display display parms)
 552       (make-frame parms))))
 553
 554 ;;;; Creation of additional frames, and other frame miscellanea
 555
 556 (defun modify-all-frames-parameters (alist)
 557   "Modify all current and future frames' parameters according to ALIST.
 558 This changes `default-frame-alist' and possibly `initial-frame-alist'.
 559 Furthermore, this function removes all parameters in ALIST from
 560 `window-system-default-frame-alist'.
 561 See help of `modify-frame-parameters' for more information."
 562   (dolist (frame (frame-list))
 563     (modify-frame-parameters frame alist))
 564
 565   (dolist (pair alist) ;; conses to add/replace
 566     ;; initial-frame-alist needs setting only when
 567     ;; frame-notice-user-settings is true.
 568     (and frame-notice-user-settings
 569          (setq initial-frame-alist
 570                (assq-delete-all (car pair) initial-frame-alist)))
 571     (setq default-frame-alist
 572           (assq-delete-all (car pair) default-frame-alist))
 573     ;; Remove any similar settings from the window-system specific
 574     ;; parameters---they would override default-frame-alist.
 575     (dolist (w window-system-default-frame-alist)
 576       (setcdr w (assq-delete-all (car pair) (cdr w)))))
 577
 578   (and frame-notice-user-settings
 579        (setq initial-frame-alist (append initial-frame-alist alist)))
 580   (setq default-frame-alist (append default-frame-alist alist)))
 581
 582 (defun get-other-frame ()
 583   "Return some frame other than the current frame.
 584 Create one if necessary.  Note that the minibuffer frame, if separate,
 585 is not considered (see `next-frame')."
 586   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 587                (make-frame)
 588              (next-frame (selected-frame)))))
 589     s))
 590
 591 (defun next-multiframe-window ()
 592   "Select the next window, regardless of which frame it is on."
 593   (interactive)
 594   (select-window (next-window (selected-window)
 595                               (> (minibuffer-depth) 0)
 596                               0))
 597   (select-frame-set-input-focus (selected-frame)))
 598
 599 (defun previous-multiframe-window ()
 600   "Select the previous window, regardless of which frame it is on."
 601   (interactive)
 602   (select-window (previous-window (selected-window)
 603                                   (> (minibuffer-depth) 0)
 604                                   0))
 605   (select-frame-set-input-focus (selected-frame)))
 606
 607 (defun make-frame-on-display (display &optional parameters)
 608   "Make a frame on X display DISPLAY.
 609 The optional second argument PARAMETERS specifies additional frame parameters."
 610   (interactive "sMake frame on display: ")
 611   (or (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
 612       (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
 613   (when (and (boundp 'x-initialized) (not x-initialized))
 614     (setq x-display-name display)
 615     (x-initialize-window-system))
 616   (make-frame `((window-system . x) (display . ,display) . ,parameters)))
 617
 618 (defun make-frame-on-tty (tty type &optional parameters)
 619   "Make a frame on terminal device TTY.
 620 TTY should be the file name of the tty device to use.  TYPE
 621 should be the terminal type string of TTY, for example \"xterm\"
 622 or \"vt100\".  The optional third argument PARAMETERS specifies
 623 additional frame parameters."
 624   (interactive "fOpen frame on tty device: \nsTerminal type of %s: ")
 625   (unless tty
 626     (error "Invalid terminal device"))
 627   (unless type
 628     (error "Invalid terminal type"))
 629   (make-frame `((window-system . nil) (tty . ,tty) (tty-type . ,type) . ,parameters)))
 630
 631 (defun make-frame-command ()
 632   "Make a new frame, and select it if the terminal displays only one frame."
 633   (interactive)
 634   (if (and window-system (not (eq window-system 'pc)))
 635       (make-frame)
 636     (select-frame (make-frame))))
 637
 638 (defvar before-make-frame-hook nil
 639   "Functions to run before a frame is created.")
 640
 641 (defvar after-make-frame-functions nil
 642   "Functions to run after a frame is created.
 643 The functions are run with one arg, the newly created frame.")
 644
 645 (defvar after-setting-font-hook nil
 646   "Functions to run after a frame's font has been changed.")
 647
 648 ;; Alias, kept temporarily.
 649 (define-obsolete-function-alias 'new-frame 'make-frame "22.1")
 650
 651 (defun make-frame (&optional parameters)
 652   "Return a newly created frame displaying the current buffer.
 653 Optional argument PARAMETERS is an alist of parameters for the new frame.
 654 Each element of PARAMETERS should have the form (NAME . VALUE), for example:
 655
 656  (name . STRING)        The frame should be named STRING.
 657
 658  (width . NUMBER)       The frame should be NUMBER characters in width.
 659  (height . NUMBER)      The frame should be NUMBER text lines high.
 660
 661 You cannot specify either `width' or `height', you must use neither or both.
 662
 663  (minibuffer . t)       The frame should have a minibuffer.
 664  (minibuffer . nil)     The frame should have no minibuffer.
 665  (minibuffer . only)    The frame should contain only a minibuffer.
 666  (minibuffer . WINDOW)  The frame should use WINDOW as its minibuffer window.
 667
 668  (window-system . nil)  The frame should be displayed on a terminal device.
 669  (window-system . x)    The frame should be displayed in an X window.
 670
 671  (terminal . ID)          The frame should use the terminal identified by ID.
 672
 673 Before the frame is created (via `frame-creation-function-alist'), functions on the
 674 hook `before-make-frame-hook' are run.  After the frame is created, functions
 675 on `after-make-frame-functions' are run with one arg, the newly created frame.
 676
 677 This function itself does not make the new frame the selected frame.
 678 The previously selected frame remains selected.  However, the
 679 window system may select the new frame for its own reasons, for
 680 instance if the frame appears under the mouse pointer and your
 681 setup is for focus to follow the pointer."
 682   (interactive)
 683   (let* ((w (cond
 684              ((assq 'terminal parameters)
 685               (let ((type (terminal-live-p (cdr (assq 'terminal parameters)))))
 686                 (cond
 687                  ((eq type t) nil)
 688                  ((eq type nil) (error "Terminal %s does not exist" (cdr (assq 'terminal parameters))))
 689                  (t type))))
 690              ((assq 'window-system parameters)
 691               (cdr (assq 'window-system parameters)))
 692              (t window-system)))
 693          (frame-creation-function (cdr (assq w frame-creation-function-alist)))
 694          (oldframe (selected-frame))
 695          frame)
 696     (unless frame-creation-function
 697       (error "Don't know how to create a frame on window system %s" w))
 698     (run-hooks 'before-make-frame-hook)
 699     (setq frame (funcall frame-creation-function (append parameters (cdr (assq w window-system-default-frame-alist)))))
 700     (normal-erase-is-backspace-setup-frame frame)
 701     ;; Inherit the 'environment and 'client parameters.
 702     (let ((env (frame-parameter oldframe 'environment))
 703           (client (frame-parameter oldframe 'client)))
 704       (if (not (framep env))
 705           (setq env oldframe))
 706       (if (and env (not (assq 'environment parameters)))
 707           (set-frame-parameter frame 'environment env))
 708       (if (and client (not (assq 'client parameters)))
 709           (set-frame-parameter frame 'client client)))
 710     (run-hook-with-args 'after-make-frame-functions frame)
 711     frame))
 712
 713 (defun filtered-frame-list (predicate)
 714   "Return a list of all live frames which satisfy PREDICATE."
 715   (let* ((frames (frame-list))
 716          (list frames))
 717     (while (consp frames)
 718       (unless (funcall predicate (car frames))
 719         (setcar frames nil))
 720       (setq frames (cdr frames)))
 721     (delq nil list)))
 722
 723 (defun minibuffer-frame-list ()
 724   "Return a list of all frames with their own minibuffers."
 725   (filtered-frame-list
 726    (function (lambda (frame)
 727                (eq frame (window-frame (minibuffer-window frame)))))))
 728
 729 (defun frames-on-display-list (&optional terminal)
 730   "Return a list of all frames on TERMINAL.
 731
 732 TERMINAL should be a terminal identifier (an integer), a frame,
 733 or a name of an X display (a string of the form
 734 HOST:SERVER.SCREEN).
 735
 736 If TERMINAL is omitted or nil, it defaults to the selected
 737 frame's terminal device."
 738   (let* ((terminal (terminal-id terminal))
 739          (func #'(lambda (frame)
 740                    (eq (frame-terminal frame) terminal))))
 741     (filtered-frame-list func)))
 742
 743 (defun framep-on-display (&optional terminal)
 744   "Return the type of frames on TERMINAL.
 745 TERMINAL may be a terminal id, a display name or a frame.  If it
 746 is a frame, its type is returned.  If TERMINAL is omitted or nil,
 747 it defaults to the selected frame's terminal device.  All frames
 748 on a given display are of the same type."
 749   (or (terminal-live-p terminal)
 750       (framep terminal)
 751       (framep (car (frames-on-display-list terminal)))))
 752
 753 (defun frame-remove-geometry-params (param-list)
 754   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 755 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 756 `height', `user-size' and `user-position' parameters.
 757 Emacs uses this to avoid overriding explicit moves and resizings from
 758 the user during startup."
 759   (setq param-list (cons nil param-list))
 760   (let ((tail param-list))
 761     (while (consp (cdr tail))
 762       (if (and (consp (car (cdr tail)))
 763                (memq (car (car (cdr tail)))
 764                      '(height width top left user-position user-size)))
 765           (progn
 766             (setq frame-initial-geometry-arguments
 767                   (cons (car (cdr tail)) frame-initial-geometry-arguments))
 768             (setcdr tail (cdr (cdr tail))))
 769         (setq tail (cdr tail)))))
 770   (setq frame-initial-geometry-arguments
 771         (nreverse frame-initial-geometry-arguments))
 772   (cdr param-list))
 773
 774 (defcustom focus-follows-mouse (not (eq window-system 'mac))
 775   "*Non-nil if window system changes focus when you move the mouse.
 776 You should set this variable to tell Emacs how your window manager
 777 handles focus, since there is no way in general for Emacs to find out
 778 automatically.
 779
 780 This variable does not have any effect on MS-Windows."
 781   :type 'boolean
 782   :group 'frames
 783   :version "20.3")
 784
 785 (defun select-frame-set-input-focus (frame)
 786   "Select FRAME, raise it, and set input focus, if possible."
 787     (select-frame frame)
 788     (raise-frame frame)
 789     ;; Ensure, if possible, that frame gets input focus.
 790     (cond ((memq (window-system frame) '(x max))
 791            (x-focus-frame frame))
 792           ((eq (window-system frame) 'w32)
 793            (w32-focus-frame frame)))
 794     (cond (focus-follows-mouse
 795            (set-mouse-position (selected-frame) (1- (frame-width)) 0))))
 796
 797 (defun other-frame (arg)
 798   "Select the ARGth different visible frame on current display, and raise it.
 799 All frames are arranged in a cyclic order.
 800 This command selects the frame ARG steps away in that order.
 801 A negative ARG moves in the opposite order.
 802
 803 To make this command work properly, you must tell Emacs
 804 how the system (or the window manager) generally handles
 805 focus-switching between windows.  If moving the mouse onto a window
 806 selects it (gives it focus), set `focus-follows-mouse' to t.
 807 Otherwise, that variable should be nil."
 808   (interactive "p")
 809   (let ((frame (selected-frame)))
 810     (while (> arg 0)
 811       (setq frame (next-frame frame))
 812       (while (not (eq (frame-visible-p frame) t))
 813         (setq frame (next-frame frame)))
 814       (setq arg (1- arg)))
 815     (while (< arg 0)
 816       (setq frame (previous-frame frame))
 817       (while (not (eq (frame-visible-p frame) t))
 818         (setq frame (previous-frame frame)))
 819       (setq arg (1+ arg)))
 820     (select-frame-set-input-focus frame)))
 821
 822 (defun iconify-or-deiconify-frame ()
 823   "Iconify the selected frame, or deiconify if it's currently an icon."
 824   (interactive)
 825   (if (eq (cdr (assq 'visibility (frame-parameters))) t)
 826       (iconify-frame)
 827     (make-frame-visible)))
 828
 829 (defun suspend-frame ()
 830   "Do whatever is right to suspend the current frame.
 831 Calls `suspend-emacs' if invoked from the controlling tty device,
 832 `suspend-tty' from a secondary tty device, and
 833 `iconify-or-deiconify-frame' from an X frame."
 834   (interactive)
 835   (let ((type (framep (selected-frame))))
 836     (cond
 837      ((eq type 'x) (iconify-or-deiconify-frame))
 838      ((eq type t)
 839       (if (controlling-tty-p)
 840           (suspend-emacs)
 841         (suspend-tty)))
 842      (t (suspend-emacs)))))
 843
 844 (defun make-frame-names-alist ()
 845   (let* ((current-frame (selected-frame))
 846          (falist
 847           (cons
 848            (cons (frame-parameter current-frame 'name) current-frame) nil))
 849          (frame (next-frame nil t)))
 850     (while (not (eq frame current-frame))
 851       (progn
 852         (setq falist (cons (cons (frame-parameter frame 'name) frame) falist))
 853         (setq frame (next-frame frame t))))
 854     falist))
 855
 856 (defvar frame-name-history nil)
 857 (defun select-frame-by-name (name)
 858   "Select the frame on the current terminal whose name is NAME and raise it.
 859 If there is no frame by that name, signal an error."
 860   (interactive
 861    (let* ((frame-names-alist (make-frame-names-alist))
 862            (default (car (car frame-names-alist)))
 863            (input (completing-read
 864                    (format "Select Frame (default %s): " default)
 865                    frame-names-alist nil t nil 'frame-name-history)))
 866      (if (= (length input) 0)
 867          (list default)
 868        (list input))))
 869   (let* ((frame-names-alist (make-frame-names-alist))
 870          (frame (cdr (assoc name frame-names-alist))))
 871     (or frame
 872         (error "There is no frame named `%s'" name))
 873     (make-frame-visible frame)
 874     (raise-frame frame)
 875     (select-frame frame)
 876     ;; Ensure, if possible, that frame gets input focus.
 877     (cond ((eq (window-system frame) 'x)
 878            (x-focus-frame frame))
 879           ((eq (window-system frame) 'w32)
 880            (w32-focus-frame frame)))
 881     (when focus-follows-mouse
 882       (set-mouse-position frame (1- (frame-width frame)) 0))))
 883 \f
 884 ;;;; Frame configurations
 885
 886 (defun current-frame-configuration ()
 887   "Return a list describing the positions and states of all frames.
 888 Its car is `frame-configuration'.
 889 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 890 where
 891   FRAME is a frame object,
 892   ALIST is an association list specifying some of FRAME's parameters, and
 893   WINDOW-CONFIG is a window configuration object for FRAME."
 894   (cons 'frame-configuration
 895         (mapcar (function
 896                  (lambda (frame)
 897                    (list frame
 898                          (frame-parameters frame)
 899                          (current-window-configuration frame))))
 900                 (frame-list))))
 901
 902 (defun set-frame-configuration (configuration &optional nodelete)
 903   "Restore the frames to the state described by CONFIGURATION.
 904 Each frame listed in CONFIGURATION has its position, size, window
 905 configuration, and other parameters set as specified in CONFIGURATION.
 906 However, this function does not restore deleted frames.
 907
 908 Ordinarily, this function deletes all existing frames not
 909 listed in CONFIGURATION.  But if optional second argument NODELETE
 910 is given and non-nil, the unwanted frames are iconified instead."
 911   (or (frame-configuration-p configuration)
 912       (signal 'wrong-type-argument
 913               (list 'frame-configuration-p configuration)))
 914   (let ((config-alist (cdr configuration))
 915         frames-to-delete)
 916     (mapcar (function
 917              (lambda (frame)
 918                (let ((parameters (assq frame config-alist)))
 919                  (if parameters
 920                      (progn
 921                        (modify-frame-parameters
 922                         frame
 923                         ;; Since we can't set a frame's minibuffer status,
 924                         ;; we might as well omit the parameter altogether.
 925                         (let* ((parms (nth 1 parameters))
 926                                (mini (assq 'minibuffer parms)))
 927                           (if mini (setq parms (delq mini parms)))
 928                           parms))
 929                        (set-window-configuration (nth 2 parameters)))
 930                    (setq frames-to-delete (cons frame frames-to-delete))))))
 931             (frame-list))
 932     (if nodelete
 933         ;; Note: making frames invisible here was tried
 934         ;; but led to some strange behavior--each time the frame
 935         ;; was made visible again, the window manager asked afresh
 936         ;; for where to put it.
 937         (mapcar 'iconify-frame frames-to-delete)
 938       (mapcar 'delete-frame frames-to-delete))))
 939 \f
 940 ;;;; Convenience functions for accessing and interactively changing
 941 ;;;; frame parameters.
 942
 943 (defun frame-height (&optional frame)
 944   "Return number of lines available for display on FRAME.
 945 If FRAME is omitted, describe the currently selected frame."
 946   (cdr (assq 'height (frame-parameters frame))))
 947
 948 (defun frame-width (&optional frame)
 949   "Return number of columns available for display on FRAME.
 950 If FRAME is omitted, describe the currently selected frame."
 951   (cdr (assq 'width (frame-parameters frame))))
 952
 953 (defalias 'set-default-font 'set-frame-font)
 954 (defun set-frame-font (font-name &optional keep-size)
 955   "Set the font of the selected frame to FONT-NAME.
 956 When called interactively, prompt for the name of the font to use.
 957 To get the frame's current default font, use `frame-parameters'.
 958
 959 The default behavior is to keep the numbers of lines and columns in
 960 the frame, thus may change its pixel size.  If optional KEEP-SIZE is
 961 non-nil (interactively, prefix argument) the current frame size (in
 962 pixels) is kept by adjusting the numbers of the lines and columns."
 963   (interactive
 964    (let* ((completion-ignore-case t)
 965           (font (completing-read "Font name: "
 966                          (mapcar #'list
 967                                  ;; x-list-fonts will fail with an error
 968                                  ;; if this frame doesn't support fonts.
 969                                  (x-list-fonts "*" nil (selected-frame)))
 970                          nil nil nil nil
 971                          (frame-parameter nil 'font))))
 972      (list font current-prefix-arg)))
 973   (let (fht fwd)
 974     (if keep-size
 975         (setq fht (* (frame-parameter nil 'height) (frame-char-height))
 976               fwd (* (frame-parameter nil 'width)  (frame-char-width))))
 977     (modify-frame-parameters (selected-frame)
 978                              (list (cons 'font font-name)))
 979     (if keep-size
 980         (modify-frame-parameters
 981          (selected-frame)
 982          (list (cons 'height (round fht (frame-char-height)))
 983                (cons 'width (round fwd (frame-char-width)))))))
 984   (run-hooks 'after-setting-font-hook 'after-setting-font-hooks))
 985
 986 (defun set-frame-parameter (frame parameter value)
 987   "Set frame parameter PARAMETER to VALUE on FRAME.
 988 If FRAME is nil, it defaults to the selected frame.
 989 See `modify-frame-parameters'."
 990   (modify-frame-parameters frame (list (cons parameter value))))
 991
 992 (defun set-background-color (color-name)
 993   "Set the background color of the selected frame to COLOR-NAME.
 994 When called interactively, prompt for the name of the color to use.
 995 To get the frame's current background color, use `frame-parameters'."
 996   (interactive (list (facemenu-read-color "Background color: ")))
 997   (modify-frame-parameters (selected-frame)
 998                            (list (cons 'background-color color-name)))
 999   (or window-system
1000       (face-set-after-frame-default (selected-frame))))
1001
1002 (defun set-foreground-color (color-name)
1003   "Set the foreground color of the selected frame to COLOR-NAME.
1004 When called interactively, prompt for the name of the color to use.
1005 To get the frame's current foreground color, use `frame-parameters'."
1006   (interactive (list (facemenu-read-color "Foreground color: ")))
1007   (modify-frame-parameters (selected-frame)
1008                            (list (cons 'foreground-color color-name)))
1009   (or window-system
1010       (face-set-after-frame-default (selected-frame))))
1011
1012 (defun set-cursor-color (color-name)
1013   "Set the text cursor color of the selected frame to COLOR-NAME.
1014 When called interactively, prompt for the name of the color to use.
1015 To get the frame's current cursor color, use `frame-parameters'."
1016   (interactive (list (facemenu-read-color "Cursor color: ")))
1017   (modify-frame-parameters (selected-frame)
1018                            (list (cons 'cursor-color color-name))))
1019
1020 (defun set-mouse-color (color-name)
1021   "Set the color of the mouse pointer of the selected frame to COLOR-NAME.
1022 When called interactively, prompt for the name of the color to use.
1023 To get the frame's current mouse color, use `frame-parameters'."
1024   (interactive (list (facemenu-read-color "Mouse color: ")))
1025   (modify-frame-parameters (selected-frame)
1026                            (list (cons 'mouse-color
1027                                        (or color-name
1028                                            (cdr (assq 'mouse-color
1029                                                       (frame-parameters))))))))
1030
1031 (defun set-border-color (color-name)
1032   "Set the color of the border of the selected frame to COLOR-NAME.
1033 When called interactively, prompt for the name of the color to use.
1034 To get the frame's current border color, use `frame-parameters'."
1035   (interactive (list (facemenu-read-color "Border color: ")))
1036   (modify-frame-parameters (selected-frame)
1037                            (list (cons 'border-color color-name))))
1038
1039 (defun auto-raise-mode (arg)
1040   "Toggle whether or not the selected frame should auto-raise.
1041 With arg, turn auto-raise mode on if and only if arg is positive.
1042 Note that this controls Emacs's own auto-raise feature.
1043 Some window managers allow you to enable auto-raise for certain windows.
1044 You can use that for Emacs windows if you wish, but if you do,
1045 that is beyond the control of Emacs and this command has no effect on it."
1046   (interactive "P")
1047   (if (null arg)
1048       (setq arg
1049             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
1050                 -1 1)))
1051   (if (> arg 0)
1052       (raise-frame (selected-frame)))
1053   (modify-frame-parameters (selected-frame)
1054                            (list (cons 'auto-raise (> arg 0)))))
1055
1056 (defun auto-lower-mode (arg)
1057   "Toggle whether or not the selected frame should auto-lower.
1058 With arg, turn auto-lower mode on if and only if arg is positive.
1059 Note that this controls Emacs's own auto-lower feature.
1060 Some window managers allow you to enable auto-lower for certain windows.
1061 You can use that for Emacs windows if you wish, but if you do,
1062 that is beyond the control of Emacs and this command has no effect on it."
1063   (interactive "P")
1064   (if (null arg)
1065       (setq arg
1066             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
1067                 -1 1)))
1068   (modify-frame-parameters (selected-frame)
1069                            (list (cons 'auto-lower (> arg 0)))))
1070 (defun set-frame-name (name)
1071   "Set the name of the selected frame to NAME.
1072 When called interactively, prompt for the name of the frame.
1073 The frame name is displayed on the modeline if the terminal displays only
1074 one frame, otherwise the name is displayed on the frame's caption bar."
1075   (interactive "sFrame name: ")
1076   (modify-frame-parameters (selected-frame)
1077                            (list (cons 'name name))))
1078
1079 (defun frame-current-scroll-bars (&optional frame)
1080   "Return the current scroll-bar settings in frame FRAME.
1081 Value is a cons (VERTICAL . HORIZ0NTAL) where VERTICAL specifies the
1082 current location of the vertical scroll-bars (left, right, or nil),
1083 and HORIZONTAL specifies the current location of the horizontal scroll
1084 bars (top, bottom, or nil)."
1085   (let ((vert (frame-parameter frame 'vertical-scroll-bars))
1086         (hor nil))
1087     (unless (memq vert '(left right nil))
1088       (setq vert default-frame-scroll-bars))
1089     (cons vert hor)))
1090 \f
1091 ;;;; Frame/display capabilities.
1092 (defun selected-terminal ()
1093   "Return the terminal that is now selected."
1094   (frame-terminal (selected-frame)))
1095
1096 (defun display-mouse-p (&optional display)
1097   "Return non-nil if DISPLAY has a mouse available.
1098 DISPLAY can be a display name, a frame, or nil (meaning the selected
1099 frame's display)."
1100   (let ((frame-type (framep-on-display display)))
1101     (cond
1102      ((eq frame-type 'pc)
1103       (msdos-mouse-p))
1104      ((eq system-type 'windows-nt)
1105       (with-no-warnings
1106        (> w32-num-mouse-buttons 0)))
1107      ((memq frame-type '(x mac))
1108       t)    ;; We assume X and Mac *always* have a pointing device
1109      (t
1110       (or (and (featurep 'xt-mouse)
1111                xterm-mouse-mode)
1112           ;; t-mouse is distributed with the GPM package.  It doesn't have
1113           ;; a toggle.
1114           (featurep 't-mouse))))))
1115
1116 (defun display-popup-menus-p (&optional display)
1117   "Return non-nil if popup menus are supported on DISPLAY.
1118 DISPLAY can be a display name, a frame, or nil (meaning the selected
1119 frame's display).
1120 Support for popup menus requires that the mouse be available."
1121   (and
1122    (let ((frame-type (framep-on-display display)))
1123      (memq frame-type '(x w32 pc mac)))
1124    (display-mouse-p display)))
1125
1126 (defun display-graphic-p (&optional display)
1127   "Return non-nil if DISPLAY is a graphic display.
1128 Graphical displays are those which are capable of displaying several
1129 frames and several different fonts at once.  This is true for displays
1130 that use a window system such as X, and false for text-only terminals.
1131 DISPLAY can be a display name, a frame, or nil (meaning the selected
1132 frame's display)."
1133   (not (null (memq (framep-on-display display) '(x w32 mac)))))
1134
1135 (defun display-images-p (&optional display)
1136   "Return non-nil if DISPLAY can display images.
1137
1138 DISPLAY can be a display name, a frame, or nil (meaning the selected
1139 frame's display)."
1140   (and (display-graphic-p display)
1141        (fboundp 'image-mask-p)
1142        (fboundp 'image-size)))
1143
1144 (defalias 'display-multi-frame-p 'display-graphic-p)
1145 (defalias 'display-multi-font-p 'display-graphic-p)
1146
1147 (defun display-selections-p (&optional display)
1148   "Return non-nil if DISPLAY supports selections.
1149 A selection is a way to transfer text or other data between programs
1150 via special system buffers called `selection' or `cut buffer' or
1151 `clipboard'.
1152 DISPLAY can be a display name, a frame, or nil (meaning the selected
1153 frame's display)."
1154   (let ((frame-type (framep-on-display display)))
1155     (cond
1156      ((eq frame-type 'pc)
1157       ;; MS-DOG frames support selections when Emacs runs inside
1158       ;; the Windows' DOS Box.
1159       (with-no-warnings
1160        (not (null dos-windows-version))))
1161      ((memq frame-type '(x w32 mac))
1162       t)    ;; FIXME?
1163      (t
1164       nil))))
1165
1166 (defun display-screens (&optional display)
1167   "Return the number of screens associated with DISPLAY."
1168   (let ((frame-type (framep-on-display display)))
1169     (cond
1170      ((memq frame-type '(x w32 mac))
1171       (x-display-screens display))
1172      (t
1173       1))))
1174
1175 (defun display-pixel-height (&optional display)
1176   "Return the height of DISPLAY's screen in pixels.
1177 For character terminals, each character counts as a single pixel."
1178   (let ((frame-type (framep-on-display display)))
1179     (cond
1180      ((memq frame-type '(x w32 mac))
1181       (x-display-pixel-height display))
1182      (t
1183       (frame-height (if (framep display) display (selected-frame)))))))
1184
1185 (defun display-pixel-width (&optional display)
1186   "Return the width of DISPLAY's screen in pixels.
1187 For character terminals, each character counts as a single pixel."
1188   (let ((frame-type (framep-on-display display)))
1189     (cond
1190      ((memq frame-type '(x w32 mac))
1191       (x-display-pixel-width display))
1192      (t
1193       (frame-width (if (framep display) display (selected-frame)))))))
1194
1195 (defcustom display-mm-dimensions-alist nil
1196   "Alist for specifying screen dimensions in millimeters.
1197 The dimensions will be used for `display-mm-height' and
1198 `display-mm-width' if defined for the respective display.
1199
1200 Each element of the alist has the form (display . (width . height)),
1201 e.g. (\":0.0\" . (287 . 215)).
1202
1203 If `display' equals t, it specifies dimensions for all graphical
1204 displays not explicitely specified."
1205   :version "22.1"
1206   :type '(alist :key-type (choice (string :tag "Display name")
1207                                   (const :tag "Default" t))
1208                 :value-type (cons :tag "Dimensions"
1209                                   (integer :tag "Width")
1210                                   (integer :tag "Height")))
1211   :group 'frames)
1212
1213 (defun display-mm-height (&optional display)
1214   "Return the height of DISPLAY's screen in millimeters.
1215 System values can be overriden by `display-mm-dimensions-alist'.
1216 If the information is unavailable, value is nil."
1217   (and (memq (framep-on-display display) '(x w32 mac))
1218        (or (cddr (assoc (or display (frame-parameter nil 'display))
1219                         display-mm-dimensions-alist))
1220            (cddr (assoc t display-mm-dimensions-alist))
1221            (x-display-mm-height display))))
1222
1223 (defun display-mm-width (&optional display)
1224   "Return the width of DISPLAY's screen in millimeters.
1225 System values can be overriden by `display-mm-dimensions-alist'.
1226 If the information is unavailable, value is nil."
1227   (and (memq (framep-on-display display) '(x w32 mac))
1228        (or (cadr (assoc (or display (frame-parameter nil 'display))
1229                         display-mm-dimensions-alist))
1230            (cadr (assoc t display-mm-dimensions-alist))
1231            (x-display-mm-width display))))
1232
1233 (defun display-backing-store (&optional display)
1234   "Return the backing store capability of DISPLAY's screen.
1235 The value may be `always', `when-mapped', `not-useful', or nil if
1236 the question is inapplicable to a certain kind of display."
1237   (let ((frame-type (framep-on-display display)))
1238     (cond
1239      ((memq frame-type '(x w32 mac))
1240       (x-display-backing-store display))
1241      (t
1242       'not-useful))))
1243
1244 (defun display-save-under (&optional display)
1245   "Return non-nil if DISPLAY's screen supports the SaveUnder feature."
1246   (let ((frame-type (framep-on-display display)))
1247     (cond
1248      ((memq frame-type '(x w32 mac))
1249       (x-display-save-under display))
1250      (t
1251       'not-useful))))
1252
1253 (defun display-planes (&optional display)
1254   "Return the number of planes supported by DISPLAY."
1255   (let ((frame-type (framep-on-display display)))
1256     (cond
1257      ((memq frame-type '(x w32 mac))
1258       (x-display-planes display))
1259      ((eq frame-type 'pc)
1260       4)
1261      (t
1262       (truncate (log (length (tty-color-alist)) 2))))))
1263
1264 (defun display-color-cells (&optional display)
1265   "Return the number of color cells supported by DISPLAY."
1266   (let ((frame-type (framep-on-display display)))
1267     (cond
1268      ((memq frame-type '(x w32 mac))
1269       (x-display-color-cells display))
1270      ((eq frame-type 'pc)
1271       16)
1272      (t
1273       (tty-display-color-cells display)))))
1274
1275 (defun display-visual-class (&optional display)
1276   "Returns the visual class of DISPLAY.
1277 The value is one of the symbols `static-gray', `gray-scale',
1278 `static-color', `pseudo-color', `true-color', or `direct-color'."
1279   (let ((frame-type (framep-on-display display)))
1280     (cond
1281      ((memq frame-type '(x w32 mac))
1282       (x-display-visual-class display))
1283      ((and (memq frame-type '(pc t))
1284            (tty-display-color-p display))
1285       'static-color)
1286      (t
1287       'static-gray))))
1288
1289 \f
1290 ;;;; Aliases for backward compatibility with Emacs 18.
1291 (define-obsolete-function-alias 'screen-height 'frame-height) ;before 19.15
1292 (define-obsolete-function-alias 'screen-width 'frame-width) ;before 19.15
1293
1294 (defun set-screen-width (cols &optional pretend)
1295   "Change the size of the screen to COLS columns.
1296 Optional second arg non-nil means that redisplay should use COLS columns
1297 but that the idea of the actual width of the frame should not be changed.
1298 This function is provided only for compatibility with Emacs 18."
1299   (set-frame-width (selected-frame) cols pretend))
1300
1301 (defun set-screen-height (lines &optional pretend)
1302   "Change the height of the screen to LINES lines.
1303 Optional second arg non-nil means that redisplay should use LINES lines
1304 but that the idea of the actual height of the screen should not be changed.
1305 This function is provided only for compatibility with Emacs 18."
1306   (set-frame-height (selected-frame) lines pretend))
1307
1308 (defun delete-other-frames (&optional frame)
1309   "Delete all frames except FRAME.
1310 If FRAME uses another frame's minibuffer, the minibuffer frame is
1311 left untouched.  FRAME nil or omitted means use the selected frame."
1312   (interactive)
1313   (unless frame
1314     (setq frame (selected-frame)))
1315   (let* ((mini-frame (window-frame (minibuffer-window frame)))
1316          (frames (delq mini-frame (delq frame (frame-list)))))
1317     ;; Delete mon-minibuffer-only frames first, because `delete-frame'
1318     ;; signals an error when trying to delete a mini-frame that's
1319     ;; still in use by another frame.
1320     (dolist (frame frames)
1321       (unless (eq (frame-parameter frame 'minibuffer) 'only)
1322         (delete-frame frame)))
1323     ;; Delete minibuffer-only frames.
1324     (dolist (frame frames)
1325       (when (eq (frame-parameter frame 'minibuffer) 'only)
1326         (delete-frame frame)))))
1327
1328 (make-obsolete 'set-screen-width 'set-frame-width) ;before 19.15
1329 (make-obsolete 'set-screen-height 'set-frame-height) ;before 19.15
1330
1331 ;; miscellaneous obsolescence declarations
1332 (define-obsolete-variable-alias 'delete-frame-hook
1333     'delete-frame-functions "22.1")
1334
1335 \f
1336 ;; Highlighting trailing whitespace.
1337
1338 (make-variable-buffer-local 'show-trailing-whitespace)
1339
1340 (defcustom show-trailing-whitespace nil
1341   "*Non-nil means highlight trailing whitespace.
1342 This is done in the face `trailing-whitespace'."
1343   :type 'boolean
1344   :group 'whitespace-faces)
1345
1346
1347 \f
1348 ;; Scrolling
1349
1350 (defgroup scrolling nil
1351   "Scrolling windows."
1352   :version "21.1"
1353   :group 'frames)
1354
1355 (defcustom auto-hscroll-mode t
1356   "*Allow or disallow automatic scrolling windows horizontally.
1357 If non-nil, windows are automatically scrolled horizontally to make
1358 point visible."
1359   :version "21.1"
1360   :type 'boolean
1361   :group 'scrolling)
1362 (defvaralias 'automatic-hscrolling 'auto-hscroll-mode)
1363
1364 \f
1365 ;; Blinking cursor
1366
1367 (defgroup cursor nil
1368   "Displaying text cursors."
1369   :version "21.1"
1370   :group 'frames)
1371
1372 (defcustom blink-cursor-delay 0.5
1373   "*Seconds of idle time after which cursor starts to blink."
1374   :type 'number
1375   :group 'cursor)
1376
1377 (defcustom blink-cursor-interval 0.5
1378   "*Length of cursor blink interval in seconds."
1379   :type 'number
1380   :group 'cursor)
1381
1382 (defvar blink-cursor-idle-timer nil
1383   "Timer started after `blink-cursor-delay' seconds of Emacs idle time.
1384 The function `blink-cursor-start' is called when the timer fires.")
1385
1386 (defvar blink-cursor-timer nil
1387   "Timer started from `blink-cursor-start'.
1388 This timer calls `blink-cursor-timer-function' every
1389 `blink-cursor-interval' seconds.")
1390
1391 (defun blink-cursor-start ()
1392   "Timer function called from the timer `blink-cursor-idle-timer'.
1393 This starts the timer `blink-cursor-timer', which makes the cursor blink
1394 if appropriate.  It also arranges to cancel that timer when the next
1395 command starts, by installing a pre-command hook."
1396   (when (null blink-cursor-timer)
1397     ;; Set up the timer first, so that if this signals an error,
1398     ;; blink-cursor-end is not added to pre-command-hook.
1399     (setq blink-cursor-timer
1400           (run-with-timer blink-cursor-interval blink-cursor-interval
1401                           'blink-cursor-timer-function))
1402     (add-hook 'pre-command-hook 'blink-cursor-end)
1403     (internal-show-cursor nil nil)))
1404
1405 (defun blink-cursor-timer-function ()
1406   "Timer function of timer `blink-cursor-timer'."
1407   (internal-show-cursor nil (not (internal-show-cursor-p))))
1408
1409 (defun blink-cursor-end ()
1410   "Stop cursor blinking.
1411 This is installed as a pre-command hook by `blink-cursor-start'.
1412 When run, it cancels the timer `blink-cursor-timer' and removes
1413 itself as a pre-command hook."
1414   (remove-hook 'pre-command-hook 'blink-cursor-end)
1415   (internal-show-cursor nil t)
1416   (when blink-cursor-timer
1417     (cancel-timer blink-cursor-timer)
1418     (setq blink-cursor-timer nil)))
1419
1420 (define-minor-mode blink-cursor-mode
1421   "Toggle blinking cursor mode.
1422 With a numeric argument, turn blinking cursor mode on iff ARG is positive.
1423 When blinking cursor mode is enabled, the cursor of the selected
1424 window blinks.
1425
1426 Note that this command is effective only when Emacs
1427 displays through a window system, because then Emacs does its own
1428 cursor display.  On a text-only terminal, this is not implemented."
1429   :init-value (not (or noninteractive
1430                        no-blinking-cursor
1431                        (eq system-type 'ms-dos)
1432                        (not (memq window-system '(x w32 mac)))))
1433   :initialize 'custom-initialize-safe-default
1434   :group 'cursor
1435   :global t
1436   (if blink-cursor-idle-timer (cancel-timer blink-cursor-idle-timer))
1437   (setq blink-cursor-idle-timer nil)
1438   (blink-cursor-end)
1439   (when blink-cursor-mode
1440     ;; Hide the cursor.
1441     ;;(internal-show-cursor nil nil)
1442     (setq blink-cursor-idle-timer
1443           (run-with-idle-timer blink-cursor-delay
1444                                blink-cursor-delay
1445                                'blink-cursor-start))))
1446
1447 (define-obsolete-variable-alias 'blink-cursor 'blink-cursor-mode "22.1")
1448 \f
1449 ;; Hourglass pointer
1450
1451 (defcustom display-hourglass t
1452   "*Non-nil means show an hourglass pointer, when Emacs is busy.
1453 This feature only works when on a window system that can change
1454 cursor shapes."
1455   :type 'boolean
1456   :group 'cursor)
1457
1458 (defcustom hourglass-delay 1
1459   "*Seconds to wait before displaying an hourglass pointer when Emacs is busy."
1460   :type 'number
1461   :group 'cursor)
1462
1463 \f
1464 (defcustom cursor-in-non-selected-windows t
1465   "*Non-nil means show a hollow box cursor in non-selected windows.
1466 If nil, don't show a cursor except in the selected window.
1467 Use Custom to set this variable to get the display updated."
1468   :tag "Cursor In Non-selected Windows"
1469   :type 'boolean
1470   :group 'cursor
1471   :set #'(lambda (symbol value)
1472            (set-default symbol value)
1473            (force-mode-line-update t)))
1474
1475 \f
1476 ;;;; Key bindings
1477
1478 (define-key ctl-x-5-map "2" 'make-frame-command)
1479 (define-key ctl-x-5-map "1" 'delete-other-frames)
1480 (define-key ctl-x-5-map "0" 'delete-frame)
1481 (define-key ctl-x-5-map "o" 'other-frame)
1482
1483 (provide 'frame)
1484
1485 ;; arch-tag: 82979c70-b8f2-4306-b2ad-ddbd6b328b56
1486 ;;; frame.el ends here