configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation; either version 3, or (at your option)
  14 dnl  any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  23 dnl  Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 dnl  Boston, MA 02110-1301, USA.
  25
  26 AC_PREREQ(2.61)dnl
  27 AC_INIT(emacs, 23.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 lispdir='${datadir}/emacs/${version}/lisp'
  36 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  37 '${datadir}/emacs/site-lisp'
  38 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  39 etcdir='${datadir}/emacs/${version}/etc'
  40 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  41 docdir='${datadir}/emacs/${version}/etc'
  42 gamedir='${localstatedir}/games/emacs'
  43
  44 gameuser=games
  45
  46 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  47 dnl Create a new --with option that defaults to being disabled.
  48 dnl NAME is the base name of the option.  The shell variable with_NAME
  49 dnl   will be set to either the user's value (if the option is
  50 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  51 dnl   option is not specified).  Note that the shell variable name is
  52 dnl   constructed as autoconf does, by replacing non-alphanumeric
  53 dnl   characters with "_".
  54 dnl HELP-STRING is the help text for the option.
  55 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  56   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  57     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  58 ])dnl
  59
  60 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  61 dnl Create a new --with option that defaults to being enabled.  NAME
  62 dnl   is the base name of the option.  The shell variable with_NAME
  63 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  64 dnl   'yes' (if the option is not specified).  Note that the shell
  65 dnl   variable name is constructed as autoconf does, by replacing
  66 dnl   non-alphanumeric characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  70    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  71 ])dnl
  72
  73 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  74 if test "$with_pop" = yes; then
  75    AC_DEFINE(MAIL_USE_POP)
  76 fi
  77 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  78
  79 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  80 if test "$with_kerberos" = yes; then
  81    AC_DEFINE(KERBEROS)
  82 fi
  83 AH_TEMPLATE(KERBEROS,
  84             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  85
  86 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  87 if test "${with_kerberos5}" = yes; then
  88   if test "${with_kerberos}" != yes; then
  89     with_kerberos=yes
  90     AC_DEFINE(KERBEROS)
  91   fi
  92   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  93 fi
  94
  95 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  96 if test "$with_hesiod" = yes; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 101
 102 dnl FIXME currently it is not the last.
 103 dnl This should be the last --with option, because --with-x is
 104 dnl added later on when we find the path of X, and it's best to
 105 dnl keep them together visually.
 106 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 107  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 108 [         case "${withval}" in
 109             y | ye | yes )      val=gtk ;;
 110             n | no )            val=no  ;;
 111             l | lu | luc | luci | lucid )       val=lucid ;;
 112             a | at | ath | athe | athen | athena )      val=athena ;;
 113             m | mo | mot | moti | motif )       val=motif ;;
 114             g | gt | gtk  )     val=gtk ;;
 115             * )
 116 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 117 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 118 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 119             ;;
 120           esac
 121           with_x_toolkit=$val
 122 ])
 123
 124 dnl _ON results in a '--without' option in the --help output, so
 125 dnl the help text should refer to "don't compile", etc.
 126 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 127 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 128 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 129 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 130 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 131 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 132
 133 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 134 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 135 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 136 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 137
 138 OPTION_DEFAULT_OFF([gtk],[use GTK toolkit])
 139 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 140 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 141 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 142 OPTION_DEFAULT_OFF([carbon],[use Carbon GUI on Mac OS X.  This is unsupported!])
 143
 144 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 145 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 146
 147 AC_ARG_WITH([pkg-config-prog],dnl
 148 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 149                   [Path to pkg-config for finding GTK and librsvg])])
 150 if test "X${with_pkg_config_prog}" != X; then
 151    if test "${with_pkg_config_prog}" != yes; then
 152       PKG_CONFIG="${with_pkg_config_prog}"
 153    fi
 154 fi
 155
 156 AC_ARG_ENABLE(carbon-app,
 157 [AS_HELP_STRING([--enable-carbon-app@<:@=DIR@:>@],
 158                 [specify install directory for Emacs.app on Mac OS X
 159                  [DIR=/Application]])],
 160 [ carbon_appdir_x=${enableval}])
 161
 162 AC_ARG_ENABLE(font-backend,
 163 [  --enable-font-backend   compile code of font-backend support],
 164       USE_FONT_BACKEND=$enableval,
 165       USE_FONT_BACKEND=no)
 166
 167 AC_ARG_ENABLE(asserts,
 168 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 169       USE_XASSERTS=$enableval,
 170       USE_XASSERTS=no)
 171
 172 AC_ARG_ENABLE(maintainer-mode,
 173 [AS_HELP_STRING([--enable-maintainer-mode],
 174                 [enable make rules and dependencies not useful (and sometimes
 175                  confusing) to the casual installer])],
 176       USE_MAINTAINER_MODE=$enableval,
 177       USE_MAINTAINER_MODE=no)
 178 if test $USE_MAINTAINER_MODE = yes; then
 179   MAINT=
 180 else
 181   MAINT=#
 182 fi
 183 AC_SUBST(MAINT)
 184
 185 AC_ARG_ENABLE(locallisppath,
 186 [AS_HELP_STRING([--enable-locallisppath=PATH],
 187                 [directories Emacs should search for lisp files specific
 188                  to this site])],
 189 if test "${enableval}" = "no"; then
 190   locallisppath=
 191 elif test "${enableval}" != "yes"; then
 192   locallisppath=${enableval}
 193 fi)
 194
 195 #### Make srcdir absolute, if it isn't already.  It's important to
 196 #### avoid running the path through pwd unnecessarily, since pwd can
 197 #### give you automounter prefixes, which can go away.  We do all this
 198 #### so Emacs can find its files when run uninstalled.
 199 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 200 unset CDPATH
 201 case "${srcdir}" in
 202   /* ) ;;
 203   . )
 204     ## We may be able to use the $PWD environment variable to make this
 205     ## absolute.  But sometimes PWD is inaccurate.
 206     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 207     ## but that tested only for a well-formed and valid PWD,
 208     ## it did not object when PWD was well-formed and valid but just wrong.
 209     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 210     then
 211       srcdir="$PWD"
 212     else
 213       srcdir="`(cd ${srcdir}; pwd)`"
 214     fi
 215   ;;
 216   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 217 esac
 218
 219 #### Check if the source directory already has a configured system in it.
 220 if test `pwd` != `(cd ${srcdir} && pwd)` \
 221    && test -f "${srcdir}/src/config.h" ; then
 222   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 223    as a build directory right now; it has been configured in its own
 224    right.  To configure in another directory as well, you MUST
 225    use GNU make.  If you do not have GNU make, then you must
 226    now do `make distclean' in ${srcdir},
 227    and then run $0 again.]])
 228 fi
 229
 230 #### Given the configuration name, set machfile and opsysfile to the
 231 #### names of the m/*.h and s/*.h files we should use.
 232
 233 ### Canonicalize the configuration name.
 234
 235 AC_CANONICAL_HOST
 236 canonical=$host
 237 configuration=${host_alias-${build_alias-$host}}
 238
 239 dnl This used to use changequote, but, apart from `changequote is evil'
 240 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 241 dnl the great gob of text.  Thus it's not processed for possible expansion.
 242 dnl Just make sure the brackets remain balanced.
 243 dnl
 244 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 245 dnl indicated by comments.
 246 dnl quotation begins
 247 [
 248
 249 ### If you add support for a new configuration, add code to this
 250 ### switch statement to recognize your configuration name and select
 251 ### the appropriate operating system and machine description files.
 252
 253 ### You would hope that you could choose an m/*.h file pretty much
 254 ### based on the machine portion of the configuration name, and an s-
 255 ### file based on the operating system portion.  However, it turns out
 256 ### that each m/*.h file is pretty manufacturer-specific - for
 257 ### example hp9000s300.h is a 68000 machine;
 258 ### mips.h, pmax.h are all MIPS
 259 ### machines.  So we basically have to have a special case for each
 260 ### configuration name.
 261 ###
 262 ### As far as handling version numbers on operating systems is
 263 ### concerned, make sure things will fail in a fixable way.  If
 264 ### /etc/MACHINES doesn't say anything about version numbers, be
 265 ### prepared to handle anything reasonably.  If version numbers
 266 ### matter, be sure /etc/MACHINES says something about it.
 267 ###
 268 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 269 ### "System V Release 4"; he writes, "The old convention encouraged
 270 ### confusion between `system' and `release' levels'."
 271
 272 machine='' opsys='' unported=no
 273 case "${canonical}" in
 274
 275   ## FreeBSD ports
 276   *-*-freebsd* )
 277     opsys=freebsd
 278     case "${canonical}" in
 279       alpha*-*-freebsd*)        machine=alpha ;;
 280       ia64-*-freebsd*)          machine=ia64 ;;
 281       sparc64-*-freebsd*)       machine=sparc ;;
 282       powerpc-*-freebsd*)       machine=macppc ;;
 283       i[3456]86-*-freebsd*)     machine=intel386 ;;
 284       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 285     esac
 286   ;;
 287
 288   ## FreeBSD kernel + glibc based userland
 289   *-*-kfreebsd*gnu* )
 290     opsys=gnu-kfreebsd
 291     case "${canonical}" in
 292       alpha*-*-kfreebsd*)       machine=alpha ;;
 293       ia64-*-kfreebsd*)         machine=ia64 ;;
 294       sparc64-*-kfreebsd*)      machine=sparc ;;
 295       powerpc-*-kfreebsd*)      machine=macppc ;;
 296       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 297       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 298     esac
 299   ;;
 300
 301   ## NetBSD ports
 302   *-*-netbsd* )
 303     opsys=netbsd
 304     if test -f /usr/lib/crti.o; then]
 305 dnl The close and open brackets here are because this section is quoted --
 306 dnl see the `changequote' comment above.
 307       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 308 [   fi
 309
 310     case "${canonical}" in
 311       alpha*-*-netbsd*) machine=alpha ;;
 312       i[3456]86-*-netbsd*) machine=intel386 ;;
 313       m68k-*-netbsd*)
 314                         # This is somewhat bogus.
 315                         machine=hp9000s300 ;;
 316       mips-*-netbsd*)   machine=pmax ;;
 317       mipsel-*-netbsd*) machine=pmax ;;
 318       mipseb-*-netbsd*) machine=pmax ;;
 319       powerpc-*-netbsd*) machine=macppc ;;
 320       sparc*-*-netbsd*) machine=sparc ;;
 321       vax-*-netbsd*)    machine=vax ;;
 322       arm-*-netbsd*)    machine=arm ;;
 323       x86_64-*-netbsd*) machine=amdx86-64 ;;
 324       hppa-*-netbsd*)   machine=hp800 ;;
 325     esac
 326   ;;
 327
 328   ## OpenBSD ports
 329   *-*-openbsd* )
 330     opsys=openbsd
 331     case "${canonical}" in
 332       alpha*-*-openbsd*)        machine=alpha ;;
 333       arm-*-openbsd*)          machine=arm ;;
 334       hppa-*-openbsd*)         machine=hp9000s300 ;;
 335       i386-*-openbsd*)         machine=intel386 ;;
 336       m68k-*-openbsd*)         machine=hp9000s300 ;;
 337       mips64-*-openbsd*)       machine=mips64 ;;
 338       powerpc-*-openbsd*)      machine=macppc ;;
 339       sparc*-*-openbsd*)       machine=sparc ;;
 340       vax-*-openbsd*)          machine=vax ;;
 341       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 342     esac
 343   ;;
 344
 345   ## LynxOS ports
 346   *-*-lynxos* )
 347     opsys=lynxos
 348     case "${canonical}" in
 349       i[3456]86-*-lynxos*) machine=intel386 ;;
 350       powerpc-*-lynxos*) machine=powerpc ;;
 351     esac
 352   ;;
 353
 354   ## BSDI ports
 355   *-*-bsdi* )
 356     opsys=bsdi
 357     case "${canonical}" in
 358       i[345]86-*-bsdi*) machine=intel386 ;;
 359       sparc-*-bsdi*)  machine=sparc ;;
 360       powerpc-*-bsdi*)  machine=macppc ;;
 361     esac
 362     case "${canonical}" in
 363       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 364       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 365       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 366       *-*-bsdi3* )              opsys=bsdos3 ;;
 367       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 368     esac
 369   ;;
 370
 371   ## Alpha (DEC) machines.
 372   alpha*-dec-osf* )
 373     machine=alpha opsys=osf1
 374     # This is needed to find X11R6.1 libraries for certain tests.
 375     NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 376     GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 377     # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
 378     # due to non-traditional preprocessing with the current compiler
 379     # defaults.  OSF 4 can also have that compiler version, and there
 380     # seems always to have been a usable /usr/bin/cpp.
 381     NON_GNU_CPP=/usr/bin/cpp
 382     case "${canonical}" in
 383     alpha*-dec-osf[5-9]*)
 384       opsys=osf5-0 ;;
 385     esac
 386   ;;
 387
 388   alpha*-*-linux-gnu* )
 389     machine=alpha opsys=gnu-linux
 390   ;;
 391
 392   arm*-*-linux-gnu* )
 393     machine=arm opsys=gnu-linux
 394   ;;
 395
 396   ## Apple Darwin / Mac OS X
 397   *-apple-darwin* )
 398     case "${canonical}" in
 399       i[3456]86-* )  machine=intel386 ;;
 400       powerpc-* )    machine=powermac ;;
 401       * )            unported=yes ;;
 402     esac
 403     opsys=darwin
 404     # Define CPP as follows to make autoconf work correctly.
 405     CPP="${CC-cc} -E -no-cpp-precomp"
 406     # Use fink packages if available.
 407     if test -d /sw/include && test -d /sw/lib; then
 408       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 409       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 410       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 411     fi
 412   ;;
 413
 414   ## Compaq Nonstop
 415   mips-compaq-nonstopux* )
 416     machine=nonstopux opsys=nonstopux
 417     ;;
 418
 419   ## Cubix QBx/386
 420   i[3456]86-cubix-sysv* )
 421     machine=intel386 opsys=usg5-3
 422   ;;
 423
 424   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 425     machine=pmax opsys=bsd4-2
 426   ;;
 427   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 428     machine=pmax opsys=bsd4-3
 429   ;;
 430   mips-dec-ultrix* )
 431     machine=pmax opsys=ultrix4-3
 432   ;;
 433   mips-dec-osf* )
 434     machine=pmax opsys=osf1
 435   ;;
 436   mips-dec-mach_bsd4.3* )
 437     machine=pmax opsys=mach-bsd4-3
 438   ;;
 439
 440   ## HP 9000 series 200 or 300
 441   m68*-hp-bsd* )
 442     machine=hp9000s300 opsys=bsd4-3
 443   ;;
 444   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 445   m68*-hp-hpux* )
 446     case "`uname -r`" in
 447       ## Someone's system reports A.B8.05 for this.
 448       ## I wonder what other possibilities there are.
 449       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 450       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 451       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 452       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 453       *) machine=hp9000s300 opsys=hpux ;;
 454     esac
 455   ;;
 456
 457   ## HP 9000 series 700 and 800, running HP/UX
 458   hppa*-hp-hpux7* )
 459     machine=hp800 opsys=hpux
 460   ;;
 461   hppa*-hp-hpux8* )
 462     machine=hp800 opsys=hpux8
 463   ;;
 464   hppa*-hp-hpux9shr* )
 465     machine=hp800 opsys=hpux9shr
 466   ;;
 467   hppa*-hp-hpux9* )
 468     machine=hp800 opsys=hpux9
 469   ;;
 470   hppa*-hp-hpux10.2* )
 471     machine=hp800 opsys=hpux10-20
 472   ;;
 473   hppa*-hp-hpux10* )
 474     machine=hp800 opsys=hpux10
 475   ;;
 476   hppa*-hp-hpux1[1-9]* )
 477     machine=hp800 opsys=hpux11
 478     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 479   ;;
 480
 481   hppa*-*-linux-gnu* )
 482     machine=hp800 opsys=gnu-linux
 483   ;;
 484
 485   ## HP 9000 series 700 and 800, running HP/UX
 486   hppa*-hp-hpux* )
 487     ## Cross-compilation?  Nah!
 488     case "`uname -r`" in
 489       ## Someone's system reports A.B8.05 for this.
 490       ## I wonder what other possibilities there are.
 491       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 492       *.08.* ) machine=hp800 opsys=hpux8 ;;
 493       *.09.* ) machine=hp800 opsys=hpux9 ;;
 494       *) machine=hp800 opsys=hpux10 ;;
 495     esac
 496   ;;
 497   hppa*-*-nextstep* )
 498     machine=hp800 opsys=nextstep
 499   ;;
 500
 501   ## IBM machines
 502   i370-ibm-aix*)
 503     machine=ibm370aix opsys=usg5-3
 504   ;;
 505   s390-*-linux-gnu* )
 506     machine=ibms390 opsys=gnu-linux
 507   ;;
 508   s390x-*-linux-gnu* )
 509     machine=ibms390x opsys=gnu-linux
 510   ;;
 511   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 512     machine=ibmrs6000 opsys=aix3-1
 513   ;;
 514   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 515     machine=ibmrs6000 opsys=aix3-2-5
 516   ;;
 517   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 518     machine=ibmrs6000 opsys=aix4-1
 519   ;;
 520   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 521     machine=ibmrs6000 opsys=aix4-2
 522   ;;
 523   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 524     machine=ibmrs6000 opsys=aix4-2
 525   ;;
 526   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 527     machine=ibmrs6000 opsys=aix4-2
 528   ;;
 529   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 530     machine=ibmrs6000 opsys=aix4
 531   ;;
 532   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 533     machine=ibmrs6000 opsys=aix4-1
 534   ;;
 535   rs6000-ibm-aix* | powerpc-ibm-aix* )
 536     machine=ibmrs6000 opsys=aix3-2
 537   ;;
 538
 539   ## Prime EXL
 540   i[3456]86-prime-sysv* )
 541     machine=i386 opsys=usg5-3
 542   ;;
 543
 544   ## ncr machine running svr4.3.
 545   i[3456]86-ncr-sysv4.3 )
 546     machine=ncr386 opsys=usg5-4-3
 547   ;;
 548
 549   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 550   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 551   i[3456]86-ncr-sysv* )
 552     machine=ncr386 opsys=usg5-4-2
 553   ;;
 554
 555   ## Macintosh PowerPC
 556   powerpc*-*-linux-gnu* )
 557     machine=macppc opsys=gnu-linux
 558   ;;
 559
 560   ## Workstations sold by MIPS
 561   ## This is not necessarily all workstations using the MIPS processor -
 562   ## Irises are produced by SGI, and DECstations by DEC.
 563
 564   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 565   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 566   ## it gives for choosing between the alternatives seems to be "Use
 567   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 568   ## the BSD world."  I'll assume that these are instructions for
 569   ## handling two odd situations, and that every other situation
 570   ## should use mips.h and usg5-2-2, they being listed first.
 571   mips-mips-usg* )
 572     machine=mips4
 573     ## Fall through to the general code at the bottom to decide on the OS.
 574   ;;
 575   mips-mips-riscos4* )
 576     machine=mips4 opsys=bsd4-3
 577     NON_GNU_CC="cc -systype bsd43"
 578     NON_GNU_CPP="cc -systype bsd43 -E"
 579   ;;
 580   mips-mips-riscos5* )
 581     machine=mips4 opsys=riscos5
 582     NON_GNU_CC="cc -systype bsd43"
 583     NON_GNU_CPP="cc -systype bsd43 -E"
 584   ;;
 585   mips-mips-bsd* )
 586     machine=mips opsys=bsd4-3
 587   ;;
 588   mips-mips-* )
 589     machine=mips opsys=usg5-2-2
 590   ;;
 591
 592   ## NeXT
 593   m68*-next-* | m68k-*-nextstep* )
 594     machine=m68k opsys=nextstep
 595   ;;
 596
 597   ## NEC EWS4800
 598   mips-nec-sysv4*)
 599   machine=ews4800 opsys=ux4800
 600   ;;
 601
 602   ## Siemens Nixdorf
 603   mips-siemens-sysv* | mips-sni-sysv*)
 604     machine=mips-siemens opsys=usg5-4
 605     NON_GNU_CC=/usr/ccs/bin/cc
 606     NON_GNU_CPP=/usr/ccs/lib/cpp
 607   ;;
 608
 609   ## Silicon Graphics machines
 610   ## Iris 4D
 611   mips-sgi-irix6.5 )
 612     machine=iris4d opsys=irix6-5
 613     # Without defining _LANGUAGE_C, things get masked out in the headers
 614     # so that, for instance, grepping for `free' in stdlib.h fails and
 615     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 616     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 617     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 618   ;;
 619   mips-sgi-irix6* )
 620     machine=iris4d opsys=irix6-0
 621     # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
 622     # but presumably it does no harm.
 623     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 624     # -32 probably isn't necessary in later v.6s -- anyone know which?
 625     NON_GCC_TEST_OPTIONS=-32
 626   ;;
 627   mips-sgi-irix5.[01]* )
 628     machine=iris4d opsys=irix5-0
 629   ;;
 630   mips-sgi-irix5* | mips-sgi-irix* )
 631     machine=iris4d opsys=irix5-2
 632   ;;
 633
 634   ## Suns
 635   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 636     machine=sparc opsys=gnu-linux
 637   ;;
 638
 639   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 640     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 641     | rs6000-*-solaris2*)
 642     case "${canonical}" in
 643       i[3456]86-*-* )     machine=intel386 ;;
 644       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 645       powerpcle* )      machine=powerpcle ;;
 646       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 647       sparc* )          machine=sparc ;;
 648       * )               unported=yes ;;
 649     esac
 650     case "${canonical}" in
 651       *-sunos5.3* | *-solaris2.3* )
 652                 opsys=sol2-3
 653                 NON_GNU_CPP=/usr/ccs/lib/cpp
 654                 ;;
 655       *-sunos5.4* | *-solaris2.4* )
 656                 opsys=sol2-4
 657                 NON_GNU_CPP=/usr/ccs/lib/cpp
 658                 RANLIB="ar -ts"
 659                 ;;
 660       *-sunos5.5* | *-solaris2.5* )
 661                 opsys=sol2-5
 662                 NON_GNU_CPP=/usr/ccs/lib/cpp
 663                 RANLIB="ar -ts"
 664                 ;;
 665       *-sunos5.6* | *-solaris2.6* )
 666                 opsys=sol2-6
 667                 NON_GNU_CPP=/usr/ccs/lib/cpp
 668                 RANLIB="ar -ts"
 669                 ;;
 670       *-sunos5* | *-solaris* )
 671                 opsys=sol2-6
 672                 emacs_check_sunpro_c=yes
 673                 NON_GNU_CPP=/usr/ccs/lib/cpp
 674                 ;;
 675       *                   ) opsys=bsd4-2   ;;
 676     esac
 677     ## Watch out for a compiler that we know will not work.
 678     case "${canonical}" in
 679      *-solaris* | *-sunos5* )
 680                 if [ "x$CC" = x/usr/ucb/cc ]; then
 681                   ## /usr/ucb/cc doesn't work;
 682                   ## we should find some other compiler that does work.
 683                   unset CC
 684                 fi
 685                 ;;
 686       *) ;;
 687     esac
 688   ;;
 689   sparc-*-nextstep* )
 690     machine=sparc opsys=nextstep
 691   ;;
 692
 693   ## Tandem Integrity S2
 694   mips-tandem-sysv* )
 695     machine=tandem-s2 opsys=usg5-3
 696   ;;
 697
 698   ## Vaxen.
 699   vax-dec-* )
 700     machine=vax
 701     case "${canonical}" in
 702       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 703       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 704       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 705       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 706       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 707       *-vms* )                                          opsys=vms ;;
 708       * )                                               unported=yes
 709     esac
 710   ;;
 711
 712   ## IA-64
 713   ia64*-*-linux* )
 714     machine=ia64 opsys=gnu-linux
 715   ;;
 716
 717   ## Intel 386 machines where we don't care about the manufacturer
 718   i[3456]86-*-* )
 719     machine=intel386
 720     case "${canonical}" in
 721       *-cygwin )                opsys=cygwin ;;
 722       *-darwin* )               opsys=darwin
 723                                 CPP="${CC-cc} -E -no-cpp-precomp"
 724                                 ;;
 725       *-xenix* )                opsys=xenix ;;
 726       *-linux-gnu* )            opsys=gnu-linux ;;
 727       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 728       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 729       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 730       *-386bsd* )               opsys=386bsd ;;
 731       *-nextstep* )             opsys=nextstep ;;
 732       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 733     esac
 734   ;;
 735
 736   ## m68k Linux-based GNU system
 737   m68k-*-linux-gnu* )
 738     machine=m68k opsys=gnu-linux
 739   ;;
 740
 741   ## Mips Linux-based GNU system
 742   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 743     machine=mips opsys=gnu-linux
 744   ;;
 745
 746   ## UXP/DS
 747   sparc-fujitsu-sysv4* )
 748     machine=sparc opsys=uxpds
 749     NON_GNU_CPP=/usr/ccs/lib/cpp
 750     RANLIB="ar -ts"
 751   ;;
 752
 753   ## AMD x86-64 Linux-based GNU system
 754   x86_64-*-linux-gnu* )
 755     machine=amdx86-64 opsys=gnu-linux
 756   ;;
 757
 758   ## Tensilica Xtensa Linux-based GNU system
 759   xtensa*-*-linux-gnu* )
 760     machine=xtensa opsys=gnu-linux
 761     ;;
 762
 763   * )
 764     unported=yes
 765   ;;
 766 esac
 767
 768 ### If the code above didn't choose an operating system, just choose
 769 ### an operating system based on the configuration name.  You really
 770 ### only want to use this when you have no idea what the right
 771 ### operating system is; if you know what operating systems a machine
 772 ### runs, it's cleaner to make it explicit in the case statement
 773 ### above.
 774 if test x"${opsys}" = x; then
 775   case "${canonical}" in
 776     *-gnu* )                            opsys=gnu ;;
 777     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 778     *-bsd4.2 )                          opsys=bsd4-2 ;;
 779     *-bsd4.3 )                          opsys=bsd4-3 ;;
 780     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 781     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 782     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 783     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 784     *-sysv4.2uw* )                      opsys=unixware ;;
 785     *-sysv5uw* )                        opsys=unixware ;;
 786     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 787     *-sysv4.1* | *-sysvr4.1* )
 788         NON_GNU_CPP=/usr/lib/cpp
 789         opsys=usg5-4 ;;
 790     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 791         if [ x$NON_GNU_CPP = x ]; then
 792           if [ -f /usr/ccs/lib/cpp ]; then
 793             NON_GNU_CPP=/usr/ccs/lib/cpp
 794           else
 795             NON_GNU_CPP=/lib/cpp
 796           fi
 797         fi
 798         opsys=usg5-4-2 ;;
 799     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 800     * )
 801       unported=yes
 802     ;;
 803   esac
 804 fi
 805
 806 ]
 807 dnl quotation ends
 808
 809 if test $unported = yes; then
 810   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 811 Check `etc/MACHINES' for recognized configuration names.])
 812 fi
 813
 814 machfile="m/${machine}.h"
 815 opsysfile="s/${opsys}.h"
 816
 817
 818 #### Choose a compiler.
 819 test -n "$CC" && cc_specified=yes
 820
 821 # Save the value of CFLAGS that the user specified.
 822 SPECIFIED_CFLAGS="$CFLAGS"
 823
 824 AC_PROG_CC
 825
 826 # On Suns, sometimes $CPP names a directory.
 827 if test -n "$CPP" && test -d "$CPP"; then
 828   CPP=
 829 fi
 830
 831 ## If not using gcc, and on Solaris, and no CPP specified, see if
 832 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 833 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 834  test x"$CPP" = x; then
 835   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 836   AC_CACHE_VAL(emacs_cv_sunpro_c,
 837   [AC_TRY_LINK([],
 838 [#ifndef __SUNPRO_C
 839 fail;
 840 #endif
 841 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 842   AC_MSG_RESULT($emacs_cv_sunpro_c)
 843
 844   if test x"$emacs_cv_sunpro_c" = xyes; then
 845     NON_GNU_CPP="$CC -E -Xs"
 846   fi
 847 fi
 848
 849 #### Some systems specify a CPP to use unless we are using GCC.
 850 #### Now that we know whether we are using GCC, we can decide whether
 851 #### to use that one.
 852 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 853 then
 854   CPP="$NON_GNU_CPP"
 855 fi
 856
 857 #### Some systems specify a CC to use unless we are using GCC.
 858 #### Now that we know whether we are using GCC, we can decide whether
 859 #### to use that one.
 860 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 861   test x$cc_specified != xyes
 862 then
 863   CC="$NON_GNU_CC"
 864 fi
 865
 866 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 867 then
 868   CC="$CC $GCC_TEST_OPTIONS"
 869 fi
 870
 871 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 872 then
 873   CC="$CC $NON_GCC_TEST_OPTIONS"
 874 fi
 875
 876 dnl checks for Unix variants
 877 AC_AIX
 878 AC_GNU_SOURCE
 879
 880 ### Use -Wno-pointer-sign if the compiler supports it
 881 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 882 SAVE_CFLAGS="$CFLAGS"
 883 CFLAGS="$CFLAGS -Wno-pointer-sign"
 884 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 885 if test $has_option = yes; then
 886    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 887 fi
 888 AC_MSG_RESULT($has_option)
 889 CFLAGS="$SAVE_CFLAGS"
 890 unset has_option
 891 unset SAVE_CFLAGS
 892
 893 #### Some other nice autoconf tests.
 894
 895 dnl checks for programs
 896 AC_PROG_LN_S
 897 AC_PROG_CPP
 898 AC_PROG_INSTALL
 899 if test "x$RANLIB" = x; then
 900   AC_PROG_RANLIB
 901 fi
 902 AC_PATH_PROG(INSTALL_INFO, install-info)
 903 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 904 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 905 dnl Don't use GZIP, which is used by gzip for additional parameters.
 906 AC_PATH_PROG(GZIP_PROG, gzip)
 907
 908
 909 ## Need makeinfo >= 4.6 (?) to build the manuals.
 910 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 911 dnl By this stage, configure has already checked for egrep and set EGREP,
 912 dnl or exited with an error if no egrep was found.
 913 if test "$MAKEINFO" != "no" && \
 914   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 915    MAKEINFO=no
 916 fi
 917
 918 if test "$MAKEINFO" = "no"; then
 919   AC_MSG_ERROR( [makeinfo >= 4.6 is required] )
 920 fi
 921
 922
 923 dnl Add our options to ac_link now, after it is set up.
 924
 925 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 926 then
 927   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 928 fi
 929
 930 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 931 then
 932   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 933 fi
 934
 935 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 936 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 937 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 938 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 939 dnl if not built to support GNU ld.
 940
 941 late_LDFLAGS=$LDFLAGS
 942 if test "$GCC" = yes; then
 943   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 944 else
 945   LDFLAGS="$LDFLAGS -znocombreloc"
 946 fi
 947
 948 AC_MSG_CHECKING([for -znocombreloc])
 949 AC_LINK_IFELSE([main(){return 0;}],
 950   [AC_MSG_RESULT(yes)],
 951   LDFLAGS=$late_LDFLAGS
 952   [AC_MSG_RESULT(no)])
 953
 954 #### Extract some information from the operating system and machine files.
 955
 956 AC_CHECKING([the machine- and system-dependent files to find out
 957  - which libraries the lib-src programs will want, and
 958  - whether the GNU malloc routines are usable])
 959
 960 ### First figure out CFLAGS (which we use for running the compiler here)
 961 ### and REAL_CFLAGS (which we use for real compilation).
 962 ### The two are the same except on a few systems, where they are made
 963 ### different to work around various lossages.  For example,
 964 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 965 ### as implying static linking.
 966
 967 ### If the CFLAGS env var is specified, we use that value
 968 ### instead of the default.
 969
 970 ### It's not important that this name contain the PID; you can't run
 971 ### two configures in the same directory and have anything work
 972 ### anyway.
 973 tempcname="conftest.c"
 974
 975 echo '
 976 #include "'${srcdir}'/src/'${opsysfile}'"
 977 #include "'${srcdir}'/src/'${machfile}'"
 978 #ifndef LIBS_MACHINE
 979 #define LIBS_MACHINE
 980 #endif
 981 #ifndef LIBS_SYSTEM
 982 #define LIBS_SYSTEM
 983 #endif
 984 #ifndef C_SWITCH_SYSTEM
 985 #define C_SWITCH_SYSTEM
 986 #endif
 987 #ifndef C_SWITCH_MACHINE
 988 #define C_SWITCH_MACHINE
 989 #endif
 990 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 991 configure___ c_switch_system=C_SWITCH_SYSTEM
 992 configure___ c_switch_machine=C_SWITCH_MACHINE
 993
 994 #ifndef LIB_X11_LIB
 995 #define LIB_X11_LIB -lX11
 996 #endif
 997
 998 #ifndef LIBX11_MACHINE
 999 #define LIBX11_MACHINE
1000 #endif
1001
1002 #ifndef LIBX11_SYSTEM
1003 #define LIBX11_SYSTEM
1004 #endif
1005 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1006
1007 #ifdef UNEXEC
1008 configure___ unexec=UNEXEC
1009 #else
1010 configure___ unexec=unexec.o
1011 #endif
1012
1013 #ifdef SYSTEM_MALLOC
1014 configure___ system_malloc=yes
1015 #else
1016 configure___ system_malloc=no
1017 #endif
1018
1019 #ifdef USE_MMAP_FOR_BUFFERS
1020 configure___ use_mmap_for_buffers=yes
1021 #else
1022 configure___ use_mmap_for_buffers=no
1023 #endif
1024
1025 #ifndef C_DEBUG_SWITCH
1026 #define C_DEBUG_SWITCH -g
1027 #endif
1028
1029 #ifndef C_OPTIMIZE_SWITCH
1030 #ifdef __GNUC__
1031 #define C_OPTIMIZE_SWITCH -O2
1032 #else
1033 #define C_OPTIMIZE_SWITCH -O
1034 #endif
1035 #endif
1036
1037 #ifndef C_WARNINGS_SWITCH
1038 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
1039 #endif
1040
1041 #ifndef LD_SWITCH_MACHINE
1042 #define LD_SWITCH_MACHINE
1043 #endif
1044
1045 #ifndef LD_SWITCH_SYSTEM
1046 #define LD_SWITCH_SYSTEM
1047 #endif
1048
1049 #ifndef LD_SWITCH_X_SITE_AUX
1050 #define LD_SWITCH_X_SITE_AUX
1051 #endif
1052
1053 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1054 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1055
1056 #ifdef THIS_IS_CONFIGURE
1057
1058 /* Get the CFLAGS for tests in configure.  */
1059 #ifdef __GNUC__
1060 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1061 #else
1062 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1063 #endif
1064
1065 #else /* not THIS_IS_CONFIGURE */
1066
1067 /* Get the CFLAGS for real compilation.  */
1068 #ifdef __GNUC__
1069 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
1070 #else
1071 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1072 #endif
1073
1074 #endif /* not THIS_IS_CONFIGURE */
1075 ' > ${tempcname}
1076
1077 # The value of CPP is a quoted variable reference, so we need to do this
1078 # to get its actual value...
1079 CPP=`eval "echo $CPP"`
1080 [eval `${CPP} -Isrc ${tempcname} \
1081        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1082 if test "x$SPECIFIED_CFLAGS" = x; then
1083   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1084          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1085 else
1086   REAL_CFLAGS="$CFLAGS"
1087 fi]
1088 rm ${tempcname}
1089
1090 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1091
1092 ### Make sure subsequent tests use flags consistent with the build flags.
1093
1094 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1095   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1096 else
1097   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1098 fi
1099
1100 dnl For AC_FUNC_GETLOADAVG, at least:
1101 AC_CONFIG_LIBOBJ_DIR(src)
1102
1103 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1104 AC_SYS_LARGEFILE
1105
1106
1107 ### The standard library on x86-64 and s390x GNU/Linux distributions can
1108 ### be located in either /usr/lib64 or /usr/lib.
1109 case "${canonical}" in
1110   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1111     if test -d /usr/lib64; then
1112       AC_DEFINE(HAVE_LIB64_DIR, 1,
1113         [Define to 1 if the directory /usr/lib64 exists.])
1114 fi
1115 esac
1116
1117 dnl This function defintion taken from Gnome 2.0
1118 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1119 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1120 dnl also defines GSTUFF_PKG_ERRORS on error
1121 AC_DEFUN([PKG_CHECK_MODULES], [
1122   succeeded=no
1123
1124   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1125
1126   if test "$PKG_CONFIG" = "no" ; then
1127      ifelse([$4], , [AC_MSG_ERROR([
1128       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1129   else
1130      PKG_CONFIG_MIN_VERSION=0.9.0
1131      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1132         AC_MSG_CHECKING(for $2)
1133
1134         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1135             AC_MSG_RESULT(yes)
1136             succeeded=yes
1137
1138             AC_MSG_CHECKING($1_CFLAGS)
1139             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1140             AC_MSG_RESULT($$1_CFLAGS)
1141
1142             AC_MSG_CHECKING($1_LIBS)
1143             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1144             AC_MSG_RESULT($$1_LIBS)
1145         else
1146             AC_MSG_RESULT(no)
1147             $1_CFLAGS=""
1148             $1_LIBS=""
1149             ## If we have a custom action on failure, don't print errors, but
1150             ## do set a variable so people can do so.
1151             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1152             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1153         fi
1154
1155         AC_SUBST($1_CFLAGS)
1156         AC_SUBST($1_LIBS)
1157      else
1158         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1159         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1160      fi
1161   fi
1162
1163   if test $succeeded = yes; then
1164      ifelse([$3], , :, [$3])
1165   else
1166      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1167   fi
1168 ])
1169
1170
1171 if test "${with_sound}" != "no"; then
1172   # Sound support for GNU/Linux and the free BSDs.
1173   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1174   # Emulation library used on NetBSD.
1175   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1176   AC_SUBST(LIBSOUND)
1177
1178   ALSA_REQUIRED=1.0.0
1179   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1180   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1181   if test $HAVE_ALSA = yes; then
1182     SAVE_CFLAGS="$CFLAGS"
1183     SAVE_LDFLAGS="$LDFLAGS"
1184     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1185     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1186     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1187                     emacs_alsa_normal=yes,
1188                     emacs_alsa_normal=no)
1189     if test "$emacs_alsa_normal" != yes; then
1190       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1191                      [snd_lib_error_set_handler (0);],
1192                      emacs_alsa_subdir=yes,
1193                      emacs_alsa_subdir=no)
1194       if test "$emacs_alsa_subdir" != yes; then
1195         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1196       fi
1197       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1198     fi
1199
1200     CFLAGS="$SAVE_CFLAGS"
1201     LDFLAGS="$SAVE_LDFLAGS"
1202     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1203     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1204     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1205   fi
1206   AC_SUBST(CFLAGS_SOUND)
1207 fi
1208
1209 dnl checks for header files
1210 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1211   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1212   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1213   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1214   sys/utsname.h pwd.h)
1215
1216 AC_MSG_CHECKING(if personality LINUX32 can be set)
1217 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1218                emacs_cv_personality_linux32=yes,
1219                emacs_cv_personality_linux32=no)
1220 AC_MSG_RESULT($emacs_cv_personality_linux32)
1221
1222 if test $emacs_cv_personality_linux32 = yes; then
1223   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1224             [Define to 1 if personality LINUX32 can be set.])
1225 fi
1226
1227 dnl On Solaris 8 there's a compilation warning for term.h because
1228 dnl it doesn't define `bool'.
1229 AC_CHECK_HEADERS(term.h, , , -)
1230 AC_HEADER_STDC
1231 AC_HEADER_TIME
1232 AC_CHECK_DECLS([sys_siglist])
1233 if test $ac_cv_have_decl_sys_siglist != yes; then
1234   # For Tru64, at least:
1235   AC_CHECK_DECLS([__sys_siglist])
1236   if test $ac_cv_have_decl___sys_siglist = yes; then
1237     AC_DEFINE(sys_siglist, __sys_siglist,
1238               [Define to any substitute for sys_siglist.])
1239   fi
1240 fi
1241 AC_HEADER_SYS_WAIT
1242
1243 dnl Some systems have utime.h but don't declare the struct anyplace.
1244 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1245 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1246 #include <sys/time.h>
1247 #include <time.h>
1248 #else
1249 #ifdef HAVE_SYS_TIME_H
1250 #include <sys/time.h>
1251 #else
1252 #include <time.h>
1253 #endif
1254 #endif
1255 #ifdef HAVE_UTIME_H
1256 #include <utime.h>
1257 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1258   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1259 if test $emacs_cv_struct_utimbuf = yes; then
1260   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1261 fi
1262
1263 dnl checks for typedefs
1264 AC_TYPE_SIGNAL
1265
1266 dnl Check for speed_t typedef.
1267 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1268   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1269     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1270 if test $emacs_cv_speed_t = yes; then
1271   AC_DEFINE(HAVE_SPEED_T, 1,
1272            [Define to 1 if `speed_t' is declared by <termios.h>.])
1273 fi
1274
1275 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1276 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1277 #include <sys/time.h>
1278 #include <time.h>
1279 #else
1280 #ifdef HAVE_SYS_TIME_H
1281 #include <sys/time.h>
1282 #else
1283 #include <time.h>
1284 #endif
1285 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1286   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1287 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1288 if test $emacs_cv_struct_timeval = yes; then
1289   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1290 fi
1291
1292 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1293 AC_TRY_COMPILE([#include <math.h>],
1294 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1295   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1296 HAVE_EXCEPTION=$emacs_cv_struct_exception
1297 if test $emacs_cv_struct_exception != yes; then
1298   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1299 fi
1300
1301 AC_CHECK_HEADERS(sys/socket.h)
1302 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1303 #if HAVE_SYS_SOCKET_H
1304 #include <sys/socket.h>
1305 #endif])
1306
1307 dnl checks for structure members
1308 AC_STRUCT_TM
1309 AC_STRUCT_TIMEZONE
1310 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1311                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1312                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1313                 [#include <time.h>])
1314 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1315                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1316                   struct ifreq.ifr_addr], , ,
1317                  [AC_INCLUDES_DEFAULT
1318 #if HAVE_SYS_SOCKET_H
1319 #include <sys/socket.h>
1320 #endif
1321 #if HAVE_NET_IF_H
1322 #include <net/if.h>
1323 #endif])
1324
1325 dnl checks for compiler characteristics
1326
1327 dnl Testing __STDC__ to determine prototype support isn't good enough.
1328 dnl DEC C, for instance, doesn't define it with default options, and
1329 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1330 dnl and void *.
1331 AC_C_PROTOTYPES
1332 AC_C_VOLATILE
1333 AC_C_CONST
1334 dnl This isn't useful because we can't turn on use of `inline' unless
1335 dnl the compiler groks `extern inline'.
1336 dnl AC_C_INLINE
1337 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1338   [AC_TRY_COMPILE(, [void * foo;],
1339                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1340 if test $emacs_cv_void_star = yes; then
1341   AC_DEFINE(POINTER_TYPE, void)
1342 else
1343   AC_DEFINE(POINTER_TYPE, char)
1344 fi
1345 AH_TEMPLATE(POINTER_TYPE,
1346             [Define as `void' if your compiler accepts `void *'; otherwise
1347              define as `char'.])dnl
1348
1349
1350
1351 dnl This could be used for targets which can have both byte sexes.
1352 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1353 dnl AC_C_BIGENDIAN
1354
1355 dnl check for Make feature
1356 AC_PROG_MAKE_SET
1357
1358 dnl checks for operating system services
1359 AC_SYS_LONG_FILE_NAMES
1360
1361 #### Choose a window system.
1362
1363 AC_PATH_X
1364 if test "$no_x" = yes; then
1365   window_system=none
1366 else
1367   window_system=x11
1368 fi
1369
1370 if test "${x_libraries}" != NONE; then
1371   if test -n "${x_libraries}"; then
1372     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1373     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1374   fi
1375   x_default_search_path=""
1376   x_search_path=${x_libraries}
1377   if test -z "${x_search_path}"; then
1378     x_search_path=/usr/lib
1379   fi
1380   for x_library in `echo ${x_search_path}: | \
1381                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1382     x_search_path="\
1383 ${x_library}/X11/%L/%T/%N%C%S:\
1384 ${x_library}/X11/%l/%T/%N%C%S:\
1385 ${x_library}/X11/%T/%N%C%S:\
1386 ${x_library}/X11/%L/%T/%N%S:\
1387 ${x_library}/X11/%l/%T/%N%S:\
1388 ${x_library}/X11/%T/%N%S"
1389     if test x"${x_default_search_path}" = x; then
1390       x_default_search_path=${x_search_path}
1391     else
1392       x_default_search_path="${x_search_path}:${x_default_search_path}"
1393     fi
1394   done
1395 fi
1396 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1397   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1398 fi
1399
1400 if test x"${x_includes}" = x; then
1401   bitmapdir=/usr/include/X11/bitmaps
1402 else
1403   # accumulate include directories that have X11 bitmap subdirectories
1404   bmd_acc="dummyval"
1405   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1406     if test -d "${bmd}/X11/bitmaps"; then
1407       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1408     fi
1409     if test -d "${bmd}/bitmaps"; then
1410       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1411     fi
1412   done
1413   if test ${bmd_acc} != "dummyval"; then
1414     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1415   fi
1416 fi
1417
1418 HAVE_CARBON=no
1419 if test "${with_carbon}" != no; then
1420   AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1421 fi
1422 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1423   if test "${with_carbon+set}" != set \
1424      && test "${carbon_appdir_x+set}" != set; then
1425     for var in with_x with_x_toolkit with_gtk with_xim \
1426                with_xpm with_jpeg with_tiff with_gif with_png; do
1427       if eval test \"\${$var+set}\" = set; then
1428         HAVE_CARBON=no
1429         break
1430       fi
1431     done
1432   fi
1433 fi
1434 if test "${HAVE_CARBON}" = yes; then
1435   window_system=mac
1436 fi
1437
1438 case "${window_system}" in
1439   x11 )
1440     HAVE_X_WINDOWS=yes
1441     HAVE_X11=yes
1442     case "${with_x_toolkit}" in
1443       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1444       motif ) USE_X_TOOLKIT=MOTIF ;;
1445       gtk ) with_gtk=yes
1446 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1447 dnl USE_X_TOOLKIT is set.
1448             USE_X_TOOLKIT=none ;;
1449       no ) USE_X_TOOLKIT=none ;;
1450 dnl If user did not say whether to use a toolkit, make this decision later:
1451 dnl use the toolkit if we have gtk, or X11R5 or newer.
1452       * )
1453           if test x"$with_gtk" = xyes; then
1454              USE_X_TOOLKIT=none
1455           else
1456              USE_X_TOOLKIT=maybe
1457           fi
1458           ;;
1459     esac
1460   ;;
1461   mac | none )
1462     HAVE_X_WINDOWS=no
1463     HAVE_X11=no
1464     USE_X_TOOLKIT=none
1465   ;;
1466 esac
1467
1468 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1469    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1470    if test "$HAVE_XSERVER" = true ||
1471       test -n "$DISPLAY" ||
1472       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1473         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1474 were found.  You should install the relevant development files for X
1475 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1476 sure you have development files for image handling, i.e.
1477 tiff, gif, jpeg, png and xpm.
1478 If you are sure you want Emacs compiled without X window support, pass
1479   --without-x
1480 to configure.])
1481    fi
1482 fi
1483
1484 ### If we're using X11, we should use the X menu package.
1485 HAVE_MENUS=no
1486 case ${HAVE_X11} in
1487   yes ) HAVE_MENUS=yes ;;
1488 esac
1489
1490 ### Compute the unexec source name from the object name.
1491 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1492
1493 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1494 # Assume not, until told otherwise.
1495 GNU_MALLOC=yes
1496 doug_lea_malloc=yes
1497 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1498 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1499 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1500                emacs_cv_var___after_morecore_hook,
1501 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1502   emacs_cv_var___after_morecore_hook=yes,
1503   emacs_cv_var___after_morecore_hook=no)])
1504 if test $emacs_cv_var___after_morecore_hook = no; then
1505   doug_lea_malloc=no
1506 fi
1507 if test "${system_malloc}" = "yes"; then
1508   GNU_MALLOC=no
1509   GNU_MALLOC_reason="
1510     (The GNU allocators don't work with this system configuration.)"
1511 fi
1512 if test "$doug_lea_malloc" = "yes" ; then
1513   if test "$GNU_MALLOC" = yes ; then
1514     GNU_MALLOC_reason="
1515       (Using Doug Lea's new malloc from the GNU C Library.)"
1516   fi
1517   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1518             [Define to 1 if you are using the GNU C Library.])
1519 fi
1520
1521 if test x"${REL_ALLOC}" = x; then
1522   REL_ALLOC=${GNU_MALLOC}
1523 fi
1524
1525 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1526 dnl the system configuration file (s/*.h) to turn the use of mmap
1527 dnl in the relocating allocator on.
1528
1529 AC_FUNC_MMAP
1530 if test $use_mmap_for_buffers = yes; then
1531   REL_ALLOC=no
1532 fi
1533
1534 LIBS="$libsrc_libs $LIBS"
1535
1536 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1537 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1538 AC_CHECK_LIB(dnet, dnet_ntoa)
1539 dnl This causes -lresolv to get used in subsequent tests,
1540 dnl which causes failures on some systems such as HPUX 9.
1541 dnl AC_CHECK_LIB(resolv, gethostbyname)
1542
1543 dnl FIXME replace main with a function we actually want from this library.
1544 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1545
1546 AC_CHECK_LIB(pthreads, cma_open)
1547
1548 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1549 if test -d /usr/X386/include; then
1550   HAVE_XFREE386=yes
1551   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1552 else
1553   HAVE_XFREE386=no
1554 fi
1555 AC_MSG_RESULT($HAVE_XFREE386)
1556
1557 dnl Check for need for bigtoc support on IBM AIX
1558
1559 case ${host_os} in
1560 aix*)
1561   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1562     case $GCC in
1563     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1564     *) gdb_cv_bigtoc=-bbigtoc ;;
1565     esac
1566
1567     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1568     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1569   ])
1570   ;;
1571 esac
1572
1573 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1574 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1575 # REAL_CPPFLAGS later on.
1576
1577 REAL_CPPFLAGS="$CPPFLAGS"
1578
1579 if test "${HAVE_X11}" = "yes"; then
1580   DEFS="$C_SWITCH_X_SITE $DEFS"
1581   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1582   LIBS="$LIBX $LIBS"
1583   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1584   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1585
1586   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1587   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1588   # but it's more convenient here to set LD_RUN_PATH
1589   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1590   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1591     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1592     export LD_RUN_PATH
1593   fi
1594
1595   if test "${opsys}" = "gnu-linux"; then
1596     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1597     AC_TRY_LINK([],
1598      [XOpenDisplay ("foo");],
1599      [xlinux_first_failure=no],
1600      [xlinux_first_failure=yes])
1601     if test "${xlinux_first_failure}" = "yes"; then
1602       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1603       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1604       OLD_CPPFLAGS="$CPPFLAGS"
1605       OLD_LIBS="$LIBS"
1606       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1607       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1608       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1609       LIBS="$LIBS -b i486-linuxaout"
1610       AC_TRY_LINK([],
1611        [XOpenDisplay ("foo");],
1612        [xlinux_second_failure=no],
1613        [xlinux_second_failure=yes])
1614       if test "${xlinux_second_failure}" = "yes"; then
1615         # If we get the same failure with -b, there is no use adding -b.
1616         # So take it out.  This plays safe.
1617         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1618         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1619         CPPFLAGS="$OLD_CPPFLAGS"
1620         LIBS="$OLD_LIBS"
1621         AC_MSG_RESULT(no)
1622       else
1623         AC_MSG_RESULT(yes)
1624       fi
1625     else
1626       AC_MSG_RESULT(no)
1627     fi
1628   fi
1629
1630   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1631   # header files included from there.
1632   AC_MSG_CHECKING(for Xkb)
1633   AC_TRY_LINK([#include <X11/Xlib.h>
1634 #include <X11/XKBlib.h>],
1635         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1636         emacs_xkb=yes, emacs_xkb=no)
1637   AC_MSG_RESULT($emacs_xkb)
1638   if test $emacs_xkb = yes; then
1639     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1640   fi
1641
1642   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1643 XScreenNumberOfScreen XSetWMProtocols)
1644 fi
1645
1646 if test "${window_system}" = "x11"; then
1647   AC_MSG_CHECKING(X11 version 6)
1648   AC_CACHE_VAL(emacs_cv_x11_version_6,
1649   [AC_TRY_LINK([#include <X11/Xlib.h>],
1650 [#if XlibSpecificationRelease < 6
1651 fail;
1652 #endif
1653 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1654   if test $emacs_cv_x11_version_6 = yes; then
1655     AC_MSG_RESULT(6 or newer)
1656     AC_DEFINE(HAVE_X11R6, 1,
1657               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1658   else
1659     AC_MSG_RESULT(before 6)
1660   fi
1661 fi
1662
1663
1664 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1665 HAVE_RSVG=no
1666 if test "${HAVE_X11}" = "yes" || test "${HAVE_CARBON}" = "yes"; then
1667   if test "${with_rsvg}" != "no"; then
1668     RSVG_REQUIRED=2.0.0
1669     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1670
1671     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1672     AC_SUBST(RSVG_CFLAGS)
1673     AC_SUBST(RSVG_LIBS)
1674
1675     if test ".${RSVG_CFLAGS}" != "."; then
1676       HAVE_RSVG=yes
1677       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1678       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1679       LIBS="$RSVG_LIBS $LIBS"
1680     fi
1681   fi
1682 fi
1683
1684
1685 HAVE_GTK=no
1686 if test "${with_gtk}" = "yes" && test "$USE_X_TOOLKIT" = "gtk"; then
1687   USE_X_TOOLKIT=none
1688 fi
1689 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "gtk" || \
1690  test "$USE_X_TOOLKIT" = "maybe"; then
1691   if test "$USE_X_TOOLKIT" != "none" && test "$USE_X_TOOLKIT" != "maybe"; then
1692     AC_MSG_ERROR([Conflicting options, --with-gtk is incompatible with --with-x-toolkit=${with_x_toolkit}]);
1693   fi
1694   GLIB_REQUIRED=2.6
1695   GTK_REQUIRED=2.6
1696   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1697
1698   dnl Checks for libraries.
1699   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1700   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1701      AC_MSG_ERROR($GTK_PKG_ERRORS)
1702   fi
1703 fi
1704
1705
1706 if test x"$pkg_check_gtk" = xyes; then
1707
1708   AC_SUBST(GTK_CFLAGS)
1709   AC_SUBST(GTK_LIBS)
1710   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1711   CFLAGS="$CFLAGS $GTK_CFLAGS"
1712   LIBS="$GTK_LIBS $LIBS"
1713   dnl Try to compile a simple GTK program.
1714   GTK_COMPILES=no
1715   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1716   if test "${GTK_COMPILES}" != "yes"; then
1717     if test "$USE_X_TOOLKIT" != "maybe"; then
1718       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1719     fi
1720   else
1721     HAVE_GTK=yes
1722     AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
1723     USE_X_TOOLKIT=none
1724   fi
1725
1726 fi
1727
1728
1729 if test "${HAVE_GTK}" = "yes"; then
1730
1731   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1732   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1733   if test "$with_toolkit_scroll_bars" != no; then
1734     with_toolkit_scroll_bars=yes
1735   fi
1736
1737   dnl  Check if we can use multiple displays with this GTK version.
1738   dnl  If gdk_display_open exists, assume all others are there also.
1739   HAVE_GTK_MULTIDISPLAY=no
1740   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1741   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1742     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1743               [Define to 1 if GTK can handle more than one display.])
1744   fi
1745
1746   dnl  Check if we have the old file selection dialog.
1747   dnl  If gdk_display_open exists, assume all others are there also.
1748   HAVE_GTK_FILE_SELECTION=no
1749   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1750
1751   dnl  Check if we have the new file chooser dialog
1752   dnl  If gdk_display_open exists, assume all others are there also.
1753   HAVE_GTK_FILE_CHOOSER=no
1754   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1755
1756   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1757      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1758     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1759               [Define to 1 if GTK has both file selection and chooser dialog.])
1760   fi
1761
1762   dnl Check if pthreads are available.  Emacs only needs this when using
1763   dnl gtk_file_chooser under Gnome.
1764   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1765     HAVE_GTK_AND_PTHREAD=no
1766     AC_CHECK_HEADERS(pthread.h)
1767     if test "$ac_cv_header_pthread_h"; then
1768       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1769     fi
1770     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1771       case "${canonical}" in
1772         *-hpux*) ;;
1773         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1774       esac
1775       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1776                [Define to 1 if you have GTK and pthread (-lpthread).])
1777     fi
1778   fi
1779 fi
1780
1781 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1782 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1783 dnl also not configured.
1784 HAVE_DBUS=no
1785 if test "${with_dbus}" = "yes"; then
1786    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1787    if test "$HAVE_DBUS" = yes; then
1788       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1789    fi
1790 fi
1791
1792 dnl Do not put whitespace before the #include statements below.
1793 dnl Older compilers (eg sunos4 cc) choke on it.
1794 HAVE_XAW3D=no
1795 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1796   if test "$with_xaw3d" != no; then
1797     AC_MSG_CHECKING(for xaw3d)
1798     AC_CACHE_VAL(emacs_cv_xaw3d,
1799     [AC_TRY_LINK([
1800 #include <X11/Intrinsic.h>
1801 #include <X11/Xaw3d/Simple.h>],
1802       [],
1803       emacs_cv_xaw3d=yes,
1804       emacs_cv_xaw3d=no)])
1805   else
1806     emacs_cv_xaw3d=no
1807   fi
1808   if test $emacs_cv_xaw3d = yes; then
1809     AC_MSG_RESULT([yes; using Lucid toolkit])
1810     USE_X_TOOLKIT=LUCID
1811     HAVE_XAW3D=yes
1812     AC_DEFINE(HAVE_XAW3D, 1,
1813               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1814   else
1815     AC_MSG_RESULT(no)
1816     AC_MSG_CHECKING(for libXaw)
1817     AC_CACHE_VAL(emacs_cv_xaw,
1818     [AC_TRY_LINK([
1819 #include <X11/Intrinsic.h>
1820 #include <X11/Xaw/Simple.h>],
1821       [],
1822       emacs_cv_xaw=yes,
1823       emacs_cv_xaw=no)])
1824     if test $emacs_cv_xaw = yes; then
1825       AC_MSG_RESULT([yes; using Lucid toolkit])
1826       USE_X_TOOLKIT=LUCID
1827     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1828       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1829     else
1830       AC_MSG_RESULT([no; do not use toolkit by default])
1831       USE_X_TOOLKIT=none
1832     fi
1833   fi
1834 fi
1835
1836 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1837
1838 if test "${USE_X_TOOLKIT}" != "none"; then
1839   AC_MSG_CHECKING(X11 toolkit version)
1840   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1841   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1842 [#if XtSpecificationRelease < 6
1843 fail;
1844 #endif
1845 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1846   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1847   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1848     AC_MSG_RESULT(6 or newer)
1849     AC_DEFINE(HAVE_X11XTR6, 1,
1850               [Define to 1 if you have the X11R6 or newer version of Xt.])
1851   else
1852     AC_MSG_RESULT(before 6)
1853   fi
1854
1855 dnl If using toolkit, check whether libXmu.a exists.
1856 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1857   OLDLIBS="$LIBS"
1858   if test x$HAVE_X11XTR6 = xyes; then
1859     LIBS="-lXt -lSM -lICE $LIBS"
1860   else
1861     LIBS="-lXt $LIBS"
1862   fi
1863   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1864   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1865 fi
1866
1867 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1868 if test "${HAVE_X11}" = "yes"; then
1869   if test "${USE_X_TOOLKIT}" != "none"; then
1870     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1871   fi
1872 fi
1873
1874 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1875   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1876   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1877     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1878 int x = 5;
1879 #else
1880 Motif version prior to 2.1.
1881 #endif],
1882     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1883   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1884   if test $emacs_cv_motif_version_2_1 = yes; then
1885     HAVE_LIBXP=no
1886     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1887               [Define to 1 if you have Motif 2.1 or newer.])
1888     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1889     if test ${HAVE_LIBXP} = yes; then
1890       AC_DEFINE(HAVE_LIBXP, 1,
1891                 [Define to 1 if you have the Xp library (-lXp).])
1892     fi
1893   else
1894     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1895     # We put this in CFLAGS temporarily to precede other -I options
1896     # that might be in CFLAGS temporarily.
1897     # We put this in CPPFLAGS where it precedes the other -I options.
1898     OLD_CPPFLAGS=$CPPFLAGS
1899     OLD_CFLAGS=$CFLAGS
1900     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1901     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1902     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1903       [int x = 5;],
1904       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1905     if test $emacs_cv_lesstif = yes; then
1906       # Make sure this -I option remains in CPPFLAGS after it is set
1907       # back to REAL_CPPFLAGS.
1908       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1909       # have those other -I options anyway.  Ultimately, having this
1910       # directory ultimately in CPPFLAGS will be enough.
1911       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1912       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1913     else
1914       CFLAGS=$OLD_CFLAGS
1915       CPPFLAGS=$OLD_CPPFLAGS
1916     fi
1917   fi
1918 fi
1919
1920 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1921 dnl using Motif or Xaw3d is available, and unless
1922 dnl --with-toolkit-scroll-bars=no was specified.
1923
1924 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1925             [Define to 1 if we should use toolkit scroll bars.])dnl
1926 USE_TOOLKIT_SCROLL_BARS=no
1927 if test "${with_toolkit_scroll_bars}" != "no"; then
1928   if test "${USE_X_TOOLKIT}" != "none"; then
1929     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1930       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1931       HAVE_XAW3D=no
1932       USE_TOOLKIT_SCROLL_BARS=yes
1933     elif test "${HAVE_XAW3D}" = "yes"; then
1934       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1935       USE_TOOLKIT_SCROLL_BARS=yes
1936     fi
1937   elif test "${HAVE_GTK}" = "yes"; then
1938     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1939     USE_TOOLKIT_SCROLL_BARS=yes
1940   elif test "${HAVE_CARBON}" = "yes"; then
1941     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1942     USE_TOOLKIT_SCROLL_BARS=yes
1943   fi
1944 fi
1945
1946 dnl See if XIM is available.
1947 AC_TRY_COMPILE([
1948           #include <X11/Xlib.h>
1949           #include <X11/Xresource.h>],
1950          [XIMProc  callback;],
1951          [HAVE_XIM=yes
1952          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1953          HAVE_XIM=no)
1954
1955 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1956
1957 if test "${with_xim}" != "no"; then
1958   AC_DEFINE(USE_XIM, 1,
1959             [Define to 1 if we should use XIM, if it is available.])
1960 fi
1961
1962
1963 if test "${HAVE_XIM}" != "no"; then
1964   late_CFLAGS=$CFLAGS
1965   if test "$GCC" = yes; then
1966     CFLAGS="$CFLAGS --pedantic-errors"
1967   fi
1968   AC_TRY_COMPILE([
1969 #include <X11/Xlib.h>
1970 #include <X11/Xresource.h>],
1971 [Display *display;
1972 XrmDatabase db;
1973 char *res_name;
1974 char *res_class;
1975 XIMProc  callback;
1976 XPointer *client_data;
1977 #ifndef __GNUC__
1978 /* If we're not using GCC, it's probably not XFree86, and this is
1979    probably right, but we can't use something like --pedantic-errors.  */
1980 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1981                                            char*, XIMProc, XPointer*);
1982 #endif
1983 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1984    client_data);],
1985     [emacs_cv_arg6_star=yes])
1986   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1987          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1988 either XPointer or XPointer*.])dnl
1989   if test "$emacs_cv_arg6_star" = yes; then
1990     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1991   else
1992     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1993   fi
1994   CFLAGS=$late_CFLAGS
1995 fi
1996
1997 #### For font-backend
1998 if test "${USE_FONT_BACKEND}" = "yes"; then
1999
2000 AC_DEFINE(USE_FONT_BACKEND, 1,
2001           [Define to 1 if we should use font-backend.])
2002
2003 ### Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
2004 HAVE_XFT=maybe
2005 if test "${HAVE_X11}" = "yes"; then
2006   if test "x${with_freetype}" = "xno"; then
2007     with_xft="no";
2008   fi
2009   if test "x${with_xft}" != "xno"; then
2010
2011     dnl Check if --with-pkg-config-prog has been given.
2012     if test "X${with_pkg_config_prog}" != X; then
2013       PKG_CONFIG="${with_pkg_config_prog}"
2014     fi
2015
2016     PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2017     if test "$HAVE_XFT" != no; then
2018       OLD_CPPFLAGS="$CPPFLAGS"
2019       OLD_CFLAGS="$CFLAGS"
2020       OLD_LIBS="$LIBS"
2021       CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2022       CFLAGS="$CFLAGS $XFT_CFLAGS"
2023       LIBS="$XFT_LIBS $LIBS"
2024       AC_CHECK_HEADER(X11/Xft/Xft.h,
2025         AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2026
2027       if test "${HAVE_XFT}" = "yes"; then
2028         AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2029         AC_SUBST(XFT_LIBS)
2030         C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2031       else
2032         CPPFLAGS="$OLD_CPPFLAGS"
2033         CFLAGS="$OLD_CFLAGS"
2034         LIBS="$OLD_LIBS"
2035       fi
2036     fi
2037   fi
2038 fi
2039 dnl For the "Does Emacs use" message at the end.
2040 if test "$HAVE_XFT" != "yes"; then
2041    HAVE_XFT=no
2042 fi
2043
2044
2045 HAVE_FREETYPE=no
2046 ### Use -lfreetype if available, unless `--with-freetype=no'.
2047 if test "${HAVE_XFT}" = "yes"; then
2048   dnl As we use Xft, we anyway use freetype.
2049   dnl In this case, there's no need of additional CFLAGS and LIBS.
2050   HAVE_FREETYPE=yes
2051 elif test "x${with_freetype}" != "xno"; then
2052   dnl Check if --with-pkg-config-prog has been given.
2053   if test "X${with_pkg_config_prog}" != X; then
2054     PKG_CONFIG="${with_pkg_config_prog}"
2055   fi
2056
2057   PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
2058   if test "${HAVE_FREETYPE}" = "yes"; then
2059     PKG_CHECK_MODULES(FONTCONFIG, fontconfig, HAVE_FC=yes, HAVE_FC=no)
2060     if test "${HAVE_FC}" = "no"; then
2061       dnl Witout fontconfig, we can't use freetype at the moment.
2062       HAVE_FREETYPE=no
2063     fi
2064   fi
2065 fi
2066
2067 HAVE_LIBOTF=no
2068 if test "${HAVE_FREETYPE}" = "yes"; then
2069   AC_DEFINE(HAVE_FREETYPE, 1,
2070             [Define to 1 if you have freetype and fontconfig libraries.])
2071   if test "${with_libotf}" != "no"; then
2072     dnl Check if --with-pkg-config-prog has been given.
2073     if test "X${with_pkg_config_prog}" != X; then
2074       PKG_CONFIG="${with_pkg_config_prog}"
2075     fi
2076     PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2077                       HAVE_LIBOTF=no)
2078     if test "$HAVE_LIBOTF" = "yes"; then
2079       AC_DEFINE(HAVE_LIBOTF, 1,
2080                 [Define to 1 if you have libotf library.])
2081     fi
2082   fi
2083 fi
2084
2085 HAVE_M17N_FLT=no
2086 if test "${with_m17n_flt}" != "no"; then
2087   dnl Check if --with-pkg-config-prog has been given.
2088   if test "X${with_pkg_config_prog}" != X; then
2089     PKG_CONFIG="${with_pkg_config_prog}"
2090   fi
2091   dnl Checks for libraries.
2092   PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes,
2093                     HAVE_M17N_FLT=no)
2094   if test "$HAVE_M17N_FLT" = "yes"; then
2095     AC_DEFINE(HAVE_M17N_FLT, 1,
2096               [Define to 1 if you have m17n-flt library.])
2097   fi
2098 fi
2099
2100 AC_SUBST(FREETYPE_CFLAGS)
2101 AC_SUBST(FREETYPE_LIBS)
2102 AC_SUBST(FONTCONFIG_CFLAGS)
2103 AC_SUBST(FONTCONFIG_LIBS)
2104 AC_SUBST(LIBOTF_CFLAGS)
2105 AC_SUBST(LIBOTF_LIBS)
2106 AC_SUBST(M17N_FLT_CFLAGS)
2107 AC_SUBST(M17N_FLT_LIBS)
2108
2109 fi
2110 #### End for font-backend
2111
2112 ### Use -lXpm if available, unless `--with-xpm=no'.
2113 HAVE_XPM=no
2114 if test "${HAVE_X11}" = "yes"; then
2115   if test "${with_xpm}" != "no"; then
2116     AC_CHECK_HEADER(X11/xpm.h,
2117       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2118     if test "${HAVE_XPM}" = "yes"; then
2119       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2120       AC_EGREP_CPP(no_return_alloc_pixels,
2121       [#include "X11/xpm.h"
2122 #ifndef XpmReturnAllocPixels
2123 no_return_alloc_pixels
2124 #endif
2125       ], HAVE_XPM=no, HAVE_XPM=yes)
2126
2127       if test "${HAVE_XPM}" = "yes"; then
2128         AC_MSG_RESULT(yes)
2129       else
2130         AC_MSG_RESULT(no)
2131       fi
2132     fi
2133   fi
2134
2135   if test "${HAVE_XPM}" = "yes"; then
2136     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2137   fi
2138 fi
2139
2140 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2141 HAVE_JPEG=no
2142 if test "${HAVE_X11}" = "yes"; then
2143   if test "${with_jpeg}" != "no"; then
2144     dnl Checking for jpeglib.h can lose because of a redefinition of
2145     dnl  HAVE_STDLIB_H.
2146     AC_CHECK_HEADER(jerror.h,
2147       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2148   fi
2149
2150   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2151   if test "${HAVE_JPEG}" = "yes"; then
2152     AC_DEFINE(HAVE_JPEG)
2153     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2154         [#include <jpeglib.h>
2155          version=JPEG_LIB_VERSION
2156 ],
2157         [AC_DEFINE(HAVE_JPEG)],
2158         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2159         HAVE_JPEG=no])
2160   fi
2161 fi
2162
2163 ### Use -lpng if available, unless `--with-png=no'.
2164 HAVE_PNG=no
2165 if test "${HAVE_X11}" = "yes"; then
2166   if test "${with_png}" != "no"; then
2167     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2168     # in /usr/include/libpng.
2169     AC_CHECK_HEADERS(png.h libpng/png.h)
2170     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2171       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2172     fi
2173   fi
2174
2175   if test "${HAVE_PNG}" = "yes"; then
2176     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2177   fi
2178 fi
2179
2180 ### Use -ltiff if available, unless `--with-tiff=no'.
2181 HAVE_TIFF=no
2182 if test "${HAVE_X11}" = "yes"; then
2183   if test "${with_tiff}" != "no"; then
2184     AC_CHECK_HEADER(tiffio.h,
2185       [tifflibs="-lz -lm"
2186       # At least one tiff package requires the jpeg library.
2187       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2188       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2189   fi
2190
2191   if test "${HAVE_TIFF}" = "yes"; then
2192     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2193   fi
2194 fi
2195
2196 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2197 HAVE_GIF=no
2198 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2199   AC_CHECK_HEADER(gif_lib.h,
2200 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2201 # Earlier versions can crash Emacs.
2202     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2203
2204   if test "$HAVE_GIF" = yes; then
2205       ac_gif_lib_name="-lgif"
2206   fi
2207
2208 # If gif_lib.h but no libgif, try libungif.
2209   if test x"$try_libungif" = xyes; then
2210     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2211
2212     if test "$HAVE_GIF" = yes; then
2213       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2214       ac_gif_lib_name="-lungif"
2215     fi
2216   fi
2217
2218   if test "${HAVE_GIF}" = "yes"; then
2219     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2220   fi
2221 fi
2222
2223 dnl Check for required libraries.
2224 if test "${HAVE_X11}" = "yes"; then
2225   MISSING=""
2226   WITH_NO=""
2227   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2228     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2229   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2230     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2231   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2232     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2233   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2234     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2235   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2236     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2237
2238   if test "X${MISSING}" != X; then
2239     AC_MSG_ERROR([The following required libraries were not found:
2240     $MISSING
2241 Maybe some development libraries/packages are missing?
2242 If you don't want to link with them give
2243     $WITH_NO
2244 as options to configure])
2245   fi
2246 fi
2247
2248 ### Use -lgpm if available, unless `--with-gpm=no'.
2249 HAVE_GPM=no
2250 if test "${with_gpm}" != "no"; then
2251   AC_CHECK_HEADER(gpm.h,
2252     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2253 fi
2254
2255 if test "${HAVE_GPM}" = "yes"; then
2256   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2257 fi
2258
2259 dnl Check for malloc/malloc.h on darwin
2260 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2261
2262 ### Use Mac OS X Carbon API to implement GUI.
2263 if test "${HAVE_CARBON}" = "yes"; then
2264   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2265   ## Specify the install directory
2266   carbon_appdir=
2267   if test "${carbon_appdir_x}" != ""; then
2268     case ${carbon_appdir_x} in
2269       y | ye | yes)  carbon_appdir=/Applications ;;
2270       * ) carbon_appdir=${carbon_appdir_x} ;;
2271     esac
2272   fi
2273   # We also have mouse menus.
2274   HAVE_MENUS=yes
2275 fi
2276
2277 ### Use session management (-lSM -lICE) if available
2278 HAVE_X_SM=no
2279 if test "${HAVE_X11}" = "yes"; then
2280   AC_CHECK_HEADER(X11/SM/SMlib.h,
2281     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2282
2283   if test "${HAVE_X_SM}" = "yes"; then
2284     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2285     case "$LIBS" in
2286       *-lSM*) ;;
2287       *)      LIBS="-lSM -lICE $LIBS" ;;
2288     esac
2289   fi
2290 fi
2291
2292 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2293 AC_CACHE_CHECK(whether netdb declares h_errno,
2294                emacs_cv_netdb_declares_h_errno,
2295 [AC_TRY_LINK([#include <netdb.h>],
2296   [return h_errno;],
2297   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2298 if test $emacs_cv_netdb_declares_h_errno = yes; then
2299   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2300 fi
2301
2302 AC_FUNC_ALLOCA
2303
2304 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2305 dnl FIXME is there an autoconf test that does the right thing, without
2306 dnl needing to call A_M_E afterwards?
2307 if test x"$ac_cv_func_alloca_works" != xyes; then
2308    AC_MSG_ERROR( [a system implementation of alloca is required] )
2309 fi
2310
2311 # fmod, logb, and frexp are found in -lm on most systems.
2312 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2313 AC_CHECK_LIB(m, sqrt)
2314
2315 # Check for mail-locking functions in a "mail" library.  Probably this should
2316 # have the same check as for liblockfile below.
2317 AC_CHECK_LIB(mail, maillock)
2318 dnl Debian, at least:
2319 AC_CHECK_LIB(lockfile, maillock)
2320 # If we have the shared liblockfile, assume we must use it for mail
2321 # locking (e.g. Debian).  If we couldn't link against liblockfile
2322 # (no liblockfile.a installed), ensure that we don't need to.
2323 if test "$ac_cv_lib_lockfile_maillock" = no; then
2324   dnl This works for files generally, not just executables.
2325   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2326   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2327                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2328   if test $ac_cv_prog_liblockfile = yes; then
2329     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2330 This probably means that movemail could lose mail.
2331 There may be a `development' package to install containing liblockfile.])
2332   else :
2333   fi
2334 fi
2335 AC_CHECK_FUNCS(touchlock)
2336 AC_CHECK_HEADERS(maillock.h)
2337
2338 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2339 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2340 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2341 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2342 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2343 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2344 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2345 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2346 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2347
2348 AC_CHECK_HEADERS(sys/un.h)
2349
2350 AC_FUNC_MKTIME
2351 if test "$ac_cv_func_working_mktime" = no; then
2352   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2353 fi
2354
2355 AC_FUNC_GETLOADAVG
2356
2357 AC_FUNC_FSEEKO
2358
2359 # Configure getopt.
2360 m4_include([m4/getopt.m4])
2361 gl_GETOPT_IFELSE([
2362   gl_GETOPT_SUBSTITUTE_HEADER
2363   gl_PREREQ_GETOPT
2364   GETOPTOBJS='getopt.o getopt1.o'
2365 ])
2366 AC_SUBST(GETOPTOBJS)
2367
2368 AC_FUNC_GETPGRP
2369
2370 AC_FUNC_STRFTIME
2371
2372 # UNIX98 PTYs.
2373 AC_CHECK_FUNCS(grantpt)
2374
2375 # PTY-related GNU extensions.
2376 AC_CHECK_FUNCS(getpt)
2377
2378 # Check this now, so that we will NOT find the above functions in ncurses.
2379 # That is because we have not set up to link ncurses in lib-src.
2380 # It's better to believe a function is not available
2381 # than to expect to find it in ncurses.
2382 AC_CHECK_LIB(ncurses, tparm)
2383
2384 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2385
2386 resolv=no
2387 AC_TRY_LINK([#include <netinet/in.h>
2388 #include <arpa/nameser.h>
2389 #include <resolv.h>],
2390     [return res_init();],
2391     have_res_init=yes, have_res_init=no)
2392 if test "$have_res_init" = no; then
2393   OLIBS="$LIBS"
2394   LIBS="$LIBS -lresolv"
2395   AC_MSG_CHECKING(for res_init with -lresolv)
2396   AC_TRY_LINK([#include <netinet/in.h>
2397 #include <arpa/nameser.h>
2398 #include <resolv.h>],
2399     [return res_init();],
2400     have_res_init=yes, have_res_init=no)
2401   AC_MSG_RESULT($have_res_init)
2402   if test "$have_res_init" = yes ; then
2403     resolv=yes
2404   fi
2405   LIBS="$OLIBS"
2406 fi
2407
2408 if test "$have_res_init" = yes; then
2409   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2410 fi
2411
2412 # Do we need the Hesiod library to provide the support routines?
2413 if test "$with_hesiod" = yes ; then
2414   # Don't set $LIBS here -- see comments above.
2415   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2416      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2417                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2418   if test "$resolv" = yes ; then
2419     RESOLVLIB=-lresolv
2420   else
2421     RESOLVLIB=
2422   fi
2423   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2424         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2425                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2426         :, $RESOLVLIB)])
2427 fi
2428
2429 # Do we need libresolv (due to res_init or Hesiod)?
2430 if test "$resolv" = yes ; then
2431   AC_DEFINE(HAVE_LIBRESOLV, 1,
2432             [Define to 1 if you have the resolv library (-lresolv).])
2433 fi
2434
2435 # These tell us which Kerberos-related libraries to use.
2436 if test "${with_kerberos+set}" = set; then
2437   AC_CHECK_LIB(com_err, com_err)
2438   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2439   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2440   AC_CHECK_LIB(krb5, krb5_init_context)
2441   if test "${with_kerberos5+set}" != set; then
2442     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2443                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2444     AC_CHECK_LIB(krb4, krb_get_cred,,
2445                  [AC_CHECK_LIB(krb, krb_get_cred)])
2446   fi
2447
2448   if test "${with_kerberos5+set}" = set; then
2449     AC_CHECK_HEADERS(krb5.h)
2450   else
2451     AC_CHECK_HEADERS(des.h,,
2452                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2453                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2454     AC_CHECK_HEADERS(krb.h,,
2455                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2456                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2457   fi
2458   AC_CHECK_HEADERS(com_err.h)
2459 fi
2460
2461 # Solaris requires -lintl if you want strerror (which calls dgettext)
2462 # to return localized messages.
2463 AC_CHECK_LIB(intl, dgettext)
2464
2465 AC_MSG_CHECKING(whether localtime caches TZ)
2466 AC_CACHE_VAL(emacs_cv_localtime_cache,
2467 [if test x$ac_cv_func_tzset = xyes; then
2468 AC_TRY_RUN([#include <time.h>
2469 extern char **environ;
2470 unset_TZ ()
2471 {
2472   char **from, **to;
2473   for (to = from = environ; (*to = *from); from++)
2474     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2475       to++;
2476 }
2477 char TZ_GMT0[] = "TZ=GMT0";
2478 char TZ_PST8[] = "TZ=PST8";
2479 main()
2480 {
2481   time_t now = time ((time_t *) 0);
2482   int hour_GMT0, hour_unset;
2483   if (putenv (TZ_GMT0) != 0)
2484     exit (1);
2485   hour_GMT0 = localtime (&now)->tm_hour;
2486   unset_TZ ();
2487   hour_unset = localtime (&now)->tm_hour;
2488   if (putenv (TZ_PST8) != 0)
2489     exit (1);
2490   if (localtime (&now)->tm_hour == hour_GMT0)
2491     exit (1);
2492   unset_TZ ();
2493   if (localtime (&now)->tm_hour != hour_unset)
2494     exit (1);
2495   exit (0);
2496 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2497 [# If we have tzset, assume the worst when cross-compiling.
2498 emacs_cv_localtime_cache=yes])
2499 else
2500         # If we lack tzset, report that localtime does not cache TZ,
2501         # since we can't invalidate the cache if we don't have tzset.
2502         emacs_cv_localtime_cache=no
2503 fi])dnl
2504 AC_MSG_RESULT($emacs_cv_localtime_cache)
2505 if test $emacs_cv_localtime_cache = yes; then
2506   AC_DEFINE(LOCALTIME_CACHE, 1,
2507             [Define to 1 if localtime caches TZ.])
2508 fi
2509
2510 if test "x$HAVE_TIMEVAL" = xyes; then
2511   AC_CHECK_FUNCS(gettimeofday)
2512   if test $ac_cv_func_gettimeofday = yes; then
2513     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2514                    emacs_cv_gettimeofday_two_arguments,
2515     [AC_TRY_COMPILE([
2516 #ifdef TIME_WITH_SYS_TIME
2517 #include <sys/time.h>
2518 #include <time.h>
2519 #else
2520 #ifdef HAVE_SYS_TIME_H
2521 #include <sys/time.h>
2522 #else
2523 #include <time.h>
2524 #endif
2525 #endif],
2526       [struct timeval time;
2527        gettimeofday (&time, 0);],
2528       emacs_cv_gettimeofday_two_arguments=yes,
2529       emacs_cv_gettimeofday_two_arguments=no)])
2530     if test $emacs_cv_gettimeofday_two_arguments = no; then
2531       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2532                 [Define to 1 if gettimeofday accepts only one argument.])
2533     fi
2534   fi
2535 fi
2536
2537 ok_so_far=yes
2538 AC_CHECK_FUNC(socket, , ok_so_far=no)
2539 if test $ok_so_far = yes; then
2540   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2541 fi
2542 if test $ok_so_far = yes; then
2543   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2544 fi
2545 if test $ok_so_far = yes; then
2546 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2547   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2548             [Define to 1 if you have inet sockets.])
2549 fi
2550
2551 AC_CHECK_HEADERS(sys/ioctl.h)
2552
2553 if test -f /usr/lpp/X11/bin/smt.exp; then
2554   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2555             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2556 fi
2557
2558 AC_MSG_CHECKING(whether system supports dynamic ptys)
2559 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2560   AC_MSG_RESULT(yes)
2561   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2562 else
2563   AC_MSG_RESULT(no)
2564 fi
2565
2566 AC_FUNC_FORK
2567
2568 dnl Adapted from Haible's version.
2569 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2570   [AC_TRY_LINK([#include <langinfo.h>],
2571     [char* cs = nl_langinfo(CODESET);],
2572     emacs_cv_langinfo_codeset=yes,
2573     emacs_cv_langinfo_codeset=no)
2574   ])
2575 if test $emacs_cv_langinfo_codeset = yes; then
2576   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2577     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2578 fi
2579
2580 AC_CHECK_TYPES(size_t)
2581
2582 AC_TYPE_MBSTATE_T
2583
2584 dnl Restrict could probably be used effectively other than in regex.c.
2585 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2586   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2587                   emacs_cv_c_restrict=yes,
2588                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2589                                   emacs_cv_c_restrict=__restrict,
2590                                   emacs_cv_c_restrict=no)])])
2591 case "$emacs_cv_c_restrict" in
2592   yes) emacs_restrict=restrict;;
2593   no) emacs_restrict="";;
2594   *) emacs_restrict="$emacs_cv_c_restrict";;
2595 esac
2596 if test "$emacs_restrict" != __restrict; then
2597   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2598     [Define to compiler's equivalent of C99 restrict keyword.
2599      Don't define if equivalent is `__restrict'.])
2600 fi
2601
2602 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2603   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2604                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2605 if test "$emacs_cv_c_restrict_arr" = yes; then
2606   AC_DEFINE(__restrict_arr, __restrict,
2607     [Define to compiler's equivalent of C99 restrict keyword in array
2608      declarations.  Define as empty for no equivalent.])
2609 fi
2610
2611 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2612 dnl how the tty code is related to POSIX and/or other versions of termios.
2613 dnl The following looks like a useful start.
2614 dnl
2615 dnl AC_SYS_POSIX_TERMIOS
2616 dnl if test $ac_cv_sys_posix_termios = yes; then
2617 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2618 dnl                                and macros for terminal control.])
2619 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2620 dnl fi
2621
2622 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2623
2624 # Set up the CFLAGS for real compilation, so we can substitute it.
2625 CFLAGS="$REAL_CFLAGS"
2626 CPPFLAGS="$REAL_CPPFLAGS"
2627
2628 #### Find out which version of Emacs this is.
2629 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2630          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2631 if test x"${version}" = x; then
2632   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2633 fi
2634
2635 ### Specify what sort of things we'll be editing into Makefile and config.h.
2636 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2637 AC_SUBST(version)
2638 AC_SUBST(configuration)
2639 AC_SUBST(canonical)
2640 AC_SUBST(srcdir)
2641 AC_SUBST(prefix)
2642 AC_SUBST(exec_prefix)
2643 AC_SUBST(bindir)
2644 AC_SUBST(datadir)
2645 AC_SUBST(sharedstatedir)
2646 AC_SUBST(libexecdir)
2647 AC_SUBST(mandir)
2648 AC_SUBST(infodir)
2649 AC_SUBST(lispdir)
2650 AC_SUBST(locallisppath)
2651 AC_SUBST(lisppath)
2652 AC_SUBST(x_default_search_path)
2653 AC_SUBST(etcdir)
2654 AC_SUBST(archlibdir)
2655 AC_SUBST(docdir)
2656 AC_SUBST(bitmapdir)
2657 AC_SUBST(gamedir)
2658 AC_SUBST(gameuser)
2659 AC_SUBST(c_switch_system)
2660 AC_SUBST(c_switch_machine)
2661 AC_SUBST(LD_SWITCH_X_SITE)
2662 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2663 AC_SUBST(C_SWITCH_X_SITE)
2664 AC_SUBST(CFLAGS)
2665 AC_SUBST(X_TOOLKIT_TYPE)
2666 AC_SUBST(machfile)
2667 AC_SUBST(opsysfile)
2668 AC_SUBST(GETLOADAVG_LIBS)
2669 AC_SUBST(carbon_appdir)
2670
2671 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2672                    [Define to the canonical Emacs configuration name.])
2673 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2674                    [Define to the options passed to configure.])
2675 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2676                    [Define to the used machine dependent file.])
2677 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2678                    [Define to the used os dependent file.])
2679 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2680 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2681  may need to deal with X Windows.  For instance, if you've defined
2682  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2683  your loader can find on its own, you might want to add "-L/..." or
2684  something similar.])
2685 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2686                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2687                     in case it's needed (for Solaris, for example).])
2688 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2689 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2690  may need to deal with X Windows.  For instance, if you've defined
2691  HAVE_X_WINDOWS above and your X include files aren't in a place
2692  that your compiler can find on its own, you might want to add
2693  "-I/..." or something similar.])
2694 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2695                    [Define to the unexec source file name.])
2696
2697 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2698   AC_DEFINE(HAVE_X_WINDOWS, 1,
2699             [Define to 1 if you want to use the X window system.])
2700 fi
2701 if test "${USE_X_TOOLKIT}" != "none" ; then
2702   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2703 fi
2704 if test "${HAVE_X11}" = "yes" ; then
2705   AC_DEFINE(HAVE_X11, 1,
2706             [Define to 1 if you want to use version 11 of X windows.
2707              Otherwise, Emacs expects to use version 10.])
2708 fi
2709 if test "${HAVE_XFREE386}" = "yes" ; then
2710   AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2711 fi
2712 if test "${HAVE_MENUS}" = "yes" ; then
2713   AC_DEFINE(HAVE_MENUS, 1,
2714             [Define to 1 if you have mouse menus.
2715              (This is automatic if you use X, but the option to specify it remains.)
2716              It is also defined with other window systems that support xmenu.c.])
2717 fi
2718 if test "${GNU_MALLOC}" = "yes" ; then
2719   AC_DEFINE(GNU_MALLOC, 1,
2720             [Define to 1 if you want to use the GNU memory allocator.])
2721 fi
2722 if test "${REL_ALLOC}" = "yes" ; then
2723   AC_DEFINE(REL_ALLOC, 1,
2724             [Define REL_ALLOC if you want to use the relocating allocator for
2725              buffer space.])
2726 fi
2727
2728
2729 AH_TOP([/* GNU Emacs site configuration template file.
2730    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2731      2006, 2007, 2008  Free Software Foundation, Inc.
2732
2733 This file is part of GNU Emacs.
2734
2735 GNU Emacs is free software; you can redistribute it and/or modify
2736 it under the terms of the GNU General Public License as published by
2737 the Free Software Foundation; either version 3, or (at your option)
2738 any later version.
2739
2740 GNU Emacs is distributed in the hope that it will be useful,
2741 but WITHOUT ANY WARRANTY; without even the implied warranty of
2742 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2743 GNU General Public License for more details.
2744
2745 You should have received a copy of the GNU General Public License
2746 along with GNU Emacs; see the file COPYING.  If not, write to the
2747 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
2748 Boston, MA 02110-1301, USA.  */
2749
2750
2751 /* No code in Emacs #includes config.h twice, but some bits of code
2752    intended to work with other packages as well (like gmalloc.c)
2753    think they can include it as many times as they like.  */
2754 #ifndef EMACS_CONFIG_H
2755 #define EMACS_CONFIG_H
2756 ])dnl
2757
2758 AH_BOTTOM([
2759 /* If we're using any sort of window system, define some consequences.  */
2760 #ifdef HAVE_X_WINDOWS
2761 #define HAVE_WINDOW_SYSTEM
2762 #define MULTI_KBOARD
2763 #define HAVE_MOUSE
2764 #endif
2765
2766 /* Multi-tty support relies on MULTI_KBOARD.  It seems safe to turn it
2767    on unconditionally. */
2768 #ifndef MULTI_KBOARD
2769 #define MULTI_KBOARD
2770 #endif
2771
2772 /* If we're using the Carbon API on Mac OS X, define a few more
2773    variables as well.  */
2774 #ifdef HAVE_CARBON
2775 #define HAVE_WINDOW_SYSTEM
2776 #define HAVE_MOUSE
2777 #endif
2778
2779 /* Define USER_FULL_NAME to return a string
2780    that is the user's full name.
2781    It can assume that the variable `pw'
2782    points to the password file entry for this user.
2783
2784    At some sites, the pw_gecos field contains
2785    the user's full name.  If neither this nor any other
2786    field contains the right thing, use pw_name,
2787    giving the user's login name, since that is better than nothing.  */
2788 #define USER_FULL_NAME pw->pw_gecos
2789
2790 /* Define AMPERSAND_FULL_NAME if you use the convention
2791    that & in the full name stands for the login id.  */
2792 /* Turned on June 1996 supposing nobody will mind it.  */
2793 #define AMPERSAND_FULL_NAME
2794
2795 /* We have blockinput.h.  */
2796 #define DO_BLOCK_INPUT
2797
2798 /* Define HAVE_SOUND if we have sound support.  We know it works
2799    and compiles only on the specified platforms.   For others,
2800    it probably doesn't make sense to try.  */
2801
2802 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2803 #ifdef HAVE_MACHINE_SOUNDCARD_H
2804 #define HAVE_SOUND 1
2805 #endif
2806 #ifdef HAVE_SYS_SOUNDCARD_H
2807 #define HAVE_SOUND 1
2808 #endif
2809 #ifdef HAVE_SOUNDCARD_H
2810 #define HAVE_SOUND 1
2811 #endif
2812 #ifdef HAVE_ALSA
2813 #define HAVE_SOUND 1
2814 #endif
2815 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2816
2817 /* If using GNU, then support inline function declarations. */
2818 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2819    generally, because even if non-gcc compilers accept `inline', they
2820    may reject `extern inline'.  */
2821 #if defined (__GNUC__) && defined (OPTIMIZE)
2822 #define INLINE __inline__
2823 #else
2824 #define INLINE
2825 #endif
2826
2827 /* Include the os and machine dependent files.  */
2828 #include config_opsysfile
2829 #include config_machfile
2830
2831 /* Load in the conversion definitions if this system
2832    needs them and the source file being compiled has not
2833    said to inhibit this.  There should be no need for you
2834    to alter these lines.  */
2835
2836 #ifdef SHORTNAMES
2837 #ifndef NO_SHORTNAMES
2838 #include "../shortnames/remap.h"
2839 #endif /* not NO_SHORTNAMES */
2840 #endif /* SHORTNAMES */
2841
2842 /* If no remapping takes place, static variables cannot be dumped as
2843    pure, so don't worry about the `static' keyword. */
2844 #ifdef NO_REMAP
2845 #undef static
2846 #endif
2847
2848 /* Define `subprocesses' should be defined if you want to
2849    have code for asynchronous subprocesses
2850    (as used in M-x compile and M-x shell).
2851    These do not work for some USG systems yet;
2852    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
2853
2854 #ifndef VMS
2855 #ifndef USG
2856 /* #define subprocesses */
2857 #endif
2858 #endif
2859
2860 /* SIGTYPE is the macro we actually use.  */
2861 #ifndef SIGTYPE
2862 #define SIGTYPE RETSIGTYPE
2863 #endif
2864
2865 #ifdef emacs /* Don't do this for lib-src.  */
2866 /* Tell regex.c to use a type compatible with Emacs.  */
2867 #define RE_TRANSLATE_TYPE Lisp_Object
2868 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2869 #ifdef make_number
2870 /* If make_number is a macro, use it.  */
2871 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2872 #else
2873 /* If make_number is a function, avoid it.  */
2874 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2875 #endif
2876 #endif
2877
2878 /* Avoid link-time collision with system mktime if we will use our own.  */
2879 #if ! HAVE_MKTIME || BROKEN_MKTIME
2880 #define mktime emacs_mktime
2881 #endif
2882
2883 #define my_strftime nstrftime   /* for strftime.c */
2884
2885 /* The rest of the code currently tests the CPP symbol BSTRING.
2886    Override any claims made by the system-description files.
2887    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2888 #undef BSTRING
2889 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2890 #define BSTRING
2891 #endif
2892
2893 /* Some of the files of Emacs which are intended for use with other
2894    programs assume that if you have a config.h file, you must declare
2895    the type of getenv.
2896
2897    This declaration shouldn't appear when alloca.s or Makefile.in
2898    includes config.h.  */
2899 #ifndef NOT_C_CODE
2900 extern char *getenv ();
2901 #endif
2902
2903 /* These default definitions are good for almost all machines.
2904    The exceptions override them in m/MACHINE.h.  */
2905
2906 #ifndef BITS_PER_CHAR
2907 #define BITS_PER_CHAR 8
2908 #endif
2909
2910 #ifndef BITS_PER_SHORT
2911 #define BITS_PER_SHORT 16
2912 #endif
2913
2914 /* Note that lisp.h uses this in a preprocessor conditional, so it
2915    would not work to use sizeof.  That being so, we do all of them
2916    without sizeof, for uniformity's sake.  */
2917 #ifndef BITS_PER_INT
2918 #define BITS_PER_INT 32
2919 #endif
2920
2921 #ifndef BITS_PER_LONG
2922 #ifdef _LP64
2923 #define BITS_PER_LONG 64
2924 #else
2925 #define BITS_PER_LONG 32
2926 #endif
2927 #endif
2928
2929 /* Define if the compiler supports function prototypes.  It may do so
2930    but not define __STDC__ (e.g. DEC C by default) or may define it as
2931    zero.  */
2932 #undef PROTOTYPES
2933 /* For mktime.c:  */
2934 #ifndef __P
2935 # if defined PROTOTYPES
2936 #  define __P(args) args
2937 # else
2938 #  define __P(args) ()
2939 # endif  /* GCC.  */
2940 #endif /* __P */
2941
2942 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2943 #ifndef NOT_C_CODE
2944 #ifdef HAVE_STRING_H
2945 #include "string.h"
2946 #endif
2947 #ifdef HAVE_STRINGS_H
2948 #include "strings.h"  /* May be needed for bcopy & al. */
2949 #endif
2950 #ifdef HAVE_STDLIB_H
2951 #include <stdlib.h>
2952 #endif
2953 #ifndef __GNUC__
2954 # ifdef HAVE_ALLOCA_H
2955 #  include <alloca.h>
2956 # else /* AIX files deal with #pragma.  */
2957 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2958 char *alloca ();
2959 #  endif
2960 # endif /* HAVE_ALLOCA_H */
2961 #endif /* __GNUC__ */
2962 #ifndef HAVE_SIZE_T
2963 typedef unsigned size_t;
2964 #endif
2965 #endif /* NOT_C_CODE */
2966
2967 /* Define HAVE_X_I18N if we have usable i18n support.  */
2968
2969 #ifdef HAVE_X11R6
2970 #define HAVE_X_I18N
2971 #elif !defined X11R5_INHIBIT_I18N
2972 #define HAVE_X_I18N
2973 #endif
2974
2975 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2976
2977 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2978 #define HAVE_X11R6_XIM
2979 #endif
2980
2981 /* Should we enable expensive run-time checking of data types?  */
2982 #undef ENABLE_CHECKING
2983
2984 #if defined __GNUC__ && (__GNUC__ > 2 \
2985                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2986 #define NO_RETURN       __attribute__ ((__noreturn__))
2987 #else
2988 #define NO_RETURN       /* nothing */
2989 #endif
2990
2991 /* These won't be used automatically yet.  We also need to know, at least,
2992    that the stack is continuous.  */
2993 #ifdef __GNUC__
2994 #  ifndef GC_SETJMP_WORKS
2995   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2996      see NON_SAVING_SETJMP in the target descriptions.  */
2997   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2998      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2999      Fixme: Deal with SVR3.  */
3000 #    define GC_SETJMP_WORKS 1
3001 #  endif
3002 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3003 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3004 #  endif
3005 #endif
3006
3007 #ifndef HAVE_BCOPY
3008 #define bcopy(a,b,s) memcpy (b,a,s)
3009 #endif
3010 #ifndef HAVE_BZERO
3011 #define bzero(a,s) memset (a,0,s)
3012 #endif
3013 #ifndef HAVE_BCMP
3014 #define BCMP memcmp
3015 #endif
3016
3017 #endif /* EMACS_CONFIG_H */
3018
3019 /*
3020 Local Variables:
3021 mode: c
3022 End:
3023 */
3024 ])dnl
3025
3026 #### Report on what we decided to do.
3027 #### Report GTK as a toolkit, even if it doesn't use Xt.
3028 #### It makes printing result more understandable as using GTK sets
3029 #### toolkit_scroll_bars to yes by default.
3030 if test "${HAVE_GTK}" = "yes"; then
3031   USE_X_TOOLKIT=GTK
3032 fi
3033
3034 echo "
3035 Configured for \`${canonical}'.
3036
3037   Where should the build process find the source code?    ${srcdir}
3038   What operating system and machine description files should Emacs use?
3039         \`${opsysfile}' and \`${machfile}'
3040   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3041   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3042   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3043   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3044   What window system should Emacs use?                    ${window_system}
3045   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3046
3047 if test -n "${x_includes}"; then
3048 echo "  Where do we find X Windows header files?                ${x_includes}"
3049 else
3050 echo "  Where do we find X Windows header files?                Standard dirs"
3051 fi
3052 if test -n "${x_libraries}"; then
3053 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3054 else
3055 echo "  Where do we find X Windows libraries?                   Standard dirs"
3056 fi
3057
3058 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3059 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3060 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3061 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3062 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
3063 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3064 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3065 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3066 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3067 echo "  Does Emacs use a font backend?                          ${USE_FONT_BACKEND}"
3068
3069 if test "${USE_FONT_BACKEND}" = "yes"; then
3070   echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3071   echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3072   echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3073   echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3074 fi
3075 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
3076 echo
3077
3078 if test $USE_XASSERTS = yes; then
3079    echo "  Compiling with asserts turned on."
3080    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3081    echo
3082 fi
3083
3084 if test "$USE_X_TOOLKIT" = GTK; then
3085   case "$canonical" in
3086   *cygwin*)
3087     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
3088   will probably get a crash on startup.  If this happens, please use another
3089   toolkit for Emacs.  See etc/PROBLEMS for more information."
3090   ;;
3091   esac
3092 fi
3093
3094
3095 if test "$HAVE_CARBON" = "yes"; then
3096    echo
3097    echo "Warning: The Mac Carbon port is currently unsupported and has
3098 known problems.  It is not recommended for use by non-developers.
3099 Read the emacs-devel archives for more information."
3100    echo
3101 fi
3102
3103 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3104   echo "D-Bus integration has been tested for GNU/Linux only."
3105   echo
3106 fi
3107
3108
3109 # Remove any trailing slashes in these variables.
3110 [test "${prefix}" != NONE &&
3111   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3112 test "${exec_prefix}" != NONE &&
3113   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3114
3115 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3116 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3117 ## from Makefile.c can correctly provide the arg `-traditional' to the
3118 ## C preprocessor.
3119
3120 AC_EGREP_CPP(yes..yes,
3121         [yes..yes],
3122         CPP_NEED_TRADITIONAL=no,
3123         CPP_NEED_TRADITIONAL=yes)
3124
3125 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3126         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3127         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3128         lwlib/Makefile lisp/Makefile leim/Makefile, [
3129
3130 ### Make the necessary directories, if they don't exist.
3131 for dir in etc lisp ; do
3132   test -d ${dir} || mkdir ${dir}
3133 done
3134
3135 # Build src/Makefile from ${srcdir}/src/Makefile.c
3136 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3137 # This must be done after src/config.h is built, since we rely on that file.
3138
3139 # Now get this: Some word that is part of the ${srcdir} directory name
3140 # or the ${configuration} value might, just might, happen to be an
3141 # identifier like `sun4' or `i386' or something, and be predefined by
3142 # the C preprocessor to some helpful value like 1, or maybe the empty
3143 # string.  Needless to say consequent macro substitutions are less
3144 # than conducive to the makefile finding the correct directory.
3145 [undefs="`echo $top_srcdir $configuration $canonical |
3146 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3147     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3148 `"]
3149
3150 echo creating src/epaths.h
3151 ${MAKE-make} epaths-force
3152
3153 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3154 # `..' to `. .'  unless invoked with -traditional
3155
3156 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3157   CPPFLAGS="$CPPFLAGS -traditional"
3158 fi
3159
3160 echo creating lib-src/Makefile
3161 ( cd lib-src
3162   rm -f junk.c junk1.c junk2.c
3163   sed -e '/start of cpp stuff/q' \
3164       < Makefile.c > junk1.c
3165   sed -e '1,/start of cpp stuff/d'\
3166       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3167       < Makefile.c > junk.c
3168   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3169       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3170   cat junk1.c junk2.c > Makefile.new
3171   rm -f junk.c junk1.c junk2.c
3172   chmod 444 Makefile.new
3173   mv -f Makefile.new Makefile
3174 )
3175
3176 echo creating src/Makefile
3177 ( cd src
3178   rm -f junk.c junk1.c junk2.c
3179   sed -e '/start of cpp stuff/q' \
3180       < Makefile.c > junk1.c
3181   sed -e '1,/start of cpp stuff/d'\
3182       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3183       < Makefile.c > junk.c
3184   if test -f ${srcdir}/admin/unidata/UnicodeData.txt; then
3185     echo creating ${srcdir}/admin/unidata/Makefile
3186     cp ${srcdir}/admin/unidata/Makefile.in ${srcdir}/admin/unidata/Makefile
3187     CPPFLAGS="$CPPFLAGS -DHAVE_UNIDATA"
3188   fi
3189   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3190       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3191   cat junk1.c junk2.c > Makefile.new
3192   rm -f junk.c junk1.c junk2.c
3193   chmod 444 Makefile.new
3194   mv -f Makefile.new Makefile
3195 )
3196
3197 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3198   echo creating src/.gdbinit
3199   echo source $srcdir/src/.gdbinit > src/.gdbinit
3200 fi
3201
3202 # This is how we know whether to re-run configure in certain cases.
3203 touch src/config.stamp
3204
3205 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3206
3207 m4_if(dnl       Do not change this comment
3208    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3209 )dnl