lisp/url/url-http.el

   1 ;;; url-http.el --- HTTP retrieval routines
   2
   3 ;; Copyright (C) 1999, 2001, 2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   4
   5 ;; Author: Bill Perry <wmperry@gnu.org>
   6 ;; Keywords: comm, data, processes
   7
   8 ;; This file is part of GNU Emacs.
   9 ;;
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28 (defvar url-http-extra-headers)
  29 (defvar url-http-target-url)
  30 (defvar url-http-proxy)
  31 (defvar url-http-connection-opened)
  32 (require 'url-gw)
  33 (require 'url-util)
  34 (require 'url-parse)
  35 (require 'url-cookie)
  36 (require 'mail-parse)
  37 (require 'url-auth)
  38 (require 'url)
  39 (autoload 'url-cache-create-filename "url-cache")
  40
  41 (defconst url-http-default-port 80 "Default HTTP port.")
  42 (defconst url-http-asynchronous-p t "HTTP retrievals are asynchronous.")
  43 (defalias 'url-http-expand-file-name 'url-default-expander)
  44
  45 (defvar url-http-real-basic-auth-storage nil)
  46 (defvar url-http-proxy-basic-auth-storage nil)
  47
  48 (defvar url-http-open-connections (make-hash-table :test 'equal
  49                                                    :size 17)
  50   "A hash table of all open network connections.")
  51
  52 (defvar url-http-version "1.1"
  53   "What version of HTTP we advertise, as a string.
  54 Valid values are 1.1 and 1.0.
  55 This is only useful when debugging the HTTP subsystem.
  56
  57 Setting this to 1.0 will tell servers not to send chunked encoding,
  58 and other HTTP/1.1 specific features.")
  59
  60 (defvar url-http-attempt-keepalives t
  61   "Whether to use a single TCP connection multiple times in HTTP.
  62 This is only useful when debugging the HTTP subsystem.  Setting to
  63 nil will explicitly close the connection to the server after every
  64 request.")
  65
  66 ;(eval-when-compile
  67 ;; These are all macros so that they are hidden from external sight
  68 ;; when the file is byte-compiled.
  69 ;;
  70 ;; This allows us to expose just the entry points we want.
  71
  72 ;; These routines will allow us to implement persistent HTTP
  73 ;; connections.
  74 (defsubst url-http-debug (&rest args)
  75   (if quit-flag
  76       (let ((proc (get-buffer-process (current-buffer))))
  77         ;; The user hit C-g, honor it!  Some things can get in an
  78         ;; incredibly tight loop (chunked encoding)
  79         (if proc
  80             (progn
  81               (set-process-sentinel proc nil)
  82               (set-process-filter proc nil)))
  83         (error "Transfer interrupted!")))
  84   (apply 'url-debug 'http args))
  85
  86 (defun url-http-mark-connection-as-busy (host port proc)
  87   (url-http-debug "Marking connection as busy: %s:%d %S" host port proc)
  88   (set-process-query-on-exit-flag proc t)
  89   (puthash (cons host port)
  90               (delq proc (gethash (cons host port) url-http-open-connections))
  91               url-http-open-connections)
  92   proc)
  93
  94 (defun url-http-mark-connection-as-free (host port proc)
  95   (url-http-debug "Marking connection as free: %s:%d %S" host port proc)
  96   (when (memq (process-status proc) '(open run connect))
  97     (set-process-buffer proc nil)
  98     (set-process-sentinel proc 'url-http-idle-sentinel)
  99     (set-process-query-on-exit-flag proc nil)
 100     (puthash (cons host port)
 101              (cons proc (gethash (cons host port) url-http-open-connections))
 102              url-http-open-connections))
 103   nil)
 104
 105 (defun url-http-find-free-connection (host port)
 106   (let ((conns (gethash (cons host port) url-http-open-connections))
 107         (found nil))
 108     (while (and conns (not found))
 109       (if (not (memq (process-status (car conns)) '(run open connect)))
 110           (progn
 111             (url-http-debug "Cleaning up dead process: %s:%d %S"
 112                             host port (car conns))
 113             (url-http-idle-sentinel (car conns) nil))
 114         (setq found (car conns))
 115         (url-http-debug "Found existing connection: %s:%d %S" host port found))
 116       (pop conns))
 117     (if found
 118         (url-http-debug "Reusing existing connection: %s:%d" host port)
 119       (url-http-debug "Contacting host: %s:%d" host port))
 120     (url-lazy-message "Contacting host: %s:%d" host port)
 121     (url-http-mark-connection-as-busy
 122      host port
 123      (or found
 124          (let ((buf (generate-new-buffer " *url-http-temp*")))
 125            ;; `url-open-stream' needs a buffer in which to do things
 126            ;; like authentication.  But we use another buffer afterwards.
 127            (unwind-protect
 128                (let ((proc (url-open-stream host buf host port)))
 129                  ;; url-open-stream might return nil.
 130                  (when (processp proc)
 131                    ;; Drop the temp buffer link before killing the buffer.
 132                    (set-process-buffer proc nil))
 133                  proc)
 134              (kill-buffer buf)))))))
 135
 136 ;; Building an HTTP request
 137 (defun url-http-user-agent-string ()
 138   (if (or (eq url-privacy-level 'paranoid)
 139           (and (listp url-privacy-level)
 140                (memq 'agent url-privacy-level)))
 141       ""
 142     (format "User-Agent: %sURL/%s%s\r\n"
 143             (if url-package-name
 144                 (concat url-package-name "/" url-package-version " ")
 145               "")
 146             url-version
 147             (cond
 148              ((and url-os-type url-system-type)
 149               (concat " (" url-os-type "; " url-system-type ")"))
 150              ((or url-os-type url-system-type)
 151               (concat " (" (or url-system-type url-os-type) ")"))
 152              (t "")))))
 153
 154 (defun url-http-create-request (&optional ref-url)
 155   "Create an HTTP request for `url-http-target-url', referred to by REF-URL."
 156   (declare (special proxy-info
 157                     url-http-method url-http-data
 158                     url-http-extra-headers))
 159   (let* ((extra-headers)
 160          (request nil)
 161          (no-cache (cdr-safe (assoc "Pragma" url-http-extra-headers)))
 162          (using-proxy url-http-proxy)
 163          (proxy-auth (if (or (cdr-safe (assoc "Proxy-Authorization"
 164                                               url-http-extra-headers))
 165                              (not using-proxy))
 166                          nil
 167                        (let ((url-basic-auth-storage
 168                               'url-http-proxy-basic-auth-storage))
 169                          (url-get-authentication url-http-target-url nil 'any nil))))
 170          (real-fname (concat (url-filename url-http-target-url)
 171                              (url-recreate-url-attributes url-http-target-url)))
 172          (host (url-host url-http-target-url))
 173          (auth (if (cdr-safe (assoc "Authorization" url-http-extra-headers))
 174                    nil
 175                  (url-get-authentication (or
 176                                           (and (boundp 'proxy-info)
 177                                                proxy-info)
 178                                           url-http-target-url) nil 'any nil))))
 179     (if (equal "" real-fname)
 180         (setq real-fname "/"))
 181     (setq no-cache (and no-cache (string-match "no-cache" no-cache)))
 182     (if auth
 183         (setq auth (concat "Authorization: " auth "\r\n")))
 184     (if proxy-auth
 185         (setq proxy-auth (concat "Proxy-Authorization: " proxy-auth "\r\n")))
 186
 187     ;; Protection against stupid values in the referer
 188     (if (and ref-url (stringp ref-url) (or (string= ref-url "file:nil")
 189                                            (string= ref-url "")))
 190         (setq ref-url nil))
 191
 192     ;; We do not want to expose the referer if the user is paranoid.
 193     (if (or (memq url-privacy-level '(low high paranoid))
 194             (and (listp url-privacy-level)
 195                  (memq 'lastloc url-privacy-level)))
 196         (setq ref-url nil))
 197
 198     ;; url-http-extra-headers contains an assoc-list of
 199     ;; header/value pairs that we need to put into the request.
 200     (setq extra-headers (mapconcat
 201                          (lambda (x)
 202                            (concat (car x) ": " (cdr x)))
 203                          url-http-extra-headers "\r\n"))
 204     (if (not (equal extra-headers ""))
 205         (setq extra-headers (concat extra-headers "\r\n")))
 206
 207     ;; This was done with a call to `format'.  Concatting parts has
 208     ;; the advantage of keeping the parts of each header together and
 209     ;; allows us to elide null lines directly, at the cost of making
 210     ;; the layout less clear.
 211     (setq request
 212           ;; We used to concat directly, but if one of the strings happens
 213           ;; to being multibyte (even if it only contains pure ASCII) then
 214           ;; every string gets converted with `string-MAKE-multibyte' which
 215           ;; turns the 127-255 codes into things like latin-1 accented chars
 216           ;; (it would work right if it used `string-TO-multibyte' instead).
 217           ;; So to avoid the problem we force every string to be unibyte.
 218           (mapconcat
 219            ;; FIXME: Instead of `string-AS-unibyte' we'd want
 220            ;; `string-to-unibyte', so as to properly signal an error if one
 221            ;; of the strings contains a multibyte char.
 222            'string-as-unibyte
 223            (delq nil
 224             (list
 225              ;; The request
 226              (or url-http-method "GET") " "
 227              (if using-proxy (url-recreate-url url-http-target-url) real-fname)
 228              " HTTP/" url-http-version "\r\n"
 229              ;; Version of MIME we speak
 230              "MIME-Version: 1.0\r\n"
 231              ;; (maybe) Try to keep the connection open
 232              "Connection: " (if (or using-proxy
 233                                     (not url-http-attempt-keepalives))
 234                                 "close" "keep-alive") "\r\n"
 235                                 ;; HTTP extensions we support
 236              (if url-extensions-header
 237                  (format
 238                   "Extension: %s\r\n" url-extensions-header))
 239              ;; Who we want to talk to
 240              (if (/= (url-port url-http-target-url)
 241                      (url-scheme-get-property
 242                       (url-type url-http-target-url) 'default-port))
 243                  (format
 244                   "Host: %s:%d\r\n" host (url-port url-http-target-url))
 245                (format "Host: %s\r\n" host))
 246              ;; Who its from
 247              (if url-personal-mail-address
 248                  (concat
 249                   "From: " url-personal-mail-address "\r\n"))
 250              ;; Encodings we understand
 251              (if url-mime-encoding-string
 252                  (concat
 253                   "Accept-encoding: " url-mime-encoding-string "\r\n"))
 254              (if url-mime-charset-string
 255                  (concat
 256                   "Accept-charset: " url-mime-charset-string "\r\n"))
 257              ;; Languages we understand
 258              (if url-mime-language-string
 259                  (concat
 260                   "Accept-language: " url-mime-language-string "\r\n"))
 261              ;; Types we understand
 262              "Accept: " (or url-mime-accept-string "*/*") "\r\n"
 263              ;; User agent
 264              (url-http-user-agent-string)
 265              ;; Proxy Authorization
 266              proxy-auth
 267              ;; Authorization
 268              auth
 269              ;; Cookies
 270              (url-cookie-generate-header-lines host real-fname
 271                                                (equal "https" (url-type url-http-target-url)))
 272              ;; If-modified-since
 273              (if (and (not no-cache)
 274                       (member url-http-method '("GET" nil)))
 275                  (let ((tm (url-is-cached url-http-target-url)))
 276                    (if tm
 277                        (concat "If-modified-since: "
 278                                (url-get-normalized-date tm) "\r\n"))))
 279              ;; Whence we came
 280              (if ref-url (concat
 281                           "Referer: " ref-url "\r\n"))
 282              extra-headers
 283              ;; Length of data
 284              (if url-http-data
 285                  (concat
 286                   "Content-length: " (number-to-string
 287                                       (length url-http-data))
 288                   "\r\n"))
 289              ;; End request
 290              "\r\n"
 291              ;; Any data
 292              url-http-data))
 293            ""))
 294     (url-http-debug "Request is: \n%s" request)
 295     request))
 296
 297 ;; Parsing routines
 298 (defun url-http-clean-headers ()
 299   "Remove trailing \r from header lines.
 300 This allows us to use `mail-fetch-field', etc."
 301   (declare (special url-http-end-of-headers))
 302   (goto-char (point-min))
 303   (while (re-search-forward "\r$" url-http-end-of-headers t)
 304     (replace-match "")))
 305
 306 (defun url-http-handle-authentication (proxy)
 307   (declare (special status success url-http-method url-http-data
 308                     url-callback-function url-callback-arguments))
 309   (url-http-debug "Handling %s authentication" (if proxy "proxy" "normal"))
 310   (let ((auths (or (nreverse
 311                     (mail-fetch-field
 312                      (if proxy "proxy-authenticate" "www-authenticate")
 313                      nil nil t))
 314                   '("basic")))
 315         (type nil)
 316         (url (url-recreate-url url-current-object))
 317         (url-basic-auth-storage 'url-http-real-basic-auth-storage)
 318         auth
 319         (strength 0))
 320     ;; Cheating, but who cares? :)
 321     (if proxy
 322         (setq url-basic-auth-storage 'url-http-proxy-basic-auth-storage))
 323
 324     ;; find strongest supported auth
 325     (dolist (this-auth auths)
 326       (setq this-auth (url-eat-trailing-space
 327                        (url-strip-leading-spaces
 328                         this-auth)))
 329       (let* ((this-type
 330               (if (string-match "[ \t]" this-auth)
 331                   (downcase (substring this-auth 0 (match-beginning 0)))
 332                 (downcase this-auth)))
 333              (registered (url-auth-registered this-type))
 334              (this-strength (cddr registered)))
 335         (when (and registered (> this-strength strength))
 336           (setq auth this-auth
 337                 type this-type
 338                 strength this-strength))))
 339
 340     (if (not (url-auth-registered type))
 341         (progn
 342           (widen)
 343           (goto-char (point-max))
 344           (insert "<hr>Sorry, but I do not know how to handle " type
 345                   " authentication.  If you'd like to write it,"
 346                   " send it to " url-bug-address ".<hr>")
 347           (setq status t))
 348       (let* ((args (url-parse-args (subst-char-in-string ?, ?\; auth)))
 349              (auth (url-get-authentication url (cdr-safe (assoc "realm" args))
 350                                            type t args)))
 351         (if (not auth)
 352             (setq success t)
 353           (push (cons (if proxy "Proxy-Authorization" "Authorization") auth)
 354                 url-http-extra-headers)
 355           (let ((url-request-method url-http-method)
 356                 (url-request-data url-http-data)
 357                 (url-request-extra-headers url-http-extra-headers))
 358             (url-retrieve-internal url url-callback-function
 359                                    url-callback-arguments)))))))
 360
 361 (defun url-http-parse-response ()
 362   "Parse just the response code."
 363   (declare (special url-http-end-of-headers url-http-response-status
 364                     url-http-response-version))
 365   (if (not url-http-end-of-headers)
 366       (error "Trying to parse HTTP response code in odd buffer: %s" (buffer-name)))
 367   (url-http-debug "url-http-parse-response called in (%s)" (buffer-name))
 368   (goto-char (point-min))
 369   (skip-chars-forward " \t\n")          ; Skip any blank crap
 370   (skip-chars-forward "HTTP/")          ; Skip HTTP Version
 371   (setq url-http-response-version
 372         (buffer-substring (point)
 373                           (progn
 374                             (skip-chars-forward "[0-9].")
 375                             (point))))
 376   (setq url-http-response-status (read (current-buffer))))
 377
 378 (defun url-http-handle-cookies ()
 379   "Handle all set-cookie / set-cookie2 headers in an HTTP response.
 380 The buffer must already be narrowed to the headers, so `mail-fetch-field' will
 381 work correctly."
 382   (let ((cookies (nreverse (mail-fetch-field "Set-Cookie" nil nil t)))
 383         (cookies2 (nreverse (mail-fetch-field "Set-Cookie2" nil nil t))))
 384     (and cookies (url-http-debug "Found %d Set-Cookie headers" (length cookies)))
 385     (and cookies2 (url-http-debug "Found %d Set-Cookie2 headers" (length cookies2)))
 386     (while cookies
 387       (url-cookie-handle-set-cookie (pop cookies)))
 388 ;;;     (while cookies2
 389 ;;;       (url-cookie-handle-set-cookie2 (pop cookies)))
 390     )
 391   )
 392
 393 (defun url-http-parse-headers ()
 394  "Parse and handle HTTP specific headers.
 395 Return t if and only if the current buffer is still active and
 396 should be shown to the user."
 397   ;; The comments after each status code handled are taken from RFC
 398   ;; 2616 (HTTP/1.1)
 399   (declare (special url-http-end-of-headers url-http-response-status
 400                     url-http-response-version
 401                     url-http-method url-http-data url-http-process
 402                     url-callback-function url-callback-arguments))
 403
 404   (url-http-mark-connection-as-free (url-host url-current-object)
 405                                     (url-port url-current-object)
 406                                     url-http-process)
 407
 408   (if (or (not (boundp 'url-http-end-of-headers))
 409           (not url-http-end-of-headers))
 410       (error "Trying to parse headers in odd buffer: %s" (buffer-name)))
 411   (goto-char (point-min))
 412   (url-http-debug "url-http-parse-headers called in (%s)" (buffer-name))
 413   (url-http-parse-response)
 414   (mail-narrow-to-head)
 415   ;;(narrow-to-region (point-min) url-http-end-of-headers)
 416   (let ((connection (mail-fetch-field "Connection")))
 417     ;; In HTTP 1.0, keep the connection only if there is a
 418     ;; "Connection: keep-alive" header.
 419     ;; In HTTP 1.1 (and greater), keep the connection unless there is a
 420     ;; "Connection: close" header
 421     (cond
 422      ((string= url-http-response-version "1.0")
 423       (unless (and connection
 424                    (string= (downcase connection) "keep-alive"))
 425         (delete-process url-http-process)))
 426      (t
 427       (when (and connection
 428                  (string= (downcase connection) "close"))
 429         (delete-process url-http-process)))))
 430   (let ((buffer (current-buffer))
 431         (class nil)
 432         (success nil))
 433     (setq class (/ url-http-response-status 100))
 434     (url-http-debug "Parsed HTTP headers: class=%d status=%d" class url-http-response-status)
 435     (url-http-handle-cookies)
 436
 437     (case class
 438       ;; Classes of response codes
 439       ;;
 440       ;; 5xx = Server Error
 441       ;; 4xx = Client Error
 442       ;; 3xx = Redirection
 443       ;; 2xx = Successful
 444       ;; 1xx = Informational
 445       (1                                ; Information messages
 446        ;; 100 = Continue with request
 447        ;; 101 = Switching protocols
 448        ;; 102 = Processing (Added by DAV)
 449        (url-mark-buffer-as-dead buffer)
 450        (error "HTTP responses in class 1xx not supported (%d)" url-http-response-status))
 451       (2                                ; Success
 452        ;; 200 Ok
 453        ;; 201 Created
 454        ;; 202 Accepted
 455        ;; 203 Non-authoritative information
 456        ;; 204 No content
 457        ;; 205 Reset content
 458        ;; 206 Partial content
 459        ;; 207 Multi-status (Added by DAV)
 460        (case url-http-response-status
 461          ((204 205)
 462           ;; No new data, just stay at the same document
 463           (url-mark-buffer-as-dead buffer)
 464           (setq success t))
 465          (otherwise
 466           ;; Generic success for all others.  Store in the cache, and
 467           ;; mark it as successful.
 468           (widen)
 469           (if (and url-automatic-caching (equal url-http-method "GET"))
 470               (url-store-in-cache buffer))
 471           (setq success t))))
 472       (3                                ; Redirection
 473        ;; 300 Multiple choices
 474        ;; 301 Moved permanently
 475        ;; 302 Found
 476        ;; 303 See other
 477        ;; 304 Not modified
 478        ;; 305 Use proxy
 479        ;; 307 Temporary redirect
 480        (let ((redirect-uri (or (mail-fetch-field "Location")
 481                                (mail-fetch-field "URI"))))
 482          (case url-http-response-status
 483            (300
 484             ;; Quoth the spec (section 10.3.1)
 485             ;; -------------------------------
 486             ;; The requested resource corresponds to any one of a set of
 487             ;; representations, each with its own specific location and
 488             ;; agent-driven negotiation information is being provided so
 489             ;; that the user can select a preferred representation and
 490             ;; redirect its request to that location.
 491             ;; [...]
 492             ;; If the server has a preferred choice of representation, it
 493             ;; SHOULD include the specific URI for that representation in
 494             ;; the Location field; user agents MAY use the Location field
 495             ;; value for automatic redirection.
 496             ;; -------------------------------
 497             ;; We do not support agent-driven negotiation, so we just
 498             ;; redirect to the preferred URI if one is provided.
 499             nil)
 500            ((301 302 307)
 501             ;; If the 301|302 status code is received in response to a
 502             ;; request other than GET or HEAD, the user agent MUST NOT
 503             ;; automatically redirect the request unless it can be
 504             ;; confirmed by the user, since this might change the
 505             ;; conditions under which the request was issued.
 506             (if (member url-http-method '("HEAD" "GET"))
 507                 ;; Automatic redirection is ok
 508                 nil
 509               ;; It is just too big of a pain in the ass to get this
 510               ;; prompt all the time.  We will just silently lose our
 511               ;; data and convert to a GET method.
 512               (url-http-debug "Converting `%s' request to `GET' because of REDIRECT(%d)"
 513                               url-http-method url-http-response-status)
 514               (setq url-http-method "GET"
 515                     url-http-data nil)))
 516            (303
 517             ;; The response to the request can be found under a different
 518             ;; URI and SHOULD be retrieved using a GET method on that
 519             ;; resource.
 520             (setq url-http-method "GET"
 521                   url-http-data nil))
 522            (304
 523             ;; The 304 response MUST NOT contain a message-body.
 524             (url-http-debug "Extracting document from cache... (%s)"
 525                             (url-cache-create-filename (url-view-url t)))
 526             (url-cache-extract (url-cache-create-filename (url-view-url t)))
 527             (setq redirect-uri nil
 528                   success t))
 529            (305
 530             ;; The requested resource MUST be accessed through the
 531             ;; proxy given by the Location field.  The Location field
 532             ;; gives the URI of the proxy.  The recipient is expected
 533             ;; to repeat this single request via the proxy.  305
 534             ;; responses MUST only be generated by origin servers.
 535             (error "Redirection thru a proxy server not supported: %s"
 536                    redirect-uri))
 537            (otherwise
 538             ;; Treat everything like '300'
 539             nil))
 540          (when redirect-uri
 541            ;; Clean off any whitespace and/or <...> cruft.
 542            (if (string-match "\\([^ \t]+\\)[ \t]" redirect-uri)
 543                (setq redirect-uri (match-string 1 redirect-uri)))
 544            (if (string-match "^<\\(.*\\)>$" redirect-uri)
 545                (setq redirect-uri (match-string 1 redirect-uri)))
 546
 547            ;; Some stupid sites (like sourceforge) send a
 548            ;; non-fully-qualified URL (ie: /), which royally confuses
 549            ;; the URL library.
 550            (if (not (string-match url-nonrelative-link redirect-uri))
 551                ;; Be careful to use the real target URL, otherwise we may
 552                ;; compute the redirection relative to the URL of the proxy.
 553                (setq redirect-uri
 554                      (url-expand-file-name redirect-uri url-http-target-url)))
 555            (let ((url-request-method url-http-method)
 556                  (url-request-data url-http-data)
 557                  (url-request-extra-headers url-http-extra-headers))
 558              ;; Check existing number of redirects
 559              (if (or (< url-max-redirections 0)
 560                      (and (> url-max-redirections 0)
 561                           (let ((events (car url-callback-arguments))
 562                                 (old-redirects 0))
 563                             (while events
 564                               (if (eq (car events) :redirect)
 565                                   (setq old-redirects (1+ old-redirects)))
 566                               (and (setq events (cdr events))
 567                                    (setq events (cdr events))))
 568                             (< old-redirects url-max-redirections))))
 569                  ;; url-max-redirections hasn't been reached, so go
 570                  ;; ahead and redirect.
 571                  (progn
 572                    ;; Remember that the request was redirected.
 573                    (setf (car url-callback-arguments)
 574                          (nconc (list :redirect redirect-uri)
 575                                 (car url-callback-arguments)))
 576                    ;; Put in the current buffer a forwarding pointer to the new
 577                    ;; destination buffer.
 578                    ;; FIXME: This is a hack to fix url-retrieve-synchronously
 579                    ;; without changing the API.  Instead url-retrieve should
 580                    ;; either simply not return the "destination" buffer, or it
 581                    ;; should take an optional `dest-buf' argument.
 582                    (set (make-local-variable 'url-redirect-buffer)
 583                         (url-retrieve-internal
 584                          redirect-uri url-callback-function
 585                          url-callback-arguments))
 586                    (url-mark-buffer-as-dead buffer))
 587                ;; We hit url-max-redirections, so issue an error and
 588                ;; stop redirecting.
 589                (url-http-debug "Maximum redirections reached")
 590                (setf (car url-callback-arguments)
 591                      (nconc (list :error (list 'error 'http-redirect-limit
 592                                                redirect-uri))
 593                             (car url-callback-arguments)))
 594                (setq success t))))))
 595       (4                                ; Client error
 596        ;; 400 Bad Request
 597        ;; 401 Unauthorized
 598        ;; 402 Payment required
 599        ;; 403 Forbidden
 600        ;; 404 Not found
 601        ;; 405 Method not allowed
 602        ;; 406 Not acceptable
 603        ;; 407 Proxy authentication required
 604        ;; 408 Request time-out
 605        ;; 409 Conflict
 606        ;; 410 Gone
 607        ;; 411 Length required
 608        ;; 412 Precondition failed
 609        ;; 413 Request entity too large
 610        ;; 414 Request-URI too large
 611        ;; 415 Unsupported media type
 612        ;; 416 Requested range not satisfiable
 613        ;; 417 Expectation failed
 614        ;; 422 Unprocessable Entity (Added by DAV)
 615        ;; 423 Locked
 616        ;; 424 Failed Dependency
 617        (case url-http-response-status
 618          (401
 619           ;; The request requires user authentication.  The response
 620           ;; MUST include a WWW-Authenticate header field containing a
 621           ;; challenge applicable to the requested resource.  The
 622           ;; client MAY repeat the request with a suitable
 623           ;; Authorization header field.
 624           (url-http-handle-authentication nil))
 625          (402
 626           ;; This code is reserved for future use
 627           (url-mark-buffer-as-dead buffer)
 628           (error "Somebody wants you to give them money"))
 629          (403
 630           ;; The server understood the request, but is refusing to
 631           ;; fulfill it.  Authorization will not help and the request
 632           ;; SHOULD NOT be repeated.
 633           (setq success t))
 634          (404
 635           ;; Not found
 636           (setq success t))
 637          (405
 638           ;; The method specified in the Request-Line is not allowed
 639           ;; for the resource identified by the Request-URI.  The
 640           ;; response MUST include an Allow header containing a list of
 641           ;; valid methods for the requested resource.
 642           (setq success t))
 643          (406
 644           ;; The resource identified by the request is only capable of
 645           ;; generating response entities which have content
 646           ;; characteristics nota cceptable according to the accept
 647           ;; headers sent in the request.
 648           (setq success t))
 649          (407
 650           ;; This code is similar to 401 (Unauthorized), but indicates
 651           ;; that the client must first authenticate itself with the
 652           ;; proxy.  The proxy MUST return a Proxy-Authenticate header
 653           ;; field containing a challenge applicable to the proxy for
 654           ;; the requested resource.
 655           (url-http-handle-authentication t))
 656          (408
 657           ;; The client did not produce a request within the time that
 658           ;; the server was prepared to wait.  The client MAY repeat
 659           ;; the request without modifications at any later time.
 660           (setq success t))
 661          (409
 662           ;; The request could not be completed due to a conflict with
 663           ;; the current state of the resource.  This code is only
 664           ;; allowed in situations where it is expected that the user
 665           ;; mioght be able to resolve the conflict and resubmit the
 666           ;; request.  The response body SHOULD include enough
 667           ;; information for the user to recognize the source of the
 668           ;; conflict.
 669           (setq success t))
 670          (410
 671           ;; The requested resource is no longer available at the
 672           ;; server and no forwarding address is known.
 673           (setq success t))
 674          (411
 675           ;; The server refuses to accept the request without a defined
 676           ;; Content-Length.  The client MAY repeat the request if it
 677           ;; adds a valid Content-Length header field containing the
 678           ;; length of the message-body in the request message.
 679           ;;
 680           ;; NOTE - this will never happen because
 681           ;; `url-http-create-request' automatically calculates the
 682           ;; content-length.
 683           (setq success t))
 684          (412
 685           ;; The precondition given in one or more of the
 686           ;; request-header fields evaluated to false when it was
 687           ;; tested on the server.
 688           (setq success t))
 689          ((413 414)
 690           ;; The server is refusing to process a request because the
 691           ;; request entity|URI is larger than the server is willing or
 692           ;; able to process.
 693           (setq success t))
 694          (415
 695           ;; The server is refusing to service the request because the
 696           ;; entity of the request is in a format not supported by the
 697           ;; requested resource for the requested method.
 698           (setq success t))
 699          (416
 700           ;; A server SHOULD return a response with this status code if
 701           ;; a request included a Range request-header field, and none
 702           ;; of the range-specifier values in this field overlap the
 703           ;; current extent of the selected resource, and the request
 704           ;; did not include an If-Range request-header field.
 705           (setq success t))
 706          (417
 707           ;; The expectation given in an Expect request-header field
 708           ;; could not be met by this server, or, if the server is a
 709           ;; proxy, the server has unambiguous evidence that the
 710           ;; request could not be met by the next-hop server.
 711           (setq success t))
 712          (otherwise
 713           ;; The request could not be understood by the server due to
 714           ;; malformed syntax.  The client SHOULD NOT repeat the
 715           ;; request without modifications.
 716           (setq success t)))
 717        ;; Tell the callback that an error occurred, and what the
 718        ;; status code was.
 719        (when success
 720          (setf (car url-callback-arguments)
 721                (nconc (list :error (list 'error 'http url-http-response-status))
 722                       (car url-callback-arguments)))))
 723       (5
 724        ;; 500 Internal server error
 725        ;; 501 Not implemented
 726        ;; 502 Bad gateway
 727        ;; 503 Service unavailable
 728        ;; 504 Gateway time-out
 729        ;; 505 HTTP version not supported
 730        ;; 507 Insufficient storage
 731        (setq success t)
 732        (case url-http-response-status
 733          (501
 734           ;; The server does not support the functionality required to
 735           ;; fulfill the request.
 736           nil)
 737          (502
 738           ;; The server, while acting as a gateway or proxy, received
 739           ;; an invalid response from the upstream server it accessed
 740           ;; in attempting to fulfill the request.
 741           nil)
 742          (503
 743           ;; The server is currently unable to handle the request due
 744           ;; to a temporary overloading or maintenance of the server.
 745           ;; The implication is that this is a temporary condition
 746           ;; which will be alleviated after some delay.  If known, the
 747           ;; length of the delay MAY be indicated in a Retry-After
 748           ;; header.  If no Retry-After is given, the client SHOULD
 749           ;; handle the response as it would for a 500 response.
 750           nil)
 751          (504
 752           ;; The server, while acting as a gateway or proxy, did not
 753           ;; receive a timely response from the upstream server
 754           ;; specified by the URI (e.g. HTTP, FTP, LDAP) or some other
 755           ;; auxiliary server (e.g. DNS) it needed to access in
 756           ;; attempting to complete the request.
 757           nil)
 758          (505
 759           ;; The server does not support, or refuses to support, the
 760           ;; HTTP protocol version that was used in the request
 761           ;; message.
 762           nil)
 763          (507                           ; DAV
 764           ;; The method could not be performed on the resource
 765           ;; because the server is unable to store the representation
 766           ;; needed to successfully complete the request.  This
 767           ;; condition is considered to be temporary.  If the request
 768           ;; which received this status code was the result of a user
 769           ;; action, the request MUST NOT be repeated until it is
 770           ;; requested by a separate user action.
 771           nil))
 772        ;; Tell the callback that an error occurred, and what the
 773        ;; status code was.
 774        (when success
 775          (setf (car url-callback-arguments)
 776                (nconc (list :error (list 'error 'http url-http-response-status))
 777                       (car url-callback-arguments)))))
 778       (otherwise
 779        (error "Unknown class of HTTP response code: %d (%d)"
 780               class url-http-response-status)))
 781     (if (not success)
 782         (url-mark-buffer-as-dead buffer))
 783     (url-http-debug "Finished parsing HTTP headers: %S" success)
 784     (widen)
 785     success))
 786
 787 ;; Miscellaneous
 788 (defun url-http-activate-callback ()
 789   "Activate callback specified when this buffer was created."
 790   (declare (special url-http-process
 791                     url-callback-function
 792                     url-callback-arguments))
 793   (url-http-mark-connection-as-free (url-host url-current-object)
 794                                     (url-port url-current-object)
 795                                     url-http-process)
 796   (url-http-debug "Activating callback in buffer (%s)" (buffer-name))
 797   (apply url-callback-function url-callback-arguments))
 798
 799 ;; )
 800
 801 ;; These unfortunately cannot be macros... please ignore them!
 802 (defun url-http-idle-sentinel (proc why)
 803   "Remove (now defunct) process PROC from the list of open connections."
 804   (maphash (lambda (key val)
 805                 (if (memq proc val)
 806                     (puthash key (delq proc val) url-http-open-connections)))
 807               url-http-open-connections))
 808
 809 (defun url-http-end-of-document-sentinel (proc why)
 810   ;; Sentinel used for old HTTP/0.9 or connections we know are going
 811   ;; to die as the 'end of document' notifier.
 812   (url-http-debug "url-http-end-of-document-sentinel in buffer (%s)"
 813                   (process-buffer proc))
 814   (url-http-idle-sentinel proc why)
 815   (with-current-buffer (process-buffer proc)
 816     (goto-char (point-min))
 817     (if (not (looking-at "HTTP/"))
 818         ;; HTTP/0.9 just gets passed back no matter what
 819         (url-http-activate-callback)
 820       (if (url-http-parse-headers)
 821           (url-http-activate-callback)))))
 822
 823 (defun url-http-simple-after-change-function (st nd length)
 824   ;; Function used when we do NOT know how long the document is going to be
 825   ;; Just _very_ simple 'downloaded %d' type of info.
 826   (declare (special url-http-end-of-headers))
 827   (url-lazy-message "Reading %s..." (url-pretty-length nd)))
 828
 829 (defun url-http-content-length-after-change-function (st nd length)
 830   "Function used when we DO know how long the document is going to be.
 831 More sophisticated percentage downloaded, etc.
 832 Also does minimal parsing of HTTP headers and will actually cause
 833 the callback to be triggered."
 834   (declare (special url-current-object
 835                     url-http-end-of-headers
 836                     url-http-content-length
 837                     url-http-content-type
 838                     url-http-process))
 839   (if url-http-content-type
 840       (url-display-percentage
 841        "Reading [%s]... %s of %s (%d%%)"
 842        (url-percentage (- nd url-http-end-of-headers)
 843                        url-http-content-length)
 844        url-http-content-type
 845        (url-pretty-length (- nd url-http-end-of-headers))
 846        (url-pretty-length url-http-content-length)
 847        (url-percentage (- nd url-http-end-of-headers)
 848                        url-http-content-length))
 849     (url-display-percentage
 850      "Reading... %s of %s (%d%%)"
 851      (url-percentage (- nd url-http-end-of-headers)
 852                      url-http-content-length)
 853      (url-pretty-length (- nd url-http-end-of-headers))
 854      (url-pretty-length url-http-content-length)
 855      (url-percentage (- nd url-http-end-of-headers)
 856                      url-http-content-length)))
 857
 858   (if (> (- nd url-http-end-of-headers) url-http-content-length)
 859       (progn
 860         ;; Found the end of the document!  Wheee!
 861         (url-display-percentage nil nil)
 862         (url-lazy-message "Reading... done.")
 863         (if (url-http-parse-headers)
 864             (url-http-activate-callback)))))
 865
 866 (defun url-http-chunked-encoding-after-change-function (st nd length)
 867   "Function used when dealing with 'chunked' encoding.
 868 Cannot give a sophisticated percentage, but we need a different
 869 function to look for the special 0-length chunk that signifies
 870 the end of the document."
 871   (declare (special url-current-object
 872                     url-http-end-of-headers
 873                     url-http-content-type
 874                     url-http-chunked-length
 875                     url-http-chunked-counter
 876                     url-http-process url-http-chunked-start))
 877   (save-excursion
 878     (goto-char st)
 879     (let ((read-next-chunk t)
 880           (case-fold-search t)
 881           (regexp nil)
 882           (no-initial-crlf nil))
 883       ;; We need to loop thru looking for more chunks even within
 884       ;; one after-change-function call.
 885       (while read-next-chunk
 886         (setq no-initial-crlf (= 0 url-http-chunked-counter))
 887         (if url-http-content-type
 888             (url-display-percentage nil
 889              "Reading [%s]... chunk #%d"
 890              url-http-content-type url-http-chunked-counter)
 891           (url-display-percentage nil
 892            "Reading... chunk #%d"
 893            url-http-chunked-counter))
 894         (url-http-debug "Reading chunk %d (%d %d %d)"
 895                         url-http-chunked-counter st nd length)
 896         (setq regexp (if no-initial-crlf
 897                          "\\([0-9a-z]+\\).*\r?\n"
 898                        "\r?\n\\([0-9a-z]+\\).*\r?\n"))
 899
 900         (if url-http-chunked-start
 901             ;; We know how long the chunk is supposed to be, skip over
 902             ;; leading crap if possible.
 903             (if (> nd (+ url-http-chunked-start url-http-chunked-length))
 904                 (progn
 905                   (url-http-debug "Got to the end of chunk #%d!"
 906                                   url-http-chunked-counter)
 907                   (goto-char (+ url-http-chunked-start
 908                                 url-http-chunked-length)))
 909               (url-http-debug "Still need %d bytes to hit end of chunk"
 910                               (- (+ url-http-chunked-start
 911                                     url-http-chunked-length)
 912                                  nd))
 913               (setq read-next-chunk nil)))
 914         (if (not read-next-chunk)
 915             (url-http-debug "Still spinning for next chunk...")
 916           (if no-initial-crlf (skip-chars-forward "\r\n"))
 917           (if (not (looking-at regexp))
 918               (progn
 919            ;; Must not have received the entirety of the chunk header,
 920                 ;; need to spin some more.
 921                 (url-http-debug "Did not see start of chunk @ %d!" (point))
 922                 (setq read-next-chunk nil))
 923             (add-text-properties (match-beginning 0) (match-end 0)
 924                                  (list 'start-open t
 925                                        'end-open t
 926                                        'chunked-encoding t
 927                                        'face 'cursor
 928                                        'invisible t))
 929             (setq url-http-chunked-length (string-to-number (buffer-substring
 930                                                              (match-beginning 1)
 931                                                              (match-end 1))
 932                                                             16)
 933                   url-http-chunked-counter (1+ url-http-chunked-counter)
 934                   url-http-chunked-start (set-marker
 935                                           (or url-http-chunked-start
 936                                               (make-marker))
 937                                           (match-end 0)))
 938 ;           (if (not url-http-debug)
 939                 (delete-region (match-beginning 0) (match-end 0));)
 940             (url-http-debug "Saw start of chunk %d (length=%d, start=%d"
 941                             url-http-chunked-counter url-http-chunked-length
 942                             (marker-position url-http-chunked-start))
 943             (if (= 0 url-http-chunked-length)
 944                 (progn
 945                   ;; Found the end of the document!  Wheee!
 946                   (url-http-debug "Saw end of stream chunk!")
 947                   (setq read-next-chunk nil)
 948                   (url-display-percentage nil nil)
 949                   ;; Every chunk, even the last 0-length one, is
 950                   ;; terminated by CRLF.  Skip it.
 951                   (when (looking-at "\r?\n")
 952                     (url-http-debug "Removing terminator of last chunk")
 953                     (delete-region (match-beginning 0) (match-end 0)))
 954                   (if (re-search-forward "^\r*$" nil t)
 955                       (url-http-debug "Saw end of trailers..."))
 956                   (if (url-http-parse-headers)
 957                       (url-http-activate-callback))))))))))
 958
 959 (defun url-http-wait-for-headers-change-function (st nd length)
 960   ;; This will wait for the headers to arrive and then splice in the
 961   ;; next appropriate after-change-function, etc.
 962   (declare (special url-current-object
 963                     url-http-end-of-headers
 964                     url-http-content-type
 965                     url-http-content-length
 966                     url-http-transfer-encoding
 967                     url-callback-function
 968                     url-callback-arguments
 969                     url-http-process
 970                     url-http-method
 971                     url-http-after-change-function
 972                     url-http-response-status))
 973   (url-http-debug "url-http-wait-for-headers-change-function (%s)"
 974                   (buffer-name))
 975   (when (not (bobp))
 976     (let ((end-of-headers nil)
 977           (old-http nil)
 978           (content-length nil))
 979       (goto-char (point-min))
 980       (if (and (looking-at ".*\n")      ; have one line at least
 981                (not (looking-at "^HTTP/[1-9]\\.[0-9]")))
 982           ;; Not HTTP/x.y data, must be 0.9
 983           ;; God, I wish this could die.
 984           (setq end-of-headers t
 985                 url-http-end-of-headers 0
 986                 old-http t)
 987         (when (re-search-forward "^\r*$" nil t)
 988           ;; Saw the end of the headers
 989           (url-http-debug "Saw end of headers... (%s)" (buffer-name))
 990           (setq url-http-end-of-headers (set-marker (make-marker)
 991                                                     (point))
 992                 end-of-headers t)
 993           (url-http-clean-headers)))
 994
 995       (if (not end-of-headers)
 996           ;; Haven't seen the end of the headers yet, need to wait
 997           ;; for more data to arrive.
 998           nil
 999         (if old-http
1000             (message "HTTP/0.9 How I hate thee!")
1001           (progn
1002             (url-http-parse-response)
1003             (mail-narrow-to-head)
1004             ;;(narrow-to-region (point-min) url-http-end-of-headers)
1005             (setq url-http-transfer-encoding (mail-fetch-field
1006                                               "transfer-encoding")
1007                   url-http-content-type (mail-fetch-field "content-type"))
1008             (if (mail-fetch-field "content-length")
1009                 (setq url-http-content-length
1010                       (string-to-number (mail-fetch-field "content-length"))))
1011             (widen)))
1012         (when url-http-transfer-encoding
1013           (setq url-http-transfer-encoding
1014                 (downcase url-http-transfer-encoding)))
1015
1016         (cond
1017          ((or (= url-http-response-status 204)
1018               (= url-http-response-status 205))
1019           (url-http-debug "%d response must have headers only (%s)."
1020                           url-http-response-status (buffer-name))
1021           (when (url-http-parse-headers)
1022             (url-http-activate-callback)))
1023          ((string= "HEAD" url-http-method)
1024           ;; A HEAD request is _ALWAYS_ terminated by the header
1025           ;; information, regardless of any entity headers,
1026           ;; according to section 4.4 of the HTTP/1.1 draft.
1027           (url-http-debug "HEAD request must have headers only (%s)."
1028                           (buffer-name))
1029           (when (url-http-parse-headers)
1030             (url-http-activate-callback)))
1031          ((string= "CONNECT" url-http-method)
1032           ;; A CONNECT request is finished, but we cannot stick this
1033           ;; back on the free connectin list
1034           (url-http-debug "CONNECT request must have headers only.")
1035           (when (url-http-parse-headers)
1036             (url-http-activate-callback)))
1037          ((equal url-http-response-status 304)
1038           ;; Only allowed to have a header section.  We have to handle
1039           ;; this here instead of in url-http-parse-headers because if
1040           ;; you have a cached copy of something without a known
1041           ;; content-length, and try to retrieve it from the cache, we'd
1042           ;; fall into the 'being dumb' section and wait for the
1043           ;; connection to terminate, which means we'd wait for 10
1044           ;; seconds for the keep-alives to time out on some servers.
1045           (when (url-http-parse-headers)
1046             (url-http-activate-callback)))
1047          (old-http
1048           ;; HTTP/0.9 always signaled end-of-connection by closing the
1049           ;; connection.
1050           (url-http-debug
1051            "Saw HTTP/0.9 response, connection closed means end of document.")
1052           (setq url-http-after-change-function
1053                 'url-http-simple-after-change-function))
1054          ((equal url-http-transfer-encoding "chunked")
1055           (url-http-debug "Saw chunked encoding.")
1056           (setq url-http-after-change-function
1057                 'url-http-chunked-encoding-after-change-function)
1058           (when (> nd url-http-end-of-headers)
1059             (url-http-debug
1060              "Calling initial chunked-encoding for extra data at end of headers")
1061             (url-http-chunked-encoding-after-change-function
1062              (marker-position url-http-end-of-headers) nd
1063              (- nd url-http-end-of-headers))))
1064          ((integerp url-http-content-length)
1065           (url-http-debug
1066            "Got a content-length, being smart about document end.")
1067           (setq url-http-after-change-function
1068                 'url-http-content-length-after-change-function)
1069           (cond
1070            ((= 0 url-http-content-length)
1071             ;; We got a NULL body!  Activate the callback
1072             ;; immediately!
1073             (url-http-debug
1074              "Got 0-length content-length, activating callback immediately.")
1075             (when (url-http-parse-headers)
1076               (url-http-activate-callback)))
1077            ((> nd url-http-end-of-headers)
1078             ;; Have some leftover data
1079             (url-http-debug "Calling initial content-length for extra data at end of headers")
1080             (url-http-content-length-after-change-function
1081              (marker-position url-http-end-of-headers)
1082              nd
1083              (- nd url-http-end-of-headers)))
1084            (t
1085             nil)))
1086          (t
1087           (url-http-debug "No content-length, being dumb.")
1088           (setq url-http-after-change-function
1089                 'url-http-simple-after-change-function)))))
1090     ;; We are still at the beginning of the buffer... must just be
1091     ;; waiting for a response.
1092     (url-http-debug "Spinning waiting for headers..."))
1093   (goto-char (point-max)))
1094
1095 ;;;###autoload
1096 (defun url-http (url callback cbargs)
1097   "Retrieve URL via HTTP asynchronously.
1098 URL must be a parsed URL.  See `url-generic-parse-url' for details.
1099 When retrieval is completed, the function CALLBACK is executed with
1100 CBARGS as the arguments."
1101   (check-type url vector "Need a pre-parsed URL.")
1102   (declare (special url-current-object
1103                     url-http-end-of-headers
1104                     url-http-content-type
1105                     url-http-content-length
1106                     url-http-transfer-encoding
1107                     url-http-after-change-function
1108                     url-callback-function
1109                     url-callback-arguments
1110                     url-http-method
1111                     url-http-extra-headers
1112                     url-http-data
1113                     url-http-chunked-length
1114                     url-http-chunked-start
1115                     url-http-chunked-counter
1116                     url-http-process))
1117   (let* ((host (url-host (or url-using-proxy url)))
1118          (port (url-port (or url-using-proxy url)))
1119          (connection (url-http-find-free-connection host port))
1120          (buffer (generate-new-buffer (format " *http %s:%d*" host port))))
1121     (if (not connection)
1122         ;; Failed to open the connection for some reason
1123         (progn
1124           (kill-buffer buffer)
1125           (setq buffer nil)
1126           (error "Could not create connection to %s:%d" host port))
1127       (with-current-buffer buffer
1128         (mm-disable-multibyte)
1129         (setq url-current-object url
1130               mode-line-format "%b [%s]")
1131
1132         (dolist (var '(url-http-end-of-headers
1133                        url-http-content-type
1134                        url-http-content-length
1135                        url-http-transfer-encoding
1136                        url-http-after-change-function
1137                        url-http-response-version
1138                        url-http-response-status
1139                        url-http-chunked-length
1140                        url-http-chunked-counter
1141                        url-http-chunked-start
1142                        url-callback-function
1143                        url-callback-arguments
1144                        url-http-process
1145                        url-http-method
1146                        url-http-extra-headers
1147                        url-http-data
1148                        url-http-target-url
1149                        url-http-connection-opened
1150                        url-http-proxy))
1151           (set (make-local-variable var) nil))
1152
1153         (setq url-http-method (or url-request-method "GET")
1154               url-http-extra-headers url-request-extra-headers
1155               url-http-data url-request-data
1156               url-http-process connection
1157               url-http-chunked-length nil
1158               url-http-chunked-start nil
1159               url-http-chunked-counter 0
1160               url-callback-function callback
1161               url-callback-arguments cbargs
1162               url-http-after-change-function 'url-http-wait-for-headers-change-function
1163               url-http-target-url url-current-object
1164               url-http-connection-opened nil
1165               url-http-proxy url-using-proxy)
1166
1167         (set-process-buffer connection buffer)
1168         (set-process-filter connection 'url-http-generic-filter)
1169         (let ((status (process-status connection)))
1170           (cond
1171            ((eq status 'connect)
1172             ;; Asynchronous connection
1173             (set-process-sentinel connection 'url-http-async-sentinel))
1174            ((eq status 'failed)
1175             ;; Asynchronous connection failed
1176             (error "Could not create connection to %s:%d" host port))
1177            (t
1178             (set-process-sentinel connection 'url-http-end-of-document-sentinel)
1179             (process-send-string connection (url-http-create-request)))))))
1180     buffer))
1181
1182 (defun url-http-async-sentinel (proc why)
1183   (declare (special url-callback-arguments))
1184   ;; We are performing an asynchronous connection, and a status change
1185   ;; has occurred.
1186   (with-current-buffer (process-buffer proc)
1187     (cond
1188      (url-http-connection-opened
1189       (url-http-end-of-document-sentinel proc why))
1190      ((string= (substring why 0 4) "open")
1191       (setq url-http-connection-opened t)
1192       (process-send-string proc (url-http-create-request)))
1193      (t
1194       (setf (car url-callback-arguments)
1195             (nconc (list :error (list 'error 'connection-failed why
1196                                       :host (url-host (or url-http-proxy url-current-object))
1197                                       :service (url-port (or url-http-proxy url-current-object))))
1198                    (car url-callback-arguments)))
1199       (url-http-activate-callback)))))
1200
1201 ;; Since Emacs 19/20 does not allow you to change the
1202 ;; `after-change-functions' hook in the midst of running them, we fake
1203 ;; an after change by hooking into the process filter and inserting
1204 ;; the data ourselves.  This is slightly less efficient, but there
1205 ;; were tons of weird ways the after-change code was biting us in the
1206 ;; shorts.
1207 (defun url-http-generic-filter (proc data)
1208   ;; Sometimes we get a zero-length data chunk after the process has
1209   ;; been changed to 'free', which means it has no buffer associated
1210   ;; with it.  Do nothing if there is no buffer, or 0 length data.
1211   (declare (special url-http-after-change-function))
1212   (and (process-buffer proc)
1213        (/= (length data) 0)
1214        (with-current-buffer (process-buffer proc)
1215          (url-http-debug "Calling after change function `%s' for `%S'" url-http-after-change-function proc)
1216          (funcall url-http-after-change-function
1217                   (point-max)
1218                   (progn
1219                     (goto-char (point-max))
1220                     (insert data)
1221                     (point-max))
1222                   (length data)))))
1223
1224 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1225 ;;; file-name-handler stuff from here on out
1226 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1227 (defalias 'url-http-symbol-value-in-buffer
1228   (if (fboundp 'symbol-value-in-buffer)
1229       'symbol-value-in-buffer
1230     (lambda (symbol buffer &optional unbound-value)
1231       "Return the value of SYMBOL in BUFFER, or UNBOUND-VALUE if it is unbound."
1232       (with-current-buffer buffer
1233         (if (not (boundp symbol))
1234             unbound-value
1235           (symbol-value symbol))))))
1236
1237 (defun url-http-head (url)
1238   (let ((url-request-method "HEAD")
1239         (url-request-data nil))
1240     (url-retrieve-synchronously url)))
1241
1242 ;;;###autoload
1243 (defun url-http-file-exists-p (url)
1244   (let ((status nil)
1245         (exists nil)
1246         (buffer (url-http-head url)))
1247     (if (not buffer)
1248         (setq exists nil)
1249       (setq status (url-http-symbol-value-in-buffer 'url-http-response-status
1250                                                     buffer 500)
1251             exists (and (integerp status)
1252                         (>= status 200) (< status 300)))
1253       (kill-buffer buffer))
1254     exists))
1255
1256 ;;;###autoload
1257 (defalias 'url-http-file-readable-p 'url-http-file-exists-p)
1258
1259 (defun url-http-head-file-attributes (url &optional id-format)
1260   (let ((buffer (url-http-head url)))
1261     (when buffer
1262       (prog1
1263           (list
1264            nil                          ;dir / link / normal file
1265            1                            ;number of links to file.
1266            0 0                          ;uid ; gid
1267            nil nil nil                  ;atime ; mtime ; ctime
1268            (url-http-symbol-value-in-buffer 'url-http-content-length
1269                                             buffer -1)
1270            (eval-when-compile (make-string 10 ?-))
1271            nil nil nil)          ;whether gid would change ; inode ; device.
1272         (kill-buffer buffer)))))
1273
1274 (declare-function url-dav-file-attributes (url &optional id-format))
1275
1276 ;;;###autoload
1277 (defun url-http-file-attributes (url &optional id-format)
1278   (if (url-dav-supported-p url)
1279       (url-dav-file-attributes url id-format)
1280     (url-http-head-file-attributes url id-format)))
1281
1282 ;;;###autoload
1283 (defun url-http-options (url)
1284   "Return a property list describing options available for URL.
1285 This list is retrieved using the `OPTIONS' HTTP method.
1286
1287 Property list members:
1288
1289 methods
1290   A list of symbols specifying what HTTP methods the resource
1291   supports.
1292
1293 dav
1294   A list of numbers specifying what DAV protocol/schema versions are
1295   supported.
1296
1297 dasl
1298   A list of supported DASL search types supported (string form)
1299
1300 ranges
1301   A list of the units available for use in partial document fetches.
1302
1303 p3p
1304   The `Platform For Privacy Protection' description for the resource.
1305   Currently this is just the raw header contents.  This is likely to
1306   change once P3P is formally supported by the URL package or
1307   Emacs/W3."
1308   (let* ((url-request-method "OPTIONS")
1309          (url-request-data nil)
1310          (buffer (url-retrieve-synchronously url))
1311          (header nil)
1312          (options nil))
1313     (when (and buffer (= 2 (/ (url-http-symbol-value-in-buffer
1314                                'url-http-response-status buffer 0) 100)))
1315       ;; Only parse the options if we got a 2xx response code!
1316       (with-current-buffer buffer
1317         (save-restriction
1318           (save-match-data
1319             (mail-narrow-to-head)
1320
1321             ;; Figure out what methods are supported.
1322             (when (setq header (mail-fetch-field "allow"))
1323               (setq options (plist-put
1324                              options 'methods
1325                              (mapcar 'intern (split-string header "[ ,]+")))))
1326
1327             ;; Check for DAV
1328             (when (setq header (mail-fetch-field "dav"))
1329               (setq options (plist-put
1330                              options 'dav
1331                              (delq 0
1332                                    (mapcar 'string-to-number
1333                                            (split-string header "[, ]+"))))))
1334
1335             ;; Now for DASL
1336             (when (setq header (mail-fetch-field "dasl"))
1337               (setq options (plist-put
1338                              options 'dasl
1339                              (split-string header "[, ]+"))))
1340
1341             ;; P3P - should get more detailed here.  FIXME
1342             (when (setq header (mail-fetch-field "p3p"))
1343               (setq options (plist-put options 'p3p header)))
1344
1345             ;; Check for whether they accept byte-range requests.
1346             (when (setq header (mail-fetch-field "accept-ranges"))
1347               (setq options (plist-put
1348                              options 'ranges
1349                              (delq 'none
1350                                    (mapcar 'intern
1351                                            (split-string header "[, ]+"))))))
1352             ))))
1353     (if buffer (kill-buffer buffer))
1354     options))
1355
1356 ;; HTTPS.  This used to be in url-https.el, but that file collides
1357 ;; with url-http.el on systems with 8-character file names.
1358 (require 'tls)
1359
1360 ;;;###autoload
1361 (defconst url-https-default-port 443 "Default HTTPS port.")
1362 ;;;###autoload
1363 (defconst url-https-asynchronous-p t "HTTPS retrievals are asynchronous.")
1364 ;;;###autoload
1365 (defalias 'url-https-expand-file-name 'url-http-expand-file-name)
1366
1367 (defmacro url-https-create-secure-wrapper (method args)
1368   `(defun ,(intern (format (if method "url-https-%s" "url-https") method)) ,args
1369     ,(format "HTTPS wrapper around `%s' call." (or method "url-http"))
1370     (let ((url-gateway-method 'tls))
1371       (,(intern (format (if method "url-http-%s" "url-http") method))
1372        ,@(remove '&rest (remove '&optional args))))))
1373
1374 ;;;###autoload (autoload 'url-https "url-http")
1375 (url-https-create-secure-wrapper nil (url callback cbargs))
1376 ;;;###autoload (autoload 'url-https-file-exists-p "url-http")
1377 (url-https-create-secure-wrapper file-exists-p (url))
1378 ;;;###autoload (autoload 'url-https-file-readable-p "url-http")
1379 (url-https-create-secure-wrapper file-readable-p (url))
1380 ;;;###autoload (autoload 'url-https-file-attributes "url-http")
1381 (url-https-create-secure-wrapper file-attributes (url &optional id-format))
1382
1383 (provide 'url-http)
1384
1385 ;; arch-tag: ba7c59ae-c0f4-4a31-9617-d85f221732ee
1386 ;;; url-http.el ends here