lisp/server.el

   1 ;;; server.el --- Lisp code for GNU Emacs running as server process
   2
   3 ;; Copyright (C) 1986, 1987, 1992, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   4 ;;   2001, 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: William Sommerfeld <wesommer@athena.mit.edu>
   7 ;; Maintainer: FSF
   8 ;; Keywords: processes
   9
  10 ;; Changes by peck@sun.com and by rms.
  11 ;; Overhaul by Karoly Lorentey <lorentey@elte.hu> for multi-tty support.
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  28 ;; Boston, MA 02110-1301, USA.
  29
  30 ;;; Commentary:
  31
  32 ;; This Lisp code is run in Emacs when it is to operate as
  33 ;; a server for other processes.
  34
  35 ;; Load this library and do M-x server-edit to enable Emacs as a server.
  36 ;; Emacs opens up a socket for communication with clients.  If there are no
  37 ;; client buffers to edit, server-edit acts like (switch-to-buffer
  38 ;; (other-buffer))
  39
  40 ;; When some other program runs "the editor" to edit a file,
  41 ;; "the editor" can be the Emacs client program ../lib-src/emacsclient.
  42 ;; This program transmits the file names to Emacs through
  43 ;; the server subprocess, and Emacs visits them and lets you edit them.
  44
  45 ;; Note that any number of clients may dispatch files to Emacs to be edited.
  46
  47 ;; When you finish editing a Server buffer, again call server-edit
  48 ;; to mark that buffer as done for the client and switch to the next
  49 ;; Server buffer.  When all the buffers for a client have been edited
  50 ;; and exited with server-edit, the client "editor" will return
  51 ;; to the program that invoked it.
  52
  53 ;; Your editing commands and Emacs's display output go to and from
  54 ;; the terminal in the usual way.  Thus, server operation is possible
  55 ;; only when Emacs can talk to the terminal at the time you invoke
  56 ;; the client.  This is possible in four cases:
  57
  58 ;; 1. On a window system, where Emacs runs in one window and the
  59 ;; program that wants to use "the editor" runs in another.
  60
  61 ;; 2. On a multi-terminal system, where Emacs runs on one terminal and the
  62 ;; program that wants to use "the editor" runs on another.
  63
  64 ;; 3. When the program that wants to use "the editor" is running
  65 ;; as a subprocess of Emacs.
  66
  67 ;; 4. On a system with job control, when Emacs is suspended, the program
  68 ;; that wants to use "the editor" will stop and display
  69 ;; "Waiting for Emacs...".  It can then be suspended, and Emacs can be
  70 ;; brought into the foreground for editing.  When done editing, Emacs is
  71 ;; suspended again, and the client program is brought into the foreground.
  72
  73 ;; The buffer local variable "server-buffer-clients" lists
  74 ;; the clients who are waiting for this buffer to be edited.
  75 ;; The global variable "server-clients" lists all the waiting clients,
  76 ;; and which files are yet to be edited for each.
  77
  78 ;;; Code:
  79
  80 (eval-when-compile (require 'cl))
  81
  82 (defgroup server nil
  83   "Emacs running as a server process."
  84   :group 'external)
  85
  86 (defcustom server-visit-hook nil
  87   "*Hook run when visiting a file for the Emacs server."
  88   :group 'server
  89   :type 'hook)
  90
  91 (defcustom server-switch-hook nil
  92   "*Hook run when switching to a buffer for the Emacs server."
  93   :group 'server
  94   :type 'hook)
  95
  96 (defcustom server-done-hook nil
  97   "*Hook run when done editing a buffer for the Emacs server."
  98   :group 'server
  99   :type 'hook)
 100
 101 (defvar server-process nil
 102   "The current server process.")
 103
 104 (defvar server-clients nil
 105   "List of current server clients.
 106 Each element is (PROC PROPERTIES...) where PROC is a process object,
 107 and PROPERTIES is an association list of client properties.")
 108
 109 (defvar server-buffer-clients nil
 110   "List of client processes requesting editing of current buffer.")
 111 (make-variable-buffer-local 'server-buffer-clients)
 112 ;; Changing major modes should not erase this local.
 113 (put 'server-buffer-clients 'permanent-local t)
 114
 115 (defcustom server-window nil
 116   "*Specification of the window to use for selecting Emacs server buffers.
 117 If nil, use the selected window.
 118 If it is a function, it should take one argument (a buffer) and
 119 display and select it.  A common value is `pop-to-buffer'.
 120 If it is a window, use that.
 121 If it is a frame, use the frame's selected window.
 122
 123 It is not meaningful to set this to a specific frame or window with Custom.
 124 Only programs can do so."
 125   :group 'server
 126   :version "22.1"
 127   :type '(choice (const :tag "Use selected window"
 128                         :match (lambda (widget value)
 129                                  (not (functionp value)))
 130                         nil)
 131                  (function-item :tag "Use pop-to-buffer" pop-to-buffer)
 132                  (function :tag "Other function")))
 133
 134 (defcustom server-temp-file-regexp "^/tmp/Re\\|/draft$"
 135   "*Regexp matching names of temporary files.
 136 These are deleted and reused after each edit by the programs that
 137 invoke the Emacs server."
 138   :group 'server
 139   :type 'regexp)
 140
 141 (defcustom server-kill-new-buffers t
 142   "*Whether to kill buffers when done with them.
 143 If non-nil, kill a buffer unless it already existed before editing
 144 it with Emacs server.  If nil, kill only buffers as specified by
 145 `server-temp-file-regexp'.
 146 Please note that only buffers are killed that still have a client,
 147 i.e. buffers visited which \"emacsclient --no-wait\" are never killed in
 148 this way."
 149   :group 'server
 150   :type 'boolean
 151   :version "21.1")
 152
 153 (or (assq 'server-buffer-clients minor-mode-alist)
 154     (setq minor-mode-alist (cons '(server-buffer-clients " Server") minor-mode-alist)))
 155
 156 (defvar server-existing-buffer nil
 157   "Non-nil means the buffer existed before the server was asked to visit it.
 158 This means that the server should not kill the buffer when you say you
 159 are done with it in the server.")
 160 (make-variable-buffer-local 'server-existing-buffer)
 161
 162 (defvar server-name "server")
 163
 164 (defvar server-socket-dir nil
 165   "The directory in which to place the server socket.
 166 Initialized by `server-start'.")
 167
 168 (defun server-client (proc)
 169   "Return the Emacs client corresponding to PROC.
 170 PROC must be a process object.
 171 The car of the result is PROC; the cdr is an association list.
 172 See `server-client-get' and `server-client-set'."
 173   (assq proc server-clients))
 174
 175 (defun server-client-get (client property)
 176   "Get the value of PROPERTY in CLIENT.
 177 CLIENT may be a process object, or a client returned by `server-client'.
 178 Return nil if CLIENT has no such property."
 179   (or (listp client) (setq client (server-client client)))
 180   (cdr (assq property (cdr client))))
 181
 182 (defun server-client-set (client property value)
 183   "Set the PROPERTY to VALUE in CLIENT, and return VALUE.
 184 CLIENT may be a process object, or a client returned by `server-client'."
 185   (let (p proc)
 186     (if (listp client)
 187         (setq proc (car client))
 188       (setq proc client
 189             client (server-client client)))
 190     (setq p (assq property client))
 191     (cond
 192      (p (setcdr p value))
 193      (client (setcdr client (cons (cons property value) (cdr client))))
 194      (t (setq server-clients
 195               `((,proc (,property . ,value)) . ,server-clients))))
 196     value))
 197
 198 (defun server-clients-with (property value)
 199   "Return a list of clients with PROPERTY set to VALUE."
 200   (let (result)
 201     (dolist (client server-clients result)
 202       (when (equal value (server-client-get client property))
 203         (setq result (cons (car client) result))))))
 204
 205 (defun server-add-client (proc)
 206   "Create a client for process PROC, if it doesn't already have one.
 207 New clients have no properties."
 208   (unless (server-client proc)
 209     (setq server-clients (cons (cons proc nil)
 210                                server-clients))))
 211
 212 (defun server-getenv-from (env variable)
 213   "Get the value of VARIABLE in ENV.
 214 VARIABLE should be a string.  Value is nil if VARIABLE is
 215 undefined in ENV.  Otherwise, value is a string.
 216
 217 ENV should be in the same format as `process-environment'."
 218   (let (entry result)
 219     (while (and env (null result))
 220       (setq entry (car env)
 221             env (cdr env))
 222       (if (and (> (length entry) (length variable))
 223                (eq ?= (aref entry (length variable)))
 224                (equal variable (substring entry 0 (length variable))))
 225           (setq result (substring entry (+ (length variable) 1)))))
 226     result))
 227
 228 (defmacro server-with-environment (env vars &rest body)
 229   "Evaluate BODY with environment variables VARS set to those in ENV.
 230 The environment variables are then restored to their previous values.
 231
 232 VARS should be a list of strings.
 233 ENV should be in the same format as `process-environment'."
 234   (declare (indent 2))
 235   (let ((oldvalues (make-symbol "oldvalues"))
 236         (var (make-symbol "var"))
 237         (value (make-symbol "value"))
 238         (pair (make-symbol "pair")))
 239     `(let (,oldvalues)
 240        (dolist (,var ,vars)
 241          (let ((,value (server-getenv-from ,env ,var)))
 242            (setq ,oldvalues (cons (cons ,var (getenv ,var)) ,oldvalues))
 243            (setenv ,var ,value)))
 244        (unwind-protect
 245            (progn ,@body)
 246          (dolist (,pair ,oldvalues)
 247            (setenv (car ,pair) (cdr ,pair)))))))
 248
 249 (defun server-delete-client (client &optional noframe)
 250   "Delete CLIENT, including its buffers, terminals and frames.
 251 If NOFRAME is non-nil, let the frames live.  (To be used from
 252 `delete-frame-functions'.)"
 253   (server-log (concat "server-delete-client" (if noframe " noframe"))
 254               client)
 255   ;; Force a new lookup of client (prevents infinite recursion).
 256   (setq client (server-client
 257                 (if (listp client) (car client) client)))
 258   (let ((proc (car client))
 259         (buffers (server-client-get client 'buffers)))
 260     (when client
 261
 262       ;; Kill the client's buffers.
 263       (dolist (buf buffers)
 264         (when (buffer-live-p buf)
 265           (with-current-buffer buf
 266             ;; Kill the buffer if necessary.
 267             (when (and (equal server-buffer-clients
 268                               (list proc))
 269                        (or (and server-kill-new-buffers
 270                                 (not server-existing-buffer))
 271                            (server-temp-file-p))
 272                        (not (buffer-modified-p)))
 273               (let (flag)
 274                 (unwind-protect
 275                     (progn (setq server-buffer-clients nil)
 276                            (kill-buffer (current-buffer))
 277                            (setq flag t))
 278                   (unless flag
 279                     ;; Restore clients if user pressed C-g in `kill-buffer'.
 280                     (setq server-buffer-clients (list proc)))))))))
 281
 282       ;; Delete the client's frames.
 283       (unless noframe
 284         (dolist (frame (frame-list))
 285           (when (and (frame-live-p frame)
 286                      (equal proc (frame-parameter frame 'client)))
 287             ;; Prevent `server-handle-delete-frame' from calling us
 288             ;; recursively.
 289             (set-frame-parameter frame 'client nil)
 290             (delete-frame frame))))
 291
 292       (setq server-clients (delq client server-clients))
 293
 294       ;; Delete the client's tty.
 295       (let ((terminal (server-client-get client 'terminal)))
 296         (when (eq (terminal-live-p terminal) t)
 297           (delete-terminal terminal)))
 298
 299       ;; Delete the client's process.
 300       (if (eq (process-status (car client)) 'open)
 301           (delete-process (car client)))
 302
 303       (server-log "Deleted" proc))))
 304
 305 (defun server-log (string &optional client)
 306   "If a *server* buffer exists, write STRING to it for logging purposes.
 307 If CLIENT is non-nil, add a description of it to the logged
 308 message."
 309   (if (get-buffer "*server*")
 310       (with-current-buffer "*server*"
 311         (goto-char (point-max))
 312         (insert (current-time-string)
 313                 (cond
 314                  ((null client) " ")
 315                  ((listp client) (format " %s: " (car client)))
 316                  (t (format " %s: " client)))
 317                 string)
 318         (or (bolp) (newline)))))
 319
 320 (defun server-sentinel (proc msg)
 321   "The process sentinel for Emacs server connections."
 322   ;; If this is a new client process, set the query-on-exit flag to nil
 323   ;; for this process (it isn't inherited from the server process).
 324   (when (and (eq (process-status proc) 'open)
 325              (process-query-on-exit-flag proc))
 326     (set-process-query-on-exit-flag proc nil))
 327   (server-log (format "Status changed to %s: %s" (process-status proc) msg) proc)
 328   (server-delete-client proc))
 329
 330 (defun server-handle-delete-frame (frame)
 331   "Delete the client connection when the emacsclient frame is deleted."
 332   (let ((proc (frame-parameter frame 'client)))
 333     (when (and (frame-live-p frame)
 334                proc
 335                ;; See if this is the last frame for this client.
 336                (>= 1 (let ((frame-num 0))
 337                       (dolist (f (frame-list))
 338                         (when (eq proc (frame-parameter f 'client))
 339                           (setq frame-num (1+ frame-num))))
 340                       frame-num)))
 341       (server-log (format "server-handle-delete-frame, frame %s" frame) proc)
 342       (server-delete-client proc 'noframe)))) ; Let delete-frame delete the frame later.
 343
 344 (defun server-handle-suspend-tty (terminal)
 345   "Notify the emacsclient process to suspend itself when its tty device is suspended."
 346   (dolist (proc (server-clients-with 'terminal terminal))
 347     (server-log (format "server-handle-suspend-tty, terminal %s" terminal) proc)
 348     (condition-case err
 349         (server-send-string proc "-suspend \n")
 350       (file-error (condition-case nil (server-delete-client proc) (error nil))))))
 351
 352 (defun server-unquote-arg (arg)
 353   "Remove &-quotation from ARG.
 354 See `server-quote-arg' and `server-process-filter'."
 355   (replace-regexp-in-string
 356    "&." (lambda (s)
 357           (case (aref s 1)
 358             (?& "&")
 359             (?- "-")
 360             (?n "\n")
 361             (t " ")))
 362    arg t t))
 363
 364 (defun server-quote-arg (arg)
 365   "In ARG, insert a & before each &, each space, each newline, and -.
 366 Change spaces to underscores, too, so that the return value never
 367 contains a space.
 368
 369 See `server-unquote-arg' and `server-process-filter'."
 370   (replace-regexp-in-string
 371    "[-&\n ]" (lambda (s)
 372                (case (aref s 0)
 373                  (?& "&&")
 374                  (?- "&-")
 375                  (?\n "&n")
 376                  (?\s "&_")))
 377    arg t t))
 378
 379 (defun server-send-string (proc string)
 380   "A wrapper around `proc-send-string' for logging."
 381   (server-log (concat "Sent " string) proc)
 382   (process-send-string proc string))
 383
 384 (defun server-ensure-safe-dir (dir)
 385   "Make sure DIR is a directory with no race-condition issues.
 386 Creates the directory if necessary and makes sure:
 387 - there's no symlink involved
 388 - it's owned by us
 389 - it's not readable/writable by anybody else."
 390   (setq dir (directory-file-name dir))
 391   (let ((attrs (file-attributes dir)))
 392     (unless attrs
 393       (letf (((default-file-modes) ?\700)) (make-directory dir))
 394       (setq attrs (file-attributes dir)))
 395     ;; Check that it's safe for use.
 396     (unless (and (eq t (car attrs)) (eq (nth 2 attrs) (user-uid))
 397                  (zerop (logand ?\077 (file-modes dir))))
 398       (error "The directory %s is unsafe" dir))))
 399
 400 ;;;###autoload
 401 (defun server-start (&optional leave-dead)
 402   "Allow this Emacs process to be a server for client processes.
 403 This starts a server communications subprocess through which
 404 client \"editors\" can send your editing commands to this Emacs
 405 job.  To use the server, set up the program `emacsclient' in the
 406 Emacs distribution as your standard \"editor\".
 407
 408 Prefix arg LEAVE-DEAD means just kill any existing server
 409 communications subprocess."
 410   (interactive "P")
 411   (when (or
 412          (not server-clients)
 413          (yes-or-no-p
 414           "The current server still has clients; delete them? "))
 415     ;; It is safe to get the user id now.
 416     (setq server-socket-dir (or server-socket-dir
 417                                 (format "/tmp/emacs%d" (user-uid))))
 418     ;; kill it dead!
 419     (if server-process
 420         (condition-case () (delete-process server-process) (error nil)))
 421     ;; Delete the socket files made by previous server invocations.
 422     (condition-case ()
 423         (delete-file (expand-file-name server-name server-socket-dir))
 424       (error nil))
 425     ;; If this Emacs already had a server, clear out associated status.
 426     (while server-clients
 427       (server-delete-client (car server-clients)))
 428     ;; Now any previous server is properly stopped.
 429     (if leave-dead
 430         (progn
 431           (server-log (message "Server stopped"))
 432           (setq server-process nil))
 433       ;; Make sure there is a safe directory in which to place the socket.
 434       (server-ensure-safe-dir server-socket-dir)
 435       (if server-process
 436           (server-log (message "Restarting server"))
 437         (server-log (message "Starting server")))
 438       (letf (((default-file-modes) ?\700))
 439         (add-hook 'suspend-tty-functions 'server-handle-suspend-tty)
 440         (add-hook 'delete-frame-functions 'server-handle-delete-frame)
 441         (add-hook 'kill-buffer-query-functions 'server-kill-buffer-query-function)
 442         (add-hook 'kill-emacs-query-functions 'server-kill-emacs-query-function)
 443         (setq server-process
 444               (make-network-process
 445                :name "server" :family 'local :server t :noquery t
 446                :service (expand-file-name server-name server-socket-dir)
 447                :sentinel 'server-sentinel :filter 'server-process-filter
 448                ;; We must receive file names without being decoded.
 449                ;; Those are decoded by server-process-filter according
 450                ;; to file-name-coding-system.
 451                :coding 'raw-text))))))
 452
 453 ;;;###autoload
 454 (define-minor-mode server-mode
 455   "Toggle Server mode.
 456 With ARG, turn Server mode on if ARG is positive, off otherwise.
 457 Server mode runs a process that accepts commands from the
 458 `emacsclient' program.  See `server-start' and Info node `Emacs server'."
 459   :global t
 460   :group 'server
 461   :version "22.1"
 462   ;; Fixme: Should this check for an existing server socket and do
 463   ;; nothing if there is one (for multiple Emacs sessions)?
 464   (server-start (not server-mode)))
 465 \f
 466 (defun server-process-filter (proc string)
 467   "Process a request from the server to edit some files.
 468 PROC is the server process.  STRING consists of a sequence of
 469 commands prefixed by a dash.  Some commands have arguments; these
 470 are &-quoted and need to be decoded by `server-unquote-arg'.  The
 471 filter parses and executes these commands.
 472
 473 To illustrate the protocol, here is an example command that
 474 emacsclient sends to create a new X frame (note that the whole
 475 sequence is sent on a single line):
 476
 477         -version 21.3.50 xterm
 478         -env HOME /home/lorentey
 479         -env DISPLAY :0.0
 480         ... lots of other -env commands
 481         -display :0.0
 482         -window-system
 483
 484 The server normally sends back the single command `-good-version'
 485 as a response.
 486
 487 The following commands are accepted by the server:
 488
 489 `-version CLIENT-VERSION'
 490   Check version numbers between server and client, and signal an
 491   error if there is a mismatch.  The server replies with
 492   `-good-version' to confirm the match.
 493
 494 `-env NAME=VALUE'
 495   An environment variable on the client side.
 496
 497 `-dir DIRNAME'
 498   The current working directory of the client process.
 499
 500 `-current-frame'
 501   Forbid the creation of new frames.
 502
 503 `-nowait'
 504   Request that the next frame created should not be
 505   associated with this client.
 506
 507 `-display DISPLAY'
 508   Set the display name to open X frames on.
 509
 510 `-position LINE[:COLUMN]'
 511   Go to the given line and column number
 512   in the next file opened.
 513
 514 `-file FILENAME'
 515   Load the given file in the current frame.
 516
 517 `-eval EXPR'
 518   Evaluate EXPR as a Lisp expression and return the
 519   result in -print commands.
 520
 521 `-window-system'
 522   Open a new X frame.
 523
 524 `-tty DEVICENAME TYPE'
 525   Open a new tty frame at the client.
 526
 527 `-suspend'
 528   Suspend this tty frame.  The client sends this string in
 529   response to SIGTSTP and SIGTTOU.  The server must cease all I/O
 530   on this tty until it gets a -resume command.
 531
 532 `-resume'
 533   Resume this tty frame. The client sends this string when it
 534   gets the SIGCONT signal and it is the foreground process on its
 535   controlling tty.
 536
 537 `-ignore COMMENT'
 538   Do nothing, but put the comment in the server
 539   log.  Useful for debugging.
 540
 541
 542 The following commands are accepted by the client:
 543
 544 `-good-version'
 545   Signals a version match between the client and the server.
 546
 547 `-emacs-pid PID'
 548   Describes the process id of the Emacs process;
 549   used to forward window change signals to it.
 550
 551 `-window-system-unsupported'
 552   Signals that the server does not
 553   support creating X frames; the client must try again with a tty
 554   frame.
 555
 556 `-print STRING'
 557   Print STRING on stdout.  Used to send values
 558   returned by -eval.
 559
 560 `-error DESCRIPTION'
 561   Signal an error (but continue processing).
 562
 563 `-suspend'
 564   Suspend this terminal, i.e., stop the client process.  Sent
 565   when the user presses C-z."
 566   (server-log (concat "Received " string) proc)
 567   (let ((prev (process-get proc 'previous-string)))
 568     (when prev
 569       (setq string (concat prev string))
 570       (process-put proc 'previous-string nil)))
 571   (condition-case err
 572       (progn
 573         (server-add-client proc)
 574         ;; If the input is multiple lines,
 575         ;; process each line individually.
 576         (while (string-match "\n" string)
 577           (let ((request (substring string 0 (match-beginning 0)))
 578                 (coding-system (and default-enable-multibyte-characters
 579                                     (or file-name-coding-system
 580                                         default-file-name-coding-system)))
 581                 (client (server-client proc))
 582                 current-frame
 583                 nowait ; t if emacsclient does not want to wait for us.
 584                 frame ; The frame that was opened for the client (if any).
 585                 display              ; Open the frame on this display.
 586                 dontkill       ; t if the client should not be killed.
 587                 env
 588                 dir
 589                 (files nil)
 590                 (lineno 1)
 591                 (columnno 0))
 592             ;; Remove this line from STRING.
 593             (setq string (substring string (match-end 0)))
 594             (while (string-match " *[^ ]* " request)
 595               (let ((arg (substring request (match-beginning 0) (1- (match-end 0)))))
 596                 (setq request (substring request (match-end 0)))
 597                 (cond
 598                  ;; -version CLIENT-VERSION:
 599                  ;; Check version numbers, signal an error if there is a mismatch.
 600                  ((and (equal "-version" arg)
 601                        (string-match "\\([0-9.]+\\) " request))
 602                   (let* ((client-version (match-string 1 request))
 603                          (truncated-emacs-version
 604                           (substring emacs-version 0 (length client-version))))
 605                     (setq request (substring request (match-end 0)))
 606                     (if (equal client-version truncated-emacs-version)
 607                         (progn
 608                           (server-send-string proc "-good-version \n")
 609                           (server-client-set client 'version client-version))
 610                       (error (concat "Version mismatch: Emacs is "
 611                                      truncated-emacs-version
 612                                      ", emacsclient is " client-version)))))
 613
 614                  ;; -nowait:  Emacsclient won't wait for a result.
 615                  ((equal "-nowait" arg) (setq nowait t))
 616
 617                  ;; -current-frame:  Don't create frames.
 618                  ((equal "-current-frame" arg) (setq current-frame t))
 619
 620                  ;; -display DISPLAY:
 621                  ;; Open X frames on the given display instead of the default.
 622                  ((and (equal "-display" arg) (string-match "\\([^ ]*\\) " request))
 623                   (setq display (match-string 1 request)
 624                         request (substring request (match-end 0))))
 625
 626                  ;; -window-system:  Open a new X frame.
 627                  ((equal "-window-system" arg)
 628                   (unless (server-client-get client 'version)
 629                     (error "Protocol error; make sure to use the correct version of emacsclient"))
 630                   (unless current-frame
 631                     (if (fboundp 'x-create-frame)
 632                         (let ((params (if nowait
 633                                           ;; Flag frame as client-created, but use a dummy client.
 634                                           ;; This will prevent the frame from being deleted when
 635                                           ;; emacsclient quits while also preventing
 636                                           ;; `server-save-buffers-kill-terminal' from unexpectedly
 637                                           ;; killing emacs on that frame.
 638                                           (list (cons 'client 'nowait) (cons 'environment env))
 639                                         (list (cons 'client proc) (cons 'environment env)))))
 640                           (setq frame (make-frame-on-display
 641                                        (or display
 642                                            (frame-parameter nil 'display)
 643                                            (getenv "DISPLAY")
 644                                            (error "Please specify display"))
 645                                        params))
 646                           (server-log (format "%s created" frame) proc)
 647                           ;; XXX We need to ensure the parameters are
 648                           ;; really set because Emacs forgets unhandled
 649                           ;; initialization parameters for X frames at
 650                           ;; the moment.
 651                           (modify-frame-parameters frame params)
 652                           (select-frame frame)
 653                           (server-client-set client 'frame frame)
 654                           (server-client-set client 'terminal (frame-terminal frame))
 655
 656                           ;; Display *scratch* by default.
 657                           (switch-to-buffer (get-buffer-create "*scratch*") 'norecord)
 658                           (if dir (setq default-directory dir))
 659
 660                           (setq dontkill t))
 661                       ;; This emacs does not support X.
 662                       (server-log "Window system unsupported" proc)
 663                       (server-send-string proc "-window-system-unsupported \n")
 664                       (setq dontkill t))))
 665
 666                  ;; -resume:  Resume a suspended tty frame.
 667                  ((equal "-resume" arg)
 668                   (let ((terminal (server-client-get client 'terminal)))
 669                     (setq dontkill t)
 670                     (when (eq (terminal-live-p terminal) t)
 671                       (resume-tty terminal))))
 672
 673                  ;; -suspend:  Suspend the client's frame.  (In case we
 674                  ;; get out of sync, and a C-z sends a SIGTSTP to
 675                  ;; emacsclient.)
 676                  ((equal "-suspend" arg)
 677                   (let ((terminal (server-client-get client 'terminal)))
 678                     (setq dontkill t)
 679                     (when (eq (terminal-live-p terminal) t)
 680                       (suspend-tty terminal))))
 681
 682                  ;; -ignore COMMENT:  Noop; useful for debugging emacsclient.
 683                  ;; (The given comment appears in the server log.)
 684                  ((and (equal "-ignore" arg) (string-match "\\([^ ]*\\) " request))
 685                   (setq dontkill t
 686                         request (substring request (match-end 0))))
 687
 688                  ;; -tty DEVICE-NAME TYPE:  Open a new tty frame at the client.
 689                  ((and (equal "-tty" arg) (string-match "\\([^ ]*\\) \\([^ ]*\\) " request))
 690                   (let ((tty (server-unquote-arg (match-string 1 request)))
 691                         (type (server-unquote-arg (match-string 2 request))))
 692                     (setq request (substring request (match-end 0)))
 693                     (unless (server-client-get client 'version)
 694                       (error "Protocol error; make sure you use the correct version of emacsclient"))
 695                     (unless current-frame
 696                       (server-with-environment env
 697                           '("LANG" "LC_CTYPE" "LC_ALL"
 698                             ;; For tgetent(3); list according to ncurses(3).
 699                             "BAUDRATE" "COLUMNS" "ESCDELAY" "HOME" "LINES"
 700                             "NCURSES_ASSUMED_COLORS" "NCURSES_NO_PADDING"
 701                             "NCURSES_NO_SETBUF" "TERM" "TERMCAP" "TERMINFO"
 702                             "TERMINFO_DIRS" "TERMPATH")
 703                         (setq frame (make-frame-on-tty tty type
 704                                                        ;; Ignore nowait here; we always need to clean
 705                                                        ;; up opened ttys when the client dies.
 706                                                        `((client . ,proc)
 707                                                          (environment . ,env)))))
 708                       (select-frame frame)
 709                       (server-client-set client 'frame frame)
 710                       (server-client-set client 'tty (terminal-name frame))
 711                       (server-client-set client 'terminal (frame-terminal frame))
 712
 713                       ;; Display *scratch* by default.
 714                       (switch-to-buffer (get-buffer-create "*scratch*") 'norecord)
 715                       (if dir (setq default-directory dir))
 716
 717                       ;; Reply with our pid.
 718                       (server-send-string proc (concat "-emacs-pid " (number-to-string (emacs-pid)) "\n"))
 719                       (setq dontkill t))))
 720
 721                  ;; -position LINE:  Go to the given line in the next file.
 722                  ((and (equal "-position" arg) (string-match "\\(\\+[0-9]+\\) " request))
 723                   (setq lineno (string-to-number (substring (match-string 1 request) 1))
 724                         request (substring request (match-end 0))))
 725
 726                  ;; -position LINE:COLUMN:  Set point to the given position in the next file.
 727                  ((and (equal "-position" arg) (string-match "\\+\\([0-9]+\\):\\([0-9]+\\) " request))
 728                   (setq lineno (string-to-number (match-string 1 request))
 729                         columnno (string-to-number (match-string 2 request))
 730                         request (substring request (match-end 0))))
 731
 732                  ;; -file FILENAME:  Load the given file.
 733                  ((and (equal "-file" arg) (string-match "\\([^ ]+\\) " request))
 734                   (let ((file (server-unquote-arg (match-string 1 request))))
 735                     (setq request (substring request (match-end 0)))
 736                     (if coding-system
 737                         (setq file (decode-coding-string file coding-system)))
 738                     (setq file (command-line-normalize-file-name file))
 739                     (push (list file lineno columnno) files)
 740                     (server-log (format "New file: %s (%d:%d)" file lineno columnno) proc))
 741                   (setq lineno 1
 742                         columnno 0))
 743
 744                  ;; -eval EXPR:  Evaluate a Lisp expression.
 745                  ((and (equal "-eval" arg) (string-match "\\([^ ]+\\) " request))
 746                   (let ((expr (server-unquote-arg (match-string 1 request))))
 747                     (setq request (substring request (match-end 0)))
 748                     (if coding-system
 749                         (setq expr (decode-coding-string expr coding-system)))
 750                     (let ((v (eval (car (read-from-string expr)))))
 751                       (when (and (not frame) v)
 752                         (with-temp-buffer
 753                           (let ((standard-output (current-buffer)))
 754                             (pp v)
 755                             (server-send-string
 756                              proc (format "-print %s\n"
 757                                           (server-quote-arg
 758                                            (buffer-substring-no-properties (point-min)
 759                                                                            (point-max)))))))))
 760                     (setq lineno 1
 761                           columnno 0)))
 762
 763                  ;; -env NAME=VALUE:  An environment variable.
 764                  ((and (equal "-env" arg) (string-match "\\([^ ]+\\) " request))
 765                   (let ((var (server-unquote-arg (match-string 1 request))))
 766                     ;; XXX Variables should be encoded as in getenv/setenv.
 767                     (setq request (substring request (match-end 0)))
 768                     (setq env (cons var env))))
 769
 770                  ;; -dir DIRNAME:  The cwd of the emacsclient process.
 771                  ((and (equal "-dir" arg) (string-match "\\([^ ]+\\) " request))
 772                   (setq dir (server-unquote-arg (match-string 1 request)))
 773                   (setq request (substring request (match-end 0)))
 774                   (if coding-system
 775                       (setq dir (decode-coding-string dir coding-system)))
 776                   (setq dir (command-line-normalize-file-name dir)))
 777
 778                  ;; Unknown command.
 779                  (t (error "Unknown command: %s" arg)))))
 780
 781             (let (buffers)
 782               (when files
 783                 (run-hooks 'pre-command-hook)
 784                 (setq buffers (server-visit-files files client nowait))
 785                 (run-hooks 'post-command-hook))
 786
 787               (when frame
 788                 (with-selected-frame frame
 789                   (display-startup-echo-area-message)
 790                   (unless inhibit-splash-screen
 791                     (condition-case err
 792                         ;; This looks scary because `fancy-splash-screens'
 793                         ;; will call `recursive-edit' from a process filter.
 794                         ;; However, that should be safe to do now.
 795                         (display-splash-screen t)
 796                       ;; `recursive-edit' will throw an error if Emacs is
 797                       ;; already doing a recursive edit elsewhere.  Catch it
 798                       ;; here so that we can finish normally.
 799                       (error nil)))))
 800
 801               ;; Delete the client if necessary.
 802               (cond
 803                (nowait
 804                 ;; Client requested nowait; return immediately.
 805                 (server-log "Close nowait client" proc)
 806                 (server-delete-client proc))
 807                ((and (not dontkill) (null buffers))
 808                 ;; This client is empty; get rid of it immediately.
 809                 (server-log "Close empty client" proc)
 810                 (server-delete-client proc)))
 811               (cond
 812                ((or isearch-mode (minibufferp))
 813                 nil)
 814                ((and frame (null buffers))
 815                 (message "%s" (substitute-command-keys
 816                                "When done with this frame, type \\[delete-frame]")))
 817                ((not (null buffers))
 818                 (server-switch-buffer (car buffers))
 819                 (run-hooks 'server-switch-hook)
 820                 (unless nowait
 821                   (message "%s" (substitute-command-keys
 822                                  "When done with a buffer, type \\[server-edit]"))))))))
 823
 824         ;; Save for later any partial line that remains.
 825         (when (> (length string) 0)
 826           (process-put proc 'previous-string string)))
 827     ;; condition-case
 828     (error (ignore-errors
 829              (server-send-string
 830               proc (concat "-error " (server-quote-arg (error-message-string err))))
 831              (setq string "")
 832              (server-log (error-message-string err) proc)
 833              (delete-process proc)))))
 834
 835 (defun server-goto-line-column (file-line-col)
 836   "Move point to the position indicated in FILE-LINE-COL.
 837 FILE-LINE-COL should be a three-element list as described in
 838 `server-visit-files'."
 839   (goto-line (nth 1 file-line-col))
 840   (let ((column-number (nth 2 file-line-col)))
 841     (if (> column-number 0)
 842         (move-to-column (1- column-number)))))
 843
 844 (defun server-visit-files (files client &optional nowait)
 845   "Find FILES and return a list of buffers created.
 846 FILES is an alist whose elements are (FILENAME LINENUMBER COLUMNNUMBER).
 847 CLIENT is the client that requested this operation.
 848 NOWAIT non-nil means this client is not waiting for the results,
 849 so don't mark these buffers specially, just visit them normally."
 850   ;; Bind last-nonmenu-event to force use of keyboard, not mouse, for queries.
 851   (let ((last-nonmenu-event t) client-record)
 852     ;; Restore the current buffer afterward, but not using save-excursion,
 853     ;; because we don't want to save point in this buffer
 854     ;; if it happens to be one of those specified by the server.
 855     (save-current-buffer
 856       (dolist (file files)
 857         ;; If there is an existing buffer modified or the file is
 858         ;; modified, revert it.  If there is an existing buffer with
 859         ;; deleted file, offer to write it.
 860         (let* ((filen (car file))
 861                (obuf (get-file-buffer filen)))
 862           (add-to-history 'file-name-history filen)
 863           (if (and obuf (set-buffer obuf))
 864               (progn
 865                 (cond ((file-exists-p filen)
 866                        (if (not (verify-visited-file-modtime obuf))
 867                            (revert-buffer t nil)))
 868                       (t
 869                        (if (y-or-n-p
 870                             (concat "File no longer exists: " filen
 871                                     ", write buffer to file? "))
 872                            (write-file filen))))
 873                 (unless server-buffer-clients
 874                   (setq server-existing-buffer t))
 875                 (server-goto-line-column file))
 876             (set-buffer (find-file-noselect filen))
 877             (server-goto-line-column file)
 878             (run-hooks 'server-visit-hook)))
 879         (unless nowait
 880           ;; When the buffer is killed, inform the clients.
 881           (add-hook 'kill-buffer-hook 'server-kill-buffer nil t)
 882           (push (car client) server-buffer-clients))
 883         (push (current-buffer) client-record)))
 884     (unless nowait
 885       (server-client-set
 886        client 'buffers
 887        (nconc (server-client-get client 'buffers) client-record)))
 888     client-record))
 889 \f
 890 (defun server-buffer-done (buffer &optional for-killing)
 891   "Mark BUFFER as \"done\" for its client(s).
 892 This buries the buffer, then returns a list of the form (NEXT-BUFFER KILLED).
 893 NEXT-BUFFER is another server buffer, as a suggestion for what to select next,
 894 or nil.  KILLED is t if we killed BUFFER (typically, because it was visiting
 895 a temp file).
 896 FOR-KILLING if non-nil indicates that we are called from `kill-buffer'."
 897   (let ((next-buffer nil)
 898         (killed nil))
 899     (dolist (client server-clients)
 900       (let ((buffers (server-client-get client 'buffers)))
 901         (or next-buffer
 902             (setq next-buffer (nth 1 (memq buffer buffers))))
 903         (when buffers                   ; Ignore bufferless clients.
 904           (setq buffers (delq buffer buffers))
 905           ;; Delete all dead buffers from CLIENT.
 906           (dolist (b buffers)
 907             (and (bufferp b)
 908                  (not (buffer-live-p b))
 909                  (setq buffers (delq b buffers))))
 910           (server-client-set client 'buffers buffers)
 911           ;; If client now has no pending buffers,
 912           ;; tell it that it is done, and forget it entirely.
 913           (unless buffers
 914             (server-log "Close" client)
 915             (server-delete-client client)))))
 916     (if (and (bufferp buffer) (buffer-name buffer))
 917         ;; We may or may not kill this buffer;
 918         ;; if we do, do not call server-buffer-done recursively
 919         ;; from kill-buffer-hook.
 920         (let ((server-kill-buffer-running t))
 921           (with-current-buffer buffer
 922             (setq server-buffer-clients nil)
 923             (run-hooks 'server-done-hook))
 924           ;; Notice whether server-done-hook killed the buffer.
 925           (if (null (buffer-name buffer))
 926               (setq killed t)
 927             ;; Don't bother killing or burying the buffer
 928             ;; when we are called from kill-buffer.
 929             (unless for-killing
 930               (when (and (not killed)
 931                          server-kill-new-buffers
 932                          (with-current-buffer buffer
 933                            (not server-existing-buffer)))
 934                 (setq killed t)
 935                 (bury-buffer buffer)
 936                 (kill-buffer buffer))
 937               (unless killed
 938                 (if (server-temp-file-p buffer)
 939                     (progn
 940                       (kill-buffer buffer)
 941                       (setq killed t))
 942                   (bury-buffer buffer)))))))
 943     (list next-buffer killed)))
 944
 945 (defun server-temp-file-p (&optional buffer)
 946   "Return non-nil if BUFFER contains a file considered temporary.
 947 These are files whose names suggest they are repeatedly
 948 reused to pass information to another program.
 949
 950 The variable `server-temp-file-regexp' controls which filenames
 951 are considered temporary."
 952   (and (buffer-file-name buffer)
 953        (string-match server-temp-file-regexp (buffer-file-name buffer))))
 954
 955 (defun server-done ()
 956   "Offer to save current buffer, mark it as \"done\" for clients.
 957 This kills or buries the buffer, then returns a list
 958 of the form (NEXT-BUFFER KILLED).  NEXT-BUFFER is another server buffer,
 959 as a suggestion for what to select next, or nil.
 960 KILLED is t if we killed BUFFER, which happens if it was created
 961 specifically for the clients and did not exist before their request for it."
 962   (when server-buffer-clients
 963     (if (server-temp-file-p)
 964         ;; For a temp file, save, and do make a non-numeric backup
 965         ;; (unless make-backup-files is nil).
 966         (let ((version-control nil)
 967               (buffer-backed-up nil))
 968           (save-buffer))
 969       (if (and (buffer-modified-p)
 970                buffer-file-name
 971                (y-or-n-p (concat "Save file " buffer-file-name "? ")))
 972           (save-buffer)))
 973     (server-buffer-done (current-buffer))))
 974
 975 ;; Ask before killing a server buffer.
 976 ;; It was suggested to release its client instead,
 977 ;; but I think that is dangerous--the client would proceed
 978 ;; using whatever is on disk in that file. -- rms.
 979 (defun server-kill-buffer-query-function ()
 980   "Ask before killing a server buffer."
 981   (or (not server-buffer-clients)
 982       (let ((res t))
 983         (dolist (proc server-buffer-clients res)
 984           (let ((client (server-client proc)))
 985             (when (and client (eq (process-status proc) 'open))
 986               (setq res nil)))))
 987       (yes-or-no-p (format "Buffer `%s' still has clients; kill it? "
 988                            (buffer-name (current-buffer))))))
 989
 990 (defun server-kill-emacs-query-function ()
 991   "Ask before exiting Emacs it has live clients."
 992   (or (not server-clients)
 993       (let (live-client)
 994         (dolist (client server-clients live-client)
 995           (if (memq t (mapcar 'buffer-live-p (server-client-get
 996                                               client 'buffers)))
 997               (setq live-client t))))
 998       (yes-or-no-p "This Emacs session has clients; exit anyway? ")))
 999
1000 (defvar server-kill-buffer-running nil
1001   "Non-nil while `server-kill-buffer' or `server-buffer-done' is running.")
1002
1003 (defun server-kill-buffer ()
1004   "Remove the current buffer from its clients' buffer list.
1005 Designed to be added to `kill-buffer-hook'."
1006   ;; Prevent infinite recursion if user has made server-done-hook
1007   ;; call kill-buffer.
1008   (or server-kill-buffer-running
1009       (and server-buffer-clients
1010            (let ((server-kill-buffer-running t))
1011              (when server-process
1012                (server-buffer-done (current-buffer) t))))))
1013 \f
1014 (defun server-edit (&optional arg)
1015   "Switch to next server editing buffer; say \"Done\" for current buffer.
1016 If a server buffer is current, it is marked \"done\" and optionally saved.
1017 The buffer is also killed if it did not exist before the clients asked for it.
1018 When all of a client's buffers are marked as \"done\", the client is notified.
1019
1020 Temporary files such as MH <draft> files are always saved and backed up,
1021 no questions asked.  (The variable `make-backup-files', if nil, still
1022 inhibits a backup; you can set it locally in a particular buffer to
1023 prevent a backup for it.)  The variable `server-temp-file-regexp' controls
1024 which filenames are considered temporary.
1025
1026 If invoked with a prefix argument, or if there is no server process running,
1027 starts server process and that is all.  Invoked by \\[server-edit]."
1028   (interactive "P")
1029   (cond
1030    ((or arg
1031         (not server-process)
1032         (memq (process-status server-process) '(signal exit)))
1033     (server-mode 1))
1034    (server-clients (apply 'server-switch-buffer (server-done)))
1035    (t (message "No server editing buffers exist"))))
1036
1037 (defun server-switch-buffer (&optional next-buffer killed-one)
1038   "Switch to another buffer, preferably one that has a client.
1039 Arg NEXT-BUFFER is a suggestion; if it is a live buffer, use it.
1040
1041 KILLED-ONE is t in a recursive call if we have already killed one
1042 temp-file server buffer.  This means we should avoid the final
1043 \"switch to some other buffer\" since we've already effectively
1044 done that."
1045   (if (null next-buffer)
1046       (progn
1047         (let ((rest server-clients))
1048           (while (and rest (not next-buffer))
1049             (let ((client (car rest)))
1050               ;; Only look at frameless clients.
1051               (when (not (server-client-get client 'frame))
1052                 (setq next-buffer (car (server-client-get client 'buffers))))
1053               (setq rest (cdr rest)))))
1054         (and next-buffer (server-switch-buffer next-buffer killed-one))
1055         (unless (or next-buffer killed-one (window-dedicated-p (selected-window)))
1056           ;; (switch-to-buffer (other-buffer))
1057           (message "No server buffers remain to edit")))
1058     (if (not (buffer-live-p next-buffer))
1059         ;; If NEXT-BUFFER is a dead buffer, remove the server records for it
1060         ;; and try the next surviving server buffer.
1061         (apply 'server-switch-buffer (server-buffer-done next-buffer))
1062       ;; OK, we know next-buffer is live, let's display and select it.
1063       (if (functionp server-window)
1064           (funcall server-window next-buffer)
1065         (let ((win (get-buffer-window next-buffer 0)))
1066           (if (and win (not server-window))
1067               ;; The buffer is already displayed: just reuse the window.
1068               (let ((frame (window-frame win)))
1069                 (if (eq (frame-visible-p frame) 'icon)
1070                     (raise-frame frame))
1071                 (select-window win)
1072                 (set-buffer next-buffer))
1073             ;; Otherwise, let's find an appropriate window.
1074             (cond ((and (windowp server-window)
1075                         (window-live-p server-window))
1076                    (select-window server-window))
1077                   ((framep server-window)
1078                    (if (not (frame-live-p server-window))
1079                        (setq server-window (make-frame)))
1080                    (select-window (frame-selected-window server-window))))
1081             (if (window-minibuffer-p (selected-window))
1082                 (select-window (next-window nil 'nomini 0)))
1083             ;; Move to a non-dedicated window, if we have one.
1084             (when (window-dedicated-p (selected-window))
1085               (select-window
1086                (get-window-with-predicate
1087                 (lambda (w)
1088                   (and (not (window-dedicated-p w))
1089                        (equal (frame-terminal (window-frame w))
1090                               (frame-terminal (selected-frame)))))
1091                 'nomini 'visible (selected-window))))
1092             (condition-case nil
1093                 (switch-to-buffer next-buffer)
1094               ;; After all the above, we might still have ended up with
1095               ;; a minibuffer/dedicated-window (if there's no other).
1096               (error (pop-to-buffer next-buffer)))))))))
1097
1098 ;;;###autoload
1099 (defun server-save-buffers-kill-terminal (proc &optional arg)
1100   "Offer to save each buffer, then kill PROC.
1101
1102 With prefix arg, silently save all file-visiting buffers, then kill.
1103
1104 If emacsclient was started with a list of filenames to edit, then
1105 only these files will be asked to be saved."
1106   (let ((buffers (server-client-get proc 'buffers)))
1107     ;; If client is bufferless, emulate a normal Emacs session
1108     ;; exit and offer to save all buffers.  Otherwise, offer to
1109     ;; save only the buffers belonging to the client.
1110     (save-some-buffers arg
1111                        (if buffers
1112                            (lambda () (memq (current-buffer) buffers))
1113                          t))
1114     (server-delete-client proc)))
1115
1116 (define-key ctl-x-map "#" 'server-edit)
1117
1118 (defun server-unload-hook ()
1119   "Unload the server library."
1120   (server-mode -1)
1121   (remove-hook 'suspend-tty-functions 'server-handle-suspend-tty)
1122   (remove-hook 'delete-frame-functions 'server-handle-delete-frame)
1123   (remove-hook 'kill-buffer-query-functions 'server-kill-buffer-query-function)
1124   (remove-hook 'kill-emacs-query-functions 'server-kill-emacs-query-function)
1125   (remove-hook 'kill-buffer-hook 'server-kill-buffer))
1126
1127 (add-hook 'kill-emacs-hook (lambda () (server-mode -1))) ;Cleanup upon exit.
1128 (add-hook 'server-unload-hook 'server-unload-hook)
1129 \f
1130 (provide 'server)
1131
1132 ;; arch-tag: 1f7ecb42-f00a-49f8-906d-61995d84c8d6
1133 ;;; server.el ends here