lisp/rect.el

   1 ;;; rect.el --- rectangle functions for GNU Emacs.
   2
   3 ;; Copyright (C) 1985, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package provides the operations on rectangles that are ocumented
  28 ;; in the Emacs manual.
  29
  30 ;;; Code:
  31
  32 ;; extract-rectangle-line stores lines into this list
  33 ;; to accumulate them for extract-rectangle and delete-extract-rectangle.
  34 (defvar operate-on-rectangle-lines)
  35
  36 (defun operate-on-rectangle (function start end coerce-tabs)
  37   "Call FUNCTION for each line of rectangle with corners at START, END.
  38 If COERCE-TABS is non-nil, convert multi-column characters
  39 that span the starting or ending columns on any line
  40 to multiple spaces before calling FUNCTION.
  41 FUNCTION is called with three arguments:
  42  position of start of segment of this line within the rectangle,
  43  number of columns that belong to rectangle but are before that position,
  44  number of columns that belong to rectangle but are after point.
  45 Point is at the end of the segment of this line within the rectangle."
  46   (let (startcol startlinepos endcol endlinepos)
  47     (save-excursion
  48      (goto-char start)
  49      (setq startcol (current-column))
  50      (beginning-of-line)
  51      (setq startlinepos (point)))
  52     (save-excursion
  53      (goto-char end)
  54      (setq endcol (current-column))
  55      (forward-line 1)
  56      (setq endlinepos (point-marker)))
  57     (if (< endcol startcol)
  58         (setq startcol (prog1 endcol (setq endcol startcol))))
  59     (save-excursion
  60      (goto-char startlinepos)
  61      (while (< (point) endlinepos)
  62        (let (startpos begextra endextra)
  63          (move-to-column startcol coerce-tabs)
  64          (setq begextra (- (current-column) startcol))
  65          (setq startpos (point))
  66          (move-to-column endcol coerce-tabs)
  67          ;; If we overshot, move back one character
  68          ;; so that endextra will be positive.
  69          (if (and (not coerce-tabs) (> (current-column) endcol))
  70              (backward-char 1))
  71          (setq endextra (- endcol (current-column)))
  72          (if (< begextra 0)
  73              (setq endextra (+ endextra begextra)
  74                    begextra 0))
  75          (funcall function startpos begextra endextra))
  76        (forward-line 1)))
  77     (- endcol startcol)))
  78
  79 (defun delete-rectangle-line (startdelpos ignore ignore)
  80   (delete-region startdelpos (point)))
  81
  82 (defun delete-extract-rectangle-line (startdelpos begextra endextra)
  83   (save-excursion
  84    (extract-rectangle-line startdelpos begextra endextra))
  85   (delete-region startdelpos (point)))
  86
  87 (defun extract-rectangle-line (startdelpos begextra endextra)
  88   (let ((line (buffer-substring startdelpos (point)))
  89         (end (point)))
  90     (goto-char startdelpos)
  91     (while (search-forward "\t" end t)
  92       (let ((width (- (current-column)
  93                       (save-excursion (forward-char -1)
  94                                       (current-column)))))
  95         (setq line (concat (substring line 0 (- (point) end 1))
  96                            (spaces-string width)
  97                            (substring line (+ (length line) (- (point) end)))))))
  98     (if (or (> begextra 0) (> endextra 0))
  99         (setq line (concat (spaces-string begextra)
 100                            line
 101                            (spaces-string endextra))))
 102     (setq operate-on-rectangle-lines (cons line operate-on-rectangle-lines))))
 103
 104 (defconst spaces-strings
 105   '["" " " "  " "   " "    " "     " "      " "       " "        "])
 106
 107 (defun spaces-string (n)
 108   (if (<= n 8) (aref spaces-strings n)
 109     (let ((val ""))
 110       (while (> n 8)
 111         (setq val (concat "        " val)
 112               n (- n 8)))
 113       (concat val (aref spaces-strings n)))))
 114
 115 ;;;###autoload
 116 (defun delete-rectangle (start end)
 117   "Delete (don't save) text in rectangle with point and mark as corners.
 118 The same range of columns is deleted in each line starting with the line
 119 where the region begins and ending with the line where the region ends."
 120   (interactive "r")
 121   (operate-on-rectangle 'delete-rectangle-line start end t))
 122
 123 ;;;###autoload
 124 (defun delete-extract-rectangle (start end)
 125   "Delete contents of rectangle and return it as a list of strings.
 126 Arguments START and END are the corners of the rectangle.
 127 The value is list of strings, one for each line of the rectangle."
 128   (let (operate-on-rectangle-lines)
 129     (operate-on-rectangle 'delete-extract-rectangle-line
 130                           start end t)
 131     (nreverse operate-on-rectangle-lines)))
 132
 133 ;;;###autoload
 134 (defun extract-rectangle (start end)
 135   "Return contents of rectangle with corners at START and END.
 136 Value is list of strings, one for each line of the rectangle."
 137   (let (operate-on-rectangle-lines)
 138     (operate-on-rectangle 'extract-rectangle-line start end nil)
 139     (nreverse operate-on-rectangle-lines)))
 140
 141 (defvar killed-rectangle nil
 142   "Rectangle for yank-rectangle to insert.")
 143
 144 ;;;###autoload
 145 (defun kill-rectangle (start end)
 146   "Delete rectangle with corners at point and mark; save as last killed one.
 147 Calling from program, supply two args START and END, buffer positions.
 148 But in programs you might prefer to use `delete-extract-rectangle'."
 149   (interactive "r")
 150   (if buffer-read-only
 151       (progn
 152         (setq killed-rectangle (extract-rectangle start end))
 153         (barf-if-buffer-read-only)))
 154   (setq killed-rectangle (delete-extract-rectangle start end)))
 155
 156 ;;;###autoload
 157 (defun yank-rectangle ()
 158   "Yank the last killed rectangle with upper left corner at point."
 159   (interactive)
 160   (insert-rectangle killed-rectangle))
 161
 162 ;;;###autoload
 163 (defun insert-rectangle (rectangle)
 164   "Insert text of RECTANGLE with upper left corner at point.
 165 RECTANGLE's first line is inserted at point, its second
 166 line is inserted at a point vertically under point, etc.
 167 RECTANGLE should be a list of strings.
 168 After this command, the mark is at the upper left corner
 169 and point is at the lower right corner."
 170   (let ((lines rectangle)
 171         (insertcolumn (current-column))
 172         (first t))
 173     (push-mark)
 174     (while lines
 175       (or first
 176           (progn
 177            (forward-line 1)
 178            (or (bolp) (insert ?\n))
 179            (move-to-column insertcolumn t)))
 180       (setq first nil)
 181       (insert (car lines))
 182       (setq lines (cdr lines)))))
 183
 184 ;;;###autoload
 185 (defun open-rectangle (start end)
 186   "Blank out rectangle with corners at point and mark, shifting text right.
 187 The text previously in the region is not overwritten by the blanks,
 188 but instead winds up to the right of the rectangle."
 189   (interactive "r")
 190   (operate-on-rectangle 'open-rectangle-line start end nil)
 191   (goto-char start))
 192
 193 (defun open-rectangle-line (startpos begextra endextra)
 194   ;; Column where rectangle ends.
 195   (let ((endcol (+ (current-column) endextra))
 196         whitewidth)
 197     (goto-char startpos)
 198     ;; Column where rectangle begins.
 199     (let ((begcol (- (current-column) begextra)))
 200       (skip-chars-forward " \t")
 201       ;; Width of whitespace to be deleted and recreated.
 202       (setq whitewidth (- (current-column) begcol)))
 203     ;; Delete the whitespace following the start column.
 204     (delete-region startpos (point))
 205     ;; Open the desired width, plus same amount of whitespace we just deleted.
 206     (indent-to (+ endcol whitewidth))))
 207
 208 ;;;###autoload
 209 (defun close-rectangle (start end)
 210   "Delete all whitespace following a specified column in each line.
 211 The left edge of the rectangle specifies the position in each line
 212 at which whitespace deletion should begin.  On each line in the
 213 rectangle, all continuous whitespace starting at that column is deleted."
 214   (interactive "r")
 215   (operate-on-rectangle '(lambda (startpos begextra endextra)
 216                            (save-excursion
 217                              (goto-char startpos)
 218                              (delete-region (point)
 219                                             (progn
 220                                               (skip-syntax-forward " ")
 221                                               (point)))))
 222                         start end t))
 223
 224 ;; string-rectangle uses this variable to pass the string
 225 ;; to string-rectangle-line.
 226 (defvar string-rectangle-string)
 227
 228 ;;;###autoload
 229 (defun string-rectangle (start end string)
 230   "Replace rectangle contents with STRING on each line.
 231 The length of STRING need not be the same as the rectangle width.
 232
 233 Called from a program, takes three args; START, END and STRING."
 234   (interactive "r\nsString rectangle: ")
 235   (let ((string-rectangle-string string))
 236     (operate-on-rectangle 'string-rectangle-line start end t)))
 237
 238 (defun string-rectangle-line (startpos begextra endextra)
 239   (let (whitespace)
 240     ;; Delete the width of the rectangle.
 241     (delete-region startpos (point))
 242     ;; Compute horizontal width of following whitespace.
 243     (let ((ocol (current-column)))
 244       (skip-chars-forward " \t")
 245       (setq whitespace (- (current-column) ocol)))
 246     ;; Delete the following whitespace.
 247     (delete-region startpos (point))
 248     ;; Insert the desired string.
 249     (insert string-rectangle-string)
 250     ;; Insert the same width of whitespace that we had before.
 251     (indent-to (+ (current-column) whitespace))))
 252
 253 ;;;###autoload
 254 (defun clear-rectangle (start end)
 255   "Blank out rectangle with corners at point and mark.
 256 The text previously in the region is overwritten by the blanks.
 257 When called from a program, requires two args which specify the corners."
 258   (interactive "r")
 259   (operate-on-rectangle 'clear-rectangle-line start end t))
 260
 261 (defun clear-rectangle-line (startpos begextra endextra)
 262   ;; Find end of whitespace after the rectangle.
 263   (skip-chars-forward " \t")
 264   (let ((column (+ (current-column) endextra)))
 265     ;; Delete the text in the rectangle, and following whitespace.
 266     (delete-region (point)
 267                    (progn (goto-char startpos)
 268                           (skip-chars-backward " \t")
 269                           (point)))
 270     ;; Reindent out to same column that we were at.
 271     (indent-to column)))
 272
 273 (provide 'rect)
 274
 275 ;;; rect.el ends here