lisp/mail/sendmail.el

   1 ;;; sendmail.el --- mail sending commands for Emacs.
   2
   3 ;; Copyright (C) 1985, 1986, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This mode provides mail-sending facilities from within Emacs.  It is
  27 ;; documented in the Emacs user's manual.
  28
  29 ;;; Code:
  30
  31 ;;;###autoload
  32 (defvar mail-self-blind nil "\
  33 Non-nil means insert BCC to self in messages to be sent.
  34 This is done when the message is initialized,
  35 so you can remove or alter the BCC field to override the default.")
  36
  37 ;;;###autoload
  38 (defvar mail-interactive nil "\
  39 Non-nil means when sending a message wait for and display errors.
  40 nil means let mailer mail back a message to report errors.")
  41
  42 ;;;###autoload
  43 (defvar mail-yank-ignored-headers "^via:\\|^mail-from:\\|^origin:\\|^status:\\|^remailed\\|^received:\\|^message-id:\\|^summary-line:\\|^to:\\|^subject:\\|^in-reply-to:\\|^return-path:" "\
  44 Delete these headers from old message when it's inserted in a reply.")
  45
  46 ;; Useful to set in site-init.el
  47 ;;;###autoload
  48 (defvar send-mail-function 'sendmail-send-it "\
  49 Function to call to send the current buffer as mail.
  50 The headers are be delimited by a line which is `mail-header-separator'.")
  51
  52 ;;;###autoload
  53 (defvar mail-header-separator "--text follows this line--" "\
  54 *Line used to separate headers from text in messages being composed.")
  55
  56 ;;;###autoload
  57 (defvar mail-archive-file-name nil "\
  58 *Name of file to write all outgoing messages in, or nil for none.
  59 Do not use an rmail file here!  Instead, use its inbox file.")
  60
  61 (defvar mail-default-reply-to nil
  62   "*Address to insert as default Reply-to field of outgoing messages.")
  63
  64 (defvar mail-alias-file nil
  65   "*If non-nil, the name of a file to use instead of `/usr/lib/aliases'.
  66 This file defines aliases to be expanded by the mailer; this is a different
  67 feature from that of defining aliases in `.mailrc' to be expanded in Emacs.
  68 This variable has no effect unless your system uses sendmail as its mailer.")
  69
  70 (defvar mail-aliases t
  71   "Alist of mail address aliases,
  72 or t meaning should be initialized from `~/.mailrc'.
  73 The alias definitions in `~/.mailrc' have this form:
  74     alias ALIAS MEANING")
  75
  76 (defvar mail-yank-prefix nil
  77   "*Prefix insert on lines of yanked message being replied to.
  78 nil means use indentation.")
  79 (defvar mail-indentation-spaces 3
  80   "*Number of spaces to insert at the beginning of each cited line.
  81 Used by `mail-yank-original' via `mail-yank-cite'.")
  82 (defvar mail-yank-hooks '(mail-indent-citation)
  83   "*Hook for modifying a citation just inserted in the mail buffer.
  84 Each hook function can find the citation between (point) and (mark t).
  85 And each hook function should leave point and mark around the citation
  86 text as modified.
  87
  88 This is a normal hook, currently misnamed for historical reasons.")
  89
  90 (defvar mail-abbrevs-loaded nil)
  91 (defvar mail-mode-map nil)
  92
  93 (autoload 'build-mail-aliases "mailalias"
  94   "Read mail aliases from `~/.mailrc' and set `mail-aliases'."
  95   nil)
  96
  97 (autoload 'expand-mail-aliases "mailalias"
  98   "Expand all mail aliases in suitable header fields found between BEG and END.
  99 Suitable header fields are `To', `Cc' and `Bcc' and their `Resent-' variants.
 100 Optional second arg EXCLUDE may be a regular expression defining text to be
 101 removed from alias expansions."
 102   nil)
 103
 104 ;;;###autoload
 105 (defvar mail-signature nil
 106   "*Text inserted at end of mail buffer when a message is initialized.
 107 If t, it means to insert the contents of the file `~/.signature'.")
 108
 109 (defvar mail-reply-buffer nil)
 110 (defvar mail-send-actions nil
 111   "A list of actions to be performed upon successful sending of a message.")
 112
 113 (defvar mail-default-headers nil
 114   "*A string containing header lines, to be inserted in outgoing messages.
 115 It is inserted before you edit the message,
 116 so you can edit or delete these lines.")
 117
 118 (defvar mail-mode-syntax-table nil
 119   "Syntax table used while in mail mode.")
 120
 121 (if (null mail-mode-syntax-table)
 122     (progn
 123      (setq mail-mode-syntax-table (copy-syntax-table text-mode-syntax-table))
 124      (modify-syntax-entry ?% ". " mail-mode-syntax-table)))
 125
 126 (defun mail-setup (to subject in-reply-to cc replybuffer actions)
 127   (if (eq mail-aliases t)
 128       (progn
 129         (setq mail-aliases nil)
 130         (if (file-exists-p "~/.mailrc")
 131             (build-mail-aliases))))
 132   (setq mail-send-actions actions)
 133   (setq mail-reply-buffer replybuffer)
 134   (goto-char (point-min))
 135   (insert "To: ")
 136   (save-excursion
 137     (if to
 138         ;; Here removed code to extract names from within <...>
 139         ;; on the assumption that mail-strip-quoted-names
 140         ;; has been called and has done so.
 141         (let ((fill-prefix "\t")
 142               (address-start (point)))
 143           (insert to "\n")
 144           (fill-region-as-paragraph address-start (point-max)))
 145       (newline))
 146     (if cc
 147         (let ((fill-prefix "\t")
 148               (address-start (progn (insert "CC: ") (point))))
 149           (insert cc "\n")
 150           (fill-region-as-paragraph address-start (point-max))))
 151     (if in-reply-to
 152         (insert "In-reply-to: " in-reply-to "\n"))
 153     (insert "Subject: " (or subject "") "\n")
 154     (if mail-default-headers
 155         (insert mail-default-headers))
 156     (if mail-default-reply-to
 157         (insert "Reply-to: " mail-default-reply-to "\n"))
 158     (if mail-self-blind
 159         (insert "BCC: " (user-login-name) "\n"))
 160     (if mail-archive-file-name
 161         (insert "FCC: " mail-archive-file-name "\n"))
 162     (insert mail-header-separator "\n")
 163     ;; Insert the signature.  But remember the beginning of the message.
 164     (if to (setq to (point)))
 165     (cond ((eq mail-signature t)
 166            (if (file-exists-p "~/.signature")
 167                (insert-file-contents "~/.signature")))
 168           (mail-signature
 169            (insert mail-signature)))
 170     (goto-char (point-max))
 171     (or (bolp) (newline)))
 172   (if to (goto-char to))
 173   (or to subject in-reply-to
 174       (set-buffer-modified-p nil))
 175   (run-hooks 'mail-setup-hook))
 176
 177 ;;;###autoload
 178 (defun mail-mode ()
 179   "Major mode for editing mail to be sent.
 180 Like Text Mode but with these additional commands:
 181 C-c C-s  mail-send (send the message)    C-c C-c  mail-send-and-exit
 182 C-c C-f  move to a header field (and create it if there isn't):
 183          C-c C-f C-t  move to To:       C-c C-f C-s  move to Subj:
 184          C-c C-f C-b  move to BCC:      C-c C-f C-c  move to CC:
 185 C-c C-t  move to message text.
 186 C-c C-y  mail-yank-original (insert current message, in Rmail).
 187 C-c C-q  mail-fill-yanked-message (fill what was yanked).
 188 C-c C-v  mail-sent-via (add a sent-via field for each To or CC)."
 189   (interactive)
 190   (kill-all-local-variables)
 191   (make-local-variable 'mail-reply-buffer)
 192   (setq mail-reply-buffer nil)
 193   (make-local-variable 'mail-send-actions)
 194   (set-syntax-table mail-mode-syntax-table)
 195   (use-local-map mail-mode-map)
 196   (setq local-abbrev-table text-mode-abbrev-table)
 197   (setq major-mode 'mail-mode)
 198   (setq mode-name "Mail")
 199   (setq buffer-offer-save t)
 200   (make-local-variable 'paragraph-separate)
 201   (make-local-variable 'paragraph-start)
 202   (setq paragraph-start (concat "^" mail-header-separator
 203                                 "$\\|^[ \t]*[-_][-_][-_]+$\\|"
 204                                 paragraph-start))
 205   (setq paragraph-separate (concat "^" mail-header-separator
 206                                    "$\\|^[ \t]*[-_][-_][-_]+$\\|"
 207                                    paragraph-separate))
 208   (run-hooks 'text-mode-hook 'mail-mode-hook))
 209
 210 (if mail-mode-map
 211     nil
 212   (setq mail-mode-map (nconc (make-sparse-keymap) text-mode-map))
 213   (define-key mail-mode-map "\C-c?" 'describe-mode)
 214   (define-key mail-mode-map "\C-c\C-f\C-t" 'mail-to)
 215   (define-key mail-mode-map "\C-c\C-f\C-b" 'mail-bcc)
 216   (define-key mail-mode-map "\C-c\C-f\C-f" 'mail-fcc)
 217   (define-key mail-mode-map "\C-c\C-f\C-c" 'mail-cc)
 218   (define-key mail-mode-map "\C-c\C-f\C-s" 'mail-subject)
 219   (define-key mail-mode-map "\C-c\C-t" 'mail-text)
 220   (define-key mail-mode-map "\C-c\C-y" 'mail-yank-original)
 221   (define-key mail-mode-map "\C-c\C-q" 'mail-fill-yanked-message)
 222   (define-key mail-mode-map "\C-c\C-w" 'mail-signature)
 223   (define-key mail-mode-map "\C-c\C-v" 'mail-sent-via)
 224   (define-key mail-mode-map "\C-c\C-c" 'mail-send-and-exit)
 225   (define-key mail-mode-map "\C-c\C-s" 'mail-send))
 226 \f
 227 (defun mail-send-and-exit (arg)
 228   "Send message like `mail-send', then, if no errors, exit from mail buffer.
 229 Prefix arg means don't delete this window."
 230   (interactive "P")
 231   (mail-send)
 232   (let ((newbuf (other-buffer (current-buffer))))
 233     (bury-buffer (current-buffer))
 234     (if (and (not arg)
 235              (not (one-window-p))
 236              (save-excursion
 237                (set-buffer (window-buffer (next-window (selected-window) 'not)))
 238                (eq major-mode 'rmail-mode)))
 239         (delete-window)
 240       (switch-to-buffer newbuf))))
 241
 242 (defun mail-send ()
 243   "Send the message in the current buffer.
 244 If `mail-interactive' is non-nil, wait for success indication
 245 or error messages, and inform user.
 246 Otherwise any failure is reported in a message back to
 247 the user from the mailer."
 248   (interactive)
 249   (if (or (buffer-modified-p)
 250           (y-or-n-p "Message already sent; resend? "))
 251       (progn
 252         (message "Sending...")
 253         (run-hooks 'mail-send-hook)
 254         (funcall send-mail-function)
 255         ;; Now perform actions on successful sending.
 256         (while mail-send-actions
 257           (condition-case nil
 258               (apply (car (car mail-send-actions))
 259                      (cdr (car mail-send-actions)))
 260             (error))
 261           (setq mail-send-actions (cdr mail-send-actions)))
 262         (message "Sending...done")
 263         ;; If buffer has no file, mark it as unmodified and delete autosave.
 264         (if (not buffer-file-name)
 265             (progn
 266               (set-buffer-modified-p nil)
 267               (delete-auto-save-file-if-necessary t))))))
 268
 269 (defun sendmail-send-it ()
 270   (let ((errbuf (if mail-interactive
 271                     (generate-new-buffer " sendmail errors")
 272                   0))
 273         (tembuf (generate-new-buffer " sendmail temp"))
 274         (case-fold-search nil)
 275         delimline
 276         (mailbuf (current-buffer)))
 277     (unwind-protect
 278         (save-excursion
 279           (set-buffer tembuf)
 280           (erase-buffer)
 281           (insert-buffer-substring mailbuf)
 282           (goto-char (point-max))
 283           ;; require one newline at the end.
 284           (or (= (preceding-char) ?\n)
 285               (insert ?\n))
 286           ;; Change header-delimiter to be what sendmail expects.
 287           (goto-char (point-min))
 288           (re-search-forward
 289             (concat "^" (regexp-quote mail-header-separator) "\n"))
 290           (replace-match "\n")
 291           (backward-char 1)
 292           (setq delimline (point-marker))
 293           (if mail-aliases
 294               (expand-mail-aliases (point-min) delimline))
 295           (goto-char (point-min))
 296           ;; ignore any blank lines in the header
 297           (while (and (re-search-forward "\n\n\n*" delimline t)
 298                       (< (point) delimline))
 299             (replace-match "\n"))
 300           (let ((case-fold-search t))
 301             (goto-char (point-min))
 302             (if (re-search-forward "^Sender:" delimline t)
 303                 (error "Sender may not be specified."))
 304             ;; Find and handle any FCC fields.
 305             (goto-char (point-min))
 306             (if (re-search-forward "^FCC:" delimline t)
 307                 (mail-do-fcc delimline))
 308             ;; If the From is different than current user, insert Sender.
 309             (goto-char (point-min))
 310             (and (re-search-forward "^From:"  delimline t)
 311                  (progn
 312                    (require 'mail-utils)
 313                    (not (string-equal
 314                          (mail-strip-quoted-names
 315                           (save-restriction
 316                             (narrow-to-region (point-min) delimline)
 317                             (mail-fetch-field "From")))
 318                          (user-login-name))))
 319                  (progn
 320                    (forward-line 1)
 321                    (insert "Sender: " (user-login-name) "\n")))
 322             ;; "S:" is an abbreviation for "Subject:".
 323             (goto-char (point-min))
 324             (if (re-search-forward "^S:" delimline t)
 325                 (replace-match "Subject:"))
 326             ;; Don't send out a blank subject line
 327             (goto-char (point-min))
 328             (if (re-search-forward "^Subject:[ \t]*\n" delimline t)
 329                 (replace-match ""))
 330             (if mail-interactive
 331                 (save-excursion
 332                   (set-buffer errbuf)
 333                   (erase-buffer))))
 334           (apply 'call-process-region
 335                  (append (list (point-min) (point-max)
 336                                (if (boundp 'sendmail-program)
 337                                    sendmail-program
 338                                  "/usr/lib/sendmail")
 339                                nil errbuf nil
 340                                "-oi" "-t")
 341                          ;; Always specify who from,
 342                          ;; since some systems have broken sendmails.
 343                          (list "-f" (user-login-name))
 344 ;;;                      ;; Don't say "from root" if running under su.
 345 ;;;                      (and (equal (user-real-login-name) "root")
 346 ;;;                           (list "-f" (user-login-name)))
 347                          (and mail-alias-file
 348                               (list (concat "-oA" mail-alias-file)))
 349                          ;; These mean "report errors by mail"
 350                          ;; and "deliver in background".
 351                          (if (null mail-interactive) '("-oem" "-odb"))))
 352           (if mail-interactive
 353               (save-excursion
 354                 (set-buffer errbuf)
 355                 (goto-char (point-min))
 356                 (while (re-search-forward "\n\n* *" nil t)
 357                   (replace-match "; "))
 358                 (if (not (zerop (buffer-size)))
 359                     (error "Sending...failed to %s"
 360                            (buffer-substring (point-min) (point-max)))))))
 361       (kill-buffer tembuf)
 362       (if (bufferp errbuf)
 363           (kill-buffer errbuf)))))
 364
 365 (defun mail-do-fcc (header-end)
 366   (let (fcc-list
 367         (rmailbuf (current-buffer))
 368         (time (current-time))
 369         timezone
 370         (tembuf (generate-new-buffer " rmail output"))
 371         (case-fold-search t))
 372     (save-excursion
 373       (goto-char (point-min))
 374       (while (re-search-forward "^FCC:[ \t]*" header-end t)
 375         (setq fcc-list (cons (buffer-substring (point)
 376                                                (progn
 377                                                  (end-of-line)
 378                                                  (skip-chars-backward " \t")
 379                                                  (point)))
 380                              fcc-list))
 381         (delete-region (match-beginning 0)
 382                        (progn (forward-line 1) (point))))
 383       (let* ((foo (current-time-zone time))
 384              (offset (if (car foo) (/ (car foo) 60) 0))
 385              (abs (abs offset)))
 386         (setq timezone (format "%s%02d%02d"
 387                                (if (< offset 0) "-" "+")
 388                                (/ abs 60)
 389                                (% abs 60))))
 390       (set-buffer tembuf)
 391       (erase-buffer)
 392       ;; This initial newline is written out if the fcc file already exists.
 393       (insert "\nFrom " (user-login-name) " "
 394               (current-time-string time) "\n")
 395       ;; Insert the time zone before the year.
 396       (forward-char -1)
 397       (forward-word -1)
 398       (insert timezone " ")
 399       (goto-char (point-max))
 400       (insert-buffer-substring rmailbuf)
 401       ;; Make sure messages are separated.
 402       (goto-char (point-max))
 403       (insert ?\n)
 404       (goto-char 2)
 405       ;; ``Quote'' "^From " as ">From "
 406       ;;  (note that this isn't really quoting, as there is no requirement
 407       ;;   that "^[>]+From " be quoted in the same transparent way.)
 408       (let ((case-fold-search nil))
 409         (while (search-forward "\nFrom " nil t)
 410           (forward-char -5)
 411           (insert ?>)))
 412       (while fcc-list
 413         (let ((buffer (get-file-buffer (car fcc-list))))
 414           (if buffer
 415               ;; File is present in a buffer => append to that buffer.
 416               (let ((curbuf (current-buffer))
 417                     (beg (point-min)) (end (point-max))
 418                     (beg2 (save-excursion (goto-char (point-min))
 419                                           (forward-line 2) (point))))
 420                 (save-excursion
 421                   (set-buffer buffer)
 422                   ;; Keep the end of the accessible portion at the same place
 423                   ;; unless it is the end of the buffer.
 424                   (let ((max (if (/= (1+ (buffer-size)) (point-max))
 425                                  (point-max))))
 426                     (unwind-protect
 427                         ;; Code below lifted from rmailout.el
 428                         ;; function rmail-output-to-rmail-file:
 429                         (let ((buffer-read-only nil)
 430                               (msg (and (boundp 'rmail-current-message)
 431                                         rmail-current-message)))
 432                           ;; If MSG is non-nil, buffer is in RMAIL mode.
 433                           (if msg
 434                               (progn
 435                                 (rmail-maybe-set-message-counters)
 436                                 (widen)
 437                                 (narrow-to-region (point-max) (point-max))
 438                                 (insert "\C-l\n0, unseen,,\n*** EOOH ***\n"
 439                                         "From: " (user-login-name) "\n"
 440                                         "Date: " (current-time-string) "\n")
 441                                 (insert-buffer-substring curbuf beg2 end)
 442                                 (insert "\n\C-_")
 443                                 (goto-char (point-min))
 444                                 (widen)
 445                                 (search-backward "\n\^_")
 446                                 (narrow-to-region (point) (point-max))
 447                                 (rmail-count-new-messages t)
 448                                 (rmail-show-message msg)
 449                                 (setq max nil))
 450                             ;; Output file not in rmail mode
 451                             ;; => just insert at the end.
 452                             (narrow-to-region (point-min) (1+ (buffer-size)))
 453                             (goto-char (point-max))
 454                             (insert-buffer-substring curbuf beg end)))
 455                       (if max (narrow-to-region (point-min) max))))))
 456             ;; Else append to the file directly.
 457             (write-region
 458              ;; Include a blank line before if file already exists.
 459
 460              (if (file-exists-p (car fcc-list)) (point-min) (1+ (point-min)))
 461              (point-max) (car fcc-list) t)))
 462         (setq fcc-list (cdr fcc-list))))
 463     (kill-buffer tembuf)))
 464
 465 (defun mail-sent-via ()
 466   "Make a Sent-via header line from each To or CC header line."
 467   (interactive)
 468   (save-excursion
 469     (goto-char (point-min))
 470     ;; find the header-separator
 471     (search-forward (concat "\n" mail-header-separator "\n"))
 472     (forward-line -1)
 473     ;; put a marker at the end of the header
 474     (let ((end (point-marker))
 475           (case-fold-search t)
 476           to-line)
 477       (goto-char (point-min))
 478       ;; search for the To: lines and make Sent-via: lines from them
 479       ;; search for the next To: line
 480       (while (re-search-forward "^\\(to\\|cc\\):" end t)
 481         ;; Grab this line plus all its continuations, sans the `to:'.
 482         (let ((to-line
 483                (buffer-substring (point)
 484                                  (progn
 485                                    (if (re-search-forward "^[^ \t\n]" end t)
 486                                        (backward-char 1)
 487                                      (goto-char end))
 488                                    (point)))))
 489           ;; Insert a copy, with altered header field name.
 490           (insert-before-markers "Sent-via:" to-line))))))
 491 \f
 492 (defun mail-to ()
 493   "Move point to end of To-field."
 494   (interactive)
 495   (expand-abbrev)
 496   (mail-position-on-field "To"))
 497
 498 (defun mail-subject ()
 499   "Move point to end of Subject-field."
 500   (interactive)
 501   (expand-abbrev)
 502   (mail-position-on-field "Subject"))
 503
 504 (defun mail-cc ()
 505   "Move point to end of CC-field.  Create a CC field if none."
 506   (interactive)
 507   (expand-abbrev)
 508   (or (mail-position-on-field "cc" t)
 509       (progn (mail-position-on-field "to")
 510              (insert "\nCC: "))))
 511
 512 (defun mail-bcc ()
 513   "Move point to end of BCC-field.  Create a BCC field if none."
 514   (interactive)
 515   (expand-abbrev)
 516   (or (mail-position-on-field "bcc" t)
 517       (progn (mail-position-on-field "to")
 518              (insert "\nBCC: "))))
 519
 520 (defun mail-fcc ()
 521   "Add a new FCC field, with file name completion."
 522   (interactive)
 523   (expand-abbrev)
 524   (or (mail-position-on-field "fcc" t)  ;Put new field after exiting FCC.
 525       (mail-position-on-field "to"))
 526   (insert "\nFCC: " (read-file-name "Folder carbon copy: ")))
 527
 528 (defun mail-position-on-field (field &optional soft)
 529   (let (end
 530         (case-fold-search t))
 531     (goto-char (point-min))
 532     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "\n"))
 533     (setq end (match-beginning 0))
 534     (goto-char (point-min))
 535     (if (re-search-forward (concat "^" (regexp-quote field) ":") end t)
 536         (progn
 537           (re-search-forward "^[^ \t]" nil 'move)
 538           (beginning-of-line)
 539           (skip-chars-backward "\n")
 540           t)
 541       (or soft
 542           (progn (goto-char end)
 543                  (insert field ": \n")
 544                  (skip-chars-backward "\n")))
 545       nil)))
 546
 547 (defun mail-text ()
 548   "Move point to beginning of text field."
 549   (interactive)
 550   (goto-char (point-min))
 551   (search-forward (concat "\n" mail-header-separator "\n")))
 552 \f
 553 (defun mail-signature (atpoint)
 554   "Sign letter with contents of `mail-signature-file'."
 555   (interactive "P")
 556   (save-excursion
 557     (or atpoint
 558         (goto-char (point-max)))
 559     (skip-chars-backward " \t\n")
 560     (end-of-line)
 561     (or atpoint
 562         (delete-region (point) (point-max)))
 563     (insert "\n\n")
 564     (insert-file-contents (expand-file-name "~/.signature"))))
 565
 566 (defun mail-fill-yanked-message (&optional justifyp)
 567   "Fill the paragraphs of a message yanked into this one.
 568 Numeric argument means justify as well."
 569   (interactive "P")
 570   (save-excursion
 571     (goto-char (point-min))
 572     (search-forward (concat "\n" mail-header-separator "\n") nil t)
 573     (fill-individual-paragraphs (point)
 574                                 (point-max)
 575                                 justifyp
 576                                 t)))
 577
 578 (defun mail-indent-citation ()
 579   "Modify text just inserted from a message to be cited.
 580 The inserted text should be the region.
 581 When this function returns, the region is again around the modified text.
 582
 583 Normally, indent each nonblank line `mail-indentation-spaces' spaces.
 584 However, if `mail-yank-prefix' is non-nil, insert that prefix on each line."
 585   (let ((start (point)))
 586     (mail-yank-clear-headers start (mark t))
 587     (if (null mail-yank-prefix)
 588         (indent-rigidly start (mark t) mail-indentation-spaces)
 589       (save-excursion
 590         (goto-char start)
 591         (while (< (point) (mark t))
 592           (insert mail-yank-prefix)
 593           (forward-line 1))))))
 594
 595 (defun mail-yank-original (arg)
 596   "Insert the message being replied to, if any (in rmail).
 597 Puts point before the text and mark after.
 598 Normally, indents each nonblank line ARG spaces (default 3).
 599 However, if `mail-yank-prefix' is non-nil, insert that prefix on each line.
 600
 601 Just \\[universal-argument] as argument means don't indent, insert no prefix,
 602 and don't delete any header fields."
 603   (interactive "P")
 604   (if mail-reply-buffer
 605       (let ((start (point)))
 606         (delete-windows-on mail-reply-buffer)
 607         (insert-buffer mail-reply-buffer)
 608         (if (consp arg)
 609             nil
 610           (goto-char start)
 611           (let ((mail-indentation-spaces (if arg (prefix-numeric-value arg)
 612                                            mail-indentation-spaces)))
 613             (run-hooks 'mail-yank-hooks)))
 614         ;; This is like exchange-point-and-mark, but doesn't activate the mark.
 615         ;; It is cleaner to avoid activation, even though the command
 616         ;; loop would deactivate the mark because we inserted text.
 617         (goto-char (prog1 (mark t)
 618                      (set-marker (mark-marker) (point) (current-buffer))))
 619         (if (not (eolp)) (insert ?\n)))))
 620
 621 (defun mail-yank-clear-headers (start end)
 622   (save-excursion
 623     (goto-char start)
 624     (if (search-forward "\n\n" end t)
 625         (save-restriction
 626           (narrow-to-region start (point))
 627           (goto-char start)
 628           (while (let ((case-fold-search t))
 629                    (re-search-forward mail-yank-ignored-headers nil t))
 630             (beginning-of-line)
 631             (delete-region (point)
 632                            (progn (re-search-forward "\n[^ \t]")
 633                                   (forward-char -1)
 634                                   (point))))))))
 635 \f
 636 ;; Put these last, to reduce chance of lossage from quitting in middle of loading the file.
 637
 638 ;;;###autoload
 639 (defun mail (&optional noerase to subject in-reply-to cc replybuffer actions)
 640   "Edit a message to be sent.  Prefix arg means resume editing (don't erase).
 641 When this function returns, the buffer `*mail*' is selected.
 642 The value is t if the message was newly initialized; otherwise, nil.
 643
 644 By default, the signature file `~/.signature' is inserted at the end;
 645 see the variable `mail-signature'.
 646
 647 \\<mail-mode-map>
 648 While editing message, type \\[mail-send-and-exit] to send the message and exit.
 649
 650 Various special commands starting with C-c are available in sendmail mode
 651 to move to message header fields:
 652 \\{mail-mode-map}
 653
 654 If `mail-self-blind' is non-nil, a BCC to yourself is inserted
 655 when the message is initialized.
 656
 657 If `mail-default-reply-to' is non-nil, it should be an address (a string);
 658 a Reply-to: field with that address is inserted.
 659
 660 If `mail-archive-file-name' is non-nil, an FCC field with that file name
 661 is inserted.
 662
 663 If `mail-setup-hook' is bound, its value is called with no arguments
 664 after the message is initialized.  It can add more default fields.
 665
 666 When calling from a program, the second through fifth arguments
 667  TO, SUBJECT, IN-REPLY-TO and CC specify if non-nil
 668  the initial contents of those header fields.
 669  These arguments should not have final newlines.
 670 The sixth argument REPLYBUFFER is a buffer whose contents
 671  should be yanked if the user types C-c C-y.
 672 The seventh argument ACTIONS is a list of actions to take
 673  if/when the message is sent.  Each action looks like (FUNCTION . ARGS);
 674  when the message is sent, we apply FUNCTION to ARGS.
 675  This is how Rmail arranges to mark messages `answered'."
 676   (interactive "P")
 677 ;;; This is commented out because I found it was confusing in practice.
 678 ;;; It is easy enough to rename *mail* by hand with rename-buffer
 679 ;;; if you want to have multiple mail buffers.
 680 ;;; And then you can control which messages to save. --rms.
 681 ;;;  (let ((index 1)
 682 ;;;     buffer)
 683 ;;;    ;; If requested, look for a mail buffer that is modified and go to it.
 684 ;;;    (if noerase
 685 ;;;     (progn
 686 ;;;       (while (and (setq buffer
 687 ;;;                         (get-buffer (if (= 1 index) "*mail*"
 688 ;;;                                       (format "*mail*<%d>" index))))
 689 ;;;                   (not (buffer-modified-p buffer)))
 690 ;;;         (setq index (1+ index)))
 691 ;;;       (if buffer (switch-to-buffer buffer)
 692 ;;;         ;; If none exists, start a new message.
 693 ;;;         ;; This will never re-use an existing unmodified mail buffer
 694 ;;;         ;; (since index is not 1 anymore).  Perhaps it should.
 695 ;;;         (setq noerase nil))))
 696 ;;;    ;; Unless we found a modified message and are happy, start a new message.
 697 ;;;    (if (not noerase)
 698 ;;;     (progn
 699 ;;;       ;; Look for existing unmodified mail buffer.
 700 ;;;       (while (and (setq buffer
 701 ;;;                         (get-buffer (if (= 1 index) "*mail*"
 702 ;;;                                       (format "*mail*<%d>" index))))
 703 ;;;                   (buffer-modified-p buffer))
 704 ;;;         (setq index (1+ index)))
 705 ;;;       ;; If none, make a new one.
 706 ;;;       (or buffer
 707 ;;;           (setq buffer (generate-new-buffer "*mail*")))
 708 ;;;       ;; Go there and initialize it.
 709 ;;;       (switch-to-buffer buffer)
 710 ;;;       (erase-buffer)
 711 ;;;          (setq default-directory (expand-file-name "~/"))
 712 ;;;          (auto-save-mode auto-save-default)
 713 ;;;          (mail-mode)
 714 ;;;          (mail-setup to subject in-reply-to cc replybuffer actions)
 715 ;;;       (if (and buffer-auto-save-file-name
 716 ;;;                (file-exists-p buffer-auto-save-file-name))
 717 ;;;           (message "Auto save file for draft message exists; consider M-x mail-recover"))
 718 ;;;          t))
 719   (switch-to-buffer "*mail*")
 720   (setq default-directory (expand-file-name "~/"))
 721   (auto-save-mode auto-save-default)
 722   (mail-mode)
 723   (let (initialized)
 724     (and (not noerase)
 725          (or (not (buffer-modified-p))
 726              (y-or-n-p "Unsent message being composed; erase it? "))
 727          (progn (erase-buffer)
 728                 (mail-setup to subject in-reply-to cc replybuffer actions)
 729                 (setq initialized t)))
 730     (if (and buffer-auto-save-file-name
 731              (file-exists-p buffer-auto-save-file-name))
 732         (message "Auto save file for draft message exists; consider M-x mail-recover"))
 733     initialized))
 734
 735 (defun mail-recover ()
 736   "Reread contents of current buffer from its last auto-save file."
 737   (interactive)
 738   (let ((file-name (make-auto-save-file-name)))
 739     (cond ((save-window-excursion
 740              (if (not (eq system-type 'vax-vms))
 741                  (with-output-to-temp-buffer "*Directory*"
 742                    (buffer-disable-undo standard-output)
 743                    (call-process "ls" nil standard-output nil "-l" file-name)))
 744              (yes-or-no-p (format "Recover auto save file %s? " file-name)))
 745            (let ((buffer-read-only nil))
 746              (erase-buffer)
 747              (insert-file-contents file-name nil)))
 748           (t (error "mail-recover cancelled.")))))
 749
 750 ;;;###autoload
 751 (defun mail-other-window (&optional noerase to subject in-reply-to cc replybuffer sendactions)
 752   "Like `mail' command, but display mail buffer in another window."
 753   (interactive "P")
 754   (let ((pop-up-windows t))
 755     (pop-to-buffer "*mail*"))
 756   (mail noerase to subject in-reply-to cc replybuffer sendactions))
 757
 758 ;;;###autoload
 759 (defun mail-other-frame (&optional noerase to subject in-reply-to cc replybuffer sendactions)
 760   "Like `mail' command, but display mail buffer in another frame."
 761   (interactive "P")
 762   (let ((pop-up-frames t))
 763     (pop-to-buffer "*mail*"))
 764   (mail noerase to subject in-reply-to cc replybuffer sendactions))
 765
 766
 767 ;;;###autoload
 768 (define-key ctl-x-map "m" 'mail)
 769
 770 ;;;###autoload
 771 (define-key ctl-x-4-map "m" 'mail-other-window)
 772
 773 ;;;###autoload
 774 (define-key ctl-x-5-map "m" 'mail-other-frame)
 775
 776
 777 ;;; Do not add anything but external entries on this page.
 778
 779 (provide 'sendmail)
 780
 781 ;;; sendmail.el ends here