lisp/fast-lock.el

   1 ;;; fast-lock.el --- Automagic text properties caching for fast Font Lock mode.
   2
   3 ;; Copyright (C) 1994, 1995, 1996 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Marshall <simon@gnu.ai.mit.edu>
   6 ;; Keywords: faces files
   7 ;; Version: 3.11
   8
   9 ;;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Lazy Lock mode is a Font Lock support mode.
  29 ;; It makes visiting a file in Font Lock mode faster by restoring its face text
  30 ;; properties from automatically saved associated Font Lock cache files.
  31 ;;
  32 ;; See caveats and feedback below.
  33 ;; See also the lazy-lock package.  (But don't use the two at the same time!)
  34
  35 ;; Installation:
  36 ;;
  37 ;; Put in your ~/.emacs:
  38 ;;
  39 ;; (setq font-lock-support-mode 'fast-lock-mode)
  40 ;;
  41 ;; Start up a new Emacs and use font-lock as usual (except that you can use the
  42 ;; so-called "gaudier" fontification regexps on big files without frustration).
  43 ;;
  44 ;; When you visit a file (which has `font-lock-mode' enabled) that has a
  45 ;; corresponding Font Lock cache file associated with it, the Font Lock cache
  46 ;; will be loaded from that file instead of being generated by Font Lock code.
  47
  48 ;; Caveats:
  49 ;;
  50 ;; A cache will be saved when visiting a compressed file using crypt++, but not
  51 ;; be read.  This is a "feature"/"consequence"/"bug" of crypt++.
  52 ;;
  53 ;; Version control packages are likely to stamp all over file modification
  54 ;; times.  Therefore the act of checking out may invalidate a cache.
  55 \f
  56 ;; History:
  57 ;;
  58 ;; 0.02--1.00:
  59 ;; - Changed name from turbo-prop to fast-lock.  Automagic for font-lock only
  60 ;; - Made `fast-lock-mode' a minor mode, like G. Dinesh Dutt's fss-mode
  61 ;; 1.00--1.01:
  62 ;; - Turn on `fast-lock-mode' only if `buffer-file-name' or `interactive-p'
  63 ;; - Made `fast-lock-file-name' use `buffer-name' if `buffer-file-name' is nil
  64 ;; - Moved save-all conditions to `fast-lock-save-cache'
  65 ;; - Added `fast-lock-save-text-properties' to `kill-buffer-hook'
  66 ;; 1.01--2.00: complete rewrite---not worth the space to document
  67 ;; - Changed structure of text properties cache and threw out file mod checks
  68 ;; 2.00--2.01:
  69 ;; - Made `condition-case' forms understand `quit'.
  70 ;; - Made `fast-lock' require `font-lock'
  71 ;; - Made `fast-lock-cache-name' chase links (from Ben Liblit)
  72 ;; 2.01--3.00:
  73 ;; - Changed structure of cache to include `font-lock-keywords' (from rms)
  74 ;; - Changed `fast-lock-cache-mechanisms' to `fast-lock-cache-directories'
  75 ;; - Removed `fast-lock-read-others'
  76 ;; - Made `fast-lock-read-cache' ignore cache owner
  77 ;; - Made `fast-lock-save-cache-external' create cache directory
  78 ;; - Made `fast-lock-save-cache-external' save `font-lock-keywords'
  79 ;; - Made `fast-lock-cache-data' check `font-lock-keywords'
  80 ;; 3.00--3.01: incorporated port of 2.00 to Lucid, made by Barry Warsaw
  81 ;; - Package now provides itself
  82 ;; - Lucid: Use `font-lock-any-extents-p' for `font-lock-any-properties-p'
  83 ;; - Lucid: Use `list-faces' for `face-list'
  84 ;; - Lucid: Added `set-text-properties'
  85 ;; - Lucid: Made `turn-on-fast-lock' pass 1 not t to `fast-lock-mode'
  86 ;; - Removed test for `fast-lock-mode' from `fast-lock-read-cache'
  87 ;; - Lucid: Added Lucid-specific `fast-lock-get-face-properties'
  88 ;; 3.01--3.02: now works with Lucid Emacs, thanks to Barry Warsaw
  89 ;; - Made `fast-lock-cache-name' map ":" to ";" for OS/2 (from Serganova Vera)
  90 ;; - Made `fast-lock-cache-name' use abbreviated file name (from Barry Warsaw)
  91 ;; - Lucid: Separated handlers for `error' and `quit' for `condition-case'
  92 ;; 3.02--3.03:
  93 ;; - Changed `fast-lock-save-cache-external' to `fast-lock-save-cache-data'
  94 ;; - Lucid: Added Lucid-specific `fast-lock-set-face-properties'
  95 ;; 3.03--3.04:
  96 ;; - Corrected `subrp' test of Lucid code
  97 ;; - Replaced `font-lock-any-properties-p' with `text-property-not-all'
  98 ;; - Lucid: Made `fast-lock-set-face-properties' put `text-prop' on extents
  99 ;; - Made `fast-lock-cache-directories' a regexp alist (from Colin Rafferty)
 100 ;; - Made `fast-lock-cache-directory' to return a usable cache file directory
 101 ;; 3.04--3.05:
 102 ;; - Lucid: Fix for XEmacs 19.11 `text-property-not-all'
 103 ;; - Replaced `subrp' test of Lucid code with `emacs-version' `string-match'
 104 ;; - Made `byte-compile-warnings' omit `unresolved' on compilation
 105 ;; - Made `fast-lock-save-cache-data' use a buffer (from Rick Sladkey)
 106 ;; - Reverted to old `fast-lock-get-face-properties' (from Rick Sladkey)
 107 ;; 3.05--3.06: incorporated hack of 3.03, made by Jonathan Stigelman (Stig)
 108 ;; - Reverted to 3.04 version of `fast-lock-get-face-properties'
 109 ;; - XEmacs: Removed `list-faces' `defalias'
 110 ;; - Made `fast-lock-mode' and `turn-on-fast-lock' succeed `autoload' cookies
 111 ;; - Added `fast-lock-submit-bug-report'
 112 ;; - Renamed `fast-lock-save-size' to `fast-lock-minimum-size'
 113 ;; - Made `fast-lock-save-cache' output a message if no save ever attempted
 114 ;; - Made `fast-lock-save-cache-data' output a message if save attempted
 115 ;; - Made `fast-lock-cache-data' output a message if load attempted
 116 ;; - Made `fast-lock-save-cache-data' do `condition-case' not `unwind-protect'
 117 ;; - Made `fast-lock-save-cache' and `fast-lock-read-cache' return nothing
 118 ;; - Made `fast-lock-save-cache' check `buffer-modified-p' (Stig)
 119 ;; - Added `fast-lock-save-events'
 120 ;; - Added `fast-lock-after-save-hook' to `after-save-hook' (Stig)
 121 ;; - Added `fast-lock-kill-buffer-hook' to `kill-buffer-hook'
 122 ;; - Changed `fast-lock-save-caches' to `fast-lock-kill-emacs-hook'
 123 ;; - Added `fast-lock-kill-emacs-hook' to `kill-emacs-hook'
 124 ;; - Made `fast-lock-save-cache' check `verify-visited-file-modtime' (Stig)
 125 ;; - Made `visited-file-modtime' be the basis of the timestamp (Stig)
 126 ;; - Made `fast-lock-save-cache-1' and `fast-lock-cache-data' use/reformat it
 127 ;; - Added `fast-lock-cache-filename' to keep track of the cache file name
 128 ;; - Added `fast-lock-after-fontify-buffer'
 129 ;; - Added `fast-lock-save-faces' list of faces to save (idea from Stig/Tibor)
 130 ;; - Made `fast-lock-get-face-properties' functions use it
 131 ;; - XEmacs: Made `fast-lock-set-face-properties' do extents the Font Lock way
 132 ;; - XEmacs: Removed fix for `text-property-not-all' (19.11 support dropped)
 133 ;; - Made `fast-lock-mode' ensure `font-lock-mode' is on
 134 ;; - Made `fast-lock-save-cache' do `cdr-safe' not `cdr' (from Dave Foster)
 135 ;; - Made `fast-lock-save-cache' do `set-buffer' first (from Dave Foster)
 136 ;; - Made `fast-lock-save-cache' loop until saved or quit (from Georg Nikodym)
 137 ;; - Made `fast-lock-cache-data' check `buffer-modified-p'
 138 ;; - Made `fast-lock-cache-data' do `font-lock-compile-keywords' if necessary
 139 ;; - XEmacs: Made `font-lock-compile-keywords' `defalias'
 140 ;; 3.06--3.07:
 141 ;; - XEmacs: Add `fast-lock-after-fontify-buffer' to the Font Lock hook
 142 ;; - Made `fast-lock-cache-name' explain the use of `directory-abbrev-alist'
 143 ;; - Made `fast-lock-mode' use `buffer-file-truename' not `buffer-file-name'
 144 ;; 3.07--3.08:
 145 ;; - Made `fast-lock-read-cache' set `fast-lock-cache-filename'
 146 ;; 3.08--3.09:
 147 ;; - Made `fast-lock-save-cache' cope if `fast-lock-minimum-size' is an a list
 148 ;; - Made `fast-lock-mode' respect the value of `font-lock-inhibit-thing-lock'
 149 ;; - Added `fast-lock-after-unfontify-buffer'
 150 ;; 3.09--3.10:
 151 ;; - Rewrite for Common Lisp macros
 152 ;; - Made fast-lock.el barf on a crap 8+3 pseudo-OS (Eli Zaretskii help)
 153 ;; - XEmacs: Made `add-minor-mode' succeed `autoload' cookie
 154 ;; - XEmacs: Made `fast-lock-save-faces' default to `font-lock-face-list'
 155 ;; - Made `fast-lock-save-cache' use `font-lock-value-in-major-mode'
 156 ;; - Wrap with `save-buffer-state' (Ray Van Tassle report)
 157 ;; - Made `fast-lock-mode' wrap `font-lock-support-mode'
 158 ;; 3.10--3.11:
 159 ;; - Made `fast-lock-get-face-properties' cope with face lists
 160 ;; - Added `fast-lock-verbose'
 161 ;; - XEmacs: Add `font-lock-value-in-major-mode' if necessary
 162 ;; - Removed `fast-lock-submit-bug-report' and bade farewell
 163 \f
 164 ;;; Code:
 165
 166 (require 'font-lock)
 167
 168 ;; Make sure fast-lock.el is supported.
 169 (if (and (eq system-type 'ms-dos) (not (msdos-long-file-names)))
 170     (error "`fast-lock' was written for long file name systems"))
 171
 172 (eval-when-compile
 173   ;;
 174   ;; We don't do this at the top-level as we only use non-autoloaded macros.
 175   (require 'cl)
 176   ;;
 177   ;; I prefer lazy code---and lazy mode.
 178   (setq byte-compile-dynamic t byte-compile-dynamic-docstrings t)
 179   ;; But, we make sure that the code is as zippy as can be.
 180   (setq byte-optimize t)
 181   ;;
 182   ;; We use this to preserve or protect things when modifying text properties.
 183   (defmacro save-buffer-state (varlist &rest body)
 184     "Bind variables according to VARLIST and eval BODY restoring buffer state."
 185     (` (let* ((,@ (append varlist
 186                    '((modified (buffer-modified-p))
 187                      (inhibit-read-only t) (buffer-undo-list t)
 188                      before-change-functions after-change-functions
 189                      deactivate-mark buffer-file-name buffer-file-truename))))
 190          (,@ body)
 191          (when (and (not modified) (buffer-modified-p))
 192            (set-buffer-modified-p nil)))))
 193   (put 'save-buffer-state 'lisp-indent-function 1)
 194   ;;
 195   ;; We use this to verify that a face should be saved.
 196   (defmacro fast-lock-save-facep (face)
 197     "Return non-nil if FACE is one of `fast-lock-save-faces'."
 198     (` (or (null fast-lock-save-faces)
 199            (if (symbolp (, face))
 200                (memq (, face) fast-lock-save-faces)
 201              (let ((faces (, face)))
 202                (while (unless (memq (car faces) fast-lock-save-faces)
 203                         (setq faces (cdr faces))))
 204                faces))))))
 205
 206 ;(defun fast-lock-submit-bug-report ()
 207 ;  "Submit via mail a bug report on fast-lock.el."
 208 ;  (interactive)
 209 ;  (let ((reporter-prompt-for-summary-p t))
 210 ;    (reporter-submit-bug-report "simon@gnu.ai.mit.edu" "fast-lock 3.11"
 211 ;     '(fast-lock-cache-directories fast-lock-minimum-size
 212 ;       fast-lock-save-others fast-lock-save-events fast-lock-save-faces
 213 ;       fast-lock-verbose)
 214 ;     nil nil
 215 ;     (concat "Hi Si.,
 216 ;
 217 ;I want to report a bug.  I've read the `Bugs' section of `Info' on Emacs, so I
 218 ;know how to make a clear and unambiguous report.  To reproduce the bug:
 219 ;
 220 ;Start a fresh editor via `" invocation-name " -no-init-file -no-site-file'.
 221 ;In the `*scratch*' buffer, evaluate:"))))
 222
 223 (defvar fast-lock-mode nil)
 224 (defvar fast-lock-cache-timestamp nil)  ; for saving/reading
 225 (defvar fast-lock-cache-filename nil)   ; for deleting
 226 \f
 227 ;; User Variables:
 228
 229 (defvar fast-lock-cache-directories '("." "~/.emacs-flc")
 230 ; - `internal', keep each file's Font Lock cache file in the same file.
 231 ; - `external', keep each file's Font Lock cache file in the same directory.
 232   "*Directories in which Font Lock cache files are saved and read.
 233 Each item should be either DIR or a cons pair of the form (REGEXP . DIR) where
 234 DIR is a directory name (relative or absolute) and REGEXP is a regexp.
 235
 236 An attempt will be made to save or read Font Lock cache files using these items
 237 until one succeeds (i.e., until a readable or writable one is found).  If an
 238 item contains REGEXP, DIR is used only if the buffer file name matches REGEXP.
 239 For example:
 240
 241  (let ((home (expand-file-name (abbreviate-file-name (file-truename \"~/\")))))
 242    (list (cons (concat \"^\" (regexp-quote home)) \".\") \"~/.emacs-flc\"))
 243     =>
 244  ((\"^/your/true/home/directory/\" . \".\") \"~/.emacs-flc\")
 245
 246 would cause a file's current directory to be used if the file is under your
 247 home directory hierarchy, or otherwise the absolute directory `~/.emacs-flc'.")
 248
 249 (defvar fast-lock-minimum-size (* 25 1024)
 250   "*Minimum size of a buffer for cached fontification.
 251 Only buffers more than this can have associated Font Lock cache files saved.
 252 If nil, means cache files are never created.
 253 If a list, each element should be a cons pair of the form (MAJOR-MODE . SIZE),
 254 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 255  ((c-mode . 25600) (c++-mode . 25600) (rmail-mode . 1048576))
 256 means that the minimum size is 25K for buffers in C or C++ modes, one megabyte
 257 for buffers in Rmail mode, and size is irrelevant otherwise.")
 258
 259 (defvar fast-lock-save-events '(kill-buffer kill-emacs)
 260   "*Events under which caches will be saved.
 261 Valid events are `save-buffer', `kill-buffer' and `kill-emacs'.
 262 If concurrent editing sessions use the same associated cache file for a file's
 263 buffer, then you should add `save-buffer' to this list.")
 264
 265 (defvar fast-lock-save-others t
 266   "*If non-nil, save Font Lock cache files irrespective of file owner.
 267 If nil, means only buffer files known to be owned by you can have associated
 268 Font Lock cache files saved.  Ownership may be unknown for networked files.")
 269
 270 (defvar fast-lock-save-faces
 271   (when (save-match-data (string-match "XEmacs" (emacs-version)))
 272     ;; XEmacs uses extents for everything, so we have to pick the right ones.
 273     font-lock-face-list)
 274   "Faces that will be saved in a Font Lock cache file.
 275 If nil, means information for all faces will be saved.")
 276
 277 (defvar fast-lock-verbose font-lock-verbose
 278   "*If non-nil, means show status messages for cache processing.
 279 If a number, only buffers greater than this size have processing messages.")
 280 \f
 281 ;; User Functions:
 282
 283 ;;;###autoload
 284 (defun fast-lock-mode (&optional arg)
 285   "Toggle Fast Lock mode.
 286 With arg, turn Fast Lock mode on if and only if arg is positive and the buffer
 287 is associated with a file.  Enable it automatically in your `~/.emacs' by:
 288
 289  (setq font-lock-support-mode 'fast-lock-mode)
 290
 291 If Fast Lock mode is enabled, and the current buffer does not contain any text
 292 properties, any associated Font Lock cache is used if its timestamp matches the
 293 buffer's file, and its `font-lock-keywords' match those that you are using.
 294
 295 Font Lock caches may be saved:
 296 - When you save the file's buffer.
 297 - When you kill an unmodified file's buffer.
 298 - When you exit Emacs, for all unmodified or saved buffers.
 299 Depending on the value of `fast-lock-save-events'.
 300 See also the commands `fast-lock-read-cache' and `fast-lock-save-cache'.
 301
 302 Use \\[font-lock-fontify-buffer] to fontify the buffer if the cache is bad.
 303
 304 Various methods of control are provided for the Font Lock cache.  In general,
 305 see variable `fast-lock-cache-directories' and function `fast-lock-cache-name'.
 306 For saving, see variables `fast-lock-minimum-size', `fast-lock-save-events',
 307 `fast-lock-save-others' and `fast-lock-save-faces'."
 308   (interactive "P")
 309   ;; Only turn on if we are visiting a file.  We could use `buffer-file-name',
 310   ;; but many packages temporarily wrap that to nil when doing their own thing.
 311   (set (make-local-variable 'fast-lock-mode)
 312        (and buffer-file-truename
 313             (not (memq 'fast-lock-mode font-lock-inhibit-thing-lock))
 314             (if arg (> (prefix-numeric-value arg) 0) (not fast-lock-mode))))
 315   (if (and fast-lock-mode (not font-lock-mode))
 316       ;; Turned on `fast-lock-mode' rather than `font-lock-mode'.
 317       (let ((font-lock-support-mode 'fast-lock-mode))
 318         (font-lock-mode t))
 319     ;; Let's get down to business.
 320     (set (make-local-variable 'fast-lock-cache-timestamp) nil)
 321     (set (make-local-variable 'fast-lock-cache-filename) nil)
 322     (when (and fast-lock-mode (not font-lock-fontified))
 323       (fast-lock-read-cache))))
 324
 325 (defun fast-lock-read-cache ()
 326   "Read the Font Lock cache for the current buffer.
 327
 328 The following criteria must be met for a Font Lock cache file to be read:
 329 - Fast Lock mode must be turned on in the buffer.
 330 - The buffer must not be modified.
 331 - The buffer's `font-lock-keywords' must match the cache's.
 332 - The buffer file's timestamp must match the cache's.
 333 - Criteria imposed by `fast-lock-cache-directories'.
 334
 335 See `fast-lock-mode'."
 336   (interactive)
 337   (let ((directories fast-lock-cache-directories)
 338         (modified (buffer-modified-p)) (inhibit-read-only t)
 339         (fontified font-lock-fontified))
 340     (set (make-local-variable 'font-lock-fontified) nil)
 341     ;; Keep trying directories until fontification is turned off.
 342     (while (and directories (not font-lock-fontified))
 343       (let ((directory (fast-lock-cache-directory (car directories) nil)))
 344         (condition-case nil
 345             (when directory
 346               (setq fast-lock-cache-filename (fast-lock-cache-name directory))
 347               (when (file-readable-p fast-lock-cache-filename)
 348                 (load fast-lock-cache-filename t t t)))
 349           (error nil) (quit nil))
 350         (setq directories (cdr directories))))
 351     ;; Unset `fast-lock-cache-filename', and restore `font-lock-fontified', if
 352     ;; we don't use a cache.  (Note that `fast-lock-cache-data' sets the value
 353     ;; of `fast-lock-cache-timestamp'.)
 354     (set-buffer-modified-p modified)
 355     (unless font-lock-fontified
 356       (setq fast-lock-cache-filename nil font-lock-fontified fontified))))
 357
 358 (defun fast-lock-save-cache (&optional buffer)
 359   "Save the Font Lock cache of BUFFER or the current buffer.
 360
 361 The following criteria must be met for a Font Lock cache file to be saved:
 362 - Fast Lock mode must be turned on in the buffer.
 363 - The event must be one of `fast-lock-save-events'.
 364 - The buffer must be at least `fast-lock-minimum-size' bytes long.
 365 - The buffer file must be owned by you, or `fast-lock-save-others' must be t.
 366 - The buffer must contain at least one `face' text property.
 367 - The buffer must not be modified.
 368 - The buffer file's timestamp must be the same as the file's on disk.
 369 - The on disk file's timestamp must be different than the buffer's cache.
 370 - Criteria imposed by `fast-lock-cache-directories'.
 371
 372 See `fast-lock-mode'."
 373   (interactive)
 374   (save-excursion
 375     (when buffer
 376       (set-buffer buffer))
 377     (let ((min-size (font-lock-value-in-major-mode fast-lock-minimum-size))
 378           (file-timestamp (visited-file-modtime)) (saved nil))
 379       (when (and fast-lock-mode
 380              ;;
 381              ;; "Only save if the buffer matches the file, the file has
 382              ;; changed, and it was changed by the current emacs session."
 383              ;;
 384              ;; Only save if the buffer is not modified,
 385              ;; (i.e., so we don't save for something not on disk)
 386              (not (buffer-modified-p))
 387              ;; and the file's timestamp is the same as the buffer's,
 388              ;; (i.e., someone else hasn't written the file in the meantime)
 389              (verify-visited-file-modtime (current-buffer))
 390              ;; and the file's timestamp is different from the cache's.
 391              ;; (i.e., a save has occurred since the cache was read)
 392              (not (equal fast-lock-cache-timestamp file-timestamp))
 393              ;;
 394              ;; Only save if user's restrictions are satisfied.
 395              (and min-size (>= (buffer-size) min-size))
 396              (or fast-lock-save-others
 397                  (eq (user-uid) (nth 2 (file-attributes buffer-file-name))))
 398              ;;
 399              ;; Only save if there are `face' properties to save.
 400              (text-property-not-all (point-min) (point-max) 'face nil))
 401         ;;
 402         ;; Try each directory until we manage to save or the user quits.
 403         (let ((directories fast-lock-cache-directories))
 404           (while (and directories (memq saved '(nil error)))
 405             (let* ((dir (fast-lock-cache-directory (car directories) t))
 406                    (file (and dir (fast-lock-cache-name dir))))
 407               (when (and file (file-writable-p file))
 408                 (setq saved (fast-lock-save-cache-1 file file-timestamp)))
 409               (setq directories (cdr directories)))))))))
 410
 411 ;;;###autoload
 412 (defun turn-on-fast-lock ()
 413   "Unconditionally turn on Fast Lock mode."
 414   (fast-lock-mode t))
 415 \f
 416 ;;; API Functions:
 417
 418 (defun fast-lock-after-fontify-buffer ()
 419   ;; Delete the Font Lock cache file used to restore fontification, if any.
 420   (when fast-lock-cache-filename
 421     (if (file-writable-p fast-lock-cache-filename)
 422         (delete-file fast-lock-cache-filename)
 423       (message "File %s font lock cache cannot be deleted" (buffer-name))))
 424   ;; Flag so that a cache will be saved later even if the file is never saved.
 425   (setq fast-lock-cache-timestamp nil))
 426
 427 (defalias 'fast-lock-after-unfontify-buffer
 428   'ignore)
 429 \f
 430 ;; Miscellaneous Functions:
 431
 432 (defun fast-lock-save-cache-after-save-file ()
 433   ;; Do `fast-lock-save-cache' if `save-buffer' is on `fast-lock-save-events'.
 434   (when (memq 'save-buffer fast-lock-save-events)
 435     (fast-lock-save-cache)))
 436
 437 (defun fast-lock-save-cache-before-kill-buffer ()
 438   ;; Do `fast-lock-save-cache' if `kill-buffer' is on `fast-lock-save-events'.
 439   (when (memq 'kill-buffer fast-lock-save-events)
 440     (fast-lock-save-cache)))
 441
 442 (defun fast-lock-save-caches-before-kill-emacs ()
 443   ;; Do `fast-lock-save-cache's if `kill-emacs' is on `fast-lock-save-events'.
 444   (when (memq 'kill-emacs fast-lock-save-events)
 445     (mapcar 'fast-lock-save-cache (buffer-list))))
 446
 447 (defun fast-lock-cache-directory (directory create)
 448   "Return usable directory based on DIRECTORY.
 449 Returns nil if the directory does not exist, or, if CREATE non-nil, cannot be
 450 created.  DIRECTORY may be a string or a cons pair of the form (REGEXP . DIR).
 451 See `fast-lock-cache-directories'."
 452   (let ((dir
 453          (cond ((not buffer-file-name)
 454                 ;; Should never be nil, but `crypt++' screws it up.
 455                 nil)
 456                ((stringp directory)
 457                 ;; Just a directory.
 458                 directory)
 459                (t
 460                 ;; A directory iff the file name matches the regexp.
 461                 (let ((bufile (expand-file-name buffer-file-truename))
 462                       (case-fold-search nil))
 463                   (when (save-match-data (string-match (car directory) bufile))
 464                     (cdr directory)))))))
 465     (cond ((not dir)
 466            nil)
 467           ((file-accessible-directory-p dir)
 468            dir)
 469           (create
 470            (condition-case nil
 471                (progn (make-directory dir t) dir)
 472              (error nil))))))
 473
 474 ;; If you are wondering why we only hash if the directory is not ".", rather
 475 ;; than if `file-name-absolute-p', it is because if we just appended ".flc" for
 476 ;; relative cache directories (that are not ".") then it is possible that more
 477 ;; than one file would have the same cache name in that directory, if the luser
 478 ;; made a link from one relative cache directory to another.  (Phew!)
 479 (defun fast-lock-cache-name (directory)
 480   "Return full cache path name using caching DIRECTORY.
 481 If DIRECTORY is `.', the path is the buffer file name appended with `.flc'.
 482 Otherwise, the path name is constructed from DIRECTORY and the buffer's true
 483 abbreviated file name, with all `/' characters in the name replaced with `#'
 484 characters, and appended with `.flc'.
 485
 486 If the same file has different cache path names when edited on different
 487 machines, e.g., on one machine the cache file name has the prefix `#home',
 488 perhaps due to automount, try putting in your `~/.emacs' something like:
 489
 490  (setq directory-abbrev-alist (cons '(\"^/home/\" . \"/\") directory-abbrev-alist))
 491
 492 Emacs automagically removes the common `/tmp_mnt' automount prefix by default.
 493
 494 See `fast-lock-cache-directory'."
 495   (if (string-equal directory ".")
 496       (concat buffer-file-name ".flc")
 497     (let* ((bufile (expand-file-name buffer-file-truename))
 498            (chars-alist
 499             (if (eq system-type 'emx)
 500                 '((?/ . (?#)) (?# . (?# ?#)) (?: . (?\;)) (?\; . (?\; ?\;)))
 501               '((?/ . (?#)) (?# . (?# ?#)))))
 502            (mapchars
 503             (function (lambda (c) (or (cdr (assq c chars-alist)) (list c))))))
 504       (concat
 505        (file-name-as-directory (expand-file-name directory))
 506        (mapconcat 'char-to-string (apply 'append (mapcar mapchars bufile)) "")
 507        ".flc"))))
 508 \f
 509 ;; Font Lock Cache Processing Functions:
 510
 511 (defun fast-lock-save-cache-1 (file timestamp)
 512   ;; Save the FILE with the TIMESTAMP as:
 513   ;; (fast-lock-cache-data Version=2 TIMESTAMP font-lock-keywords PROPERTIES).
 514   ;; Returns non-nil if a save was attempted to a writable cache file.
 515   (let ((tpbuf (generate-new-buffer " *fast-lock*"))
 516         (verbose (if (numberp fast-lock-verbose)
 517                      (> (buffer-size) fast-lock-verbose)
 518                    fast-lock-verbose))
 519         (saved t))
 520     (if verbose (message "Saving %s font lock cache..." (buffer-name)))
 521     (condition-case nil
 522         (save-excursion
 523           (print (list 'fast-lock-cache-data 2
 524                        (list 'quote timestamp)
 525                        (list 'quote font-lock-keywords)
 526                        (list 'quote (fast-lock-get-face-properties)))
 527                  tpbuf)
 528           (set-buffer tpbuf)
 529           (write-region (point-min) (point-max) file nil 'quietly)
 530           (setq fast-lock-cache-timestamp timestamp
 531                 fast-lock-cache-filename file))
 532       (error (setq saved 'error)) (quit (setq saved 'quit)))
 533     (kill-buffer tpbuf)
 534     (if verbose (message "Saving %s font lock cache...%s" (buffer-name)
 535                          (cond ((eq saved 'error) "failed")
 536                                ((eq saved 'quit) "aborted")
 537                                (t "done"))))
 538     ;; We return non-nil regardless of whether a failure occurred.
 539     saved))
 540
 541 (defun fast-lock-cache-data (version timestamp keywords properties
 542                              &rest ignored)
 543   ;; Change from (HIGH LOW) for back compatibility.  Remove for version 3!
 544   (when (consp (cdr-safe timestamp))
 545     (setcdr timestamp (nth 1 timestamp)))
 546   ;; Compile KEYWORDS and `font-lock-keywords' in case one is and one isn't.
 547   (let ((current font-lock-keywords))
 548     (setq keywords (font-lock-compile-keywords keywords)
 549           font-lock-keywords (font-lock-compile-keywords current)))
 550   ;; Use the Font Lock cache PROPERTIES if we're using cache VERSION format 2,
 551   ;; the current buffer's file timestamp matches the TIMESTAMP, and the current
 552   ;; buffer's font-lock-keywords are the same as KEYWORDS.
 553   (let ((buf-timestamp (visited-file-modtime))
 554         (verbose (if (numberp fast-lock-verbose)
 555                      (> (buffer-size) fast-lock-verbose)
 556                    fast-lock-verbose))
 557         (loaded t))
 558     (if (or (/= version 2)
 559             (buffer-modified-p)
 560             (not (equal timestamp buf-timestamp))
 561             (not (equal keywords font-lock-keywords)))
 562         (setq loaded nil)
 563       (if verbose (message "Loading %s font lock cache..." (buffer-name)))
 564       (condition-case nil
 565           (fast-lock-set-face-properties properties)
 566         (error (setq loaded 'error)) (quit (setq loaded 'quit)))
 567       (if verbose (message "Loading %s font lock cache...%s" (buffer-name)
 568                            (cond ((eq loaded 'error) "failed")
 569                                  ((eq loaded 'quit) "aborted")
 570                                  (t "done")))))
 571     (setq font-lock-fontified (eq loaded t)
 572           fast-lock-cache-timestamp (and (eq loaded t) timestamp))))
 573 \f
 574 ;; Text Properties Processing Functions:
 575
 576 ;; This is fast, but fails if adjacent characters have different `face' text
 577 ;; properties.  Maybe that's why I dropped it in the first place?
 578 ;(defun fast-lock-get-face-properties ()
 579 ;  "Return a list of all `face' text properties in the current buffer.
 580 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 581 ;where VALUE is a `face' property value and STARTx and ENDx are positions."
 582 ;  (save-restriction
 583 ;    (widen)
 584 ;    (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 585 ;         (limit (point-max)) end properties value cell)
 586 ;      (while start
 587 ;       (setq end (next-single-property-change start 'face nil limit)
 588 ;             value (get-text-property start 'face))
 589 ;       ;; Make, or add to existing, list of regions with same `face'.
 590 ;       (if (setq cell (assq value properties))
 591 ;           (setcdr cell (cons start (cons end (cdr cell))))
 592 ;         (setq properties (cons (list value start end) properties)))
 593 ;       (setq start (next-single-property-change end 'face)))
 594 ;      properties)))
 595
 596 ;; This is slow, but copes if adjacent characters have different `face' text
 597 ;; properties, but fails if they are lists.
 598 ;(defun fast-lock-get-face-properties ()
 599 ;  "Return a list of all `face' text properties in the current buffer.
 600 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 601 ;where VALUE is a `face' property value and STARTx and ENDx are positions.
 602 ;Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 603 ;  (save-restriction
 604 ;    (widen)
 605 ;    (let ((faces (or fast-lock-save-faces (face-list))) (limit (point-max))
 606 ;         properties regions face start end)
 607 ;      (while faces
 608 ;       (setq face (car faces) faces (cdr faces) regions () end (point-min))
 609 ;       ;; Make a list of start/end regions with `face' property face.
 610 ;       (while (setq start (text-property-any end limit 'face face))
 611 ;         (setq end (or (text-property-not-all start limit 'face face) limit)
 612 ;               regions (cons start (cons end regions))))
 613 ;       ;; Add `face' face's regions, if any, to properties.
 614 ;       (when regions
 615 ;         (push (cons face regions) properties)))
 616 ;      properties)))
 617
 618 (defun fast-lock-get-face-properties ()
 619   "Return a list of all `face' text properties in the current buffer.
 620 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 621 where VALUE is a `face' property value and STARTx and ENDx are positions."
 622   (save-restriction
 623     (widen)
 624     (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 625           end properties value cell)
 626       (while start
 627         (setq end (next-single-property-change start 'face nil (point-max))
 628               value (get-text-property start 'face))
 629         ;; Make, or add to existing, list of regions with same `face'.
 630         (cond ((setq cell (assoc value properties))
 631                (setcdr cell (cons start (cons end (cdr cell)))))
 632               ((fast-lock-save-facep value)
 633                (push (list value start end) properties)))
 634         (setq start (text-property-not-all end (point-max) 'face nil)))
 635       properties)))
 636
 637 (defun fast-lock-set-face-properties (properties)
 638   "Set all `face' text properties to PROPERTIES in the current buffer.
 639 Any existing `face' text properties are removed first.
 640 See `fast-lock-get-face-properties' for the format of PROPERTIES."
 641   (save-buffer-state (plist regions)
 642     (save-restriction
 643       (widen)
 644       (font-lock-unfontify-region (point-min) (point-max))
 645       (while properties
 646         (setq plist (list 'face (car (car properties)))
 647               regions (cdr (car properties))
 648               properties (cdr properties))
 649         ;; Set the `face' property for each start/end region.
 650         (while regions
 651           (set-text-properties (nth 0 regions) (nth 1 regions) plist)
 652           (setq regions (nthcdr 2 regions)))))))
 653 \f
 654 ;; Functions for XEmacs:
 655
 656 (when (save-match-data (string-match "XEmacs" (emacs-version)))
 657   ;;
 658   ;; It would be better to use XEmacs' `map-extents' over extents with a
 659   ;; `font-lock' property, but `face' properties are on different extents.
 660   (defun fast-lock-get-face-properties ()
 661     "Return a list of all `face' text properties in the current buffer.
 662 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 663 where VALUE is a `face' property value and STARTx and ENDx are positions.
 664 Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 665     (save-restriction
 666       (widen)
 667       (let ((properties ()) cell)
 668         (map-extents
 669          (function (lambda (extent ignore)
 670             (let ((value (extent-face extent)))
 671               ;; We're only interested if it's one of `fast-lock-save-faces'.
 672               (when (and value (fast-lock-save-facep value))
 673                 (let ((start (extent-start-position extent))
 674                       (end (extent-end-position extent)))
 675                   ;; Make or add to existing list of regions with the same
 676                   ;; `face' property value.
 677                   (if (setq cell (assoc value properties))
 678                       (setcdr cell (cons start (cons end (cdr cell))))
 679                     (push (list value start end) properties))))
 680               ;; Return nil to keep `map-extents' going.
 681               nil))))
 682         properties)))
 683   ;;
 684   ;; Make extents just like XEmacs' font-lock.el does.
 685   (defun fast-lock-set-face-properties (properties)
 686     "Set all `face' text properties to PROPERTIES in the current buffer.
 687 Any existing `face' text properties are removed first.
 688 See `fast-lock-get-face-properties' for the format of PROPERTIES."
 689     (save-restriction
 690       (widen)
 691       (font-lock-unfontify-region (point-min) (point-max))
 692       (while properties
 693         (let ((face (car (car properties)))
 694               (regions (cdr (car properties))))
 695           ;; Set the `face' property, etc., for each start/end region.
 696           (while regions
 697             (font-lock-set-face (nth 0 regions) (nth 1 regions) face)
 698             (setq regions (nthcdr 2 regions)))
 699           (setq properties (cdr properties))))))
 700   ;;
 701   ;; XEmacs 19.12 font-lock.el's `font-lock-fontify-buffer' runs a hook.
 702   (add-hook 'font-lock-after-fontify-buffer-hook
 703             'fast-lock-after-fontify-buffer))
 704
 705 (unless (boundp 'font-lock-inhibit-thing-lock)
 706   (defvar font-lock-inhibit-thing-lock nil
 707     "List of Font Lock mode related modes that should not be turned on."))
 708
 709 (unless (fboundp 'font-lock-value-in-major-mode)
 710   (defun font-lock-value-in-major-mode (alist)
 711     ;; Return value in ALIST for `major-mode'.
 712     (if (consp alist)
 713         (cdr (or (assq major-mode alist) (assq t alist)))
 714       alist)))
 715
 716 (unless (fboundp 'font-lock-compile-keywords)
 717   (defalias 'font-lock-compile-keywords 'identity))
 718 \f
 719 ;; Install ourselves:
 720
 721 (add-hook 'after-save-hook 'fast-lock-save-cache-after-save-file)
 722 (add-hook 'kill-buffer-hook 'fast-lock-save-cache-before-kill-buffer)
 723 (add-hook 'kill-emacs-hook 'fast-lock-save-caches-before-kill-emacs)
 724
 725 ;;;###autoload
 726 (if (fboundp 'add-minor-mode) (add-minor-mode 'fast-lock-mode nil))
 727 ;;;###dont-autoload
 728 (unless (assq 'fast-lock-mode minor-mode-alist)
 729   (setq minor-mode-alist (append minor-mode-alist '((fast-lock-mode nil)))))
 730
 731 ;; Provide ourselves:
 732
 733 (provide 'fast-lock)
 734
 735 ;;; fast-lock.el ends here