lisp/url/url-file.el

   1 ;;; url-file.el --- File retrieval code
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Keywords: comm, data, processes
   7
   8 ;; This file is part of GNU Emacs.
   9 ;;
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28 (require 'mailcap)
  29 (require 'url-vars)
  30 (require 'url-parse)
  31 (require 'url-dired)
  32
  33 (defconst url-file-default-port 21 "Default FTP port.")
  34 (defconst url-file-asynchronous-p t "FTP transfers are asynchronous.")
  35 (defalias 'url-file-expand-file-name 'url-default-expander)
  36
  37 (defun url-file-find-possibly-compressed-file (fname &rest args)
  38   "Find the exact file referenced by `fname'.
  39 This tries the common compression extensions, because things like
  40 ange-ftp and efs are not quite smart enough to realize when a server
  41 can do automatic decompression for them, and won't find 'foo' if
  42 'foo.gz' exists, even though the FTP server would happily serve it up
  43 to them."
  44   (let ((scratch nil)
  45         (compressed-extensions '("" ".gz" ".z" ".Z" ".bz2"))
  46         (found nil))
  47     (while (and compressed-extensions (not found))
  48       (if (file-exists-p (setq scratch (concat fname (pop compressed-extensions))))
  49           (setq found scratch)))
  50     found))
  51
  52 (defun url-file-host-is-local-p (host)
  53   "Return t if HOST references our local machine."
  54   (let ((case-fold-search t))
  55     (or
  56      (null host)
  57      (string= "" host)
  58      (equal (downcase host) (downcase (system-name)))
  59      (and (string-match "^localhost$" host) t)
  60      (and (not (string-match (regexp-quote ".") host))
  61           (equal (downcase host) (if (string-match (regexp-quote ".")
  62                                                    (system-name))
  63                                      (substring (system-name) 0
  64                                                 (match-beginning 0))
  65                                    (system-name)))))))
  66
  67 (defun url-file-asynch-callback (x y name buff func args &optional efs)
  68   (if (not (featurep 'ange-ftp))
  69       ;; EFS passes us an extra argument
  70       (setq name buff
  71             buff func
  72             func args
  73             args efs))
  74   (let ((size (nth 7 (file-attributes name))))
  75     (with-current-buffer buff
  76       (goto-char (point-max))
  77       (if (/= -1 size)
  78           (insert (format "Content-length: %d\n" size)))
  79       (insert "\n")
  80       (insert-file-contents-literally name)
  81       (if (not (url-file-host-is-local-p (url-host url-current-object)))
  82           (condition-case ()
  83               (delete-file name)
  84             (error nil)))
  85       (apply func args))))
  86
  87 (declare-function ange-ftp-set-passwd "ange-ftp" (host user passwd))
  88 (declare-function ange-ftp-copy-file-internal "ange-ftp"
  89                   (filename newname ok-if-already-exists
  90                             keep-date &optional msg cont nowait))
  91
  92 (defun url-file-build-filename (url)
  93   (if (not (vectorp url))
  94       (setq url (url-generic-parse-url url)))
  95   (let* ((user (url-user url))
  96          (pass (url-password url))
  97          (port (url-port url))
  98          (host (url-host url))
  99          (site (if (and port (/= port 21))
 100                    (if (featurep 'ange-ftp)
 101                        (format "%s %d" host port)
 102                      ;; This works in Emacs 21's ange-ftp too.
 103                      (format "%s#%d" host port))
 104                  host))
 105          (file (url-unhex-string (url-filename url)))
 106          (filename (if (or user (not (url-file-host-is-local-p host)))
 107                        (concat "/" (or user "anonymous") "@" site ":" file)
 108                      (if (and (memq system-type
 109                                     '(emx ms-dos windows-nt ms-windows))
 110                               (string-match "^/[a-zA-Z]:/" file))
 111                          (substring file 1)
 112                        file)))
 113          pos-index)
 114
 115     (and user pass
 116          (cond
 117           ((featurep 'ange-ftp)
 118            (ange-ftp-set-passwd host user pass))
 119           ((when (featurep 'xemacs)
 120              (or (featurep 'efs) (featurep 'efs-auto)
 121                  (efs-set-passwd host user pass))))
 122           (t
 123            nil)))
 124
 125     ;; This makes sure that directories have a trailing directory
 126     ;; separator on them so URL expansion works right.
 127     ;;
 128     ;; FIXME?  What happens if the remote system doesn't use our local
 129     ;; directory-sep-char as its separator?  Would it be safer to just
 130     ;; use '/' unconditionally and rely on the FTP server to
 131     ;; straighten it out for us?
 132     ;; (if (and (file-directory-p filename)
 133     ;;          (not (string-match (format "%c$" directory-sep-char) filename)))
 134     ;;     (setf (url-filename url)
 135     ;;           (format "%s%c" filename directory-sep-char)))
 136     (if (and (file-directory-p filename)
 137              (not (string-match "/\\'" filename)))
 138         (setf (url-filename url) (format "%s/" filename)))
 139
 140
 141     ;; If it is a directory, look for an index file first.
 142     (if (and (file-directory-p filename)
 143              url-directory-index-file
 144              (setq pos-index (expand-file-name url-directory-index-file filename))
 145              (file-exists-p pos-index)
 146              (file-readable-p pos-index))
 147         (setq filename pos-index))
 148
 149     ;; Find the (possibly compressed) file
 150     (setq filename (url-file-find-possibly-compressed-file filename))
 151     filename))
 152
 153 ;;;###autoload
 154 (defun url-file (url callback cbargs)
 155   "Handle file: and ftp: URLs."
 156   (let* ((buffer nil)
 157          (uncompressed-filename nil)
 158          (content-type nil)
 159          (content-encoding nil)
 160          (coding-system-for-read 'binary))
 161
 162     (setq filename (url-file-build-filename url))
 163
 164     (if (not filename)
 165         (error "File does not exist: %s" (url-recreate-url url)))
 166
 167     ;; Need to figure out the content-type from the real extension,
 168     ;; not the compressed one.
 169     (setq uncompressed-filename (if (string-match "\\.\\(gz\\|Z\\|z\\)$" filename)
 170                                     (substring filename 0 (match-beginning 0))
 171                                   filename))
 172     (setq content-type (mailcap-extension-to-mime
 173                         (url-file-extension uncompressed-filename))
 174           content-encoding (case (intern (url-file-extension filename))
 175                              ((\.z \.gz) "gzip")
 176                              (\.Z "compress")
 177                              (\.uue "x-uuencoded")
 178                              (\.hqx "x-hqx")
 179                              (\.bz2 "x-bzip2")
 180                              (otherwise nil)))
 181
 182     (if (file-directory-p filename)
 183         ;; A directory is done the same whether we are local or remote
 184         (url-find-file-dired filename)
 185       (with-current-buffer
 186           (setq buffer (generate-new-buffer " *url-file*"))
 187         (mm-disable-multibyte)
 188         (setq url-current-object url)
 189         (insert "Content-type: " (or content-type "application/octet-stream") "\n")
 190         (if content-encoding
 191             (insert "Content-transfer-encoding: " content-encoding "\n"))
 192         (if (url-file-host-is-local-p (url-host url))
 193               ;; Local files are handled slightly oddly
 194             (if (featurep 'ange-ftp)
 195                 (url-file-asynch-callback nil nil
 196                                           filename
 197                                           (current-buffer)
 198                                           callback cbargs)
 199               (url-file-asynch-callback nil nil nil
 200                                         filename
 201                                         (current-buffer)
 202                                         callback cbargs))
 203           ;; FTP handling
 204           (let ((new (make-temp-file
 205                       (format "url-tmp.%d" (user-real-uid)))))
 206             (if (featurep 'ange-ftp)
 207                 (ange-ftp-copy-file-internal filename (expand-file-name new) t
 208                                              nil t
 209                                              (list 'url-file-asynch-callback
 210                                                    new (current-buffer)
 211                                                    callback cbargs)
 212                                              t)
 213               (when (featurep 'xemacs)
 214                 (autoload 'efs-copy-file-internal "efs")
 215                 (efs-copy-file-internal filename (efs-ftp-path filename)
 216                                         new (efs-ftp-path new)
 217                                         t nil 0
 218                                         (list 'url-file-asynch-callback
 219                                               new (current-buffer)
 220                                               callback cbargs)
 221                                         0 nil)))))))
 222     buffer))
 223
 224 (defmacro url-file-create-wrapper (method args)
 225   `(defalias ',(intern (format "url-ftp-%s" method))
 226      (defun ,(intern (format "url-file-%s" method)) ,args
 227        ,(format "FTP/FILE URL wrapper around `%s' call." method)
 228        (setq url (url-file-build-filename url))
 229        (and url (,method ,@(remove '&rest (remove '&optional args)))))))
 230
 231 (url-file-create-wrapper file-exists-p (url))
 232 (url-file-create-wrapper file-attributes (url &optional id-format))
 233 (url-file-create-wrapper file-symlink-p (url))
 234 (url-file-create-wrapper file-readable-p (url))
 235 (url-file-create-wrapper file-writable-p (url))
 236 (url-file-create-wrapper file-executable-p (url))
 237 (url-file-create-wrapper directory-files (url &optional full match nosort))
 238 (url-file-create-wrapper file-truename (url &optional counter prev-dirs))
 239
 240 (provide 'url-file)
 241
 242 ;; arch-tag: 010e914a-7313-494b-8a8c-6495a862157d
 243 ;;; url-file.el ends here