lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001, 2002
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file contains those help commands which are complicated, and
  29 ;; which may not be used in every session.  For example
  30 ;; `describe-function' will probably be heavily used when doing elisp
  31 ;; programming, but not if just editing C files.  Simpler help commands
  32 ;; are in help.el
  33
  34 ;;; Code:
  35
  36 (require 'help-mode)
  37
  38
  39 ;;;###autoload
  40 (defun help-with-tutorial (&optional arg)
  41   "Select the Emacs learn-by-doing tutorial.
  42 If there is a tutorial version written in the language
  43 of the selected language environment, that version is used.
  44 If there's no tutorial in that language, `TUTORIAL' is selected.
  45 With ARG, you are asked to choose which language."
  46   (interactive "P")
  47   (let ((lang (if arg
  48                     (let ((minibuffer-setup-hook minibuffer-setup-hook))
  49                       (add-hook 'minibuffer-setup-hook
  50                                 'minibuffer-completion-help)
  51                       (read-language-name 'tutorial "Language: " "English"))
  52                 (if (get-language-info current-language-environment 'tutorial)
  53                     current-language-environment
  54                   "English")))
  55         file filename)
  56     (setq filename (get-language-info lang 'tutorial))
  57     (setq file (expand-file-name (concat "~/" filename)))
  58     (delete-other-windows)
  59     (if (get-file-buffer file)
  60         (switch-to-buffer (get-file-buffer file))
  61       (switch-to-buffer (create-file-buffer file))
  62       (setq buffer-file-name file)
  63       (setq default-directory (expand-file-name "~/"))
  64       (setq buffer-auto-save-file-name nil)
  65       (insert-file-contents (expand-file-name filename data-directory))
  66       (goto-char (point-min))
  67       (search-forward "\n<<")
  68       (beginning-of-line)
  69       ;; Convert the <<...>> line to the proper [...] line,
  70       ;; or just delete the <<...>> line if a [...] line follows.
  71       (cond ((save-excursion
  72                (forward-line 1)
  73                (looking-at "\\["))
  74              (delete-region (point) (progn (forward-line 1) (point))))
  75             ((looking-at "<<Blank lines inserted.*>>")
  76              (replace-match "[Middle of page left blank for didactic purposes.   Text continues below]"))
  77             (t
  78              (looking-at "<<")
  79              (replace-match "[")
  80              (search-forward ">>")
  81              (replace-match "]")))
  82       (beginning-of-line)
  83       (let ((n (- (window-height (selected-window))
  84                   (count-lines (point-min) (point))
  85                   6)))
  86         (if (< n 8)
  87             (progn
  88               ;; For a short gap, we don't need the [...] line,
  89               ;; so delete it.
  90               (delete-region (point) (progn (end-of-line) (point)))
  91               (newline n))
  92           ;; Some people get confused by the large gap.
  93           (newline (/ n 2))
  94
  95           ;; Skip the [...] line (don't delete it).
  96           (forward-line 1)
  97           (newline (- n (/ n 2)))))
  98       (goto-char (point-min))
  99       (set-buffer-modified-p nil))))
 100
 101 ;;;###autoload
 102 (defun locate-library (library &optional nosuffix path interactive-call)
 103   "Show the precise file name of Emacs library LIBRARY.
 104 This command searches the directories in `load-path' like `\\[load-library]'
 105 to find the file that `\\[load-library] RET LIBRARY RET' would load.
 106 Optional second arg NOSUFFIX non-nil means don't add suffixes `load-suffixes'
 107 to the specified name LIBRARY.
 108
 109 If the optional third arg PATH is specified, that list of directories
 110 is used instead of `load-path'.
 111
 112 When called from a program, the file name is normaly returned as a
 113 string.  When run interactively, the argument INTERACTIVE-CALL is t,
 114 and the file name is displayed in the echo area."
 115   (interactive (list (completing-read "Locate library: "
 116                                       'locate-file-completion
 117                                       (cons load-path load-suffixes))
 118                      nil nil
 119                      t))
 120   (let ((file (locate-file library
 121                            (or path load-path)
 122                            (append (unless nosuffix load-suffixes) '("")))))
 123     (if interactive-call
 124         (if file
 125             (message "Library is file %s" (abbreviate-file-name file))
 126           (message "No library %s in search path" library)))
 127     file))
 128
 129 \f
 130 ;; Functions
 131
 132 ;;;###autoload
 133 (defun describe-function (function)
 134   "Display the full documentation of FUNCTION (a symbol)."
 135   (interactive
 136    (let ((fn (function-called-at-point))
 137          (enable-recursive-minibuffers t)
 138          val)
 139      (setq val (completing-read (if fn
 140                                     (format "Describe function (default %s): " fn)
 141                                   "Describe function: ")
 142                                 obarray 'fboundp t nil nil (symbol-name fn)))
 143      (list (if (equal val "")
 144                fn (intern val)))))
 145   (if (null function)
 146       (message "You didn't specify a function")
 147     (help-setup-xref (list #'describe-function function) (interactive-p))
 148     (save-excursion
 149       (with-output-to-temp-buffer (help-buffer)
 150         (prin1 function)
 151         ;; Use " is " instead of a colon so that
 152         ;; it is easier to get out the function name using forward-sexp.
 153         (princ " is ")
 154         (describe-function-1 function)
 155         (print-help-return-message)
 156         (with-current-buffer standard-output
 157           ;; Return the text we displayed.
 158           (buffer-string))))))
 159
 160 (defun help-split-fundoc (doc def)
 161   "Split a function docstring DOC into the actual doc and the usage info.
 162 Return (USAGE . DOC) or nil if there's no usage info.
 163 DEF is the function whose usage we're looking for in DOC."
 164   ;; Functions can get the calling sequence at the end of the doc string.
 165   ;; In cases where `function' has been fset to a subr we can't search for
 166   ;; function's name in the doc string so we use `fn' as the anonymous
 167   ;; function name instead.
 168   (when (and doc (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" doc))
 169     (cons (format "(%s%s"
 170                   ;; Replace `fn' with the actual function name.
 171                   (if (consp def) "anonymous" def)
 172                   (match-string 1 doc))
 173           (substring doc 0 (match-beginning 0)))))
 174
 175 (defun help-add-fundoc-usage (doc arglist)
 176   "Add the usage info to the docstring DOC.
 177 If DOC already has a usage info, then just return DOC unchanged.
 178 The usage info is built from ARGLIST.  DOC can be nil."
 179   (unless (stringp doc) (setq doc "Not documented"))
 180   (if (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" doc)
 181       doc
 182     (format "%s%s%s" doc
 183             (if (string-match "\n?\n\\'" doc)
 184                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
 185               "\n\n")
 186             (help-make-usage 'fn arglist))))
 187
 188 (defun help-function-arglist (def)
 189   ;; Handle symbols aliased to other symbols.
 190   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 191   ;; If definition is a macro, find the function inside it.
 192   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 193   (cond
 194    ((byte-code-function-p def) (aref def 0))
 195    ((eq (car-safe def) 'lambda) (nth 1 def))
 196    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 197     "[Arg list not available until function definition is loaded.]")
 198    (t t)))
 199
 200 (defun help-make-usage (function arglist)
 201   (cons (if (symbolp function) function 'anonymous)
 202         (mapcar (lambda (arg)
 203                   (if (not (symbolp arg))
 204                       (if (and (consp arg) (symbolp (car arg)))
 205                           ;; CL style default values for optional args.
 206                           (cons (intern (upcase (symbol-name (car arg))))
 207                                 (cdr arg))
 208                         arg)
 209                     (let ((name (symbol-name arg)))
 210                       (if (string-match "\\`&" name) arg
 211                         (intern (upcase name))))))
 212                 arglist)))
 213
 214 ;;;###autoload
 215 (defun describe-function-1 (function)
 216   (let* ((def (if (symbolp function)
 217                   (symbol-function function)
 218                 function))
 219          file-name string
 220          (beg (if (commandp def) "an interactive " "a ")))
 221     (setq string
 222           (cond ((or (stringp def)
 223                      (vectorp def))
 224                  "a keyboard macro")
 225                 ((subrp def)
 226                  (if (eq 'unevalled (cdr (subr-arity def)))
 227                      (concat beg "special form")
 228                    (concat beg "built-in function")))
 229                 ((byte-code-function-p def)
 230                  (concat beg "compiled Lisp function"))
 231                 ((symbolp def)
 232                  (while (symbolp (symbol-function def))
 233                    (setq def (symbol-function def)))
 234                  (format "an alias for `%s'" def))
 235                 ((eq (car-safe def) 'lambda)
 236                  (concat beg "Lisp function"))
 237                 ((eq (car-safe def) 'macro)
 238                  "a Lisp macro")
 239                 ((eq (car-safe def) 'autoload)
 240                  (setq file-name (nth 1 def))
 241                  (format "%s autoloaded %s"
 242                          (if (commandp def) "an interactive" "an")
 243                          (if (eq (nth 4 def) 'keymap) "keymap"
 244                            (if (nth 4 def) "Lisp macro" "Lisp function"))
 245                          ))
 246                 ((keymapp def)
 247                  (let ((is-full nil)
 248                        (elts (cdr-safe def)))
 249                    (while elts
 250                      (if (char-table-p (car-safe elts))
 251                          (setq is-full t
 252                                elts nil))
 253                      (setq elts (cdr-safe elts)))
 254                    (if is-full
 255                        "a full keymap"
 256                      "a sparse keymap")))
 257                 (t "")))
 258     (princ string)
 259     (with-current-buffer standard-output
 260       (save-excursion
 261         (save-match-data
 262           (if (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 263               (help-xref-button 1 'help-function def)))))
 264     (or file-name
 265         (setq file-name (symbol-file function)))
 266     (when (equal file-name "loaddefs.el")
 267       ;; Find the real def site of the preloaded function.
 268       ;; This is necessary only for defaliases.
 269       (let ((location
 270              (condition-case nil
 271                  (find-function-search-for-symbol function nil "loaddefs.el")
 272                (error nil))))
 273         (when location
 274           (with-current-buffer (car location)
 275             (goto-char (cdr location))
 276             (when (re-search-backward
 277                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 278               (setq file-name (match-string 1)))))))
 279     (cond
 280      (file-name
 281       (princ " in `")
 282       ;; We used to add .el to the file name,
 283       ;; but that's completely wrong when the user used load-file.
 284       (princ file-name)
 285       (princ "'")
 286       ;; Make a hyperlink to the library.
 287       (with-current-buffer standard-output
 288         (save-excursion
 289           (re-search-backward "`\\([^`']+\\)'" nil t)
 290           (help-xref-button 1 'help-function-def function file-name)))))
 291     (princ ".")
 292     (terpri)
 293     (when (commandp function)
 294       (let* ((remapped (command-remapping function))
 295              (keys (where-is-internal
 296                     (or remapped function) overriding-local-map nil nil)))
 297         (when remapped
 298           (princ "It is remapped to `")
 299           (princ (symbol-name remapped))
 300           (princ "'"))
 301         (when keys
 302           (princ (if remapped " which is bound to " "It is bound to "))
 303           ;; FIXME: This list can be very long (f.ex. for self-insert-command).
 304           (princ (mapconcat 'key-description keys ", ")))
 305         (when (or remapped keys)
 306           (princ ".")
 307           (terpri))))
 308     (let* ((arglist (help-function-arglist def))
 309            (doc (documentation function))
 310            (usage (help-split-fundoc doc function)))
 311       ;; If definition is a keymap, skip arglist note.
 312       (unless (keymapp def)
 313         (princ (cond
 314                 (usage (setq doc (cdr usage)) (car usage))
 315                 ((listp arglist) (help-make-usage function arglist))
 316                 ((stringp arglist) arglist)
 317                 ;; Maybe the arglist is in the docstring of the alias.
 318                 ((let ((fun function))
 319                    (while (and (symbolp fun)
 320                                (setq fun (symbol-function fun))
 321                                (not (setq usage (help-split-fundoc
 322                                                  (documentation fun)
 323                                                  function)))))
 324                    usage)
 325                  (car usage))
 326                 ((or (stringp def)
 327                      (vectorp def))
 328                  (format "\nMacro: %s" (format-kbd-macro def)))
 329                 (t "[Missing arglist.  Please make a bug report.]")))
 330         (terpri))
 331       (let ((obsolete (and
 332                        ;; function might be a lambda construct.
 333                        (symbolp function)
 334                        (get function 'byte-obsolete-info))))
 335         (when obsolete
 336           (terpri)
 337           (princ "This function is obsolete")
 338           (if (nth 2 obsolete) (princ (format " since %s" (nth 2 obsolete))))
 339           (princ ";") (terpri)
 340           (princ (if (stringp (car obsolete)) (car obsolete)
 341                    (format "use `%s' instead." (car obsolete))))
 342           (terpri)))
 343       (terpri)
 344       (princ (or doc "Not documented.")))))
 345
 346 \f
 347 ;; Variables
 348
 349 ;;;###autoload
 350 (defun variable-at-point ()
 351   "Return the bound variable symbol found around point.
 352 Return 0 if there is no such symbol."
 353   (condition-case ()
 354       (with-syntax-table emacs-lisp-mode-syntax-table
 355         (save-excursion
 356           (or (not (zerop (skip-syntax-backward "_w")))
 357               (eq (char-syntax (following-char)) ?w)
 358               (eq (char-syntax (following-char)) ?_)
 359               (forward-sexp -1))
 360           (skip-chars-forward "'")
 361           (let ((obj (read (current-buffer))))
 362             (or (and (symbolp obj) (boundp obj) obj)
 363                 0))))
 364     (error 0)))
 365
 366 ;;;###autoload
 367 (defun describe-variable (variable &optional buffer)
 368   "Display the full documentation of VARIABLE (a symbol).
 369 Returns the documentation as a string, also.
 370 If VARIABLE has a buffer-local value in BUFFER (default to the current buffer),
 371 it is displayed along with the global value."
 372   (interactive
 373    (let ((v (variable-at-point))
 374          (enable-recursive-minibuffers t)
 375          val)
 376      (setq val (completing-read (if (symbolp v)
 377                                     (format
 378                                      "Describe variable (default %s): " v)
 379                                   "Describe variable: ")
 380                                 obarray 'boundp t nil nil
 381                                 (if (symbolp v) (symbol-name v))))
 382      (list (if (equal val "")
 383                v (intern val)))))
 384   (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 385   (if (not (symbolp variable))
 386       (message "You did not specify a variable")
 387     (save-excursion
 388       (let* ((valvoid (not (with-current-buffer buffer (boundp variable))))
 389              ;; Extract the value before setting up the output buffer,
 390              ;; in case `buffer' *is* the output buffer.
 391              (val (unless valvoid (buffer-local-value variable buffer))))
 392         (help-setup-xref (list #'describe-variable variable buffer)
 393                          (interactive-p))
 394         (with-output-to-temp-buffer (help-buffer)
 395           (with-current-buffer buffer
 396             (prin1 variable)
 397             (if valvoid
 398                 (princ " is void")
 399               (with-current-buffer standard-output
 400                 (princ "'s value is ")
 401                 (terpri)
 402                 (let ((from (point)))
 403                   (pp val)
 404                   (help-xref-on-pp from (point))
 405                   (if (< (point) (+ from 20))
 406                       (delete-region (1- from) from)))))
 407             (terpri)
 408             (when (local-variable-p variable)
 409               (princ (format "Local in buffer %s; " (buffer-name)))
 410               (if (not (default-boundp variable))
 411                   (princ "globally void")
 412                 (let ((val (default-value variable)))
 413                   (with-current-buffer standard-output
 414                     (princ "global value is ")
 415                     (terpri)
 416                     ;; Fixme: pp can take an age if you happen to
 417                     ;; ask for a very large expression.  We should
 418                     ;; probably print it raw once and check it's a
 419                     ;; sensible size before prettyprinting.  -- fx
 420                     (let ((from (point)))
 421                       (pp val)
 422                       (help-xref-on-pp from (point))
 423                       (if (< (point) (+ from 20))
 424                         (delete-region (1- from) from))))))
 425               (terpri))
 426             (terpri)
 427             (with-current-buffer standard-output
 428               (when (> (count-lines (point-min) (point-max)) 10)
 429                 ;; Note that setting the syntax table like below
 430                 ;; makes forward-sexp move over a `'s' at the end
 431                 ;; of a symbol.
 432                 (set-syntax-table emacs-lisp-mode-syntax-table)
 433                 (goto-char (point-min))
 434                 (if valvoid
 435                     (forward-line 1)
 436                   (forward-sexp 1)
 437                   (delete-region (point) (progn (end-of-line) (point)))
 438                   (insert " value is shown below.\n\n")
 439                   (save-excursion
 440                     (insert "\n\nValue:"))))
 441               ;; Add a note for variables that have been make-var-buffer-local.
 442               (when (and (local-variable-if-set-p variable)
 443                          (or (not (local-variable-p variable))
 444                              (with-temp-buffer
 445                                (local-variable-if-set-p variable))))
 446                 (save-excursion
 447                   (forward-line -1)
 448                   (insert "Automatically becomes buffer-local when set in any fashion.\n"))))
 449             ;; Mention if it's an alias
 450             (let* ((alias (condition-case nil
 451                              (indirect-variable variable)
 452                            (error variable)))
 453                    (obsolete (get variable 'byte-obsolete-variable))
 454                    (doc (or (documentation-property variable 'variable-documentation)
 455                             (documentation-property alias 'variable-documentation))))
 456               (unless (eq alias variable)
 457                 (princ (format "This variable is an alias for `%s'." alias))
 458                 (terpri)
 459                 (terpri))
 460               (when obsolete
 461                 (princ "This variable is obsolete")
 462                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 463                 (princ ";") (terpri)
 464                 (princ (if (stringp (car obsolete)) (car obsolete)
 465                          (format "use `%s' instead." (car obsolete))))
 466                 (terpri)
 467                 (terpri))
 468               (princ (or doc "Not documented as a variable.")))
 469             ;; Make a link to customize if this variable can be customized.
 470             (if (custom-variable-p variable)
 471                 (let ((customize-label "customize"))
 472                   (terpri)
 473                   (terpri)
 474                   (princ (concat "You can " customize-label " this variable."))
 475                   (with-current-buffer standard-output
 476                     (save-excursion
 477                       (re-search-backward
 478                        (concat "\\(" customize-label "\\)") nil t)
 479                       (help-xref-button 1 'help-customize-variable variable)))))
 480             ;; Make a hyperlink to the library if appropriate.  (Don't
 481             ;; change the format of the buffer's initial line in case
 482             ;; anything expects the current format.)
 483             (let ((file-name (symbol-file (cons 'defvar variable))))
 484               (when (equal file-name "loaddefs.el")
 485                 ;; Find the real def site of the preloaded variable.
 486                 (let ((location
 487                        (condition-case nil
 488                            (find-variable-noselect variable file-name)
 489                          (error nil))))
 490                   (when location
 491                     (with-current-buffer (car location)
 492                       (goto-char (cdr location))
 493                       (when (re-search-backward
 494                              "^;;; Generated autoloads from \\(.*\\)" nil t)
 495                         (setq file-name (match-string 1)))))))
 496               (when file-name
 497                 (princ "\n\nDefined in `")
 498                 (princ file-name)
 499                 (princ "'.")
 500                 (with-current-buffer standard-output
 501                   (save-excursion
 502                     (re-search-backward "`\\([^`']+\\)'" nil t)
 503                     (help-xref-button 1 'help-variable-def
 504                                       variable file-name)))))
 505
 506             (print-help-return-message)
 507             (save-excursion
 508               (set-buffer standard-output)
 509               ;; Return the text we displayed.
 510               (buffer-string))))))))
 511
 512
 513 ;;;###autoload
 514 (defun describe-syntax (&optional buffer)
 515   "Describe the syntax specifications in the syntax table of BUFFER.
 516 The descriptions are inserted in a help buffer, which is then displayed.
 517 BUFFER defaults to the current buffer."
 518   (interactive)
 519   (setq buffer (or buffer (current-buffer)))
 520   (help-setup-xref (list #'describe-syntax buffer) (interactive-p))
 521   (with-output-to-temp-buffer (help-buffer)
 522     (let ((table (with-current-buffer buffer (syntax-table))))
 523       (with-current-buffer standard-output
 524         (describe-vector table 'internal-describe-syntax-value)
 525         (while (setq table (char-table-parent table))
 526           (insert "\nThe parent syntax table is:")
 527           (describe-vector table 'internal-describe-syntax-value))))))
 528
 529 (defun help-describe-category-set (value)
 530   (insert (cond
 531            ((null value) "default")
 532            ((char-table-p value) "deeper char-table ...")
 533            (t (condition-case err
 534                   (category-set-mnemonics value)
 535                 (error "invalid"))))))
 536
 537 ;;;###autoload
 538 (defun describe-categories (&optional buffer)
 539   "Describe the category specifications in the current category table.
 540 The descriptions are inserted in a buffer, which is then displayed."
 541   (interactive)
 542   (setq buffer (or buffer (current-buffer)))
 543   (help-setup-xref (list #'describe-categories buffer) (interactive-p))
 544   (with-output-to-temp-buffer (help-buffer)
 545     (let ((table (with-current-buffer buffer (category-table))))
 546       (with-current-buffer standard-output
 547         (describe-vector table 'help-describe-category-set)
 548         (let ((docs (char-table-extra-slot table 0)))
 549           (if (or (not (vectorp docs)) (/= (length docs) 95))
 550               (insert "Invalid first extra slot in this char table\n")
 551             (insert "Meanings of mnemonic characters are:\n")
 552             (dotimes (i 95)
 553               (let ((elt (aref docs i)))
 554                 (when elt
 555                   (insert (+ i ?\ ) ": " elt "\n"))))
 556             (while (setq table (char-table-parent table))
 557               (insert "\nThe parent category table is:")
 558               (describe-vector table 'help-describe-category-set))))))))
 559
 560 (provide 'help-fns)
 561
 562 ;;; help-fns.el ends here