lisp/replace.el

   1 ;;; replace.el --- replace commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992, 1994, 1996, 1997, 2000, 2001, 2002,
   4 ;;   2003, 2004  Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package supplies the string and regular-expression replace functions
  28 ;; documented in the Emacs user's manual.
  29
  30 ;;; Code:
  31
  32 (defcustom case-replace t
  33   "*Non-nil means `query-replace' should preserve case in replacements."
  34   :type 'boolean
  35   :group 'matching)
  36
  37 (defvar query-replace-history nil)
  38
  39 (defvar query-replace-interactive nil
  40   "Non-nil means `query-replace' uses the last search string.
  41 That becomes the \"string to replace\".")
  42
  43 (defcustom query-replace-from-history-variable 'query-replace-history
  44   "History list to use for the FROM argument of `query-replace' commands.
  45 The value of this variable should be a symbol; that symbol
  46 is used as a variable to hold a history list for the strings
  47 or patterns to be replaced."
  48   :group 'matching
  49   :type 'symbol
  50   :version "20.3")
  51
  52 (defcustom query-replace-to-history-variable 'query-replace-history
  53   "History list to use for the TO argument of `query-replace' commands.
  54 The value of this variable should be a symbol; that symbol
  55 is used as a variable to hold a history list for replacement
  56 strings or patterns."
  57   :group 'matching
  58   :type 'symbol
  59   :version "20.3")
  60
  61 (defcustom query-replace-skip-read-only nil
  62   "*Non-nil means `query-replace' and friends ignore read-only matches."
  63   :type 'boolean
  64   :group 'matching
  65   :version "21.4")
  66
  67 (defun query-replace-descr (string)
  68   (mapconcat 'isearch-text-char-description string ""))
  69
  70 (defun query-replace-read-from (string regexp-flag)
  71   "Query and return the `from' argument of a query-replace operation.
  72 The return value can also be a pair (FROM . TO) indicating that the user
  73 wants to replace FROM with TO."
  74   (if query-replace-interactive
  75       (car (if regexp-flag regexp-search-ring search-ring))
  76     (let* ((lastfrom (car (symbol-value query-replace-from-history-variable)))
  77            (lastto (car (symbol-value query-replace-to-history-variable)))
  78            (from
  79             ;; The save-excursion here is in case the user marks and copies
  80             ;; a region in order to specify the minibuffer input.
  81             ;; That should not clobber the region for the query-replace itself.
  82             (save-excursion
  83               (when (equal lastfrom lastto)
  84                 ;; Typically, this is because the two histlists are shared.
  85                 (setq lastfrom (cadr (symbol-value
  86                                       query-replace-from-history-variable))))
  87               (read-from-minibuffer
  88                (if (and lastto lastfrom)
  89                    (format "%s (default %s -> %s): " string
  90                            (query-replace-descr lastfrom)
  91                            (query-replace-descr lastto))
  92                  (format "%s: " string))
  93                nil nil nil
  94                query-replace-from-history-variable
  95                nil t t))))
  96       (if (and (zerop (length from)) lastto lastfrom)
  97           (cons lastfrom
  98                 (query-replace-compile-replacement lastto regexp-flag))
  99         ;; Warn if user types \n or \t, but don't reject the input.
 100         (and regexp-flag
 101              (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\(\\\\[nt]\\)" from)
 102              (let ((match (match-string 3 from)))
 103                (cond
 104                 ((string= match "\\n")
 105                  (message "Note: `\\n' here doesn't match a newline; to do that, type C-q C-j instead"))
 106                 ((string= match "\\t")
 107                  (message "Note: `\\t' here doesn't match a tab; to do that, just type TAB")))
 108                (sit-for 2)))
 109         from))))
 110
 111 (defun query-replace-compile-replacement (to regexp-flag)
 112   "Maybe convert a regexp replacement TO to Lisp.
 113 Returns a list suitable for `perform-replace' if necessary,
 114 the original string if not."
 115   (if (and regexp-flag
 116            (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\\\[,#]" to))
 117       (let (pos list char)
 118         (while
 119             (progn
 120               (setq pos (match-end 0))
 121               (push (substring to 0 (- pos 2)) list)
 122               (setq char (aref to (1- pos))
 123                     to (substring to pos))
 124               (cond ((eq char ?\#)
 125                      (push '(number-to-string replace-count) list))
 126                     ((eq char ?\,)
 127                      (setq pos (read-from-string to))
 128                      (push `(replace-quote ,(car pos)) list)
 129                      (let ((end
 130                             ;; Swallow a space after a symbol
 131                             ;; if there is a space.
 132                             (if (and (or (symbolp (car pos))
 133                                          ;; Swallow a space after 'foo
 134                                          ;; but not after (quote foo).
 135                                          (and (eq (car-safe (car pos)) 'quote)
 136                                               (not (= ?\( (aref to 0)))))
 137                                      (eq (string-match " " to (cdr pos))
 138                                          (cdr pos)))
 139                                 (1+ (cdr pos))
 140                               (cdr pos))))
 141                        (setq to (substring to end)))))
 142               (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\\\[,#]" to)))
 143         (setq to (nreverse (delete "" (cons to list))))
 144         (replace-match-string-symbols to)
 145         (cons 'replace-eval-replacement
 146               (if (cdr to)
 147                   (cons 'concat to)
 148                 (car to))))
 149     to))
 150
 151
 152 (defun query-replace-read-to (from string regexp-flag)
 153   "Query and return the `to' argument of a query-replace operation."
 154   (query-replace-compile-replacement
 155    (save-excursion
 156      (read-from-minibuffer
 157       (format "%s %s with: " string (query-replace-descr from))
 158       nil nil nil
 159       query-replace-to-history-variable from t t))
 160    regexp-flag))
 161
 162 (defun query-replace-read-args (string regexp-flag &optional noerror)
 163   (unless noerror
 164     (barf-if-buffer-read-only))
 165   (let* ((from (query-replace-read-from string regexp-flag))
 166          (to (if (consp from) (prog1 (cdr from) (setq from (car from)))
 167                (query-replace-read-to from string regexp-flag))))
 168     (list from to current-prefix-arg)))
 169
 170 (defun query-replace (from-string to-string &optional delimited start end)
 171   "Replace some occurrences of FROM-STRING with TO-STRING.
 172 As each match is found, the user must type a character saying
 173 what to do with it.  For directions, type \\[help-command] at that time.
 174
 175 In Transient Mark mode, if the mark is active, operate on the contents
 176 of the region.  Otherwise, operate from point to the end of the buffer.
 177
 178 If `query-replace-interactive' is non-nil, the last incremental search
 179 string is used as FROM-STRING--you don't have to specify it with the
 180 minibuffer.
 181
 182 Matching is independent of case if `case-fold-search' is non-nil and
 183 FROM-STRING has no uppercase letters.  Replacement transfers the case
 184 pattern of the old text to the new text, if `case-replace' and
 185 `case-fold-search' are non-nil and FROM-STRING has no uppercase
 186 letters.  \(Transferring the case pattern means that if the old text
 187 matched is all caps, or capitalized, then its replacement is upcased
 188 or capitalized.)
 189
 190 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 191 only matches surrounded by word boundaries.
 192 Fourth and fifth arg START and END specify the region to operate on.
 193
 194 To customize possible responses, change the \"bindings\" in `query-replace-map'."
 195   (interactive (let ((common
 196                       (query-replace-read-args "Query replace" nil)))
 197                  (list (nth 0 common) (nth 1 common) (nth 2 common)
 198                        ;; These are done separately here
 199                        ;; so that command-history will record these expressions
 200                        ;; rather than the values they had this time.
 201                        (if (and transient-mark-mode mark-active)
 202                            (region-beginning))
 203                        (if (and transient-mark-mode mark-active)
 204                            (region-end)))))
 205   (perform-replace from-string to-string t nil delimited nil nil start end))
 206
 207 (define-key esc-map "%" 'query-replace)
 208
 209 (defun query-replace-regexp (regexp to-string &optional delimited start end)
 210   "Replace some things after point matching REGEXP with TO-STRING.
 211 As each match is found, the user must type a character saying
 212 what to do with it.  For directions, type \\[help-command] at that time.
 213
 214 In Transient Mark mode, if the mark is active, operate on the contents
 215 of the region.  Otherwise, operate from point to the end of the buffer.
 216
 217 If `query-replace-interactive' is non-nil, the last incremental search
 218 regexp is used as REGEXP--you don't have to specify it with the
 219 minibuffer.
 220
 221 Matching is independent of case if `case-fold-search' is non-nil and
 222 REGEXP has no uppercase letters.  Replacement transfers the case
 223 pattern of the old text to the new text, if `case-replace' and
 224 `case-fold-search' are non-nil and REGEXP has no uppercase letters.
 225 \(Transferring the case pattern means that if the old text matched is
 226 all caps, or capitalized, then its replacement is upcased or
 227 capitalized.)
 228
 229 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 230 only matches surrounded by word boundaries.
 231 Fourth and fifth arg START and END specify the region to operate on.
 232
 233 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 234 and `\\=\\N' (where N is a digit) stands for
 235 whatever what matched the Nth `\\(...\\)' in REGEXP.
 236 `\\?' lets you edit the replacement text in the minibuffer
 237 at the given position for each replacement.
 238
 239 In interactive calls, the replacement text can contain `\\,'
 240 followed by a Lisp expression.  Each
 241 replacement evaluates that expression to compute the replacement
 242 string.  Inside of that expression, `\\&' is a string denoting the
 243 whole match as a string, `\\N' for a partial match, `\\#&' and `\\#N'
 244 for the whole or a partial match converted to a number with
 245 `string-to-number', and `\\#' itself for the number of replacements
 246 done so far (starting with zero).
 247
 248 If the replacement expression is a symbol, write a space after it
 249 to terminate it.  One space there, if any, will be discarded.
 250
 251 When using those Lisp features interactively in the replacement
 252 text, TO-STRING is actually made a list instead of a string.
 253 Use \\[repeat-complex-command] after this command for details."
 254   (interactive
 255    (let ((common
 256           (query-replace-read-args "Query replace regexp" t)))
 257      (list (nth 0 common) (nth 1 common) (nth 2 common)
 258            ;; These are done separately here
 259            ;; so that command-history will record these expressions
 260            ;; rather than the values they had this time.
 261            (if (and transient-mark-mode mark-active)
 262                (region-beginning))
 263            (if (and transient-mark-mode mark-active)
 264                (region-end)))))
 265   (perform-replace regexp to-string t t delimited nil nil start end))
 266
 267 (define-key esc-map [?\C-%] 'query-replace-regexp)
 268
 269 (defun query-replace-regexp-eval (regexp to-expr &optional delimited start end)
 270   "Replace some things after point matching REGEXP with the result of TO-EXPR.
 271 As each match is found, the user must type a character saying
 272 what to do with it.  For directions, type \\[help-command] at that time.
 273
 274 TO-EXPR is a Lisp expression evaluated to compute each replacement.  It may
 275 reference `replace-count' to get the number of replacements already made.
 276 If the result of TO-EXPR is not a string, it is converted to one using
 277 `prin1-to-string' with the NOESCAPE argument (which see).
 278
 279 For convenience, when entering TO-EXPR interactively, you can use `\\&' or
 280 `\\0' to stand for whatever matched the whole of REGEXP, and `\\N' (where
 281 N is a digit) to stand for whatever matched the Nth `\\(...\\)' in REGEXP.
 282 Use `\\#&' or `\\#N' if you want a number instead of a string.
 283 In interactive use, `\\#' in itself stands for `replace-count'.
 284
 285 In Transient Mark mode, if the mark is active, operate on the contents
 286 of the region.  Otherwise, operate from point to the end of the buffer.
 287
 288 If `query-replace-interactive' is non-nil, the last incremental search
 289 regexp is used as REGEXP--you don't have to specify it with the
 290 minibuffer.
 291
 292 Preserves case in each replacement if `case-replace' and `case-fold-search'
 293 are non-nil and REGEXP has no uppercase letters.
 294
 295 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 296 only matches that are surrounded by word boundaries.
 297 Fourth and fifth arg START and END specify the region to operate on."
 298   (interactive
 299    (progn
 300    (barf-if-buffer-read-only)
 301    (let* ((from
 302            ;; Let-bind the history var to disable the "foo -> bar" default.
 303            ;; Maybe we shouldn't disable this default, but for now I'll
 304            ;; leave it off.  --Stef
 305            (let ((query-replace-to-history-variable nil))
 306              (query-replace-read-from "Query replace regexp" t)))
 307           (to (list (read-from-minibuffer
 308                      (format "Query replace regexp %s with eval: "
 309                              (query-replace-descr from))
 310                      nil nil t query-replace-to-history-variable from t))))
 311      ;; We make TO a list because replace-match-string-symbols requires one,
 312      ;; and the user might enter a single token.
 313      (replace-match-string-symbols to)
 314      (list from (car to) current-prefix-arg
 315            (if (and transient-mark-mode mark-active)
 316                (region-beginning))
 317            (if (and transient-mark-mode mark-active)
 318                (region-end))))))
 319   (perform-replace regexp (cons 'replace-eval-replacement to-expr)
 320                    t 'literal delimited nil nil start end))
 321
 322 (defun map-query-replace-regexp (regexp to-strings &optional n start end)
 323   "Replace some matches for REGEXP with various strings, in rotation.
 324 The second argument TO-STRINGS contains the replacement strings,
 325 separated by spaces.  Third arg DELIMITED (prefix arg if interactive),
 326 if non-nil, means replace only matches surrounded by word boundaries.
 327 This command works like `query-replace-regexp' except that each
 328 successive replacement uses the next successive replacement string,
 329 wrapping around from the last such string to the first.
 330
 331 In Transient Mark mode, if the mark is active, operate on the contents
 332 of the region.  Otherwise, operate from point to the end of the buffer.
 333
 334 Non-interactively, TO-STRINGS may be a list of replacement strings.
 335
 336 If `query-replace-interactive' is non-nil, the last incremental search
 337 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 338
 339 A prefix argument N says to use each replacement string N times
 340 before rotating to the next.
 341 Fourth and fifth arg START and END specify the region to operate on."
 342   (interactive
 343    (let* ((from (if query-replace-interactive
 344                     (car regexp-search-ring)
 345                   (read-from-minibuffer "Map query replace (regexp): "
 346                                         nil nil nil
 347                                         'query-replace-history nil t)))
 348           (to (read-from-minibuffer
 349                (format "Query replace %s with (space-separated strings): "
 350                        (query-replace-descr from))
 351                nil nil nil
 352                'query-replace-history from t)))
 353      (list from to
 354            (and current-prefix-arg
 355                 (prefix-numeric-value current-prefix-arg))
 356            (if (and transient-mark-mode mark-active)
 357                (region-beginning))
 358            (if (and transient-mark-mode mark-active)
 359                (region-end)))))
 360   (let (replacements)
 361     (if (listp to-strings)
 362         (setq replacements to-strings)
 363       (while (/= (length to-strings) 0)
 364         (if (string-match " " to-strings)
 365             (setq replacements
 366                   (append replacements
 367                           (list (substring to-strings 0
 368                                            (string-match " " to-strings))))
 369                   to-strings (substring to-strings
 370                                        (1+ (string-match " " to-strings))))
 371           (setq replacements (append replacements (list to-strings))
 372                 to-strings ""))))
 373     (perform-replace regexp replacements t t nil n nil start end)))
 374
 375 (defun replace-string (from-string to-string &optional delimited start end)
 376   "Replace occurrences of FROM-STRING with TO-STRING.
 377 Preserve case in each match if `case-replace' and `case-fold-search'
 378 are non-nil and FROM-STRING has no uppercase letters.
 379 \(Preserving case means that if the string matched is all caps, or capitalized,
 380 then its replacement is upcased or capitalized.)
 381
 382 In Transient Mark mode, if the mark is active, operate on the contents
 383 of the region.  Otherwise, operate from point to the end of the buffer.
 384
 385 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 386 only matches surrounded by word boundaries.
 387 Fourth and fifth arg START and END specify the region to operate on.
 388
 389 If `query-replace-interactive' is non-nil, the last incremental search
 390 string is used as FROM-STRING--you don't have to specify it with the
 391 minibuffer.
 392
 393 This function is usually the wrong thing to use in a Lisp program.
 394 What you probably want is a loop like this:
 395   (while (search-forward FROM-STRING nil t)
 396     (replace-match TO-STRING nil t))
 397 which will run faster and will not set the mark or print anything.
 398 \(You may need a more complex loop if FROM-STRING can match the null string
 399 and TO-STRING is also null.)"
 400   (interactive
 401    (let ((common
 402           (query-replace-read-args "Replace string" nil)))
 403      (list (nth 0 common) (nth 1 common) (nth 2 common)
 404            (if (and transient-mark-mode mark-active)
 405                (region-beginning))
 406            (if (and transient-mark-mode mark-active)
 407                (region-end)))))
 408   (perform-replace from-string to-string nil nil delimited nil nil start end))
 409
 410 (defun replace-regexp (regexp to-string &optional delimited start end)
 411   "Replace things after point matching REGEXP with TO-STRING.
 412 Preserve case in each match if `case-replace' and `case-fold-search'
 413 are non-nil and REGEXP has no uppercase letters.
 414
 415 In Transient Mark mode, if the mark is active, operate on the contents
 416 of the region.  Otherwise, operate from point to the end of the buffer.
 417
 418 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 419 only matches surrounded by word boundaries.
 420 Fourth and fifth arg START and END specify the region to operate on.
 421
 422 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 423 and `\\=\\N' (where N is a digit) stands for
 424 whatever what matched the Nth `\\(...\\)' in REGEXP.
 425 `\\?' lets you edit the replacement text in the minibuffer
 426 at the given position for each replacement.
 427
 428 In interactive calls, the replacement text may contain `\\,'
 429 followed by a Lisp expression used as part of the replacement
 430 text.  Inside of that expression, `\\&' is a string denoting the
 431 whole match, `\\N' a partial matches, `\\#&' and `\\#N' the
 432 respective numeric values from `string-to-number', and `\\#'
 433 itself for `replace-count', the number of replacements occured so
 434 far.
 435
 436 If your Lisp expression is an identifier and the next letter in
 437 the replacement string would be interpreted as part of it, you
 438 can wrap it with an expression like `\\,(or \\#)'.  Incidentally,
 439 for this particular case you may also enter `\\#' in the
 440 replacement text directly.
 441
 442 When using those Lisp features interactively in the replacement
 443 text, TO-STRING is actually made a list instead of a string.
 444 Use \\[repeat-complex-command] after this command for details.
 445
 446 If `query-replace-interactive' is non-nil, the last incremental search
 447 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 448
 449 This function is usually the wrong thing to use in a Lisp program.
 450 What you probably want is a loop like this:
 451   (while (re-search-forward REGEXP nil t)
 452     (replace-match TO-STRING nil nil))
 453 which will run faster and will not set the mark or print anything."
 454   (interactive
 455    (let ((common
 456           (query-replace-read-args "Replace regexp" t)))
 457      (list (nth 0 common) (nth 1 common) (nth 2 common)
 458            (if (and transient-mark-mode mark-active)
 459                (region-beginning))
 460            (if (and transient-mark-mode mark-active)
 461                (region-end)))))
 462   (perform-replace regexp to-string nil t delimited nil nil start end))
 463
 464 \f
 465 (defvar regexp-history nil
 466   "History list for some commands that read regular expressions.")
 467
 468
 469 (defalias 'delete-non-matching-lines 'keep-lines)
 470 (defalias 'delete-matching-lines 'flush-lines)
 471 (defalias 'count-matches 'how-many)
 472
 473
 474 (defun keep-lines-read-args (prompt)
 475   "Read arguments for `keep-lines' and friends.
 476 Prompt for a regexp with PROMPT.
 477 Value is a list, (REGEXP)."
 478   (list (read-from-minibuffer prompt nil nil nil
 479                               'regexp-history nil t)))
 480
 481 (defun keep-lines (regexp &optional rstart rend)
 482   "Delete all lines except those containing matches for REGEXP.
 483 A match split across lines preserves all the lines it lies in.
 484 Applies to all lines after point.
 485
 486 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 487 the matching is case-sensitive.
 488
 489 Second and third arg RSTART and REND specify the region to operate on.
 490
 491 Interactively, in Transient Mark mode when the mark is active, operate
 492 on the contents of the region.  Otherwise, operate from point to the
 493 end of the buffer."
 494
 495   (interactive
 496    (progn
 497      (barf-if-buffer-read-only)
 498      (keep-lines-read-args "Keep lines (containing match for regexp): ")))
 499   (if rstart
 500       (progn
 501         (goto-char (min rstart rend))
 502         (setq rend (copy-marker (max rstart rend))))
 503     (if (and transient-mark-mode mark-active)
 504         (setq rstart (region-beginning)
 505               rend (copy-marker (region-end)))
 506       (setq rstart (point)
 507             rend (point-max-marker)))
 508     (goto-char rstart))
 509   (save-excursion
 510     (or (bolp) (forward-line 1))
 511     (let ((start (point))
 512           (case-fold-search  (and case-fold-search
 513                                   (isearch-no-upper-case-p regexp t))))
 514       (while (< (point) rend)
 515         ;; Start is first char not preserved by previous match.
 516         (if (not (re-search-forward regexp rend 'move))
 517             (delete-region start rend)
 518           (let ((end (save-excursion (goto-char (match-beginning 0))
 519                                      (beginning-of-line)
 520                                      (point))))
 521             ;; Now end is first char preserved by the new match.
 522             (if (< start end)
 523                 (delete-region start end))))
 524
 525         (setq start (save-excursion (forward-line 1) (point)))
 526         ;; If the match was empty, avoid matching again at same place.
 527         (and (< (point) rend)
 528              (= (match-beginning 0) (match-end 0))
 529              (forward-char 1))))))
 530
 531
 532 (defun flush-lines (regexp &optional rstart rend)
 533   "Delete lines containing matches for REGEXP.
 534 If a match is split across lines, all the lines it lies in are deleted.
 535 Applies to lines after point.
 536
 537 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 538 the matching is case-sensitive.
 539
 540 Second and third arg RSTART and REND specify the region to operate on.
 541
 542 Interactively, in Transient Mark mode when the mark is active, operate
 543 on the contents of the region.  Otherwise, operate from point to the
 544 end of the buffer."
 545
 546   (interactive
 547    (progn
 548      (barf-if-buffer-read-only)
 549      (keep-lines-read-args "Flush lines (containing match for regexp): ")))
 550   (if rstart
 551       (progn
 552         (goto-char (min rstart rend))
 553         (setq rend (copy-marker (max rstart rend))))
 554     (if (and transient-mark-mode mark-active)
 555         (setq rstart (region-beginning)
 556               rend (copy-marker (region-end)))
 557       (setq rstart (point)
 558             rend (point-max-marker)))
 559     (goto-char rstart))
 560   (let ((case-fold-search (and case-fold-search
 561                                (isearch-no-upper-case-p regexp t))))
 562     (save-excursion
 563       (while (and (< (point) rend)
 564                   (re-search-forward regexp rend t))
 565         (delete-region (save-excursion (goto-char (match-beginning 0))
 566                                        (beginning-of-line)
 567                                        (point))
 568                        (progn (forward-line 1) (point)))))))
 569
 570
 571 (defun how-many (regexp &optional rstart rend)
 572   "Print number of matches for REGEXP following point.
 573
 574 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 575 the matching is case-sensitive.
 576
 577 Second and third arg RSTART and REND specify the region to operate on.
 578
 579 Interactively, in Transient Mark mode when the mark is active, operate
 580 on the contents of the region.  Otherwise, operate from point to the
 581 end of the buffer."
 582
 583   (interactive
 584    (keep-lines-read-args "How many matches for (regexp): "))
 585   (save-excursion
 586     (if rstart
 587         (goto-char (min rstart rend))
 588       (if (and transient-mark-mode mark-active)
 589           (setq rstart (region-beginning)
 590                 rend (copy-marker (region-end)))
 591         (setq rstart (point)
 592               rend (point-max-marker)))
 593       (goto-char rstart))
 594     (let ((count 0)
 595           opoint
 596           (case-fold-search (and case-fold-search
 597                                  (isearch-no-upper-case-p regexp t))))
 598       (while (and (< (point) rend)
 599                   (progn (setq opoint (point))
 600                          (re-search-forward regexp rend t)))
 601         (if (= opoint (point))
 602             (forward-char 1)
 603           (setq count (1+ count))))
 604       (message "%d occurrences" count))))
 605
 606 \f
 607 (defvar occur-mode-map
 608   (let ((map (make-sparse-keymap)))
 609     (define-key map [mouse-2] 'occur-mode-mouse-goto)
 610     (define-key map "\C-c\C-c" 'occur-mode-goto-occurrence)
 611     (define-key map "\C-m" 'occur-mode-goto-occurrence)
 612     (define-key map "o" 'occur-mode-goto-occurrence-other-window)
 613     (define-key map "\C-o" 'occur-mode-display-occurrence)
 614     (define-key map "\M-n" 'occur-next)
 615     (define-key map "\M-p" 'occur-prev)
 616     (define-key map "r" 'occur-rename-buffer)
 617     (define-key map "c" 'clone-buffer)
 618     (define-key map "g" 'revert-buffer)
 619     (define-key map "q" 'quit-window)
 620     (define-key map "z" 'kill-this-buffer)
 621     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
 622     map)
 623   "Keymap for `occur-mode'.")
 624
 625 (defvar occur-revert-arguments nil
 626   "Arguments to pass to `occur-1' to revert an Occur mode buffer.
 627 See `occur-revert-function'.")
 628
 629 (defcustom occur-mode-hook '(turn-on-font-lock)
 630   "Hook run when entering Occur mode."
 631   :type 'hook
 632   :group 'matching)
 633
 634 (defcustom occur-hook nil
 635   "Hook run when `occur' is called."
 636   :type 'hook
 637   :group 'matching)
 638
 639 (put 'occur-mode 'mode-class 'special)
 640 (defun occur-mode ()
 641   "Major mode for output from \\[occur].
 642 \\<occur-mode-map>Move point to one of the items in this buffer, then use
 643 \\[occur-mode-goto-occurrence] to go to the occurrence that the item refers to.
 644 Alternatively, click \\[occur-mode-mouse-goto] on an item to go to it.
 645
 646 \\{occur-mode-map}"
 647   (interactive)
 648   (kill-all-local-variables)
 649   (use-local-map occur-mode-map)
 650   (setq major-mode 'occur-mode)
 651   (setq mode-name "Occur")
 652   (set (make-local-variable 'revert-buffer-function) 'occur-revert-function)
 653   (make-local-variable 'occur-revert-arguments)
 654   (add-hook 'change-major-mode-hook 'font-lock-defontify nil t)
 655   (setq next-error-function 'occur-next-error)
 656   (run-hooks 'occur-mode-hook))
 657
 658 (defun occur-revert-function (ignore1 ignore2)
 659   "Handle `revert-buffer' for Occur mode buffers."
 660   (apply 'occur-1 (append occur-revert-arguments (list (buffer-name)))))
 661
 662 (defun occur-mode-mouse-goto (event)
 663   "In Occur mode, go to the occurrence whose line you click on."
 664   (interactive "e")
 665   (let (pos)
 666     (save-excursion
 667       (set-buffer (window-buffer (posn-window (event-end event))))
 668       (save-excursion
 669         (goto-char (posn-point (event-end event)))
 670         (setq pos (occur-mode-find-occurrence))))
 671     (pop-to-buffer (marker-buffer pos))
 672     (goto-char pos)))
 673
 674 (defun occur-mode-find-occurrence ()
 675   (let ((pos (get-text-property (point) 'occur-target)))
 676     (unless pos
 677       (error "No occurrence on this line"))
 678     (unless (buffer-live-p (marker-buffer pos))
 679       (error "Buffer for this occurrence was killed"))
 680     pos))
 681
 682 (defun occur-mode-goto-occurrence ()
 683   "Go to the occurrence the current line describes."
 684   (interactive)
 685   (let ((pos (occur-mode-find-occurrence)))
 686     (pop-to-buffer (marker-buffer pos))
 687     (goto-char pos)))
 688
 689 (defun occur-mode-goto-occurrence-other-window ()
 690   "Go to the occurrence the current line describes, in another window."
 691   (interactive)
 692   (let ((pos (occur-mode-find-occurrence)))
 693     (switch-to-buffer-other-window (marker-buffer pos))
 694     (goto-char pos)))
 695
 696 (defun occur-mode-display-occurrence ()
 697   "Display in another window the occurrence the current line describes."
 698   (interactive)
 699   (let ((pos (occur-mode-find-occurrence))
 700         window
 701         ;; Bind these to ensure `display-buffer' puts it in another window.
 702         same-window-buffer-names
 703         same-window-regexps)
 704     (setq window (display-buffer (marker-buffer pos)))
 705     ;; This is the way to set point in the proper window.
 706     (save-selected-window
 707       (select-window window)
 708       (goto-char pos))))
 709
 710 (defun occur-find-match (n search message)
 711   (if (not n) (setq n 1))
 712   (let ((r))
 713     (while (> n 0)
 714       (setq r (funcall search (point) 'occur-match))
 715       (and r
 716            (get-text-property r 'occur-match)
 717            (setq r (funcall search r 'occur-match)))
 718       (if r
 719           (goto-char r)
 720         (error message))
 721       (setq n (1- n)))))
 722
 723 (defun occur-next (&optional n)
 724   "Move to the Nth (default 1) next match in an Occur mode buffer."
 725   (interactive "p")
 726   (occur-find-match n #'next-single-property-change "No more matches"))
 727
 728 (defun occur-prev (&optional n)
 729   "Move to the Nth (default 1) previous match in an Occur mode buffer."
 730   (interactive "p")
 731   (occur-find-match n #'previous-single-property-change "No earlier matches"))
 732
 733 (defun occur-next-error (&optional argp reset)
 734   "Move to the Nth (default 1) next match in an Occur mode buffer.
 735 Compatibility function for \\[next-error] invocations."
 736   (interactive "p")
 737   ;; we need to run occur-find-match from within the Occur buffer
 738   (with-current-buffer
 739       (if (next-error-buffer-p (current-buffer))
 740           (current-buffer)
 741         (next-error-find-buffer nil nil (lambda() (eq major-mode 'occur-mode))))
 742
 743     (when reset
 744       (goto-char (point-min)))
 745     (occur-find-match
 746      (abs (prefix-numeric-value argp))
 747      (if (> 0 (prefix-numeric-value argp))
 748          #'previous-single-property-change
 749        #'next-single-property-change)
 750      "No more matches")
 751     ;; In case the *Occur* buffer is visible in a nonselected window.
 752     (set-window-point (get-buffer-window (current-buffer)) (point))
 753     (occur-mode-goto-occurrence)))
 754 \f
 755 (defcustom list-matching-lines-default-context-lines 0
 756   "*Default number of context lines included around `list-matching-lines' matches.
 757 A negative number means to include that many lines before the match.
 758 A positive number means to include that many lines both before and after."
 759   :type 'integer
 760   :group 'matching)
 761
 762 (defalias 'list-matching-lines 'occur)
 763
 764 (defcustom list-matching-lines-face 'bold
 765   "*Face used by \\[list-matching-lines] to show the text that matches.
 766 If the value is nil, don't highlight the matching portions specially."
 767   :type 'face
 768   :group 'matching)
 769
 770 (defcustom list-matching-lines-buffer-name-face 'underline
 771   "*Face used by \\[list-matching-lines] to show the names of buffers.
 772 If the value is nil, don't highlight the buffer names specially."
 773   :type 'face
 774   :group 'matching)
 775
 776 (defun occur-accumulate-lines (count &optional keep-props)
 777   (save-excursion
 778     (let ((forwardp (> count 0))
 779           (result nil))
 780       (while (not (or (zerop count)
 781                       (if forwardp
 782                           (eobp)
 783                         (bobp))))
 784         (setq count (+ count (if forwardp -1 1)))
 785         (push
 786          (funcall (if keep-props
 787                       #'buffer-substring
 788                     #'buffer-substring-no-properties)
 789           (line-beginning-position)
 790           (line-end-position))
 791          result)
 792         (forward-line (if forwardp 1 -1)))
 793       (nreverse result))))
 794
 795 (defun occur-read-primary-args ()
 796   (list (let* ((default (car regexp-history))
 797                (input
 798                 (read-from-minibuffer
 799                  (if default
 800                      (format "List lines matching regexp (default `%s'): "
 801                              (query-replace-descr default))
 802                    "List lines matching regexp: ")
 803                  nil
 804                  nil
 805                  nil
 806                  'regexp-history
 807                  default)))
 808           (if (equal input "")
 809               default
 810             input))
 811         (when current-prefix-arg
 812           (prefix-numeric-value current-prefix-arg))))
 813
 814 (defun occur-rename-buffer (&optional unique-p)
 815   "Rename the current *Occur* buffer to *Occur: original-buffer-name*.
 816 Here `original-buffer-name' is the buffer name were occur was originally run.
 817 When given the prefix argument, the renaming will not clobber the existing
 818 buffer(s) of that name, but use `generate-new-buffer-name' instead.
 819 You can add this to `occur-hook' if you always want a separate *Occur*
 820 buffer for each buffer where you invoke `occur'."
 821   (interactive "P")
 822   (with-current-buffer
 823       (if (eq major-mode 'occur-mode) (current-buffer) (get-buffer "*Occur*"))
 824     (rename-buffer (concat "*Occur: "
 825                            (mapconcat #'buffer-name
 826                                       (car (cddr occur-revert-arguments)) "/")
 827                            "*")
 828                    unique-p)))
 829
 830 (defun occur (regexp &optional nlines)
 831   "Show all lines in the current buffer containing a match for REGEXP.
 832
 833 If a match spreads across multiple lines, all those lines are shown.
 834
 835 Each line is displayed with NLINES lines before and after, or -NLINES
 836 before if NLINES is negative.
 837 NLINES defaults to `list-matching-lines-default-context-lines'.
 838 Interactively it is the prefix arg.
 839
 840 The lines are shown in a buffer named `*Occur*'.
 841 It serves as a menu to find any of the occurrences in this buffer.
 842 \\<occur-mode-map>\\[describe-mode] in that buffer will explain how.
 843
 844 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 845 the matching is case-sensitive."
 846   (interactive (occur-read-primary-args))
 847   (occur-1 regexp nlines (list (current-buffer))))
 848
 849 (defun multi-occur (bufs regexp &optional nlines)
 850   "Show all lines in buffers BUFS containing a match for REGEXP.
 851 This function acts on multiple buffers; otherwise, it is exactly like
 852 `occur'."
 853   (interactive
 854    (cons
 855     (let* ((bufs (list (read-buffer "First buffer to search: "
 856                                     (current-buffer) t)))
 857            (buf nil)
 858            (ido-ignore-item-temp-list bufs))
 859       (while (not (string-equal
 860                    (setq buf (read-buffer
 861                               (if (eq read-buffer-function 'ido-read-buffer)
 862                                   "Next buffer to search (C-j to end): "
 863                                 "Next buffer to search (RET to end): ")
 864                               nil t))
 865                    ""))
 866         (add-to-list 'bufs buf)
 867         (setq ido-ignore-item-temp-list bufs))
 868       (nreverse (mapcar #'get-buffer bufs)))
 869     (occur-read-primary-args)))
 870   (occur-1 regexp nlines bufs))
 871
 872 (defun multi-occur-by-filename-regexp (bufregexp regexp &optional nlines)
 873   "Show all lines matching REGEXP in buffers named by BUFREGEXP.
 874 See also `multi-occur'."
 875   (interactive
 876    (cons
 877     (let* ((default (car regexp-history))
 878            (input
 879             (read-from-minibuffer
 880              "List lines in buffers whose filename matches regexp: "
 881              nil
 882              nil
 883              nil
 884              'regexp-history)))
 885       (if (equal input "")
 886           default
 887         input))
 888     (occur-read-primary-args)))
 889   (when bufregexp
 890     (occur-1 regexp nlines
 891              (delq nil
 892                    (mapcar (lambda (buf)
 893                              (when (and (buffer-file-name buf)
 894                                         (string-match bufregexp
 895                                                       (buffer-file-name buf)))
 896                                buf))
 897                            (buffer-list))))))
 898
 899 (defun occur-1 (regexp nlines bufs &optional buf-name)
 900   (unless buf-name
 901     (setq buf-name "*Occur*"))
 902   (let ((occur-buf (get-buffer-create buf-name))
 903         (made-temp-buf nil)
 904         (active-bufs (delq nil (mapcar #'(lambda (buf)
 905                                            (when (buffer-live-p buf) buf))
 906                                        bufs))))
 907     ;; Handle the case where one of the buffers we're searching is the
 908     ;; *Occur* buffer itself.
 909     (when (memq occur-buf bufs)
 910       (setq occur-buf (with-current-buffer occur-buf
 911                         (clone-buffer "*Occur-temp*"))
 912             made-temp-buf t))
 913     (with-current-buffer occur-buf
 914       (setq buffer-read-only nil)
 915       (occur-mode)
 916       (erase-buffer)
 917       (let ((count (occur-engine
 918                     regexp active-bufs occur-buf
 919                     (or nlines list-matching-lines-default-context-lines)
 920                     (and case-fold-search
 921                          (isearch-no-upper-case-p regexp t))
 922                     list-matching-lines-buffer-name-face
 923                     nil list-matching-lines-face t)))
 924         (let* ((bufcount (length active-bufs))
 925                (diff (- (length bufs) bufcount)))
 926           (message "Searched %d buffer%s%s; %s match%s for `%s'"
 927                    bufcount (if (= bufcount 1) "" "s")
 928                    (if (zerop diff) "" (format " (%d killed)" diff))
 929                    (if (zerop count) "no" (format "%d" count))
 930                    (if (= count 1) "" "es")
 931                    regexp))
 932         ;; If we had to make a temporary buffer, make it the *Occur*
 933         ;; buffer now.
 934         (when made-temp-buf
 935           (with-current-buffer (get-buffer buf-name)
 936             (kill-buffer (current-buffer)))
 937           (rename-buffer buf-name))
 938         (setq occur-revert-arguments (list regexp nlines bufs)
 939               buffer-read-only t)
 940         (if (> count 0)
 941             (progn
 942               (display-buffer occur-buf)
 943               (setq next-error-last-buffer occur-buf))
 944           (kill-buffer occur-buf)))
 945       (run-hooks 'occur-hook))))
 946
 947 (defun occur-engine-add-prefix (lines)
 948   (mapcar
 949    #'(lambda (line)
 950        (concat "       :" line "\n"))
 951    lines))
 952
 953 (defun occur-engine (regexp buffers out-buf nlines case-fold-search
 954                             title-face prefix-face match-face keep-props)
 955   (with-current-buffer out-buf
 956     (setq buffer-read-only nil)
 957     (let ((globalcount 0)
 958           (coding nil))
 959       ;; Map over all the buffers
 960       (dolist (buf buffers)
 961         (when (buffer-live-p buf)
 962           (let ((matches 0)     ;; count of matched lines
 963                 (lines 1)       ;; line count
 964                 (matchbeg 0)
 965                 (origpt nil)
 966                 (begpt nil)
 967                 (endpt nil)
 968                 (marker nil)
 969                 (curstring "")
 970                 (headerpt (with-current-buffer out-buf (point))))
 971             (save-excursion
 972               (set-buffer buf)
 973               (or coding
 974                   ;; Set CODING only if the current buffer locally
 975                   ;; binds buffer-file-coding-system.
 976                   (not (local-variable-p 'buffer-file-coding-system))
 977                   (setq coding buffer-file-coding-system))
 978               (save-excursion
 979                 (goto-char (point-min)) ;; begin searching in the buffer
 980                 (while (not (eobp))
 981                   (setq origpt (point))
 982                   (when (setq endpt (re-search-forward regexp nil t))
 983                     (setq matches (1+ matches)) ;; increment match count
 984                     (setq matchbeg (match-beginning 0))
 985                     (setq begpt (save-excursion
 986                                   (goto-char matchbeg)
 987                                   (line-beginning-position)))
 988                     (setq lines (+ lines (1- (count-lines origpt endpt))))
 989                     (setq marker (make-marker))
 990                     (set-marker marker matchbeg)
 991                     (setq curstring (buffer-substring begpt
 992                                                       (line-end-position)))
 993                     ;; Depropertize the string, and maybe
 994                     ;; highlight the matches
 995                     (let ((len (length curstring))
 996                           (start 0))
 997                       (unless keep-props
 998                         (set-text-properties 0 len nil curstring))
 999                       (while (and (< start len)
1000                                   (string-match regexp curstring start))
1001                         (add-text-properties (match-beginning 0)
1002                                              (match-end 0)
1003                                              (append
1004                                               `(occur-match t)
1005                                               (when match-face
1006                                                 ;; Use `face' rather than
1007                                                 ;; `font-lock-face' here
1008                                                 ;; so as to override faces
1009                                                 ;; copied from the buffer.
1010                                                 `(face ,match-face)))
1011                                              curstring)
1012                         (setq start (match-end 0))))
1013                     ;; Generate the string to insert for this match
1014                     (let* ((out-line
1015                             (concat
1016                              ;; Using 7 digits aligns tabs properly.
1017                              (apply #'propertize (format "%7d:" lines)
1018                                     (append
1019                                      (when prefix-face
1020                                        `(font-lock-face prefix-face))
1021                                      '(occur-prefix t)))
1022                              curstring
1023                              "\n"))
1024                            (data
1025                             (if (= nlines 0)
1026                                 ;; The simple display style
1027                                 out-line
1028                               ;; The complex multi-line display
1029                               ;; style.  Generate a list of lines,
1030                               ;; concatenate them all together.
1031                               (apply #'concat
1032                                      (nconc
1033                                       (occur-engine-add-prefix (nreverse (cdr (occur-accumulate-lines (- (1+ (abs nlines))) keep-props))))
1034                                       (list out-line)
1035                                       (if (> nlines 0)
1036                                           (occur-engine-add-prefix
1037                                            (cdr (occur-accumulate-lines (1+ nlines) keep-props)))))))))
1038                       ;; Actually insert the match display data
1039                       (with-current-buffer out-buf
1040                         (let ((beg (point))
1041                               (end (progn (insert data) (point))))
1042                           (unless (= nlines 0)
1043                             (insert "-------\n"))
1044                           (add-text-properties
1045                            beg end
1046                            `(occur-target ,marker help-echo "mouse-2: go to this occurrence"))
1047                           ;; We don't put `mouse-face' on the newline,
1048                           ;; because that loses.
1049                           (add-text-properties beg (1- end) '(mouse-face highlight)))))
1050                     (goto-char endpt))
1051                   (if endpt
1052                       (progn
1053                         (setq lines (1+ lines))
1054                         ;; On to the next match...
1055                         (forward-line 1))
1056                     (goto-char (point-max))))))
1057             (when (not (zerop matches)) ;; is the count zero?
1058               (setq globalcount (+ globalcount matches))
1059               (with-current-buffer out-buf
1060                 (goto-char headerpt)
1061                 (let ((beg (point))
1062                       end)
1063                   (insert (format "%d match%s for \"%s\" in buffer: %s\n"
1064                                   matches (if (= matches 1) "" "es")
1065                                   regexp (buffer-name buf)))
1066                   (setq end (point))
1067                   (add-text-properties beg end
1068                                        (append
1069                                         (when title-face
1070                                           `(font-lock-face ,title-face))
1071                                         `(occur-title ,buf))))
1072                 (goto-char (point-min)))))))
1073       (if coding
1074           ;; CODING is buffer-file-coding-system of the first buffer
1075           ;; that locally binds it.  Let's use it also for the output
1076           ;; buffer.
1077           (set-buffer-file-coding-system coding))
1078       ;; Return the number of matches
1079       globalcount)))
1080
1081 \f
1082 ;; It would be nice to use \\[...], but there is no reasonable way
1083 ;; to make that display both SPC and Y.
1084 (defconst query-replace-help
1085   "Type Space or `y' to replace one match, Delete or `n' to skip to next,
1086 RET or `q' to exit, Period to replace one match and exit,
1087 Comma to replace but not move point immediately,
1088 C-r to enter recursive edit (\\[exit-recursive-edit] to get out again),
1089 C-w to delete match and recursive edit,
1090 C-l to clear the screen, redisplay, and offer same replacement again,
1091 ! to replace all remaining matches with no more questions,
1092 ^ to move point back to previous match,
1093 E to edit the replacement string"
1094   "Help message while in `query-replace'.")
1095
1096 (defvar query-replace-map (make-sparse-keymap)
1097   "Keymap that defines the responses to questions in `query-replace'.
1098 The \"bindings\" in this map are not commands; they are answers.
1099 The valid answers include `act', `skip', `act-and-show',
1100 `exit', `act-and-exit', `edit', `delete-and-edit', `recenter',
1101 `automatic', `backup', `exit-prefix', and `help'.")
1102
1103 (define-key query-replace-map " " 'act)
1104 (define-key query-replace-map "\d" 'skip)
1105 (define-key query-replace-map [delete] 'skip)
1106 (define-key query-replace-map [backspace] 'skip)
1107 (define-key query-replace-map "y" 'act)
1108 (define-key query-replace-map "n" 'skip)
1109 (define-key query-replace-map "Y" 'act)
1110 (define-key query-replace-map "N" 'skip)
1111 (define-key query-replace-map "e" 'edit-replacement)
1112 (define-key query-replace-map "E" 'edit-replacement)
1113 (define-key query-replace-map "," 'act-and-show)
1114 (define-key query-replace-map "q" 'exit)
1115 (define-key query-replace-map "\r" 'exit)
1116 (define-key query-replace-map [return] 'exit)
1117 (define-key query-replace-map "." 'act-and-exit)
1118 (define-key query-replace-map "\C-r" 'edit)
1119 (define-key query-replace-map "\C-w" 'delete-and-edit)
1120 (define-key query-replace-map "\C-l" 'recenter)
1121 (define-key query-replace-map "!" 'automatic)
1122 (define-key query-replace-map "^" 'backup)
1123 (define-key query-replace-map "\C-h" 'help)
1124 (define-key query-replace-map [f1] 'help)
1125 (define-key query-replace-map [help] 'help)
1126 (define-key query-replace-map "?" 'help)
1127 (define-key query-replace-map "\C-g" 'quit)
1128 (define-key query-replace-map "\C-]" 'quit)
1129 (define-key query-replace-map "\e" 'exit-prefix)
1130 (define-key query-replace-map [escape] 'exit-prefix)
1131
1132 (defun replace-match-string-symbols (n)
1133   "Process a list (and any sub-lists), expanding certain symbols.
1134 Symbol  Expands To
1135 N     (match-string N)           (where N is a string of digits)
1136 #N    (string-to-number (match-string N))
1137 &     (match-string 0)
1138 #&    (string-to-number (match-string 0))
1139 #     replace-count
1140
1141 Note that these symbols must be preceeded by a backslash in order to
1142 type them."
1143   (while n
1144     (cond
1145      ((consp (car n))
1146       (replace-match-string-symbols (car n))) ;Process sub-list
1147      ((symbolp (car n))
1148       (let ((name (symbol-name (car n))))
1149         (cond
1150          ((string-match "^[0-9]+$" name)
1151           (setcar n (list 'match-string (string-to-number name))))
1152          ((string-match "^#[0-9]+$" name)
1153           (setcar n (list 'string-to-number
1154                           (list 'match-string
1155                                 (string-to-number (substring name 1))))))
1156          ((string= "&" name)
1157           (setcar n '(match-string 0)))
1158          ((string= "#&" name)
1159           (setcar n '(string-to-number (match-string 0))))
1160          ((string= "#" name)
1161           (setcar n 'replace-count))))))
1162     (setq n (cdr n))))
1163
1164 (defun replace-eval-replacement (expression replace-count)
1165   (let ((replacement (eval expression)))
1166     (if (stringp replacement)
1167         replacement
1168       (prin1-to-string replacement t))))
1169
1170 (defun replace-quote (replacement)
1171   "Quote a replacement string.
1172 This just doubles all backslashes in REPLACEMENT and
1173 returns the resulting string.  If REPLACEMENT is not
1174 a string, it is first passed through `prin1-to-string'
1175 with the `noescape' argument set.
1176
1177 `match-data' is preserved across the call."
1178   (save-match-data
1179     (replace-regexp-in-string "\\\\" "\\\\"
1180                               (if (stringp replacement)
1181                                   replacement
1182                                 (prin1-to-string replacement t))
1183                               t t)))
1184
1185 (defun replace-loop-through-replacements (data replace-count)
1186   ;; DATA is a vector contaning the following values:
1187   ;;   0 next-rotate-count
1188   ;;   1 repeat-count
1189   ;;   2 next-replacement
1190   ;;   3 replacements
1191   (if (= (aref data 0) replace-count)
1192       (progn
1193         (aset data 0 (+ replace-count (aref data 1)))
1194         (let ((next (cdr (aref data 2))))
1195           (aset data 2 (if (consp next) next (aref data 3))))))
1196   (car (aref data 2)))
1197
1198 (defun replace-match-data (integers reuse &optional new)
1199   "Like `match-data', but markers in REUSE get invalidated.
1200 If NEW is non-NIL, it is set and returned instead of fresh data,
1201 but coerced to the correct value of INTEGERS."
1202   (or (and new
1203            (progn
1204              (set-match-data new)
1205              (and (eq new reuse)
1206                   (eq (null integers) (markerp (car reuse)))
1207                   new)))
1208       (match-data integers
1209                   (prog1 reuse
1210                     (while reuse
1211                       (if (markerp (car reuse))
1212                           (set-marker (car reuse) nil))
1213                       (setq reuse (cdr reuse)))))))
1214
1215 (defun replace-match-maybe-edit (newtext fixedcase literal noedit match-data)
1216   "Make a replacement with `replace-match', editing `\\?'.
1217 NEWTEXT, FIXEDCASE, LITERAL are just passed on.  If NOEDIT is true, no
1218 check for `\\?' is made to save time.  MATCH-DATA is used for the
1219 replacement.  In case editing is done, it is changed to use markers.
1220
1221 The return value is non-NIL if there has been no `\\?' or NOEDIT was
1222 passed in.  If LITERAL is set, no checking is done, anyway."
1223   (unless (or literal noedit)
1224     (setq noedit t)
1225     (while (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\(\\\\\\?\\)"
1226                          newtext)
1227       (setq newtext
1228             (read-input "Edit replacement string: "
1229                         (prog1
1230                             (cons
1231                              (replace-match "" t t newtext 3)
1232                              (1+ (match-beginning 3)))
1233                           (setq match-data
1234                                 (replace-match-data
1235                                  nil match-data match-data))))
1236             noedit nil)))
1237   (set-match-data match-data)
1238   (replace-match newtext fixedcase literal)
1239   noedit)
1240
1241 (defun perform-replace (from-string replacements
1242                         query-flag regexp-flag delimited-flag
1243                         &optional repeat-count map start end)
1244   "Subroutine of `query-replace'.  Its complexity handles interactive queries.
1245 Don't use this in your own program unless you want to query and set the mark
1246 just as `query-replace' does.  Instead, write a simple loop like this:
1247
1248   (while (re-search-forward \"foo[ \\t]+bar\" nil t)
1249     (replace-match \"foobar\" nil nil))
1250
1251 which will run faster and probably do exactly what you want.  Please
1252 see the documentation of `replace-match' to find out how to simulate
1253 `case-replace'.
1254
1255 This function returns nil if and only if there were no matches to
1256 make, or the user didn't cancel the call."
1257   (or map (setq map query-replace-map))
1258   (and query-flag minibuffer-auto-raise
1259        (raise-frame (window-frame (minibuffer-window))))
1260   (let ((nocasify (not (and case-fold-search case-replace
1261                             (string-equal from-string
1262                                           (downcase from-string)))))
1263         (case-fold-search (and case-fold-search
1264                                (string-equal from-string
1265                                              (downcase from-string))))
1266         (literal (or (not regexp-flag) (eq regexp-flag 'literal)))
1267         (search-function (if regexp-flag 're-search-forward 'search-forward))
1268         (search-string from-string)
1269         (real-match-data nil)           ; the match data for the current match
1270         (next-replacement nil)
1271         (noedit nil)
1272         (keep-going t)
1273         (stack nil)
1274         (replace-count 0)
1275         (nonempty-match nil)
1276
1277         ;; If non-nil, it is marker saying where in the buffer to stop.
1278         (limit nil)
1279
1280         ;; Data for the next match.  If a cons, it has the same format as
1281         ;; (match-data); otherwise it is t if a match is possible at point.
1282         (match-again t)
1283
1284         (message
1285          (if query-flag
1286              (substitute-command-keys
1287               "Query replacing %s with %s: (\\<query-replace-map>\\[help] for help) "))))
1288
1289     ;; If region is active, in Transient Mark mode, operate on region.
1290     (when start
1291       (setq limit (copy-marker (max start end)))
1292       (goto-char (min start end))
1293       (deactivate-mark))
1294
1295     ;; REPLACEMENTS is either a string, a list of strings, or a cons cell
1296     ;; containing a function and its first argument.  The function is
1297     ;; called to generate each replacement like this:
1298     ;;   (funcall (car replacements) (cdr replacements) replace-count)
1299     ;; It must return a string.
1300     (cond
1301      ((stringp replacements)
1302       (setq next-replacement replacements
1303             replacements     nil))
1304      ((stringp (car replacements)) ; If it isn't a string, it must be a cons
1305       (or repeat-count (setq repeat-count 1))
1306       (setq replacements (cons 'replace-loop-through-replacements
1307                                (vector repeat-count repeat-count
1308                                        replacements replacements)))))
1309
1310     (if delimited-flag
1311         (setq search-function 're-search-forward
1312               search-string (concat "\\b"
1313                                     (if regexp-flag from-string
1314                                       (regexp-quote from-string))
1315                                     "\\b")))
1316     (push-mark)
1317     (undo-boundary)
1318     (unwind-protect
1319         ;; Loop finding occurrences that perhaps should be replaced.
1320         (while (and keep-going
1321                     (not (or (eobp) (and limit (>= (point) limit))))
1322                     ;; Use the next match if it is already known;
1323                     ;; otherwise, search for a match after moving forward
1324                     ;; one char if progress is required.
1325                     (setq real-match-data
1326                           (if (consp match-again)
1327                               (progn (goto-char (nth 1 match-again))
1328                                      (replace-match-data t
1329                                       real-match-data
1330                                       match-again))
1331                             (and (or match-again
1332                                      ;; MATCH-AGAIN non-nil means we
1333                                      ;; accept an adjacent match.  If
1334                                      ;; we don't, move one char to the
1335                                      ;; right.  This takes us a
1336                                      ;; character too far at the end,
1337                                      ;; but this is undone after the
1338                                      ;; while-loop.
1339                                      (progn
1340                                        (forward-char 1)
1341                                        (not (or (eobp)
1342                                                 (and limit (>= (point) limit))))))
1343                                  (funcall search-function search-string limit t)
1344                                  ;; For speed, use only integers and
1345                                  ;; reuse the list used last time.
1346                                  (replace-match-data t real-match-data)))))
1347           ;; Optionally ignore matches that have a read-only property.
1348           (unless (and query-replace-skip-read-only
1349                        (text-property-not-all
1350                         (match-beginning 0) (match-end 0)
1351                         'read-only nil))
1352
1353             ;; Record whether the match is nonempty, to avoid an infinite loop
1354             ;; repeatedly matching the same empty string.
1355             (setq nonempty-match
1356                   (/= (nth 0 real-match-data) (nth 1 real-match-data)))
1357
1358             ;; If the match is empty, record that the next one can't be
1359             ;; adjacent.
1360
1361             ;; Otherwise, if matching a regular expression, do the next
1362             ;; match now, since the replacement for this match may
1363             ;; affect whether the next match is adjacent to this one.
1364             ;; If that match is empty, don't use it.
1365             (setq match-again
1366                   (and nonempty-match
1367                        (or (not regexp-flag)
1368                            (and (looking-at search-string)
1369                                 (let ((match (match-data)))
1370                                   (and (/= (nth 0 match) (nth 1 match))
1371                                        match))))))
1372
1373             ;; Calculate the replacement string, if necessary.
1374             (when replacements
1375               (set-match-data real-match-data)
1376               (setq next-replacement
1377                     (funcall (car replacements) (cdr replacements)
1378                              replace-count)
1379                     noedit nil))
1380             (if (not query-flag)
1381                 (let ((inhibit-read-only
1382                        query-replace-skip-read-only))
1383                   (unless (or literal noedit)
1384                     (replace-highlight (nth 0 real-match-data)
1385                                        (nth 1 real-match-data)))
1386                   (setq noedit
1387                         (replace-match-maybe-edit
1388                          next-replacement nocasify literal
1389                          noedit real-match-data)
1390                         replace-count (1+ replace-count)))
1391               (undo-boundary)
1392               (let (done replaced key def)
1393                 ;; Loop reading commands until one of them sets done,
1394                 ;; which means it has finished handling this
1395                 ;; occurrence.  Any command that sets `done' should
1396                 ;; leave behind proper match data for the stack.
1397                 ;; Commands not setting `done' need to adjust
1398                 ;; `real-match-data'.
1399                 (while (not done)
1400                   (set-match-data real-match-data)
1401                   (replace-highlight (match-beginning 0) (match-end 0))
1402                   ;; Bind message-log-max so we don't fill up the message log
1403                   ;; with a bunch of identical messages.
1404                   (let ((message-log-max nil))
1405                     (message message
1406                              (query-replace-descr from-string)
1407                              (query-replace-descr next-replacement)))
1408                   (setq key (read-event))
1409                   ;; Necessary in case something happens during read-event
1410                   ;; that clobbers the match data.
1411                   (set-match-data real-match-data)
1412                   (setq key (vector key))
1413                   (setq def (lookup-key map key))
1414                   ;; Restore the match data while we process the command.
1415                   (cond ((eq def 'help)
1416                          (with-output-to-temp-buffer "*Help*"
1417                            (princ
1418                             (concat "Query replacing "
1419                                     (if regexp-flag "regexp " "")
1420                                     from-string " with "
1421                                     next-replacement ".\n\n"
1422                                     (substitute-command-keys
1423                                      query-replace-help)))
1424                            (with-current-buffer standard-output
1425                              (help-mode))))
1426                         ((eq def 'exit)
1427                          (setq keep-going nil)
1428                          (setq done t))
1429                         ((eq def 'backup)
1430                          (if stack
1431                              (let ((elt (pop stack)))
1432                                (goto-char (nth 0 elt))
1433                                (setq replaced (nth 1 elt)
1434                                      real-match-data
1435                                      (replace-match-data
1436                                       t real-match-data
1437                                       (nth 2 elt))))
1438                            (message "No previous match")
1439                            (ding 'no-terminate)
1440                            (sit-for 1)))
1441                         ((eq def 'act)
1442                          (or replaced
1443                              (setq noedit
1444                                    (replace-match-maybe-edit
1445                                     next-replacement nocasify literal
1446                                     noedit real-match-data)
1447                                    replace-count (1+ replace-count)))
1448                          (setq done t replaced t))
1449                         ((eq def 'act-and-exit)
1450                          (or replaced
1451                              (setq noedit
1452                                    (replace-match-maybe-edit
1453                                     next-replacement nocasify literal
1454                                     noedit real-match-data)
1455                                    replace-count (1+ replace-count)))
1456                          (setq keep-going nil)
1457                          (setq done t replaced t))
1458                         ((eq def 'act-and-show)
1459                          (if (not replaced)
1460                              (setq noedit
1461                                    (replace-match-maybe-edit
1462                                     next-replacement nocasify literal
1463                                     noedit real-match-data)
1464                                    replace-count (1+ replace-count)
1465                                    real-match-data (replace-match-data
1466                                                     t real-match-data)
1467                                    replaced t)))
1468                         ((eq def 'automatic)
1469                          (or replaced
1470                              (setq noedit
1471                                    (replace-match-maybe-edit
1472                                     next-replacement nocasify literal
1473                                     noedit real-match-data)
1474                                    replace-count (1+ replace-count)))
1475                          (setq done t query-flag nil replaced t))
1476                         ((eq def 'skip)
1477                          (setq done t))
1478                         ((eq def 'recenter)
1479                          (recenter nil))
1480                         ((eq def 'edit)
1481                          (let ((opos (point-marker)))
1482                            (setq real-match-data (replace-match-data
1483                                                   nil real-match-data
1484                                                   real-match-data))
1485                            (goto-char (match-beginning 0))
1486                            (save-excursion
1487                              (save-window-excursion
1488                                (recursive-edit)))
1489                            (goto-char opos)
1490                            (set-marker opos nil))
1491                          ;; Before we make the replacement,
1492                          ;; decide whether the search string
1493                          ;; can match again just after this match.
1494                          (if (and regexp-flag nonempty-match)
1495                              (setq match-again (and (looking-at search-string)
1496                                                     (match-data)))))
1497                         ;; Edit replacement.
1498                         ((eq def 'edit-replacement)
1499                          (setq real-match-data (replace-match-data
1500                                                 nil real-match-data
1501                                                 real-match-data)
1502                                next-replacement
1503                                (read-input "Edit replacement string: "
1504                                            next-replacement)
1505                                noedit nil)
1506                          (if replaced
1507                              (set-match-data real-match-data)
1508                            (setq noedit
1509                                  (replace-match-maybe-edit
1510                                   next-replacement nocasify literal noedit
1511                                   real-match-data)
1512                                  replaced t))
1513                          (setq done t))
1514
1515                         ((eq def 'delete-and-edit)
1516                          (replace-match "" t t)
1517                          (setq real-match-data (replace-match-data
1518                                                 nil real-match-data))
1519                          (replace-dehighlight)
1520                          (save-excursion (recursive-edit))
1521                          (setq replaced t))
1522                         ;; Note: we do not need to treat `exit-prefix'
1523                         ;; specially here, since we reread
1524                         ;; any unrecognized character.
1525                         (t
1526                          (setq this-command 'mode-exited)
1527                          (setq keep-going nil)
1528                          (setq unread-command-events
1529                                (append (listify-key-sequence key)
1530                                        unread-command-events))
1531                          (setq done t))))
1532                 ;; Record previous position for ^ when we move on.
1533                 ;; Change markers to numbers in the match data
1534                 ;; since lots of markers slow down editing.
1535                 (push (list (point) replaced
1536 ;;; If the replacement has already happened, all we need is the
1537 ;;; current match start and end.  We could get this with a trivial
1538 ;;; match like
1539 ;;; (save-excursion (goto-char (match-beginning 0))
1540 ;;;                 (search-forward (match-string 0))
1541 ;;;                 (match-data t))
1542 ;;; if we really wanted to avoid manually constructing match data.
1543 ;;; Adding current-buffer is necessary so that match-data calls can
1544 ;;; return markers which are appropriate for editing.
1545                             (if replaced
1546                                 (list
1547                                  (match-beginning 0)
1548                                  (match-end 0)
1549                                  (current-buffer))
1550                               (match-data t)))
1551                       stack)))))
1552
1553       ;; The code preventing adjacent regexp matches in the condition
1554       ;; of the while-loop above will haven taken us one character
1555       ;; beyond the last replacement.  Undo that.
1556       (when (and regexp-flag (not match-again) (> replace-count 0))
1557         (backward-char 1))
1558
1559       (replace-dehighlight))
1560     (or unread-command-events
1561         (message "Replaced %d occurrence%s"
1562                  replace-count
1563                  (if (= replace-count 1) "" "s")))
1564     (and keep-going stack)))
1565
1566 (defcustom query-replace-highlight t
1567   "*Non-nil means to highlight words during query replacement."
1568   :type 'boolean
1569   :group 'matching)
1570
1571 (defvar replace-overlay nil)
1572
1573 (defun replace-dehighlight ()
1574   (and replace-overlay
1575        (progn
1576          (delete-overlay replace-overlay)
1577          (setq replace-overlay nil))))
1578
1579 (defun replace-highlight (start end)
1580   (and query-replace-highlight
1581        (if replace-overlay
1582            (move-overlay replace-overlay start end (current-buffer))
1583          (setq replace-overlay (make-overlay start end))
1584          (overlay-put replace-overlay 'face
1585                       (if (facep 'query-replace)
1586                           'query-replace 'region)))))
1587
1588 ;; arch-tag: 16b4cd61-fd40-497b-b86f-b667c4cf88e4
1589 ;;; replace.el ends here