lisp/server.el

   1 ;;; server.el --- Lisp code for GNU Emacs running as server process
   2
   3 ;; Copyright (C) 1986, 1987, 1992, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   4 ;;   2001, 2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: William Sommerfeld <wesommer@athena.mit.edu>
   7 ;; Maintainer: FSF
   8 ;; Keywords: processes
   9
  10 ;; Changes by peck@sun.com and by rms.
  11 ;; Overhaul by Karoly Lorentey <lorentey@elte.hu> for multi-tty support.
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 3, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  28 ;; Boston, MA 02110-1301, USA.
  29
  30 ;;; Commentary:
  31
  32 ;; This Lisp code is run in Emacs when it is to operate as
  33 ;; a server for other processes.
  34
  35 ;; Load this library and do M-x server-edit to enable Emacs as a server.
  36 ;; Emacs opens up a socket for communication with clients.  If there are no
  37 ;; client buffers to edit, server-edit acts like (switch-to-buffer
  38 ;; (other-buffer))
  39
  40 ;; When some other program runs "the editor" to edit a file,
  41 ;; "the editor" can be the Emacs client program ../lib-src/emacsclient.
  42 ;; This program transmits the file names to Emacs through
  43 ;; the server subprocess, and Emacs visits them and lets you edit them.
  44
  45 ;; Note that any number of clients may dispatch files to Emacs to be edited.
  46
  47 ;; When you finish editing a Server buffer, again call server-edit
  48 ;; to mark that buffer as done for the client and switch to the next
  49 ;; Server buffer.  When all the buffers for a client have been edited
  50 ;; and exited with server-edit, the client "editor" will return
  51 ;; to the program that invoked it.
  52
  53 ;; Your editing commands and Emacs's display output go to and from
  54 ;; the terminal in the usual way.  Thus, server operation is possible
  55 ;; only when Emacs can talk to the terminal at the time you invoke
  56 ;; the client.  This is possible in four cases:
  57
  58 ;; 1. On a window system, where Emacs runs in one window and the
  59 ;; program that wants to use "the editor" runs in another.
  60
  61 ;; 2. On a multi-terminal system, where Emacs runs on one terminal and the
  62 ;; program that wants to use "the editor" runs on another.
  63
  64 ;; 3. When the program that wants to use "the editor" is running
  65 ;; as a subprocess of Emacs.
  66
  67 ;; 4. On a system with job control, when Emacs is suspended, the program
  68 ;; that wants to use "the editor" will stop and display
  69 ;; "Waiting for Emacs...".  It can then be suspended, and Emacs can be
  70 ;; brought into the foreground for editing.  When done editing, Emacs is
  71 ;; suspended again, and the client program is brought into the foreground.
  72
  73 ;; The buffer local variable "server-buffer-clients" lists
  74 ;; the clients who are waiting for this buffer to be edited.
  75 ;; The global variable "server-clients" lists all the waiting clients,
  76 ;; and which files are yet to be edited for each.
  77
  78 ;; Todo:
  79
  80 ;; - handle command-line-args-left.
  81 ;; - move most of the args processing and decision making from emacsclient.c
  82 ;;   to here.
  83 ;; - fix up handling of the client's environment (place it in the terminal?).
  84
  85 ;;; Code:
  86
  87 (eval-when-compile (require 'cl))
  88
  89 (defgroup server nil
  90   "Emacs running as a server process."
  91   :group 'external)
  92
  93 (defcustom server-use-tcp nil
  94   "If non-nil, use TCP sockets instead of local sockets."
  95   :set #'(lambda (sym val)
  96            (unless (featurep 'make-network-process '(:family local))
  97              (setq val t)
  98              (unless load-in-progress
  99                (message "Local sockets unsupported, using TCP sockets")))
 100            (when val (random t))
 101            (set-default sym val))
 102   :group 'server
 103   :type 'boolean
 104   :version "22.1")
 105
 106 (defcustom server-host nil
 107   "The name or IP address to use as host address of the server process.
 108 If set, the server accepts remote connections; otherwise it is local."
 109   :group 'server
 110   :type '(choice
 111           (string :tag "Name or IP address")
 112           (const :tag "Local" nil))
 113   :version "22.1")
 114 (put 'server-host 'risky-local-variable t)
 115
 116 (defcustom server-auth-dir (concat user-emacs-directory "server/")
 117   "Directory for server authentication files."
 118   :group 'server
 119   :type 'directory
 120   :version "22.1")
 121 (put 'server-auth-dir 'risky-local-variable t)
 122
 123 (defcustom server-raise-frame t
 124   "If non-nil, raise frame when switching to a buffer."
 125   :group 'server
 126   :type 'boolean
 127   :version "22.1")
 128
 129 (defcustom server-visit-hook nil
 130   "Hook run when visiting a file for the Emacs server."
 131   :group 'server
 132   :type 'hook)
 133
 134 (defcustom server-switch-hook nil
 135   "Hook run when switching to a buffer for the Emacs server."
 136   :group 'server
 137   :type 'hook)
 138
 139 (defcustom server-done-hook nil
 140   "Hook run when done editing a buffer for the Emacs server."
 141   :group 'server
 142   :type 'hook)
 143
 144 (defvar server-process nil
 145   "The current server process.")
 146
 147 (defvar server-clients nil
 148   "List of current server clients.
 149 Each element is a process.")
 150
 151 (defvar server-buffer-clients nil
 152   "List of client processes requesting editing of current buffer.")
 153 (make-variable-buffer-local 'server-buffer-clients)
 154 ;; Changing major modes should not erase this local.
 155 (put 'server-buffer-clients 'permanent-local t)
 156
 157 (defcustom server-window nil
 158   "Specification of the window to use for selecting Emacs server buffers.
 159 If nil, use the selected window.
 160 If it is a function, it should take one argument (a buffer) and
 161 display and select it.  A common value is `pop-to-buffer'.
 162 If it is a window, use that.
 163 If it is a frame, use the frame's selected window.
 164
 165 It is not meaningful to set this to a specific frame or window with Custom.
 166 Only programs can do so."
 167   :group 'server
 168   :version "22.1"
 169   :type '(choice (const :tag "Use selected window"
 170                         :match (lambda (widget value)
 171                                  (not (functionp value)))
 172                         nil)
 173                  (function-item :tag "Display in new frame" switch-to-buffer-other-frame)
 174                  (function-item :tag "Use pop-to-buffer" pop-to-buffer)
 175                  (function :tag "Other function")))
 176
 177 (defcustom server-temp-file-regexp "^/tmp/Re\\|/draft$"
 178   "Regexp matching names of temporary files.
 179 These are deleted and reused after each edit by the programs that
 180 invoke the Emacs server."
 181   :group 'server
 182   :type 'regexp)
 183
 184 (defcustom server-kill-new-buffers t
 185   "Whether to kill buffers when done with them.
 186 If non-nil, kill a buffer unless it already existed before editing
 187 it with the Emacs server.  If nil, kill only buffers as specified by
 188 `server-temp-file-regexp'.
 189 Please note that only buffers that still have a client are killed,
 190 i.e. buffers visited with \"emacsclient --no-wait\" are never killed in
 191 this way."
 192   :group 'server
 193   :type 'boolean
 194   :version "21.1")
 195
 196 (or (assq 'server-buffer-clients minor-mode-alist)
 197     (push '(server-buffer-clients " Server") minor-mode-alist))
 198
 199 (defvar server-existing-buffer nil
 200   "Non-nil means the buffer existed before the server was asked to visit it.
 201 This means that the server should not kill the buffer when you say you
 202 are done with it in the server.")
 203 (make-variable-buffer-local 'server-existing-buffer)
 204
 205 (defvar server-name "server")
 206
 207 (defvar server-socket-dir nil
 208   "The directory in which to place the server socket.
 209 Initialized by `server-start'.")
 210
 211 (defun server-clients-with (property value)
 212   "Return a list of clients with PROPERTY set to VALUE."
 213   (let (result)
 214     (dolist (proc server-clients result)
 215       (when (equal value (process-get proc property))
 216         (push proc result)))))
 217
 218 (defun server-add-client (proc)
 219   "Create a client for process PROC, if it doesn't already have one.
 220 New clients have no properties."
 221   (add-to-list 'server-clients proc))
 222
 223 (defmacro server-with-environment (env vars &rest body)
 224   "Evaluate BODY with environment variables VARS set to those in ENV.
 225 The environment variables are then restored to their previous values.
 226
 227 VARS should be a list of strings.
 228 ENV should be in the same format as `process-environment'."
 229   (declare (indent 2))
 230   (let ((var (make-symbol "var"))
 231         (value (make-symbol "value")))
 232     `(let ((process-environment process-environment))
 233        (dolist (,var ,vars)
 234          (let ((,value (getenv-internal ,var ,env)))
 235            (push (if (null ,value)
 236                      ,var
 237                    (concat ,var "=" ,value))
 238                  process-environment)))
 239        (progn ,@body))))
 240
 241 (defun server-delete-client (proc &optional noframe)
 242   "Delete PROC, including its buffers, terminals and frames.
 243 If NOFRAME is non-nil, let the frames live.  (To be used from
 244 `delete-frame-functions'.)"
 245   (server-log (concat "server-delete-client" (if noframe " noframe"))
 246               proc)
 247   ;; Force a new lookup of client (prevents infinite recursion).
 248   (when (memq proc server-clients)
 249     (let ((buffers (process-get proc 'buffers)))
 250
 251       ;; Kill the client's buffers.
 252       (dolist (buf buffers)
 253         (when (buffer-live-p buf)
 254           (with-current-buffer buf
 255             ;; Kill the buffer if necessary.
 256             (when (and (equal server-buffer-clients
 257                               (list proc))
 258                        (or (and server-kill-new-buffers
 259                                 (not server-existing-buffer))
 260                            (server-temp-file-p))
 261                        (not (buffer-modified-p)))
 262               (let (flag)
 263                 (unwind-protect
 264                     (progn (setq server-buffer-clients nil)
 265                            (kill-buffer (current-buffer))
 266                            (setq flag t))
 267                   (unless flag
 268                     ;; Restore clients if user pressed C-g in `kill-buffer'.
 269                     (setq server-buffer-clients (list proc)))))))))
 270
 271       ;; Delete the client's frames.
 272       (unless noframe
 273         (dolist (frame (frame-list))
 274           (when (and (frame-live-p frame)
 275                      (equal proc (frame-parameter frame 'client)))
 276             ;; Prevent `server-handle-delete-frame' from calling us
 277             ;; recursively.
 278             (set-frame-parameter frame 'client nil)
 279             (delete-frame frame))))
 280
 281       (setq server-clients (delq proc server-clients))
 282
 283       ;; Delete the client's tty.
 284       (let ((terminal (process-get proc 'terminal)))
 285         ;; Only delete the terminal if it is non-nil.
 286         (when (and terminal (eq (terminal-live-p terminal) t))
 287           (delete-terminal terminal)))
 288
 289       ;; Delete the client's process.
 290       (if (eq (process-status proc) 'open)
 291           (delete-process proc))
 292
 293       (server-log "Deleted" proc))))
 294
 295 (defun server-log (string &optional client)
 296   "If a *server* buffer exists, write STRING to it for logging purposes.
 297 If CLIENT is non-nil, add a description of it to the logged message."
 298   (when (get-buffer "*server*")
 299     (with-current-buffer "*server*"
 300       (goto-char (point-max))
 301       (insert (current-time-string)
 302               (cond
 303                ((null client) " ")
 304                ((listp client) (format " %s: " (car client)))
 305                (t (format " %s: " client)))
 306               string)
 307       (or (bolp) (newline)))))
 308
 309 (defun server-sentinel (proc msg)
 310   "The process sentinel for Emacs server connections."
 311   ;; If this is a new client process, set the query-on-exit flag to nil
 312   ;; for this process (it isn't inherited from the server process).
 313   (when (and (eq (process-status proc) 'open)
 314              (process-query-on-exit-flag proc))
 315     (set-process-query-on-exit-flag proc nil))
 316   ;; Delete the associated connection file, if applicable.
 317   ;; This is actually problematic: the file may have been overwritten by
 318   ;; another Emacs server in the mean time, so it's not ours any more.
 319   ;; (and (process-contact proc :server)
 320   ;;      (eq (process-status proc) 'closed)
 321   ;;      (ignore-errors (delete-file (process-get proc :server-file))))
 322   (server-log (format "Status changed to %s: %s" (process-status proc) msg) proc)
 323   (server-delete-client proc))
 324
 325 (defun server-select-display (display)
 326   ;; If the current frame is on `display' we're all set.
 327   ;; Similarly if we are unable to open a frames on other displays, there's
 328   ;; nothing more we can do.
 329   (unless (or (not (fboundp 'make-frame-on-display))
 330               (equal (frame-parameter (selected-frame) 'display) display))
 331     ;; Otherwise, look for an existing frame there and select it.
 332     (dolist (frame (frame-list))
 333       (when (equal (frame-parameter frame 'display) display)
 334         (select-frame frame)))
 335     ;; If there's no frame on that display yet, create and select one.
 336     (unless (equal (frame-parameter (selected-frame) 'display) display)
 337       (let* ((buffer (generate-new-buffer " *server-dummy*"))
 338              (frame (make-frame-on-display
 339                      display
 340                      ;; Make it display (and remember) some dummy buffer, so
 341                      ;; we can detect later if the frame is in use or not.
 342                      `((server-dummmy-buffer . ,buffer)
 343                        ;; This frame may be deleted later (see
 344                        ;; server-unselect-display) so we want it to be as
 345                        ;; unobtrusive as possible.
 346                        (visibility . nil)))))
 347         (select-frame frame)
 348         (set-window-buffer (selected-window) buffer)
 349         frame))))
 350
 351 (defun server-unselect-display (frame)
 352   (when (frame-live-p frame)
 353     ;; If the temporary frame is in use (displays something real), make it
 354     ;; visible.  If not (which can happen if the user's customizations call
 355     ;; pop-to-buffer etc.), delete it to avoid preserving the connection after
 356     ;; the last real frame is deleted.
 357     (if (and (eq (frame-first-window frame)
 358                  (next-window (frame-first-window frame) 'nomini))
 359              (eq (window-buffer (frame-first-window frame))
 360                  (frame-parameter frame 'server-dummy-buffer)))
 361         ;; The temp frame still only shows one buffer, and that is the
 362         ;; internal temp buffer.
 363         (delete-frame frame)
 364       (set-frame-parameter frame 'visibility t))
 365     (kill-buffer (frame-parameter frame 'server-dummy-buffer))
 366     (set-frame-parameter frame 'server-dummy-buffer nil)))
 367
 368 (defun server-handle-delete-frame (frame)
 369   "Delete the client connection when the emacsclient frame is deleted."
 370   (let ((proc (frame-parameter frame 'client)))
 371     (when (and (frame-live-p frame)
 372                proc
 373                ;; See if this is the last frame for this client.
 374                (>= 1 (let ((frame-num 0))
 375                       (dolist (f (frame-list))
 376                         (when (eq proc (frame-parameter f 'client))
 377                           (setq frame-num (1+ frame-num))))
 378                       frame-num)))
 379       (server-log (format "server-handle-delete-frame, frame %s" frame) proc)
 380       (server-delete-client proc 'noframe)))) ; Let delete-frame delete the frame later.
 381
 382 (defun server-handle-suspend-tty (terminal)
 383   "Notify the emacsclient process to suspend itself when its tty device is suspended."
 384   (dolist (proc (server-clients-with 'terminal terminal))
 385     (server-log (format "server-handle-suspend-tty, terminal %s" terminal) proc)
 386     (condition-case err
 387         (server-send-string proc "-suspend \n")
 388       (file-error                       ;The pipe/socket was closed.
 389        (ignore-errors (server-delete-client proc))))))
 390
 391 (defun server-unquote-arg (arg)
 392   "Remove &-quotation from ARG.
 393 See `server-quote-arg' and `server-process-filter'."
 394   (replace-regexp-in-string
 395    "&." (lambda (s)
 396           (case (aref s 1)
 397             (?& "&")
 398             (?- "-")
 399             (?n "\n")
 400             (t " ")))
 401    arg t t))
 402
 403 (defun server-quote-arg (arg)
 404   "In ARG, insert a & before each &, each space, each newline, and -.
 405 Change spaces to underscores, too, so that the return value never
 406 contains a space.
 407
 408 See `server-unquote-arg' and `server-process-filter'."
 409   (replace-regexp-in-string
 410    "[-&\n ]" (lambda (s)
 411                (case (aref s 0)
 412                  (?& "&&")
 413                  (?- "&-")
 414                  (?\n "&n")
 415                  (?\s "&_")))
 416    arg t t))
 417
 418 (defun server-send-string (proc string)
 419   "A wrapper around `proc-send-string' for logging."
 420   (server-log (concat "Sent " string) proc)
 421   (process-send-string proc string))
 422
 423 (defun server-ensure-safe-dir (dir)
 424   "Make sure DIR is a directory with no race-condition issues.
 425 Creates the directory if necessary and makes sure:
 426 - there's no symlink involved
 427 - it's owned by us
 428 - it's not readable/writable by anybody else."
 429   (setq dir (directory-file-name dir))
 430   (let ((attrs (file-attributes dir)))
 431     (unless attrs
 432       (letf (((default-file-modes) ?\700)) (make-directory dir t))
 433       (setq attrs (file-attributes dir)))
 434     ;; Check that it's safe for use.
 435     (unless (and (eq t (car attrs)) (eql (nth 2 attrs) (user-uid))
 436                  (or (eq system-type 'windows-nt)
 437                      (zerop (logand ?\077 (file-modes dir)))))
 438       (error "The directory %s is unsafe" dir))))
 439
 440 ;;;###autoload
 441 (defun server-start (&optional leave-dead)
 442   "Allow this Emacs process to be a server for client processes.
 443 This starts a server communications subprocess through which
 444 client \"editors\" can send your editing commands to this Emacs
 445 job.  To use the server, set up the program `emacsclient' in the
 446 Emacs distribution as your standard \"editor\".
 447
 448 Optional argument LEAVE-DEAD (interactively, a prefix arg) means just
 449 kill any existing server communications subprocess."
 450   (interactive "P")
 451   (when (or
 452          (not server-clients)
 453          (yes-or-no-p
 454           "The current server still has clients; delete them? "))
 455     ;; It is safe to get the user id now.
 456     (setq server-socket-dir (or server-socket-dir
 457                                 (format "/tmp/emacs%d" (user-uid))))
 458     (when server-process
 459       ;; kill it dead!
 460       (ignore-errors (delete-process server-process)))
 461     ;; Delete the socket files made by previous server invocations.
 462     (condition-case ()
 463         (delete-file (expand-file-name server-name server-socket-dir))
 464       (error nil))
 465     ;; If this Emacs already had a server, clear out associated status.
 466     (while server-clients
 467       (server-delete-client (car server-clients)))
 468     ;; Now any previous server is properly stopped.
 469     (if leave-dead
 470         (progn
 471           (server-log (message "Server stopped"))
 472           (setq server-process nil))
 473       (let* ((server-dir (if server-use-tcp server-auth-dir server-socket-dir))
 474              (server-file (expand-file-name server-name server-dir)))
 475         ;; Make sure there is a safe directory in which to place the socket.
 476         (server-ensure-safe-dir server-dir)
 477         ;; Remove any leftover socket or authentication file.
 478         (ignore-errors (delete-file server-file))
 479         (when server-process
 480           (server-log (message "Restarting server")))
 481         (letf (((default-file-modes) ?\700))
 482           (add-hook 'suspend-tty-functions 'server-handle-suspend-tty)
 483           (add-hook 'delete-frame-functions 'server-handle-delete-frame)
 484           (add-hook 'kill-buffer-query-functions 'server-kill-buffer-query-function)
 485           (add-hook 'kill-emacs-query-functions 'server-kill-emacs-query-function)
 486           (add-hook 'kill-emacs-hook (lambda () (server-mode -1))) ;Cleanup upon exit.
 487           (setq server-process
 488                 (apply #'make-network-process
 489                        :name server-name
 490                        :server t
 491                        :noquery t
 492                        :sentinel 'server-sentinel
 493                        :filter 'server-process-filter
 494                        ;; We must receive file names without being decoded.
 495                        ;; Those are decoded by server-process-filter according
 496                        ;; to file-name-coding-system.
 497                        :coding 'raw-text
 498                        ;; The rest of the args depends on the kind of socket used.
 499                        (if server-use-tcp
 500                            (list :family nil
 501                                  :service t
 502                                  :host (or server-host 'local)
 503                                  :plist '(:authenticated nil))
 504                          (list :family 'local
 505                                :service server-file
 506                                :plist '(:authenticated t)))))
 507           (unless server-process (error "Could not start server process"))
 508           (when server-use-tcp
 509             (let ((auth-key
 510                    (loop
 511                       ;; The auth key is a 64-byte string of random chars in the
 512                       ;; range `!'..`~'.
 513                       for i below 64
 514                       collect (+ 33 (random 94)) into auth
 515                       finally return (concat auth))))
 516               (process-put server-process :auth-key auth-key)
 517               (with-temp-file server-file
 518                 (set-buffer-multibyte nil)
 519                 (setq buffer-file-coding-system 'no-conversion)
 520                 (insert (format-network-address
 521                          (process-contact server-process :local))
 522                         " " (int-to-string (emacs-pid))
 523                         "\n" auth-key)))))))))
 524
 525 (defun server-running-p (&optional name)
 526   "Test whether server NAME is running."
 527   (interactive
 528    (list (if current-prefix-arg
 529              (read-string "Server name: " nil nil server-name))))
 530   (unless name (setq name server-name))
 531   (condition-case nil
 532       (progn
 533         (delete-process
 534          (make-network-process
 535           :name "server-client-test" :family 'local :server nil :noquery t
 536           :service (expand-file-name name server-socket-dir)))
 537         t)
 538     (file-error nil)))
 539
 540 ;;;###autoload
 541 (define-minor-mode server-mode
 542   "Toggle Server mode.
 543 With ARG, turn Server mode on if ARG is positive, off otherwise.
 544 Server mode runs a process that accepts commands from the
 545 `emacsclient' program.  See `server-start' and Info node `Emacs server'."
 546   :global t
 547   :group 'server
 548   :version "22.1"
 549   ;; Fixme: Should this check for an existing server socket and do
 550   ;; nothing if there is one (for multiple Emacs sessions)?
 551   (server-start (not server-mode)))
 552 \f
 553 (defun server-eval-and-print (expr proc)
 554   "Eval EXPR and send the result back to client PROC."
 555   (let ((v (eval (car (read-from-string expr)))))
 556     (when (and v proc)
 557       (with-temp-buffer
 558         (let ((standard-output (current-buffer)))
 559           (pp v)
 560           (let ((text (buffer-substring-no-properties
 561                        (point-min) (point-max))))
 562             (server-send-string
 563              proc (format "-print %s\n"
 564                           (server-quote-arg text)))))))))
 565
 566 (defun server-create-tty-frame (tty type proc)
 567   (add-to-list 'frame-inherited-parameters 'client)
 568   (let ((frame
 569          (server-with-environment (process-get proc 'env)
 570              '("LANG" "LC_CTYPE" "LC_ALL"
 571                ;; For tgetent(3); list according to ncurses(3).
 572                "BAUDRATE" "COLUMNS" "ESCDELAY" "HOME" "LINES"
 573                "NCURSES_ASSUMED_COLORS" "NCURSES_NO_PADDING"
 574                "NCURSES_NO_SETBUF" "TERM" "TERMCAP" "TERMINFO"
 575                "TERMINFO_DIRS" "TERMPATH"
 576                ;; rxvt wants these
 577                "COLORFGBG" "COLORTERM")
 578            (make-frame-on-tty tty type
 579                               ;; Ignore nowait here; we always need to
 580                               ;; clean up opened ttys when the client dies.
 581                               `((client . ,proc)
 582                                 ;; This is a leftover from an earlier
 583                                 ;; attempt at making it possible for process
 584                                 ;; run in the server process to use the
 585                                 ;; environment of the client process.
 586                                 ;; It has no effect now and to make it work
 587                                 ;; we'd need to decide how to make
 588                                 ;; process-environment interact with client
 589                                 ;; envvars, and then to change the
 590                                 ;; C functions `child_setup' and
 591                                 ;; `getenv_internal' accordingly.
 592                                 (environment . ,(process-get proc 'env)))))))
 593
 594     ;; ttys don't use the `display' parameter, but callproc.c does to set
 595     ;; the DISPLAY environment on subprocesses.
 596     (set-frame-parameter frame 'display
 597                          (getenv-internal "DISPLAY" (process-get proc 'env)))
 598     (select-frame frame)
 599     (process-put proc 'frame frame)
 600     (process-put proc 'terminal (frame-terminal frame))
 601
 602     ;; Display *scratch* by default.
 603     (switch-to-buffer (get-buffer-create "*scratch*") 'norecord)
 604
 605     ;; Reply with our pid.
 606     (server-send-string proc (concat "-emacs-pid "
 607                                      (number-to-string (emacs-pid)) "\n"))
 608     frame))
 609
 610 (defun server-create-window-system-frame (display nowait proc)
 611   (add-to-list 'frame-inherited-parameters 'client)
 612   (if (not (fboundp 'make-frame-on-display))
 613       (progn
 614         ;; This emacs does not support X.
 615         (server-log "Window system unsupported" proc)
 616         (server-send-string proc "-window-system-unsupported \n")
 617         nil)
 618     ;; Flag frame as client-created, but use a dummy client.
 619     ;; This will prevent the frame from being deleted when
 620     ;; emacsclient quits while also preventing
 621     ;; `server-save-buffers-kill-terminal' from unexpectedly
 622     ;; killing emacs on that frame.
 623     (let* ((params `((client . ,(if nowait 'nowait proc))
 624                      ;; This is a leftover, see above.
 625                      (environment . ,(process-get proc 'env))))
 626            (frame (make-frame-on-display
 627                    (or display
 628                        (frame-parameter nil 'display)
 629                        (getenv "DISPLAY")
 630                        (error "Please specify display"))
 631                    params)))
 632       (server-log (format "%s created" frame) proc)
 633       ;; XXX We need to ensure the parameters are really set because Emacs
 634       ;; forgets unhandled initialization parameters for X frames at
 635       ;; the moment.
 636       (modify-frame-parameters frame params)
 637       (select-frame frame)
 638       (process-put proc 'frame frame)
 639       (process-put proc 'terminal (frame-terminal frame))
 640
 641       ;; Display *scratch* by default.
 642       (switch-to-buffer (get-buffer-create "*scratch*") 'norecord)
 643       frame)))
 644
 645
 646 (defun server-goto-toplevel (proc)
 647   (condition-case nil
 648       ;; If we're running isearch, we must abort it to allow Emacs to
 649       ;; display the buffer and switch to it.
 650       (dolist (buffer (buffer-list))
 651         (with-current-buffer buffer
 652           (when (bound-and-true-p isearch-mode)
 653             (isearch-cancel))))
 654     ;; Signaled by isearch-cancel.
 655     (quit (message nil)))
 656   (when (> (recursion-depth) 0)
 657     ;; We're inside a minibuffer already, so if the emacs-client is trying
 658     ;; to open a frame on a new display, we might end up with an unusable
 659     ;; frame because input from that display will be blocked (until exiting
 660     ;; the minibuffer).  Better exit this minibuffer right away.
 661     ;; Similarly with recursive-edits such as the splash screen.
 662     (run-with-timer 0 nil (lexical-let ((proc proc))
 663                             (lambda () (server-execute-continuation proc))))
 664     (top-level)))
 665
 666 ;; We use various special properties on process objects:
 667 ;; - `env' stores the info about the environment of the emacsclient process.
 668 ;; - `continuation' is a no-arg function that we need to execute.  It contains
 669 ;;   commands we wanted to execute in some earlier invocation of the process
 670 ;;   filter but that we somehow were unable to process at that time
 671 ;;   (e.g. because we first need to throw to the toplevel).
 672
 673 (defun server-execute-continuation (proc)
 674   (let ((continuation (process-get proc 'continuation)))
 675     (process-put proc 'continuation nil)
 676     (if continuation (ignore-errors (funcall continuation)))))
 677
 678 (defun* server-process-filter (proc string)
 679   "Process a request from the server to edit some files.
 680 PROC is the server process.  STRING consists of a sequence of
 681 commands prefixed by a dash.  Some commands have arguments; these
 682 are &-quoted and need to be decoded by `server-unquote-arg'.  The
 683 filter parses and executes these commands.
 684
 685 To illustrate the protocol, here is an example command that
 686 emacsclient sends to create a new X frame (note that the whole
 687 sequence is sent on a single line):
 688
 689         -env HOME /home/lorentey
 690         -env DISPLAY :0.0
 691         ... lots of other -env commands
 692         -display :0.0
 693         -window-system
 694
 695 The following commands are accepted by the server:
 696
 697 `-auth AUTH-STRING'
 698   Authenticate the client using the secret authentication string
 699   AUTH-STRING.
 700
 701 `-env NAME=VALUE'
 702   An environment variable on the client side.
 703
 704 `-dir DIRNAME'
 705   The current working directory of the client process.
 706
 707 `-current-frame'
 708   Forbid the creation of new frames.
 709
 710 `-nowait'
 711   Request that the next frame created should not be
 712   associated with this client.
 713
 714 `-display DISPLAY'
 715   Set the display name to open X frames on.
 716
 717 `-position LINE[:COLUMN]'
 718   Go to the given line and column number
 719   in the next file opened.
 720
 721 `-file FILENAME'
 722   Load the given file in the current frame.
 723
 724 `-eval EXPR'
 725   Evaluate EXPR as a Lisp expression and return the
 726   result in -print commands.
 727
 728 `-window-system'
 729   Open a new X frame.
 730
 731 `-tty DEVICENAME TYPE'
 732   Open a new tty frame at the client.
 733
 734 `-suspend'
 735   Suspend this tty frame.  The client sends this string in
 736   response to SIGTSTP and SIGTTOU.  The server must cease all I/O
 737   on this tty until it gets a -resume command.
 738
 739 `-resume'
 740   Resume this tty frame.  The client sends this string when it
 741   gets the SIGCONT signal and it is the foreground process on its
 742   controlling tty.
 743
 744 `-ignore COMMENT'
 745   Do nothing, but put the comment in the server
 746   log.  Useful for debugging.
 747
 748
 749 The following commands are accepted by the client:
 750
 751 `-emacs-pid PID'
 752   Describes the process id of the Emacs process;
 753   used to forward window change signals to it.
 754
 755 `-window-system-unsupported'
 756   Signals that the server does not support creating X frames;
 757   the client must try again with a tty frame.
 758
 759 `-print STRING'
 760   Print STRING on stdout.  Used to send values
 761   returned by -eval.
 762
 763 `-error DESCRIPTION'
 764   Signal an error (but continue processing).
 765
 766 `-suspend'
 767   Suspend this terminal, i.e., stop the client process.
 768   Sent when the user presses C-z."
 769   (server-log (concat "Received " string) proc)
 770   ;; First things first: let's check the authentication
 771   (unless (process-get proc :authenticated)
 772     (if (and (string-match "-auth \\(.*?\\)\n" string)
 773              (equal (match-string 1 string) (process-get proc :auth-key)))
 774         (progn
 775           (setq string (substring string (match-end 0)))
 776           (process-put proc :authenticated t)
 777           (server-log "Authentication successful" proc))
 778       (server-log "Authentication failed" proc)
 779       (server-send-string
 780        proc (concat "-error " (server-quote-arg "Authentication failed")))
 781       (delete-process proc)
 782       ;; We return immediately
 783       (return-from server-process-filter)))
 784   (let ((prev (process-get proc 'previous-string)))
 785     (when prev
 786       (setq string (concat prev string))
 787       (process-put proc 'previous-string nil)))
 788   (condition-case err
 789       (progn
 790         (server-add-client proc)
 791         (if (not (string-match "\n" string))
 792             ;; Save for later any partial line that remains.
 793             (when (> (length string) 0)
 794               (process-put proc 'previous-string string))
 795
 796           ;; In earlier versions of server.el (where we used an `emacsserver'
 797           ;; process), there could be multiple lines.  Nowadays this is not
 798           ;; supported any more.
 799           (assert (eq (match-end 0) (length string)))
 800           (let ((request (substring string 0 (match-beginning 0)))
 801                 (coding-system (and default-enable-multibyte-characters
 802                                     (or file-name-coding-system
 803                                         default-file-name-coding-system)))
 804                 nowait ; t if emacsclient does not want to wait for us.
 805                 frame ; The frame that was opened for the client (if any).
 806                 display              ; Open the frame on this display.
 807                 dontkill       ; t if the client should not be killed.
 808                 (commands ())
 809                 dir
 810                 (tty-name nil)       ;nil, `window-system', or the tty name.
 811                 tty-type             ;string.
 812                 (files nil)
 813                 (lineno 1)
 814                 (columnno 0)
 815                 command-line-args-left
 816                 arg)
 817             ;; Remove this line from STRING.
 818             (setq string (substring string (match-end 0)))
 819             (setq command-line-args-left
 820                   (mapcar 'server-unquote-arg (split-string request " " t)))
 821             (while (setq arg (pop command-line-args-left))
 822                 (cond
 823                  ;; -version CLIENT-VERSION: obsolete at birth.
 824                  ((and (equal "-version" arg) command-line-args-left)
 825                   (pop command-line-args-left))
 826
 827                  ;; -nowait:  Emacsclient won't wait for a result.
 828                  ((equal "-nowait" arg) (setq nowait t))
 829
 830                  ;; -current-frame:  Don't create frames.
 831                  ((equal "-current-frame" arg) (setq tty-name nil))
 832
 833                  ;; -display DISPLAY:
 834                  ;; Open X frames on the given display instead of the default.
 835                  ((and (equal "-display" arg) command-line-args-left)
 836                   (setq display (pop command-line-args-left)))
 837
 838                  ;; -window-system:  Open a new X frame.
 839                  ((equal "-window-system" arg)
 840                   (setq dontkill t)
 841                   (setq tty-name 'window-system))
 842
 843                  ;; -resume:  Resume a suspended tty frame.
 844                  ((equal "-resume" arg)
 845                   (lexical-let ((terminal (process-get proc 'terminal)))
 846                     (setq dontkill t)
 847                     (push (lambda ()
 848                             (when (eq (terminal-live-p terminal) t)
 849                               (resume-tty terminal)))
 850                           commands)))
 851
 852                  ;; -suspend:  Suspend the client's frame.  (In case we
 853                  ;; get out of sync, and a C-z sends a SIGTSTP to
 854                  ;; emacsclient.)
 855                  ((equal "-suspend" arg)
 856                   (lexical-let ((terminal (process-get proc 'terminal)))
 857                     (setq dontkill t)
 858                     (push (lambda ()
 859                             (when (eq (terminal-live-p terminal) t)
 860                               (suspend-tty terminal)))
 861                           commands)))
 862
 863                  ;; -ignore COMMENT:  Noop; useful for debugging emacsclient.
 864                  ;; (The given comment appears in the server log.)
 865                  ((and (equal "-ignore" arg) command-line-args-left
 866                   (setq dontkill t)
 867                   (pop command-line-args-left)))
 868
 869                  ;; -tty DEVICE-NAME TYPE:  Open a new tty frame at the client.
 870                  ((and (equal "-tty" arg)
 871                        (cdr command-line-args-left))
 872                   (setq tty-name (pop command-line-args-left)
 873                         tty-type (pop command-line-args-left)
 874                         dontkill t))
 875
 876                  ;; -position LINE[:COLUMN]:  Set point to the given
 877                  ;;  position in the next file.
 878                  ((and (equal "-position" arg)
 879                        command-line-args-left
 880                        (string-match "\\+\\([0-9]+\\)\\(?::\\([0-9]+\\)\\)?"
 881                                      (car command-line-args-left)))
 882                   (setq arg (pop command-line-args-left))
 883                   (setq lineno (string-to-number (match-string 1 arg))
 884                         columnno (if (null (match-end 2)) 0
 885                                    (string-to-number (match-string 2 arg)))))
 886
 887                  ;; -file FILENAME:  Load the given file.
 888                  ((and (equal "-file" arg)
 889                        command-line-args-left)
 890                   (let ((file (pop command-line-args-left)))
 891                     (if coding-system
 892                         (setq file (decode-coding-string file coding-system)))
 893                     (setq file (command-line-normalize-file-name file))
 894                     (push (list file lineno columnno) files)
 895                     (server-log (format "New file: %s (%d:%d)"
 896                                         file lineno columnno) proc))
 897                   (setq lineno 1
 898                         columnno 0))
 899
 900                  ;; -eval EXPR:  Evaluate a Lisp expression.
 901                  ((and (equal "-eval" arg)
 902                        command-line-args-left)
 903                   (lexical-let ((expr (pop command-line-args-left)))
 904                     (if coding-system
 905                         (setq expr (decode-coding-string expr coding-system)))
 906                     (push (lambda () (server-eval-and-print expr proc))
 907                           commands)
 908                     (setq lineno 1
 909                           columnno 0)))
 910
 911                  ;; -env NAME=VALUE:  An environment variable.
 912                  ((and (equal "-env" arg) command-line-args-left)
 913                   (let ((var (pop command-line-args-left)))
 914                     ;; XXX Variables should be encoded as in getenv/setenv.
 915                     (process-put proc 'env
 916                                  (cons var (process-get proc 'env)))))
 917
 918                  ;; -dir DIRNAME:  The cwd of the emacsclient process.
 919                  ((and (equal "-dir" arg) command-line-args-left)
 920                   (setq dir (pop command-line-args-left))
 921                   (if coding-system
 922                       (setq dir (decode-coding-string dir coding-system)))
 923                   (setq dir (command-line-normalize-file-name dir)))
 924
 925                  ;; Unknown command.
 926                  (t (error "Unknown command: %s" arg))))
 927
 928             (setq frame
 929                   (case tty-name
 930                     ((nil) (if display (server-select-display display)))
 931                     ((window-system)
 932                      (server-create-window-system-frame display nowait proc))
 933                     (t (server-create-tty-frame tty-name tty-type proc))))
 934
 935             (process-put proc 'continuation
 936                          (lexical-let ((proc proc)
 937                                        (files files)
 938                                        (nowait nowait)
 939                                        (commands commands)
 940                                        (dontkill dontkill)
 941                                        (frame frame)
 942                                        (tty-name tty-name))
 943                            (lambda ()
 944                              (server-execute proc files nowait commands
 945                                              dontkill frame tty-name))))
 946
 947             (when (or frame files)
 948               (server-goto-toplevel proc))
 949
 950             (server-execute-continuation proc))))
 951     ;; condition-case
 952     (error (server-return-error proc err))))
 953
 954 (defun server-execute (proc files nowait commands dontkill frame tty-name)
 955   (condition-case err
 956       (let* ((buffers
 957               (when files
 958                 (run-hooks 'pre-command-hook)
 959                 (prog1 (server-visit-files files proc nowait)
 960                   (run-hooks 'post-command-hook)))))
 961
 962         (mapc 'funcall (nreverse commands))
 963
 964         ;; Delete the client if necessary.
 965         (cond
 966          (nowait
 967           ;; Client requested nowait; return immediately.
 968           (server-log "Close nowait client" proc)
 969           (server-delete-client proc))
 970          ((and (not dontkill) (null buffers))
 971           ;; This client is empty; get rid of it immediately.
 972           (server-log "Close empty client" proc)
 973           (server-delete-client proc)))
 974         (cond
 975          ((or isearch-mode (minibufferp))
 976           nil)
 977          ((and frame (null buffers))
 978           (message "%s" (substitute-command-keys
 979                          "When done with this frame, type \\[delete-frame]")))
 980          ((not (null buffers))
 981           (server-switch-buffer (car buffers))
 982           (run-hooks 'server-switch-hook)
 983           (unless nowait
 984             (message "%s" (substitute-command-keys
 985                            "When done with a buffer, type \\[server-edit]")))))
 986         (when (and frame (null tty-name))
 987           (server-unselect-display frame)))
 988     (error (server-return-error proc err))))
 989
 990 (defun server-return-error (proc err)
 991   (ignore-errors
 992     (server-send-string
 993      proc (concat "-error " (server-quote-arg
 994                              (error-message-string err))))
 995     (server-log (error-message-string err) proc)
 996     (delete-process proc)))
 997
 998 (defun server-goto-line-column (file-line-col)
 999   "Move point to the position indicated in FILE-LINE-COL.
1000 FILE-LINE-COL should be a three-element list as described in
1001 `server-visit-files'."
1002   (goto-line (nth 1 file-line-col))
1003   (let ((column-number (nth 2 file-line-col)))
1004     (when (> column-number 0)
1005       (move-to-column (1- column-number)))))
1006
1007 (defun server-visit-files (files proc &optional nowait)
1008   "Find FILES and return a list of buffers created.
1009 FILES is an alist whose elements are (FILENAME LINENUMBER COLUMNNUMBER).
1010 PROC is the client that requested this operation.
1011 NOWAIT non-nil means this client is not waiting for the results,
1012 so don't mark these buffers specially, just visit them normally."
1013   ;; Bind last-nonmenu-event to force use of keyboard, not mouse, for queries.
1014   (let ((last-nonmenu-event t) client-record)
1015     ;; Restore the current buffer afterward, but not using save-excursion,
1016     ;; because we don't want to save point in this buffer
1017     ;; if it happens to be one of those specified by the server.
1018     (save-current-buffer
1019       (dolist (file files)
1020         ;; If there is an existing buffer modified or the file is
1021         ;; modified, revert it.  If there is an existing buffer with
1022         ;; deleted file, offer to write it.
1023         (let* ((minibuffer-auto-raise (or server-raise-frame
1024                                           minibuffer-auto-raise))
1025                (filen (car file))
1026                (obuf (get-file-buffer filen)))
1027           (add-to-history 'file-name-history filen)
1028           (if (and obuf (set-buffer obuf))
1029               (progn
1030                 (cond ((file-exists-p filen)
1031                        (when (not (verify-visited-file-modtime obuf))
1032                          (revert-buffer t nil)))
1033                       (t
1034                        (when (y-or-n-p
1035                               (concat "File no longer exists: " filen
1036                                       ", write buffer to file? "))
1037                          (write-file filen))))
1038                 (unless server-buffer-clients
1039                   (setq server-existing-buffer t))
1040                 (server-goto-line-column file))
1041             (set-buffer (find-file-noselect filen))
1042             (server-goto-line-column file)
1043             (run-hooks 'server-visit-hook)))
1044         (unless nowait
1045           ;; When the buffer is killed, inform the clients.
1046           (add-hook 'kill-buffer-hook 'server-kill-buffer nil t)
1047           (push proc server-buffer-clients))
1048         (push (current-buffer) client-record)))
1049     (unless nowait
1050       (process-put proc 'buffers
1051                    (nconc (process-get proc 'buffers) client-record)))
1052     client-record))
1053 \f
1054 (defun server-buffer-done (buffer &optional for-killing)
1055   "Mark BUFFER as \"done\" for its client(s).
1056 This buries the buffer, then returns a list of the form (NEXT-BUFFER KILLED).
1057 NEXT-BUFFER is another server buffer, as a suggestion for what to select next,
1058 or nil.  KILLED is t if we killed BUFFER (typically, because it was visiting
1059 a temp file).
1060 FOR-KILLING if non-nil indicates that we are called from `kill-buffer'."
1061   (let ((next-buffer nil)
1062         (killed nil))
1063     (dolist (proc server-clients)
1064       (let ((buffers (process-get proc 'buffers)))
1065         (or next-buffer
1066             (setq next-buffer (nth 1 (memq buffer buffers))))
1067         (when buffers                   ; Ignore bufferless clients.
1068           (setq buffers (delq buffer buffers))
1069           ;; Delete all dead buffers from PROC.
1070           (dolist (b buffers)
1071             (and (bufferp b)
1072                  (not (buffer-live-p b))
1073                  (setq buffers (delq b buffers))))
1074           (process-put proc 'buffers buffers)
1075           ;; If client now has no pending buffers,
1076           ;; tell it that it is done, and forget it entirely.
1077           (unless buffers
1078             (server-log "Close" proc)
1079             (server-delete-client proc)))))
1080     (when (and (bufferp buffer) (buffer-name buffer))
1081       ;; We may or may not kill this buffer;
1082       ;; if we do, do not call server-buffer-done recursively
1083       ;; from kill-buffer-hook.
1084       (let ((server-kill-buffer-running t))
1085         (with-current-buffer buffer
1086           (setq server-buffer-clients nil)
1087           (run-hooks 'server-done-hook))
1088         ;; Notice whether server-done-hook killed the buffer.
1089         (if (null (buffer-name buffer))
1090             (setq killed t)
1091           ;; Don't bother killing or burying the buffer
1092           ;; when we are called from kill-buffer.
1093           (unless for-killing
1094             (when (and (not killed)
1095                        server-kill-new-buffers
1096                        (with-current-buffer buffer
1097                          (not server-existing-buffer)))
1098               (setq killed t)
1099               (bury-buffer buffer)
1100               (kill-buffer buffer))
1101             (unless killed
1102               (if (server-temp-file-p buffer)
1103                   (progn
1104                     (kill-buffer buffer)
1105                     (setq killed t))
1106                 (bury-buffer buffer)))))))
1107     (list next-buffer killed)))
1108
1109 (defun server-temp-file-p (&optional buffer)
1110   "Return non-nil if BUFFER contains a file considered temporary.
1111 These are files whose names suggest they are repeatedly
1112 reused to pass information to another program.
1113
1114 The variable `server-temp-file-regexp' controls which filenames
1115 are considered temporary."
1116   (and (buffer-file-name buffer)
1117        (string-match server-temp-file-regexp (buffer-file-name buffer))))
1118
1119 (defun server-done ()
1120   "Offer to save current buffer, mark it as \"done\" for clients.
1121 This kills or buries the buffer, then returns a list
1122 of the form (NEXT-BUFFER KILLED).  NEXT-BUFFER is another server buffer,
1123 as a suggestion for what to select next, or nil.
1124 KILLED is t if we killed BUFFER, which happens if it was created
1125 specifically for the clients and did not exist before their request for it."
1126   (when server-buffer-clients
1127     (if (server-temp-file-p)
1128         ;; For a temp file, save, and do make a non-numeric backup
1129         ;; (unless make-backup-files is nil).
1130         (let ((version-control nil)
1131               (buffer-backed-up nil))
1132           (save-buffer))
1133       (when (and (buffer-modified-p)
1134                  buffer-file-name
1135                  (y-or-n-p (concat "Save file " buffer-file-name "? ")))
1136         (save-buffer)))
1137     (server-buffer-done (current-buffer))))
1138
1139 ;; Ask before killing a server buffer.
1140 ;; It was suggested to release its client instead,
1141 ;; but I think that is dangerous--the client would proceed
1142 ;; using whatever is on disk in that file. -- rms.
1143 (defun server-kill-buffer-query-function ()
1144   "Ask before killing a server buffer."
1145   (or (not server-buffer-clients)
1146       (let ((res t))
1147         (dolist (proc server-buffer-clients res)
1148           (when (and (memq proc server-clients)
1149                      (eq (process-status proc) 'open))
1150             (setq res nil))))
1151       (yes-or-no-p (format "Buffer `%s' still has clients; kill it? "
1152                            (buffer-name (current-buffer))))))
1153
1154 (defun server-kill-emacs-query-function ()
1155   "Ask before exiting Emacs if it has live clients."
1156   (or (not server-clients)
1157       (let (live-client)
1158         (dolist (proc server-clients live-client)
1159           (when (memq t (mapcar 'buffer-live-p (process-get
1160                                                 proc 'buffers)))
1161             (setq live-client t))))
1162       (yes-or-no-p "This Emacs session has clients; exit anyway? ")))
1163
1164 (defvar server-kill-buffer-running nil
1165   "Non-nil while `server-kill-buffer' or `server-buffer-done' is running.")
1166
1167 (defun server-kill-buffer ()
1168   "Remove the current buffer from its clients' buffer list.
1169 Designed to be added to `kill-buffer-hook'."
1170   ;; Prevent infinite recursion if user has made server-done-hook
1171   ;; call kill-buffer.
1172   (or server-kill-buffer-running
1173       (and server-buffer-clients
1174            (let ((server-kill-buffer-running t))
1175              (when server-process
1176                (server-buffer-done (current-buffer) t))))))
1177 \f
1178 (defun server-edit (&optional arg)
1179   "Switch to next server editing buffer; say \"Done\" for current buffer.
1180 If a server buffer is current, it is marked \"done\" and optionally saved.
1181 The buffer is also killed if it did not exist before the clients asked for it.
1182 When all of a client's buffers are marked as \"done\", the client is notified.
1183
1184 Temporary files such as MH <draft> files are always saved and backed up,
1185 no questions asked.  (The variable `make-backup-files', if nil, still
1186 inhibits a backup; you can set it locally in a particular buffer to
1187 prevent a backup for it.)  The variable `server-temp-file-regexp' controls
1188 which filenames are considered temporary.
1189
1190 If invoked with a prefix argument, or if there is no server process running,
1191 starts server process and that is all.  Invoked by \\[server-edit]."
1192   (interactive "P")
1193   (cond
1194     ((or arg
1195          (not server-process)
1196          (memq (process-status server-process) '(signal exit)))
1197      (server-mode 1))
1198     (server-clients (apply 'server-switch-buffer (server-done)))
1199     (t (message "No server editing buffers exist"))))
1200
1201 (defun server-switch-buffer (&optional next-buffer killed-one)
1202   "Switch to another buffer, preferably one that has a client.
1203 Arg NEXT-BUFFER is a suggestion; if it is a live buffer, use it.
1204
1205 KILLED-ONE is t in a recursive call if we have already killed one
1206 temp-file server buffer.  This means we should avoid the final
1207 \"switch to some other buffer\" since we've already effectively
1208 done that."
1209   (if (null next-buffer)
1210       (progn
1211         (let ((rest server-clients))
1212           (while (and rest (not next-buffer))
1213             (let ((proc (car rest)))
1214               ;; Only look at frameless clients.
1215               (when (not (process-get proc 'frame))
1216                 (setq next-buffer (car (process-get proc 'buffers))))
1217               (setq rest (cdr rest)))))
1218         (and next-buffer (server-switch-buffer next-buffer killed-one))
1219         (unless (or next-buffer killed-one (window-dedicated-p (selected-window)))
1220           ;; (switch-to-buffer (other-buffer))
1221           (message "No server buffers remain to edit")))
1222     (if (not (buffer-live-p next-buffer))
1223         ;; If NEXT-BUFFER is a dead buffer, remove the server records for it
1224         ;; and try the next surviving server buffer.
1225         (apply 'server-switch-buffer (server-buffer-done next-buffer))
1226       ;; OK, we know next-buffer is live, let's display and select it.
1227       (if (functionp server-window)
1228           (funcall server-window next-buffer)
1229         (let ((win (get-buffer-window next-buffer 0)))
1230           (if (and win (not server-window))
1231               ;; The buffer is already displayed: just reuse the window.
1232               (progn
1233                 (select-window win)
1234                 (set-buffer next-buffer))
1235             ;; Otherwise, let's find an appropriate window.
1236             (cond ((window-live-p server-window)
1237                    (select-window server-window))
1238                   ((framep server-window)
1239                    (unless (frame-live-p server-window)
1240                      (setq server-window (make-frame)))
1241                    (select-window (frame-selected-window server-window))))
1242             (when (window-minibuffer-p (selected-window))
1243               (select-window (next-window nil 'nomini 0)))
1244             ;; Move to a non-dedicated window, if we have one.
1245             (when (window-dedicated-p (selected-window))
1246               (select-window
1247                (get-window-with-predicate
1248                 (lambda (w)
1249                   (and (not (window-dedicated-p w))
1250                        (equal (frame-terminal (window-frame w))
1251                               (frame-terminal (selected-frame)))))
1252                 'nomini 'visible (selected-window))))
1253             (condition-case nil
1254                 (switch-to-buffer next-buffer)
1255               ;; After all the above, we might still have ended up with
1256               ;; a minibuffer/dedicated-window (if there's no other).
1257               (error (pop-to-buffer next-buffer)))))))
1258     (when server-raise-frame
1259       (select-frame-set-input-focus (window-frame (selected-window))))))
1260
1261 ;;;###autoload
1262 (defun server-save-buffers-kill-terminal (proc &optional arg)
1263   "Offer to save each buffer, then kill PROC.
1264
1265 With prefix arg, silently save all file-visiting buffers, then kill.
1266
1267 If emacsclient was started with a list of filenames to edit, then
1268 only these files will be asked to be saved."
1269   (let ((buffers (process-get proc 'buffers)))
1270     ;; If client is bufferless, emulate a normal Emacs session
1271     ;; exit and offer to save all buffers.  Otherwise, offer to
1272     ;; save only the buffers belonging to the client.
1273     (save-some-buffers arg
1274                        (if buffers
1275                            (lambda () (memq (current-buffer) buffers))
1276                          t))
1277     (server-delete-client proc)))
1278
1279 (define-key ctl-x-map "#" 'server-edit)
1280
1281 (defun server-unload-function ()
1282   "Unload the server library."
1283   (server-mode -1)
1284   (substitute-key-definition 'server-edit nil ctl-x-map)
1285   (save-current-buffer
1286     (dolist (buffer (buffer-list))
1287       (set-buffer buffer)
1288       (remove-hook 'kill-buffer-hook 'server-kill-buffer t)))
1289   ;; continue standard unloading
1290   nil)
1291
1292 \f
1293 (provide 'server)
1294
1295 ;; arch-tag: 1f7ecb42-f00a-49f8-906d-61995d84c8d6
1296 ;;; server.el ends here