lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems
   2
   3 ;; Copyright (C) 1993, 1994, 1996, 1997, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (defvar frame-creation-function-alist
  29   (list (cons nil
  30               (if (fboundp 'tty-create-frame-with-faces)
  31                   'tty-create-frame-with-faces
  32                 (lambda (parameters)
  33                   (error "Can't create multiple frames without a window system")))))
  34   "Alist of window-system dependent functions to call to create a new frame.
  35 The window system startup file should add its frame creation
  36 function to this list, which should take an alist of parameters
  37 as its argument.")
  38
  39 (defvar window-system-default-frame-alist nil
  40   "Alist of window-system dependent default frame parameters.
  41 You can set this in your `.emacs' file; for example,
  42
  43     ;; Disable menubar and toolbar on the console, but enable them under X.
  44     (setq window-system-default-frame-alist
  45           '((x (menu-bar-lines . 1) (tool-bar-lines . 1))
  46             (nil (menu-bar-lines . 0) (tool-bar-lines . 0))))
  47
  48 Parameters specified here supersede the values given in `default-frame-alist'.")
  49
  50 ;; The initial value given here used to ask for a minibuffer.
  51 ;; But that's not necessary, because the default is to have one.
  52 ;; By not specifying it here, we let an X resource specify it.
  53 (defcustom initial-frame-alist nil
  54   "*Alist of frame parameters for creating the initial X window frame.
  55 You can set this in your `.emacs' file; for example,
  56  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  57 Parameters specified here supersede the values given in `default-frame-alist'.
  58
  59 If the value calls for a frame without a minibuffer, and you have not created
  60 a minibuffer frame on your own, one is created according to
  61 `minibuffer-frame-alist'.
  62
  63 You can specify geometry-related options for just the initial frame
  64 by setting this variable in your `.emacs' file; however, they won't
  65 take effect until Emacs reads `.emacs', which happens after first creating
  66 the frame.  If you want the frame to have the proper geometry as soon
  67 as it appears, you need to use this three-step process:
  68 * Specify X resources to give the geometry you want.
  69 * Set `default-frame-alist' to override these options so that they
  70   don't affect subsequent frames.
  71 * Set `initial-frame-alist' in a way that matches the X resources,
  72   to override what you put in `default-frame-alist'."
  73   :type '(repeat (cons :format "%v"
  74                        (symbol :tag "Parameter")
  75                        (sexp :tag "Value")))
  76   :group 'frames)
  77
  78 (defcustom minibuffer-frame-alist '((width . 80) (height . 2))
  79   "*Alist of frame parameters for initially creating a minibuffer frame.
  80 You can set this in your `.emacs' file; for example,
  81  (setq minibuffer-frame-alist
  82    '((top . 1) (left . 1) (width . 80) (height . 2)))
  83 Parameters specified here supersede the values given in
  84 `default-frame-alist', for a minibuffer frame."
  85   :type '(repeat (cons :format "%v"
  86                        (symbol :tag "Parameter")
  87                        (sexp :tag "Value")))
  88   :group 'frames)
  89
  90 (defcustom pop-up-frame-alist nil
  91   "*Alist of frame parameters used when creating pop-up frames.
  92 Pop-up frames are used for completions, help, and the like.
  93 This variable can be set in your init file, like this:
  94   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  95 These supersede the values given in `default-frame-alist',
  96 for pop-up frames."
  97   :type '(repeat (cons :format "%v"
  98                        (symbol :tag "Parameter")
  99                        (sexp :tag "Value")))
 100   :group 'frames)
 101
 102 (setq pop-up-frame-function
 103       ;; Using `function' here caused some sort of problem.
 104       '(lambda ()
 105          (make-frame pop-up-frame-alist)))
 106
 107 (defcustom special-display-frame-alist
 108   '((height . 14) (width . 80) (unsplittable . t))
 109   "*Alist of frame parameters used when creating special frames.
 110 Special frames are used for buffers whose names are in
 111 `special-display-buffer-names' and for buffers whose names match
 112 one of the regular expressions in `special-display-regexps'.
 113 This variable can be set in your init file, like this:
 114   (setq special-display-frame-alist '((width . 80) (height . 20)))
 115 These supersede the values given in `default-frame-alist'."
 116   :type '(repeat (cons :format "%v"
 117                          (symbol :tag "Parameter")
 118                          (sexp :tag "Value")))
 119   :group 'frames)
 120
 121 (defun special-display-popup-frame (buffer &optional args)
 122   "Display BUFFER in its own frame, reusing an existing window if any.
 123 Return the window chosen.
 124 Currently we do not insist on selecting the window within its frame.
 125 If ARGS is an alist, use it as a list of frame parameter specs.
 126 If ARGS is a list whose car is a symbol,
 127 use (car ARGS) as a function to do the work.
 128 Pass it BUFFER as first arg, and (cdr ARGS) gives the rest of the args."
 129   (if (and args (symbolp (car args)))
 130       (apply (car args) buffer (cdr args))
 131     (let ((window (get-buffer-window buffer 0)))
 132       (or
 133        ;; If we have a window already, make it visible.
 134        (when window
 135          (let ((frame (window-frame window)))
 136            (make-frame-visible frame)
 137            (raise-frame frame)
 138            window))
 139        ;; Reuse the current window if the user requested it.
 140        (when (cdr (assq 'same-window args))
 141          (condition-case nil
 142              (progn (switch-to-buffer buffer) (selected-window))
 143            (error nil)))
 144        ;; Stay on the same frame if requested.
 145        (when (or (cdr (assq 'same-frame args)) (cdr (assq 'same-window args)))
 146          (let* ((pop-up-frames nil) (pop-up-windows t)
 147                 special-display-regexps special-display-buffer-names
 148                 (window (display-buffer buffer)))
 149            ;; Only do it if this is a new window:
 150            ;; (set-window-dedicated-p window t)
 151            window))
 152        ;; If no window yet, make one in a new frame.
 153        (let ((frame
 154               (with-current-buffer buffer
 155                 (make-frame (append args special-display-frame-alist)))))
 156          (set-window-buffer (frame-selected-window frame) buffer)
 157          (set-window-dedicated-p (frame-selected-window frame) t)
 158          (frame-selected-window frame))))))
 159
 160 (defun handle-delete-frame (event)
 161   "Handle delete-frame events from the X server."
 162   (interactive "e")
 163   (let ((frame (posn-window (event-start event)))
 164         (i 0)
 165         (tail (frame-list)))
 166     (while tail
 167       (and (frame-visible-p (car tail))
 168            (not (eq (car tail) frame))
 169           (setq i (1+ i)))
 170       (setq tail (cdr tail)))
 171     (if (> i 0)
 172         (delete-frame frame t)
 173       ;; Gildea@x.org says it is ok to ask questions before terminating.
 174       (save-buffers-kill-emacs))))
 175 \f
 176 ;;;; Arrangement of frames at startup
 177
 178 ;; 1) Load the window system startup file from the lisp library and read the
 179 ;; high-priority arguments (-q and the like).  The window system startup
 180 ;; file should create any frames specified in the window system defaults.
 181 ;;
 182 ;; 2) If no frames have been opened, we open an initial text frame.
 183 ;;
 184 ;; 3) Once the init file is done, we apply any newly set parameters
 185 ;; in initial-frame-alist to the frame.
 186
 187 ;; These are now called explicitly at the proper times,
 188 ;; since that is easier to understand.
 189 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
 190 ;; (add-hook 'before-init-hook 'frame-initialize)
 191 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
 192
 193 ;; If we create the initial frame, this is it.
 194 (defvar frame-initial-frame nil)
 195
 196 ;; Record the parameters used in frame-initialize to make the initial frame.
 197 (defvar frame-initial-frame-alist)
 198
 199 (defvar frame-initial-geometry-arguments nil)
 200
 201 ;; startup.el calls this function before loading the user's init
 202 ;; file - if there is no frame with a minibuffer open now, create
 203 ;; one to display messages while loading the init file.
 204 (defun frame-initialize ()
 205   "Create an initial frame if necessary."
 206   ;; Are we actually running under a window system at all?
 207   (if (and initial-window-system
 208            (not noninteractive)
 209            (not (eq initial-window-system 'pc)))
 210       (progn
 211         ;; Turn on special-display processing only if there's a window system.
 212         (setq special-display-function 'special-display-popup-frame)
 213
 214         ;; If there is no frame with a minibuffer besides the terminal
 215         ;; frame, then we need to create the opening frame.  Make sure
 216         ;; it has a minibuffer, but let initial-frame-alist omit the
 217         ;; minibuffer spec.
 218         (or (delq terminal-frame (minibuffer-frame-list))
 219             (progn
 220               (setq frame-initial-frame-alist
 221                     (append initial-frame-alist default-frame-alist nil))
 222               (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
 223                   (setq frame-initial-frame-alist
 224                         (cons '(horizontal-scroll-bars . t)
 225                               frame-initial-frame-alist)))
 226               (setq frame-initial-frame-alist
 227                     (cons (cons 'window-system initial-window-system)
 228                           frame-initial-frame-alist))
 229               (setq default-minibuffer-frame
 230                     (setq frame-initial-frame
 231                           (make-frame frame-initial-frame-alist)))
 232               ;; Delete any specifications for window geometry parameters
 233               ;; so that we won't reapply them in frame-notice-user-settings.
 234               ;; It would be wrong to reapply them then,
 235               ;; because that would override explicit user resizing.
 236               (setq initial-frame-alist
 237                     (frame-remove-geometry-params initial-frame-alist))))
 238         ;; Copy the environment of the Emacs process into the new frame.
 239         (set-frame-parameter frame-initial-frame 'environment
 240                              (frame-parameter terminal-frame 'environment))
 241         ;; At this point, we know that we have a frame open, so we
 242         ;; can delete the terminal frame.
 243         (delete-frame terminal-frame)
 244         (setq terminal-frame nil))))
 245
 246 (defvar frame-notice-user-settings t
 247   "Non-nil means function `frame-notice-user-settings' wasn't run yet.")
 248
 249 (declare-function tool-bar-mode "tool-bar" (&optional arg))
 250
 251 ;; startup.el calls this function after loading the user's init
 252 ;; file.  Now default-frame-alist and initial-frame-alist contain
 253 ;; information to which we must react; do what needs to be done.
 254 (defun frame-notice-user-settings ()
 255   "Act on user's init file settings of frame parameters.
 256 React to settings of `initial-frame-alist',
 257 `window-system-default-frame-alist' and `default-frame-alist'
 258 there (in decreasing order of priority)."
 259   ;; Make menu-bar-mode and default-frame-alist consistent.
 260   (when (boundp 'menu-bar-mode)
 261     (let ((default (assq 'menu-bar-lines default-frame-alist)))
 262       (if default
 263           (setq menu-bar-mode (not (eq (cdr default) 0)))
 264         (setq default-frame-alist
 265               (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
 266                     default-frame-alist)))))
 267
 268   ;; Make tool-bar-mode and default-frame-alist consistent.  Don't do
 269   ;; it in batch mode since that would leave a tool-bar-lines
 270   ;; parameter in default-frame-alist in a dumped Emacs, which is not
 271   ;; what we want.
 272   (when (and (boundp 'tool-bar-mode)
 273              (not noninteractive))
 274     (let ((default (assq 'tool-bar-lines default-frame-alist)))
 275       (if default
 276           (setq tool-bar-mode (not (eq (cdr default) 0)))
 277         ;; If Emacs was started on a tty, changing default-frame-alist
 278         ;; would disable the toolbar on X frames created later.  We
 279         ;; want to keep the default of showing a toolbar under X even
 280         ;; in this case.
 281         ;;
 282         ;; If the user explicitly called `tool-bar-mode' in .emacs,
 283         ;; then default-frame-alist is already changed anyway.
 284         (when initial-window-system
 285           (setq default-frame-alist
 286                 (cons (cons 'tool-bar-lines (if tool-bar-mode 1 0))
 287                       default-frame-alist))))))
 288
 289   ;; Creating and deleting frames may shift the selected frame around,
 290   ;; and thus the current buffer.  Protect against that.  We don't
 291   ;; want to use save-excursion here, because that may also try to set
 292   ;; the buffer of the selected window, which fails when the selected
 293   ;; window is the minibuffer.
 294   (let ((old-buffer (current-buffer))
 295         (window-system-frame-alist
 296          (cdr (assq initial-window-system
 297                     window-system-default-frame-alist))))
 298
 299     (when (and frame-notice-user-settings
 300                (null frame-initial-frame))
 301       ;; This case happens when we don't have a window system, and
 302       ;; also for MS-DOS frames.
 303       (let ((parms (frame-parameters frame-initial-frame)))
 304         ;; Don't change the frame names.
 305         (setq parms (delq (assq 'name parms) parms))
 306         ;; Can't modify the minibuffer parameter, so don't try.
 307         (setq parms (delq (assq 'minibuffer parms) parms))
 308         (modify-frame-parameters nil
 309                                  (if (null initial-window-system)
 310                                      (append initial-frame-alist
 311                                              window-system-frame-alist
 312                                              default-frame-alist
 313                                              parms
 314                                              nil)
 315                                    ;; initial-frame-alist and
 316                                    ;; default-frame-alist were already
 317                                    ;; applied in pc-win.el.
 318                                    parms))
 319         (if (null initial-window-system) ;; MS-DOS does this differently in pc-win.el
 320             (let ((newparms (frame-parameters))
 321                   (frame (selected-frame)))
 322               (tty-handle-reverse-video frame newparms)
 323               ;; If we changed the background color, we need to update
 324               ;; the background-mode parameter, and maybe some faces,
 325               ;; too.
 326               (when (assq 'background-color newparms)
 327                 (unless (or (assq 'background-mode initial-frame-alist)
 328                             (assq 'background-mode default-frame-alist))
 329                   (frame-set-background-mode frame))
 330                 (face-set-after-frame-default frame))))))
 331
 332     ;; If the initial frame is still around, apply initial-frame-alist
 333     ;; and default-frame-alist to it.
 334     (when (frame-live-p frame-initial-frame)
 335
 336       ;; When tool-bar has been switched off, correct the frame size
 337       ;; by the lines added in x-create-frame for the tool-bar and
 338       ;; switch `tool-bar-mode' off.
 339       (when (display-graphic-p)
 340         (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 341                                   (assq 'tool-bar-lines window-system-frame-alist)
 342                                   (assq 'tool-bar-lines default-frame-alist))))
 343           (when (and tool-bar-originally-present
 344                      (or (null tool-bar-lines)
 345                          (null (cdr tool-bar-lines))
 346                          (eq 0 (cdr tool-bar-lines))))
 347             (let* ((char-height (frame-char-height frame-initial-frame))
 348                    (image-height tool-bar-images-pixel-height)
 349                    (margin (cond ((and (consp tool-bar-button-margin)
 350                                        (integerp (cdr tool-bar-button-margin))
 351                                        (> tool-bar-button-margin 0))
 352                                   (cdr tool-bar-button-margin))
 353                                  ((and (integerp tool-bar-button-margin)
 354                                        (> tool-bar-button-margin 0))
 355                                   tool-bar-button-margin)
 356                                  (t 0)))
 357                    (relief (if (and (integerp tool-bar-button-relief)
 358                                     (> tool-bar-button-relief 0))
 359                                tool-bar-button-relief 3))
 360                    (lines (/ (+ image-height
 361                                 (* 2 margin)
 362                                 (* 2 relief)
 363                                 (1- char-height))
 364                              char-height))
 365                    (height (frame-parameter frame-initial-frame 'height))
 366                    (newparms (list (cons 'height (- height lines))))
 367                    (initial-top (cdr (assq 'top
 368                                            frame-initial-geometry-arguments)))
 369                    (top (frame-parameter frame-initial-frame 'top)))
 370               (when (and (consp initial-top) (eq '- (car initial-top)))
 371                 (let ((adjusted-top
 372                        (cond ((and (consp top)
 373                                    (eq '+ (car top)))
 374                               (list '+
 375                                     (+ (cadr top)
 376                                        (* lines char-height))))
 377                              ((and (consp top)
 378                                    (eq '- (car top)))
 379                               (list '-
 380                                     (- (cadr top)
 381                                        (* lines char-height))))
 382                              (t (+ top (* lines char-height))))))
 383                   (setq newparms
 384                         (append newparms
 385                                 `((top . ,adjusted-top))
 386                                 nil))))
 387               (modify-frame-parameters frame-initial-frame newparms)
 388               (tool-bar-mode -1)))))
 389
 390       ;; The initial frame we create above always has a minibuffer.
 391       ;; If the user wants to remove it, or make it a minibuffer-only
 392       ;; frame, then we'll have to delete the current frame and make a
 393       ;; new one; you can't remove or add a root window to/from an
 394       ;; existing frame.
 395       ;;
 396       ;; NOTE: default-frame-alist was nil when we created the
 397       ;; existing frame.  We need to explicitly include
 398       ;; default-frame-alist in the parameters of the screen we
 399       ;; create here, so that its new value, gleaned from the user's
 400       ;; .emacs file, will be applied to the existing screen.
 401       (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 402                             (assq 'minibuffer window-system-frame-alist)
 403                             (assq 'minibuffer default-frame-alist)
 404                             '(minibuffer . t)))
 405                    t))
 406           ;; Create the new frame.
 407           (let (parms new)
 408             ;; If the frame isn't visible yet, wait till it is.
 409             ;; If the user has to position the window,
 410             ;; Emacs doesn't know its real position until
 411             ;; the frame is seen to be visible.
 412             (while (not (cdr (assq 'visibility
 413                                    (frame-parameters frame-initial-frame))))
 414               (sleep-for 1))
 415             (setq parms (frame-parameters frame-initial-frame))
 416
 417             ;; Get rid of `name' unless it was specified explicitly before.
 418             (or (assq 'name frame-initial-frame-alist)
 419                 (setq parms (delq (assq 'name parms) parms)))
 420             ;; An explicit parent-id is a request to XEmbed the frame.
 421             (or (assq 'parent-id frame-initial-frame-alist)
 422                 (setq parms (delq (assq 'parent-id parms) parms)))
 423
 424             (setq parms (append initial-frame-alist
 425                                 window-system-frame-alist
 426                                 default-frame-alist
 427                                 parms
 428                                 nil))
 429
 430             ;; Get rid of `reverse', because that was handled
 431             ;; when we first made the frame.
 432             (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))
 433
 434             (if (assq 'height frame-initial-geometry-arguments)
 435                 (setq parms (assq-delete-all 'height parms)))
 436             (if (assq 'width frame-initial-geometry-arguments)
 437                 (setq parms (assq-delete-all 'width parms)))
 438             (if (assq 'left frame-initial-geometry-arguments)
 439                 (setq parms (assq-delete-all 'left parms)))
 440             (if (assq 'top frame-initial-geometry-arguments)
 441                 (setq parms (assq-delete-all 'top parms)))
 442             (setq new
 443                   (make-frame
 444                    ;; Use the geometry args that created the existing
 445                    ;; frame, rather than the parms we get for it.
 446                    (append frame-initial-geometry-arguments
 447                            '((user-size . t) (user-position . t))
 448                            parms)))
 449             ;; The initial frame, which we are about to delete, may be
 450             ;; the only frame with a minibuffer.  If it is, create a
 451             ;; new one.
 452             (or (delq frame-initial-frame (minibuffer-frame-list))
 453                 (make-initial-minibuffer-frame nil))
 454
 455             ;; If the initial frame is serving as a surrogate
 456             ;; minibuffer frame for any frames, we need to wean them
 457             ;; onto a new frame.  The default-minibuffer-frame
 458             ;; variable must be handled similarly.
 459             (let ((users-of-initial
 460                    (filtered-frame-list
 461                     (lambda (frame)
 462                       (and (not (eq frame frame-initial-frame))
 463                            (eq (window-frame
 464                                 (minibuffer-window frame))
 465                                frame-initial-frame))))))
 466               (if (or users-of-initial
 467                       (eq default-minibuffer-frame frame-initial-frame))
 468
 469                   ;; Choose an appropriate frame.  Prefer frames which
 470                   ;; are only minibuffers.
 471                   (let* ((new-surrogate
 472                           (car
 473                            (or (filtered-frame-list
 474                                 (lambda (frame)
 475                                   (eq (cdr (assq 'minibuffer
 476                                                  (frame-parameters frame)))
 477                                       'only)))
 478                                (minibuffer-frame-list))))
 479                          (new-minibuffer (minibuffer-window new-surrogate)))
 480
 481                     (if (eq default-minibuffer-frame frame-initial-frame)
 482                         (setq default-minibuffer-frame new-surrogate))
 483
 484                     ;; Wean the frames using frame-initial-frame as
 485                     ;; their minibuffer frame.
 486                     (dolist (frame users-of-initial)
 487                       (modify-frame-parameters
 488                        frame (list (cons 'minibuffer new-minibuffer)))))))
 489
 490             ;; Redirect events enqueued at this frame to the new frame.
 491             ;; Is this a good idea?
 492             (redirect-frame-focus frame-initial-frame new)
 493
 494             ;; Finally, get rid of the old frame.
 495             (delete-frame frame-initial-frame t))
 496
 497         ;; Otherwise, we don't need all that rigamarole; just apply
 498         ;; the new parameters.
 499         (let (newparms allparms tail)
 500           (setq allparms (append initial-frame-alist
 501                                  window-system-frame-alist
 502                                  default-frame-alist nil))
 503           (if (assq 'height frame-initial-geometry-arguments)
 504               (setq allparms (assq-delete-all 'height allparms)))
 505           (if (assq 'width frame-initial-geometry-arguments)
 506               (setq allparms (assq-delete-all 'width allparms)))
 507           (if (assq 'left frame-initial-geometry-arguments)
 508               (setq allparms (assq-delete-all 'left allparms)))
 509           (if (assq 'top frame-initial-geometry-arguments)
 510               (setq allparms (assq-delete-all 'top allparms)))
 511           (setq tail allparms)
 512           ;; Find just the parms that have changed since we first
 513           ;; made this frame.  Those are the ones actually set by
 514           ;; the init file.  For those parms whose values we already knew
 515           ;; (such as those spec'd by command line options)
 516           ;; it is undesirable to specify the parm again
 517           ;; once the user has seen the frame and been able to alter it
 518           ;; manually.
 519           (while tail
 520             (let (newval oldval)
 521               (setq oldval (assq (car (car tail))
 522                                  frame-initial-frame-alist))
 523               (setq newval (cdr (assq (car (car tail)) allparms)))
 524               (or (and oldval (eq (cdr oldval) newval))
 525                   (setq newparms
 526                         (cons (cons (car (car tail)) newval) newparms))))
 527             (setq tail (cdr tail)))
 528           (setq newparms (nreverse newparms))
 529           (modify-frame-parameters frame-initial-frame
 530                                    newparms)
 531           ;; If we changed the background color,
 532           ;; we need to update the background-mode parameter
 533           ;; and maybe some faces too.
 534           (when (assq 'background-color newparms)
 535             (unless (assq 'background-mode newparms)
 536               (frame-set-background-mode frame-initial-frame))
 537             (face-set-after-frame-default frame-initial-frame)))))
 538
 539     ;; Restore the original buffer.
 540     (set-buffer old-buffer)
 541
 542     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 543     ;; Make sure frame-notice-user-settings does nothing if called twice.
 544     (setq frame-notice-user-settings nil)
 545     (setq frame-initial-frame nil)))
 546
 547 (defun make-initial-minibuffer-frame (display)
 548   (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
 549     (if display
 550         (make-frame-on-display display parms)
 551       (make-frame parms))))
 552
 553 ;;;; Creation of additional frames, and other frame miscellanea
 554
 555 (defun modify-all-frames-parameters (alist)
 556   "Modify all current and future frames' parameters according to ALIST.
 557 This changes `default-frame-alist' and possibly `initial-frame-alist'.
 558 Furthermore, this function removes all parameters in ALIST from
 559 `window-system-default-frame-alist'.
 560 See help of `modify-frame-parameters' for more information."
 561   (dolist (frame (frame-list))
 562     (modify-frame-parameters frame alist))
 563
 564   (dolist (pair alist) ;; conses to add/replace
 565     ;; initial-frame-alist needs setting only when
 566     ;; frame-notice-user-settings is true.
 567     (and frame-notice-user-settings
 568          (setq initial-frame-alist
 569                (assq-delete-all (car pair) initial-frame-alist)))
 570     (setq default-frame-alist
 571           (assq-delete-all (car pair) default-frame-alist))
 572     ;; Remove any similar settings from the window-system specific
 573     ;; parameters---they would override default-frame-alist.
 574     (dolist (w window-system-default-frame-alist)
 575       (setcdr w (assq-delete-all (car pair) (cdr w)))))
 576
 577   (and frame-notice-user-settings
 578        (setq initial-frame-alist (append initial-frame-alist alist)))
 579   (setq default-frame-alist (append default-frame-alist alist)))
 580
 581 (defun get-other-frame ()
 582   "Return some frame other than the current frame.
 583 Create one if necessary.  Note that the minibuffer frame, if separate,
 584 is not considered (see `next-frame')."
 585   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 586                (make-frame)
 587              (next-frame (selected-frame)))))
 588     s))
 589
 590 (defun next-multiframe-window ()
 591   "Select the next window, regardless of which frame it is on."
 592   (interactive)
 593   (select-window (next-window (selected-window)
 594                               (> (minibuffer-depth) 0)
 595                               0))
 596   (select-frame-set-input-focus (selected-frame)))
 597
 598 (defun previous-multiframe-window ()
 599   "Select the previous window, regardless of which frame it is on."
 600   (interactive)
 601   (select-window (previous-window (selected-window)
 602                                   (> (minibuffer-depth) 0)
 603                                   0))
 604   (select-frame-set-input-focus (selected-frame)))
 605
 606 (declare-function x-initialize-window-system "term/x-win" ())
 607 (defvar x-display-name)
 608
 609 (defun make-frame-on-display (display &optional parameters)
 610   "Make a frame on X display DISPLAY.
 611 The optional second argument PARAMETERS specifies additional frame parameters."
 612   (interactive "sMake frame on display: ")
 613   (or (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
 614       (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
 615   (when (and (boundp 'x-initialized) (not x-initialized))
 616     (setq x-display-name display)
 617     (x-initialize-window-system))
 618   (make-frame `((window-system . x) (display . ,display) . ,parameters)))
 619
 620 (defun make-frame-on-tty (tty type &optional parameters)
 621   "Make a frame on terminal device TTY.
 622 TTY should be the file name of the tty device to use.  TYPE
 623 should be the terminal type string of TTY, for example \"xterm\"
 624 or \"vt100\".  The optional third argument PARAMETERS specifies
 625 additional frame parameters."
 626   (interactive "fOpen frame on tty device: \nsTerminal type of %s: ")
 627   (unless tty
 628     (error "Invalid terminal device"))
 629   (unless type
 630     (error "Invalid terminal type"))
 631   (make-frame `((window-system . nil) (tty . ,tty) (tty-type . ,type) . ,parameters)))
 632
 633 (declare-function x-close-connection "xfns.c" (terminal))
 634
 635 (defun close-display-connection (display)
 636   "Close the connection to a display, deleting all its associated frames.
 637 For DISPLAY, specify either a frame or a display name (a string).
 638 If DISPLAY is nil, that stands for the selected frame's display."
 639   (interactive
 640    (list
 641     (let* ((default (frame-parameter nil 'display))
 642            (display (completing-read
 643                      (format "Close display (default %s): " default)
 644                      (delete-dups
 645                       (mapcar (lambda (frame)
 646                                 (frame-parameter frame 'display))
 647                               (frame-list)))
 648                      nil t nil nil
 649                      default)))
 650       (if (zerop (length display)) default display))))
 651   (let ((frames (delq nil
 652                       (mapcar (lambda (frame)
 653                                 (if (equal display
 654                                            (frame-parameter frame 'display))
 655                                     frame))
 656                               (frame-list)))))
 657     (if (and (consp frames)
 658              (not (y-or-n-p (if (cdr frames)
 659                                 (format "Delete %s frames? " (length frames))
 660                               (format "Delete %s ? " (car frames))))))
 661         (error "Abort!")
 662       (mapc 'delete-frame frames)
 663       (x-close-connection display))))
 664
 665 (defun make-frame-command ()
 666   "Make a new frame, and select it if the terminal displays only one frame."
 667   (interactive)
 668   (if (and window-system (not (eq window-system 'pc)))
 669       (make-frame)
 670     (select-frame (make-frame))))
 671
 672 (defvar before-make-frame-hook nil
 673   "Functions to run before a frame is created.")
 674
 675 (defvar after-make-frame-functions nil
 676   "Functions to run after a frame is created.
 677 The functions are run with one arg, the newly created frame.")
 678
 679 (defvar after-setting-font-hook nil
 680   "Functions to run after a frame's font has been changed.")
 681
 682 ;; Alias, kept temporarily.
 683 (define-obsolete-function-alias 'new-frame 'make-frame "22.1")
 684
 685 (defvar frame-inherited-parameters '()
 686   ;; FIXME: Shouldn't we add `font' here as well?
 687   "Parameters `make-frame' copies from the `selected-frame' to the new frame.")
 688
 689 (defun make-frame (&optional parameters)
 690   "Return a newly created frame displaying the current buffer.
 691 Optional argument PARAMETERS is an alist of parameters for the new frame.
 692 Each element of PARAMETERS should have the form (NAME . VALUE), for example:
 693
 694  (name . STRING)        The frame should be named STRING.
 695
 696  (width . NUMBER)       The frame should be NUMBER characters in width.
 697  (height . NUMBER)      The frame should be NUMBER text lines high.
 698
 699 You cannot specify either `width' or `height', you must use neither or both.
 700
 701  (minibuffer . t)       The frame should have a minibuffer.
 702  (minibuffer . nil)     The frame should have no minibuffer.
 703  (minibuffer . only)    The frame should contain only a minibuffer.
 704  (minibuffer . WINDOW)  The frame should use WINDOW as its minibuffer window.
 705
 706  (window-system . nil)  The frame should be displayed on a terminal device.
 707  (window-system . x)    The frame should be displayed in an X window.
 708
 709  (terminal . ID)          The frame should use the terminal identified by ID.
 710
 711 Before the frame is created (via `frame-creation-function-alist'), functions on the
 712 hook `before-make-frame-hook' are run.  After the frame is created, functions
 713 on `after-make-frame-functions' are run with one arg, the newly created frame.
 714
 715 This function itself does not make the new frame the selected frame.
 716 The previously selected frame remains selected.  However, the
 717 window system may select the new frame for its own reasons, for
 718 instance if the frame appears under the mouse pointer and your
 719 setup is for focus to follow the pointer."
 720   (interactive)
 721   (let* ((w (cond
 722              ((assq 'terminal parameters)
 723               (let ((type (terminal-live-p (cdr (assq 'terminal parameters)))))
 724                 (cond
 725                  ((eq type t) nil)
 726                  ((eq type nil) (error "Terminal %s does not exist"
 727                                        (cdr (assq 'terminal parameters))))
 728                  (t type))))
 729              ((assq 'window-system parameters)
 730               (cdr (assq 'window-system parameters)))
 731              (t window-system)))
 732          (frame-creation-function (cdr (assq w frame-creation-function-alist)))
 733          (oldframe (selected-frame))
 734          frame)
 735     (unless frame-creation-function
 736       (error "Don't know how to create a frame on window system %s" w))
 737     (run-hooks 'before-make-frame-hook)
 738     (setq frame
 739           (funcall frame-creation-function
 740                    (append parameters
 741                            (cdr (assq w window-system-default-frame-alist)))))
 742     (normal-erase-is-backspace-setup-frame frame)
 743     ;; Inherit the original frame's parameters.
 744     (dolist (param frame-inherited-parameters)
 745       (unless (assq param parameters)   ;Overridden by explicit parameters.
 746         (let ((val (frame-parameter oldframe param)))
 747           (when val (set-frame-parameter frame param val)))))
 748     (run-hook-with-args 'after-make-frame-functions frame)
 749     frame))
 750
 751 (defun filtered-frame-list (predicate)
 752   "Return a list of all live frames which satisfy PREDICATE."
 753   (let* ((frames (frame-list))
 754          (list frames))
 755     (while (consp frames)
 756       (unless (funcall predicate (car frames))
 757         (setcar frames nil))
 758       (setq frames (cdr frames)))
 759     (delq nil list)))
 760
 761 (defun minibuffer-frame-list ()
 762   "Return a list of all frames with their own minibuffers."
 763   (filtered-frame-list
 764    (lambda (frame)
 765      (eq frame (window-frame (minibuffer-window frame))))))
 766
 767 ;; Used to be called `terminal-id' in termdev.el.
 768 (defun get-device-terminal (device)
 769   "Return the terminal corresponding to DEVICE.
 770 DEVICE can be a terminal, a frame, nil (meaning the selected frame's terminal),
 771 the name of an X display device (HOST.SERVER.SCREEN) or a tty device file."
 772   (cond
 773    ((or (null device) (framep device))
 774     (frame-terminal device))
 775    ((stringp device)
 776     (let ((f (car (filtered-frame-list
 777                    (lambda (frame)
 778                      (or (equal (frame-parameter frame 'display) device)
 779                          (equal (frame-parameter frame 'tty) device)))))))
 780       (or f (error "Display %s does not exist" device))
 781       (frame-terminal f)))
 782    ((terminal-live-p device) device)
 783    (t
 784     (error "Invalid argument %s in `get-device-terminal'" device))))
 785
 786 (defun frames-on-display-list (&optional device)
 787   "Return a list of all frames on DEVICE.
 788
 789 DEVICE should be a terminal, a frame,
 790 or a name of an X display or tty (a string of the form
 791 HOST:SERVER.SCREEN).
 792
 793 If DEVICE is omitted or nil, it defaults to the selected
 794 frame's terminal device."
 795   (let* ((terminal (get-device-terminal device))
 796          (func #'(lambda (frame)
 797                    (eq (frame-terminal frame) terminal))))
 798     (filtered-frame-list func)))
 799
 800 (defun framep-on-display (&optional terminal)
 801   "Return the type of frames on TERMINAL.
 802 TERMINAL may be a terminal id, a display name or a frame.  If it
 803 is a frame, its type is returned.  If TERMINAL is omitted or nil,
 804 it defaults to the selected frame's terminal device.  All frames
 805 on a given display are of the same type."
 806   (or (terminal-live-p terminal)
 807       (framep terminal)
 808       (framep (car (frames-on-display-list terminal)))))
 809
 810 (defun frame-remove-geometry-params (param-list)
 811   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 812 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 813 `height', `user-size' and `user-position' parameters.
 814 Emacs uses this to avoid overriding explicit moves and resizings from
 815 the user during startup."
 816   (setq param-list (cons nil param-list))
 817   (let ((tail param-list))
 818     (while (consp (cdr tail))
 819       (if (and (consp (car (cdr tail)))
 820                (memq (car (car (cdr tail)))
 821                      '(height width top left user-position user-size)))
 822           (progn
 823             (setq frame-initial-geometry-arguments
 824                   (cons (car (cdr tail)) frame-initial-geometry-arguments))
 825             (setcdr tail (cdr (cdr tail))))
 826         (setq tail (cdr tail)))))
 827   (setq frame-initial-geometry-arguments
 828         (nreverse frame-initial-geometry-arguments))
 829   (cdr param-list))
 830
 831 (declare-function x-focus-frame "xfns.c" (frame))
 832
 833 (defun select-frame-set-input-focus (frame)
 834   "Select FRAME, raise it, and set input focus, if possible."
 835     (select-frame frame)
 836     (raise-frame frame)
 837     ;; Ensure, if possible, that frame gets input focus.
 838     (when (memq (window-system frame) '(x mac w32))
 839       (x-focus-frame frame))
 840     (when focus-follows-mouse
 841       (set-mouse-position (selected-frame) (1- (frame-width)) 0)))
 842
 843 (defun other-frame (arg)
 844   "Select the ARGth different visible frame on current display, and raise it.
 845 All frames are arranged in a cyclic order.
 846 This command selects the frame ARG steps away in that order.
 847 A negative ARG moves in the opposite order.
 848
 849 To make this command work properly, you must tell Emacs
 850 how the system (or the window manager) generally handles
 851 focus-switching between windows.  If moving the mouse onto a window
 852 selects it (gives it focus), set `focus-follows-mouse' to t.
 853 Otherwise, that variable should be nil."
 854   (interactive "p")
 855   (let ((frame (selected-frame)))
 856     (while (> arg 0)
 857       (setq frame (next-frame frame))
 858       (while (not (eq (frame-visible-p frame) t))
 859         (setq frame (next-frame frame)))
 860       (setq arg (1- arg)))
 861     (while (< arg 0)
 862       (setq frame (previous-frame frame))
 863       (while (not (eq (frame-visible-p frame) t))
 864         (setq frame (previous-frame frame)))
 865       (setq arg (1+ arg)))
 866     (select-frame-set-input-focus frame)))
 867
 868 (defun iconify-or-deiconify-frame ()
 869   "Iconify the selected frame, or deiconify if it's currently an icon."
 870   (interactive)
 871   (if (eq (cdr (assq 'visibility (frame-parameters))) t)
 872       (iconify-frame)
 873     (make-frame-visible)))
 874
 875 (defun suspend-frame ()
 876   "Do whatever is right to suspend the current frame.
 877 Calls `suspend-emacs' if invoked from the controlling tty device,
 878 `suspend-tty' from a secondary tty device, and
 879 `iconify-or-deiconify-frame' from an X frame."
 880   (interactive)
 881   (let ((type (framep (selected-frame))))
 882     (cond
 883      ((memq type '(x w32)) (iconify-or-deiconify-frame))
 884      ((eq type t)
 885       (if (controlling-tty-p)
 886           (suspend-emacs)
 887         (suspend-tty)))
 888      (t (suspend-emacs)))))
 889
 890 (defun make-frame-names-alist ()
 891   (let* ((current-frame (selected-frame))
 892          (falist
 893           (cons
 894            (cons (frame-parameter current-frame 'name) current-frame) nil))
 895          (frame (next-frame nil t)))
 896     (while (not (eq frame current-frame))
 897       (progn
 898         (setq falist (cons (cons (frame-parameter frame 'name) frame) falist))
 899         (setq frame (next-frame frame t))))
 900     falist))
 901
 902 (defvar frame-name-history nil)
 903 (defun select-frame-by-name (name)
 904   "Select the frame on the current terminal whose name is NAME and raise it.
 905 If there is no frame by that name, signal an error."
 906   (interactive
 907    (let* ((frame-names-alist (make-frame-names-alist))
 908            (default (car (car frame-names-alist)))
 909            (input (completing-read
 910                    (format "Select Frame (default %s): " default)
 911                    frame-names-alist nil t nil 'frame-name-history)))
 912      (if (= (length input) 0)
 913          (list default)
 914        (list input))))
 915   (let* ((frame-names-alist (make-frame-names-alist))
 916          (frame (cdr (assoc name frame-names-alist))))
 917     (or frame
 918         (error "There is no frame named `%s'" name))
 919     (make-frame-visible frame)
 920     (raise-frame frame)
 921     (select-frame frame)
 922     ;; Ensure, if possible, that frame gets input focus.
 923     (cond ((memq (window-system frame) '(x w32))
 924            (x-focus-frame frame)))
 925     (when focus-follows-mouse
 926       (set-mouse-position frame (1- (frame-width frame)) 0))))
 927 \f
 928 ;;;; Frame configurations
 929
 930 (defun current-frame-configuration ()
 931   "Return a list describing the positions and states of all frames.
 932 Its car is `frame-configuration'.
 933 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 934 where
 935   FRAME is a frame object,
 936   ALIST is an association list specifying some of FRAME's parameters, and
 937   WINDOW-CONFIG is a window configuration object for FRAME."
 938   (cons 'frame-configuration
 939         (mapcar (lambda (frame)
 940                   (list frame
 941                         (frame-parameters frame)
 942                         (current-window-configuration frame)))
 943                 (frame-list))))
 944
 945 (defun set-frame-configuration (configuration &optional nodelete)
 946   "Restore the frames to the state described by CONFIGURATION.
 947 Each frame listed in CONFIGURATION has its position, size, window
 948 configuration, and other parameters set as specified in CONFIGURATION.
 949 However, this function does not restore deleted frames.
 950
 951 Ordinarily, this function deletes all existing frames not
 952 listed in CONFIGURATION.  But if optional second argument NODELETE
 953 is given and non-nil, the unwanted frames are iconified instead."
 954   (or (frame-configuration-p configuration)
 955       (signal 'wrong-type-argument
 956               (list 'frame-configuration-p configuration)))
 957   (let ((config-alist (cdr configuration))
 958         frames-to-delete)
 959     (dolist (frame (frame-list))
 960       (let ((parameters (assq frame config-alist)))
 961         (if parameters
 962             (progn
 963               (modify-frame-parameters
 964                frame
 965                ;; Since we can't set a frame's minibuffer status,
 966                ;; we might as well omit the parameter altogether.
 967                (let* ((parms (nth 1 parameters))
 968                       (mini (assq 'minibuffer parms))
 969                       (name (assq 'name parms))
 970                       (explicit-name (cdr (assq 'explicit-name parms))))
 971                  (when mini (setq parms (delq mini parms)))
 972                  ;; Leave name in iff it was set explicitly.
 973                  ;; This should fix the behavior reported in
 974                  ;; http://lists.gnu.org/archive/html/emacs-devel/2007-08/msg01632.html
 975                  (when (and name (not explicit-name))
 976                    (setq parms (delq name parms)))
 977                  parms))
 978               (set-window-configuration (nth 2 parameters)))
 979           (setq frames-to-delete (cons frame frames-to-delete)))))
 980     (mapc (if nodelete
 981               ;; Note: making frames invisible here was tried
 982               ;; but led to some strange behavior--each time the frame
 983               ;; was made visible again, the window manager asked afresh
 984               ;; for where to put it.
 985               'iconify-frame
 986             'delete-frame)
 987           frames-to-delete)))
 988 \f
 989 ;;;; Convenience functions for accessing and interactively changing
 990 ;;;; frame parameters.
 991
 992 (defun frame-height (&optional frame)
 993   "Return number of lines available for display on FRAME.
 994 If FRAME is omitted, describe the currently selected frame."
 995   (cdr (assq 'height (frame-parameters frame))))
 996
 997 (defun frame-width (&optional frame)
 998   "Return number of columns available for display on FRAME.
 999 If FRAME is omitted, describe the currently selected frame."
1000   (cdr (assq 'width (frame-parameters frame))))
1001
1002 (declare-function x-list-fonts "xfaces.c"
1003                   (pattern &optional face frame maximum width))
1004
1005 (defalias 'set-default-font 'set-frame-font)
1006 (defun set-frame-font (font-name &optional keep-size)
1007   "Set the font of the selected frame to FONT-NAME.
1008 When called interactively, prompt for the name of the font to use.
1009 To get the frame's current default font, use `frame-parameters'.
1010
1011 The default behavior is to keep the numbers of lines and columns in
1012 the frame, thus may change its pixel size.  If optional KEEP-SIZE is
1013 non-nil (interactively, prefix argument) the current frame size (in
1014 pixels) is kept by adjusting the numbers of the lines and columns."
1015   (interactive
1016    (let* ((completion-ignore-case t)
1017           (font (completing-read "Font name: "
1018                                  ;; x-list-fonts will fail with an error
1019                                  ;; if this frame doesn't support fonts.
1020                                  (x-list-fonts "*" nil (selected-frame))
1021                                  nil nil nil nil
1022                                  (frame-parameter nil 'font))))
1023      (list font current-prefix-arg)))
1024   (let (fht fwd)
1025     (if keep-size
1026         (setq fht (* (frame-parameter nil 'height) (frame-char-height))
1027               fwd (* (frame-parameter nil 'width)  (frame-char-width))))
1028     (modify-frame-parameters (selected-frame)
1029                              (list (cons 'font font-name)))
1030     (if keep-size
1031         (modify-frame-parameters
1032          (selected-frame)
1033          (list (cons 'height (round fht (frame-char-height)))
1034                (cons 'width (round fwd (frame-char-width)))))))
1035   (run-hooks 'after-setting-font-hook 'after-setting-font-hooks))
1036
1037 (defun set-frame-parameter (frame parameter value)
1038   "Set frame parameter PARAMETER to VALUE on FRAME.
1039 If FRAME is nil, it defaults to the selected frame.
1040 See `modify-frame-parameters'."
1041   (modify-frame-parameters frame (list (cons parameter value))))
1042
1043 (defun set-background-color (color-name)
1044   "Set the background color of the selected frame to COLOR-NAME.
1045 When called interactively, prompt for the name of the color to use.
1046 To get the frame's current background color, use `frame-parameters'."
1047   (interactive (list (facemenu-read-color "Background color: ")))
1048   (modify-frame-parameters (selected-frame)
1049                            (list (cons 'background-color color-name)))
1050   (or window-system
1051       (face-set-after-frame-default (selected-frame))))
1052
1053 (defun set-foreground-color (color-name)
1054   "Set the foreground color of the selected frame to COLOR-NAME.
1055 When called interactively, prompt for the name of the color to use.
1056 To get the frame's current foreground color, use `frame-parameters'."
1057   (interactive (list (facemenu-read-color "Foreground color: ")))
1058   (modify-frame-parameters (selected-frame)
1059                            (list (cons 'foreground-color color-name)))
1060   (or window-system
1061       (face-set-after-frame-default (selected-frame))))
1062
1063 (defun set-cursor-color (color-name)
1064   "Set the text cursor color of the selected frame to COLOR-NAME.
1065 When called interactively, prompt for the name of the color to use.
1066 To get the frame's current cursor color, use `frame-parameters'."
1067   (interactive (list (facemenu-read-color "Cursor color: ")))
1068   (modify-frame-parameters (selected-frame)
1069                            (list (cons 'cursor-color color-name))))
1070
1071 (defun set-mouse-color (color-name)
1072   "Set the color of the mouse pointer of the selected frame to COLOR-NAME.
1073 When called interactively, prompt for the name of the color to use.
1074 To get the frame's current mouse color, use `frame-parameters'."
1075   (interactive (list (facemenu-read-color "Mouse color: ")))
1076   (modify-frame-parameters (selected-frame)
1077                            (list (cons 'mouse-color
1078                                        (or color-name
1079                                            (cdr (assq 'mouse-color
1080                                                       (frame-parameters))))))))
1081
1082 (defun set-border-color (color-name)
1083   "Set the color of the border of the selected frame to COLOR-NAME.
1084 When called interactively, prompt for the name of the color to use.
1085 To get the frame's current border color, use `frame-parameters'."
1086   (interactive (list (facemenu-read-color "Border color: ")))
1087   (modify-frame-parameters (selected-frame)
1088                            (list (cons 'border-color color-name))))
1089
1090 (defun auto-raise-mode (arg)
1091   "Toggle whether or not the selected frame should auto-raise.
1092 With arg, turn auto-raise mode on if and only if arg is positive.
1093 Note that this controls Emacs's own auto-raise feature.
1094 Some window managers allow you to enable auto-raise for certain windows.
1095 You can use that for Emacs windows if you wish, but if you do,
1096 that is beyond the control of Emacs and this command has no effect on it."
1097   (interactive "P")
1098   (if (null arg)
1099       (setq arg
1100             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
1101                 -1 1)))
1102   (if (> arg 0)
1103       (raise-frame (selected-frame)))
1104   (modify-frame-parameters (selected-frame)
1105                            (list (cons 'auto-raise (> arg 0)))))
1106
1107 (defun auto-lower-mode (arg)
1108   "Toggle whether or not the selected frame should auto-lower.
1109 With arg, turn auto-lower mode on if and only if arg is positive.
1110 Note that this controls Emacs's own auto-lower feature.
1111 Some window managers allow you to enable auto-lower for certain windows.
1112 You can use that for Emacs windows if you wish, but if you do,
1113 that is beyond the control of Emacs and this command has no effect on it."
1114   (interactive "P")
1115   (if (null arg)
1116       (setq arg
1117             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
1118                 -1 1)))
1119   (modify-frame-parameters (selected-frame)
1120                            (list (cons 'auto-lower (> arg 0)))))
1121 (defun set-frame-name (name)
1122   "Set the name of the selected frame to NAME.
1123 When called interactively, prompt for the name of the frame.
1124 The frame name is displayed on the modeline if the terminal displays only
1125 one frame, otherwise the name is displayed on the frame's caption bar."
1126   (interactive "sFrame name: ")
1127   (modify-frame-parameters (selected-frame)
1128                            (list (cons 'name name))))
1129
1130 (defun frame-current-scroll-bars (&optional frame)
1131   "Return the current scroll-bar settings in frame FRAME.
1132 Value is a cons (VERTICAL . HORIZ0NTAL) where VERTICAL specifies the
1133 current location of the vertical scroll-bars (left, right, or nil),
1134 and HORIZONTAL specifies the current location of the horizontal scroll
1135 bars (top, bottom, or nil)."
1136   (let ((vert (frame-parameter frame 'vertical-scroll-bars))
1137         (hor nil))
1138     (unless (memq vert '(left right nil))
1139       (setq vert default-frame-scroll-bars))
1140     (cons vert hor)))
1141 \f
1142 ;;;; Frame/display capabilities.
1143 (defun selected-terminal ()
1144   "Return the terminal that is now selected."
1145   (frame-terminal (selected-frame)))
1146
1147 (declare-function msdos-mouse-p "dosfns.c")
1148
1149 (defun display-mouse-p (&optional display)
1150   "Return non-nil if DISPLAY has a mouse available.
1151 DISPLAY can be a display name, a frame, or nil (meaning the selected
1152 frame's display)."
1153   (let ((frame-type (framep-on-display display)))
1154     (cond
1155      ((eq frame-type 'pc)
1156       (msdos-mouse-p))
1157      ((eq system-type 'windows-nt)
1158       (with-no-warnings
1159        (> w32-num-mouse-buttons 0)))
1160      ((memq frame-type '(x mac))
1161       t)    ;; We assume X and Mac *always* have a pointing device
1162      (t
1163       (or (and (featurep 'xt-mouse)
1164                xterm-mouse-mode)
1165           ;; t-mouse is distributed with the GPM package.  It doesn't have
1166           ;; a toggle.
1167           (featurep 't-mouse))))))
1168
1169 (defun display-popup-menus-p (&optional display)
1170   "Return non-nil if popup menus are supported on DISPLAY.
1171 DISPLAY can be a display name, a frame, or nil (meaning the selected
1172 frame's display).
1173 Support for popup menus requires that the mouse be available."
1174   (and
1175    (let ((frame-type (framep-on-display display)))
1176      (memq frame-type '(x w32 pc mac)))
1177    (display-mouse-p display)))
1178
1179 (defun display-graphic-p (&optional display)
1180   "Return non-nil if DISPLAY is a graphic display.
1181 Graphical displays are those which are capable of displaying several
1182 frames and several different fonts at once.  This is true for displays
1183 that use a window system such as X, and false for text-only terminals.
1184 DISPLAY can be a display name, a frame, or nil (meaning the selected
1185 frame's display)."
1186   (not (null (memq (framep-on-display display) '(x w32 mac)))))
1187
1188 (defun display-images-p (&optional display)
1189   "Return non-nil if DISPLAY can display images.
1190
1191 DISPLAY can be a display name, a frame, or nil (meaning the selected
1192 frame's display)."
1193   (and (display-graphic-p display)
1194        (fboundp 'image-mask-p)
1195        (fboundp 'image-size)))
1196
1197 (defalias 'display-multi-frame-p 'display-graphic-p)
1198 (defalias 'display-multi-font-p 'display-graphic-p)
1199
1200 (defun display-selections-p (&optional display)
1201   "Return non-nil if DISPLAY supports selections.
1202 A selection is a way to transfer text or other data between programs
1203 via special system buffers called `selection' or `cut buffer' or
1204 `clipboard'.
1205 DISPLAY can be a display name, a frame, or nil (meaning the selected
1206 frame's display)."
1207   (let ((frame-type (framep-on-display display)))
1208     (cond
1209      ((eq frame-type 'pc)
1210       ;; MS-DOG frames support selections when Emacs runs inside
1211       ;; the Windows' DOS Box.
1212       (with-no-warnings
1213        (not (null dos-windows-version))))
1214      ((memq frame-type '(x w32 mac))
1215       t)    ;; FIXME?
1216      (t
1217       nil))))
1218
1219 (declare-function x-display-screens "xfns.c" (&optional terminal))
1220
1221 (defun display-screens (&optional display)
1222   "Return the number of screens associated with DISPLAY."
1223   (let ((frame-type (framep-on-display display)))
1224     (cond
1225      ((memq frame-type '(x w32 mac))
1226       (x-display-screens display))
1227      (t
1228       1))))
1229
1230 (declare-function x-display-pixel-height "xfns.c" (&optional terminal))
1231
1232 (defun display-pixel-height (&optional display)
1233   "Return the height of DISPLAY's screen in pixels.
1234 For character terminals, each character counts as a single pixel."
1235   (let ((frame-type (framep-on-display display)))
1236     (cond
1237      ((memq frame-type '(x w32 mac))
1238       (x-display-pixel-height display))
1239      (t
1240       (frame-height (if (framep display) display (selected-frame)))))))
1241
1242 (declare-function x-display-pixel-width "xfns.c" (&optional terminal))
1243
1244 (defun display-pixel-width (&optional display)
1245   "Return the width of DISPLAY's screen in pixels.
1246 For character terminals, each character counts as a single pixel."
1247   (let ((frame-type (framep-on-display display)))
1248     (cond
1249      ((memq frame-type '(x w32 mac))
1250       (x-display-pixel-width display))
1251      (t
1252       (frame-width (if (framep display) display (selected-frame)))))))
1253
1254 (defcustom display-mm-dimensions-alist nil
1255   "Alist for specifying screen dimensions in millimeters.
1256 The dimensions will be used for `display-mm-height' and
1257 `display-mm-width' if defined for the respective display.
1258
1259 Each element of the alist has the form (display . (width . height)),
1260 e.g. (\":0.0\" . (287 . 215)).
1261
1262 If `display' equals t, it specifies dimensions for all graphical
1263 displays not explicitely specified."
1264   :version "22.1"
1265   :type '(alist :key-type (choice (string :tag "Display name")
1266                                   (const :tag "Default" t))
1267                 :value-type (cons :tag "Dimensions"
1268                                   (integer :tag "Width")
1269                                   (integer :tag "Height")))
1270   :group 'frames)
1271
1272 (declare-function x-display-mm-height "xfns.c" (&optional terminal))
1273
1274 (defun display-mm-height (&optional display)
1275   "Return the height of DISPLAY's screen in millimeters.
1276 System values can be overridden by `display-mm-dimensions-alist'.
1277 If the information is unavailable, value is nil."
1278   (and (memq (framep-on-display display) '(x w32 mac))
1279        (or (cddr (assoc (or display (frame-parameter nil 'display))
1280                         display-mm-dimensions-alist))
1281            (cddr (assoc t display-mm-dimensions-alist))
1282            (x-display-mm-height display))))
1283
1284 (declare-function x-display-mm-width "xfns.c" (&optional terminal))
1285
1286 (defun display-mm-width (&optional display)
1287   "Return the width of DISPLAY's screen in millimeters.
1288 System values can be overridden by `display-mm-dimensions-alist'.
1289 If the information is unavailable, value is nil."
1290   (and (memq (framep-on-display display) '(x w32 mac))
1291        (or (cadr (assoc (or display (frame-parameter nil 'display))
1292                         display-mm-dimensions-alist))
1293            (cadr (assoc t display-mm-dimensions-alist))
1294            (x-display-mm-width display))))
1295
1296 (declare-function x-display-backing-store "xfns.c" (&optional terminal))
1297
1298 (defun display-backing-store (&optional display)
1299   "Return the backing store capability of DISPLAY's screen.
1300 The value may be `always', `when-mapped', `not-useful', or nil if
1301 the question is inapplicable to a certain kind of display."
1302   (let ((frame-type (framep-on-display display)))
1303     (cond
1304      ((memq frame-type '(x w32 mac))
1305       (x-display-backing-store display))
1306      (t
1307       'not-useful))))
1308
1309 (declare-function x-display-save-under "xfns.c" (&optional terminal))
1310
1311 (defun display-save-under (&optional display)
1312   "Return non-nil if DISPLAY's screen supports the SaveUnder feature."
1313   (let ((frame-type (framep-on-display display)))
1314     (cond
1315      ((memq frame-type '(x w32 mac))
1316       (x-display-save-under display))
1317      (t
1318       'not-useful))))
1319
1320 (declare-function x-display-planes "xfns.c" (&optional terminal))
1321
1322 (defun display-planes (&optional display)
1323   "Return the number of planes supported by DISPLAY."
1324   (let ((frame-type (framep-on-display display)))
1325     (cond
1326      ((memq frame-type '(x w32 mac))
1327       (x-display-planes display))
1328      ((eq frame-type 'pc)
1329       4)
1330      (t
1331       (truncate (log (length (tty-color-alist)) 2))))))
1332
1333 (declare-function x-display-color-cells "xfns.c" (&optional terminal))
1334
1335 (defun display-color-cells (&optional display)
1336   "Return the number of color cells supported by DISPLAY."
1337   (let ((frame-type (framep-on-display display)))
1338     (cond
1339      ((memq frame-type '(x w32 mac))
1340       (x-display-color-cells display))
1341      ((eq frame-type 'pc)
1342       16)
1343      (t
1344       (tty-display-color-cells display)))))
1345
1346 (declare-function x-display-visual-class "xfns.c" (&optional terminal))
1347
1348 (defun display-visual-class (&optional display)
1349   "Returns the visual class of DISPLAY.
1350 The value is one of the symbols `static-gray', `gray-scale',
1351 `static-color', `pseudo-color', `true-color', or `direct-color'."
1352   (let ((frame-type (framep-on-display display)))
1353     (cond
1354      ((memq frame-type '(x w32 mac))
1355       (x-display-visual-class display))
1356      ((and (memq frame-type '(pc t))
1357            (tty-display-color-p display))
1358       'static-color)
1359      (t
1360       'static-gray))))
1361
1362 \f
1363 ;;;; Frame geometry values
1364
1365 (defun frame-geom-value-cons (type value &optional frame)
1366   "Return equivalent geometry value for FRAME as a cons with car `+'.
1367 A geometry value equivalent to VALUE for FRAME is returned,
1368 where the value is a cons with car `+', not numeric.
1369 TYPE is the car of the original geometry spec (TYPE . VALUE).
1370    It is `top' or `left', depending on which edge VALUE is related to.
1371 VALUE is the cdr of a frame geometry spec: (left/top . VALUE).
1372 If VALUE is a number, then it is converted to a cons value, perhaps
1373    relative to the opposite frame edge from that in the original spec.
1374 FRAME defaults to the selected frame.
1375
1376 Examples (measures in pixels) -
1377  Assuming display height/width=1024, frame height/width=600:
1378  300 inside display edge:                   300  => (+  300)
1379                                         (+  300) => (+  300)
1380  300 inside opposite display edge:      (-  300) => (+  124)
1381                                            -300  => (+  124)
1382  300 beyond display edge
1383   (= 724 inside opposite display edge): (+ -300) => (+ -300)
1384  300 beyond display edge
1385   (= 724 inside opposite display edge): (- -300) => (+  724)
1386
1387 In the 3rd, 4th, and 6th examples, the returned value is relative to
1388 the opposite frame edge from the edge indicated in the input spec."
1389   (cond ((and (consp value) (eq '+ (car value))) ; e.g. (+ 300), (+ -300)
1390          value)
1391         ((natnump value) (list '+ value)) ; e.g. 300 => (+ 300)
1392         (t                              ; e.g. -300, (- 300), (- -300)
1393          (list '+ (- (if (eq 'left type) ; => (+ 124), (+ 124), (+ 724)
1394                          (x-display-pixel-width)
1395                        (x-display-pixel-height))
1396                      (if (integerp value) (- value) (cadr value))
1397                      (if (eq 'left type)
1398                          (frame-pixel-width frame)
1399                        (frame-pixel-height frame)))))))
1400
1401 (defun frame-geom-spec-cons (spec &optional frame)
1402   "Return equivalent geometry spec for FRAME as a cons with car `+'.
1403 A geometry specification equivalent to SPEC for FRAME is returned,
1404 where the value is a cons with car `+', not numeric.
1405 SPEC is a frame geometry spec: (left . VALUE) or (top . VALUE).
1406 If VALUE is a number, then it is converted to a cons value, perhaps
1407    relative to the opposite frame edge from that in the original spec.
1408 FRAME defaults to the selected frame.
1409
1410 Examples (measures in pixels) -
1411  Assuming display height=1024, frame height=600:
1412  top 300 below display top:               (top .  300) => (top +  300)
1413                                           (top +  300) => (top +  300)
1414  bottom 300 above display bottom:         (top -  300) => (top +  124)
1415                                           (top . -300) => (top +  124)
1416  top 300 above display top
1417   (= bottom 724 above display bottom):    (top + -300) => (top + -300)
1418  bottom 300 below display bottom
1419   (= top 724 below display top):          (top - -300) => (top +  724)
1420
1421 In the 3rd, 4th, and 6th examples, the returned value is relative to
1422 the opposite frame edge from the edge indicated in the input spec."
1423   (cons (car spec) (frame-geom-value-cons (car spec) (cdr spec))))
1424 \f
1425 ;;;; Aliases for backward compatibility with Emacs 18.
1426 (define-obsolete-function-alias 'screen-height 'frame-height "19.7")
1427 (define-obsolete-function-alias 'screen-width 'frame-width "19.7")
1428
1429 (defun set-screen-width (cols &optional pretend)
1430   "Change the size of the screen to COLS columns.
1431 Optional second arg non-nil means that redisplay should use COLS columns
1432 but that the idea of the actual width of the frame should not be changed.
1433 This function is provided only for compatibility with Emacs 18."
1434   (set-frame-width (selected-frame) cols pretend))
1435
1436 (defun set-screen-height (lines &optional pretend)
1437   "Change the height of the screen to LINES lines.
1438 Optional second arg non-nil means that redisplay should use LINES lines
1439 but that the idea of the actual height of the screen should not be changed.
1440 This function is provided only for compatibility with Emacs 18."
1441   (set-frame-height (selected-frame) lines pretend))
1442
1443 (defun delete-other-frames (&optional frame)
1444   "Delete all frames except FRAME.
1445 If FRAME uses another frame's minibuffer, the minibuffer frame is
1446 left untouched.  FRAME nil or omitted means use the selected frame."
1447   (interactive)
1448   (unless frame
1449     (setq frame (selected-frame)))
1450   (let* ((mini-frame (window-frame (minibuffer-window frame)))
1451          (frames (delq mini-frame (delq frame (frame-list)))))
1452     ;; Delete mon-minibuffer-only frames first, because `delete-frame'
1453     ;; signals an error when trying to delete a mini-frame that's
1454     ;; still in use by another frame.
1455     (dolist (frame frames)
1456       (unless (eq (frame-parameter frame 'minibuffer) 'only)
1457         (delete-frame frame)))
1458     ;; Delete minibuffer-only frames.
1459     (dolist (frame frames)
1460       (when (eq (frame-parameter frame 'minibuffer) 'only)
1461         (delete-frame frame)))))
1462
1463 (make-obsolete 'set-screen-width 'set-frame-width "19.7")
1464 (make-obsolete 'set-screen-height 'set-frame-height "19.7")
1465
1466 ;; miscellaneous obsolescence declarations
1467 (define-obsolete-variable-alias 'delete-frame-hook
1468     'delete-frame-functions "22.1")
1469
1470 \f
1471 ;; Highlighting trailing whitespace.
1472
1473 (make-variable-buffer-local 'show-trailing-whitespace)
1474
1475 (defcustom show-trailing-whitespace nil
1476   "*Non-nil means highlight trailing whitespace.
1477 This is done in the face `trailing-whitespace'."
1478   :type 'boolean
1479   :group 'whitespace-faces)
1480
1481
1482 \f
1483 ;; Scrolling
1484
1485 (defgroup scrolling nil
1486   "Scrolling windows."
1487   :version "21.1"
1488   :group 'frames)
1489
1490 (defcustom auto-hscroll-mode t
1491   "*Allow or disallow automatic scrolling windows horizontally.
1492 If non-nil, windows are automatically scrolled horizontally to make
1493 point visible."
1494   :version "21.1"
1495   :type 'boolean
1496   :group 'scrolling)
1497 (defvaralias 'automatic-hscrolling 'auto-hscroll-mode)
1498
1499 \f
1500 ;; Blinking cursor
1501
1502 (defgroup cursor nil
1503   "Displaying text cursors."
1504   :version "21.1"
1505   :group 'frames)
1506
1507 (defcustom blink-cursor-delay 0.5
1508   "*Seconds of idle time after which cursor starts to blink."
1509   :type 'number
1510   :group 'cursor)
1511
1512 (defcustom blink-cursor-interval 0.5
1513   "*Length of cursor blink interval in seconds."
1514   :type 'number
1515   :group 'cursor)
1516
1517 (defvar blink-cursor-idle-timer nil
1518   "Timer started after `blink-cursor-delay' seconds of Emacs idle time.
1519 The function `blink-cursor-start' is called when the timer fires.")
1520
1521 (defvar blink-cursor-timer nil
1522   "Timer started from `blink-cursor-start'.
1523 This timer calls `blink-cursor-timer-function' every
1524 `blink-cursor-interval' seconds.")
1525
1526 (defun blink-cursor-start ()
1527   "Timer function called from the timer `blink-cursor-idle-timer'.
1528 This starts the timer `blink-cursor-timer', which makes the cursor blink
1529 if appropriate.  It also arranges to cancel that timer when the next
1530 command starts, by installing a pre-command hook."
1531   (when (null blink-cursor-timer)
1532     ;; Set up the timer first, so that if this signals an error,
1533     ;; blink-cursor-end is not added to pre-command-hook.
1534     (setq blink-cursor-timer
1535           (run-with-timer blink-cursor-interval blink-cursor-interval
1536                           'blink-cursor-timer-function))
1537     (add-hook 'pre-command-hook 'blink-cursor-end)
1538     (internal-show-cursor nil nil)))
1539
1540 (defun blink-cursor-timer-function ()
1541   "Timer function of timer `blink-cursor-timer'."
1542   (internal-show-cursor nil (not (internal-show-cursor-p))))
1543
1544 (defun blink-cursor-end ()
1545   "Stop cursor blinking.
1546 This is installed as a pre-command hook by `blink-cursor-start'.
1547 When run, it cancels the timer `blink-cursor-timer' and removes
1548 itself as a pre-command hook."
1549   (remove-hook 'pre-command-hook 'blink-cursor-end)
1550   (internal-show-cursor nil t)
1551   (when blink-cursor-timer
1552     (cancel-timer blink-cursor-timer)
1553     (setq blink-cursor-timer nil)))
1554
1555 (define-minor-mode blink-cursor-mode
1556   "Toggle blinking cursor mode.
1557 With a numeric argument, turn blinking cursor mode on if ARG is positive,
1558 otherwise turn it off.  When blinking cursor mode is enabled, the
1559 cursor of the selected window blinks.
1560
1561 Note that this command is effective only when Emacs
1562 displays through a window system, because then Emacs does its own
1563 cursor display.  On a text-only terminal, this is not implemented."
1564   :init-value (not (or noninteractive
1565                        no-blinking-cursor
1566                        (eq system-type 'ms-dos)
1567                        (not (memq window-system '(x w32 mac)))))
1568   :initialize 'custom-initialize-safe-default
1569   :group 'cursor
1570   :global t
1571   (if blink-cursor-idle-timer (cancel-timer blink-cursor-idle-timer))
1572   (setq blink-cursor-idle-timer nil)
1573   (blink-cursor-end)
1574   (when blink-cursor-mode
1575     ;; Hide the cursor.
1576     ;;(internal-show-cursor nil nil)
1577     (setq blink-cursor-idle-timer
1578           (run-with-idle-timer blink-cursor-delay
1579                                blink-cursor-delay
1580                                'blink-cursor-start))))
1581
1582 (define-obsolete-variable-alias 'blink-cursor 'blink-cursor-mode "22.1")
1583 \f
1584 ;; Hourglass pointer
1585
1586 (defcustom display-hourglass t
1587   "*Non-nil means show an hourglass pointer, when Emacs is busy.
1588 This feature only works when on a window system that can change
1589 cursor shapes."
1590   :type 'boolean
1591   :group 'cursor)
1592
1593 (defcustom hourglass-delay 1
1594   "*Seconds to wait before displaying an hourglass pointer when Emacs is busy."
1595   :type 'number
1596   :group 'cursor)
1597
1598 \f
1599 (defcustom cursor-in-non-selected-windows t
1600   "*Non-nil means show a hollow box cursor in non-selected windows.
1601 If nil, don't show a cursor except in the selected window.
1602 If t, display a cursor related to the usual cursor type
1603  \(a solid box becomes hollow, a bar becomes a narrower bar).
1604 You can also specify the cursor type as in the `cursor-type' variable.
1605 Use Custom to set this variable to get the display updated."
1606   :tag "Cursor In Non-selected Windows"
1607   :type 'boolean
1608   :group 'cursor
1609   :set #'(lambda (symbol value)
1610            (set-default symbol value)
1611            (force-mode-line-update t)))
1612
1613 \f
1614 ;;;; Key bindings
1615
1616 (define-key ctl-x-5-map "2" 'make-frame-command)
1617 (define-key ctl-x-5-map "1" 'delete-other-frames)
1618 (define-key ctl-x-5-map "0" 'delete-frame)
1619 (define-key ctl-x-5-map "o" 'other-frame)
1620
1621 (provide 'frame)
1622
1623 ;; arch-tag: 82979c70-b8f2-4306-b2ad-ddbd6b328b56
1624 ;;; frame.el ends here