lisp/descr-text.el

   1 ;;; descr-text.el --- describe text mode
   2
   3 ;; Copyright (c) 1994, 1995, 1996, 2001, 2002 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.org>
   6 ;; Keywords: faces
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Describe-Text Mode.
  28
  29 ;;; Code:
  30
  31 (defun describe-text-done ()
  32   "Delete the current window or bury the current buffer."
  33   (interactive)
  34   (if (> (count-windows) 1)
  35       (delete-window)
  36     (bury-buffer)))
  37
  38 (defvar describe-text-mode-map
  39   (let ((map (make-sparse-keymap)))
  40     (set-keymap-parent map widget-keymap)
  41     map)
  42   "Keymap for `describe-text-mode'.")
  43
  44 (defcustom describe-text-mode-hook nil
  45   "List of hook functions ran by `describe-text-mode'."
  46   :type 'hook)
  47
  48 (defun describe-text-mode ()
  49   "Major mode for buffers created by `describe-char'.
  50
  51 \\{describe-text-mode-map}
  52 Entry to this mode calls the value of `describe-text-mode-hook'
  53 if that value is non-nil."
  54   (kill-all-local-variables)
  55   (setq major-mode 'describe-text-mode
  56         mode-name "Describe-Text")
  57   (use-local-map describe-text-mode-map)
  58   (widget-setup)
  59   (add-hook 'change-major-mode-hook 'font-lock-defontify nil t)
  60   (run-hooks 'describe-text-mode-hook))
  61
  62 ;;; Describe-Text Utilities.
  63
  64 (defun describe-text-widget (widget)
  65   "Insert text to describe WIDGET in the current buffer."
  66   (widget-create 'link
  67                  :notify `(lambda (&rest ignore)
  68                             (widget-browse ',widget))
  69                  (format "%S" (if (symbolp widget)
  70                                   widget
  71                                 (car widget))))
  72   (widget-insert " ")
  73   (widget-create 'info-link :tag "widget" "(widget)Top"))
  74
  75 (defun describe-text-sexp (sexp)
  76   "Insert a short description of SEXP in the current buffer."
  77   (let ((pp (condition-case signal
  78                 (pp-to-string sexp)
  79               (error (prin1-to-string signal)))))
  80     (when (string-match "\n\\'" pp)
  81       (setq pp (substring pp 0 (1- (length pp)))))
  82     (if (cond ((string-match "\n" pp)
  83                nil)
  84               ((> (length pp) (- (window-width) (current-column)))
  85                nil)
  86               (t t))
  87         (widget-insert pp)
  88       (widget-create 'push-button
  89                      :tag "show"
  90                      :action (lambda (widget &optional event)
  91                                (with-output-to-temp-buffer
  92                                    "*Pp Eval Output*"
  93                                  (princ (widget-get widget :value))))
  94                      pp))))
  95
  96 (defun describe-property-list (properties)
  97   "Insert a description of PROPERTIES in the current buffer.
  98 PROPERTIES should be a list of overlay or text properties.
  99 The `category' property is made into a widget button that call
 100 `describe-text-category' when pushed."
 101   ;; Sort the properties by the size of their value.
 102   (dolist (elt (sort (let ((ret nil)
 103                            (key nil)
 104                            (val nil)
 105                            (len nil))
 106                        (while properties
 107                          (setq key (pop properties)
 108                                val (pop properties)
 109                                len 0)
 110                          (unless (or (eq key 'category)
 111                                      (widgetp val))
 112                            (setq val (pp-to-string val)
 113                                  len (length val)))
 114                          (push (list key val len) ret))
 115                        ret)
 116                      (lambda (a b)
 117                        (< (nth 2 a)
 118                           (nth 2 b)))))
 119     (let ((key (nth 0 elt))
 120           (value (nth 1 elt)))
 121       (widget-insert (propertize (format "  %-20s " key)
 122                                  'font-lock-face 'italic))
 123       (cond ((eq key 'category)
 124              (widget-create 'link
 125                             :notify `(lambda (&rest ignore)
 126                                        (describe-text-category ',value))
 127                             (format "%S" value)))
 128             ((widgetp value)
 129              (describe-text-widget value))
 130             (t
 131              (widget-insert value))))
 132     (widget-insert "\n")))
 133 \f
 134 ;;; Describe-Text Commands.
 135
 136 (defun describe-text-category (category)
 137   "Describe a text property category."
 138   (interactive "S")
 139   (save-excursion
 140     (with-output-to-temp-buffer "*Help*"
 141       (set-buffer standard-output)
 142       (widget-insert "Category " (format "%S" category) ":\n\n")
 143       (describe-property-list (symbol-plist category))
 144       (describe-text-mode)
 145       (goto-char (point-min)))))
 146
 147 ;;;###autoload
 148 (defun describe-text-properties (pos &optional output-buffer)
 149   "Describe widgets, buttons, overlays and text properties at POS.
 150 Interactively, describe them for the character after point.
 151 If optional second argument OUTPUT-BUFFER is non-nil,
 152 insert the output into that buffer, and don't initialize or clear it
 153 otherwise."
 154   (interactive "d")
 155   (if (>= pos (point-max))
 156       (error "No character follows specified position"))
 157   (if output-buffer
 158       (describe-text-properties-1 pos output-buffer)
 159     (if (not (or (text-properties-at pos) (overlays-at pos)))
 160         (message "This is plain text.")
 161       (let ((buffer (current-buffer)))
 162         (when (eq buffer (get-buffer "*Help*"))
 163           (error "Can't do self inspection"))
 164         (save-excursion
 165           (with-output-to-temp-buffer "*Help*"
 166             (set-buffer standard-output)
 167             (setq output-buffer (current-buffer))
 168             (widget-insert "Text content at position " (format "%d" pos) ":\n\n")
 169             (with-current-buffer buffer
 170               (describe-text-properties-1 pos output-buffer))
 171             (describe-text-mode)
 172             (goto-char (point-min))))))))
 173
 174 (defun describe-text-properties-1 (pos output-buffer)
 175   (let* ((properties (text-properties-at pos))
 176          (overlays (overlays-at pos))
 177          overlay
 178          (wid-field (get-char-property pos 'field))
 179          (wid-button (get-char-property pos 'button))
 180          (wid-doc (get-char-property pos 'widget-doc))
 181          ;; If button.el is not loaded, we have no buttons in the text.
 182          (button (and (fboundp 'button-at) (button-at pos)))
 183          (button-type (and button (button-type button)))
 184          (button-label (and button (button-label button)))
 185          (widget (or wid-field wid-button wid-doc)))
 186     (with-current-buffer output-buffer
 187       ;; Widgets
 188       (when (widgetp widget)
 189         (newline)
 190         (widget-insert (cond (wid-field "This is an editable text area")
 191                              (wid-button "This is an active area")
 192                              (wid-doc "This is documentation text")))
 193         (widget-insert " of a ")
 194         (describe-text-widget widget)
 195         (widget-insert ".\n\n"))
 196       ;; Buttons
 197       (when (and button (not (widgetp wid-button)))
 198         (newline)
 199         (widget-insert "Here is a " (format "%S" button-type)
 200                        " button labeled `" button-label "'.\n\n"))
 201       ;; Overlays
 202       (when overlays
 203         (newline)
 204         (if (eq (length overlays) 1)
 205             (widget-insert "There is an overlay here:\n")
 206           (widget-insert "There are " (format "%d" (length overlays))
 207                          " overlays here:\n"))
 208         (dolist (overlay overlays)
 209           (widget-insert " From " (format "%d" (overlay-start overlay))
 210                          " to " (format "%d" (overlay-end overlay)) "\n")
 211           (describe-property-list (overlay-properties overlay)))
 212         (widget-insert "\n"))
 213       ;; Text properties
 214       (when properties
 215         (newline)
 216         (widget-insert "There are text properties here:\n")
 217         (describe-property-list properties)))))
 218
 219 ;;;###autoload
 220 (defun describe-char (pos)
 221   "Describe the character after POS (interactively, the character after point).
 222 The information includes character code, charset and code points in it,
 223 syntax, category, how the character is encoded in a file,
 224 character composition information (if relevant),
 225 as well as widgets, buttons, overlays, and text properties."
 226   (interactive "d")
 227   (if (>= pos (point-max))
 228       (error "No character follows specified position"))
 229   (let* ((char (char-after pos))
 230          (charset (char-charset char))
 231          (buffer (current-buffer))
 232          (composition (find-composition pos nil nil t))
 233          (composed (if composition (buffer-substring (car composition)
 234                                                      (nth 1 composition))))
 235          (multibyte-p enable-multibyte-characters)
 236          item-list max-width)
 237     (if (eq charset 'unknown)
 238         (setq item-list
 239               `(("character"
 240                  ,(format "%s (0%o, %d, 0x%x) -- invalid character code"
 241                           (if (< char 256)
 242                               (single-key-description char)
 243                             (char-to-string char))
 244                           char char char))))
 245       (setq item-list
 246             `(("character"
 247                ,(format "%s (0%o, %d, 0x%x)" (if (< char 256)
 248                                                  (single-key-description char)
 249                                                (char-to-string char))
 250                         char char char))
 251               ("charset"
 252                ,(symbol-name charset)
 253                ,(format "(%s)" (charset-description charset)))
 254               ("code point"
 255                ,(let ((split (split-char char)))
 256                   (if (= (charset-dimension charset) 1)
 257                       (format "%d" (nth 1 split))
 258                     (format "%d %d" (nth 1 split) (nth 2 split)))))
 259               ("syntax"
 260                ,(let ((syntax (syntax-after pos)))
 261                   (with-temp-buffer
 262                     (internal-describe-syntax-value syntax)
 263                     (buffer-string))))
 264               ("category"
 265                ,@(let ((category-set (char-category-set char)))
 266                    (if (not category-set)
 267                        '("-- none --")
 268                      (mapcar #'(lambda (x) (format "%c:%s  "
 269                                                    x (category-docstring x)))
 270                              (category-set-mnemonics category-set)))))
 271               ,@(let ((props (aref char-code-property-table char))
 272                       ps)
 273                   (when props
 274                     (while props
 275                       (push (format "%s:" (pop props)) ps)
 276                       (push (format "%s;" (pop props)) ps))
 277                     (list (cons "Properties" (nreverse ps)))))
 278               ("buffer code"
 279                ,(encoded-string-description
 280                  (string-as-unibyte (char-to-string char)) nil))
 281               ("file code"
 282                ,@(let* ((coding buffer-file-coding-system)
 283                         (encoded (encode-coding-char char coding)))
 284                    (if encoded
 285                        (list (encoded-string-description encoded coding)
 286                              (format "(encoded by coding system %S)" coding))
 287                      (list "not encodable by coding system"
 288                            (symbol-name coding)))))
 289               ,@(if (or (memq 'mule-utf-8
 290                           (find-coding-systems-region pos (1+ pos)))
 291                         (get-char-property pos 'untranslated-utf-8))
 292                     (let ((uc (or (get-char-property pos 'untranslated-utf-8)
 293                                   (encode-char char 'ucs))))
 294                       (if uc
 295                           (list (list "Unicode"
 296                                       (format "%04X" uc))))))
 297               ,(if (display-graphic-p (selected-frame))
 298                    (list "font" (or (internal-char-font pos)
 299                                     "-- none --"))
 300                  (list "terminal code"
 301                        (let* ((coding (terminal-coding-system))
 302                               (encoded (encode-coding-char char coding)))
 303                          (if encoded
 304                              (encoded-string-description encoded coding)
 305                            "not encodable")))))))
 306     (setq max-width (apply #'max (mapcar #'(lambda (x) (length (car x)))
 307                                          item-list)))
 308     (when (eq (current-buffer) (get-buffer "*Help*"))
 309       (error "Can't do self inspection"))
 310     (with-output-to-temp-buffer "*Help*"
 311       (with-current-buffer standard-output
 312         (set-buffer-multibyte multibyte-p)
 313         (let ((formatter (format "%%%ds:" max-width)))
 314           (dolist (elt item-list)
 315             (insert (format formatter (car elt)))
 316             (dolist (clm (cdr elt))
 317               (when (>= (+ (current-column)
 318                            (or (string-match "\n" clm)
 319                                (string-width clm)) 1)
 320                         (frame-width))
 321                 (insert "\n")
 322                 (indent-to (1+ max-width)))
 323               (insert " " clm))
 324             (insert "\n")))
 325         (when composition
 326           (insert "\nComposed with the "
 327                   (cond
 328                    ((eq pos (car composition)) "following ")
 329                    ((eq (1+ pos) (cadr composition)) "preceding ")
 330                    (t ""))
 331                   "character(s) `"
 332                   (cond
 333                    ((eq pos (car composition)) (substring composed 1))
 334                    ((eq (1+ pos) (cadr composition)) (substring composed 0 -1))
 335                    (t (concat (substring composed 0 (- pos (car composition)))
 336                               "' and `"
 337                               (substring composed (- (1+ pos) (car composition))))))
 338
 339                   "' to form `" composed "'")
 340           (if (nth 3 composition)
 341               (insert ".\n")
 342             (insert "\nby the rule ("
 343                     (mapconcat (lambda (x)
 344                                  (format (if (consp x) "%S" "?%c") x))
 345                                (nth 2 composition)
 346                                " ")
 347                     ").\n"
 348                     "See the variable `reference-point-alist' for "
 349                     "the meaning of the rule.\n")))
 350
 351         (let ((output (current-buffer)))
 352           (with-current-buffer buffer
 353             (describe-text-properties pos output))
 354           (describe-text-mode))))))
 355
 356 (provide 'descr-text)
 357
 358 ;;; descr-text.el ends here