lisp/scroll-bar.el

   1 ;;; scroll-bar.el --- window system-independent scroll bar support.
   2
   3 ;; Copyright (C) 1993, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: hardware
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Window-system-independent bindings of mouse clicks on the scroll bar.
  28 ;; Presently emulates the scroll-bar behavior of xterm.
  29
  30 ;;; Code:
  31
  32 (require 'mouse)
  33
  34 \f
  35 ;;;; Utilities.
  36
  37 (defun scroll-bar-event-ratio (event)
  38   "Given a scroll bar event EVENT, return the scroll bar position as a ratio.
  39 The value is a cons cell (PORTION . WHOLE) containing two integers
  40 whose ratio gives the event's vertical position in the scroll bar, with 0
  41 referring to the top and 1 to the bottom."
  42   (nth 2 event))
  43
  44 (defun scroll-bar-scale (num-denom whole)
  45   "Given a pair (NUM . DENOM) and WHOLE, return (/ (* NUM WHOLE) DENOM).
  46 This is handy for scaling a position on a scroll bar into real units,
  47 like buffer positions.  If SCROLL-BAR-POS is the (PORTION . WHOLE) pair
  48 from a scroll bar event, then (scroll-bar-scale SCROLL-BAR-POS
  49 \(buffer-size)) is the position in the current buffer corresponding to
  50 that scroll bar position."
  51   ;; We multiply before we divide to maintain precision.
  52   ;; We use floating point because the product of a large buffer size
  53   ;; with a large scroll bar portion can easily overflow a lisp int.
  54   (truncate (/ (* (float (car num-denom)) whole) (cdr num-denom))))
  55
  56 \f
  57 ;;;; Helpful functions for enabling and disabling scroll bars.
  58
  59 (defvar scroll-bar-mode)
  60
  61 (defvar scroll-bar-mode-explicit nil
  62   "Non-nil means `set-scroll-bar-mode' should really do something.
  63 This is nil while loading `scroll-bar.el', and t afterward.")
  64
  65 (defun set-scroll-bar-mode-1 (ignore value)
  66   (set-scroll-bar-mode value))
  67
  68 (defun set-scroll-bar-mode (value)
  69   "Set `scroll-bar-mode' to VALUE and put the new value into effect."
  70   (setq scroll-bar-mode value)
  71
  72   (when scroll-bar-mode-explicit
  73     ;; Apply it to default-frame-alist.
  74     (let ((parameter (assq 'vertical-scroll-bars default-frame-alist)))
  75       (if (consp parameter)
  76           (setcdr parameter scroll-bar-mode)
  77         (setq default-frame-alist
  78               (cons (cons 'vertical-scroll-bars scroll-bar-mode)
  79                     default-frame-alist))))
  80
  81     ;; Apply it to existing frames.
  82     (let ((frames (frame-list)))
  83       (while frames
  84         (modify-frame-parameters
  85          (car frames)
  86          (list (cons 'vertical-scroll-bars scroll-bar-mode)))
  87         (setq frames (cdr frames))))))
  88
  89 (defcustom scroll-bar-mode
  90   (if (eq system-type 'windows-nt) 'right 'left)
  91   "*Specify whether to have vertical scroll bars, and on which side.
  92 Possible values are nil (no scroll bars), `left' (scroll bars on left)
  93 and `right' (scroll bars on right).
  94 When you set the variable in a Lisp program, it takes effect for new frames,
  95 and for existing frames when `toggle-scroll-bar' is used.
  96 When you set this with the customization buffer,
  97 it takes effect immediately for all frames."
  98   :type '(choice (const :tag "none (nil)")
  99                  (const left)
 100                  (const right))
 101   :group 'frames
 102   :set 'set-scroll-bar-mode-1)
 103
 104 ;; We just set scroll-bar-mode, but that was the default.
 105 ;; If it is set again, that is for real.
 106 (setq scroll-bar-mode-explicit t)
 107
 108 (defun scroll-bar-mode (flag)
 109   "Toggle display of vertical scroll bars on all frames.
 110 This command applies to all frames that exist and frames to be
 111 created in the future.
 112 With a numeric argument, if the argument is negative,
 113 turn off scroll bars; otherwise, turn on scroll bars."
 114   (interactive "P")
 115   (if flag (setq flag (prefix-numeric-value flag)))
 116
 117   ;; Tweedle the variable according to the argument.
 118   (set-scroll-bar-mode (if (null flag) (not scroll-bar-mode)
 119                          (and (or (not (numberp flag)) (>= flag 0))
 120                               (if (eq system-type 'windows-nt) 'right 'left)))))
 121
 122 (defun toggle-scroll-bar (arg)
 123   "Toggle whether or not the selected frame has vertical scroll bars.
 124 With arg, turn vertical scroll bars on if and only if arg is positive.
 125 The variable `scroll-bar-mode' controls which side the scroll bars are on
 126 when they are turned on; if it is nil, they go on the left."
 127   (interactive "P")
 128   (if (null arg)
 129       (setq arg
 130             (if (cdr (assq 'vertical-scroll-bars
 131                            (frame-parameters (selected-frame))))
 132                 -1 1))
 133     (setq arg (prefix-numeric-value arg)))
 134   (modify-frame-parameters
 135    (selected-frame)
 136    (list (cons 'vertical-scroll-bars
 137                (if (> arg 0)
 138                    (or scroll-bar-mode
 139                        (if (eq system-type 'windows-nt) 'right 'left)))))))
 140
 141 (defun toggle-horizontal-scroll-bar (arg)
 142   "Toggle whether or not the selected frame has horizontal scroll bars.
 143 With arg, turn horizontal scroll bars on if and only if arg is positive.
 144 Horizontal scroll bars aren't implemented yet."
 145   (interactive "P")
 146   (error "Horizontal scroll bars aren't implemented yet"))
 147 \f
 148 ;;;; Buffer navigation using the scroll bar.
 149
 150 ;;; This was used for up-events on button 2, but no longer.
 151 (defun scroll-bar-set-window-start (event)
 152   "Set the window start according to where the scroll bar is dragged.
 153 EVENT should be a scroll bar click or drag event."
 154   (interactive "e")
 155   (let* ((end-position (event-end event))
 156          (window (nth 0 end-position))
 157          (portion-whole (nth 2 end-position)))
 158     (save-excursion
 159       (set-buffer (window-buffer window))
 160       (save-excursion
 161         (goto-char (+ (point-min)
 162                       (scroll-bar-scale portion-whole
 163                                         (- (point-max) (point-min)))))
 164         (beginning-of-line)
 165         (set-window-start window (point))))))
 166
 167 (defun scroll-bar-drag-position (portion-whole)
 168   "Calculate new window start for drag event."
 169   (save-excursion
 170     (goto-char (+ (point-min)
 171                   (scroll-bar-scale portion-whole
 172                                     (- (point-max) (point-min)))))
 173     (beginning-of-line)
 174     (point)))
 175
 176 (defun scroll-bar-maybe-set-window-start (event)
 177   "Set the window start according to where the scroll bar is dragged.
 178 Only change window start if the new start is substantially different.
 179 EVENT should be a scroll bar click or drag event."
 180   (interactive "e")
 181   (let* ((end-position (event-end event))
 182          (window (nth 0 end-position))
 183          (portion-whole (nth 2 end-position))
 184          (next-portion-whole (cons (1+ (car portion-whole))
 185                                    (cdr portion-whole)))
 186          portion-start
 187          next-portion-start
 188          (current-start (window-start window)))
 189     (save-excursion
 190       (set-buffer (window-buffer window))
 191       (setq portion-start (scroll-bar-drag-position portion-whole))
 192       (setq next-portion-start (max
 193                                 (scroll-bar-drag-position next-portion-whole)
 194                                 (1+ portion-start)))
 195       (if (or (>= current-start next-portion-start)
 196               (< current-start portion-start))
 197           (set-window-start window portion-start)
 198         ;; Always set window start, to ensure scroll bar position is updated.
 199         (set-window-start window current-start)))))
 200
 201 ;; Scroll the window to the proper position for EVENT.
 202 (defun scroll-bar-drag-1 (event)
 203   (let* ((start-position (event-start event))
 204          (window (nth 0 start-position))
 205          (portion-whole (nth 2 start-position)))
 206     (save-excursion
 207       (set-buffer (window-buffer window))
 208       ;; Calculate position relative to the accessible part of the buffer.
 209       (goto-char (+ (point-min)
 210                     (scroll-bar-scale portion-whole
 211                                       (- (point-max) (point-min)))))
 212       (beginning-of-line)
 213       (set-window-start window (point)))))
 214
 215 (defun scroll-bar-drag (event)
 216   "Scroll the window by dragging the scroll bar slider.
 217 If you click outside the slider, the window scrolls to bring the slider there."
 218   (interactive "e")
 219   (let* (done
 220          (echo-keystrokes 0)
 221          (end-position (event-end event))
 222          (window (nth 0 end-position))
 223          (before-scroll))
 224     (with-current-buffer (window-buffer window)
 225       (setq before-scroll point-before-scroll))
 226     (save-selected-window
 227       (select-window window)
 228       (setq before-scroll
 229             (or before-scroll (point))))
 230     (scroll-bar-drag-1 event)
 231     (track-mouse
 232       (while (not done)
 233         (setq event (read-event))
 234         (if (eq (car-safe event) 'mouse-movement)
 235             (setq event (read-event)))
 236         (cond ((eq (car-safe event) 'scroll-bar-movement)
 237                (scroll-bar-drag-1 event))
 238               (t
 239                ;; Exit when we get the drag event; ignore that event.
 240                (setq done t)))))
 241     (sit-for 0)
 242     (with-current-buffer (window-buffer window)
 243       (setq point-before-scroll before-scroll))))
 244
 245 (defun scroll-bar-scroll-down (event)
 246   "Scroll the window's top line down to the location of the scroll bar click.
 247 EVENT should be a scroll bar click."
 248   (interactive "e")
 249   (let* ((end-position (event-end event))
 250          (window (nth 0 end-position))
 251          (before-scroll))
 252     (with-current-buffer (window-buffer window)
 253       (setq before-scroll point-before-scroll))
 254     (save-selected-window
 255       (let ((portion-whole (nth 2 end-position)))
 256         (select-window window)
 257         (setq before-scroll
 258               (or before-scroll (point)))
 259         (scroll-down
 260          (scroll-bar-scale portion-whole (1- (window-height))))))
 261     (sit-for 0)
 262     (with-current-buffer (window-buffer window)
 263       (setq point-before-scroll before-scroll))))
 264
 265 (defun scroll-bar-scroll-up (event)
 266   "Scroll the line next to the scroll bar click to the top of the window.
 267 EVENT should be a scroll bar click."
 268   (interactive "e")
 269   (let* ((end-position (event-end event))
 270          (window (nth 0 end-position))
 271          (before-scroll))
 272     (with-current-buffer (window-buffer window)
 273       (setq before-scroll point-before-scroll))
 274     (save-selected-window
 275       (let ((portion-whole (nth 2 end-position)))
 276         (select-window window)
 277         (setq before-scroll
 278               (or before-scroll (point)))
 279         (scroll-up
 280          (scroll-bar-scale portion-whole (1- (window-height))))))
 281     (sit-for 0)
 282     (with-current-buffer (window-buffer window)
 283       (setq point-before-scroll before-scroll))))
 284
 285 \f
 286 ;;;; Bindings.
 287
 288 ;;; For now, we'll set things up to work like xterm.
 289 (global-set-key [vertical-scroll-bar mouse-1] 'scroll-bar-scroll-up)
 290 (global-set-key [vertical-scroll-bar drag-mouse-1] 'scroll-bar-scroll-up)
 291
 292 (global-set-key [vertical-scroll-bar down-mouse-2] 'scroll-bar-drag)
 293
 294 (global-set-key [vertical-scroll-bar mouse-3] 'scroll-bar-scroll-down)
 295 (global-set-key [vertical-scroll-bar drag-mouse-3] 'scroll-bar-scroll-down)
 296
 297 \f
 298 (provide 'scroll-bar)
 299
 300 ;;; scroll-bar.el ends here