lisp/url/url-http.el

   1 ;;; url-http.el --- HTTP retrieval routines
   2
   3 ;; Copyright (C) 1999, 2001, 2004, 2005, 2006, 2007  Free Software Foundation, Inc.
   4
   5 ;; Author: Bill Perry <wmperry@gnu.org>
   6 ;; Keywords: comm, data, processes
   7
   8 ;; This file is part of GNU Emacs.
   9 ;;
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30 (defvar url-http-extra-headers)
  31 (defvar url-http-target-url)
  32 (defvar url-http-proxy)
  33 (defvar url-http-connection-opened)
  34 (require 'url-gw)
  35 (require 'url-util)
  36 (require 'url-parse)
  37 (require 'url-cookie)
  38 (require 'mail-parse)
  39 (require 'url-auth)
  40 (require 'url)
  41 (autoload 'url-cache-create-filename "url-cache")
  42
  43 (defconst url-http-default-port 80 "Default HTTP port.")
  44 (defconst url-http-asynchronous-p t "HTTP retrievals are asynchronous.")
  45 (defalias 'url-http-expand-file-name 'url-default-expander)
  46
  47 (defvar url-http-real-basic-auth-storage nil)
  48 (defvar url-http-proxy-basic-auth-storage nil)
  49
  50 (defvar url-http-open-connections (make-hash-table :test 'equal
  51                                                    :size 17)
  52   "A hash table of all open network connections.")
  53
  54 (defvar url-http-version "1.1"
  55   "What version of HTTP we advertise, as a string.
  56 Valid values are 1.1 and 1.0.
  57 This is only useful when debugging the HTTP subsystem.
  58
  59 Setting this to 1.0 will tell servers not to send chunked encoding,
  60 and other HTTP/1.1 specific features.")
  61
  62 (defvar url-http-attempt-keepalives t
  63   "Whether to use a single TCP connection multiple times in HTTP.
  64 This is only useful when debugging the HTTP subsystem.  Setting to
  65 nil will explicitly close the connection to the server after every
  66 request.")
  67
  68 ;(eval-when-compile
  69 ;; These are all macros so that they are hidden from external sight
  70 ;; when the file is byte-compiled.
  71 ;;
  72 ;; This allows us to expose just the entry points we want.
  73
  74 ;; These routines will allow us to implement persistent HTTP
  75 ;; connections.
  76 (defsubst url-http-debug (&rest args)
  77   (if quit-flag
  78       (let ((proc (get-buffer-process (current-buffer))))
  79         ;; The user hit C-g, honor it!  Some things can get in an
  80         ;; incredibly tight loop (chunked encoding)
  81         (if proc
  82             (progn
  83               (set-process-sentinel proc nil)
  84               (set-process-filter proc nil)))
  85         (error "Transfer interrupted!")))
  86   (apply 'url-debug 'http args))
  87
  88 (defun url-http-mark-connection-as-busy (host port proc)
  89   (url-http-debug "Marking connection as busy: %s:%d %S" host port proc)
  90   (puthash (cons host port)
  91               (delq proc (gethash (cons host port) url-http-open-connections))
  92               url-http-open-connections)
  93   proc)
  94
  95 (defun url-http-mark-connection-as-free (host port proc)
  96   (url-http-debug "Marking connection as free: %s:%d %S" host port proc)
  97   (when (memq (process-status proc) '(open run connect))
  98     (set-process-buffer proc nil)
  99     (set-process-sentinel proc 'url-http-idle-sentinel)
 100     (puthash (cons host port)
 101              (cons proc (gethash (cons host port) url-http-open-connections))
 102              url-http-open-connections))
 103   nil)
 104
 105 (defun url-http-find-free-connection (host port)
 106   (let ((conns (gethash (cons host port) url-http-open-connections))
 107         (found nil))
 108     (while (and conns (not found))
 109       (if (not (memq (process-status (car conns)) '(run open connect)))
 110           (progn
 111             (url-http-debug "Cleaning up dead process: %s:%d %S"
 112                             host port (car conns))
 113             (url-http-idle-sentinel (car conns) nil))
 114         (setq found (car conns))
 115         (url-http-debug "Found existing connection: %s:%d %S" host port found))
 116       (pop conns))
 117     (if found
 118         (url-http-debug "Reusing existing connection: %s:%d" host port)
 119       (url-http-debug "Contacting host: %s:%d" host port))
 120     (url-lazy-message "Contacting host: %s:%d" host port)
 121     (url-http-mark-connection-as-busy
 122      host port
 123      (or found
 124          (let ((buf (generate-new-buffer " *url-http-temp*")))
 125            ;; `url-open-stream' needs a buffer in which to do things
 126            ;; like authentication.  But we use another buffer afterwards.
 127            (unwind-protect
 128                (let ((proc (url-open-stream host buf host port)))
 129                  ;; url-open-stream might return nil.
 130                  (when (processp proc)
 131                    ;; Drop the temp buffer link before killing the buffer.
 132                    (set-process-buffer proc nil))
 133                  proc)
 134              (kill-buffer buf)))))))
 135
 136 ;; Building an HTTP request
 137 (defun url-http-user-agent-string ()
 138   (if (or (eq url-privacy-level 'paranoid)
 139           (and (listp url-privacy-level)
 140                (memq 'agent url-privacy-level)))
 141       ""
 142     (format "User-Agent: %sURL/%s%s\r\n"
 143             (if url-package-name
 144                 (concat url-package-name "/" url-package-version " ")
 145               "")
 146             url-version
 147             (cond
 148              ((and url-os-type url-system-type)
 149               (concat " (" url-os-type "; " url-system-type ")"))
 150              ((or url-os-type url-system-type)
 151               (concat " (" (or url-system-type url-os-type) ")"))
 152              (t "")))))
 153
 154 (defun url-http-create-request (&optional ref-url)
 155   "Create an HTTP request for `url-http-target-url', referred to by REF-URL."
 156   (declare (special proxy-info
 157                     url-http-method url-http-data
 158                     url-http-extra-headers))
 159   (let* ((extra-headers)
 160          (request nil)
 161          (no-cache (cdr-safe (assoc "Pragma" url-http-extra-headers)))
 162          (using-proxy url-http-proxy)
 163          (proxy-auth (if (or (cdr-safe (assoc "Proxy-Authorization"
 164                                               url-http-extra-headers))
 165                              (not using-proxy))
 166                          nil
 167                        (let ((url-basic-auth-storage
 168                               'url-http-proxy-basic-auth-storage))
 169                          (url-get-authentication url-http-target-url nil 'any nil))))
 170          (real-fname (concat (url-filename url-http-target-url)
 171                              (url-recreate-url-attributes url-http-target-url)))
 172          (host (url-host url-http-target-url))
 173          (auth (if (cdr-safe (assoc "Authorization" url-http-extra-headers))
 174                    nil
 175                  (url-get-authentication (or
 176                                           (and (boundp 'proxy-info)
 177                                                proxy-info)
 178                                           url-http-target-url) nil 'any nil))))
 179     (if (equal "" real-fname)
 180         (setq real-fname "/"))
 181     (setq no-cache (and no-cache (string-match "no-cache" no-cache)))
 182     (if auth
 183         (setq auth (concat "Authorization: " auth "\r\n")))
 184     (if proxy-auth
 185         (setq proxy-auth (concat "Proxy-Authorization: " proxy-auth "\r\n")))
 186
 187     ;; Protection against stupid values in the referer
 188     (if (and ref-url (stringp ref-url) (or (string= ref-url "file:nil")
 189                                            (string= ref-url "")))
 190         (setq ref-url nil))
 191
 192     ;; We do not want to expose the referer if the user is paranoid.
 193     (if (or (memq url-privacy-level '(low high paranoid))
 194             (and (listp url-privacy-level)
 195                  (memq 'lastloc url-privacy-level)))
 196         (setq ref-url nil))
 197
 198     ;; url-http-extra-headers contains an assoc-list of
 199     ;; header/value pairs that we need to put into the request.
 200     (setq extra-headers (mapconcat
 201                          (lambda (x)
 202                            (concat (car x) ": " (cdr x)))
 203                          url-http-extra-headers "\r\n"))
 204     (if (not (equal extra-headers ""))
 205         (setq extra-headers (concat extra-headers "\r\n")))
 206
 207     ;; This was done with a call to `format'.  Concatting parts has
 208     ;; the advantage of keeping the parts of each header together and
 209     ;; allows us to elide null lines directly, at the cost of making
 210     ;; the layout less clear.
 211     (setq request
 212           ;; We used to concat directly, but if one of the strings happens
 213           ;; to being multibyte (even if it only contains pure ASCII) then
 214           ;; every string gets converted with `string-MAKE-multibyte' which
 215           ;; turns the 127-255 codes into things like latin-1 accented chars
 216           ;; (it would work right if it used `string-TO-multibyte' instead).
 217           ;; So to avoid the problem we force every string to be unibyte.
 218           (mapconcat
 219            ;; FIXME: Instead of `string-AS-unibyte' we'd want
 220            ;; `string-to-unibyte', so as to properly signal an error if one
 221            ;; of the strings contains a multibyte char.
 222            'string-as-unibyte
 223            (delq nil
 224             (list
 225              ;; The request
 226              (or url-http-method "GET") " "
 227              (if using-proxy (url-recreate-url url-http-target-url) real-fname)
 228              " HTTP/" url-http-version "\r\n"
 229              ;; Version of MIME we speak
 230              "MIME-Version: 1.0\r\n"
 231              ;; (maybe) Try to keep the connection open
 232              "Connection: " (if (or using-proxy
 233                                     (not url-http-attempt-keepalives))
 234                                 "close" "keep-alive") "\r\n"
 235                                 ;; HTTP extensions we support
 236              (if url-extensions-header
 237                  (format
 238                   "Extension: %s\r\n" url-extensions-header))
 239              ;; Who we want to talk to
 240              (if (/= (url-port url-http-target-url)
 241                      (url-scheme-get-property
 242                       (url-type url-http-target-url) 'default-port))
 243                  (format
 244                   "Host: %s:%d\r\n" host (url-port url-http-target-url))
 245                (format "Host: %s\r\n" host))
 246              ;; Who its from
 247              (if url-personal-mail-address
 248                  (concat
 249                   "From: " url-personal-mail-address "\r\n"))
 250              ;; Encodings we understand
 251              (if url-mime-encoding-string
 252                  (concat
 253                   "Accept-encoding: " url-mime-encoding-string "\r\n"))
 254              (if url-mime-charset-string
 255                  (concat
 256                   "Accept-charset: " url-mime-charset-string "\r\n"))
 257              ;; Languages we understand
 258              (if url-mime-language-string
 259                  (concat
 260                   "Accept-language: " url-mime-language-string "\r\n"))
 261              ;; Types we understand
 262              "Accept: " (or url-mime-accept-string "*/*") "\r\n"
 263              ;; User agent
 264              (url-http-user-agent-string)
 265              ;; Proxy Authorization
 266              proxy-auth
 267              ;; Authorization
 268              auth
 269              ;; Cookies
 270              (url-cookie-generate-header-lines host real-fname
 271                                                (equal "https" (url-type url-http-target-url)))
 272              ;; If-modified-since
 273              (if (and (not no-cache)
 274                       (member url-http-method '("GET" nil)))
 275                  (let ((tm (url-is-cached url-http-target-url)))
 276                    (if tm
 277                        (concat "If-modified-since: "
 278                                (url-get-normalized-date tm) "\r\n"))))
 279              ;; Whence we came
 280              (if ref-url (concat
 281                           "Referer: " ref-url "\r\n"))
 282              extra-headers
 283              ;; Length of data
 284              (if url-http-data
 285                  (concat
 286                   "Content-length: " (number-to-string
 287                                       (length url-http-data))
 288                   "\r\n"))
 289              ;; End request
 290              "\r\n"
 291              ;; Any data
 292              url-http-data))
 293            ""))
 294     (url-http-debug "Request is: \n%s" request)
 295     request))
 296
 297 ;; Parsing routines
 298 (defun url-http-clean-headers ()
 299   "Remove trailing \r from header lines.
 300 This allows us to use `mail-fetch-field', etc."
 301   (declare (special url-http-end-of-headers))
 302   (goto-char (point-min))
 303   (while (re-search-forward "\r$" url-http-end-of-headers t)
 304     (replace-match "")))
 305
 306 (defun url-http-handle-authentication (proxy)
 307   (declare (special status success url-http-method url-http-data
 308                     url-callback-function url-callback-arguments))
 309   (url-http-debug "Handling %s authentication" (if proxy "proxy" "normal"))
 310   (let ((auths (or (nreverse
 311                     (mail-fetch-field
 312                      (if proxy "proxy-authenticate" "www-authenticate")
 313                      nil nil t))
 314                   '("basic")))
 315         (type nil)
 316         (url (url-recreate-url url-current-object))
 317         (url-basic-auth-storage 'url-http-real-basic-auth-storage)
 318         auth
 319         (strength 0))
 320     ;; Cheating, but who cares? :)
 321     (if proxy
 322         (setq url-basic-auth-storage 'url-http-proxy-basic-auth-storage))
 323
 324     ;; find strongest supported auth
 325     (dolist (this-auth auths)
 326       (setq this-auth (url-eat-trailing-space
 327                        (url-strip-leading-spaces
 328                         this-auth)))
 329       (let* ((this-type
 330               (if (string-match "[ \t]" this-auth)
 331                   (downcase (substring this-auth 0 (match-beginning 0)))
 332                 (downcase this-auth)))
 333              (registered (url-auth-registered this-type))
 334              (this-strength (cddr registered)))
 335         (when (and registered (> this-strength strength))
 336           (setq auth this-auth
 337                 type this-type
 338                 strength this-strength))))
 339
 340     (if (not (url-auth-registered type))
 341         (progn
 342           (widen)
 343           (goto-char (point-max))
 344           (insert "<hr>Sorry, but I do not know how to handle " type
 345                   " authentication.  If you'd like to write it,"
 346                   " send it to " url-bug-address ".<hr>")
 347           (setq status t))
 348       (let* ((args (url-parse-args (subst-char-in-string ?, ?\; auth)))
 349              (auth (url-get-authentication url (cdr-safe (assoc "realm" args))
 350                                            type t args)))
 351         (if (not auth)
 352             (setq success t)
 353           (push (cons (if proxy "Proxy-Authorization" "Authorization") auth)
 354                 url-http-extra-headers)
 355           (let ((url-request-method url-http-method)
 356                 (url-request-data url-http-data)
 357                 (url-request-extra-headers url-http-extra-headers))
 358             (url-retrieve-internal url url-callback-function
 359                                    url-callback-arguments)))))))
 360
 361 (defun url-http-parse-response ()
 362   "Parse just the response code."
 363   (declare (special url-http-end-of-headers url-http-response-status
 364                     url-http-response-version))
 365   (if (not url-http-end-of-headers)
 366       (error "Trying to parse HTTP response code in odd buffer: %s" (buffer-name)))
 367   (url-http-debug "url-http-parse-response called in (%s)" (buffer-name))
 368   (goto-char (point-min))
 369   (skip-chars-forward " \t\n")          ; Skip any blank crap
 370   (skip-chars-forward "HTTP/")          ; Skip HTTP Version
 371   (setq url-http-response-version
 372         (buffer-substring (point)
 373                           (progn
 374                             (skip-chars-forward "[0-9].")
 375                             (point))))
 376   (setq url-http-response-status (read (current-buffer))))
 377
 378 (defun url-http-handle-cookies ()
 379   "Handle all set-cookie / set-cookie2 headers in an HTTP response.
 380 The buffer must already be narrowed to the headers, so `mail-fetch-field' will
 381 work correctly."
 382   (let ((cookies (mail-fetch-field "Set-Cookie" nil nil t))
 383         (cookies2 (mail-fetch-field "Set-Cookie2" nil nil t)))
 384     (and cookies (url-http-debug "Found %d Set-Cookie headers" (length cookies)))
 385     (and cookies2 (url-http-debug "Found %d Set-Cookie2 headers" (length cookies2)))
 386     (while cookies
 387       (url-cookie-handle-set-cookie (pop cookies)))
 388 ;;;     (while cookies2
 389 ;;;       (url-cookie-handle-set-cookie2 (pop cookies)))
 390     )
 391   )
 392
 393 (defun url-http-parse-headers ()
 394  "Parse and handle HTTP specific headers.
 395 Return t if and only if the current buffer is still active and
 396 should be shown to the user."
 397   ;; The comments after each status code handled are taken from RFC
 398   ;; 2616 (HTTP/1.1)
 399   (declare (special url-http-end-of-headers url-http-response-status
 400                     url-http-response-version
 401                     url-http-method url-http-data url-http-process
 402                     url-callback-function url-callback-arguments))
 403
 404   (url-http-mark-connection-as-free (url-host url-current-object)
 405                                     (url-port url-current-object)
 406                                     url-http-process)
 407
 408   (if (or (not (boundp 'url-http-end-of-headers))
 409           (not url-http-end-of-headers))
 410       (error "Trying to parse headers in odd buffer: %s" (buffer-name)))
 411   (goto-char (point-min))
 412   (url-http-debug "url-http-parse-headers called in (%s)" (buffer-name))
 413   (url-http-parse-response)
 414   (mail-narrow-to-head)
 415   ;;(narrow-to-region (point-min) url-http-end-of-headers)
 416   (let ((connection (mail-fetch-field "Connection")))
 417     ;; In HTTP 1.0, keep the connection only if there is a
 418     ;; "Connection: keep-alive" header.
 419     ;; In HTTP 1.1 (and greater), keep the connection unless there is a
 420     ;; "Connection: close" header
 421     (cond
 422      ((string= url-http-response-version "1.0")
 423       (unless (and connection
 424                    (string= (downcase connection) "keep-alive"))
 425         (delete-process url-http-process)))
 426      (t
 427       (when (and connection
 428                  (string= (downcase connection) "close"))
 429         (delete-process url-http-process)))))
 430   (let ((class nil)
 431         (success nil))
 432     (setq class (/ url-http-response-status 100))
 433     (url-http-debug "Parsed HTTP headers: class=%d status=%d" class url-http-response-status)
 434     (url-http-handle-cookies)
 435
 436     (case class
 437       ;; Classes of response codes
 438       ;;
 439       ;; 5xx = Server Error
 440       ;; 4xx = Client Error
 441       ;; 3xx = Redirection
 442       ;; 2xx = Successful
 443       ;; 1xx = Informational
 444       (1                                ; Information messages
 445        ;; 100 = Continue with request
 446        ;; 101 = Switching protocols
 447        ;; 102 = Processing (Added by DAV)
 448        (url-mark-buffer-as-dead (current-buffer))
 449        (error "HTTP responses in class 1xx not supported (%d)" url-http-response-status))
 450       (2                                ; Success
 451        ;; 200 Ok
 452        ;; 201 Created
 453        ;; 202 Accepted
 454        ;; 203 Non-authoritative information
 455        ;; 204 No content
 456        ;; 205 Reset content
 457        ;; 206 Partial content
 458        ;; 207 Multi-status (Added by DAV)
 459        (case url-http-response-status
 460          ((204 205)
 461           ;; No new data, just stay at the same document
 462           (url-mark-buffer-as-dead (current-buffer))
 463           (setq success t))
 464          (otherwise
 465           ;; Generic success for all others.  Store in the cache, and
 466           ;; mark it as successful.
 467           (widen)
 468           (if (and url-automatic-caching (equal url-http-method "GET"))
 469               (url-store-in-cache (current-buffer)))
 470           (setq success t))))
 471       (3                                ; Redirection
 472        ;; 300 Multiple choices
 473        ;; 301 Moved permanently
 474        ;; 302 Found
 475        ;; 303 See other
 476        ;; 304 Not modified
 477        ;; 305 Use proxy
 478        ;; 307 Temporary redirect
 479        (let ((redirect-uri (or (mail-fetch-field "Location")
 480                                (mail-fetch-field "URI"))))
 481          (case url-http-response-status
 482            (300
 483             ;; Quoth the spec (section 10.3.1)
 484             ;; -------------------------------
 485             ;; The requested resource corresponds to any one of a set of
 486             ;; representations, each with its own specific location and
 487             ;; agent-driven negotiation information is being provided so
 488             ;; that the user can select a preferred representation and
 489             ;; redirect its request to that location.
 490             ;; [...]
 491             ;; If the server has a preferred choice of representation, it
 492             ;; SHOULD include the specific URI for that representation in
 493             ;; the Location field; user agents MAY use the Location field
 494             ;; value for automatic redirection.
 495             ;; -------------------------------
 496             ;; We do not support agent-driven negotiation, so we just
 497             ;; redirect to the preferred URI if one is provided.
 498             nil)
 499            ((301 302 307)
 500             ;; If the 301|302 status code is received in response to a
 501             ;; request other than GET or HEAD, the user agent MUST NOT
 502             ;; automatically redirect the request unless it can be
 503             ;; confirmed by the user, since this might change the
 504             ;; conditions under which the request was issued.
 505             (if (member url-http-method '("HEAD" "GET"))
 506                 ;; Automatic redirection is ok
 507                 nil
 508               ;; It is just too big of a pain in the ass to get this
 509               ;; prompt all the time.  We will just silently lose our
 510               ;; data and convert to a GET method.
 511               (url-http-debug "Converting `%s' request to `GET' because of REDIRECT(%d)"
 512                               url-http-method url-http-response-status)
 513               (setq url-http-method "GET"
 514                     url-http-data nil)))
 515            (303
 516             ;; The response to the request can be found under a different
 517             ;; URI and SHOULD be retrieved using a GET method on that
 518             ;; resource.
 519             (setq url-http-method "GET"
 520                   url-http-data nil))
 521            (304
 522             ;; The 304 response MUST NOT contain a message-body.
 523             (url-http-debug "Extracting document from cache... (%s)"
 524                             (url-cache-create-filename (url-view-url t)))
 525             (url-cache-extract (url-cache-create-filename (url-view-url t)))
 526             (setq redirect-uri nil
 527                   success t))
 528            (305
 529             ;; The requested resource MUST be accessed through the
 530             ;; proxy given by the Location field.  The Location field
 531             ;; gives the URI of the proxy.  The recipient is expected
 532             ;; to repeat this single request via the proxy.  305
 533             ;; responses MUST only be generated by origin servers.
 534             (error "Redirection thru a proxy server not supported: %s"
 535                    redirect-uri))
 536            (otherwise
 537             ;; Treat everything like '300'
 538             nil))
 539          (when redirect-uri
 540            ;; Clean off any whitespace and/or <...> cruft.
 541            (if (string-match "\\([^ \t]+\\)[ \t]" redirect-uri)
 542                (setq redirect-uri (match-string 1 redirect-uri)))
 543            (if (string-match "^<\\(.*\\)>$" redirect-uri)
 544                (setq redirect-uri (match-string 1 redirect-uri)))
 545
 546            ;; Some stupid sites (like sourceforge) send a
 547            ;; non-fully-qualified URL (ie: /), which royally confuses
 548            ;; the URL library.
 549            (if (not (string-match url-nonrelative-link redirect-uri))
 550                ;; Be careful to use the real target URL, otherwise we may
 551                ;; compute the redirection relative to the URL of the proxy.
 552                (setq redirect-uri
 553                      (url-expand-file-name redirect-uri url-http-target-url)))
 554            (let ((url-request-method url-http-method)
 555                  (url-request-data url-http-data)
 556                  (url-request-extra-headers url-http-extra-headers))
 557              ;; Remember that the request was redirected.
 558              (setf (car url-callback-arguments)
 559                    (nconc (list :redirect redirect-uri)
 560                           (car url-callback-arguments)))
 561               ;; Put in the current buffer a forwarding pointer to the new
 562               ;; destination buffer.
 563               ;; FIXME: This is a hack to fix url-retrieve-synchronously
 564               ;; without changing the API.  Instead url-retrieve should
 565               ;; either simply not return the "destination" buffer, or it
 566               ;; should take an optional `dest-buf' argument.
 567               (set (make-local-variable 'url-redirect-buffer)
 568                    (url-retrieve-internal
 569                     redirect-uri url-callback-function
 570                     url-callback-arguments))
 571               (url-mark-buffer-as-dead (current-buffer))))))
 572       (4                                ; Client error
 573        ;; 400 Bad Request
 574        ;; 401 Unauthorized
 575        ;; 402 Payment required
 576        ;; 403 Forbidden
 577        ;; 404 Not found
 578        ;; 405 Method not allowed
 579        ;; 406 Not acceptable
 580        ;; 407 Proxy authentication required
 581        ;; 408 Request time-out
 582        ;; 409 Conflict
 583        ;; 410 Gone
 584        ;; 411 Length required
 585        ;; 412 Precondition failed
 586        ;; 413 Request entity too large
 587        ;; 414 Request-URI too large
 588        ;; 415 Unsupported media type
 589        ;; 416 Requested range not satisfiable
 590        ;; 417 Expectation failed
 591        ;; 422 Unprocessable Entity (Added by DAV)
 592        ;; 423 Locked
 593        ;; 424 Failed Dependency
 594        (case url-http-response-status
 595          (401
 596           ;; The request requires user authentication.  The response
 597           ;; MUST include a WWW-Authenticate header field containing a
 598           ;; challenge applicable to the requested resource.  The
 599           ;; client MAY repeat the request with a suitable
 600           ;; Authorization header field.
 601           (url-http-handle-authentication nil))
 602          (402
 603           ;; This code is reserved for future use
 604           (url-mark-buffer-as-dead (current-buffer))
 605           (error "Somebody wants you to give them money"))
 606          (403
 607           ;; The server understood the request, but is refusing to
 608           ;; fulfill it.  Authorization will not help and the request
 609           ;; SHOULD NOT be repeated.
 610           (setq success t))
 611          (404
 612           ;; Not found
 613           (setq success t))
 614          (405
 615           ;; The method specified in the Request-Line is not allowed
 616           ;; for the resource identified by the Request-URI.  The
 617           ;; response MUST include an Allow header containing a list of
 618           ;; valid methods for the requested resource.
 619           (setq success t))
 620          (406
 621           ;; The resource identified by the request is only capable of
 622           ;; generating response entities which have content
 623           ;; characteristics nota cceptable according to the accept
 624           ;; headers sent in the request.
 625           (setq success t))
 626          (407
 627           ;; This code is similar to 401 (Unauthorized), but indicates
 628           ;; that the client must first authenticate itself with the
 629           ;; proxy.  The proxy MUST return a Proxy-Authenticate header
 630           ;; field containing a challenge applicable to the proxy for
 631           ;; the requested resource.
 632           (url-http-handle-authentication t))
 633          (408
 634           ;; The client did not produce a request within the time that
 635           ;; the server was prepared to wait.  The client MAY repeat
 636           ;; the request without modifications at any later time.
 637           (setq success t))
 638          (409
 639           ;; The request could not be completed due to a conflict with
 640           ;; the current state of the resource.  This code is only
 641           ;; allowed in situations where it is expected that the user
 642           ;; mioght be able to resolve the conflict and resubmit the
 643           ;; request.  The response body SHOULD include enough
 644           ;; information for the user to recognize the source of the
 645           ;; conflict.
 646           (setq success t))
 647          (410
 648           ;; The requested resource is no longer available at the
 649           ;; server and no forwarding address is known.
 650           (setq success t))
 651          (411
 652           ;; The server refuses to accept the request without a defined
 653           ;; Content-Length.  The client MAY repeat the request if it
 654           ;; adds a valid Content-Length header field containing the
 655           ;; length of the message-body in the request message.
 656           ;;
 657           ;; NOTE - this will never happen because
 658           ;; `url-http-create-request' automatically calculates the
 659           ;; content-length.
 660           (setq success t))
 661          (412
 662           ;; The precondition given in one or more of the
 663           ;; request-header fields evaluated to false when it was
 664           ;; tested on the server.
 665           (setq success t))
 666          ((413 414)
 667           ;; The server is refusing to process a request because the
 668           ;; request entity|URI is larger than the server is willing or
 669           ;; able to process.
 670           (setq success t))
 671          (415
 672           ;; The server is refusing to service the request because the
 673           ;; entity of the request is in a format not supported by the
 674           ;; requested resource for the requested method.
 675           (setq success t))
 676          (416
 677           ;; A server SHOULD return a response with this status code if
 678           ;; a request included a Range request-header field, and none
 679           ;; of the range-specifier values in this field overlap the
 680           ;; current extent of the selected resource, and the request
 681           ;; did not include an If-Range request-header field.
 682           (setq success t))
 683          (417
 684           ;; The expectation given in an Expect request-header field
 685           ;; could not be met by this server, or, if the server is a
 686           ;; proxy, the server has unambiguous evidence that the
 687           ;; request could not be met by the next-hop server.
 688           (setq success t))
 689          (otherwise
 690           ;; The request could not be understood by the server due to
 691           ;; malformed syntax.  The client SHOULD NOT repeat the
 692           ;; request without modifications.
 693           (setq success t)))
 694        ;; Tell the callback that an error occurred, and what the
 695        ;; status code was.
 696        (when success
 697          (setf (car url-callback-arguments)
 698                (nconc (list :error (list 'error 'http url-http-response-status))
 699                       (car url-callback-arguments)))))
 700       (5
 701        ;; 500 Internal server error
 702        ;; 501 Not implemented
 703        ;; 502 Bad gateway
 704        ;; 503 Service unavailable
 705        ;; 504 Gateway time-out
 706        ;; 505 HTTP version not supported
 707        ;; 507 Insufficient storage
 708        (setq success t)
 709        (case url-http-response-status
 710          (501
 711           ;; The server does not support the functionality required to
 712           ;; fulfill the request.
 713           nil)
 714          (502
 715           ;; The server, while acting as a gateway or proxy, received
 716           ;; an invalid response from the upstream server it accessed
 717           ;; in attempting to fulfill the request.
 718           nil)
 719          (503
 720           ;; The server is currently unable to handle the request due
 721           ;; to a temporary overloading or maintenance of the server.
 722           ;; The implication is that this is a temporary condition
 723           ;; which will be alleviated after some delay.  If known, the
 724           ;; length of the delay MAY be indicated in a Retry-After
 725           ;; header.  If no Retry-After is given, the client SHOULD
 726           ;; handle the response as it would for a 500 response.
 727           nil)
 728          (504
 729           ;; The server, while acting as a gateway or proxy, did not
 730           ;; receive a timely response from the upstream server
 731           ;; specified by the URI (e.g. HTTP, FTP, LDAP) or some other
 732           ;; auxiliary server (e.g. DNS) it needed to access in
 733           ;; attempting to complete the request.
 734           nil)
 735          (505
 736           ;; The server does not support, or refuses to support, the
 737           ;; HTTP protocol version that was used in the request
 738           ;; message.
 739           nil)
 740          (507                           ; DAV
 741           ;; The method could not be performed on the resource
 742           ;; because the server is unable to store the representation
 743           ;; needed to successfully complete the request.  This
 744           ;; condition is considered to be temporary.  If the request
 745           ;; which received this status code was the result of a user
 746           ;; action, the request MUST NOT be repeated until it is
 747           ;; requested by a separate user action.
 748           nil))
 749        ;; Tell the callback that an error occurred, and what the
 750        ;; status code was.
 751        (when success
 752          (setf (car url-callback-arguments)
 753                (nconc (list :error (list 'error 'http url-http-response-status))
 754                       (car url-callback-arguments)))))
 755       (otherwise
 756        (error "Unknown class of HTTP response code: %d (%d)"
 757               class url-http-response-status)))
 758     (if (not success)
 759         (url-mark-buffer-as-dead (current-buffer)))
 760     (url-http-debug "Finished parsing HTTP headers: %S" success)
 761     (widen)
 762     success))
 763
 764 ;; Miscellaneous
 765 (defun url-http-activate-callback ()
 766   "Activate callback specified when this buffer was created."
 767   (declare (special url-http-process
 768                     url-callback-function
 769                     url-callback-arguments))
 770   (url-http-mark-connection-as-free (url-host url-current-object)
 771                                     (url-port url-current-object)
 772                                     url-http-process)
 773   (url-http-debug "Activating callback in buffer (%s)" (buffer-name))
 774   (apply url-callback-function url-callback-arguments))
 775
 776 ;; )
 777
 778 ;; These unfortunately cannot be macros... please ignore them!
 779 (defun url-http-idle-sentinel (proc why)
 780   "Remove this (now defunct) process PROC from the list of open connections."
 781   (maphash (lambda (key val)
 782                 (if (memq proc val)
 783                     (puthash key (delq proc val) url-http-open-connections)))
 784               url-http-open-connections))
 785
 786 (defun url-http-end-of-document-sentinel (proc why)
 787   ;; Sentinel used for old HTTP/0.9 or connections we know are going
 788   ;; to die as the 'end of document' notifier.
 789   (url-http-debug "url-http-end-of-document-sentinel in buffer (%s)"
 790                   (process-buffer proc))
 791   (url-http-idle-sentinel proc why)
 792   (with-current-buffer (process-buffer proc)
 793     (goto-char (point-min))
 794     (if (not (looking-at "HTTP/"))
 795         ;; HTTP/0.9 just gets passed back no matter what
 796         (url-http-activate-callback)
 797       (if (url-http-parse-headers)
 798           (url-http-activate-callback)))))
 799
 800 (defun url-http-simple-after-change-function (st nd length)
 801   ;; Function used when we do NOT know how long the document is going to be
 802   ;; Just _very_ simple 'downloaded %d' type of info.
 803   (declare (special url-http-end-of-headers))
 804   (url-lazy-message "Reading %s..." (url-pretty-length nd)))
 805
 806 (defun url-http-content-length-after-change-function (st nd length)
 807   "Function used when we DO know how long the document is going to be.
 808 More sophisticated percentage downloaded, etc.
 809 Also does minimal parsing of HTTP headers and will actually cause
 810 the callback to be triggered."
 811   (declare (special url-current-object
 812                     url-http-end-of-headers
 813                     url-http-content-length
 814                     url-http-content-type
 815                     url-http-process))
 816   (if url-http-content-type
 817       (url-display-percentage
 818        "Reading [%s]... %s of %s (%d%%)"
 819        (url-percentage (- nd url-http-end-of-headers)
 820                        url-http-content-length)
 821        url-http-content-type
 822        (url-pretty-length (- nd url-http-end-of-headers))
 823        (url-pretty-length url-http-content-length)
 824        (url-percentage (- nd url-http-end-of-headers)
 825                        url-http-content-length))
 826     (url-display-percentage
 827      "Reading... %s of %s (%d%%)"
 828      (url-percentage (- nd url-http-end-of-headers)
 829                      url-http-content-length)
 830      (url-pretty-length (- nd url-http-end-of-headers))
 831      (url-pretty-length url-http-content-length)
 832      (url-percentage (- nd url-http-end-of-headers)
 833                      url-http-content-length)))
 834
 835   (if (> (- nd url-http-end-of-headers) url-http-content-length)
 836       (progn
 837         ;; Found the end of the document!  Wheee!
 838         (url-display-percentage nil nil)
 839         (url-lazy-message "Reading... done.")
 840         (if (url-http-parse-headers)
 841             (url-http-activate-callback)))))
 842
 843 (defun url-http-chunked-encoding-after-change-function (st nd length)
 844   "Function used when dealing with 'chunked' encoding.
 845 Cannot give a sophisticated percentage, but we need a different
 846 function to look for the special 0-length chunk that signifies
 847 the end of the document."
 848   (declare (special url-current-object
 849                     url-http-end-of-headers
 850                     url-http-content-type
 851                     url-http-chunked-length
 852                     url-http-chunked-counter
 853                     url-http-process url-http-chunked-start))
 854   (save-excursion
 855     (goto-char st)
 856     (let ((read-next-chunk t)
 857           (case-fold-search t)
 858           (regexp nil)
 859           (no-initial-crlf nil))
 860       ;; We need to loop thru looking for more chunks even within
 861       ;; one after-change-function call.
 862       (while read-next-chunk
 863         (setq no-initial-crlf (= 0 url-http-chunked-counter))
 864         (if url-http-content-type
 865             (url-display-percentage nil
 866              "Reading [%s]... chunk #%d"
 867              url-http-content-type url-http-chunked-counter)
 868           (url-display-percentage nil
 869            "Reading... chunk #%d"
 870            url-http-chunked-counter))
 871         (url-http-debug "Reading chunk %d (%d %d %d)"
 872                         url-http-chunked-counter st nd length)
 873         (setq regexp (if no-initial-crlf
 874                          "\\([0-9a-z]+\\).*\r?\n"
 875                        "\r?\n\\([0-9a-z]+\\).*\r?\n"))
 876
 877         (if url-http-chunked-start
 878             ;; We know how long the chunk is supposed to be, skip over
 879             ;; leading crap if possible.
 880             (if (> nd (+ url-http-chunked-start url-http-chunked-length))
 881                 (progn
 882                   (url-http-debug "Got to the end of chunk #%d!"
 883                                   url-http-chunked-counter)
 884                   (goto-char (+ url-http-chunked-start
 885                                 url-http-chunked-length)))
 886               (url-http-debug "Still need %d bytes to hit end of chunk"
 887                               (- (+ url-http-chunked-start
 888                                     url-http-chunked-length)
 889                                  nd))
 890               (setq read-next-chunk nil)))
 891         (if (not read-next-chunk)
 892             (url-http-debug "Still spinning for next chunk...")
 893           (if no-initial-crlf (skip-chars-forward "\r\n"))
 894           (if (not (looking-at regexp))
 895               (progn
 896            ;; Must not have received the entirety of the chunk header,
 897                 ;; need to spin some more.
 898                 (url-http-debug "Did not see start of chunk @ %d!" (point))
 899                 (setq read-next-chunk nil))
 900             (add-text-properties (match-beginning 0) (match-end 0)
 901                                  (list 'start-open t
 902                                        'end-open t
 903                                        'chunked-encoding t
 904                                        'face 'cursor
 905                                        'invisible t))
 906             (setq url-http-chunked-length (string-to-number (buffer-substring
 907                                                              (match-beginning 1)
 908                                                              (match-end 1))
 909                                                             16)
 910                   url-http-chunked-counter (1+ url-http-chunked-counter)
 911                   url-http-chunked-start (set-marker
 912                                           (or url-http-chunked-start
 913                                               (make-marker))
 914                                           (match-end 0)))
 915 ;           (if (not url-http-debug)
 916                 (delete-region (match-beginning 0) (match-end 0));)
 917             (url-http-debug "Saw start of chunk %d (length=%d, start=%d"
 918                             url-http-chunked-counter url-http-chunked-length
 919                             (marker-position url-http-chunked-start))
 920             (if (= 0 url-http-chunked-length)
 921                 (progn
 922                   ;; Found the end of the document!  Wheee!
 923                   (url-http-debug "Saw end of stream chunk!")
 924                   (setq read-next-chunk nil)
 925                   (url-display-percentage nil nil)
 926                   (goto-char (match-end 1))
 927                   (if (re-search-forward "^\r*$" nil t)
 928                       (url-http-debug "Saw end of trailers..."))
 929                   (if (url-http-parse-headers)
 930                       (url-http-activate-callback))))))))))
 931
 932 (defun url-http-wait-for-headers-change-function (st nd length)
 933   ;; This will wait for the headers to arrive and then splice in the
 934   ;; next appropriate after-change-function, etc.
 935   (declare (special url-current-object
 936                     url-http-end-of-headers
 937                     url-http-content-type
 938                     url-http-content-length
 939                     url-http-transfer-encoding
 940                     url-callback-function
 941                     url-callback-arguments
 942                     url-http-process
 943                     url-http-method
 944                     url-http-after-change-function
 945                     url-http-response-status))
 946   (url-http-debug "url-http-wait-for-headers-change-function (%s)"
 947                   (buffer-name))
 948   (when (not (bobp))
 949     (let ((end-of-headers nil)
 950           (old-http nil)
 951           (content-length nil))
 952       (goto-char (point-min))
 953       (if (and (looking-at ".*\n")      ; have one line at least
 954                (not (looking-at "^HTTP/[1-9]\\.[0-9]")))
 955           ;; Not HTTP/x.y data, must be 0.9
 956           ;; God, I wish this could die.
 957           (setq end-of-headers t
 958                 url-http-end-of-headers 0
 959                 old-http t)
 960         (when (re-search-forward "^\r*$" nil t)
 961           ;; Saw the end of the headers
 962           (url-http-debug "Saw end of headers... (%s)" (buffer-name))
 963           (setq url-http-end-of-headers (set-marker (make-marker)
 964                                                     (point))
 965                 end-of-headers t)
 966           (url-http-clean-headers)))
 967
 968       (if (not end-of-headers)
 969           ;; Haven't seen the end of the headers yet, need to wait
 970           ;; for more data to arrive.
 971           nil
 972         (if old-http
 973             (message "HTTP/0.9 How I hate thee!")
 974           (progn
 975             (url-http-parse-response)
 976             (mail-narrow-to-head)
 977             ;;(narrow-to-region (point-min) url-http-end-of-headers)
 978             (setq url-http-transfer-encoding (mail-fetch-field
 979                                               "transfer-encoding")
 980                   url-http-content-type (mail-fetch-field "content-type"))
 981             (if (mail-fetch-field "content-length")
 982                 (setq url-http-content-length
 983                       (string-to-number (mail-fetch-field "content-length"))))
 984             (widen)))
 985         (when url-http-transfer-encoding
 986           (setq url-http-transfer-encoding
 987                 (downcase url-http-transfer-encoding)))
 988
 989         (cond
 990          ((or (= url-http-response-status 204)
 991               (= url-http-response-status 205))
 992           (url-http-debug "%d response must have headers only (%s)."
 993                           url-http-response-status (buffer-name))
 994           (when (url-http-parse-headers)
 995             (url-http-activate-callback)))
 996          ((string= "HEAD" url-http-method)
 997           ;; A HEAD request is _ALWAYS_ terminated by the header
 998           ;; information, regardless of any entity headers,
 999           ;; according to section 4.4 of the HTTP/1.1 draft.
1000           (url-http-debug "HEAD request must have headers only (%s)."
1001                           (buffer-name))
1002           (when (url-http-parse-headers)
1003             (url-http-activate-callback)))
1004          ((string= "CONNECT" url-http-method)
1005           ;; A CONNECT request is finished, but we cannot stick this
1006           ;; back on the free connectin list
1007           (url-http-debug "CONNECT request must have headers only.")
1008           (when (url-http-parse-headers)
1009             (url-http-activate-callback)))
1010          ((equal url-http-response-status 304)
1011           ;; Only allowed to have a header section.  We have to handle
1012           ;; this here instead of in url-http-parse-headers because if
1013           ;; you have a cached copy of something without a known
1014           ;; content-length, and try to retrieve it from the cache, we'd
1015           ;; fall into the 'being dumb' section and wait for the
1016           ;; connection to terminate, which means we'd wait for 10
1017           ;; seconds for the keep-alives to time out on some servers.
1018           (when (url-http-parse-headers)
1019             (url-http-activate-callback)))
1020          (old-http
1021           ;; HTTP/0.9 always signaled end-of-connection by closing the
1022           ;; connection.
1023           (url-http-debug
1024            "Saw HTTP/0.9 response, connection closed means end of document.")
1025           (setq url-http-after-change-function
1026                 'url-http-simple-after-change-function))
1027          ((equal url-http-transfer-encoding "chunked")
1028           (url-http-debug "Saw chunked encoding.")
1029           (setq url-http-after-change-function
1030                 'url-http-chunked-encoding-after-change-function)
1031           (when (> nd url-http-end-of-headers)
1032             (url-http-debug
1033              "Calling initial chunked-encoding for extra data at end of headers")
1034             (url-http-chunked-encoding-after-change-function
1035              (marker-position url-http-end-of-headers) nd
1036              (- nd url-http-end-of-headers))))
1037          ((integerp url-http-content-length)
1038           (url-http-debug
1039            "Got a content-length, being smart about document end.")
1040           (setq url-http-after-change-function
1041                 'url-http-content-length-after-change-function)
1042           (cond
1043            ((= 0 url-http-content-length)
1044             ;; We got a NULL body!  Activate the callback
1045             ;; immediately!
1046             (url-http-debug
1047              "Got 0-length content-length, activating callback immediately.")
1048             (when (url-http-parse-headers)
1049               (url-http-activate-callback)))
1050            ((> nd url-http-end-of-headers)
1051             ;; Have some leftover data
1052             (url-http-debug "Calling initial content-length for extra data at end of headers")
1053             (url-http-content-length-after-change-function
1054              (marker-position url-http-end-of-headers)
1055              nd
1056              (- nd url-http-end-of-headers)))
1057            (t
1058             nil)))
1059          (t
1060           (url-http-debug "No content-length, being dumb.")
1061           (setq url-http-after-change-function
1062                 'url-http-simple-after-change-function)))))
1063     ;; We are still at the beginning of the buffer... must just be
1064     ;; waiting for a response.
1065     (url-http-debug "Spinning waiting for headers..."))
1066   (goto-char (point-max)))
1067
1068 ;;;###autoload
1069 (defun url-http (url callback cbargs)
1070   "Retrieve URL via HTTP asynchronously.
1071 URL must be a parsed URL.  See `url-generic-parse-url' for details.
1072 When retrieval is completed, the function CALLBACK is executed with
1073 CBARGS as the arguments."
1074   (check-type url vector "Need a pre-parsed URL.")
1075   (declare (special url-current-object
1076                     url-http-end-of-headers
1077                     url-http-content-type
1078                     url-http-content-length
1079                     url-http-transfer-encoding
1080                     url-http-after-change-function
1081                     url-callback-function
1082                     url-callback-arguments
1083                     url-http-method
1084                     url-http-extra-headers
1085                     url-http-data
1086                     url-http-chunked-length
1087                     url-http-chunked-start
1088                     url-http-chunked-counter
1089                     url-http-process))
1090   (let* ((host (url-host (or url-using-proxy url)))
1091          (port (url-port (or url-using-proxy url)))
1092          (connection (url-http-find-free-connection host port))
1093          (buffer (generate-new-buffer (format " *http %s:%d*" host port))))
1094     (if (not connection)
1095         ;; Failed to open the connection for some reason
1096         (progn
1097           (kill-buffer buffer)
1098           (setq buffer nil)
1099           (error "Could not create connection to %s:%d" host port))
1100       (with-current-buffer buffer
1101         (mm-disable-multibyte)
1102         (setq url-current-object url
1103               mode-line-format "%b [%s]")
1104
1105         (dolist (var '(url-http-end-of-headers
1106                        url-http-content-type
1107                        url-http-content-length
1108                        url-http-transfer-encoding
1109                        url-http-after-change-function
1110                        url-http-response-version
1111                        url-http-response-status
1112                        url-http-chunked-length
1113                        url-http-chunked-counter
1114                        url-http-chunked-start
1115                        url-callback-function
1116                        url-callback-arguments
1117                        url-http-process
1118                        url-http-method
1119                        url-http-extra-headers
1120                        url-http-data
1121                        url-http-target-url
1122                        url-http-connection-opened
1123                        url-http-proxy))
1124           (set (make-local-variable var) nil))
1125
1126         (setq url-http-method (or url-request-method "GET")
1127               url-http-extra-headers url-request-extra-headers
1128               url-http-data url-request-data
1129               url-http-process connection
1130               url-http-chunked-length nil
1131               url-http-chunked-start nil
1132               url-http-chunked-counter 0
1133               url-callback-function callback
1134               url-callback-arguments cbargs
1135               url-http-after-change-function 'url-http-wait-for-headers-change-function
1136               url-http-target-url url-current-object
1137               url-http-connection-opened nil
1138               url-http-proxy url-using-proxy)
1139
1140         (set-process-buffer connection buffer)
1141         (set-process-filter connection 'url-http-generic-filter)
1142         (let ((status (process-status connection)))
1143           (cond
1144            ((eq status 'connect)
1145             ;; Asynchronous connection
1146             (set-process-sentinel connection 'url-http-async-sentinel))
1147            ((eq status 'failed)
1148             ;; Asynchronous connection failed
1149             (error "Could not create connection to %s:%d" host port))
1150            (t
1151             (set-process-sentinel connection 'url-http-end-of-document-sentinel)
1152             (process-send-string connection (url-http-create-request)))))))
1153     buffer))
1154
1155 (defun url-http-async-sentinel (proc why)
1156   (declare (special url-callback-arguments))
1157   ;; We are performing an asynchronous connection, and a status change
1158   ;; has occurred.
1159   (with-current-buffer (process-buffer proc)
1160     (cond
1161      (url-http-connection-opened
1162       (url-http-end-of-document-sentinel proc why))
1163      ((string= (substring why 0 4) "open")
1164       (setq url-http-connection-opened t)
1165       (process-send-string proc (url-http-create-request)))
1166      (t
1167       (setf (car url-callback-arguments)
1168             (nconc (list :error (list 'error 'connection-failed why
1169                                       :host (url-host (or url-http-proxy url-current-object))
1170                                       :service (url-port (or url-http-proxy url-current-object))))
1171                    (car url-callback-arguments)))
1172       (url-http-activate-callback)))))
1173
1174 ;; Since Emacs 19/20 does not allow you to change the
1175 ;; `after-change-functions' hook in the midst of running them, we fake
1176 ;; an after change by hooking into the process filter and inserting
1177 ;; the data ourselves.  This is slightly less efficient, but there
1178 ;; were tons of weird ways the after-change code was biting us in the
1179 ;; shorts.
1180 (defun url-http-generic-filter (proc data)
1181   ;; Sometimes we get a zero-length data chunk after the process has
1182   ;; been changed to 'free', which means it has no buffer associated
1183   ;; with it.  Do nothing if there is no buffer, or 0 length data.
1184   (declare (special url-http-after-change-function))
1185   (and (process-buffer proc)
1186        (/= (length data) 0)
1187        (with-current-buffer (process-buffer proc)
1188          (url-http-debug "Calling after change function `%s' for `%S'" url-http-after-change-function proc)
1189          (funcall url-http-after-change-function
1190                   (point-max)
1191                   (progn
1192                     (goto-char (point-max))
1193                     (insert data)
1194                     (point-max))
1195                   (length data)))))
1196
1197 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1198 ;;; file-name-handler stuff from here on out
1199 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1200 (defalias 'url-http-symbol-value-in-buffer
1201   (if (fboundp 'symbol-value-in-buffer)
1202       'symbol-value-in-buffer
1203     (lambda (symbol buffer &optional unbound-value)
1204       "Return the value of SYMBOL in BUFFER, or UNBOUND-VALUE if it is unbound."
1205       (with-current-buffer buffer
1206         (if (not (boundp symbol))
1207             unbound-value
1208           (symbol-value symbol))))))
1209
1210 (defun url-http-head (url)
1211   (let ((url-request-method "HEAD")
1212         (url-request-data nil))
1213     (url-retrieve-synchronously url)))
1214
1215 ;;;###autoload
1216 (defun url-http-file-exists-p (url)
1217   (let ((status nil)
1218         (exists nil)
1219         (buffer (url-http-head url)))
1220     (if (not buffer)
1221         (setq exists nil)
1222       (setq status (url-http-symbol-value-in-buffer 'url-http-response-status
1223                                                     buffer 500)
1224             exists (and (integerp status)
1225                         (>= status 200) (< status 300)))
1226       (kill-buffer buffer))
1227     exists))
1228
1229 ;;;###autoload
1230 (defalias 'url-http-file-readable-p 'url-http-file-exists-p)
1231
1232 (defun url-http-head-file-attributes (url &optional id-format)
1233   (let ((buffer (url-http-head url)))
1234     (when buffer
1235       (prog1
1236           (list
1237            nil                          ;dir / link / normal file
1238            1                            ;number of links to file.
1239            0 0                          ;uid ; gid
1240            nil nil nil                  ;atime ; mtime ; ctime
1241            (url-http-symbol-value-in-buffer 'url-http-content-length
1242                                             buffer -1)
1243            (eval-when-compile (make-string 10 ?-))
1244            nil nil nil)          ;whether gid would change ; inode ; device.
1245         (kill-buffer buffer)))))
1246
1247 ;;;###autoload
1248 (defun url-http-file-attributes (url &optional id-format)
1249   (if (url-dav-supported-p url)
1250       (url-dav-file-attributes url id-format)
1251     (url-http-head-file-attributes url id-format)))
1252
1253 ;;;###autoload
1254 (defun url-http-options (url)
1255   "Return a property list describing options available for URL.
1256 This list is retrieved using the `OPTIONS' HTTP method.
1257
1258 Property list members:
1259
1260 methods
1261   A list of symbols specifying what HTTP methods the resource
1262   supports.
1263
1264 dav
1265   A list of numbers specifying what DAV protocol/schema versions are
1266   supported.
1267
1268 dasl
1269   A list of supported DASL search types supported (string form)
1270
1271 ranges
1272   A list of the units available for use in partial document fetches.
1273
1274 p3p
1275   The `Platform For Privacy Protection' description for the resource.
1276   Currently this is just the raw header contents.  This is likely to
1277   change once P3P is formally supported by the URL package or
1278   Emacs/W3."
1279   (let* ((url-request-method "OPTIONS")
1280          (url-request-data nil)
1281          (buffer (url-retrieve-synchronously url))
1282          (header nil)
1283          (options nil))
1284     (when (and buffer (= 2 (/ (url-http-symbol-value-in-buffer
1285                                'url-http-response-status buffer 0) 100)))
1286       ;; Only parse the options if we got a 2xx response code!
1287       (with-current-buffer buffer
1288         (save-restriction
1289           (save-match-data
1290             (mail-narrow-to-head)
1291
1292             ;; Figure out what methods are supported.
1293             (when (setq header (mail-fetch-field "allow"))
1294               (setq options (plist-put
1295                              options 'methods
1296                              (mapcar 'intern (split-string header "[ ,]+")))))
1297
1298             ;; Check for DAV
1299             (when (setq header (mail-fetch-field "dav"))
1300               (setq options (plist-put
1301                              options 'dav
1302                              (delq 0
1303                                    (mapcar 'string-to-number
1304                                            (split-string header "[, ]+"))))))
1305
1306             ;; Now for DASL
1307             (when (setq header (mail-fetch-field "dasl"))
1308               (setq options (plist-put
1309                              options 'dasl
1310                              (split-string header "[, ]+"))))
1311
1312             ;; P3P - should get more detailed here.  FIXME
1313             (when (setq header (mail-fetch-field "p3p"))
1314               (setq options (plist-put options 'p3p header)))
1315
1316             ;; Check for whether they accept byte-range requests.
1317             (when (setq header (mail-fetch-field "accept-ranges"))
1318               (setq options (plist-put
1319                              options 'ranges
1320                              (delq 'none
1321                                    (mapcar 'intern
1322                                            (split-string header "[, ]+"))))))
1323             ))))
1324     (if buffer (kill-buffer buffer))
1325     options))
1326
1327 ;; HTTPS.  This used to be in url-https.el, but that file collides
1328 ;; with url-http.el on systems with 8-character file names.
1329 (require 'tls)
1330
1331 ;;;###autoload
1332 (defconst url-https-default-port 443 "Default HTTPS port.")
1333 ;;;###autoload
1334 (defconst url-https-asynchronous-p t "HTTPS retrievals are asynchronous.")
1335 ;;;###autoload
1336 (defalias 'url-https-expand-file-name 'url-http-expand-file-name)
1337
1338 (defmacro url-https-create-secure-wrapper (method args)
1339   `(defun ,(intern (format (if method "url-https-%s" "url-https") method)) ,args
1340     ,(format "HTTPS wrapper around `%s' call." (or method "url-http"))
1341     (let ((url-gateway-method 'tls))
1342       (,(intern (format (if method "url-http-%s" "url-http") method))
1343        ,@(remove '&rest (remove '&optional args))))))
1344
1345 ;;;###autoload (autoload 'url-https "url-http")
1346 (url-https-create-secure-wrapper nil (url callback cbargs))
1347 ;;;###autoload (autoload 'url-https-file-exists-p "url-http")
1348 (url-https-create-secure-wrapper file-exists-p (url))
1349 ;;;###autoload (autoload 'url-https-file-readable-p "url-http")
1350 (url-https-create-secure-wrapper file-readable-p (url))
1351 ;;;###autoload (autoload 'url-https-file-attributes "url-http")
1352 (url-https-create-secure-wrapper file-attributes (url &optional id-format))
1353
1354 (provide 'url-http)
1355
1356 ;; arch-tag: ba7c59ae-c0f4-4a31-9617-d85f221732ee
1357 ;;; url-http.el ends here