lisp/emacs-lisp/easy-mmode.el

   1 ;;; easy-mmode.el --- easy definition for major and minor modes
   2
   3 ;; Copyright (C) 1997, 2000-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Georges Brun-Cottan <Georges.Brun-Cottan@inria.fr>
   6 ;; Maintainer: Stefan Monnier <monnier@gnu.org>
   7 ;; Package: emacs
   8
   9 ;; Keywords: extensions lisp
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; Minor modes are useful and common.  This package makes defining a
  29 ;; minor mode easy, by focusing on the writing of the minor mode
  30 ;; functionalities themselves.  Moreover, this package enforces a
  31 ;; conventional naming of user interface primitives, making things
  32 ;; natural for the minor-mode end-users.
  33
  34 ;; For each mode, easy-mmode defines the following:
  35 ;; <mode>      : The minor mode predicate. A buffer-local variable.
  36 ;; <mode>-map  : The keymap possibly associated to <mode>.
  37 ;;       see `define-minor-mode' documentation
  38 ;;
  39 ;; eval
  40 ;;  (pp (macroexpand '(define-minor-mode <your-mode> <doc>)))
  41 ;; to check the result before using it.
  42
  43 ;; The order in which minor modes are installed is important.  Keymap
  44 ;; lookup proceeds down minor-mode-map-alist, and the order there
  45 ;; tends to be the reverse of the order in which the modes were
  46 ;; installed.  Perhaps there should be a feature to let you specify
  47 ;; orderings.
  48
  49 ;; Additionally to `define-minor-mode', the package provides convenient
  50 ;; ways to define keymaps, and other helper functions for major and minor modes.
  51
  52 ;;; Code:
  53
  54 (eval-when-compile (require 'cl))
  55
  56 (defun easy-mmode-pretty-mode-name (mode &optional lighter)
  57   "Turn the symbol MODE into a string intended for the user.
  58 If provided, LIGHTER will be used to help choose capitalization by,
  59 replacing its case-insensitive matches with the literal string in LIGHTER."
  60   (let* ((case-fold-search t)
  61          ;; Produce "Foo-Bar minor mode" from foo-bar-minor-mode.
  62          (name (concat (replace-regexp-in-string
  63                         ;; If the original mode name included "-minor" (some
  64                         ;; of them don't, e.g. auto-revert-mode), then
  65                         ;; replace it with " minor".
  66                         "-Minor" " minor"
  67                         ;; "foo-bar-minor" -> "Foo-Bar-Minor"
  68                         (capitalize (replace-regexp-in-string
  69                                      ;; "foo-bar-minor-mode" -> "foo-bar-minor"
  70                                      "-mode\\'" "" (symbol-name mode))))
  71                        " mode")))
  72     (if (not (stringp lighter)) name
  73       ;; Strip leading and trailing whitespace from LIGHTER.
  74       (setq lighter (replace-regexp-in-string "\\`\\s-+\\|\\s-+\\'" ""
  75                                               lighter))
  76       ;; Replace any (case-insensitive) matches for LIGHTER in NAME
  77       ;; with a literal LIGHTER.  E.g., if NAME is "Iimage mode" and
  78       ;; LIGHTER is " iImag", then this will produce "iImage mode".
  79       ;; (LIGHTER normally comes from the mode-line string passed to
  80       ;; define-minor-mode, and normally includes at least one leading
  81       ;; space.)
  82       (replace-regexp-in-string (regexp-quote lighter) lighter name t t))))
  83
  84 ;;;###autoload
  85 (defalias 'easy-mmode-define-minor-mode 'define-minor-mode)
  86 ;;;###autoload
  87 (defmacro define-minor-mode (mode doc &optional init-value lighter keymap &rest body)
  88   "Define a new minor mode MODE.
  89 This defines the control variable MODE and the toggle command MODE.
  90 DOC is the documentation for the mode toggle command.
  91
  92 Optional INIT-VALUE is the initial value of the mode's variable.
  93 Optional LIGHTER is displayed in the modeline when the mode is on.
  94 Optional KEYMAP is the default keymap bound to the mode keymap.
  95   If non-nil, it should be a variable name (whose value is a keymap),
  96   or an expression that returns either a keymap or a list of
  97   arguments for `easy-mmode-define-keymap'.  If KEYMAP is not a symbol,
  98   this also defines the variable MODE-map.
  99
 100 BODY contains code to execute each time the mode is enabled or disabled.
 101   It is executed after toggling the mode, and before running MODE-hook.
 102   Before the actual body code, you can write keyword arguments, i.e.
 103   alternating keywords and values.  These following special keywords
 104   are supported (other keywords are passed to `defcustom' if the minor
 105   mode is global):
 106
 107 :group GROUP    Custom group name to use in all generated `defcustom' forms.
 108                 Defaults to MODE without the possible trailing \"-mode\".
 109                 Don't use this default group name unless you have written a
 110                 `defgroup' to define that group properly.
 111 :global GLOBAL  If non-nil specifies that the minor mode is not meant to be
 112                 buffer-local, so don't make the variable MODE buffer-local.
 113                 By default, the mode is buffer-local.
 114 :init-value VAL Same as the INIT-VALUE argument.
 115 :lighter SPEC   Same as the LIGHTER argument.
 116 :keymap MAP     Same as the KEYMAP argument.
 117 :require SYM    Same as in `defcustom'.
 118 :variable PLACE The location (as can be used with `setf') to use instead
 119                 of the variable MODE to store the state of the mode.  PLACE
 120                 can also be of the form (GET . SET) where GET is an expression
 121                 that returns the current state and SET is a function that takes
 122                 a new state and sets it.  If you specify a :variable, this
 123                 function assumes it is defined elsewhere.
 124
 125 For example, you could write
 126   (define-minor-mode foo-mode \"If enabled, foo on you!\"
 127     :lighter \" Foo\" :require 'foo :global t :group 'hassle :version \"27.5\"
 128     ...BODY CODE...)"
 129   (declare (debug (&define name stringp
 130                            [&optional [&not keywordp] sexp
 131                             &optional [&not keywordp] sexp
 132                             &optional [&not keywordp] sexp]
 133                            [&rest [keywordp sexp]]
 134                            def-body)))
 135
 136   ;; Allow skipping the first three args.
 137   (cond
 138    ((keywordp init-value)
 139     (setq body (list* init-value lighter keymap body)
 140           init-value nil lighter nil keymap nil))
 141    ((keywordp lighter)
 142     (setq body (list* lighter keymap body) lighter nil keymap nil))
 143    ((keywordp keymap) (push keymap body) (setq keymap nil)))
 144
 145   (let* ((last-message (make-symbol "last-message"))
 146          (mode-name (symbol-name mode))
 147          (pretty-name (easy-mmode-pretty-mode-name mode lighter))
 148          (globalp nil)
 149          (set nil)
 150          (initialize nil)
 151          (group nil)
 152          (type nil)
 153          (extra-args nil)
 154          (extra-keywords nil)
 155          (variable nil)          ;The PLACE where the state is stored.
 156          (setter nil)            ;The function (if any) to set the mode var.
 157          (modefun mode)          ;The minor mode function name we're defining.
 158          (require t)
 159          (hook (intern (concat mode-name "-hook")))
 160          (hook-on (intern (concat mode-name "-on-hook")))
 161          (hook-off (intern (concat mode-name "-off-hook")))
 162          keyw keymap-sym)
 163
 164     ;; Check keys.
 165     (while (keywordp (setq keyw (car body)))
 166       (setq body (cdr body))
 167       (case keyw
 168         (:init-value (setq init-value (pop body)))
 169         (:lighter (setq lighter (purecopy (pop body))))
 170         (:global (setq globalp (pop body)))
 171         (:extra-args (setq extra-args (pop body)))
 172         (:set (setq set (list :set (pop body))))
 173         (:initialize (setq initialize (list :initialize (pop body))))
 174         (:group (setq group (nconc group (list :group (pop body)))))
 175         (:type (setq type (list :type (pop body))))
 176         (:require (setq require (pop body)))
 177         (:keymap (setq keymap (pop body)))
 178         (:variable (setq variable (pop body))
 179          (if (not (functionp (cdr-safe variable)))
 180              ;; PLACE is not of the form (GET . SET).
 181              (setq mode variable)
 182            (setq mode (car variable))
 183            (setq setter (cdr variable))))
 184         (t (push keyw extra-keywords) (push (pop body) extra-keywords))))
 185
 186     (setq keymap-sym (if (and keymap (symbolp keymap)) keymap
 187                        (intern (concat mode-name "-map"))))
 188
 189     (unless set (setq set '(:set 'custom-set-minor-mode)))
 190
 191     (unless initialize
 192       (setq initialize '(:initialize 'custom-initialize-default)))
 193
 194     (unless group
 195       ;; We might as well provide a best-guess default group.
 196       (setq group
 197             `(:group ',(intern (replace-regexp-in-string
 198                                 "-mode\\'" "" mode-name)))))
 199
 200     ;; TODO? Mark booleans as safe if booleanp?  Eg abbrev-mode.
 201     (unless type (setq type '(:type 'boolean)))
 202
 203     `(progn
 204        ;; Define the variable to enable or disable the mode.
 205        ,(cond
 206          ;; If :variable is specified, then the var will be
 207          ;; declared elsewhere.
 208          (variable nil)
 209          ((not globalp)
 210           `(progn
 211              (defvar ,mode ,init-value ,(format "Non-nil if %s is enabled.
 212 Use the command `%s' to change this variable." pretty-name mode))
 213              (make-variable-buffer-local ',mode)))
 214          (t
 215           (let ((base-doc-string
 216                  (concat "Non-nil if %s is enabled.
 217 See the command `%s' for a description of this minor mode."
 218                          (if body "
 219 Setting this variable directly does not take effect;
 220 either customize it (see the info node `Easy Customization')
 221 or call the function `%s'."))))
 222             `(defcustom ,mode ,init-value
 223                ,(format base-doc-string pretty-name mode mode)
 224                ,@set
 225                ,@initialize
 226                ,@group
 227                ,@type
 228                ,@(unless (eq require t) `(:require ,require))
 229                ,@(nreverse extra-keywords)))))
 230
 231        ;; The actual function.
 232        (defun ,modefun (&optional arg ,@extra-args)
 233          ,(or doc
 234               (format (concat "Toggle %s on or off.
 235 Interactively, with no prefix argument, toggle the mode.
 236 With universal prefix ARG turn mode on.
 237 With zero or negative ARG turn mode off.
 238 \\{%s}") pretty-name keymap-sym))
 239          ;; Use `toggle' rather than (if ,mode 0 1) so that using
 240          ;; repeat-command still does the toggling correctly.
 241          (interactive (list (or current-prefix-arg 'toggle)))
 242          (let ((,last-message (current-message)))
 243            (,@(if setter (list setter)
 244                 (list (if (symbolp mode) 'setq 'setf) mode))
 245             (if (eq arg 'toggle)
 246                 (not ,mode)
 247               ;; A nil argument also means ON now.
 248               (> (prefix-numeric-value arg) 0)))
 249            ,@body
 250            ;; The on/off hooks are here for backward compatibility only.
 251            (run-hooks ',hook (if ,mode ',hook-on ',hook-off))
 252            (if (called-interactively-p 'any)
 253                (progn
 254                  ,(if (and globalp (symbolp mode))
 255                       `(customize-mark-as-set ',mode))
 256                  ;; Avoid overwriting a message shown by the body,
 257                  ;; but do overwrite previous messages.
 258                  (unless (and (current-message)
 259                               (not (equal ,last-message
 260                                           (current-message))))
 261                    (message ,(format "%s %%sabled" pretty-name)
 262                             (if ,mode "en" "dis"))))))
 263          (force-mode-line-update)
 264          ;; Return the new setting.
 265          ,mode)
 266
 267        ;; Autoloading a define-minor-mode autoloads everything
 268        ;; up-to-here.
 269        :autoload-end
 270
 271        ;; Define the minor-mode keymap.
 272        ,(unless (symbolp keymap)        ;nil is also a symbol.
 273           `(defvar ,keymap-sym
 274              (let ((m ,keymap))
 275                (cond ((keymapp m) m)
 276                      ((listp m) (easy-mmode-define-keymap m))
 277                      (t (error "Invalid keymap %S" m))))
 278              ,(format "Keymap for `%s'." mode-name)))
 279
 280        ,(if (not (symbolp mode))
 281             (if (or lighter keymap)
 282                 (error ":lighter and :keymap unsupported with mode expression %s" mode))
 283           `(with-no-warnings
 284              (add-minor-mode ',mode ',lighter
 285                            ,(if keymap keymap-sym
 286                                 `(if (boundp ',keymap-sym) ,keymap-sym))
 287                              nil
 288                              ,(unless (eq mode modefun) 'modefun)))))))
 289 \f
 290 ;;;
 291 ;;; make global minor mode
 292 ;;;
 293
 294 ;;;###autoload
 295 (defalias 'easy-mmode-define-global-mode 'define-globalized-minor-mode)
 296 ;;;###autoload
 297 (defalias 'define-global-minor-mode 'define-globalized-minor-mode)
 298 ;;;###autoload
 299 (defmacro define-globalized-minor-mode (global-mode mode turn-on &rest keys)
 300   "Make a global mode GLOBAL-MODE corresponding to buffer-local minor MODE.
 301 TURN-ON is a function that will be called with no args in every buffer
 302   and that should try to turn MODE on if applicable for that buffer.
 303 KEYS is a list of CL-style keyword arguments.  As the minor mode
 304   defined by this function is always global, any :global keyword is
 305   ignored.  Other keywords have the same meaning as in `define-minor-mode',
 306   which see.  In particular, :group specifies the custom group.
 307   The most useful keywords are those that are passed on to the
 308   `defcustom'.  It normally makes no sense to pass the :lighter
 309   or :keymap keywords to `define-globalized-minor-mode', since these
 310   are usually passed to the buffer-local version of the minor mode.
 311
 312 If MODE's set-up depends on the major mode in effect when it was
 313 enabled, then disabling and reenabling MODE should make MODE work
 314 correctly with the current major mode.  This is important to
 315 prevent problems with derived modes, that is, major modes that
 316 call another major mode in their body."
 317
 318   (let* ((global-mode-name (symbol-name global-mode))
 319          (pretty-name (easy-mmode-pretty-mode-name mode))
 320          (pretty-global-name (easy-mmode-pretty-mode-name global-mode))
 321          (group nil)
 322          (extra-keywords nil)
 323          (MODE-buffers (intern (concat global-mode-name "-buffers")))
 324          (MODE-enable-in-buffers
 325           (intern (concat global-mode-name "-enable-in-buffers")))
 326          (MODE-check-buffers
 327           (intern (concat global-mode-name "-check-buffers")))
 328          (MODE-cmhh (intern (concat global-mode-name "-cmhh")))
 329          (MODE-major-mode (intern (concat (symbol-name mode) "-major-mode")))
 330          keyw)
 331
 332     ;; Check keys.
 333     (while (keywordp (setq keyw (car keys)))
 334       (setq keys (cdr keys))
 335       (case keyw
 336         (:group (setq group (nconc group (list :group (pop keys)))))
 337         (:global (setq keys (cdr keys)))
 338         (t (push keyw extra-keywords) (push (pop keys) extra-keywords))))
 339
 340     (unless group
 341       ;; We might as well provide a best-guess default group.
 342       (setq group
 343             `(:group ',(intern (replace-regexp-in-string
 344                                 "-mode\\'" "" (symbol-name mode))))))
 345
 346     `(progn
 347        (defvar ,MODE-major-mode nil)
 348        (make-variable-buffer-local ',MODE-major-mode)
 349        ;; The actual global minor-mode
 350        (define-minor-mode ,global-mode
 351          ;; Very short lines to avoid too long lines in the generated
 352          ;; doc string.
 353          ,(format "Toggle %s in all buffers.
 354 With prefix ARG, enable %s if ARG is positive;
 355 otherwise, disable it.  If called from Lisp, enable the mode if
 356 ARG is omitted or nil.
 357
 358 %s is enabled in all buffers where
 359 \`%s' would do it.
 360 See `%s' for more information on %s."
 361                   pretty-name pretty-global-name
 362                   pretty-name turn-on mode pretty-name)
 363          :global t ,@group ,@(nreverse extra-keywords)
 364
 365          ;; Setup hook to handle future mode changes and new buffers.
 366          (if ,global-mode
 367              (progn
 368                (add-hook 'after-change-major-mode-hook
 369                          ',MODE-enable-in-buffers)
 370                (add-hook 'fundamental-mode-hook ',MODE-enable-in-buffers)
 371                (add-hook 'find-file-hook ',MODE-check-buffers)
 372                (add-hook 'change-major-mode-hook ',MODE-cmhh))
 373            (remove-hook 'after-change-major-mode-hook ',MODE-enable-in-buffers)
 374            (remove-hook 'fundamental-mode-hook ',MODE-enable-in-buffers)
 375            (remove-hook 'find-file-hook ',MODE-check-buffers)
 376            (remove-hook 'change-major-mode-hook ',MODE-cmhh))
 377
 378          ;; Go through existing buffers.
 379          (dolist (buf (buffer-list))
 380            (with-current-buffer buf
 381              (if ,global-mode (,turn-on) (when ,mode (,mode -1))))))
 382
 383        ;; Autoloading define-globalized-minor-mode autoloads everything
 384        ;; up-to-here.
 385        :autoload-end
 386
 387        ;; List of buffers left to process.
 388        (defvar ,MODE-buffers nil)
 389
 390        ;; The function that calls TURN-ON in each buffer.
 391        (defun ,MODE-enable-in-buffers ()
 392          (dolist (buf ,MODE-buffers)
 393            (when (buffer-live-p buf)
 394              (with-current-buffer buf
 395                (unless (eq ,MODE-major-mode major-mode)
 396                  (if ,mode
 397                      (progn
 398                        (,mode -1)
 399                        (,turn-on)
 400                        (setq ,MODE-major-mode major-mode))
 401                    (,turn-on)
 402                    (setq ,MODE-major-mode major-mode)))))))
 403        (put ',MODE-enable-in-buffers 'definition-name ',global-mode)
 404
 405        (defun ,MODE-check-buffers ()
 406          (,MODE-enable-in-buffers)
 407          (setq ,MODE-buffers nil)
 408          (remove-hook 'post-command-hook ',MODE-check-buffers))
 409        (put ',MODE-check-buffers 'definition-name ',global-mode)
 410
 411        ;; The function that catches kill-all-local-variables.
 412        (defun ,MODE-cmhh ()
 413          (add-to-list ',MODE-buffers (current-buffer))
 414          (add-hook 'post-command-hook ',MODE-check-buffers))
 415        (put ',MODE-cmhh 'definition-name ',global-mode))))
 416
 417 ;;;
 418 ;;; easy-mmode-defmap
 419 ;;;
 420
 421 (eval-and-compile
 422   (if (fboundp 'set-keymap-parents)
 423       (defalias 'easy-mmode-set-keymap-parents 'set-keymap-parents)
 424     (defun easy-mmode-set-keymap-parents (m parents)
 425       (set-keymap-parent
 426        m
 427        (cond
 428         ((not (consp parents)) parents)
 429         ((not (cdr parents)) (car parents))
 430         (t (let ((m (copy-keymap (pop parents))))
 431              (easy-mmode-set-keymap-parents m parents)
 432              m)))))))
 433
 434 ;;;###autoload
 435 (defun easy-mmode-define-keymap (bs &optional name m args)
 436   "Return a keymap built from bindings BS.
 437 BS must be a list of (KEY . BINDING) where
 438 KEY and BINDINGS are suitable for `define-key'.
 439 Optional NAME is passed to `make-sparse-keymap'.
 440 Optional map M can be used to modify an existing map.
 441 ARGS is a list of additional keyword arguments.
 442
 443 Valid keywords and arguments are:
 444
 445   :name      Name of the keymap; overrides NAME argument.
 446   :dense     Non-nil for a dense keymap.
 447   :inherit   Parent keymap.
 448   :group     Ignored.
 449   :suppress  Non-nil to call `suppress-keymap' on keymap,
 450              'nodigits to suppress digits as prefix arguments."
 451   (let (inherit dense suppress)
 452     (while args
 453       (let ((key (pop args))
 454             (val (pop args)))
 455         (case key
 456          (:name (setq name val))
 457          (:dense (setq dense val))
 458          (:inherit (setq inherit val))
 459          (:suppress (setq suppress val))
 460          (:group)
 461          (t (message "Unknown argument %s in defmap" key)))))
 462     (unless (keymapp m)
 463       (setq bs (append m bs))
 464       (setq m (if dense (make-keymap name) (make-sparse-keymap name))))
 465     (when suppress
 466       (suppress-keymap m (eq suppress 'nodigits)))
 467     (dolist (b bs)
 468       (let ((keys (car b))
 469             (binding (cdr b)))
 470         (dolist (key (if (consp keys) keys (list keys)))
 471           (cond
 472            ((symbolp key)
 473             (substitute-key-definition key binding m global-map))
 474            ((null binding)
 475             (unless (keymapp (lookup-key m key)) (define-key m key binding)))
 476            ((let ((o (lookup-key m key)))
 477               (or (null o) (numberp o) (eq o 'undefined)))
 478             (define-key m key binding))))))
 479     (cond
 480      ((keymapp inherit) (set-keymap-parent m inherit))
 481      ((consp inherit) (easy-mmode-set-keymap-parents m inherit)))
 482     m))
 483
 484 ;;;###autoload
 485 (defmacro easy-mmode-defmap (m bs doc &rest args)
 486   "Define a constant M whose value is the result of `easy-mmode-define-keymap'.
 487 The M, BS, and ARGS arguments are as per that function.  DOC is
 488 the constant's documentation."
 489   `(defconst ,m
 490      (easy-mmode-define-keymap ,bs nil (if (boundp ',m) ,m) ,(cons 'list args))
 491      ,doc))
 492
 493 \f
 494 ;;;
 495 ;;; easy-mmode-defsyntax
 496 ;;;
 497
 498 (defun easy-mmode-define-syntax (css args)
 499   (let ((st (make-syntax-table (plist-get args :copy)))
 500         (parent (plist-get args :inherit)))
 501     (dolist (cs css)
 502       (let ((char (car cs))
 503             (syntax (cdr cs)))
 504         (if (sequencep char)
 505             (mapc (lambda (c) (modify-syntax-entry c syntax st)) char)
 506           (modify-syntax-entry char syntax st))))
 507     (if parent (set-char-table-parent
 508                 st (if (symbolp parent) (symbol-value parent) parent)))
 509     st))
 510
 511 ;;;###autoload
 512 (defmacro easy-mmode-defsyntax (st css doc &rest args)
 513   "Define variable ST as a syntax-table.
 514 CSS contains a list of syntax specifications of the form (CHAR . SYNTAX)."
 515   `(progn
 516      (autoload 'easy-mmode-define-syntax "easy-mmode")
 517      (defconst ,st (easy-mmode-define-syntax ,css ,(cons 'list args)) ,doc)))
 518
 519
 520 \f
 521 ;;;
 522 ;;; easy-mmode-define-navigation
 523 ;;;
 524
 525 (defmacro easy-mmode-define-navigation (base re &optional name endfun narrowfun
 526                                              &rest body)
 527   "Define BASE-next and BASE-prev to navigate in the buffer.
 528 RE determines the places the commands should move point to.
 529 NAME should describe the entities matched by RE.  It is used to build
 530   the docstrings of the two functions.
 531 BASE-next also tries to make sure that the whole entry is visible by
 532   searching for its end (by calling ENDFUN if provided or by looking for
 533   the next entry) and recentering if necessary.
 534 ENDFUN should return the end position (with or without moving point).
 535 NARROWFUN non-nil means to check for narrowing before moving, and if
 536 found, do `widen' first and then call NARROWFUN with no args after moving.
 537 BODY is executed after moving to the destination location."
 538   (declare (indent 5) (debug (exp exp exp def-form def-form &rest def-body)))
 539   (let* ((base-name (symbol-name base))
 540          (prev-sym (intern (concat base-name "-prev")))
 541          (next-sym (intern (concat base-name "-next")))
 542          (when-narrowed
 543           (lambda (body)
 544             (if (null narrowfun) body
 545               `(let ((was-narrowed
 546                       (prog1 (or (< (- (point-max) (point-min)) (buffer-size)))
 547                         (widen))))
 548                  ,body
 549                  (when was-narrowed (,narrowfun)))))))
 550     (unless name (setq name base-name))
 551     `(progn
 552        (add-to-list 'debug-ignored-errors
 553                     ,(concat "^No \\(previous\\|next\\) " (regexp-quote name)))
 554        (defun ,next-sym (&optional count)
 555          ,(format "Go to the next COUNT'th %s." name)
 556          (interactive "p")
 557          (unless count (setq count 1))
 558          (if (< count 0) (,prev-sym (- count))
 559            (if (looking-at ,re) (setq count (1+ count)))
 560            ,(funcall when-narrowed
 561              `(if (not (re-search-forward ,re nil t count))
 562                   (if (looking-at ,re)
 563                       (goto-char (or ,(if endfun `(,endfun)) (point-max)))
 564                     (error "No next %s" ,name))
 565                 (goto-char (match-beginning 0))
 566                 (when (and (eq (current-buffer) (window-buffer (selected-window)))
 567                            (called-interactively-p 'interactive))
 568                   (let ((endpt (or (save-excursion
 569                                      ,(if endfun `(,endfun)
 570                                         `(re-search-forward ,re nil t 2)))
 571                                    (point-max))))
 572                     (unless (pos-visible-in-window-p endpt nil t)
 573                       (recenter '(0)))))))
 574            ,@body))
 575        (put ',next-sym 'definition-name ',base)
 576        (defun ,prev-sym (&optional count)
 577          ,(format "Go to the previous COUNT'th %s" (or name base-name))
 578          (interactive "p")
 579          (unless count (setq count 1))
 580          (if (< count 0) (,next-sym (- count))
 581            ,(funcall when-narrowed
 582              `(unless (re-search-backward ,re nil t count)
 583                 (error "No previous %s" ,name)))
 584            ,@body))
 585        (put ',prev-sym 'definition-name ',base))))
 586
 587
 588 (provide 'easy-mmode)
 589
 590 ;;; easy-mmode.el ends here