lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile
  28   (require 'cl))
  29
  30 (require 'cus-face)
  31
  32 \f
  33 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  34 ;;; Font selection.
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36
  37 (defgroup font-selection nil
  38   "Influencing face font selection."
  39   :group 'faces)
  40
  41
  42 (defcustom face-font-selection-order
  43   '(:width :height :weight :slant)
  44   "*A list specifying how face font selection chooses fonts.
  45 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  46 must appear once in the list, and the list must not contain any other
  47 elements.  Font selection tries to find a best matching font for
  48 those face attributes first that appear first in the list.  For
  49 example, if `:slant' appears before `:height', font selection first
  50 tries to find a font with a suitable slant, even if this results in
  51 a font height that isn't optimal."
  52   :tag "Font selection order."
  53   :group 'font-selection
  54   :set #'(lambda (symbol value)
  55            (set-default symbol value)
  56            (internal-set-font-selection-order value)))
  57
  58 ;; This is defined originally in {w32,x}faces.c.
  59 (defcustom face-font-family-alternatives
  60   '(("courier" "fixed")
  61     ("helv" "helvetica" "arial" "fixed"))
  62   "*Alist of alternative font family names.
  63 Each element has the the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  64 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  65 ALTERNATIVE2 etc."
  66   :tag "Alternative font families to try."
  67   :group 'font-selection
  68   :set #'(lambda (symbol value)
  69            (set-default symbol value)
  70            (internal-set-alternative-font-family-alist value)))
  71
  72
  73 \f
  74 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  75 ;;; Creation, copying.
  76 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  77
  78
  79 (defun face-list ()
  80   "Return a list of all defined face names."
  81   (mapcar #'car face-new-frame-defaults))
  82
  83
  84 ;;; ### If not frame-local initialize by what X resources?
  85
  86 (defun make-face (face &optional no-init-from-resources)
  87   "Define a new face with name FACE, a symbol.
  88 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
  89 variants of FACE from X resources.  (X resources recognized are found
  90 in the global variable `face-x-resources'.)  If FACE is already known
  91 as a face, leave it unmodified.  Value is FACE."
  92   (interactive "SMake face: ")
  93   (unless (facep face)
  94     ;; Make frame-local faces (this also makes the global one).
  95     (dolist (frame (frame-list))
  96       (internal-make-lisp-face face frame))
  97     ;; Add the face to the face menu.
  98     (when (fboundp 'facemenu-add-new-face)
  99       (facemenu-add-new-face face))
 100     ;; Define frame-local faces for all frames from X resources.
 101     (unless no-init-from-resources
 102       (make-face-x-resource-internal face)))
 103   face)
 104
 105
 106 (defun make-empty-face (face)
 107   "Define a new, empty face with name FACE.
 108 If the face already exists, it is left unmodified.  Value is FACE."
 109   (interactive "SMake empty face: ")
 110   (make-face face 'no-init-from-resources))
 111
 112
 113 (defun copy-face (old-face new-face &optional frame new-frame)
 114   "Define a face just like OLD-FACE, with name NEW-FACE.
 115
 116 If NEW-FACE already exists as a face, it is modified to be like
 117 OLD-FACE.  If it doesn't already exist, it is created.
 118
 119 If the optional argument FRAME is given as a frame,  NEW-FACE is
 120 changed on FRAME only.
 121 If FRAME is t, the frame-independent default specification for OLD-FACE
 122 is copied to NEW-FACE.
 123 If FRAME is nil, copying is done for the frame-independent defaults
 124 and for each existing frame.
 125
 126 If the optional fourth argument NEW-FRAME is given,
 127 copy the information from face OLD-FACE on frame FRAME
 128 to NEW-FACE on frame NEW-FRAME."
 129   (let ((inhibit-quit t))
 130     (if (null frame)
 131         (progn
 132           (dolist (frame (frame-list))
 133             (copy-face old-face new-face frame))
 134           (copy-face old-face new-face t))
 135       (internal-copy-lisp-face old-face new-face frame new-frame))
 136     new-face))
 137
 138
 139 \f
 140 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 141 ;;; Obsolete functions
 142 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 143
 144 ;; The functions in this section are defined because Lisp packages use
 145 ;; them, despite the prefix `internal-' suggesting that they are
 146 ;; private to the face implementation.
 147
 148 (defun internal-find-face (name &optional frame)
 149   "Retrieve the face named NAME.
 150 Return nil if there is no such face.
 151 If the optional argument FRAME is given, this gets the face NAME for
 152 that frame; otherwise, it uses the selected frame.
 153 If FRAME is the symbol t, then the global, non-frame face is returned.
 154 If NAME is already a face, it is simply returned.
 155
 156 This function is defined for compatibility with Emacs 20.2.  It
 157 should not be used anymore."
 158   (facep name))
 159 (make-obsolete 'internal-find-face 'facep)
 160
 161
 162 (defun internal-get-face (name &optional frame)
 163   "Retrieve the face named NAME; error if there is none.
 164 If the optional argument FRAME is given, this gets the face NAME for
 165 that frame; otherwise, it uses the selected frame.
 166 If FRAME is the symbol t, then the global, non-frame face is returned.
 167 If NAME is already a face, it is simply returned.
 168
 169 This function is defined for compatibility with Emacs 20.2.  It
 170 should not be used anymore."
 171   (or (internal-find-face name frame)
 172       (check-face name)))
 173 (make-obsolete 'internal-get-face "See `facep' and `check-face'.")
 174
 175 \f
 176 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 177 ;;; Predicates, type checks.
 178 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 179
 180 (defun facep (face)
 181   "Return non-nil if FACE is a face name."
 182   (internal-lisp-face-p face))
 183
 184
 185 (defun check-face (face)
 186   "Signal an error if FACE doesn't name a face.
 187 Value is FACE."
 188   (unless (facep face)
 189     (error "Not a face: %s" face))
 190   face)
 191
 192
 193 ;; The ID returned is not to be confused with the internally used IDs
 194 ;; of realized faces.  The ID assigned to Lisp faces is used to
 195 ;; support faces in display table entries.
 196
 197 (defun face-id (face &optional frame)
 198   "Return the interNal ID of face with name FACE.
 199 If optional argument FRAME is nil or omitted, use the selected frame."
 200   (check-face face)
 201   (get face 'face))
 202
 203
 204 (defun face-equal (face1 face2 &optional frame)
 205   "Non-nil if faces FACE1 and FACE2 are equal.
 206 Faces are considered equal if all their attributes are equal.
 207 If the optional argument FRAME is given, report on face FACE in that frame.
 208 If FRAME is t, report on the defaults for face FACE (for new frames).
 209 If FRAME is omitted or nil, use the selected frame."
 210   (internal-lisp-face-equal-p face1 face2 frame))
 211
 212
 213 (defun face-differs-from-default-p (face &optional frame)
 214   "Non-nil if FACE displays differently from the default face.
 215 If the optional argument FRAME is given, report on face FACE in that frame.
 216 If FRAME is t, report on the defaults for face FACE (for new frames).
 217 If FRAME is omitted or nil, use the selected frame.
 218 A face is considered to be ``the same'' as the default face if it is
 219 actually specified in the same way (equal attributes) or if it is
 220 fully-unspecified, and thus inherits the attributes of any face it
 221 is displayed on top of."
 222   (cond ((eq frame t) (setq frame nil))
 223         ((null frame) (setq frame (selected-frame))))
 224   (let* ((v1 (internal-lisp-face-p face frame))
 225          (n (if v1 (length v1) 0))
 226          (v2 (internal-lisp-face-p 'default frame))
 227          (i 1))
 228     (unless v1
 229       (error "Not a face: %S" face))
 230     (while (and (< i n)
 231                 (or (eq 'unspecified (aref v1 i))
 232                     (equal (aref v1 i) (aref v2 i))))
 233       (setq i (1+ i)))
 234     (< i n)))
 235
 236
 237 (defun face-nontrivial-p (face &optional frame)
 238   "True if face FACE has some non-nil attribute.
 239 If the optional argument FRAME is given, report on face FACE in that frame.
 240 If FRAME is t, report on the defaults for face FACE (for new frames).
 241 If FRAME is omitted or nil, use the selected frame."
 242   (not (internal-lisp-face-empty-p face frame)))
 243
 244
 245 \f
 246 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 247 ;;; Setting face attributes from X resources.
 248 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 249
 250 (defcustom face-x-resources
 251   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 252     (:width (".attributeWidth" . "Face.AttributeWidth"))
 253     (:height (".attributeHeight" . "Face.AttributeHeight"))
 254     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 255     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 256     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 257     (:background (".attributeBackground" . "Face.AttributeBackground"))
 258     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 259     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 260     (:box (".attributeBox" . "Face.AttributeBox"))
 261     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 262     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 263     (:stipple
 264      (".attributeStipple" . "Face.AttributeStipple")
 265      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 266     (:font (".attributeFont" . "Face.AttributeFont"))
 267     (:bold (".attributeBold" . "Face.AttributeBold"))
 268     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 269     (:font (".attributeFont" . "Face.AttributeFont")))
 270   "*List of X resources and classes for face attributes.
 271 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 272 the name of a face attribute, and each ENTRY is a cons of the form
 273 (RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 274 X resource class for the attribute."
 275   :type 'sexp
 276   :group 'faces)
 277
 278
 279 (defun set-face-attribute-from-resource (face attribute resource class frame)
 280   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 281 Value is the attribute value specified by the resource, or nil
 282 if not present.  This function displays a message if the resource
 283 specifies an invalid attribute."
 284   (let* ((face-name (face-name face))
 285          (value (internal-face-x-get-resource (concat face-name resource)
 286                                               class frame)))
 287     (when value
 288       (condition-case ()
 289           (internal-set-lisp-face-attribute-from-resource
 290            face attribute (downcase value) frame)
 291         (error
 292          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 293                   face-name frame attribute value))))
 294     value))
 295
 296
 297 (defun set-face-attributes-from-resources (face frame)
 298   "Set attributes of FACE from X resources for FRAME."
 299   (when (memq (framep frame) '(x w32))
 300     (dolist (definition face-x-resources)
 301       (let ((attribute (car definition)))
 302         (dolist (entry (cdr definition))
 303           (set-face-attribute-from-resource face attribute (car entry)
 304                                             (cdr entry) frame))))))
 305
 306
 307 (defun make-face-x-resource-internal (face &optional frame)
 308   "Fill frame-local FACE on FRAME from X resources.
 309 FRAME nil or not specified means do it for all frames."
 310   (if (null frame)
 311       (dolist (frame (frame-list))
 312         (set-face-attributes-from-resources face frame))
 313     (set-face-attributes-from-resources face frame)))
 314
 315
 316 \f
 317 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 318 ;;; Retrieving face attributes.
 319 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 320
 321 (defun face-name (face)
 322   "Return the name of face FACE."
 323   (symbol-name (check-face face)))
 324
 325
 326 (defun face-attribute (face attribute &optional frame)
 327   "Return the value of FACE's ATTRIBUTE on FRAME.
 328 If the optional argument FRAME is given, report on face FACE in that frame.
 329 If FRAME is t, report on the defaults for face FACE (for new frames).
 330 If FRAME is omitted or nil, use the selected frame."
 331   (internal-get-lisp-face-attribute face attribute frame))
 332
 333
 334 (defun face-foreground (face &optional frame)
 335   "Return the foreground color name of FACE, or nil if unspecified.
 336 If the optional argument FRAME is given, report on face FACE in that frame.
 337 If FRAME is t, report on the defaults for face FACE (for new frames).
 338 If FRAME is omitted or nil, use the selected frame."
 339   (internal-get-lisp-face-attribute face :foreground frame))
 340
 341
 342 (defun face-background (face &optional frame)
 343   "Return the background color name of FACE, or nil if unspecified.
 344 If the optional argument FRAME is given, report on face FACE in that frame.
 345 If FRAME is t, report on the defaults for face FACE (for new frames).
 346 If FRAME is omitted or nil, use the selected frame."
 347   (internal-get-lisp-face-attribute face :background frame))
 348
 349
 350 (defun face-stipple (face &optional frame)
 351  "Return the stipple pixmap name of FACE, or nil if unspecified.
 352 If the optional argument FRAME is given, report on face FACE in that frame.
 353 If FRAME is t, report on the defaults for face FACE (for new frames).
 354 If FRAME is omitted or nil, use the selected frame."
 355   (internal-get-lisp-face-attribute face :stipple frame))
 356
 357
 358 (defalias 'face-background-pixmap 'face-stipple)
 359
 360
 361 (defun face-underline-p (face &optional frame)
 362  "Return non-nil if FACE is underlined.
 363 If the optional argument FRAME is given, report on face FACE in that frame.
 364 If FRAME is t, report on the defaults for face FACE (for new frames).
 365 If FRAME is omitted or nil, use the selected frame."
 366  (eq (face-attribute face :underline frame) t))
 367
 368
 369 (defun face-inverse-video-p (face &optional frame)
 370  "Return non-nil if FACE is in inverse video on FRAME.
 371 If the optional argument FRAME is given, report on face FACE in that frame.
 372 If FRAME is t, report on the defaults for face FACE (for new frames).
 373 If FRAME is omitted or nil, use the selected frame."
 374  (eq (face-attribute face :inverse-video frame) t))
 375
 376
 377 (defun face-bold-p (face &optional frame)
 378   "Return non-nil if the font of FACE is bold on FRAME.
 379 If the optional argument FRAME is given, report on face FACE in that frame.
 380 If FRAME is t, report on the defaults for face FACE (for new frames).
 381 If FRAME is omitted or nil, use the selected frame.
 382 Use `face-attribute' for finer control."
 383   (let ((bold (face-attribute face :weight frame)))
 384     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 385
 386
 387 (defun face-italic-p (face &optional frame)
 388   "Return non-nil if the font of FACE is italic on FRAME.
 389 If the optional argument FRAME is given, report on face FACE in that frame.
 390 If FRAME is t, report on the defaults for face FACE (for new frames).
 391 If FRAME is omitted or nil, use the selected frame.
 392 Use `face-attribute' for finer control."
 393   (let ((italic (face-attribute face :slant frame)))
 394     (memq italic '(italic oblique))))
 395
 396
 397
 398
 399 \f
 400 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 401 ;;; Face documentation.
 402 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 403
 404 (defun face-documentation (face)
 405   "Get the documentation string for FACE."
 406   (get face 'face-documentation))
 407
 408
 409 (defun set-face-documentation (face string)
 410   "Set the documentation string for FACE to STRING."
 411   ;; Perhaps the text should go in DOC.
 412   (put face 'face-documentation (purecopy string)))
 413
 414
 415 (defalias 'face-doc-string 'face-documentation)
 416 (defalias 'set-face-doc-string 'set-face-documentation)
 417
 418
 419 \f
 420 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 421 ;; Setting face attributes.
 422 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 423
 424
 425 (defun set-face-attribute (face frame &rest args)
 426   "Set attributes of FACE on FRAME from ARGS.
 427
 428 FRAME nil means change attributes on all frames.  FRAME t means change
 429 the default for new frames (this is done automatically each time an
 430 attribute is changed on all frames).
 431
 432 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 433 face attribute name.  All attributes can be set to `unspecified';
 434 this fact is not further mentioned below.
 435
 436 The following attributes are recognized:
 437
 438 `:family'
 439
 440 VALUE must be a string specifying the font family, e.g. ``courier'',
 441 or a fontset alias name.  If a font family is specified, wild-cards `*'
 442 and `?' are allowed.
 443
 444 `:width'
 445
 446 VALUE specifies the relative proportionate width of the font to use.
 447 It must be one of the symbols `ultra-condensed', `extra-condensed',
 448 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 449 `extra-expanded', or `ultra-expanded'.
 450
 451 `:height'
 452
 453 VALUE must be an integer specifying the height of the font to use in
 454 1/10 pt.
 455
 456 `:weight'
 457
 458 VALUE specifies the weight of the font to use.  It must be one of the
 459 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 460 `semi-light', `light', `extra-light', `ultra-light'.
 461
 462 `:slant'
 463
 464 VALUE specifies the slant of the font to use.  It must be one of the
 465 symbols `italic', `oblique', `normal', `reverse-italic', or
 466 `reverse-oblique'.
 467
 468 `:foreground', `:background'
 469
 470 VALUE must be a color name, a string.
 471
 472 `:underline'
 473
 474 VALUE specifies whether characters in FACE should be underlined.  If
 475 VALUE is t, underline with foreground color of the face.  If VALUE is
 476 a string, underline with that color.  If VALUE is nil, explicitly
 477 don't underline.
 478
 479 `:overline'
 480
 481 VALUE specifies whether characters in FACE should be overlined.  If
 482 VALUE is t, overline with foreground color of the face.  If VALUE is a
 483 string, overline with that color.  If VALUE is nil, explicitly don't
 484 overline.
 485
 486 `:strike-through'
 487
 488 VALUE specifies whether characters in FACE should be drawn with a line
 489 striking through them.  If VALUE is t, use the foreground color of the
 490 face.  If VALUE is a string, strike-through with that color.  If VALUE
 491 is nil, explicitly don't strike through.
 492
 493 `:box'
 494
 495 VALUE specifies whether characters in FACE should have a box drawn
 496 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 497 VALUE is t, draw a box with lines of width 1 in the foreground color
 498 of the face.  If VALUE is a string, the string must be a color name,
 499 and the box is drawn in that color with a line width of 1.  Otherwise,
 500 VALUE must be a property list of the form `(:line-width WIDTH
 501 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 502 the property list, a default value will be used for the value, as
 503 specified below.  WIDTH specifies the width of the lines to draw; it
 504 defaults to 1.  COLOR is the name of the color to draw in, default is
 505 the foreground color of the face for simple boxes, and the background
 506 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 507 should be draw.  If STYLE is `released-button', draw a box looking
 508 like a released 3D button.  If STYLE is `pressed-button' draw a box
 509 that appears like a pressed button.  If STYLE is nil, the default if
 510 the property list doesn't contain a style specification, draw a 2D
 511 box.
 512
 513 `:inverse-video'
 514
 515 VALUE specifies whether characters in FACE should be displayed in
 516 inverse video.  VALUE must be one of t or nil.
 517
 518 `:stipple'
 519
 520 If VALUE is a string, it must be the name of a file of pixmap data.
 521 The directories listed in the `x-bitmap-file-path' variable are
 522 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 523 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 524 is a string containing the raw bits of the bitmap.  VALUE nil means
 525 explicitly don't use a stipple pattern.
 526
 527 For convenience, attributes `:family', `:width', `:height', `:weight',
 528 and `:slant' may also be set in one step from an X font name:
 529
 530 `:font'
 531
 532 Set font-related face attributes from VALUE.  VALUE must be a valid
 533 XLFD font name.  If it is a font name pattern, the first matching font
 534 will be used.
 535
 536 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 537 be used to specify that a bold or italic font should be used.  VALUE
 538 must be t or nil in that case.  A value of `unspecified' is not allowed."
 539   (setq args (purecopy args))
 540   (cond ((null frame)
 541          ;; Change face on all frames.
 542          (dolist (frame (frame-list))
 543            (apply #'set-face-attribute face frame args))
 544          ;; Record that as a default for new frames.
 545          (apply #'set-face-attribute face t args))
 546         (t
 547          (while args
 548            (internal-set-lisp-face-attribute face (car args)
 549                                              (purecopy (cadr args))
 550                                              frame)
 551            (setq args (cdr (cdr args)))))))
 552
 553
 554 (defun make-face-bold (face &optional frame noerror)
 555   "Make the font of FACE be bold, if possible.
 556 FRAME nil or not specified means change face on all frames.
 557 Argument NOERROR is ignored and retained for compatibility.
 558 Use `set-face-attribute' for finer control of the font weight."
 559   (interactive (list (read-face-name "Make which face bold ")))
 560   (set-face-attribute face frame :weight 'bold))
 561
 562
 563 (defun make-face-unbold (face &optional frame noerror)
 564   "Make the font of FACE be non-bold, if possible.
 565 FRAME nil or not specified means change face on all frames.
 566 Argument NOERROR is ignored and retained for compatibility."
 567   (interactive (list (read-face-name "Make which face non-bold ")))
 568   (set-face-attribute face frame :weight 'normal))
 569
 570
 571 (defun make-face-italic (face &optional frame noerror)
 572   "Make the font of FACE be italic, if possible.
 573 FRAME nil or not specified means change face on all frames.
 574 Argument NOERROR is ignored and retained for compatibility.
 575 Use `set-face-attribute' for finer control of the font slant."
 576   (interactive (list (read-face-name "Make which face italic ")))
 577   (set-face-attribute face frame :slant 'italic))
 578
 579
 580 (defun make-face-unitalic (face &optional frame noerror)
 581   "Make the font of FACE be non-italic, if possible.
 582 FRAME nil or not specified means change face on all frames.
 583 Argument NOERROR is ignored and retained for compatibility."
 584   (interactive (list (read-face-name "Make which face non-italic ")))
 585   (set-face-attribute face frame :slant 'normal))
 586
 587
 588 (defun make-face-bold-italic (face &optional frame noerror)
 589   "Make the font of FACE be bold and italic, if possible.
 590 FRAME nil or not specified means change face on all frames.
 591 Argument NOERROR is ignored and retained for compatibility.
 592 Use `set-face-attribute' for finer control of font weight and slant."
 593   (interactive (list (read-face-name "Make which face bold-italic: ")))
 594   (set-face-attribute face frame :weight 'bold :slant 'italic))
 595
 596
 597 (defun set-face-font (face font &optional frame)
 598   "Change font-related attributes of FACE to those of FONT (a string).
 599 FRAME nil or not specified means change face on all frames.
 600 This sets the attributes `:family', `:width', `:height', `:weight',
 601 and `:slant'.  When called interactively, prompt for the face and font."
 602   (interactive (read-face-and-attribute :font))
 603   (set-face-attribute face frame :font font))
 604
 605
 606 ;; Implementation note: Emulating gray background colors with a
 607 ;; stipple pattern is now part of the face realization process, and is
 608 ;; done in C depending on the frame on which the face is realized.
 609
 610 (defun set-face-background (face color &optional frame)
 611   "Change the background color of face FACE to COLOR (a string).
 612 FRAME nil or not specified means change face on all frames.
 613 When called interactively, prompt for the face and color."
 614   (interactive (read-face-and-attribute :background))
 615   (set-face-attribute face frame :background color))
 616
 617
 618 (defun set-face-foreground (face color &optional frame)
 619   "Change the foreground color of face FACE to COLOR (a string).
 620 FRAME nil or not specified means change face on all frames.
 621 When called interactively, prompt for the face and color."
 622   (interactive (read-face-and-attribute :foreground))
 623   (set-face-attribute face frame :foreground color))
 624
 625
 626 (defun set-face-stipple (face stipple &optional frame)
 627   "Change the stipple pixmap of face FACE to STIPPLE.
 628 FRAME nil or not specified means change face on all frames.
 629 STIPPLE should be a string, the name of a file of pixmap data.
 630 The directories listed in the `x-bitmap-file-path' variable are searched.
 631
 632 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 633 where WIDTH and HEIGHT are the size in pixels,
 634 and DATA is a string, containing the raw bits of the bitmap."
 635   (interactive (read-face-and-attribute :stipple))
 636   (set-face-attribute face frame :stipple stipple))
 637
 638
 639 (defun set-face-underline (face underline &optional frame)
 640   "Specify whether face FACE is underlined.
 641 UNDERLINE nil means FACE explicitly doesn't underline.
 642 UNDERLINE non-nil means FACE explicitly does underlining
 643 with the same of the foreground color.
 644 If UNDERLINE is a string, underline with the color named UNDERLINE.
 645 FRAME nil or not specified means change face on all frames.
 646 Use `set-face-attribute' to ``unspecify'' underlining."
 647   (interactive
 648    (let ((list (read-face-and-attribute :underline)))
 649      (list (car list) (eq (car (cdr list)) t))))
 650   (set-face-attribute face frame :underline underline))
 651
 652
 653 (defun set-face-underline-p (face underline-p &optional frame)
 654   "Specify whether face FACE is underlined.
 655 UNDERLINE-P nil means FACE explicitly doesn't underline.
 656 UNDERLINE-P non-nil means FACE explicitly does underlining.
 657 FRAME nil or not specified means change face on all frames.
 658 Use `set-face-attribute' to ``unspecify'' underlining."
 659   (interactive
 660    (let ((list (read-face-and-attribute :underline)))
 661      (list (car list) (eq (car (cdr list)) t))))
 662   (set-face-attribute face frame :underline underline-p))
 663
 664
 665 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 666   "Specify whether face FACE is in inverse video.
 667 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 668 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 669 FRAME nil or not specified means change face on all frames.
 670 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 671   (interactive
 672    (let ((list (read-face-and-attribute :inverse-video)))
 673      (list (car list) (eq (car (cdr list)) t))))
 674   (set-face-attribute face frame :inverse-video inverse-video-p))
 675
 676
 677 (defun set-face-bold-p (face bold-p &optional frame)
 678   "Specify whether face FACE is bold.
 679 BOLD-P non-nil means FACE should explicitly display bold.
 680 BOLD-P nil means FACE should explicitly display non-bold.
 681 FRAME nil or not specified means change face on all frames.
 682 Use `set-face-attribute' or `modify-face' for finer control."
 683   (if (null bold-p)
 684       (make-face-unbold face frame)
 685     (make-face-bold face frame)))
 686
 687
 688 (defun set-face-italic-p (face italic-p &optional frame)
 689   "Specify whether face FACE is italic.
 690 ITALIC-P non-nil means FACE should explicitly display italic.
 691 ITALIC-P nil means FACE should explicitly display non-italic.
 692 FRAME nil or not specified means change face on all frames.
 693 Use `set-face-attribute' or `modify-face' for finer control."
 694   (if (null italic-p)
 695       (make-face-unitalic face frame)
 696     (make-face-italic face frame)))
 697
 698
 699 (defalias 'set-face-background-pixmap 'set-face-stipple)
 700
 701
 702 (defun invert-face (face &optional frame)
 703   "Swap the foreground and background colors of FACE.
 704 FRAME nil or not specified means change face on all frames.
 705 If FACE specifies neither foreground nor background color,
 706 set its foreground and background to the background and foreground
 707 of the default face.  Value is FACE."
 708   (interactive (list (read-face-name "Invert face ")))
 709   (let ((fg (face-attribute face :foreground frame))
 710         (bg (face-attribute face :background frame)))
 711     (if (or fg bg)
 712         (set-face-attribute face frame :foreground bg :background fg)
 713       (set-face-attribute face frame
 714                           :foreground
 715                           (face-attribute 'default :background frame)
 716                           :background
 717                           (face-attribute 'default :foreground frame))))
 718   face)
 719
 720 \f
 721 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 722 ;;; Interactively modifying faces.
 723 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 724
 725 (defun read-face-name (prompt)
 726   "Read and return a face symbol, prompting with PROMPT.
 727 Value is a symbol naming a known face."
 728   (let ((face-list (mapcar #'(lambda (x) (cons (symbol-name x) x))
 729                            (face-list)))
 730         (def (thing-at-point 'symbol))
 731         face)
 732     (cond ((assoc def face-list)
 733            (setq prompt (concat prompt "(default " def "): ")))
 734           (t (setq def nil)
 735              (setq prompt (concat prompt ": "))))
 736     (while (equal "" (setq face (completing-read
 737                                  prompt face-list nil t nil nil def))))
 738     (intern face)))
 739
 740
 741 (defun face-valid-attribute-values (attribute &optional frame)
 742   "Return valid values for face attribute ATTRIBUTE.
 743 The optional argument FRAME is used to determine available fonts
 744 and colors.  If it is nil or not specified, the selected frame is
 745 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 746 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 747 an integer value."
 748   (let (valid)
 749     (setq valid
 750           (case attribute
 751             (:family
 752              (if window-system
 753                  (mapcar #'(lambda (x) (cons (car x) (car x)))
 754                          (x-font-family-list))
 755                ;; Only one font on TTYs.
 756                (list (cons "default" "default"))))
 757             ((:width :weight :slant :inverse-video)
 758              (mapcar #'(lambda (x) (cons (symbol-name x) x))
 759                      (internal-lisp-face-attribute-values attribute)))
 760             ((:underline :overline :strike-through :box)
 761              (if window-system
 762                  (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 763                                 (internal-lisp-face-attribute-values attribute))
 764                         (mapcar #'(lambda (c) (cons c c))
 765                                 (x-defined-colors frame)))
 766                (mapcar #'(lambda (x) (cons (symbol-name x) x))
 767                        (internal-lisp-face-attribute-values attribute))))
 768             ((:foreground :background)
 769              (mapcar #'(lambda (c) (cons c c))
 770                      (defined-colors frame)))
 771             ((:height)
 772              'integerp)
 773             (:stipple
 774              (and (memq window-system '(x w32))
 775                   (mapcar #'list
 776                           (apply #'nconc (mapcar #'directory-files
 777                                                  x-bitmap-file-path)))))
 778             (t
 779              (error "Internal error"))))
 780     (if (listp valid)
 781         (nconc (list (cons "unspecified" 'unspecified)) valid)
 782       valid)))
 783
 784
 785
 786 (defvar face-attribute-name-alist
 787   '((:family . "font family")
 788     (:width . "character set width")
 789     (:height . "height in 1/10 pt")
 790     (:weight . "weight")
 791     (:slant . "slant")
 792     (:underline . "underline")
 793     (:overline . "overline")
 794     (:strike-through . "strike-through")
 795     (:box . "box")
 796     (:inverse-video . "inverse-video display")
 797     (:foreground . "foreground color")
 798     (:background . "background color")
 799     (:stipple . "background stipple"))
 800   "An alist of descriptive names for face attributes.
 801 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 802 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 803 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 804
 805
 806 (defun face-descriptive-attribute-name (attribute)
 807   "Return a descriptive name for ATTRIBUTE."
 808   (cdr (assq attribute face-attribute-name-alist)))
 809
 810
 811 (defun face-read-string (face default name &optional completion-alist)
 812   "Interactively read a face attribute string value.
 813 FACE is the face whose attribute is read.  DEFAULT is the default
 814 value to return if no new value is entered.  NAME is a descriptive
 815 name of the attribute for prompting.  COMPLETION-ALIST is an alist
 816 of valid values, if non-nil.
 817
 818 Entering nothing accepts the default value DEFAULT.
 819 Value is the new attribute value."
 820   (let* ((completion-ignore-case t)
 821          (value (completing-read
 822                  (if default
 823                      (format "Set face %s %s (default %s): "
 824                              face name (downcase (if (symbolp default)
 825                                                      (symbol-name default)
 826                                                    default)))
 827                    (format "Set face %s %s: " face name))
 828                  completion-alist)))
 829     (if (equal value "") default value)))
 830
 831
 832 (defun face-read-integer (face default name)
 833   "Interactively read an integer face attribute value.
 834 FACE is the face whose attribute is read.  DEFAULT is the default
 835 value to return if no new value is entered.  NAME is a descriptive
 836 name of the attribute for prompting.  Value is the new attribute value."
 837   (let ((new-value
 838          (face-read-string face
 839                            (if (memq default
 840                                      '(unspecified
 841                                        "unspecified-fg"
 842                                        "unspecified-bg"))
 843                                default
 844                              (int-to-string default))
 845                            name
 846                            (list (cons "unspecified" 'unspecified)))))
 847     (if (memq new-value '(unspecified "unspecified-fg" "unspecified-bg"))
 848         new-value
 849       (string-to-int new-value))))
 850
 851
 852 (defun read-face-attribute (face attribute &optional frame)
 853   "Interactively read a new value for FACE's ATTRIBUTE.
 854 Optional argument FRAME nil or unspecified means read an attribute value
 855 of a global face.  Value is the new attribute value."
 856   (let* ((old-value (face-attribute face attribute frame))
 857          (attribute-name (face-descriptive-attribute-name attribute))
 858          (valid (face-valid-attribute-values attribute frame))
 859          new-value)
 860     ;; Represent complex attribute values as strings by printing them
 861     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
 862     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
 863     ;; SHADOW)'.
 864     (when (and (or (eq attribute :stipple)
 865                    (eq attribute :box))
 866                (or (consp old-value)
 867                    (vectorp old-value)))
 868       (setq old-value (prin1-to-string old-value)))
 869     (cond ((listp valid)
 870            (setq new-value
 871                  (face-read-string face old-value attribute-name valid))
 872            ;; Terminal frames can support colors that don't appear
 873            ;; explicitly in VALID, using color approximation code
 874            ;; in tty-colors.el.
 875            (if (and (memq attribute '(:foreground :background))
 876                     (not (memq window-system '(x w32 mac)))
 877                     (not (memq new-value
 878                                '(unspecified
 879                                  "unspecified-fg"
 880                                  "unspecified-bg"))))
 881                (setq new-value (car (tty-color-desc new-value frame))))
 882            (unless (eq new-value 'unspecified)
 883              (setq new-value (cdr (assoc new-value valid)))))
 884           ((eq valid 'integerp)
 885            (setq new-value (face-read-integer face old-value attribute-name)))
 886           (t (error "Internal error")))
 887     ;; Convert stipple and box value text we read back to a list or
 888     ;; vector if it looks like one.  This makes the assumption that a
 889     ;; pixmap file name won't start with an open-paren.
 890     (when (and (or (eq attribute :stipple)
 891                    (eq attribute :box))
 892                (stringp new-value)
 893                (string-match "^[[(]" new-value))
 894       (setq new-value (read new-value)))
 895     new-value))
 896
 897
 898 (defun read-face-font (face &optional frame)
 899   "Read the name of a font for FACE on FRAME.
 900 If optional argument FRAME Is nil or omitted, use the selected frame."
 901   (let ((completion-ignore-case t))
 902     (completing-read (format "Set font attributes of face %s from font: " face)
 903                      (mapcar 'list (x-list-fonts "*" nil frame)))))
 904
 905
 906 (defun read-all-face-attributes (face &optional frame)
 907   "Interactively read all attributes for FACE.
 908 If optional argument FRAME Is nil or omitted, use the selected frame.
 909 Value is a property list of attribute names and new values."
 910   (let (result)
 911     (dolist (attribute face-attribute-name-alist result)
 912       (setq result (cons (car attribute)
 913                          (cons (read-face-attribute face (car attribute) frame)
 914                                result))))))
 915
 916
 917 (defun modify-face (&optional frame)
 918   "Modify attributes of faces interactively.
 919 If optional argument FRAME is nil or omitted, modify the face used
 920 for newly created frame, i.e. the global face."
 921   (interactive)
 922   (let ((face (read-face-name "Modify face ")))
 923     (apply #'set-face-attribute face frame
 924            (read-all-face-attributes face frame))))
 925
 926
 927 (defun read-face-and-attribute (attribute &optional frame)
 928   "Read face name and face attribute value.
 929 ATTRIBUTE is the attribute whose new value is read.
 930 FRAME nil or unspecified means read attribute value of global face.
 931 Value is a list (FACE NEW-VALUE) where FACE is the face read
 932 (a symbol), and NEW-VALUE is value read."
 933   (cond ((eq attribute :font)
 934          (let* ((prompt (format "Set font-related attributes of face "))
 935                 (face (read-face-name prompt))
 936                 (font (read-face-font face frame)))
 937            (list face font)))
 938         (t
 939          (let* ((attribute-name (face-descriptive-attribute-name attribute))
 940                 (prompt (format "Set %s of face " attribute-name))
 941                 (face (read-face-name prompt))
 942                 (new-value (read-face-attribute face attribute frame)))
 943            (list face new-value)))))
 944
 945
 946 \f
 947 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 948 ;;; Listing faces.
 949 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 950
 951 (defvar list-faces-sample-text
 952   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 953   "*Text string to display as the sample text for `list-faces-display'.")
 954
 955
 956 ;; The name list-faces would be more consistent, but let's avoid a
 957 ;; conflict with Lucid, which uses that name differently.
 958
 959 (defun list-faces-display ()
 960   "List all faces, using the same sample text in each.
 961 The sample text is a string that comes from the variable
 962 `list-faces-sample-text'."
 963   (interactive)
 964   (let ((faces (sort (face-list) #'string-lessp))
 965         (face nil)
 966         (frame (selected-frame))
 967         disp-frame window face-name)
 968     (with-output-to-temp-buffer "*Faces*"
 969       (save-excursion
 970         (set-buffer standard-output)
 971         (setq truncate-lines t)
 972         (insert
 973          (substitute-command-keys
 974           (concat
 975            "Use "
 976            (if (display-mouse-p) "\\[help-follow-mouse] or ")
 977            "\\[help-follow] on a face name to customize it\n"
 978            "or on its sample text for a decription of the face.\n\n")))
 979         (setq help-xref-stack nil)
 980         (while faces
 981           (setq face (car faces))
 982           (setq faces (cdr faces))
 983           (setq face-name (symbol-name face))
 984           (insert (format "%25s " face-name))
 985           ;; Hyperlink to a customization buffer for the face.  Using
 986           ;; the help xref mechanism may not be the best way.
 987           (save-excursion
 988             (save-match-data
 989               (search-backward face-name)
 990               (help-xref-button 0 (lambda (f)
 991                                     (if help-xref-stack
 992                                         (pop help-xref-stack))
 993                                     (customize-face f))
 994                                 face-name
 995                                 "mouse-2: customize this face")))
 996           (let ((beg (point)))
 997             (insert list-faces-sample-text)
 998             ;; Hyperlink to a help buffer for the face.
 999             (save-excursion
1000               (save-match-data
1001                 (search-backward list-faces-sample-text)
1002                 (help-xref-button 0 #'describe-face face
1003                                   "mouse-2: describe this face")))
1004             (insert "\n")
1005             (put-text-property beg (1- (point)) 'face face)
1006             ;; If the sample text has multiple lines, line up all of them.
1007             (goto-char beg)
1008             (forward-line 1)
1009             (while (not (eobp))
1010               (insert "                          ")
1011               (forward-line 1))))
1012         (goto-char (point-min)))
1013       (print-help-return-message))
1014     ;; If the *Faces* buffer appears in a different frame,
1015     ;; copy all the face definitions from FRAME,
1016     ;; so that the display will reflect the frame that was selected.
1017     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1018     (setq disp-frame (if window (window-frame window)
1019                        (car (frame-list))))
1020     (or (eq frame disp-frame)
1021         (let ((faces (face-list)))
1022           (while faces
1023             (copy-face (car faces) (car faces) frame disp-frame)
1024             (setq faces (cdr faces)))))))
1025
1026
1027 (defun describe-face (face &optional frame)
1028   "Display the properties of face FACE on FRAME.
1029 If the optional argument FRAME is given, report on face FACE in that frame.
1030 If FRAME is t, report on the defaults for face FACE (for new frames).
1031 If FRAME is omitted or nil, use the selected frame."
1032   (interactive (list (read-face-name "Describe face")))
1033   (let* ((attrs '((:family . "Family")
1034                   (:width . "Width")
1035                   (:height . "Height")
1036                   (:weight . "Weight")
1037                   (:slant . "Slant")
1038                   (:foreground . "Foreground")
1039                   (:background . "Background")
1040                   (:underline . "Underline")
1041                   (:overline . "Overline")
1042                   (:strike-through . "Strike-through")
1043                   (:box . "Box")
1044                   (:inverse-video . "Inverse")
1045                   (:stipple . "Stipple")
1046                   (:font . "Font or fontset")))
1047         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1048                                         attrs))))
1049     (with-output-to-temp-buffer "*Help*"
1050       (save-excursion
1051         (set-buffer standard-output)
1052         (dolist (a attrs)
1053           (let ((attr (face-attribute face (car a) frame)))
1054             (insert (make-string (- max-width (length (cdr a))) ?\ )
1055                     (cdr a) ": " (format "%s" attr) "\n")))
1056         (insert "\nDocumentation:\n\n"
1057                 (or (face-documentation face)
1058                     "not documented as a face."))
1059         (let ((customize-label "customize"))
1060           (terpri)
1061           (terpri)
1062           (princ (concat "You can " customize-label " this face."))
1063           (with-current-buffer "*Help*"
1064             (save-excursion
1065               (re-search-backward
1066                (concat "\\(" customize-label "\\)") nil t)
1067               (help-xref-button 1 #'customize-face face
1068                                 "mouse-2, RET: customize face")))))
1069       (print-help-return-message)
1070       (with-current-buffer "*Help*"
1071         (help-setup-xref (list #'describe-face face) (interactive-p))
1072         (buffer-string)))))
1073 \f
1074 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1075 ;;; Face specifications (defface).
1076 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1077
1078 ;; Parameter FRAME Is kept for call compatibility to with previous
1079 ;; face implementation.
1080
1081 (defun face-attr-construct (face &optional frame)
1082   "Return a defface-style attribute list for FACE on FRAME.
1083 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1084 face attributes of FACE where ATTRIBUTE is the attribute name and
1085 VALUE is the specified value of that attribute."
1086   (let (result)
1087     (dolist (entry face-attribute-name-alist result)
1088       (let* ((attribute (car entry))
1089              (value (face-attribute face attribute)))
1090         (unless (eq value 'unspecified)
1091           (setq result (nconc (list attribute value) result)))))))
1092
1093
1094 (defun face-spec-set-match-display (display frame)
1095   "Non-nil if DISPLAY matches FRAME.
1096 DISPLAY is part of a spec such as can be used in `defface'.
1097 If FRAME is nil, the current FRAME is used."
1098   (let* ((conjuncts display)
1099          conjunct req options
1100          ;; t means we have succeeded against all the conjuncts in
1101          ;; DISPLAY that have been tested so far.
1102          (match t))
1103     (if (eq conjuncts t)
1104         (setq conjuncts nil))
1105     (while (and conjuncts match)
1106       (setq conjunct (car conjuncts)
1107             conjuncts (cdr conjuncts)
1108             req (car conjunct)
1109             options (cdr conjunct)
1110             match (cond ((eq req 'type)
1111                          (or (memq window-system options)
1112                              (and (null window-system)
1113                                   (memq 'tty options))
1114                              (and (memq 'motif options)
1115                                   (featurep 'motif))
1116                              (and (memq 'lucid options)
1117                                   (featurep 'x-toolkit)
1118                                   (not (featurep 'motif)))
1119                              (and (memq 'x-toolkit options)
1120                                   (featurep 'x-toolkit))))
1121                         ((eq req 'class)
1122                          (memq (frame-parameter frame 'display-type) options))
1123                         ((eq req 'background)
1124                          (memq (frame-parameter frame 'background-mode)
1125                                options))
1126                         (t (error "Unknown req `%S' with options `%S'"
1127                                   req options)))))
1128     match))
1129
1130
1131 (defun face-spec-choose (spec &optional frame)
1132   "Choose the proper attributes for FRAME, out of SPEC."
1133   (unless frame
1134     (setq frame (selected-frame)))
1135   (let ((tail spec)
1136         result)
1137     (while tail
1138       (let* ((entry (car tail))
1139              (display (nth 0 entry))
1140              (attrs (nth 1 entry)))
1141         (setq tail (cdr tail))
1142         (when (face-spec-set-match-display display frame)
1143           (setq result attrs tail nil))))
1144     result))
1145
1146
1147 (defun face-spec-reset-face (face &optional frame)
1148   "Reset all attributes of FACE on FRAME to unspecified."
1149   (let ((attrs face-attribute-name-alist)
1150         params)
1151     (while attrs
1152       (let ((attr-and-name (car attrs)))
1153         (setq params (cons (car attr-and-name) (cons 'unspecified params))))
1154       (setq attrs (cdr attrs)))
1155     (apply #'set-face-attribute face frame params)))
1156
1157
1158 (defun face-spec-set (face spec &optional frame)
1159   "Set FACE's attributes according to the first matching entry in SPEC.
1160 FRAME is the frame whose frame-local face is set.  FRAME nil means
1161 do it on all frames.  See `defface' for information about SPEC."
1162   (let ((attrs (face-spec-choose spec frame))
1163         params)
1164     (while attrs
1165       (let ((attribute (car attrs))
1166             (value (car (cdr attrs))))
1167         ;; Support some old-style attribute names and values.
1168         (case attribute
1169           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1170           (:italic (setq attribute :slant value (if value 'italic 'normal))))
1171         (setq params (cons attribute (cons value params))))
1172       (setq attrs (cdr (cdr attrs))))
1173     (face-spec-reset-face face frame)
1174     (apply #'set-face-attribute face frame params)))
1175
1176
1177 (defun face-attr-match-p (face attrs &optional frame)
1178   "Value is non-nil if attributes of FACE match values in plist ATTRS.
1179 Optional parameter FRAME is the frame whose definition of FACE
1180 is used.  If nil or omitted, use the selected frame."
1181   (unless frame
1182     (setq frame (selected-frame)))
1183   (let ((list face-attribute-name-alist)
1184         (match t))
1185     (while (and match (not (null list)))
1186       (let* ((attr (car (car list)))
1187              (specified-value (plist-get attrs attr))
1188              (value-now (face-attribute face attr frame)))
1189         (when specified-value
1190           (setq match (equal specified-value value-now)))
1191         (setq list (cdr list))))
1192     match))
1193
1194
1195 (defun face-spec-match-p (face spec &optional frame)
1196   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1197   (face-attr-match-p face (face-spec-choose spec frame) frame))
1198
1199
1200 \f
1201 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1202 ;;; Frame-type independent color support.
1203 ;;; We keep the old x-* names as aliases for back-compatibility.
1204 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1205
1206 (defun defined-colors (&optional frame)
1207   "Return a list of colors supported for a particular frame.
1208 The argument FRAME specifies which frame to try.
1209 The value may be different for frames on different display types.
1210 If FRAME doesn't support colors, the value is nil."
1211   (if (memq (framep (or frame (selected-frame))) '(x w32))
1212       (xw-defined-colors frame)
1213     (mapcar 'car (tty-color-alist frame))))
1214 (defalias 'x-defined-colors 'defined-colors)
1215
1216 (defun color-defined-p (color &optional frame)
1217   "Return non-nil if color COLOR is supported on frame FRAME.
1218 If FRAME is omitted or nil, use the selected frame.
1219 If COLOR is the symbol `unspecified' or one of the strings
1220 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1221   (if (memq color '(unspecified "unspecified-bg" "unspecified-fg"))
1222       nil
1223     (if (memq (framep (or frame (selected-frame))) '(x w32))
1224         (xw-color-defined-p color frame)
1225       (numberp (tty-color-translate color frame)))))
1226 (defalias 'x-color-defined-p 'color-defined-p)
1227
1228 (defun color-values (color &optional frame)
1229   "Return a description of the color named COLOR on frame FRAME.
1230 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1231 These values appear to range from 0 to 65280 or 65535, depending
1232 on the system; white is \(65280 65280 65280\) or \(65535 65535 65535\).
1233 If FRAME is omitted or nil, use the selected frame.
1234 If FRAME cannot display COLOR, the value is nil.
1235 If COLOR is the symbol `unspecified' or one of the strings
1236 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1237   (if (memq color '(unspecified "unspecified-fg" "unspecified-bg"))
1238       nil
1239     (if (memq (framep (or frame (selected-frame))) '(x w32))
1240         (xw-color-values color frame)
1241       (tty-color-values color frame))))
1242 (defalias 'x-color-values 'color-values)
1243
1244 (defun display-color-p (&optional display)
1245   "Return t if DISPLAY supports color.
1246 The optional argument DISPLAY specifies which display to ask about.
1247 DISPLAY should be either a frame or a display name (a string).
1248 If omitted or nil, that stands for the selected frame's display."
1249   (if (memq (framep-on-display display) '(x w32))
1250       (xw-display-color-p display)
1251     (tty-display-color-p display)))
1252 (defalias 'x-display-color-p 'display-color-p)
1253
1254 (defun display-grayscale-p (&optional display)
1255   "Return non-nil if frames on DISPLAY can display shades of gray."
1256   (let ((frame-type (framep-on-display display)))
1257     (cond
1258      ((memq frame-type '(x w32 mac))
1259       (x-display-grayscale-p display))
1260      (t
1261       (> (tty-color-gray-shades display) 2)))))
1262
1263 \f
1264 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1265 ;;; Background mode.
1266 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1267
1268 (defcustom frame-background-mode nil
1269   "*The brightness of the background.
1270 Set this to the symbol `dark' if your background color is dark, `light' if
1271 your background is light, or nil (default) if you want Emacs to
1272 examine the brightness for you."
1273   :group 'faces
1274   :set #'(lambda (var value)
1275            (set var value)
1276            (mapcar 'frame-set-background-mode (frame-list)))
1277   :initialize 'custom-initialize-changed
1278   :type '(choice (choice-item dark)
1279                  (choice-item light)
1280                  (choice-item :tag "default" nil)))
1281
1282
1283 (defun frame-set-background-mode (frame)
1284   "Set up the `background-mode' and `display-type' frame parameters for FRAME."
1285   (let* ((bg-resource
1286           (and window-system
1287                (x-get-resource ".backgroundMode" "BackgroundMode")))
1288          (params (frame-parameters frame))
1289          (bg-mode (cond (frame-background-mode)
1290                         ((null window-system)
1291                          ;; No way to determine this automatically (?).
1292                          'dark)
1293                         (bg-resource
1294                          (intern (downcase bg-resource)))
1295                         ((< (apply '+ (x-color-values
1296                                        (cdr (assq 'background-color
1297                                                   params))
1298                                        frame))
1299                             ;; Just looking at the screen, colors whose
1300                             ;; values add up to .6 of the white total
1301                             ;; still look dark to me.
1302                             (* (apply '+ (x-color-values "white" frame)) .6))
1303                          'dark)
1304                         (t 'light)))
1305          (display-type (cond ((null window-system)
1306                               (if (tty-display-color-p frame) 'color 'mono))
1307                              ((x-display-color-p frame)
1308                               'color)
1309                              ((x-display-grayscale-p frame)
1310                               'grayscale)
1311                              (t 'mono))))
1312     (modify-frame-parameters frame
1313                              (list (cons 'background-mode bg-mode)
1314                                    (cons 'display-type display-type))))
1315
1316   ;; For all named faces, choose face specs matching the new frame
1317   ;; parameters.
1318   (let ((face-list (face-list)))
1319     (while face-list
1320       (let* ((face (car face-list))
1321              (spec (get face 'face-defface-spec)))
1322         (when spec
1323           (face-spec-set face spec frame))
1324       (setq face-list (cdr face-list))))))
1325
1326
1327
1328 \f
1329 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1330 ;;; Frame creation.
1331 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1332
1333 (defun x-handle-named-frame-geometry (parameters)
1334   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1335 Value is the new parameter list."
1336   (let* ((name (or (cdr (assq 'name parameters))
1337                    (cdr (assq 'name default-frame-alist))))
1338          (x-resource-name name)
1339          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1340     (when res-geometry
1341       (let ((parsed (x-parse-geometry res-geometry)))
1342         ;; If the resource specifies a position, call the position
1343         ;; and size "user-specified".
1344         (when (or (assq 'top parsed)
1345                   (assq 'left parsed))
1346           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1347         ;; Put the geometry parameters at the end.  Copy
1348         ;; default-frame-alist so that they go after it.
1349         (setq parameters (append parameters default-frame-alist parsed))))
1350     parameters))
1351
1352
1353 (defun x-handle-reverse-video (frame parameters)
1354   "Handle the reverse-video frame parameter and X resource.
1355 `x-create-frame' does not handle this one."
1356   (when (cdr (or (assq 'reverse parameters)
1357                  (assq 'reverse default-frame-alist)
1358                  (let ((resource (x-get-resource "reverseVideo"
1359                                                  "ReverseVideo")))
1360                    (if resource
1361                        (cons nil (member (downcase resource)
1362                                          '("on" "true")))))))
1363       (let* ((params (frame-parameters frame))
1364              (bg (cdr (assq 'foreground-color params)))
1365              (fg (cdr (assq 'background-color params))))
1366         (modify-frame-parameters frame
1367                                  (list (cons 'foreground-color fg)
1368                                        (cons 'background-color bg)))
1369         (if (equal bg (cdr (assq 'border-color params)))
1370             (modify-frame-parameters frame
1371                                      (list (cons 'border-color fg))))
1372         (if (equal bg (cdr (assq 'mouse-color params)))
1373             (modify-frame-parameters frame
1374                                      (list (cons 'mouse-color fg))))
1375         (if (equal bg (cdr (assq 'cursor-color params)))
1376             (modify-frame-parameters frame
1377                                      (list (cons 'cursor-color fg)))))))
1378
1379
1380 (defun x-create-frame-with-faces (&optional parameters)
1381   "Create a frame from optional frame parameters PARAMETERS.
1382 Parameters not specified by PARAMETERS are taken from
1383 `default-frame-alist'.  If PARAMETERS specify a frame name,
1384 handle X geometry resources for that name.  If either PARAMETERS
1385 or `default-frame-alist' contains a `reverse' parameter, or
1386 the X resource ``reverseVideo'' is present, handle that.
1387 Value is the new frame created."
1388   (setq parameters (x-handle-named-frame-geometry parameters))
1389   (let ((visibility-spec (assq 'visibility parameters))
1390         (frame-list (frame-list))
1391         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1392         success)
1393     (unwind-protect
1394         (progn
1395           (x-handle-reverse-video frame parameters)
1396           (frame-set-background-mode frame)
1397           (face-set-after-frame-default frame)
1398           (if (or (null frame-list) (null visibility-spec))
1399               (make-frame-visible frame)
1400             (modify-frame-parameters frame (list visibility-spec)))
1401           (setq success t))
1402       (unless success
1403         (delete-frame frame)))
1404     frame))
1405
1406
1407 (defun face-set-after-frame-default (frame)
1408   "Set frame-local faces of FRAME from face specs and resources.
1409 Initialize colors of certain faces from frame parameters."
1410   (dolist (face (face-list))
1411     (let ((spec (or (get face 'saved-face)
1412                     (get face 'face-defface-spec))))
1413       (when spec
1414         (face-spec-set face spec frame))
1415       (internal-merge-in-global-face face frame)
1416       (when (memq window-system '(x w32))
1417         (make-face-x-resource-internal face frame))))
1418
1419   ;; Initialize attributes from frame parameters.
1420   (let ((params '((foreground-color default :foreground)
1421                   (background-color default :background)
1422                   (border-color border :background)
1423                   (cursor-color cursor :background)
1424                   (scroll-bar-foreground scroll-bar :foreground)
1425                   (scroll-bar-background scroll-bar :background)
1426                   (mouse-color mouse :background))))
1427     (while params
1428       (let ((param-name (nth 0 (car params)))
1429             (face (nth 1 (car params)))
1430             (attr (nth 2 (car params)))
1431             value)
1432         (when (setq value (frame-parameter frame param-name))
1433           (set-face-attribute face frame attr value)))
1434       (setq params (cdr params)))))
1435
1436
1437 (defun tty-create-frame-with-faces (&optional parameters)
1438   "Create a frame from optional frame parameters PARAMETERS.
1439 Parameters not specified by PARAMETERS are taken from
1440 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1441 contains a `reverse' parameter, handle that.  Value is the new frame
1442 created."
1443   (let ((frame (make-terminal-frame parameters))
1444         success)
1445     (unwind-protect
1446         (progn
1447           (frame-set-background-mode frame)
1448           (face-set-after-frame-default frame)
1449           (setq success t))
1450       (unless success
1451         (delete-frame frame)))
1452     frame))
1453
1454
1455 ;; Called from C function init_display to initialize faces of the
1456 ;; dumped terminal frame on startup.
1457
1458 (defun tty-set-up-initial-frame-faces ()
1459   (let ((frame (selected-frame)))
1460     (frame-set-background-mode frame)
1461     (face-set-after-frame-default frame)))
1462
1463
1464
1465 \f
1466 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1467 ;;; Compatiblity with 20.2
1468 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1469
1470 ;; Update a frame's faces when we change its default font.
1471
1472 (defun frame-update-faces (frame)
1473   nil)
1474 (make-obsolete 'frame-update-faces "No longer necessary")
1475
1476 ;; Update the colors of FACE, after FRAME's own colors have been
1477 ;; changed.
1478
1479 (defun frame-update-face-colors (frame)
1480   (frame-set-background-mode frame))
1481 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode)
1482
1483 \f
1484 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1485 ;;; Standard faces.
1486 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1487
1488 (defgroup basic-faces nil
1489   "The standard faces of Emacs."
1490   :group 'faces)
1491
1492
1493 (defface default
1494   '((t nil))
1495   "Basic default face."
1496   :group 'basic-faces)
1497
1498
1499 (defface mode-line
1500   '((((type x) (class color))
1501      (:box (:line-width 2 :style released-button) :background "grey75"))
1502     (((type w32) (class color))
1503      (:box (:line-width 2 :style released-button) :background "grey75"))
1504     (t
1505      (:inverse-video t)))
1506   "Basic mode line face."
1507   :version "21.1"
1508   :group 'modeline
1509   :group 'basic-faces)
1510
1511 ;; Make `modeline' an alias for `mode-line', for compatibility.
1512 (put 'modeline 'face-alias 'mode-line)
1513
1514 (defface header-line
1515   '((((type x) (class color))
1516      (:box (:line-width 2 :style released-button) :background "grey75"))
1517     (((type w32) (class color))
1518      (:box (:line-width 2 :style released-button) :background "grey75"))
1519     (t
1520      (:inverse-video t)))
1521   "Basic header-line face."
1522   :version "21.1"
1523   :group 'basic-faces)
1524
1525
1526 (defface tool-bar
1527   '((((type x) (class color))
1528      (:box (:line-width 1 :style released-button) :background "grey75"))
1529     (((type x) (class mono))
1530      (:box (:line-width 1 :style released-button) :background "grey"))
1531     (((type w32) (class color))
1532      (:box (:line-width 1 :style released-button) :background "grey75"))
1533     (t
1534      ()))
1535   "Basic tool-bar face."
1536   :version "21.1"
1537   :group 'basic-faces)
1538
1539
1540 (defface region
1541   '((((type tty) (class color))
1542      (:background "blue" :foreground "white"))
1543     (((type tty) (class mono))
1544      (:inverse-video t))
1545     (((class color) (background dark))
1546      (:background "blue"))
1547     (((class color) (background light))
1548      (:background "lightblue"))
1549     (t (:background "gray")))
1550   "Basic face for highlighting the region."
1551   :group 'basic-faces)
1552
1553
1554 (defface fringe
1555   '((((class color))
1556      (:background "grey95"))
1557     (t
1558      (:background "gray")))
1559   "Basic face for the fringes to the left and right of windows under X."
1560   :version "21.1"
1561   :group 'frames
1562   :group 'basic-faces)
1563
1564
1565 (defface scroll-bar '()
1566   "Basic face for the scroll bar colors under X."
1567   :version "21.1"
1568   :group 'frames
1569   :group 'basic-faces)
1570
1571
1572 (defface menu
1573   '((((type x-toolkit)) ())
1574     (t (:inverse-video t)))
1575   "Basic menu face."
1576   :version "21.1"
1577   :group 'menu
1578   :group 'basic-faces)
1579
1580
1581 (defface border '()
1582   "Basic face for the frame border under X."
1583   :version "21.1"
1584   :group 'frames
1585   :group 'basic-faces)
1586
1587
1588 (defface cursor '()
1589   "Basic face for the cursor color under X."
1590   :version "21.1"
1591   :group 'cursor
1592   :group 'basic-faces)
1593
1594
1595 (defface mouse '()
1596   "Basic face for the mouse color under X."
1597   :version "21.1"
1598   :group 'mouse
1599   :group 'basic-faces)
1600
1601
1602 (defface bold '((t (:weight bold)))
1603   "Basic bold face."
1604   :group 'basic-faces)
1605
1606
1607 (defface italic '((t (:slant italic)))
1608   "Basic italic font."
1609   :group 'basic-faces)
1610
1611
1612 (defface bold-italic '((t (:weight bold :slant italic)))
1613   "Basic bold-italic face."
1614   :group 'basic-faces)
1615
1616
1617 (defface underline '((t (:underline t)))
1618   "Basic underlined face."
1619   :group 'basic-faces)
1620
1621
1622 (defface highlight
1623   '((((type tty) (class color))
1624      (:background "green"))
1625     (((class color) (background light))
1626      (:background "darkseagreen2"))
1627     (((class color) (background dark))
1628      (:background "darkolivegreen"))
1629     (t (:inverse-video t)))
1630   "Basic face for highlighting."
1631   :group 'basic-faces)
1632
1633
1634 (defface secondary-selection
1635   '((((type tty) (class color))
1636      (:background "cyan"))
1637     (((class color) (background light))
1638      (:background "yellow"))
1639     (((class color) (background dark))
1640      (:background "yellow"))
1641     (t (:inverse-video t)))
1642   "Basic face for displaying the secondary selection."
1643   :group 'basic-faces)
1644
1645
1646 (defface fixed-pitch '((t (:family "courier")))
1647   "The basic fixed-pitch face."
1648   :group 'basic-faces)
1649
1650
1651 (defface variable-pitch '((t (:family "helv")))
1652   "The basic variable-pitch face."
1653   :group 'basic-faces)
1654
1655
1656 (defface trailing-whitespace
1657   '((((class color) (background light))
1658      (:background "red"))
1659     (((class color) (background dark))
1660      (:background "red"))
1661     (t (:inverse-video t)))
1662   "Basic face for highlighting trailing whitespace."
1663   :version "21.1"
1664   :group 'font-lock                     ; like `show-trailing-whitespace'
1665   :group 'basic-faces)
1666
1667
1668 \f
1669 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1670 ;;; Manipulating font names.
1671 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1672
1673 ;; This is here for compatibilty with Emacs 20.2.  For example,
1674 ;; international/fontset.el uses x-resolve-font-name.  The following
1675 ;; functions are not used in the face implementation itself.
1676
1677 (defvar x-font-regexp nil)
1678 (defvar x-font-regexp-head nil)
1679 (defvar x-font-regexp-weight nil)
1680 (defvar x-font-regexp-slant nil)
1681
1682 (defconst x-font-regexp-weight-subnum 1)
1683 (defconst x-font-regexp-slant-subnum 2)
1684 (defconst x-font-regexp-swidth-subnum 3)
1685 (defconst x-font-regexp-adstyle-subnum 4)
1686
1687 ;;; Regexps matching font names in "Host Portable Character Representation."
1688 ;;;
1689 (let ((-                "[-?]")
1690       (foundry          "[^-]+")
1691       (family           "[^-]+")
1692       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
1693 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
1694       (weight\?         "\\([^-]*\\)")                                  ; 1
1695       (slant            "\\([ior]\\)")                                  ; 2
1696 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
1697       (slant\?          "\\([^-]?\\)")                                  ; 2
1698 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
1699       (swidth           "\\([^-]*\\)")                                  ; 3
1700 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
1701       (adstyle          "\\([^-]*\\)")                                  ; 4
1702       (pixelsize        "[0-9]+")
1703       (pointsize        "[0-9][0-9]+")
1704       (resx             "[0-9][0-9]+")
1705       (resy             "[0-9][0-9]+")
1706       (spacing          "[cmp?*]")
1707       (avgwidth         "[0-9]+")
1708       (registry         "[^-]+")
1709       (encoding         "[^-]+")
1710       )
1711   (setq x-font-regexp
1712         (concat "\\`\\*?[-?*]"
1713                 foundry - family - weight\? - slant\? - swidth - adstyle -
1714                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
1715                 registry - encoding "\\*?\\'"
1716                 ))
1717   (setq x-font-regexp-head
1718         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
1719                 "\\([-*?]\\|\\'\\)"))
1720   (setq x-font-regexp-slant (concat - slant -))
1721   (setq x-font-regexp-weight (concat - weight -))
1722   nil)
1723
1724
1725 (defun x-resolve-font-name (pattern &optional face frame)
1726   "Return a font name matching PATTERN.
1727 All wildcards in PATTERN are instantiated.
1728 If PATTERN is nil, return the name of the frame's base font, which never
1729 contains wildcards.
1730 Given optional arguments FACE and FRAME, return a font which is
1731 also the same size as FACE on FRAME, or fail."
1732   (or (symbolp face)
1733       (setq face (face-name face)))
1734   (and (eq frame t)
1735        (setq frame nil))
1736   (if pattern
1737       ;; Note that x-list-fonts has code to handle a face with nil as its font.
1738       (let ((fonts (x-list-fonts pattern face frame 1)))
1739         (or fonts
1740             (if face
1741                 (if (string-match "\\*" pattern)
1742                     (if (null (face-font face))
1743                         (error "No matching fonts are the same height as the frame default font")
1744                       (error "No matching fonts are the same height as face `%s'" face))
1745                   (if (null (face-font face))
1746                       (error "Height of font `%s' doesn't match the frame default font"
1747                              pattern)
1748                     (error "Height of font `%s' doesn't match face `%s'"
1749                            pattern face)))
1750               (error "No fonts match `%s'" pattern)))
1751         (car fonts))
1752     (cdr (assq 'font (frame-parameters (selected-frame))))))
1753
1754
1755 (defun x-frob-font-weight (font which)
1756   (let ((case-fold-search t))
1757     (cond ((string-match x-font-regexp font)
1758            (concat (substring font 0
1759                               (match-beginning x-font-regexp-weight-subnum))
1760                    which
1761                    (substring font (match-end x-font-regexp-weight-subnum)
1762                               (match-beginning x-font-regexp-adstyle-subnum))
1763                    ;; Replace the ADD_STYLE_NAME field with *
1764                    ;; because the info in it may not be the same
1765                    ;; for related fonts.
1766                    "*"
1767                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1768           ((string-match x-font-regexp-head font)
1769            (concat (substring font 0 (match-beginning 1)) which
1770                    (substring font (match-end 1))))
1771           ((string-match x-font-regexp-weight font)
1772            (concat (substring font 0 (match-beginning 1)) which
1773                    (substring font (match-end 1)))))))
1774 (make-obsolete 'x-frob-font-weight 'make-face-...)
1775
1776 (defun x-frob-font-slant (font which)
1777   (let ((case-fold-search t))
1778     (cond ((string-match x-font-regexp font)
1779            (concat (substring font 0
1780                               (match-beginning x-font-regexp-slant-subnum))
1781                    which
1782                    (substring font (match-end x-font-regexp-slant-subnum)
1783                               (match-beginning x-font-regexp-adstyle-subnum))
1784                    ;; Replace the ADD_STYLE_NAME field with *
1785                    ;; because the info in it may not be the same
1786                    ;; for related fonts.
1787                    "*"
1788                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1789           ((string-match x-font-regexp-head font)
1790            (concat (substring font 0 (match-beginning 2)) which
1791                    (substring font (match-end 2))))
1792           ((string-match x-font-regexp-slant font)
1793            (concat (substring font 0 (match-beginning 1)) which
1794                    (substring font (match-end 1)))))))
1795 (make-obsolete 'x-frob-font-slant 'make-face-...)
1796
1797 (defun x-make-font-bold (font)
1798   "Given an X font specification, make a bold version of it.
1799 If that can't be done, return nil."
1800   (x-frob-font-weight font "bold"))
1801 (make-obsolete 'x-make-font-bold 'make-face-bold)
1802
1803 (defun x-make-font-demibold (font)
1804   "Given an X font specification, make a demibold version of it.
1805 If that can't be done, return nil."
1806   (x-frob-font-weight font "demibold"))
1807 (make-obsolete 'x-make-font-demibold 'make-face-bold)
1808
1809 (defun x-make-font-unbold (font)
1810   "Given an X font specification, make a non-bold version of it.
1811 If that can't be done, return nil."
1812   (x-frob-font-weight font "medium"))
1813 (make-obsolete 'x-make-font-unbold 'make-face-unbold)
1814
1815 (defun x-make-font-italic (font)
1816   "Given an X font specification, make an italic version of it.
1817 If that can't be done, return nil."
1818   (x-frob-font-slant font "i"))
1819 (make-obsolete 'x-make-font-italic 'make-face-italic)
1820
1821 (defun x-make-font-oblique (font) ; you say tomayto...
1822   "Given an X font specification, make an oblique version of it.
1823 If that can't be done, return nil."
1824   (x-frob-font-slant font "o"))
1825 (make-obsolete 'x-make-font-oblique 'make-face-italic)
1826
1827 (defun x-make-font-unitalic (font)
1828   "Given an X font specification, make a non-italic version of it.
1829 If that can't be done, return nil."
1830   (x-frob-font-slant font "r"))
1831 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic)
1832
1833 (defun x-make-font-bold-italic (font)
1834   "Given an X font specification, make a bold and italic version of it.
1835 If that can't be done, return nil."
1836   (and (setq font (x-make-font-bold font))
1837        (x-make-font-italic font)))
1838 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic)
1839
1840 (provide 'faces)
1841
1842 ;;; faces.el ends here