lisp/replace.el

   1 ;;; replace.el --- replace commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992, 1994, 1996, 1997, 2000, 2001,
   4 ;;   2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package supplies the string and regular-expression replace functions
  28 ;; documented in the Emacs user's manual.
  29
  30 ;;; Code:
  31
  32 (defcustom case-replace t
  33   "*Non-nil means `query-replace' should preserve case in replacements."
  34   :type 'boolean
  35   :group 'matching)
  36
  37 (defvar query-replace-history nil)
  38
  39 (defvar query-replace-defaults nil
  40   "Default values of FROM-STRING and TO-STRING for `query-replace'.
  41 This is a cons cell (FROM-STRING . TO-STRING), or nil if there is
  42 no default value.")
  43
  44 (defvar query-replace-interactive nil
  45   "Non-nil means `query-replace' uses the last search string.
  46 That becomes the \"string to replace\".")
  47
  48 (defcustom query-replace-from-history-variable 'query-replace-history
  49   "History list to use for the FROM argument of `query-replace' commands.
  50 The value of this variable should be a symbol; that symbol
  51 is used as a variable to hold a history list for the strings
  52 or patterns to be replaced."
  53   :group 'matching
  54   :type 'symbol
  55   :version "20.3")
  56
  57 (defcustom query-replace-to-history-variable 'query-replace-history
  58   "History list to use for the TO argument of `query-replace' commands.
  59 The value of this variable should be a symbol; that symbol
  60 is used as a variable to hold a history list for replacement
  61 strings or patterns."
  62   :group 'matching
  63   :type 'symbol
  64   :version "20.3")
  65
  66 (defcustom query-replace-skip-read-only nil
  67   "*Non-nil means `query-replace' and friends ignore read-only matches."
  68   :type 'boolean
  69   :group 'matching
  70   :version "22.1")
  71
  72 (defcustom query-replace-highlight t
  73   "*Non-nil means to highlight matches during query replacement."
  74   :type 'boolean
  75   :group 'matching)
  76
  77 (defcustom query-replace-lazy-highlight t
  78   "*Controls the lazy-highlighting during query replacements.
  79 When non-nil, all text in the buffer matching the current match
  80 is highlighted lazily using isearch lazy highlighting (see
  81 `lazy-highlight-initial-delay' and `lazy-highlight-interval')."
  82   :type 'boolean
  83   :group 'lazy-highlight
  84   :group 'matching
  85   :version "22.1")
  86
  87 (defface query-replace
  88   '((t (:inherit isearch)))
  89   "Face for highlighting query replacement matches."
  90   :group 'matching
  91   :version "22.1")
  92
  93 (defun query-replace-descr (string)
  94   (mapconcat 'isearch-text-char-description string ""))
  95
  96 (defun query-replace-read-from (prompt regexp-flag)
  97   "Query and return the `from' argument of a query-replace operation.
  98 The return value can also be a pair (FROM . TO) indicating that the user
  99 wants to replace FROM with TO."
 100   (if query-replace-interactive
 101       (car (if regexp-flag regexp-search-ring search-ring))
 102     (let* ((history-add-new-input nil)
 103            (from
 104             ;; The save-excursion here is in case the user marks and copies
 105             ;; a region in order to specify the minibuffer input.
 106             ;; That should not clobber the region for the query-replace itself.
 107             (save-excursion
 108               (read-from-minibuffer
 109                (if query-replace-defaults
 110                    (format "%s (default %s -> %s): " prompt
 111                            (query-replace-descr (car query-replace-defaults))
 112                            (query-replace-descr (cdr query-replace-defaults)))
 113                  (format "%s: " prompt))
 114                nil nil nil
 115                query-replace-from-history-variable
 116                nil t))))
 117       (if (and (zerop (length from)) query-replace-defaults)
 118           (cons (car query-replace-defaults)
 119                 (query-replace-compile-replacement
 120                  (cdr query-replace-defaults) regexp-flag))
 121         (add-to-history query-replace-from-history-variable from nil t)
 122         ;; Warn if user types \n or \t, but don't reject the input.
 123         (and regexp-flag
 124              (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\(\\\\[nt]\\)" from)
 125              (let ((match (match-string 3 from)))
 126                (cond
 127                 ((string= match "\\n")
 128                  (message "Note: `\\n' here doesn't match a newline; to do that, type C-q C-j instead"))
 129                 ((string= match "\\t")
 130                  (message "Note: `\\t' here doesn't match a tab; to do that, just type TAB")))
 131                (sit-for 2)))
 132         from))))
 133
 134 (defun query-replace-compile-replacement (to regexp-flag)
 135   "Maybe convert a regexp replacement TO to Lisp.
 136 Returns a list suitable for `perform-replace' if necessary,
 137 the original string if not."
 138   (if (and regexp-flag
 139            (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\\\[,#]" to))
 140       (let (pos list char)
 141         (while
 142             (progn
 143               (setq pos (match-end 0))
 144               (push (substring to 0 (- pos 2)) list)
 145               (setq char (aref to (1- pos))
 146                     to (substring to pos))
 147               (cond ((eq char ?\#)
 148                      (push '(number-to-string replace-count) list))
 149                     ((eq char ?\,)
 150                      (setq pos (read-from-string to))
 151                      (push `(replace-quote ,(car pos)) list)
 152                      (let ((end
 153                             ;; Swallow a space after a symbol
 154                             ;; if there is a space.
 155                             (if (and (or (symbolp (car pos))
 156                                          ;; Swallow a space after 'foo
 157                                          ;; but not after (quote foo).
 158                                          (and (eq (car-safe (car pos)) 'quote)
 159                                               (not (= ?\( (aref to 0)))))
 160                                      (eq (string-match " " to (cdr pos))
 161                                          (cdr pos)))
 162                                 (1+ (cdr pos))
 163                               (cdr pos))))
 164                        (setq to (substring to end)))))
 165               (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\\\[,#]" to)))
 166         (setq to (nreverse (delete "" (cons to list))))
 167         (replace-match-string-symbols to)
 168         (cons 'replace-eval-replacement
 169               (if (cdr to)
 170                   (cons 'concat to)
 171                 (car to))))
 172     to))
 173
 174
 175 (defun query-replace-read-to (from prompt regexp-flag)
 176   "Query and return the `to' argument of a query-replace operation."
 177   (query-replace-compile-replacement
 178    (save-excursion
 179      (let* ((history-add-new-input nil)
 180             (to (read-from-minibuffer
 181                  (format "%s %s with: " prompt (query-replace-descr from))
 182                  nil nil nil
 183                  query-replace-to-history-variable from t)))
 184        (add-to-history query-replace-to-history-variable to nil t)
 185        (setq query-replace-defaults (cons from to))
 186        to))
 187    regexp-flag))
 188
 189 (defun query-replace-read-args (prompt regexp-flag &optional noerror)
 190   (unless noerror
 191     (barf-if-buffer-read-only))
 192   (let* ((from (query-replace-read-from prompt regexp-flag))
 193          (to (if (consp from) (prog1 (cdr from) (setq from (car from)))
 194                (query-replace-read-to from prompt regexp-flag))))
 195     (list from to current-prefix-arg)))
 196
 197 (defun query-replace (from-string to-string &optional delimited start end)
 198   "Replace some occurrences of FROM-STRING with TO-STRING.
 199 As each match is found, the user must type a character saying
 200 what to do with it.  For directions, type \\[help-command] at that time.
 201
 202 In Transient Mark mode, if the mark is active, operate on the contents
 203 of the region.  Otherwise, operate from point to the end of the buffer.
 204
 205 If `query-replace-interactive' is non-nil, the last incremental search
 206 string is used as FROM-STRING--you don't have to specify it with the
 207 minibuffer.
 208
 209 Matching is independent of case if `case-fold-search' is non-nil and
 210 FROM-STRING has no uppercase letters.  Replacement transfers the case
 211 pattern of the old text to the new text, if `case-replace' and
 212 `case-fold-search' are non-nil and FROM-STRING has no uppercase
 213 letters.  \(Transferring the case pattern means that if the old text
 214 matched is all caps, or capitalized, then its replacement is upcased
 215 or capitalized.)
 216
 217 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 218 only matches surrounded by word boundaries.
 219 Fourth and fifth arg START and END specify the region to operate on.
 220
 221 To customize possible responses, change the \"bindings\" in `query-replace-map'."
 222   (interactive (let ((common
 223                       (query-replace-read-args
 224                        (if (and transient-mark-mode mark-active)
 225                          "Query replace in region"
 226                          "Query replace")
 227                          nil)))
 228                  (list (nth 0 common) (nth 1 common) (nth 2 common)
 229                        ;; These are done separately here
 230                        ;; so that command-history will record these expressions
 231                        ;; rather than the values they had this time.
 232                        (if (and transient-mark-mode mark-active)
 233                            (region-beginning))
 234                        (if (and transient-mark-mode mark-active)
 235                            (region-end)))))
 236   (perform-replace from-string to-string t nil delimited nil nil start end))
 237
 238 (define-key esc-map "%" 'query-replace)
 239
 240 (defun query-replace-regexp (regexp to-string &optional delimited start end)
 241   "Replace some things after point matching REGEXP with TO-STRING.
 242 As each match is found, the user must type a character saying
 243 what to do with it.  For directions, type \\[help-command] at that time.
 244
 245 In Transient Mark mode, if the mark is active, operate on the contents
 246 of the region.  Otherwise, operate from point to the end of the buffer.
 247
 248 If `query-replace-interactive' is non-nil, the last incremental search
 249 regexp is used as REGEXP--you don't have to specify it with the
 250 minibuffer.
 251
 252 Matching is independent of case if `case-fold-search' is non-nil and
 253 REGEXP has no uppercase letters.  Replacement transfers the case
 254 pattern of the old text to the new text, if `case-replace' and
 255 `case-fold-search' are non-nil and REGEXP has no uppercase letters.
 256 \(Transferring the case pattern means that if the old text matched is
 257 all caps, or capitalized, then its replacement is upcased or
 258 capitalized.)
 259
 260 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 261 only matches surrounded by word boundaries.
 262 Fourth and fifth arg START and END specify the region to operate on.
 263
 264 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 265 and `\\=\\N' (where N is a digit) stands for
 266 whatever what matched the Nth `\\(...\\)' in REGEXP.
 267 `\\?' lets you edit the replacement text in the minibuffer
 268 at the given position for each replacement.
 269
 270 In interactive calls, the replacement text can contain `\\,'
 271 followed by a Lisp expression.  Each
 272 replacement evaluates that expression to compute the replacement
 273 string.  Inside of that expression, `\\&' is a string denoting the
 274 whole match as a string, `\\N' for a partial match, `\\#&' and `\\#N'
 275 for the whole or a partial match converted to a number with
 276 `string-to-number', and `\\#' itself for the number of replacements
 277 done so far (starting with zero).
 278
 279 If the replacement expression is a symbol, write a space after it
 280 to terminate it.  One space there, if any, will be discarded.
 281
 282 When using those Lisp features interactively in the replacement
 283 text, TO-STRING is actually made a list instead of a string.
 284 Use \\[repeat-complex-command] after this command for details."
 285   (interactive
 286    (let ((common
 287           (query-replace-read-args
 288            (if (and transient-mark-mode mark-active)
 289                "Query replace regexp in region"
 290              "Query replace regexp")
 291            t)))
 292      (list (nth 0 common) (nth 1 common) (nth 2 common)
 293            ;; These are done separately here
 294            ;; so that command-history will record these expressions
 295            ;; rather than the values they had this time.
 296            (if (and transient-mark-mode mark-active)
 297                (region-beginning))
 298            (if (and transient-mark-mode mark-active)
 299                (region-end)))))
 300   (perform-replace regexp to-string t t delimited nil nil start end))
 301
 302 (define-key esc-map [?\C-%] 'query-replace-regexp)
 303
 304 (defun query-replace-regexp-eval (regexp to-expr &optional delimited start end)
 305   "Replace some things after point matching REGEXP with the result of TO-EXPR.
 306 As each match is found, the user must type a character saying
 307 what to do with it.  For directions, type \\[help-command] at that time.
 308
 309 TO-EXPR is a Lisp expression evaluated to compute each replacement.  It may
 310 reference `replace-count' to get the number of replacements already made.
 311 If the result of TO-EXPR is not a string, it is converted to one using
 312 `prin1-to-string' with the NOESCAPE argument (which see).
 313
 314 For convenience, when entering TO-EXPR interactively, you can use `\\&' or
 315 `\\0' to stand for whatever matched the whole of REGEXP, and `\\N' (where
 316 N is a digit) to stand for whatever matched the Nth `\\(...\\)' in REGEXP.
 317 Use `\\#&' or `\\#N' if you want a number instead of a string.
 318 In interactive use, `\\#' in itself stands for `replace-count'.
 319
 320 In Transient Mark mode, if the mark is active, operate on the contents
 321 of the region.  Otherwise, operate from point to the end of the buffer.
 322
 323 If `query-replace-interactive' is non-nil, the last incremental search
 324 regexp is used as REGEXP--you don't have to specify it with the
 325 minibuffer.
 326
 327 Preserves case in each replacement if `case-replace' and `case-fold-search'
 328 are non-nil and REGEXP has no uppercase letters.
 329
 330 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 331 only matches that are surrounded by word boundaries.
 332 Fourth and fifth arg START and END specify the region to operate on."
 333   (interactive
 334    (progn
 335    (barf-if-buffer-read-only)
 336    (let* ((from
 337            ;; Let-bind the history var to disable the "foo -> bar" default.
 338            ;; Maybe we shouldn't disable this default, but for now I'll
 339            ;; leave it off.  --Stef
 340            (let ((query-replace-to-history-variable nil))
 341              (query-replace-read-from "Query replace regexp" t)))
 342           (to (list (read-from-minibuffer
 343                      (format "Query replace regexp %s with eval: "
 344                              (query-replace-descr from))
 345                      nil nil t query-replace-to-history-variable from t))))
 346      ;; We make TO a list because replace-match-string-symbols requires one,
 347      ;; and the user might enter a single token.
 348      (replace-match-string-symbols to)
 349      (list from (car to) current-prefix-arg
 350            (if (and transient-mark-mode mark-active)
 351                (region-beginning))
 352            (if (and transient-mark-mode mark-active)
 353                (region-end))))))
 354   (perform-replace regexp (cons 'replace-eval-replacement to-expr)
 355                    t 'literal delimited nil nil start end))
 356
 357 (defun map-query-replace-regexp (regexp to-strings &optional n start end)
 358   "Replace some matches for REGEXP with various strings, in rotation.
 359 The second argument TO-STRINGS contains the replacement strings,
 360 separated by spaces.  Third arg DELIMITED (prefix arg if interactive),
 361 if non-nil, means replace only matches surrounded by word boundaries.
 362 This command works like `query-replace-regexp' except that each
 363 successive replacement uses the next successive replacement string,
 364 wrapping around from the last such string to the first.
 365
 366 In Transient Mark mode, if the mark is active, operate on the contents
 367 of the region.  Otherwise, operate from point to the end of the buffer.
 368
 369 Non-interactively, TO-STRINGS may be a list of replacement strings.
 370
 371 If `query-replace-interactive' is non-nil, the last incremental search
 372 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 373
 374 A prefix argument N says to use each replacement string N times
 375 before rotating to the next.
 376 Fourth and fifth arg START and END specify the region to operate on."
 377   (interactive
 378    (let* ((from (if query-replace-interactive
 379                     (car regexp-search-ring)
 380                   (read-from-minibuffer "Map query replace (regexp): "
 381                                         nil nil nil
 382                                         'query-replace-history nil t)))
 383           (to (read-from-minibuffer
 384                (format "Query replace %s with (space-separated strings): "
 385                        (query-replace-descr from))
 386                nil nil nil
 387                'query-replace-history from t)))
 388      (list from to
 389            (and current-prefix-arg
 390                 (prefix-numeric-value current-prefix-arg))
 391            (if (and transient-mark-mode mark-active)
 392                (region-beginning))
 393            (if (and transient-mark-mode mark-active)
 394                (region-end)))))
 395   (let (replacements)
 396     (if (listp to-strings)
 397         (setq replacements to-strings)
 398       (while (/= (length to-strings) 0)
 399         (if (string-match " " to-strings)
 400             (setq replacements
 401                   (append replacements
 402                           (list (substring to-strings 0
 403                                            (string-match " " to-strings))))
 404                   to-strings (substring to-strings
 405                                        (1+ (string-match " " to-strings))))
 406           (setq replacements (append replacements (list to-strings))
 407                 to-strings ""))))
 408     (perform-replace regexp replacements t t nil n nil start end)))
 409
 410 (defun replace-string (from-string to-string &optional delimited start end)
 411   "Replace occurrences of FROM-STRING with TO-STRING.
 412 Preserve case in each match if `case-replace' and `case-fold-search'
 413 are non-nil and FROM-STRING has no uppercase letters.
 414 \(Preserving case means that if the string matched is all caps, or capitalized,
 415 then its replacement is upcased or capitalized.)
 416
 417 In Transient Mark mode, if the mark is active, operate on the contents
 418 of the region.  Otherwise, operate from point to the end of the buffer.
 419
 420 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 421 only matches surrounded by word boundaries.
 422 Fourth and fifth arg START and END specify the region to operate on.
 423
 424 If `query-replace-interactive' is non-nil, the last incremental search
 425 string is used as FROM-STRING--you don't have to specify it with the
 426 minibuffer.
 427
 428 This function is usually the wrong thing to use in a Lisp program.
 429 What you probably want is a loop like this:
 430   (while (search-forward FROM-STRING nil t)
 431     (replace-match TO-STRING nil t))
 432 which will run faster and will not set the mark or print anything.
 433 \(You may need a more complex loop if FROM-STRING can match the null string
 434 and TO-STRING is also null.)"
 435   (interactive
 436    (let ((common
 437           (query-replace-read-args
 438            (if (and transient-mark-mode mark-active)
 439                "Replace string in region"
 440              "Replace string")
 441            nil)))
 442      (list (nth 0 common) (nth 1 common) (nth 2 common)
 443            (if (and transient-mark-mode mark-active)
 444                (region-beginning))
 445            (if (and transient-mark-mode mark-active)
 446                (region-end)))))
 447   (perform-replace from-string to-string nil nil delimited nil nil start end))
 448
 449 (defun replace-regexp (regexp to-string &optional delimited start end)
 450   "Replace things after point matching REGEXP with TO-STRING.
 451 Preserve case in each match if `case-replace' and `case-fold-search'
 452 are non-nil and REGEXP has no uppercase letters.
 453
 454 In Transient Mark mode, if the mark is active, operate on the contents
 455 of the region.  Otherwise, operate from point to the end of the buffer.
 456
 457 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 458 only matches surrounded by word boundaries.
 459 Fourth and fifth arg START and END specify the region to operate on.
 460
 461 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 462 and `\\=\\N' (where N is a digit) stands for
 463 whatever what matched the Nth `\\(...\\)' in REGEXP.
 464 `\\?' lets you edit the replacement text in the minibuffer
 465 at the given position for each replacement.
 466
 467 In interactive calls, the replacement text may contain `\\,'
 468 followed by a Lisp expression used as part of the replacement
 469 text.  Inside of that expression, `\\&' is a string denoting the
 470 whole match, `\\N' a partial match, `\\#&' and `\\#N' the respective
 471 numeric values from `string-to-number', and `\\#' itself for
 472 `replace-count', the number of replacements occurred so far.
 473
 474 If your Lisp expression is an identifier and the next letter in
 475 the replacement string would be interpreted as part of it, you
 476 can wrap it with an expression like `\\,(or \\#)'.  Incidentally,
 477 for this particular case you may also enter `\\#' in the
 478 replacement text directly.
 479
 480 When using those Lisp features interactively in the replacement
 481 text, TO-STRING is actually made a list instead of a string.
 482 Use \\[repeat-complex-command] after this command for details.
 483
 484 If `query-replace-interactive' is non-nil, the last incremental search
 485 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 486
 487 This function is usually the wrong thing to use in a Lisp program.
 488 What you probably want is a loop like this:
 489   (while (re-search-forward REGEXP nil t)
 490     (replace-match TO-STRING nil nil))
 491 which will run faster and will not set the mark or print anything."
 492   (interactive
 493    (let ((common
 494           (query-replace-read-args
 495            (if (and transient-mark-mode mark-active)
 496                "Replace regexp in region"
 497              "Replace regexp")
 498            t)))
 499      (list (nth 0 common) (nth 1 common) (nth 2 common)
 500            (if (and transient-mark-mode mark-active)
 501                (region-beginning))
 502            (if (and transient-mark-mode mark-active)
 503                (region-end)))))
 504   (perform-replace regexp to-string nil t delimited nil nil start end))
 505
 506 \f
 507 (defvar regexp-history nil
 508   "History list for some commands that read regular expressions.")
 509
 510
 511 (defalias 'delete-non-matching-lines 'keep-lines)
 512 (defalias 'delete-matching-lines 'flush-lines)
 513 (defalias 'count-matches 'how-many)
 514
 515
 516 (defun keep-lines-read-args (prompt)
 517   "Read arguments for `keep-lines' and friends.
 518 Prompt for a regexp with PROMPT.
 519 Value is a list, (REGEXP)."
 520   (list (read-from-minibuffer prompt nil nil nil
 521                               'regexp-history nil t)
 522         nil nil t))
 523
 524 (defun keep-lines (regexp &optional rstart rend interactive)
 525   "Delete all lines except those containing matches for REGEXP.
 526 A match split across lines preserves all the lines it lies in.
 527 When called from Lisp (and usually interactively as well, see below)
 528 applies to all lines starting after point.
 529
 530 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 531 the matching is case-sensitive.
 532
 533 Second and third arg RSTART and REND specify the region to operate on.
 534 This command operates on (the accessible part of) all lines whose
 535 accessible part is entirely contained in the region determined by RSTART
 536 and REND.  (A newline ending a line counts as part of that line.)
 537
 538 Interactively, in Transient Mark mode when the mark is active, operate
 539 on all lines whose accessible part is entirely contained in the region.
 540 Otherwise, the command applies to all lines starting after point.
 541 When calling this function from Lisp, you can pretend that it was
 542 called interactively by passing a non-nil INTERACTIVE argument.
 543
 544 This function starts looking for the next match from the end of
 545 the previous match.  Hence, it ignores matches that overlap
 546 a previously found match."
 547
 548   (interactive
 549    (progn
 550      (barf-if-buffer-read-only)
 551      (keep-lines-read-args "Keep lines (containing match for regexp): ")))
 552   (if rstart
 553       (progn
 554         (goto-char (min rstart rend))
 555         (setq rend
 556               (progn
 557                 (save-excursion
 558                   (goto-char (max rstart rend))
 559                   (unless (or (bolp) (eobp))
 560                     (forward-line 0))
 561                   (point-marker)))))
 562     (if (and interactive transient-mark-mode mark-active)
 563         (setq rstart (region-beginning)
 564               rend (progn
 565                      (goto-char (region-end))
 566                      (unless (or (bolp) (eobp))
 567                        (forward-line 0))
 568                      (point-marker)))
 569       (setq rstart (point)
 570             rend (point-max-marker)))
 571     (goto-char rstart))
 572   (save-excursion
 573     (or (bolp) (forward-line 1))
 574     (let ((start (point))
 575           (case-fold-search  (and case-fold-search
 576                                   (isearch-no-upper-case-p regexp t))))
 577       (while (< (point) rend)
 578         ;; Start is first char not preserved by previous match.
 579         (if (not (re-search-forward regexp rend 'move))
 580             (delete-region start rend)
 581           (let ((end (save-excursion (goto-char (match-beginning 0))
 582                                      (forward-line 0)
 583                                      (point))))
 584             ;; Now end is first char preserved by the new match.
 585             (if (< start end)
 586                 (delete-region start end))))
 587
 588         (setq start (save-excursion (forward-line 1) (point)))
 589         ;; If the match was empty, avoid matching again at same place.
 590         (and (< (point) rend)
 591              (= (match-beginning 0) (match-end 0))
 592              (forward-char 1)))))
 593   (set-marker rend nil)
 594   nil)
 595
 596
 597 (defun flush-lines (regexp &optional rstart rend interactive)
 598  "Delete lines containing matches for REGEXP.
 599 When called from Lisp (and usually when called interactively as
 600 well, see below), applies to the part of the buffer after point.
 601 The line point is in is deleted if and only if it contains a
 602 match for regexp starting after point.
 603
 604 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 605 the matching is case-sensitive.
 606
 607 Second and third arg RSTART and REND specify the region to operate on.
 608 Lines partially contained in this region are deleted if and only if
 609 they contain a match entirely contained in it.
 610
 611 Interactively, in Transient Mark mode when the mark is active, operate
 612 on the contents of the region.  Otherwise, operate from point to the
 613 end of (the accessible portion of) the buffer.  When calling this function
 614 from Lisp, you can pretend that it was called interactively by passing
 615 a non-nil INTERACTIVE argument.
 616
 617 If a match is split across lines, all the lines it lies in are deleted.
 618 They are deleted _before_ looking for the next match.  Hence, a match
 619 starting on the same line at which another match ended is ignored."
 620
 621   (interactive
 622    (progn
 623      (barf-if-buffer-read-only)
 624      (keep-lines-read-args "Flush lines (containing match for regexp): ")))
 625   (if rstart
 626       (progn
 627         (goto-char (min rstart rend))
 628         (setq rend (copy-marker (max rstart rend))))
 629     (if (and interactive transient-mark-mode mark-active)
 630         (setq rstart (region-beginning)
 631               rend (copy-marker (region-end)))
 632       (setq rstart (point)
 633             rend (point-max-marker)))
 634     (goto-char rstart))
 635   (let ((case-fold-search (and case-fold-search
 636                                (isearch-no-upper-case-p regexp t))))
 637     (save-excursion
 638       (while (and (< (point) rend)
 639                   (re-search-forward regexp rend t))
 640         (delete-region (save-excursion (goto-char (match-beginning 0))
 641                                        (forward-line 0)
 642                                        (point))
 643                        (progn (forward-line 1) (point))))))
 644   (set-marker rend nil)
 645   nil)
 646
 647
 648 (defun how-many (regexp &optional rstart rend interactive)
 649   "Print and return number of matches for REGEXP following point.
 650 When called from Lisp and INTERACTIVE is omitted or nil, just return
 651 the number, do not print it; if INTERACTIVE is t, the function behaves
 652 in all respects has if it had been called interactively.
 653
 654 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 655 the matching is case-sensitive.
 656
 657 Second and third arg RSTART and REND specify the region to operate on.
 658
 659 Interactively, in Transient Mark mode when the mark is active, operate
 660 on the contents of the region.  Otherwise, operate from point to the
 661 end of (the accessible portion of) the buffer.
 662
 663 This function starts looking for the next match from the end of
 664 the previous match.  Hence, it ignores matches that overlap
 665 a previously found match."
 666
 667   (interactive
 668    (keep-lines-read-args "How many matches for (regexp): "))
 669   (save-excursion
 670     (if rstart
 671         (progn
 672           (goto-char (min rstart rend))
 673           (setq rend (max rstart rend)))
 674       (if (and interactive transient-mark-mode mark-active)
 675           (setq rstart (region-beginning)
 676                 rend (region-end))
 677         (setq rstart (point)
 678               rend (point-max)))
 679       (goto-char rstart))
 680     (let ((count 0)
 681           opoint
 682           (case-fold-search (and case-fold-search
 683                                  (isearch-no-upper-case-p regexp t))))
 684       (while (and (< (point) rend)
 685                   (progn (setq opoint (point))
 686                          (re-search-forward regexp rend t)))
 687         (if (= opoint (point))
 688             (forward-char 1)
 689           (setq count (1+ count))))
 690       (when interactive (message "%d occurrence%s"
 691                                  count
 692                                  (if (= count 1) "" "s")))
 693       count)))
 694
 695 \f
 696 (defvar occur-mode-map
 697   (let ((map (make-sparse-keymap)))
 698     ;; We use this alternative name, so we can use \\[occur-mode-mouse-goto].
 699     (define-key map [mouse-2] 'occur-mode-mouse-goto)
 700     (define-key map "\C-c\C-c" 'occur-mode-goto-occurrence)
 701     (define-key map "\C-m" 'occur-mode-goto-occurrence)
 702     (define-key map "o" 'occur-mode-goto-occurrence-other-window)
 703     (define-key map "\C-o" 'occur-mode-display-occurrence)
 704     (define-key map "\M-n" 'occur-next)
 705     (define-key map "\M-p" 'occur-prev)
 706     (define-key map "r" 'occur-rename-buffer)
 707     (define-key map "c" 'clone-buffer)
 708     (define-key map "g" 'revert-buffer)
 709     (define-key map "q" 'quit-window)
 710     (define-key map "z" 'kill-this-buffer)
 711     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
 712     map)
 713   "Keymap for `occur-mode'.")
 714
 715 (defvar occur-revert-arguments nil
 716   "Arguments to pass to `occur-1' to revert an Occur mode buffer.
 717 See `occur-revert-function'.")
 718
 719 (defcustom occur-mode-hook '(turn-on-font-lock)
 720   "Hook run when entering Occur mode."
 721   :type 'hook
 722   :group 'matching)
 723
 724 (defcustom occur-hook nil
 725   "Hook run by Occur when there are any matches."
 726   :type 'hook
 727   :group 'matching)
 728
 729 (put 'occur-mode 'mode-class 'special)
 730 (defun occur-mode ()
 731   "Major mode for output from \\[occur].
 732 \\<occur-mode-map>Move point to one of the items in this buffer, then use
 733 \\[occur-mode-goto-occurrence] to go to the occurrence that the item refers to.
 734 Alternatively, click \\[occur-mode-mouse-goto] on an item to go to it.
 735
 736 \\{occur-mode-map}"
 737   (interactive)
 738   (kill-all-local-variables)
 739   (use-local-map occur-mode-map)
 740   (setq major-mode 'occur-mode)
 741   (setq mode-name "Occur")
 742   (set (make-local-variable 'revert-buffer-function) 'occur-revert-function)
 743   (make-local-variable 'occur-revert-arguments)
 744   (add-hook 'change-major-mode-hook 'font-lock-defontify nil t)
 745   (setq next-error-function 'occur-next-error)
 746   (run-mode-hooks 'occur-mode-hook))
 747
 748 (defun occur-revert-function (ignore1 ignore2)
 749   "Handle `revert-buffer' for Occur mode buffers."
 750   (apply 'occur-1 (append occur-revert-arguments (list (buffer-name)))))
 751
 752 (defun occur-mode-find-occurrence ()
 753   (let ((pos (get-text-property (point) 'occur-target)))
 754     (unless pos
 755       (error "No occurrence on this line"))
 756     (unless (buffer-live-p (marker-buffer pos))
 757       (error "Buffer for this occurrence was killed"))
 758     pos))
 759
 760 (defalias 'occur-mode-mouse-goto 'occur-mode-goto-occurrence)
 761 (defun occur-mode-goto-occurrence (&optional event)
 762   "Go to the occurrence the current line describes."
 763   (interactive (list last-nonmenu-event))
 764   (let ((pos
 765          (if (null event)
 766              ;; Actually `event-end' works correctly with a nil argument as
 767              ;; well, so we could dispense with this test, but let's not
 768              ;; rely on this undocumented behavior.
 769              (occur-mode-find-occurrence)
 770            (with-current-buffer (window-buffer (posn-window (event-end event)))
 771              (save-excursion
 772                (goto-char (posn-point (event-end event)))
 773                (occur-mode-find-occurrence)))))
 774         same-window-buffer-names
 775         same-window-regexps)
 776     (pop-to-buffer (marker-buffer pos))
 777     (goto-char pos)))
 778
 779 (defun occur-mode-goto-occurrence-other-window ()
 780   "Go to the occurrence the current line describes, in another window."
 781   (interactive)
 782   (let ((pos (occur-mode-find-occurrence)))
 783     (switch-to-buffer-other-window (marker-buffer pos))
 784     (goto-char pos)))
 785
 786 (defun occur-mode-display-occurrence ()
 787   "Display in another window the occurrence the current line describes."
 788   (interactive)
 789   (let ((pos (occur-mode-find-occurrence))
 790         window
 791         ;; Bind these to ensure `display-buffer' puts it in another window.
 792         same-window-buffer-names
 793         same-window-regexps)
 794     (setq window (display-buffer (marker-buffer pos)))
 795     ;; This is the way to set point in the proper window.
 796     (save-selected-window
 797       (select-window window)
 798       (goto-char pos))))
 799
 800 (defun occur-find-match (n search message)
 801   (if (not n) (setq n 1))
 802   (let ((r))
 803     (while (> n 0)
 804       (setq r (funcall search (point) 'occur-match))
 805       (and r
 806            (get-text-property r 'occur-match)
 807            (setq r (funcall search r 'occur-match)))
 808       (if r
 809           (goto-char r)
 810         (error message))
 811       (setq n (1- n)))))
 812
 813 (defun occur-next (&optional n)
 814   "Move to the Nth (default 1) next match in an Occur mode buffer."
 815   (interactive "p")
 816   (occur-find-match n #'next-single-property-change "No more matches"))
 817
 818 (defun occur-prev (&optional n)
 819   "Move to the Nth (default 1) previous match in an Occur mode buffer."
 820   (interactive "p")
 821   (occur-find-match n #'previous-single-property-change "No earlier matches"))
 822
 823 (defun occur-next-error (&optional argp reset)
 824   "Move to the Nth (default 1) next match in an Occur mode buffer.
 825 Compatibility function for \\[next-error] invocations."
 826   (interactive "p")
 827   ;; we need to run occur-find-match from within the Occur buffer
 828   (with-current-buffer
 829       ;; Choose the buffer and make it current.
 830       (if (next-error-buffer-p (current-buffer))
 831           (current-buffer)
 832         (next-error-find-buffer nil nil
 833                                 (lambda ()
 834                                   (eq major-mode 'occur-mode))))
 835
 836     (goto-char (cond (reset (point-min))
 837                      ((< argp 0) (line-beginning-position))
 838                      ((> argp 0) (line-end-position))
 839                      ((point))))
 840     (occur-find-match
 841      (abs argp)
 842      (if (> 0 argp)
 843          #'previous-single-property-change
 844        #'next-single-property-change)
 845      "No more matches")
 846     ;; In case the *Occur* buffer is visible in a nonselected window.
 847     (set-window-point (get-buffer-window (current-buffer)) (point))
 848     (occur-mode-goto-occurrence)))
 849 \f
 850 (defface match
 851   '((((class color) (min-colors 88) (background light))
 852      :background "Tan")
 853     (((class color) (min-colors 88) (background dark))
 854      :background "RoyalBlue3")
 855     (((class color) (min-colors 8))
 856      :background "blue" :foreground "white")
 857     (((type tty) (class mono))
 858      :inverse-video t)
 859     (t :background "gray"))
 860   "Face used to highlight matches permanently."
 861   :group 'matching
 862   :version "22.1")
 863
 864 (defcustom list-matching-lines-default-context-lines 0
 865   "*Default number of context lines included around `list-matching-lines' matches.
 866 A negative number means to include that many lines before the match.
 867 A positive number means to include that many lines both before and after."
 868   :type 'integer
 869   :group 'matching)
 870
 871 (defalias 'list-matching-lines 'occur)
 872
 873 (defcustom list-matching-lines-face 'match
 874   "*Face used by \\[list-matching-lines] to show the text that matches.
 875 If the value is nil, don't highlight the matching portions specially."
 876   :type 'face
 877   :group 'matching)
 878
 879 (defcustom list-matching-lines-buffer-name-face 'underline
 880   "*Face used by \\[list-matching-lines] to show the names of buffers.
 881 If the value is nil, don't highlight the buffer names specially."
 882   :type 'face
 883   :group 'matching)
 884
 885 (defcustom occur-excluded-properties
 886   '(read-only invisible intangible field mouse-face help-echo local-map keymap
 887     yank-handler follow-link)
 888   "*Text properties to discard when copying lines to the *Occur* buffer.
 889 The value should be a list of text properties to discard or t,
 890 which means to discard all text properties."
 891   :type '(choice (const :tag "All" t) (repeat symbol))
 892   :group 'matching
 893   :version "22.1")
 894
 895 (defun occur-accumulate-lines (count &optional keep-props)
 896   (save-excursion
 897     (let ((forwardp (> count 0))
 898           result beg end)
 899       (while (not (or (zerop count)
 900                       (if forwardp
 901                           (eobp)
 902                         (bobp))))
 903         (setq count (+ count (if forwardp -1 1)))
 904         (setq beg (line-beginning-position)
 905               end (line-end-position))
 906         (if (and keep-props (if (boundp 'jit-lock-mode) jit-lock-mode)
 907                  (text-property-not-all beg end 'fontified t))
 908             (if (fboundp 'jit-lock-fontify-now)
 909                 (jit-lock-fontify-now beg end)))
 910         (push
 911          (if (and keep-props (not (eq occur-excluded-properties t)))
 912              (let ((str (buffer-substring beg end)))
 913                (remove-list-of-text-properties
 914                 0 (length str) occur-excluded-properties str)
 915                str)
 916            (buffer-substring-no-properties beg end))
 917          result)
 918         (forward-line (if forwardp 1 -1)))
 919       (nreverse result))))
 920
 921 (defun occur-read-primary-args ()
 922   (list (let* ((default (car regexp-history))
 923                (input
 924                 (read-from-minibuffer
 925                  (if default
 926                      (format "List lines matching regexp (default %s): "
 927                              (query-replace-descr default))
 928                    "List lines matching regexp: ")
 929                  nil
 930                  nil
 931                  nil
 932                  'regexp-history
 933                  default)))
 934           (if (equal input "")
 935               default
 936             input))
 937         (when current-prefix-arg
 938           (prefix-numeric-value current-prefix-arg))))
 939
 940 (defun occur-rename-buffer (&optional unique-p interactive-p)
 941   "Rename the current *Occur* buffer to *Occur: original-buffer-name*.
 942 Here `original-buffer-name' is the buffer name were Occur was originally run.
 943 When given the prefix argument, or called non-interactively, the renaming
 944 will not clobber the existing buffer(s) of that name, but use
 945 `generate-new-buffer-name' instead.  You can add this to `occur-hook'
 946 if you always want a separate *Occur* buffer for each buffer where you
 947 invoke `occur'."
 948   (interactive "P\np")
 949   (with-current-buffer
 950       (if (eq major-mode 'occur-mode) (current-buffer) (get-buffer "*Occur*"))
 951     (rename-buffer (concat "*Occur: "
 952                            (mapconcat #'buffer-name
 953                                       (car (cddr occur-revert-arguments)) "/")
 954                            "*")
 955                    (or unique-p (not interactive-p)))))
 956
 957 (defun occur (regexp &optional nlines)
 958   "Show all lines in the current buffer containing a match for REGEXP.
 959 This function can not handle matches that span more than one line.
 960
 961 Each line is displayed with NLINES lines before and after, or -NLINES
 962 before if NLINES is negative.
 963 NLINES defaults to `list-matching-lines-default-context-lines'.
 964 Interactively it is the prefix arg.
 965
 966 The lines are shown in a buffer named `*Occur*'.
 967 It serves as a menu to find any of the occurrences in this buffer.
 968 \\<occur-mode-map>\\[describe-mode] in that buffer will explain how.
 969
 970 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 971 the matching is case-sensitive."
 972   (interactive (occur-read-primary-args))
 973   (occur-1 regexp nlines (list (current-buffer))))
 974
 975 (defun multi-occur (bufs regexp &optional nlines)
 976   "Show all lines in buffers BUFS containing a match for REGEXP.
 977 This function acts on multiple buffers; otherwise, it is exactly like
 978 `occur'.  When you invoke this command interactively, you must specify
 979 the buffer names that you want, one by one."
 980   (interactive
 981    (cons
 982     (let* ((bufs (list (read-buffer "First buffer to search: "
 983                                     (current-buffer) t)))
 984            (buf nil)
 985            (ido-ignore-item-temp-list bufs))
 986       (while (not (string-equal
 987                    (setq buf (read-buffer
 988                               (if (eq read-buffer-function 'ido-read-buffer)
 989                                   "Next buffer to search (C-j to end): "
 990                                 "Next buffer to search (RET to end): ")
 991                               nil t))
 992                    ""))
 993         (add-to-list 'bufs buf)
 994         (setq ido-ignore-item-temp-list bufs))
 995       (nreverse (mapcar #'get-buffer bufs)))
 996     (occur-read-primary-args)))
 997   (occur-1 regexp nlines bufs))
 998
 999 (defun multi-occur-in-matching-buffers (bufregexp regexp &optional allbufs)
1000   "Show all lines matching REGEXP in buffers specified by BUFREGEXP.
1001 Normally BUFREGEXP matches against each buffer's visited file name,
1002 but if you specify a prefix argument, it matches against the buffer name.
1003 See also `multi-occur'."
1004   (interactive
1005    (cons
1006     (let* ((default (car regexp-history))
1007            (input
1008             (read-from-minibuffer
1009              (if current-prefix-arg
1010                  "List lines in buffers whose names match regexp: "
1011                "List lines in buffers whose filenames match regexp: ")
1012              nil
1013              nil
1014              nil
1015              'regexp-history)))
1016       (if (equal input "")
1017           default
1018         input))
1019     (occur-read-primary-args)))
1020   (when bufregexp
1021     (occur-1 regexp nil
1022              (delq nil
1023                    (mapcar (lambda (buf)
1024                              (when (if allbufs
1025                                        (string-match bufregexp
1026                                                      (buffer-name buf))
1027                                      (and (buffer-file-name buf)
1028                                           (string-match bufregexp
1029                                                         (buffer-file-name buf))))
1030                                buf))
1031                            (buffer-list))))))
1032
1033 (defun occur-1 (regexp nlines bufs &optional buf-name)
1034   (unless buf-name
1035     (setq buf-name "*Occur*"))
1036   (let (occur-buf
1037         (active-bufs (delq nil (mapcar #'(lambda (buf)
1038                                            (when (buffer-live-p buf) buf))
1039                                        bufs))))
1040     ;; Handle the case where one of the buffers we're searching is the
1041     ;; output buffer.  Just rename it.
1042     (when (member buf-name (mapcar 'buffer-name active-bufs))
1043       (with-current-buffer (get-buffer buf-name)
1044         (rename-uniquely)))
1045
1046     ;; Now find or create the output buffer.
1047     ;; If we just renamed that buffer, we will make a new one here.
1048     (setq occur-buf (get-buffer-create buf-name))
1049
1050     (with-current-buffer occur-buf
1051       (occur-mode)
1052       (let ((inhibit-read-only t))
1053         (erase-buffer)
1054         (let ((count (occur-engine
1055                       regexp active-bufs occur-buf
1056                       (or nlines list-matching-lines-default-context-lines)
1057                       (and case-fold-search
1058                            (isearch-no-upper-case-p regexp t))
1059                       list-matching-lines-buffer-name-face
1060                       nil list-matching-lines-face
1061                       (not (eq occur-excluded-properties t)))))
1062           (let* ((bufcount (length active-bufs))
1063                  (diff (- (length bufs) bufcount)))
1064             (message "Searched %d buffer%s%s; %s match%s for `%s'"
1065                      bufcount (if (= bufcount 1) "" "s")
1066                      (if (zerop diff) "" (format " (%d killed)" diff))
1067                      (if (zerop count) "no" (format "%d" count))
1068                      (if (= count 1) "" "es")
1069                      regexp))
1070           (setq occur-revert-arguments (list regexp nlines bufs))
1071           (if (= count 0)
1072               (kill-buffer occur-buf)
1073             (display-buffer occur-buf)
1074             (setq next-error-last-buffer occur-buf)
1075             (setq buffer-read-only t)
1076             (set-buffer-modified-p nil)
1077             (run-hooks 'occur-hook)))))))
1078
1079 (defun occur-engine-add-prefix (lines)
1080   (mapcar
1081    #'(lambda (line)
1082        (concat "       :" line "\n"))
1083    lines))
1084
1085 (defun occur-engine (regexp buffers out-buf nlines case-fold-search
1086                             title-face prefix-face match-face keep-props)
1087   (with-current-buffer out-buf
1088     (let ((globalcount 0)
1089           ;; Don't generate undo entries for creation of the initial contents.
1090           (buffer-undo-list t)
1091           (coding nil))
1092       ;; Map over all the buffers
1093       (dolist (buf buffers)
1094         (when (buffer-live-p buf)
1095           (let ((matches 0)     ;; count of matched lines
1096                 (lines 1)       ;; line count
1097                 (matchbeg 0)
1098                 (origpt nil)
1099                 (begpt nil)
1100                 (endpt nil)
1101                 (marker nil)
1102                 (curstring "")
1103                 (inhibit-field-text-motion t)
1104                 (headerpt (with-current-buffer out-buf (point))))
1105             (with-current-buffer buf
1106               (or coding
1107                   ;; Set CODING only if the current buffer locally
1108                   ;; binds buffer-file-coding-system.
1109                   (not (local-variable-p 'buffer-file-coding-system))
1110                   (setq coding buffer-file-coding-system))
1111               (save-excursion
1112                 (goto-char (point-min)) ;; begin searching in the buffer
1113                 (while (not (eobp))
1114                   (setq origpt (point))
1115                   (when (setq endpt (re-search-forward regexp nil t))
1116                     (setq matches (1+ matches)) ;; increment match count
1117                     (setq matchbeg (match-beginning 0))
1118                     (setq lines (+ lines (1- (count-lines origpt endpt))))
1119                     (save-excursion
1120                       (goto-char matchbeg)
1121                       (setq begpt (line-beginning-position)
1122                             endpt (line-end-position)))
1123                     (setq marker (make-marker))
1124                     (set-marker marker matchbeg)
1125                     (if (and keep-props
1126                              (if (boundp 'jit-lock-mode) jit-lock-mode)
1127                              (text-property-not-all begpt endpt 'fontified t))
1128                         (if (fboundp 'jit-lock-fontify-now)
1129                             (jit-lock-fontify-now begpt endpt)))
1130                     (if (and keep-props (not (eq occur-excluded-properties t)))
1131                         (progn
1132                           (setq curstring (buffer-substring begpt endpt))
1133                           (remove-list-of-text-properties
1134                            0 (length curstring) occur-excluded-properties curstring))
1135                       (setq curstring (buffer-substring-no-properties begpt endpt)))
1136                     ;; Highlight the matches
1137                     (let ((len (length curstring))
1138                           (start 0))
1139                       (while (and (< start len)
1140                                   (string-match regexp curstring start))
1141                         (add-text-properties
1142                          (match-beginning 0) (match-end 0)
1143                          (append
1144                           `(occur-match t)
1145                           (when match-face
1146                             ;; Use `face' rather than `font-lock-face' here
1147                             ;; so as to override faces copied from the buffer.
1148                             `(face ,match-face)))
1149                          curstring)
1150                         (setq start (match-end 0))))
1151                     ;; Generate the string to insert for this match
1152                     (let* ((out-line
1153                             (concat
1154                              ;; Using 7 digits aligns tabs properly.
1155                              (apply #'propertize (format "%7d:" lines)
1156                                     (append
1157                                      (when prefix-face
1158                                        `(font-lock-face prefix-face))
1159                                      `(occur-prefix t mouse-face (highlight)
1160                                        occur-target ,marker follow-link t
1161                                        help-echo "mouse-2: go to this occurrence")))
1162                              ;; We don't put `mouse-face' on the newline,
1163                              ;; because that loses.  And don't put it
1164                              ;; on context lines to reduce flicker.
1165                              (propertize curstring 'mouse-face (list 'highlight)
1166                                          'occur-target marker
1167                                          'follow-link t
1168                                          'help-echo
1169                                          "mouse-2: go to this occurrence")
1170                              ;; Add marker at eol, but no mouse props.
1171                              (propertize "\n" 'occur-target marker)))
1172                            (data
1173                             (if (= nlines 0)
1174                                 ;; The simple display style
1175                                 out-line
1176                               ;; The complex multi-line display
1177                               ;; style.  Generate a list of lines,
1178                               ;; concatenate them all together.
1179                               (apply #'concat
1180                                      (nconc
1181                                       (occur-engine-add-prefix (nreverse (cdr (occur-accumulate-lines (- (1+ (abs nlines))) keep-props))))
1182                                       (list out-line)
1183                                       (if (> nlines 0)
1184                                           (occur-engine-add-prefix
1185                                            (cdr (occur-accumulate-lines (1+ nlines) keep-props)))))))))
1186                       ;; Actually insert the match display data
1187                       (with-current-buffer out-buf
1188                         (let ((beg (point))
1189                               (end (progn (insert data) (point))))
1190                           (unless (= nlines 0)
1191                             (insert "-------\n")))))
1192                     (goto-char endpt))
1193                   (if endpt
1194                       (progn
1195                         (setq lines (1+ lines))
1196                         ;; On to the next match...
1197                         (forward-line 1))
1198                     (goto-char (point-max))))))
1199             (when (not (zerop matches)) ;; is the count zero?
1200               (setq globalcount (+ globalcount matches))
1201               (with-current-buffer out-buf
1202                 (goto-char headerpt)
1203                 (let ((beg (point))
1204                       end)
1205                   (insert (format "%d match%s for \"%s\" in buffer: %s\n"
1206                                   matches (if (= matches 1) "" "es")
1207                                   regexp (buffer-name buf)))
1208                   (setq end (point))
1209                   (add-text-properties beg end
1210                                        (append
1211                                         (when title-face
1212                                           `(font-lock-face ,title-face))
1213                                         `(occur-title ,buf))))
1214                 (goto-char (point-min)))))))
1215       (if coding
1216           ;; CODING is buffer-file-coding-system of the first buffer
1217           ;; that locally binds it.  Let's use it also for the output
1218           ;; buffer.
1219           (set-buffer-file-coding-system coding))
1220       ;; Return the number of matches
1221       globalcount)))
1222
1223 \f
1224 ;; It would be nice to use \\[...], but there is no reasonable way
1225 ;; to make that display both SPC and Y.
1226 (defconst query-replace-help
1227   "Type Space or `y' to replace one match, Delete or `n' to skip to next,
1228 RET or `q' to exit, Period to replace one match and exit,
1229 Comma to replace but not move point immediately,
1230 C-r to enter recursive edit (\\[exit-recursive-edit] to get out again),
1231 C-w to delete match and recursive edit,
1232 C-l to clear the screen, redisplay, and offer same replacement again,
1233 ! to replace all remaining matches with no more questions,
1234 ^ to move point back to previous match,
1235 E to edit the replacement string"
1236   "Help message while in `query-replace'.")
1237
1238 (defvar query-replace-map
1239   (let ((map (make-sparse-keymap)))
1240     (define-key map " " 'act)
1241     (define-key map "\d" 'skip)
1242     (define-key map [delete] 'skip)
1243     (define-key map [backspace] 'skip)
1244     (define-key map "y" 'act)
1245     (define-key map "n" 'skip)
1246     (define-key map "Y" 'act)
1247     (define-key map "N" 'skip)
1248     (define-key map "e" 'edit-replacement)
1249     (define-key map "E" 'edit-replacement)
1250     (define-key map "," 'act-and-show)
1251     (define-key map "q" 'exit)
1252     (define-key map "\r" 'exit)
1253     (define-key map [return] 'exit)
1254     (define-key map "." 'act-and-exit)
1255     (define-key map "\C-r" 'edit)
1256     (define-key map "\C-w" 'delete-and-edit)
1257     (define-key map "\C-l" 'recenter)
1258     (define-key map "!" 'automatic)
1259     (define-key map "^" 'backup)
1260     (define-key map "\C-h" 'help)
1261     (define-key map [f1] 'help)
1262     (define-key map [help] 'help)
1263     (define-key map "?" 'help)
1264     (define-key map "\C-g" 'quit)
1265     (define-key map "\C-]" 'quit)
1266     (define-key map "\e" 'exit-prefix)
1267     (define-key map [escape] 'exit-prefix)
1268     map)
1269   "Keymap that defines the responses to questions in `query-replace'.
1270 The \"bindings\" in this map are not commands; they are answers.
1271 The valid answers include `act', `skip', `act-and-show',
1272 `exit', `act-and-exit', `edit', `delete-and-edit', `recenter',
1273 `automatic', `backup', `exit-prefix', and `help'.")
1274
1275 (defun replace-match-string-symbols (n)
1276   "Process a list (and any sub-lists), expanding certain symbols.
1277 Symbol  Expands To
1278 N     (match-string N)           (where N is a string of digits)
1279 #N    (string-to-number (match-string N))
1280 &     (match-string 0)
1281 #&    (string-to-number (match-string 0))
1282 #     replace-count
1283
1284 Note that these symbols must be preceeded by a backslash in order to
1285 type them using Lisp syntax."
1286   (while (consp n)
1287     (cond
1288      ((consp (car n))
1289       (replace-match-string-symbols (car n))) ;Process sub-list
1290      ((symbolp (car n))
1291       (let ((name (symbol-name (car n))))
1292         (cond
1293          ((string-match "^[0-9]+$" name)
1294           (setcar n (list 'match-string (string-to-number name))))
1295          ((string-match "^#[0-9]+$" name)
1296           (setcar n (list 'string-to-number
1297                           (list 'match-string
1298                                 (string-to-number (substring name 1))))))
1299          ((string= "&" name)
1300           (setcar n '(match-string 0)))
1301          ((string= "#&" name)
1302           (setcar n '(string-to-number (match-string 0))))
1303          ((string= "#" name)
1304           (setcar n 'replace-count))))))
1305     (setq n (cdr n))))
1306
1307 (defun replace-eval-replacement (expression replace-count)
1308   (let ((replacement (eval expression)))
1309     (if (stringp replacement)
1310         replacement
1311       (prin1-to-string replacement t))))
1312
1313 (defun replace-quote (replacement)
1314   "Quote a replacement string.
1315 This just doubles all backslashes in REPLACEMENT and
1316 returns the resulting string.  If REPLACEMENT is not
1317 a string, it is first passed through `prin1-to-string'
1318 with the `noescape' argument set.
1319
1320 `match-data' is preserved across the call."
1321   (save-match-data
1322     (replace-regexp-in-string "\\\\" "\\\\"
1323                               (if (stringp replacement)
1324                                   replacement
1325                                 (prin1-to-string replacement t))
1326                               t t)))
1327
1328 (defun replace-loop-through-replacements (data replace-count)
1329   ;; DATA is a vector contaning the following values:
1330   ;;   0 next-rotate-count
1331   ;;   1 repeat-count
1332   ;;   2 next-replacement
1333   ;;   3 replacements
1334   (if (= (aref data 0) replace-count)
1335       (progn
1336         (aset data 0 (+ replace-count (aref data 1)))
1337         (let ((next (cdr (aref data 2))))
1338           (aset data 2 (if (consp next) next (aref data 3))))))
1339   (car (aref data 2)))
1340
1341 (defun replace-match-data (integers reuse &optional new)
1342   "Like `match-data', but markers in REUSE get invalidated.
1343 If NEW is non-nil, it is set and returned instead of fresh data,
1344 but coerced to the correct value of INTEGERS."
1345   (or (and new
1346            (progn
1347              (set-match-data new)
1348              (and (eq new reuse)
1349                   (eq (null integers) (markerp (car reuse)))
1350                   new)))
1351       (match-data integers reuse t)))
1352
1353 (defun replace-match-maybe-edit (newtext fixedcase literal noedit match-data)
1354   "Make a replacement with `replace-match', editing `\\?'.
1355 NEWTEXT, FIXEDCASE, LITERAL are just passed on.  If NOEDIT is true, no
1356 check for `\\?' is made to save time.  MATCH-DATA is used for the
1357 replacement.  In case editing is done, it is changed to use markers.
1358
1359 The return value is non-nil if there has been no `\\?' or NOEDIT was
1360 passed in.  If LITERAL is set, no checking is done, anyway."
1361   (unless (or literal noedit)
1362     (setq noedit t)
1363     (while (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\(\\\\\\?\\)"
1364                          newtext)
1365       (setq newtext
1366             (read-string "Edit replacement string: "
1367                          (prog1
1368                              (cons
1369                               (replace-match "" t t newtext 3)
1370                               (1+ (match-beginning 3)))
1371                            (setq match-data
1372                                  (replace-match-data
1373                                   nil match-data match-data))))
1374             noedit nil)))
1375   (set-match-data match-data)
1376   (replace-match newtext fixedcase literal)
1377   noedit)
1378
1379 (defun perform-replace (from-string replacements
1380                         query-flag regexp-flag delimited-flag
1381                         &optional repeat-count map start end)
1382   "Subroutine of `query-replace'.  Its complexity handles interactive queries.
1383 Don't use this in your own program unless you want to query and set the mark
1384 just as `query-replace' does.  Instead, write a simple loop like this:
1385
1386   (while (re-search-forward \"foo[ \\t]+bar\" nil t)
1387     (replace-match \"foobar\" nil nil))
1388
1389 which will run faster and probably do exactly what you want.  Please
1390 see the documentation of `replace-match' to find out how to simulate
1391 `case-replace'.
1392
1393 This function returns nil if and only if there were no matches to
1394 make, or the user didn't cancel the call."
1395   (or map (setq map query-replace-map))
1396   (and query-flag minibuffer-auto-raise
1397        (raise-frame (window-frame (minibuffer-window))))
1398   (let ((nocasify (not (and case-fold-search case-replace
1399                             (string-equal from-string
1400                                           (downcase from-string)))))
1401         (case-fold-search (and case-fold-search
1402                                (string-equal from-string
1403                                              (downcase from-string))))
1404         (literal (or (not regexp-flag) (eq regexp-flag 'literal)))
1405         (search-function (if regexp-flag 're-search-forward 'search-forward))
1406         (search-string from-string)
1407         (real-match-data nil)           ; the match data for the current match
1408         (next-replacement nil)
1409         (noedit nil)
1410         (keep-going t)
1411         (stack nil)
1412         (replace-count 0)
1413         (nonempty-match nil)
1414
1415         ;; If non-nil, it is marker saying where in the buffer to stop.
1416         (limit nil)
1417
1418         ;; Data for the next match.  If a cons, it has the same format as
1419         ;; (match-data); otherwise it is t if a match is possible at point.
1420         (match-again t)
1421
1422         (message
1423          (if query-flag
1424              (substitute-command-keys
1425               "Query replacing %s with %s: (\\<query-replace-map>\\[help] for help) "))))
1426
1427     ;; If region is active, in Transient Mark mode, operate on region.
1428     (when start
1429       (setq limit (copy-marker (max start end)))
1430       (goto-char (min start end))
1431       (deactivate-mark))
1432
1433     ;; REPLACEMENTS is either a string, a list of strings, or a cons cell
1434     ;; containing a function and its first argument.  The function is
1435     ;; called to generate each replacement like this:
1436     ;;   (funcall (car replacements) (cdr replacements) replace-count)
1437     ;; It must return a string.
1438     (cond
1439      ((stringp replacements)
1440       (setq next-replacement replacements
1441             replacements     nil))
1442      ((stringp (car replacements)) ; If it isn't a string, it must be a cons
1443       (or repeat-count (setq repeat-count 1))
1444       (setq replacements (cons 'replace-loop-through-replacements
1445                                (vector repeat-count repeat-count
1446                                        replacements replacements)))))
1447
1448     (if delimited-flag
1449         (setq search-function 're-search-forward
1450               search-string (concat "\\b"
1451                                     (if regexp-flag from-string
1452                                       (regexp-quote from-string))
1453                                     "\\b")))
1454     (when query-replace-lazy-highlight
1455       (setq isearch-lazy-highlight-last-string nil))
1456
1457     (push-mark)
1458     (undo-boundary)
1459     (unwind-protect
1460         ;; Loop finding occurrences that perhaps should be replaced.
1461         (while (and keep-going
1462                     (not (or (eobp) (and limit (>= (point) limit))))
1463                     ;; Use the next match if it is already known;
1464                     ;; otherwise, search for a match after moving forward
1465                     ;; one char if progress is required.
1466                     (setq real-match-data
1467                           (if (consp match-again)
1468                               (progn (goto-char (nth 1 match-again))
1469                                      (replace-match-data t
1470                                       real-match-data
1471                                       match-again))
1472                             (and (or match-again
1473                                      ;; MATCH-AGAIN non-nil means we
1474                                      ;; accept an adjacent match.  If
1475                                      ;; we don't, move one char to the
1476                                      ;; right.  This takes us a
1477                                      ;; character too far at the end,
1478                                      ;; but this is undone after the
1479                                      ;; while-loop.
1480                                      (progn
1481                                        (forward-char 1)
1482                                        (not (or (eobp)
1483                                                 (and limit (>= (point) limit))))))
1484                                  (funcall search-function search-string limit t)
1485                                  ;; For speed, use only integers and
1486                                  ;; reuse the list used last time.
1487                                  (replace-match-data t real-match-data)))))
1488
1489           ;; Record whether the match is nonempty, to avoid an infinite loop
1490           ;; repeatedly matching the same empty string.
1491           (setq nonempty-match
1492                 (/= (nth 0 real-match-data) (nth 1 real-match-data)))
1493
1494           ;; If the match is empty, record that the next one can't be
1495           ;; adjacent.
1496
1497           ;; Otherwise, if matching a regular expression, do the next
1498           ;; match now, since the replacement for this match may
1499           ;; affect whether the next match is adjacent to this one.
1500           ;; If that match is empty, don't use it.
1501           (setq match-again
1502                 (and nonempty-match
1503                      (or (not regexp-flag)
1504                          (and (looking-at search-string)
1505                               (let ((match (match-data)))
1506                                 (and (/= (nth 0 match) (nth 1 match))
1507                                      match))))))
1508
1509           ;; Optionally ignore matches that have a read-only property.
1510           (unless (and query-replace-skip-read-only
1511                        (text-property-not-all
1512                         (nth 0 real-match-data) (nth 1 real-match-data)
1513                         'read-only nil))
1514
1515             ;; Calculate the replacement string, if necessary.
1516             (when replacements
1517               (set-match-data real-match-data)
1518               (setq next-replacement
1519                     (funcall (car replacements) (cdr replacements)
1520                              replace-count)
1521                     noedit nil))
1522             (if (not query-flag)
1523                 (let ((inhibit-read-only
1524                        query-replace-skip-read-only))
1525                   (unless (or literal noedit)
1526                     (replace-highlight
1527                      (nth 0 real-match-data) (nth 1 real-match-data)
1528                      start end search-string
1529                      (or delimited-flag regexp-flag) case-fold-search))
1530                   (setq noedit
1531                         (replace-match-maybe-edit
1532                          next-replacement nocasify literal
1533                          noedit real-match-data)
1534                         replace-count (1+ replace-count)))
1535               (undo-boundary)
1536               (let (done replaced key def)
1537                 ;; Loop reading commands until one of them sets done,
1538                 ;; which means it has finished handling this
1539                 ;; occurrence.  Any command that sets `done' should
1540                 ;; leave behind proper match data for the stack.
1541                 ;; Commands not setting `done' need to adjust
1542                 ;; `real-match-data'.
1543                 (while (not done)
1544                   (set-match-data real-match-data)
1545                   (replace-highlight
1546                    (match-beginning 0) (match-end 0)
1547                    start end search-string
1548                    (or delimited-flag regexp-flag) case-fold-search)
1549                   ;; Bind message-log-max so we don't fill up the message log
1550                   ;; with a bunch of identical messages.
1551                   (let ((message-log-max nil))
1552                     (message message
1553                              (query-replace-descr from-string)
1554                              (query-replace-descr next-replacement)))
1555                   (setq key (read-event))
1556                   ;; Necessary in case something happens during read-event
1557                   ;; that clobbers the match data.
1558                   (set-match-data real-match-data)
1559                   (setq key (vector key))
1560                   (setq def (lookup-key map key))
1561                   ;; Restore the match data while we process the command.
1562                   (cond ((eq def 'help)
1563                          (with-output-to-temp-buffer "*Help*"
1564                            (princ
1565                             (concat "Query replacing "
1566                                     (if regexp-flag "regexp " "")
1567                                     from-string " with "
1568                                     next-replacement ".\n\n"
1569                                     (substitute-command-keys
1570                                      query-replace-help)))
1571                            (with-current-buffer standard-output
1572                              (help-mode))))
1573                         ((eq def 'exit)
1574                          (setq keep-going nil)
1575                          (setq done t))
1576                         ((eq def 'backup)
1577                          (if stack
1578                              (let ((elt (pop stack)))
1579                                (goto-char (nth 0 elt))
1580                                (setq replaced (nth 1 elt)
1581                                      real-match-data
1582                                      (replace-match-data
1583                                       t real-match-data
1584                                       (nth 2 elt))))
1585                            (message "No previous match")
1586                            (ding 'no-terminate)
1587                            (sit-for 1)))
1588                         ((eq def 'act)
1589                          (or replaced
1590                              (setq noedit
1591                                    (replace-match-maybe-edit
1592                                     next-replacement nocasify literal
1593                                     noedit real-match-data)
1594                                    replace-count (1+ replace-count)))
1595                          (setq done t replaced t))
1596                         ((eq def 'act-and-exit)
1597                          (or replaced
1598                              (setq noedit
1599                                    (replace-match-maybe-edit
1600                                     next-replacement nocasify literal
1601                                     noedit real-match-data)
1602                                    replace-count (1+ replace-count)))
1603                          (setq keep-going nil)
1604                          (setq done t replaced t))
1605                         ((eq def 'act-and-show)
1606                          (if (not replaced)
1607                              (setq noedit
1608                                    (replace-match-maybe-edit
1609                                     next-replacement nocasify literal
1610                                     noedit real-match-data)
1611                                    replace-count (1+ replace-count)
1612                                    real-match-data (replace-match-data
1613                                                     t real-match-data)
1614                                    replaced t)))
1615                         ((eq def 'automatic)
1616                          (or replaced
1617                              (setq noedit
1618                                    (replace-match-maybe-edit
1619                                     next-replacement nocasify literal
1620                                     noedit real-match-data)
1621                                    replace-count (1+ replace-count)))
1622                          (setq done t query-flag nil replaced t))
1623                         ((eq def 'skip)
1624                          (setq done t))
1625                         ((eq def 'recenter)
1626                          (recenter nil))
1627                         ((eq def 'edit)
1628                          (let ((opos (point-marker)))
1629                            (setq real-match-data (replace-match-data
1630                                                   nil real-match-data
1631                                                   real-match-data))
1632                            (goto-char (match-beginning 0))
1633                            (save-excursion
1634                              (save-window-excursion
1635                                (recursive-edit)))
1636                            (goto-char opos)
1637                            (set-marker opos nil))
1638                          ;; Before we make the replacement,
1639                          ;; decide whether the search string
1640                          ;; can match again just after this match.
1641                          (if (and regexp-flag nonempty-match)
1642                              (setq match-again (and (looking-at search-string)
1643                                                     (match-data)))))
1644                         ;; Edit replacement.
1645                         ((eq def 'edit-replacement)
1646                          (setq real-match-data (replace-match-data
1647                                                 nil real-match-data
1648                                                 real-match-data)
1649                                next-replacement
1650                                (read-string "Edit replacement string: "
1651                                             next-replacement)
1652                                noedit nil)
1653                          (if replaced
1654                              (set-match-data real-match-data)
1655                            (setq noedit
1656                                  (replace-match-maybe-edit
1657                                   next-replacement nocasify literal noedit
1658                                   real-match-data)
1659                                  replaced t))
1660                          (setq done t))
1661
1662                         ((eq def 'delete-and-edit)
1663                          (replace-match "" t t)
1664                          (setq real-match-data (replace-match-data
1665                                                 nil real-match-data))
1666                          (replace-dehighlight)
1667                          (save-excursion (recursive-edit))
1668                          (setq replaced t))
1669                         ;; Note: we do not need to treat `exit-prefix'
1670                         ;; specially here, since we reread
1671                         ;; any unrecognized character.
1672                         (t
1673                          (setq this-command 'mode-exited)
1674                          (setq keep-going nil)
1675                          (setq unread-command-events
1676                                (append (listify-key-sequence key)
1677                                        unread-command-events))
1678                          (setq done t)))
1679                   (when query-replace-lazy-highlight
1680                     ;; Force lazy rehighlighting only after replacements
1681                     (if (not (memq def '(skip backup)))
1682                         (setq isearch-lazy-highlight-last-string nil))))
1683                 ;; Record previous position for ^ when we move on.
1684                 ;; Change markers to numbers in the match data
1685                 ;; since lots of markers slow down editing.
1686                 (push (list (point) replaced
1687 ;;;  If the replacement has already happened, all we need is the
1688 ;;;  current match start and end.  We could get this with a trivial
1689 ;;;  match like
1690 ;;;  (save-excursion (goto-char (match-beginning 0))
1691 ;;;                  (search-forward (match-string 0))
1692 ;;;                  (match-data t))
1693 ;;;  if we really wanted to avoid manually constructing match data.
1694 ;;;  Adding current-buffer is necessary so that match-data calls can
1695 ;;;  return markers which are appropriate for editing.
1696                             (if replaced
1697                                 (list
1698                                  (match-beginning 0)
1699                                  (match-end 0)
1700                                  (current-buffer))
1701                               (match-data t)))
1702                       stack)))))
1703
1704       ;; The code preventing adjacent regexp matches in the condition
1705       ;; of the while-loop above will haven taken us one character
1706       ;; beyond the last replacement.  Undo that.
1707       (when (and regexp-flag (not match-again) (> replace-count 0))
1708         (backward-char 1))
1709
1710       (replace-dehighlight))
1711     (or unread-command-events
1712         (message "Replaced %d occurrence%s"
1713                  replace-count
1714                  (if (= replace-count 1) "" "s")))
1715     (and keep-going stack)))
1716
1717 (defvar replace-overlay nil)
1718
1719 (defun replace-highlight (match-beg match-end range-beg range-end
1720                           string regexp case-fold)
1721   (if query-replace-highlight
1722       (if replace-overlay
1723           (move-overlay replace-overlay match-beg match-end (current-buffer))
1724         (setq replace-overlay (make-overlay match-beg match-end))
1725         (overlay-put replace-overlay 'priority 1001) ;higher than lazy overlays
1726         (overlay-put replace-overlay 'face 'query-replace)))
1727   (if query-replace-lazy-highlight
1728       (let ((isearch-string string)
1729             (isearch-regexp regexp)
1730             (isearch-case-fold-search case-fold))
1731         (isearch-lazy-highlight-new-loop range-beg range-end))))
1732
1733 (defun replace-dehighlight ()
1734   (when replace-overlay
1735     (delete-overlay replace-overlay))
1736   (when query-replace-lazy-highlight
1737     (lazy-highlight-cleanup lazy-highlight-cleanup)
1738     (setq isearch-lazy-highlight-last-string nil)))
1739
1740 ;; arch-tag: 16b4cd61-fd40-497b-b86f-b667c4cf88e4
1741 ;;; replace.el ends here