lisp/mail/mail-utils.el

   1 ;;; mail-utils.el --- utility functions used both by rmail and rnews
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: mail, news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Utility functions for mail and netnews handling.  These handle fine
  27 ;; points of header parsing.
  28
  29 ;;; Code:
  30
  31 ;;; We require lisp-mode to make sure that lisp-mode-syntax-table has
  32 ;;; been initialized.
  33 (require 'lisp-mode)
  34
  35 ;;;###autoload
  36 (defvar mail-use-rfc822 nil "\
  37 *If non-nil, use a full, hairy RFC822 parser on mail addresses.
  38 Otherwise, (the default) use a smaller, somewhat faster, and
  39 often correct parser.")
  40
  41 (defun mail-string-delete (string start end)
  42   "Returns a string containing all of STRING except the part
  43 from START (inclusive) to END (exclusive)."
  44   (if (null end) (substring string 0 start)
  45     (concat (substring string 0 start)
  46             (substring string end nil))))
  47
  48 (defun mail-strip-quoted-names (address)
  49   "Delete comments and quoted strings in an address list ADDRESS.
  50 Also delete leading/trailing whitespace and replace FOO <BAR> with just BAR.
  51 Return a modified address list."
  52   (if (null address)
  53       nil
  54     (if mail-use-rfc822
  55         (progn (require 'rfc822)
  56                (mapconcat 'identity (rfc822-addresses address) ", "))
  57       (let (pos)
  58        (string-match "\\`[ \t\n]*" address)
  59        ;; strip surrounding whitespace
  60        (setq address (substring address
  61                                 (match-end 0)
  62                                 (string-match "[ \t\n]*\\'" address
  63                                               (match-end 0))))
  64
  65        ;; Detect nested comments.
  66        (if (string-match "[ \t]*(\\([^)\"\\]\\|\\\\.\\|\\\\\n\\)*(" address)
  67            ;; Strip nested comments.
  68            (save-excursion
  69              (set-buffer (get-buffer-create " *temp*"))
  70              (erase-buffer)
  71              (insert address)
  72              (set-syntax-table lisp-mode-syntax-table)
  73              (goto-char 1)
  74              (while (search-forward "(" nil t)
  75                (forward-char -1)
  76                (skip-chars-backward " \t")
  77                (delete-region (point)
  78                               (save-excursion
  79                                 (condition-case ()
  80                                     (forward-sexp 1)
  81                                   (error (goto-char (point-max))))
  82                                   (point))))
  83              (setq address (buffer-string))
  84              (erase-buffer))
  85          ;; Strip non-nested comments an easier way.
  86          (while (setq pos (string-match
  87                             ;; This doesn't hack rfc822 nested comments
  88                             ;;  `(xyzzy (foo) whinge)' properly.  Big deal.
  89                             "[ \t]*(\\([^)\"\\]\\|\\\\.\\|\\\\\n\\)*)"
  90                             address))
  91            (setq address
  92                  (mail-string-delete address
  93                                      pos (match-end 0)))))
  94
  95        ;; strip `quoted' names (This is supposed to hack `"Foo Bar" <bar@host>')
  96        (setq pos 0)
  97        (while (setq pos (string-match
  98                           "[ \t]*\"\\([^\"\\]\\|\\\\.\\|\\\\\n\\)*\"[ \t\n]*"
  99                           address pos))
 100          ;; If the next thing is "@", we have "foo bar"@host.  Leave it.
 101          (if (and (> (length address) (match-end 0))
 102                   (= (aref address (match-end 0)) ?@))
 103              (setq pos (match-end 0))
 104            (setq address
 105                  (mail-string-delete address
 106                                      pos (match-end 0)))))
 107        ;; Retain only part of address in <> delims, if there is such a thing.
 108        (while (setq pos (string-match "\\(,\\|\\`\\)[^,]*<\\([^>,]*>\\)"
 109                                       address))
 110          (let ((junk-beg (match-end 1))
 111                (junk-end (match-beginning 2))
 112                (close (match-end 0)))
 113            (setq address (mail-string-delete address (1- close) close))
 114            (setq address (mail-string-delete address junk-beg junk-end))))
 115        address))))
 116
 117 (or (and (boundp 'rmail-default-dont-reply-to-names)
 118          (not (null rmail-default-dont-reply-to-names)))
 119     (setq rmail-default-dont-reply-to-names "info-"))
 120
 121 ; rmail-dont-reply-to-names is defined in loaddefs
 122 (defun rmail-dont-reply-to (userids)
 123   "Returns string of mail addresses USERIDS sans any recipients
 124 that start with matches for `rmail-dont-reply-to-names'.
 125 Usenet paths ending in an element that matches are removed also."
 126   (if (null rmail-dont-reply-to-names)
 127       (setq rmail-dont-reply-to-names
 128             (concat (if rmail-default-dont-reply-to-names
 129                         (concat rmail-default-dont-reply-to-names "\\|")
 130                         "")
 131                     (concat (regexp-quote (user-login-name))
 132                             "\\>"))))
 133   (let ((match (concat "\\(^\\|,\\)[ \t\n]*\\([^,\n]*!\\|\\)\\("
 134                        rmail-dont-reply-to-names
 135                        "\\)"))
 136         (case-fold-search t)
 137         pos epos)
 138     (while (setq pos (string-match match userids))
 139       (if (> pos 0) (setq pos (1+ pos)))
 140       (setq epos
 141             (if (string-match "[ \t\n,]+" userids (match-end 0))
 142                 (match-end 0)
 143               (length userids)))
 144       (setq userids
 145             (mail-string-delete
 146               userids pos epos)))
 147     ;; get rid of any trailing commas
 148     (if (setq pos (string-match "[ ,\t\n]*\\'" userids))
 149         (setq userids (substring userids 0 pos)))
 150     ;; remove leading spaces. they bother me.
 151     (if (string-match "\\s *" userids)
 152         (substring userids (match-end 0))
 153       userids)))
 154 \f
 155 ;;;###autoload
 156 (defun mail-fetch-field (field-name &optional last all)
 157   "Return the value of the header field FIELD-NAME.
 158 The buffer is expected to be narrowed to just the headers of the message.
 159 If second arg LAST is non-nil, use the last such field if there are several.
 160 If third arg ALL is non-nil, concatenate all such fields with commas between."
 161   (save-excursion
 162     (goto-char (point-min))
 163     (let ((case-fold-search t)
 164           (name (concat "^" (regexp-quote field-name) "[ \t]*:[ \t]*")))
 165       (if all
 166           (let ((value ""))
 167             (while (re-search-forward name nil t)
 168               (let ((opoint (point)))
 169                 (while (progn (forward-line 1)
 170                               (looking-at "[ \t]")))
 171                 ;; Back up over newline, then trailing spaces or tabs
 172                 (forward-char -1)
 173                 (while (member (preceding-char) '(?  ?\t))
 174                   (forward-char -1))
 175                 (setq value (concat value
 176                                     (if (string= value "") "" ", ")
 177                                     (buffer-substring opoint (point))))))
 178             (and (not (string= value "")) value))
 179         (if (re-search-forward name nil t)
 180             (progn
 181               (if last (while (re-search-forward name nil t)))
 182               (let ((opoint (point)))
 183                 (while (progn (forward-line 1)
 184                               (looking-at "[ \t]")))
 185                 ;; Back up over newline, then trailing spaces or tabs
 186                 (forward-char -1)
 187                 (while (member (preceding-char) '(?  ?\t))
 188                   (forward-char -1))
 189                 (buffer-substring opoint (point)))))))))
 190 \f
 191 ;; Parse a list of tokens separated by commas.
 192 ;; It runs from point to the end of the visible part of the buffer.
 193 ;; Whitespace before or after tokens is ignored,
 194 ;; but whitespace within tokens is kept.
 195 (defun mail-parse-comma-list ()
 196   (let (accumulated
 197         beg)
 198     (skip-chars-forward " ")
 199     (while (not (eobp))
 200       (setq beg (point))
 201       (skip-chars-forward "^,")
 202       (skip-chars-backward " ")
 203       (setq accumulated
 204             (cons (buffer-substring beg (point))
 205                   accumulated))
 206       (skip-chars-forward "^,")
 207       (skip-chars-forward ", "))
 208     accumulated))
 209
 210 (defun mail-comma-list-regexp (labels)
 211   (let (pos)
 212     (setq pos (or (string-match "[^ \t]" labels) 0))
 213     ;; Remove leading and trailing whitespace.
 214     (setq labels (substring labels pos (string-match "[ \t]*$" labels pos)))
 215     ;; Change each comma to \|, and flush surrounding whitespace.
 216     (while (setq pos (string-match "[ \t]*,[ \t]*" labels))
 217       (setq labels
 218             (concat (substring labels 0 pos)
 219                     "\\|"
 220                     (substring labels (match-end 0))))))
 221   labels)
 222 \f
 223 (defun mail-rfc822-time-zone (time)
 224   (let* ((sec (or (car (current-time-zone time)) 0))
 225          (absmin (/ (abs sec) 60)))
 226     (format "%c%02d%02d" (if (< sec 0) ?- ?+) (/ absmin 60) (% absmin 60))))
 227
 228 (defun mail-rfc822-date ()
 229   (let* ((time (current-time))
 230          (s (current-time-string time)))
 231     (string-match "[^ ]+ +\\([^ ]+\\) +\\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)" s)
 232     (concat (substring s (match-beginning 2) (match-end 2)) " "
 233             (substring s (match-beginning 1) (match-end 1)) " "
 234             (substring s (match-beginning 4) (match-end 4)) " "
 235             (substring s (match-beginning 3) (match-end 3)) " "
 236             (mail-rfc822-time-zone time))))
 237
 238 (provide 'mail-utils)
 239
 240 ;;; mail-utils.el ends here